lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34)> or C<(re_eval 19)>.
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 514
 515 BEGIN {
 516     require feature;
 517     $^V =~ /^v(\d+\.\d+)/;
 518     feature->import(":$1");
 519 }
 520
 521 # Debugger for Perl 5.00x; perl5db.pl patch level:
 522 $VERSION = '1.37';
 523
 524 $header = "perl5db.pl version $VERSION";
 525
 526 =head1 DEBUGGER ROUTINES
 527
 528 =head2 C<DB::eval()>
 529
 530 This function replaces straight C<eval()> inside the debugger; it simplifies
 531 the process of evaluating code in the user's context.
 532
 533 The code to be evaluated is passed via the package global variable
 534 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 535
 536 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 537 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 538 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 539 user's current package, grabbed when C<DB::DB> got control.  This causes the
 540 proper context to be used when the eval is actually done.  Afterward, we
 541 restore C<$trace>, C<$single>, and C<$^D>.
 542
 543 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 544 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 545 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 546 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 547 considered sane by the debugger. If there was an C<eval()> error, we print
 548 it on the debugger's output. If C<$onetimedump> is defined, we call
 549 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 550 'methods'. Setting it to something else causes the debugger to do the eval
 551 but not print the result - handy if you want to do something else with it
 552 (the "watch expressions" code does this to get the value of the watch
 553 expression but not show it unless it matters).
 554
 555 In any case, we then return the list of output from C<eval> to the caller,
 556 and unwinding restores the former version of C<$@> in C<@saved> as well
 557 (the localization of C<$saved[0]> goes away at the end of this scope).
 558
 559 =head3 Parameters and variables influencing execution of DB::eval()
 560
 561 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 562 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 563 The variables listed below influence C<DB::eval()>'s execution directly.
 564
 565 =over 4
 566
 567 =item C<$evalarg> - the thing to actually be eval'ed
 568
 569 =item C<$trace> - Current state of execution tracing
 570
 571 =item C<$single> - Current state of single-stepping
 572
 573 =item C<$onetimeDump> - what is to be displayed after the evaluation
 574
 575 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 576
 577 =back
 578
 579 The following variables are altered by C<DB::eval()> during its execution. They
 580 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 581
 582 =over 4
 583
 584 =item C<@res> - used to capture output from actual C<eval>.
 585
 586 =item C<$otrace> - saved value of C<$trace>.
 587
 588 =item C<$osingle> - saved value of C<$single>.
 589
 590 =item C<$od> - saved value of C<$^D>.
 591
 592 =item C<$saved[0]> - saved value of C<$@>.
 593
 594 =item $\ - for output of C<$@> if there is an evaluation error.
 595
 596 =back
 597
 598 =head3 The problem of lexicals
 599
 600 The context of C<DB::eval()> presents us with some problems. Obviously,
 601 we want to be 'sandboxed' away from the debugger's internals when we do
 602 the eval, but we need some way to control how punctuation variables and
 603 debugger globals are used.
 604
 605 We can't use local, because the code inside C<DB::eval> can see localized
 606 variables; and we can't use C<my> either for the same reason. The code
 607 in this routine compromises and uses C<my>.
 608
 609 After this routine is over, we don't have user code executing in the debugger's
 610 context, so we can use C<my> freely.
 611
 612 =cut
 613
 614 ############################################## Begin lexical danger zone
 615
 616 # 'my' variables used here could leak into (that is, be visible in)
 617 # the context that the code being evaluated is executing in. This means that
 618 # the code could modify the debugger's variables.
 619 #
 620 # Fiddling with the debugger's context could be Bad. We insulate things as
 621 # much as we can.
 622
 623 sub eval {
 624
 625     # 'my' would make it visible from user code
 626     #    but so does local! --tchrist
 627     # Remember: this localizes @DB::res, not @main::res.
 628     local @res;
 629     {
 630
 631         # Try to keep the user code from messing  with us. Save these so that
 632         # even if the eval'ed code changes them, we can put them back again.
 633         # Needed because the user could refer directly to the debugger's
 634         # package globals (and any 'my' variables in this containing scope)
 635         # inside the eval(), and we want to try to stay safe.
 636         local $otrace  = $trace;
 637         local $osingle = $single;
 638         local $od      = $^D;
 639
 640         # Untaint the incoming eval() argument.
 641         { ($evalarg) = $evalarg =~ /(.*)/s; }
 642
 643         # $usercontext built in DB::DB near the comment
 644         # "set up the context for DB::eval ..."
 645         # Evaluate and save any results.
 646         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 647
 648         # Restore those old values.
 649         $trace  = $otrace;
 650         $single = $osingle;
 651         $^D     = $od;
 652     }
 653
 654     # Save the current value of $@, and preserve it in the debugger's copy
 655     # of the saved precious globals.
 656     my $at = $@;
 657
 658     # Since we're only saving $@, we only have to localize the array element
 659     # that it will be stored in.
 660     local $saved[0];    # Preserve the old value of $@
 661     eval { &DB::save };
 662
 663     # Now see whether we need to report an error back to the user.
 664     if ($at) {
 665         local $\ = '';
 666         print $OUT $at;
 667     }
 668
 669     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 670     # are package globals.
 671     elsif ($onetimeDump) {
 672         if ( $onetimeDump eq 'dump' ) {
 673             local $option{dumpDepth} = $onetimedumpDepth
 674               if defined $onetimedumpDepth;
 675             dumpit( $OUT, \@res );
 676         }
 677         elsif ( $onetimeDump eq 'methods' ) {
 678             methods( $res[0] );
 679         }
 680     } ## end elsif ($onetimeDump)
 681     @res;
 682 } ## end sub eval
 683
 684 ############################################## End lexical danger zone
 685
 686 # After this point it is safe to introduce lexicals.
 687 # The code being debugged will be executing in its own context, and
 688 # can't see the inside of the debugger.
 689 #
 690 # However, one should not overdo it: leave as much control from outside as
 691 # possible. If you make something a lexical, it's not going to be addressable
 692 # from outside the debugger even if you know its name.
 693
 694 # This file is automatically included if you do perl -d.
 695 # It's probably not useful to include this yourself.
 696 #
 697 # Before venturing further into these twisty passages, it is
 698 # wise to read the perldebguts man page or risk the ire of dragons.
 699 #
 700 # (It should be noted that perldebguts will tell you a lot about
 701 # the underlying mechanics of how the debugger interfaces into the
 702 # Perl interpreter, but not a lot about the debugger itself. The new
 703 # comments in this code try to address this problem.)
 704
 705 # Note that no subroutine call is possible until &DB::sub is defined
 706 # (for subroutines defined outside of the package DB). In fact the same is
 707 # true if $deep is not defined.
 708
 709 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 710
 711 # modified Perl debugger, to be run from Emacs in perldb-mode
 712 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 713 # Johan Vromans -- upgrade to 4.0 pl 10
 714 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 715 ########################################################################
 716
 717 =head1 DEBUGGER INITIALIZATION
 718
 719 The debugger starts up in phases.
 720
 721 =head2 BASIC SETUP
 722
 723 First, it initializes the environment it wants to run in: turning off
 724 warnings during its own compilation, defining variables which it will need
 725 to avoid warnings later, setting itself up to not exit when the program
 726 terminates, and defaulting to printing return values for the C<r> command.
 727
 728 =cut
 729
 730 # Needed for the statement after exec():
 731 #
 732 # This BEGIN block is simply used to switch off warnings during debugger
 733 # compilation. Probably it would be better practice to fix the warnings,
 734 # but this is how it's done at the moment.
 735
 736 BEGIN {
 737     $ini_warn = $^W;
 738     $^W       = 0;
 739 }    # Switch compilation warnings off until another BEGIN.
 740
 741 local ($^W) = 0;    # Switch run-time warnings off during init.
 742
 743 =head2 THREADS SUPPORT
 744
 745 If we are running under a threaded Perl, we require threads and threads::shared
 746 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 747 threaded debugger control.  C<-dt> can also be used to set this.
 748
 749 Each new thread will be announced and the debugger prompt will always inform
 750 you of each new thread created.  It will also indicate the thread id in which
 751 we are currently running within the prompt like this:
 752
 753         [tid] DB<$i>
 754
 755 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 756 command prompt.  The prompt will show: C<[0]> when running under threads, but
 757 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 758
 759 While running under threads, when you set or delete a breakpoint (etc.), this
 760 will apply to all threads, not just the currently running one.  When you are
 761 in a currently executing thread, you will stay there until it completes.  With
 762 the current implementation it is not currently possible to hop from one thread
 763 to another.
 764
 765 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 766
 767 Note that threading support was built into the debugger as of Perl version
 768 C<5.8.6> and debugger version C<1.2.8>.
 769
 770 =cut
 771
 772 BEGIN {
 773   # ensure we can share our non-threaded variables or no-op
 774   if ($ENV{PERL5DB_THREADED}) {
 775         require threads;
 776         require threads::shared;
 777         import threads::shared qw(share);
 778         $DBGR;
 779         share(\$DBGR);
 780         lock($DBGR);
 781         print "Threads support enabled\n";
 782   } else {
 783         *lock  = sub(*) {};
 784         *share = sub(*) {};
 785   }
 786 }
 787
 788 # This would probably be better done with "use vars", but that wasn't around
 789 # when this code was originally written. (Neither was "use strict".) And on
 790 # the principle of not fiddling with something that was working, this was
 791 # left alone.
 792 warn(               # Do not ;-)
 793     # These variables control the execution of 'dumpvar.pl'.
 794     $dumpvar::hashDepth,
 795     $dumpvar::arrayDepth,
 796     $dumpvar::dumpDBFiles,
 797     $dumpvar::dumpPackages,
 798     $dumpvar::quoteHighBit,
 799     $dumpvar::printUndef,
 800     $dumpvar::globPrint,
 801     $dumpvar::usageOnly,
 802
 803     # used to save @ARGV and extract any debugger-related flags.
 804     @ARGS,
 805
 806     # used to control die() reporting in diesignal()
 807     $Carp::CarpLevel,
 808
 809     # used to prevent multiple entries to diesignal()
 810     # (if for instance diesignal() itself dies)
 811     $panic,
 812
 813     # used to prevent the debugger from running nonstop
 814     # after a restart
 815     $second_time,
 816   )
 817   if 0;
 818
 819 # without threads, $filename is not defined until DB::DB is called
 820 foreach my $k (keys (%INC)) {
 821         &share(\$main::{'_<'.$filename}) if defined $filename;
 822 };
 823
 824 # Command-line + PERLLIB:
 825 # Save the contents of @INC before they are modified elsewhere.
 826 @ini_INC = @INC;
 827
 828 # This was an attempt to clear out the previous values of various
 829 # trapped errors. Apparently it didn't help. XXX More info needed!
 830 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 831
 832 # We set these variables to safe values. We don't want to blindly turn
 833 # off warnings, because other packages may still want them.
 834 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 835                                    # (local $^W cannot help - other packages!).
 836
 837 # Default to not exiting when program finishes; print the return
 838 # value when the 'r' command is used to return from a subroutine.
 839 $inhibit_exit = $option{PrintRet} = 1;
 840
 841 # Default to 1 so the prompt will display the first line.
 842 $trace_to_depth = 1;
 843
 844 =head1 OPTION PROCESSING
 845
 846 The debugger's options are actually spread out over the debugger itself and
 847 C<dumpvar.pl>; some of these are variables to be set, while others are
 848 subs to be called with a value. To try to make this a little easier to
 849 manage, the debugger uses a few data structures to define what options
 850 are legal and how they are to be processed.
 851
 852 First, the C<@options> array defines the I<names> of all the options that
 853 are to be accepted.
 854
 855 =cut
 856
 857 @options = qw(
 858   CommandSet   HistFile      HistSize
 859   hashDepth    arrayDepth    dumpDepth
 860   DumpDBFiles  DumpPackages  DumpReused
 861   compactDump  veryCompact   quote
 862   HighBit      undefPrint    globPrint
 863   PrintRet     UsageOnly     frame
 864   AutoTrace    TTY           noTTY
 865   ReadLine     NonStop       LineInfo
 866   maxTraceLen  recallCommand ShellBang
 867   pager        tkRunning     ornaments
 868   signalLevel  warnLevel     dieLevel
 869   inhibit_exit ImmediateStop bareStringify
 870   CreateTTY    RemotePort    windowSize
 871   DollarCaretP
 872 );
 873
 874 @RememberOnROptions = qw(DollarCaretP);
 875
 876 =pod
 877
 878 Second, C<optionVars> lists the variables that each option uses to save its
 879 state.
 880
 881 =cut
 882
 883 %optionVars = (
 884     hashDepth     => \$dumpvar::hashDepth,
 885     arrayDepth    => \$dumpvar::arrayDepth,
 886     CommandSet    => \$CommandSet,
 887     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 888     DumpPackages  => \$dumpvar::dumpPackages,
 889     DumpReused    => \$dumpvar::dumpReused,
 890     HighBit       => \$dumpvar::quoteHighBit,
 891     undefPrint    => \$dumpvar::printUndef,
 892     globPrint     => \$dumpvar::globPrint,
 893     UsageOnly     => \$dumpvar::usageOnly,
 894     CreateTTY     => \$CreateTTY,
 895     bareStringify => \$dumpvar::bareStringify,
 896     frame         => \$frame,
 897     AutoTrace     => \$trace,
 898     inhibit_exit  => \$inhibit_exit,
 899     maxTraceLen   => \$maxtrace,
 900     ImmediateStop => \$ImmediateStop,
 901     RemotePort    => \$remoteport,
 902     windowSize    => \$window,
 903     HistFile      => \$histfile,
 904     HistSize      => \$histsize,
 905 );
 906
 907 =pod
 908
 909 Third, C<%optionAction> defines the subroutine to be called to process each
 910 option.
 911
 912 =cut
 913
 914 %optionAction = (
 915     compactDump   => \&dumpvar::compactDump,
 916     veryCompact   => \&dumpvar::veryCompact,
 917     quote         => \&dumpvar::quote,
 918     TTY           => \&TTY,
 919     noTTY         => \&noTTY,
 920     ReadLine      => \&ReadLine,
 921     NonStop       => \&NonStop,
 922     LineInfo      => \&LineInfo,
 923     recallCommand => \&recallCommand,
 924     ShellBang     => \&shellBang,
 925     pager         => \&pager,
 926     signalLevel   => \&signalLevel,
 927     warnLevel     => \&warnLevel,
 928     dieLevel      => \&dieLevel,
 929     tkRunning     => \&tkRunning,
 930     ornaments     => \&ornaments,
 931     RemotePort    => \&RemotePort,
 932     DollarCaretP  => \&DollarCaretP,
 933 );
 934
 935 =pod
 936
 937 Last, the C<%optionRequire> notes modules that must be C<require>d if an
 938 option is used.
 939
 940 =cut
 941
 942 # Note that this list is not complete: several options not listed here
 943 # actually require that dumpvar.pl be loaded for them to work, but are
 944 # not in the table. A subsequent patch will correct this problem; for
 945 # the moment, we're just recommenting, and we are NOT going to change
 946 # function.
 947 %optionRequire = (
 948     compactDump => 'dumpvar.pl',
 949     veryCompact => 'dumpvar.pl',
 950     quote       => 'dumpvar.pl',
 951 );
 952
 953 =pod
 954
 955 There are a number of initialization-related variables which can be set
 956 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
 957 variable. These are:
 958
 959 =over 4
 960
 961 =item C<$rl> - readline control XXX needs more explanation
 962
 963 =item C<$warnLevel> - whether or not debugger takes over warning handling
 964
 965 =item C<$dieLevel> - whether or not debugger takes over die handling
 966
 967 =item C<$signalLevel> - whether or not debugger takes over signal handling
 968
 969 =item C<$pre> - preprompt actions (array reference)
 970
 971 =item C<$post> - postprompt actions (array reference)
 972
 973 =item C<$pretype>
 974
 975 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
 976
 977 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
 978
 979 =back
 980
 981 =cut
 982
 983 # These guys may be defined in $ENV{PERL5DB} :
 984 $rl          = 1     unless defined $rl;
 985 $warnLevel   = 1     unless defined $warnLevel;
 986 $dieLevel    = 1     unless defined $dieLevel;
 987 $signalLevel = 1     unless defined $signalLevel;
 988 $pre         = []    unless defined $pre;
 989 $post        = []    unless defined $post;
 990 $pretype     = []    unless defined $pretype;
 991 $CreateTTY   = 3     unless defined $CreateTTY;
 992 $CommandSet  = '580' unless defined $CommandSet;
 993
 994 share($rl);
 995 share($warnLevel);
 996 share($dieLevel);
 997 share($signalLevel);
 998 share($pre);
 999 share($post);
1000 share($pretype);
1001 share($rl);
1002 share($CreateTTY);
1003 share($CommandSet);
1004
1005 =pod
1006
1007 The default C<die>, C<warn>, and C<signal> handlers are set up.
1008
1009 =cut
1010
1011 warnLevel($warnLevel);
1012 dieLevel($dieLevel);
1013 signalLevel($signalLevel);
1014
1015 =pod
1016
1017 The pager to be used is needed next. We try to get it from the
1018 environment first.  If it's not defined there, we try to find it in
1019 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1020 then call the C<pager()> function to save the pager name.
1021
1022 =cut
1023
1024 # This routine makes sure $pager is set up so that '|' can use it.
1025 pager(
1026
1027     # If PAGER is defined in the environment, use it.
1028     defined $ENV{PAGER}
1029     ? $ENV{PAGER}
1030
1031       # If not, see if Config.pm defines it.
1032     : eval { require Config }
1033       && defined $Config::Config{pager}
1034     ? $Config::Config{pager}
1035
1036       # If not, fall back to 'more'.
1037     : 'more'
1038   )
1039   unless defined $pager;
1040
1041 =pod
1042
1043 We set up the command to be used to access the man pages, the command
1044 recall character (C<!> unless otherwise defined) and the shell escape
1045 character (C<!> unless otherwise defined). Yes, these do conflict, and
1046 neither works in the debugger at the moment.
1047
1048 =cut
1049
1050 setman();
1051
1052 # Set up defaults for command recall and shell escape (note:
1053 # these currently don't work in linemode debugging).
1054 &recallCommand("!") unless defined $prc;
1055 &shellBang("!")     unless defined $psh;
1056
1057 =pod
1058
1059 We then set up the gigantic string containing the debugger help.
1060 We also set the limit on the number of arguments we'll display during a
1061 trace.
1062
1063 =cut
1064
1065 sethelp();
1066
1067 # If we didn't get a default for the length of eval/stack trace args,
1068 # set it here.
1069 $maxtrace = 400 unless defined $maxtrace;
1070
1071 =head2 SETTING UP THE DEBUGGER GREETING
1072
1073 The debugger I<greeting> helps to inform the user how many debuggers are
1074 running, and whether the current debugger is the primary or a child.
1075
1076 If we are the primary, we just hang onto our pid so we'll have it when
1077 or if we start a child debugger. If we are a child, we'll set things up
1078 so we'll have a unique greeting and so the parent will give us our own
1079 TTY later.
1080
1081 We save the current contents of the C<PERLDB_PIDS> environment variable
1082 because we mess around with it. We'll also need to hang onto it because
1083 we'll need it if we restart.
1084
1085 Child debuggers make a label out of the current PID structure recorded in
1086 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1087 yet so the parent will give them one later via C<resetterm()>.
1088
1089 =cut
1090
1091 # Save the current contents of the environment; we're about to
1092 # much with it. We'll need this if we have to restart.
1093 $ini_pids = $ENV{PERLDB_PIDS};
1094
1095 if ( defined $ENV{PERLDB_PIDS} ) {
1096
1097     # We're a child. Make us a label out of the current PID structure
1098     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1099     # a term yet so the parent will give us one later via resetterm().
1100
1101     my $env_pids = $ENV{PERLDB_PIDS};
1102     $pids = "[$env_pids]";
1103
1104     # Unless we are on OpenVMS, all programs under the DCL shell run under
1105     # the same PID.
1106
1107     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1108         $term_pid         = $$;
1109     }
1110     else {
1111         $ENV{PERLDB_PIDS} .= "->$$";
1112         $term_pid = -1;
1113     }
1114
1115 } ## end if (defined $ENV{PERLDB_PIDS...
1116 else {
1117
1118     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1119     # child debugger, and mark us as the parent, so we'll know to set up
1120     # more TTY's is we have to.
1121     $ENV{PERLDB_PIDS} = "$$";
1122     $pids             = "[pid=$$]";
1123     $term_pid         = $$;
1124 }
1125
1126 $pidprompt = '';
1127
1128 # Sets up $emacs as a synonym for $slave_editor.
1129 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1130
1131 =head2 READING THE RC FILE
1132
1133 The debugger will read a file of initialization options if supplied. If
1134 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1135
1136 =cut
1137
1138 # As noted, this test really doesn't check accurately that the debugger
1139 # is running at a terminal or not.
1140
1141 my $dev_tty = '/dev/tty';
1142    $dev_tty = 'TT:' if ($^O eq 'VMS');
1143 if ( -e $dev_tty ) {                      # this is the wrong metric!
1144     $rcfile = ".perldb";
1145 }
1146 else {
1147     $rcfile = "perldb.ini";
1148 }
1149
1150 =pod
1151
1152 The debugger does a safety test of the file to be read. It must be owned
1153 either by the current user or root, and must only be writable by the owner.
1154
1155 =cut
1156
1157 # This wraps a safety test around "do" to read and evaluate the init file.
1158 #
1159 # This isn't really safe, because there's a race
1160 # between checking and opening.  The solution is to
1161 # open and fstat the handle, but then you have to read and
1162 # eval the contents.  But then the silly thing gets
1163 # your lexical scope, which is unfortunate at best.
1164 sub safe_do {
1165     my $file = shift;
1166
1167     # Just exactly what part of the word "CORE::" don't you understand?
1168     local $SIG{__WARN__};
1169     local $SIG{__DIE__};
1170
1171     unless ( is_safe_file($file) ) {
1172         CORE::warn <<EO_GRIPE;
1173 perldb: Must not source insecure rcfile $file.
1174         You or the superuser must be the owner, and it must not
1175         be writable by anyone but its owner.
1176 EO_GRIPE
1177         return;
1178     } ## end unless (is_safe_file($file...
1179
1180     do $file;
1181     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1182 } ## end sub safe_do
1183
1184 # This is the safety test itself.
1185 #
1186 # Verifies that owner is either real user or superuser and that no
1187 # one but owner may write to it.  This function is of limited use
1188 # when called on a path instead of upon a handle, because there are
1189 # no guarantees that filename (by dirent) whose file (by ino) is
1190 # eventually accessed is the same as the one tested.
1191 # Assumes that the file's existence is not in doubt.
1192 sub is_safe_file {
1193     my $path = shift;
1194     stat($path) || return;    # mysteriously vaporized
1195     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1196
1197     return 0 if $uid != 0 && $uid != $<;
1198     return 0 if $mode & 022;
1199     return 1;
1200 } ## end sub is_safe_file
1201
1202 # If the rcfile (whichever one we decided was the right one to read)
1203 # exists, we safely do it.
1204 if ( -f $rcfile ) {
1205     safe_do("./$rcfile");
1206 }
1207
1208 # If there isn't one here, try the user's home directory.
1209 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1210     safe_do("$ENV{HOME}/$rcfile");
1211 }
1212
1213 # Else try the login directory.
1214 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1215     safe_do("$ENV{LOGDIR}/$rcfile");
1216 }
1217
1218 # If the PERLDB_OPTS variable has options in it, parse those out next.
1219 if ( defined $ENV{PERLDB_OPTS} ) {
1220     parse_options( $ENV{PERLDB_OPTS} );
1221 }
1222
1223 =pod
1224
1225 The last thing we do during initialization is determine which subroutine is
1226 to be used to obtain a new terminal when a new debugger is started. Right now,
1227 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1228 (darwin).
1229
1230 =cut
1231
1232 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1233 # Works if you're running an xterm or xterm-like window, or you're on
1234 # OS/2, or on Mac OS X. This may need some expansion.
1235
1236 if (not defined &get_fork_TTY)       # only if no routine exists
1237 {
1238     if ( defined $remoteport ) {
1239                                                  # Expect an inetd-like server
1240         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1241     }
1242     elsif (defined $ENV{TERM}                    # If we know what kind
1243                                                  # of terminal this is,
1244         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1245         and defined $ENV{DISPLAY}                # and what display it's on,
1246       )
1247     {
1248         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1249     }
1250     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1251         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1252     }
1253     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1254             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1255             and $ENV{TERM_PROGRAM}
1256                 eq 'Apple_Terminal'              # Terminal.app
1257             )
1258     {
1259         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1260     }
1261 } ## end if (not defined &get_fork_TTY...
1262
1263 # untaint $^O, which may have been tainted by the last statement.
1264 # see bug [perl #24674]
1265 $^O =~ m/^(.*)\z/;
1266 $^O = $1;
1267
1268 # Here begin the unreadable code.  It needs fixing.
1269
1270 =head2 RESTART PROCESSING
1271
1272 This section handles the restart command. When the C<R> command is invoked, it
1273 tries to capture all of the state it can into environment variables, and
1274 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1275 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1276 the R command stuffed into the environment variables.
1277
1278   PERLDB_RESTART   - flag only, contains no restart data itself.
1279   PERLDB_HIST      - command history, if it's available
1280   PERLDB_ON_LOAD   - breakpoints set by the rc file
1281   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1282   PERLDB_VISITED   - files that had breakpoints
1283   PERLDB_FILE_...  - breakpoints for a file
1284   PERLDB_OPT       - active options
1285   PERLDB_INC       - the original @INC
1286   PERLDB_PRETYPE   - preprompt debugger actions
1287   PERLDB_PRE       - preprompt Perl code
1288   PERLDB_POST      - post-prompt Perl code
1289   PERLDB_TYPEAHEAD - typeahead captured by readline()
1290
1291 We chug through all these variables and plug the values saved in them
1292 back into the appropriate spots in the debugger.
1293
1294 =cut
1295
1296 if ( exists $ENV{PERLDB_RESTART} ) {
1297
1298     # We're restarting, so we don't need the flag that says to restart anymore.
1299     delete $ENV{PERLDB_RESTART};
1300
1301     # $restart = 1;
1302     @hist          = get_list('PERLDB_HIST');
1303     %break_on_load = get_list("PERLDB_ON_LOAD");
1304     %postponed     = get_list("PERLDB_POSTPONE");
1305
1306         share(@hist);
1307         share(@truehist);
1308         share(%break_on_load);
1309         share(%postponed);
1310
1311     # restore breakpoints/actions
1312     my @had_breakpoints = get_list("PERLDB_VISITED");
1313     for my $file_idx ( 0 .. $#had_breakpoints ) {
1314         my $filename = $had_breakpoints[$file_idx];
1315         my %pf = get_list("PERLDB_FILE_$file_idx");
1316         $postponed_file{ $filename } = \%pf if %pf;
1317         my @lines = sort {$a <=> $b} keys(%pf);
1318         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1319         for my $line_idx (0 .. $#lines) {
1320             _set_breakpoint_enabled_status(
1321                 $filename,
1322                 $lines[$line_idx],
1323                 ($enabled_statuses[$line_idx] ? 1 : ''),
1324             );
1325         }
1326     }
1327
1328     # restore options
1329     my %opt = get_list("PERLDB_OPT");
1330     my ( $opt, $val );
1331     while ( ( $opt, $val ) = each %opt ) {
1332         $val =~ s/[\\\']/\\$1/g;
1333         parse_options("$opt'$val'");
1334     }
1335
1336     # restore original @INC
1337     @INC     = get_list("PERLDB_INC");
1338     @ini_INC = @INC;
1339
1340     # return pre/postprompt actions and typeahead buffer
1341     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1342     $pre       = [ get_list("PERLDB_PRE") ];
1343     $post      = [ get_list("PERLDB_POST") ];
1344     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1345 } ## end if (exists $ENV{PERLDB_RESTART...
1346
1347 =head2 SETTING UP THE TERMINAL
1348
1349 Now, we'll decide how the debugger is going to interact with the user.
1350 If there's no TTY, we set the debugger to run non-stop; there's not going
1351 to be anyone there to enter commands.
1352
1353 =cut
1354
1355 if ($notty) {
1356     $runnonstop = 1;
1357         share($runnonstop);
1358 }
1359
1360 =pod
1361
1362 If there is a TTY, we have to determine who it belongs to before we can
1363 proceed. If this is a slave editor or graphical debugger (denoted by
1364 the first command-line switch being '-emacs'), we shift this off and
1365 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1366
1367 =cut
1368
1369 else {
1370
1371     # Is Perl being run from a slave editor or graphical debugger?
1372     # If so, don't use readline, and set $slave_editor = 1.
1373     $slave_editor =
1374       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1375     $rl = 0, shift(@main::ARGV) if $slave_editor;
1376
1377     #require Term::ReadLine;
1378
1379 =pod
1380
1381 We then determine what the console should be on various systems:
1382
1383 =over 4
1384
1385 =item * Cygwin - We use C<stdin> instead of a separate device.
1386
1387 =cut
1388
1389     if ( $^O eq 'cygwin' ) {
1390
1391         # /dev/tty is binary. use stdin for textmode
1392         undef $console;
1393     }
1394
1395 =item * Unix - use C</dev/tty>.
1396
1397 =cut
1398
1399     elsif ( -e "/dev/tty" ) {
1400         $console = "/dev/tty";
1401     }
1402
1403 =item * Windows or MSDOS - use C<con>.
1404
1405 =cut
1406
1407     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1408         $console = "con";
1409     }
1410
1411 =item * VMS - use C<sys$command>.
1412
1413 =cut
1414
1415     else {
1416
1417         # everything else is ...
1418         $console = "sys\$command";
1419     }
1420
1421 =pod
1422
1423 =back
1424
1425 Several other systems don't use a specific console. We C<undef $console>
1426 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1427 with a slave editor, Epoc).
1428
1429 =cut
1430
1431     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1432
1433         # /dev/tty is binary. use stdin for textmode
1434         $console = undef;
1435     }
1436
1437     if ( $^O eq 'NetWare' ) {
1438
1439         # /dev/tty is binary. use stdin for textmode
1440         $console = undef;
1441     }
1442
1443     # In OS/2, we need to use STDIN to get textmode too, even though
1444     # it pretty much looks like Unix otherwise.
1445     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1446     {    # In OS/2
1447         $console = undef;
1448     }
1449
1450     # EPOC also falls into the 'got to use STDIN' camp.
1451     if ( $^O eq 'epoc' ) {
1452         $console = undef;
1453     }
1454
1455 =pod
1456
1457 If there is a TTY hanging around from a parent, we use that as the console.
1458
1459 =cut
1460
1461     $console = $tty if defined $tty;
1462
1463 =head2 SOCKET HANDLING
1464
1465 The debugger is capable of opening a socket and carrying out a debugging
1466 session over the socket.
1467
1468 If C<RemotePort> was defined in the options, the debugger assumes that it
1469 should try to start a debugging session on that port. It builds the socket
1470 and then tries to connect the input and output filehandles to it.
1471
1472 =cut
1473
1474     # Handle socket stuff.
1475
1476     if ( defined $remoteport ) {
1477
1478         # If RemotePort was defined in the options, connect input and output
1479         # to the socket.
1480         $IN = $OUT = connect_remoteport();
1481     } ## end if (defined $remoteport)
1482
1483 =pod
1484
1485 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1486 this is probably a situation where multiple debuggers are running (for example,
1487 a backticked command that starts up another debugger). We create a new IN and
1488 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1489 and if we can.
1490
1491 =cut
1492
1493     # Non-socket.
1494     else {
1495
1496         # Two debuggers running (probably a system or a backtick that invokes
1497         # the debugger itself under the running one). create a new IN and OUT
1498         # filehandle, and do the necessary mojo to create a new tty if we
1499         # know how, and we can.
1500         create_IN_OUT(4) if $CreateTTY & 4;
1501         if ($console) {
1502
1503             # If we have a console, check to see if there are separate ins and
1504             # outs to open. (They are assumed identical if not.)
1505
1506             my ( $i, $o ) = split /,/, $console;
1507             $o = $i unless defined $o;
1508
1509             # read/write on in, or just read, or read on STDIN.
1510             open( IN,      "+<$i" )
1511               || open( IN, "<$i" )
1512               || open( IN, "<&STDIN" );
1513
1514             # read/write/create/clobber out, or write/create/clobber out,
1515             # or merge with STDERR, or merge with STDOUT.
1516                  open( OUT, "+>$o" )
1517               || open( OUT, ">$o" )
1518               || open( OUT, ">&STDERR" )
1519               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1520
1521         } ## end if ($console)
1522         elsif ( not defined $console ) {
1523
1524             # No console. Open STDIN.
1525             open( IN, "<&STDIN" );
1526
1527             # merge with STDERR, or with STDOUT.
1528             open( OUT,      ">&STDERR" )
1529               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1530             $console = 'STDIN/OUT';
1531         } ## end elsif (not defined $console)
1532
1533         # Keep copies of the filehandles so that when the pager runs, it
1534         # can close standard input without clobbering ours.
1535         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1536     } ## end elsif (from if(defined $remoteport))
1537
1538     # Unbuffer DB::OUT. We need to see responses right away.
1539     my $previous = select($OUT);
1540     $| = 1;                                  # for DB::OUT
1541     select($previous);
1542
1543     # Line info goes to debugger output unless pointed elsewhere.
1544     # Pointing elsewhere makes it possible for slave editors to
1545     # keep track of file and position. We have both a filehandle
1546     # and a I/O description to keep track of.
1547     $LINEINFO = $OUT     unless defined $LINEINFO;
1548     $lineinfo = $console unless defined $lineinfo;
1549         # share($LINEINFO); # <- unable to share globs
1550         share($lineinfo);   #
1551
1552 =pod
1553
1554 To finish initialization, we show the debugger greeting,
1555 and then call the C<afterinit()> subroutine if there is one.
1556
1557 =cut
1558
1559     # Show the debugger greeting.
1560     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1561     unless ($runnonstop) {
1562         local $\ = '';
1563         local $, = '';
1564         if ( $term_pid eq '-1' ) {
1565             print $OUT "\nDaughter DB session started...\n";
1566         }
1567         else {
1568             print $OUT "\nLoading DB routines from $header\n";
1569             print $OUT (
1570                 "Editor support ",
1571                 $slave_editor ? "enabled" : "available", ".\n"
1572             );
1573             print $OUT
1574 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1575         } ## end else [ if ($term_pid eq '-1')
1576     } ## end unless ($runnonstop)
1577 } ## end else [ if ($notty)
1578
1579 # XXX This looks like a bug to me.
1580 # Why copy to @ARGS and then futz with @args?
1581 @ARGS = @ARGV;
1582 for (@args) {
1583     # Make sure backslashes before single quotes are stripped out, and
1584     # keep args unless they are numeric (XXX why?)
1585     # s/\'/\\\'/g;                      # removed while not justified understandably
1586     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1587 }
1588
1589 # If there was an afterinit() sub defined, call it. It will get
1590 # executed in our scope, so it can fiddle with debugger globals.
1591 if ( defined &afterinit ) {    # May be defined in $rcfile
1592     &afterinit();
1593 }
1594
1595 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1596 $I_m_init = 1;
1597
1598 ############################################################ Subroutines
1599
1600 =head1 SUBROUTINES
1601
1602 =head2 DB
1603
1604 This gigantic subroutine is the heart of the debugger. Called before every
1605 statement, its job is to determine if a breakpoint has been reached, and
1606 stop if so; read commands from the user, parse them, and execute
1607 them, and then send execution off to the next statement.
1608
1609 Note that the order in which the commands are processed is very important;
1610 some commands earlier in the loop will actually alter the C<$cmd> variable
1611 to create other commands to be executed later. This is all highly I<optimized>
1612 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1613 see what's happening in any given command.
1614
1615 =cut
1616
1617 sub DB {
1618
1619     # lock the debugger and get the thread id for the prompt
1620         lock($DBGR);
1621         my $tid;
1622         if ($ENV{PERL5DB_THREADED}) {
1623                 $tid = eval { "[".threads->tid."]" };
1624         }
1625
1626     # Check for whether we should be running continuously or not.
1627     # _After_ the perl program is compiled, $single is set to 1:
1628     if ( $single and not $second_time++ ) {
1629
1630         # Options say run non-stop. Run until we get an interrupt.
1631         if ($runnonstop) {    # Disable until signal
1632                 # If there's any call stack in place, turn off single
1633                 # stepping into subs throughout the stack.
1634             for ( $i = 0 ; $i <= $stack_depth ; ) {
1635                 $stack[ $i++ ] &= ~1;
1636             }
1637
1638             # And we are now no longer in single-step mode.
1639             $single = 0;
1640
1641             # If we simply returned at this point, we wouldn't get
1642             # the trace info. Fall on through.
1643             # return;
1644         } ## end if ($runnonstop)
1645
1646         elsif ($ImmediateStop) {
1647
1648             # We are supposed to stop here; XXX probably a break.
1649             $ImmediateStop = 0;    # We've processed it; turn it off
1650             $signal        = 1;    # Simulate an interrupt to force
1651                                    # us into the command loop
1652         }
1653     } ## end if ($single and not $second_time...
1654
1655     # If we're in single-step mode, or an interrupt (real or fake)
1656     # has occurred, turn off non-stop mode.
1657     $runnonstop = 0 if $single or $signal;
1658
1659     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1660     # The code being debugged may have altered them.
1661     &save;
1662
1663     # Since DB::DB gets called after every line, we can use caller() to
1664     # figure out where we last were executing. Sneaky, eh? This works because
1665     # caller is returning all the extra information when called from the
1666     # debugger.
1667     local ( $package, $filename, $line ) = caller;
1668     local $filename_ini = $filename;
1669
1670     # set up the context for DB::eval, so it can properly execute
1671     # code on behalf of the user. We add the package in so that the
1672     # code is eval'ed in the proper package (not in the debugger!).
1673     local $usercontext =
1674       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1675
1676     # Create an alias to the active file magical array to simplify
1677     # the code here.
1678     local (*dbline) = $main::{ '_<' . $filename };
1679
1680     # Last line in the program.
1681     local $max = $#dbline;
1682
1683     # if we have something here, see if we should break.
1684     if ( $dbline{$line}
1685         && _is_breakpoint_enabled($filename, $line)
1686         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1687     {
1688
1689         # Stop if the stop criterion says to just stop.
1690         if ( $stop eq '1' ) {
1691             $signal |= 1;
1692         }
1693
1694         # It's a conditional stop; eval it in the user's context and
1695         # see if we should stop. If so, remove the one-time sigil.
1696         elsif ($stop) {
1697             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1698             &eval;
1699             # If the breakpoint is temporary, then delete its enabled status.
1700             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1701                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1702             }
1703         }
1704     } ## end if ($dbline{$line} && ...
1705
1706     # Preserve the current stop-or-not, and see if any of the W
1707     # (watch expressions) has changed.
1708     my $was_signal = $signal;
1709
1710     # If we have any watch expressions ...
1711     if ( $trace & 2 ) {
1712         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1713             $evalarg = $to_watch[$n];
1714             local $onetimeDump;    # Tell DB::eval() to not output results
1715
1716             # Fix context DB::eval() wants to return an array, but
1717             # we need a scalar here.
1718             my ($val) = join( "', '", &eval );
1719             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1720
1721             # Did it change?
1722             if ( $val ne $old_watch[$n] ) {
1723
1724                 # Yep! Show the difference, and fake an interrupt.
1725                 $signal = 1;
1726                 print $OUT <<EOP;
1727 Watchpoint $n:\t$to_watch[$n] changed:
1728     old value:\t$old_watch[$n]
1729     new value:\t$val
1730 EOP
1731                 $old_watch[$n] = $val;
1732             } ## end if ($val ne $old_watch...
1733         } ## end for (my $n = 0 ; $n <= ...
1734     } ## end if ($trace & 2)
1735
1736 =head2 C<watchfunction()>
1737
1738 C<watchfunction()> is a function that can be defined by the user; it is a
1739 function which will be run on each entry to C<DB::DB>; it gets the
1740 current package, filename, and line as its parameters.
1741
1742 The watchfunction can do anything it likes; it is executing in the
1743 debugger's context, so it has access to all of the debugger's internal
1744 data structures and functions.
1745
1746 C<watchfunction()> can control the debugger's actions. Any of the following
1747 will cause the debugger to return control to the user's program after
1748 C<watchfunction()> executes:
1749
1750 =over 4
1751
1752 =item *
1753
1754 Returning a false value from the C<watchfunction()> itself.
1755
1756 =item *
1757
1758 Altering C<$single> to a false value.
1759
1760 =item *
1761
1762 Altering C<$signal> to a false value.
1763
1764 =item *
1765
1766 Turning off the C<4> bit in C<$trace> (this also disables the
1767 check for C<watchfunction()>. This can be done with
1768
1769     $trace &= ~4;
1770
1771 =back
1772
1773 =cut
1774
1775     # If there's a user-defined DB::watchfunction, call it with the
1776     # current package, filename, and line. The function executes in
1777     # the DB:: package.
1778     if ( $trace & 4 ) {    # User-installed watch
1779         return
1780           if watchfunction( $package, $filename, $line )
1781           and not $single
1782           and not $was_signal
1783           and not( $trace & ~4 );
1784     } ## end if ($trace & 4)
1785
1786     # Pick up any alteration to $signal in the watchfunction, and
1787     # turn off the signal now.
1788     $was_signal = $signal;
1789     $signal     = 0;
1790
1791 =head2 GETTING READY TO EXECUTE COMMANDS
1792
1793 The debugger decides to take control if single-step mode is on, the
1794 C<t> command was entered, or the user generated a signal. If the program
1795 has fallen off the end, we set things up so that entering further commands
1796 won't cause trouble, and we say that the program is over.
1797
1798 =cut
1799
1800     # Make sure that we always print if asked for explicitly regardless
1801     # of $trace_to_depth .
1802     my $explicit_stop = ($single || $was_signal);
1803
1804     # Check to see if we should grab control ($single true,
1805     # trace set appropriately, or we got a signal).
1806     if ( $explicit_stop || ( $trace & 1 ) ) {
1807
1808         # Yes, grab control.
1809         if ($slave_editor) {
1810
1811             # Tell the editor to update its position.
1812             $position = "\032\032$filename:$line:0\n";
1813             print_lineinfo($position);
1814         }
1815
1816 =pod
1817
1818 Special check: if we're in package C<DB::fake>, we've gone through the
1819 C<END> block at least once. We set up everything so that we can continue
1820 to enter commands and have a valid context to be in.
1821
1822 =cut
1823
1824         elsif ( $package eq 'DB::fake' ) {
1825
1826             # Fallen off the end already.
1827             $term || &setterm;
1828             print_help(<<EOP);
1829 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1830   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1831   B<h q>, B<h R> or B<h o> to get additional info.
1832 EOP
1833
1834             # Set the DB::eval context appropriately.
1835             $package     = 'main';
1836             $usercontext =
1837                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
1838               . "package $package;";    # this won't let them modify, alas
1839         } ## end elsif ($package eq 'DB::fake')
1840
1841 =pod
1842
1843 If the program hasn't finished executing, we scan forward to the
1844 next executable line, print that out, build the prompt from the file and line
1845 number information, and print that.
1846
1847 =cut
1848
1849         else {
1850
1851
1852             # Still somewhere in the midst of execution. Set up the
1853             #  debugger prompt.
1854             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1855                                  # Perl 5 ones (sorry, we don't print Klingon
1856                                  #module names)
1857
1858             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
1859             $prefix .= "$sub($filename:";
1860             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1861
1862             # Break up the prompt if it's really long.
1863             if ( length($prefix) > 30 ) {
1864                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
1865                 $prefix   = "";
1866                 $infix    = ":\t";
1867             }
1868             else {
1869                 $infix    = "):\t";
1870                 $position = "$prefix$line$infix$dbline[$line]$after";
1871             }
1872
1873             # Print current line info, indenting if necessary.
1874             if ($frame) {
1875                 print_lineinfo( ' ' x $stack_depth,
1876                     "$line:\t$dbline[$line]$after" );
1877             }
1878             else {
1879                 depth_print_lineinfo($explicit_stop, $position);
1880             }
1881
1882             # Scan forward, stopping at either the end or the next
1883             # unbreakable line.
1884             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
1885             {    #{ vi
1886
1887                 # Drop out on null statements, block closers, and comments.
1888                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
1889
1890                 # Drop out if the user interrupted us.
1891                 last if $signal;
1892
1893                 # Append a newline if the line doesn't have one. Can happen
1894                 # in eval'ed text, for instance.
1895                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
1896
1897                 # Next executable line.
1898                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
1899                 $position .= $incr_pos;
1900                 if ($frame) {
1901
1902                     # Print it indented if tracing is on.
1903                     print_lineinfo( ' ' x $stack_depth,
1904                         "$i:\t$dbline[$i]$after" );
1905                 }
1906                 else {
1907                     depth_print_lineinfo($explicit_stop, $incr_pos);
1908                 }
1909             } ## end for ($i = $line + 1 ; $i...
1910         } ## end else [ if ($slave_editor)
1911     } ## end if ($single || ($trace...
1912
1913 =pod
1914
1915 If there's an action to be executed for the line we stopped at, execute it.
1916 If there are any preprompt actions, execute those as well.
1917
1918 =cut
1919
1920     # If there's an action, do it now.
1921     $evalarg = $action, &eval if $action;
1922
1923     # Are we nested another level (e.g., did we evaluate a function
1924     # that had a breakpoint in it at the debugger prompt)?
1925     if ( $single || $was_signal ) {
1926
1927         # Yes, go down a level.
1928         local $level = $level + 1;
1929
1930         # Do any pre-prompt actions.
1931         foreach $evalarg (@$pre) {
1932             &eval;
1933         }
1934
1935         # Complain about too much recursion if we passed the limit.
1936         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
1937           if $single & 4;
1938
1939         # The line we're currently on. Set $incr to -1 to stay here
1940         # until we get a command that tells us to advance.
1941         $start = $line;
1942         $incr  = -1;      # for backward motion.
1943
1944         # Tack preprompt debugger actions ahead of any actual input.
1945         @typeahead = ( @$pretype, @typeahead );
1946
1947 =head2 WHERE ARE WE?
1948
1949 XXX Relocate this section?
1950
1951 The debugger normally shows the line corresponding to the current line of
1952 execution. Sometimes, though, we want to see the next line, or to move elsewhere
1953 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
1954
1955 C<$incr> controls by how many lines the I<current> line should move forward
1956 after a command is executed. If set to -1, this indicates that the I<current>
1957 line shouldn't change.
1958
1959 C<$start> is the I<current> line. It is used for things like knowing where to
1960 move forwards or backwards from when doing an C<L> or C<-> command.
1961
1962 C<$max> tells the debugger where the last line of the current file is. It's
1963 used to terminate loops most often.
1964
1965 =head2 THE COMMAND LOOP
1966
1967 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
1968 in two parts:
1969
1970 =over 4
1971
1972 =item *
1973
1974 The outer part of the loop, starting at the C<CMD> label. This loop
1975 reads a command and then executes it.
1976
1977 =item *
1978
1979 The inner part of the loop, starting at the C<PIPE> label. This part
1980 is wholly contained inside the C<CMD> block and only executes a command.
1981 Used to handle commands running inside a pager.
1982
1983 =back
1984
1985 So why have two labels to restart the loop? Because sometimes, it's easier to
1986 have a command I<generate> another command and then re-execute the loop to do
1987 the new command. This is faster, but perhaps a bit more convoluted.
1988
1989 =cut
1990
1991         # The big command dispatch loop. It keeps running until the
1992         # user yields up control again.
1993         #
1994         # If we have a terminal for input, and we get something back
1995         # from readline(), keep on processing.
1996       CMD:
1997         while (
1998
1999             # We have a terminal, or can get one ...
2000             ( $term || &setterm ),
2001
2002             # ... and it belogs to this PID or we get one for this PID ...
2003             ( $term_pid == $$ or resetterm(1) ),
2004
2005             # ... and we got a line of command input ...
2006             defined(
2007                 $cmd = &readline(
2008                         "$pidprompt $tid DB"
2009                       . ( '<' x $level )
2010                       . ( $#hist + 1 )
2011                       . ( '>' x $level ) . " "
2012                 )
2013             )
2014           )
2015         {
2016
2017                         share($cmd);
2018             # ... try to execute the input as debugger commands.
2019
2020             # Don't stop running.
2021             $single = 0;
2022
2023             # No signal is active.
2024             $signal = 0;
2025
2026             # Handle continued commands (ending with \):
2027             $cmd =~ s/\\$/\n/ && do {
2028                 $cmd .= &readline("  cont: ");
2029                 redo CMD;
2030             };
2031
2032 =head4 The null command
2033
2034 A newline entered by itself means I<re-execute the last command>. We grab the
2035 command out of C<$laststep> (where it was recorded previously), and copy it
2036 back into C<$cmd> to be executed below. If there wasn't any previous command,
2037 we'll do nothing below (no command will match). If there was, we also save it
2038 in the command history and fall through to allow the command parsing to pick
2039 it up.
2040
2041 =cut
2042
2043             # Empty input means repeat the last command.
2044             $cmd =~ /^$/ && ( $cmd = $laststep );
2045             chomp($cmd);    # get rid of the annoying extra newline
2046             push( @hist, $cmd ) if length($cmd) > 1;
2047             push( @truehist, $cmd );
2048                         share(@hist);
2049                         share(@truehist);
2050
2051             # This is a restart point for commands that didn't arrive
2052             # via direct user input. It allows us to 'redo PIPE' to
2053             # re-execute command processing without reading a new command.
2054           PIPE: {
2055                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2056                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2057                 ($i) = split( /\s+/, $cmd );
2058
2059 =head3 COMMAND ALIASES
2060
2061 The debugger can create aliases for commands (these are stored in the
2062 C<%alias> hash). Before a command is executed, the command loop looks it up
2063 in the alias hash and substitutes the contents of the alias for the command,
2064 completely replacing it.
2065
2066 =cut
2067
2068                 # See if there's an alias for the command, and set it up if so.
2069                 if ( $alias{$i} ) {
2070
2071                     # Squelch signal handling; we want to keep control here
2072                     # if something goes loco during the alias eval.
2073                     local $SIG{__DIE__};
2074                     local $SIG{__WARN__};
2075
2076                     # This is a command, so we eval it in the DEBUGGER's
2077                     # scope! Otherwise, we can't see the special debugger
2078                     # variables, or get to the debugger's subs. (Well, we
2079                     # _could_, but why make it even more complicated?)
2080                     eval "\$cmd =~ $alias{$i}";
2081                     if ($@) {
2082                         local $\ = '';
2083                         print $OUT "Couldn't evaluate '$i' alias: $@";
2084                         next CMD;
2085                     }
2086                 } ## end if ($alias{$i})
2087
2088 =head3 MAIN-LINE COMMANDS
2089
2090 All of these commands work up to and after the program being debugged has
2091 terminated.
2092
2093 =head4 C<q> - quit
2094
2095 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2096 try to execute further, cleaning any restart-related stuff out of the
2097 environment, and executing with the last value of C<$?>.
2098
2099 =cut
2100
2101                 $cmd =~ /^q$/ && do {
2102                     $fall_off_end = 1;
2103                     clean_ENV();
2104                     exit $?;
2105                 };
2106
2107 =head4 C<t> - trace [n]
2108
2109 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2110 If level is specified, set C<$trace_to_depth>.
2111
2112 =cut
2113
2114                 $cmd =~ /^t(?:\s+(\d+))?$/ && do {
2115                     my $levels = $1;
2116                     $trace ^= 1;
2117                     local $\ = '';
2118                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2119                     print $OUT "Trace = "
2120                       . ( ( $trace & 1 )
2121                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2122                       : "off" ) . "\n";
2123                     next CMD;
2124                 };
2125
2126 =head4 C<S> - list subroutines matching/not matching a pattern
2127
2128 Walks through C<%sub>, checking to see whether or not to print the name.
2129
2130 =cut
2131
2132                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2133
2134                     $Srev     = defined $2;     # Reverse scan?
2135                     $Spatt    = $3;             # The pattern (if any) to use.
2136                     $Snocheck = !defined $1;    # No args - print all subs.
2137
2138                     # Need to make these sane here.
2139                     local $\ = '';
2140                     local $, = '';
2141
2142                     # Search through the debugger's magical hash of subs.
2143                     # If $nocheck is true, just print the sub name.
2144                     # Otherwise, check it against the pattern. We then use
2145                     # the XOR trick to reverse the condition as required.
2146                     foreach $subname ( sort( keys %sub ) ) {
2147                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2148                             print $OUT $subname, "\n";
2149                         }
2150                     }
2151                     next CMD;
2152                 };
2153
2154 =head4 C<X> - list variables in current package
2155
2156 Since the C<V> command actually processes this, just change this to the
2157 appropriate C<V> command and fall through.
2158
2159 =cut
2160
2161                 $cmd =~ s/^X\b/V $package/;
2162
2163 =head4 C<V> - list variables
2164
2165 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2166
2167 =cut
2168
2169                 # Bare V commands get the currently-being-debugged package
2170                 # added.
2171                 $cmd =~ /^V$/ && do {
2172                     $cmd = "V $package";
2173                 };
2174
2175                 # V - show variables in package.
2176                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2177
2178                     # Save the currently selected filehandle and
2179                     # force output to debugger's filehandle (dumpvar
2180                     # just does "print" for output).
2181                     local ($savout) = select($OUT);
2182
2183                     # Grab package name and variables to dump.
2184                     $packname = $1;
2185                     @vars     = split( ' ', $2 );
2186
2187                     # If main::dumpvar isn't here, get it.
2188                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2189                     if ( defined &main::dumpvar ) {
2190
2191                         # We got it. Turn off subroutine entry/exit messages
2192                         # for the moment, along with return values.
2193                         local $frame = 0;
2194                         local $doret = -2;
2195
2196                         # must detect sigpipe failures  - not catching
2197                         # then will cause the debugger to die.
2198                         eval {
2199                             &main::dumpvar(
2200                                 $packname,
2201                                 defined $option{dumpDepth}
2202                                 ? $option{dumpDepth}
2203                                 : -1,    # assume -1 unless specified
2204                                 @vars
2205                             );
2206                         };
2207
2208                         # The die doesn't need to include the $@, because
2209                         # it will automatically get propagated for us.
2210                         if ($@) {
2211                             die unless $@ =~ /dumpvar print failed/;
2212                         }
2213                     } ## end if (defined &main::dumpvar)
2214                     else {
2215
2216                         # Couldn't load dumpvar.
2217                         print $OUT "dumpvar.pl not available.\n";
2218                     }
2219
2220                     # Restore the output filehandle, and go round again.
2221                     select($savout);
2222                     next CMD;
2223                 };
2224
2225 =head4 C<x> - evaluate and print an expression
2226
2227 Hands the expression off to C<DB::eval>, setting it up to print the value
2228 via C<dumpvar.pl> instead of just printing it directly.
2229
2230 =cut
2231
2232                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2233                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2234
2235                     # handle special  "x 3 blah" syntax XXX propagate
2236                     # doc back to special variables.
2237                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2238                         $onetimedumpDepth = $1;
2239                     }
2240                 };
2241
2242 =head4 C<m> - print methods
2243
2244 Just uses C<DB::methods> to determine what methods are available.
2245
2246 =cut
2247
2248                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2249                     methods($1);
2250                     next CMD;
2251                 };
2252
2253                 # m expr - set up DB::eval to do the work
2254                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2255                     $onetimeDump = 'methods';   #  method output gets used there
2256                 };
2257
2258 =head4 C<f> - switch files
2259
2260 =cut
2261
2262                 $cmd =~ /^f\b\s*(.*)/ && do {
2263                     $file = $1;
2264                     $file =~ s/\s+$//;
2265
2266                     # help for no arguments (old-style was return from sub).
2267                     if ( !$file ) {
2268                         print $OUT
2269                           "The old f command is now the r command.\n";    # hint
2270                         print $OUT "The new f command switches filenames.\n";
2271                         next CMD;
2272                     } ## end if (!$file)
2273
2274                     # if not in magic file list, try a close match.
2275                     if ( !defined $main::{ '_<' . $file } ) {
2276                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2277                             {
2278                                 $try = substr( $try, 2 );
2279                                 print $OUT "Choosing $try matching '$file':\n";
2280                                 $file = $try;
2281                             }
2282                         } ## end if (($try) = grep(m#^_<.*$file#...
2283                     } ## end if (!defined $main::{ ...
2284
2285                     # If not successfully switched now, we failed.
2286                     if ( !defined $main::{ '_<' . $file } ) {
2287                         print $OUT "No file matching '$file' is loaded.\n";
2288                         next CMD;
2289                     }
2290
2291                     # We switched, so switch the debugger internals around.
2292                     elsif ( $file ne $filename ) {
2293                         *dbline   = $main::{ '_<' . $file };
2294                         $max      = $#dbline;
2295                         $filename = $file;
2296                         $start    = 1;
2297                         $cmd      = "l";
2298                     } ## end elsif ($file ne $filename)
2299
2300                     # We didn't switch; say we didn't.
2301                     else {
2302                         print $OUT "Already in $file.\n";
2303                         next CMD;
2304                     }
2305                 };
2306
2307 =head4 C<.> - return to last-executed line.
2308
2309 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2310 and then we look up the line in the magical C<%dbline> hash.
2311
2312 =cut
2313
2314                 # . command.
2315                 $cmd =~ /^\.$/ && do {
2316                     $incr = -1;    # stay at current line
2317
2318                     # Reset everything to the old location.
2319                     $start    = $line;
2320                     $filename = $filename_ini;
2321                     *dbline   = $main::{ '_<' . $filename };
2322                     $max      = $#dbline;
2323
2324                     # Now where are we?
2325                     print_lineinfo($position);
2326                     next CMD;
2327                 };
2328
2329 =head4 C<-> - back one window
2330
2331 We change C<$start> to be one window back; if we go back past the first line,
2332 we set it to be the first line. We ser C<$incr> to put us back at the
2333 currently-executing line, and then put a C<l $start +> (list one window from
2334 C<$start>) in C<$cmd> to be executed later.
2335
2336 =cut
2337
2338                 # - - back a window.
2339                 $cmd =~ /^-$/ && do {
2340
2341                     # back up by a window; go to 1 if back too far.
2342                     $start -= $incr + $window + 1;
2343                     $start = 1 if $start <= 0;
2344                     $incr  = $window - 1;
2345
2346                     # Generate and execute a "l +" command (handled below).
2347                     $cmd = 'l ' . ($start) . '+';
2348                 };
2349
2350 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2351
2352 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2353 problems, most notably that the default case of several commands destroying
2354 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2355 retain the old commands for those who were used to using them or who preferred
2356 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2357 deal with them instead of processing them in-line.
2358
2359 =cut
2360
2361                 # All of these commands were remapped in perl 5.8.0;
2362                 # we send them off to the secondary dispatcher (see below).
2363                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2364                     &cmd_wrapper( $1, $2, $line );
2365                     next CMD;
2366                 };
2367
2368 =head4 C<y> - List lexicals in higher scope
2369
2370 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2371 above the current one and then displays then using C<dumpvar.pl>.
2372
2373 =cut
2374
2375                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2376
2377                     # See if we've got the necessary support.
2378                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2379                       or &warn(
2380                         $@ =~ /locate/
2381                         ? "PadWalker module not found - please install\n"
2382                         : $@
2383                       )
2384                       and next CMD;
2385
2386                     # Load up dumpvar if we don't have it. If we can, that is.
2387                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2388                     defined &main::dumpvar
2389                       or print $OUT "dumpvar.pl not available.\n"
2390                       and next CMD;
2391
2392                     # Got all the modules we need. Find them and print them.
2393                     my @vars = split( ' ', $2 || '' );
2394
2395                     # Find the pad.
2396                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2397
2398                     # Oops. Can't find it.
2399                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2400
2401                     # Show the desired vars with dumplex().
2402                     my $savout = select($OUT);
2403
2404                     # Have dumplex dump the lexicals.
2405                     dumpvar::dumplex( $_, $h->{$_},
2406                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2407                         @vars )
2408                       for sort keys %$h;
2409                     select($savout);
2410                     next CMD;
2411                 };
2412
2413 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2414
2415 All of the commands below this point don't work after the program being
2416 debugged has ended. All of them check to see if the program has ended; this
2417 allows the commands to be relocated without worrying about a 'line of
2418 demarcation' above which commands can be entered anytime, and below which
2419 they can't.
2420
2421 =head4 C<n> - single step, but don't trace down into subs
2422
2423 Done by setting C<$single> to 2, which forces subs to execute straight through
2424 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2425 so a null command knows what to re-execute.
2426
2427 =cut
2428
2429                 # n - next
2430                 $cmd =~ /^n$/ && do {
2431                     end_report(), next CMD if $finished and $level <= 1;
2432
2433                     # Single step, but don't enter subs.
2434                     $single = 2;
2435
2436                     # Save for empty command (repeat last).
2437                     $laststep = $cmd;
2438                     last CMD;
2439                 };
2440
2441 =head4 C<s> - single-step, entering subs
2442
2443 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2444 subs. Also saves C<s> as C<$lastcmd>.
2445
2446 =cut
2447
2448                 # s - single step.
2449                 $cmd =~ /^s$/ && do {
2450
2451                     # Get out and restart the command loop if program
2452                     # has finished.
2453                     end_report(), next CMD if $finished and $level <= 1;
2454
2455                     # Single step should enter subs.
2456                     $single = 1;
2457
2458                     # Save for empty command (repeat last).
2459                     $laststep = $cmd;
2460                     last CMD;
2461                 };
2462
2463 =head4 C<c> - run continuously, setting an optional breakpoint
2464
2465 Most of the code for this command is taken up with locating the optional
2466 breakpoint, which is either a subroutine name or a line number. We set
2467 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2468 in this and all call levels above this one.
2469
2470 =cut
2471
2472                 # c - start continuous execution.
2473                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2474
2475                     # Hey, show's over. The debugged program finished
2476                     # executing already.
2477                     end_report(), next CMD if $finished and $level <= 1;
2478
2479                     # Capture the place to put a one-time break.
2480                     $subname = $i = $1;
2481
2482                     #  Probably not needed, since we finish an interactive
2483                     #  sub-session anyway...
2484                     # local $filename = $filename;
2485                     # local *dbline = *dbline; # XXX Would this work?!
2486                     #
2487                     # The above question wonders if localizing the alias
2488                     # to the magic array works or not. Since it's commented
2489                     # out, we'll just leave that to speculation for now.
2490
2491                     # If the "subname" isn't all digits, we'll assume it
2492                     # is a subroutine name, and try to find it.
2493                     if ( $subname =~ /\D/ ) {    # subroutine name
2494                             # Qualify it to the current package unless it's
2495                             # already qualified.
2496                         $subname = $package . "::" . $subname
2497                           unless $subname =~ /::/;
2498
2499                         # find_sub will return "file:line_number" corresponding
2500                         # to where the subroutine is defined; we call find_sub,
2501                         # break up the return value, and assign it in one
2502                         # operation.
2503                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2504
2505                         # Force the line number to be numeric.
2506                         $i += 0;
2507
2508                         # If we got a line number, we found the sub.
2509                         if ($i) {
2510
2511                             # Switch all the debugger's internals around so
2512                             # we're actually working with that file.
2513                             $filename = $file;
2514                             *dbline   = $main::{ '_<' . $filename };
2515
2516                             # Mark that there's a breakpoint in this file.
2517                             $had_breakpoints{$filename} |= 1;
2518
2519                             # Scan forward to the first executable line
2520                             # after the 'sub whatever' line.
2521                             $max = $#dbline;
2522                             ++$i while $dbline[$i] == 0 && $i < $max;
2523                         } ## end if ($i)
2524
2525                         # We didn't find a sub by that name.
2526                         else {
2527                             print $OUT "Subroutine $subname not found.\n";
2528                             next CMD;
2529                         }
2530                     } ## end if ($subname =~ /\D/)
2531
2532                     # At this point, either the subname was all digits (an
2533                     # absolute line-break request) or we've scanned through
2534                     # the code following the definition of the sub, looking
2535                     # for an executable, which we may or may not have found.
2536                     #
2537                     # If $i (which we set $subname from) is non-zero, we
2538                     # got a request to break at some line somewhere. On
2539                     # one hand, if there wasn't any real subroutine name
2540                     # involved, this will be a request to break in the current
2541                     # file at the specified line, so we have to check to make
2542                     # sure that the line specified really is breakable.
2543                     #
2544                     # On the other hand, if there was a subname supplied, the
2545                     # preceding block has moved us to the proper file and
2546                     # location within that file, and then scanned forward
2547                     # looking for the next executable line. We have to make
2548                     # sure that one was found.
2549                     #
2550                     # On the gripping hand, we can't do anything unless the
2551                     # current value of $i points to a valid breakable line.
2552                     # Check that.
2553                     if ($i) {
2554
2555                         # Breakable?
2556                         if ( $dbline[$i] == 0 ) {
2557                             print $OUT "Line $i not breakable.\n";
2558                             next CMD;
2559                         }
2560
2561                         # Yes. Set up the one-time-break sigil.
2562                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2563                         _enable_breakpoint_temp_enabled_status($filename, $i);
2564                     } ## end if ($i)
2565
2566                     # Turn off stack tracing from here up.
2567                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2568                         $stack[ $i++ ] &= ~1;
2569                     }
2570                     last CMD;
2571                 };
2572
2573 =head4 C<r> - return from a subroutine
2574
2575 For C<r> to work properly, the debugger has to stop execution again
2576 immediately after the return is executed. This is done by forcing
2577 single-stepping to be on in the call level above the current one. If
2578 we are printing return values when a C<r> is executed, set C<$doret>
2579 appropriately, and force us out of the command loop.
2580
2581 =cut
2582
2583                 # r - return from the current subroutine.
2584                 $cmd =~ /^r$/ && do {
2585
2586                     # Can't do anything if the program's over.
2587                     end_report(), next CMD if $finished and $level <= 1;
2588
2589                     # Turn on stack trace.
2590                     $stack[$stack_depth] |= 1;
2591
2592                     # Print return value unless the stack is empty.
2593                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2594                     last CMD;
2595                 };
2596
2597 =head4 C<T> - stack trace
2598
2599 Just calls C<DB::print_trace>.
2600
2601 =cut
2602
2603                 $cmd =~ /^T$/ && do {
2604                     print_trace( $OUT, 1 );    # skip DB
2605                     next CMD;
2606                 };
2607
2608 =head4 C<w> - List window around current line.
2609
2610 Just calls C<DB::cmd_w>.
2611
2612 =cut
2613
2614                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2615
2616 =head4 C<W> - watch-expression processing.
2617
2618 Just calls C<DB::cmd_W>.
2619
2620 =cut
2621
2622                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2623
2624 =head4 C</> - search forward for a string in the source
2625
2626 We take the argument and treat it as a pattern. If it turns out to be a
2627 bad one, we return the error we got from trying to C<eval> it and exit.
2628 If not, we create some code to do the search and C<eval> it so it can't
2629 mess us up.
2630
2631 =cut
2632
2633                 $cmd =~ /^\/(.*)$/ && do {
2634
2635                     # The pattern as a string.
2636                     $inpat = $1;
2637
2638                     # Remove the final slash.
2639                     $inpat =~ s:([^\\])/$:$1:;
2640
2641                     # If the pattern isn't null ...
2642                     if ( $inpat ne "" ) {
2643
2644                         # Turn of warn and die procesing for a bit.
2645                         local $SIG{__DIE__};
2646                         local $SIG{__WARN__};
2647
2648                         # Create the pattern.
2649                         eval '$inpat =~ m' . "\a$inpat\a";
2650                         if ( $@ ne "" ) {
2651
2652                             # Oops. Bad pattern. No biscuit.
2653                             # Print the eval error and go back for more
2654                             # commands.
2655                             print $OUT "$@";
2656                             next CMD;
2657                         }
2658                         $pat = $inpat;
2659                     } ## end if ($inpat ne "")
2660
2661                     # Set up to stop on wrap-around.
2662                     $end = $start;
2663
2664                     # Don't move off the current line.
2665                     $incr = -1;
2666
2667                     # Done in eval so nothing breaks if the pattern
2668                     # does something weird.
2669                     eval '
2670                         for (;;) {
2671                             # Move ahead one line.
2672                             ++$start;
2673
2674                             # Wrap if we pass the last line.
2675                             $start = 1 if ($start > $max);
2676
2677                             # Stop if we have gotten back to this line again,
2678                             last if ($start == $end);
2679
2680                             # A hit! (Note, though, that we are doing
2681                             # case-insensitive matching. Maybe a qr//
2682                             # expression would be better, so the user could
2683                             # do case-sensitive matching if desired.
2684                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2685                                 if ($slave_editor) {
2686                                     # Handle proper escaping in the slave.
2687                                     print $OUT "\032\032$filename:$start:0\n";
2688                                 }
2689                                 else {
2690                                     # Just print the line normally.
2691                                     print $OUT "$start:\t",$dbline[$start],"\n";
2692                                 }
2693                                 # And quit since we found something.
2694                                 last;
2695                             }
2696                          } ';
2697
2698                     # If we wrapped, there never was a match.
2699                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2700                     next CMD;
2701                 };
2702
2703 =head4 C<?> - search backward for a string in the source
2704
2705 Same as for C</>, except the loop runs backwards.
2706
2707 =cut
2708
2709                 # ? - backward pattern search.
2710                 $cmd =~ /^\?(.*)$/ && do {
2711
2712                     # Get the pattern, remove trailing question mark.
2713                     $inpat = $1;
2714                     $inpat =~ s:([^\\])\?$:$1:;
2715
2716                     # If we've got one ...
2717                     if ( $inpat ne "" ) {
2718
2719                         # Turn off die & warn handlers.
2720                         local $SIG{__DIE__};
2721                         local $SIG{__WARN__};
2722                         eval '$inpat =~ m' . "\a$inpat\a";
2723
2724                         if ( $@ ne "" ) {
2725
2726                             # Ouch. Not good. Print the error.
2727                             print $OUT $@;
2728                             next CMD;
2729                         }
2730                         $pat = $inpat;
2731                     } ## end if ($inpat ne "")
2732
2733                     # Where we are now is where to stop after wraparound.
2734                     $end = $start;
2735
2736                     # Don't move away from this line.
2737                     $incr = -1;
2738
2739                     # Search inside the eval to prevent pattern badness
2740                     # from killing us.
2741                     eval '
2742                         for (;;) {
2743                             # Back up a line.
2744                             --$start;
2745
2746                             # Wrap if we pass the first line.
2747
2748                             $start = $max if ($start <= 0);
2749
2750                             # Quit if we get back where we started,
2751                             last if ($start == $end);
2752
2753                             # Match?
2754                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2755                                 if ($slave_editor) {
2756                                     # Yep, follow slave editor requirements.
2757                                     print $OUT "\032\032$filename:$start:0\n";
2758                                 }
2759                                 else {
2760                                     # Yep, just print normally.
2761                                     print $OUT "$start:\t",$dbline[$start],"\n";
2762                                 }
2763
2764                                 # Found, so done.
2765                                 last;
2766                             }
2767                         } ';
2768
2769                     # Say we failed if the loop never found anything,
2770                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2771                     next CMD;
2772                 };
2773
2774 =head4 C<$rc> - Recall command
2775
2776 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2777 that the terminal supports history). It find the the command required, puts it
2778 into C<$cmd>, and redoes the loop to execute it.
2779
2780 =cut
2781
2782                 # $rc - recall command.
2783                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
2784
2785                     # No arguments, take one thing off history.
2786                     pop(@hist) if length($cmd) > 1;
2787
2788                     # Relative (- found)?
2789                     #  Y - index back from most recent (by 1 if bare minus)
2790                     #  N - go to that particular command slot or the last
2791                     #      thing if nothing following.
2792                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
2793
2794                     # Pick out the command desired.
2795                     $cmd = $hist[$i];
2796
2797                     # Print the command to be executed and restart the loop
2798                     # with that command in the buffer.
2799                     print $OUT $cmd, "\n";
2800                     redo CMD;
2801                 };
2802
2803 =head4 C<$sh$sh> - C<system()> command
2804
2805 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2806 C<STDOUT> from getting messed up.
2807
2808 =cut
2809
2810                 # $sh$sh - run a shell command (if it's all ASCII).
2811                 # Can't run shell commands with Unicode in the debugger, hmm.
2812                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
2813
2814                     # System it.
2815                     &system($1);
2816                     next CMD;
2817                 };
2818
2819 =head4 C<$rc I<pattern> $rc> - Search command history
2820
2821 Another command to manipulate C<@hist>: this one searches it with a pattern.
2822 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2823
2824 =cut
2825
2826                 # $rc pattern $rc - find a command in the history.
2827                 $cmd =~ /^$rc([^$rc].*)$/ && do {
2828
2829                     # Create the pattern to use.
2830                     $pat = "^$1";
2831
2832                     # Toss off last entry if length is >1 (and it always is).
2833                     pop(@hist) if length($cmd) > 1;
2834
2835                     # Look backward through the history.
2836                     for ( $i = $#hist ; $i ; --$i ) {
2837
2838                         # Stop if we find it.
2839                         last if $hist[$i] =~ /$pat/;
2840                     }
2841
2842                     if ( !$i ) {
2843
2844                         # Never found it.
2845                         print $OUT "No such command!\n\n";
2846                         next CMD;
2847                     }
2848
2849                     # Found it. Put it in the buffer, print it, and process it.
2850                     $cmd = $hist[$i];
2851                     print $OUT $cmd, "\n";
2852                     redo CMD;
2853                 };
2854
2855 =head4 C<$sh> - Invoke a shell
2856
2857 Uses C<DB::system> to invoke a shell.
2858
2859 =cut
2860
2861                 # $sh - start a shell.
2862                 $cmd =~ /^$sh$/ && do {
2863
2864                     # Run the user's shell. If none defined, run Bourne.
2865                     # We resume execution when the shell terminates.
2866                     &system( $ENV{SHELL} || "/bin/sh" );
2867                     next CMD;
2868                 };
2869
2870 =head4 C<$sh I<command>> - Force execution of a command in a shell
2871
2872 Like the above, but the command is passed to the shell. Again, we use
2873 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2874
2875 =cut
2876
2877                 # $sh command - start a shell and run a command in it.
2878                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
2879
2880                     # XXX: using csh or tcsh destroys sigint retvals!
2881                     #&system($1);  # use this instead
2882
2883                     # use the user's shell, or Bourne if none defined.
2884                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
2885                     next CMD;
2886                 };
2887
2888 =head4 C<H> - display commands in history
2889
2890 Prints the contents of C<@hist> (if any).
2891
2892 =cut
2893
2894                 $cmd =~ /^H\b\s*\*/ && do {
2895                     @hist = @truehist = ();
2896                     print $OUT "History cleansed\n";
2897                     next CMD;
2898                 };
2899
2900                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
2901
2902                     # Anything other than negative numbers is ignored by
2903                     # the (incorrect) pattern, so this test does nothing.
2904                     $end = $2 ? ( $#hist - $2 ) : 0;
2905
2906                     # Set to the minimum if less than zero.
2907                     $hist = 0 if $hist < 0;
2908
2909                     # Start at the end of the array.
2910                     # Stay in while we're still above the ending value.
2911                     # Tick back by one each time around the loop.
2912                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2913
2914                         # Print the command  unless it has no arguments.
2915                         print $OUT "$i: ", $hist[$i], "\n"
2916                           unless $hist[$i] =~ /^.?$/;
2917                     }
2918                     next CMD;
2919                 };
2920
2921 =head4 C<man, doc, perldoc> - look up documentation
2922
2923 Just calls C<runman()> to print the appropriate document.
2924
2925 =cut
2926
2927                 # man, perldoc, doc - show manual pages.
2928                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
2929                     runman($1);
2930                     next CMD;
2931                 };
2932
2933 =head4 C<p> - print
2934
2935 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2936 the bottom of the loop.
2937
2938 =cut
2939
2940                 # p - print (no args): print $_.
2941                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
2942
2943                 # p - print the given expression.
2944                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
2945
2946 =head4 C<=> - define command alias
2947
2948 Manipulates C<%alias> to add or list command aliases.
2949
2950 =cut
2951
2952                 # = - set up a command alias.
2953                 $cmd =~ s/^=\s*// && do {
2954                     my @keys;
2955                     if ( length $cmd == 0 ) {
2956
2957                         # No args, get current aliases.
2958                         @keys = sort keys %alias;
2959                     }
2960                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
2961
2962                         # Creating a new alias. $k is alias name, $v is
2963                         # alias value.
2964
2965                         # can't use $_ or kill //g state
2966                         for my $x ( $k, $v ) {
2967
2968                             # Escape "alarm" characters.
2969                             $x =~ s/\a/\\a/g;
2970                         }
2971
2972                         # Substitute key for value, using alarm chars
2973                         # as separators (which is why we escaped them in
2974                         # the command).
2975                         $alias{$k} = "s\a$k\a$v\a";
2976
2977                         # Turn off standard warn and die behavior.
2978                         local $SIG{__DIE__};
2979                         local $SIG{__WARN__};
2980
2981                         # Is it valid Perl?
2982                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
2983
2984                             # Nope. Bad alias. Say so and get out.
2985                             print $OUT "Can't alias $k to $v: $@\n";
2986                             delete $alias{$k};
2987                             next CMD;
2988                         }
2989
2990                         # We'll only list the new one.
2991                         @keys = ($k);
2992                     } ## end elsif (my ($k, $v) = ($cmd...
2993
2994                     # The argument is the alias to list.
2995                     else {
2996                         @keys = ($cmd);
2997                     }
2998
2999                     # List aliases.
3000                     for my $k (@keys) {
3001
3002                         # Messy metaquoting: Trim the substitution code off.
3003                         # We use control-G as the delimiter because it's not
3004                         # likely to appear in the alias.
3005                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3006
3007                             # Print the alias.
3008                             print $OUT "$k\t= $1\n";
3009                         }
3010                         elsif ( defined $alias{$k} ) {
3011
3012                             # Couldn't trim it off; just print the alias code.
3013                             print $OUT "$k\t$alias{$k}\n";
3014                         }
3015                         else {
3016
3017                             # No such, dude.
3018                             print "No alias for $k\n";
3019                         }
3020                     } ## end for my $k (@keys)
3021                     next CMD;
3022                 };
3023
3024 =head4 C<source> - read commands from a file.
3025
3026 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3027 pick it up.
3028
3029 =cut
3030
3031                 # source - read commands from a file (or pipe!) and execute.
3032                 $cmd =~ /^source\s+(.*\S)/ && do {
3033                     if ( open my $fh, $1 ) {
3034
3035                         # Opened OK; stick it in the list of file handles.
3036                         push @cmdfhs, $fh;
3037                     }
3038                     else {
3039
3040                         # Couldn't open it.
3041                         &warn("Can't execute '$1': $!\n");
3042                     }
3043                     next CMD;
3044                 };
3045
3046                 $cmd =~ /^(enable|disable)\s+(\S+)\s*$/ && do {
3047                     my ($cmd, $position) = ($1, $2);
3048
3049                     my ($fn, $line_num);
3050                     if ($position =~ m{\A\d+\z})
3051                     {
3052                         $fn = $filename;
3053                         $line_num = $position;
3054                     }
3055                     elsif ($position =~ m{\A(.*):(\d+)\z})
3056                     {
3057                         ($fn, $line_num) = ($1, $2);
3058                     }
3059                     else
3060                     {
3061                         &warn("Wrong spec for enable/disable argument.\n");
3062                     }
3063
3064                     if (defined($fn)) {
3065                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3066                             _set_breakpoint_enabled_status($fn, $line_num,
3067                                 ($cmd eq 'enable' ? 1 : '')
3068                             );
3069                         }
3070                         else {
3071                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3072                         }
3073                     }
3074
3075                     next CMD;
3076                 };
3077
3078 =head4 C<save> - send current history to a file
3079
3080 Takes the complete history, (not the shrunken version you see with C<H>),
3081 and saves it to the given filename, so it can be replayed using C<source>.
3082
3083 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3084
3085 =cut
3086
3087                 # save source - write commands to a file for later use
3088                 $cmd =~ /^save\s*(.*)$/ && do {
3089                     my $file = $1 || '.perl5dbrc';    # default?
3090                     if ( open my $fh, "> $file" ) {
3091
3092                        # chomp to remove extraneous newlines from source'd files
3093                         chomp( my @truelist =
3094                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3095                               @truehist );
3096                         print $fh join( "\n", @truelist );
3097                         print "commands saved in $file\n";
3098                     }
3099                     else {
3100                         &warn("Can't save debugger commands in '$1': $!\n");
3101                     }
3102                     next CMD;
3103                 };
3104
3105 =head4 C<R> - restart
3106
3107 Restart the debugger session.
3108
3109 =head4 C<rerun> - rerun the current session
3110
3111 Return to any given position in the B<true>-history list
3112
3113 =cut
3114
3115                 # R - restart execution.
3116                 # rerun - controlled restart execution.
3117                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3118                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3119
3120                     # Close all non-system fds for a clean restart.  A more
3121                     # correct method would be to close all fds that were not
3122                     # open when the process started, but this seems to be
3123                     # hard.  See "debugger 'R'estart and open database
3124                     # connections" on p5p.
3125
3126                     my $max_fd = 1024; # default if POSIX can't be loaded
3127                     if (eval { require POSIX }) {
3128                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3129                     }
3130
3131                     if (defined $max_fd) {
3132                         foreach ($^F+1 .. $max_fd-1) {
3133                             next unless open FD_TO_CLOSE, "<&=$_";
3134                             close(FD_TO_CLOSE);
3135                         }
3136                     }
3137
3138                     # And run Perl again.  We use exec() to keep the
3139                     # PID stable (and that way $ini_pids is still valid).
3140                     exec(@args) || print $OUT "exec failed: $!\n";
3141
3142                     last CMD;
3143                 };
3144
3145 =head4 C<|, ||> - pipe output through the pager.
3146
3147 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3148 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3149 pipe to the pager (restoring the output filehandles if this fails). If this
3150 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3151 set C<$signal>, sending us back into the debugger.
3152
3153 We then trim off the pipe symbols and C<redo> the command loop at the
3154 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3155 reading another.
3156
3157 =cut
3158
3159                 # || - run command in the pager, with output to DB::OUT.
3160                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3161                     if ( $pager =~ /^\|/ ) {
3162
3163                         # Default pager is into a pipe. Redirect I/O.
3164                         open( SAVEOUT, ">&STDOUT" )
3165                           || &warn("Can't save STDOUT");
3166                         open( STDOUT, ">&OUT" )
3167                           || &warn("Can't redirect STDOUT");
3168                     } ## end if ($pager =~ /^\|/)
3169                     else {
3170
3171                         # Not into a pipe. STDOUT is safe.
3172                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3173                     }
3174
3175                     # Fix up environment to record we have less if so.
3176                     fix_less();
3177
3178                     unless ( $piped = open( OUT, $pager ) ) {
3179
3180                         # Couldn't open pipe to pager.
3181                         &warn("Can't pipe output to '$pager'");
3182                         if ( $pager =~ /^\|/ ) {
3183
3184                             # Redirect I/O back again.
3185                             open( OUT, ">&STDOUT" )    # XXX: lost message
3186                               || &warn("Can't restore DB::OUT");
3187                             open( STDOUT, ">&SAVEOUT" )
3188                               || &warn("Can't restore STDOUT");
3189                             close(SAVEOUT);
3190                         } ## end if ($pager =~ /^\|/)
3191                         else {
3192
3193                             # Redirect I/O. STDOUT already safe.
3194                             open( OUT, ">&STDOUT" )    # XXX: lost message
3195                               || &warn("Can't restore DB::OUT");
3196                         }
3197                         next CMD;
3198                     } ## end unless ($piped = open(OUT,...
3199
3200                     # Set up broken-pipe handler if necessary.
3201                     $SIG{PIPE} = \&DB::catch
3202                       if $pager =~ /^\|/
3203                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3204
3205                     # Save current filehandle, unbuffer out, and put it back.
3206                     $selected = select(OUT);
3207                     $|        = 1;
3208
3209                     # Don't put it back if pager was a pipe.
3210                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3211
3212                     # Trim off the pipe symbols and run the command now.
3213                     $cmd =~ s/^\|+\s*//;
3214                     redo PIPE;
3215                 };
3216
3217 =head3 END OF COMMAND PARSING
3218
3219 Anything left in C<$cmd> at this point is a Perl expression that we want to
3220 evaluate. We'll always evaluate in the user's context, and fully qualify
3221 any variables we might want to address in the C<DB> package.
3222
3223 =cut
3224
3225                 # t - turn trace on.
3226                 $cmd =~ s/^t\s+(\d+)?/\$DB::trace |= 1;\n/ && do {
3227                     $trace_to_depth = $1 ? $stack_depth||0 + $1 : 1E9;
3228                 };
3229
3230                 # s - single-step. Remember the last command was 's'.
3231                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3232
3233                 # n - single-step, but not into subs. Remember last command
3234                 # was 'n'.
3235                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3236
3237             }    # PIPE:
3238
3239             # Make sure the flag that says "the debugger's running" is
3240             # still on, to make sure we get control again.
3241             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3242
3243             # Run *our* eval that executes in the caller's context.
3244             &eval;
3245
3246             # Turn off the one-time-dump stuff now.
3247             if ($onetimeDump) {
3248                 $onetimeDump      = undef;
3249                 $onetimedumpDepth = undef;
3250             }
3251             elsif ( $term_pid == $$ ) {
3252                 eval {          # May run under miniperl, when not available...
3253                     STDOUT->flush();
3254                     STDERR->flush();
3255                 };
3256
3257                 # XXX If this is the master pid, print a newline.
3258                 print $OUT "\n";
3259             }
3260         } ## end while (($term || &setterm...
3261
3262 =head3 POST-COMMAND PROCESSING
3263
3264 After each command, we check to see if the command output was piped anywhere.
3265 If so, we go through the necessary code to unhook the pipe and go back to
3266 our standard filehandles for input and output.
3267
3268 =cut
3269
3270         continue {    # CMD:
3271
3272             # At the end of every command:
3273             if ($piped) {
3274
3275                 # Unhook the pipe mechanism now.
3276                 if ( $pager =~ /^\|/ ) {
3277
3278                     # No error from the child.
3279                     $? = 0;
3280
3281                     # we cannot warn here: the handle is missing --tchrist
3282                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3283
3284                     # most of the $? crud was coping with broken cshisms
3285                     # $? is explicitly set to 0, so this never runs.
3286                     if ($?) {
3287                         print SAVEOUT "Pager '$pager' failed: ";
3288                         if ( $? == -1 ) {
3289                             print SAVEOUT "shell returned -1\n";
3290                         }
3291                         elsif ( $? >> 8 ) {
3292                             print SAVEOUT ( $? & 127 )
3293                               ? " (SIG#" . ( $? & 127 ) . ")"
3294                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3295                         }
3296                         else {
3297                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3298                         }
3299                     } ## end if ($?)
3300
3301                     # Reopen filehandle for our output (if we can) and
3302                     # restore STDOUT (if we can).
3303                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3304                     open( STDOUT, ">&SAVEOUT" )
3305                       || &warn("Can't restore STDOUT");
3306
3307                     # Turn off pipe exception handler if necessary.
3308                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3309
3310                     # Will stop ignoring SIGPIPE if done like nohup(1)
3311                     # does SIGINT but Perl doesn't give us a choice.
3312                 } ## end if ($pager =~ /^\|/)
3313                 else {
3314
3315                     # Non-piped "pager". Just restore STDOUT.
3316                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3317                 }
3318
3319                 # Close filehandle pager was using, restore the normal one
3320                 # if necessary,
3321                 close(SAVEOUT);
3322                 select($selected), $selected = "" unless $selected eq "";
3323
3324                 # No pipes now.
3325                 $piped = "";
3326             } ## end if ($piped)
3327         }    # CMD:
3328
3329 =head3 COMMAND LOOP TERMINATION
3330
3331 When commands have finished executing, we come here. If the user closed the
3332 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3333 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3334 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3335 The interpreter will then execute the next line and then return control to us
3336 again.
3337
3338 =cut
3339
3340         # No more commands? Quit.
3341         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3342
3343         # Evaluate post-prompt commands.
3344         foreach $evalarg (@$post) {
3345             &eval;
3346         }
3347     }    # if ($single || $signal)
3348
3349     # Put the user's globals back where you found them.
3350     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3351     ();
3352 } ## end sub DB
3353
3354 # The following code may be executed now:
3355 # BEGIN {warn 4}
3356
3357 =head2 sub
3358
3359 C<sub> is called whenever a subroutine call happens in the program being
3360 debugged. The variable C<$DB::sub> contains the name of the subroutine
3361 being called.
3362
3363 The core function of this subroutine is to actually call the sub in the proper
3364 context, capturing its output. This of course causes C<DB::DB> to get called
3365 again, repeating until the subroutine ends and returns control to C<DB::sub>
3366 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3367 return value, and returns its captured copy of the return value as its own
3368 return value. The value then feeds back into the program being debugged as if
3369 C<DB::sub> hadn't been there at all.
3370
3371 C<sub> does all the work of printing the subroutine entry and exit messages
3372 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3373 and also prints the return value if needed (for the C<r> command and if
3374 the 16 bit is set in C<$frame>).
3375
3376 It also tracks the subroutine call depth by saving the current setting of
3377 C<$single> in the C<@stack> package global; if this exceeds the value in
3378 C<$deep>, C<sub> automatically turns on printing of the current depth by
3379 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3380 of stop/don't stop on entry to subs set as it currently is set.
3381
3382 =head3 C<caller()> support
3383
3384 If C<caller()> is called from the package C<DB>, it provides some
3385 additional data, in the following order:
3386
3387 =over 4
3388
3389 =item * C<$package>
3390
3391 The package name the sub was in
3392
3393 =item * C<$filename>
3394
3395 The filename it was defined in
3396
3397 =item * C<$line>
3398
3399 The line number it was defined on
3400
3401 =item * C<$subroutine>
3402
3403 The subroutine name; C<(eval)> if an C<eval>().
3404
3405 =item * C<$hasargs>
3406
3407 1 if it has arguments, 0 if not
3408
3409 =item * C<$wantarray>
3410
3411 1 if array context, 0 if scalar context
3412
3413 =item * C<$evaltext>
3414
3415 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3416
3417 =item * C<$is_require>
3418
3419 frame was created by a C<use> or C<require> statement
3420
3421 =item * C<$hints>
3422
3423 pragma information; subject to change between versions
3424
3425 =item * C<$bitmask>
3426
3427 pragma information; subject to change between versions
3428
3429 =item * C<@DB::args>
3430
3431 arguments with which the subroutine was invoked
3432
3433 =back
3434
3435 =cut
3436
3437 sub sub {
3438         # Do not use a regex in this subroutine -> results in corrupted memory
3439         # See: [perl #66110]
3440
3441         # lock ourselves under threads
3442         lock($DBGR);
3443
3444     # Whether or not the autoloader was running, a scalar to put the
3445     # sub's return value in (if needed), and an array to put the sub's
3446     # return value in (if needed).
3447     my ( $al, $ret, @ret ) = "";
3448         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3449                 print "creating new thread\n";
3450         }
3451
3452     # If the last ten characters are '::AUTOLOAD', note we've traced
3453     # into AUTOLOAD for $sub.
3454     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3455         $al = " for $$sub" if defined $$sub;
3456     }
3457
3458     # We stack the stack pointer and then increment it to protect us
3459     # from a situation that might unwind a whole bunch of call frames
3460     # at once. Localizing the stack pointer means that it will automatically
3461     # unwind the same amount when multiple stack frames are unwound.
3462     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3463
3464     # Expand @stack.
3465     $#stack = $stack_depth;
3466
3467     # Save current single-step setting.
3468     $stack[-1] = $single;
3469
3470     # Turn off all flags except single-stepping.
3471     $single &= 1;
3472
3473     # If we've gotten really deeply recursed, turn on the flag that will
3474     # make us stop with the 'deep recursion' message.
3475     $single |= 4 if $stack_depth == $deep;
3476
3477     # If frame messages are on ...
3478     (
3479         $frame & 4    # Extended frame entry message
3480         ? (
3481             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3482
3483             # Why -1? But it works! :-(
3484             # Because print_trace will call add 1 to it and then call
3485             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3486             # in dump_trace.
3487             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3488           )
3489         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3490
3491           # standard frame entry message
3492       )
3493       if $frame;
3494
3495     # Determine the sub's return type, and capture appropriately.
3496     if (wantarray) {
3497
3498         # Called in array context. call sub and capture output.
3499         # DB::DB will recursively get control again if appropriate; we'll come
3500         # back here when the sub is finished.
3501         @ret = &$sub;
3502
3503         # Pop the single-step value back off the stack.
3504         $single |= $stack[ $stack_depth-- ];
3505
3506         # Check for exit trace messages...
3507         (
3508             $frame & 4    # Extended exit message
3509             ? (
3510                 print_lineinfo( ' ' x $stack_depth, "out " ),
3511                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3512               )
3513             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3514
3515               # Standard exit message
3516           )
3517           if $frame & 2;
3518
3519         # Print the return info if we need to.
3520         if ( $doret eq $stack_depth or $frame & 16 ) {
3521
3522             # Turn off output record separator.
3523             local $\ = '';
3524             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3525
3526             # Indent if we're printing because of $frame tracing.
3527             print $fh ' ' x $stack_depth if $frame & 16;
3528
3529             # Print the return value.
3530             print $fh "list context return from $sub:\n";
3531             dumpit( $fh, \@ret );
3532
3533             # And don't print it again.
3534             $doret = -2;
3535         } ## end if ($doret eq $stack_depth...
3536             # And we have to return the return value now.
3537         @ret;
3538     } ## end if (wantarray)
3539
3540     # Scalar context.
3541     else {
3542         if ( defined wantarray ) {
3543
3544             # Save the value if it's wanted at all.
3545             $ret = &$sub;
3546         }
3547         else {
3548
3549             # Void return, explicitly.
3550             &$sub;
3551             undef $ret;
3552         }
3553
3554         # Pop the single-step value off the stack.
3555         $single |= $stack[ $stack_depth-- ];
3556
3557         # If we're doing exit messages...
3558         (
3559             $frame & 4    # Extended messages
3560             ? (
3561                 print_lineinfo( ' ' x $stack_depth, "out " ),
3562                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3563               )
3564             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3565
3566               # Standard messages
3567           )
3568           if $frame & 2;
3569
3570         # If we are supposed to show the return value... same as before.
3571         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3572             local $\ = '';
3573             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3574             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3575             print $fh (
3576                 defined wantarray
3577                 ? "scalar context return from $sub: "
3578                 : "void context return from $sub\n"
3579             );
3580             dumpit( $fh, $ret ) if defined wantarray;
3581             $doret = -2;
3582         } ## end if ($doret eq $stack_depth...
3583
3584         # Return the appropriate scalar value.
3585         $ret;
3586     } ## end else [ if (wantarray)
3587 } ## end sub sub
3588
3589 sub lsub : lvalue {
3590
3591         # lock ourselves under threads
3592         lock($DBGR);
3593
3594     # Whether or not the autoloader was running, a scalar to put the
3595     # sub's return value in (if needed), and an array to put the sub's
3596     # return value in (if needed).
3597     my ( $al, $ret, @ret ) = "";
3598         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3599                 print "creating new thread\n";
3600         }
3601
3602     # If the last ten characters are C'::AUTOLOAD', note we've traced
3603     # into AUTOLOAD for $sub.
3604     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3605         $al = " for $$sub";
3606     }
3607
3608     # We stack the stack pointer and then increment it to protect us
3609     # from a situation that might unwind a whole bunch of call frames
3610     # at once. Localizing the stack pointer means that it will automatically
3611     # unwind the same amount when multiple stack frames are unwound.
3612     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3613
3614     # Expand @stack.
3615     $#stack = $stack_depth;
3616
3617     # Save current single-step setting.
3618     $stack[-1] = $single;
3619
3620     # Turn off all flags except single-stepping.
3621     $single &= 1;
3622
3623     # If we've gotten really deeply recursed, turn on the flag that will
3624     # make us stop with the 'deep recursion' message.
3625     $single |= 4 if $stack_depth == $deep;
3626
3627     # If frame messages are on ...
3628     (
3629         $frame & 4    # Extended frame entry message
3630         ? (
3631             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3632
3633             # Why -1? But it works! :-(
3634             # Because print_trace will call add 1 to it and then call
3635             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3636             # in dump_trace.
3637             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3638           )
3639         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3640
3641           # standard frame entry message
3642       )
3643       if $frame;
3644
3645     # Pop the single-step value back off the stack.
3646     $single |= $stack[ $stack_depth-- ];
3647
3648     # call the original lvalue sub.
3649     &$sub;
3650 }
3651
3652 # Abstracting common code from multiple places elsewhere:
3653 sub depth_print_lineinfo {
3654     my $always_print = shift;
3655
3656     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3657 }
3658
3659 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3660
3661 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3662 Most of the changes were to systematize the command structure and to eliminate
3663 commands that threw away user input without checking.
3664
3665 The following sections describe the code added to make it easy to support
3666 multiple command sets with conflicting command names. This section is a start
3667 at unifying all command processing to make it simpler to develop commands.
3668
3669 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3670 number, and C<$dbline> (the current line) as arguments.
3671
3672 Support functions in this section which have multiple modes of failure C<die>
3673 on error; the rest simply return a false value.
3674
3675 The user-interface functions (all of the C<cmd_*> functions) just output
3676 error messages.
3677
3678 =head2 C<%set>
3679
3680 The C<%set> hash defines the mapping from command letter to subroutine
3681 name suffix.
3682
3683 C<%set> is a two-level hash, indexed by set name and then by command name.
3684 Note that trying to set the CommandSet to C<foobar> simply results in the
3685 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3686
3687 =cut
3688
3689 ### The API section
3690
3691 my %set = (    #
3692     'pre580' => {
3693         'a' => 'pre580_a',
3694         'A' => 'pre580_null',
3695         'b' => 'pre580_b',
3696         'B' => 'pre580_null',
3697         'd' => 'pre580_null',
3698         'D' => 'pre580_D',
3699         'h' => 'pre580_h',
3700         'M' => 'pre580_null',
3701         'O' => 'o',
3702         'o' => 'pre580_null',
3703         'v' => 'M',
3704         'w' => 'v',
3705         'W' => 'pre580_W',
3706     },
3707     'pre590' => {
3708         '<'  => 'pre590_prepost',
3709         '<<' => 'pre590_prepost',
3710         '>'  => 'pre590_prepost',
3711         '>>' => 'pre590_prepost',
3712         '{'  => 'pre590_prepost',
3713         '{{' => 'pre590_prepost',
3714     },
3715 );
3716
3717 my %breakpoints_data;
3718
3719 sub _has_breakpoint_data_ref {
3720     my ($filename, $line) = @_;
3721
3722     return (
3723         exists( $breakpoints_data{$filename} )
3724             and
3725         exists( $breakpoints_data{$filename}{$line} )
3726     );
3727 }
3728
3729 sub _get_breakpoint_data_ref {
3730     my ($filename, $line) = @_;
3731
3732     return ($breakpoints_data{$filename}{$line} ||= +{});
3733 }
3734
3735 sub _delete_breakpoint_data_ref {
3736     my ($filename, $line) = @_;
3737
3738     delete($breakpoints_data{$filename}{$line});
3739     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3740         delete($breakpoints_data{$filename});
3741     }
3742
3743     return;
3744 }
3745
3746 sub _set_breakpoint_enabled_status {
3747     my ($filename, $line, $status) = @_;
3748
3749     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3750         ($status ? 1 : '')
3751         ;
3752
3753     return;
3754 }
3755
3756 sub _enable_breakpoint_temp_enabled_status {
3757     my ($filename, $line) = @_;
3758
3759     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3760
3761     return;
3762 }
3763
3764 sub _cancel_breakpoint_temp_enabled_status {
3765     my ($filename, $line) = @_;
3766
3767     my $ref = _get_breakpoint_data_ref($filename, $line);
3768
3769     delete ($ref->{'temp_enabled'});
3770
3771     if (! %$ref) {
3772         _delete_breakpoint_data_ref($filename, $line);
3773     }
3774
3775     return;
3776 }
3777
3778 sub _is_breakpoint_enabled {
3779     my ($filename, $line) = @_;
3780
3781     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3782     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3783 }
3784
3785 =head2 C<cmd_wrapper()> (API)
3786
3787 C<cmd_wrapper()> allows the debugger to switch command sets
3788 depending on the value of the C<CommandSet> option.
3789
3790 It tries to look up the command in the C<%set> package-level I<lexical>
3791 (which means external entities can't fiddle with it) and create the name of
3792 the sub to call based on the value found in the hash (if it's there). I<All>
3793 of the commands to be handled in a set have to be added to C<%set>; if they
3794 aren't found, the 5.8.0 equivalent is called (if there is one).
3795
3796 This code uses symbolic references.
3797
3798 =cut
3799
3800 sub cmd_wrapper {
3801     my $cmd      = shift;
3802     my $line     = shift;
3803     my $dblineno = shift;
3804
3805     # Assemble the command subroutine's name by looking up the
3806     # command set and command name in %set. If we can't find it,
3807     # default to the older version of the command.
3808     my $call = 'cmd_'
3809       . ( $set{$CommandSet}{$cmd}
3810           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3811
3812     # Call the command subroutine, call it by name.
3813     return &$call( $cmd, $line, $dblineno );
3814 } ## end sub cmd_wrapper
3815
3816 =head3 C<cmd_a> (command)
3817
3818 The C<a> command handles pre-execution actions. These are associated with a
3819 particular line, so they're stored in C<%dbline>. We default to the current
3820 line if none is specified.
3821
3822 =cut
3823
3824 sub cmd_a {
3825     my $cmd    = shift;
3826     my $line   = shift || '';    # [.|line] expr
3827     my $dbline = shift;
3828
3829     # If it's dot (here), or not all digits,  use the current line.
3830     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3831
3832     # Should be a line number followed by an expression.
3833     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3834         my ( $lineno, $expr ) = ( $1, $2 );
3835
3836         # If we have an expression ...
3837         if ( length $expr ) {
3838
3839             # ... but the line isn't breakable, complain.
3840             if ( $dbline[$lineno] == 0 ) {
3841                 print $OUT
3842                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3843             }
3844             else {
3845
3846                 # It's executable. Record that the line has an action.
3847                 $had_breakpoints{$filename} |= 2;
3848
3849                 # Remove any action, temp breakpoint, etc.
3850                 $dbline{$lineno} =~ s/\0[^\0]*//;
3851
3852                 # Add the action to the line.
3853                 $dbline{$lineno} .= "\0" . action($expr);
3854             }
3855         } ## end if (length $expr)
3856     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3857     else {
3858
3859         # Syntax wrong.
3860         print $OUT
3861           "Adding an action requires an optional lineno and an expression\n"
3862           ;    # hint
3863     }
3864 } ## end sub cmd_a
3865
3866 =head3 C<cmd_A> (command)
3867
3868 Delete actions. Similar to above, except the delete code is in a separate
3869 subroutine, C<delete_action>.
3870
3871 =cut
3872
3873 sub cmd_A {
3874     my $cmd    = shift;
3875     my $line   = shift || '';
3876     my $dbline = shift;
3877
3878     # Dot is this line.
3879     $line =~ s/^\./$dbline/;
3880
3881     # Call delete_action with a null param to delete them all.
3882     # The '1' forces the eval to be true. It'll be false only
3883     # if delete_action blows up for some reason, in which case
3884     # we print $@ and get out.
3885     if ( $line eq '*' ) {
3886         eval { &delete_action(); 1 } or print $OUT $@ and return;
3887     }
3888
3889     # There's a real line  number. Pass it to delete_action.
3890     # Error trapping is as above.
3891     elsif ( $line =~ /^(\S.*)/ ) {
3892         eval { &delete_action($1); 1 } or print $OUT $@ and return;
3893     }
3894
3895     # Swing and a miss. Bad syntax.
3896     else {
3897         print $OUT
3898           "Deleting an action requires a line number, or '*' for all\n" ; # hint
3899     }
3900 } ## end sub cmd_A
3901
3902 =head3 C<delete_action> (API)
3903
3904 C<delete_action> accepts either a line number or C<undef>. If a line number
3905 is specified, we check for the line being executable (if it's not, it
3906 couldn't have had an  action). If it is, we just take the action off (this
3907 will get any kind of an action, including breakpoints).
3908
3909 =cut
3910
3911 sub delete_action {
3912     my $i = shift;
3913     if ( defined($i) ) {
3914
3915         # Can there be one?
3916         die "Line $i has no action .\n" if $dbline[$i] == 0;
3917
3918         # Nuke whatever's there.
3919         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
3920         delete $dbline{$i} if $dbline{$i} eq '';
3921     }
3922     else {
3923         print $OUT "Deleting all actions...\n";
3924         for my $file ( keys %had_breakpoints ) {
3925             local *dbline = $main::{ '_<' . $file };
3926             my $max = $#dbline;
3927             my $was;
3928             for ( $i = 1 ; $i <= $max ; $i++ ) {
3929                 if ( defined $dbline{$i} ) {
3930                     $dbline{$i} =~ s/\0[^\0]*//;
3931                     delete $dbline{$i} if $dbline{$i} eq '';
3932                 }
3933                 unless ( $had_breakpoints{$file} &= ~2 ) {
3934                     delete $had_breakpoints{$file};
3935                 }
3936             } ## end for ($i = 1 ; $i <= $max...
3937         } ## end for my $file (keys %had_breakpoints)
3938     } ## end else [ if (defined($i))
3939 } ## end sub delete_action
3940
3941 =head3 C<cmd_b> (command)
3942
3943 Set breakpoints. Since breakpoints can be set in so many places, in so many
3944 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
3945 we try to parse the command type, and then shuttle it off to an appropriate
3946 subroutine to actually do the work of setting the breakpoint in the right
3947 place.
3948
3949 =cut
3950
3951 sub cmd_b {
3952     my $cmd    = shift;
3953     my $line   = shift;    # [.|line] [cond]
3954     my $dbline = shift;
3955
3956     # Make . the current line number if it's there..
3957     $line =~ s/^\.(\s|\z)/$dbline$1/;
3958
3959     # No line number, no condition. Simple break on current line.
3960     if ( $line =~ /^\s*$/ ) {
3961         &cmd_b_line( $dbline, 1 );
3962     }
3963
3964     # Break on load for a file.
3965     elsif ( $line =~ /^load\b\s*(.*)/ ) {
3966         my $file = $1;
3967         $file =~ s/\s+$//;
3968         &cmd_b_load($file);
3969     }
3970
3971     # b compile|postpone <some sub> [<condition>]
3972     # The interpreter actually traps this one for us; we just put the
3973     # necessary condition in the %postponed hash.
3974     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
3975
3976         # Capture the condition if there is one. Make it true if none.
3977         my $cond = length $3 ? $3 : '1';
3978
3979         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
3980         # if it was 'compile'.
3981         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
3982
3983         # De-Perl4-ify the name - ' separators to ::.
3984         $subname =~ s/\'/::/g;
3985
3986         # Qualify it into the current package unless it's already qualified.
3987         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
3988
3989         # Add main if it starts with ::.
3990         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
3991
3992         # Save the break type for this sub.
3993         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
3994     } ## end elsif ($line =~ ...
3995     # b <filename>:<line> [<condition>]
3996     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
3997         my ($filename, $line_num, $cond) = ($1, $2, $3);
3998         cmd_b_filename_line(
3999             $filename,
4000             $line_num,
4001             (length($cond) ? $cond : '1'),
4002         );
4003     }
4004     # b <sub name> [<condition>]
4005     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4006
4007         #
4008         $subname = $1;
4009         $cond = length $2 ? $2 : '1';
4010         &cmd_b_sub( $subname, $cond );
4011     }
4012
4013     # b <line> [<condition>].
4014     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4015
4016         # Capture the line. If none, it's the current line.
4017         $line = $1 || $dbline;
4018
4019         # If there's no condition, make it '1'.
4020         $cond = length $2 ? $2 : '1';
4021
4022         # Break on line.
4023         &cmd_b_line( $line, $cond );
4024     }
4025
4026     # Line didn't make sense.
4027     else {
4028         print "confused by line($line)?\n";
4029     }
4030 } ## end sub cmd_b
4031
4032 =head3 C<break_on_load> (API)
4033
4034 We want to break when this file is loaded. Mark this file in the
4035 C<%break_on_load> hash, and note that it has a breakpoint in
4036 C<%had_breakpoints>.
4037
4038 =cut
4039
4040 sub break_on_load {
4041     my $file = shift;
4042     $break_on_load{$file} = 1;
4043     $had_breakpoints{$file} |= 1;
4044 }
4045
4046 =head3 C<report_break_on_load> (API)
4047
4048 Gives us an array of filenames that are set to break on load. Note that
4049 only files with break-on-load are in here, so simply showing the keys
4050 suffices.
4051
4052 =cut
4053
4054 sub report_break_on_load {
4055     sort keys %break_on_load;
4056 }
4057
4058 =head3 C<cmd_b_load> (command)
4059
4060 We take the file passed in and try to find it in C<%INC> (which maps modules
4061 to files they came from). We mark those files for break-on-load via
4062 C<break_on_load> and then report that it was done.
4063
4064 =cut
4065
4066 sub cmd_b_load {
4067     my $file = shift;
4068     my @files;
4069
4070     # This is a block because that way we can use a redo inside it
4071     # even without there being any looping structure at all outside it.
4072     {
4073
4074         # Save short name and full path if found.
4075         push @files, $file;
4076         push @files, $::INC{$file} if $::INC{$file};
4077
4078         # Tack on .pm and do it again unless there was a '.' in the name
4079         # already.
4080         $file .= '.pm', redo unless $file =~ /\./;
4081     }
4082
4083     # Do the real work here.
4084     break_on_load($_) for @files;
4085
4086     # All the files that have break-on-load breakpoints.
4087     @files = report_break_on_load;
4088
4089     # Normalize for the purposes of our printing this.
4090     local $\ = '';
4091     local $" = ' ';
4092     print $OUT "Will stop on load of '@files'.\n";
4093 } ## end sub cmd_b_load
4094
4095 =head3 C<$filename_error> (API package global)
4096
4097 Several of the functions we need to implement in the API need to work both
4098 on the current file and on other files. We don't want to duplicate code, so
4099 C<$filename_error> is used to contain the name of the file that's being
4100 worked on (if it's not the current one).
4101
4102 We can now build functions in pairs: the basic function works on the current
4103 file, and uses C<$filename_error> as part of its error message. Since this is
4104 initialized to C<"">, no filename will appear when we are working on the
4105 current file.
4106
4107 The second function is a wrapper which does the following:
4108
4109 =over 4
4110
4111 =item *
4112
4113 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4114
4115 =item *
4116
4117 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4118
4119 =item *
4120
4121 Calls the first function.
4122
4123 The first function works on the I<current> file (i.e., the one we changed to),
4124 and prints C<$filename_error> in the error message (the name of the other file)
4125 if it needs to. When the functions return, C<*dbline> is restored to point
4126 to the actual current file (the one we're executing in) and
4127 C<$filename_error> is restored to C<"">. This restores everything to
4128 the way it was before the second function was called at all.
4129
4130 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4131 details.
4132
4133 =back
4134
4135 =cut
4136
4137 $filename_error = '';
4138
4139 =head3 breakable_line(from, to) (API)
4140
4141 The subroutine decides whether or not a line in the current file is breakable.
4142 It walks through C<@dbline> within the range of lines specified, looking for
4143 the first line that is breakable.
4144
4145 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4146 first line I<after> C<$to> that's breakable, if there is one.
4147
4148 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4149 first line I<before> C<$to> that's breakable, if there is one.
4150
4151 =cut
4152
4153 sub breakable_line {
4154
4155     my ( $from, $to ) = @_;
4156
4157     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4158     my $i = $from;
4159
4160     # If there are at least 2 arguments, we're trying to search a range.
4161     if ( @_ >= 2 ) {
4162
4163         # $delta is positive for a forward search, negative for a backward one.
4164         my $delta = $from < $to ? +1 : -1;
4165
4166         # Keep us from running off the ends of the file.
4167         my $limit = $delta > 0 ? $#dbline : 1;
4168
4169         # Clever test. If you're a mathematician, it's obvious why this
4170         # test works. If not:
4171         # If $delta is positive (going forward), $limit will be $#dbline.
4172         #    If $to is less than $limit, ($limit - $to) will be positive, times
4173         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4174         #    as the stopping point.
4175         #
4176         #    If $to is greater than $limit, ($limit - $to) is negative,
4177         #    times $delta of 1 (positive), so the result is < 0 and we should
4178         #    use $limit ($#dbline) as the stopping point.
4179         #
4180         # If $delta is negative (going backward), $limit will be 1.
4181         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4182         #    (negative) so the result is > 0, and we use $to as the stopping
4183         #    point.
4184         #
4185         #    If $to is less than zero, ($limit - $to) will be positive,
4186         #    times $delta of -1 (negative), so the result is not > 0, and
4187         #    we use $limit (1) as the stopping point.
4188         #
4189         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4190         #    (negative), still giving zero; the result is not > 0, and
4191         #    we use $limit (1) as the stopping point.
4192         #
4193         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4194         #    (negative), giving a positive (>0) value, so we'll set $limit to
4195         #    $to.
4196
4197         $limit = $to if ( $limit - $to ) * $delta > 0;
4198
4199         # The real search loop.
4200         # $i starts at $from (the point we want to start searching from).
4201         # We move through @dbline in the appropriate direction (determined
4202         # by $delta: either -1 (back) or +1 (ahead).
4203         # We stay in as long as we haven't hit an executable line
4204         # ($dbline[$i] == 0 means not executable) and we haven't reached
4205         # the limit yet (test similar to the above).
4206         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4207
4208     } ## end if (@_ >= 2)
4209
4210     # If $i points to a line that is executable, return that.
4211     return $i unless $dbline[$i] == 0;
4212
4213     # Format the message and print it: no breakable lines in range.
4214     my ( $pl, $upto ) = ( '', '' );
4215     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4216
4217     # If there's a filename in filename_error, we'll see it.
4218     # If not, not.
4219     die "Line$pl $from$upto$filename_error not breakable\n";
4220 } ## end sub breakable_line
4221
4222 =head3 breakable_line_in_filename(file, from, to) (API)
4223
4224 Like C<breakable_line>, but look in another file.
4225
4226 =cut
4227
4228 sub breakable_line_in_filename {
4229
4230     # Capture the file name.
4231     my ($f) = shift;
4232
4233     # Swap the magic line array over there temporarily.
4234     local *dbline = $main::{ '_<' . $f };
4235
4236     # If there's an error, it's in this other file.
4237     local $filename_error = " of '$f'";
4238
4239     # Find the breakable line.
4240     breakable_line(@_);
4241
4242     # *dbline and $filename_error get restored when this block ends.
4243
4244 } ## end sub breakable_line_in_filename
4245
4246 =head3 break_on_line(lineno, [condition]) (API)
4247
4248 Adds a breakpoint with the specified condition (or 1 if no condition was
4249 specified) to the specified line. Dies if it can't.
4250
4251 =cut
4252
4253 sub break_on_line {
4254     my ( $i, $cond ) = @_;
4255
4256     # Always true if no condition supplied.
4257     $cond = 1 unless @_ >= 2;
4258
4259     my $inii  = $i;
4260     my $after = '';
4261     my $pl    = '';
4262
4263     # Woops, not a breakable line. $filename_error allows us to say
4264     # if it was in a different file.
4265     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4266
4267     # Mark this file as having breakpoints in it.
4268     $had_breakpoints{$filename} |= 1;
4269
4270     # If there is an action or condition here already ...
4271     if ( $dbline{$i} ) {
4272
4273         # ... swap this condition for the existing one.
4274         $dbline{$i} =~ s/^[^\0]*/$cond/;
4275     }
4276     else {
4277
4278         # Nothing here - just add the condition.
4279         $dbline{$i} = $cond;
4280
4281         _set_breakpoint_enabled_status($filename, $i, 1);
4282     }
4283 } ## end sub break_on_line
4284
4285 =head3 cmd_b_line(line, [condition]) (command)
4286
4287 Wrapper for C<break_on_line>. Prints the failure message if it
4288 doesn't work.
4289
4290 =cut
4291
4292 sub cmd_b_line {
4293     eval { break_on_line(@_); 1 } or do {
4294         local $\ = '';
4295         print $OUT $@ and return;
4296     };
4297 } ## end sub cmd_b_line
4298
4299 =head3 cmd_b_filename_line(line, [condition]) (command)
4300
4301 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4302 doesn't work.
4303
4304 =cut
4305
4306 sub cmd_b_filename_line {
4307     eval { break_on_filename_line(@_); 1 } or do {
4308         local $\ = '';
4309         print $OUT $@ and return;
4310     };
4311 }
4312
4313 =head3 break_on_filename_line(file, line, [condition]) (API)
4314
4315 Switches to the file specified and then calls C<break_on_line> to set
4316 the breakpoint.
4317
4318 =cut
4319
4320 sub break_on_filename_line {
4321     my ( $f, $i, $cond ) = @_;
4322
4323     # Always true if condition left off.
4324     $cond = 1 unless @_ >= 3;
4325
4326     # Switch the magical hash temporarily.
4327     local *dbline = $main::{ '_<' . $f };
4328
4329     # Localize the variables that break_on_line uses to make its message.
4330     local $filename_error = " of '$f'";
4331     local $filename       = $f;
4332
4333     # Add the breakpoint.
4334     break_on_line( $i, $cond );
4335 } ## end sub break_on_filename_line
4336
4337 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4338
4339 Switch to another file, search the range of lines specified for an
4340 executable one, and put a breakpoint on the first one you find.
4341
4342 =cut
4343
4344 sub break_on_filename_line_range {
4345     my ( $f, $from, $to, $cond ) = @_;
4346
4347     # Find a breakable line if there is one.
4348     my $i = breakable_line_in_filename( $f, $from, $to );
4349
4350     # Always true if missing.
4351     $cond = 1 unless @_ >= 3;
4352
4353     # Add the breakpoint.
4354     break_on_filename_line( $f, $i, $cond );
4355 } ## end sub break_on_filename_line_range
4356
4357 =head3 subroutine_filename_lines(subname, [condition]) (API)
4358
4359 Search for a subroutine within a given file. The condition is ignored.
4360 Uses C<find_sub> to locate the desired subroutine.
4361
4362 =cut
4363
4364 sub subroutine_filename_lines {
4365     my ( $subname, $cond ) = @_;
4366
4367     # Returned value from find_sub() is fullpathname:startline-endline.
4368     # The match creates the list (fullpathname, start, end). Falling off
4369     # the end of the subroutine returns this implicitly.
4370     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4371 } ## end sub subroutine_filename_lines
4372
4373 =head3 break_subroutine(subname) (API)
4374
4375 Places a break on the first line possible in the specified subroutine. Uses
4376 C<subroutine_filename_lines> to find the subroutine, and
4377 C<break_on_filename_line_range> to place the break.
4378
4379 =cut
4380
4381 sub break_subroutine {
4382     my $subname = shift;
4383
4384     # Get filename, start, and end.
4385     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4386       or die "Subroutine $subname not found.\n";
4387
4388     # Null condition changes to '1' (always true).
4389     $cond = 1 unless @_ >= 2;
4390
4391     # Put a break the first place possible in the range of lines
4392     # that make up this subroutine.
4393     break_on_filename_line_range( $file, $s, $e, @_ );
4394 } ## end sub break_subroutine
4395
4396 =head3 cmd_b_sub(subname, [condition]) (command)
4397
4398 We take the incoming subroutine name and fully-qualify it as best we can.
4399
4400 =over 4
4401
4402 =item 1. If it's already fully-qualified, leave it alone.
4403
4404 =item 2. Try putting it in the current package.
4405
4406 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4407
4408 =item 4. If it starts with '::', put it in 'main::'.
4409
4410 =back
4411
4412 After all this cleanup, we call C<break_subroutine> to try to set the
4413 breakpoint.
4414
4415 =cut
4416
4417 sub cmd_b_sub {
4418     my ( $subname, $cond ) = @_;
4419
4420     # Add always-true condition if we have none.
4421     $cond = 1 unless @_ >= 2;
4422
4423     # If the subname isn't a code reference, qualify it so that
4424     # break_subroutine() will work right.
4425     unless ( ref $subname eq 'CODE' ) {
4426
4427         # Not Perl4.
4428         $subname =~ s/\'/::/g;
4429         my $s = $subname;
4430
4431         # Put it in this package unless it's already qualified.
4432         $subname = "${'package'}::" . $subname
4433           unless $subname =~ /::/;
4434
4435         # Requalify it into CORE::GLOBAL if qualifying it into this
4436         # package resulted in its not being defined, but only do so
4437         # if it really is in CORE::GLOBAL.
4438         $subname = "CORE::GLOBAL::$s"
4439           if not defined &$subname
4440           and $s !~ /::/
4441           and defined &{"CORE::GLOBAL::$s"};
4442
4443         # Put it in package 'main' if it has a leading ::.
4444         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4445
4446     } ## end unless (ref $subname eq 'CODE')
4447
4448     # Try to set the breakpoint.
4449     eval { break_subroutine( $subname, $cond ); 1 } or do {
4450         local $\ = '';
4451         print $OUT $@ and return;
4452       }
4453 } ## end sub cmd_b_sub
4454
4455 =head3 C<cmd_B> - delete breakpoint(s) (command)
4456
4457 The command mostly parses the command line and tries to turn the argument
4458 into a line spec. If it can't, it uses the current line. It then calls
4459 C<delete_breakpoint> to actually do the work.
4460
4461 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4462 thereby deleting all the breakpoints.
4463
4464 =cut
4465
4466 sub cmd_B {
4467     my $cmd = shift;
4468
4469     # No line spec? Use dbline.
4470     # If there is one, use it if it's non-zero, or wipe it out if it is.
4471     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4472     my $dbline = shift;
4473
4474     # If the line was dot, make the line the current one.
4475     $line =~ s/^\./$dbline/;
4476
4477     # If it's * we're deleting all the breakpoints.
4478     if ( $line eq '*' ) {
4479         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4480     }
4481
4482     # If there is a line spec, delete the breakpoint on that line.
4483     elsif ( $line =~ /^(\S.*)/ ) {
4484         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4485             local $\ = '';
4486             print $OUT $@ and return;
4487         };
4488     } ## end elsif ($line =~ /^(\S.*)/)
4489
4490     # No line spec.
4491     else {
4492         print $OUT
4493           "Deleting a breakpoint requires a line number, or '*' for all\n"
4494           ;    # hint
4495     }
4496 } ## end sub cmd_B
4497
4498 =head3 delete_breakpoint([line]) (API)
4499
4500 This actually does the work of deleting either a single breakpoint, or all
4501 of them.
4502
4503 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4504 just drop out with a message saying so. If it is, we remove the condition
4505 part of the 'condition\0action' that says there's a breakpoint here. If,
4506 after we've done that, there's nothing left, we delete the corresponding
4507 line in C<%dbline> to signal that no action needs to be taken for this line.
4508
4509 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4510 which lists all currently-loaded files which have breakpoints. We then look
4511 at each line in each of these files, temporarily switching the C<%dbline>
4512 and C<@dbline> structures to point to the files in question, and do what
4513 we did in the single line case: delete the condition in C<@dbline>, and
4514 delete the key in C<%dbline> if nothing's left.
4515
4516 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4517 C<%break_on_load>, because these structures contain breakpoints for files
4518 and code that haven't been loaded yet. We can just kill these off because there
4519 are no magical debugger structures associated with them.
4520
4521 =cut
4522
4523 sub delete_breakpoint {
4524     my $i = shift;
4525
4526     my $fn = $filename;
4527
4528     # If we got a line, delete just that one.
4529     if ( defined($i) ) {
4530
4531         # Woops. This line wasn't breakable at all.
4532         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4533
4534         # Kill the condition, but leave any action.
4535         $dbline{$i} =~ s/^[^\0]*//;
4536
4537         # Remove the entry entirely if there's no action left.
4538         if ($dbline{$i} eq '') {
4539             delete $dbline{$i};
4540             _delete_breakpoint_data_ref($fn, $i);
4541         }
4542     }
4543
4544     # No line; delete them all.
4545     else {
4546         print $OUT "Deleting all breakpoints...\n";
4547
4548         # %had_breakpoints lists every file that had at least one
4549         # breakpoint in it.
4550         for my $file ( keys %had_breakpoints ) {
4551
4552             # Switch to the desired file temporarily.
4553             local *dbline = $main::{ '_<' . $file };
4554
4555             my $max = $#dbline;
4556             my $was;
4557
4558             # For all lines in this file ...
4559             for ( $i = 1 ; $i <= $max ; $i++ ) {
4560
4561                 # If there's a breakpoint or action on this line ...
4562                 if ( defined $dbline{$i} ) {
4563
4564                     # ... remove the breakpoint.
4565                     $dbline{$i} =~ s/^[^\0]+//;
4566                     if ( $dbline{$i} =~ s/^\0?$// ) {
4567
4568                         # Remove the entry altogether if no action is there.
4569                         delete $dbline{$i};
4570                         _delete_breakpoint_data_ref($file, $i);
4571                     }
4572                 } ## end if (defined $dbline{$i...
4573             } ## end for ($i = 1 ; $i <= $max...
4574
4575             # If, after we turn off the "there were breakpoints in this file"
4576             # bit, the entry in %had_breakpoints for this file is zero,
4577             # we should remove this file from the hash.
4578             if ( not $had_breakpoints{$file} &= ~1 ) {
4579                 delete $had_breakpoints{$file};
4580             }
4581         } ## end for my $file (keys %had_breakpoints)
4582
4583         # Kill off all the other breakpoints that are waiting for files that
4584         # haven't been loaded yet.
4585         undef %postponed;
4586         undef %postponed_file;
4587         undef %break_on_load;
4588     } ## end else [ if (defined($i))
4589 } ## end sub delete_breakpoint
4590
4591 =head3 cmd_stop (command)
4592
4593 This is meant to be part of the new command API, but it isn't called or used
4594 anywhere else in the debugger. XXX It is probably meant for use in development
4595 of new commands.
4596
4597 =cut
4598
4599 sub cmd_stop {    # As on ^C, but not signal-safy.
4600     $signal = 1;
4601 }
4602
4603 =head3 C<cmd_e> - threads
4604
4605 Display the current thread id:
4606
4607         e
4608
4609 This could be how (when implemented) to send commands to this thread id (e cmd)
4610 or that thread id (e tid cmd).
4611
4612 =cut
4613
4614 sub cmd_e {
4615     my $cmd  = shift;
4616     my $line = shift;
4617         unless (exists($INC{'threads.pm'})) {
4618                 print "threads not loaded($ENV{PERL5DB_THREADED})
4619                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4620         } else {
4621                 my $tid = threads->tid;
4622                 print "thread id: $tid\n";
4623         }
4624 } ## end sub cmd_e
4625
4626 =head3 C<cmd_E> - list of thread ids
4627
4628 Display the list of available thread ids:
4629
4630         E
4631
4632 This could be used (when implemented) to send commands to all threads (E cmd).
4633
4634 =cut
4635
4636 sub cmd_E {
4637     my $cmd  = shift;
4638     my $line = shift;
4639         unless (exists($INC{'threads.pm'})) {
4640                 print "threads not loaded($ENV{PERL5DB_THREADED})
4641                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4642         } else {
4643                 my $tid = threads->tid;
4644                 print "thread ids: ".join(', ',
4645                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4646                 )."\n";
4647         }
4648 } ## end sub cmd_E
4649
4650 =head3 C<cmd_h> - help command (command)
4651
4652 Does the work of either
4653
4654 =over 4
4655
4656 =item *
4657
4658 Showing all the debugger help
4659
4660 =item *
4661
4662 Showing help for a specific command
4663
4664 =back
4665
4666 =cut
4667
4668 sub cmd_h {
4669     my $cmd = shift;
4670
4671     # If we have no operand, assume null.
4672     my $line = shift || '';
4673
4674     # 'h h'. Print the long-format help.
4675     if ( $line =~ /^h\s*/ ) {
4676         print_help($help);
4677     }
4678
4679     # 'h <something>'. Search for the command and print only its help.
4680     elsif ( $line =~ /^(\S.*)$/ ) {
4681
4682         # support long commands; otherwise bogus errors
4683         # happen when you ask for h on <CR> for example
4684         my $asked = $1;    # the command requested
4685                            # (for proper error message)
4686
4687         my $qasked = quotemeta($asked);    # for searching; we don't
4688                                            # want to use it as a pattern.
4689                                            # XXX: finds CR but not <CR>
4690
4691         # Search the help string for the command.
4692         if (
4693             $help =~ /^                    # Start of a line
4694                       <?                   # Optional '<'
4695                       (?:[IB]<)            # Optional markup
4696                       $qasked              # The requested command
4697                      /mx
4698           )
4699         {
4700
4701             # It's there; pull it out and print it.
4702             while (
4703                 $help =~ /^
4704                               (<?            # Optional '<'
4705                                  (?:[IB]<)   # Optional markup
4706                                  $qasked     # The command
4707                                  ([\s\S]*?)  # Description line(s)
4708                               \n)            # End of last description line
4709                               (?!\s)         # Next line not starting with
4710                                              # whitespace
4711                              /mgx
4712               )
4713             {
4714                 print_help($1);
4715             }
4716         }
4717
4718         # Not found; not a debugger command.
4719         else {
4720             print_help("B<$asked> is not a debugger command.\n");
4721         }
4722     } ## end elsif ($line =~ /^(\S.*)$/)
4723
4724     # 'h' - print the summary help.
4725     else {
4726         print_help($summary);
4727     }
4728 } ## end sub cmd_h
4729
4730 =head3 C<cmd_i> - inheritance display
4731
4732 Display the (nested) parentage of the module or object given.
4733
4734 =cut
4735
4736 sub cmd_i {
4737     my $cmd  = shift;
4738     my $line = shift;
4739     foreach my $isa ( split( /\s+/, $line ) ) {
4740         $evalarg = $isa;
4741         ($isa) = &eval;
4742         no strict 'refs';
4743         print join(
4744             ', ',
4745             map {
4746                 "$_"
4747                   . (
4748                     defined( ${"$_\::VERSION"} )
4749                     ? ' ' . ${"$_\::VERSION"}
4750                     : undef )
4751               } @{mro::get_linear_isa(ref($isa) || $isa)}
4752         );
4753         print "\n";
4754     }
4755 } ## end sub cmd_i
4756
4757 =head3 C<cmd_l> - list lines (command)
4758
4759 Most of the command is taken up with transforming all the different line
4760 specification syntaxes into 'start-stop'. After that is done, the command
4761 runs a loop over C<@dbline> for the specified range of lines. It handles
4762 the printing of each line and any markers (C<==E<gt>> for current line,
4763 C<b> for break on this line, C<a> for action on this line, C<:> for this
4764 line breakable).
4765
4766 We save the last line listed in the C<$start> global for further listing
4767 later.
4768
4769 =cut
4770
4771 sub cmd_l {
4772     my $current_line = $line;
4773     my $cmd  = shift;
4774     my $line = shift;
4775
4776     # If this is '-something', delete any spaces after the dash.
4777     $line =~ s/^-\s*$/-/;
4778
4779     # If the line is '$something', assume this is a scalar containing a
4780     # line number.
4781     if ( $line =~ /^(\$.*)/s ) {
4782
4783         # Set up for DB::eval() - evaluate in *user* context.
4784         $evalarg = $1;
4785         # $evalarg = $2;
4786         my ($s) = &eval;
4787
4788         # Ooops. Bad scalar.
4789         print( $OUT "Error: $@\n" ), next CMD if $@;
4790
4791         # Good scalar. If it's a reference, find what it points to.
4792         $s = CvGV_name($s);
4793         print( $OUT "Interpreted as: $1 $s\n" );
4794         $line = "$1 $s";
4795
4796         # Call self recursively to really do the command.
4797         &cmd_l( 'l', $s );
4798     } ## end if ($line =~ /^(\$.*)/s)
4799
4800     # l name. Try to find a sub by that name.
4801     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
4802         my $s = $subname = $1;
4803
4804         # De-Perl4.
4805         $subname =~ s/\'/::/;
4806
4807         # Put it in this package unless it starts with ::.
4808         $subname = $package . "::" . $subname unless $subname =~ /::/;
4809
4810         # Put it in CORE::GLOBAL if t doesn't start with :: and
4811         # it doesn't live in this package and it lives in CORE::GLOBAL.
4812         $subname = "CORE::GLOBAL::$s"
4813           if not defined &$subname
4814           and $s !~ /::/
4815           and defined &{"CORE::GLOBAL::$s"};
4816
4817         # Put leading '::' names into 'main::'.
4818         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4819
4820         # Get name:start-stop from find_sub, and break this up at
4821         # colons.
4822         @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
4823
4824         # Pull off start-stop.
4825         $subrange = pop @pieces;
4826
4827         # If the name contained colons, the split broke it up.
4828         # Put it back together.
4829         $file = join( ':', @pieces );
4830
4831         # If we're not in that file, switch over to it.
4832         if ( $file ne $filename ) {
4833             print $OUT "Switching to file '$file'.\n"
4834               unless $slave_editor;
4835
4836             # Switch debugger's magic structures.
4837             *dbline   = $main::{ '_<' . $file };
4838             $max      = $#dbline;
4839             $filename = $file;
4840         } ## end if ($file ne $filename)
4841
4842         # Subrange is 'start-stop'. If this is less than a window full,
4843         # swap it to 'start+', which will list a window from the start point.
4844         if ($subrange) {
4845             if ( eval($subrange) < -$window ) {
4846                 $subrange =~ s/-.*/+/;
4847             }
4848
4849             # Call self recursively to list the range.
4850             $line = $subrange;
4851             &cmd_l( 'l', $subrange );
4852         } ## end if ($subrange)
4853
4854         # Couldn't find it.
4855         else {
4856             print $OUT "Subroutine $subname not found.\n";
4857         }
4858     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
4859
4860     # Bare 'l' command.
4861     elsif ( $line =~ /^\s*$/ ) {
4862
4863         # Compute new range to list.
4864         $incr = $window - 1;
4865         $line = $start . '-' . ( $start + $incr );
4866
4867         # Recurse to do it.
4868         &cmd_l( 'l', $line );
4869     }
4870
4871     # l [start]+number_of_lines
4872     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
4873
4874         # Don't reset start for 'l +nnn'.
4875         $start = $1 if $1;
4876
4877         # Increment for list. Use window size if not specified.
4878         # (Allows 'l +' to work.)
4879         $incr = $2;
4880         $incr = $window - 1 unless $incr;
4881
4882         # Create a line range we'll understand, and recurse to do it.
4883         $line = $start . '-' . ( $start + $incr );
4884         &cmd_l( 'l', $line );
4885     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
4886
4887     # l start-stop or l start,stop
4888     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
4889
4890         # Determine end point; use end of file if not specified.
4891         $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
4892
4893         # Go on to the end, and then stop.
4894         $end = $max if $end > $max;
4895
4896         # Determine start line.
4897         $i    = $2;
4898         $i    = $line if $i eq '.';
4899         $i    = 1 if $i < 1;
4900         $incr = $end - $i;
4901
4902         # If we're running under a slave editor, force it to show the lines.
4903         if ($slave_editor) {
4904             print $OUT "\032\032$filename:$i:0\n";
4905             $i = $end;
4906         }
4907
4908         # We're doing it ourselves. We want to show the line and special
4909         # markers for:
4910         # - the current line in execution
4911         # - whether a line is breakable or not
4912         # - whether a line has a break or not
4913         # - whether a line has an action or not
4914         else {
4915             for ( ; $i <= $end ; $i++ ) {
4916
4917                 # Check for breakpoints and actions.
4918                 my ( $stop, $action );
4919                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
4920                   if $dbline{$i};
4921
4922                 # ==> if this is the current line in execution,
4923                 # : if it's breakable.
4924                 $arrow =
4925                   ( $i == $current_line and $filename eq $filename_ini )
4926                   ? '==>'
4927                   : ( $dbline[$i] + 0 ? ':' : ' ' );
4928
4929                 # Add break and action indicators.
4930                 $arrow .= 'b' if $stop;
4931                 $arrow .= 'a' if $action;
4932
4933                 # Print the line.
4934                 print $OUT "$i$arrow\t", $dbline[$i];
4935
4936                 # Move on to the next line. Drop out on an interrupt.
4937                 $i++, last if $signal;
4938             } ## end for (; $i <= $end ; $i++)
4939
4940             # Line the prompt up; print a newline if the last line listed
4941             # didn't have a newline.
4942             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
4943         } ## end else [ if ($slave_editor)
4944
4945         # Save the point we last listed to in case another relative 'l'
4946         # command is desired. Don't let it run off the end.
4947         $start = $i;
4948         $start = $max if $start > $max;
4949     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
4950 } ## end sub cmd_l
4951
4952 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
4953
4954 To list breakpoints, the command has to look determine where all of them are
4955 first. It starts a C<%had_breakpoints>, which tells us what all files have
4956 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
4957 magic source and breakpoint data structures) to the file, and then look
4958 through C<%dbline> for lines with breakpoints and/or actions, listing them
4959 out. We look through C<%postponed> not-yet-compiled subroutines that have
4960 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
4961 that have breakpoints.
4962
4963 Watchpoints are simpler: we just list the entries in C<@to_watch>.
4964
4965 =cut
4966
4967 sub cmd_L {
4968     my $cmd = shift;
4969
4970     # If no argument, list everything. Pre-5.8.0 version always lists
4971     # everything
4972     my $arg = shift || 'abw';
4973     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
4974
4975     # See what is wanted.
4976     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
4977     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
4978     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
4979
4980     # Breaks and actions are found together, so we look in the same place
4981     # for both.
4982     if ( $break_wanted or $action_wanted ) {
4983
4984         # Look in all the files with breakpoints...
4985         for my $file ( keys %had_breakpoints ) {
4986
4987             # Temporary switch to this file.
4988             local *dbline = $main::{ '_<' . $file };
4989
4990             # Set up to look through the whole file.
4991             my $max = $#dbline;
4992             my $was;    # Flag: did we print something
4993                         # in this file?
4994
4995             # For each line in the file ...
4996             for ( $i = 1 ; $i <= $max ; $i++ ) {
4997
4998                 # We've got something on this line.
4999                 if ( defined $dbline{$i} ) {
5000
5001                     # Print the header if we haven't.
5002                     print $OUT "$file:\n" unless $was++;
5003
5004                     # Print the line.
5005                     print $OUT " $i:\t", $dbline[$i];
5006
5007                     # Pull out the condition and the action.
5008                     ( $stop, $action ) = split( /\0/, $dbline{$i} );
5009
5010                     # Print the break if there is one and it's wanted.
5011                     print $OUT "   break if (", $stop, ")\n"
5012                       if $stop
5013                       and $break_wanted;
5014
5015                     # Print the action if there is one and it's wanted.
5016                     print $OUT "   action:  ", $action, "\n"
5017                       if $action
5018                       and $action_wanted;
5019
5020                     # Quit if the user hit interrupt.
5021                     last if $signal;
5022                 } ## end if (defined $dbline{$i...
5023             } ## end for ($i = 1 ; $i <= $max...
5024         } ## end for my $file (keys %had_breakpoints)
5025     } ## end if ($break_wanted or $action_wanted)
5026
5027     # Look for breaks in not-yet-compiled subs:
5028     if ( %postponed and $break_wanted ) {
5029         print $OUT "Postponed breakpoints in subroutines:\n";
5030         my $subname;
5031         for $subname ( keys %postponed ) {
5032             print $OUT " $subname\t$postponed{$subname}\n";
5033             last if $signal;
5034         }
5035     } ## end if (%postponed and $break_wanted)
5036
5037     # Find files that have not-yet-loaded breaks:
5038     my @have = map {    # Combined keys
5039         keys %{ $postponed_file{$_} }
5040     } keys %postponed_file;
5041
5042     # If there are any, list them.
5043     if ( @have and ( $break_wanted or $action_wanted ) ) {
5044         print $OUT "Postponed breakpoints in files:\n";
5045         my ( $file, $line );
5046
5047         for $file ( keys %postponed_file ) {
5048             my $db = $postponed_file{$file};
5049             print $OUT " $file:\n";
5050             for $line ( sort { $a <=> $b } keys %$db ) {
5051                 print $OUT "  $line:\n";
5052                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5053                 print $OUT "    break if (", $stop, ")\n"
5054                   if $stop
5055                   and $break_wanted;
5056                 print $OUT "    action:  ", $action, "\n"
5057                   if $action
5058                   and $action_wanted;
5059                 last if $signal;
5060             } ## end for $line (sort { $a <=>...
5061             last if $signal;
5062         } ## end for $file (keys %postponed_file)
5063     } ## end if (@have and ($break_wanted...
5064     if ( %break_on_load and $break_wanted ) {
5065         print $OUT "Breakpoints on load:\n";
5066         my $file;
5067         for $file ( keys %break_on_load ) {
5068             print $OUT " $file\n";
5069             last if $signal;
5070         }
5071     } ## end if (%break_on_load and...
5072     if ($watch_wanted) {
5073         if ( $trace & 2 ) {
5074             print $OUT "Watch-expressions:\n" if @to_watch;
5075             for my $expr (@to_watch) {
5076                 print $OUT " $expr\n";
5077                 last if $signal;
5078             }
5079         } ## end if ($trace & 2)
5080     } ## end if ($watch_wanted)
5081 } ## end sub cmd_L
5082
5083 =head3 C<cmd_M> - list modules (command)
5084
5085 Just call C<list_modules>.
5086
5087 =cut
5088
5089 sub cmd_M {
5090     &list_modules();
5091 }
5092
5093 =head3 C<cmd_o> - options (command)
5094
5095 If this is just C<o> by itself, we list the current settings via
5096 C<dump_option>. If there's a nonblank value following it, we pass that on to
5097 C<parse_options> for processing.
5098
5099 =cut
5100
5101 sub cmd_o {
5102     my $cmd = shift;
5103     my $opt = shift || '';    # opt[=val]
5104
5105     # Nonblank. Try to parse and process.
5106     if ( $opt =~ /^(\S.*)/ ) {
5107         &parse_options($1);
5108     }
5109
5110     # Blank. List the current option settings.
5111     else {
5112         for (@options) {
5113             &dump_option($_);
5114         }
5115     }
5116 } ## end sub cmd_o
5117
5118 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5119
5120 Advises the user that the O command has been renamed.
5121
5122 =cut
5123
5124 sub cmd_O {
5125     print $OUT "The old O command is now the o command.\n";             # hint
5126     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5127     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5128 }
5129
5130 =head3 C<cmd_v> - view window (command)
5131
5132 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5133 move back a few lines to list the selected line in context. Uses C<cmd_l>
5134 to do the actual listing after figuring out the range of line to request.
5135
5136 =cut
5137
5138 sub cmd_v {
5139     my $cmd  = shift;
5140     my $line = shift;
5141
5142     # Extract the line to list around. (Astute readers will have noted that
5143     # this pattern will match whether or not a numeric line is specified,
5144     # which means that we'll always enter this loop (though a non-numeric
5145     # argument results in no action at all)).
5146     if ( $line =~ /^(\d*)$/ ) {
5147
5148         # Total number of lines to list (a windowful).
5149         $incr = $window - 1;
5150
5151         # Set the start to the argument given (if there was one).
5152         $start = $1 if $1;
5153
5154         # Back up by the context amount.
5155         $start -= $preview;
5156
5157         # Put together a linespec that cmd_l will like.
5158         $line = $start . '-' . ( $start + $incr );
5159
5160         # List the lines.
5161         &cmd_l( 'l', $line );
5162     } ## end if ($line =~ /^(\d*)$/)
5163 } ## end sub cmd_v
5164
5165 =head3 C<cmd_w> - add a watch expression (command)
5166
5167 The 5.8 version of this command adds a watch expression if one is specified;
5168 it does nothing if entered with no operands.
5169
5170 We extract the expression, save it, evaluate it in the user's context, and
5171 save the value. We'll re-evaluate it each time the debugger passes a line,
5172 and will stop (see the code at the top of the command loop) if the value
5173 of any of the expressions changes.
5174
5175 =cut
5176
5177 sub cmd_w {
5178     my $cmd = shift;
5179
5180     # Null expression if no arguments.
5181     my $expr = shift || '';
5182
5183     # If expression is not null ...
5184     if ( $expr =~ /^(\S.*)/ ) {
5185
5186         # ... save it.
5187         push @to_watch, $expr;
5188
5189         # Parameterize DB::eval and call it to get the expression's value
5190         # in the user's context. This version can handle expressions which
5191         # return a list value.
5192         $evalarg = $expr;
5193         my ($val) = join( ' ', &eval );
5194         $val = ( defined $val ) ? "'$val'" : 'undef';
5195
5196         # Save the current value of the expression.
5197         push @old_watch, $val;
5198
5199         # We are now watching expressions.
5200         $trace |= 2;
5201     } ## end if ($expr =~ /^(\S.*)/)
5202
5203     # You have to give one to get one.
5204     else {
5205         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5206     }
5207 } ## end sub cmd_w
5208
5209 =head3 C<cmd_W> - delete watch expressions (command)
5210
5211 This command accepts either a watch expression to be removed from the list
5212 of watch expressions, or C<*> to delete them all.
5213
5214 If C<*> is specified, we simply empty the watch expression list and the
5215 watch expression value list. We also turn off the bit that says we've got
5216 watch expressions.
5217
5218 If an expression (or partial expression) is specified, we pattern-match
5219 through the expressions and remove the ones that match. We also discard
5220 the corresponding values. If no watch expressions are left, we turn off
5221 the I<watching expressions> bit.
5222
5223 =cut
5224
5225 sub cmd_W {
5226     my $cmd  = shift;
5227     my $expr = shift || '';
5228
5229     # Delete them all.
5230     if ( $expr eq '*' ) {
5231
5232         # Not watching now.
5233         $trace &= ~2;
5234
5235         print $OUT "Deleting all watch expressions ...\n";
5236
5237         # And all gone.
5238         @to_watch = @old_watch = ();
5239     }
5240
5241     # Delete one of them.
5242     elsif ( $expr =~ /^(\S.*)/ ) {
5243
5244         # Where we are in the list.
5245         my $i_cnt = 0;
5246
5247         # For each expression ...
5248         foreach (@to_watch) {
5249             my $val = $to_watch[$i_cnt];
5250
5251             # Does this one match the command argument?
5252             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5253                                       # Yes. Turn it off, and its value too.
5254                 splice( @to_watch,  $i_cnt, 1 );
5255                 splice( @old_watch, $i_cnt, 1 );
5256             }
5257             $i_cnt++;
5258         } ## end foreach (@to_watch)
5259
5260         # We don't bother to turn watching off because
5261         #  a) we don't want to stop calling watchfunction() it it exists
5262         #  b) foreach over a null list doesn't do anything anyway
5263
5264     } ## end elsif ($expr =~ /^(\S.*)/)
5265
5266     # No command arguments entered.
5267     else {
5268         print $OUT
5269           "Deleting a watch-expression requires an expression, or '*' for all\n"
5270           ;    # hint
5271     }
5272 } ## end sub cmd_W
5273
5274 ### END of the API section
5275
5276 =head1 SUPPORT ROUTINES
5277
5278 These are general support routines that are used in a number of places
5279 throughout the debugger.
5280
5281 =head2 save
5282
5283 save() saves the user's versions of globals that would mess us up in C<@saved>,
5284 and installs the versions we like better.
5285
5286 =cut
5287
5288 sub save {
5289
5290     # Save eval failure, command failure, extended OS error, output field
5291     # separator, input record separator, output record separator and
5292     # the warning setting.
5293     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5294
5295     $,  = "";      # output field separator is null string
5296     $/  = "\n";    # input record separator is newline
5297     $\  = "";      # output record separator is null string
5298     $^W = 0;       # warnings are off
5299 } ## end sub save
5300
5301 =head2 C<print_lineinfo> - show where we are now
5302
5303 print_lineinfo prints whatever it is that it is handed; it prints it to the
5304 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5305 us to feed line information to a slave editor without messing up the
5306 debugger output.
5307
5308 =cut
5309
5310 sub print_lineinfo {
5311
5312     # Make the terminal sensible if we're not the primary debugger.
5313     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5314     local $\ = '';
5315     local $, = '';
5316     print $LINEINFO @_;
5317 } ## end sub print_lineinfo
5318
5319 =head2 C<postponed_sub>
5320
5321 Handles setting postponed breakpoints in subroutines once they're compiled.
5322 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5323 range for the subroutine, then mark the file as having a breakpoint,
5324 temporarily switch the C<*dbline> glob over to the source file, and then
5325 search the given range of lines to find a breakable line. If we find one,
5326 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5327
5328 =cut
5329
5330 # The following takes its argument via $evalarg to preserve current @_
5331
5332 sub postponed_sub {
5333
5334     # Get the subroutine name.
5335     my $subname = shift;
5336
5337     # If this is a 'break +<n> if <condition>' ...
5338     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5339
5340         # If there's no offset, use '+0'.
5341         my $offset = $1 || 0;
5342
5343         # find_sub's value is 'fullpath-filename:start-stop'. It's
5344         # possible that the filename might have colons in it too.
5345         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5346         if ($i) {
5347
5348             # We got the start line. Add the offset '+<n>' from
5349             # $postponed{subname}.
5350             $i += $offset;
5351
5352             # Switch to the file this sub is in, temporarily.
5353             local *dbline = $main::{ '_<' . $file };
5354
5355             # No warnings, please.
5356             local $^W = 0;    # != 0 is magical below
5357
5358             # This file's got a breakpoint in it.
5359             $had_breakpoints{$file} |= 1;
5360
5361             # Last line in file.
5362             my $max = $#dbline;
5363
5364             # Search forward until we hit a breakable line or get to
5365             # the end of the file.
5366             ++$i until $dbline[$i] != 0 or $i >= $max;
5367
5368             # Copy the breakpoint in and delete it from %postponed.
5369             $dbline{$i} = delete $postponed{$subname};
5370         } ## end if ($i)
5371
5372         # find_sub didn't find the sub.
5373         else {
5374             local $\ = '';
5375             print $OUT "Subroutine $subname not found.\n";
5376         }
5377         return;
5378     } ## end if ($postponed{$subname...
5379     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5380
5381     #print $OUT "In postponed_sub for '$subname'.\n";
5382 } ## end sub postponed_sub
5383
5384 =head2 C<postponed>
5385
5386 Called after each required file is compiled, but before it is executed;
5387 also called if the name of a just-compiled subroutine is a key of
5388 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5389 etc.) into the just-compiled code.
5390
5391 If this is a C<require>'d file, the incoming parameter is the glob
5392 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5393
5394 If it's a subroutine, the incoming parameter is the subroutine name.
5395
5396 =cut
5397
5398 sub postponed {
5399
5400     # If there's a break, process it.
5401     if ($ImmediateStop) {
5402
5403         # Right, we've stopped. Turn it off.
5404         $ImmediateStop = 0;
5405
5406         # Enter the command loop when DB::DB gets called.
5407         $signal = 1;
5408     }
5409
5410     # If this is a subroutine, let postponed_sub() deal with it.
5411     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5412
5413     # Not a subroutine. Deal with the file.
5414     local *dbline = shift;
5415     my $filename = $dbline;
5416     $filename =~ s/^_<//;
5417     local $\ = '';
5418     $signal = 1, print $OUT "'$filename' loaded...\n"
5419       if $break_on_load{$filename};
5420     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5421
5422     # Do we have any breakpoints to put in this file?
5423     return unless $postponed_file{$filename};
5424
5425     # Yes. Mark this file as having breakpoints.
5426     $had_breakpoints{$filename} |= 1;
5427
5428     # "Cannot be done: insufficient magic" - we can't just put the
5429     # breakpoints saved in %postponed_file into %dbline by assigning
5430     # the whole hash; we have to do it one item at a time for the
5431     # breakpoints to be set properly.
5432     #%dbline = %{$postponed_file{$filename}};
5433
5434     # Set the breakpoints, one at a time.
5435     my $key;
5436
5437     for $key ( keys %{ $postponed_file{$filename} } ) {
5438
5439         # Stash the saved breakpoint into the current file's magic line array.
5440         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5441     }
5442
5443     # This file's been compiled; discard the stored breakpoints.
5444     delete $postponed_file{$filename};
5445
5446 } ## end sub postponed
5447
5448 =head2 C<dumpit>
5449
5450 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5451
5452 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5453 a reference to a variable (the thing to be dumped) as its input.
5454
5455 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5456 the currently-selected filehandle, thank you very much). The current
5457 values of the package globals C<$single> and C<$trace> are backed up in
5458 lexicals, and they are turned off (this keeps the debugger from trying
5459 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5460 preserve its current value and it is set to zero to prevent entry/exit
5461 messages from printing, and C<$doret> is localized as well and set to -2 to
5462 prevent return values from being shown.
5463
5464 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5465 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5466 installed version in C<@INC>, yours will be used instead. Possible security
5467 problem?).
5468
5469 It then checks to see if the subroutine C<main::dumpValue> is now defined
5470 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5471 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5472 is called, and picks up the variable to be dumped from the parameter list.
5473
5474 It checks the package global C<%options> to see if there's a C<dumpDepth>
5475 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5476 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5477 structure: -1 means dump everything.
5478
5479 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5480 warning.
5481
5482 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5483 and we then return to the caller.
5484
5485 =cut
5486
5487 sub dumpit {
5488
5489     # Save the current output filehandle and switch to the one
5490     # passed in as the first parameter.
5491     local ($savout) = select(shift);
5492
5493     # Save current settings of $single and $trace, and then turn them off.
5494     my $osingle = $single;
5495     my $otrace  = $trace;
5496     $single = $trace = 0;
5497
5498     # XXX Okay, what do $frame and $doret do, again?
5499     local $frame = 0;
5500     local $doret = -2;
5501
5502     # Load dumpvar.pl unless we've already got the sub we need from it.
5503     unless ( defined &main::dumpValue ) {
5504         do 'dumpvar.pl' or die $@;
5505     }
5506
5507     # If the load succeeded (or we already had dumpvalue()), go ahead
5508     # and dump things.
5509     if ( defined &main::dumpValue ) {
5510         local $\ = '';
5511         local $, = '';
5512         local $" = ' ';
5513         my $v = shift;
5514         my $maxdepth = shift || $option{dumpDepth};
5515         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5516         &main::dumpValue( $v, $maxdepth );
5517     } ## end if (defined &main::dumpValue)
5518
5519     # Oops, couldn't load dumpvar.pl.
5520     else {
5521         local $\ = '';
5522         print $OUT "dumpvar.pl not available.\n";
5523     }
5524
5525     # Reset $single and $trace to their old values.
5526     $single = $osingle;
5527     $trace  = $otrace;
5528
5529     # Restore the old filehandle.
5530     select($savout);
5531 } ## end sub dumpit
5532
5533 =head2 C<print_trace>
5534
5535 C<print_trace>'s job is to print a stack trace. It does this via the
5536 C<dump_trace> routine, which actually does all the ferreting-out of the
5537 stack trace data. C<print_trace> takes care of formatting it nicely and
5538 printing it to the proper filehandle.
5539
5540 Parameters:
5541
5542 =over 4
5543
5544 =item *
5545
5546 The filehandle to print to.
5547
5548 =item *
5549
5550 How many frames to skip before starting trace.
5551
5552 =item *
5553
5554 How many frames to print.
5555
5556 =item *
5557
5558 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5559
5560 =back
5561
5562 The original comment below seems to be noting that the traceback may not be
5563 correct if this routine is called in a tied method.
5564
5565 =cut
5566
5567 # Tied method do not create a context, so may get wrong message:
5568
5569 sub print_trace {
5570     local $\ = '';
5571     my $fh = shift;
5572
5573     # If this is going to a slave editor, but we're not the primary
5574     # debugger, reset it first.
5575     resetterm(1)
5576       if $fh        eq $LINEINFO    # slave editor
5577       and $LINEINFO eq $OUT         # normal output
5578       and $term_pid != $$;          # not the primary
5579
5580     # Collect the actual trace information to be formatted.
5581     # This is an array of hashes of subroutine call info.
5582     my @sub = dump_trace( $_[0] + 1, $_[1] );
5583
5584     # Grab the "short report" flag from @_.
5585     my $short = $_[2];              # Print short report, next one for sub name
5586
5587     # Run through the traceback info, format it, and print it.
5588     my $s;
5589     for ( $i = 0 ; $i <= $#sub ; $i++ ) {
5590
5591         # Drop out if the user has lost interest and hit control-C.
5592         last if $signal;
5593
5594         # Set the separator so arrys print nice.
5595         local $" = ', ';
5596
5597         # Grab and stringify the arguments if they are there.
5598         my $args =
5599           defined $sub[$i]{args}
5600           ? "(@{ $sub[$i]{args} })"
5601           : '';
5602
5603         # Shorten them up if $maxtrace says they're too long.
5604         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5605           if length $args > $maxtrace;
5606
5607         # Get the file name.
5608         my $file = $sub[$i]{file};
5609
5610         # Put in a filename header if short is off.
5611         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
5612
5613         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5614         $s = $sub[$i]{sub};
5615         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5616
5617         # Short report uses trimmed file and sub names.
5618         if ($short) {
5619             my $sub = @_ >= 4 ? $_[3] : $s;
5620             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5621         } ## end if ($short)
5622
5623         # Non-short report includes full names.
5624         else {
5625             print $fh "$sub[$i]{context} = $s$args"
5626               . " called from $file"
5627               . " line $sub[$i]{line}\n";
5628         }
5629     } ## end for ($i = 0 ; $i <= $#sub...
5630 } ## end sub print_trace
5631
5632 =head2 dump_trace(skip[,count])
5633
5634 Actually collect the traceback information available via C<caller()>. It does
5635 some filtering and cleanup of the data, but mostly it just collects it to
5636 make C<print_trace()>'s job easier.
5637
5638 C<skip> defines the number of stack frames to be skipped, working backwards
5639 from the most current. C<count> determines the total number of frames to
5640 be returned; all of them (well, the first 10^9) are returned if C<count>
5641 is omitted.
5642
5643 This routine returns a list of hashes, from most-recent to least-recent
5644 stack frame. Each has the following keys and values:
5645
5646 =over 4
5647
5648 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5649
5650 =item * C<sub> - subroutine name, or C<eval> information
5651
5652 =item * C<args> - undef, or a reference to an array of arguments
5653
5654 =item * C<file> - the file in which this item was defined (if any)
5655
5656 =item * C<line> - the line on which it was defined
5657
5658 =back
5659
5660 =cut
5661
5662 sub dump_trace {
5663
5664     # How many levels to skip.
5665     my $skip = shift;
5666
5667     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5668     # it's unlikely that we'll have more than a billion stack frames. If you
5669     # do, you've got an awfully big machine...)
5670     my $count = shift || 1e9;
5671
5672     # We increment skip because caller(1) is the first level *back* from
5673     # the current one.  Add $skip to the count of frames so we have a
5674     # simple stop criterion, counting from $skip to $count+$skip.
5675     $skip++;
5676     $count += $skip;
5677
5678     # These variables are used to capture output from caller();
5679     my ( $p, $file, $line, $sub, $h, $context );
5680
5681     my ( $e, $r, @a, @sub, $args );
5682
5683     # XXX Okay... why'd we do that?
5684     my $nothard = not $frame & 8;
5685     local $frame = 0;
5686
5687     # Do not want to trace this.
5688     my $otrace = $trace;
5689     $trace = 0;
5690
5691     # Start out at the skip count.
5692     # If we haven't reached the number of frames requested, and caller() is
5693     # still returning something, stay in the loop. (If we pass the requested
5694     # number of stack frames, or we run out - caller() returns nothing - we
5695     # quit.
5696     # Up the stack frame index to go back one more level each time.
5697     for (
5698         $i = $skip ;
5699         $i < $count
5700         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5701         $i++
5702       )
5703     {
5704
5705         # Go through the arguments and save them for later.
5706         @a = ();
5707         for $arg (@args) {
5708             my $type;
5709             if ( not defined $arg ) {    # undefined parameter
5710                 push @a, "undef";
5711             }
5712
5713             elsif ( $nothard and tied $arg ) {    # tied parameter
5714                 push @a, "tied";
5715             }
5716             elsif ( $nothard and $type = ref $arg ) {    # reference
5717                 push @a, "ref($type)";
5718             }
5719             else {                                       # can be stringified
5720                 local $_ =
5721                   "$arg";    # Safe to stringify now - should not call f().
5722
5723                 # Backslash any single-quotes or backslashes.
5724                 s/([\'\\])/\\$1/g;
5725
5726                 # Single-quote it unless it's a number or a colon-separated
5727                 # name.
5728                 s/(.*)/'$1'/s
5729                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5730
5731                 # Turn high-bit characters into meta-whatever.
5732                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5733
5734                 # Turn control characters into ^-whatever.
5735                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5736
5737                 push( @a, $_ );
5738             } ## end else [ if (not defined $arg)
5739         } ## end for $arg (@args)
5740
5741         # If context is true, this is array (@)context.
5742         # If context is false, this is scalar ($) context.
5743         # If neither, context isn't defined. (This is apparently a 'can't
5744         # happen' trap.)
5745         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5746
5747         # if the sub has args ($h true), make an anonymous array of the
5748         # dumped args.
5749         $args = $h ? [@a] : undef;
5750
5751         # remove trailing newline-whitespace-semicolon-end of line sequence
5752         # from the eval text, if any.
5753         $e =~ s/\n\s*\;\s*\Z// if $e;
5754
5755         # Escape backslashed single-quotes again if necessary.
5756         $e =~ s/([\\\'])/\\$1/g if $e;
5757
5758         # if the require flag is true, the eval text is from a require.
5759         if ($r) {
5760             $sub = "require '$e'";
5761         }
5762
5763         # if it's false, the eval text is really from an eval.
5764         elsif ( defined $r ) {
5765             $sub = "eval '$e'";
5766         }
5767
5768         # If the sub is '(eval)', this is a block eval, meaning we don't
5769         # know what the eval'ed text actually was.
5770         elsif ( $sub eq '(eval)' ) {
5771             $sub = "eval {...}";
5772         }
5773
5774         # Stick the collected information into @sub as an anonymous hash.
5775         push(
5776             @sub,
5777             {
5778                 context => $context,
5779                 sub     => $sub,
5780                 args    => $args,
5781                 file    => $file,
5782                 line    => $line
5783             }
5784         );
5785
5786         # Stop processing frames if the user hit control-C.
5787         last if $signal;
5788     } ## end for ($i = $skip ; $i < ...
5789
5790     # Restore the trace value again.
5791     $trace = $otrace;
5792     @sub;
5793 } ## end sub dump_trace
5794
5795 =head2 C<action()>
5796
5797 C<action()> takes input provided as the argument to an add-action command,
5798 either pre- or post-, and makes sure it's a complete command. It doesn't do
5799 any fancy parsing; it just keeps reading input until it gets a string
5800 without a trailing backslash.
5801
5802 =cut
5803
5804 sub action {
5805     my $action = shift;
5806
5807     while ( $action =~ s/\\$// ) {
5808
5809         # We have a backslash on the end. Read more.
5810         $action .= &gets;
5811     } ## end while ($action =~ s/\\$//)
5812
5813     # Return the assembled action.
5814     $action;
5815 } ## end sub action
5816
5817 =head2 unbalanced
5818
5819 This routine mostly just packages up a regular expression to be used
5820 to check that the thing it's being matched against has properly-matched
5821 curly braces.
5822
5823 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
5824 speeds things up by only creating the qr//'ed expression once; if it's
5825 already defined, we don't try to define it again. A speed hack.
5826
5827 =cut
5828
5829 sub unbalanced {
5830
5831     # I hate using globals!
5832     $balanced_brace_re ||= qr{
5833         ^ \{
5834              (?:
5835                  (?> [^{}] + )              # Non-parens without backtracking
5836                 |
5837                  (??{ $balanced_brace_re }) # Group with matching parens
5838               ) *
5839           \} $
5840    }x;
5841     return $_[0] !~ m/$balanced_brace_re/;
5842 } ## end sub unbalanced
5843
5844 =head2 C<gets()>
5845
5846 C<gets()> is a primitive (very primitive) routine to read continuations.
5847 It was devised for reading continuations for actions.
5848 it just reads more input with C<readline()> and returns it.
5849
5850 =cut
5851
5852 sub gets {
5853     &readline("cont: ");
5854 }
5855
5856 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
5857
5858 The C<system()> function assumes that it can just go ahead and use STDIN and
5859 STDOUT, but under the debugger, we want it to use the debugger's input and
5860 outout filehandles.
5861
5862 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
5863 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
5864 and then puts everything back again.
5865
5866 =cut
5867
5868 sub system {
5869
5870     # We save, change, then restore STDIN and STDOUT to avoid fork() since
5871     # some non-Unix systems can do system() but have problems with fork().
5872     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
5873     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
5874     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
5875     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
5876
5877     # XXX: using csh or tcsh destroys sigint retvals!
5878     system(@_);
5879     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
5880     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
5881     close(SAVEIN);
5882     close(SAVEOUT);
5883
5884     # most of the $? crud was coping with broken cshisms
5885     if ( $? >> 8 ) {
5886         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
5887     }
5888     elsif ($?) {
5889         &warn(
5890             "(Command died of SIG#",
5891             ( $? & 127 ),
5892             ( ( $? & 128 ) ? " -- core dumped" : "" ),
5893             ")", "\n"
5894         );
5895     } ## end elsif ($?)
5896
5897     return $?;
5898
5899 } ## end sub system
5900
5901 =head1 TTY MANAGEMENT
5902
5903 The subs here do some of the terminal management for multiple debuggers.
5904
5905 =head2 setterm
5906
5907 Top-level function called when we want to set up a new terminal for use
5908 by the debugger.
5909
5910 If the C<noTTY> debugger option was set, we'll either use the terminal
5911 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
5912 to find one. If we're a forked debugger, we call C<resetterm> to try to
5913 get a whole new terminal if we can.
5914
5915 In either case, we set up the terminal next. If the C<ReadLine> option was
5916 true, we'll get a C<Term::ReadLine> object for the current terminal and save
5917 the appropriate attributes. We then
5918
5919 =cut
5920
5921 sub setterm {
5922
5923     # Load Term::Readline, but quietly; don't debug it and don't trace it.
5924     local $frame = 0;
5925     local $doret = -2;
5926     require Term::ReadLine;
5927
5928     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
5929     if ($notty) {
5930         if ($tty) {
5931             my ( $i, $o ) = split $tty, /,/;
5932             $o = $i unless defined $o;
5933             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
5934             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
5935             $IN  = \*IN;
5936             $OUT = \*OUT;
5937             my $sel = select($OUT);
5938             $| = 1;
5939             select($sel);
5940         } ## end if ($tty)
5941
5942         # We don't have a TTY - try to find one via Term::Rendezvous.
5943         else {
5944             require Term::Rendezvous;
5945
5946             # See if we have anything to pass to Term::Rendezvous.
5947             # Use $HOME/.perldbtty$$ if not.
5948             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
5949
5950             # Rendezvous and get the filehandles.
5951             my $term_rv = Term::Rendezvous->new( $rv );
5952             $IN  = $term_rv->IN;
5953             $OUT = $term_rv->OUT;
5954         } ## end else [ if ($tty)
5955     } ## end if ($notty)
5956
5957     # We're a daughter debugger. Try to fork off another TTY.
5958     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
5959         resetterm(2);
5960     }
5961
5962     # If we shouldn't use Term::ReadLine, don't.
5963     if ( !$rl ) {
5964         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
5965     }
5966
5967     # We're using Term::ReadLine. Get all the attributes for this terminal.
5968     else {
5969         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
5970
5971         $rl_attribs = $term->Attribs;
5972         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
5973           if defined $rl_attribs->{basic_word_break_characters}
5974           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
5975         $rl_attribs->{special_prefixes} = '$@&%';
5976         $rl_attribs->{completer_word_break_characters} .= '$@&%';
5977         $rl_attribs->{completion_function} = \&db_complete;
5978     } ## end else [ if (!$rl)
5979
5980     # Set up the LINEINFO filehandle.
5981     $LINEINFO = $OUT     unless defined $LINEINFO;
5982     $lineinfo = $console unless defined $lineinfo;
5983
5984     $term->MinLine(2);
5985
5986     &load_hist();
5987
5988     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
5989         $term->SetHistory(@hist);
5990     }
5991
5992     # XXX Ornaments are turned on unconditionally, which is not
5993     # always a good thing.
5994     ornaments($ornaments) if defined $ornaments;
5995     $term_pid = $$;
5996 } ## end sub setterm
5997
5998 sub load_hist {
5999     $histfile //= option_val("HistFile", undef);
6000     return unless defined $histfile;
6001     open my $fh, "<", $histfile or return;
6002     local $/ = "\n";
6003     @hist = ();
6004     while (<$fh>) {
6005         chomp;
6006         push @hist, $_;
6007     }
6008     close $fh;
6009 }
6010
6011 sub save_hist {
6012     return unless defined $histfile;
6013     eval { require File::Path } or return;
6014     eval { require File::Basename } or return;
6015     File::Path::mkpath(File::Basename::dirname($histfile));
6016     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6017     $histsize //= option_val("HistSize",100);
6018     my @copy = grep { $_ ne '?' } @hist;
6019     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6020     for ($start .. $#copy) {
6021         print $fh "$copy[$_]\n";
6022     }
6023     close $fh or die "Could not write '$histfile': $!";
6024 }
6025
6026 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6027
6028 When the process being debugged forks, or the process invokes a command
6029 via C<system()> which starts a new debugger, we need to be able to get a new
6030 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6031 fight over the terminal, and you can never quite be sure who's going to get the
6032 input you're typing.
6033
6034 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6035 is tasked with doing all the necessary operating system mojo to get a new
6036 TTY (and probably another window) and to direct the new debugger to read and
6037 write there.
6038
6039 The debugger provides C<get_fork_TTY> functions which work for TCP
6040 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6041 supported. You are encouraged to write C<get_fork_TTY> functions which
6042 work for I<your> platform and contribute them.
6043
6044 =head3 C<socket_get_fork_TTY>
6045
6046 =cut
6047
6048 sub connect_remoteport {
6049     require IO::Socket;
6050
6051     my $socket = IO::Socket::INET->new(
6052         Timeout  => '10',
6053         PeerAddr => $remoteport,
6054         Proto    => 'tcp',
6055     );
6056     if ( ! $socket ) {
6057         die "Unable to connect to remote host: $remoteport\n";
6058     }
6059     return $socket;
6060 }
6061
6062 sub socket_get_fork_TTY {
6063     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6064
6065     # Do I need to worry about setting $term?
6066
6067     reset_IN_OUT( $IN, $OUT );
6068     return '';
6069 }
6070
6071 =head3 C<xterm_get_fork_TTY>
6072
6073 This function provides the C<get_fork_TTY> function for X11. If a
6074 program running under the debugger forks, a new <xterm> window is opened and
6075 the subsidiary debugger is directed there.
6076
6077 The C<open()> call is of particular note here. We have the new C<xterm>
6078 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6079 command (which prints the device name of the TTY we'll want to use for input
6080 and output to STDOUT, then C<sleep> for a very long time, routing this output
6081 to file number 3. This way we can simply read from the <XT> filehandle (which
6082 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6083
6084 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6085 properly set up.
6086
6087 =cut
6088
6089 sub xterm_get_fork_TTY {
6090     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6091     open XT,
6092 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6093  sleep 10000000' |];
6094
6095     # Get the output from 'tty' and clean it up a little.
6096     my $tty = <XT>;
6097     chomp $tty;
6098
6099     $pidprompt = '';    # Shown anyway in titlebar
6100
6101     # We need $term defined or we can not switch to the newly created xterm
6102     if ($tty ne '' && !defined $term) {
6103         require Term::ReadLine;
6104         if ( !$rl ) {
6105             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6106         }
6107         else {
6108             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6109         }
6110     }
6111     # There's our new TTY.
6112     return $tty;
6113 } ## end sub xterm_get_fork_TTY
6114
6115 =head3 C<os2_get_fork_TTY>
6116
6117 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6118
6119 =cut
6120
6121 # This example function resets $IN, $OUT itself
6122 my $c_pipe = 0;
6123 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6124     local $\  = '';
6125     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6126     my %opt = ( title => "Daughter Perl debugger $pids $name",
6127                 ($rl ? (read_by_key => 1) : ()) );
6128     require OS2::Process;
6129     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6130       or return;
6131     $pidprompt = '';    # Shown anyway in titlebar
6132     reset_IN_OUT($in, $out);
6133     $tty = '*reset*';
6134     return '';          # Indicate that reset_IN_OUT is called
6135 } ## end sub os2_get_fork_TTY
6136
6137 =head3 C<macosx_get_fork_TTY>
6138
6139 The Mac OS X version uses AppleScript to tell Terminal.app to create
6140 a new window.
6141
6142 =cut
6143
6144 # Notes about Terminal.app's AppleScript support,
6145 # (aka things that might break in future OS versions).
6146 #
6147 # The "do script" command doesn't return a reference to the new window
6148 # it creates, but since it appears frontmost and windows are enumerated
6149 # front to back, we can use "first window" === "window 1".
6150 #
6151 # Since "do script" is implemented by supplying the argument (plus a
6152 # return character) as terminal input, there's a potential race condition
6153 # where the debugger could beat the shell to reading the command.
6154 # To prevent this, we wait for the screen to clear before proceeding.
6155 #
6156 # 10.3 and 10.4:
6157 # There's no direct accessor for the tty device name, so we fiddle
6158 # with the window title options until it says what we want.
6159 #
6160 # 10.5:
6161 # There _is_ a direct accessor for the tty device name, _and_ there's
6162 # a new possible component of the window title (the name of the settings
6163 # set).  A separate version is needed.
6164
6165 my @script_versions=
6166
6167     ([237, <<'__LEOPARD__'],
6168 tell application "Terminal"
6169     do script "clear;exec sleep 100000"
6170     tell first tab of first window
6171         copy tty to thetty
6172         set custom title to "forked perl debugger"
6173         set title displays custom title to true
6174         repeat while (length of first paragraph of (get contents)) > 0
6175             delay 0.1
6176         end repeat
6177     end tell
6178 end tell
6179 thetty
6180 __LEOPARD__
6181
6182      [100, <<'__JAGUAR_TIGER__'],
6183 tell application "Terminal"
6184     do script "clear;exec sleep 100000"
6185     tell first window
6186         set title displays shell path to false
6187         set title displays window size to false
6188         set title displays file name to false
6189         set title displays device name to true
6190         set title displays custom title to true
6191         set custom title to ""
6192         copy "/dev/" & name to thetty
6193         set custom title to "forked perl debugger"
6194         repeat while (length of first paragraph of (get contents)) > 0
6195             delay 0.1
6196         end repeat
6197     end tell
6198 end tell
6199 thetty
6200 __JAGUAR_TIGER__
6201
6202 );
6203
6204 sub macosx_get_fork_TTY
6205 {
6206     my($version,$script,$pipe,$tty);
6207
6208     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6209     foreach my $entry (@script_versions) {
6210         if ($version>=$entry->[0]) {
6211             $script=$entry->[1];
6212             last;
6213         }
6214     }
6215     return unless defined($script);
6216     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6217     $tty=readline($pipe);
6218     close($pipe);
6219     return unless defined($tty) && $tty =~ m(^/dev/);
6220     chomp $tty;
6221     return $tty;
6222 }
6223
6224 =head2 C<create_IN_OUT($flags)>
6225
6226 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6227 try to diagnose why.
6228
6229 Flags are:
6230
6231 =over 4
6232
6233 =item * 1 - Don't know how to create a new TTY.
6234
6235 =item * 2 - Debugger has forked, but we can't get a new TTY.
6236
6237 =item * 4 - standard debugger startup is happening.
6238
6239 =back
6240
6241 =cut
6242
6243 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6244
6245     # If we know how to get a new TTY, do it! $in will have
6246     # the TTY name if get_fork_TTY works.
6247     my $in = &get_fork_TTY if defined &get_fork_TTY;
6248
6249     # It used to be that
6250     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6251
6252     if ( not defined $in ) {
6253         my $why = shift;
6254
6255         # We don't know how.
6256         print_help(<<EOP) if $why == 1;
6257 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6258 EOP
6259
6260         # Forked debugger.
6261         print_help(<<EOP) if $why == 2;
6262 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6263   This may be an asynchronous session, so the parent debugger may be active.
6264 EOP
6265
6266         # Note that both debuggers are fighting over the same input.
6267         print_help(<<EOP) if $why != 4;
6268   Since two debuggers fight for the same TTY, input is severely entangled.
6269
6270 EOP
6271         print_help(<<EOP);
6272   I know how to switch the output to a different window in xterms, OS/2
6273   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6274   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6275   B<DB::get_fork_TTY()> returning this.
6276
6277   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6278   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6279
6280 EOP
6281     } ## end if (not defined $in)
6282     elsif ( $in ne '' ) {
6283         TTY($in);
6284     }
6285     else {
6286         $console = '';    # Indicate no need to open-from-the-console
6287     }
6288     undef $fork_TTY;
6289 } ## end sub create_IN_OUT
6290
6291 =head2 C<resetterm>
6292
6293 Handles rejiggering the prompt when we've forked off a new debugger.
6294
6295 If the new debugger happened because of a C<system()> that invoked a
6296 program under the debugger, the arrow between the old pid and the new
6297 in the prompt has I<two> dashes instead of one.
6298
6299 We take the current list of pids and add this one to the end. If there
6300 isn't any list yet, we make one up out of the initial pid associated with
6301 the terminal and our new pid, sticking an arrow (either one-dashed or
6302 two dashed) in between them.
6303
6304 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6305 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6306 and try to do that.
6307
6308 =cut
6309
6310 sub resetterm {    # We forked, so we need a different TTY
6311
6312     # Needs to be passed to create_IN_OUT() as well.
6313     my $in = shift;
6314
6315     # resetterm(2): got in here because of a system() starting a debugger.
6316     # resetterm(1): just forked.
6317     my $systemed = $in > 1 ? '-' : '';
6318
6319     # If there's already a list of pids, add this to the end.
6320     if ($pids) {
6321         $pids =~ s/\]/$systemed->$$]/;
6322     }
6323
6324     # No pid list. Time to make one.
6325     else {
6326         $pids = "[$term_pid->$$]";
6327     }
6328
6329     # The prompt we're going to be using for this debugger.
6330     $pidprompt = $pids;
6331
6332     # We now 0wnz this terminal.
6333     $term_pid = $$;
6334
6335     # Just return if we're not supposed to try to create a new TTY.
6336     return unless $CreateTTY & $in;
6337
6338     # Try to create a new IN/OUT pair.
6339     create_IN_OUT($in);
6340 } ## end sub resetterm
6341
6342 =head2 C<readline>
6343
6344 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6345 the next line, print a message saying we got it, add it to the terminal
6346 history (if possible), and return it.
6347
6348 If there's nothing in the typeahead buffer, check the command filehandle stack.
6349 If there are any filehandles there, read from the last one, and return the line
6350 if we got one. If not, we pop the filehandle off and close it, and try the
6351 next one up the stack.
6352
6353 If we've emptied the filehandle stack, we check to see if we've got a socket
6354 open, and we read that and return it if we do. If we don't, we just call the
6355 core C<readline()> and return its value.
6356
6357 =cut
6358
6359 sub readline {
6360
6361     # Localize to prevent it from being smashed in the program being debugged.
6362     local $.;
6363
6364     # Pull a line out of the typeahead if there's stuff there.
6365     if (@typeahead) {
6366
6367         # How many lines left.
6368         my $left = @typeahead;
6369
6370         # Get the next line.
6371         my $got = shift @typeahead;
6372
6373         # Print a message saying we got input from the typeahead.
6374         local $\ = '';
6375         print $OUT "auto(-$left)", shift, $got, "\n";
6376
6377         # Add it to the terminal history (if possible).
6378         $term->AddHistory($got)
6379           if length($got) > 1
6380           and defined $term->Features->{addHistory};
6381         return $got;
6382     } ## end if (@typeahead)
6383
6384     # We really need to read some input. Turn off entry/exit trace and
6385     # return value printing.
6386     local $frame = 0;
6387     local $doret = -2;
6388
6389     # If there are stacked filehandles to read from ...
6390     while (@cmdfhs) {
6391
6392         # Read from the last one in the stack.
6393         my $line = CORE::readline( $cmdfhs[-1] );
6394
6395         # If we got a line ...
6396         defined $line
6397           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6398           : close pop @cmdfhs;                            # Pop and close
6399     } ## end while (@cmdfhs)
6400
6401     # Nothing on the filehandle stack. Socket?
6402     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6403
6404         # Send anything we have to send.
6405         $OUT->write( join( '', @_ ) );
6406
6407         # Receive anything there is to receive.
6408         $stuff;
6409         my $stuff = '';
6410         my $buf;
6411         do {
6412             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6413                                             # XXX Don't know. You tell me.
6414         } while length $buf and ($stuff .= $buf) !~ /\n/;
6415
6416         # What we got.
6417         $stuff;
6418     } ## end if (ref $OUT and UNIVERSAL::isa...
6419
6420     # No socket. Just read from the terminal.
6421     else {
6422         $term->readline(@_);
6423     }
6424 } ## end sub readline
6425
6426 =head1 OPTIONS SUPPORT ROUTINES
6427
6428 These routines handle listing and setting option values.
6429
6430 =head2 C<dump_option> - list the current value of an option setting
6431
6432 This routine uses C<option_val> to look up the value for an option.
6433 It cleans up escaped single-quotes and then displays the option and
6434 its value.
6435
6436 =cut
6437
6438 sub dump_option {
6439     my ( $opt, $val ) = @_;
6440     $val = option_val( $opt, 'N/A' );
6441     $val =~ s/([\\\'])/\\$1/g;
6442     printf $OUT "%20s = '%s'\n", $opt, $val;
6443 } ## end sub dump_option
6444
6445 sub options2remember {
6446     foreach my $k (@RememberOnROptions) {
6447         $option{$k} = option_val( $k, 'N/A' );
6448     }
6449     return %option;
6450 }
6451
6452 =head2 C<option_val> - find the current value of an option
6453
6454 This can't just be a simple hash lookup because of the indirect way that
6455 the option values are stored. Some are retrieved by calling a subroutine,
6456 some are just variables.
6457
6458 You must supply a default value to be used in case the option isn't set.
6459
6460 =cut
6461
6462 sub option_val {
6463     my ( $opt, $default ) = @_;
6464     my $val;
6465
6466     # Does this option exist, and is it a variable?
6467     # If so, retrieve the value via the value in %optionVars.
6468     if (    defined $optionVars{$opt}
6469         and defined ${ $optionVars{$opt} } )
6470     {
6471         $val = ${ $optionVars{$opt} };
6472     }
6473
6474     # Does this option exist, and it's a subroutine?
6475     # If so, call the subroutine via the ref in %optionAction
6476     # and capture the value.
6477     elsif ( defined $optionAction{$opt}
6478         and defined &{ $optionAction{$opt} } )
6479     {
6480         $val = &{ $optionAction{$opt} }();
6481     }
6482
6483     # If there's an action or variable for the supplied option,
6484     # but no value was set, use the default.
6485     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6486         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6487     {
6488         $val = $default;
6489     }
6490
6491     # Otherwise, do the simple hash lookup.
6492     else {
6493         $val = $option{$opt};
6494     }
6495
6496     # If the value isn't defined, use the default.
6497     # Then return whatever the value is.
6498     $val = $default unless defined $val;
6499     $val;
6500 } ## end sub option_val
6501
6502 =head2 C<parse_options>
6503
6504 Handles the parsing and execution of option setting/displaying commands.
6505
6506 An option entered by itself is assumed to be I<set me to 1> (the default value)
6507 if the option is a boolean one. If not, the user is prompted to enter a valid
6508 value or to query the current value (via C<option? >).
6509
6510 If C<option=value> is entered, we try to extract a quoted string from the
6511 value (if it is quoted). If it's not, we just use the whole value as-is.
6512
6513 We load any modules required to service this option, and then we set it: if
6514 it just gets stuck in a variable, we do that; if there's a subroutine to
6515 handle setting the option, we call that.
6516
6517 Finally, if we're running in interactive mode, we display the effect of the
6518 user's command back to the terminal, skipping this if we're setting things
6519 during initialization.
6520
6521 =cut
6522
6523 sub parse_options {
6524     local ($_) = @_;
6525     local $\ = '';
6526
6527     # These options need a value. Don't allow them to be clobbered by accident.
6528     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6529       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6530       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6531     };
6532
6533     while (length) {
6534         my $val_defaulted;
6535
6536         # Clean off excess leading whitespace.
6537         s/^\s+// && next;
6538
6539         # Options are always all word characters, followed by a non-word
6540         # separator.
6541         s/^(\w+)(\W?)// or print( $OUT "Invalid option '$_'\n" ), last;
6542         my ( $opt, $sep ) = ( $1, $2 );
6543
6544         # Make sure that such an option exists.
6545         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6546           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6547
6548         print( $OUT "Unknown option '$opt'\n" ), next unless $matches;
6549         print( $OUT "Ambiguous option '$opt'\n" ), next if $matches > 1;
6550         my $val;
6551
6552         # '?' as separator means query, but must have whitespace after it.
6553         if ( "?" eq $sep ) {
6554             print( $OUT "Option query '$opt?' followed by non-space '$_'\n" ),
6555               last
6556               if /^\S/;
6557
6558             #&dump_option($opt);
6559         } ## end if ("?" eq $sep)
6560
6561         # Separator is whitespace (or just a carriage return).
6562         # They're going for a default, which we assume is 1.
6563         elsif ( $sep !~ /\S/ ) {
6564             $val_defaulted = 1;
6565             $val           = "1";   #  this is an evil default; make 'em set it!
6566         }
6567
6568         # Separator is =. Trying to set a value.
6569         elsif ( $sep eq "=" ) {
6570
6571             # If quoted, extract a quoted string.
6572             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6573                 my $quote = $1;
6574                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6575             }
6576
6577             # Not quoted. Use the whole thing. Warn about 'option='.
6578             else {
6579                 s/^(\S*)//;
6580                 $val = $1;
6581                 print OUT qq(Option better cleared using $opt=""\n)
6582                   unless length $val;
6583             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6584
6585         } ## end elsif ($sep eq "=")
6586
6587         # "Quoted" with [], <>, or {}.
6588         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6589             my ($end) =
6590               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6591             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6592               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
6593             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6594         } ## end else [ if ("?" eq $sep)
6595
6596         # Exclude non-booleans from getting set to 1 by default.
6597         if ( $opt_needs_val{$option} && $val_defaulted ) {
6598             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6599             print $OUT
6600 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
6601             next;
6602         } ## end if ($opt_needs_val{$option...
6603
6604         # Save the option value.
6605         $option{$option} = $val if defined $val;
6606
6607         # Load any module that this option requires.
6608         eval qq{
6609                 local \$frame = 0;
6610                 local \$doret = -2;
6611                 require '$optionRequire{$option}';
6612                 1;
6613                } || die $@   # XXX: shouldn't happen
6614           if defined $optionRequire{$option}
6615           && defined $val;
6616
6617         # Set it.
6618         # Stick it in the proper variable if it goes in a variable.
6619         ${ $optionVars{$option} } = $val
6620           if defined $optionVars{$option}
6621           && defined $val;
6622
6623         # Call the appropriate sub if it gets set via sub.
6624         &{ $optionAction{$option} }($val)
6625           if defined $optionAction{$option}
6626           && defined &{ $optionAction{$option} }
6627           && defined $val;
6628
6629         # Not initialization - echo the value we set it to.
6630         dump_option($option) unless $OUT eq \*STDERR;
6631     } ## end while (length)
6632 } ## end sub parse_options
6633
6634 =head1 RESTART SUPPORT
6635
6636 These routines are used to store (and restore) lists of items in environment
6637 variables during a restart.
6638
6639 =head2 set_list
6640
6641 Set_list packages up items to be stored in a set of environment variables
6642 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6643 the values). Values outside the standard ASCII charset are stored by encoding
6644 then as hexadecimal values.
6645
6646 =cut
6647
6648 sub set_list {
6649     my ( $stem, @list ) = @_;
6650     my $val;
6651
6652     # VAR_n: how many we have. Scalar assignment gets the number of items.
6653     $ENV{"${stem}_n"} = @list;
6654
6655     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6656     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6657     for $i ( 0 .. $#list ) {
6658         $val = $list[$i];
6659         $val =~ s/\\/\\\\/g;
6660         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6661         $ENV{"${stem}_$i"} = $val;
6662     } ## end for $i (0 .. $#list)
6663 } ## end sub set_list
6664
6665 =head2 get_list
6666
6667 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6668 back, and then pull VAR_0, VAR_1. etc. back out.
6669
6670 =cut
6671
6672 sub get_list {
6673     my $stem = shift;
6674     my @list;
6675     my $n = delete $ENV{"${stem}_n"};
6676     my $val;
6677     for $i ( 0 .. $n - 1 ) {
6678         $val = delete $ENV{"${stem}_$i"};
6679         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6680         push @list, $val;
6681     }
6682     @list;
6683 } ## end sub get_list
6684
6685 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6686
6687 =head2 catch()
6688
6689 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6690 set an already-existing global scalar variable to a constant value. This
6691 avoids allocating any memory possibly in the middle of something that will
6692 get all confused if we do, particularly under I<unsafe signals>.
6693
6694 =cut
6695
6696 sub catch {
6697     $signal = 1;
6698     return;    # Put nothing on the stack - malloc/free land!
6699 }
6700
6701 =head2 C<warn()>
6702
6703 C<warn> emits a warning, by joining together its arguments and printing
6704 them, with couple of fillips.
6705
6706 If the composited message I<doesn't> end with a newline, we automatically
6707 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6708 to be set to the filehandle to be used to output warnings; it makes no
6709 assumptions about what filehandles are available.
6710
6711 =cut
6712
6713 sub warn {
6714     my ($msg) = join( "", @_ );
6715     $msg .= ": $!\n" unless $msg =~ /\n$/;
6716     local $\ = '';
6717     print $OUT $msg;
6718 } ## end sub warn
6719
6720 =head1 INITIALIZATION TTY SUPPORT
6721
6722 =head2 C<reset_IN_OUT>
6723
6724 This routine handles restoring the debugger's input and output filehandles
6725 after we've tried and failed to move them elsewhere.  In addition, it assigns
6726 the debugger's output filehandle to $LINEINFO if it was already open there.
6727
6728 =cut
6729
6730 sub reset_IN_OUT {
6731     my $switch_li = $LINEINFO eq $OUT;
6732
6733     # If there's a term and it's able to get a new tty, try to get one.
6734     if ( $term and $term->Features->{newTTY} ) {
6735         ( $IN, $OUT ) = ( shift, shift );
6736         $term->newTTY( $IN, $OUT );
6737     }
6738
6739     # This term can't get a new tty now. Better luck later.
6740     elsif ($term) {
6741         &warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
6742     }
6743
6744     # Set the filehndles up as they were.
6745     else {
6746         ( $IN, $OUT ) = ( shift, shift );
6747     }
6748
6749     # Unbuffer the output filehandle.
6750     my $o = select $OUT;
6751     $| = 1;
6752     select $o;
6753
6754     # Point LINEINFO to the same output filehandle if it was there before.
6755     $LINEINFO = $OUT if $switch_li;
6756 } ## end sub reset_IN_OUT
6757
6758 =head1 OPTION SUPPORT ROUTINES
6759
6760 The following routines are used to process some of the more complicated
6761 debugger options.
6762
6763 =head2 C<TTY>
6764
6765 Sets the input and output filehandles to the specified files or pipes.
6766 If the terminal supports switching, we go ahead and do it. If not, and
6767 there's already a terminal in place, we save the information to take effect
6768 on restart.
6769
6770 If there's no terminal yet (for instance, during debugger initialization),
6771 we go ahead and set C<$console> and C<$tty> to the file indicated.
6772
6773 =cut
6774
6775 sub TTY {
6776
6777     if ( @_ and $term and $term->Features->{newTTY} ) {
6778
6779         # This terminal supports switching to a new TTY.
6780         # Can be a list of two files, or on string containing both names,
6781         # comma-separated.
6782         # XXX Should this perhaps be an assignment from @_?
6783         my ( $in, $out ) = shift;
6784         if ( $in =~ /,/ ) {
6785
6786             # Split list apart if supplied.
6787             ( $in, $out ) = split /,/, $in, 2;
6788         }
6789         else {
6790
6791             # Use the same file for both input and output.
6792             $out = $in;
6793         }
6794
6795         # Open file onto the debugger's filehandles, if you can.
6796         open IN,  $in     or die "cannot open '$in' for read: $!";
6797         open OUT, ">$out" or die "cannot open '$out' for write: $!";
6798
6799         # Swap to the new filehandles.
6800         reset_IN_OUT( \*IN, \*OUT );
6801
6802         # Save the setting for later.
6803         return $tty = $in;
6804     } ## end if (@_ and $term and $term...
6805
6806     # Terminal doesn't support new TTY, or doesn't support readline.
6807     # Can't do it now, try restarting.
6808     &warn("Too late to set TTY, enabled on next 'R'!\n") if $term and @_;
6809
6810     # Useful if done through PERLDB_OPTS:
6811     $console = $tty = shift if @_;
6812
6813     # Return whatever the TTY is.
6814     $tty or $console;
6815 } ## end sub TTY
6816
6817 =head2 C<noTTY>
6818
6819 Sets the C<$notty> global, controlling whether or not the debugger tries to
6820 get a terminal to read from. If called after a terminal is already in place,
6821 we save the value to use it if we're restarted.
6822
6823 =cut
6824
6825 sub noTTY {
6826     if ($term) {
6827         &warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
6828     }
6829     $notty = shift if @_;
6830     $notty;
6831 } ## end sub noTTY
6832
6833 =head2 C<ReadLine>
6834
6835 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
6836 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
6837 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
6838 the value in case a restart is done so we can change it then.
6839
6840 =cut
6841
6842 sub ReadLine {
6843     if ($term) {
6844         &warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
6845     }
6846     $rl = shift if @_;
6847     $rl;
6848 } ## end sub ReadLine
6849
6850 =head2 C<RemotePort>
6851
6852 Sets the port that the debugger will try to connect to when starting up.
6853 If the terminal's already been set up, we can't do it, but we remember the
6854 setting in case the user does a restart.
6855
6856 =cut
6857
6858 sub RemotePort {
6859     if ($term) {
6860         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
6861     }
6862     $remoteport = shift if @_;
6863     $remoteport;
6864 } ## end sub RemotePort
6865
6866 =head2 C<tkRunning>
6867
6868 Checks with the terminal to see if C<Tk> is running, and returns true or
6869 false. Returns false if the current terminal doesn't support C<readline>.
6870
6871 =cut
6872
6873 sub tkRunning {
6874     if ( ${ $term->Features }{tkRunning} ) {
6875         return $term->tkRunning(@_);
6876     }
6877     else {
6878         local $\ = '';
6879         print $OUT "tkRunning not supported by current ReadLine package.\n";
6880         0;
6881     }
6882 } ## end sub tkRunning
6883
6884 =head2 C<NonStop>
6885
6886 Sets nonstop mode. If a terminal's already been set up, it's too late; the
6887 debugger remembers the setting in case you restart, though.
6888
6889 =cut
6890
6891 sub NonStop {
6892     if ($term) {
6893         &warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
6894           if @_;
6895     }
6896     $runnonstop = shift if @_;
6897     $runnonstop;
6898 } ## end sub NonStop
6899
6900 sub DollarCaretP {
6901     if ($term) {
6902         &warn("Some flag changes could not take effect until next 'R'!\n")
6903           if @_;
6904     }
6905     $^P = parse_DollarCaretP_flags(shift) if @_;
6906     expand_DollarCaretP_flags($^P);
6907 }
6908
6909 =head2 C<pager>
6910
6911 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
6912 there already.
6913
6914 =cut
6915
6916 sub pager {
6917     if (@_) {
6918         $pager = shift;
6919         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
6920     }
6921     $pager;
6922 } ## end sub pager
6923
6924 =head2 C<shellBang>
6925
6926 Sets the shell escape command, and generates a printable copy to be used
6927 in the help.
6928
6929 =cut
6930
6931 sub shellBang {
6932
6933     # If we got an argument, meta-quote it, and add '\b' if it
6934     # ends in a word character.
6935     if (@_) {
6936         $sh = quotemeta shift;
6937         $sh .= "\\b" if $sh =~ /\w$/;
6938     }
6939
6940     # Generate the printable version for the help:
6941     $psh = $sh;    # copy it
6942     $psh =~ s/\\b$//;        # Take off trailing \b if any
6943     $psh =~ s/\\(.)/$1/g;    # De-escape
6944     $psh;                    # return the printable version
6945 } ## end sub shellBang
6946
6947 =head2 C<ornaments>
6948
6949 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
6950 was passed as the argument. (This means you can't override the terminal's
6951 ornaments.)
6952
6953 =cut
6954
6955 sub ornaments {
6956     if ( defined $term ) {
6957
6958         # We don't want to show warning backtraces, but we do want die() ones.
6959         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
6960
6961         # No ornaments if the terminal doesn't support them.
6962         return '' unless $term->Features->{ornaments};
6963         eval { $term->ornaments(@_) } || '';
6964     }
6965
6966     # Use what was passed in if we can't determine it ourselves.
6967     else {
6968         $ornaments = shift;
6969     }
6970 } ## end sub ornaments
6971
6972 =head2 C<recallCommand>
6973
6974 Sets the recall command, and builds a printable version which will appear in
6975 the help text.
6976
6977 =cut
6978
6979 sub recallCommand {
6980
6981     # If there is input, metaquote it. Add '\b' if it ends with a word
6982     # character.
6983     if (@_) {
6984         $rc = quotemeta shift;
6985         $rc .= "\\b" if $rc =~ /\w$/;
6986     }
6987
6988     # Build it into a printable version.
6989     $prc = $rc;    # Copy it
6990     $prc =~ s/\\b$//;        # Remove trailing \b
6991     $prc =~ s/\\(.)/$1/g;    # Remove escapes
6992     $prc;                    # Return the printable version
6993 } ## end sub recallCommand
6994
6995 =head2 C<LineInfo> - where the line number information goes
6996
6997 Called with no arguments, returns the file or pipe that line info should go to.
6998
6999 Called with an argument (a file or a pipe), it opens that onto the
7000 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7001 file or pipe again to the caller.
7002
7003 =cut
7004
7005 sub LineInfo {
7006     return $lineinfo unless @_;
7007     $lineinfo = shift;
7008
7009     #  If this is a valid "thing to be opened for output", tack a
7010     # '>' onto the front.
7011     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7012
7013     # If this is a pipe, the stream points to a slave editor.
7014     $slave_editor = ( $stream =~ /^\|/ );
7015
7016     # Open it up and unbuffer it.
7017     open( LINEINFO, "$stream" ) || &warn("Cannot open '$stream' for write");
7018     $LINEINFO = \*LINEINFO;
7019     my $save = select($LINEINFO);
7020     $| = 1;
7021     select($save);
7022
7023     # Hand the file or pipe back again.
7024     $lineinfo;
7025 } ## end sub LineInfo
7026
7027 =head1 COMMAND SUPPORT ROUTINES
7028
7029 These subroutines provide functionality for various commands.
7030
7031 =head2 C<list_modules>
7032
7033 For the C<M> command: list modules loaded and their versions.
7034 Essentially just runs through the keys in %INC, picks each package's
7035 C<$VERSION> variable, gets the file name, and formats the information
7036 for output.
7037
7038 =cut
7039
7040 sub list_modules {    # versions
7041     my %version;
7042     my $file;
7043
7044     # keys are the "as-loaded" name, values are the fully-qualified path
7045     # to the file itself.
7046     for ( keys %INC ) {
7047         $file = $_;                                # get the module name
7048         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7049         s,/,::,g;                                  # change '/' to '::'
7050         s/^perl5db$/DB/;                           # Special case: debugger
7051                                                    # moves to package DB
7052         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7053
7054         # If the package has a $VERSION package global (as all good packages
7055         # should!) decode it and save as partial message.
7056         if ( defined ${ $_ . '::VERSION' } ) {
7057             $version{$file} = "${ $_ . '::VERSION' } from ";
7058         }
7059
7060         # Finish up the message with the file the package came from.
7061         $version{$file} .= $INC{$file};
7062     } ## end for (keys %INC)
7063
7064     # Hey, dumpit() formats a hash nicely, so why not use it?
7065     dumpit( $OUT, \%version );
7066 } ## end sub list_modules
7067
7068 =head2 C<sethelp()>
7069
7070 Sets up the monster string used to format and print the help.
7071
7072 =head3 HELP MESSAGE FORMAT
7073
7074 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7075 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7076 easy to parse and portable, but which still allows the help to be a little
7077 nicer than just plain text.
7078
7079 Essentially, you define the command name (usually marked up with C<< B<> >>
7080 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7081 newline. The descriptive text can also be marked up in the same way. If you
7082 need to continue the descriptive text to another line, start that line with
7083 just tabs and then enter the marked-up text.
7084
7085 If you are modifying the help text, I<be careful>. The help-string parser is
7086 not very sophisticated, and if you don't follow these rules it will mangle the
7087 help beyond hope until you fix the string.
7088
7089 =cut
7090
7091 sub sethelp {
7092
7093     # XXX: make sure there are tabs between the command and explanation,
7094     #      or print_help will screw up your formatting if you have
7095     #      eeevil ornaments enabled.  This is an insane mess.
7096
7097     $help = "
7098 Help is currently only available for the new 5.8 command set.
7099 No help is available for the old command set.
7100 We assume you know what you're doing if you switch to it.
7101
7102 B<T>        Stack trace.
7103 B<s> [I<expr>]    Single step [in I<expr>].
7104 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7105 <B<CR>>        Repeat last B<n> or B<s> command.
7106 B<r>        Return from current subroutine.
7107 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7108         at the specified position.
7109 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7110 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7111 B<l> I<line>        List single I<line>.
7112 B<l> I<subname>    List first window of lines from subroutine.
7113 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7114 B<l>        List next window of lines.
7115 B<->        List previous window of lines.
7116 B<v> [I<line>]    View window around I<line>.
7117 B<.>        Return to the executed line.
7118 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7119         I<filename> may be either the full name of the file, or a regular
7120         expression matching the full file name:
7121         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7122         Evals (with saved bodies) are considered to be filenames:
7123         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7124         (in the order of execution).
7125 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7126 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7127 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7128 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7129 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
7130 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7131 B<b>        Sets breakpoint on current line)
7132 B<b> [I<line>] [I<condition>]
7133         Set breakpoint; I<line> defaults to the current execution line;
7134         I<condition> breaks if it evaluates to true, defaults to '1'.
7135 B<b> I<subname> [I<condition>]
7136         Set breakpoint at first line of subroutine.
7137 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7138 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7139 B<b> B<postpone> I<subname> [I<condition>]
7140         Set breakpoint at first line of subroutine after
7141         it is compiled.
7142 B<b> B<compile> I<subname>
7143         Stop after the subroutine is compiled.
7144 B<B> [I<line>]    Delete the breakpoint for I<line>.
7145 B<B> I<*>             Delete all breakpoints.
7146 B<a> [I<line>] I<command>
7147         Set an action to be done before the I<line> is executed;
7148         I<line> defaults to the current execution line.
7149         Sequence is: check for breakpoint/watchpoint, print line
7150         if necessary, do action, prompt user if necessary,
7151         execute line.
7152 B<a>        Does nothing
7153 B<A> [I<line>]    Delete the action for I<line>.
7154 B<A> I<*>             Delete all actions.
7155 B<w> I<expr>        Add a global watch-expression.
7156 B<w>             Does nothing
7157 B<W> I<expr>        Delete a global watch-expression.
7158 B<W> I<*>             Delete all watch-expressions.
7159 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7160         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7161 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7162 B<x> I<expr>        Evals expression in list context, dumps the result.
7163 B<m> I<expr>        Evals expression in list context, prints methods callable
7164         on the first element of the result.
7165 B<m> I<class>        Prints methods callable via the given class.
7166 B<M>        Show versions of loaded modules.
7167 B<i> I<class>       Prints nested parents of given class.
7168 B<e>         Display current thread id.
7169 B<E>         Display all thread ids the current one will be identified: <n>.
7170 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7171
7172 B<<> ?            List Perl commands to run before each prompt.
7173 B<<> I<expr>        Define Perl command to run before each prompt.
7174 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7175 B<< *>                Delete the list of perl commands to run before each prompt.
7176 B<>> ?            List Perl commands to run after each prompt.
7177 B<>> I<expr>        Define Perl command to run after each prompt.
7178 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7179 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7180 B<{> I<db_command>    Define debugger command to run before each prompt.
7181 B<{> ?            List debugger commands to run before each prompt.
7182 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7183 B<{ *>             Delete the list of debugger commands to run before each prompt.
7184 B<$prc> I<number>    Redo a previous command (default previous command).
7185 B<$prc> I<-number>    Redo number'th-to-last command.
7186 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7187         See 'B<O> I<recallCommand>' too.
7188 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7189       . (
7190         $rc eq $sh
7191         ? ""
7192         : "
7193 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7194       ) . "
7195         See 'B<O> I<shellBang>' too.
7196 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7197 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7198 B<rerun>           Rerun session to current position.
7199 B<rerun> I<n>         Rerun session to numbered command.
7200 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7201 B<H> I<-number>    Display last number commands (default all).
7202 B<H> I<*>          Delete complete history.
7203 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7204 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7205 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
7206 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7207 I<command>        Execute as a perl statement in current package.
7208 B<R>        Pure-man-restart of debugger, some of debugger state
7209         and command-line options may be lost.
7210         Currently the following settings are preserved:
7211         history, breakpoints and actions, debugger B<O>ptions
7212         and the following command-line options: I<-w>, I<-I>, I<-e>.
7213
7214 B<o> [I<opt>] ...    Set boolean option to true
7215 B<o> [I<opt>B<?>]    Query options
7216 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7217         Set options.  Use quotes if spaces in value.
7218     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7219     I<pager>            program for output of \"|cmd\";
7220     I<tkRunning>            run Tk while prompting (with ReadLine);
7221     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7222     I<inhibit_exit>        Allows stepping off the end of the script.
7223     I<ImmediateStop>        Debugger should stop as early as possible.
7224     I<RemotePort>            Remote hostname:port for remote debugging
7225   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7226     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7227     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7228     I<globPrint>             whether to print contents of globs;
7229     I<DumpDBFiles>         dump arrays holding debugged files;
7230     I<DumpPackages>         dump symbol tables of packages;
7231     I<DumpReused>             dump contents of \"reused\" addresses;
7232     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7233     I<bareStringify>         Do not print the overload-stringified value;
7234   Other options include:
7235     I<PrintRet>        affects printing of return value after B<r> command,
7236     I<frame>        affects printing messages on subroutine entry/exit.
7237     I<AutoTrace>    affects printing messages on possible breaking points.
7238     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7239     I<ornaments>     affects screen appearance of the command line.
7240     I<CreateTTY>     bits control attempts to create a new TTY on events:
7241             1: on fork()    2: debugger is started inside debugger
7242             4: on startup
7243     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7244     You can put additional initialization options I<TTY>, I<noTTY>,
7245     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7246     B<R> after you set them).
7247
7248 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7249 B<h>        Summary of debugger commands.
7250 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7251 B<h h>        Long help for debugger commands
7252 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7253         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7254         Set B<\$DB::doccmd> to change viewer.
7255
7256 Type '|h h' for a paged display if this was too hard to read.
7257
7258 ";    # Fix balance of vi % matching: }}}}
7259
7260     #  note: tabs in the following section are not-so-helpful
7261     $summary = <<"END_SUM";
7262 I<List/search source lines:>               I<Control script execution:>
7263   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7264   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7265   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7266   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7267   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7268   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7269 I<Debugger controls:>                        B<L>           List break/watch/actions
7270   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
7271   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7272   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7273   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7274   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7275   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7276   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7277   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7278   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7279 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7280   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7281   B<p> I<expr>         Print expression (uses script's current package).
7282   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7283   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7284   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7285   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7286   B<e>     Display thread id     B<E> Display all thread ids.
7287 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7288 END_SUM
7289
7290     # ')}}; # Fix balance of vi % matching
7291
7292     # and this is really numb...
7293     $pre580_help = "
7294 B<T>        Stack trace.
7295 B<s> [I<expr>]    Single step [in I<expr>].
7296 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7297 B<CR>>        Repeat last B<n> or B<s> command.
7298 B<r>        Return from current subroutine.
7299 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7300         at the specified position.
7301 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7302 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7303 B<l> I<line>        List single I<line>.
7304 B<l> I<subname>    List first window of lines from subroutine.
7305 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7306 B<l>        List next window of lines.
7307 B<->        List previous window of lines.
7308 B<w> [I<line>]    List window around I<line>.
7309 B<.>        Return to the executed line.
7310 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7311         I<filename> may be either the full name of the file, or a regular
7312         expression matching the full file name:
7313         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7314         Evals (with saved bodies) are considered to be filenames:
7315         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7316         (in the order of execution).
7317 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7318 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7319 B<L>        List all breakpoints and actions.
7320 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7321 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
7322 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7323 B<b> [I<line>] [I<condition>]
7324         Set breakpoint; I<line> defaults to the current execution line;
7325         I<condition> breaks if it evaluates to true, defaults to '1'.
7326 B<b> I<subname> [I<condition>]
7327         Set breakpoint at first line of subroutine.
7328 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7329 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7330 B<b> B<postpone> I<subname> [I<condition>]
7331         Set breakpoint at first line of subroutine after
7332         it is compiled.
7333 B<b> B<compile> I<subname>
7334         Stop after the subroutine is compiled.
7335 B<d> [I<line>]    Delete the breakpoint for I<line>.
7336 B<D>        Delete all breakpoints.
7337 B<a> [I<line>] I<command>
7338         Set an action to be done before the I<line> is executed;
7339         I<line> defaults to the current execution line.
7340         Sequence is: check for breakpoint/watchpoint, print line
7341         if necessary, do action, prompt user if necessary,
7342         execute line.
7343 B<a> [I<line>]    Delete the action for I<line>.
7344 B<A>        Delete all actions.
7345 B<W> I<expr>        Add a global watch-expression.
7346 B<W>        Delete all watch-expressions.
7347 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7348         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7349 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7350 B<x> I<expr>        Evals expression in list context, dumps the result.
7351 B<m> I<expr>        Evals expression in list context, prints methods callable
7352         on the first element of the result.
7353 B<m> I<class>        Prints methods callable via the given class.
7354
7355 B<<> ?            List Perl commands to run before each prompt.
7356 B<<> I<expr>        Define Perl command to run before each prompt.
7357 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7358 B<>> ?            List Perl commands to run after each prompt.
7359 B<>> I<expr>        Define Perl command to run after each prompt.
7360 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7361 B<{> I<db_command>    Define debugger command to run before each prompt.
7362 B<{> ?            List debugger commands to run before each prompt.
7363 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7364 B<$prc> I<number>    Redo a previous command (default previous command).
7365 B<$prc> I<-number>    Redo number'th-to-last command.
7366 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7367         See 'B<O> I<recallCommand>' too.
7368 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7369       . (
7370         $rc eq $sh
7371         ? ""
7372         : "
7373 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7374       ) . "
7375         See 'B<O> I<shellBang>' too.
7376 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7377 B<H> I<-number>    Display last number commands (default all).
7378 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7379 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7380 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7381 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7382 I<command>        Execute as a perl statement in current package.
7383 B<v>        Show versions of loaded modules.
7384 B<R>        Pure-man-restart of debugger, some of debugger state
7385         and command-line options may be lost.
7386         Currently the following settings are preserved:
7387         history, breakpoints and actions, debugger B<O>ptions
7388         and the following command-line options: I<-w>, I<-I>, I<-e>.
7389
7390 B<O> [I<opt>] ...    Set boolean option to true
7391 B<O> [I<opt>B<?>]    Query options
7392 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7393         Set options.  Use quotes if spaces in value.
7394     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7395     I<pager>            program for output of \"|cmd\";
7396     I<tkRunning>            run Tk while prompting (with ReadLine);
7397     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7398     I<inhibit_exit>        Allows stepping off the end of the script.
7399     I<ImmediateStop>        Debugger should stop as early as possible.
7400     I<RemotePort>            Remote hostname:port for remote debugging
7401   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7402     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7403     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7404     I<globPrint>             whether to print contents of globs;
7405     I<DumpDBFiles>         dump arrays holding debugged files;
7406     I<DumpPackages>         dump symbol tables of packages;
7407     I<DumpReused>             dump contents of \"reused\" addresses;
7408     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7409     I<bareStringify>         Do not print the overload-stringified value;
7410   Other options include:
7411     I<PrintRet>        affects printing of return value after B<r> command,
7412     I<frame>        affects printing messages on subroutine entry/exit.
7413     I<AutoTrace>    affects printing messages on possible breaking points.
7414     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7415     I<ornaments>     affects screen appearance of the command line.
7416     I<CreateTTY>     bits control attempts to create a new TTY on events:
7417             1: on fork()    2: debugger is started inside debugger
7418             4: on startup
7419     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7420     You can put additional initialization options I<TTY>, I<noTTY>,
7421     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7422     B<R> after you set them).
7423
7424 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7425 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7426 B<h h>        Summary of debugger commands.
7427 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7428         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7429         Set B<\$DB::doccmd> to change viewer.
7430
7431 Type '|h' for a paged display if this was too hard to read.
7432
7433 ";    # Fix balance of vi % matching: }}}}
7434
7435     #  note: tabs in the following section are not-so-helpful
7436     $pre580_summary = <<"END_SUM";
7437 I<List/search source lines:>               I<Control script execution:>
7438   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7439   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7440   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7441   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7442   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7443   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7444 I<Debugger controls:>                        B<L>           List break/watch/actions
7445   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7446   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7447   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7448   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7449   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7450   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7451   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7452   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7453 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7454   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7455   B<p> I<expr>         Print expression (uses script's current package).
7456   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7457   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7458   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7459   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7460 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7461 END_SUM
7462
7463     # ')}}; # Fix balance of vi % matching
7464
7465 } ## end sub sethelp
7466
7467 =head2 C<print_help()>
7468
7469 Most of what C<print_help> does is just text formatting. It finds the
7470 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7471 terminal control characters to simulate them (courtesy of
7472 C<Term::ReadLine::TermCap>).
7473
7474 =cut
7475
7476 sub print_help {
7477     local $_ = shift;
7478
7479     # Restore proper alignment destroyed by eeevil I<> and B<>
7480     # ornaments: A pox on both their houses!
7481     #
7482     # A help command will have everything up to and including
7483     # the first tab sequence padded into a field 16 (or if indented 20)
7484     # wide.  If it's wider than that, an extra space will be added.
7485     s{
7486         ^                       # only matters at start of line
7487           ( \040{4} | \t )*     # some subcommands are indented
7488           ( < ?                 # so <CR> works
7489             [BI] < [^\t\n] + )  # find an eeevil ornament
7490           ( \t+ )               # original separation, discarded
7491           ( .* )                # this will now start (no earlier) than
7492                                 # column 16
7493     } {
7494         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7495         my $clean = $command;
7496         $clean =~ s/[BI]<([^>]*)>/$1/g;
7497
7498         # replace with this whole string:
7499         ($leadwhite ? " " x 4 : "")
7500       . $command
7501       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7502       . $text;
7503
7504     }mgex;
7505
7506     s{                          # handle bold ornaments
7507        B < ( [^>] + | > ) >
7508     } {
7509           $Term::ReadLine::TermCap::rl_term_set[2]
7510         . $1
7511         . $Term::ReadLine::TermCap::rl_term_set[3]
7512     }gex;
7513
7514     s{                         # handle italic ornaments
7515        I < ( [^>] + | > ) >
7516     } {
7517           $Term::ReadLine::TermCap::rl_term_set[0]
7518         . $1
7519         . $Term::ReadLine::TermCap::rl_term_set[1]
7520     }gex;
7521
7522     local $\ = '';
7523     print $OUT $_;
7524 } ## end sub print_help
7525
7526 =head2 C<fix_less>
7527
7528 This routine does a lot of gyrations to be sure that the pager is C<less>.
7529 It checks for C<less> masquerading as C<more> and records the result in
7530 C<$fixed_less> so we don't have to go through doing the stats again.
7531
7532 =cut
7533
7534 sub fix_less {
7535
7536     # We already know if this is set.
7537     return if $fixed_less;
7538
7539     # Pager is less for sure.
7540     my $is_less = $pager =~ /\bless\b/;
7541     if ( $pager =~ /\bmore\b/ ) {
7542
7543         # Nope, set to more. See what's out there.
7544         my @st_more = stat('/usr/bin/more');
7545         my @st_less = stat('/usr/bin/less');
7546
7547         # is it really less, pretending to be more?
7548              $is_less = @st_more
7549           && @st_less
7550           && $st_more[0] == $st_less[0]
7551           && $st_more[1] == $st_less[1];
7552     } ## end if ($pager =~ /\bmore\b/)
7553
7554     # changes environment!
7555     # 'r' added so we don't do (slow) stats again.
7556     $fixed_less = 1 if $is_less;
7557 } ## end sub fix_less
7558
7559 =head1 DIE AND WARN MANAGEMENT
7560
7561 =head2 C<diesignal>
7562
7563 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7564 to debug a debugger problem.
7565
7566 It does its best to report the error that occurred, and then forces the
7567 program, debugger, and everything to die.
7568
7569 =cut
7570
7571 sub diesignal {
7572
7573     # No entry/exit messages.
7574     local $frame = 0;
7575
7576     # No return value prints.
7577     local $doret = -2;
7578
7579     # set the abort signal handling to the default (just terminate).
7580     $SIG{'ABRT'} = 'DEFAULT';
7581
7582     # If we enter the signal handler recursively, kill myself with an
7583     # abort signal (so we just terminate).
7584     kill 'ABRT', $$ if $panic++;
7585
7586     # If we can show detailed info, do so.
7587     if ( defined &Carp::longmess ) {
7588
7589         # Don't recursively enter the warn handler, since we're carping.
7590         local $SIG{__WARN__} = '';
7591
7592         # Skip two levels before reporting traceback: we're skipping
7593         # mydie and confess.
7594         local $Carp::CarpLevel = 2;    # mydie + confess
7595
7596         # Tell us all about it.
7597         &warn( Carp::longmess("Signal @_") );
7598     }
7599
7600     # No Carp. Tell us about the signal as best we can.
7601     else {
7602         local $\ = '';
7603         print $DB::OUT "Got signal @_\n";
7604     }
7605
7606     # Drop dead.
7607     kill 'ABRT', $$;
7608 } ## end sub diesignal
7609
7610 =head2 C<dbwarn>
7611
7612 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7613 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7614
7615 =cut
7616
7617 sub dbwarn {
7618
7619     # No entry/exit trace.
7620     local $frame = 0;
7621
7622     # No return value printing.
7623     local $doret = -2;
7624
7625     # Turn off warn and die handling to prevent recursive entries to this
7626     # routine.
7627     local $SIG{__WARN__} = '';
7628     local $SIG{__DIE__}  = '';
7629
7630     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7631     # done yet), we may not be able to do a require.
7632     eval { require Carp }
7633       if defined $^S;    # If error/warning during compilation,
7634                          # require may be broken.
7635
7636     # Use the core warn() unless Carp loaded OK.
7637     CORE::warn( @_,
7638         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7639       return
7640       unless defined &Carp::longmess;
7641
7642     # Save the current values of $single and $trace, and then turn them off.
7643     my ( $mysingle, $mytrace ) = ( $single, $trace );
7644     $single = 0;
7645     $trace  = 0;
7646
7647     # We can call Carp::longmess without its being "debugged" (which we
7648     # don't want - we just want to use it!). Capture this for later.
7649     my $mess = Carp::longmess(@_);
7650
7651     # Restore $single and $trace to their original values.
7652     ( $single, $trace ) = ( $mysingle, $mytrace );
7653
7654     # Use the debugger's own special way of printing warnings to print
7655     # the stack trace message.
7656     &warn($mess);
7657 } ## end sub dbwarn
7658
7659 =head2 C<dbdie>
7660
7661 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7662 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7663 single stepping and tracing during the call to C<Carp::longmess> to avoid
7664 debugging it - we just want to use it.
7665
7666 If C<dieLevel> is zero, we let the program being debugged handle the
7667 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7668 the debugger takes over all exception handling, printing a backtrace and
7669 displaying the exception via its C<dbwarn()> routine.
7670
7671 =cut
7672
7673 sub dbdie {
7674     local $frame         = 0;
7675     local $doret         = -2;
7676     local $SIG{__DIE__}  = '';
7677     local $SIG{__WARN__} = '';
7678     my $i      = 0;
7679     my $ineval = 0;
7680     my $sub;
7681     if ( $dieLevel > 2 ) {
7682         local $SIG{__WARN__} = \&dbwarn;
7683         &warn(@_);    # Yell no matter what
7684         return;
7685     }
7686     if ( $dieLevel < 2 ) {
7687         die @_ if $^S;    # in eval propagate
7688     }
7689
7690     # The code used to check $^S to see if compilation of the current thing
7691     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7692     eval { require Carp };
7693
7694     die( @_,
7695         "\nCannot print stack trace, load with -MCarp option to see stack" )
7696       unless defined &Carp::longmess;
7697
7698     # We do not want to debug this chunk (automatic disabling works
7699     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7700     # get the stack trace from Carp::longmess (if possible), restore $signal
7701     # and $trace, and then die with the stack trace.
7702     my ( $mysingle, $mytrace ) = ( $single, $trace );
7703     $single = 0;
7704     $trace  = 0;
7705     my $mess = "@_";
7706     {
7707
7708         package Carp;    # Do not include us in the list
7709         eval { $mess = Carp::longmess(@_); };
7710     }
7711     ( $single, $trace ) = ( $mysingle, $mytrace );
7712     die $mess;
7713 } ## end sub dbdie
7714
7715 =head2 C<warnlevel()>
7716
7717 Set the C<$DB::warnLevel> variable that stores the value of the
7718 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7719 results in the debugger taking over all warning handlers. Setting
7720 C<warnLevel> to zero leaves any warning handlers set up by the program
7721 being debugged in place.
7722
7723 =cut
7724
7725 sub warnLevel {
7726     if (@_) {
7727         $prevwarn = $SIG{__WARN__} unless $warnLevel;
7728         $warnLevel = shift;
7729         if ($warnLevel) {
7730             $SIG{__WARN__} = \&DB::dbwarn;
7731         }
7732         elsif ($prevwarn) {
7733             $SIG{__WARN__} = $prevwarn;
7734         } else {
7735             undef $SIG{__WARN__};
7736         }
7737     } ## end if (@_)
7738     $warnLevel;
7739 } ## end sub warnLevel
7740
7741 =head2 C<dielevel>
7742
7743 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7744 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7745 zero lets you use your own C<die()> handler.
7746
7747 =cut
7748
7749 sub dieLevel {
7750     local $\ = '';
7751     if (@_) {
7752         $prevdie = $SIG{__DIE__} unless $dieLevel;
7753         $dieLevel = shift;
7754         if ($dieLevel) {
7755
7756             # Always set it to dbdie() for non-zero values.
7757             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7758
7759             # No longer exists, so don't try  to use it.
7760             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7761
7762             # If we've finished initialization, mention that stack dumps
7763             # are enabled, If dieLevel is 1, we won't stack dump if we die
7764             # in an eval().
7765             print $OUT "Stack dump during die enabled",
7766               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7767               if $I_m_init;
7768
7769             # XXX This is probably obsolete, given that diehard() is gone.
7770             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7771         } ## end if ($dieLevel)
7772
7773         # Put the old one back if there was one.
7774         elsif ($prevdie) {
7775             $SIG{__DIE__} = $prevdie;
7776             print $OUT "Default die handler restored.\n";
7777         } else {
7778             undef $SIG{__DIE__};
7779             print $OUT "Die handler removed.\n";
7780         }
7781     } ## end if (@_)
7782     $dieLevel;
7783 } ## end sub dieLevel
7784
7785 =head2 C<signalLevel>
7786
7787 Number three in a series: set C<signalLevel> to zero to keep your own
7788 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
7789 takes over and handles them with C<DB::diesignal()>.
7790
7791 =cut
7792
7793 sub signalLevel {
7794     if (@_) {
7795         $prevsegv = $SIG{SEGV} unless $signalLevel;
7796         $prevbus  = $SIG{BUS}  unless $signalLevel;
7797         $signalLevel = shift;
7798         if ($signalLevel) {
7799             $SIG{SEGV} = \&DB::diesignal;
7800             $SIG{BUS}  = \&DB::diesignal;
7801         }
7802         else {
7803             $SIG{SEGV} = $prevsegv;
7804             $SIG{BUS}  = $prevbus;
7805         }
7806     } ## end if (@_)
7807     $signalLevel;
7808 } ## end sub signalLevel
7809
7810 =head1 SUBROUTINE DECODING SUPPORT
7811
7812 These subroutines are used during the C<x> and C<X> commands to try to
7813 produce as much information as possible about a code reference. They use
7814 L<Devel::Peek> to try to find the glob in which this code reference lives
7815 (if it does) - this allows us to actually code references which correspond
7816 to named subroutines (including those aliased via glob assignment).
7817
7818 =head2 C<CvGV_name()>
7819
7820 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
7821 via that routine. If this fails, return the reference again (when the
7822 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
7823
7824 =cut
7825
7826 sub CvGV_name {
7827     my $in   = shift;
7828     my $name = CvGV_name_or_bust($in);
7829     defined $name ? $name : $in;
7830 }
7831
7832 =head2 C<CvGV_name_or_bust> I<coderef>
7833
7834 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
7835 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
7836 find a glob for this ref.
7837
7838 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
7839
7840 =cut
7841
7842 sub CvGV_name_or_bust {
7843     my $in = shift;
7844     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
7845     return unless ref $in;
7846     $in = \&$in;            # Hard reference...
7847     eval { require Devel::Peek; 1 } or return;
7848     my $gv = Devel::Peek::CvGV($in) or return;
7849     *$gv{PACKAGE} . '::' . *$gv{NAME};
7850 } ## end sub CvGV_name_or_bust
7851
7852 =head2 C<find_sub>
7853
7854 A utility routine used in various places; finds the file where a subroutine
7855 was defined, and returns that filename and a line-number range.
7856
7857 Tries to use C<@sub> first; if it can't find it there, it tries building a
7858 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
7859 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
7860 this way, it brute-force searches C<%sub>, checking for identical references.
7861
7862 =cut
7863
7864 sub find_sub {
7865     my $subr = shift;
7866     $sub{$subr} or do {
7867         return unless defined &$subr;
7868         my $name = CvGV_name_or_bust($subr);
7869         my $data;
7870         $data = $sub{$name} if defined $name;
7871         return $data if defined $data;
7872
7873         # Old stupid way...
7874         $subr = \&$subr;    # Hard reference
7875         my $s;
7876         for ( keys %sub ) {
7877             $s = $_, last if $subr eq \&$_;
7878         }
7879         $sub{$s} if $s;
7880       } ## end do
7881 } ## end sub find_sub
7882
7883 =head2 C<methods>
7884
7885 A subroutine that uses the utility function C<methods_via> to find all the
7886 methods in the class corresponding to the current reference and in
7887 C<UNIVERSAL>.
7888
7889 =cut
7890
7891 sub methods {
7892
7893     # Figure out the class - either this is the class or it's a reference
7894     # to something blessed into that class.
7895     my $class = shift;
7896     $class = ref $class if ref $class;
7897
7898     local %seen;
7899
7900     # Show the methods that this class has.
7901     methods_via( $class, '', 1 );
7902
7903     # Show the methods that UNIVERSAL has.
7904     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
7905 } ## end sub methods
7906
7907 =head2 C<methods_via($class, $prefix, $crawl_upward)>
7908
7909 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
7910 all the parent class methods. C<$class> is the name of the next class to
7911 try; C<$prefix> is the message prefix, which gets built up as we go up the
7912 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
7913 higher in the C<@ISA> tree, 0 if we should stop.
7914
7915 =cut
7916
7917 sub methods_via {
7918
7919     # If we've processed this class already, just quit.
7920     my $class = shift;
7921     return if $seen{$class}++;
7922
7923     # This is a package that is contributing the methods we're about to print.
7924     my $prefix  = shift;
7925     my $prepend = $prefix ? "via $prefix: " : '';
7926     my @to_print;
7927
7928     # Extract from all the symbols in this class.
7929     while (my ($name, $glob) = each %{"${class}::"}) {
7930         # references directly in the symbol table are Proxy Constant
7931         # Subroutines, and are by their very nature defined
7932         # Otherwise, check if the thing is a typeglob, and if it is, it decays
7933         # to a subroutine reference, which can be tested by defined.
7934         # $glob might also be the value -1  (from sub foo;)
7935         # or (say) '$$' (from sub foo ($$);)
7936         # \$glob will be SCALAR in both cases.
7937         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
7938             && !$seen{$name}++) {
7939             push @to_print, "$prepend$name\n";
7940         }
7941     }
7942
7943     {
7944         local $\ = '';
7945         local $, = '';
7946         print $DB::OUT $_ foreach sort @to_print;
7947     }
7948
7949     # If the $crawl_upward argument is false, just quit here.
7950     return unless shift;
7951
7952     # $crawl_upward true: keep going up the tree.
7953     # Find all the classes this one is a subclass of.
7954     for $name ( @{"${class}::ISA"} ) {
7955
7956         # Set up the new prefix.
7957         $prepend = $prefix ? $prefix . " -> $name" : $name;
7958
7959         # Crawl up the tree and keep trying to crawl up.
7960         methods_via( $name, $prepend, 1 );
7961     }
7962 } ## end sub methods_via
7963
7964 =head2 C<setman> - figure out which command to use to show documentation
7965
7966 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
7967
7968 =cut
7969
7970 sub setman {
7971     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
7972       ? "man"         # O Happy Day!
7973       : "perldoc";    # Alas, poor unfortunates
7974 } ## end sub setman
7975
7976 =head2 C<runman> - run the appropriate command to show documentation
7977
7978 Accepts a man page name; runs the appropriate command to display it (set up
7979 during debugger initialization). Uses C<DB::system> to avoid mucking up the
7980 program's STDIN and STDOUT.
7981
7982 =cut
7983
7984 sub runman {
7985     my $page = shift;
7986     unless ($page) {
7987         &system("$doccmd $doccmd");
7988         return;
7989     }
7990
7991     # this way user can override, like with $doccmd="man -Mwhatever"
7992     # or even just "man " to disable the path check.
7993     unless ( $doccmd eq 'man' ) {
7994         &system("$doccmd $page");
7995         return;
7996     }
7997
7998     $page = 'perl' if lc($page) eq 'help';
7999
8000     require Config;
8001     my $man1dir = $Config::Config{'man1dir'};
8002     my $man3dir = $Config::Config{'man3dir'};
8003     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8004     my $manpath = '';
8005     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8006     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8007     chop $manpath if $manpath;
8008
8009     # harmless if missing, I figure
8010     my $oldpath = $ENV{MANPATH};
8011     $ENV{MANPATH} = $manpath if $manpath;
8012     my $nopathopt = $^O =~ /dunno what goes here/;
8013     if (
8014         CORE::system(
8015             $doccmd,
8016
8017             # I just *know* there are men without -M
8018             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8019             split ' ', $page
8020         )
8021       )
8022     {
8023         unless ( $page =~ /^perl\w/ ) {
8024 # do it this way because its easier to slurp in to keep up to date - clunky though.
8025 my @pods = qw(
8026     5004delta
8027     5005delta
8028     561delta
8029     56delta
8030     570delta
8031     571delta
8032     572delta
8033     573delta
8034     58delta
8035     581delta
8036     582delta
8037     583delta
8038     584delta
8039     590delta
8040     591delta
8041     592delta
8042     aix
8043     amiga
8044     apio
8045     api
8046     artistic
8047     beos
8048     book
8049     boot
8050     bot
8051     bs2000
8052     call
8053     ce
8054     cheat
8055     clib
8056     cn
8057     compile
8058     cygwin
8059     data
8060     dbmfilter
8061     debguts
8062     debtut
8063     debug
8064     delta
8065     dgux
8066     diag
8067     doc
8068     dos
8069     dsc
8070     ebcdic
8071     embed
8072     epoc
8073     faq1
8074     faq2
8075     faq3
8076     faq4
8077     faq5
8078     faq6
8079     faq7
8080     faq8
8081     faq9
8082     faq
8083     filter
8084     fork
8085     form
8086     freebsd
8087     func
8088     gpl
8089     guts
8090     hack
8091     hist
8092     hpux
8093     hurd
8094     intern
8095     intro
8096     iol
8097     ipc
8098     irix
8099     jp
8100     ko
8101     lexwarn
8102     locale
8103     lol
8104     macos
8105     macosx
8106     modinstall
8107     modlib
8108     mod
8109     modstyle
8110     mpeix
8111     netware
8112     newmod
8113     number
8114     obj
8115     opentut
8116     op
8117     os2
8118     os390
8119     os400
8120     packtut
8121     plan9
8122     pod
8123     podspec
8124     port
8125     qnx
8126     ref
8127     reftut
8128     re
8129     requick
8130     reref
8131     retut
8132     run
8133     sec
8134     solaris
8135     style
8136     sub
8137     syn
8138     thrtut
8139     tie
8140     toc
8141     todo
8142     tooc
8143     toot
8144     trap
8145     tru64
8146     tw
8147     unicode
8148     uniintro
8149     util
8150     uts
8151     var
8152     vmesa
8153     vms
8154     vos
8155     win32
8156     xs
8157     xstut
8158 );
8159             if (grep { $page eq $_ } @pods) {
8160                 $page =~ s/^/perl/;
8161                 CORE::system( $doccmd,
8162                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8163                     $page );
8164             } ## end if (grep { $page eq $_...
8165         } ## end unless ($page =~ /^perl\w/)
8166     } ## end if (CORE::system($doccmd...
8167     if ( defined $oldpath ) {
8168         $ENV{MANPATH} = $manpath;
8169     }
8170     else {
8171         delete $ENV{MANPATH};
8172     }
8173 } ## end sub runman
8174
8175 #use Carp;                          # This did break, left for debugging
8176
8177 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8178
8179 Because of the way the debugger interface to the Perl core is designed, any
8180 debugger package globals that C<DB::sub()> requires have to be defined before
8181 any subroutines can be called. These are defined in the second C<BEGIN> block.
8182
8183 This block sets things up so that (basically) the world is sane
8184 before the debugger starts executing. We set up various variables that the
8185 debugger has to have set up before the Perl core starts running:
8186
8187 =over 4
8188
8189 =item *
8190
8191 The debugger's own filehandles (copies of STD and STDOUT for now).
8192
8193 =item *
8194
8195 Characters for shell escapes, the recall command, and the history command.
8196
8197 =item *
8198
8199 The maximum recursion depth.
8200
8201 =item *
8202
8203 The size of a C<w> command's window.
8204
8205 =item *
8206
8207 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8208
8209 =item *
8210
8211 The fact that we're not in a sub at all right now.
8212
8213 =item *
8214
8215 The default SIGINT handler for the debugger.
8216
8217 =item *
8218
8219 The appropriate value of the flag in C<$^D> that says the debugger is running
8220
8221 =item *
8222
8223 The current debugger recursion level
8224
8225 =item *
8226
8227 The list of postponed items and the C<$single> stack (XXX define this)
8228
8229 =item *
8230
8231 That we want no return values and no subroutine entry/exit trace.
8232
8233 =back
8234
8235 =cut
8236
8237 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8238
8239 BEGIN {    # This does not compile, alas. (XXX eh?)
8240     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8241     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8242
8243     # Define characters used by command parsing.
8244     $sh       = '!';      # Shell escape (does not work)
8245     $rc       = ',';      # Recall command (does not work)
8246     @hist     = ('?');    # Show history (does not work)
8247     @truehist = ();       # Can be saved for replay (per session)
8248
8249     # This defines the point at which you get the 'deep recursion'
8250     # warning. It MUST be defined or the debugger will not load.
8251     $deep = 100;
8252
8253     # Number of lines around the current one that are shown in the
8254     # 'w' command.
8255     $window = 10;
8256
8257     # How much before-the-current-line context the 'v' command should
8258     # use in calculating the start of the window it will display.
8259     $preview = 3;
8260
8261     # We're not in any sub yet, but we need this to be a defined value.
8262     $sub = '';
8263
8264     # Set up the debugger's interrupt handler. It simply sets a flag
8265     # ($signal) that DB::DB() will check before each command is executed.
8266     $SIG{INT} = \&DB::catch;
8267
8268     # The following lines supposedly, if uncommented, allow the debugger to
8269     # debug itself. Perhaps we can try that someday.
8270     # This may be enabled to debug debugger:
8271     #$warnLevel = 1 unless defined $warnLevel;
8272     #$dieLevel = 1 unless defined $dieLevel;
8273     #$signalLevel = 1 unless defined $signalLevel;
8274
8275     # This is the flag that says "a debugger is running, please call
8276     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8277     # execute anything in the user's context, because we always want to
8278     # get control back.
8279     $db_stop = 0;          # Compiler warning ...
8280     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8281
8282     # This variable records how many levels we're nested in debugging. Used
8283     # Used in the debugger prompt, and in determining whether it's all over or
8284     # not.
8285     $level = 0;            # Level of recursive debugging
8286
8287     # "Triggers bug (?) in perl if we postpone this until runtime."
8288     # XXX No details on this yet, or whether we should fix the bug instead
8289     # of work around it. Stay tuned.
8290     @postponed = @stack = (0);
8291
8292     # Used to track the current stack depth using the auto-stacked-variable
8293     # trick.
8294     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8295
8296     # Don't print return values on exiting a subroutine.
8297     $doret = -2;
8298
8299     # No extry/exit tracing.
8300     $frame = 0;
8301
8302 } ## end BEGIN
8303
8304 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8305
8306 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8307
8308 =head2 db_complete
8309
8310 C<readline> support - adds command completion to basic C<readline>.
8311
8312 Returns a list of possible completions to C<readline> when invoked. C<readline>
8313 will print the longest common substring following the text already entered.
8314
8315 If there is only a single possible completion, C<readline> will use it in full.
8316
8317 This code uses C<map> and C<grep> heavily to create lists of possible
8318 completion. Think LISP in this section.
8319
8320 =cut
8321
8322 sub db_complete {
8323
8324     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8325     # $text is the text to be completed.
8326     # $line is the incoming line typed by the user.
8327     # $start is the start of the text to be completed in the incoming line.
8328     my ( $text, $line, $start ) = @_;
8329
8330     # Save the initial text.
8331     # The search pattern is current package, ::, extract the next qualifier
8332     # Prefix and pack are set to undef.
8333     my ( $itext, $search, $prefix, $pack ) =
8334       ( $text, "^\Q${'package'}::\E([^:]+)\$" );
8335
8336 =head3 C<b postpone|compile>
8337
8338 =over 4
8339
8340 =item *
8341
8342 Find all the subroutines that might match in this package
8343
8344 =item *
8345
8346 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8347
8348 =item *
8349
8350 Include all the rest of the subs that are known
8351
8352 =item *
8353
8354 C<grep> out the ones that match the text we have so far
8355
8356 =item *
8357
8358 Return this as the list of possible completions
8359
8360 =back
8361
8362 =cut
8363
8364     return sort grep /^\Q$text/, ( keys %sub ),
8365       qw(postpone load compile),    # subroutines
8366       ( map { /$search/ ? ($1) : () } keys %sub )
8367       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8368
8369 =head3 C<b load>
8370
8371 Get all the possible files from C<@INC> as it currently stands and
8372 select the ones that match the text so far.
8373
8374 =cut
8375
8376     return sort grep /^\Q$text/, values %INC    # files
8377       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8378
8379 =head3  C<V> (list variable) and C<m> (list modules)
8380
8381 There are two entry points for these commands:
8382
8383 =head4 Unqualified package names
8384
8385 Get the top-level packages and grab everything that matches the text
8386 so far. For each match, recursively complete the partial packages to
8387 get all possible matching packages. Return this sorted list.
8388
8389 =cut
8390
8391     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8392       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8393       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8394
8395 =head4 Qualified package names
8396
8397 Take a partially-qualified package and find all subpackages for it
8398 by getting all the subpackages for the package so far, matching all
8399 the subpackages against the text, and discarding all of them which
8400 start with 'main::'. Return this list.
8401
8402 =cut
8403
8404     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8405       grep !/^main::/, grep /^\Q$text/,
8406       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () } keys %{ $prefix . '::' }
8407       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8408       and $text =~ /^(.*[^:])::?(\w*)$/
8409       and $prefix = $1;
8410
8411 =head3 C<f> - switch files
8412
8413 Here, we want to get a fully-qualified filename for the C<f> command.
8414 Possibilities are:
8415
8416 =over 4
8417
8418 =item 1. The original source file itself
8419
8420 =item 2. A file from C<@INC>
8421
8422 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8423
8424 =back
8425
8426 =cut
8427
8428     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8429            # We might possibly want to switch to an eval (which has a "filename"
8430            # like '(eval 9)'), so we may need to clean up the completion text
8431            # before proceeding.
8432         $prefix = length($1) - length($text);
8433         $text   = $1;
8434
8435 =pod
8436
8437 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8438 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8439 out of C<%main::>, add the initial source file, and extract the ones that
8440 match the completion text so far.
8441
8442 =cut
8443
8444         return sort
8445           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8446           $0;
8447     } ## end if ($line =~ /^\|*f\s+(.*)/)
8448
8449 =head3 Subroutine name completion
8450
8451 We look through all of the defined subs (the keys of C<%sub>) and
8452 return both all the possible matches to the subroutine name plus
8453 all the matches qualified to the current package.
8454
8455 =cut
8456
8457     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8458         $text = substr $text, 1;
8459         $prefix = "&";
8460         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8461           (
8462             map { /$search/ ? ($1) : () }
8463               keys %sub
8464           );
8465     } ## end if ((substr $text, 0, ...
8466
8467 =head3  Scalar, array, and hash completion: partially qualified package
8468
8469 Much like the above, except we have to do a little more cleanup:
8470
8471 =cut
8472
8473     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8474
8475 =pod
8476
8477 =over 4
8478
8479 =item *
8480
8481 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8482
8483 =cut
8484
8485         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8486
8487 =pod
8488
8489 =item *
8490
8491 Figure out the prefix vs. what needs completing.
8492
8493 =cut
8494
8495         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8496         $text   = $2;
8497
8498 =pod
8499
8500 =item *
8501
8502 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8503
8504 =cut
8505
8506         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8507           keys %$pack;
8508
8509 =pod
8510
8511 =item *
8512
8513 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8514
8515 =cut
8516
8517         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8518             return db_complete( $out[0], $line, $start );
8519         }
8520
8521         # Return the list of possibles.
8522         return sort @out;
8523
8524     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8525
8526 =pod
8527
8528 =back
8529
8530 =head3 Symbol completion: current package or package C<main>.
8531
8532 =cut
8533
8534     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8535 =pod
8536
8537 =over 4
8538
8539 =item *
8540
8541 If it's C<main>, delete main to just get C<::> leading.
8542
8543 =cut
8544
8545         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8546
8547 =pod
8548
8549 =item *
8550
8551 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8552
8553 =cut
8554
8555         $prefix = substr $text, 0, 1;
8556         $text   = substr $text, 1;
8557
8558         my @out;
8559
8560 =pod
8561
8562 =item *
8563
8564 We look for the lexical scope above DB::DB and auto-complete lexical variables
8565 if PadWalker could be loaded.
8566
8567 =cut
8568
8569         if (not $text =~ /::/ and eval { require PadWalker } ) {
8570             my $level = 1;
8571             while (1) {
8572                 my @info = caller($level);
8573                 $level++;
8574                 $level = -1, last
8575                   if not @info;
8576                 last if $info[3] eq 'DB::DB';
8577             }
8578             if ($level > 0) {
8579                 my $lexicals = PadWalker::peek_my($level);
8580                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
8581             }
8582         }
8583
8584 =pod
8585
8586 =item *
8587
8588 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8589
8590 =cut
8591
8592         push @out, map "$prefix$_", grep /^\Q$text/,
8593           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8594           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8595
8596 =item *
8597
8598 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8599
8600 =back
8601
8602 =cut
8603
8604         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8605             return db_complete( $out[0], $line, $start );
8606         }
8607
8608         # Return the list of possibles.
8609         return sort @out;
8610     } ## end if ($text =~ /^[\$@%]/)
8611
8612 =head3 Options
8613
8614 We use C<option_val()> to look up the current value of the option. If there's
8615 only a single value, we complete the command in such a way that it is a
8616 complete command for setting the option in question. If there are multiple
8617 possible values, we generate a command consisting of the option plus a trailing
8618 question mark, which, if executed, will list the current value of the option.
8619
8620 =cut
8621
8622     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8623     {    # Options after space
8624            # We look for the text to be matched in the list of possible options,
8625            # and fetch the current value.
8626         my @out = grep /^\Q$text/, @options;
8627         my $val = option_val( $out[0], undef );
8628
8629         # Set up a 'query option's value' command.
8630         my $out = '? ';
8631         if ( not defined $val or $val =~ /[\n\r]/ ) {
8632
8633             # There's really nothing else we can do.
8634         }
8635
8636         # We have a value. Create a proper option-setting command.
8637         elsif ( $val =~ /\s/ ) {
8638
8639             # XXX This may be an extraneous variable.
8640             my $found;
8641
8642             # We'll want to quote the string (because of the embedded
8643             # whtespace), but we want to make sure we don't end up with
8644             # mismatched quote characters. We try several possibilities.
8645             foreach $l ( split //, qq/\"\'\#\|/ ) {
8646
8647                 # If we didn't find this quote character in the value,
8648                 # quote it using this quote character.
8649                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8650             }
8651         } ## end elsif ($val =~ /\s/)
8652
8653         # Don't need any quotes.
8654         else {
8655             $out = "=$val ";
8656         }
8657
8658         # If there were multiple possible values, return '? ', which
8659         # makes the command into a query command. If there was just one,
8660         # have readline append that.
8661         $rl_attribs->{completer_terminator_character} =
8662           ( @out == 1 ? $out : '? ' );
8663
8664         # Return list of possibilities.
8665         return sort @out;
8666     } ## end if ((substr $line, 0, ...
8667
8668 =head3 Filename completion
8669
8670 For entering filenames. We simply call C<readline>'s C<filename_list()>
8671 method with the completion text to get the possible completions.
8672
8673 =cut
8674
8675     return $term->filename_list($text);    # filenames
8676
8677 } ## end sub db_complete
8678
8679 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8680
8681 Functions that possibly ought to be somewhere else.
8682
8683 =head2 end_report
8684
8685 Say we're done.
8686
8687 =cut
8688
8689 sub end_report {
8690     local $\ = '';
8691     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
8692 }
8693
8694 =head2 clean_ENV
8695
8696 If we have $ini_pids, save it in the environment; else remove it from the
8697 environment. Used by the C<R> (restart) command.
8698
8699 =cut
8700
8701 sub clean_ENV {
8702     if ( defined($ini_pids) ) {
8703         $ENV{PERLDB_PIDS} = $ini_pids;
8704     }
8705     else {
8706         delete( $ENV{PERLDB_PIDS} );
8707     }
8708 } ## end sub clean_ENV
8709
8710 # PERLDBf_... flag names from perl.h
8711 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8712
8713 BEGIN {
8714     %DollarCaretP_flags = (
8715         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8716         PERLDBf_LINE      => 0x02,     # Keep line #
8717         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8718         PERLDBf_INTER     => 0x08,     # Preserve more data
8719         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8720         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8721         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8722         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8723         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8724         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8725         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
8726         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
8727     );
8728     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
8729     # doesn't need to set it. It's provided for the benefit of profilers and
8730     # other code analysers.
8731
8732     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8733 }
8734
8735 sub parse_DollarCaretP_flags {
8736     my $flags = shift;
8737     $flags =~ s/^\s+//;
8738     $flags =~ s/\s+$//;
8739     my $acu = 0;
8740     foreach my $f ( split /\s*\|\s*/, $flags ) {
8741         my $value;
8742         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8743             $value = hex $1;
8744         }
8745         elsif ( $f =~ /^(\d+)$/ ) {
8746             $value = int $1;
8747         }
8748         elsif ( $f =~ /^DEFAULT$/i ) {
8749             $value = $DollarCaretP_flags{PERLDB_ALL};
8750         }
8751         else {
8752             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8753             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8754             unless ( defined $value ) {
8755                 print $OUT (
8756                     "Unrecognized \$^P flag '$f'!\n",
8757                     "Acceptable flags are: "
8758                       . join( ', ', sort keys %DollarCaretP_flags ),
8759                     ", and hexadecimal and decimal numbers.\n"
8760                 );
8761                 return undef;
8762             }
8763         }
8764         $acu |= $value;
8765     }
8766     $acu;
8767 }
8768
8769 sub expand_DollarCaretP_flags {
8770     my $DollarCaretP = shift;
8771     my @bits         = (
8772         map {
8773             my $n = ( 1 << $_ );
8774             ( $DollarCaretP & $n )
8775               ? ( $DollarCaretP_flags_r{$n}
8776                   || sprintf( '0x%x', $n ) )
8777               : ()
8778           } 0 .. 31
8779     );
8780     return @bits ? join( '|', @bits ) : 0;
8781 }
8782
8783 =over 4
8784
8785 =item rerun
8786
8787 Rerun the current session to:
8788
8789     rerun        current position
8790
8791     rerun 4      command number 4
8792
8793     rerun -4     current command minus 4 (go back 4 steps)
8794
8795 Whether this always makes sense, in the current context is unknowable, and is
8796 in part left as a useful exercise for the reader.  This sub returns the
8797 appropriate arguments to rerun the current session.
8798
8799 =cut
8800
8801 sub rerun {
8802     my $i = shift;
8803     my @args;
8804     pop(@truehist);                      # strim
8805     unless (defined $truehist[$i]) {
8806         print "Unable to return to non-existent command: $i\n";
8807     } else {
8808         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
8809         my @temp = @truehist;            # store
8810         push(@DB::typeahead, @truehist); # saved
8811         @truehist = @hist = ();          # flush
8812         @args = &restart();              # setup
8813         &get_list("PERLDB_HIST");        # clean
8814         &set_list("PERLDB_HIST", @temp); # reset
8815     }
8816     return @args;
8817 }
8818
8819 =item restart
8820
8821 Restarting the debugger is a complex operation that occurs in several phases.
8822 First, we try to reconstruct the command line that was used to invoke Perl
8823 and the debugger.
8824
8825 =cut
8826
8827 sub restart {
8828     # I may not be able to resurrect you, but here goes ...
8829     print $OUT
8830 "Warning: some settings and command-line options may be lost!\n";
8831     my ( @script, @flags, $cl );
8832
8833     # If warn was on before, turn it on again.
8834     push @flags, '-w' if $ini_warn;
8835
8836     # Rebuild the -I flags that were on the initial
8837     # command line.
8838     for (@ini_INC) {
8839         push @flags, '-I', $_;
8840     }
8841
8842     # Turn on taint if it was on before.
8843     push @flags, '-T' if ${^TAINT};
8844
8845     # Arrange for setting the old INC:
8846     # Save the current @init_INC in the environment.
8847     set_list( "PERLDB_INC", @ini_INC );
8848
8849     # If this was a perl one-liner, go to the "file"
8850     # corresponding to the one-liner read all the lines
8851     # out of it (except for the first one, which is going
8852     # to be added back on again when 'perl -d' runs: that's
8853     # the 'require perl5db.pl;' line), and add them back on
8854     # to the command line to be executed.
8855     if ( $0 eq '-e' ) {
8856         for ( 1 .. $#{'::_<-e'} ) {  # The first line is PERL5DB
8857             chomp( $cl = ${'::_<-e'}[$_] );
8858             push @script, '-e', $cl;
8859         }
8860     } ## end if ($0 eq '-e')
8861
8862     # Otherwise we just reuse the original name we had
8863     # before.
8864     else {
8865         @script = $0;
8866     }
8867
8868 =pod
8869
8870 After the command line  has been reconstructed, the next step is to save
8871 the debugger's status in environment variables. The C<DB::set_list> routine
8872 is used to save aggregate variables (both hashes and arrays); scalars are
8873 just popped into environment variables directly.
8874
8875 =cut
8876
8877     # If the terminal supported history, grab it and
8878     # save that in the environment.
8879     set_list( "PERLDB_HIST",
8880           $term->Features->{getHistory}
8881         ? $term->GetHistory
8882         : @hist );
8883
8884     # Find all the files that were visited during this
8885     # session (i.e., the debugger had magic hashes
8886     # corresponding to them) and stick them in the environment.
8887     my @had_breakpoints = keys %had_breakpoints;
8888     set_list( "PERLDB_VISITED", @had_breakpoints );
8889
8890     # Save the debugger options we chose.
8891     set_list( "PERLDB_OPT", %option );
8892     # set_list( "PERLDB_OPT", options2remember() );
8893
8894     # Save the break-on-loads.
8895     set_list( "PERLDB_ON_LOAD", %break_on_load );
8896
8897 =pod
8898
8899 The most complex part of this is the saving of all of the breakpoints. They
8900 can live in an awful lot of places, and we have to go through all of them,
8901 find the breakpoints, and then save them in the appropriate environment
8902 variable via C<DB::set_list>.
8903
8904 =cut
8905
8906     # Go through all the breakpoints and make sure they're
8907     # still valid.
8908     my @hard;
8909     for ( 0 .. $#had_breakpoints ) {
8910
8911         # We were in this file.
8912         my $file = $had_breakpoints[$_];
8913
8914         # Grab that file's magic line hash.
8915         *dbline = $main::{ '_<' . $file };
8916
8917         # Skip out if it doesn't exist, or if the breakpoint
8918         # is in a postponed file (we'll do postponed ones
8919         # later).
8920         next unless %dbline or $postponed_file{$file};
8921
8922         # In an eval. This is a little harder, so we'll
8923         # do more processing on that below.
8924         ( push @hard, $file ), next
8925           if $file =~ /^\(\w*eval/;
8926
8927         # XXX I have no idea what this is doing. Yet.
8928         my @add;
8929         @add = %{ $postponed_file{$file} }
8930           if $postponed_file{$file};
8931
8932         # Save the list of all the breakpoints for this file.
8933         set_list( "PERLDB_FILE_$_", %dbline, @add );
8934
8935         # Serialize the extra data %breakpoints_data hash.
8936         # That's a bug fix.
8937         set_list( "PERLDB_FILE_ENABLED_$_",
8938             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
8939             sort { $a <=> $b } keys(%dbline)
8940         )
8941     } ## end for (0 .. $#had_breakpoints)
8942
8943     # The breakpoint was inside an eval. This is a little
8944     # more difficult. XXX and I don't understand it.
8945     for (@hard) {
8946         # Get over to the eval in question.
8947         *dbline = $main::{ '_<' . $_ };
8948         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
8949         for $sub ( keys %sub ) {
8950             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
8951             $subs{$sub} = [ $1, $2 ];
8952         }
8953         unless (%subs) {
8954             print $OUT
8955               "No subroutines in $_, ignoring breakpoints.\n";
8956             next;
8957         }
8958       LINES: for $line ( keys %dbline ) {
8959
8960             # One breakpoint per sub only:
8961             my ( $offset, $sub, $found );
8962           SUBS: for $sub ( keys %subs ) {
8963                 if (
8964                     $subs{$sub}->[1] >=
8965                     $line    # Not after the subroutine
8966                     and (
8967                         not defined $offset    # Not caught
8968                         or $offset < 0
8969                     )
8970                   )
8971                 {                              # or badly caught
8972                     $found  = $sub;
8973                     $offset = $line - $subs{$sub}->[0];
8974                     $offset = "+$offset", last SUBS
8975                       if $offset >= 0;
8976                 } ## end if ($subs{$sub}->[1] >=...
8977             } ## end for $sub (keys %subs)
8978             if ( defined $offset ) {
8979                 $postponed{$found} =
8980                   "break $offset if $dbline{$line}";
8981             }
8982             else {
8983                 print $OUT
8984 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
8985             }
8986         } ## end for $line (keys %dbline)
8987     } ## end for (@hard)
8988
8989     # Save the other things that don't need to be
8990     # processed.
8991     set_list( "PERLDB_POSTPONE",  %postponed );
8992     set_list( "PERLDB_PRETYPE",   @$pretype );
8993     set_list( "PERLDB_PRE",       @$pre );
8994     set_list( "PERLDB_POST",      @$post );
8995     set_list( "PERLDB_TYPEAHEAD", @typeahead );
8996
8997     # We are officially restarting.
8998     $ENV{PERLDB_RESTART} = 1;
8999
9000     # We are junking all child debuggers.
9001     delete $ENV{PERLDB_PIDS};    # Restore ini state
9002
9003     # Set this back to the initial pid.
9004     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9005
9006 =pod
9007
9008 After all the debugger status has been saved, we take the command we built up
9009 and then return it, so we can C<exec()> it. The debugger will spot the
9010 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9011 from the environment.
9012
9013 =cut
9014
9015     # And run Perl again. Add the "-d" flag, all the
9016     # flags we built up, the script (whether a one-liner
9017     # or a file), add on the -emacs flag for a slave editor,
9018     # and then the old arguments.
9019
9020     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9021
9022 };  # end restart
9023
9024 =back
9025
9026 =head1 END PROCESSING - THE C<END> BLOCK
9027
9028 Come here at the very end of processing. We want to go into a
9029 loop where we allow the user to enter commands and interact with the
9030 debugger, but we don't want anything else to execute.
9031
9032 First we set the C<$finished> variable, so that some commands that
9033 shouldn't be run after the end of program quit working.
9034
9035 We then figure out whether we're truly done (as in the user entered a C<q>
9036 command, or we finished execution while running nonstop). If we aren't,
9037 we set C<$single> to 1 (causing the debugger to get control again).
9038
9039 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9040 message and returns control to the debugger. Repeat.
9041
9042 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9043 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9044 break, run to completion.).
9045
9046 =cut
9047
9048 END {
9049     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9050     $fall_off_end = 1 unless $inhibit_exit;
9051
9052     # Do not stop in at_exit() and destructors on exit:
9053     if ($fall_off_end or $runnonstop) {
9054         &save_hist();
9055     } else {
9056         $DB::single = 1;
9057         DB::fake::at_exit();
9058     }
9059 } ## end END
9060
9061 =head1 PRE-5.8 COMMANDS
9062
9063 Some of the commands changed function quite a bit in the 5.8 command
9064 realignment, so much so that the old code had to be replaced completely.
9065 Because we wanted to retain the option of being able to go back to the
9066 former command set, we moved the old code off to this section.
9067
9068 There's an awful lot of duplicated code here. We've duplicated the
9069 comments to keep things clear.
9070
9071 =head2 Null command
9072
9073 Does nothing. Used to I<turn off> commands.
9074
9075 =cut
9076
9077 sub cmd_pre580_null {
9078
9079     # do nothing...
9080 }
9081
9082 =head2 Old C<a> command.
9083
9084 This version added actions if you supplied them, and deleted them
9085 if you didn't.
9086
9087 =cut
9088
9089 sub cmd_pre580_a {
9090     my $xcmd = shift;
9091     my $cmd  = shift;
9092
9093     # Argument supplied. Add the action.
9094     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9095
9096         # If the line isn't there, use the current line.
9097         $i = $1 || $line;
9098         $j = $2;
9099
9100         # If there is an action ...
9101         if ( length $j ) {
9102
9103             # ... but the line isn't breakable, skip it.
9104             if ( $dbline[$i] == 0 ) {
9105                 print $OUT "Line $i may not have an action.\n";
9106             }
9107             else {
9108
9109                 # ... and the line is breakable:
9110                 # Mark that there's an action in this file.
9111                 $had_breakpoints{$filename} |= 2;
9112
9113                 # Delete any current action.
9114                 $dbline{$i} =~ s/\0[^\0]*//;
9115
9116                 # Add the new action, continuing the line as needed.
9117                 $dbline{$i} .= "\0" . action($j);
9118             }
9119         } ## end if (length $j)
9120
9121         # No action supplied.
9122         else {
9123
9124             # Delete the action.
9125             $dbline{$i} =~ s/\0[^\0]*//;
9126
9127             # Mark as having no break or action if nothing's left.
9128             delete $dbline{$i} if $dbline{$i} eq '';
9129         }
9130     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9131 } ## end sub cmd_pre580_a
9132
9133 =head2 Old C<b> command
9134
9135 Add breakpoints.
9136
9137 =cut
9138
9139 sub cmd_pre580_b {
9140     my $xcmd   = shift;
9141     my $cmd    = shift;
9142     my $dbline = shift;
9143
9144     # Break on load.
9145     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9146         my $file = $1;
9147         $file =~ s/\s+$//;
9148         &cmd_b_load($file);
9149     }
9150
9151     # b compile|postpone <some sub> [<condition>]
9152     # The interpreter actually traps this one for us; we just put the
9153     # necessary condition in the %postponed hash.
9154     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9155
9156         # Capture the condition if there is one. Make it true if none.
9157         my $cond = length $3 ? $3 : '1';
9158
9159         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9160         # if it was 'compile'.
9161         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9162
9163         # De-Perl4-ify the name - ' separators to ::.
9164         $subname =~ s/\'/::/g;
9165
9166         # Qualify it into the current package unless it's already qualified.
9167         $subname = "${'package'}::" . $subname
9168           unless $subname =~ /::/;
9169
9170         # Add main if it starts with ::.
9171         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9172
9173         # Save the break type for this sub.
9174         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9175     } ## end elsif ($cmd =~ ...
9176
9177     # b <sub name> [<condition>]
9178     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9179         my $subname = $1;
9180         my $cond = length $2 ? $2 : '1';
9181         &cmd_b_sub( $subname, $cond );
9182     }
9183     # b <line> [<condition>].
9184     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9185         my $i = $1 || $dbline;
9186         my $cond = length $2 ? $2 : '1';
9187         &cmd_b_line( $i, $cond );
9188     }
9189 } ## end sub cmd_pre580_b
9190
9191 =head2 Old C<D> command.
9192
9193 Delete all breakpoints unconditionally.
9194
9195 =cut
9196
9197 sub cmd_pre580_D {
9198     my $xcmd = shift;
9199     my $cmd  = shift;
9200     if ( $cmd =~ /^\s*$/ ) {
9201         print $OUT "Deleting all breakpoints...\n";
9202
9203         # %had_breakpoints lists every file that had at least one
9204         # breakpoint in it.
9205         my $file;
9206         for $file ( keys %had_breakpoints ) {
9207
9208             # Switch to the desired file temporarily.
9209             local *dbline = $main::{ '_<' . $file };
9210
9211             my $max = $#dbline;
9212             my $was;
9213
9214             # For all lines in this file ...
9215             for ( $i = 1 ; $i <= $max ; $i++ ) {
9216
9217                 # If there's a breakpoint or action on this line ...
9218                 if ( defined $dbline{$i} ) {
9219
9220                     # ... remove the breakpoint.
9221                     $dbline{$i} =~ s/^[^\0]+//;
9222                     if ( $dbline{$i} =~ s/^\0?$// ) {
9223
9224                         # Remove the entry altogether if no action is there.
9225                         delete $dbline{$i};
9226                     }
9227                 } ## end if (defined $dbline{$i...
9228             } ## end for ($i = 1 ; $i <= $max...
9229
9230             # If, after we turn off the "there were breakpoints in this file"
9231             # bit, the entry in %had_breakpoints for this file is zero,
9232             # we should remove this file from the hash.
9233             if ( not $had_breakpoints{$file} &= ~1 ) {
9234                 delete $had_breakpoints{$file};
9235             }
9236         } ## end for $file (keys %had_breakpoints)
9237
9238         # Kill off all the other breakpoints that are waiting for files that
9239         # haven't been loaded yet.
9240         undef %postponed;
9241         undef %postponed_file;
9242         undef %break_on_load;
9243     } ## end if ($cmd =~ /^\s*$/)
9244 } ## end sub cmd_pre580_D
9245
9246 =head2 Old C<h> command
9247
9248 Print help. Defaults to printing the long-form help; the 5.8 version
9249 prints the summary by default.
9250
9251 =cut
9252
9253 sub cmd_pre580_h {
9254     my $xcmd = shift;
9255     my $cmd  = shift;
9256
9257     # Print the *right* help, long format.
9258     if ( $cmd =~ /^\s*$/ ) {
9259         print_help($pre580_help);
9260     }
9261
9262     # 'h h' - explicitly-requested summary.
9263     elsif ( $cmd =~ /^h\s*/ ) {
9264         print_help($pre580_summary);
9265     }
9266
9267     # Find and print a command's help.
9268     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9269         my $asked  = $1;                   # for proper errmsg
9270         my $qasked = quotemeta($asked);    # for searching
9271                                            # XXX: finds CR but not <CR>
9272         if (
9273             $pre580_help =~ /^
9274                               <?           # Optional '<'
9275                               (?:[IB]<)    # Optional markup
9276                               $qasked      # The command name
9277                             /mx
9278           )
9279         {
9280
9281             while (
9282                 $pre580_help =~ /^
9283                                   (             # The command help:
9284                                    <?           # Optional '<'
9285                                    (?:[IB]<)    # Optional markup
9286                                    $qasked      # The command name
9287                                    ([\s\S]*?)   # Lines starting with tabs
9288                                    \n           # Final newline
9289                                   )
9290                                   (?!\s)/mgx
9291               )    # Line not starting with space
9292                    # (Next command's help)
9293             {
9294                 print_help($1);
9295             }
9296         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9297
9298         # Help not found.
9299         else {
9300             print_help("B<$asked> is not a debugger command.\n");
9301         }
9302     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9303 } ## end sub cmd_pre580_h
9304
9305 =head2 Old C<W> command
9306
9307 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9308
9309 =cut
9310
9311 sub cmd_pre580_W {
9312     my $xcmd = shift;
9313     my $cmd  = shift;
9314
9315     # Delete all watch expressions.
9316     if ( $cmd =~ /^$/ ) {
9317
9318         # No watching is going on.
9319         $trace &= ~2;
9320
9321         # Kill all the watch expressions and values.
9322         @to_watch = @old_watch = ();
9323     }
9324
9325     # Add a watch expression.
9326     elsif ( $cmd =~ /^(.*)/s ) {
9327
9328         # add it to the list to be watched.
9329         push @to_watch, $1;
9330
9331         # Get the current value of the expression.
9332         # Doesn't handle expressions returning list values!
9333         $evalarg = $1;
9334         my ($val) = &eval;
9335         $val = ( defined $val ) ? "'$val'" : 'undef';
9336
9337         # Save it.
9338         push @old_watch, $val;
9339
9340         # We're watching stuff.
9341         $trace |= 2;
9342
9343     } ## end elsif ($cmd =~ /^(.*)/s)
9344 } ## end sub cmd_pre580_W
9345
9346 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9347
9348 The debugger used to have a bunch of nearly-identical code to handle
9349 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9350 C<cmd_prepost> unify all this into one set of code to handle the
9351 appropriate actions.
9352
9353 =head2 C<cmd_pre590_prepost>
9354
9355 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9356 do something destructive. In pre 5.8 debuggers, the default action was to
9357 delete all the actions.
9358
9359 =cut
9360
9361 sub cmd_pre590_prepost {
9362     my $cmd    = shift;
9363     my $line   = shift || '*';
9364     my $dbline = shift;
9365
9366     return &cmd_prepost( $cmd, $line, $dbline );
9367 } ## end sub cmd_pre590_prepost
9368
9369 =head2 C<cmd_prepost>
9370
9371 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9372 Since the lists of actions are all held in arrays that are pointed to by
9373 references anyway, all we have to do is pick the right array reference and
9374 then use generic code to all, delete, or list actions.
9375
9376 =cut
9377
9378 sub cmd_prepost {
9379     my $cmd = shift;
9380
9381     # No action supplied defaults to 'list'.
9382     my $line = shift || '?';
9383
9384     # Figure out what to put in the prompt.
9385     my $which = '';
9386
9387     # Make sure we have some array or another to address later.
9388     # This means that if ssome reason the tests fail, we won't be
9389     # trying to stash actions or delete them from the wrong place.
9390     my $aref = [];
9391
9392     # < - Perl code to run before prompt.
9393     if ( $cmd =~ /^\</o ) {
9394         $which = 'pre-perl';
9395         $aref  = $pre;
9396     }
9397
9398     # > - Perl code to run after prompt.
9399     elsif ( $cmd =~ /^\>/o ) {
9400         $which = 'post-perl';
9401         $aref  = $post;
9402     }
9403
9404     # { - first check for properly-balanced braces.
9405     elsif ( $cmd =~ /^\{/o ) {
9406         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9407             print $OUT
9408 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
9409         }
9410
9411         # Properly balanced. Pre-prompt debugger actions.
9412         else {
9413             $which = 'pre-debugger';
9414             $aref  = $pretype;
9415         }
9416     } ## end elsif ( $cmd =~ /^\{/o )
9417
9418     # Did we find something that makes sense?
9419     unless ($which) {
9420         print $OUT "Confused by command: $cmd\n";
9421     }
9422
9423     # Yes.
9424     else {
9425
9426         # List actions.
9427         if ( $line =~ /^\s*\?\s*$/o ) {
9428             unless (@$aref) {
9429
9430                 # Nothing there. Complain.
9431                 print $OUT "No $which actions.\n";
9432             }
9433             else {
9434
9435                 # List the actions in the selected list.
9436                 print $OUT "$which commands:\n";
9437                 foreach my $action (@$aref) {
9438                     print $OUT "\t$cmd -- $action\n";
9439                 }
9440             } ## end else
9441         } ## end if ( $line =~ /^\s*\?\s*$/o)
9442
9443         # Might be a delete.
9444         else {
9445             if ( length($cmd) == 1 ) {
9446                 if ( $line =~ /^\s*\*\s*$/o ) {
9447
9448                     # It's a delete. Get rid of the old actions in the
9449                     # selected list..
9450                     @$aref = ();
9451                     print $OUT "All $cmd actions cleared.\n";
9452                 }
9453                 else {
9454
9455                     # Replace all the actions. (This is a <, >, or {).
9456                     @$aref = action($line);
9457                 }
9458             } ## end if ( length($cmd) == 1)
9459             elsif ( length($cmd) == 2 ) {
9460
9461                 # Add the action to the line. (This is a <<, >>, or {{).
9462                 push @$aref, action($line);
9463             }
9464             else {
9465
9466                 # <<<, >>>>, {{{{{{ ... something not a command.
9467                 print $OUT
9468                   "Confused by strange length of $which command($cmd)...\n";
9469             }
9470         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9471     } ## end else
9472 } ## end sub cmd_prepost
9473
9474 =head1 C<DB::fake>
9475
9476 Contains the C<at_exit> routine that the debugger uses to issue the
9477 C<Debugged program terminated ...> message after the program completes. See
9478 the C<END> block documentation for more details.
9479
9480 =cut
9481
9482 package DB::fake;
9483
9484 sub at_exit {
9485     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
9486 }
9487
9488 package DB;    # Do not trace this 1; below!
9489
9490 1;
9491
9492