write_buildcustomize.pl

   1 #!./miniperl -w
   2
   3 use strict;
   4
   5 my $osname = $^O;
   6 my $file = 'lib/buildcustomize.pl';
   7
   8 if ( @ARGV % 2 ) {
   9     my $dir = shift;
  10     chdir $dir or die "Can't chdir '$dir': $!";
  11     unshift @INC, 'lib';
  12 }
  13
  14 if ( @ARGV ) {
  15     # Used during cross-compilation.
  16     $osname = $ARGV[1];
  17 }
  18
  19 # To clarify, this isn't the entire suite of modules considered "toolchain"
  20 # It's not even all modules needed to build ext/
  21 # It's just the source paths of the (minimum complete set of) modules in ext/
  22 # needed to build the nonxs modules
  23 # After which, all nonxs modules are in lib, which was always sufficient to
  24 # allow miniperl to build everything else.
  25 # Getopt::Long is here because it's used by podlators, which is one of the
  26 # nonxs modules.
  27 # Term::ReadLine is not here for building but for allowing the debugger to
  28 # run under miniperl when nothing but miniperl will build :-(.
  29 # Text::ParseWords is required in ExtUtils::Liblist::Kid
  30
  31 my @toolchain = qw(cpan/AutoLoader/lib
  32                    dist/Carp/lib
  33                    dist/PathTools dist/PathTools/lib
  34                    cpan/ExtUtils-Install/lib
  35                    cpan/ExtUtils-MakeMaker/lib
  36                    cpan/ExtUtils-Manifest/lib
  37                    cpan/File-Path/lib
  38                    ext/re
  39                    dist/Term-ReadLine/lib
  40                    dist/Exporter/lib
  41                    ext/File-Find/lib
  42                    cpan/Text-Tabs/lib
  43                    dist/constant/lib
  44                    cpan/version/lib
  45                    cpan/Getopt-Long/lib
  46                    cpan/Text-ParseWords/lib
  47                    cpan/ExtUtils-PL2Bat/lib
  48                    );
  49
  50 # These are for XS building on Win32, since nonxs and xs build simultaneously
  51 # on Win32 if parallel building
  52 push @toolchain, qw(
  53         dist/ExtUtils-ParseXS/lib
  54         cpan/parent/lib
  55         cpan/ExtUtils-Constant/lib
  56 ) if $^O eq 'MSWin32';
  57 push @toolchain, 'ext/VMS-Filespec/lib' if $^O eq 'VMS';
  58
  59 unshift @INC, @toolchain;
  60 require File::Spec::Functions;
  61 require Cwd;
  62
  63 my $cwd  = Cwd::getcwd();
  64
  65 defined $cwd
  66   or die "$0: Can't determine current working directory\n";
  67
  68 # lib must be last, as the toolchain modules write themselves into it
  69 # as they build, and it's important that @INC order ensures that the partially
  70 # written files are always masked by the complete versions.
  71
  72 my $inc = join ",\n        ",
  73     map { "q\0$_\0" }
  74     (map {File::Spec::Functions::rel2abs($_, $cwd)} (
  75 # faster build on the non-parallel Win32 build process
  76         $^O eq 'MSWin32' ? ('lib', @toolchain ) : (@toolchain, 'lib')
  77     ));
  78
  79 open my $fh, '>', $file
  80     or die "Can't open $file: $!";
  81
  82 my $error;
  83
  84 # If any of the system's build tools are written in Perl, then this module
  85 # may well be loaded by a much older version than we are building. So keep it
  86 # as backwards compatible as is easy.
  87 print $fh <<"EOT" or $error = "Can't print to $file: $!";
  88 #!perl
  89
  90 #   !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
  91 #   This file is generated by write_buildcustomize.pl.
  92 #   Any changes made here will be lost!
  93
  94 # We are miniperl, building extensions
  95 # Replace the first entry of \@INC ("lib") with the list of
  96 # directories we need.
  97 splice(\@INC, 0, 1, $inc);
  98 \$^O = '$osname';
  99 __END__
 100 EOT
 101
 102 if ($error) {
 103     close $fh
 104         or warn "Can't unlink $file after error: $!";
 105 } else {
 106     if (close $fh) {
 107         do $file and exit;
 108         $error = "Can't load generated $file: $@";
 109     } else {
 110         $error = "Can't close $file: $!";
 111     }
 112 }
 113
 114 # It's going very wrong, so try to remove the botched file.
 115
 116 unlink $file
 117     or warn "Can't unlink $file after error: $!";
 118 die $error;
 119
 120 # ex: set ts=8 sts=4 sw=4 et: