pod/perlrebackslash.pod

   1 =head1 NAME
   2
   3 perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
   4
   5 =head1 DESCRIPTION
   6
   7 The top level documentation about Perl regular expressions
   8 is found in L<perlre>.
   9
  10 This document describes all backslash and escape sequences. After
  11 explaining the role of the backslash, it lists all the sequences that have
  12 a special meaning in Perl regular expressions (in alphabetical order),
  13 then describes each of them.
  14
  15 Most sequences are described in detail in different documents; the primary
  16 purpose of this document is to have a quick reference guide describing all
  17 backslash and escape sequences.
  18
  19 =head2 The backslash
  20
  21 In a regular expression, the backslash can perform one of two tasks:
  22 it either takes away the special meaning of the character following it
  23 (for instance, C<\|> matches a vertical bar, it's not an alternation),
  24 or it is the start of a backslash or escape sequence.
  25
  26 The rules determining what it is are quite simple: if the character
  27 following the backslash is an ASCII punctuation (non-word) character (that is,
  28 anything that is not a letter, digit, or underscore), then the backslash just
  29 takes away any special meaning of the character following it.
  30
  31 If the character following the backslash is an ASCII letter or an ASCII digit,
  32 then the sequence may be special; if so, it's listed below. A few letters have
  33 not been used yet, so escaping them with a backslash doesn't change them to be
  34 special.  A future version of Perl may assign a special meaning to them, so if
  35 you have warnings turned on, Perl issues a warning if you use such a
  36 sequence.  [1].
  37
  38 It is however guaranteed that backslash or escape sequences never have a
  39 punctuation character following the backslash, not now, and not in a future
  40 version of Perl 5. So it is safe to put a backslash in front of a non-word
  41 character.
  42
  43 Note that the backslash itself is special; if you want to match a backslash,
  44 you have to escape the backslash with a backslash: C</\\/> matches a single
  45 backslash.
  46
  47 =over 4
  48
  49 =item [1]
  50
  51 There is one exception. If you use an alphanumeric character as the
  52 delimiter of your pattern (which you probably shouldn't do for readability
  53 reasons), you have to escape the delimiter if you want to match
  54 it. Perl won't warn then. See also L<perlop/Gory details of parsing
  55 quoted constructs>.
  56
  57 =back
  58
  59
  60 =head2 All the sequences and escapes
  61
  62 Those not usable within a bracketed character class (like C<[\da-z]>) are marked
  63 as C<Not in [].>
  64
  65  \000              Octal escape sequence.  See also \o{}.
  66  \1                Absolute backreference.  Not in [].
  67  \a                Alarm or bell.
  68  \A                Beginning of string.  Not in [].
  69  \b{}, \b          Boundary. (\b is a backspace in []).
  70  \B{}, \B          Not a boundary.  Not in [].
  71  \cX               Control-X.
  72  \d                Match any digit character.
  73  \D                Match any character that isn't a digit.
  74  \e                Escape character.
  75  \E                Turn off \Q, \L and \U processing.  Not in [].
  76  \f                Form feed.
  77  \F                Foldcase till \E.  Not in [].
  78  \g{}, \g1         Named, absolute or relative backreference.
  79                    Not in [].
  80  \G                Pos assertion.  Not in [].
  81  \h                Match any horizontal whitespace character.
  82  \H                Match any character that isn't horizontal whitespace.
  83  \k{}, \k<>, \k''  Named backreference.  Not in [].
  84  \K                Keep the stuff left of \K.  Not in [].
  85  \l                Lowercase next character.  Not in [].
  86  \L                Lowercase till \E.  Not in [].
  87  \n                (Logical) newline character.
  88  \N                Match any character but newline.  Not in [].
  89  \N{}              Named or numbered (Unicode) character or sequence.
  90  \o{}              Octal escape sequence.
  91  \p{}, \pP         Match any character with the given Unicode property.
  92  \P{}, \PP         Match any character without the given property.
  93  \Q                Quote (disable) pattern metacharacters till \E.  Not
  94                    in [].
  95  \r                Return character.
  96  \R                Generic new line.  Not in [].
  97  \s                Match any whitespace character.
  98  \S                Match any character that isn't a whitespace.
  99  \t                Tab character.
 100  \u                Titlecase next character.  Not in [].
 101  \U                Uppercase till \E.  Not in [].
 102  \v                Match any vertical whitespace character.
 103  \V                Match any character that isn't vertical whitespace
 104  \w                Match any word character.
 105  \W                Match any character that isn't a word character.
 106  \x{}, \x00        Hexadecimal escape sequence.
 107  \X                Unicode "extended grapheme cluster".  Not in [].
 108  \z                End of string.  Not in [].
 109  \Z                End of string.  Not in [].
 110
 111 =head2 Character Escapes
 112
 113 =head3  Fixed characters
 114
 115 A handful of characters have a dedicated I<character escape>. The following
 116 table shows them, along with their ASCII code points (in decimal and hex),
 117 their ASCII name, the control escape on ASCII platforms and a short
 118 description.  (For EBCDIC platforms, see L<perlebcdic/OPERATOR DIFFERENCES>.)
 119
 120  Seq.  Code Point  ASCII   Cntrl   Description.
 121        Dec    Hex
 122   \a     7     07    BEL    \cG    alarm or bell
 123   \b     8     08     BS    \cH    backspace [1]
 124   \e    27     1B    ESC    \c[    escape character
 125   \f    12     0C     FF    \cL    form feed
 126   \n    10     0A     LF    \cJ    line feed [2]
 127   \r    13     0D     CR    \cM    carriage return
 128   \t     9     09    TAB    \cI    tab
 129
 130 =over 4
 131
 132 =item [1]
 133
 134 C<\b> is the backspace character only inside a character class. Outside a
 135 character class, C<\b> alone is a word-character/non-word-character
 136 boundary, and C<\b{}> is some other type of boundary.
 137
 138 =item [2]
 139
 140 C<\n> matches a logical newline. Perl converts between C<\n> and your
 141 OS's native newline character when reading from or writing to text files.
 142
 143 =back
 144
 145 =head4 Example
 146
 147  $str =~ /\t/;   # Matches if $str contains a (horizontal) tab.
 148
 149 =head3 Control characters
 150
 151 C<\c> is used to denote a control character; the character following C<\c>
 152 determines the value of the construct.  For example the value of C<\cA> is
 153 C<chr(1)>, and the value of C<\cb> is C<chr(2)>, etc.
 154 The gory details are in L<perlop/"Regexp Quote-Like Operators">.  A complete
 155 list of what C<chr(1)>, etc. means for ASCII and EBCDIC platforms is in
 156 L<perlebcdic/OPERATOR DIFFERENCES>.
 157
 158 Note that C<\c\> alone at the end of a regular expression (or doubled-quoted
 159 string) is not valid.  The backslash must be followed by another character.
 160 That is, C<\c\I<X>> means C<chr(28) . 'I<X>'> for all characters I<X>.
 161
 162 To write platform-independent code, you must use C<\N{I<NAME>}> instead, like
 163 C<\N{ESCAPE}> or C<\N{U+001B}>, see L<charnames>.
 164
 165 Mnemonic: I<c>ontrol character.
 166
 167 =head4 Example
 168
 169  $str =~ /\cK/;  # Matches if $str contains a vertical tab (control-K).
 170
 171 =head3 Named or numbered characters and character sequences
 172
 173 Unicode characters have a Unicode name and numeric code point (ordinal)
 174 value.  Use the
 175 C<\N{}> construct to specify a character by either of these values.
 176 Certain sequences of characters also have names.
 177
 178 To specify by name, the name of the character or character sequence goes
 179 between the curly braces.
 180
 181 To specify a character by Unicode code point, use the form C<\N{U+I<code
 182 point>}>, where I<code point> is a number in hexadecimal that gives the
 183 code point that Unicode has assigned to the desired character.  It is
 184 customary but not required to use leading zeros to pad the number to 4
 185 digits.  Thus C<\N{U+0041}> means C<LATIN CAPITAL LETTER A>, and you will
 186 rarely see it written without the two leading zeros.  C<\N{U+0041}> means
 187 "A" even on EBCDIC machines (where the ordinal value of "A" is not 0x41).
 188
 189 It is even possible to give your own names to characters and character
 190 sequences by using the L<charnames> module.  These custom names are
 191 lexically scoped, and so a given code point may have different names
 192 in different scopes.  The name used is what is in effect at the time the
 193 C<\N{}> is expanded.  For patterns in double-quotish context, that means
 194 at the time the pattern is parsed.  But for patterns that are delimitted
 195 by single quotes, the expansion is deferred until pattern compilation
 196 time, which may very well have a different C<charnames> translator in
 197 effect.
 198
 199 (There is an expanded internal form that you may see in debug output:
 200 C<\N{U+I<code point>.I<code point>...}>.
 201 The C<...> means any number of these I<code point>s separated by dots.
 202 This represents the sequence formed by the characters.  This is an internal
 203 form only, subject to change, and you should not try to use it yourself.)
 204
 205 Mnemonic: I<N>amed character.
 206
 207 Note that a character or character sequence expressed as a named
 208 or numbered character is considered a character without special
 209 meaning by the regex engine, and will match "as is".
 210
 211 =head4 Example
 212
 213  $str =~ /\N{THAI CHARACTER SO SO}/;  # Matches the Thai SO SO character
 214
 215  use charnames 'Cyrillic';            # Loads Cyrillic names.
 216  $str =~ /\N{ZHE}\N{KA}/;             # Match "ZHE" followed by "KA".
 217
 218 =head3 Octal escapes
 219
 220 There are two forms of octal escapes.  Each is used to specify a character by
 221 its code point specified in octal notation.
 222
 223 One form, available starting in Perl 5.14 looks like C<\o{...}>, where the dots
 224 represent one or more octal digits.  It can be used for any Unicode character.
 225
 226 It was introduced to avoid the potential problems with the other form,
 227 available in all Perls.  That form consists of a backslash followed by three
 228 octal digits.  One problem with this form is that it can look exactly like an
 229 old-style backreference (see
 230 L</Disambiguation rules between old-style octal escapes and backreferences>
 231 below.)  You can avoid this by making the first of the three digits always a
 232 zero, but that makes \077 the largest code point specifiable.
 233
 234 In some contexts, a backslash followed by two or even one octal digits may be
 235 interpreted as an octal escape, sometimes with a warning, and because of some
 236 bugs, sometimes with surprising results.  Also, if you are creating a regex
 237 out of smaller snippets concatenated together, and you use fewer than three
 238 digits, the beginning of one snippet may be interpreted as adding digits to the
 239 ending of the snippet before it.  See L</Absolute referencing> for more
 240 discussion and examples of the snippet problem.
 241
 242 Note that a character expressed as an octal escape is considered
 243 a character without special meaning by the regex engine, and will match
 244 "as is".
 245
 246 To summarize, the C<\o{}> form is always safe to use, and the other form is
 247 safe to use for code points through \077 when you use exactly three digits to
 248 specify them.
 249
 250 Mnemonic: I<0>ctal or I<o>ctal.
 251
 252 =head4 Examples (assuming an ASCII platform)
 253
 254  $str = "Perl";
 255  $str =~ /\o{120}/;  # Match, "\120" is "P".
 256  $str =~ /\120/;     # Same.
 257  $str =~ /\o{120}+/; # Match, "\120" is "P",
 258                      # it's repeated at least once.
 259  $str =~ /\120+/;    # Same.
 260  $str =~ /P\053/;    # No match, "\053" is "+" and taken literally.
 261  /\o{23073}/         # Black foreground, white background smiling face.
 262  /\o{4801234567}/    # Raises a warning, and yields chr(4).
 263
 264 =head4 Disambiguation rules between old-style octal escapes and backreferences
 265
 266 Octal escapes of the C<\000> form outside of bracketed character classes
 267 potentially clash with old-style backreferences (see L</Absolute referencing>
 268 below).  They both consist of a backslash followed by numbers.  So Perl has to
 269 use heuristics to determine whether it is a backreference or an octal escape.
 270 Perl uses the following rules to disambiguate:
 271
 272 =over 4
 273
 274 =item 1
 275
 276 If the backslash is followed by a single digit, it's a backreference.
 277
 278 =item 2
 279
 280 If the first digit following the backslash is a 0, it's an octal escape.
 281
 282 =item 3
 283
 284 If the number following the backslash is N (in decimal), and Perl already
 285 has seen N capture groups, Perl considers this a backreference.  Otherwise,
 286 it considers it an octal escape. If N has more than three digits, Perl
 287 takes only the first three for the octal escape; the rest are matched as is.
 288
 289  my $pat  = "(" x 999;
 290     $pat .= "a";
 291     $pat .= ")" x 999;
 292  /^($pat)\1000$/;   #  Matches 'aa'; there are 1000 capture groups.
 293  /^$pat\1000$/;     #  Matches 'a@0'; there are 999 capture groups
 294                     #  and \1000 is seen as \100 (a '@') and a '0'.
 295
 296 =back
 297
 298 You can force a backreference interpretation always by using the C<\g{...}>
 299 form.  You can the force an octal interpretation always by using the C<\o{...}>
 300 form, or for numbers up through \077 (= 63 decimal), by using three digits,
 301 beginning with a "0".
 302
 303 =head3 Hexadecimal escapes
 304
 305 Like octal escapes, there are two forms of hexadecimal escapes, but both start
 306 with the sequence C<\x>.  This is followed by either exactly two hexadecimal
 307 digits forming a number, or a hexadecimal number of arbitrary length surrounded
 308 by curly braces. The hexadecimal number is the code point of the character you
 309 want to express.
 310
 311 Note that a character expressed as one of these escapes is considered a
 312 character without special meaning by the regex engine, and will match
 313 "as is".
 314
 315 Mnemonic: heI<x>adecimal.
 316
 317 =head4 Examples (assuming an ASCII platform)
 318
 319  $str = "Perl";
 320  $str =~ /\x50/;    # Match, "\x50" is "P".
 321  $str =~ /\x50+/;   # Match, "\x50" is "P", it is repeated at least once
 322  $str =~ /P\x2B/;   # No match, "\x2B" is "+" and taken literally.
 323
 324  /\x{2603}\x{2602}/ # Snowman with an umbrella.
 325                     # The Unicode character 2603 is a snowman,
 326                     # the Unicode character 2602 is an umbrella.
 327  /\x{263B}/         # Black smiling face.
 328  /\x{263b}/         # Same, the hex digits A - F are case insensitive.
 329
 330 =head2 Modifiers
 331
 332 A number of backslash sequences have to do with changing the character,
 333 or characters following them. C<\l> will lowercase the character following
 334 it, while C<\u> will uppercase (or, more accurately, titlecase) the
 335 character following it. They provide functionality similar to the
 336 functions C<lcfirst> and C<ucfirst>.
 337
 338 To uppercase or lowercase several characters, one might want to use
 339 C<\L> or C<\U>, which will lowercase/uppercase all characters following
 340 them, until either the end of the pattern or the next occurrence of
 341 C<\E>, whichever comes first. They provide functionality similar to what
 342 the functions C<lc> and C<uc> provide.
 343
 344 C<\Q> is used to quote (disable) pattern metacharacters, up to the next
 345 C<\E> or the end of the pattern. C<\Q> adds a backslash to any character
 346 that could have special meaning to Perl.  In the ASCII range, it quotes
 347 every character that isn't a letter, digit, or underscore.  See
 348 L<perlfunc/quotemeta> for details on what gets quoted for non-ASCII
 349 code points.  Using this ensures that any character between C<\Q> and
 350 C<\E> will be matched literally, not interpreted as a metacharacter by
 351 the regex engine.
 352
 353 C<\F> can be used to casefold all characters following, up to the next C<\E>
 354 or the end of the pattern. It provides the functionality similar to
 355 the C<fc> function.
 356
 357 Mnemonic: I<L>owercase, I<U>ppercase, I<F>old-case, I<Q>uotemeta, I<E>nd.
 358
 359 =head4 Examples
 360
 361  $sid     = "sid";
 362  $greg    = "GrEg";
 363  $miranda = "(Miranda)";
 364  $str     =~ /\u$sid/;        # Matches 'Sid'
 365  $str     =~ /\L$greg/;       # Matches 'greg'
 366  $str     =~ /\Q$miranda\E/;  # Matches '(Miranda)', as if the pattern
 367                               #   had been written as /\(Miranda\)/
 368
 369 =head2 Character classes
 370
 371 Perl regular expressions have a large range of character classes. Some of
 372 the character classes are written as a backslash sequence. We will briefly
 373 discuss those here; full details of character classes can be found in
 374 L<perlrecharclass>.
 375
 376 C<\w> is a character class that matches any single I<word> character
 377 (letters, digits, Unicode marks, and connector punctuation (like the
 378 underscore)).  C<\d> is a character class that matches any decimal
 379 digit, while the character class C<\s> matches any whitespace character.
 380 New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal
 381 and vertical whitespace characters.
 382
 383 The exact set of characters matched by C<\d>, C<\s>, and C<\w> varies
 384 depending on various pragma and regular expression modifiers.  It is
 385 possible to restrict the match to the ASCII range by using the C</a>
 386 regular expression modifier.  See L<perlrecharclass>.
 387
 388 The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
 389 character classes that match, respectively, any character that isn't a
 390 word character, digit, whitespace, horizontal whitespace, or vertical
 391 whitespace.
 392
 393 Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
 394
 395 =head3 Unicode classes
 396
 397 C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
 398 match a character that matches the given Unicode property; properties
 399 include things like "letter", or "thai character". Capitalizing the
 400 sequence to C<\PP> and C<\P{Property}> make the sequence match a character
 401 that doesn't match the given Unicode property. For more details, see
 402 L<perlrecharclass/Backslash sequences> and
 403 L<perlunicode/Unicode Character Properties>.
 404
 405 Mnemonic: I<p>roperty.
 406
 407 =head2 Referencing
 408
 409 If capturing parenthesis are used in a regular expression, we can refer
 410 to the part of the source string that was matched, and match exactly the
 411 same thing. There are three ways of referring to such I<backreference>:
 412 absolutely, relatively, and by name.
 413
 414 =for later add link to perlrecapture
 415
 416 =head3 Absolute referencing
 417
 418 Either C<\gI<N>> (starting in Perl 5.10.0), or C<\I<N>> (old-style) where I<N>
 419 is a positive (unsigned) decimal number of any length is an absolute reference
 420 to a capturing group.
 421
 422 I<N> refers to the Nth set of parentheses, so C<\gI<N>> refers to whatever has
 423 been matched by that set of parentheses.  Thus C<\g1> refers to the first
 424 capture group in the regex.
 425
 426 The C<\gI<N>> form can be equivalently written as C<\g{I<N>}>
 427 which avoids ambiguity when building a regex by concatenating shorter
 428 strings.  Otherwise if you had a regex C<qr/$a$b/>, and C<$a> contained
 429 C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which is
 430 probably not what you intended.
 431
 432 In the C<\I<N>> form, I<N> must not begin with a "0", and there must be at
 433 least I<N> capturing groups, or else I<N> is considered an octal escape
 434 (but something like C<\18> is the same as C<\0018>; that is, the octal escape
 435 C<"\001"> followed by a literal digit C<"8">).
 436
 437 Mnemonic: I<g>roup.
 438
 439 =head4 Examples
 440
 441  /(\w+) \g1/;    # Finds a duplicated word, (e.g. "cat cat").
 442  /(\w+) \1/;     # Same thing; written old-style.
 443  /(.)(.)\g2\g1/;  # Match a four letter palindrome (e.g. "ABBA").
 444
 445
 446 =head3 Relative referencing
 447
 448 C<\g-I<N>> (starting in Perl 5.10.0) is used for relative addressing.  (It can
 449 be written as C<\g{-I<N>>.)  It refers to the I<N>th group before the
 450 C<\g{-I<N>}>.
 451
 452 The big advantage of this form is that it makes it much easier to write
 453 patterns with references that can be interpolated in larger patterns,
 454 even if the larger pattern also contains capture groups.
 455
 456 =head4 Examples
 457
 458  /(A)        # Group 1
 459   (          # Group 2
 460     (B)      # Group 3
 461     \g{-1}   # Refers to group 3 (B)
 462     \g{-3}   # Refers to group 1 (A)
 463   )
 464  /x;         # Matches "ABBA".
 465
 466  my $qr = qr /(.)(.)\g{-2}\g{-1}/;  # Matches 'abab', 'cdcd', etc.
 467  /$qr$qr/                           # Matches 'ababcdcd'.
 468
 469 =head3 Named referencing
 470
 471 C<\g{I<name>}> (starting in Perl 5.10.0) can be used to back refer to a
 472 named capture group, dispensing completely with having to think about capture
 473 buffer positions.
 474
 475 To be compatible with .Net regular expressions, C<\g{name}> may also be
 476 written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
 477
 478 To prevent any ambiguity, I<name> must not start with a digit nor contain a
 479 hyphen.
 480
 481 =head4 Examples
 482
 483  /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
 484  /(?<word>\w+) \k{word}/ # Same.
 485  /(?<word>\w+) \k<word>/ # Same.
 486  /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
 487                          # Match a four letter palindrome (e.g. "ABBA")
 488
 489 =head2 Assertions
 490
 491 Assertions are conditions that have to be true; they don't actually
 492 match parts of the substring. There are six assertions that are written as
 493 backslash sequences.
 494
 495 =over 4
 496
 497 =item \A
 498
 499 C<\A> only matches at the beginning of the string. If the C</m> modifier
 500 isn't used, then C</\A/> is equivalent to C</^/>. However, if the C</m>
 501 modifier is used, then C</^/> matches internal newlines, but the meaning
 502 of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
 503 of the string regardless whether the C</m> modifier is used.
 504
 505 =item \z, \Z
 506
 507 C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
 508 used, then C</\Z/> is equivalent to C</$/>; that is, it matches at the
 509 end of the string, or one before the newline at the end of the string. If the
 510 C</m> modifier is used, then C</$/> matches at internal newlines, but the
 511 meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
 512 the end of the string (or just before a trailing newline) regardless whether
 513 the C</m> modifier is used.
 514
 515 C<\z> is just like C<\Z>, except that it does not match before a trailing
 516 newline. C<\z> matches at the end of the string only, regardless of the
 517 modifiers used, and not just before a newline.  It is how to anchor the
 518 match to the true end of the string under all conditions.
 519
 520 =item \G
 521
 522 C<\G> is usually used only in combination with the C</g> modifier. If the
 523 C</g> modifier is used and the match is done in scalar context, Perl
 524 remembers where in the source string the last match ended, and the next time,
 525 it will start the match from where it ended the previous time.
 526
 527 C<\G> matches the point where the previous match on that string ended,
 528 or the beginning of that string if there was no previous match.
 529
 530 =for later add link to perlremodifiers
 531
 532 Mnemonic: I<G>lobal.
 533
 534 =item \b{}, \b, \B{}, \B
 535
 536 C<\b{...}>, available starting in v5.22, matches a boundary (between two
 537 characters, or before the first character of the string, or after the
 538 final character of the string) based on the Unicode rules for the
 539 boundary type specified inside the braces.  The boundary
 540 types are given a few paragraphs below.  C<\B{...}> matches at any place
 541 between characters where C<\b{...}> of the same type doesn't match.
 542
 543 C<\b> when not immediately followed by a C<"{"> matches at any place
 544 between a word (something matched by C<\w>) and a non-word character
 545 (C<\W>); C<\B> when not immediately followed by a C<"{"> matches at any
 546 place between characters where C<\b> doesn't match.  To get better
 547 word matching of natural language text, see L</\b{wb}> below.
 548
 549 C<\b>
 550 and C<\B> assume there's a non-word character before the beginning and after
 551 the end of the source string; so C<\b> will match at the beginning (or end)
 552 of the source string if the source string begins (or ends) with a word
 553 character. Otherwise, C<\B> will match.
 554
 555 Do not use something like C<\b=head\d\b> and expect it to match the
 556 beginning of a line.  It can't, because for there to be a boundary before
 557 the non-word "=", there must be a word character immediately previous.
 558 All plain C<\b> and C<\B> boundary determinations look for word
 559 characters alone, not for
 560 non-word characters nor for string ends.  It may help to understand how
 561 C<\b> and C<\B> work by equating them as follows:
 562
 563     \b  really means    (?:(?<=\w)(?!\w)|(?<!\w)(?=\w))
 564     \B  really means    (?:(?<=\w)(?=\w)|(?<!\w)(?!\w))
 565
 566 In contrast, C<\b{...}> and C<\B{...}> may or may not match at the
 567 beginning and end of the line, depending on the boundary type.  These
 568 implement the Unicode default boundaries, specified in
 569 L<http://www.unicode.org/reports/tr14/> and
 570 L<http://www.unicode.org/reports/tr29/>.
 571 The boundary types are:
 572
 573 =over
 574
 575 =item C<\b{gcb}> or C<\b{g}>
 576
 577 This matches a Unicode "Grapheme Cluster Boundary".  (Actually Perl
 578 always uses the improved "extended" grapheme cluster").  These are
 579 explained below under L</C<\X>>.  In fact, C<\X> is another way to get
 580 the same functionality.  It is equivalent to C</.+?\b{gcb}/>.  Use
 581 whichever is most convenient for your situation.
 582
 583 =item C<\b{lb}>
 584
 585 This matches according to the default Unicode Line Breaking Algorithm
 586 (L<http://www.unicode.org/reports/tr14/>), as customized in that
 587 document
 588 (L<Example 7 of revision 35|http://www.unicode.org/reports/tr14/tr14-35.html#Example7>)
 589 for better handling of numeric expressions.
 590
 591 This is suitable for many purposes, but the L<Unicode::LineBreak> module
 592 is available on CPAN that provides many more features, including
 593 customization.
 594
 595 =item C<\b{sb}>
 596
 597 This matches a Unicode "Sentence Boundary".  This is an aid to parsing
 598 natural language sentences.  It gives good, but imperfect results.  For
 599 example, it thinks that "Mr. Smith" is two sentences.  More details are
 600 at L<http://www.unicode.org/reports/tr29/>.  Note also that it thinks
 601 that anything matching L</\R> (except form feed and vertical tab) is a
 602 sentence boundary.  C<\b{sb}> works with text designed for
 603 word-processors which wrap lines
 604 automatically for display, but hard-coded line boundaries are considered
 605 to be essentially the ends of text blocks (paragraphs really), and hence
 606 the ends of sentences.  C<\b{sb}> doesn't do well with text containing
 607 embedded newlines, like the source text of the document you are reading.
 608 Such text needs to be preprocessed to get rid of the line separators
 609 before looking for sentence boundaries.  Some people view this as a bug
 610 in the Unicode standard, and this behavior is quite subject to change in
 611 future Perl versions.
 612
 613 =item C<\b{wb}>
 614
 615 This matches a Unicode "Word Boundary", but tailored to Perl
 616 expectations.  This gives better (though not
 617 perfect) results for natural language processing than plain C<\b>
 618 (without braces) does.  For example, it understands that apostrophes can
 619 be in the middle of words and that parentheses aren't (see the examples
 620 below).  More details are at L<http://www.unicode.org/reports/tr29/>.
 621
 622 The current Unicode definition of a Word Boundary matches between every
 623 white space character.  Perl tailors this, starting in version 5.24, to
 624 generally not break up spans of white space, just as plain C<\b> has
 625 always functioned.  This allows C<\b{wb}> to be a drop-in replacement for
 626 C<\b>, but with generally better results for natural language
 627 processing.  (The exception to this tailoring is when a span of white
 628 space is immediately followed by something like U+0303, COMBINING TILDE.
 629 If the final space character in the span is a horizontal white space, it
 630 is broken out so that it attaches instead to the combining character.
 631 To be precise, if a span of white space that ends in a horizontal space
 632 has the character immediately following it have any of the Word
 633 Boundary property values "Extend", "Format" or "ZWJ", the boundary between the
 634 final horizontal space character and the rest of the span matches
 635 C<\b{wb}>.  In all other cases the boundary between two white space
 636 characters matches C<\B{wb}>.)
 637
 638 =back
 639
 640 It is important to realize when you use these Unicode boundaries,
 641 that you are taking a risk that a future version of Perl which contains
 642 a later version of the Unicode Standard will not work precisely the same
 643 way as it did when your code was written.  These rules are not
 644 considered stable and have been somewhat more subject to change than the
 645 rest of the Standard.  Unicode reserves the right to change them at
 646 will, and Perl reserves the right to update its implementation to
 647 Unicode's new rules.  In the past, some changes have been because new
 648 characters have been added to the Standard which have different
 649 characteristics than all previous characters, so new rules are
 650 formulated for handling them.  These should not cause any backward
 651 compatibility issues.  But some changes have changed the treatment of
 652 existing characters because the Unicode Technical Committee has decided
 653 that the change is warranted for whatever reason.  This could be to fix
 654 a bug, or because they think better results are obtained with the new
 655 rule.
 656
 657 It is also important to realize that these are default boundary
 658 definitions, and that implementations may wish to tailor the results for
 659 particular purposes and locales.  For example, some languages, such as
 660 Japanese and Thai, require dictionary lookup to accurately determine
 661 word boundaries.
 662
 663 Mnemonic: I<b>oundary.
 664
 665 =back
 666
 667 =head4 Examples
 668
 669   "cat"   =~ /\Acat/;     # Match.
 670   "cat"   =~ /cat\Z/;     # Match.
 671   "cat\n" =~ /cat\Z/;     # Match.
 672   "cat\n" =~ /cat\z/;     # No match.
 673
 674   "cat"   =~ /\bcat\b/;   # Matches.
 675   "cats"  =~ /\bcat\b/;   # No match.
 676   "cat"   =~ /\bcat\B/;   # No match.
 677   "cats"  =~ /\bcat\B/;   # Match.
 678
 679   while ("cat dog" =~ /(\w+)/g) {
 680       print $1;           # Prints 'catdog'
 681   }
 682   while ("cat dog" =~ /\G(\w+)/g) {
 683       print $1;           # Prints 'cat'
 684   }
 685
 686   my $s = "He said, \"Is pi 3.14? (I'm not sure).\"";
 687   print join("|", $s =~ m/ ( .+? \b     ) /xg), "\n";
 688   print join("|", $s =~ m/ ( .+? \b{wb} ) /xg), "\n";
 689  prints
 690   He| |said|, "|Is| |pi| |3|.|14|? (|I|'|m| |not| |sure
 691   He| |said|,| |"|Is| |pi| |3.14|?| |(|I'm| |not| |sure|)|.|"
 692
 693 =head2 Misc
 694
 695 Here we document the backslash sequences that don't fall in one of the
 696 categories above. These are:
 697
 698 =over 4
 699
 700 =item \K
 701
 702 This appeared in perl 5.10.0. Anything matched left of C<\K> is
 703 not included in C<$&>, and will not be replaced if the pattern is
 704 used in a substitution. This lets you write C<s/PAT1 \K PAT2/REPL/x>
 705 instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
 706
 707 Mnemonic: I<K>eep.
 708
 709 =item \N
 710
 711 This feature, available starting in v5.12,  matches any character
 712 that is B<not> a newline.  It is a short-hand for writing C<[^\n]>, and is
 713 identical to the C<.> metasymbol, except under the C</s> flag, which changes
 714 the meaning of C<.>, but not C<\N>.
 715
 716 Note that C<\N{...}> can mean a
 717 L<named or numbered character
 718 |/Named or numbered characters and character sequences>.
 719
 720 Mnemonic: Complement of I<\n>.
 721
 722 =item \R
 723 X<\R>
 724
 725 C<\R> matches a I<generic newline>; that is, anything considered a
 726 linebreak sequence by Unicode. This includes all characters matched by
 727 C<\v> (vertical whitespace), and the multi character sequence C<"\x0D\x0A">
 728 (carriage return followed by a line feed, sometimes called the network
 729 newline; it's the end of line sequence used in Microsoft text files opened
 730 in binary mode). C<\R> is equivalent to C<< (?>\x0D\x0A|\v) >>.  (The
 731 reason it doesn't backtrack is that the sequence is considered
 732 inseparable.  That means that
 733
 734  "\x0D\x0A" =~ /^\R\x0A$/   # No match
 735
 736 fails, because the C<\R> matches the entire string, and won't backtrack
 737 to match just the C<"\x0D">.)  Since
 738 C<\R> can match a sequence of more than one character, it cannot be put
 739 inside a bracketed character class; C</[\R]/> is an error; use C<\v>
 740 instead.  C<\R> was introduced in perl 5.10.0.
 741
 742 Note that this does not respect any locale that might be in effect; it
 743 matches according to the platform's native character set.
 744
 745 Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>,
 746 and more importantly because Unicode recommends such a regular expression
 747 metacharacter, and suggests C<\R> as its notation.
 748
 749 =item \X
 750 X<\X>
 751
 752 This matches a Unicode I<extended grapheme cluster>.
 753
 754 C<\X> matches quite well what normal (non-Unicode-programmer) usage
 755 would consider a single character.  As an example, consider a G with some sort
 756 of diacritic mark, such as an arrow.  There is no such single character in
 757 Unicode, but one can be composed by using a G followed by a Unicode "COMBINING
 758 UPWARDS ARROW BELOW", and would be displayed by Unicode-aware software as if it
 759 were a single character.
 760
 761 The match is greedy and non-backtracking, so that the cluster is never
 762 broken up into smaller components.
 763
 764 See also L<C<\b{gcb}>|/\b{}, \b, \B{}, \B>.
 765
 766 Mnemonic: eI<X>tended Unicode character.
 767
 768 =back
 769
 770 =head4 Examples
 771
 772  $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'
 773  $str =~ s/(.)\K\g1//g;    # Delete duplicated characters.
 774
 775  "\n"   =~ /^\R$/;         # Match, \n   is a generic newline.
 776  "\r"   =~ /^\R$/;         # Match, \r   is a generic newline.
 777  "\r\n" =~ /^\R$/;         # Match, \r\n is a generic newline.
 778
 779  "P\x{307}" =~ /^\X$/     # \X matches a P with a dot above.
 780
 781 =cut