lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.42';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     $CommandSet
 631     $CreateTTY
 632     $DBGR
 633     @dbline
 634     $dbline
 635     %dbline
 636     $dieLevel
 637     $filename
 638     $histfile
 639     $histsize
 640     $IN
 641     $inhibit_exit
 642     @ini_INC
 643     $ini_warn
 644     $maxtrace
 645     $od
 646     @options
 647     $osingle
 648     $otrace
 649     $pager
 650     $post
 651     %postponed
 652     $prc
 653     $pre
 654     $pretype
 655     $psh
 656     @RememberOnROptions
 657     $remoteport
 658     @res
 659     $rl
 660     @saved
 661     $signalLevel
 662     $sub
 663     $term
 664     $usercontext
 665     $warnLevel
 666 );
 667
 668 our (
 669     @cmdfhs,
 670     $evalarg,
 671     $frame,
 672     $hist,
 673     $ImmediateStop,
 674     $line,
 675     $onetimeDump,
 676     $onetimedumpDepth,
 677     %option,
 678     $OUT,
 679     $packname,
 680     $signal,
 681     $single,
 682     $start,
 683     %sub,
 684     $subname,
 685     $trace,
 686     $window,
 687 );
 688
 689 # Used to save @ARGV and extract any debugger-related flags.
 690 use vars qw(@ARGS);
 691
 692 # Used to prevent multiple entries to diesignal()
 693 # (if for instance diesignal() itself dies)
 694 use vars qw($panic);
 695
 696 # Used to prevent the debugger from running nonstop
 697 # after a restart
 698 our ($second_time);
 699
 700 sub _calc_usercontext {
 701     my ($package) = @_;
 702
 703     # Cancel strict completely for the evaluated code, so the code
 704     # the user evaluates won't be affected by it. (Shlomi Fish)
 705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 706     . "package $package;";    # this won't let them modify, alas
 707 }
 708
 709 sub eval {
 710
 711     # 'my' would make it visible from user code
 712     #    but so does local! --tchrist
 713     # Remember: this localizes @DB::res, not @main::res.
 714     local @res;
 715     {
 716
 717         # Try to keep the user code from messing  with us. Save these so that
 718         # even if the eval'ed code changes them, we can put them back again.
 719         # Needed because the user could refer directly to the debugger's
 720         # package globals (and any 'my' variables in this containing scope)
 721         # inside the eval(), and we want to try to stay safe.
 722         local $otrace  = $trace;
 723         local $osingle = $single;
 724         local $od      = $^D;
 725
 726         # Untaint the incoming eval() argument.
 727         { ($evalarg) = $evalarg =~ /(.*)/s; }
 728
 729         # $usercontext built in DB::DB near the comment
 730         # "set up the context for DB::eval ..."
 731         # Evaluate and save any results.
 732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 733
 734         # Restore those old values.
 735         $trace  = $otrace;
 736         $single = $osingle;
 737         $^D     = $od;
 738     }
 739
 740     # Save the current value of $@, and preserve it in the debugger's copy
 741     # of the saved precious globals.
 742     my $at = $@;
 743
 744     # Since we're only saving $@, we only have to localize the array element
 745     # that it will be stored in.
 746     local $saved[0];    # Preserve the old value of $@
 747     eval { &DB::save };
 748
 749     # Now see whether we need to report an error back to the user.
 750     if ($at) {
 751         local $\ = '';
 752         print $OUT $at;
 753     }
 754
 755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 756     # are package globals.
 757     elsif ($onetimeDump) {
 758         if ( $onetimeDump eq 'dump' ) {
 759             local $option{dumpDepth} = $onetimedumpDepth
 760               if defined $onetimedumpDepth;
 761             dumpit( $OUT, \@res );
 762         }
 763         elsif ( $onetimeDump eq 'methods' ) {
 764             methods( $res[0] );
 765         }
 766     } ## end elsif ($onetimeDump)
 767     @res;
 768 } ## end sub eval
 769
 770 ############################################## End lexical danger zone
 771
 772 # After this point it is safe to introduce lexicals.
 773 # The code being debugged will be executing in its own context, and
 774 # can't see the inside of the debugger.
 775 #
 776 # However, one should not overdo it: leave as much control from outside as
 777 # possible. If you make something a lexical, it's not going to be addressable
 778 # from outside the debugger even if you know its name.
 779
 780 # This file is automatically included if you do perl -d.
 781 # It's probably not useful to include this yourself.
 782 #
 783 # Before venturing further into these twisty passages, it is
 784 # wise to read the perldebguts man page or risk the ire of dragons.
 785 #
 786 # (It should be noted that perldebguts will tell you a lot about
 787 # the underlying mechanics of how the debugger interfaces into the
 788 # Perl interpreter, but not a lot about the debugger itself. The new
 789 # comments in this code try to address this problem.)
 790
 791 # Note that no subroutine call is possible until &DB::sub is defined
 792 # (for subroutines defined outside of the package DB). In fact the same is
 793 # true if $deep is not defined.
 794
 795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 796
 797 # modified Perl debugger, to be run from Emacs in perldb-mode
 798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 799 # Johan Vromans -- upgrade to 4.0 pl 10
 800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 801 ########################################################################
 802
 803 =head1 DEBUGGER INITIALIZATION
 804
 805 The debugger starts up in phases.
 806
 807 =head2 BASIC SETUP
 808
 809 First, it initializes the environment it wants to run in: turning off
 810 warnings during its own compilation, defining variables which it will need
 811 to avoid warnings later, setting itself up to not exit when the program
 812 terminates, and defaulting to printing return values for the C<r> command.
 813
 814 =cut
 815
 816 # Needed for the statement after exec():
 817 #
 818 # This BEGIN block is simply used to switch off warnings during debugger
 819 # compilation. Probably it would be better practice to fix the warnings,
 820 # but this is how it's done at the moment.
 821
 822 BEGIN {
 823     $ini_warn = $^W;
 824     $^W       = 0;
 825 }    # Switch compilation warnings off until another BEGIN.
 826
 827 local ($^W) = 0;    # Switch run-time warnings off during init.
 828
 829 =head2 THREADS SUPPORT
 830
 831 If we are running under a threaded Perl, we require threads and threads::shared
 832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 833 threaded debugger control.  C<-dt> can also be used to set this.
 834
 835 Each new thread will be announced and the debugger prompt will always inform
 836 you of each new thread created.  It will also indicate the thread id in which
 837 we are currently running within the prompt like this:
 838
 839     [tid] DB<$i>
 840
 841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 842 command prompt.  The prompt will show: C<[0]> when running under threads, but
 843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 844
 845 While running under threads, when you set or delete a breakpoint (etc.), this
 846 will apply to all threads, not just the currently running one.  When you are
 847 in a currently executing thread, you will stay there until it completes.  With
 848 the current implementation it is not currently possible to hop from one thread
 849 to another.
 850
 851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 852
 853 Note that threading support was built into the debugger as of Perl version
 854 C<5.8.6> and debugger version C<1.2.8>.
 855
 856 =cut
 857
 858 BEGIN {
 859     # ensure we can share our non-threaded variables or no-op
 860     if ($ENV{PERL5DB_THREADED}) {
 861         require threads;
 862         require threads::shared;
 863         import threads::shared qw(share);
 864         $DBGR;
 865         share(\$DBGR);
 866         lock($DBGR);
 867         print "Threads support enabled\n";
 868     } else {
 869         *share = sub(\[$@%]) {};
 870     }
 871 }
 872
 873 # These variables control the execution of 'dumpvar.pl'.
 874 {
 875     package dumpvar;
 876     use vars qw(
 877     $hashDepth
 878     $arrayDepth
 879     $dumpDBFiles
 880     $dumpPackages
 881     $quoteHighBit
 882     $printUndef
 883     $globPrint
 884     $usageOnly
 885     );
 886 }
 887
 888 # used to control die() reporting in diesignal()
 889 {
 890     package Carp;
 891     use vars qw($CarpLevel);
 892 }
 893
 894 # without threads, $filename is not defined until DB::DB is called
 895 share($main::{'_<'.$filename}) if defined $filename;
 896
 897 # Command-line + PERLLIB:
 898 # Save the contents of @INC before they are modified elsewhere.
 899 @ini_INC = @INC;
 900
 901 # This was an attempt to clear out the previous values of various
 902 # trapped errors. Apparently it didn't help. XXX More info needed!
 903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 904
 905 # We set these variables to safe values. We don't want to blindly turn
 906 # off warnings, because other packages may still want them.
 907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 908                                    # (local $^W cannot help - other packages!).
 909
 910 # Default to not exiting when program finishes; print the return
 911 # value when the 'r' command is used to return from a subroutine.
 912 $inhibit_exit = $option{PrintRet} = 1;
 913
 914 use vars qw($trace_to_depth);
 915
 916 # Default to 1E9 so it won't be limited to a certain recursion depth.
 917 $trace_to_depth = 1E9;
 918
 919 =head1 OPTION PROCESSING
 920
 921 The debugger's options are actually spread out over the debugger itself and
 922 C<dumpvar.pl>; some of these are variables to be set, while others are
 923 subs to be called with a value. To try to make this a little easier to
 924 manage, the debugger uses a few data structures to define what options
 925 are legal and how they are to be processed.
 926
 927 First, the C<@options> array defines the I<names> of all the options that
 928 are to be accepted.
 929
 930 =cut
 931
 932 @options = qw(
 933   CommandSet   HistFile      HistSize
 934   hashDepth    arrayDepth    dumpDepth
 935   DumpDBFiles  DumpPackages  DumpReused
 936   compactDump  veryCompact   quote
 937   HighBit      undefPrint    globPrint
 938   PrintRet     UsageOnly     frame
 939   AutoTrace    TTY           noTTY
 940   ReadLine     NonStop       LineInfo
 941   maxTraceLen  recallCommand ShellBang
 942   pager        tkRunning     ornaments
 943   signalLevel  warnLevel     dieLevel
 944   inhibit_exit ImmediateStop bareStringify
 945   CreateTTY    RemotePort    windowSize
 946   DollarCaretP
 947 );
 948
 949 @RememberOnROptions = qw(DollarCaretP);
 950
 951 =pod
 952
 953 Second, C<optionVars> lists the variables that each option uses to save its
 954 state.
 955
 956 =cut
 957
 958 use vars qw(%optionVars);
 959
 960 %optionVars = (
 961     hashDepth     => \$dumpvar::hashDepth,
 962     arrayDepth    => \$dumpvar::arrayDepth,
 963     CommandSet    => \$CommandSet,
 964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 965     DumpPackages  => \$dumpvar::dumpPackages,
 966     DumpReused    => \$dumpvar::dumpReused,
 967     HighBit       => \$dumpvar::quoteHighBit,
 968     undefPrint    => \$dumpvar::printUndef,
 969     globPrint     => \$dumpvar::globPrint,
 970     UsageOnly     => \$dumpvar::usageOnly,
 971     CreateTTY     => \$CreateTTY,
 972     bareStringify => \$dumpvar::bareStringify,
 973     frame         => \$frame,
 974     AutoTrace     => \$trace,
 975     inhibit_exit  => \$inhibit_exit,
 976     maxTraceLen   => \$maxtrace,
 977     ImmediateStop => \$ImmediateStop,
 978     RemotePort    => \$remoteport,
 979     windowSize    => \$window,
 980     HistFile      => \$histfile,
 981     HistSize      => \$histsize,
 982 );
 983
 984 =pod
 985
 986 Third, C<%optionAction> defines the subroutine to be called to process each
 987 option.
 988
 989 =cut
 990
 991 use vars qw(%optionAction);
 992
 993 %optionAction = (
 994     compactDump   => \&dumpvar::compactDump,
 995     veryCompact   => \&dumpvar::veryCompact,
 996     quote         => \&dumpvar::quote,
 997     TTY           => \&TTY,
 998     noTTY         => \&noTTY,
 999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 our ($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed,
1366                      and have actions
1367   PERLDB_VISITED   - files that had breakpoints
1368   PERLDB_FILE_...  - breakpoints for a file
1369   PERLDB_OPT       - active options
1370   PERLDB_INC       - the original @INC
1371   PERLDB_PRETYPE   - preprompt debugger actions
1372   PERLDB_PRE       - preprompt Perl code
1373   PERLDB_POST      - post-prompt Perl code
1374   PERLDB_TYPEAHEAD - typeahead captured by readline()
1375
1376 We chug through all these variables and plug the values saved in them
1377 back into the appropriate spots in the debugger.
1378
1379 =cut
1380
1381 use vars qw(%postponed_file @typeahead);
1382
1383 our (@hist, @truehist);
1384
1385 sub _restore_shared_globals_after_restart
1386 {
1387     @hist          = get_list('PERLDB_HIST');
1388     %break_on_load = get_list("PERLDB_ON_LOAD");
1389     %postponed     = get_list("PERLDB_POSTPONE");
1390
1391     share(@hist);
1392     share(@truehist);
1393     share(%break_on_load);
1394     share(%postponed);
1395 }
1396
1397 sub _restore_breakpoints_and_actions {
1398
1399     my @had_breakpoints = get_list("PERLDB_VISITED");
1400
1401     for my $file_idx ( 0 .. $#had_breakpoints ) {
1402         my $filename = $had_breakpoints[$file_idx];
1403         my %pf = get_list("PERLDB_FILE_$file_idx");
1404         $postponed_file{ $filename } = \%pf if %pf;
1405         my @lines = sort {$a <=> $b} keys(%pf);
1406         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1407         for my $line_idx (0 .. $#lines) {
1408             _set_breakpoint_enabled_status(
1409                 $filename,
1410                 $lines[$line_idx],
1411                 ($enabled_statuses[$line_idx] ? 1 : ''),
1412             );
1413         }
1414     }
1415
1416     return;
1417 }
1418
1419 sub _restore_options_after_restart
1420 {
1421     my %options_map = get_list("PERLDB_OPT");
1422
1423     while ( my ( $opt, $val ) = each %options_map ) {
1424         $val =~ s/[\\\']/\\$1/g;
1425         parse_options("$opt'$val'");
1426     }
1427
1428     return;
1429 }
1430
1431 sub _restore_globals_after_restart
1432 {
1433     # restore original @INC
1434     @INC     = get_list("PERLDB_INC");
1435     @ini_INC = @INC;
1436
1437     # return pre/postprompt actions and typeahead buffer
1438     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1439     $pre       = [ get_list("PERLDB_PRE") ];
1440     $post      = [ get_list("PERLDB_POST") ];
1441     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1442
1443     return;
1444 }
1445
1446
1447 if ( exists $ENV{PERLDB_RESTART} ) {
1448
1449     # We're restarting, so we don't need the flag that says to restart anymore.
1450     delete $ENV{PERLDB_RESTART};
1451
1452     # $restart = 1;
1453     _restore_shared_globals_after_restart();
1454
1455     _restore_breakpoints_and_actions();
1456
1457     # restore options
1458     _restore_options_after_restart();
1459
1460     _restore_globals_after_restart();
1461 } ## end if (exists $ENV{PERLDB_RESTART...
1462
1463 =head2 SETTING UP THE TERMINAL
1464
1465 Now, we'll decide how the debugger is going to interact with the user.
1466 If there's no TTY, we set the debugger to run non-stop; there's not going
1467 to be anyone there to enter commands.
1468
1469 =cut
1470
1471 use vars qw($notty $console $tty $LINEINFO);
1472 use vars qw($lineinfo $doccmd);
1473
1474 our ($runnonstop);
1475
1476 # Local autoflush to avoid rt#116769,
1477 # as calling IO::File methods causes an unresolvable loop
1478 # that results in debugger failure.
1479 sub _autoflush {
1480     my $o = select($_[0]);
1481     $|++;
1482     select($o);
1483 }
1484
1485 if ($notty) {
1486     $runnonstop = 1;
1487     share($runnonstop);
1488 }
1489
1490 =pod
1491
1492 If there is a TTY, we have to determine who it belongs to before we can
1493 proceed. If this is a slave editor or graphical debugger (denoted by
1494 the first command-line switch being '-emacs'), we shift this off and
1495 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1496
1497 =cut
1498
1499 else {
1500
1501     # Is Perl being run from a slave editor or graphical debugger?
1502     # If so, don't use readline, and set $slave_editor = 1.
1503     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1504         $rl = 0;
1505         shift(@main::ARGV);
1506     }
1507
1508     #require Term::ReadLine;
1509
1510 =pod
1511
1512 We then determine what the console should be on various systems:
1513
1514 =over 4
1515
1516 =item * Cygwin - We use C<stdin> instead of a separate device.
1517
1518 =cut
1519
1520     if ( $^O eq 'cygwin' ) {
1521
1522         # /dev/tty is binary. use stdin for textmode
1523         undef $console;
1524     }
1525
1526 =item * Unix - use F</dev/tty>.
1527
1528 =cut
1529
1530     elsif ( -e "/dev/tty" ) {
1531         $console = "/dev/tty";
1532     }
1533
1534 =item * Windows or MSDOS - use C<con>.
1535
1536 =cut
1537
1538     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1539         $console = "con";
1540     }
1541
1542 =item * VMS - use C<sys$command>.
1543
1544 =cut
1545
1546     else {
1547
1548         # everything else is ...
1549         $console = "sys\$command";
1550     }
1551
1552 =pod
1553
1554 =back
1555
1556 Several other systems don't use a specific console. We C<undef $console>
1557 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1558 with a slave editor).
1559
1560 =cut
1561
1562     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1563
1564         # /dev/tty is binary. use stdin for textmode
1565         $console = undef;
1566     }
1567
1568     if ( $^O eq 'NetWare' ) {
1569
1570         # /dev/tty is binary. use stdin for textmode
1571         $console = undef;
1572     }
1573
1574     # In OS/2, we need to use STDIN to get textmode too, even though
1575     # it pretty much looks like Unix otherwise.
1576     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1577     {    # In OS/2
1578         $console = undef;
1579     }
1580
1581 =pod
1582
1583 If there is a TTY hanging around from a parent, we use that as the console.
1584
1585 =cut
1586
1587     $console = $tty if defined $tty;
1588
1589 =head2 SOCKET HANDLING
1590
1591 The debugger is capable of opening a socket and carrying out a debugging
1592 session over the socket.
1593
1594 If C<RemotePort> was defined in the options, the debugger assumes that it
1595 should try to start a debugging session on that port. It builds the socket
1596 and then tries to connect the input and output filehandles to it.
1597
1598 =cut
1599
1600     # Handle socket stuff.
1601
1602     if ( defined $remoteport ) {
1603
1604         # If RemotePort was defined in the options, connect input and output
1605         # to the socket.
1606         $IN = $OUT = connect_remoteport();
1607     } ## end if (defined $remoteport)
1608
1609 =pod
1610
1611 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1612 this is probably a situation where multiple debuggers are running (for example,
1613 a backticked command that starts up another debugger). We create a new IN and
1614 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1615 and if we can.
1616
1617 =cut
1618
1619     # Non-socket.
1620     else {
1621
1622         # Two debuggers running (probably a system or a backtick that invokes
1623         # the debugger itself under the running one). create a new IN and OUT
1624         # filehandle, and do the necessary mojo to create a new tty if we
1625         # know how, and we can.
1626         create_IN_OUT(4) if $CreateTTY & 4;
1627         if ($console) {
1628
1629             # If we have a console, check to see if there are separate ins and
1630             # outs to open. (They are assumed identical if not.)
1631
1632             my ( $i, $o ) = split /,/, $console;
1633             $o = $i unless defined $o;
1634
1635             # read/write on in, or just read, or read on STDIN.
1636             open( IN,      "+<$i" )
1637               || open( IN, "<$i" )
1638               || open( IN, "<&STDIN" );
1639
1640             # read/write/create/clobber out, or write/create/clobber out,
1641             # or merge with STDERR, or merge with STDOUT.
1642                  open( OUT, "+>$o" )
1643               || open( OUT, ">$o" )
1644               || open( OUT, ">&STDERR" )
1645               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1646
1647         } ## end if ($console)
1648         elsif ( not defined $console ) {
1649
1650             # No console. Open STDIN.
1651             open( IN, "<&STDIN" );
1652
1653             # merge with STDERR, or with STDOUT.
1654             open( OUT,      ">&STDERR" )
1655               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1656             $console = 'STDIN/OUT';
1657         } ## end elsif (not defined $console)
1658
1659         # Keep copies of the filehandles so that when the pager runs, it
1660         # can close standard input without clobbering ours.
1661         if ($console or (not defined($console))) {
1662             $IN = \*IN;
1663             $OUT = \*OUT;
1664         }
1665     } ## end elsif (from if(defined $remoteport))
1666
1667     # Unbuffer DB::OUT. We need to see responses right away.
1668     _autoflush($OUT);
1669
1670     # Line info goes to debugger output unless pointed elsewhere.
1671     # Pointing elsewhere makes it possible for slave editors to
1672     # keep track of file and position. We have both a filehandle
1673     # and a I/O description to keep track of.
1674     $LINEINFO = $OUT     unless defined $LINEINFO;
1675     $lineinfo = $console unless defined $lineinfo;
1676     # share($LINEINFO); # <- unable to share globs
1677     share($lineinfo);   #
1678
1679 =pod
1680
1681 To finish initialization, we show the debugger greeting,
1682 and then call the C<afterinit()> subroutine if there is one.
1683
1684 =cut
1685
1686     # Show the debugger greeting.
1687     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1688     unless ($runnonstop) {
1689         local $\ = '';
1690         local $, = '';
1691         if ( $term_pid eq '-1' ) {
1692             print $OUT "\nDaughter DB session started...\n";
1693         }
1694         else {
1695             print $OUT "\nLoading DB routines from $header\n";
1696             print $OUT (
1697                 "Editor support ",
1698                 $slave_editor ? "enabled" : "available", ".\n"
1699             );
1700             print $OUT
1701 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1702         } ## end else [ if ($term_pid eq '-1')
1703     } ## end unless ($runnonstop)
1704 } ## end else [ if ($notty)
1705
1706 # XXX This looks like a bug to me.
1707 # Why copy to @ARGS and then futz with @args?
1708 @ARGS = @ARGV;
1709 # for (@args) {
1710     # Make sure backslashes before single quotes are stripped out, and
1711     # keep args unless they are numeric (XXX why?)
1712     # s/\'/\\\'/g;                      # removed while not justified understandably
1713     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1714 # }
1715
1716 # If there was an afterinit() sub defined, call it. It will get
1717 # executed in our scope, so it can fiddle with debugger globals.
1718 if ( defined &afterinit ) {    # May be defined in $rcfile
1719     afterinit();
1720 }
1721
1722 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1723 use vars qw($I_m_init);
1724
1725 $I_m_init = 1;
1726
1727 ############################################################ Subroutines
1728
1729 =head1 SUBROUTINES
1730
1731 =head2 DB
1732
1733 This gigantic subroutine is the heart of the debugger. Called before every
1734 statement, its job is to determine if a breakpoint has been reached, and
1735 stop if so; read commands from the user, parse them, and execute
1736 them, and then send execution off to the next statement.
1737
1738 Note that the order in which the commands are processed is very important;
1739 some commands earlier in the loop will actually alter the C<$cmd> variable
1740 to create other commands to be executed later. This is all highly I<optimized>
1741 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1742 see what's happening in any given command.
1743
1744 =cut
1745
1746 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1747
1748 use vars qw(
1749     $action
1750     $cmd
1751     $file
1752     $filename_ini
1753     $finished
1754     %had_breakpoints
1755     $level
1756     $max
1757     $package
1758     $try
1759 );
1760
1761 our (
1762     %alias,
1763     $doret,
1764     $end,
1765     $fall_off_end,
1766     $incr,
1767     $laststep,
1768     $rc,
1769     $sh,
1770     $stack_depth,
1771     @stack,
1772     @to_watch,
1773     @old_watch,
1774 );
1775
1776 sub _DB__determine_if_we_should_break
1777 {
1778     # if we have something here, see if we should break.
1779     # $stop is lexical and local to this block - $action on the other hand
1780     # is global.
1781     my $stop;
1782
1783     if ( $dbline{$line}
1784         && _is_breakpoint_enabled($filename, $line)
1785         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1786     {
1787
1788         # Stop if the stop criterion says to just stop.
1789         if ( $stop eq '1' ) {
1790             $signal |= 1;
1791         }
1792
1793         # It's a conditional stop; eval it in the user's context and
1794         # see if we should stop. If so, remove the one-time sigil.
1795         elsif ($stop) {
1796             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1797             # The &-call is here to ascertain the mutability of @_.
1798             &DB::eval;
1799             # If the breakpoint is temporary, then delete its enabled status.
1800             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1801                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1802             }
1803         }
1804     } ## end if ($dbline{$line} && ...
1805 }
1806
1807 sub _DB__is_finished {
1808     if ($finished and $level <= 1) {
1809         end_report();
1810         return 1;
1811     }
1812     else {
1813         return;
1814     }
1815 }
1816
1817 sub _DB__read_next_cmd
1818 {
1819     my ($tid) = @_;
1820
1821     # We have a terminal, or can get one ...
1822     if (!$term) {
1823         setterm();
1824     }
1825
1826     # ... and it belongs to this PID or we get one for this PID ...
1827     if ($term_pid != $$) {
1828         resetterm(1);
1829     }
1830
1831     # ... and we got a line of command input ...
1832     $cmd = DB::readline(
1833         "$pidprompt $tid DB"
1834         . ( '<' x $level )
1835         . ( $#hist + 1 )
1836         . ( '>' x $level ) . " "
1837     );
1838
1839     return defined($cmd);
1840 }
1841
1842 sub _DB__trim_command_and_return_first_component {
1843     my ($obj) = @_;
1844
1845     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1846     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1847
1848     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1849
1850     $obj->cmd_verb($verb);
1851     $obj->cmd_args($args);
1852
1853     return;
1854 }
1855
1856 sub _DB__handle_f_command {
1857     my ($obj) = @_;
1858
1859     if ($file = $obj->cmd_args) {
1860         # help for no arguments (old-style was return from sub).
1861         if ( !$file ) {
1862             print $OUT
1863             "The old f command is now the r command.\n";    # hint
1864             print $OUT "The new f command switches filenames.\n";
1865             next CMD;
1866         } ## end if (!$file)
1867
1868         # if not in magic file list, try a close match.
1869         if ( !defined $main::{ '_<' . $file } ) {
1870             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1871                 {
1872                     $try = substr( $try, 2 );
1873                     print $OUT "Choosing $try matching '$file':\n";
1874                     $file = $try;
1875                 }
1876             } ## end if (($try) = grep(m#^_<.*$file#...
1877         } ## end if (!defined $main::{ ...
1878
1879         # If not successfully switched now, we failed.
1880         if ( !defined $main::{ '_<' . $file } ) {
1881             print $OUT "No file matching '$file' is loaded.\n";
1882             next CMD;
1883         }
1884
1885         # We switched, so switch the debugger internals around.
1886         elsif ( $file ne $filename ) {
1887             *dbline   = $main::{ '_<' . $file };
1888             $max      = $#dbline;
1889             $filename = $file;
1890             $start    = 1;
1891             $cmd      = "l";
1892         } ## end elsif ($file ne $filename)
1893
1894         # We didn't switch; say we didn't.
1895         else {
1896             print $OUT "Already in $file.\n";
1897             next CMD;
1898         }
1899     }
1900
1901     return;
1902 }
1903
1904 sub _DB__handle_dot_command {
1905     my ($obj) = @_;
1906
1907     # . command.
1908     if ($obj->_is_full('.')) {
1909         $incr = -1;    # stay at current line
1910
1911         # Reset everything to the old location.
1912         $start    = $line;
1913         $filename = $filename_ini;
1914         *dbline   = $main::{ '_<' . $filename };
1915         $max      = $#dbline;
1916
1917         # Now where are we?
1918         print_lineinfo($obj->position());
1919         next CMD;
1920     }
1921
1922     return;
1923 }
1924
1925 sub _DB__handle_y_command {
1926     my ($obj) = @_;
1927
1928     if (my ($match_level, $match_vars)
1929         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1930
1931         # See if we've got the necessary support.
1932         if (!eval { require PadWalker; PadWalker->VERSION(0.08) }) {
1933             my $Err = $@;
1934             _db_warn(
1935                 $Err =~ /locate/
1936                 ? "PadWalker module not found - please install\n"
1937                 : $Err
1938             );
1939             next CMD;
1940         }
1941
1942         # Load up dumpvar if we don't have it. If we can, that is.
1943         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1944         defined &main::dumpvar
1945             or print $OUT "dumpvar.pl not available.\n"
1946             and next CMD;
1947
1948         # Got all the modules we need. Find them and print them.
1949         my @vars = split( ' ', $match_vars || '' );
1950
1951         # Find the pad.
1952         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1953
1954         # Oops. Can't find it.
1955         if (my $Err = $@) {
1956             $Err =~ s/ at .*//;
1957             _db_warn($Err);
1958             next CMD;
1959         }
1960
1961         # Show the desired vars with dumplex().
1962         my $savout = select($OUT);
1963
1964         # Have dumplex dump the lexicals.
1965         foreach my $key (sort keys %$h) {
1966             dumpvar::dumplex( $key, $h->{$key},
1967                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1968                 @vars );
1969         }
1970         select($savout);
1971         next CMD;
1972     }
1973 }
1974
1975 sub _DB__handle_c_command {
1976     my ($obj) = @_;
1977
1978     my $i = $obj->cmd_args;
1979
1980     if ($i =~ m#\A[\w:]*\z#) {
1981
1982         # Hey, show's over. The debugged program finished
1983         # executing already.
1984         next CMD if _DB__is_finished();
1985
1986         # Capture the place to put a one-time break.
1987         $subname = $i;
1988
1989         #  Probably not needed, since we finish an interactive
1990         #  sub-session anyway...
1991         # local $filename = $filename;
1992         # local *dbline = *dbline; # XXX Would this work?!
1993         #
1994         # The above question wonders if localizing the alias
1995         # to the magic array works or not. Since it's commented
1996         # out, we'll just leave that to speculation for now.
1997
1998         # If the "subname" isn't all digits, we'll assume it
1999         # is a subroutine name, and try to find it.
2000         if ( $subname =~ /\D/ ) {    # subroutine name
2001             # Qualify it to the current package unless it's
2002             # already qualified.
2003             $subname = $package . "::" . $subname
2004             unless $subname =~ /::/;
2005
2006             # find_sub will return "file:line_number" corresponding
2007             # to where the subroutine is defined; we call find_sub,
2008             # break up the return value, and assign it in one
2009             # operation.
2010             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2011
2012             # Force the line number to be numeric.
2013             $i = $i + 0;
2014
2015             # If we got a line number, we found the sub.
2016             if ($i) {
2017
2018                 # Switch all the debugger's internals around so
2019                 # we're actually working with that file.
2020                 $filename = $file;
2021                 *dbline   = $main::{ '_<' . $filename };
2022
2023                 # Mark that there's a breakpoint in this file.
2024                 $had_breakpoints{$filename} |= 1;
2025
2026                 # Scan forward to the first executable line
2027                 # after the 'sub whatever' line.
2028                 $max = $#dbline;
2029                 my $_line_num = $i;
2030                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2031                 {
2032                     $_line_num++;
2033                 }
2034                 $i = $_line_num;
2035             } ## end if ($i)
2036
2037             # We didn't find a sub by that name.
2038             else {
2039                 print $OUT "Subroutine $subname not found.\n";
2040                 next CMD;
2041             }
2042         } ## end if ($subname =~ /\D/)
2043
2044         # At this point, either the subname was all digits (an
2045         # absolute line-break request) or we've scanned through
2046         # the code following the definition of the sub, looking
2047         # for an executable, which we may or may not have found.
2048         #
2049         # If $i (which we set $subname from) is non-zero, we
2050         # got a request to break at some line somewhere. On
2051         # one hand, if there wasn't any real subroutine name
2052         # involved, this will be a request to break in the current
2053         # file at the specified line, so we have to check to make
2054         # sure that the line specified really is breakable.
2055         #
2056         # On the other hand, if there was a subname supplied, the
2057         # preceding block has moved us to the proper file and
2058         # location within that file, and then scanned forward
2059         # looking for the next executable line. We have to make
2060         # sure that one was found.
2061         #
2062         # On the gripping hand, we can't do anything unless the
2063         # current value of $i points to a valid breakable line.
2064         # Check that.
2065         if ($i) {
2066
2067             # Breakable?
2068             if ( $dbline[$i] == 0 ) {
2069                 print $OUT "Line $i not breakable.\n";
2070                 next CMD;
2071             }
2072
2073             # Yes. Set up the one-time-break sigil.
2074             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2075             _enable_breakpoint_temp_enabled_status($filename, $i);
2076         } ## end if ($i)
2077
2078         # Turn off stack tracing from here up.
2079         for my $j (0 .. $stack_depth) {
2080             $stack[ $j ] &= ~1;
2081         }
2082         last CMD;
2083     }
2084
2085     return;
2086 }
2087
2088 sub _DB__handle_forward_slash_command {
2089     my ($obj) = @_;
2090
2091     # The pattern as a string.
2092     use vars qw($inpat);
2093
2094     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2095
2096         # Remove the final slash.
2097         $inpat =~ s:([^\\])/$:$1:;
2098
2099         # If the pattern isn't null ...
2100         if ( $inpat ne "" ) {
2101
2102             # Turn off warn and die processing for a bit.
2103             local $SIG{__DIE__};
2104             local $SIG{__WARN__};
2105
2106             # Create the pattern.
2107             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2108             if ( $@ ne "" ) {
2109
2110                 # Oops. Bad pattern. No biscuit.
2111                 # Print the eval error and go back for more
2112                 # commands.
2113                 print {$OUT} "$@";
2114                 next CMD;
2115             }
2116             $obj->pat($inpat);
2117         } ## end if ($inpat ne "")
2118
2119         # Set up to stop on wrap-around.
2120         $end = $start;
2121
2122         # Don't move off the current line.
2123         $incr = -1;
2124
2125         my $pat = $obj->pat;
2126
2127         # Done in eval so nothing breaks if the pattern
2128         # does something weird.
2129         eval
2130         {
2131             no strict q/vars/;
2132             for (;;) {
2133                 # Move ahead one line.
2134                 ++$start;
2135
2136                 # Wrap if we pass the last line.
2137                 if ($start > $max) {
2138                     $start = 1;
2139                 }
2140
2141                 # Stop if we have gotten back to this line again,
2142                 last if ($start == $end);
2143
2144                 # A hit! (Note, though, that we are doing
2145                 # case-insensitive matching. Maybe a qr//
2146                 # expression would be better, so the user could
2147                 # do case-sensitive matching if desired.
2148                 if ($dbline[$start] =~ m/$pat/i) {
2149                     if ($slave_editor) {
2150                         # Handle proper escaping in the slave.
2151                         print {$OUT} "\032\032$filename:$start:0\n";
2152                     }
2153                     else {
2154                         # Just print the line normally.
2155                         print {$OUT} "$start:\t",$dbline[$start],"\n";
2156                     }
2157                     # And quit since we found something.
2158                     last;
2159                 }
2160             }
2161         };
2162
2163         if ($@) {
2164             warn $@;
2165         }
2166
2167         # If we wrapped, there never was a match.
2168         if ( $start == $end ) {
2169             print {$OUT} "/$pat/: not found\n";
2170         }
2171         next CMD;
2172     }
2173
2174     return;
2175 }
2176
2177 sub _DB__handle_question_mark_command {
2178     my ($obj) = @_;
2179
2180     # ? - backward pattern search.
2181     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2182
2183         # Get the pattern, remove trailing question mark.
2184         $inpat =~ s:([^\\])\?$:$1:;
2185
2186         # If we've got one ...
2187         if ( $inpat ne "" ) {
2188
2189             # Turn off die & warn handlers.
2190             local $SIG{__DIE__};
2191             local $SIG{__WARN__};
2192             eval '$inpat =~ m' . "\a$inpat\a";
2193
2194             if ( $@ ne "" ) {
2195
2196                 # Ouch. Not good. Print the error.
2197                 print $OUT $@;
2198                 next CMD;
2199             }
2200             $obj->pat($inpat);
2201         } ## end if ($inpat ne "")
2202
2203         # Where we are now is where to stop after wraparound.
2204         $end = $start;
2205
2206         # Don't move away from this line.
2207         $incr = -1;
2208
2209         my $pat = $obj->pat;
2210         # Search inside the eval to prevent pattern badness
2211         # from killing us.
2212         eval {
2213             no strict q/vars/;
2214             for (;;) {
2215                 # Back up a line.
2216                 --$start;
2217
2218                 # Wrap if we pass the first line.
2219
2220                 $start = $max if ($start <= 0);
2221
2222                 # Quit if we get back where we started,
2223                 last if ($start == $end);
2224
2225                 # Match?
2226                 if ($dbline[$start] =~ m/$pat/i) {
2227                     if ($slave_editor) {
2228                         # Yep, follow slave editor requirements.
2229                         print $OUT "\032\032$filename:$start:0\n";
2230                     }
2231                     else {
2232                         # Yep, just print normally.
2233                         print $OUT "$start:\t",$dbline[$start],"\n";
2234                     }
2235
2236                     # Found, so done.
2237                     last;
2238                 }
2239             }
2240         };
2241
2242         # Say we failed if the loop never found anything,
2243         if ( $start == $end ) {
2244             print {$OUT} "?$pat?: not found\n";
2245         }
2246         next CMD;
2247     }
2248
2249     return;
2250 }
2251
2252 sub _DB__handle_restart_and_rerun_commands {
2253     my ($obj) = @_;
2254
2255     my $cmd_cmd = $obj->cmd_verb;
2256     my $cmd_params = $obj->cmd_args;
2257     # R - restart execution.
2258     # rerun - controlled restart execution.
2259     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2260         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2261
2262         # Close all non-system fds for a clean restart.  A more
2263         # correct method would be to close all fds that were not
2264         # open when the process started, but this seems to be
2265         # hard.  See "debugger 'R'estart and open database
2266         # connections" on p5p.
2267
2268         my $max_fd = 1024; # default if POSIX can't be loaded
2269         if (eval { require POSIX }) {
2270             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2271         }
2272
2273         if (defined $max_fd) {
2274             foreach ($^F+1 .. $max_fd-1) {
2275                 next unless open FD_TO_CLOSE, "<&=$_";
2276                 close(FD_TO_CLOSE);
2277             }
2278         }
2279
2280         # And run Perl again.  We use exec() to keep the
2281         # PID stable (and that way $ini_pids is still valid).
2282         exec(@args) or print {$OUT} "exec failed: $!\n";
2283
2284         last CMD;
2285     }
2286
2287     return;
2288 }
2289
2290 sub _DB__handle_run_command_in_pager_command {
2291     my ($obj) = @_;
2292
2293     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2294         if ( $pager =~ /^\|/ ) {
2295
2296             # Default pager is into a pipe. Redirect I/O.
2297             open( SAVEOUT, ">&STDOUT" )
2298             || _db_warn("Can't save STDOUT");
2299             open( STDOUT, ">&OUT" )
2300             || _db_warn("Can't redirect STDOUT");
2301         } ## end if ($pager =~ /^\|/)
2302         else {
2303
2304             # Not into a pipe. STDOUT is safe.
2305             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2306         }
2307
2308         # Fix up environment to record we have less if so.
2309         fix_less();
2310
2311         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2312
2313             # Couldn't open pipe to pager.
2314             _db_warn("Can't pipe output to '$pager'");
2315             if ( $pager =~ /^\|/ ) {
2316
2317                 # Redirect I/O back again.
2318                 open( OUT, ">&STDOUT" )    # XXX: lost message
2319                 || _db_warn("Can't restore DB::OUT");
2320                 open( STDOUT, ">&SAVEOUT" )
2321                 || _db_warn("Can't restore STDOUT");
2322                 close(SAVEOUT);
2323             } ## end if ($pager =~ /^\|/)
2324             else {
2325
2326                 # Redirect I/O. STDOUT already safe.
2327                 open( OUT, ">&STDOUT" )    # XXX: lost message
2328                 || _db_warn("Can't restore DB::OUT");
2329             }
2330             next CMD;
2331         } ## end unless ($piped = open(OUT,...
2332
2333         # Set up broken-pipe handler if necessary.
2334         $SIG{PIPE} = \&DB::catch
2335         if $pager =~ /^\|/
2336         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2337
2338         _autoflush(\*OUT);
2339         # Save current filehandle, and put it back.
2340         $obj->selected(scalar( select(OUT) ));
2341         # Don't put it back if pager was a pipe.
2342         if ($cmd !~ /\A\|\|/)
2343         {
2344             select($obj->selected());
2345             $obj->selected("");
2346         }
2347
2348         # Trim off the pipe symbols and run the command now.
2349         $cmd =~ s#\A\|+\s*##;
2350         redo PIPE;
2351     }
2352
2353     return;
2354 }
2355
2356 sub _DB__handle_m_command {
2357     my ($obj) = @_;
2358
2359     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2360         methods($1);
2361         next CMD;
2362     }
2363
2364     # m expr - set up DB::eval to do the work
2365     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2366         $onetimeDump = 'methods';   #  method output gets used there
2367     }
2368
2369     return;
2370 }
2371
2372 sub _DB__at_end_of_every_command {
2373     my ($obj) = @_;
2374
2375     # At the end of every command:
2376     if ($obj->piped) {
2377
2378         # Unhook the pipe mechanism now.
2379         if ( $pager =~ /^\|/ ) {
2380
2381             # No error from the child.
2382             $? = 0;
2383
2384             # we cannot warn here: the handle is missing --tchrist
2385             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2386
2387             # most of the $? crud was coping with broken cshisms
2388             # $? is explicitly set to 0, so this never runs.
2389             if ($?) {
2390                 print SAVEOUT "Pager '$pager' failed: ";
2391                 if ( $? == -1 ) {
2392                     print SAVEOUT "shell returned -1\n";
2393                 }
2394                 elsif ( $? >> 8 ) {
2395                     print SAVEOUT ( $? & 127 )
2396                     ? " (SIG#" . ( $? & 127 ) . ")"
2397                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2398                 }
2399                 else {
2400                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2401                 }
2402             } ## end if ($?)
2403
2404             # Reopen filehandle for our output (if we can) and
2405             # restore STDOUT (if we can).
2406             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2407             open( STDOUT, ">&SAVEOUT" )
2408             || _db_warn("Can't restore STDOUT");
2409
2410             # Turn off pipe exception handler if necessary.
2411             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2412
2413             # Will stop ignoring SIGPIPE if done like nohup(1)
2414             # does SIGINT but Perl doesn't give us a choice.
2415         } ## end if ($pager =~ /^\|/)
2416         else {
2417
2418             # Non-piped "pager". Just restore STDOUT.
2419             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2420         }
2421
2422         # Close filehandle pager was using, restore the normal one
2423         # if necessary,
2424         close(SAVEOUT);
2425
2426         if ($obj->selected() ne "") {
2427             select($obj->selected);
2428             $obj->selected("");
2429         }
2430
2431         # No pipes now.
2432         $obj->piped("");
2433     } ## end if ($piped)
2434
2435     return;
2436 }
2437
2438 sub _DB__handle_watch_expressions
2439 {
2440     my $self = shift;
2441
2442     if ( $DB::trace & 2 ) {
2443         for my $n (0 .. $#DB::to_watch) {
2444             $DB::evalarg = $DB::to_watch[$n];
2445             local $DB::onetimeDump;    # Tell DB::eval() to not output results
2446
2447             # Fix context DB::eval() wants to return an array, but
2448             # we need a scalar here.
2449             my ($val) = join( "', '", DB::eval(@_) );
2450             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
2451
2452             # Did it change?
2453             if ( $val ne $DB::old_watch[$n] ) {
2454
2455                 # Yep! Show the difference, and fake an interrupt.
2456                 $DB::signal = 1;
2457                 print {$DB::OUT} <<EOP;
2458 Watchpoint $n:\t$DB::to_watch[$n] changed:
2459     old value:\t$DB::old_watch[$n]
2460     new value:\t$val
2461 EOP
2462                 $DB::old_watch[$n] = $val;
2463             } ## end if ($val ne $old_watch...
2464         } ## end for my $n (0 ..
2465     } ## end if ($trace & 2)
2466
2467     return;
2468 }
2469
2470 # 't' is type.
2471 # 'm' is method.
2472 # 'v' is the value (i.e: method name or subroutine ref).
2473 # 's' is subroutine.
2474 my %cmd_lookup =
2475 (
2476     '-' => { t => 'm', v => '_handle_dash_command', },
2477     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2478     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2479     'H' => { t => 'm', v => '_handle_H_command', },
2480     'S' => { t => 'm', v => '_handle_S_command', },
2481     'T' => { t => 'm', v => '_handle_T_command', },
2482     'W' => { t => 'm', v => '_handle_W_command', },
2483     'c' => { t => 's', v => \&_DB__handle_c_command, },
2484     'f' => { t => 's', v => \&_DB__handle_f_command, },
2485     'm' => { t => 's', v => \&_DB__handle_m_command, },
2486     'n' => { t => 'm', v => '_handle_n_command', },
2487     'p' => { t => 'm', v => '_handle_p_command', },
2488     'q' => { t => 'm', v => '_handle_q_command', },
2489     'r' => { t => 'm', v => '_handle_r_command', },
2490     's' => { t => 'm', v => '_handle_s_command', },
2491     'save' => { t => 'm', v => '_handle_save_command', },
2492     'source' => { t => 'm', v => '_handle_source_command', },
2493     't' => { t => 'm', v => '_handle_t_command', },
2494     'w' => { t => 'm', v => '_handle_w_command', },
2495     'x' => { t => 'm', v => '_handle_x_command', },
2496     'y' => { t => 's', v => \&_DB__handle_y_command, },
2497     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2498         ('X', 'V')),
2499     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2500         qw(enable disable)),
2501     (map { $_ =>
2502         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2503         } qw(R rerun)),
2504     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2505         qw(a A b B e E h i l L M o O v w W)),
2506 );
2507
2508 sub DB {
2509
2510     # lock the debugger and get the thread id for the prompt
2511     lock($DBGR);
2512     my $tid;
2513     my $position;
2514     my ($prefix, $after, $infix);
2515     my $pat;
2516     my $explicit_stop;
2517     my $piped;
2518     my $selected;
2519
2520     if ($ENV{PERL5DB_THREADED}) {
2521         $tid = eval { "[".threads->tid."]" };
2522     }
2523
2524     my $cmd_verb;
2525     my $cmd_args;
2526
2527     my $obj = DB::Obj->new(
2528         {
2529             position => \$position,
2530             prefix => \$prefix,
2531             after => \$after,
2532             explicit_stop => \$explicit_stop,
2533             infix => \$infix,
2534             cmd_args => \$cmd_args,
2535             cmd_verb => \$cmd_verb,
2536             pat => \$pat,
2537             piped => \$piped,
2538             selected => \$selected,
2539         },
2540     );
2541
2542     $obj->_DB_on_init__initialize_globals(@_);
2543
2544     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2545     # The code being debugged may have altered them.
2546     DB::save();
2547
2548     # Since DB::DB gets called after every line, we can use caller() to
2549     # figure out where we last were executing. Sneaky, eh? This works because
2550     # caller is returning all the extra information when called from the
2551     # debugger.
2552     local ( $package, $filename, $line ) = caller;
2553     $filename_ini = $filename;
2554
2555     # set up the context for DB::eval, so it can properly execute
2556     # code on behalf of the user. We add the package in so that the
2557     # code is eval'ed in the proper package (not in the debugger!).
2558     local $usercontext = _calc_usercontext($package);
2559
2560     # Create an alias to the active file magical array to simplify
2561     # the code here.
2562     local (*dbline) = $main::{ '_<' . $filename };
2563
2564     # Last line in the program.
2565     $max = $#dbline;
2566
2567     # The &-call is here to ascertain the mutability of @_.
2568     &_DB__determine_if_we_should_break;
2569
2570     # Preserve the current stop-or-not, and see if any of the W
2571     # (watch expressions) has changed.
2572     my $was_signal = $signal;
2573
2574     # If we have any watch expressions ...
2575     _DB__handle_watch_expressions($obj);
2576
2577 =head2 C<watchfunction()>
2578
2579 C<watchfunction()> is a function that can be defined by the user; it is a
2580 function which will be run on each entry to C<DB::DB>; it gets the
2581 current package, filename, and line as its parameters.
2582
2583 The watchfunction can do anything it likes; it is executing in the
2584 debugger's context, so it has access to all of the debugger's internal
2585 data structures and functions.
2586
2587 C<watchfunction()> can control the debugger's actions. Any of the following
2588 will cause the debugger to return control to the user's program after
2589 C<watchfunction()> executes:
2590
2591 =over 4
2592
2593 =item *
2594
2595 Returning a false value from the C<watchfunction()> itself.
2596
2597 =item *
2598
2599 Altering C<$single> to a false value.
2600
2601 =item *
2602
2603 Altering C<$signal> to a false value.
2604
2605 =item *
2606
2607 Turning off the C<4> bit in C<$trace> (this also disables the
2608 check for C<watchfunction()>. This can be done with
2609
2610     $trace &= ~4;
2611
2612 =back
2613
2614 =cut
2615
2616     # If there's a user-defined DB::watchfunction, call it with the
2617     # current package, filename, and line. The function executes in
2618     # the DB:: package.
2619     if ( $trace & 4 ) {    # User-installed watch
2620         return
2621           if watchfunction( $package, $filename, $line )
2622           and not $single
2623           and not $was_signal
2624           and not( $trace & ~4 );
2625     } ## end if ($trace & 4)
2626
2627     # Pick up any alteration to $signal in the watchfunction, and
2628     # turn off the signal now.
2629     $was_signal = $signal;
2630     $signal     = 0;
2631
2632 =head2 GETTING READY TO EXECUTE COMMANDS
2633
2634 The debugger decides to take control if single-step mode is on, the
2635 C<t> command was entered, or the user generated a signal. If the program
2636 has fallen off the end, we set things up so that entering further commands
2637 won't cause trouble, and we say that the program is over.
2638
2639 =cut
2640
2641     # Make sure that we always print if asked for explicitly regardless
2642     # of $trace_to_depth .
2643     $explicit_stop = ($single || $was_signal);
2644
2645     # Check to see if we should grab control ($single true,
2646     # trace set appropriately, or we got a signal).
2647     if ( $explicit_stop || ( $trace & 1 ) ) {
2648         $obj->_DB__grab_control(@_);
2649     } ## end if ($single || ($trace...
2650
2651 =pod
2652
2653 If there's an action to be executed for the line we stopped at, execute it.
2654 If there are any preprompt actions, execute those as well.
2655
2656 =cut
2657
2658     # If there's an action, do it now.
2659     if ($action) {
2660         $evalarg = $action;
2661         # The &-call is here to ascertain the mutability of @_.
2662         &DB::eval;
2663     }
2664
2665     # Are we nested another level (e.g., did we evaluate a function
2666     # that had a breakpoint in it at the debugger prompt)?
2667     if ( $single || $was_signal ) {
2668
2669         # Yes, go down a level.
2670         local $level = $level + 1;
2671
2672         # Do any pre-prompt actions.
2673         foreach $evalarg (@$pre) {
2674             # The &-call is here to ascertain the mutability of @_.
2675             &DB::eval;
2676         }
2677
2678         # Complain about too much recursion if we passed the limit.
2679         if ($single & 4) {
2680             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2681         }
2682
2683         # The line we're currently on. Set $incr to -1 to stay here
2684         # until we get a command that tells us to advance.
2685         $start = $line;
2686         $incr  = -1;      # for backward motion.
2687
2688         # Tack preprompt debugger actions ahead of any actual input.
2689         @typeahead = ( @$pretype, @typeahead );
2690
2691 =head2 WHERE ARE WE?
2692
2693 XXX Relocate this section?
2694
2695 The debugger normally shows the line corresponding to the current line of
2696 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2697 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2698
2699 C<$incr> controls by how many lines the I<current> line should move forward
2700 after a command is executed. If set to -1, this indicates that the I<current>
2701 line shouldn't change.
2702
2703 C<$start> is the I<current> line. It is used for things like knowing where to
2704 move forwards or backwards from when doing an C<L> or C<-> command.
2705
2706 C<$max> tells the debugger where the last line of the current file is. It's
2707 used to terminate loops most often.
2708
2709 =head2 THE COMMAND LOOP
2710
2711 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2712 in two parts:
2713
2714 =over 4
2715
2716 =item *
2717
2718 The outer part of the loop, starting at the C<CMD> label. This loop
2719 reads a command and then executes it.
2720
2721 =item *
2722
2723 The inner part of the loop, starting at the C<PIPE> label. This part
2724 is wholly contained inside the C<CMD> block and only executes a command.
2725 Used to handle commands running inside a pager.
2726
2727 =back
2728
2729 So why have two labels to restart the loop? Because sometimes, it's easier to
2730 have a command I<generate> another command and then re-execute the loop to do
2731 the new command. This is faster, but perhaps a bit more convoluted.
2732
2733 =cut
2734
2735         # The big command dispatch loop. It keeps running until the
2736         # user yields up control again.
2737         #
2738         # If we have a terminal for input, and we get something back
2739         # from readline(), keep on processing.
2740
2741       CMD:
2742         while (_DB__read_next_cmd($tid))
2743         {
2744
2745             share($cmd);
2746             # ... try to execute the input as debugger commands.
2747
2748             # Don't stop running.
2749             $single = 0;
2750
2751             # No signal is active.
2752             $signal = 0;
2753
2754             # Handle continued commands (ending with \):
2755             if ($cmd =~ s/\\\z/\n/) {
2756                 $cmd .= DB::readline("  cont: ");
2757                 redo CMD;
2758             }
2759
2760 =head4 The null command
2761
2762 A newline entered by itself means I<re-execute the last command>. We grab the
2763 command out of C<$laststep> (where it was recorded previously), and copy it
2764 back into C<$cmd> to be executed below. If there wasn't any previous command,
2765 we'll do nothing below (no command will match). If there was, we also save it
2766 in the command history and fall through to allow the command parsing to pick
2767 it up.
2768
2769 =cut
2770
2771             # Empty input means repeat the last command.
2772             if ($cmd eq '') {
2773                 $cmd = $laststep;
2774             }
2775             chomp($cmd);    # get rid of the annoying extra newline
2776             if (length($cmd) >= 2) {
2777                 push( @hist, $cmd );
2778             }
2779             push( @truehist, $cmd );
2780             share(@hist);
2781             share(@truehist);
2782
2783             # This is a restart point for commands that didn't arrive
2784             # via direct user input. It allows us to 'redo PIPE' to
2785             # re-execute command processing without reading a new command.
2786           PIPE: {
2787                 _DB__trim_command_and_return_first_component($obj);
2788
2789 =head3 COMMAND ALIASES
2790
2791 The debugger can create aliases for commands (these are stored in the
2792 C<%alias> hash). Before a command is executed, the command loop looks it up
2793 in the alias hash and substitutes the contents of the alias for the command,
2794 completely replacing it.
2795
2796 =cut
2797
2798                 # See if there's an alias for the command, and set it up if so.
2799                 if ( $alias{$cmd_verb} ) {
2800
2801                     # Squelch signal handling; we want to keep control here
2802                     # if something goes loco during the alias eval.
2803                     local $SIG{__DIE__};
2804                     local $SIG{__WARN__};
2805
2806                     # This is a command, so we eval it in the DEBUGGER's
2807                     # scope! Otherwise, we can't see the special debugger
2808                     # variables, or get to the debugger's subs. (Well, we
2809                     # _could_, but why make it even more complicated?)
2810                     eval "\$cmd =~ $alias{$cmd_verb}";
2811                     if ($@) {
2812                         local $\ = '';
2813                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2814                         next CMD;
2815                     }
2816                     _DB__trim_command_and_return_first_component($obj);
2817                 } ## end if ($alias{$cmd_verb})
2818
2819 =head3 MAIN-LINE COMMANDS
2820
2821 All of these commands work up to and after the program being debugged has
2822 terminated.
2823
2824 =head4 C<q> - quit
2825
2826 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2827 try to execute further, cleaning any restart-related stuff out of the
2828 environment, and executing with the last value of C<$?>.
2829
2830 =cut
2831
2832                 # All of these commands were remapped in perl 5.8.0;
2833                 # we send them off to the secondary dispatcher (see below).
2834                 $obj->_handle_special_char_cmd_wrapper_commands;
2835                 _DB__trim_command_and_return_first_component($obj);
2836
2837                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2838                     my $type = $cmd_rec->{t};
2839                     my $val = $cmd_rec->{v};
2840                     if ($type eq 'm') {
2841                         $obj->$val();
2842                     }
2843                     elsif ($type eq 's') {
2844                         $val->($obj);
2845                     }
2846                 }
2847
2848 =head4 C<t> - trace [n]
2849
2850 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2851 If level is specified, set C<$trace_to_depth>.
2852
2853 =head4 C<S> - list subroutines matching/not matching a pattern
2854
2855 Walks through C<%sub>, checking to see whether or not to print the name.
2856
2857 =head4 C<X> - list variables in current package
2858
2859 Since the C<V> command actually processes this, just change this to the
2860 appropriate C<V> command and fall through.
2861
2862 =head4 C<V> - list variables
2863
2864 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2865
2866 =head4 C<x> - evaluate and print an expression
2867
2868 Hands the expression off to C<DB::eval>, setting it up to print the value
2869 via C<dumpvar.pl> instead of just printing it directly.
2870
2871 =head4 C<m> - print methods
2872
2873 Just uses C<DB::methods> to determine what methods are available.
2874
2875 =head4 C<f> - switch files
2876
2877 Switch to a different filename.
2878
2879 =head4 C<.> - return to last-executed line.
2880
2881 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2882 and then we look up the line in the magical C<%dbline> hash.
2883
2884 =head4 C<-> - back one window
2885
2886 We change C<$start> to be one window back; if we go back past the first line,
2887 we set it to be the first line. We ser C<$incr> to put us back at the
2888 currently-executing line, and then put a C<l $start +> (list one window from
2889 C<$start>) in C<$cmd> to be executed later.
2890
2891 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2892
2893 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2894 problems, most notably that the default case of several commands destroying
2895 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2896 retain the old commands for those who were used to using them or who preferred
2897 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2898 deal with them instead of processing them in-line.
2899
2900 =head4 C<y> - List lexicals in higher scope
2901
2902 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2903 above the current one and then displays then using C<dumpvar.pl>.
2904
2905 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2906
2907 All of the commands below this point don't work after the program being
2908 debugged has ended. All of them check to see if the program has ended; this
2909 allows the commands to be relocated without worrying about a 'line of
2910 demarcation' above which commands can be entered anytime, and below which
2911 they can't.
2912
2913 =head4 C<n> - single step, but don't trace down into subs
2914
2915 Done by setting C<$single> to 2, which forces subs to execute straight through
2916 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2917 so a null command knows what to re-execute.
2918
2919 =head4 C<s> - single-step, entering subs
2920
2921 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2922 subs. Also saves C<s> as C<$lastcmd>.
2923
2924 =head4 C<c> - run continuously, setting an optional breakpoint
2925
2926 Most of the code for this command is taken up with locating the optional
2927 breakpoint, which is either a subroutine name or a line number. We set
2928 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2929 in this and all call levels above this one.
2930
2931 =head4 C<r> - return from a subroutine
2932
2933 For C<r> to work properly, the debugger has to stop execution again
2934 immediately after the return is executed. This is done by forcing
2935 single-stepping to be on in the call level above the current one. If
2936 we are printing return values when a C<r> is executed, set C<$doret>
2937 appropriately, and force us out of the command loop.
2938
2939 =head4 C<T> - stack trace
2940
2941 Just calls C<DB::print_trace>.
2942
2943 =head4 C<w> - List window around current line.
2944
2945 Just calls C<DB::cmd_w>.
2946
2947 =head4 C<W> - watch-expression processing.
2948
2949 Just calls C<DB::cmd_W>.
2950
2951 =head4 C</> - search forward for a string in the source
2952
2953 We take the argument and treat it as a pattern. If it turns out to be a
2954 bad one, we return the error we got from trying to C<eval> it and exit.
2955 If not, we create some code to do the search and C<eval> it so it can't
2956 mess us up.
2957
2958 =cut
2959
2960                 _DB__handle_forward_slash_command($obj);
2961
2962 =head4 C<?> - search backward for a string in the source
2963
2964 Same as for C</>, except the loop runs backwards.
2965
2966 =cut
2967
2968                 _DB__handle_question_mark_command($obj);
2969
2970 =head4 C<$rc> - Recall command
2971
2972 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2973 that the terminal supports history). It finds the command required, puts it
2974 into C<$cmd>, and redoes the loop to execute it.
2975
2976 =cut
2977
2978                 # $rc - recall command.
2979                 $obj->_handle_rc_recall_command;
2980
2981 =head4 C<$sh$sh> - C<system()> command
2982
2983 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
2984 C<STDOUT> from getting messed up.
2985
2986 =cut
2987
2988                 $obj->_handle_sh_command;
2989
2990 =head4 C<$rc I<pattern> $rc> - Search command history
2991
2992 Another command to manipulate C<@hist>: this one searches it with a pattern.
2993 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2994
2995 =cut
2996
2997                 $obj->_handle_rc_search_history_command;
2998
2999 =head4 C<$sh> - Invoke a shell
3000
3001 Uses C<_db_system()> to invoke a shell.
3002
3003 =cut
3004
3005 =head4 C<$sh I<command>> - Force execution of a command in a shell
3006
3007 Like the above, but the command is passed to the shell. Again, we use
3008 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
3009
3010 =head4 C<H> - display commands in history
3011
3012 Prints the contents of C<@hist> (if any).
3013
3014 =head4 C<man, doc, perldoc> - look up documentation
3015
3016 Just calls C<runman()> to print the appropriate document.
3017
3018 =cut
3019
3020                 $obj->_handle_doc_command;
3021
3022 =head4 C<p> - print
3023
3024 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3025 the bottom of the loop.
3026
3027 =head4 C<=> - define command alias
3028
3029 Manipulates C<%alias> to add or list command aliases.
3030
3031 =head4 C<source> - read commands from a file.
3032
3033 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3034 pick it up.
3035
3036 =head4 C<enable> C<disable> - enable or disable breakpoints
3037
3038 This enables or disables breakpoints.
3039
3040 =head4 C<save> - send current history to a file
3041
3042 Takes the complete history, (not the shrunken version you see with C<H>),
3043 and saves it to the given filename, so it can be replayed using C<source>.
3044
3045 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3046
3047 =head4 C<R> - restart
3048
3049 Restart the debugger session.
3050
3051 =head4 C<rerun> - rerun the current session
3052
3053 Return to any given position in the B<true>-history list
3054
3055 =head4 C<|, ||> - pipe output through the pager.
3056
3057 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3058 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3059 pipe to the pager (restoring the output filehandles if this fails). If this
3060 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3061 set C<$signal>, sending us back into the debugger.
3062
3063 We then trim off the pipe symbols and C<redo> the command loop at the
3064 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3065 reading another.
3066
3067 =cut
3068
3069                 # || - run command in the pager, with output to DB::OUT.
3070                 _DB__handle_run_command_in_pager_command($obj);
3071
3072 =head3 END OF COMMAND PARSING
3073
3074 Anything left in C<$cmd> at this point is a Perl expression that we want to
3075 evaluate. We'll always evaluate in the user's context, and fully qualify
3076 any variables we might want to address in the C<DB> package.
3077
3078 =cut
3079
3080             }    # PIPE:
3081
3082             # trace an expression
3083             $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3084
3085             # Make sure the flag that says "the debugger's running" is
3086             # still on, to make sure we get control again.
3087             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3088
3089             # Run *our* eval that executes in the caller's context.
3090             # The &-call is here to ascertain the mutability of @_.
3091             &DB::eval;
3092
3093             # Turn off the one-time-dump stuff now.
3094             if ($onetimeDump) {
3095                 $onetimeDump      = undef;
3096                 $onetimedumpDepth = undef;
3097             }
3098             elsif ( $term_pid == $$ ) {
3099                 eval { # May run under miniperl, when not available...
3100                     STDOUT->flush();
3101                     STDERR->flush();
3102                 };
3103
3104                 # XXX If this is the master pid, print a newline.
3105                 print {$OUT} "\n";
3106             }
3107         } ## end while (($term || &setterm...
3108
3109 =head3 POST-COMMAND PROCESSING
3110
3111 After each command, we check to see if the command output was piped anywhere.
3112 If so, we go through the necessary code to unhook the pipe and go back to
3113 our standard filehandles for input and output.
3114
3115 =cut
3116
3117         continue {    # CMD:
3118             _DB__at_end_of_every_command($obj);
3119         }    # CMD:
3120
3121 =head3 COMMAND LOOP TERMINATION
3122
3123 When commands have finished executing, we come here. If the user closed the
3124 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3125 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3126 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3127 The interpreter will then execute the next line and then return control to us
3128 again.
3129
3130 =cut
3131
3132         # No more commands? Quit.
3133         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3134
3135         # Evaluate post-prompt commands.
3136         foreach $evalarg (@$post) {
3137             # The &-call is here to ascertain the mutability of @_.
3138             &DB::eval;
3139         }
3140     }    # if ($single || $signal)
3141
3142     # Put the user's globals back where you found them.
3143     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3144     ();
3145 } ## end sub DB
3146
3147 # Because DB::Obj is used above,
3148 #
3149 #   my $obj = DB::Obj->new(
3150 #
3151 # The following package declaration must come before that,
3152 # or else runtime errors will occur with
3153 #
3154 #   PERLDB_OPTS="autotrace nonstop"
3155 #
3156 # ( rt#116771 )
3157 BEGIN {
3158
3159 package DB::Obj;
3160
3161 sub new {
3162     my $class = shift;
3163
3164     my $self = bless {}, $class;
3165
3166     $self->_init(@_);
3167
3168     return $self;
3169 }
3170
3171 sub _init {
3172     my ($self, $args) = @_;
3173
3174     %{$self} = (%$self, %$args);
3175
3176     return;
3177 }
3178
3179 {
3180     no strict 'refs';
3181     foreach my $slot_name (qw(
3182         after explicit_stop infix pat piped position prefix selected cmd_verb
3183         cmd_args
3184         )) {
3185         my $slot = $slot_name;
3186         *{$slot} = sub {
3187             my $self = shift;
3188
3189             if (@_) {
3190                 ${ $self->{$slot} } = shift;
3191             }
3192
3193             return ${ $self->{$slot} };
3194         };
3195
3196         *{"append_to_$slot"} = sub {
3197             my $self = shift;
3198             my $s = shift;
3199
3200             return $self->$slot($self->$slot . $s);
3201         };
3202     }
3203 }
3204
3205 sub _DB_on_init__initialize_globals
3206 {
3207     my $self = shift;
3208
3209     # Check for whether we should be running continuously or not.
3210     # _After_ the perl program is compiled, $single is set to 1:
3211     if ( $single and not $second_time++ ) {
3212
3213         # Options say run non-stop. Run until we get an interrupt.
3214         if ($runnonstop) {    # Disable until signal
3215                 # If there's any call stack in place, turn off single
3216                 # stepping into subs throughout the stack.
3217             for my $i (0 .. $stack_depth) {
3218                 $stack[ $i ] &= ~1;
3219             }
3220
3221             # And we are now no longer in single-step mode.
3222             $single = 0;
3223
3224             # If we simply returned at this point, we wouldn't get
3225             # the trace info. Fall on through.
3226             # return;
3227         } ## end if ($runnonstop)
3228
3229         elsif ($ImmediateStop) {
3230
3231             # We are supposed to stop here; XXX probably a break.
3232             $ImmediateStop = 0;    # We've processed it; turn it off
3233             $signal        = 1;    # Simulate an interrupt to force
3234                                    # us into the command loop
3235         }
3236     } ## end if ($single and not $second_time...
3237
3238     # If we're in single-step mode, or an interrupt (real or fake)
3239     # has occurred, turn off non-stop mode.
3240     $runnonstop = 0 if $single or $signal;
3241
3242     return;
3243 }
3244
3245 sub _my_print_lineinfo
3246 {
3247     my ($self, $i, $incr_pos) = @_;
3248
3249     if ($frame) {
3250         # Print it indented if tracing is on.
3251         DB::print_lineinfo( ' ' x $stack_depth,
3252             "$i:\t$DB::dbline[$i]" . $self->after );
3253     }
3254     else {
3255         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3256     }
3257 }
3258
3259 sub _curr_line {
3260     return $DB::dbline[$line];
3261 }
3262
3263 sub _is_full {
3264     my ($self, $letter) = @_;
3265
3266     return ($DB::cmd eq $letter);
3267 }
3268
3269 sub _DB__grab_control
3270 {
3271     my $self = shift;
3272
3273     # Yes, grab control.
3274     if ($slave_editor) {
3275
3276         # Tell the editor to update its position.
3277         $self->position("\032\032${DB::filename}:$line:0\n");
3278         DB::print_lineinfo($self->position());
3279     }
3280
3281 =pod
3282
3283 Special check: if we're in package C<DB::fake>, we've gone through the
3284 C<END> block at least once. We set up everything so that we can continue
3285 to enter commands and have a valid context to be in.
3286
3287 =cut
3288
3289     elsif ( $DB::package eq 'DB::fake' ) {
3290
3291         # Fallen off the end already.
3292         if (!$DB::term) {
3293             DB::setterm();
3294         }
3295
3296         DB::print_help(<<EOP);
3297 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3298 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3299 B<h q>, B<h R> or B<h o> to get additional info.
3300 EOP
3301
3302         # Set the DB::eval context appropriately.
3303         $DB::package     = 'main';
3304         $DB::usercontext = DB::_calc_usercontext($DB::package);
3305     } ## end elsif ($package eq 'DB::fake')
3306
3307 =pod
3308
3309 If the program hasn't finished executing, we scan forward to the
3310 next executable line, print that out, build the prompt from the file and line
3311 number information, and print that.
3312
3313 =cut
3314
3315     else {
3316
3317
3318         # Still somewhere in the midst of execution. Set up the
3319         #  debugger prompt.
3320         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3321                              # Perl 5 ones (sorry, we don't print Klingon
3322                              #module names)
3323
3324         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3325         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3326         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3327
3328         # Break up the prompt if it's really long.
3329         if ( length($self->prefix()) > 30 ) {
3330             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3331             $self->prefix("");
3332             $self->infix(":\t");
3333         }
3334         else {
3335             $self->infix("):\t");
3336             $self->position(
3337                 $self->prefix . $line. $self->infix
3338                 . $self->_curr_line . $self->after
3339             );
3340         }
3341
3342         # Print current line info, indenting if necessary.
3343         $self->_my_print_lineinfo($line, $self->position);
3344
3345         my $i;
3346         my $line_i = sub { return $DB::dbline[$i]; };
3347
3348         # Scan forward, stopping at either the end or the next
3349         # unbreakable line.
3350         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3351         {    #{ vi
3352
3353             # Drop out on null statements, block closers, and comments.
3354             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3355
3356             # Drop out if the user interrupted us.
3357             last if $signal;
3358
3359             # Append a newline if the line doesn't have one. Can happen
3360             # in eval'ed text, for instance.
3361             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3362
3363             # Next executable line.
3364             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3365                 . $self->after;
3366             $self->append_to_position($incr_pos);
3367             $self->_my_print_lineinfo($i, $incr_pos);
3368         } ## end for ($i = $line + 1 ; $i...
3369     } ## end else [ if ($slave_editor)
3370
3371     return;
3372 }
3373
3374 sub _handle_t_command {
3375     my $self = shift;
3376
3377     my $levels = $self->cmd_args();
3378
3379     if ((!length($levels)) or ($levels !~ /\D/)) {
3380         $trace ^= 1;
3381         local $\ = '';
3382         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3383         print {$OUT} "Trace = "
3384         . ( ( $trace & 1 )
3385             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3386             : "off" ) . "\n";
3387         next CMD;
3388     }
3389
3390     return;
3391 }
3392
3393
3394 sub _handle_S_command {
3395     my $self = shift;
3396
3397     if (my ($print_all_subs, $should_reverse, $Spatt)
3398         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3399         # $Spatt is the pattern (if any) to use.
3400         # Reverse scan?
3401         my $Srev     = defined $should_reverse;
3402         # No args - print all subs.
3403         my $Snocheck = !defined $print_all_subs;
3404
3405         # Need to make these sane here.
3406         local $\ = '';
3407         local $, = '';
3408
3409         # Search through the debugger's magical hash of subs.
3410         # If $nocheck is true, just print the sub name.
3411         # Otherwise, check it against the pattern. We then use
3412         # the XOR trick to reverse the condition as required.
3413         foreach $subname ( sort( keys %sub ) ) {
3414             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3415                 print $OUT $subname, "\n";
3416             }
3417         }
3418         next CMD;
3419     }
3420
3421     return;
3422 }
3423
3424 sub _handle_V_command_and_X_command {
3425     my $self = shift;
3426
3427     $DB::cmd =~ s/^X\b/V $DB::package/;
3428
3429     # Bare V commands get the currently-being-debugged package
3430     # added.
3431     if ($self->_is_full('V')) {
3432         $DB::cmd = "V $DB::package";
3433     }
3434
3435     # V - show variables in package.
3436     if (my ($new_packname, $new_vars_str) =
3437         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3438
3439         # Save the currently selected filehandle and
3440         # force output to debugger's filehandle (dumpvar
3441         # just does "print" for output).
3442         my $savout = select($OUT);
3443
3444         # Grab package name and variables to dump.
3445         $packname = $new_packname;
3446         my @vars     = split( ' ', $new_vars_str );
3447
3448         # If main::dumpvar isn't here, get it.
3449         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3450         if ( defined &main::dumpvar ) {
3451
3452             # We got it. Turn off subroutine entry/exit messages
3453             # for the moment, along with return values.
3454             local $frame = 0;
3455             local $doret = -2;
3456
3457             # must detect sigpipe failures  - not catching
3458             # then will cause the debugger to die.
3459             eval {
3460                 main::dumpvar(
3461                     $packname,
3462                     defined $option{dumpDepth}
3463                     ? $option{dumpDepth}
3464                     : -1,    # assume -1 unless specified
3465                     @vars
3466                 );
3467             };
3468
3469             # The die doesn't need to include the $@, because
3470             # it will automatically get propagated for us.
3471             if ($@) {
3472                 die unless $@ =~ /dumpvar print failed/;
3473             }
3474         } ## end if (defined &main::dumpvar)
3475         else {
3476
3477             # Couldn't load dumpvar.
3478             print $OUT "dumpvar.pl not available.\n";
3479         }
3480
3481         # Restore the output filehandle, and go round again.
3482         select($savout);
3483         next CMD;
3484     }
3485
3486     return;
3487 }
3488
3489 sub _handle_dash_command {
3490     my $self = shift;
3491
3492     if ($self->_is_full('-')) {
3493
3494         # back up by a window; go to 1 if back too far.
3495         $start -= $incr + $window + 1;
3496         $start = 1 if $start <= 0;
3497         $incr  = $window - 1;
3498
3499         # Generate and execute a "l +" command (handled below).
3500         $DB::cmd = 'l ' . ($start) . '+';
3501         redo CMD;
3502     }
3503     return;
3504 }
3505
3506 sub _n_or_s_commands_generic {
3507     my ($self, $new_val) = @_;
3508     # n - next
3509     next CMD if DB::_DB__is_finished();
3510
3511     # Single step, but don't enter subs.
3512     $single = $new_val;
3513
3514     # Save for empty command (repeat last).
3515     $laststep = $DB::cmd;
3516     last CMD;
3517 }
3518
3519 sub _n_or_s {
3520     my ($self, $letter, $new_val) = @_;
3521
3522     if ($self->_is_full($letter)) {
3523         $self->_n_or_s_commands_generic($new_val);
3524     }
3525     else {
3526         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3527     }
3528
3529     return;
3530 }
3531
3532 sub _handle_n_command {
3533     my $self = shift;
3534
3535     return $self->_n_or_s('n', 2);
3536 }
3537
3538 sub _handle_s_command {
3539     my $self = shift;
3540
3541     return $self->_n_or_s('s', 1);
3542 }
3543
3544 sub _handle_r_command {
3545     my $self = shift;
3546
3547     # r - return from the current subroutine.
3548     if ($self->_is_full('r')) {
3549
3550         # Can't do anything if the program's over.
3551         next CMD if DB::_DB__is_finished();
3552
3553         # Turn on stack trace.
3554         $stack[$stack_depth] |= 1;
3555
3556         # Print return value unless the stack is empty.
3557         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3558         last CMD;
3559     }
3560
3561     return;
3562 }
3563
3564 sub _handle_T_command {
3565     my $self = shift;
3566
3567     if ($self->_is_full('T')) {
3568         DB::print_trace( $OUT, 1 );    # skip DB
3569         next CMD;
3570     }
3571
3572     return;
3573 }
3574
3575 sub _handle_w_command {
3576     my $self = shift;
3577
3578     DB::cmd_w( 'w', $self->cmd_args() );
3579     next CMD;
3580
3581     return;
3582 }
3583
3584 sub _handle_W_command {
3585     my $self = shift;
3586
3587     if (my $arg = $self->cmd_args) {
3588         DB::cmd_W( 'W', $arg );
3589         next CMD;
3590     }
3591
3592     return;
3593 }
3594
3595 sub _handle_rc_recall_command {
3596     my $self = shift;
3597
3598     # $rc - recall command.
3599     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3600
3601         # No arguments, take one thing off history.
3602         pop(@hist) if length($DB::cmd) > 1;
3603
3604         # Relative (- found)?
3605         #  Y - index back from most recent (by 1 if bare minus)
3606         #  N - go to that particular command slot or the last
3607         #      thing if nothing following.
3608
3609         $self->cmd_verb(
3610             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3611         );
3612
3613         # Pick out the command desired.
3614         $DB::cmd = $hist[$self->cmd_verb];
3615
3616         # Print the command to be executed and restart the loop
3617         # with that command in the buffer.
3618         print {$OUT} $DB::cmd, "\n";
3619         redo CMD;
3620     }
3621
3622     return;
3623 }
3624
3625 sub _handle_rc_search_history_command {
3626     my $self = shift;
3627
3628     # $rc pattern $rc - find a command in the history.
3629     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3630
3631         # Create the pattern to use.
3632         my $pat = "^$arg";
3633         $self->pat($pat);
3634
3635         # Toss off last entry if length is >1 (and it always is).
3636         pop(@hist) if length($DB::cmd) > 1;
3637
3638         my $i;
3639
3640         # Look backward through the history.
3641         SEARCH_HIST:
3642         for ( $i = $#hist ; $i ; --$i ) {
3643             # Stop if we find it.
3644             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3645         }
3646
3647         if ( !$i ) {
3648
3649             # Never found it.
3650             print $OUT "No such command!\n\n";
3651             next CMD;
3652         }
3653
3654         # Found it. Put it in the buffer, print it, and process it.
3655         $DB::cmd = $hist[$i];
3656         print $OUT $DB::cmd, "\n";
3657         redo CMD;
3658     }
3659
3660     return;
3661 }
3662
3663 sub _handle_H_command {
3664     my $self = shift;
3665
3666     if ($self->cmd_args =~ m#\A\*#) {
3667         @hist = @truehist = ();
3668         print $OUT "History cleansed\n";
3669         next CMD;
3670     }
3671
3672     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3673
3674         # Anything other than negative numbers is ignored by
3675         # the (incorrect) pattern, so this test does nothing.
3676         $end = $num ? ( $#hist - $num ) : 0;
3677
3678         # Set to the minimum if less than zero.
3679         $hist = 0 if $hist < 0;
3680
3681         # Start at the end of the array.
3682         # Stay in while we're still above the ending value.
3683         # Tick back by one each time around the loop.
3684         my $i;
3685
3686         for ( $i = $#hist ; $i > $end ; $i-- ) {
3687
3688             # Print the command  unless it has no arguments.
3689             print $OUT "$i: ", $hist[$i], "\n"
3690             unless $hist[$i] =~ /^.?$/;
3691         }
3692
3693         next CMD;
3694     }
3695
3696     return;
3697 }
3698
3699 sub _handle_doc_command {
3700     my $self = shift;
3701
3702     # man, perldoc, doc - show manual pages.
3703     if (my ($man_page)
3704         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3705         DB::runman($man_page);
3706         next CMD;
3707     }
3708
3709     return;
3710 }
3711
3712 sub _handle_p_command {
3713     my $self = shift;
3714
3715     my $print_cmd = 'print {$DB::OUT} ';
3716     # p - print (no args): print $_.
3717     if ($self->_is_full('p')) {
3718         $DB::cmd = $print_cmd . '$_';
3719     }
3720     else {
3721         # p - print the given expression.
3722         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3723     }
3724
3725     return;
3726 }
3727
3728 sub _handle_equal_sign_command {
3729     my $self = shift;
3730
3731     if ($DB::cmd =~ s/\A=\s*//) {
3732         my @keys;
3733         if ( length $DB::cmd == 0 ) {
3734
3735             # No args, get current aliases.
3736             @keys = sort keys %alias;
3737         }
3738         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3739
3740             # Creating a new alias. $k is alias name, $v is
3741             # alias value.
3742
3743             # can't use $_ or kill //g state
3744             for my $x ( $k, $v ) {
3745
3746                 # Escape "alarm" characters.
3747                 $x =~ s/\a/\\a/g;
3748             }
3749
3750             # Substitute key for value, using alarm chars
3751             # as separators (which is why we escaped them in
3752             # the command).
3753             $alias{$k} = "s\a$k\a$v\a";
3754
3755             # Turn off standard warn and die behavior.
3756             local $SIG{__DIE__};
3757             local $SIG{__WARN__};
3758
3759             # Is it valid Perl?
3760             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3761
3762                 # Nope. Bad alias. Say so and get out.
3763                 print $OUT "Can't alias $k to $v: $@\n";
3764                 delete $alias{$k};
3765                 next CMD;
3766             }
3767
3768             # We'll only list the new one.
3769             @keys = ($k);
3770         } ## end elsif (my ($k, $v) = ($DB::cmd...
3771
3772         # The argument is the alias to list.
3773         else {
3774             @keys = ($DB::cmd);
3775         }
3776
3777         # List aliases.
3778         for my $k (@keys) {
3779
3780             # Messy metaquoting: Trim the substitution code off.
3781             # We use control-G as the delimiter because it's not
3782             # likely to appear in the alias.
3783             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3784
3785                 # Print the alias.
3786                 print $OUT "$k\t= $1\n";
3787             }
3788             elsif ( defined $alias{$k} ) {
3789
3790                 # Couldn't trim it off; just print the alias code.
3791                 print $OUT "$k\t$alias{$k}\n";
3792             }
3793             else {
3794
3795                 # No such, dude.
3796                 print "No alias for $k\n";
3797             }
3798         } ## end for my $k (@keys)
3799         next CMD;
3800     }
3801
3802     return;
3803 }
3804
3805 sub _handle_source_command {
3806     my $self = shift;
3807
3808     # source - read commands from a file (or pipe!) and execute.
3809     if (my $sourced_fn = $self->cmd_args) {
3810         if ( open my $fh, $sourced_fn ) {
3811
3812             # Opened OK; stick it in the list of file handles.
3813             push @cmdfhs, $fh;
3814         }
3815         else {
3816
3817             # Couldn't open it.
3818             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3819         }
3820         next CMD;
3821     }
3822
3823     return;
3824 }
3825
3826 sub _handle_enable_disable_commands {
3827     my $self = shift;
3828
3829     my $which_cmd = $self->cmd_verb;
3830     my $position = $self->cmd_args;
3831
3832     if ($position !~ /\s/) {
3833         my ($fn, $line_num);
3834         if ($position =~ m{\A\d+\z})
3835         {
3836             $fn = $DB::filename;
3837             $line_num = $position;
3838         }
3839         elsif (my ($new_fn, $new_line_num)
3840             = $position =~ m{\A(.*):(\d+)\z}) {
3841             ($fn, $line_num) = ($new_fn, $new_line_num);
3842         }
3843         else
3844         {
3845             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3846         }
3847
3848         if (defined($fn)) {
3849             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3850                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3851                     ($which_cmd eq 'enable' ? 1 : '')
3852                 );
3853             }
3854             else {
3855                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3856             }
3857         }
3858
3859         next CMD;
3860     }
3861
3862     return;
3863 }
3864
3865 sub _handle_save_command {
3866     my $self = shift;
3867
3868     if (my $new_fn = $self->cmd_args) {
3869         my $filename = $new_fn || '.perl5dbrc';    # default?
3870         if ( open my $fh, '>', $filename ) {
3871
3872             # chomp to remove extraneous newlines from source'd files
3873             chomp( my @truelist =
3874                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3875                 @truehist );
3876             print {$fh} join( "\n", @truelist );
3877             print "commands saved in $filename\n";
3878         }
3879         else {
3880             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3881         }
3882         next CMD;
3883     }
3884
3885     return;
3886 }
3887
3888 sub _n_or_s_and_arg_commands_generic {
3889     my ($self, $letter, $new_val) = @_;
3890
3891     # s - single-step. Remember the last command was 's'.
3892     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3893         $laststep = $letter;
3894     }
3895
3896     return;
3897 }
3898
3899 sub _handle_sh_command {
3900     my $self = shift;
3901
3902     # $sh$sh - run a shell command (if it's all ASCII).
3903     # Can't run shell commands with Unicode in the debugger, hmm.
3904     my $my_cmd = $DB::cmd;
3905     if ($my_cmd =~ m#\A$sh#gms) {
3906
3907         if ($my_cmd =~ m#\G\z#cgms) {
3908             # Run the user's shell. If none defined, run Bourne.
3909             # We resume execution when the shell terminates.
3910             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3911             next CMD;
3912         }
3913         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3914             # System it.
3915             DB::_db_system($1);
3916             next CMD;
3917         }
3918         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3919             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3920             next CMD;
3921         }
3922     }
3923 }
3924
3925 sub _handle_x_command {
3926     my $self = shift;
3927
3928     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3929         $onetimeDump = 'dump';    # main::dumpvar shows the output
3930
3931         # handle special  "x 3 blah" syntax XXX propagate
3932         # doc back to special variables.
3933         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3934             $onetimedumpDepth = $1;
3935         }
3936     }
3937
3938     return;
3939 }
3940
3941 sub _handle_q_command {
3942     my $self = shift;
3943
3944     if ($self->_is_full('q')) {
3945         $fall_off_end = 1;
3946         DB::clean_ENV();
3947         exit $?;
3948     }
3949
3950     return;
3951 }
3952
3953 sub _handle_cmd_wrapper_commands {
3954     my $self = shift;
3955
3956     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
3957     next CMD;
3958 }
3959
3960 sub _handle_special_char_cmd_wrapper_commands {
3961     my $self = shift;
3962
3963     # All of these commands were remapped in perl 5.8.0;
3964     # we send them off to the secondary dispatcher (see below).
3965     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
3966         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
3967         next CMD;
3968     }
3969
3970     return;
3971 }
3972
3973 } ## end DB::Obj
3974
3975 package DB;
3976
3977 # The following code may be executed now:
3978 # BEGIN {warn 4}
3979
3980 =head2 sub
3981
3982 C<sub> is called whenever a subroutine call happens in the program being
3983 debugged. The variable C<$DB::sub> contains the name of the subroutine
3984 being called.
3985
3986 The core function of this subroutine is to actually call the sub in the proper
3987 context, capturing its output. This of course causes C<DB::DB> to get called
3988 again, repeating until the subroutine ends and returns control to C<DB::sub>
3989 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3990 return value, and returns its captured copy of the return value as its own
3991 return value. The value then feeds back into the program being debugged as if
3992 C<DB::sub> hadn't been there at all.
3993
3994 C<sub> does all the work of printing the subroutine entry and exit messages
3995 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3996 and also prints the return value if needed (for the C<r> command and if
3997 the 16 bit is set in C<$frame>).
3998
3999 It also tracks the subroutine call depth by saving the current setting of
4000 C<$single> in the C<@stack> package global; if this exceeds the value in
4001 C<$deep>, C<sub> automatically turns on printing of the current depth by
4002 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
4003 of stop/don't stop on entry to subs set as it currently is set.
4004
4005 =head3 C<caller()> support
4006
4007 If C<caller()> is called from the package C<DB>, it provides some
4008 additional data, in the following order:
4009
4010 =over 4
4011
4012 =item * C<$package>
4013
4014 The package name the sub was in
4015
4016 =item * C<$filename>
4017
4018 The filename it was defined in
4019
4020 =item * C<$line>
4021
4022 The line number it was defined on
4023
4024 =item * C<$subroutine>
4025
4026 The subroutine name; C<(eval)> if an C<eval>().
4027
4028 =item * C<$hasargs>
4029
4030 1 if it has arguments, 0 if not
4031
4032 =item * C<$wantarray>
4033
4034 1 if array context, 0 if scalar context
4035
4036 =item * C<$evaltext>
4037
4038 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4039
4040 =item * C<$is_require>
4041
4042 frame was created by a C<use> or C<require> statement
4043
4044 =item * C<$hints>
4045
4046 pragma information; subject to change between versions
4047
4048 =item * C<$bitmask>
4049
4050 pragma information; subject to change between versions
4051
4052 =item * C<@DB::args>
4053
4054 arguments with which the subroutine was invoked
4055
4056 =back
4057
4058 =cut
4059
4060 use vars qw($deep);
4061
4062 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4063 # happy. -- Shlomi Fish
4064
4065 sub _indent_print_line_info {
4066     my ($offset, $str) = @_;
4067
4068     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4069
4070     return;
4071 }
4072
4073 sub _print_frame_message {
4074     my ($al) = @_;
4075
4076     if ($frame) {
4077         if ($frame & 4) {   # Extended frame entry message
4078             _indent_print_line_info(-1, "in  ");
4079
4080             # Why -1? But it works! :-(
4081             # Because print_trace will call add 1 to it and then call
4082             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4083             # in dump_trace.
4084             #
4085             # Now it's 0 because we extracted a function.
4086             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4087         }
4088         else {
4089             _indent_print_line_info(-1, "entering $sub$al\n" );
4090         }
4091     }
4092
4093     return;
4094 }
4095
4096 sub DB::sub {
4097     # lock ourselves under threads
4098     lock($DBGR);
4099
4100     # Whether or not the autoloader was running, a scalar to put the
4101     # sub's return value in (if needed), and an array to put the sub's
4102     # return value in (if needed).
4103     my ( $al, $ret, @ret ) = "";
4104     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4105         print "creating new thread\n";
4106     }
4107
4108     # If the last ten characters are '::AUTOLOAD', note we've traced
4109     # into AUTOLOAD for $sub.
4110     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4111         no strict 'refs';
4112         $al = " for $$sub" if defined $$sub;
4113     }
4114
4115     # We stack the stack pointer and then increment it to protect us
4116     # from a situation that might unwind a whole bunch of call frames
4117     # at once. Localizing the stack pointer means that it will automatically
4118     # unwind the same amount when multiple stack frames are unwound.
4119     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4120
4121     # Expand @stack.
4122     $#stack = $stack_depth;
4123
4124     # Save current single-step setting.
4125     $stack[-1] = $single;
4126
4127     # Turn off all flags except single-stepping.
4128     $single &= 1;
4129
4130     # If we've gotten really deeply recursed, turn on the flag that will
4131     # make us stop with the 'deep recursion' message.
4132     $single |= 4 if $stack_depth == $deep;
4133
4134     # If frame messages are on ...
4135
4136     _print_frame_message($al);
4137     # standard frame entry message
4138
4139     my $print_exit_msg = sub {
4140         # Check for exit trace messages...
4141         if ($frame & 2)
4142         {
4143             if ($frame & 4)    # Extended exit message
4144             {
4145                 _indent_print_line_info(0, "out ");
4146                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4147             }
4148             else
4149             {
4150                 _indent_print_line_info(0, "exited $sub$al\n" );
4151             }
4152         }
4153         return;
4154     };
4155
4156     # Determine the sub's return type, and capture appropriately.
4157     if (wantarray) {
4158
4159         # Called in array context. call sub and capture output.
4160         # DB::DB will recursively get control again if appropriate; we'll come
4161         # back here when the sub is finished.
4162         {
4163             no strict 'refs';
4164             @ret = &$sub;
4165         }
4166
4167         # Pop the single-step value back off the stack.
4168         $single |= $stack[ $stack_depth-- ];
4169
4170         $print_exit_msg->();
4171
4172         # Print the return info if we need to.
4173         if ( $doret eq $stack_depth or $frame & 16 ) {
4174
4175             # Turn off output record separator.
4176             local $\ = '';
4177             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4178
4179             # Indent if we're printing because of $frame tracing.
4180             if ($frame & 16)
4181             {
4182                 print {$fh} ' ' x $stack_depth;
4183             }
4184
4185             # Print the return value.
4186             print {$fh} "list context return from $sub:\n";
4187             dumpit( $fh, \@ret );
4188
4189             # And don't print it again.
4190             $doret = -2;
4191         } ## end if ($doret eq $stack_depth...
4192             # And we have to return the return value now.
4193         @ret;
4194     } ## end if (wantarray)
4195
4196     # Scalar context.
4197     else {
4198         if ( defined wantarray ) {
4199             no strict 'refs';
4200             # Save the value if it's wanted at all.
4201             $ret = &$sub;
4202         }
4203         else {
4204             no strict 'refs';
4205             # Void return, explicitly.
4206             &$sub;
4207             undef $ret;
4208         }
4209
4210         # Pop the single-step value off the stack.
4211         $single |= $stack[ $stack_depth-- ];
4212
4213         # If we're doing exit messages...
4214         $print_exit_msg->();
4215
4216         # If we are supposed to show the return value... same as before.
4217         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4218             local $\ = '';
4219             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4220             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4221             print $fh (
4222                 defined wantarray
4223                 ? "scalar context return from $sub: "
4224                 : "void context return from $sub\n"
4225             );
4226             dumpit( $fh, $ret ) if defined wantarray;
4227             $doret = -2;
4228         } ## end if ($doret eq $stack_depth...
4229
4230         # Return the appropriate scalar value.
4231         $ret;
4232     } ## end else [ if (wantarray)
4233 } ## end sub _sub
4234
4235 sub lsub : lvalue {
4236
4237     no strict 'refs';
4238
4239     # lock ourselves under threads
4240     lock($DBGR);
4241
4242     # Whether or not the autoloader was running, a scalar to put the
4243     # sub's return value in (if needed), and an array to put the sub's
4244     # return value in (if needed).
4245     my ( $al, $ret, @ret ) = "";
4246     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4247         print "creating new thread\n";
4248     }
4249
4250     # If the last ten characters are C'::AUTOLOAD', note we've traced
4251     # into AUTOLOAD for $sub.
4252     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4253         $al = " for $$sub";
4254     }
4255
4256     # We stack the stack pointer and then increment it to protect us
4257     # from a situation that might unwind a whole bunch of call frames
4258     # at once. Localizing the stack pointer means that it will automatically
4259     # unwind the same amount when multiple stack frames are unwound.
4260     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4261
4262     # Expand @stack.
4263     $#stack = $stack_depth;
4264
4265     # Save current single-step setting.
4266     $stack[-1] = $single;
4267
4268     # Turn off all flags except single-stepping.
4269     # Use local so the single-step value is popped back off the
4270     # stack for us.
4271     local $single = $single & 1;
4272
4273     # If we've gotten really deeply recursed, turn on the flag that will
4274     # make us stop with the 'deep recursion' message.
4275     $single |= 4 if $stack_depth == $deep;
4276
4277     # If frame messages are on ...
4278     _print_frame_message($al);
4279
4280     # call the original lvalue sub.
4281     &$sub;
4282 }
4283
4284 # Abstracting common code from multiple places elsewhere:
4285 sub depth_print_lineinfo {
4286     my $always_print = shift;
4287
4288     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4289 }
4290
4291 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4292
4293 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4294 Most of the changes were to systematize the command structure and to eliminate
4295 commands that threw away user input without checking.
4296
4297 The following sections describe the code added to make it easy to support
4298 multiple command sets with conflicting command names. This section is a start
4299 at unifying all command processing to make it simpler to develop commands.
4300
4301 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4302 number, and C<$dbline> (the current line) as arguments.
4303
4304 Support functions in this section which have multiple modes of failure C<die>
4305 on error; the rest simply return a false value.
4306
4307 The user-interface functions (all of the C<cmd_*> functions) just output
4308 error messages.
4309
4310 =head2 C<%set>
4311
4312 The C<%set> hash defines the mapping from command letter to subroutine
4313 name suffix.
4314
4315 C<%set> is a two-level hash, indexed by set name and then by command name.
4316 Note that trying to set the CommandSet to C<foobar> simply results in the
4317 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4318
4319 =cut
4320
4321 ### The API section
4322
4323 my %set = (    #
4324     'pre580' => {
4325         'a' => 'pre580_a',
4326         'A' => 'pre580_null',
4327         'b' => 'pre580_b',
4328         'B' => 'pre580_null',
4329         'd' => 'pre580_null',
4330         'D' => 'pre580_D',
4331         'h' => 'pre580_h',
4332         'M' => 'pre580_null',
4333         'O' => 'o',
4334         'o' => 'pre580_null',
4335         'v' => 'M',
4336         'w' => 'v',
4337         'W' => 'pre580_W',
4338     },
4339     'pre590' => {
4340         '<'  => 'pre590_prepost',
4341         '<<' => 'pre590_prepost',
4342         '>'  => 'pre590_prepost',
4343         '>>' => 'pre590_prepost',
4344         '{'  => 'pre590_prepost',
4345         '{{' => 'pre590_prepost',
4346     },
4347 );
4348
4349 my %breakpoints_data;
4350
4351 sub _has_breakpoint_data_ref {
4352     my ($filename, $line) = @_;
4353
4354     return (
4355         exists( $breakpoints_data{$filename} )
4356             and
4357         exists( $breakpoints_data{$filename}{$line} )
4358     );
4359 }
4360
4361 sub _get_breakpoint_data_ref {
4362     my ($filename, $line) = @_;
4363
4364     return ($breakpoints_data{$filename}{$line} ||= +{});
4365 }
4366
4367 sub _delete_breakpoint_data_ref {
4368     my ($filename, $line) = @_;
4369
4370     delete($breakpoints_data{$filename}{$line});
4371     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4372         delete($breakpoints_data{$filename});
4373     }
4374
4375     return;
4376 }
4377
4378 sub _set_breakpoint_enabled_status {
4379     my ($filename, $line, $status) = @_;
4380
4381     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4382         ($status ? 1 : '')
4383         ;
4384
4385     return;
4386 }
4387
4388 sub _enable_breakpoint_temp_enabled_status {
4389     my ($filename, $line) = @_;
4390
4391     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4392
4393     return;
4394 }
4395
4396 sub _cancel_breakpoint_temp_enabled_status {
4397     my ($filename, $line) = @_;
4398
4399     my $ref = _get_breakpoint_data_ref($filename, $line);
4400
4401     delete ($ref->{'temp_enabled'});
4402
4403     if (! %$ref) {
4404         _delete_breakpoint_data_ref($filename, $line);
4405     }
4406
4407     return;
4408 }
4409
4410 sub _is_breakpoint_enabled {
4411     my ($filename, $line) = @_;
4412
4413     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4414     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4415 }
4416
4417 =head2 C<cmd_wrapper()> (API)
4418
4419 C<cmd_wrapper()> allows the debugger to switch command sets
4420 depending on the value of the C<CommandSet> option.
4421
4422 It tries to look up the command in the C<%set> package-level I<lexical>
4423 (which means external entities can't fiddle with it) and create the name of
4424 the sub to call based on the value found in the hash (if it's there). I<All>
4425 of the commands to be handled in a set have to be added to C<%set>; if they
4426 aren't found, the 5.8.0 equivalent is called (if there is one).
4427
4428 This code uses symbolic references.
4429
4430 =cut
4431
4432 sub cmd_wrapper {
4433     my $cmd      = shift;
4434     my $line     = shift;
4435     my $dblineno = shift;
4436
4437     # Assemble the command subroutine's name by looking up the
4438     # command set and command name in %set. If we can't find it,
4439     # default to the older version of the command.
4440     my $call = 'cmd_'
4441       . ( $set{$CommandSet}{$cmd}
4442           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4443
4444     # Call the command subroutine, call it by name.
4445     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4446 } ## end sub cmd_wrapper
4447
4448 =head3 C<cmd_a> (command)
4449
4450 The C<a> command handles pre-execution actions. These are associated with a
4451 particular line, so they're stored in C<%dbline>. We default to the current
4452 line if none is specified.
4453
4454 =cut
4455
4456 sub cmd_a {
4457     my $cmd    = shift;
4458     my $line   = shift || '';    # [.|line] expr
4459     my $dbline = shift;
4460
4461     # If it's dot (here), or not all digits,  use the current line.
4462     $line =~ s/\A\./$dbline/;
4463
4464     # Should be a line number followed by an expression.
4465     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4466
4467         if (! length($lineno)) {
4468             $lineno = $dbline;
4469         }
4470
4471         # If we have an expression ...
4472         if ( length $expr ) {
4473
4474             # ... but the line isn't breakable, complain.
4475             if ( $dbline[$lineno] == 0 ) {
4476                 print $OUT
4477                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4478             }
4479             else {
4480
4481                 # It's executable. Record that the line has an action.
4482                 $had_breakpoints{$filename} |= 2;
4483
4484                 # Remove any action, temp breakpoint, etc.
4485                 $dbline{$lineno} =~ s/\0[^\0]*//;
4486
4487                 # Add the action to the line.
4488                 $dbline{$lineno} .= "\0" . action($expr);
4489
4490                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4491             }
4492         } ## end if (length $expr)
4493     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4494     else {
4495
4496         # Syntax wrong.
4497         print $OUT
4498           "Adding an action requires an optional lineno and an expression\n"
4499           ;    # hint
4500     }
4501 } ## end sub cmd_a
4502
4503 =head3 C<cmd_A> (command)
4504
4505 Delete actions. Similar to above, except the delete code is in a separate
4506 subroutine, C<delete_action>.
4507
4508 =cut
4509
4510 sub cmd_A {
4511     my $cmd    = shift;
4512     my $line   = shift || '';
4513     my $dbline = shift;
4514
4515     # Dot is this line.
4516     $line =~ s/^\./$dbline/;
4517
4518     # Call delete_action with a null param to delete them all.
4519     # The '1' forces the eval to be true. It'll be false only
4520     # if delete_action blows up for some reason, in which case
4521     # we print $@ and get out.
4522     if ( $line eq '*' ) {
4523         if (! eval { _delete_all_actions(); 1 }) {
4524             print {$OUT} $@;
4525             return;
4526         }
4527     }
4528
4529     # There's a real line  number. Pass it to delete_action.
4530     # Error trapping is as above.
4531     elsif ( $line =~ /^(\S.*)/ ) {
4532         if (! eval { delete_action($1); 1 }) {
4533             print {$OUT} $@;
4534             return;
4535         }
4536     }
4537
4538     # Swing and a miss. Bad syntax.
4539     else {
4540         print $OUT
4541           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4542     }
4543 } ## end sub cmd_A
4544
4545 =head3 C<delete_action> (API)
4546
4547 C<delete_action> accepts either a line number or C<undef>. If a line number
4548 is specified, we check for the line being executable (if it's not, it
4549 couldn't have had an  action). If it is, we just take the action off (this
4550 will get any kind of an action, including breakpoints).
4551
4552 =cut
4553
4554 sub _remove_action_from_dbline {
4555     my $i = shift;
4556
4557     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4558     delete $dbline{$i} if $dbline{$i} eq '';
4559
4560     return;
4561 }
4562
4563 sub _delete_all_actions {
4564     print {$OUT} "Deleting all actions...\n";
4565
4566     for my $file ( keys %had_breakpoints ) {
4567         local *dbline = $main::{ '_<' . $file };
4568         $max = $#dbline;
4569         my $was;
4570         for my $i (1 .. $max) {
4571             if ( defined $dbline{$i} ) {
4572                 _remove_action_from_dbline($i);
4573             }
4574         }
4575
4576         unless ( $had_breakpoints{$file} &= ~2 ) {
4577             delete $had_breakpoints{$file};
4578         }
4579     }
4580
4581     return;
4582 }
4583
4584 sub delete_action {
4585     my $i = shift;
4586
4587     if ( defined($i) ) {
4588         # Can there be one?
4589         die "Line $i has no action .\n" if $dbline[$i] == 0;
4590
4591         # Nuke whatever's there.
4592         _remove_action_from_dbline($i);
4593     }
4594     else {
4595         _delete_all_actions();
4596     }
4597 }
4598
4599 =head3 C<cmd_b> (command)
4600
4601 Set breakpoints. Since breakpoints can be set in so many places, in so many
4602 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4603 we try to parse the command type, and then shuttle it off to an appropriate
4604 subroutine to actually do the work of setting the breakpoint in the right
4605 place.
4606
4607 =cut
4608
4609 sub cmd_b {
4610     my $cmd    = shift;
4611     my $line   = shift;    # [.|line] [cond]
4612     my $dbline = shift;
4613
4614     my $default_cond = sub {
4615         my $cond = shift;
4616         return length($cond) ? $cond : '1';
4617     };
4618
4619     # Make . the current line number if it's there..
4620     $line =~ s/^\.(\s|\z)/$dbline$1/;
4621
4622     # No line number, no condition. Simple break on current line.
4623     if ( $line =~ /^\s*$/ ) {
4624         cmd_b_line( $dbline, 1 );
4625     }
4626
4627     # Break on load for a file.
4628     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4629         $file =~ s/\s+\z//;
4630         cmd_b_load($file);
4631     }
4632
4633     # b compile|postpone <some sub> [<condition>]
4634     # The interpreter actually traps this one for us; we just put the
4635     # necessary condition in the %postponed hash.
4636     elsif ( my ($action, $subname, $cond)
4637         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4638
4639         # De-Perl4-ify the name - ' separators to ::.
4640         $subname =~ s/'/::/g;
4641
4642         # Qualify it into the current package unless it's already qualified.
4643         $subname = "${package}::" . $subname unless $subname =~ /::/;
4644
4645         # Add main if it starts with ::.
4646         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4647
4648         # Save the break type for this sub.
4649         $postponed{$subname} = (($action eq 'postpone')
4650             ? ( "break +0 if " . $default_cond->($cond) )
4651             : "compile");
4652     } ## end elsif ($line =~ ...
4653     # b <filename>:<line> [<condition>]
4654     elsif (my ($filename, $line_num, $cond)
4655         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4656         cmd_b_filename_line(
4657             $filename,
4658             $line_num,
4659             (length($cond) ? $cond : '1'),
4660         );
4661     }
4662     # b <sub name> [<condition>]
4663     elsif ( my ($new_subname, $new_cond) =
4664         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4665
4666         #
4667         $subname = $new_subname;
4668         cmd_b_sub( $subname, $default_cond->($new_cond) );
4669     }
4670
4671     # b <line> [<condition>].
4672     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4673
4674         # Capture the line. If none, it's the current line.
4675         $line = $line_n || $dbline;
4676
4677         # Break on line.
4678         cmd_b_line( $line, $default_cond->($cond) );
4679     }
4680
4681     # Line didn't make sense.
4682     else {
4683         print "confused by line($line)?\n";
4684     }
4685
4686     return;
4687 } ## end sub cmd_b
4688
4689 =head3 C<break_on_load> (API)
4690
4691 We want to break when this file is loaded. Mark this file in the
4692 C<%break_on_load> hash, and note that it has a breakpoint in
4693 C<%had_breakpoints>.
4694
4695 =cut
4696
4697 sub break_on_load {
4698     my $file = shift;
4699     $break_on_load{$file} = 1;
4700     $had_breakpoints{$file} |= 1;
4701 }
4702
4703 =head3 C<report_break_on_load> (API)
4704
4705 Gives us an array of filenames that are set to break on load. Note that
4706 only files with break-on-load are in here, so simply showing the keys
4707 suffices.
4708
4709 =cut
4710
4711 sub report_break_on_load {
4712     sort keys %break_on_load;
4713 }
4714
4715 =head3 C<cmd_b_load> (command)
4716
4717 We take the file passed in and try to find it in C<%INC> (which maps modules
4718 to files they came from). We mark those files for break-on-load via
4719 C<break_on_load> and then report that it was done.
4720
4721 =cut
4722
4723 sub cmd_b_load {
4724     my $file = shift;
4725     my @files;
4726
4727     # This is a block because that way we can use a redo inside it
4728     # even without there being any looping structure at all outside it.
4729     {
4730
4731         # Save short name and full path if found.
4732         push @files, $file;
4733         push @files, $::INC{$file} if $::INC{$file};
4734
4735         # Tack on .pm and do it again unless there was a '.' in the name
4736         # already.
4737         $file .= '.pm', redo unless $file =~ /\./;
4738     }
4739
4740     # Do the real work here.
4741     break_on_load($_) for @files;
4742
4743     # All the files that have break-on-load breakpoints.
4744     @files = report_break_on_load;
4745
4746     # Normalize for the purposes of our printing this.
4747     local $\ = '';
4748     local $" = ' ';
4749     print $OUT "Will stop on load of '@files'.\n";
4750 } ## end sub cmd_b_load
4751
4752 =head3 C<$filename_error> (API package global)
4753
4754 Several of the functions we need to implement in the API need to work both
4755 on the current file and on other files. We don't want to duplicate code, so
4756 C<$filename_error> is used to contain the name of the file that's being
4757 worked on (if it's not the current one).
4758
4759 We can now build functions in pairs: the basic function works on the current
4760 file, and uses C<$filename_error> as part of its error message. Since this is
4761 initialized to C<"">, no filename will appear when we are working on the
4762 current file.
4763
4764 The second function is a wrapper which does the following:
4765
4766 =over 4
4767
4768 =item *
4769
4770 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4771
4772 =item *
4773
4774 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4775
4776 =item *
4777
4778 Calls the first function.
4779
4780 The first function works on the I<current> file (i.e., the one we changed to),
4781 and prints C<$filename_error> in the error message (the name of the other file)
4782 if it needs to. When the functions return, C<*dbline> is restored to point
4783 to the actual current file (the one we're executing in) and
4784 C<$filename_error> is restored to C<"">. This restores everything to
4785 the way it was before the second function was called at all.
4786
4787 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4788 details.
4789
4790 =back
4791
4792 =cut
4793
4794 use vars qw($filename_error);
4795 $filename_error = '';
4796
4797 =head3 breakable_line(from, to) (API)
4798
4799 The subroutine decides whether or not a line in the current file is breakable.
4800 It walks through C<@dbline> within the range of lines specified, looking for
4801 the first line that is breakable.
4802
4803 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4804 first line I<after> C<$to> that's breakable, if there is one.
4805
4806 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4807 first line I<before> C<$to> that's breakable, if there is one.
4808
4809 =cut
4810
4811 sub breakable_line {
4812
4813     my ( $from, $to ) = @_;
4814
4815     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4816     my $i = $from;
4817
4818     # If there are at least 2 arguments, we're trying to search a range.
4819     if ( @_ >= 2 ) {
4820
4821         # $delta is positive for a forward search, negative for a backward one.
4822         my $delta = $from < $to ? +1 : -1;
4823
4824         # Keep us from running off the ends of the file.
4825         my $limit = $delta > 0 ? $#dbline : 1;
4826
4827         # Clever test. If you're a mathematician, it's obvious why this
4828         # test works. If not:
4829         # If $delta is positive (going forward), $limit will be $#dbline.
4830         #    If $to is less than $limit, ($limit - $to) will be positive, times
4831         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4832         #    as the stopping point.
4833         #
4834         #    If $to is greater than $limit, ($limit - $to) is negative,
4835         #    times $delta of 1 (positive), so the result is < 0 and we should
4836         #    use $limit ($#dbline) as the stopping point.
4837         #
4838         # If $delta is negative (going backward), $limit will be 1.
4839         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4840         #    (negative) so the result is > 0, and we use $to as the stopping
4841         #    point.
4842         #
4843         #    If $to is less than zero, ($limit - $to) will be positive,
4844         #    times $delta of -1 (negative), so the result is not > 0, and
4845         #    we use $limit (1) as the stopping point.
4846         #
4847         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4848         #    (negative), still giving zero; the result is not > 0, and
4849         #    we use $limit (1) as the stopping point.
4850         #
4851         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4852         #    (negative), giving a positive (>0) value, so we'll set $limit to
4853         #    $to.
4854
4855         $limit = $to if ( $limit - $to ) * $delta > 0;
4856
4857         # The real search loop.
4858         # $i starts at $from (the point we want to start searching from).
4859         # We move through @dbline in the appropriate direction (determined
4860         # by $delta: either -1 (back) or +1 (ahead).
4861         # We stay in as long as we haven't hit an executable line
4862         # ($dbline[$i] == 0 means not executable) and we haven't reached
4863         # the limit yet (test similar to the above).
4864         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4865
4866     } ## end if (@_ >= 2)
4867
4868     # If $i points to a line that is executable, return that.
4869     return $i unless $dbline[$i] == 0;
4870
4871     # Format the message and print it: no breakable lines in range.
4872     my ( $pl, $upto ) = ( '', '' );
4873     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4874
4875     # If there's a filename in filename_error, we'll see it.
4876     # If not, not.
4877     die "Line$pl $from$upto$filename_error not breakable\n";
4878 } ## end sub breakable_line
4879
4880 =head3 breakable_line_in_filename(file, from, to) (API)
4881
4882 Like C<breakable_line>, but look in another file.
4883
4884 =cut
4885
4886 sub breakable_line_in_filename {
4887
4888     # Capture the file name.
4889     my ($f) = shift;
4890
4891     # Swap the magic line array over there temporarily.
4892     local *dbline = $main::{ '_<' . $f };
4893
4894     # If there's an error, it's in this other file.
4895     local $filename_error = " of '$f'";
4896
4897     # Find the breakable line.
4898     breakable_line(@_);
4899
4900     # *dbline and $filename_error get restored when this block ends.
4901
4902 } ## end sub breakable_line_in_filename
4903
4904 =head3 break_on_line(lineno, [condition]) (API)
4905
4906 Adds a breakpoint with the specified condition (or 1 if no condition was
4907 specified) to the specified line. Dies if it can't.
4908
4909 =cut
4910
4911 sub break_on_line {
4912     my $i = shift;
4913     my $cond = @_ ? shift(@_) : 1;
4914
4915     my $inii  = $i;
4916     my $after = '';
4917     my $pl    = '';
4918
4919     # Woops, not a breakable line. $filename_error allows us to say
4920     # if it was in a different file.
4921     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4922
4923     # Mark this file as having breakpoints in it.
4924     $had_breakpoints{$filename} |= 1;
4925
4926     # If there is an action or condition here already ...
4927     if ( $dbline{$i} ) {
4928
4929         # ... swap this condition for the existing one.
4930         $dbline{$i} =~ s/^[^\0]*/$cond/;
4931     }
4932     else {
4933
4934         # Nothing here - just add the condition.
4935         $dbline{$i} = $cond;
4936
4937         _set_breakpoint_enabled_status($filename, $i, 1);
4938     }
4939
4940     return;
4941 } ## end sub break_on_line
4942
4943 =head3 cmd_b_line(line, [condition]) (command)
4944
4945 Wrapper for C<break_on_line>. Prints the failure message if it
4946 doesn't work.
4947
4948 =cut
4949
4950 sub cmd_b_line {
4951     if (not eval { break_on_line(@_); 1 }) {
4952         local $\ = '';
4953         print $OUT $@ and return;
4954     }
4955
4956     return;
4957 } ## end sub cmd_b_line
4958
4959 =head3 cmd_b_filename_line(line, [condition]) (command)
4960
4961 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4962 doesn't work.
4963
4964 =cut
4965
4966 sub cmd_b_filename_line {
4967     if (not eval { break_on_filename_line(@_); 1 }) {
4968         local $\ = '';
4969         print $OUT $@ and return;
4970     }
4971
4972     return;
4973 }
4974
4975 =head3 break_on_filename_line(file, line, [condition]) (API)
4976
4977 Switches to the file specified and then calls C<break_on_line> to set
4978 the breakpoint.
4979
4980 =cut
4981
4982 sub break_on_filename_line {
4983     my $f = shift;
4984     my $i = shift;
4985     my $cond = @_ ? shift(@_) : 1;
4986
4987     # Switch the magical hash temporarily.
4988     local *dbline = $main::{ '_<' . $f };
4989
4990     # Localize the variables that break_on_line uses to make its message.
4991     local $filename_error = " of '$f'";
4992     local $filename       = $f;
4993
4994     # Add the breakpoint.
4995     break_on_line( $i, $cond );
4996
4997     return;
4998 } ## end sub break_on_filename_line
4999
5000 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
5001
5002 Switch to another file, search the range of lines specified for an
5003 executable one, and put a breakpoint on the first one you find.
5004
5005 =cut
5006
5007 sub break_on_filename_line_range {
5008     my $f = shift;
5009     my $from = shift;
5010     my $to = shift;
5011     my $cond = @_ ? shift(@_) : 1;
5012
5013     # Find a breakable line if there is one.
5014     my $i = breakable_line_in_filename( $f, $from, $to );
5015
5016     # Add the breakpoint.
5017     break_on_filename_line( $f, $i, $cond );
5018
5019     return;
5020 } ## end sub break_on_filename_line_range
5021
5022 =head3 subroutine_filename_lines(subname, [condition]) (API)
5023
5024 Search for a subroutine within a given file. The condition is ignored.
5025 Uses C<find_sub> to locate the desired subroutine.
5026
5027 =cut
5028
5029 sub subroutine_filename_lines {
5030     my ( $subname ) = @_;
5031
5032     # Returned value from find_sub() is fullpathname:startline-endline.
5033     # The match creates the list (fullpathname, start, end).
5034     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
5035 } ## end sub subroutine_filename_lines
5036
5037 =head3 break_subroutine(subname) (API)
5038
5039 Places a break on the first line possible in the specified subroutine. Uses
5040 C<subroutine_filename_lines> to find the subroutine, and
5041 C<break_on_filename_line_range> to place the break.
5042
5043 =cut
5044
5045 sub break_subroutine {
5046     my $subname = shift;
5047
5048     # Get filename, start, and end.
5049     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
5050       or die "Subroutine $subname not found.\n";
5051
5052
5053     # Null condition changes to '1' (always true).
5054     my $cond = @_ ? shift(@_) : 1;
5055
5056     # Put a break the first place possible in the range of lines
5057     # that make up this subroutine.
5058     break_on_filename_line_range( $file, $s, $e, $cond );
5059
5060     return;
5061 } ## end sub break_subroutine
5062
5063 =head3 cmd_b_sub(subname, [condition]) (command)
5064
5065 We take the incoming subroutine name and fully-qualify it as best we can.
5066
5067 =over 4
5068
5069 =item 1. If it's already fully-qualified, leave it alone.
5070
5071 =item 2. Try putting it in the current package.
5072
5073 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
5074
5075 =item 4. If it starts with '::', put it in 'main::'.
5076
5077 =back
5078
5079 After all this cleanup, we call C<break_subroutine> to try to set the
5080 breakpoint.
5081
5082 =cut
5083
5084 sub cmd_b_sub {
5085     my $subname = shift;
5086     my $cond = @_ ? shift : 1;
5087
5088     # If the subname isn't a code reference, qualify it so that
5089     # break_subroutine() will work right.
5090     if ( ref($subname) ne 'CODE' ) {
5091
5092         # Not Perl 4.
5093         $subname =~ s/'/::/g;
5094         my $s = $subname;
5095
5096         # Put it in this package unless it's already qualified.
5097         if ($subname !~ /::/)
5098         {
5099             $subname = $package . '::' . $subname;
5100         };
5101
5102         # Requalify it into CORE::GLOBAL if qualifying it into this
5103         # package resulted in its not being defined, but only do so
5104         # if it really is in CORE::GLOBAL.
5105         my $core_name = "CORE::GLOBAL::$s";
5106         if ((!defined(&$subname))
5107                 and ($s !~ /::/)
5108                 and (defined &{$core_name}))
5109         {
5110             $subname = $core_name;
5111         }
5112
5113         # Put it in package 'main' if it has a leading ::.
5114         if ($subname =~ /\A::/)
5115         {
5116             $subname = "main" . $subname;
5117         }
5118     } ## end if ( ref($subname) ne 'CODE' ) {
5119
5120     # Try to set the breakpoint.
5121     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
5122         local $\ = '';
5123         print {$OUT} $@;
5124         return;
5125     }
5126
5127     return;
5128 } ## end sub cmd_b_sub
5129
5130 =head3 C<cmd_B> - delete breakpoint(s) (command)
5131
5132 The command mostly parses the command line and tries to turn the argument
5133 into a line spec. If it can't, it uses the current line. It then calls
5134 C<delete_breakpoint> to actually do the work.
5135
5136 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
5137 thereby deleting all the breakpoints.
5138
5139 =cut
5140
5141 sub cmd_B {
5142     my $cmd = shift;
5143
5144     # No line spec? Use dbline.
5145     # If there is one, use it if it's non-zero, or wipe it out if it is.
5146     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
5147     my $dbline = shift;
5148
5149     # If the line was dot, make the line the current one.
5150     $line =~ s/^\./$dbline/;
5151
5152     # If it's * we're deleting all the breakpoints.
5153     if ( $line eq '*' ) {
5154         if (not eval { delete_breakpoint(); 1 }) {
5155             print {$OUT} $@;
5156         }
5157     }
5158
5159     # If there is a line spec, delete the breakpoint on that line.
5160     elsif ( $line =~ /\A(\S.*)/ ) {
5161         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
5162             local $\ = '';
5163             print {$OUT} $@;
5164         }
5165     } ## end elsif ($line =~ /^(\S.*)/)
5166
5167     # No line spec.
5168     else {
5169         print {$OUT}
5170           "Deleting a breakpoint requires a line number, or '*' for all\n"
5171           ;    # hint
5172     }
5173
5174     return;
5175 } ## end sub cmd_B
5176
5177 =head3 delete_breakpoint([line]) (API)
5178
5179 This actually does the work of deleting either a single breakpoint, or all
5180 of them.
5181
5182 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
5183 just drop out with a message saying so. If it is, we remove the condition
5184 part of the 'condition\0action' that says there's a breakpoint here. If,
5185 after we've done that, there's nothing left, we delete the corresponding
5186 line in C<%dbline> to signal that no action needs to be taken for this line.
5187
5188 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
5189 which lists all currently-loaded files which have breakpoints. We then look
5190 at each line in each of these files, temporarily switching the C<%dbline>
5191 and C<@dbline> structures to point to the files in question, and do what
5192 we did in the single line case: delete the condition in C<@dbline>, and
5193 delete the key in C<%dbline> if nothing's left.
5194
5195 We then wholesale delete C<%postponed>, C<%postponed_file>, and
5196 C<%break_on_load>, because these structures contain breakpoints for files
5197 and code that haven't been loaded yet. We can just kill these off because there
5198 are no magical debugger structures associated with them.
5199
5200 =cut
5201
5202 sub _remove_breakpoint_entry {
5203     my ($fn, $i) = @_;
5204
5205     delete $dbline{$i};
5206     _delete_breakpoint_data_ref($fn, $i);
5207
5208     return;
5209 }
5210
5211 sub _delete_all_breakpoints {
5212     print {$OUT} "Deleting all breakpoints...\n";
5213
5214     # %had_breakpoints lists every file that had at least one
5215     # breakpoint in it.
5216     for my $fn ( keys %had_breakpoints ) {
5217
5218         # Switch to the desired file temporarily.
5219         local *dbline = $main::{ '_<' . $fn };
5220
5221         $max = $#dbline;
5222
5223         # For all lines in this file ...
5224         for my $i (1 .. $max) {
5225
5226             # If there's a breakpoint or action on this line ...
5227             if ( defined $dbline{$i} ) {
5228
5229                 # ... remove the breakpoint.
5230                 $dbline{$i} =~ s/\A[^\0]+//;
5231                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
5232                     # Remove the entry altogether if no action is there.
5233                     _remove_breakpoint_entry($fn, $i);
5234                 }
5235             } ## end if (defined $dbline{$i...
5236         } ## end for $i (1 .. $max)
5237
5238         # If, after we turn off the "there were breakpoints in this file"
5239         # bit, the entry in %had_breakpoints for this file is zero,
5240         # we should remove this file from the hash.
5241         if ( not $had_breakpoints{$fn} &= (~1) ) {
5242             delete $had_breakpoints{$fn};
5243         }
5244     } ## end for my $fn (keys %had_breakpoints)
5245
5246     # Kill off all the other breakpoints that are waiting for files that
5247     # haven't been loaded yet.
5248     undef %postponed;
5249     undef %postponed_file;
5250     undef %break_on_load;
5251
5252     return;
5253 }
5254
5255 sub _delete_breakpoint_from_line {
5256     my ($i) = @_;
5257
5258     # Woops. This line wasn't breakable at all.
5259     die "Line $i not breakable.\n" if $dbline[$i] == 0;
5260
5261     # Kill the condition, but leave any action.
5262     $dbline{$i} =~ s/\A[^\0]*//;
5263
5264     # Remove the entry entirely if there's no action left.
5265     if ($dbline{$i} eq '') {
5266         _remove_breakpoint_entry($filename, $i);
5267     }
5268
5269     return;
5270 }
5271
5272 sub delete_breakpoint {
5273     my $i = shift;
5274
5275     # If we got a line, delete just that one.
5276     if ( defined($i) ) {
5277         _delete_breakpoint_from_line($i);
5278     }
5279     # No line; delete them all.
5280     else {
5281         _delete_all_breakpoints();
5282     }
5283
5284     return;
5285 }
5286
5287 =head3 cmd_stop (command)
5288
5289 This is meant to be part of the new command API, but it isn't called or used
5290 anywhere else in the debugger. XXX It is probably meant for use in development
5291 of new commands.
5292
5293 =cut
5294
5295 sub cmd_stop {    # As on ^C, but not signal-safy.
5296     $signal = 1;
5297 }
5298
5299 =head3 C<cmd_e> - threads
5300
5301 Display the current thread id:
5302
5303     e
5304
5305 This could be how (when implemented) to send commands to this thread id (e cmd)
5306 or that thread id (e tid cmd).
5307
5308 =cut
5309
5310 sub cmd_e {
5311     my $cmd  = shift;
5312     my $line = shift;
5313     unless (exists($INC{'threads.pm'})) {
5314         print "threads not loaded($ENV{PERL5DB_THREADED})
5315         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5316     } else {
5317         my $tid = threads->tid;
5318         print "thread id: $tid\n";
5319     }
5320 } ## end sub cmd_e
5321
5322 =head3 C<cmd_E> - list of thread ids
5323
5324 Display the list of available thread ids:
5325
5326     E
5327
5328 This could be used (when implemented) to send commands to all threads (E cmd).
5329
5330 =cut
5331
5332 sub cmd_E {
5333     my $cmd  = shift;
5334     my $line = shift;
5335     unless (exists($INC{'threads.pm'})) {
5336         print "threads not loaded($ENV{PERL5DB_THREADED})
5337         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5338     } else {
5339         my $tid = threads->tid;
5340         print "thread ids: ".join(', ',
5341             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5342         )."\n";
5343     }
5344 } ## end sub cmd_E
5345
5346 =head3 C<cmd_h> - help command (command)
5347
5348 Does the work of either
5349
5350 =over 4
5351
5352 =item *
5353
5354 Showing all the debugger help
5355
5356 =item *
5357
5358 Showing help for a specific command
5359
5360 =back
5361
5362 =cut
5363
5364 use vars qw($help);
5365 use vars qw($summary);
5366
5367 sub cmd_h {
5368     my $cmd = shift;
5369
5370     # If we have no operand, assume null.
5371     my $line = shift || '';
5372
5373     # 'h h'. Print the long-format help.
5374     if ( $line =~ /\Ah\s*\z/ ) {
5375         print_help($help);
5376     }
5377
5378     # 'h <something>'. Search for the command and print only its help.
5379     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5380
5381         # support long commands; otherwise bogus errors
5382         # happen when you ask for h on <CR> for example
5383         my $qasked = quotemeta($asked);    # for searching; we don't
5384                                            # want to use it as a pattern.
5385                                            # XXX: finds CR but not <CR>
5386
5387         # Search the help string for the command.
5388         if (
5389             $help =~ /^                    # Start of a line
5390                       <?                   # Optional '<'
5391                       (?:[IB]<)            # Optional markup
5392                       $qasked              # The requested command
5393                      /mx
5394           )
5395         {
5396
5397             # It's there; pull it out and print it.
5398             while (
5399                 $help =~ /^
5400                               (<?            # Optional '<'
5401                                  (?:[IB]<)   # Optional markup
5402                                  $qasked     # The command
5403                                  ([\s\S]*?)  # Description line(s)
5404                               \n)            # End of last description line
5405                               (?!\s)         # Next line not starting with
5406                                              # whitespace
5407                              /mgx
5408               )
5409             {
5410                 print_help($1);
5411             }
5412         }
5413
5414         # Not found; not a debugger command.
5415         else {
5416             print_help("B<$asked> is not a debugger command.\n");
5417         }
5418     } ## end elsif ($line =~ /^(\S.*)$/)
5419
5420     # 'h' - print the summary help.
5421     else {
5422         print_help($summary);
5423     }
5424 } ## end sub cmd_h
5425
5426 =head3 C<cmd_i> - inheritance display
5427
5428 Display the (nested) parentage of the module or object given.
5429
5430 =cut
5431
5432 sub cmd_i {
5433     my $cmd  = shift;
5434     my $line = shift;
5435     foreach my $isa ( split( /\s+/, $line ) ) {
5436         $evalarg = $isa;
5437         # The &-call is here to ascertain the mutability of @_.
5438         ($isa) = &DB::eval;
5439         no strict 'refs';
5440         print join(
5441             ', ',
5442             map {
5443                 "$_"
5444                   . (
5445                     defined( ${"$_\::VERSION"} )
5446                     ? ' ' . ${"$_\::VERSION"}
5447                     : undef )
5448               } @{mro::get_linear_isa(ref($isa) || $isa)}
5449         );
5450         print "\n";
5451     }
5452 } ## end sub cmd_i
5453
5454 =head3 C<cmd_l> - list lines (command)
5455
5456 Most of the command is taken up with transforming all the different line
5457 specification syntaxes into 'start-stop'. After that is done, the command
5458 runs a loop over C<@dbline> for the specified range of lines. It handles
5459 the printing of each line and any markers (C<==E<gt>> for current line,
5460 C<b> for break on this line, C<a> for action on this line, C<:> for this
5461 line breakable).
5462
5463 We save the last line listed in the C<$start> global for further listing
5464 later.
5465
5466 =cut
5467
5468 sub _min {
5469     my $min = shift;
5470     foreach my $v (@_) {
5471         if ($min > $v) {
5472             $min = $v;
5473         }
5474     }
5475     return $min;
5476 }
5477
5478 sub _max {
5479     my $max = shift;
5480     foreach my $v (@_) {
5481         if ($max < $v) {
5482             $max = $v;
5483         }
5484     }
5485     return $max;
5486 }
5487
5488 sub _minify_to_max {
5489     my $ref = shift;
5490
5491     $$ref = _min($$ref, $max);
5492
5493     return;
5494 }
5495
5496 sub _cmd_l_handle_var_name {
5497     my $var_name = shift;
5498
5499     $evalarg = $var_name;
5500
5501     my ($s) = DB::eval();
5502
5503     # Ooops. Bad scalar.
5504     if ($@) {
5505         print {$OUT} "Error: $@\n";
5506         next CMD;
5507     }
5508
5509     # Good scalar. If it's a reference, find what it points to.
5510     $s = CvGV_name($s);
5511     print {$OUT} "Interpreted as: $1 $s\n";
5512     $line = "$1 $s";
5513
5514     # Call self recursively to really do the command.
5515     return _cmd_l_main( $s );
5516 }
5517
5518 sub _cmd_l_handle_subname {
5519
5520     my $s = $subname;
5521
5522     # De-Perl4.
5523     $subname =~ s/\'/::/;
5524
5525     # Put it in this package unless it starts with ::.
5526     $subname = $package . "::" . $subname unless $subname =~ /::/;
5527
5528     # Put it in CORE::GLOBAL if t doesn't start with :: and
5529     # it doesn't live in this package and it lives in CORE::GLOBAL.
5530     $subname = "CORE::GLOBAL::$s"
5531     if not defined &$subname
5532         and $s !~ /::/
5533         and defined &{"CORE::GLOBAL::$s"};
5534
5535     # Put leading '::' names into 'main::'.
5536     $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5537
5538     # Get name:start-stop from find_sub, and break this up at
5539     # colons.
5540     my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5541
5542     # Pull off start-stop.
5543     my $subrange = pop @pieces;
5544
5545     # If the name contained colons, the split broke it up.
5546     # Put it back together.
5547     $file = join( ':', @pieces );
5548
5549     # If we're not in that file, switch over to it.
5550     if ( $file ne $filename ) {
5551         if (! $slave_editor) {
5552             print {$OUT} "Switching to file '$file'.\n";
5553         }
5554
5555         # Switch debugger's magic structures.
5556         *dbline   = $main::{ '_<' . $file };
5557         $max      = $#dbline;
5558         $filename = $file;
5559     } ## end if ($file ne $filename)
5560
5561     # Subrange is 'start-stop'. If this is less than a window full,
5562     # swap it to 'start+', which will list a window from the start point.
5563     if ($subrange) {
5564         if ( eval($subrange) < -$window ) {
5565             $subrange =~ s/-.*/+/;
5566         }
5567
5568         # Call self recursively to list the range.
5569         return _cmd_l_main( $subrange );
5570     } ## end if ($subrange)
5571
5572     # Couldn't find it.
5573     else {
5574         print {$OUT} "Subroutine $subname not found.\n";
5575         return;
5576     }
5577 }
5578
5579 sub _cmd_l_empty {
5580     # Compute new range to list.
5581     $incr = $window - 1;
5582
5583     # Recurse to do it.
5584     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5585 }
5586
5587 sub _cmd_l_plus {
5588     my ($new_start, $new_incr) = @_;
5589
5590     # Don't reset start for 'l +nnn'.
5591     $start = $new_start if $new_start;
5592
5593     # Increment for list. Use window size if not specified.
5594     # (Allows 'l +' to work.)
5595     $incr = $new_incr || ($window - 1);
5596
5597     # Create a line range we'll understand, and recurse to do it.
5598     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5599 }
5600
5601 sub _cmd_l_calc_initial_end_and_i {
5602     my ($spec, $start_match, $end_match) = @_;
5603
5604     # Determine end point; use end of file if not specified.
5605     my $end = ( !defined $start_match ) ? $max :
5606     ( $end_match ? $end_match : $start_match );
5607
5608     # Go on to the end, and then stop.
5609     _minify_to_max(\$end);
5610
5611     # Determine start line.
5612     my $i = $start_match;
5613
5614     if ($i eq '.') {
5615         $i = $spec;
5616     }
5617
5618     $i = _max($i, 1);
5619
5620     $incr = $end - $i;
5621
5622     return ($end, $i);
5623 }
5624
5625 sub _cmd_l_range {
5626     my ($spec, $current_line, $start_match, $end_match) = @_;
5627
5628     my ($end, $i) =
5629         _cmd_l_calc_initial_end_and_i($spec, $start_match, $end_match);
5630
5631     # If we're running under a slave editor, force it to show the lines.
5632     if ($slave_editor) {
5633         print {$OUT} "\032\032$filename:$i:0\n";
5634         $i = $end;
5635     }
5636     # We're doing it ourselves. We want to show the line and special
5637     # markers for:
5638     # - the current line in execution
5639     # - whether a line is breakable or not
5640     # - whether a line has a break or not
5641     # - whether a line has an action or not
5642     else {
5643         I_TO_END:
5644         for ( ; $i <= $end ; $i++ ) {
5645
5646             # Check for breakpoints and actions.
5647             my ( $stop, $action );
5648             if ($dbline{$i}) {
5649                 ( $stop, $action ) = split( /\0/, $dbline{$i} );
5650             }
5651
5652             # ==> if this is the current line in execution,
5653             # : if it's breakable.
5654             my $arrow =
5655             ( $i == $current_line and $filename eq $filename_ini )
5656             ? '==>'
5657             : ( $dbline[$i] + 0 ? ':' : ' ' );
5658
5659             # Add break and action indicators.
5660             $arrow .= 'b' if $stop;
5661             $arrow .= 'a' if $action;
5662
5663             # Print the line.
5664             print {$OUT} "$i$arrow\t", $dbline[$i];
5665
5666             # Move on to the next line. Drop out on an interrupt.
5667             if ($signal) {
5668                 $i++;
5669                 last I_TO_END;
5670             }
5671         } ## end for (; $i <= $end ; $i++)
5672
5673         # Line the prompt up; print a newline if the last line listed
5674         # didn't have a newline.
5675         if ($dbline[ $i - 1 ] !~ /\n\z/) {
5676             print {$OUT} "\n";
5677         }
5678     } ## end else [ if ($slave_editor)
5679
5680     # Save the point we last listed to in case another relative 'l'
5681     # command is desired. Don't let it run off the end.
5682     $start = $i;
5683     _minify_to_max(\$start);
5684
5685     return;
5686 }
5687
5688 sub _cmd_l_main {
5689     my $spec = shift;
5690
5691     # If this is '-something', delete any spaces after the dash.
5692     $spec =~ s/\A-\s*\z/-/;
5693
5694     # If the line is '$something', assume this is a scalar containing a
5695     # line number.
5696     # Set up for DB::eval() - evaluate in *user* context.
5697     if ( my ($var_name) = $spec =~ /\A(\$.*)/s ) {
5698         return _cmd_l_handle_var_name($var_name);
5699     }
5700     # l name. Try to find a sub by that name.
5701     elsif ( ($subname) = $spec =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5702         return _cmd_l_handle_subname();
5703     }
5704     # Bare 'l' command.
5705     elsif ( $spec !~ /\S/ ) {
5706         return _cmd_l_empty();
5707     }
5708     # l [start]+number_of_lines
5709     elsif ( my ($new_start, $new_incr) = $spec =~ /\A(\d*)\+(\d*)\z/ ) {
5710         return _cmd_l_plus($new_start, $new_incr);
5711     }
5712     # l start-stop or l start,stop
5713     elsif (my ($s, $e) = $spec =~ /^(?:(-?[\d\$\.]+)(?:[-,]([\d\$\.]+))?)?/ ) {
5714         return _cmd_l_range($spec, $line, $s, $e);
5715     }
5716
5717     return;
5718 } ## end sub cmd_l
5719
5720 sub cmd_l {
5721     my (undef, $line) = @_;
5722
5723     return _cmd_l_main($line);
5724 }
5725
5726 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5727
5728 To list breakpoints, the command has to look determine where all of them are
5729 first. It starts a C<%had_breakpoints>, which tells us what all files have
5730 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5731 magic source and breakpoint data structures) to the file, and then look
5732 through C<%dbline> for lines with breakpoints and/or actions, listing them
5733 out. We look through C<%postponed> not-yet-compiled subroutines that have
5734 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5735 that have breakpoints.
5736
5737 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5738
5739 =cut
5740
5741 sub _cmd_L_calc_arg {
5742     # If no argument, list everything. Pre-5.8.0 version always lists
5743     # everything
5744     my $arg = shift || 'abw';
5745     if ($CommandSet ne '580')
5746     {
5747         $arg = 'abw';
5748     }
5749
5750     return $arg;
5751 }
5752
5753 sub _cmd_L_calc_wanted_flags {
5754     my $arg = _cmd_L_calc_arg(shift);
5755
5756     return (map { index($arg, $_) >= 0 ? 1 : 0 } qw(a b w));
5757 }
5758
5759
5760 sub _cmd_L_handle_breakpoints {
5761     my ($handle_db_line) = @_;
5762
5763     BREAKPOINTS_SCAN:
5764     # Look in all the files with breakpoints...
5765     for my $file ( keys %had_breakpoints ) {
5766
5767         # Temporary switch to this file.
5768         local *dbline = $main::{ '_<' . $file };
5769
5770         # Set up to look through the whole file.
5771         $max = $#dbline;
5772         my $was;    # Flag: did we print something
5773         # in this file?
5774
5775         # For each line in the file ...
5776         for my $i (1 .. $max) {
5777
5778             # We've got something on this line.
5779             if ( defined $dbline{$i} ) {
5780
5781                 # Print the header if we haven't.
5782                 if (not $was++) {
5783                     print {$OUT} "$file:\n";
5784                 }
5785
5786                 # Print the line.
5787                 print {$OUT} " $i:\t", $dbline[$i];
5788
5789                 $handle_db_line->($dbline{$i});
5790
5791                 # Quit if the user hit interrupt.
5792                 if ($signal) {
5793                     last BREAKPOINTS_SCAN;
5794                 }
5795             } ## end if (defined $dbline{$i...
5796         } ## end for my $i (1 .. $max)
5797     } ## end for my $file (keys %had_breakpoints)
5798
5799     return;
5800 }
5801
5802 sub _cmd_L_handle_postponed_breakpoints {
5803     my ($handle_db_line) = @_;
5804
5805     print {$OUT} "Postponed breakpoints in files:\n";
5806
5807     POSTPONED_SCANS:
5808     for my $file ( keys %postponed_file ) {
5809         my $db = $postponed_file{$file};
5810         print {$OUT} " $file:\n";
5811         for my $line ( sort { $a <=> $b } keys %$db ) {
5812             print {$OUT} "  $line:\n";
5813
5814             $handle_db_line->($db->{$line});
5815
5816             if ($signal) {
5817                 last POSTPONED_SCANS;
5818             }
5819         }
5820         if ($signal) {
5821             last POSTPONED_SCANS;
5822         }
5823     }
5824
5825     return;
5826 }
5827
5828
5829 sub cmd_L {
5830     my $cmd = shift;
5831
5832     my ($action_wanted, $break_wanted, $watch_wanted) =
5833         _cmd_L_calc_wanted_flags(shift);
5834
5835     my $handle_db_line = sub {
5836         my ($l) = @_;
5837
5838         my ( $stop, $action ) = split( /\0/, $l );
5839
5840         if ($stop and $break_wanted) {
5841             print {$OUT} "    break if (", $stop, ")\n"
5842         }
5843
5844         if ($action && $action_wanted) {
5845             print {$OUT} "    action:  ", $action, "\n"
5846         }
5847
5848         return;
5849     };
5850
5851     # Breaks and actions are found together, so we look in the same place
5852     # for both.
5853     if ( $break_wanted or $action_wanted ) {
5854         _cmd_L_handle_breakpoints($handle_db_line);
5855     }
5856
5857     # Look for breaks in not-yet-compiled subs:
5858     if ( %postponed and $break_wanted ) {
5859         print {$OUT} "Postponed breakpoints in subroutines:\n";
5860         my $subname;
5861         SUBS_SCAN:
5862         for $subname ( keys %postponed ) {
5863             print {$OUT} " $subname\t$postponed{$subname}\n";
5864             if ($signal) {
5865                 last SUBS_SCAN;
5866             }
5867         }
5868     } ## end if (%postponed and $break_wanted)
5869
5870     # Find files that have not-yet-loaded breaks:
5871     my @have = map {    # Combined keys
5872         keys %{ $postponed_file{$_} }
5873     } keys %postponed_file;
5874
5875     # If there are any, list them.
5876     if ( @have and ( $break_wanted or $action_wanted ) ) {
5877         _cmd_L_handle_postponed_breakpoints($handle_db_line);
5878     } ## end if (@have and ($break_wanted...
5879
5880     if ( %break_on_load and $break_wanted ) {
5881         print {$OUT} "Breakpoints on load:\n";
5882         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5883             print {$OUT} " $filename\n";
5884             last BREAK_ON_LOAD if $signal;
5885         }
5886     } ## end if (%break_on_load and...
5887
5888     if ($watch_wanted and ( $trace & 2 )) {
5889         print {$OUT} "Watch-expressions:\n" if @to_watch;
5890         TO_WATCH: for my $expr (@to_watch) {
5891             print {$OUT} " $expr\n";
5892             last TO_WATCH if $signal;
5893         }
5894     }
5895
5896     return;
5897 } ## end sub cmd_L
5898
5899 =head3 C<cmd_M> - list modules (command)
5900
5901 Just call C<list_modules>.
5902
5903 =cut
5904
5905 sub cmd_M {
5906     list_modules();
5907
5908     return;
5909 }
5910
5911 =head3 C<cmd_o> - options (command)
5912
5913 If this is just C<o> by itself, we list the current settings via
5914 C<dump_option>. If there's a nonblank value following it, we pass that on to
5915 C<parse_options> for processing.
5916
5917 =cut
5918
5919 sub cmd_o {
5920     my $cmd = shift;
5921     my $opt = shift || '';    # opt[=val]
5922
5923     # Nonblank. Try to parse and process.
5924     if ( $opt =~ /^(\S.*)/ ) {
5925         parse_options($1);
5926     }
5927
5928     # Blank. List the current option settings.
5929     else {
5930         for (@options) {
5931             dump_option($_);
5932         }
5933     }
5934 } ## end sub cmd_o
5935
5936 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5937
5938 Advises the user that the O command has been renamed.
5939
5940 =cut
5941
5942 sub cmd_O {
5943     print $OUT "The old O command is now the o command.\n";             # hint
5944     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5945     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5946 }
5947
5948 =head3 C<cmd_v> - view window (command)
5949
5950 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5951 move back a few lines to list the selected line in context. Uses C<cmd_l>
5952 to do the actual listing after figuring out the range of line to request.
5953
5954 =cut
5955
5956 use vars qw($preview);
5957
5958 sub cmd_v {
5959     my $cmd  = shift;
5960     my $line = shift;
5961
5962     # Extract the line to list around. (Astute readers will have noted that
5963     # this pattern will match whether or not a numeric line is specified,
5964     # which means that we'll always enter this loop (though a non-numeric
5965     # argument results in no action at all)).
5966     if ( $line =~ /^(\d*)$/ ) {
5967
5968         # Total number of lines to list (a windowful).
5969         $incr = $window - 1;
5970
5971         # Set the start to the argument given (if there was one).
5972         $start = $1 if $1;
5973
5974         # Back up by the context amount.
5975         $start -= $preview;
5976
5977         # Put together a linespec that cmd_l will like.
5978         $line = $start . '-' . ( $start + $incr );
5979
5980         # List the lines.
5981         cmd_l( 'l', $line );
5982     } ## end if ($line =~ /^(\d*)$/)
5983 } ## end sub cmd_v
5984
5985 =head3 C<cmd_w> - add a watch expression (command)
5986
5987 The 5.8 version of this command adds a watch expression if one is specified;
5988 it does nothing if entered with no operands.
5989
5990 We extract the expression, save it, evaluate it in the user's context, and
5991 save the value. We'll re-evaluate it each time the debugger passes a line,
5992 and will stop (see the code at the top of the command loop) if the value
5993 of any of the expressions changes.
5994
5995 =cut
5996
5997 sub _add_watch_expr {
5998     my $expr = shift;
5999
6000     # ... save it.
6001     push @to_watch, $expr;
6002
6003     # Parameterize DB::eval and call it to get the expression's value
6004     # in the user's context. This version can handle expressions which
6005     # return a list value.
6006     $evalarg = $expr;
6007     # The &-call is here to ascertain the mutability of @_.
6008     my ($val) = join( ' ', &DB::eval);
6009     $val = ( defined $val ) ? "'$val'" : 'undef';
6010
6011     # Save the current value of the expression.
6012     push @old_watch, $val;
6013
6014     # We are now watching expressions.
6015     $trace |= 2;
6016
6017     return;
6018 }
6019
6020 sub cmd_w {
6021     my $cmd = shift;
6022
6023     # Null expression if no arguments.
6024     my $expr = shift || '';
6025
6026     # If expression is not null ...
6027     if ( $expr =~ /\A\S/ ) {
6028         _add_watch_expr($expr);
6029     } ## end if ($expr =~ /^(\S.*)/)
6030
6031     # You have to give one to get one.
6032     else {
6033         print $OUT "Adding a watch-expression requires an expression\n";  # hint
6034     }
6035
6036     return;
6037 }
6038
6039 =head3 C<cmd_W> - delete watch expressions (command)
6040
6041 This command accepts either a watch expression to be removed from the list
6042 of watch expressions, or C<*> to delete them all.
6043
6044 If C<*> is specified, we simply empty the watch expression list and the
6045 watch expression value list. We also turn off the bit that says we've got
6046 watch expressions.
6047
6048 If an expression (or partial expression) is specified, we pattern-match
6049 through the expressions and remove the ones that match. We also discard
6050 the corresponding values. If no watch expressions are left, we turn off
6051 the I<watching expressions> bit.
6052
6053 =cut
6054
6055 sub cmd_W {
6056     my $cmd  = shift;
6057     my $expr = shift || '';
6058
6059     # Delete them all.
6060     if ( $expr eq '*' ) {
6061
6062         # Not watching now.
6063         $trace &= ~2;
6064
6065         print $OUT "Deleting all watch expressions ...\n";
6066
6067         # And all gone.
6068         @to_watch = @old_watch = ();
6069     }
6070
6071     # Delete one of them.
6072     elsif ( $expr =~ /^(\S.*)/ ) {
6073
6074         # Where we are in the list.
6075         my $i_cnt = 0;
6076
6077         # For each expression ...
6078         foreach (@to_watch) {
6079             my $val = $to_watch[$i_cnt];
6080
6081             # Does this one match the command argument?
6082             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
6083                                       # Yes. Turn it off, and its value too.
6084                 splice( @to_watch,  $i_cnt, 1 );
6085                 splice( @old_watch, $i_cnt, 1 );
6086             }
6087             $i_cnt++;
6088         } ## end foreach (@to_watch)
6089
6090         # We don't bother to turn watching off because
6091         #  a) we don't want to stop calling watchfunction() if it exists
6092         #  b) foreach over a null list doesn't do anything anyway
6093
6094     } ## end elsif ($expr =~ /^(\S.*)/)
6095
6096     # No command arguments entered.
6097     else {
6098         print $OUT
6099           "Deleting a watch-expression requires an expression, or '*' for all\n"
6100           ;    # hint
6101     }
6102 } ## end sub cmd_W
6103
6104 ### END of the API section
6105
6106 =head1 SUPPORT ROUTINES
6107
6108 These are general support routines that are used in a number of places
6109 throughout the debugger.
6110
6111 =head2 save
6112
6113 save() saves the user's versions of globals that would mess us up in C<@saved>,
6114 and installs the versions we like better.
6115
6116 =cut
6117
6118 sub save {
6119
6120     # Save eval failure, command failure, extended OS error, output field
6121     # separator, input record separator, output record separator and
6122     # the warning setting.
6123     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
6124
6125     $,  = "";      # output field separator is null string
6126     $/  = "\n";    # input record separator is newline
6127     $\  = "";      # output record separator is null string
6128     $^W = 0;       # warnings are off
6129 } ## end sub save
6130
6131 =head2 C<print_lineinfo> - show where we are now
6132
6133 print_lineinfo prints whatever it is that it is handed; it prints it to the
6134 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
6135 us to feed line information to a slave editor without messing up the
6136 debugger output.
6137
6138 =cut
6139
6140 sub print_lineinfo {
6141
6142     # Make the terminal sensible if we're not the primary debugger.
6143     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
6144     local $\ = '';
6145     local $, = '';
6146     # $LINEINFO may be undef if $noTTY is set or some other issue.
6147     if ($LINEINFO)
6148     {
6149         print {$LINEINFO} @_;
6150     }
6151 } ## end sub print_lineinfo
6152
6153 =head2 C<postponed_sub>
6154
6155 Handles setting postponed breakpoints in subroutines once they're compiled.
6156 For breakpoints, we use C<DB::find_sub> to locate the source file and line
6157 range for the subroutine, then mark the file as having a breakpoint,
6158 temporarily switch the C<*dbline> glob over to the source file, and then
6159 search the given range of lines to find a breakable line. If we find one,
6160 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
6161
6162 =cut
6163
6164 # The following takes its argument via $evalarg to preserve current @_
6165
6166 sub postponed_sub {
6167
6168     # Get the subroutine name.
6169     my $subname = shift;
6170
6171     # If this is a 'break +<n> if <condition>' ...
6172     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
6173
6174         # If there's no offset, use '+0'.
6175         my $offset = $1 || 0;
6176
6177         # find_sub's value is 'fullpath-filename:start-stop'. It's
6178         # possible that the filename might have colons in it too.
6179         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
6180         if ($i) {
6181
6182             # We got the start line. Add the offset '+<n>' from
6183             # $postponed{subname}.
6184             $i += $offset;
6185
6186             # Switch to the file this sub is in, temporarily.
6187             local *dbline = $main::{ '_<' . $file };
6188
6189             # No warnings, please.
6190             local $^W = 0;    # != 0 is magical below
6191
6192             # This file's got a breakpoint in it.
6193             $had_breakpoints{$file} |= 1;
6194
6195             # Last line in file.
6196             $max = $#dbline;
6197
6198             # Search forward until we hit a breakable line or get to
6199             # the end of the file.
6200             ++$i until $dbline[$i] != 0 or $i >= $max;
6201
6202             # Copy the breakpoint in and delete it from %postponed.
6203             $dbline{$i} = delete $postponed{$subname};
6204         } ## end if ($i)
6205
6206         # find_sub didn't find the sub.
6207         else {
6208             local $\ = '';
6209             print $OUT "Subroutine $subname not found.\n";
6210         }
6211         return;
6212     } ## end if ($postponed{$subname...
6213     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
6214
6215     #print $OUT "In postponed_sub for '$subname'.\n";
6216 } ## end sub postponed_sub
6217
6218 =head2 C<postponed>
6219
6220 Called after each required file is compiled, but before it is executed;
6221 also called if the name of a just-compiled subroutine is a key of
6222 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
6223 etc.) into the just-compiled code.
6224
6225 If this is a C<require>'d file, the incoming parameter is the glob
6226 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
6227
6228 If it's a subroutine, the incoming parameter is the subroutine name.
6229
6230 =cut
6231
6232 sub postponed {
6233
6234     # If there's a break, process it.
6235     if ($ImmediateStop) {
6236
6237         # Right, we've stopped. Turn it off.
6238         $ImmediateStop = 0;
6239
6240         # Enter the command loop when DB::DB gets called.
6241         $signal = 1;
6242     }
6243
6244     # If this is a subroutine, let postponed_sub() deal with it.
6245     if (ref(\$_[0]) ne 'GLOB') {
6246         return postponed_sub(@_);
6247     }
6248
6249     # Not a subroutine. Deal with the file.
6250     local *dbline = shift;
6251     my $filename = $dbline;
6252     $filename =~ s/^_<//;
6253     local $\ = '';
6254     $signal = 1, print $OUT "'$filename' loaded...\n"
6255       if $break_on_load{$filename};
6256     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
6257
6258     # Do we have any breakpoints to put in this file?
6259     return unless $postponed_file{$filename};
6260
6261     # Yes. Mark this file as having breakpoints.
6262     $had_breakpoints{$filename} |= 1;
6263
6264     # "Cannot be done: insufficient magic" - we can't just put the
6265     # breakpoints saved in %postponed_file into %dbline by assigning
6266     # the whole hash; we have to do it one item at a time for the
6267     # breakpoints to be set properly.
6268     #%dbline = %{$postponed_file{$filename}};
6269
6270     # Set the breakpoints, one at a time.
6271     my $key;
6272
6273     for $key ( keys %{ $postponed_file{$filename} } ) {
6274
6275         # Stash the saved breakpoint into the current file's magic line array.
6276         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
6277     }
6278
6279     # This file's been compiled; discard the stored breakpoints.
6280     delete $postponed_file{$filename};
6281
6282 } ## end sub postponed
6283
6284 =head2 C<dumpit>
6285
6286 C<dumpit> is the debugger's wrapper around dumpvar.pl.
6287
6288 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
6289 a reference to a variable (the thing to be dumped) as its input.
6290
6291 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
6292 the currently-selected filehandle, thank you very much). The current
6293 values of the package globals C<$single> and C<$trace> are backed up in
6294 lexicals, and they are turned off (this keeps the debugger from trying
6295 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
6296 preserve its current value and it is set to zero to prevent entry/exit
6297 messages from printing, and C<$doret> is localized as well and set to -2 to
6298 prevent return values from being shown.
6299
6300 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
6301 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
6302 installed version in C<@INC>, yours will be used instead. Possible security
6303 problem?).
6304
6305 It then checks to see if the subroutine C<main::dumpValue> is now defined
6306 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
6307 localizes the globals necessary for things to be sane when C<main::dumpValue()>
6308 is called, and picks up the variable to be dumped from the parameter list.
6309
6310 It checks the package global C<%options> to see if there's a C<dumpDepth>
6311 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
6312 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
6313 structure: -1 means dump everything.
6314
6315 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
6316 warning.
6317
6318 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
6319 and we then return to the caller.
6320
6321 =cut
6322
6323 sub dumpit {
6324
6325     # Save the current output filehandle and switch to the one
6326     # passed in as the first parameter.
6327     my $savout = select(shift);
6328
6329     # Save current settings of $single and $trace, and then turn them off.
6330     my $osingle = $single;
6331     my $otrace  = $trace;
6332     $single = $trace = 0;
6333
6334     # XXX Okay, what do $frame and $doret do, again?
6335     local $frame = 0;
6336     local $doret = -2;
6337
6338     # Load dumpvar.pl unless we've already got the sub we need from it.
6339     unless ( defined &main::dumpValue ) {
6340         do 'dumpvar.pl' or die $@;
6341     }
6342
6343     # If the load succeeded (or we already had dumpvalue()), go ahead
6344     # and dump things.
6345     if ( defined &main::dumpValue ) {
6346         local $\ = '';
6347         local $, = '';
6348         local $" = ' ';
6349         my $v = shift;
6350         my $maxdepth = shift || $option{dumpDepth};
6351         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
6352         main::dumpValue( $v, $maxdepth );
6353     } ## end if (defined &main::dumpValue)
6354
6355     # Oops, couldn't load dumpvar.pl.
6356     else {
6357         local $\ = '';
6358         print $OUT "dumpvar.pl not available.\n";
6359     }
6360
6361     # Reset $single and $trace to their old values.
6362     $single = $osingle;
6363     $trace  = $otrace;
6364
6365     # Restore the old filehandle.
6366     select($savout);
6367 } ## end sub dumpit
6368
6369 =head2 C<print_trace>
6370
6371 C<print_trace>'s job is to print a stack trace. It does this via the
6372 C<dump_trace> routine, which actually does all the ferreting-out of the
6373 stack trace data. C<print_trace> takes care of formatting it nicely and
6374 printing it to the proper filehandle.
6375
6376 Parameters:
6377
6378 =over 4
6379
6380 =item *
6381
6382 The filehandle to print to.
6383
6384 =item *
6385
6386 How many frames to skip before starting trace.
6387
6388 =item *
6389
6390 How many frames to print.
6391
6392 =item *
6393
6394 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
6395
6396 =back
6397
6398 The original comment below seems to be noting that the traceback may not be
6399 correct if this routine is called in a tied method.
6400
6401 =cut
6402
6403 # Tied method do not create a context, so may get wrong message:
6404
6405 sub print_trace {
6406     local $\ = '';
6407     my $fh = shift;
6408
6409     # If this is going to a slave editor, but we're not the primary
6410     # debugger, reset it first.
6411     resetterm(1)
6412       if $fh        eq $LINEINFO    # slave editor
6413       and $LINEINFO eq $OUT         # normal output
6414       and $term_pid != $$;          # not the primary
6415
6416     # Collect the actual trace information to be formatted.
6417     # This is an array of hashes of subroutine call info.
6418     my @sub = dump_trace( $_[0] + 1, $_[1] );
6419
6420     # Grab the "short report" flag from @_.
6421     my $short = $_[2];              # Print short report, next one for sub name
6422
6423     # Run through the traceback info, format it, and print it.
6424     my $s;
6425     for my $i (0 .. $#sub) {
6426
6427         # Drop out if the user has lost interest and hit control-C.
6428         last if $signal;
6429
6430         # Set the separator so arrays print nice.
6431         local $" = ', ';
6432
6433         # Grab and stringify the arguments if they are there.
6434         my $args =
6435           defined $sub[$i]{args}
6436           ? "(@{ $sub[$i]{args} })"
6437           : '';
6438
6439         # Shorten them up if $maxtrace says they're too long.
6440         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
6441           if length $args > $maxtrace;
6442
6443         # Get the file name.
6444         my $file = $sub[$i]{file};
6445
6446         # Put in a filename header if short is off.
6447         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
6448
6449         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6450         $s = $sub[$i]{'sub'};
6451         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6452
6453         # Short report uses trimmed file and sub names.
6454         if ($short) {
6455             my $sub = @_ >= 4 ? $_[3] : $s;
6456             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6457         } ## end if ($short)
6458
6459         # Non-short report includes full names.
6460         else {
6461             print $fh "$sub[$i]{context} = $s$args"
6462               . " called from $file"
6463               . " line $sub[$i]{line}\n";
6464         }
6465     } ## end for my $i (0 .. $#sub)
6466 } ## end sub print_trace
6467
6468 =head2 dump_trace(skip[,count])
6469
6470 Actually collect the traceback information available via C<caller()>. It does
6471 some filtering and cleanup of the data, but mostly it just collects it to
6472 make C<print_trace()>'s job easier.
6473
6474 C<skip> defines the number of stack frames to be skipped, working backwards
6475 from the most current. C<count> determines the total number of frames to
6476 be returned; all of them (well, the first 10^9) are returned if C<count>
6477 is omitted.
6478
6479 This routine returns a list of hashes, from most-recent to least-recent
6480 stack frame. Each has the following keys and values:
6481
6482 =over 4
6483
6484 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6485
6486 =item * C<sub> - subroutine name, or C<eval> information
6487
6488 =item * C<args> - undef, or a reference to an array of arguments
6489
6490 =item * C<file> - the file in which this item was defined (if any)
6491
6492 =item * C<line> - the line on which it was defined
6493
6494 =back
6495
6496 =cut
6497
6498 sub _dump_trace_calc_saved_single_arg
6499 {
6500     my ($nothard, $arg) = @_;
6501
6502     my $type;
6503     if ( not defined $arg ) {    # undefined parameter
6504         return "undef";
6505     }
6506
6507     elsif ( $nothard and tied $arg ) {    # tied parameter
6508         return "tied";
6509     }
6510     elsif ( $nothard and $type = ref $arg ) {    # reference
6511         return "ref($type)";
6512     }
6513     else {                                       # can be stringified
6514         local $_ =
6515         "$arg";    # Safe to stringify now - should not call f().
6516
6517         # Backslash any single-quotes or backslashes.
6518         s/([\'\\])/\\$1/g;
6519
6520         # Single-quote it unless it's a number or a colon-separated
6521         # name.
6522         s/(.*)/'$1'/s
6523         unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6524
6525         # Turn high-bit characters into meta-whatever.
6526         s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
6527
6528         # Turn control characters into ^-whatever.
6529         s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
6530
6531         return $_;
6532     }
6533 }
6534
6535 sub _dump_trace_calc_save_args {
6536     my ($nothard) = @_;
6537
6538     return [
6539         map { _dump_trace_calc_saved_single_arg($nothard, $_) } @args
6540     ];
6541 }
6542
6543 sub dump_trace {
6544
6545     # How many levels to skip.
6546     my $skip = shift;
6547
6548     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6549     # it's unlikely that we'll have more than a billion stack frames. If you
6550     # do, you've got an awfully big machine...)
6551     my $count = shift || 1e9;
6552
6553     # We increment skip because caller(1) is the first level *back* from
6554     # the current one.  Add $skip to the count of frames so we have a
6555     # simple stop criterion, counting from $skip to $count+$skip.
6556     $skip++;
6557     $count += $skip;
6558
6559     # These variables are used to capture output from caller();
6560     my ( $p, $file, $line, $sub, $h, $context );
6561
6562     my ( $e, $r, @sub, $args );
6563
6564     # XXX Okay... why'd we do that?
6565     my $nothard = not $frame & 8;
6566     local $frame = 0;
6567
6568     # Do not want to trace this.
6569     my $otrace = $trace;
6570     $trace = 0;
6571
6572     # Start out at the skip count.
6573     # If we haven't reached the number of frames requested, and caller() is
6574     # still returning something, stay in the loop. (If we pass the requested
6575     # number of stack frames, or we run out - caller() returns nothing - we
6576     # quit.
6577     # Up the stack frame index to go back one more level each time.
6578     for (
6579         my $i = $skip ;
6580         $i < $count
6581         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6582         $i++
6583     )
6584     {
6585
6586         # Go through the arguments and save them for later.
6587         my $save_args = _dump_trace_calc_save_args($nothard);
6588
6589         # If context is true, this is array (@)context.
6590         # If context is false, this is scalar ($) context.
6591         # If neither, context isn't defined. (This is apparently a 'can't
6592         # happen' trap.)
6593         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6594
6595         # if the sub has args ($h true), make an anonymous array of the
6596         # dumped args.
6597         $args = $h ? $save_args : undef;
6598
6599         # remove trailing newline-whitespace-semicolon-end of line sequence
6600         # from the eval text, if any.
6601         $e =~ s/\n\s*\;\s*\Z// if $e;
6602
6603         # Escape backslashed single-quotes again if necessary.
6604         $e =~ s/([\\\'])/\\$1/g if $e;
6605
6606         # if the require flag is true, the eval text is from a require.
6607         if ($r) {
6608             $sub = "require '$e'";
6609         }
6610
6611         # if it's false, the eval text is really from an eval.
6612         elsif ( defined $r ) {
6613             $sub = "eval '$e'";
6614         }
6615
6616         # If the sub is '(eval)', this is a block eval, meaning we don't
6617         # know what the eval'ed text actually was.
6618         elsif ( $sub eq '(eval)' ) {
6619             $sub = "eval {...}";
6620         }
6621
6622         # Stick the collected information into @sub as an anonymous hash.
6623         push(
6624             @sub,
6625             {
6626                 context => $context,
6627                 sub     => $sub,
6628                 args    => $args,
6629                 file    => $file,
6630                 line    => $line
6631             }
6632         );
6633
6634         # Stop processing frames if the user hit control-C.
6635         last if $signal;
6636     } ## end for ($i = $skip ; $i < ...
6637
6638     # Restore the trace value again.
6639     $trace = $otrace;
6640     @sub;
6641 } ## end sub dump_trace
6642
6643 =head2 C<action()>
6644
6645 C<action()> takes input provided as the argument to an add-action command,
6646 either pre- or post-, and makes sure it's a complete command. It doesn't do
6647 any fancy parsing; it just keeps reading input until it gets a string
6648 without a trailing backslash.
6649
6650 =cut
6651
6652 sub action {
6653     my $action = shift;
6654
6655     while ( $action =~ s/\\$// ) {
6656
6657         # We have a backslash on the end. Read more.
6658         $action .= gets();
6659     } ## end while ($action =~ s/\\$//)
6660
6661     # Return the assembled action.
6662     $action;
6663 } ## end sub action
6664
6665 =head2 unbalanced
6666
6667 This routine mostly just packages up a regular expression to be used
6668 to check that the thing it's being matched against has properly-matched
6669 curly braces.
6670
6671 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6672 speeds things up by only creating the qr//'ed expression once; if it's
6673 already defined, we don't try to define it again. A speed hack.
6674
6675 =cut
6676
6677 use vars qw($balanced_brace_re);
6678
6679 sub unbalanced {
6680
6681     # I hate using globals!
6682     $balanced_brace_re ||= qr{
6683         ^ \{
6684              (?:
6685                  (?> [^{}] + )              # Non-parens without backtracking
6686                 |
6687                  (??{ $balanced_brace_re }) # Group with matching parens
6688               ) *
6689           \} $
6690    }x;
6691     return $_[0] !~ m/$balanced_brace_re/;
6692 } ## end sub unbalanced
6693
6694 =head2 C<gets()>
6695
6696 C<gets()> is a primitive (very primitive) routine to read continuations.
6697 It was devised for reading continuations for actions.
6698 it just reads more input with C<readline()> and returns it.
6699
6700 =cut
6701
6702 sub gets {
6703     return DB::readline("cont: ");
6704 }
6705
6706 =head2 C<_db_system()> - handle calls to<system()> without messing up the debugger
6707
6708 The C<system()> function assumes that it can just go ahead and use STDIN and
6709 STDOUT, but under the debugger, we want it to use the debugger's input and
6710 outout filehandles.
6711
6712 C<_db_system()> socks away the program's STDIN and STDOUT, and then substitutes
6713 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6714 and then puts everything back again.
6715
6716 =cut
6717
6718 sub _db_system {
6719
6720     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6721     # some non-Unix systems can do system() but have problems with fork().
6722     open( SAVEIN,  "<&STDIN" )  || db_warn("Can't save STDIN");
6723     open( SAVEOUT, ">&STDOUT" ) || db_warn("Can't save STDOUT");
6724     open( STDIN,   "<&IN" )     || db_warn("Can't redirect STDIN");
6725     open( STDOUT,  ">&OUT" )    || db_warn("Can't redirect STDOUT");
6726
6727     # XXX: using csh or tcsh destroys sigint retvals!
6728     system(@_);
6729     open( STDIN,  "<&SAVEIN" )  || db_warn("Can't restore STDIN");
6730     open( STDOUT, ">&SAVEOUT" ) || db_warn("Can't restore STDOUT");
6731     close(SAVEIN);
6732     close(SAVEOUT);
6733
6734     # most of the $? crud was coping with broken cshisms
6735     if ( $? >> 8 ) {
6736         db_warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6737     }
6738     elsif ($?) {
6739         db_warn(
6740             "(Command died of SIG#",
6741             ( $? & 127 ),
6742             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6743             ")", "\n"
6744         );
6745     } ## end elsif ($?)
6746
6747     return $?;
6748
6749 } ## end sub system
6750
6751 *system = \&_db_system;
6752
6753 =head1 TTY MANAGEMENT
6754
6755 The subs here do some of the terminal management for multiple debuggers.
6756
6757 =head2 setterm
6758
6759 Top-level function called when we want to set up a new terminal for use
6760 by the debugger.
6761
6762 If the C<noTTY> debugger option was set, we'll either use the terminal
6763 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6764 to find one. If we're a forked debugger, we call C<resetterm> to try to
6765 get a whole new terminal if we can.
6766
6767 In either case, we set up the terminal next. If the C<ReadLine> option was
6768 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6769 the appropriate attributes. We then
6770
6771 =cut
6772
6773 use vars qw($ornaments);
6774 use vars qw($rl_attribs);
6775
6776 sub setterm {
6777
6778     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6779     local $frame = 0;
6780     local $doret = -2;
6781     require Term::ReadLine;
6782
6783     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6784     if ($notty) {
6785         if ($tty) {
6786             my ( $i, $o ) = split $tty, /,/;
6787             $o = $i unless defined $o;
6788             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6789             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6790             $IN  = \*IN;
6791             $OUT = \*OUT;
6792             _autoflush($OUT);
6793         } ## end if ($tty)
6794
6795         # We don't have a TTY - try to find one via Term::Rendezvous.
6796         else {
6797             require Term::Rendezvous;
6798
6799             # See if we have anything to pass to Term::Rendezvous.
6800             # Use $HOME/.perldbtty$$ if not.
6801             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6802
6803             # Rendezvous and get the filehandles.
6804             my $term_rv = Term::Rendezvous->new( $rv );
6805             $IN  = $term_rv->IN;
6806             $OUT = $term_rv->OUT;
6807         } ## end else [ if ($tty)
6808     } ## end if ($notty)
6809
6810     # We're a daughter debugger. Try to fork off another TTY.
6811     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6812         resetterm(2);
6813     }
6814
6815     # If we shouldn't use Term::ReadLine, don't.
6816     if ( !$rl ) {
6817         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6818     }
6819
6820     # We're using Term::ReadLine. Get all the attributes for this terminal.
6821     else {
6822         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6823
6824         $rl_attribs = $term->Attribs;
6825         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6826           if defined $rl_attribs->{basic_word_break_characters}
6827           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6828         $rl_attribs->{special_prefixes} = '$@&%';
6829         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6830         $rl_attribs->{completion_function} = \&db_complete;
6831     } ## end else [ if (!$rl)
6832
6833     # Set up the LINEINFO filehandle.
6834     $LINEINFO = $OUT     unless defined $LINEINFO;
6835     $lineinfo = $console unless defined $lineinfo;
6836
6837     $term->MinLine(2);
6838
6839     load_hist();
6840
6841     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6842         $term->SetHistory(@hist);
6843     }
6844
6845     # XXX Ornaments are turned on unconditionally, which is not
6846     # always a good thing.
6847     ornaments($ornaments) if defined $ornaments;
6848     $term_pid = $$;
6849 } ## end sub setterm
6850
6851 sub load_hist {
6852     $histfile //= option_val("HistFile", undef);
6853     return unless defined $histfile;
6854     open my $fh, "<", $histfile or return;
6855     local $/ = "\n";
6856     @hist = ();
6857     while (<$fh>) {
6858         chomp;
6859         push @hist, $_;
6860     }
6861     close $fh;
6862 }
6863
6864 sub save_hist {
6865     return unless defined $histfile;
6866     eval { require File::Path } or return;
6867     eval { require File::Basename } or return;
6868     File::Path::mkpath(File::Basename::dirname($histfile));
6869     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6870     $histsize //= option_val("HistSize",100);
6871     my @copy = grep { $_ ne '?' } @hist;
6872     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6873     for ($start .. $#copy) {
6874         print $fh "$copy[$_]\n";
6875     }
6876     close $fh or die "Could not write '$histfile': $!";
6877 }
6878
6879 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6880
6881 When the process being debugged forks, or the process invokes a command
6882 via C<system()> which starts a new debugger, we need to be able to get a new
6883 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6884 fight over the terminal, and you can never quite be sure who's going to get the
6885 input you're typing.
6886
6887 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6888 is tasked with doing all the necessary operating system mojo to get a new
6889 TTY (and probably another window) and to direct the new debugger to read and
6890 write there.
6891
6892 The debugger provides C<get_fork_TTY> functions which work for TCP
6893 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6894 supported. You are encouraged to write C<get_fork_TTY> functions which
6895 work for I<your> platform and contribute them.
6896
6897 =head3 C<socket_get_fork_TTY>
6898
6899 =cut
6900
6901 sub connect_remoteport {
6902     require IO::Socket;
6903
6904     my $socket = IO::Socket::INET->new(
6905         Timeout  => '10',
6906         PeerAddr => $remoteport,
6907         Proto    => 'tcp',
6908     );
6909     if ( ! $socket ) {
6910         die "Unable to connect to remote host: $remoteport\n";
6911     }
6912     return $socket;
6913 }
6914
6915 sub socket_get_fork_TTY {
6916     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6917
6918     # Do I need to worry about setting $term?
6919
6920     reset_IN_OUT( $IN, $OUT );
6921     return '';
6922 }
6923
6924 =head3 C<xterm_get_fork_TTY>
6925
6926 This function provides the C<get_fork_TTY> function for X11. If a
6927 program running under the debugger forks, a new <xterm> window is opened and
6928 the subsidiary debugger is directed there.
6929
6930 The C<open()> call is of particular note here. We have the new C<xterm>
6931 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6932 command (which prints the device name of the TTY we'll want to use for input
6933 and output to STDOUT, then C<sleep> for a very long time, routing this output
6934 to file number 3. This way we can simply read from the <XT> filehandle (which
6935 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6936
6937 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6938 properly set up.
6939
6940 =cut
6941
6942 sub xterm_get_fork_TTY {
6943     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6944     open XT,
6945 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6946  sleep 10000000' |];
6947
6948     # Get the output from 'tty' and clean it up a little.
6949     my $tty = <XT>;
6950     chomp $tty;
6951
6952     $pidprompt = '';    # Shown anyway in titlebar
6953
6954     # We need $term defined or we can not switch to the newly created xterm
6955     if ($tty ne '' && !defined $term) {
6956         require Term::ReadLine;
6957         if ( !$rl ) {
6958             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6959         }
6960         else {
6961             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6962         }
6963     }
6964     # There's our new TTY.
6965     return $tty;
6966 } ## end sub xterm_get_fork_TTY
6967
6968 =head3 C<os2_get_fork_TTY>
6969
6970 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6971
6972 =cut
6973
6974 # This example function resets $IN, $OUT itself
6975 my $c_pipe = 0;
6976 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6977     local $\  = '';
6978     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6979     my %opt = ( title => "Daughter Perl debugger $pids $name",
6980         ($rl ? (read_by_key => 1) : ()) );
6981     require OS2::Process;
6982     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6983       or return;
6984     $pidprompt = '';    # Shown anyway in titlebar
6985     reset_IN_OUT($in, $out);
6986     $tty = '*reset*';
6987     return '';          # Indicate that reset_IN_OUT is called
6988 } ## end sub os2_get_fork_TTY
6989
6990 =head3 C<macosx_get_fork_TTY>
6991
6992 The Mac OS X version uses AppleScript to tell Terminal.app to create
6993 a new window.
6994
6995 =cut
6996
6997 # Notes about Terminal.app's AppleScript support,
6998 # (aka things that might break in future OS versions).
6999 #
7000 # The "do script" command doesn't return a reference to the new window
7001 # it creates, but since it appears frontmost and windows are enumerated
7002 # front to back, we can use "first window" === "window 1".
7003 #
7004 # Since "do script" is implemented by supplying the argument (plus a
7005 # return character) as terminal input, there's a potential race condition
7006 # where the debugger could beat the shell to reading the command.
7007 # To prevent this, we wait for the screen to clear before proceeding.
7008 #
7009 # 10.3 and 10.4:
7010 # There's no direct accessor for the tty device name, so we fiddle
7011 # with the window title options until it says what we want.
7012 #
7013 # 10.5:
7014 # There _is_ a direct accessor for the tty device name, _and_ there's
7015 # a new possible component of the window title (the name of the settings
7016 # set).  A separate version is needed.
7017
7018 my @script_versions=
7019
7020     ([237, <<'__LEOPARD__'],
7021 tell application "Terminal"
7022     do script "clear;exec sleep 100000"
7023     tell first tab of first window
7024         copy tty to thetty
7025         set custom title to "forked perl debugger"
7026         set title displays custom title to true
7027         repeat while (length of first paragraph of (get contents)) > 0
7028             delay 0.1
7029         end repeat
7030     end tell
7031 end tell
7032 thetty
7033 __LEOPARD__
7034
7035      [100, <<'__JAGUAR_TIGER__'],
7036 tell application "Terminal"
7037     do script "clear;exec sleep 100000"
7038     tell first window
7039         set title displays shell path to false
7040         set title displays window size to false
7041         set title displays file name to false
7042         set title displays device name to true
7043         set title displays custom title to true
7044         set custom title to ""
7045         copy "/dev/" & name to thetty
7046         set custom title to "forked perl debugger"
7047         repeat while (length of first paragraph of (get contents)) > 0
7048             delay 0.1
7049         end repeat
7050     end tell
7051 end tell
7052 thetty
7053 __JAGUAR_TIGER__
7054
7055 );
7056
7057 sub macosx_get_fork_TTY
7058 {
7059     my($version,$script,$pipe,$tty);
7060
7061     return unless $version=$ENV{TERM_PROGRAM_VERSION};
7062     foreach my $entry (@script_versions) {
7063         if ($version>=$entry->[0]) {
7064             $script=$entry->[1];
7065             last;
7066         }
7067     }
7068     return unless defined($script);
7069     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
7070     $tty=readline($pipe);
7071     close($pipe);
7072     return unless defined($tty) && $tty =~ m(^/dev/);
7073     chomp $tty;
7074     return $tty;
7075 }
7076
7077 =head2 C<create_IN_OUT($flags)>
7078
7079 Create a new pair of filehandles, pointing to a new TTY. If impossible,
7080 try to diagnose why.
7081
7082 Flags are:
7083
7084 =over 4
7085
7086 =item * 1 - Don't know how to create a new TTY.
7087
7088 =item * 2 - Debugger has forked, but we can't get a new TTY.
7089
7090 =item * 4 - standard debugger startup is happening.
7091
7092 =back
7093
7094 =cut
7095
7096 use vars qw($fork_TTY);
7097
7098 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
7099
7100     # If we know how to get a new TTY, do it! $in will have
7101     # the TTY name if get_fork_TTY works.
7102     my $in = get_fork_TTY(@_) if defined &get_fork_TTY;
7103
7104     # It used to be that
7105     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
7106
7107     if ( not defined $in ) {
7108         my $why = shift;
7109
7110         # We don't know how.
7111         print_help(<<EOP) if $why == 1;
7112 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
7113 EOP
7114
7115         # Forked debugger.
7116         print_help(<<EOP) if $why == 2;
7117 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
7118   This may be an asynchronous session, so the parent debugger may be active.
7119 EOP
7120
7121         # Note that both debuggers are fighting over the same input.
7122         print_help(<<EOP) if $why != 4;
7123   Since two debuggers fight for the same TTY, input is severely entangled.
7124
7125 EOP
7126         print_help(<<EOP);
7127   I know how to switch the output to a different window in xterms, OS/2
7128   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
7129   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
7130   B<DB::get_fork_TTY()> returning this.
7131
7132   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
7133   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
7134
7135 EOP
7136     } ## end if (not defined $in)
7137     elsif ( $in ne '' ) {
7138         TTY($in);
7139     }
7140     else {
7141         $console = '';    # Indicate no need to open-from-the-console
7142     }
7143     undef $fork_TTY;
7144 } ## end sub create_IN_OUT
7145
7146 =head2 C<resetterm>
7147
7148 Handles rejiggering the prompt when we've forked off a new debugger.
7149
7150 If the new debugger happened because of a C<system()> that invoked a
7151 program under the debugger, the arrow between the old pid and the new
7152 in the prompt has I<two> dashes instead of one.
7153
7154 We take the current list of pids and add this one to the end. If there
7155 isn't any list yet, we make one up out of the initial pid associated with
7156 the terminal and our new pid, sticking an arrow (either one-dashed or
7157 two dashed) in between them.
7158
7159 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
7160 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
7161 and try to do that.
7162
7163 =cut
7164
7165 sub resetterm {    # We forked, so we need a different TTY
7166
7167     # Needs to be passed to create_IN_OUT() as well.
7168     my $in = shift;
7169
7170     # resetterm(2): got in here because of a system() starting a debugger.
7171     # resetterm(1): just forked.
7172     my $systemed = $in > 1 ? '-' : '';
7173
7174     # If there's already a list of pids, add this to the end.
7175     if ($pids) {
7176         $pids =~ s/\]/$systemed->$$]/;
7177     }
7178
7179     # No pid list. Time to make one.
7180     else {
7181         $pids = "[$term_pid->$$]";
7182     }
7183
7184     # The prompt we're going to be using for this debugger.
7185     $pidprompt = $pids;
7186
7187     # We now 0wnz this terminal.
7188     $term_pid = $$;
7189
7190     # Just return if we're not supposed to try to create a new TTY.
7191     return unless $CreateTTY & $in;
7192
7193     # Try to create a new IN/OUT pair.
7194     create_IN_OUT($in);
7195 } ## end sub resetterm
7196
7197 =head2 C<readline>
7198
7199 First, we handle stuff in the typeahead buffer. If there is any, we shift off
7200 the next line, print a message saying we got it, add it to the terminal
7201 history (if possible), and return it.
7202
7203 If there's nothing in the typeahead buffer, check the command filehandle stack.
7204 If there are any filehandles there, read from the last one, and return the line
7205 if we got one. If not, we pop the filehandle off and close it, and try the
7206 next one up the stack.
7207
7208 If we've emptied the filehandle stack, we check to see if we've got a socket
7209 open, and we read that and return it if we do. If we don't, we just call the
7210 core C<readline()> and return its value.
7211
7212 =cut
7213
7214 sub readline {
7215
7216     # Localize to prevent it from being smashed in the program being debugged.
7217     local $.;
7218
7219     # If there are stacked filehandles to read from ...
7220     # (Handle it before the typeahead, because we may call source/etc. from
7221     # the typeahead.)
7222     while (@cmdfhs) {
7223
7224         # Read from the last one in the stack.
7225         my $line = CORE::readline( $cmdfhs[-1] );
7226
7227         # If we got a line ...
7228         defined $line
7229           ? ( print $OUT ">> $line" and return $line )    # Echo and return
7230           : close pop @cmdfhs;                            # Pop and close
7231     } ## end while (@cmdfhs)
7232
7233     # Pull a line out of the typeahead if there's stuff there.
7234     if (@typeahead) {
7235
7236         # How many lines left.
7237         my $left = @typeahead;
7238
7239         # Get the next line.
7240         my $got = shift @typeahead;
7241
7242         # Print a message saying we got input from the typeahead.
7243         local $\ = '';
7244         print $OUT "auto(-$left)", shift, $got, "\n";
7245
7246         # Add it to the terminal history (if possible).
7247         $term->AddHistory($got)
7248           if length($got) > 1
7249           and defined $term->Features->{addHistory};
7250         return $got;
7251     } ## end if (@typeahead)
7252
7253     # We really need to read some input. Turn off entry/exit trace and
7254     # return value printing.
7255     local $frame = 0;
7256     local $doret = -2;
7257
7258     # Nothing on the filehandle stack. Socket?
7259     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
7260
7261         # Send anything we have to send.
7262         $OUT->write( join( '', @_ ) );
7263
7264         # Receive anything there is to receive.
7265         my $stuff = '';
7266         my $buf;
7267         my $first_time = 1;
7268
7269         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
7270         {
7271             $first_time = 0;
7272             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
7273                                             # XXX Don't know. You tell me.
7274         }
7275
7276         # What we got.
7277         return $stuff;
7278     } ## end if (ref $OUT and UNIVERSAL::isa...
7279
7280     # No socket. Just read from the terminal.
7281     else {
7282         return $term->readline(@_);
7283     }
7284 } ## end sub readline
7285
7286 =head1 OPTIONS SUPPORT ROUTINES
7287
7288 These routines handle listing and setting option values.
7289
7290 =head2 C<dump_option> - list the current value of an option setting
7291
7292 This routine uses C<option_val> to look up the value for an option.
7293 It cleans up escaped single-quotes and then displays the option and
7294 its value.
7295
7296 =cut
7297
7298 sub dump_option {
7299     my ( $opt, $val ) = @_;
7300     $val = option_val( $opt, 'N/A' );
7301     $val =~ s/([\\\'])/\\$1/g;
7302     printf $OUT "%20s = '%s'\n", $opt, $val;
7303 } ## end sub dump_option
7304
7305 sub options2remember {
7306     foreach my $k (@RememberOnROptions) {
7307         $option{$k} = option_val( $k, 'N/A' );
7308     }
7309     return %option;
7310 }
7311
7312 =head2 C<option_val> - find the current value of an option
7313
7314 This can't just be a simple hash lookup because of the indirect way that
7315 the option values are stored. Some are retrieved by calling a subroutine,
7316 some are just variables.
7317
7318 You must supply a default value to be used in case the option isn't set.
7319
7320 =cut
7321
7322 sub option_val {
7323     my ( $opt, $default ) = @_;
7324     my $val;
7325
7326     # Does this option exist, and is it a variable?
7327     # If so, retrieve the value via the value in %optionVars.
7328     if (    defined $optionVars{$opt}
7329         and defined ${ $optionVars{$opt} } )
7330     {
7331         $val = ${ $optionVars{$opt} };
7332     }
7333
7334     # Does this option exist, and it's a subroutine?
7335     # If so, call the subroutine via the ref in %optionAction
7336     # and capture the value.
7337     elsif ( defined $optionAction{$opt}
7338         and defined &{ $optionAction{$opt} } )
7339     {
7340         $val = &{ $optionAction{$opt} }();
7341     }
7342
7343     # If there's an action or variable for the supplied option,
7344     # but no value was set, use the default.
7345     elsif (defined $optionAction{$opt} and not defined $option{$opt}
7346         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
7347     {
7348         $val = $default;
7349     }
7350
7351     # Otherwise, do the simple hash lookup.
7352     else {
7353         $val = $option{$opt};
7354     }
7355
7356     # If the value isn't defined, use the default.
7357     # Then return whatever the value is.
7358     $val = $default unless defined $val;
7359     $val;
7360 } ## end sub option_val
7361
7362 =head2 C<parse_options>
7363
7364 Handles the parsing and execution of option setting/displaying commands.
7365
7366 An option entered by itself is assumed to be I<set me to 1> (the default value)
7367 if the option is a boolean one. If not, the user is prompted to enter a valid
7368 value or to query the current value (via C<option? >).
7369
7370 If C<option=value> is entered, we try to extract a quoted string from the
7371 value (if it is quoted). If it's not, we just use the whole value as-is.
7372
7373 We load any modules required to service this option, and then we set it: if
7374 it just gets stuck in a variable, we do that; if there's a subroutine to
7375 handle setting the option, we call that.
7376
7377 Finally, if we're running in interactive mode, we display the effect of the
7378 user's command back to the terminal, skipping this if we're setting things
7379 during initialization.
7380
7381 =cut
7382
7383 sub parse_options {
7384     my ($s) = @_;
7385     local $\ = '';
7386
7387     my $option;
7388
7389     # These options need a value. Don't allow them to be clobbered by accident.
7390     my %opt_needs_val = map { ( $_ => 1 ) } qw{
7391       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
7392       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
7393     };
7394
7395     while (length($s)) {
7396         my $val_defaulted;
7397
7398         # Clean off excess leading whitespace.
7399         $s =~ s/^\s+// && next;
7400
7401         # Options are always all word characters, followed by a non-word
7402         # separator.
7403         if ($s !~ s/^(\w+)(\W?)//) {
7404             print {$OUT} "Invalid option '$s'\n";
7405             last;
7406         }
7407         my ( $opt, $sep ) = ( $1, $2 );
7408
7409         # Make sure that such an option exists.
7410         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
7411           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
7412
7413         unless ($matches) {
7414             print {$OUT} "Unknown option '$opt'\n";
7415             next;
7416         }
7417         if ($matches > 1) {
7418             print {$OUT} "Ambiguous option '$opt'\n";
7419             next;
7420         }
7421         my $val;
7422
7423         # '?' as separator means query, but must have whitespace after it.
7424         if ( "?" eq $sep ) {
7425             if ($s =~ /\A\S/) {
7426                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
7427
7428                 last;
7429             }
7430
7431             #&dump_option($opt);
7432         } ## end if ("?" eq $sep)
7433
7434         # Separator is whitespace (or just a carriage return).
7435         # They're going for a default, which we assume is 1.
7436         elsif ( $sep !~ /\S/ ) {
7437             $val_defaulted = 1;
7438             $val           = "1";   #  this is an evil default; make 'em set it!
7439         }
7440
7441         # Separator is =. Trying to set a value.
7442         elsif ( $sep eq "=" ) {
7443
7444             # If quoted, extract a quoted string.
7445             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
7446                 my $quote = $1;
7447                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
7448             }
7449
7450             # Not quoted. Use the whole thing. Warn about 'option='.
7451             else {
7452                 $s =~ s/^(\S*)//;
7453                 $val = $1;
7454                 print OUT qq(Option better cleared using $opt=""\n)
7455                   unless length $val;
7456             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
7457
7458         } ## end elsif ($sep eq "=")
7459
7460         # "Quoted" with [], <>, or {}.
7461         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
7462             my ($end) =
7463               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7464             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7465               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7466             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7467         } ## end else [ if ("?" eq $sep)
7468
7469         # Exclude non-booleans from getting set to 1 by default.
7470         if ( $opt_needs_val{$option} && $val_defaulted ) {
7471             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7472             print {$OUT}
7473 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7474             next;
7475         } ## end if ($opt_needs_val{$option...
7476
7477         # Save the option value.
7478         $option{$option} = $val if defined $val;
7479
7480         # Load any module that this option requires.
7481         if ( defined($optionRequire{$option}) && defined($val) ) {
7482             eval qq{
7483             local \$frame = 0;
7484             local \$doret = -2;
7485             require '$optionRequire{$option}';
7486             1;
7487             } || die $@   # XXX: shouldn't happen
7488         }
7489
7490         # Set it.
7491         # Stick it in the proper variable if it goes in a variable.
7492         if (defined($optionVars{$option}) && defined($val)) {
7493             ${ $optionVars{$option} } = $val;
7494         }
7495
7496         # Call the appropriate sub if it gets set via sub.
7497         if (defined($optionAction{$option})
7498           && defined (&{ $optionAction{$option} })
7499           && defined ($val))
7500         {
7501           &{ $optionAction{$option} }($val);
7502         }
7503
7504         # Not initialization - echo the value we set it to.
7505         dump_option($option) if ($OUT ne \*STDERR);
7506     } ## end while (length)
7507 } ## end sub parse_options
7508
7509 =head1 RESTART SUPPORT
7510
7511 These routines are used to store (and restore) lists of items in environment
7512 variables during a restart.
7513
7514 =head2 set_list
7515
7516 Set_list packages up items to be stored in a set of environment variables
7517 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7518 the values). Values outside the standard ASCII charset are stored by encoding
7519 then as hexadecimal values.
7520
7521 =cut
7522
7523 sub set_list {
7524     my ( $stem, @list ) = @_;
7525     my $val;
7526
7527     # VAR_n: how many we have. Scalar assignment gets the number of items.
7528     $ENV{"${stem}_n"} = @list;
7529
7530     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7531     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7532     for my $i ( 0 .. $#list ) {
7533         $val = $list[$i];
7534         $val =~ s/\\/\\\\/g;
7535         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
7536         $ENV{"${stem}_$i"} = $val;
7537     } ## end for $i (0 .. $#list)
7538 } ## end sub set_list
7539
7540 =head2 get_list
7541
7542 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7543 back, and then pull VAR_0, VAR_1. etc. back out.
7544
7545 =cut
7546
7547 sub get_list {
7548     my $stem = shift;
7549     my @list;
7550     my $n = delete $ENV{"${stem}_n"};
7551     my $val;
7552     for my $i ( 0 .. $n - 1 ) {
7553         $val = delete $ENV{"${stem}_$i"};
7554         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7555         push @list, $val;
7556     }
7557     @list;
7558 } ## end sub get_list
7559
7560 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7561
7562 =head2 catch()
7563
7564 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7565 set an already-existing global scalar variable to a constant value. This
7566 avoids allocating any memory possibly in the middle of something that will
7567 get all confused if we do, particularly under I<unsafe signals>.
7568
7569 =cut
7570
7571 sub catch {
7572     $signal = 1;
7573     return;    # Put nothing on the stack - malloc/free land!
7574 }
7575
7576 =head2 C<warn()>
7577
7578 C<warn> emits a warning, by joining together its arguments and printing
7579 them, with couple of fillips.
7580
7581 If the composited message I<doesn't> end with a newline, we automatically
7582 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7583 to be set to the filehandle to be used to output warnings; it makes no
7584 assumptions about what filehandles are available.
7585
7586 =cut
7587
7588 sub _db_warn {
7589     my ($msg) = join( "", @_ );
7590     $msg .= ": $!\n" unless $msg =~ /\n$/;
7591     local $\ = '';
7592     print $OUT $msg;
7593 } ## end sub warn
7594
7595 *warn = \&_db_warn;
7596
7597 =head1 INITIALIZATION TTY SUPPORT
7598
7599 =head2 C<reset_IN_OUT>
7600
7601 This routine handles restoring the debugger's input and output filehandles
7602 after we've tried and failed to move them elsewhere.  In addition, it assigns
7603 the debugger's output filehandle to $LINEINFO if it was already open there.
7604
7605 =cut
7606
7607 sub reset_IN_OUT {
7608     my $switch_li = $LINEINFO eq $OUT;
7609
7610     # If there's a term and it's able to get a new tty, try to get one.
7611     if ( $term and $term->Features->{newTTY} ) {
7612         ( $IN, $OUT ) = ( shift, shift );
7613         $term->newTTY( $IN, $OUT );
7614     }
7615
7616     # This term can't get a new tty now. Better luck later.
7617     elsif ($term) {
7618         _db_warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7619     }
7620
7621     # Set the filehndles up as they were.
7622     else {
7623         ( $IN, $OUT ) = ( shift, shift );
7624     }
7625
7626     # Unbuffer the output filehandle.
7627     _autoflush($OUT);
7628
7629     # Point LINEINFO to the same output filehandle if it was there before.
7630     $LINEINFO = $OUT if $switch_li;
7631 } ## end sub reset_IN_OUT
7632
7633 =head1 OPTION SUPPORT ROUTINES
7634
7635 The following routines are used to process some of the more complicated
7636 debugger options.
7637
7638 =head2 C<TTY>
7639
7640 Sets the input and output filehandles to the specified files or pipes.
7641 If the terminal supports switching, we go ahead and do it. If not, and
7642 there's already a terminal in place, we save the information to take effect
7643 on restart.
7644
7645 If there's no terminal yet (for instance, during debugger initialization),
7646 we go ahead and set C<$console> and C<$tty> to the file indicated.
7647
7648 =cut
7649
7650 sub TTY {
7651
7652     if ( @_ and $term and $term->Features->{newTTY} ) {
7653
7654         # This terminal supports switching to a new TTY.
7655         # Can be a list of two files, or on string containing both names,
7656         # comma-separated.
7657         # XXX Should this perhaps be an assignment from @_?
7658         my ( $in, $out ) = shift;
7659         if ( $in =~ /,/ ) {
7660
7661             # Split list apart if supplied.
7662             ( $in, $out ) = split /,/, $in, 2;
7663         }
7664         else {
7665
7666             # Use the same file for both input and output.
7667             $out = $in;
7668         }
7669
7670         # Open file onto the debugger's filehandles, if you can.
7671         open IN,  $in     or die "cannot open '$in' for read: $!";
7672         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7673
7674         # Swap to the new filehandles.
7675         reset_IN_OUT( \*IN, \*OUT );
7676
7677         # Save the setting for later.
7678         return $tty = $in;
7679     } ## end if (@_ and $term and $term...
7680
7681     # Terminal doesn't support new TTY, or doesn't support readline.
7682     # Can't do it now, try restarting.
7683     if ($term and @_) {
7684         _db_warn("Too late to set TTY, enabled on next 'R'!\n");
7685     }
7686
7687     # Useful if done through PERLDB_OPTS:
7688     $console = $tty = shift if @_;
7689
7690     # Return whatever the TTY is.
7691     $tty or $console;
7692 } ## end sub TTY
7693
7694 =head2 C<noTTY>
7695
7696 Sets the C<$notty> global, controlling whether or not the debugger tries to
7697 get a terminal to read from. If called after a terminal is already in place,
7698 we save the value to use it if we're restarted.
7699
7700 =cut
7701
7702 sub noTTY {
7703     if ($term) {
7704         _db_warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7705     }
7706     $notty = shift if @_;
7707     $notty;
7708 } ## end sub noTTY
7709
7710 =head2 C<ReadLine>
7711
7712 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7713 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7714 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7715 the value in case a restart is done so we can change it then.
7716
7717 =cut
7718
7719 sub ReadLine {
7720     if ($term) {
7721         _db_warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7722     }
7723     $rl = shift if @_;
7724     $rl;
7725 } ## end sub ReadLine
7726
7727 =head2 C<RemotePort>
7728
7729 Sets the port that the debugger will try to connect to when starting up.
7730 If the terminal's already been set up, we can't do it, but we remember the
7731 setting in case the user does a restart.
7732
7733 =cut
7734
7735 sub RemotePort {
7736     if ($term) {
7737         _db_warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7738     }
7739     $remoteport = shift if @_;
7740     $remoteport;
7741 } ## end sub RemotePort
7742
7743 =head2 C<tkRunning>
7744
7745 Checks with the terminal to see if C<Tk> is running, and returns true or
7746 false. Returns false if the current terminal doesn't support C<readline>.
7747
7748 =cut
7749
7750 sub tkRunning {
7751     if ( ${ $term->Features }{tkRunning} ) {
7752         return $term->tkRunning(@_);
7753     }
7754     else {
7755         local $\ = '';
7756         print $OUT "tkRunning not supported by current ReadLine package.\n";
7757         0;
7758     }
7759 } ## end sub tkRunning
7760
7761 =head2 C<NonStop>
7762
7763 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7764 debugger remembers the setting in case you restart, though.
7765
7766 =cut
7767
7768 sub NonStop {
7769     if ($term) {
7770         _db_warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7771           if @_;
7772     }
7773     $runnonstop = shift if @_;
7774     $runnonstop;
7775 } ## end sub NonStop
7776
7777 sub DollarCaretP {
7778     if ($term) {
7779         _db_warn("Some flag changes could not take effect until next 'R'!\n")
7780           if @_;
7781     }
7782     $^P = parse_DollarCaretP_flags(shift) if @_;
7783     expand_DollarCaretP_flags($^P);
7784 }
7785
7786 =head2 C<pager>
7787
7788 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7789 there already.
7790
7791 =cut
7792
7793 sub pager {
7794     if (@_) {
7795         $pager = shift;
7796         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7797     }
7798     $pager;
7799 } ## end sub pager
7800
7801 =head2 C<shellBang>
7802
7803 Sets the shell escape command, and generates a printable copy to be used
7804 in the help.
7805
7806 =cut
7807
7808 sub shellBang {
7809
7810     # If we got an argument, meta-quote it, and add '\b' if it
7811     # ends in a word character.
7812     if (@_) {
7813         $sh = quotemeta shift;
7814         $sh .= "\\b" if $sh =~ /\w$/;
7815     }
7816
7817     # Generate the printable version for the help:
7818     $psh = $sh;    # copy it
7819     $psh =~ s/\\b$//;        # Take off trailing \b if any
7820     $psh =~ s/\\(.)/$1/g;    # De-escape
7821     $psh;                    # return the printable version
7822 } ## end sub shellBang
7823
7824 =head2 C<ornaments>
7825
7826 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7827 was passed as the argument. (This means you can't override the terminal's
7828 ornaments.)
7829
7830 =cut
7831
7832 sub ornaments {
7833     if ( defined $term ) {
7834
7835         # We don't want to show warning backtraces, but we do want die() ones.
7836         local $warnLevel = 0;
7837         local $dieLevel = 1;
7838
7839         # No ornaments if the terminal doesn't support them.
7840         if (not $term->Features->{ornaments}) {
7841             return '';
7842         }
7843
7844         return (eval { $term->ornaments(@_) } || '');
7845     }
7846
7847     # Use what was passed in if we can't determine it ourselves.
7848     else {
7849         $ornaments = shift;
7850
7851         return $ornaments;
7852     }
7853
7854 } ## end sub ornaments
7855
7856 =head2 C<recallCommand>
7857
7858 Sets the recall command, and builds a printable version which will appear in
7859 the help text.
7860
7861 =cut
7862
7863 sub recallCommand {
7864
7865     # If there is input, metaquote it. Add '\b' if it ends with a word
7866     # character.
7867     if (@_) {
7868         $rc = quotemeta shift;
7869         $rc .= "\\b" if $rc =~ /\w$/;
7870     }
7871
7872     # Build it into a printable version.
7873     $prc = $rc;              # Copy it
7874     $prc =~ s/\\b$//;        # Remove trailing \b
7875     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7876     return $prc;             # Return the printable version
7877 } ## end sub recallCommand
7878
7879 =head2 C<LineInfo> - where the line number information goes
7880
7881 Called with no arguments, returns the file or pipe that line info should go to.
7882
7883 Called with an argument (a file or a pipe), it opens that onto the
7884 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7885 file or pipe again to the caller.
7886
7887 =cut
7888
7889 sub LineInfo {
7890     if (@_) {
7891         $lineinfo = shift;
7892
7893         #  If this is a valid "thing to be opened for output", tack a
7894         # '>' onto the front.
7895         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7896
7897         # If this is a pipe, the stream points to a slave editor.
7898         $slave_editor = ( $stream =~ /^\|/ );
7899
7900         my $new_lineinfo_fh;
7901         # Open it up and unbuffer it.
7902         open ($new_lineinfo_fh , $stream )
7903             or _db_warn("Cannot open '$stream' for write");
7904         $LINEINFO = $new_lineinfo_fh;
7905         _autoflush($LINEINFO);
7906     }
7907
7908     return $lineinfo;
7909 } ## end sub LineInfo
7910
7911 =head1 COMMAND SUPPORT ROUTINES
7912
7913 These subroutines provide functionality for various commands.
7914
7915 =head2 C<list_modules>
7916
7917 For the C<M> command: list modules loaded and their versions.
7918 Essentially just runs through the keys in %INC, picks each package's
7919 C<$VERSION> variable, gets the file name, and formats the information
7920 for output.
7921
7922 =cut
7923
7924 sub list_modules {    # versions
7925     my %version;
7926     my $file;
7927
7928     # keys are the "as-loaded" name, values are the fully-qualified path
7929     # to the file itself.
7930     for ( keys %INC ) {
7931         $file = $_;                                # get the module name
7932         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7933         s,/,::,g;                                  # change '/' to '::'
7934         s/^perl5db$/DB/;                           # Special case: debugger
7935                                                    # moves to package DB
7936         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7937
7938         # If the package has a $VERSION package global (as all good packages
7939         # should!) decode it and save as partial message.
7940         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
7941         if ( defined $pkg_version ) {
7942             $version{$file} = "$pkg_version from ";
7943         }
7944
7945         # Finish up the message with the file the package came from.
7946         $version{$file} .= $INC{$file};
7947     } ## end for (keys %INC)
7948
7949     # Hey, dumpit() formats a hash nicely, so why not use it?
7950     dumpit( $OUT, \%version );
7951 } ## end sub list_modules
7952
7953 =head2 C<sethelp()>
7954
7955 Sets up the monster string used to format and print the help.
7956
7957 =head3 HELP MESSAGE FORMAT
7958
7959 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7960 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7961 easy to parse and portable, but which still allows the help to be a little
7962 nicer than just plain text.
7963
7964 Essentially, you define the command name (usually marked up with C<< B<> >>
7965 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7966 newline. The descriptive text can also be marked up in the same way. If you
7967 need to continue the descriptive text to another line, start that line with
7968 just tabs and then enter the marked-up text.
7969
7970 If you are modifying the help text, I<be careful>. The help-string parser is
7971 not very sophisticated, and if you don't follow these rules it will mangle the
7972 help beyond hope until you fix the string.
7973
7974 =cut
7975
7976 use vars qw($pre580_help);
7977 use vars qw($pre580_summary);
7978
7979 sub sethelp {
7980
7981     # XXX: make sure there are tabs between the command and explanation,
7982     #      or print_help will screw up your formatting if you have
7983     #      eeevil ornaments enabled.  This is an insane mess.
7984
7985     $help = "
7986 Help is currently only available for the new 5.8 command set.
7987 No help is available for the old command set.
7988 We assume you know what you're doing if you switch to it.
7989
7990 B<T>        Stack trace.
7991 B<s> [I<expr>]    Single step [in I<expr>].
7992 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7993 <B<CR>>        Repeat last B<n> or B<s> command.
7994 B<r>        Return from current subroutine.
7995 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7996         at the specified position.
7997 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7998 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7999 B<l> I<line>        List single I<line>.
8000 B<l> I<subname>    List first window of lines from subroutine.
8001 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8002 B<l>        List next window of lines.
8003 B<->        List previous window of lines.
8004 B<v> [I<line>]    View window around I<line>.
8005 B<.>        Return to the executed line.
8006 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8007         I<filename> may be either the full name of the file, or a regular
8008         expression matching the full file name:
8009         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8010         Evals (with saved bodies) are considered to be filenames:
8011         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8012         (in the order of execution).
8013 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8014 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8015 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
8016 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8017 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
8018 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8019 B<b>        Sets breakpoint on current line)
8020 B<b> [I<line>] [I<condition>]
8021         Set breakpoint; I<line> defaults to the current execution line;
8022         I<condition> breaks if it evaluates to true, defaults to '1'.
8023 B<b> I<subname> [I<condition>]
8024         Set breakpoint at first line of subroutine.
8025 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8026 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8027 B<b> B<postpone> I<subname> [I<condition>]
8028         Set breakpoint at first line of subroutine after
8029         it is compiled.
8030 B<b> B<compile> I<subname>
8031         Stop after the subroutine is compiled.
8032 B<B> [I<line>]    Delete the breakpoint for I<line>.
8033 B<B> I<*>             Delete all breakpoints.
8034 B<a> [I<line>] I<command>
8035         Set an action to be done before the I<line> is executed;
8036         I<line> defaults to the current execution line.
8037         Sequence is: check for breakpoint/watchpoint, print line
8038         if necessary, do action, prompt user if necessary,
8039         execute line.
8040 B<a>        Does nothing
8041 B<A> [I<line>]    Delete the action for I<line>.
8042 B<A> I<*>             Delete all actions.
8043 B<w> I<expr>        Add a global watch-expression.
8044 B<w>             Does nothing
8045 B<W> I<expr>        Delete a global watch-expression.
8046 B<W> I<*>             Delete all watch-expressions.
8047 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8048         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8049 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8050 B<x> I<expr>        Evals expression in list context, dumps the result.
8051 B<m> I<expr>        Evals expression in list context, prints methods callable
8052         on the first element of the result.
8053 B<m> I<class>        Prints methods callable via the given class.
8054 B<M>        Show versions of loaded modules.
8055 B<i> I<class>       Prints nested parents of given class.
8056 B<e>         Display current thread id.
8057 B<E>         Display all thread ids the current one will be identified: <n>.
8058 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8059
8060 B<<> ?            List Perl commands to run before each prompt.
8061 B<<> I<expr>        Define Perl command to run before each prompt.
8062 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8063 B<< *>                Delete the list of perl commands to run before each prompt.
8064 B<>> ?            List Perl commands to run after each prompt.
8065 B<>> I<expr>        Define Perl command to run after each prompt.
8066 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8067 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
8068 B<{> I<db_command>    Define debugger command to run before each prompt.
8069 B<{> ?            List debugger commands to run before each prompt.
8070 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8071 B<{ *>             Delete the list of debugger commands to run before each prompt.
8072 B<$prc> I<number>    Redo a previous command (default previous command).
8073 B<$prc> I<-number>    Redo number'th-to-last command.
8074 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8075         See 'B<O> I<recallCommand>' too.
8076 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8077       . (
8078         $rc eq $sh
8079         ? ""
8080         : "
8081 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8082       ) . "
8083         See 'B<O> I<shellBang>' too.
8084 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
8085 B<save> I<file>       Save current debugger session (actual history) to I<file>.
8086 B<rerun>           Rerun session to current position.
8087 B<rerun> I<n>         Rerun session to numbered command.
8088 B<rerun> I<-n>        Rerun session to number'th-to-last command.
8089 B<H> I<-number>    Display last number commands (default all).
8090 B<H> I<*>          Delete complete history.
8091 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8092 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8093 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
8094 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8095 I<command>        Execute as a perl statement in current package.
8096 B<R>        Pure-man-restart of debugger, some of debugger state
8097         and command-line options may be lost.
8098         Currently the following settings are preserved:
8099         history, breakpoints and actions, debugger B<O>ptions
8100         and the following command-line options: I<-w>, I<-I>, I<-e>.
8101
8102 B<o> [I<opt>] ...    Set boolean option to true
8103 B<o> [I<opt>B<?>]    Query options
8104 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8105         Set options.  Use quotes if spaces in value.
8106     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8107     I<pager>            program for output of \"|cmd\";
8108     I<tkRunning>            run Tk while prompting (with ReadLine);
8109     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8110     I<inhibit_exit>        Allows stepping off the end of the script.
8111     I<ImmediateStop>        Debugger should stop as early as possible.
8112     I<RemotePort>            Remote hostname:port for remote debugging
8113   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8114     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8115     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8116     I<globPrint>             whether to print contents of globs;
8117     I<DumpDBFiles>         dump arrays holding debugged files;
8118     I<DumpPackages>         dump symbol tables of packages;
8119     I<DumpReused>             dump contents of \"reused\" addresses;
8120     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8121     I<bareStringify>         Do not print the overload-stringified value;
8122   Other options include:
8123     I<PrintRet>        affects printing of return value after B<r> command,
8124     I<frame>        affects printing messages on subroutine entry/exit.
8125     I<AutoTrace>    affects printing messages on possible breaking points.
8126     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8127     I<ornaments>     affects screen appearance of the command line.
8128     I<CreateTTY>     bits control attempts to create a new TTY on events:
8129             1: on fork()    2: debugger is started inside debugger
8130             4: on startup
8131     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8132     You can put additional initialization options I<TTY>, I<noTTY>,
8133     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8134     B<R> after you set them).
8135
8136 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8137 B<h>        Summary of debugger commands.
8138 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8139 B<h h>        Long help for debugger commands
8140 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8141         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8142         Set B<\$DB::doccmd> to change viewer.
8143
8144 Type '|h h' for a paged display if this was too hard to read.
8145
8146 ";    # Fix balance of vi % matching: }}}}
8147
8148     #  note: tabs in the following section are not-so-helpful
8149     $summary = <<"END_SUM";
8150 I<List/search source lines:>               I<Control script execution:>
8151   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8152   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8153   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
8154   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8155   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8156   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
8157 I<Debugger controls:>                        B<L>           List break/watch/actions
8158   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
8159   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8160   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
8161   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8162   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
8163   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
8164   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
8165   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8166   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8167 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8168   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8169   B<p> I<expr>         Print expression (uses script's current package).
8170   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8171   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8172   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
8173   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8174   B<e>     Display thread id     B<E> Display all thread ids.
8175 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8176 END_SUM
8177
8178     # ')}}; # Fix balance of vi % matching
8179
8180     # and this is really numb...
8181     $pre580_help = "
8182 B<T>        Stack trace.
8183 B<s> [I<expr>]    Single step [in I<expr>].
8184 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8185 B<CR>>        Repeat last B<n> or B<s> command.
8186 B<r>        Return from current subroutine.
8187 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8188         at the specified position.
8189 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8190 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8191 B<l> I<line>        List single I<line>.
8192 B<l> I<subname>    List first window of lines from subroutine.
8193 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8194 B<l>        List next window of lines.
8195 B<->        List previous window of lines.
8196 B<w> [I<line>]    List window around I<line>.
8197 B<.>        Return to the executed line.
8198 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8199         I<filename> may be either the full name of the file, or a regular
8200         expression matching the full file name:
8201         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8202         Evals (with saved bodies) are considered to be filenames:
8203         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8204         (in the order of execution).
8205 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8206 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8207 B<L>        List all breakpoints and actions.
8208 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8209 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
8210 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8211 B<b> [I<line>] [I<condition>]
8212         Set breakpoint; I<line> defaults to the current execution line;
8213         I<condition> breaks if it evaluates to true, defaults to '1'.
8214 B<b> I<subname> [I<condition>]
8215         Set breakpoint at first line of subroutine.
8216 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8217 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8218 B<b> B<postpone> I<subname> [I<condition>]
8219         Set breakpoint at first line of subroutine after
8220         it is compiled.
8221 B<b> B<compile> I<subname>
8222         Stop after the subroutine is compiled.
8223 B<d> [I<line>]    Delete the breakpoint for I<line>.
8224 B<D>        Delete all breakpoints.
8225 B<a> [I<line>] I<command>
8226         Set an action to be done before the I<line> is executed;
8227         I<line> defaults to the current execution line.
8228         Sequence is: check for breakpoint/watchpoint, print line
8229         if necessary, do action, prompt user if necessary,
8230         execute line.
8231 B<a> [I<line>]    Delete the action for I<line>.
8232 B<A>        Delete all actions.
8233 B<W> I<expr>        Add a global watch-expression.
8234 B<W>        Delete all watch-expressions.
8235 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8236         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8237 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8238 B<x> I<expr>        Evals expression in list context, dumps the result.
8239 B<m> I<expr>        Evals expression in list context, prints methods callable
8240         on the first element of the result.
8241 B<m> I<class>        Prints methods callable via the given class.
8242
8243 B<<> ?            List Perl commands to run before each prompt.
8244 B<<> I<expr>        Define Perl command to run before each prompt.
8245 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8246 B<>> ?            List Perl commands to run after each prompt.
8247 B<>> I<expr>        Define Perl command to run after each prompt.
8248 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8249 B<{> I<db_command>    Define debugger command to run before each prompt.
8250 B<{> ?            List debugger commands to run before each prompt.
8251 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8252 B<$prc> I<number>    Redo a previous command (default previous command).
8253 B<$prc> I<-number>    Redo number'th-to-last command.
8254 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8255         See 'B<O> I<recallCommand>' too.
8256 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8257       . (
8258         $rc eq $sh
8259         ? ""
8260         : "
8261 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8262       ) . "
8263         See 'B<O> I<shellBang>' too.
8264 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
8265 B<H> I<-number>    Display last number commands (default all).
8266 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8267 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8268 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
8269 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8270 I<command>        Execute as a perl statement in current package.
8271 B<v>        Show versions of loaded modules.
8272 B<R>        Pure-man-restart of debugger, some of debugger state
8273         and command-line options may be lost.
8274         Currently the following settings are preserved:
8275         history, breakpoints and actions, debugger B<O>ptions
8276         and the following command-line options: I<-w>, I<-I>, I<-e>.
8277
8278 B<O> [I<opt>] ...    Set boolean option to true
8279 B<O> [I<opt>B<?>]    Query options
8280 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8281         Set options.  Use quotes if spaces in value.
8282     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8283     I<pager>            program for output of \"|cmd\";
8284     I<tkRunning>            run Tk while prompting (with ReadLine);
8285     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8286     I<inhibit_exit>        Allows stepping off the end of the script.
8287     I<ImmediateStop>        Debugger should stop as early as possible.
8288     I<RemotePort>            Remote hostname:port for remote debugging
8289   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8290     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8291     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8292     I<globPrint>             whether to print contents of globs;
8293     I<DumpDBFiles>         dump arrays holding debugged files;
8294     I<DumpPackages>         dump symbol tables of packages;
8295     I<DumpReused>             dump contents of \"reused\" addresses;
8296     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8297     I<bareStringify>         Do not print the overload-stringified value;
8298   Other options include:
8299     I<PrintRet>        affects printing of return value after B<r> command,
8300     I<frame>        affects printing messages on subroutine entry/exit.
8301     I<AutoTrace>    affects printing messages on possible breaking points.
8302     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8303     I<ornaments>     affects screen appearance of the command line.
8304     I<CreateTTY>     bits control attempts to create a new TTY on events:
8305             1: on fork()    2: debugger is started inside debugger
8306             4: on startup
8307     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8308     You can put additional initialization options I<TTY>, I<noTTY>,
8309     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8310     B<R> after you set them).
8311
8312 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8313 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8314 B<h h>        Summary of debugger commands.
8315 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8316         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8317         Set B<\$DB::doccmd> to change viewer.
8318
8319 Type '|h' for a paged display if this was too hard to read.
8320
8321 ";    # Fix balance of vi % matching: }}}}
8322
8323     #  note: tabs in the following section are not-so-helpful
8324     $pre580_summary = <<"END_SUM";
8325 I<List/search source lines:>               I<Control script execution:>
8326   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8327   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8328   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
8329   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8330   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8331   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
8332 I<Debugger controls:>                        B<L>           List break/watch/actions
8333   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
8334   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8335   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
8336   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8337   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
8338   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
8339   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8340   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8341 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8342   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8343   B<p> I<expr>         Print expression (uses script's current package).
8344   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8345   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8346   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
8347   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8348 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8349 END_SUM
8350
8351     # ')}}; # Fix balance of vi % matching
8352
8353 } ## end sub sethelp
8354
8355 =head2 C<print_help()>
8356
8357 Most of what C<print_help> does is just text formatting. It finds the
8358 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
8359 terminal control characters to simulate them (courtesy of
8360 C<Term::ReadLine::TermCap>).
8361
8362 =cut
8363
8364 sub print_help {
8365     my $help_str = shift;
8366
8367     # Restore proper alignment destroyed by eeevil I<> and B<>
8368     # ornaments: A pox on both their houses!
8369     #
8370     # A help command will have everything up to and including
8371     # the first tab sequence padded into a field 16 (or if indented 20)
8372     # wide.  If it's wider than that, an extra space will be added.
8373     $help_str =~ s{
8374         ^                       # only matters at start of line
8375           ( \040{4} | \t )*     # some subcommands are indented
8376           ( < ?                 # so <CR> works
8377             [BI] < [^\t\n] + )  # find an eeevil ornament
8378           ( \t+ )               # original separation, discarded
8379           ( .* )                # this will now start (no earlier) than
8380                                 # column 16
8381     } {
8382         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
8383         my $clean = $command;
8384         $clean =~ s/[BI]<([^>]*)>/$1/g;
8385
8386         # replace with this whole string:
8387         ($leadwhite ? " " x 4 : "")
8388       . $command
8389       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
8390       . $text;
8391
8392     }mgex;
8393
8394     $help_str =~ s{                          # handle bold ornaments
8395        B < ( [^>] + | > ) >
8396     } {
8397           $Term::ReadLine::TermCap::rl_term_set[2]
8398         . $1
8399         . $Term::ReadLine::TermCap::rl_term_set[3]
8400     }gex;
8401
8402     $help_str =~ s{                         # handle italic ornaments
8403        I < ( [^>] + | > ) >
8404     } {
8405           $Term::ReadLine::TermCap::rl_term_set[0]
8406         . $1
8407         . $Term::ReadLine::TermCap::rl_term_set[1]
8408     }gex;
8409
8410     local $\ = '';
8411     print {$OUT} $help_str;
8412
8413     return;
8414 } ## end sub print_help
8415
8416 =head2 C<fix_less>
8417
8418 This routine does a lot of gyrations to be sure that the pager is C<less>.
8419 It checks for C<less> masquerading as C<more> and records the result in
8420 C<$fixed_less> so we don't have to go through doing the stats again.
8421
8422 =cut
8423
8424 use vars qw($fixed_less);
8425
8426 sub _calc_is_less {
8427     if ($pager =~ /\bless\b/)
8428     {
8429         return 1;
8430     }
8431     elsif ($pager =~ /\bmore\b/)
8432     {
8433         # Nope, set to more. See what's out there.
8434         my @st_more = stat('/usr/bin/more');
8435         my @st_less = stat('/usr/bin/less');
8436
8437         # is it really less, pretending to be more?
8438         return (
8439             @st_more
8440             && @st_less
8441             && $st_more[0] == $st_less[0]
8442             && $st_more[1] == $st_less[1]
8443         );
8444     }
8445     else {
8446         return;
8447     }
8448 }
8449
8450 sub fix_less {
8451
8452     # We already know if this is set.
8453     return if $fixed_less;
8454
8455     # changes environment!
8456     # 'r' added so we don't do (slow) stats again.
8457     $fixed_less = 1 if _calc_is_less();
8458
8459     return;
8460 } ## end sub fix_less
8461
8462 =head1 DIE AND WARN MANAGEMENT
8463
8464 =head2 C<diesignal>
8465
8466 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
8467 to debug a debugger problem.
8468
8469 It does its best to report the error that occurred, and then forces the
8470 program, debugger, and everything to die.
8471
8472 =cut
8473
8474 sub diesignal {
8475
8476     # No entry/exit messages.
8477     local $frame = 0;
8478
8479     # No return value prints.
8480     local $doret = -2;
8481
8482     # set the abort signal handling to the default (just terminate).
8483     $SIG{'ABRT'} = 'DEFAULT';
8484
8485     # If we enter the signal handler recursively, kill myself with an
8486     # abort signal (so we just terminate).
8487     kill 'ABRT', $$ if $panic++;
8488
8489     # If we can show detailed info, do so.
8490     if ( defined &Carp::longmess ) {
8491
8492         # Don't recursively enter the warn handler, since we're carping.
8493         local $SIG{__WARN__} = '';
8494
8495         # Skip two levels before reporting traceback: we're skipping
8496         # mydie and confess.
8497         local $Carp::CarpLevel = 2;    # mydie + confess
8498
8499         # Tell us all about it.
8500         _db_warn( Carp::longmess("Signal @_") );
8501     }
8502
8503     # No Carp. Tell us about the signal as best we can.
8504     else {
8505         local $\ = '';
8506         print $DB::OUT "Got signal @_\n";
8507     }
8508
8509     # Drop dead.
8510     kill 'ABRT', $$;
8511 } ## end sub diesignal
8512
8513 =head2 C<dbwarn>
8514
8515 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8516 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8517
8518 =cut
8519
8520 sub dbwarn {
8521
8522     # No entry/exit trace.
8523     local $frame = 0;
8524
8525     # No return value printing.
8526     local $doret = -2;
8527
8528     # Turn off warn and die handling to prevent recursive entries to this
8529     # routine.
8530     local $SIG{__WARN__} = '';
8531     local $SIG{__DIE__}  = '';
8532
8533     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8534     # done yet), we may not be able to do a require.
8535     eval { require Carp }
8536       if defined $^S;    # If error/warning during compilation,
8537                          # require may be broken.
8538
8539     # Use the core warn() unless Carp loaded OK.
8540     CORE::warn( @_,
8541         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8542       return
8543       unless defined &Carp::longmess;
8544
8545     # Save the current values of $single and $trace, and then turn them off.
8546     my ( $mysingle, $mytrace ) = ( $single, $trace );
8547     $single = 0;
8548     $trace  = 0;
8549
8550     # We can call Carp::longmess without its being "debugged" (which we
8551     # don't want - we just want to use it!). Capture this for later.
8552     my $mess = Carp::longmess(@_);
8553
8554     # Restore $single and $trace to their original values.
8555     ( $single, $trace ) = ( $mysingle, $mytrace );
8556
8557     # Use the debugger's own special way of printing warnings to print
8558     # the stack trace message.
8559     _db_warn($mess);
8560 } ## end sub dbwarn
8561
8562 =head2 C<dbdie>
8563
8564 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8565 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8566 single stepping and tracing during the call to C<Carp::longmess> to avoid
8567 debugging it - we just want to use it.
8568
8569 If C<dieLevel> is zero, we let the program being debugged handle the
8570 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8571 the debugger takes over all exception handling, printing a backtrace and
8572 displaying the exception via its C<dbwarn()> routine.
8573
8574 =cut
8575
8576 sub dbdie {
8577     local $frame         = 0;
8578     local $doret         = -2;
8579     local $SIG{__DIE__}  = '';
8580     local $SIG{__WARN__} = '';
8581     if ( $dieLevel > 2 ) {
8582         local $SIG{__WARN__} = \&dbwarn;
8583         _db_warn(@_);    # Yell no matter what
8584         return;
8585     }
8586     if ( $dieLevel < 2 ) {
8587         die @_ if $^S;    # in eval propagate
8588     }
8589
8590     # The code used to check $^S to see if compilation of the current thing
8591     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8592     eval { require Carp };
8593
8594     die( @_,
8595         "\nCannot print stack trace, load with -MCarp option to see stack" )
8596       unless defined &Carp::longmess;
8597
8598     # We do not want to debug this chunk (automatic disabling works
8599     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8600     # get the stack trace from Carp::longmess (if possible), restore $signal
8601     # and $trace, and then die with the stack trace.
8602     my ( $mysingle, $mytrace ) = ( $single, $trace );
8603     $single = 0;
8604     $trace  = 0;
8605     my $mess = "@_";
8606     {
8607
8608         package Carp;    # Do not include us in the list
8609         eval { $mess = Carp::longmess(@_); };
8610     }
8611     ( $single, $trace ) = ( $mysingle, $mytrace );
8612     die $mess;
8613 } ## end sub dbdie
8614
8615 =head2 C<warnlevel()>
8616
8617 Set the C<$DB::warnLevel> variable that stores the value of the
8618 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8619 results in the debugger taking over all warning handlers. Setting
8620 C<warnLevel> to zero leaves any warning handlers set up by the program
8621 being debugged in place.
8622
8623 =cut
8624
8625 sub warnLevel {
8626     if (@_) {
8627         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8628         $warnLevel = shift;
8629         if ($warnLevel) {
8630             $SIG{__WARN__} = \&DB::dbwarn;
8631         }
8632         elsif ($prevwarn) {
8633             $SIG{__WARN__} = $prevwarn;
8634         } else {
8635             undef $SIG{__WARN__};
8636         }
8637     } ## end if (@_)
8638     $warnLevel;
8639 } ## end sub warnLevel
8640
8641 =head2 C<dielevel>
8642
8643 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8644 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8645 zero lets you use your own C<die()> handler.
8646
8647 =cut
8648
8649 sub dieLevel {
8650     local $\ = '';
8651     if (@_) {
8652         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8653         $dieLevel = shift;
8654         if ($dieLevel) {
8655
8656             # Always set it to dbdie() for non-zero values.
8657             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8658
8659             # No longer exists, so don't try  to use it.
8660             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8661
8662             # If we've finished initialization, mention that stack dumps
8663             # are enabled, If dieLevel is 1, we won't stack dump if we die
8664             # in an eval().
8665             print $OUT "Stack dump during die enabled",
8666               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8667               if $I_m_init;
8668
8669             # XXX This is probably obsolete, given that diehard() is gone.
8670             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8671         } ## end if ($dieLevel)
8672
8673         # Put the old one back if there was one.
8674         elsif ($prevdie) {
8675             $SIG{__DIE__} = $prevdie;
8676             print $OUT "Default die handler restored.\n";
8677         } else {
8678             undef $SIG{__DIE__};
8679             print $OUT "Die handler removed.\n";
8680         }
8681     } ## end if (@_)
8682     $dieLevel;
8683 } ## end sub dieLevel
8684
8685 =head2 C<signalLevel>
8686
8687 Number three in a series: set C<signalLevel> to zero to keep your own
8688 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8689 takes over and handles them with C<DB::diesignal()>.
8690
8691 =cut
8692
8693 sub signalLevel {
8694     if (@_) {
8695         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8696         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8697         $signalLevel = shift;
8698         if ($signalLevel) {
8699             $SIG{SEGV} = \&DB::diesignal;
8700             $SIG{BUS}  = \&DB::diesignal;
8701         }
8702         else {
8703             $SIG{SEGV} = $prevsegv;
8704             $SIG{BUS}  = $prevbus;
8705         }
8706     } ## end if (@_)
8707     $signalLevel;
8708 } ## end sub signalLevel
8709
8710 =head1 SUBROUTINE DECODING SUPPORT
8711
8712 These subroutines are used during the C<x> and C<X> commands to try to
8713 produce as much information as possible about a code reference. They use
8714 L<Devel::Peek> to try to find the glob in which this code reference lives
8715 (if it does) - this allows us to actually code references which correspond
8716 to named subroutines (including those aliased via glob assignment).
8717
8718 =head2 C<CvGV_name()>
8719
8720 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8721 via that routine. If this fails, return the reference again (when the
8722 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8723
8724 =cut
8725
8726 sub CvGV_name {
8727     my $in   = shift;
8728     my $name = CvGV_name_or_bust($in);
8729     defined $name ? $name : $in;
8730 }
8731
8732 =head2 C<CvGV_name_or_bust> I<coderef>
8733
8734 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8735 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8736 find a glob for this ref.
8737
8738 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8739
8740 =cut
8741
8742 use vars qw($skipCvGV);
8743
8744 sub CvGV_name_or_bust {
8745     my $in = shift;
8746     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8747     return unless ref $in;
8748     $in = \&$in;            # Hard reference...
8749     eval { require Devel::Peek; 1 } or return;
8750     my $gv = Devel::Peek::CvGV($in) or return;
8751     *$gv{PACKAGE} . '::' . *$gv{NAME};
8752 } ## end sub CvGV_name_or_bust
8753
8754 =head2 C<find_sub>
8755
8756 A utility routine used in various places; finds the file where a subroutine
8757 was defined, and returns that filename and a line-number range.
8758
8759 Tries to use C<@sub> first; if it can't find it there, it tries building a
8760 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8761 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8762 this way, it brute-force searches C<%sub>, checking for identical references.
8763
8764 =cut
8765
8766 sub _find_sub_helper {
8767     my $subr = shift;
8768
8769     return unless defined &$subr;
8770     my $name = CvGV_name_or_bust($subr);
8771     my $data;
8772     $data = $sub{$name} if defined $name;
8773     return $data if defined $data;
8774
8775     # Old stupid way...
8776     $subr = \&$subr;    # Hard reference
8777     my $s;
8778     for ( keys %sub ) {
8779         $s = $_, last if $subr eq \&$_;
8780     }
8781     if ($s)
8782     {
8783         return $sub{$s};
8784     }
8785     else
8786     {
8787         return;
8788     }
8789
8790 }
8791
8792 sub find_sub {
8793     my $subr = shift;
8794     return ( $sub{$subr} || _find_sub_helper($subr) );
8795 } ## end sub find_sub
8796
8797 =head2 C<methods>
8798
8799 A subroutine that uses the utility function C<methods_via> to find all the
8800 methods in the class corresponding to the current reference and in
8801 C<UNIVERSAL>.
8802
8803 =cut
8804
8805 use vars qw(%seen);
8806
8807 sub methods {
8808
8809     # Figure out the class - either this is the class or it's a reference
8810     # to something blessed into that class.
8811     my $class = shift;
8812     $class = ref $class if ref $class;
8813
8814     local %seen;
8815
8816     # Show the methods that this class has.
8817     methods_via( $class, '', 1 );
8818
8819     # Show the methods that UNIVERSAL has.
8820     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8821 } ## end sub methods
8822
8823 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8824
8825 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8826 all the parent class methods. C<$class> is the name of the next class to
8827 try; C<$prefix> is the message prefix, which gets built up as we go up the
8828 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8829 higher in the C<@ISA> tree, 0 if we should stop.
8830
8831 =cut
8832
8833 sub methods_via {
8834
8835     # If we've processed this class already, just quit.
8836     my $class = shift;
8837     return if $seen{$class}++;
8838
8839     # This is a package that is contributing the methods we're about to print.
8840     my $prefix  = shift;
8841     my $prepend = $prefix ? "via $prefix: " : '';
8842     my @to_print;
8843
8844     # Extract from all the symbols in this class.
8845     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8846     while (my ($name, $glob) = each %$class_ref) {
8847         # references directly in the symbol table are Proxy Constant
8848         # Subroutines, and are by their very nature defined
8849         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8850         # to a subroutine reference, which can be tested by defined.
8851         # $glob might also be the value -1  (from sub foo;)
8852         # or (say) '$$' (from sub foo ($$);)
8853         # \$glob will be SCALAR in both cases.
8854         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8855             && !$seen{$name}++) {
8856             push @to_print, "$prepend$name\n";
8857         }
8858     }
8859
8860     {
8861         local $\ = '';
8862         local $, = '';
8863         print $DB::OUT $_ foreach sort @to_print;
8864     }
8865
8866     # If the $crawl_upward argument is false, just quit here.
8867     return unless shift;
8868
8869     # $crawl_upward true: keep going up the tree.
8870     # Find all the classes this one is a subclass of.
8871     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8872     for my $name ( @$class_ISA_ref ) {
8873
8874         # Set up the new prefix.
8875         $prepend = $prefix ? $prefix . " -> $name" : $name;
8876
8877         # Crawl up the tree and keep trying to crawl up.
8878         methods_via( $name, $prepend, 1 );
8879     }
8880 } ## end sub methods_via
8881
8882 =head2 C<setman> - figure out which command to use to show documentation
8883
8884 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8885
8886 =cut
8887
8888 sub setman {
8889     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8890       ? "man"         # O Happy Day!
8891       : "perldoc";    # Alas, poor unfortunates
8892 } ## end sub setman
8893
8894 =head2 C<runman> - run the appropriate command to show documentation
8895
8896 Accepts a man page name; runs the appropriate command to display it (set up
8897 during debugger initialization). Uses C<_db_system()> to avoid mucking up the
8898 program's STDIN and STDOUT.
8899
8900 =cut
8901
8902 sub runman {
8903     my $page = shift;
8904     unless ($page) {
8905         _db_system("$doccmd $doccmd");
8906         return;
8907     }
8908
8909     # this way user can override, like with $doccmd="man -Mwhatever"
8910     # or even just "man " to disable the path check.
8911     if ( $doccmd ne 'man' ) {
8912         _db_system("$doccmd $page");
8913         return;
8914     }
8915
8916     $page = 'perl' if lc($page) eq 'help';
8917
8918     require Config;
8919     my $man1dir = $Config::Config{man1direxp};
8920     my $man3dir = $Config::Config{man3direxp};
8921     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8922     my $manpath = '';
8923     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8924     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8925     chop $manpath if $manpath;
8926
8927     # harmless if missing, I figure
8928     local $ENV{MANPATH} = $manpath if $manpath;
8929     my $nopathopt = $^O =~ /dunno what goes here/;
8930     if (
8931         CORE::system(
8932             $doccmd,
8933
8934             # I just *know* there are men without -M
8935             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8936             split ' ', $page
8937         )
8938       )
8939     {
8940         unless ( $page =~ /^perl\w/ ) {
8941             # Previously the debugger contained a list which it slurped in,
8942             # listing the known "perl" manpages. However, it was out of date,
8943             # with errors both of omission and inclusion. This approach is
8944             # considerably less complex. The failure mode on a butchered
8945             # install is simply that the user has to run man or perldoc
8946             # "manually" with the full manpage name.
8947
8948             # There is a list of $^O values in installperl to determine whether
8949             # the directory is 'pods' or 'pod'. However, we can avoid tight
8950             # coupling to that by simply checking the "non-standard" 'pods'
8951             # first.
8952             my $pods = "$Config::Config{privlibexp}/pods";
8953             $pods = "$Config::Config{privlibexp}/pod"
8954                 unless -d $pods;
8955             if (-f "$pods/perl$page.pod") {
8956                 CORE::system( $doccmd,
8957                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8958                     "perl$page" );
8959             }
8960         }
8961     } ## end if (CORE::system($doccmd...
8962 } ## end sub runman
8963
8964 #use Carp;                          # This did break, left for debugging
8965
8966 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8967
8968 Because of the way the debugger interface to the Perl core is designed, any
8969 debugger package globals that C<DB::sub()> requires have to be defined before
8970 any subroutines can be called. These are defined in the second C<BEGIN> block.
8971
8972 This block sets things up so that (basically) the world is sane
8973 before the debugger starts executing. We set up various variables that the
8974 debugger has to have set up before the Perl core starts running:
8975
8976 =over 4
8977
8978 =item *
8979
8980 The debugger's own filehandles (copies of STD and STDOUT for now).
8981
8982 =item *
8983
8984 Characters for shell escapes, the recall command, and the history command.
8985
8986 =item *
8987
8988 The maximum recursion depth.
8989
8990 =item *
8991
8992 The size of a C<w> command's window.
8993
8994 =item *
8995
8996 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8997
8998 =item *
8999
9000 The fact that we're not in a sub at all right now.
9001
9002 =item *
9003
9004 The default SIGINT handler for the debugger.
9005
9006 =item *
9007
9008 The appropriate value of the flag in C<$^D> that says the debugger is running
9009
9010 =item *
9011
9012 The current debugger recursion level
9013
9014 =item *
9015
9016 The list of postponed items and the C<$single> stack (XXX define this)
9017
9018 =item *
9019
9020 That we want no return values and no subroutine entry/exit trace.
9021
9022 =back
9023
9024 =cut
9025
9026 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
9027
9028 use vars qw($db_stop);
9029
9030 BEGIN {    # This does not compile, alas. (XXX eh?)
9031     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
9032     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
9033
9034     # Define characters used by command parsing.
9035     $sh       = '!';      # Shell escape (does not work)
9036     $rc       = ',';      # Recall command (does not work)
9037     @hist     = ('?');    # Show history (does not work)
9038     @truehist = ();       # Can be saved for replay (per session)
9039
9040     # This defines the point at which you get the 'deep recursion'
9041     # warning. It MUST be defined or the debugger will not load.
9042     $deep = 1000;
9043
9044     # Number of lines around the current one that are shown in the
9045     # 'w' command.
9046     $window = 10;
9047
9048     # How much before-the-current-line context the 'v' command should
9049     # use in calculating the start of the window it will display.
9050     $preview = 3;
9051
9052     # We're not in any sub yet, but we need this to be a defined value.
9053     $sub = '';
9054
9055     # Set up the debugger's interrupt handler. It simply sets a flag
9056     # ($signal) that DB::DB() will check before each command is executed.
9057     $SIG{INT} = \&DB::catch;
9058
9059     # The following lines supposedly, if uncommented, allow the debugger to
9060     # debug itself. Perhaps we can try that someday.
9061     # This may be enabled to debug debugger:
9062     #$warnLevel = 1 unless defined $warnLevel;
9063     #$dieLevel = 1 unless defined $dieLevel;
9064     #$signalLevel = 1 unless defined $signalLevel;
9065
9066     # This is the flag that says "a debugger is running, please call
9067     # DB::DB and DB::sub". We will turn it on forcibly before we try to
9068     # execute anything in the user's context, because we always want to
9069     # get control back.
9070     $db_stop = 0;          # Compiler warning ...
9071     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
9072
9073     # This variable records how many levels we're nested in debugging. Used
9074     # Used in the debugger prompt, and in determining whether it's all over or
9075     # not.
9076     $level = 0;            # Level of recursive debugging
9077
9078     # "Triggers bug (?) in perl if we postpone this until runtime."
9079     # XXX No details on this yet, or whether we should fix the bug instead
9080     # of work around it. Stay tuned.
9081     @stack = (0);
9082
9083     # Used to track the current stack depth using the auto-stacked-variable
9084     # trick.
9085     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
9086
9087     # Don't print return values on exiting a subroutine.
9088     $doret = -2;
9089
9090     # No extry/exit tracing.
9091     $frame = 0;
9092
9093 } ## end BEGIN
9094
9095 BEGIN { $^W = $ini_warn; }    # Switch warnings back
9096
9097 =head1 READLINE SUPPORT - COMPLETION FUNCTION
9098
9099 =head2 db_complete
9100
9101 C<readline> support - adds command completion to basic C<readline>.
9102
9103 Returns a list of possible completions to C<readline> when invoked. C<readline>
9104 will print the longest common substring following the text already entered.
9105
9106 If there is only a single possible completion, C<readline> will use it in full.
9107
9108 This code uses C<map> and C<grep> heavily to create lists of possible
9109 completion. Think LISP in this section.
9110
9111 =cut
9112
9113 sub db_complete {
9114
9115     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
9116     # $text is the text to be completed.
9117     # $line is the incoming line typed by the user.
9118     # $start is the start of the text to be completed in the incoming line.
9119     my ( $text, $line, $start ) = @_;
9120
9121     # Save the initial text.
9122     # The search pattern is current package, ::, extract the next qualifier
9123     # Prefix and pack are set to undef.
9124     my ( $itext, $search, $prefix, $pack ) =
9125       ( $text, "^\Q${package}::\E([^:]+)\$" );
9126
9127 =head3 C<b postpone|compile>
9128
9129 =over 4
9130
9131 =item *
9132
9133 Find all the subroutines that might match in this package
9134
9135 =item *
9136
9137 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
9138
9139 =item *
9140
9141 Include all the rest of the subs that are known
9142
9143 =item *
9144
9145 C<grep> out the ones that match the text we have so far
9146
9147 =item *
9148
9149 Return this as the list of possible completions
9150
9151 =back
9152
9153 =cut
9154
9155     return sort grep /^\Q$text/, ( keys %sub ),
9156       qw(postpone load compile),    # subroutines
9157       ( map { /$search/ ? ($1) : () } keys %sub )
9158       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
9159
9160 =head3 C<b load>
9161
9162 Get all the possible files from C<@INC> as it currently stands and
9163 select the ones that match the text so far.
9164
9165 =cut
9166
9167     return sort grep /^\Q$text/, values %INC    # files
9168       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
9169
9170 =head3  C<V> (list variable) and C<m> (list modules)
9171
9172 There are two entry points for these commands:
9173
9174 =head4 Unqualified package names
9175
9176 Get the top-level packages and grab everything that matches the text
9177 so far. For each match, recursively complete the partial packages to
9178 get all possible matching packages. Return this sorted list.
9179
9180 =cut
9181
9182     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9183       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
9184       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
9185
9186 =head4 Qualified package names
9187
9188 Take a partially-qualified package and find all subpackages for it
9189 by getting all the subpackages for the package so far, matching all
9190 the subpackages against the text, and discarding all of them which
9191 start with 'main::'. Return this list.
9192
9193 =cut
9194
9195     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9196       grep !/^main::/, grep /^\Q$text/,
9197       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
9198       do { no strict 'refs'; keys %{ $prefix . '::' } }
9199       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
9200       and $text =~ /^(.*[^:])::?(\w*)$/
9201       and $prefix = $1;
9202
9203 =head3 C<f> - switch files
9204
9205 Here, we want to get a fully-qualified filename for the C<f> command.
9206 Possibilities are:
9207
9208 =over 4
9209
9210 =item 1. The original source file itself
9211
9212 =item 2. A file from C<@INC>
9213
9214 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
9215
9216 =back
9217
9218 =cut
9219
9220     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
9221            # We might possibly want to switch to an eval (which has a "filename"
9222            # like '(eval 9)'), so we may need to clean up the completion text
9223            # before proceeding.
9224         $prefix = length($1) - length($text);
9225         $text   = $1;
9226
9227 =pod
9228
9229 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
9230 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
9231 out of C<%main::>, add the initial source file, and extract the ones that
9232 match the completion text so far.
9233
9234 =cut
9235
9236         return sort
9237           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
9238           $0;
9239     } ## end if ($line =~ /^\|*f\s+(.*)/)
9240
9241 =head3 Subroutine name completion
9242
9243 We look through all of the defined subs (the keys of C<%sub>) and
9244 return both all the possible matches to the subroutine name plus
9245 all the matches qualified to the current package.
9246
9247 =cut
9248
9249     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
9250         $text = substr $text, 1;
9251         $prefix = "&";
9252         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
9253           (
9254             map { /$search/ ? ($1) : () }
9255               keys %sub
9256           );
9257     } ## end if ((substr $text, 0, ...
9258
9259 =head3  Scalar, array, and hash completion: partially qualified package
9260
9261 Much like the above, except we have to do a little more cleanup:
9262
9263 =cut
9264
9265     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
9266
9267 =pod
9268
9269 =over 4
9270
9271 =item *
9272
9273 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
9274
9275 =cut
9276
9277         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
9278
9279 =pod
9280
9281 =item *
9282
9283 Figure out the prefix vs. what needs completing.
9284
9285 =cut
9286
9287         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
9288         $text   = $2;
9289
9290 =pod
9291
9292 =item *
9293
9294 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
9295
9296 =cut
9297
9298         my @out = do {
9299             no strict 'refs';
9300             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
9301             keys %$pack;
9302         };
9303
9304 =pod
9305
9306 =item *
9307
9308 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
9309
9310 =cut
9311
9312         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9313             return db_complete( $out[0], $line, $start );
9314         }
9315
9316         # Return the list of possibles.
9317         return sort @out;
9318
9319     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
9320
9321 =pod
9322
9323 =back
9324
9325 =head3 Symbol completion: current package or package C<main>.
9326
9327 =cut
9328
9329     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
9330 =pod
9331
9332 =over 4
9333
9334 =item *
9335
9336 If it's C<main>, delete main to just get C<::> leading.
9337
9338 =cut
9339
9340         $pack = ( $package eq 'main' ? '' : $package ) . '::';
9341
9342 =pod
9343
9344 =item *
9345
9346 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9347
9348 =cut
9349
9350         $prefix = substr $text, 0, 1;
9351         $text   = substr $text, 1;
9352
9353         my @out;
9354
9355 =pod
9356
9357 =item *
9358
9359 We look for the lexical scope above DB::DB and auto-complete lexical variables
9360 if PadWalker could be loaded.
9361
9362 =cut
9363
9364         if (not $text =~ /::/ and eval { require PadWalker } ) {
9365             my $level = 1;
9366             while (1) {
9367                 my @info = caller($level);
9368                 $level++;
9369                 $level = -1, last
9370                   if not @info;
9371                 last if $info[3] eq 'DB::DB';
9372             }
9373             if ($level > 0) {
9374                 my $lexicals = PadWalker::peek_my($level);
9375                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9376             }
9377         }
9378
9379 =pod
9380
9381 =item *
9382
9383 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9384
9385 =cut
9386
9387         push @out, map "$prefix$_", grep /^\Q$text/,
9388           ( grep /^_?[a-zA-Z]/, keys %$pack ),
9389           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9390
9391 =item *
9392
9393 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9394
9395 =back
9396
9397 =cut
9398
9399         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9400             return db_complete( $out[0], $line, $start );
9401         }
9402
9403         # Return the list of possibles.
9404         return sort @out;
9405     } ## end if ($text =~ /^[\$@%]/)
9406
9407 =head3 Options
9408
9409 We use C<option_val()> to look up the current value of the option. If there's
9410 only a single value, we complete the command in such a way that it is a
9411 complete command for setting the option in question. If there are multiple
9412 possible values, we generate a command consisting of the option plus a trailing
9413 question mark, which, if executed, will list the current value of the option.
9414
9415 =cut
9416
9417     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9418     {    # Options after space
9419            # We look for the text to be matched in the list of possible options,
9420            # and fetch the current value.
9421         my @out = grep /^\Q$text/, @options;
9422         my $val = option_val( $out[0], undef );
9423
9424         # Set up a 'query option's value' command.
9425         my $out = '? ';
9426         if ( not defined $val or $val =~ /[\n\r]/ ) {
9427
9428             # There's really nothing else we can do.
9429         }
9430
9431         # We have a value. Create a proper option-setting command.
9432         elsif ( $val =~ /\s/ ) {
9433
9434             # XXX This may be an extraneous variable.
9435             my $found;
9436
9437             # We'll want to quote the string (because of the embedded
9438             # whtespace), but we want to make sure we don't end up with
9439             # mismatched quote characters. We try several possibilities.
9440             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9441
9442                 # If we didn't find this quote character in the value,
9443                 # quote it using this quote character.
9444                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9445             }
9446         } ## end elsif ($val =~ /\s/)
9447
9448         # Don't need any quotes.
9449         else {
9450             $out = "=$val ";
9451         }
9452
9453         # If there were multiple possible values, return '? ', which
9454         # makes the command into a query command. If there was just one,
9455         # have readline append that.
9456         $rl_attribs->{completer_terminator_character} =
9457           ( @out == 1 ? $out : '? ' );
9458
9459         # Return list of possibilities.
9460         return sort @out;
9461     } ## end if ((substr $line, 0, ...
9462
9463 =head3 Filename completion
9464
9465 For entering filenames. We simply call C<readline>'s C<filename_list()>
9466 method with the completion text to get the possible completions.
9467
9468 =cut
9469
9470     return $term->filename_list($text);    # filenames
9471
9472 } ## end sub db_complete
9473
9474 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9475
9476 Functions that possibly ought to be somewhere else.
9477
9478 =head2 end_report
9479
9480 Say we're done.
9481
9482 =cut
9483
9484 sub end_report {
9485     local $\ = '';
9486     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9487 }
9488
9489 =head2 clean_ENV
9490
9491 If we have $ini_pids, save it in the environment; else remove it from the
9492 environment. Used by the C<R> (restart) command.
9493
9494 =cut
9495
9496 sub clean_ENV {
9497     if ( defined($ini_pids) ) {
9498         $ENV{PERLDB_PIDS} = $ini_pids;
9499     }
9500     else {
9501         delete( $ENV{PERLDB_PIDS} );
9502     }
9503 } ## end sub clean_ENV
9504
9505 # PERLDBf_... flag names from perl.h
9506 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9507
9508 BEGIN {
9509     %DollarCaretP_flags = (
9510         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9511         PERLDBf_LINE      => 0x02,     # Keep line #
9512         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9513         PERLDBf_INTER     => 0x08,     # Preserve more data
9514         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9515         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9516         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9517         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9518         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9519         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9520         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9521         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9522     );
9523     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9524     # doesn't need to set it. It's provided for the benefit of profilers and
9525     # other code analysers.
9526
9527     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9528 }
9529
9530 sub parse_DollarCaretP_flags {
9531     my $flags = shift;
9532     $flags =~ s/^\s+//;
9533     $flags =~ s/\s+$//;
9534     my $acu = 0;
9535     foreach my $f ( split /\s*\|\s*/, $flags ) {
9536         my $value;
9537         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9538             $value = hex $1;
9539         }
9540         elsif ( $f =~ /^(\d+)$/ ) {
9541             $value = int $1;
9542         }
9543         elsif ( $f =~ /^DEFAULT$/i ) {
9544             $value = $DollarCaretP_flags{PERLDB_ALL};
9545         }
9546         else {
9547             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9548             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9549             unless ( defined $value ) {
9550                 print $OUT (
9551                     "Unrecognized \$^P flag '$f'!\n",
9552                     "Acceptable flags are: "
9553                       . join( ', ', sort keys %DollarCaretP_flags ),
9554                     ", and hexadecimal and decimal numbers.\n"
9555                 );
9556                 return undef;
9557             }
9558         }
9559         $acu |= $value;
9560     }
9561     $acu;
9562 }
9563
9564 sub expand_DollarCaretP_flags {
9565     my $DollarCaretP = shift;
9566     my @bits         = (
9567         map {
9568             my $n = ( 1 << $_ );
9569             ( $DollarCaretP & $n )
9570               ? ( $DollarCaretP_flags_r{$n}
9571                   || sprintf( '0x%x', $n ) )
9572               : ()
9573           } 0 .. 31
9574     );
9575     return @bits ? join( '|', @bits ) : 0;
9576 }
9577
9578 =over 4
9579
9580 =item rerun
9581
9582 Rerun the current session to:
9583
9584     rerun        current position
9585
9586     rerun 4      command number 4
9587
9588     rerun -4     current command minus 4 (go back 4 steps)
9589
9590 Whether this always makes sense, in the current context is unknowable, and is
9591 in part left as a useful exercise for the reader.  This sub returns the
9592 appropriate arguments to rerun the current session.
9593
9594 =cut
9595
9596 sub rerun {
9597     my $i = shift;
9598     my @args;
9599     pop(@truehist);                      # strim
9600     unless (defined $truehist[$i]) {
9601         print "Unable to return to non-existent command: $i\n";
9602     } else {
9603         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9604         my @temp = @truehist;            # store
9605         push(@DB::typeahead, @truehist); # saved
9606         @truehist = @hist = ();          # flush
9607         @args = restart();              # setup
9608         get_list("PERLDB_HIST");        # clean
9609         set_list("PERLDB_HIST", @temp); # reset
9610     }
9611     return @args;
9612 }
9613
9614 =item restart
9615
9616 Restarting the debugger is a complex operation that occurs in several phases.
9617 First, we try to reconstruct the command line that was used to invoke Perl
9618 and the debugger.
9619
9620 =cut
9621
9622 sub restart {
9623     # I may not be able to resurrect you, but here goes ...
9624     print $OUT
9625 "Warning: some settings and command-line options may be lost!\n";
9626     my ( @script, @flags, $cl );
9627
9628     # If warn was on before, turn it on again.
9629     push @flags, '-w' if $ini_warn;
9630
9631     # Rebuild the -I flags that were on the initial
9632     # command line.
9633     for (@ini_INC) {
9634         push @flags, '-I', $_;
9635     }
9636
9637     # Turn on taint if it was on before.
9638     push @flags, '-T' if ${^TAINT};
9639
9640     # Arrange for setting the old INC:
9641     # Save the current @init_INC in the environment.
9642     set_list( "PERLDB_INC", @ini_INC );
9643
9644     # If this was a perl one-liner, go to the "file"
9645     # corresponding to the one-liner read all the lines
9646     # out of it (except for the first one, which is going
9647     # to be added back on again when 'perl -d' runs: that's
9648     # the 'require perl5db.pl;' line), and add them back on
9649     # to the command line to be executed.
9650     if ( $0 eq '-e' ) {
9651         my $lines = *{$main::{'_<-e'}}{ARRAY};
9652         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9653             chomp( $cl = $lines->[$_] );
9654             push @script, '-e', $cl;
9655         }
9656     } ## end if ($0 eq '-e')
9657
9658     # Otherwise we just reuse the original name we had
9659     # before.
9660     else {
9661         @script = $0;
9662     }
9663
9664 =pod
9665
9666 After the command line  has been reconstructed, the next step is to save
9667 the debugger's status in environment variables. The C<DB::set_list> routine
9668 is used to save aggregate variables (both hashes and arrays); scalars are
9669 just popped into environment variables directly.
9670
9671 =cut
9672
9673     # If the terminal supported history, grab it and
9674     # save that in the environment.
9675     set_list( "PERLDB_HIST",
9676           $term->Features->{getHistory}
9677         ? $term->GetHistory
9678         : @hist );
9679
9680     # Find all the files that were visited during this
9681     # session (i.e., the debugger had magic hashes
9682     # corresponding to them) and stick them in the environment.
9683     my @had_breakpoints = keys %had_breakpoints;
9684     set_list( "PERLDB_VISITED", @had_breakpoints );
9685
9686     # Save the debugger options we chose.
9687     set_list( "PERLDB_OPT", %option );
9688     # set_list( "PERLDB_OPT", options2remember() );
9689
9690     # Save the break-on-loads.
9691     set_list( "PERLDB_ON_LOAD", %break_on_load );
9692
9693 =pod
9694
9695 The most complex part of this is the saving of all of the breakpoints. They
9696 can live in an awful lot of places, and we have to go through all of them,
9697 find the breakpoints, and then save them in the appropriate environment
9698 variable via C<DB::set_list>.
9699
9700 =cut
9701
9702     # Go through all the breakpoints and make sure they're
9703     # still valid.
9704     my @hard;
9705     for ( 0 .. $#had_breakpoints ) {
9706
9707         # We were in this file.
9708         my $file = $had_breakpoints[$_];
9709
9710         # Grab that file's magic line hash.
9711         *dbline = $main::{ '_<' . $file };
9712
9713         # Skip out if it doesn't exist, or if the breakpoint
9714         # is in a postponed file (we'll do postponed ones
9715         # later).
9716         next unless %dbline or $postponed_file{$file};
9717
9718         # In an eval. This is a little harder, so we'll
9719         # do more processing on that below.
9720         ( push @hard, $file ), next
9721           if $file =~ /^\(\w*eval/;
9722
9723         # XXX I have no idea what this is doing. Yet.
9724         my @add;
9725         @add = %{ $postponed_file{$file} }
9726           if $postponed_file{$file};
9727
9728         # Save the list of all the breakpoints for this file.
9729         set_list( "PERLDB_FILE_$_", %dbline, @add );
9730
9731         # Serialize the extra data %breakpoints_data hash.
9732         # That's a bug fix.
9733         set_list( "PERLDB_FILE_ENABLED_$_",
9734             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9735             sort { $a <=> $b } keys(%dbline)
9736         )
9737     } ## end for (0 .. $#had_breakpoints)
9738
9739     # The breakpoint was inside an eval. This is a little
9740     # more difficult. XXX and I don't understand it.
9741     foreach my $hard_file (@hard) {
9742         # Get over to the eval in question.
9743         *dbline = $main::{ '_<' . $hard_file };
9744         my $quoted = quotemeta $hard_file;
9745         my %subs;
9746         for my $sub ( keys %sub ) {
9747             if (my ($n1, $n2) = $sub{$sub} =~ /\A$quoted:(\d+)-(\d+)\z/) {
9748                 $subs{$sub} = [ $n1, $n2 ];
9749             }
9750         }
9751         unless (%subs) {
9752             print {$OUT}
9753             "No subroutines in $hard_file, ignoring breakpoints.\n";
9754             next;
9755         }
9756         LINES: foreach my $line ( keys %dbline ) {
9757
9758             # One breakpoint per sub only:
9759             my ( $offset, $found );
9760             SUBS: foreach my $sub ( keys %subs ) {
9761                 if (
9762                     $subs{$sub}->[1] >= $line    # Not after the subroutine
9763                     and (
9764                         not defined $offset    # Not caught
9765                             or $offset < 0
9766                     )
9767                 )
9768                 {                              # or badly caught
9769                     $found  = $sub;
9770                     $offset = $line - $subs{$sub}->[0];
9771                     if ($offset >= 0) {
9772                         $offset = "+$offset";
9773                         last SUBS;
9774                     }
9775                 } ## end if ($subs{$sub}->[1] >=...
9776             } ## end for $sub (keys %subs)
9777             if ( defined $offset ) {
9778                 $postponed{$found} =
9779                 "break $offset if $dbline{$line}";
9780             }
9781             else {
9782                 print {$OUT}
9783                 ("Breakpoint in ${hard_file}:$line ignored:"
9784                 . " after all the subroutines.\n");
9785             }
9786         } ## end for $line (keys %dbline)
9787     } ## end for (@hard)
9788
9789     # Save the other things that don't need to be
9790     # processed.
9791     set_list( "PERLDB_POSTPONE",  %postponed );
9792     set_list( "PERLDB_PRETYPE",   @$pretype );
9793     set_list( "PERLDB_PRE",       @$pre );
9794     set_list( "PERLDB_POST",      @$post );
9795     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9796
9797     # We are officially restarting.
9798     $ENV{PERLDB_RESTART} = 1;
9799
9800     # We are junking all child debuggers.
9801     delete $ENV{PERLDB_PIDS};    # Restore ini state
9802
9803     # Set this back to the initial pid.
9804     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9805
9806 =pod
9807
9808 After all the debugger status has been saved, we take the command we built up
9809 and then return it, so we can C<exec()> it. The debugger will spot the
9810 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9811 from the environment.
9812
9813 =cut
9814
9815     # And run Perl again. Add the "-d" flag, all the
9816     # flags we built up, the script (whether a one-liner
9817     # or a file), add on the -emacs flag for a slave editor,
9818     # and then the old arguments.
9819
9820     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9821
9822 };  # end restart
9823
9824 =back
9825
9826 =head1 END PROCESSING - THE C<END> BLOCK
9827
9828 Come here at the very end of processing. We want to go into a
9829 loop where we allow the user to enter commands and interact with the
9830 debugger, but we don't want anything else to execute.
9831
9832 First we set the C<$finished> variable, so that some commands that
9833 shouldn't be run after the end of program quit working.
9834
9835 We then figure out whether we're truly done (as in the user entered a C<q>
9836 command, or we finished execution while running nonstop). If we aren't,
9837 we set C<$single> to 1 (causing the debugger to get control again).
9838
9839 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9840 message and returns control to the debugger. Repeat.
9841
9842 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9843 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9844 break, run to completion.).
9845
9846 =cut
9847
9848 END {
9849     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9850     $fall_off_end = 1 unless $inhibit_exit;
9851
9852     # Do not stop in at_exit() and destructors on exit:
9853     if ($fall_off_end or $runnonstop) {
9854         save_hist();
9855     } else {
9856         $DB::single = 1;
9857         DB::fake::at_exit();
9858     }
9859 } ## end END
9860
9861 =head1 PRE-5.8 COMMANDS
9862
9863 Some of the commands changed function quite a bit in the 5.8 command
9864 realignment, so much so that the old code had to be replaced completely.
9865 Because we wanted to retain the option of being able to go back to the
9866 former command set, we moved the old code off to this section.
9867
9868 There's an awful lot of duplicated code here. We've duplicated the
9869 comments to keep things clear.
9870
9871 =head2 Null command
9872
9873 Does nothing. Used to I<turn off> commands.
9874
9875 =cut
9876
9877 sub cmd_pre580_null {
9878
9879     # do nothing...
9880 }
9881
9882 =head2 Old C<a> command.
9883
9884 This version added actions if you supplied them, and deleted them
9885 if you didn't.
9886
9887 =cut
9888
9889 sub cmd_pre580_a {
9890     my $xcmd = shift;
9891     my $cmd  = shift;
9892
9893     # Argument supplied. Add the action.
9894     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9895
9896         # If the line isn't there, use the current line.
9897         my $i = $1 || $line;
9898         my $j = $2;
9899
9900         # If there is an action ...
9901         if ( length $j ) {
9902
9903             # ... but the line isn't breakable, skip it.
9904             if ( $dbline[$i] == 0 ) {
9905                 print $OUT "Line $i may not have an action.\n";
9906             }
9907             else {
9908
9909                 # ... and the line is breakable:
9910                 # Mark that there's an action in this file.
9911                 $had_breakpoints{$filename} |= 2;
9912
9913                 # Delete any current action.
9914                 $dbline{$i} =~ s/\0[^\0]*//;
9915
9916                 # Add the new action, continuing the line as needed.
9917                 $dbline{$i} .= "\0" . action($j);
9918             }
9919         } ## end if (length $j)
9920
9921         # No action supplied.
9922         else {
9923
9924             # Delete the action.
9925             $dbline{$i} =~ s/\0[^\0]*//;
9926
9927             # Mark as having no break or action if nothing's left.
9928             delete $dbline{$i} if $dbline{$i} eq '';
9929         }
9930     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9931 } ## end sub cmd_pre580_a
9932
9933 =head2 Old C<b> command
9934
9935 Add breakpoints.
9936
9937 =cut
9938
9939 sub cmd_pre580_b {
9940     my $xcmd   = shift;
9941     my $cmd    = shift;
9942     my $dbline = shift;
9943
9944     # Break on load.
9945     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9946         my $file = $1;
9947         $file =~ s/\s+$//;
9948         cmd_b_load($file);
9949     }
9950
9951     # b compile|postpone <some sub> [<condition>]
9952     # The interpreter actually traps this one for us; we just put the
9953     # necessary condition in the %postponed hash.
9954     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9955
9956         # Capture the condition if there is one. Make it true if none.
9957         my $cond = length $3 ? $3 : '1';
9958
9959         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9960         # if it was 'compile'.
9961         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9962
9963         # De-Perl4-ify the name - ' separators to ::.
9964         $subname =~ s/\'/::/g;
9965
9966         # Qualify it into the current package unless it's already qualified.
9967         $subname = "${package}::" . $subname
9968           unless $subname =~ /::/;
9969
9970         # Add main if it starts with ::.
9971         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9972
9973         # Save the break type for this sub.
9974         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9975     } ## end elsif ($cmd =~ ...
9976
9977     # b <sub name> [<condition>]
9978     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9979         my $subname = $1;
9980         my $cond = length $2 ? $2 : '1';
9981         cmd_b_sub( $subname, $cond );
9982     }
9983     # b <line> [<condition>].
9984     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9985         my $i = $1 || $dbline;
9986         my $cond = length $2 ? $2 : '1';
9987         cmd_b_line( $i, $cond );
9988     }
9989 } ## end sub cmd_pre580_b
9990
9991 =head2 Old C<D> command.
9992
9993 Delete all breakpoints unconditionally.
9994
9995 =cut
9996
9997 sub cmd_pre580_D {
9998     my $xcmd = shift;
9999     my $cmd  = shift;
10000     if ( $cmd =~ /^\s*$/ ) {
10001         print $OUT "Deleting all breakpoints...\n";
10002
10003         # %had_breakpoints lists every file that had at least one
10004         # breakpoint in it.
10005         my $file;
10006         for $file ( keys %had_breakpoints ) {
10007
10008             # Switch to the desired file temporarily.
10009             local *dbline = $main::{ '_<' . $file };
10010
10011             $max = $#dbline;
10012             my $was;
10013
10014             # For all lines in this file ...
10015             for my $i (1 .. $max) {
10016
10017                 # If there's a breakpoint or action on this line ...
10018                 if ( defined $dbline{$i} ) {
10019
10020                     # ... remove the breakpoint.
10021                     $dbline{$i} =~ s/^[^\0]+//;
10022                     if ( $dbline{$i} =~ s/^\0?$// ) {
10023
10024                         # Remove the entry altogether if no action is there.
10025                         delete $dbline{$i};
10026                     }
10027                 } ## end if (defined $dbline{$i...
10028             } ## end for my $i (1 .. $max)
10029
10030             # If, after we turn off the "there were breakpoints in this file"
10031             # bit, the entry in %had_breakpoints for this file is zero,
10032             # we should remove this file from the hash.
10033             if ( not $had_breakpoints{$file} &= ~1 ) {
10034                 delete $had_breakpoints{$file};
10035             }
10036         } ## end for $file (keys %had_breakpoints)
10037
10038         # Kill off all the other breakpoints that are waiting for files that
10039         # haven't been loaded yet.
10040         undef %postponed;
10041         undef %postponed_file;
10042         undef %break_on_load;
10043     } ## end if ($cmd =~ /^\s*$/)
10044 } ## end sub cmd_pre580_D
10045
10046 =head2 Old C<h> command
10047
10048 Print help. Defaults to printing the long-form help; the 5.8 version
10049 prints the summary by default.
10050
10051 =cut
10052
10053 sub cmd_pre580_h {
10054     my $xcmd = shift;
10055     my $cmd  = shift;
10056
10057     # Print the *right* help, long format.
10058     if ( $cmd =~ /^\s*$/ ) {
10059         print_help($pre580_help);
10060     }
10061
10062     # 'h h' - explicitly-requested summary.
10063     elsif ( $cmd =~ /^h\s*/ ) {
10064         print_help($pre580_summary);
10065     }
10066
10067     # Find and print a command's help.
10068     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
10069         my $asked  = $1;                   # for proper errmsg
10070         my $qasked = quotemeta($asked);    # for searching
10071                                            # XXX: finds CR but not <CR>
10072         if (
10073             $pre580_help =~ /^
10074                               <?           # Optional '<'
10075                               (?:[IB]<)    # Optional markup
10076                               $qasked      # The command name
10077                             /mx
10078           )
10079         {
10080
10081             while (
10082                 $pre580_help =~ /^
10083                                   (             # The command help:
10084                                    <?           # Optional '<'
10085                                    (?:[IB]<)    # Optional markup
10086                                    $qasked      # The command name
10087                                    ([\s\S]*?)   # Lines starting with tabs
10088                                    \n           # Final newline
10089                                   )
10090                                   (?!\s)/mgx
10091               )    # Line not starting with space
10092                    # (Next command's help)
10093             {
10094                 print_help($1);
10095             }
10096         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
10097
10098         # Help not found.
10099         else {
10100             print_help("B<$asked> is not a debugger command.\n");
10101         }
10102     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
10103 } ## end sub cmd_pre580_h
10104
10105 =head2 Old C<W> command
10106
10107 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
10108
10109 =cut
10110
10111 sub cmd_pre580_W {
10112     my $xcmd = shift;
10113     my $cmd  = shift;
10114
10115     # Delete all watch expressions.
10116     if ( $cmd =~ /^$/ ) {
10117
10118         # No watching is going on.
10119         $trace &= ~2;
10120
10121         # Kill all the watch expressions and values.
10122         @to_watch = @old_watch = ();
10123     }
10124
10125     # Add a watch expression.
10126     elsif ( $cmd =~ /^(.*)/s ) {
10127
10128         # add it to the list to be watched.
10129         push @to_watch, $1;
10130
10131         # Get the current value of the expression.
10132         # Doesn't handle expressions returning list values!
10133         $evalarg = $1;
10134         # The &-call is here to ascertain the mutability of @_.
10135         my ($val) = &DB::eval;
10136         $val = ( defined $val ) ? "'$val'" : 'undef';
10137
10138         # Save it.
10139         push @old_watch, $val;
10140
10141         # We're watching stuff.
10142         $trace |= 2;
10143
10144     } ## end elsif ($cmd =~ /^(.*)/s)
10145 } ## end sub cmd_pre580_W
10146
10147 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
10148
10149 The debugger used to have a bunch of nearly-identical code to handle
10150 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
10151 C<cmd_prepost> unify all this into one set of code to handle the
10152 appropriate actions.
10153
10154 =head2 C<cmd_pre590_prepost>
10155
10156 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
10157 do something destructive. In pre 5.8 debuggers, the default action was to
10158 delete all the actions.
10159
10160 =cut
10161
10162 sub cmd_pre590_prepost {
10163     my $cmd    = shift;
10164     my $line   = shift || '*';
10165     my $dbline = shift;
10166
10167     return cmd_prepost( $cmd, $line, $dbline );
10168 } ## end sub cmd_pre590_prepost
10169
10170 =head2 C<cmd_prepost>
10171
10172 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
10173 Since the lists of actions are all held in arrays that are pointed to by
10174 references anyway, all we have to do is pick the right array reference and
10175 then use generic code to all, delete, or list actions.
10176
10177 =cut
10178
10179 sub cmd_prepost {
10180     my $cmd = shift;
10181
10182     # No action supplied defaults to 'list'.
10183     my $line = shift || '?';
10184
10185     # Figure out what to put in the prompt.
10186     my $which = '';
10187
10188     # Make sure we have some array or another to address later.
10189     # This means that if for some reason the tests fail, we won't be
10190     # trying to stash actions or delete them from the wrong place.
10191     my $aref = [];
10192
10193     # < - Perl code to run before prompt.
10194     if ( $cmd =~ /^\</o ) {
10195         $which = 'pre-perl';
10196         $aref  = $pre;
10197     }
10198
10199     # > - Perl code to run after prompt.
10200     elsif ( $cmd =~ /^\>/o ) {
10201         $which = 'post-perl';
10202         $aref  = $post;
10203     }
10204
10205     # { - first check for properly-balanced braces.
10206     elsif ( $cmd =~ /^\{/o ) {
10207         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
10208             print $OUT
10209 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
10210         }
10211
10212         # Properly balanced. Pre-prompt debugger actions.
10213         else {
10214             $which = 'pre-debugger';
10215             $aref  = $pretype;
10216         }
10217     } ## end elsif ( $cmd =~ /^\{/o )
10218
10219     # Did we find something that makes sense?
10220     unless ($which) {
10221         print $OUT "Confused by command: $cmd\n";
10222     }
10223
10224     # Yes.
10225     else {
10226
10227         # List actions.
10228         if ( $line =~ /^\s*\?\s*$/o ) {
10229             unless (@$aref) {
10230
10231                 # Nothing there. Complain.
10232                 print $OUT "No $which actions.\n";
10233             }
10234             else {
10235
10236                 # List the actions in the selected list.
10237                 print $OUT "$which commands:\n";
10238                 foreach my $action (@$aref) {
10239                     print $OUT "\t$cmd -- $action\n";
10240                 }
10241             } ## end else
10242         } ## end if ( $line =~ /^\s*\?\s*$/o)
10243
10244         # Might be a delete.
10245         else {
10246             if ( length($cmd) == 1 ) {
10247                 if ( $line =~ /^\s*\*\s*$/o ) {
10248
10249                     # It's a delete. Get rid of the old actions in the
10250                     # selected list..
10251                     @$aref = ();
10252                     print $OUT "All $cmd actions cleared.\n";
10253                 }
10254                 else {
10255
10256                     # Replace all the actions. (This is a <, >, or {).
10257                     @$aref = action($line);
10258                 }
10259             } ## end if ( length($cmd) == 1)
10260             elsif ( length($cmd) == 2 ) {
10261
10262                 # Add the action to the line. (This is a <<, >>, or {{).
10263                 push @$aref, action($line);
10264             }
10265             else {
10266
10267                 # <<<, >>>>, {{{{{{ ... something not a command.
10268                 print $OUT
10269                   "Confused by strange length of $which command($cmd)...\n";
10270             }
10271         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
10272     } ## end else
10273 } ## end sub cmd_prepost
10274
10275 =head1 C<DB::fake>
10276
10277 Contains the C<at_exit> routine that the debugger uses to issue the
10278 C<Debugged program terminated ...> message after the program completes. See
10279 the C<END> block documentation for more details.
10280
10281 =cut
10282
10283 package DB::fake;
10284
10285 sub at_exit {
10286     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
10287 }
10288
10289 package DB;    # Do not trace this 1; below!
10290
10291 1;
10292
10293