regen/embed.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Regenerate (overwriting only if changed):
   4 #
   5 #    embed.h
   6 #    embedvar.h
   7 #    perlapi.c
   8 #    perlapi.h
   9 #    proto.h
  10 #
  11 # from information stored in
  12 #
  13 #    embed.fnc
  14 #    intrpvar.h
  15 #    perlvars.h
  16 #    regen/opcodes
  17 #
  18 # Accepts the standard regen_lib -q and -v args.
  19 #
  20 # This script is normally invoked from regen.pl.
  21
  22 require 5.004;  # keep this compatible, an old perl is all we may have before
  23                 # we build the new one
  24
  25 use strict;
  26
  27 BEGIN {
  28     # Get function prototypes
  29     require 'regen/regen_lib.pl';
  30     require 'regen/embed_lib.pl';
  31 }
  32
  33 my $SPLINT = 0; # Turn true for experimental splint support http://www.splint.org
  34 my $unflagged_pointers;
  35
  36 #
  37 # See database of global and static function prototypes in embed.fnc
  38 # This is used to generate prototype headers under various configurations,
  39 # export symbols lists for different platforms, and macros to provide an
  40 # implicit interpreter context argument.
  41 #
  42
  43 sub full_name ($$) { # Returns the function name with potentially the
  44                      # prefixes 'S_' or 'Perl_'
  45     my ($func, $flags) = @_;
  46
  47     return "S_$func" if $flags =~ /[si]/;
  48     return "Perl_$func" if $flags =~ /[bp]/;
  49     return $func;
  50 }
  51
  52 sub open_print_header {
  53     my ($file, $quote) = @_;
  54
  55     return open_new($file, '>',
  56                     { file => $file, style => '*', by => 'regen/embed.pl',
  57                       from => ['data in embed.fnc', 'regen/embed.pl',
  58                                'regen/opcodes', 'intrpvar.h', 'perlvars.h'],
  59                       final => "\nEdit those files and run 'make regen_headers' to effect changes.\n",
  60                       copyright => [1993 .. 2009], quote => $quote });
  61 }
  62
  63 my ($embed, $core, $ext, $api) = setup_embed();
  64
  65 # generate proto.h
  66 {
  67     my $pr = open_print_header("proto.h");
  68     print $pr "START_EXTERN_C\n";
  69     my $ret;
  70
  71     foreach (@$embed) {
  72         if (@$_ == 1) {
  73             print $pr "$_->[0]\n";
  74             next;
  75         }
  76
  77         my ($flags,$retval,$plain_func,@args) = @$_;
  78         my @nonnull;
  79         my $has_context = ( $flags !~ /n/ );
  80         my $never_returns = ( $flags =~ /r/ );
  81         my $commented_out = ( $flags =~ /m/ );
  82         my $binarycompat = ( $flags =~ /b/ );
  83         my $is_malloc = ( $flags =~ /a/ );
  84         my $can_ignore = ( $flags !~ /R/ ) && !$is_malloc;
  85         my @names_of_nn;
  86         my $func;
  87
  88         if (! $can_ignore && $retval eq 'void') {
  89             warn "It is nonsensical to require the return value of a void function ($plain_func) to be checked";
  90         }
  91
  92         my $scope_type_flag_count = 0;
  93         $scope_type_flag_count++ if $flags =~ /s/;
  94         $scope_type_flag_count++ if $flags =~ /i/;
  95         $scope_type_flag_count++ if $flags =~ /p/;
  96         warn "$plain_func: i, p, and s flags are all mutually exclusive"
  97                                                    if $scope_type_flag_count > 1;
  98         my $splint_flags = "";
  99         if ( $SPLINT && !$commented_out ) {
 100             $splint_flags .= '/*@noreturn@*/ ' if $never_returns;
 101             if ($can_ignore && ($retval ne 'void') && ($retval !~ /\*/)) {
 102                 $retval .= " /*\@alt void\@*/";
 103             }
 104         }
 105
 106         if ($flags =~ /([si])/) {
 107             my $type;
 108             if ($never_returns) {
 109                 $type = $1 eq 's' ? "PERL_STATIC_NO_RET" : "PERL_STATIC_INLINE_NO_RET";
 110             }
 111             else {
 112                 $type = $1 eq 's' ? "STATIC" : "PERL_STATIC_INLINE";
 113             }
 114             $retval = "$type $splint_flags$retval";
 115         }
 116         else {
 117             if ($never_returns) {
 118                 $retval = "PERL_CALLCONV_NO_RET $splint_flags$retval";
 119             }
 120             else {
 121                 $retval = "PERL_CALLCONV $splint_flags$retval";
 122             }
 123         }
 124         $func = full_name($plain_func, $flags);
 125         $ret = "$retval\t$func(";
 126         if ( $has_context ) {
 127             $ret .= @args ? "pTHX_ " : "pTHX";
 128         }
 129         if (@args) {
 130             my $n;
 131             for my $arg ( @args ) {
 132                 ++$n;
 133                 if ( $arg =~ /\*/ && $arg !~ /\b(NN|NULLOK)\b/ ) {
 134                     warn "$func: $arg needs NN or NULLOK\n";
 135                     ++$unflagged_pointers;
 136                 }
 137                 my $nn = ( $arg =~ s/\s*\bNN\b\s+// );
 138                 push( @nonnull, $n ) if $nn;
 139
 140                 my $nullok = ( $arg =~ s/\s*\bNULLOK\b\s+// ); # strip NULLOK with no effect
 141
 142                 # Make sure each arg has at least a type and a var name.
 143                 # An arg of "int" is valid C, but want it to be "int foo".
 144                 my $temp_arg = $arg;
 145                 $temp_arg =~ s/\*//g;
 146                 $temp_arg =~ s/\s*\bstruct\b\s*/ /g;
 147                 if ( ($temp_arg ne "...")
 148                      && ($temp_arg !~ /\w+\s+(\w+)(?:\[\d+\])?\s*$/) ) {
 149                     warn "$func: $arg ($n) doesn't have a name\n";
 150                 }
 151                 if ( $SPLINT && $nullok && !$commented_out ) {
 152                     $arg = '/*@null@*/ ' . $arg;
 153                 }
 154                 if (defined $1 && $nn && !($commented_out && !$binarycompat)) {
 155                     push @names_of_nn, $1;
 156                 }
 157             }
 158             $ret .= join ", ", @args;
 159         }
 160         else {
 161             $ret .= "void" if !$has_context;
 162         }
 163         $ret .= ")";
 164         my @attrs;
 165         if ( $flags =~ /r/ ) {
 166             push @attrs, "__attribute__noreturn__";
 167         }
 168         if ( $flags =~ /D/ ) {
 169             push @attrs, "__attribute__deprecated__";
 170         }
 171         if ( $is_malloc ) {
 172             push @attrs, "__attribute__malloc__";
 173         }
 174         if ( !$can_ignore ) {
 175             push @attrs, "__attribute__warn_unused_result__";
 176         }
 177         if ( $flags =~ /P/ ) {
 178             push @attrs, "__attribute__pure__";
 179         }
 180         if( $flags =~ /f/ ) {
 181             my $prefix  = $has_context ? 'pTHX_' : '';
 182             my $args    = scalar @args;
 183             my $pat     = $args - 1;
 184             my $macro   = @nonnull && $nonnull[-1] == $pat
 185                                 ? '__attribute__format__'
 186                                 : '__attribute__format__null_ok__';
 187             push @attrs, sprintf "%s(__printf__,%s%d,%s%d)", $macro,
 188                                 $prefix, $pat, $prefix, $args;
 189         }
 190         if ( @nonnull ) {
 191             my @pos = map { $has_context ? "pTHX_$_" : $_ } @nonnull;
 192             push @attrs, map { sprintf( "__attribute__nonnull__(%s)", $_ ) } @pos;
 193         }
 194         if ( @attrs ) {
 195             $ret .= "\n";
 196             $ret .= join( "\n", map { "\t\t\t$_" } @attrs );
 197         }
 198         $ret .= ";";
 199         $ret = "/* $ret */" if $commented_out;
 200         if (@names_of_nn) {
 201             $ret .= "\n#define PERL_ARGS_ASSERT_\U$plain_func\E\t\\\n\t"
 202                 . join '; ', map "assert($_)", @names_of_nn;
 203         }
 204         $ret .= @attrs ? "\n\n" : "\n";
 205
 206         print $pr $ret;
 207     }
 208
 209     print $pr <<'EOF';
 210 #ifdef PERL_CORE
 211 #  include "pp_proto.h"
 212 #endif
 213 END_EXTERN_C
 214 EOF
 215
 216     read_only_bottom_close_and_rename($pr);
 217 }
 218
 219 warn "$unflagged_pointers pointer arguments to clean up\n" if $unflagged_pointers;
 220
 221 sub readvars {
 222     my ($file, $pre) = @_;
 223     local (*FILE, $_);
 224     my %seen;
 225     open(FILE, "< $file")
 226         or die "embed.pl: Can't open $file: $!\n";
 227     while (<FILE>) {
 228         s/[ \t]*#.*//;          # Delete comments.
 229         if (/PERLVARA?I?C?\($pre,\s*(\w+)/) {
 230             warn "duplicate symbol $1 while processing $file line $.\n"
 231                 if $seen{$1}++;
 232         }
 233     }
 234     close(FILE);
 235     return sort keys %seen;
 236 }
 237
 238 my @intrp = readvars 'intrpvar.h','I';
 239 my @globvar = readvars 'perlvars.h','G';
 240
 241 sub hide {
 242     my ($from, $to, $indent) = @_;
 243     $indent = '' unless defined $indent;
 244     my $t = int(length("$indent$from") / 8);
 245     "#${indent}define $from" . "\t" x ($t < 3 ? 3 - $t : 1) . "$to\n";
 246 }
 247
 248 sub multon ($$$) {
 249     my ($sym,$pre,$ptr) = @_;
 250     hide("PL_$sym", "($ptr$pre$sym)");
 251 }
 252
 253 my $em = open_print_header('embed.h');
 254
 255 print $em <<'END';
 256 /* (Doing namespace management portably in C is really gross.) */
 257
 258 /* By defining PERL_NO_SHORT_NAMES (not done by default) the short forms
 259  * (like warn instead of Perl_warn) for the API are not defined.
 260  * Not defining the short forms is a good thing for cleaner embedding. */
 261
 262 #ifndef PERL_NO_SHORT_NAMES
 263
 264 /* Hide global symbols */
 265
 266 END
 267
 268 my @az = ('a'..'z');
 269
 270 sub embed_h {
 271     my ($guard, $funcs) = @_;
 272     print $em "$guard\n" if $guard;
 273
 274     my $lines;
 275     foreach (@$funcs) {
 276         if (@$_ == 1) {
 277             my $cond = $_->[0];
 278             # Indent the conditionals if we are wrapped in an #if/#endif pair.
 279             $cond =~ s/#(.*)/#  $1/ if $guard;
 280             $lines .= "$cond\n";
 281             next;
 282         }
 283         my $ret = "";
 284         my ($flags,$retval,$func,@args) = @$_;
 285         unless ($flags =~ /[om]/) {
 286             my $args = scalar @args;
 287             if ($flags =~ /n/) {
 288                 $ret = hide($func, full_name($func, $flags));
 289             }
 290             elsif ($args and $args[$args-1] =~ /\.\.\./) {
 291                 if ($flags =~ /p/) {
 292                     # we're out of luck for varargs functions under CPP
 293                     # So we can only do these macros for no implicit context:
 294                     $ret = "#ifndef PERL_IMPLICIT_CONTEXT\n"
 295                         . hide($func, full_name($func, $flags)) . "#endif\n";
 296                 }
 297             }
 298             else {
 299                 my $alist = join(",", @az[0..$args-1]);
 300                 $ret = "#define $func($alist)";
 301                 my $t = int(length($ret) / 8);
 302                 $ret .=  "\t" x ($t < 4 ? 4 - $t : 1);
 303                 $ret .= full_name($func, $flags) . "(aTHX";
 304                 $ret .= "_ " if $alist;
 305                 $ret .= $alist . ")\n";
 306             }
 307         }
 308         $lines .= $ret;
 309     }
 310     # Prune empty #if/#endif pairs.
 311     while ($lines =~ s/#\s*if[^\n]+\n#\s*endif\n//) {
 312     }
 313     # Merge adjacent blocks.
 314     while ($lines =~ s/(#ifndef PERL_IMPLICIT_CONTEXT
 315 [^\n]+
 316 )#endif
 317 #ifndef PERL_IMPLICIT_CONTEXT
 318 /$1/) {
 319     }
 320
 321     print $em $lines;
 322     print $em "#endif\n" if $guard;
 323 }
 324
 325 embed_h('', $api);
 326 embed_h('#if defined(PERL_CORE) || defined(PERL_EXT)', $ext);
 327 embed_h('#ifdef PERL_CORE', $core);
 328
 329 print $em <<'END';
 330
 331 #endif  /* #ifndef PERL_NO_SHORT_NAMES */
 332
 333 /* Compatibility stubs.  Compile extensions with -DPERL_NOCOMPAT to
 334    disable them.
 335  */
 336
 337 #if !defined(PERL_CORE)
 338 #  define sv_setptrobj(rv,ptr,name)     sv_setref_iv(rv,name,PTR2IV(ptr))
 339 #  define sv_setptrref(rv,ptr)          sv_setref_iv(rv,NULL,PTR2IV(ptr))
 340 #endif
 341
 342 #if !defined(PERL_CORE) && !defined(PERL_NOCOMPAT)
 343
 344 /* Compatibility for various misnamed functions.  All functions
 345    in the API that begin with "perl_" (not "Perl_") take an explicit
 346    interpreter context pointer.
 347    The following are not like that, but since they had a "perl_"
 348    prefix in previous versions, we provide compatibility macros.
 349  */
 350 #  define perl_atexit(a,b)              call_atexit(a,b)
 351 END
 352
 353 foreach (@$embed) {
 354     my ($flags, $retval, $func, @args) = @$_;
 355     next unless $func;
 356     next unless $flags =~ /O/;
 357
 358     my $alist = join ",", @az[0..$#args];
 359     my $ret = "#  define perl_$func($alist)";
 360     my $t = (length $ret) >> 3;
 361     $ret .=  "\t" x ($t < 5 ? 5 - $t : 1);
 362     print $em "$ret$func($alist)\n";
 363 }
 364
 365 my @nocontext;
 366 {
 367     my (%has_va, %has_nocontext);
 368     foreach (@$embed) {
 369         next unless @$_ > 1;
 370         ++$has_va{$_->[2]} if $_->[-1] =~ /\.\.\./;
 371         ++$has_nocontext{$1} if $_->[2] =~ /(.*)_nocontext/;
 372     }
 373
 374     @nocontext = sort grep {
 375         $has_nocontext{$_}
 376             && !/printf/ # Not clear to me why these are skipped but they are.
 377     } keys %has_va;
 378 }
 379
 380 print $em <<'END';
 381
 382 /* varargs functions can't be handled with CPP macros. :-(
 383    This provides a set of compatibility functions that don't take
 384    an extra argument but grab the context pointer using the macro
 385    dTHX.
 386  */
 387 #if defined(PERL_IMPLICIT_CONTEXT) && !defined(PERL_NO_SHORT_NAMES)
 388 END
 389
 390 foreach (@nocontext) {
 391     print $em hide($_, "Perl_${_}_nocontext", "  ");
 392 }
 393
 394 print $em <<'END';
 395 #endif
 396
 397 #endif /* !defined(PERL_CORE) && !defined(PERL_NOCOMPAT) */
 398
 399 #if !defined(PERL_IMPLICIT_CONTEXT)
 400 /* undefined symbols, point them back at the usual ones */
 401 END
 402
 403 foreach (@nocontext) {
 404     print $em hide("Perl_${_}_nocontext", "Perl_$_", "  ");
 405 }
 406
 407 print $em <<'END';
 408 #endif
 409 END
 410
 411 read_only_bottom_close_and_rename($em);
 412
 413 $em = open_print_header('embedvar.h');
 414
 415 print $em <<'END';
 416 /* (Doing namespace management portably in C is really gross.) */
 417
 418 /*
 419    The following combinations of MULTIPLICITY and PERL_IMPLICIT_CONTEXT
 420    are supported:
 421      1) none
 422      2) MULTIPLICITY    # supported for compatibility
 423      3) MULTIPLICITY && PERL_IMPLICIT_CONTEXT
 424
 425    All other combinations of these flags are errors.
 426
 427    only #3 is supported directly, while #2 is a special
 428    case of #3 (supported by redefining vTHX appropriately).
 429 */
 430
 431 #if defined(MULTIPLICITY)
 432 /* cases 2 and 3 above */
 433
 434 #  if defined(PERL_IMPLICIT_CONTEXT)
 435 #    define vTHX        aTHX
 436 #  else
 437 #    define vTHX        PERL_GET_INTERP
 438 #  endif
 439
 440 END
 441
 442 my $sym;
 443
 444 for $sym (@intrp) {
 445     if ($sym eq 'sawampersand') {
 446         print $em "#ifndef PL_sawampersand\n";
 447     }
 448     print $em multon($sym,'I','vTHX->');
 449     if ($sym eq 'sawampersand') {
 450         print $em "#endif\n";
 451     }
 452 }
 453
 454 print $em <<'END';
 455
 456 #endif  /* MULTIPLICITY */
 457
 458 #if defined(PERL_GLOBAL_STRUCT)
 459
 460 END
 461
 462 for $sym (@globvar) {
 463     print $em "#ifdef OS2\n" if $sym eq 'sh_path';
 464     print $em multon($sym,   'G','my_vars->');
 465     print $em multon("G$sym",'', 'my_vars->');
 466     print $em "#endif\n" if $sym eq 'sh_path';
 467 }
 468
 469 print $em <<'END';
 470
 471 #endif /* PERL_GLOBAL_STRUCT */
 472 END
 473
 474 read_only_bottom_close_and_rename($em);
 475
 476 my $capih = open_print_header('perlapi.h');
 477
 478 print $capih <<'EOT';
 479 /* declare accessor functions for Perl variables */
 480 #ifndef __perlapi_h__
 481 #define __perlapi_h__
 482
 483 #if defined (MULTIPLICITY) && defined (PERL_GLOBAL_STRUCT)
 484
 485 START_EXTERN_C
 486
 487 #undef PERLVAR
 488 #undef PERLVARA
 489 #undef PERLVARI
 490 #undef PERLVARIC
 491 #define PERLVAR(p,v,t)  EXTERN_C t* Perl_##p##v##_ptr(pTHX);
 492 #define PERLVARA(p,v,n,t)       typedef t PL_##v##_t[n];                \
 493                         EXTERN_C PL_##v##_t* Perl_##p##v##_ptr(pTHX);
 494 #define PERLVARI(p,v,t,i)       PERLVAR(p,v,t)
 495 #define PERLVARIC(p,v,t,i) PERLVAR(p,v, const t)
 496
 497 #include "perlvars.h"
 498
 499 #undef PERLVAR
 500 #undef PERLVARA
 501 #undef PERLVARI
 502 #undef PERLVARIC
 503
 504 END_EXTERN_C
 505
 506 #if defined(PERL_CORE)
 507
 508 /* accessor functions for Perl "global" variables */
 509
 510 /* these need to be mentioned here, or most linkers won't put them in
 511    the perl executable */
 512
 513 #ifndef PERL_NO_FORCE_LINK
 514
 515 START_EXTERN_C
 516
 517 #ifndef DOINIT
 518 EXTCONST void * const PL_force_link_funcs[];
 519 #else
 520 EXTCONST void * const PL_force_link_funcs[] = {
 521 #undef PERLVAR
 522 #undef PERLVARA
 523 #undef PERLVARI
 524 #undef PERLVARIC
 525 #define PERLVAR(p,v,t)          (void*)Perl_##p##v##_ptr,
 526 #define PERLVARA(p,v,n,t)       PERLVAR(p,v,t)
 527 #define PERLVARI(p,v,t,i)       PERLVAR(p,v,t)
 528 #define PERLVARIC(p,v,t,i)      PERLVAR(p,v,t)
 529
 530 /* In Tru64 (__DEC && __osf__) the cc option -std1 causes that one
 531  * cannot cast between void pointers and function pointers without
 532  * info level warnings.  The PL_force_link_funcs[] would cause a few
 533  * hundred of those warnings.  In code one can circumnavigate this by using
 534  * unions that overlay the different pointers, but in declarations one
 535  * cannot use this trick.  Therefore we just disable the warning here
 536  * for the duration of the PL_force_link_funcs[] declaration. */
 537
 538 #if defined(__DECC) && defined(__osf__)
 539 #pragma message save
 540 #pragma message disable (nonstandcast)
 541 #endif
 542
 543 #include "perlvars.h"
 544
 545 #if defined(__DECC) && defined(__osf__)
 546 #pragma message restore
 547 #endif
 548
 549 #undef PERLVAR
 550 #undef PERLVARA
 551 #undef PERLVARI
 552 #undef PERLVARIC
 553 };
 554 #endif  /* DOINIT */
 555
 556 END_EXTERN_C
 557
 558 #endif  /* PERL_NO_FORCE_LINK */
 559
 560 #else   /* !PERL_CORE */
 561
 562 EOT
 563
 564 foreach $sym (@globvar) {
 565     print $capih
 566         "#undef  PL_$sym\n" . hide("PL_$sym", "(*Perl_G${sym}_ptr(NULL))");
 567 }
 568
 569 print $capih <<'EOT';
 570
 571 #endif /* !PERL_CORE */
 572 #endif /* MULTIPLICITY && PERL_GLOBAL_STRUCT */
 573
 574 #endif /* __perlapi_h__ */
 575 EOT
 576
 577 read_only_bottom_close_and_rename($capih);
 578
 579 my $capi = open_print_header('perlapi.c', <<'EOQ');
 580  *
 581  *
 582  * Up to the threshold of the door there mounted a flight of twenty-seven
 583  * broad stairs, hewn by some unknown art of the same black stone.  This
 584  * was the only entrance to the tower; ...
 585  *
 586  *     [p.577 of _The Lord of the Rings_, III/x: "The Voice of Saruman"]
 587  *
 588  */
 589 EOQ
 590
 591 print $capi <<'EOT';
 592 #include "EXTERN.h"
 593 #include "perl.h"
 594 #include "perlapi.h"
 595
 596 #if defined (MULTIPLICITY) && defined (PERL_GLOBAL_STRUCT)
 597
 598 /* accessor functions for Perl "global" variables */
 599 START_EXTERN_C
 600
 601 #undef PERLVARI
 602 #define PERLVARI(p,v,t,i) PERLVAR(p,v,t)
 603
 604 #undef PERLVAR
 605 #undef PERLVARA
 606 #define PERLVAR(p,v,t)          t* Perl_##p##v##_ptr(pTHX)              \
 607                         { dVAR; PERL_UNUSED_CONTEXT; return &(PL_##v); }
 608 #define PERLVARA(p,v,n,t)       PL_##v##_t* Perl_##p##v##_ptr(pTHX)     \
 609                         { dVAR; PERL_UNUSED_CONTEXT; return &(PL_##v); }
 610 #undef PERLVARIC
 611 #define PERLVARIC(p,v,t,i)      \
 612                         const t* Perl_##p##v##_ptr(pTHX)                \
 613                         { PERL_UNUSED_CONTEXT; return (const t *)&(PL_##v); }
 614 #include "perlvars.h"
 615
 616 #undef PERLVAR
 617 #undef PERLVARA
 618 #undef PERLVARI
 619 #undef PERLVARIC
 620
 621 END_EXTERN_C
 622
 623 #endif /* MULTIPLICITY && PERL_GLOBAL_STRUCT */
 624 EOT
 625
 626 read_only_bottom_close_and_rename($capi);
 627
 628 # ex: set ts=8 sts=4 sw=4 noet: