t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still currrent
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17
  18 # directories with special sets of test switches
  19 my %dir_to_switch =
  20     (base => '',
  21      comp => '',
  22      run => '',
  23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  24      );
  25
  26 # "not absolute" is the the default, as it saves some fakery within TestInit
  27 # which can peturb tests, and takes CPU. Working with the upstream author of
  28 # any of these, to figure out how to remove them from this list, considered
  29 # "a good thing".
  30 my %abs = (
  31            '../cpan/Archive-Extract' => 1,
  32            '../cpan/Archive-Tar' => 1,
  33            '../cpan/AutoLoader' => 1,
  34            '../cpan/CPAN' => 1,
  35            '../cpan/Class-ISA' => 1,
  36            '../cpan/Cwd' => 1,
  37            '../cpan/Devel-PPPort' => 1,
  38            '../cpan/Encode' => 1,
  39            '../cpan/ExtUtils-Command' => 1,
  40            '../cpan/ExtUtils-Constant' => 1,
  41            '../cpan/ExtUtils-MakeMaker' => 1,
  42            '../cpan/ExtUtils-Manifest' => 1,
  43            '../cpan/ExtUtils-ParseXS' => 1,
  44            '../cpan/File-Fetch' => 1,
  45            '../cpan/IPC-Cmd' => 1,
  46            '../cpan/IPC-SysV' => 1,
  47            '../cpan/Locale-Codes' => 1,
  48            '../cpan/Log-Message' => 1,
  49            '../cpan/Math-BigInt' => 1,
  50            '../cpan/Math-BigRat' => 1,
  51            '../cpan/Math-Complex' => 1,
  52            '../cpan/Module-Build' => 1,
  53            '../cpan/Module-Load' => 1,
  54            '../cpan/Module-Load-Conditional' => 1,
  55            '../cpan/Object-Accessor' => 1,
  56            '../cpan/Package-Constants' => 1,
  57            '../cpan/Parse-CPAN-Meta' => 1,
  58            '../cpan/Pod-Simple' => 1,
  59            '../cpan/Term-UI' => 1,
  60            '../cpan/Test-Simple' => 1,
  61            '../cpan/Tie-File' => 1,
  62            '../cpan/bignum' => 1,
  63            '../cpan/podlators' => 1,
  64            '../dist/ExtUtils-Install' => 1,
  65           );
  66
  67 my %temp_no_core =
  68     ('../cpan/B-Debug' => 1,
  69      '../cpan/Compress-Raw-Bzip2' => 1,
  70      '../cpan/Compress-Raw-Zlib' => 1,
  71      '../cpan/Devel-PPPort' => 1,
  72      '../cpan/Getopt-Long' => 1,
  73      '../cpan/IO-Compress' => 1,
  74      '../cpan/Math-BigInt' => 1,
  75      '../cpan/Math-BigRat' => 1,
  76      '../cpan/MIME-Base64' => 1,
  77      '../cpan/NEXT' => 1,
  78      '../cpan/parent' => 1,
  79      '../cpan/Parse-CPAN-Meta' => 1,
  80      '../cpan/Pod-Simple' => 1,
  81      '../cpan/podlators' => 1,
  82      '../cpan/Test-Simple' => 1,
  83      '../cpan/Tie-RefHash' => 1,
  84      '../cpan/Time-HiRes' => 1,
  85      '../cpan/Unicode-Collate' => 1,
  86      '../cpan/Unicode-Normalize' => 1,
  87     );
  88
  89 if ($::do_nothing) {
  90     return 1;
  91 }
  92
  93 # Location to put the Valgrind log.
  94 my $Valgrind_Log = 'current.valgrind';
  95
  96 $| = 1;
  97
  98 # for testing TEST only
  99 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
 100 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
 101
 102 delete $ENV{PERL5LIB};
 103 delete $ENV{PERLLIB};
 104 delete $ENV{PERL5OPT};
 105
 106 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
 107 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
 108 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
 109
 110 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
 111 # can't rely on require working.
 112 {
 113     my @argv = ();
 114     foreach my $idx (0..$#ARGV) {
 115         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
 116         $::benchmark = 1 if $1 eq 'benchmark';
 117         $::core    = 1 if $1 eq 'core';
 118         $::verbose = 1 if $1 eq 'v';
 119         $::torture = 1 if $1 eq 'torture';
 120         $::with_utf8 = 1 if $1 eq 'utf8';
 121         $::with_utf16 = 1 if $1 eq 'utf16';
 122         $::taintwarn = 1 if $1 eq 'taintwarn';
 123         $ENV{PERL_CORE_MINITEST} = 1 if $1 eq 'minitest';
 124         if ($1 =~ /^deparse(,.+)?$/) {
 125             $::deparse = 1;
 126             $::deparse_opts = $1;
 127         }
 128     }
 129     @ARGV = @argv;
 130 }
 131
 132 chdir 't' if -f 't/TEST';
 133 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 134     @INC = '../lib';
 135 }
 136
 137 die "You need to run \"make test\" first to set things up.\n"
 138   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 139
 140 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
 141     unless (-x 'perl.third') {
 142         unless (-x '../perl.third') {
 143             die "You need to run \"make perl.third first.\n";
 144         }
 145         else {
 146             print "Symlinking ../perl.third as perl.third...\n";
 147             die "Failed to symlink: $!\n"
 148                 unless symlink("../perl.third", "perl.third");
 149             die "Symlinked but no executable perl.third: $!\n"
 150                 unless -x 'perl.third';
 151         }
 152     }
 153 }
 154
 155 # check leakage for embedders
 156 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 157
 158 $ENV{EMXSHELL} = 'sh';        # For OS/2
 159
 160 if ($show_elapsed_time) { require Time::HiRes }
 161
 162 my %skip = (
 163             '.' => 1,
 164             '..' => 1,
 165             'CVS' => 1,
 166             'RCS' => 1,
 167             'SCCS' => 1,
 168             '.svn' => 1,
 169            );
 170
 171 # Roll your own File::Find!
 172 sub _find_tests {
 173     my($dir) = @_;
 174     opendir DIR, $dir or die "Trouble opening $dir: $!";
 175     foreach my $f (sort { $a cmp $b } readdir DIR) {
 176         next if $skip{$f};
 177
 178         my $fullpath = "$dir/$f";
 179
 180         if (-d $fullpath) {
 181             _find_tests($fullpath);
 182         } elsif ($f =~ /\.t$/) {
 183             push @ARGV, $fullpath;
 184         }
 185     }
 186 }
 187
 188
 189 # Scan the text of the test program to find switches and special options
 190 # we might need to apply.
 191 sub _scan_test {
 192     my($test, $type) = @_;
 193
 194     open(my $script, "<", $test) or die "Can't read $test.\n";
 195     my $first_line = <$script>;
 196
 197     $first_line =~ tr/\0//d if $::with_utf16;
 198
 199     my $switch = "";
 200     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 201         $switch = "-$1";
 202     } else {
 203         if ($::taintwarn) {
 204             # not all tests are expected to pass with this option
 205             $switch = '-t';
 206         } else {
 207             $switch = '';
 208         }
 209     }
 210
 211     my $file_opts = "";
 212     if ($type eq 'deparse') {
 213         # Look for #line directives which change the filename
 214         while (<$script>) {
 215             $file_opts = $file_opts . ",-f$3$4"
 216               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 217         }
 218     }
 219
 220     close $script;
 221
 222     my $perl = './perl';
 223     my $lib  = '../lib';
 224     my $run_dir;
 225     my $return_dir;
 226
 227     $test =~ /^(.+)\/[^\/]+/;
 228     my $dir = $1;
 229     my $testswitch = $dir_to_switch{$dir};
 230     if (!defined $testswitch) {
 231         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 232             $run_dir = $1;
 233             $return_dir = '../../t';
 234             $lib = '../../lib';
 235             $perl = '../../t/perl';
 236             $testswitch = "-I../.. -MTestInit=U2T";
 237             if ($2 eq 'cpan' || $2 eq 'dist') {
 238                 if($abs{$run_dir}) {
 239                     $testswitch = $testswitch . ',A';
 240                 }
 241                 if ($temp_no_core{$run_dir}) {
 242                     $testswitch = $testswitch . ',NC';
 243                 }
 244             }
 245         } else {
 246             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 247         }
 248     }
 249
 250     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
 251
 252     my %options = (
 253         perl => $perl,
 254         lib => $lib,
 255         test => $test,
 256         run_dir => $run_dir,
 257         return_dir => $return_dir,
 258         testswitch => $testswitch,
 259         utf8 => $utf8,
 260         file => $file_opts,
 261         switch => $switch,
 262     );
 263
 264     return \%options;
 265 }
 266
 267 sub _cmd {
 268     my($options, $type) = @_;
 269
 270     my $test = $options->{test};
 271
 272     my $cmd;
 273     if ($type eq 'deparse') {
 274         my $perl = "$options->{perl} $options->{testswitch}";
 275         my $lib = $options->{lib};
 276
 277         $cmd = (
 278           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 279           "-l$::deparse_opts$options->{file} ".
 280           "$test > $test.dp ".
 281           "&& $perl $options->{switch} -I$lib $test.dp"
 282         );
 283     }
 284     elsif ($type eq 'perl') {
 285         my $perl = $options->{perl};
 286         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 287
 288         if ($ENV{PERL_VALGRIND}) {
 289             my $valgrind = $ENV{VALGRIND} // 'valgrind';
 290             my $vg_opts = $ENV{VG_OPTS}
 291               //  "--suppressions=perl.supp --leak-check=yes "
 292                 . "--leak-resolution=high --show-reachable=yes "
 293                   . "--num-callers=50";
 294             $perl = "$valgrind --log-fd=3 $vg_opts $perl";
 295             $redir = "3>$Valgrind_Log";
 296         }
 297
 298         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 299         $cmd = $perl . _quote_args($args) . " $test $redir";
 300     }
 301
 302     return $cmd;
 303 }
 304
 305 sub _before_fork {
 306     my ($options) = @_;
 307
 308     if ($options->{run_dir}) {
 309         my $run_dir = $options->{run_dir};
 310         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 311     }
 312
 313     return;
 314 }
 315
 316 sub _after_fork {
 317     my ($options) = @_;
 318
 319     if ($options->{return_dir}) {
 320         my $return_dir = $options->{return_dir};
 321         chdir $return_dir
 322            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 323     }
 324
 325     return;
 326 }
 327
 328 sub _run_test {
 329     my ($test, $type) = @_;
 330
 331     my $options = _scan_test($test, $type);
 332     # $test might have changed if we're in ext/Foo, so don't use it anymore
 333     # from now on. Use $options->{test} instead.
 334
 335     _before_fork($options);
 336
 337     my $cmd = _cmd($options, $type);
 338
 339     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 340
 341     _after_fork($options);
 342
 343     # Our environment may force us to use UTF-8, but we can't be sure that
 344     # anything we're reading from will be generating (well formed) UTF-8
 345     # This may not be the best way - possibly we should unset ${^OPEN} up
 346     # top?
 347     binmode $results;
 348
 349     return $results;
 350 }
 351
 352 sub _quote_args {
 353     my ($args) = @_;
 354     my $argstring = '';
 355
 356     foreach (split(/\s+/,$args)) {
 357        # In VMS protect with doublequotes because otherwise
 358        # DCL will lowercase -- unless already doublequoted.
 359        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 360        $argstring = $argstring . ' ' . $_;
 361     }
 362     return $argstring;
 363 }
 364
 365 sub _populate_hash {
 366     return unless defined $_[0];
 367     return map {$_, 1} split /\s+/, $_[0];
 368 }
 369
 370 sub _tests_from_manifest {
 371     my ($extensions, $known_extensions) = @_;
 372     my %skip;
 373     my %extensions = _populate_hash($extensions);
 374     my %known_extensions = _populate_hash($known_extensions);
 375
 376     foreach (keys %known_extensions) {
 377         $skip{$_} = 1 unless $extensions{$_};
 378     }
 379
 380     my @results;
 381     my $mani = '../MANIFEST';
 382     if (open(MANI, $mani)) {
 383         while (<MANI>) {
 384             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 385                 my $t = $1;
 386                 my $extension = $2;
 387                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 388                     if (defined $extension) {
 389                         $extension =~ s!/t$!!;
 390                         # XXX Do I want to warn that I'm skipping these?
 391                         next if $skip{$extension};
 392                         my $flat_extension = $extension;
 393                         $flat_extension =~ s!-!/!g;
 394                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 395                     }
 396                     my $path = "../$t";
 397                     push @results, $path;
 398                     $::path_to_name{$path} = $t;
 399                 }
 400             }
 401         }
 402         close MANI;
 403     } else {
 404         warn "$0: cannot open $mani: $!\n";
 405     }
 406     return @results;
 407 }
 408
 409 unless (@ARGV) {
 410     # base first, as TEST bails out if that can't run
 411     # then comp, to validate that require works
 412     # then run, to validate that -M works
 413     # then we know we can -MTestInit for everything else, making life simpler
 414     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
 415         _find_tests($dir);
 416     }
 417     _find_tests("lib") unless $::core;
 418     # Config.pm may be broken for make minitest. And this is only a refinement
 419     # for skipping tests on non-default builds, so it is allowed to fail.
 420     # What we want to to is make a list of extensions which we did not build.
 421     my $configsh = '../config.sh';
 422     my ($extensions, $known_extensions);
 423     if (-f $configsh) {
 424         open FH, $configsh or die "Can't open $configsh: $!";
 425         while (<FH>) {
 426             if (/^extensions=['"](.*)['"]$/) {
 427                 $extensions = $1;
 428             }
 429             elsif (/^known_extensions=['"](.*)['"]$/) {
 430                 $known_extensions = $1;
 431             }
 432         }
 433         if (!defined $known_extensions) {
 434             warn "No known_extensions line found in $configsh";
 435         }
 436         if (!defined $extensions) {
 437             warn "No extensions line found in $configsh";
 438         }
 439     }
 440     # The "complex" constructions of list return from a subroutine, and push of
 441     # a list, might fail if perl is really hosed, but they aren't needed for
 442     # make minitest, and the building of extensions will likely also fail if
 443     # something is that badly wrong.
 444     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 445     unless ($::core) {
 446         _find_tests('x2p');
 447         _find_tests('porting');
 448         _find_tests('japh') if $::torture;
 449         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 450     }
 451 }
 452
 453 if ($::deparse) {
 454     _testprogs('deparse', '',   @ARGV);
 455 }
 456 elsif ($::with_utf16) {
 457     for my $e (0, 1) {
 458         for my $b (0, 1) {
 459             print STDERR "# ENDIAN $e BOM $b\n";
 460             my @UARGV;
 461             for my $a (@ARGV) {
 462                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 463                 my $f = $e ? "v" : "n";
 464                 push @UARGV, $u;
 465                 unlink($u);
 466                 if (open(A, $a)) {
 467                     if (open(U, ">$u")) {
 468                         print U pack("$f", 0xFEFF) if $b;
 469                         while (<A>) {
 470                             print U pack("$f*", unpack("C*", $_));
 471                         }
 472                         close(U);
 473                     }
 474                     close(A);
 475                 }
 476             }
 477             _testprogs('perl', '', @UARGV);
 478             unlink(@UARGV);
 479         }
 480     }
 481 }
 482 else {
 483     _testprogs('perl',    '',   @ARGV);
 484 }
 485
 486 sub _testprogs {
 487     my ($type, $args, @tests) = @_;
 488
 489     print <<'EOT' if ($type eq 'deparse');
 490 ------------------------------------------------------------------------------
 491 TESTING DEPARSER
 492 ------------------------------------------------------------------------------
 493 EOT
 494
 495     $::bad_files = 0;
 496
 497     foreach my $t (@tests) {
 498       unless (exists $::path_to_name{$t}) {
 499         my $tname = "t/$t";
 500         $::path_to_name{$t} = $tname;
 501       }
 502     }
 503     my $maxlen = 0;
 504     foreach (@::path_to_name{@tests}) {
 505         s/\.\w+\z/./;
 506         my $len = length ;
 507         $maxlen = $len if $len > $maxlen;
 508     }
 509     # + 3 : we want three dots between the test name and the "ok"
 510     my $dotdotdot = $maxlen + 3 ;
 511     my $valgrind = 0;
 512     my $total_files = @tests;
 513     my $good_files = 0;
 514     my $tested_files  = 0;
 515     my $totmax = 0;
 516     my %failed_tests;
 517
 518     while (my $test = shift @tests) {
 519         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
 520
 521         if ($test =~ /^$/) {
 522             next;
 523         }
 524         if ($type eq 'deparse') {
 525             if ($test eq "comp/redef.t") {
 526                 # Redefinition happens at compile time
 527                 next;
 528             }
 529             elsif ($test =~ m{lib/Switch/t/}) {
 530                 # B::Deparse doesn't support source filtering
 531                 next;
 532             }
 533         }
 534         my $te = $::path_to_name{$test} . '.'
 535                     x ($dotdotdot - length($::path_to_name{$test}));
 536
 537         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 538             print $te;
 539             $te = '';
 540         }
 541
 542         my $results = _run_test($test, $type);
 543
 544         my $failure;
 545         my $next = 0;
 546         my $seen_leader = 0;
 547         my $seen_ok = 0;
 548         my $trailing_leader = 0;
 549         my $max;
 550         my %todo;
 551         while (<$results>) {
 552             next if /^\s*$/; # skip blank lines
 553             if (/^1..$/ && ($^O eq 'VMS')) {
 554                 # VMS pipe bug inserts blank lines.
 555                 my $l2 = <RESULTS>;
 556                 if ($l2 =~ /^\s*$/) {
 557                     $l2 = <RESULTS>;
 558                 }
 559                 $_ = '1..' . $l2;
 560             }
 561             if ($::verbose) {
 562                 print $_;
 563             }
 564             unless (/^\#/) {
 565                 if ($trailing_leader) {
 566                     # shouldn't be anything following a postfix 1..n
 567                     $failure = 'FAILED--extra output after trailing 1..n';
 568                     last;
 569                 }
 570                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 571                     if ($seen_leader) {
 572                         $failure = 'FAILED--seen duplicate leader';
 573                         last;
 574                     }
 575                     $max = $1;
 576                     %todo = map { $_ => 1 } split / /, $3 if $3;
 577                     $totmax = $totmax + $max;
 578                     $tested_files = $tested_files + 1;
 579                     if ($seen_ok) {
 580                         # 1..n appears at end of file
 581                         $trailing_leader = 1;
 582                         if ($next != $max) {
 583                             $failure = "FAILED--expected $max tests, saw $next";
 584                             last;
 585                         }
 586                     }
 587                     else {
 588                         $next = 0;
 589                     }
 590                     $seen_leader = 1;
 591                 }
 592                 else {
 593                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 594                         unless ($seen_leader) {
 595                             unless ($seen_ok) {
 596                                 $next = 0;
 597                             }
 598                         }
 599                         $seen_ok = 1;
 600                         $next = $next + 1;
 601                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 602                         $num = $next unless $num;
 603
 604                         if ($num == $next) {
 605
 606                             # SKIP is essentially the same as TODO for t/TEST
 607                             # this still conforms to TAP:
 608                             # http://search.cpan.org/dist/TAP/TAP.pm
 609                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 610                             $istodo = 1 if $todo{$num};
 611
 612                             if( $not && !$istodo ) {
 613                                 $failure = "FAILED at test $num";
 614                                 last;
 615                             }
 616                         }
 617                         else {
 618                             $failure ="FAILED--expected test $next, saw test $num";
 619                             last;
 620                         }
 621                     }
 622                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 623                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 624                     }
 625                     else {
 626                         # module tests are allowed extra output,
 627                         # because Test::Harness allows it
 628                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 629                         $failure = "FAILED--unexpected output at test $next";
 630                         last;
 631                     }
 632                 }
 633             }
 634         }
 635         close $results;
 636
 637         if (not defined $failure) {
 638             $failure = 'FAILED--no leader found' unless $seen_leader;
 639         }
 640
 641         if ($ENV{PERL_VALGRIND}) {
 642             my @valgrind;
 643             if (-e $Valgrind_Log) {
 644                 if (open(V, $Valgrind_Log)) {
 645                     @valgrind = <V>;
 646                     close V;
 647                 } else {
 648                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
 649                 }
 650             }
 651             if ($ENV{VG_OPTS} =~ /cachegrind/) {
 652                 if (rename $Valgrind_Log, "$test.valgrind") {
 653                     $valgrind = $valgrind + 1;
 654                 } else {
 655                     warn "$0: Failed to create '$test.valgrind': $!\n";
 656                 }
 657             }
 658             elsif (@valgrind) {
 659                 my $leaks = 0;
 660                 my $errors = 0;
 661                 for my $i (0..$#valgrind) {
 662                     local $_ = $valgrind[$i];
 663                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 664                         $errors = $errors + $1;   # there may be multiple error summaries
 665                     } elsif (/^==\d+== LEAK SUMMARY:/) {
 666                         for my $off (1 .. 4) {
 667                             if ($valgrind[$i+$off] =~
 668                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 669                                 $leaks = $leaks + $1;
 670                             }
 671                         }
 672                     }
 673                 }
 674                 if ($errors or $leaks) {
 675                     if (rename $Valgrind_Log, "$test.valgrind") {
 676                         $valgrind = $valgrind + 1;
 677                     } else {
 678                         warn "$0: Failed to create '$test.valgrind': $!\n";
 679                     }
 680                 }
 681             } else {
 682                 warn "No valgrind output?\n";
 683             }
 684             if (-e $Valgrind_Log) {
 685                 unlink $Valgrind_Log
 686                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 687             }
 688         }
 689         if ($type eq 'deparse') {
 690             unlink "./$test.dp";
 691         }
 692         if ($ENV{PERL_3LOG}) {
 693             my $tpp = $test;
 694             $tpp =~ s:^\.\./::;
 695             $tpp =~ s:/:_:g;
 696             $tpp =~ s:\.t$:.3log:;
 697             rename("perl.3log", $tpp) ||
 698                 die "rename: perl3.log to $tpp: $!\n";
 699         }
 700         if (not defined $failure and $next != $max) {
 701             $failure="FAILED--expected $max tests, saw $next";
 702         }
 703
 704         if( !defined $failure  # don't mask a test failure
 705             and $? )
 706         {
 707             $failure = "FAILED--non-zero wait status: $?";
 708         }
 709
 710         if (defined $failure) {
 711             print "${te}$failure\n";
 712             $::bad_files = $::bad_files + 1;
 713             if ($test =~ /^base/) {
 714                 die "Failed a basic test ($test) -- cannot continue.\n";
 715             }
 716             $failed_tests{$test} = 1;
 717         }
 718         else {
 719             if ($max) {
 720                 my $elapsed;
 721                 if ( $show_elapsed_time ) {
 722                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
 723                 }
 724                 else {
 725                     $elapsed = "";
 726                 }
 727                 print "${te}ok$elapsed\n";
 728                 $good_files = $good_files + 1;
 729             }
 730             else {
 731                 print "${te}skipped\n";
 732                 $tested_files = $tested_files - 1;
 733             }
 734         }
 735     } # while tests
 736
 737     if ($::bad_files == 0) {
 738         if ($good_files) {
 739             print "All tests successful.\n";
 740             # XXX add mention of 'perlbug -ok' ?
 741         }
 742         else {
 743             die "FAILED--no tests were run for some reason.\n";
 744         }
 745     }
 746     else {
 747         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 748         my $s = $::bad_files == 1 ? "" : "s";
 749         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 750         for my $test ( sort keys %failed_tests ) {
 751             print "\t$test\n";
 752         }
 753         warn <<'SHRDLU_1';
 754 ### Since not all tests were successful, you may want to run some of
 755 ### them individually and examine any diagnostic messages they produce.
 756 ### See the INSTALL document's section on "make test".
 757 SHRDLU_1
 758         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 759 ### You have a good chance to get more information by running
 760 ###   ./perl harness
 761 ### in the 't' directory since most (>=80%) of the tests succeeded.
 762 SHRDLU_2
 763         if (eval {require Config; import Config; 1}) {
 764             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 765                 warn <<SHRDLU_3;
 766 ### You may have to set your dynamic library search path,
 767 ### $p, to point to the build directory:
 768 SHRDLU_3
 769                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 770                     warn <<SHRDLU_4a;
 771 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 772 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 773 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 774 SHRDLU_4a
 775                 } else {
 776                     warn <<SHRDLU_4b;
 777 ###   setenv $p `pwd`; cd t; ./perl harness
 778 ###   $p=`pwd`; export $p; cd t; ./perl harness
 779 ###   export $p=`pwd`; cd t; ./perl harness
 780 SHRDLU_4b
 781                 }
 782                 warn <<SHRDLU_5;
 783 ### for csh-style shells, like tcsh; or for traditional/modern
 784 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 785 SHRDLU_5
 786             }
 787         }
 788     }
 789     my ($user,$sys,$cuser,$csys) = times;
 790     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
 791         $user,$sys,$cuser,$csys,$tested_files,$totmax);
 792     if ($ENV{PERL_VALGRIND}) {
 793         my $s = $valgrind == 1 ? '' : 's';
 794         print "$valgrind valgrind report$s created.\n", ;
 795     }
 796 }
 797 exit ($::bad_files != 0);
 798
 799 # ex: set ts=8 sts=4 sw=4 noet: