t/op/magic.t

   1 #!./perl
   2
   3 BEGIN {
   4     $| = 1;
   5     chdir 't' if -d 't';
   6     @INC = '../lib';
   7     $SIG{__WARN__} = sub { die "Dying on warning: ", @_ };
   8 }
   9
  10 use warnings;
  11 use Config;
  12
  13 my $test = 1;
  14 sub ok {
  15     my($ok, $info, $todo) = @_;
  16
  17     # You have to do it this way or VMS will get confused.
  18     printf "%s $test%s\n", $ok ? "ok" : "not ok",
  19                            $todo ? " # TODO $todo" : '';
  20
  21     unless( $ok ) {
  22         printf "# Failed test at line %d\n", (caller)[2];
  23         print  "# $info\n" if defined $info;
  24     }
  25
  26     $test++;
  27     return $ok;
  28 }
  29
  30 sub skip {
  31     my($reason) = @_;
  32
  33     printf "ok $test # skipped%s\n", defined $reason ? ": $reason" : '';
  34
  35     $test++;
  36     return 1;
  37 }
  38
  39 print "1..53\n";
  40
  41 $Is_MSWin32 = $^O eq 'MSWin32';
  42 $Is_NetWare = $^O eq 'NetWare';
  43 $Is_VMS     = $^O eq 'VMS';
  44 $Is_Dos     = $^O eq 'dos';
  45 $Is_os2     = $^O eq 'os2';
  46 $Is_Cygwin  = $^O eq 'cygwin';
  47 $Is_MacOS   = $^O eq 'MacOS';
  48 $Is_MPE     = $^O eq 'mpeix';
  49
  50 $PERL = ($Is_NetWare            ? 'perl'   :
  51          ($Is_MacOS || $Is_VMS) ? $^X      :
  52          $Is_MSWin32            ? '.\perl' :
  53          './perl');
  54
  55 eval '$ENV{"FOO"} = "hi there";';       # check that ENV is inited inside eval
  56 # cmd.exe will echo 'variable=value' but 4nt will echo just the value
  57 # -- Nikola Knezevic
  58 if ($Is_MSWin32)  { ok `set FOO` =~ /^(?:FOO=)?hi there$/; }
  59 elsif ($Is_MacOS) { ok "1 # skipped", 1; }
  60 elsif ($Is_VMS)   { ok `write sys\$output f\$trnlnm("FOO")` eq "hi there\n"; }
  61 else              { ok `echo \$FOO` eq "hi there\n"; }
  62
  63 unlink 'ajslkdfpqjsjfk';
  64 $! = 0;
  65 open(FOO,'ajslkdfpqjsjfk');
  66 ok $!, $!;
  67 close FOO; # just mention it, squelch used-only-once
  68
  69 if ($Is_MSWin32 || $Is_NetWare || $Is_Dos || $Is_MPE || $Is_MacOS) {
  70     skip('SIGINT not safe on this platform') for 1..4;
  71 }
  72 else {
  73   # the next tests are done in a subprocess because sh spits out a
  74   # newline onto stderr when a child process kills itself with SIGINT.
  75   # We use a pipe rather than system() because the VMS command buffer
  76   # would overflow with a command that long.
  77
  78     open( CMDPIPE, "| $PERL");
  79
  80     print CMDPIPE <<'END';
  81
  82     $| = 1;             # command buffering
  83
  84     $SIG{"INT"} = "ok3";     kill "INT",$$; sleep 1;
  85     $SIG{"INT"} = "IGNORE";  kill "INT",$$; sleep 1; print "ok 4\n";
  86     $SIG{"INT"} = "DEFAULT"; kill "INT",$$; sleep 1; print "not ok 4\n";
  87
  88     sub ok3 {
  89         if (($x = pop(@_)) eq "INT") {
  90             print "ok 3\n";
  91         }
  92         else {
  93             print "not ok 3 ($x @_)\n";
  94         }
  95     }
  96
  97 END
  98
  99     close CMDPIPE;
 100
 101     open( CMDPIPE, "| $PERL");
 102     print CMDPIPE <<'END';
 103
 104     { package X;
 105         sub DESTROY {
 106             kill "INT",$$;
 107         }
 108     }
 109     sub x {
 110         my $x=bless [], 'X';
 111         return sub { $x };
 112     }
 113     $| = 1;             # command buffering
 114     $SIG{"INT"} = "ok5";
 115     {
 116         local $SIG{"INT"}=x();
 117         print ""; # Needed to expose failure in 5.8.0 (why?)
 118     }
 119     sleep 1;
 120     delete $SIG{"INT"};
 121     kill "INT",$$; sleep 1;
 122     sub ok5 {
 123         print "ok 5\n";
 124     }
 125 END
 126     close CMDPIPE;
 127     $? >>= 8 if $^O eq 'VMS'; # POSIX status hiding in 2nd byte
 128     print $? & 0xFF ? "ok 6\n" : "not ok 6\n";
 129
 130     $test += 4;
 131 }
 132
 133 # can we slice ENV?
 134 @val1 = @ENV{keys(%ENV)};
 135 @val2 = values(%ENV);
 136 ok join(':',@val1) eq join(':',@val2);
 137 ok @val1 > 1;
 138
 139 # regex vars
 140 'foobarbaz' =~ /b(a)r/;
 141 ok $` eq 'foo', $`;
 142 ok $& eq 'bar', $&;
 143 ok $' eq 'baz', $';
 144 ok $+ eq 'a', $+;
 145
 146 # $"
 147 @a = qw(foo bar baz);
 148 ok "@a" eq "foo bar baz", "@a";
 149 {
 150     local $" = ',';
 151     ok "@a" eq "foo,bar,baz", "@a";
 152 }
 153
 154 # $;
 155 %h = ();
 156 $h{'foo', 'bar'} = 1;
 157 ok((keys %h)[0] eq "foo\034bar", (keys %h)[0]);
 158 {
 159     local $; = 'x';
 160     %h = ();
 161     $h{'foo', 'bar'} = 1;
 162     ok((keys %h)[0] eq 'fooxbar', (keys %h)[0]);
 163 }
 164
 165 # $?, $@, $$
 166 if ($Is_MacOS) {
 167     skip('$? + system are broken on MacPerl') for 1..2;
 168 }
 169 else {
 170     system qq[$PERL "-I../lib" -e "use vmsish qw(hushed); exit(0)"];
 171     ok $? == 0, $?;
 172     system qq[$PERL "-I../lib" -e "use vmsish qw(hushed); exit(1)"];
 173     ok $? != 0, $?;
 174 }
 175
 176 eval { die "foo\n" };
 177 ok $@ eq "foo\n", $@;
 178
 179 ok $$ > 0, $$;
 180 eval { $$++ };
 181 ok $@ =~ /^Modification of a read-only value attempted/;
 182
 183 # $^X and $0
 184 {
 185     if ($^O eq 'qnx') {
 186         chomp($wd = `/usr/bin/fullpath -t`);
 187     }
 188     elsif($Is_Cygwin || $Config{'d_procselfexe'}) {
 189        # Cygwin turns the symlink into the real file
 190        chomp($wd = `pwd`);
 191        $wd =~ s#/t$##;
 192     }
 193     elsif($Is_os2) {
 194        $wd = Cwd::sys_cwd();
 195     }
 196     elsif($Is_MacOS) {
 197        $wd = ':';
 198     }
 199     else {
 200         $wd = '.';
 201     }
 202     my $perl = ($Is_MacOS || $Is_VMS) ? $^X : "$wd/perl";
 203     my $headmaybe = '';
 204     my $tailmaybe = '';
 205     $script = "$wd/show-shebang";
 206     if ($Is_MSWin32) {
 207         chomp($wd = `cd`);
 208         $wd =~ s|\\|/|g;
 209         $perl = "$wd/perl.exe";
 210         $script = "$wd/show-shebang.bat";
 211         $headmaybe = <<EOH ;
 212 \@rem ='
 213 \@echo off
 214 $perl -x \%0
 215 goto endofperl
 216 \@rem ';
 217 EOH
 218         $tailmaybe = <<EOT ;
 219
 220 __END__
 221 :endofperl
 222 EOT
 223     }
 224     elsif ($Is_os2) {
 225       $script = "./show-shebang";
 226     }
 227     elsif ($Is_MacOS) {
 228       $script = ":show-shebang";
 229     }
 230     elsif ($Is_VMS) {
 231       $script = "[]show-shebang";
 232     }
 233     if ($^O eq 'os390' or $^O eq 'posix-bc' or $^O eq 'vmesa') {  # no shebang
 234         $headmaybe = <<EOH ;
 235     eval 'exec ./perl -S \$0 \${1+"\$\@"}'
 236         if 0;
 237 EOH
 238     }
 239     $s1 = "\$^X is $perl, \$0 is $script\n";
 240     ok open(SCRIPT, ">$script"), $!;
 241     ok print(SCRIPT $headmaybe . <<EOB . <<'EOF' . $tailmaybe), $!;
 242 #!$wd/perl
 243 EOB
 244 print "\$^X is $^X, \$0 is $0\n";
 245 EOF
 246     ok close(SCRIPT), $!;
 247     ok chmod(0755, $script), $!;
 248     $_ = ($Is_MacOS || $Is_VMS) ? `$perl $script` : `$script`;
 249     s/\.exe//i if $Is_Dos or $Is_Cygwin or $Is_os2;
 250     s{\bminiperl\b}{perl}; # so that test doesn't fail with miniperl
 251     s{is perl}{is $perl}; # for systems where $^X is only a basename
 252     s{\\}{/}g;
 253     ok((($Is_MSWin32 || $Is_os2) ? uc($_) eq uc($s1) : $_ eq $s1), " :$_:!=:$s1:");
 254     $_ = `$perl $script`;
 255     s/\.exe//i if $Is_Dos or $Is_os2;
 256     s{\\}{/}g;
 257     ok((($Is_MSWin32 || $Is_os2) ? uc($_) eq uc($s1) : $_ eq $s1), " :$_:!=:$s1: after `$perl $script`");
 258     ok unlink($script), $!;
 259 }
 260
 261 # $], $^O, $^T
 262 ok $] >= 5.00319, $];
 263 ok $^O;
 264 ok $^T > 850000000, $^T;
 265
 266 if ($Is_VMS || $Is_Dos || $Is_MacOS) {
 267     skip("%ENV manipulations fail or aren't safe on $^O") for 1..3;
 268 }
 269 else {
 270         $PATH = $ENV{PATH};
 271         $PDL = $ENV{PERL_DESTRUCT_LEVEL} || 0;
 272         $ENV{foo} = "bar";
 273         %ENV = ();
 274         $ENV{PATH} = $PATH;
 275         $ENV{PERL_DESTRUCT_LEVEL} = $PDL || 0;
 276         ok ($Is_MSWin32 ? (`set foo 2>NUL` eq "")
 277                                 : (`echo \$foo` eq "\n") );
 278
 279         $ENV{__NoNeSuCh} = "foo";
 280         $0 = "bar";
 281 # cmd.exe will echo 'variable=value' but 4nt will echo just the value
 282 # -- Nikola Knezevic
 283        ok ($Is_MSWin32 ? (`set __NoNeSuCh` =~ /^(?:__NoNeSuCh=)?foo$/)
 284                             : (`echo \$__NoNeSuCh` eq "foo\n") );
 285         if ($^O =~ /^(linux|freebsd)$/ &&
 286             open CMDLINE, "/proc/$$/cmdline") {
 287             chomp(my $line = scalar <CMDLINE>);
 288             my $me = (split /\0/, $line)[0];
 289             ok($me eq $0, 'altering $0 is effective (testing with /proc/)');
 290             close CMDLINE;
 291             # perlbug #22811
 292             my $mydollarzero = sub {
 293               my($arg) = shift;
 294               $0 = $arg if defined $arg;
 295               my $ps = `ps -o command= -p $$`;
 296               return if $?;
 297               chomp $ps;
 298               printf "# 0[%s]ps[%s]\n", $0, $ps;
 299               $ps;
 300             };
 301             my $ps = $mydollarzero->("x");
 302             ok(!$ps ||   # we allow that something goes wrong with the ps command
 303                $ps eq "x", 'altering $0 is effective (testing with `ps`)');
 304         } else {
 305             skip("\$0 check only on Linux and FreeBSD") for 0,1;
 306         }
 307 }
 308
 309 {
 310     my $ok = 1;
 311     my $warn = '';
 312     local $SIG{'__WARN__'} = sub { $ok = 0; $warn = join '', @_; };
 313     $! = undef;
 314     ok($ok, $warn, $Is_VMS ? "'\$!=undef' does throw a warning" : '');
 315 }
 316
 317 # test case-insignificance of %ENV (these tests must be enabled only
 318 # when perl is compiled with -DENV_IS_CASELESS)
 319 if ($Is_MSWin32 || $Is_NetWare) {
 320     %ENV = ();
 321     $ENV{'Foo'} = 'bar';
 322     $ENV{'fOo'} = 'baz';
 323     ok (scalar(keys(%ENV)) == 1);
 324     ok exists($ENV{'FOo'});
 325     ok (delete($ENV{'foO'}) eq 'baz');
 326     ok (scalar(keys(%ENV)) == 0);
 327 }
 328 else {
 329     skip('no caseless %ENV support') for 1..4;
 330 }
 331
 332 {
 333    no warnings 'void';
 334
 335 # Make sure Errno hasn't been prematurely autoloaded
 336
 337    ok !defined %Errno::;
 338
 339 # Test auto-loading of Errno when %! is used
 340
 341    ok scalar eval q{
 342       %!;
 343       defined %Errno::;
 344    }, $@;
 345 }
 346
 347
 348 # Make sure that Errno loading doesn't clobber $!
 349
 350 undef %Errno::;
 351 delete $INC{"Errno.pm"};
 352
 353 open(FOO, "nonesuch"); # Generate ENOENT
 354 my %errs = %{"!"}; # Cause Errno.pm to be loaded at run-time
 355 ok ${"!"}{ENOENT};
 356
 357 ok $^S == 0 && defined $^S;
 358 eval { ok $^S == 1 };
 359 eval " BEGIN { ok ! defined \$^S } ";
 360 ok $^S == 0 && defined $^S;
 361
 362 ok ${^TAINT} == 0;
 363 eval { ${^TAINT} = 1 };
 364 ok ${^TAINT} == 0;
 365
 366 # 5.6.1 had a bug: @+ and @- were not properly interpolated
 367 # into double-quoted strings
 368 # 20020414 mjd-perl-patch+@plover.com
 369 "I like pie" =~ /(I) (like) (pie)/;
 370 ok "@-" eq  "0 0 2 7";
 371 ok "@+" eq "10 1 6 10";
 372
 373 # Tests for the magic get of $\
 374 {
 375     my $ok = 0;
 376     # [perl #19330]
 377     {
 378         local $\ = undef;
 379         $\++; $\++;
 380         $ok = $\ eq 2;
 381     }
 382     ok $ok;
 383     $ok = 0;
 384     {
 385         local $\ = "a\0b";
 386         $ok = "a$\b" eq "aa\0bb";
 387     }
 388     ok $ok;
 389 }