lib/Net/hostent.t

   1 #!./perl -w
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6 }
   7
   8 use Test::More tests => 7;
   9
  10 BEGIN {
  11     require Config; import Config;
  12     if ($Config{'extensions'} !~ /\bSocket\b/ &&
  13         !(($^O eq 'VMS') && $Config{d_socket}))
  14     {
  15         plan skip_all => "Test uses Socket, Socket not built";
  16     }
  17 }
  18
  19
  20 BEGIN { use_ok 'Net::hostent' }
  21
  22 # Remind me to add this to Test::More.
  23 sub DIE {
  24     print "# @_\n";
  25     exit 1;
  26 }
  27
  28 # test basic resolution of localhost <-> 127.0.0.1
  29 use Socket;
  30
  31 my $h = gethost('localhost');
  32 ok(defined $h,  "gethost('localhost')") ||
  33   DIE("Can't continue without working gethost: $!");
  34
  35 is( inet_ntoa($h->addr), "127.0.0.1",   'addr from gethost' );
  36
  37 my $i = gethostbyaddr(inet_aton("127.0.0.1"));
  38 ok(defined $i,  "gethostbyaddr('127.0.0.1')") ||
  39   DIE("Can't continue without working gethostbyaddr: $!");
  40
  41 is( inet_ntoa($i->addr), "127.0.0.1",   'addr from gethostbyaddr' );
  42
  43 # need to skip the name comparisons on Win32 because windows will
  44 # return the name of the machine instead of "localhost" when resolving
  45 # 127.0.0.1 or even "localhost"
  46
  47 # - VMS returns "LOCALHOST" under tcp/ip services V4.1 ECO 2, possibly others
  48 # - OS/390 returns localhost.YADDA.YADDA
  49
  50 SKIP: {
  51     skip "Windows will return the machine name instead of 'localhost'", 2
  52       if $^O eq 'MSWin32' or $^O eq 'NetWare' or $^O eq 'cygwin';
  53
  54     print "# name = " . $h->name . ", aliases = " . join (",", @{$h->aliases}) . "\n";
  55
  56     my $in_alias;
  57     unless ($h->name =~ /^localhost(?:\..+)?$/i) {
  58         foreach (@{$h->aliases}) {
  59             if (/^localhost(?:\..+)?$/i) {
  60                 $in_alias = 1;
  61                 last;
  62             }
  63         }
  64         ok( $in_alias );
  65     } else {
  66         ok( 1 );
  67     }
  68
  69     if ($in_alias) {
  70         # If we found it in the aliases before, expect to find it there again.
  71         foreach (@{$h->aliases}) {
  72             if (/^localhost(?:\..+)?$/i) {
  73                 # This time, clear the flag if we see "localhost"
  74                 undef $in_alias;
  75                 last;
  76             }
  77         }
  78     }
  79
  80     if( $in_alias ) {
  81         like( $i->name, qr/^localhost(?:\..+)?$/i );
  82     }
  83     else {
  84         ok( !$in_alias );
  85         print "# " . $h->name . " " . join (",", @{$h->aliases}) . "\n";
  86     }
  87 }