3 perllocale - Perl locale handling (internationalization and localization)
7 Locales these days have been mostly been supplanted by Unicode, but Perl
8 continues to support them. See L</Unicode and UTF-8> below.
10 Perl supports language-specific notions of data such as "is this
11 a letter", "what is the uppercase equivalent of this letter", and
12 "which of these letters comes first". These are important issues,
13 especially for languages other than English--but also for English: it
14 would be naE<iuml>ve to imagine that C<A-Za-z> defines all the "letters"
15 needed to write correct English. Perl is also aware that some character other
16 than "." may be preferred as a decimal point, and that output date
17 representations may be language-specific. The process of making an
18 application take account of its users' preferences in such matters is
19 called B<internationalization> (often abbreviated as B<i18n>); telling
20 such an application about a particular set of preferences is known as
21 B<localization> (B<l10n>).
23 Perl can understand language-specific data via the standardized (ISO C,
24 XPG4, POSIX 1.c) method called "the locale system". The locale system is
25 controlled per application using one pragma, one function call, and
26 several environment variables.
28 B<NOTE>: This feature is new in Perl 5.004, and does not apply unless an
29 application specifically requests it--see L<Backward compatibility>.
30 The one exception is that write() now B<always> uses the current locale
33 =head1 PREPARING TO USE LOCALES
35 If Perl applications are to understand and present your data
36 correctly according a locale of your choice, B<all> of the following
43 B<Your operating system must support the locale system>. If it does,
44 you should find that the setlocale() function is a documented part of
49 B<Definitions for locales that you use must be installed>. You, or
50 your system administrator, must make sure that this is the case. The
51 available locales, the location in which they are kept, and the manner
52 in which they are installed all vary from system to system. Some systems
53 provide only a few, hard-wired locales and do not allow more to be
54 added. Others allow you to add "canned" locales provided by the system
55 supplier. Still others allow you or the system administrator to define
56 and add arbitrary locales. (You may have to ask your supplier to
57 provide canned locales that are not delivered with your operating
58 system.) Read your system documentation for further illumination.
62 B<Perl must believe that the locale system is supported>. If it does,
63 C<perl -V:d_setlocale> will say that the value for C<d_setlocale> is
68 If you want a Perl application to process and present your data
69 according to a particular locale, the application code should include
70 the S<C<use locale>> pragma (see L<The use locale pragma>) where
71 appropriate, and B<at least one> of the following must be true:
77 B<The locale-determining environment variables (see L<"ENVIRONMENT">)
78 must be correctly set up> at the time the application is started, either
79 by yourself or by whomever set up your system account; or
83 B<The application must set its own locale> using the method described in
84 L<The setlocale function>.
90 =head2 The use locale pragma
92 By default, Perl ignores the current locale. The S<C<use locale>>
93 pragma tells Perl to use the
94 current locale for some operations (C</l> for just pattern matching).
96 The current locale is set at execution time by
97 L<setlocale()|/The setlocale function> described below. If that function
98 hasn't yet been called in the course of the program's execution, the
99 current locale is that which was determined by the L<"ENVIRONMENT"> in
100 effect at the start of the program, except that
101 C<L<LC_NUMERIC|/Category LC_NUMERIC: Numeric Formatting>> is always
102 initialized to the C locale (mentioned under L<Finding locales>).
103 If there is no valid environment, the current locale is undefined. It
104 is likely, but not necessarily, the "C" locale.
106 The operations that are affected by locale are:
112 B<The comparison operators> (C<lt>, C<le>, C<cmp>, C<ge>, and C<gt>) and
113 the POSIX string collation functions strcoll() and strxfrm() use
114 C<LC_COLLATE>. sort() is also affected if used without an
115 explicit comparison function, because it uses C<cmp> by default.
117 B<Note:> C<eq> and C<ne> are unaffected by locale: they always
118 perform a char-by-char comparison of their scalar operands. What's
119 more, if C<cmp> finds that its operands are equal according to the
120 collation sequence specified by the current locale, it goes on to
121 perform a char-by-char comparison, and only returns I<0> (equal) if the
122 operands are char-for-char identical. If you really want to know whether
123 two strings--which C<eq> and C<cmp> may consider different--are equal
124 as far as collation in the locale is concerned, see the discussion in
125 L<Category LC_COLLATE: Collation>.
129 B<Regular expressions and case-modification functions> (uc(), lc(),
130 ucfirst(), and lcfirst()) use C<LC_CTYPE>
134 B<Format declarations> (format()) use C<LC_NUMERIC>
138 B<The POSIX date formatting function> (strftime()) uses C<LC_TIME>.
142 C<LC_COLLATE>, C<LC_CTYPE>, and so on, are discussed further in
143 L<LOCALE CATEGORIES>.
145 The default behavior is restored with the S<C<no locale>> pragma, or
146 upon reaching the end of the block enclosing C<use locale>.
148 The string result of any operation that uses locale
149 information is tainted, as it is possible for a locale to be
150 untrustworthy. See L<"SECURITY">.
152 =head2 The setlocale function
154 You can switch locales as often as you wish at run time with the
155 POSIX::setlocale() function:
157 # This functionality not usable prior to Perl 5.004
160 # Import locale-handling tool set from POSIX module.
161 # This example uses: setlocale -- the function call
162 # LC_CTYPE -- explained below
163 use POSIX qw(locale_h);
165 # query and save the old locale
166 $old_locale = setlocale(LC_CTYPE);
168 setlocale(LC_CTYPE, "fr_CA.ISO8859-1");
169 # LC_CTYPE now in locale "French, Canada, codeset ISO 8859-1"
171 setlocale(LC_CTYPE, "");
172 # LC_CTYPE now reset to default defined by LC_ALL/LC_CTYPE/LANG
173 # environment variables. See below for documentation.
175 # restore the old locale
176 setlocale(LC_CTYPE, $old_locale);
178 The first argument of setlocale() gives the B<category>, the second the
179 B<locale>. The category tells in what aspect of data processing you
180 want to apply locale-specific rules. Category names are discussed in
181 L<LOCALE CATEGORIES> and L<"ENVIRONMENT">. The locale is the name of a
182 collection of customization information corresponding to a particular
183 combination of language, country or territory, and codeset. Read on for
184 hints on the naming of locales: not all systems name locales as in the
187 If no second argument is provided and the category is something else
188 than LC_ALL, the function returns a string naming the current locale
189 for the category. You can use this value as the second argument in a
190 subsequent call to setlocale().
192 If no second argument is provided and the category is LC_ALL, the
193 result is implementation-dependent. It may be a string of
194 concatenated locale names (separator also implementation-dependent)
195 or a single locale name. Please consult your setlocale(3) man page for
198 If a second argument is given and it corresponds to a valid locale,
199 the locale for the category is set to that value, and the function
200 returns the now-current locale value. You can then use this in yet
201 another call to setlocale(). (In some implementations, the return
202 value may sometimes differ from the value you gave as the second
203 argument--think of it as an alias for the value you gave.)
205 As the example shows, if the second argument is an empty string, the
206 category's locale is returned to the default specified by the
207 corresponding environment variables. Generally, this results in a
208 return to the default that was in force when Perl started up: changes
209 to the environment made by the application after startup may or may not
210 be noticed, depending on your system's C library.
212 If the second argument does not correspond to a valid locale, the locale
213 for the category is not changed, and the function returns I<undef>.
215 For further information about the categories, consult setlocale(3).
217 =head2 Finding locales
219 For locales available in your system, consult also setlocale(3) to
220 see whether it leads to the list of available locales (search for the
221 I<SEE ALSO> section). If that fails, try the following command lines:
235 and see whether they list something resembling these
237 en_US.ISO8859-1 de_DE.ISO8859-1 ru_RU.ISO8859-5
238 en_US.iso88591 de_DE.iso88591 ru_RU.iso88595
241 english german russian
242 english.iso88591 german.iso88591 russian.iso88595
243 english.roman8 russian.koi8r
245 Sadly, even though the calling interface for setlocale() has been
246 standardized, names of locales and the directories where the
247 configuration resides have not been. The basic form of the name is
248 I<language_territory>B<.>I<codeset>, but the latter parts after
249 I<language> are not always present. The I<language> and I<country>
250 are usually from the standards B<ISO 3166> and B<ISO 639>, the
251 two-letter abbreviations for the countries and the languages of the
252 world, respectively. The I<codeset> part often mentions some B<ISO
253 8859> character set, the Latin codesets. For example, C<ISO 8859-1>
254 is the so-called "Western European codeset" that can be used to encode
255 most Western European languages adequately. Again, there are several
256 ways to write even the name of that one standard. Lamentably.
258 Two special locales are worth particular mention: "C" and "POSIX".
259 Currently these are effectively the same locale: the difference is
260 mainly that the first one is defined by the C standard, the second by
261 the POSIX standard. They define the B<default locale> in which
262 every program starts in the absence of locale information in its
263 environment. (The I<default> default locale, if you will.) Its language
264 is (American) English and its character codeset ASCII.
265 B<Warning>. The C locale delivered by some vendors may not
266 actually exactly match what the C standard calls for. So beware.
268 B<NOTE>: Not all systems have the "POSIX" locale (not all systems are
269 POSIX-conformant), so use "C" when you need explicitly to specify this
272 =head2 LOCALE PROBLEMS
274 You may encounter the following warning message at Perl startup:
276 perl: warning: Setting locale failed.
277 perl: warning: Please check that your locale settings:
280 are supported and installed on your system.
281 perl: warning: Falling back to the standard locale ("C").
283 This means that your locale settings had LC_ALL set to "En_US" and
284 LANG exists but has no value. Perl tried to believe you but could not.
285 Instead, Perl gave up and fell back to the "C" locale, the default locale
286 that is supposed to work no matter what. This usually means your locale
287 settings were wrong, they mention locales your system has never heard
288 of, or the locale installation in your system has problems (for example,
289 some system files are broken or missing). There are quick and temporary
290 fixes to these problems, as well as more thorough and lasting fixes.
292 =head2 Temporarily fixing locale problems
294 The two quickest fixes are either to render Perl silent about any
295 locale inconsistencies or to run Perl under the default locale "C".
297 Perl's moaning about locale problems can be silenced by setting the
298 environment variable PERL_BADLANG to a zero value, for example "0".
299 This method really just sweeps the problem under the carpet: you tell
300 Perl to shut up even when Perl sees that something is wrong. Do not
301 be surprised if later something locale-dependent misbehaves.
303 Perl can be run under the "C" locale by setting the environment
304 variable LC_ALL to "C". This method is perhaps a bit more civilized
305 than the PERL_BADLANG approach, but setting LC_ALL (or
306 other locale variables) may affect other programs as well, not just
307 Perl. In particular, external programs run from within Perl will see
308 these changes. If you make the new settings permanent (read on), all
309 programs you run see the changes. See L<"ENVIRONMENT"> for
310 the full list of relevant environment variables and L<USING LOCALES>
311 for their effects in Perl. Effects in other programs are
312 easily deducible. For example, the variable LC_COLLATE may well affect
313 your B<sort> program (or whatever the program that arranges "records"
314 alphabetically in your system is called).
316 You can test out changing these variables temporarily, and if the
317 new settings seem to help, put those settings into your shell startup
318 files. Consult your local documentation for the exact details. For in
319 Bourne-like shells (B<sh>, B<ksh>, B<bash>, B<zsh>):
321 LC_ALL=en_US.ISO8859-1
324 This assumes that we saw the locale "en_US.ISO8859-1" using the commands
325 discussed above. We decided to try that instead of the above faulty
326 locale "En_US"--and in Cshish shells (B<csh>, B<tcsh>)
328 setenv LC_ALL en_US.ISO8859-1
330 or if you have the "env" application you can do in any shell
332 env LC_ALL=en_US.ISO8859-1 perl ...
334 If you do not know what shell you have, consult your local
335 helpdesk or the equivalent.
337 =head2 Permanently fixing locale problems
339 The slower but superior fixes are when you may be able to yourself
340 fix the misconfiguration of your own environment variables. The
341 mis(sing)configuration of the whole system's locales usually requires
342 the help of your friendly system administrator.
344 First, see earlier in this document about L<Finding locales>. That tells
345 how to find which locales are really supported--and more importantly,
346 installed--on your system. In our example error message, environment
347 variables affecting the locale are listed in the order of decreasing
348 importance (and unset variables do not matter). Therefore, having
349 LC_ALL set to "En_US" must have been the bad choice, as shown by the
350 error message. First try fixing locale settings listed first.
352 Second, if using the listed commands you see something B<exactly>
353 (prefix matches do not count and case usually counts) like "En_US"
354 without the quotes, then you should be okay because you are using a
355 locale name that should be installed and available in your system.
356 In this case, see L<Permanently fixing your system's locale configuration>.
358 =head2 Permanently fixing your system's locale configuration
360 This is when you see something like:
362 perl: warning: Please check that your locale settings:
365 are supported and installed on your system.
367 but then cannot see that "En_US" listed by the above-mentioned
368 commands. You may see things like "en_US.ISO8859-1", but that isn't
369 the same. In this case, try running under a locale
370 that you can list and which somehow matches what you tried. The
371 rules for matching locale names are a bit vague because
372 standardization is weak in this area. See again the
373 L<Finding locales> about general rules.
375 =head2 Fixing system locale configuration
377 Contact a system administrator (preferably your own) and report the exact
378 error message you get, and ask them to read this same documentation you
379 are now reading. They should be able to check whether there is something
380 wrong with the locale configuration of the system. The L<Finding locales>
381 section is unfortunately a bit vague about the exact commands and places
382 because these things are not that standardized.
384 =head2 The localeconv function
386 The POSIX::localeconv() function allows you to get particulars of the
387 locale-dependent numeric formatting information specified by the current
388 C<LC_NUMERIC> and C<LC_MONETARY> locales. (If you just want the name of
389 the current locale for a particular category, use POSIX::setlocale()
390 with a single parameter--see L<The setlocale function>.)
392 use POSIX qw(locale_h);
394 # Get a reference to a hash of locale-dependent info
395 $locale_values = localeconv();
397 # Output sorted list of the values
398 for (sort keys %$locale_values) {
399 printf "%-20s = %s\n", $_, $locale_values->{$_}
402 localeconv() takes no arguments, and returns B<a reference to> a hash.
403 The keys of this hash are variable names for formatting, such as
404 C<decimal_point> and C<thousands_sep>. The values are the
405 corresponding, er, values. See L<POSIX/localeconv> for a longer
406 example listing the categories an implementation might be expected to
407 provide; some provide more and others fewer. You don't need an
408 explicit C<use locale>, because localeconv() always observes the
411 Here's a simple-minded example program that rewrites its command-line
412 parameters as integers correctly formatted in the current locale:
414 # See comments in previous example
416 use POSIX qw(locale_h);
418 # Get some of locale's numeric formatting parameters
419 my ($thousands_sep, $grouping) =
420 @{localeconv()}{'thousands_sep', 'grouping'};
422 # Apply defaults if values are missing
423 $thousands_sep = ',' unless $thousands_sep;
425 # grouping and mon_grouping are packed lists
426 # of small integers (characters) telling the
427 # grouping (thousand_seps and mon_thousand_seps
428 # being the group dividers) of numbers and
429 # monetary quantities. The integers' meanings:
430 # 255 means no more grouping, 0 means repeat
431 # the previous grouping, 1-254 means use that
432 # as the current grouping. Grouping goes from
433 # right to left (low to high digits). In the
434 # below we cheat slightly by never using anything
435 # else than the first grouping (whatever that is).
437 @grouping = unpack("C*", $grouping);
442 # Format command line params for current locale
444 $_ = int; # Chop non-integer part
446 s/(\d)(\d{$grouping[0]}($|$thousands_sep))/$1$thousands_sep$2/;
451 =head2 I18N::Langinfo
453 Another interface for querying locale-dependent information is the
454 I18N::Langinfo::langinfo() function, available at least in Unix-like
457 The following example will import the langinfo() function itself and
458 three constants to be used as arguments to langinfo(): a constant for
459 the abbreviated first day of the week (the numbering starts from
460 Sunday = 1) and two more constants for the affirmative and negative
461 answers for a yes/no question in the current locale.
463 use I18N::Langinfo qw(langinfo ABDAY_1 YESSTR NOSTR);
465 my ($abday_1, $yesstr, $nostr)
466 = map { langinfo } qw(ABDAY_1 YESSTR NOSTR);
468 print "$abday_1? [$yesstr/$nostr] ";
470 In other words, in the "C" (or English) locale the above will probably
471 print something like:
475 See L<I18N::Langinfo> for more information.
477 =head1 LOCALE CATEGORIES
479 The following subsections describe basic locale categories. Beyond these,
480 some combination categories allow manipulation of more than one
481 basic category at a time. See L<"ENVIRONMENT"> for a discussion of these.
483 =head2 Category LC_COLLATE: Collation
485 In the scope of S<C<use locale>>, Perl looks to the C<LC_COLLATE>
486 environment variable to determine the application's notions on collation
487 (ordering) of characters. For example, "b" follows "a" in Latin
488 alphabets, but where do "E<aacute>" and "E<aring>" belong? And while
489 "color" follows "chocolate" in English, what about in Spanish?
491 The following collations all make sense and you may meet any of them
499 Here is a code snippet to tell what "word"
500 characters are in the current locale, in that locale's order:
503 print +(sort grep /\w/, map { chr } 0..255), "\n";
505 Compare this with the characters that you see and their order if you
506 state explicitly that the locale should be ignored:
509 print +(sort grep /\w/, map { chr } 0..255), "\n";
511 This machine-native collation (which is what you get unless S<C<use
512 locale>> has appeared earlier in the same block) must be used for
513 sorting raw binary data, whereas the locale-dependent collation of the
514 first example is useful for natural text.
516 As noted in L<USING LOCALES>, C<cmp> compares according to the current
517 collation locale when C<use locale> is in effect, but falls back to a
518 char-by-char comparison for strings that the locale says are equal. You
519 can use POSIX::strcoll() if you don't want this fall-back:
521 use POSIX qw(strcoll);
523 !strcoll("space and case ignored", "SpaceAndCaseIgnored");
525 $equal_in_locale will be true if the collation locale specifies a
526 dictionary-like ordering that ignores space characters completely and
529 If you have a single string that you want to check for "equality in
530 locale" against several others, you might think you could gain a little
531 efficiency by using POSIX::strxfrm() in conjunction with C<eq>:
533 use POSIX qw(strxfrm);
534 $xfrm_string = strxfrm("Mixed-case string");
535 print "locale collation ignores spaces\n"
536 if $xfrm_string eq strxfrm("Mixed-casestring");
537 print "locale collation ignores hyphens\n"
538 if $xfrm_string eq strxfrm("Mixedcase string");
539 print "locale collation ignores case\n"
540 if $xfrm_string eq strxfrm("mixed-case string");
542 strxfrm() takes a string and maps it into a transformed string for use
543 in char-by-char comparisons against other transformed strings during
544 collation. "Under the hood", locale-affected Perl comparison operators
545 call strxfrm() for both operands, then do a char-by-char
546 comparison of the transformed strings. By calling strxfrm() explicitly
547 and using a non locale-affected comparison, the example attempts to save
548 a couple of transformations. But in fact, it doesn't save anything: Perl
549 magic (see L<perlguts/Magic Variables>) creates the transformed version of a
550 string the first time it's needed in a comparison, then keeps this version around
551 in case it's needed again. An example rewritten the easy way with
552 C<cmp> runs just about as fast. It also copes with null characters
553 embedded in strings; if you call strxfrm() directly, it treats the first
554 null it finds as a terminator. don't expect the transformed strings
555 it produces to be portable across systems--or even from one revision
556 of your operating system to the next. In short, don't call strxfrm()
557 directly: let Perl do it for you.
559 Note: C<use locale> isn't shown in some of these examples because it isn't
560 needed: strcoll() and strxfrm() exist only to generate locale-dependent
561 results, and so always obey the current C<LC_COLLATE> locale.
563 =head2 Category LC_CTYPE: Character Types
565 In the scope of S<C<use locale>>, Perl obeys the C<LC_CTYPE> locale
566 setting. This controls the application's notion of which characters are
567 alphabetic. This affects Perl's C<\w> regular expression metanotation,
568 which stands for alphanumeric characters--that is, alphabetic,
569 numeric, and including other special characters such as the underscore or
570 hyphen. (Consult L<perlre> for more information about
571 regular expressions.) Thanks to C<LC_CTYPE>, depending on your locale
572 setting, characters like "E<aelig>", "E<eth>", "E<szlig>", and
573 "E<oslash>" may be understood as C<\w> characters.
575 The C<LC_CTYPE> locale also provides the map used in transliterating
576 characters between lower and uppercase. This affects the case-mapping
577 functions--lc(), lcfirst, uc(), and ucfirst(); case-mapping
578 interpolation with C<\l>, C<\L>, C<\u>, or C<\U> in double-quoted strings
579 and C<s///> substitutions; and case-independent regular expression
580 pattern matching using the C<i> modifier.
582 Finally, C<LC_CTYPE> affects the POSIX character-class test
583 functions--isalpha(), islower(), and so on. For example, if you move
584 from the "C" locale to a 7-bit Scandinavian one, you may find--possibly
585 to your surprise--that "|" moves from the ispunct() class to isalpha().
586 Unfortunately, this creates big problems for regular expressions. "|" still
587 means alternation even though it matches C<\w>.
589 B<Note:> A broken or malicious C<LC_CTYPE> locale definition may result
590 in clearly ineligible characters being considered to be alphanumeric by
591 your application. For strict matching of (mundane) ASCII letters and
592 digits--for example, in command strings--locale-aware applications
593 should use C<\w> with the C</a> regular expression modifier. See L<"SECURITY">.
595 =head2 Category LC_NUMERIC: Numeric Formatting
597 After a proper POSIX::setlocale() call, Perl obeys the C<LC_NUMERIC>
598 locale information, which controls an application's idea of how numbers
599 should be formatted for human readability by the printf(), sprintf(), and
600 write() functions. String-to-numeric conversion by the POSIX::strtod()
601 function is also affected. In most implementations the only effect is to
602 change the character used for the decimal point--perhaps from "." to ",".
603 These functions aren't aware of such niceties as thousands separation and
604 so on. (See L<The localeconv function> if you care about these things.)
606 Output produced by print() is also affected by the current locale: it
607 corresponds to what you'd get from printf() in the "C" locale. The
608 same is true for Perl's internal conversions between numeric and
611 use POSIX qw(strtod setlocale LC_NUMERIC);
613 setlocale LC_NUMERIC, "";
615 $n = 5/2; # Assign numeric 2.5 to $n
617 $a = " $n"; # Locale-dependent conversion to string
619 print "half five is $n\n"; # Locale-dependent output
621 printf "half five is %g\n", $n; # Locale-dependent output
623 print "DECIMAL POINT IS COMMA\n"
624 if $n == (strtod("2,5"))[0]; # Locale-dependent conversion
626 See also L<I18N::Langinfo> and C<RADIXCHAR>.
628 =head2 Category LC_MONETARY: Formatting of monetary amounts
630 The C standard defines the C<LC_MONETARY> category, but not a function
631 that is affected by its contents. (Those with experience of standards
632 committees will recognize that the working group decided to punt on the
633 issue.) Consequently, Perl takes no notice of it. If you really want
634 to use C<LC_MONETARY>, you can query its contents--see
635 L<The localeconv function>--and use the information that it returns in your
636 application's own formatting of currency amounts. However, you may well
637 find that the information, voluminous and complex though it may be, still
638 does not quite meet your requirements: currency formatting is a hard nut
641 See also L<I18N::Langinfo> and C<CRNCYSTR>.
645 Output produced by POSIX::strftime(), which builds a formatted
646 human-readable date/time string, is affected by the current C<LC_TIME>
647 locale. Thus, in a French locale, the output produced by the C<%B>
648 format element (full month name) for the first month of the year would
649 be "janvier". Here's how to get a list of long month names in the
652 use POSIX qw(strftime);
654 $long_month_name[$_] =
655 strftime("%B", 0, 0, 0, 1, $_, 96);
658 Note: C<use locale> isn't needed in this example: as a function that
659 exists only to generate locale-dependent results, strftime() always
660 obeys the current C<LC_TIME> locale.
662 See also L<I18N::Langinfo> and C<ABDAY_1>..C<ABDAY_7>, C<DAY_1>..C<DAY_7>,
663 C<ABMON_1>..C<ABMON_12>, and C<ABMON_1>..C<ABMON_12>.
665 =head2 Other categories
667 The remaining locale category, C<LC_MESSAGES> (possibly supplemented
668 by others in particular implementations) is not currently used by
669 Perl--except possibly to affect the behavior of library functions
670 called by extensions outside the standard Perl distribution and by the
671 operating system and its utilities. Note especially that the string
672 value of C<$!> and the error messages given by external utilities may
673 be changed by C<LC_MESSAGES>. If you want to have portable error
674 codes, use C<%!>. See L<Errno>.
678 Although the main discussion of Perl security issues can be found in
679 L<perlsec>, a discussion of Perl's locale handling would be incomplete
680 if it did not draw your attention to locale-dependent security issues.
681 Locales--particularly on systems that allow unprivileged users to
682 build their own locales--are untrustworthy. A malicious (or just plain
683 broken) locale can make a locale-aware application give unexpected
684 results. Here are a few possibilities:
690 Regular expression checks for safe file names or mail addresses using
691 C<\w> may be spoofed by an C<LC_CTYPE> locale that claims that
692 characters such as "E<gt>" and "|" are alphanumeric.
696 String interpolation with case-mapping, as in, say, C<$dest =
697 "C:\U$name.$ext">, may produce dangerous results if a bogus LC_CTYPE
698 case-mapping table is in effect.
702 A sneaky C<LC_COLLATE> locale could result in the names of students with
703 "D" grades appearing ahead of those with "A"s.
707 An application that takes the trouble to use information in
708 C<LC_MONETARY> may format debits as if they were credits and vice versa
709 if that locale has been subverted. Or it might make payments in US
710 dollars instead of Hong Kong dollars.
714 The date and day names in dates formatted by strftime() could be
715 manipulated to advantage by a malicious user able to subvert the
716 C<LC_DATE> locale. ("Look--it says I wasn't in the building on
721 Such dangers are not peculiar to the locale system: any aspect of an
722 application's environment which may be modified maliciously presents
723 similar challenges. Similarly, they are not specific to Perl: any
724 programming language that allows you to write programs that take
725 account of their environment exposes you to these issues.
727 Perl cannot protect you from all possibilities shown in the
728 examples--there is no substitute for your own vigilance--but, when
729 C<use locale> is in effect, Perl uses the tainting mechanism (see
730 L<perlsec>) to mark string results that become locale-dependent, and
731 which may be untrustworthy in consequence. Here is a summary of the
732 tainting behavior of operators and functions that may be affected by
739 B<Comparison operators> (C<lt>, C<le>, C<ge>, C<gt> and C<cmp>):
741 Scalar true/false (or less/equal/greater) result is never tainted.
745 B<Case-mapping interpolation> (with C<\l>, C<\L>, C<\u> or C<\U>)
747 Result string containing interpolated material is tainted if
748 C<use locale> is in effect.
752 B<Matching operator> (C<m//>):
754 Scalar true/false result never tainted.
756 Subpatterns, either delivered as a list-context result or as $1 etc.
757 are tainted if C<use locale> is in effect, and the subpattern regular
758 expression contains C<\w> (to match an alphanumeric character), C<\W>
759 (non-alphanumeric character), C<\s> (whitespace character), or C<\S>
760 (non whitespace character). The matched-pattern variable, $&, $`
761 (pre-match), $' (post-match), and $+ (last match) are also tainted if
762 C<use locale> is in effect and the regular expression contains C<\w>,
763 C<\W>, C<\s>, or C<\S>.
767 B<Substitution operator> (C<s///>):
769 Has the same behavior as the match operator. Also, the left
770 operand of C<=~> becomes tainted when C<use locale> in effect
771 if modified as a result of a substitution based on a regular
772 expression match involving C<\w>, C<\W>, C<\s>, or C<\S>; or of
773 case-mapping with C<\l>, C<\L>,C<\u> or C<\U>.
777 B<Output formatting functions> (printf() and write()):
779 Results are never tainted because otherwise even output from print,
780 for example C<print(1/7)>, should be tainted if C<use locale> is in
785 B<Case-mapping functions> (lc(), lcfirst(), uc(), ucfirst()):
787 Results are tainted if C<use locale> is in effect.
791 B<POSIX locale-dependent functions> (localeconv(), strcoll(),
792 strftime(), strxfrm()):
794 Results are never tainted.
798 B<POSIX character class tests> (isalnum(), isalpha(), isdigit(),
799 isgraph(), islower(), isprint(), ispunct(), isspace(), isupper(),
802 True/false results are never tainted.
806 Three examples illustrate locale-dependent tainting.
807 The first program, which ignores its locale, won't run: a value taken
808 directly from the command line may not be used to name an output file
809 when taint checks are enabled.
811 #/usr/local/bin/perl -T
812 # Run with taint checking
814 # Command line sanity check omitted...
815 $tainted_output_file = shift;
817 open(F, ">$tainted_output_file")
818 or warn "Open of $untainted_output_file failed: $!\n";
820 The program can be made to run by "laundering" the tainted value through
821 a regular expression: the second example--which still ignores locale
822 information--runs, creating the file named on its command line
825 #/usr/local/bin/perl -T
827 $tainted_output_file = shift;
828 $tainted_output_file =~ m%[\w/]+%;
829 $untainted_output_file = $&;
831 open(F, ">$untainted_output_file")
832 or warn "Open of $untainted_output_file failed: $!\n";
834 Compare this with a similar but locale-aware program:
836 #/usr/local/bin/perl -T
838 $tainted_output_file = shift;
840 $tainted_output_file =~ m%[\w/]+%;
841 $localized_output_file = $&;
843 open(F, ">$localized_output_file")
844 or warn "Open of $localized_output_file failed: $!\n";
846 This third program fails to run because $& is tainted: it is the result
847 of a match involving C<\w> while C<use locale> is in effect.
855 A string that can suppress Perl's warning about failed locale settings
856 at startup. Failure can occur if the locale support in the operating
857 system is lacking (broken) in some way--or if you mistyped the name of
858 a locale when you set up your environment. If this environment
859 variable is absent, or has a value that does not evaluate to integer
860 zero--that is, "0" or ""-- Perl will complain about locale setting
863 B<NOTE>: PERL_BADLANG only gives you a way to hide the warning message.
864 The message tells about some problem in your system's locale support,
865 and you should investigate what the problem is.
869 The following environment variables are not specific to Perl: They are
870 part of the standardized (ISO C, XPG4, POSIX 1.c) setlocale() method
871 for controlling an application's opinion on data.
877 C<LC_ALL> is the "override-all" locale environment variable. If
878 set, it overrides all the rest of the locale environment variables.
882 B<NOTE>: C<LANGUAGE> is a GNU extension, it affects you only if you
883 are using the GNU libc. This is the case if you are using e.g. Linux.
884 If you are using "commercial" Unixes you are most probably I<not>
885 using GNU libc and you can ignore C<LANGUAGE>.
887 However, in the case you are using C<LANGUAGE>: it affects the
888 language of informational, warning, and error messages output by
889 commands (in other words, it's like C<LC_MESSAGES>) but it has higher
890 priority than C<LC_ALL>. Moreover, it's not a single value but
891 instead a "path" (":"-separated list) of I<languages> (not locales).
892 See the GNU C<gettext> library documentation for more information.
896 In the absence of C<LC_ALL>, C<LC_CTYPE> chooses the character type
897 locale. In the absence of both C<LC_ALL> and C<LC_CTYPE>, C<LANG>
898 chooses the character type locale.
902 In the absence of C<LC_ALL>, C<LC_COLLATE> chooses the collation
903 (sorting) locale. In the absence of both C<LC_ALL> and C<LC_COLLATE>,
904 C<LANG> chooses the collation locale.
908 In the absence of C<LC_ALL>, C<LC_MONETARY> chooses the monetary
909 formatting locale. In the absence of both C<LC_ALL> and C<LC_MONETARY>,
910 C<LANG> chooses the monetary formatting locale.
914 In the absence of C<LC_ALL>, C<LC_NUMERIC> chooses the numeric format
915 locale. In the absence of both C<LC_ALL> and C<LC_NUMERIC>, C<LANG>
916 chooses the numeric format.
920 In the absence of C<LC_ALL>, C<LC_TIME> chooses the date and time
921 formatting locale. In the absence of both C<LC_ALL> and C<LC_TIME>,
922 C<LANG> chooses the date and time formatting locale.
926 C<LANG> is the "catch-all" locale environment variable. If it is set, it
927 is used as the last resort after the overall C<LC_ALL> and the
928 category-specific C<LC_...>.
934 The LC_NUMERIC controls the numeric output:
937 use POSIX qw(locale_h); # Imports setlocale() and the LC_ constants.
938 setlocale(LC_NUMERIC, "fr_FR") or die "Pardon";
939 printf "%g\n", 1.23; # If the "fr_FR" succeeded, probably shows 1,23.
941 and also how strings are parsed by POSIX::strtod() as numbers:
944 use POSIX qw(locale_h strtod);
945 setlocale(LC_NUMERIC, "de_DE") or die "Entschuldigung";
946 my $x = strtod("2,34") + 5;
947 print $x, "\n"; # Probably shows 7,34.
951 =head2 Backward compatibility
953 Versions of Perl prior to 5.004 B<mostly> ignored locale information,
954 generally behaving as if something similar to the C<"C"> locale were
955 always in force, even if the program environment suggested otherwise
956 (see L<The setlocale function>). By default, Perl still behaves this
957 way for backward compatibility. If you want a Perl application to pay
958 attention to locale information, you B<must> use the S<C<use locale>>
959 pragma (see L<The use locale pragma>) or, in the unlikely event
960 that you want to do so for just pattern matching, the
961 C</l> regular expression modifier (see L<perlre/Character set
962 modifiers>) to instruct it to do so.
964 Versions of Perl from 5.002 to 5.003 did use the C<LC_CTYPE>
965 information if available; that is, C<\w> did understand what
966 were the letters according to the locale environment variables.
967 The problem was that the user had no control over the feature:
968 if the C library supported locales, Perl used them.
970 =head2 I18N:Collate obsolete
972 In versions of Perl prior to 5.004, per-locale collation was possible
973 using the C<I18N::Collate> library module. This module is now mildly
974 obsolete and should be avoided in new applications. The C<LC_COLLATE>
975 functionality is now integrated into the Perl core language: One can
976 use locale-specific scalar data completely normally with C<use locale>,
977 so there is no longer any need to juggle with the scalar references of
980 =head2 Sort speed and memory use impacts
982 Comparing and sorting by locale is usually slower than the default
983 sorting; slow-downs of two to four times have been observed. It will
984 also consume more memory: once a Perl scalar variable has participated
985 in any string comparison or sorting operation obeying the locale
986 collation rules, it will take 3-15 times more memory than before. (The
987 exact multiplier depends on the string's contents, the operating system
988 and the locale.) These downsides are dictated more by the operating
989 system's implementation of the locale system than by Perl.
991 =head2 write() and LC_NUMERIC
993 If a program's environment specifies an LC_NUMERIC locale and C<use
994 locale> is in effect when the format is declared, the locale is used
995 to specify the decimal point character in formatted output. Formatted
996 output cannot be controlled by C<use locale> at the time when write()
999 =head2 Freely available locale definitions
1001 There is a large collection of locale definitions at:
1003 http://std.dkuug.dk/i18n/WG15-collection/locales/
1005 You should be aware that it is
1006 unsupported, and is not claimed to be fit for any purpose. If your
1007 system allows installation of arbitrary locales, you may find the
1008 definitions useful as they are, or as a basis for the development of
1011 =head2 I18n and l10n
1013 "Internationalization" is often abbreviated as B<i18n> because its first
1014 and last letters are separated by eighteen others. (You may guess why
1015 the internalin ... internaliti ... i18n tends to get abbreviated.) In
1016 the same way, "localization" is often abbreviated to B<l10n>.
1018 =head2 An imperfect standard
1020 Internationalization, as defined in the C and POSIX standards, can be
1021 criticized as incomplete, ungainly, and having too large a granularity.
1022 (Locales apply to a whole process, when it would arguably be more useful
1023 to have them apply to a single thread, window group, or whatever.) They
1024 also have a tendency, like standards groups, to divide the world into
1025 nations, when we all know that the world can equally well be divided
1026 into bankers, bikers, gamers, and so on.
1028 =head1 Unicode and UTF-8
1030 The support of Unicode is new starting from Perl version 5.6, and more fully
1031 implemented in version 5.8 and later. See L<perluniintro>. Perl tries to
1032 work with both Unicode and locales--but of course, there are problems.
1034 Perl does not handle multi-byte locales, such as have been used for various
1035 Asian languages, such as Big5 or Shift JIS. However, the increasingly common
1036 multi-byte UTF-8 locales, if properly implemented, tend to work
1037 reasonably well in Perl, simply because both they and Perl store
1038 characters that take up multiple bytes the same way.
1040 Perl generally takes the tack to use locale rules on code points that can fit
1041 in a single byte, and Unicode rules for those that can't (though this wasn't
1042 uniformly applied prior to Perl 5.14). This prevents many problems in locales
1043 that aren't UTF-8. Suppose the locale is ISO8859-7, Greek. The character at
1044 0xD7 there is a capital Chi. But in the ISO8859-1 locale, Latin1, it is a
1045 multiplication sign. The POSIX regular expression character class
1046 C<[[:alpha:]]> will magically match 0xD7 in the Greek locale but not in the
1047 Latin one, even if the string is encoded in UTF-8, which would normally imply
1048 Unicode semantics. (The "U" in UTF-8 stands for Unicode.)
1050 However, there are places where this breaks down. Certain constructs are
1051 for Unicode only, such as C<\p{Alpha}>. They assume that 0xD7 always has its
1052 Unicode meaning (or the equivalent on EBCDIC platforms). Since Latin1 is a
1053 subset of Unicode and 0xD7 is the multiplication sign in both Latin1 and
1054 Unicode, C<\p{Alpha}> will never match it, regardless of locale. A similar
1055 issue occurs with C<\N{...}>. It is therefore a bad idea to use C<\p{}> or
1056 C<\N{}> under C<use locale>--I<unless> you can guarantee that the locale will
1057 be a ISO8859-1 or UTF-8 one. Use POSIX character classes instead.
1060 The same problem ensues if you enable automatic UTF-8-ification of your
1061 standard file handles, default C<open()> layer, and C<@ARGV> on non-ISO8859-1,
1062 non-UTF-8 locales (by using either the B<-C> command line switch or the
1063 C<PERL_UNICODE> environment variable; see L<perlrun>).
1064 Things are read in as UTF-8, which would normally imply a Unicode
1065 interpretation, but the presence of a locale causes them to be interpreted
1066 in that locale instead. For example, a 0xD7 code point in the Unicode
1067 input, which should mean the multiplication sign, won't be interpreted by
1068 Perl that way under the Greek locale. Again, this is not a problem
1069 I<provided> you make certain that all locales will always and only be either
1070 an ISO8859-1 or a UTF-8 locale.
1072 Vendor locales are notoriously buggy, and it is difficult for Perl to test
1073 its locale-handling code because this interacts with code that Perl has no
1074 control over; therefore the locale-handling code in Perl may be buggy as
1075 well. But if you I<do> have locales that work, using them may be
1076 worthwhile for certain specific purposes, as long as you keep in mind the
1077 gotchas already mentioned. For example, collation runs faster under
1078 locales than under L<Unicode::Collate> (albeit with less flexibility), and
1079 you gain access to such things as the local currency symbol and the names
1080 of the months and days of the week.
1084 =head2 Broken systems
1086 In certain systems, the operating system's locale support
1087 is broken and cannot be fixed or used by Perl. Such deficiencies can
1088 and will result in mysterious hangs and/or Perl core dumps when
1089 C<use locale> is in effect. When confronted with such a system,
1090 please report in excruciating detail to <F<perlbug@perl.org>>, and
1091 also contact your vendor: bug fixes may exist for these problems
1092 in your operating system. Sometimes such bug fixes are called an
1093 operating system upgrade.
1097 L<I18N::Langinfo>, L<perluniintro>, L<perlunicode>, L<open>,
1098 L<POSIX/isalnum>, L<POSIX/isalpha>,
1099 L<POSIX/isdigit>, L<POSIX/isgraph>, L<POSIX/islower>,
1100 L<POSIX/isprint>, L<POSIX/ispunct>, L<POSIX/isspace>,
1101 L<POSIX/isupper>, L<POSIX/isxdigit>, L<POSIX/localeconv>,
1102 L<POSIX/setlocale>, L<POSIX/strcoll>, L<POSIX/strftime>,
1103 L<POSIX/strtod>, L<POSIX/strxfrm>.
1107 Jarkko Hietaniemi's original F<perli18n.pod> heavily hacked by Dominic
1108 Dunlop, assisted by the perl5-porters. Prose worked over a bit by
1109 Tom Christiansen, and updated by Perl 5 porters.