| 1 | =head1 NAME |
| 2 | X<operator> |
| 3 | |
| 4 | perlop - Perl expressions: operators, precedence, string literals |
| 5 | |
| 6 | =head1 DESCRIPTION |
| 7 | |
| 8 | In Perl, the operator determines what operation is performed, |
| 9 | independent of the type of the operands. For example S<C<$x + $y>> |
| 10 | is always a numeric addition, and if C<$x> or C<$y> do not contain |
| 11 | numbers, an attempt is made to convert them to numbers first. |
| 12 | |
| 13 | This is in contrast to many other dynamic languages, where the |
| 14 | operation is determined by the type of the first argument. It also |
| 15 | means that Perl has two versions of some operators, one for numeric |
| 16 | and one for string comparison. For example S<C<$x == $y>> compares |
| 17 | two numbers for equality, and S<C<$x eq $y>> compares two strings. |
| 18 | |
| 19 | There are a few exceptions though: C<x> can be either string |
| 20 | repetition or list repetition, depending on the type of the left |
| 21 | operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit |
| 22 | operations. |
| 23 | |
| 24 | =head2 Operator Precedence and Associativity |
| 25 | X<operator, precedence> X<precedence> X<associativity> |
| 26 | |
| 27 | Operator precedence and associativity work in Perl more or less like |
| 28 | they do in mathematics. |
| 29 | |
| 30 | I<Operator precedence> means some operators group more tightly than others. |
| 31 | For example, in C<2 + 4 * 5>, the multiplication has higher precedence, so C<4 |
| 32 | * 5> is grouped together as the right-hand operand of the addition, rather |
| 33 | than C<2 + 4> being grouped together as the left-hand operand of the |
| 34 | multiplication. It is as if the expression were written C<2 + (4 * 5)>, not |
| 35 | C<(2 + 4) * 5>. So the expression yields C<2 + 20 == 22>, rather than |
| 36 | C<6 * 5 == 30>. |
| 37 | |
| 38 | I<Operator associativity> defines what happens if a sequence of the same |
| 39 | operators is used one after another: |
| 40 | usually that they will be grouped at the left |
| 41 | or the right. For example, in C<9 - 3 - 2>, subtraction is left associative, |
| 42 | so C<9 - 3> is grouped together as the left-hand operand of the second |
| 43 | subtraction, rather than C<3 - 2> being grouped together as the right-hand |
| 44 | operand of the first subtraction. It is as if the expression were written |
| 45 | C<(9 - 3) - 2>, not C<9 - (3 - 2)>. So the expression yields C<6 - 2 == 4>, |
| 46 | rather than C<9 - 1 == 8>. |
| 47 | |
| 48 | For simple operators that evaluate all their operands and then combine the |
| 49 | values in some way, precedence and associativity (and parentheses) imply some |
| 50 | ordering requirements on those combining operations. For example, in C<2 + 4 * |
| 51 | 5>, the grouping implied by precedence means that the multiplication of 4 and |
| 52 | 5 must be performed before the addition of 2 and 20, simply because the result |
| 53 | of that multiplication is required as one of the operands of the addition. But |
| 54 | the order of operations is not fully determined by this: in C<2 * 2 + 4 * 5> |
| 55 | both multiplications must be performed before the addition, but the grouping |
| 56 | does not say anything about the order in which the two multiplications are |
| 57 | performed. In fact Perl has a general rule that the operands of an operator |
| 58 | are evaluated in left-to-right order. A few operators such as C<&&=> have |
| 59 | special evaluation rules that can result in an operand not being evaluated at |
| 60 | all; in general, the top-level operator in an expression has control of |
| 61 | operand evaluation. |
| 62 | |
| 63 | Some comparison operators, as their associativity, I<chain> with some |
| 64 | operators of the same precedence (but never with operators of different |
| 65 | precedence). This chaining means that each comparison is performed |
| 66 | on the two arguments surrounding it, with each interior argument taking |
| 67 | part in two comparisons, and the comparison results are implicitly ANDed. |
| 68 | Thus S<C<"$x E<lt> $y E<lt>= $z">> behaves exactly like S<C<"$x E<lt> |
| 69 | $y && $y E<lt>= $z">>, assuming that C<"$y"> is as simple a scalar as |
| 70 | it looks. The ANDing short-circuits just like C<"&&"> does, stopping |
| 71 | the sequence of comparisons as soon as one yields false. |
| 72 | |
| 73 | In a chained comparison, each argument expression is evaluated at most |
| 74 | once, even if it takes part in two comparisons, but the result of the |
| 75 | evaluation is fetched for each comparison. (It is not evaluated |
| 76 | at all if the short-circuiting means that it's not required for any |
| 77 | comparisons.) This matters if the computation of an interior argument |
| 78 | is expensive or non-deterministic. For example, |
| 79 | |
| 80 | if($x < expensive_sub() <= $z) { ... |
| 81 | |
| 82 | is not entirely like |
| 83 | |
| 84 | if($x < expensive_sub() && expensive_sub() <= $z) { ... |
| 85 | |
| 86 | but instead closer to |
| 87 | |
| 88 | my $tmp = expensive_sub(); |
| 89 | if($x < $tmp && $tmp <= $z) { ... |
| 90 | |
| 91 | in that the subroutine is only called once. However, it's not exactly |
| 92 | like this latter code either, because the chained comparison doesn't |
| 93 | actually involve any temporary variable (named or otherwise): there is |
| 94 | no assignment. This doesn't make much difference where the expression |
| 95 | is a call to an ordinary subroutine, but matters more with an lvalue |
| 96 | subroutine, or if the argument expression yields some unusual kind of |
| 97 | scalar by other means. For example, if the argument expression yields |
| 98 | a tied scalar, then the expression is evaluated to produce that scalar |
| 99 | at most once, but the value of that scalar may be fetched up to twice, |
| 100 | once for each comparison in which it is actually used. |
| 101 | |
| 102 | In this example, the expression is evaluated only once, and the tied |
| 103 | scalar (the result of the expression) is fetched for each comparison that |
| 104 | uses it. |
| 105 | |
| 106 | if ($x < $tied_scalar < $z) { ... |
| 107 | |
| 108 | In the next example, the expression is evaluated only once, and the tied |
| 109 | scalar is fetched once as part of the operation within the expression. |
| 110 | The result of that operation is fetched for each comparison, which |
| 111 | normally doesn't matter unless that expression result is also magical due |
| 112 | to operator overloading. |
| 113 | |
| 114 | if ($x < $tied_scalar + 42 < $z) { ... |
| 115 | |
| 116 | Some operators are instead non-associative, meaning that it is a syntax |
| 117 | error to use a sequence of those operators of the same precedence. |
| 118 | For example, S<C<"$x .. $y .. $z">> is an error. |
| 119 | |
| 120 | Perl operators have the following associativity and precedence, |
| 121 | listed from highest precedence to lowest. Operators borrowed from |
| 122 | C keep the same precedence relationship with each other, even where |
| 123 | C's precedence is slightly screwy. (This makes learning Perl easier |
| 124 | for C folks.) With very few exceptions, these all operate on scalar |
| 125 | values only, not array values. |
| 126 | |
| 127 | left terms and list operators (leftward) |
| 128 | left -> |
| 129 | nonassoc ++ -- |
| 130 | right ** |
| 131 | right ! ~ ~. \ and unary + and - |
| 132 | left =~ !~ |
| 133 | left * / % x |
| 134 | left + - . |
| 135 | left << >> |
| 136 | nonassoc named unary operators |
| 137 | nonassoc isa |
| 138 | chained < > <= >= lt gt le ge |
| 139 | chain/na == != eq ne <=> cmp ~~ |
| 140 | left & &. |
| 141 | left | |. ^ ^. |
| 142 | left && |
| 143 | left || // |
| 144 | nonassoc .. ... |
| 145 | right ?: |
| 146 | right = += -= *= etc. goto last next redo dump |
| 147 | left , => |
| 148 | nonassoc list operators (rightward) |
| 149 | right not |
| 150 | left and |
| 151 | left or xor |
| 152 | |
| 153 | In the following sections, these operators are covered in detail, in the |
| 154 | same order in which they appear in the table above. |
| 155 | |
| 156 | Many operators can be overloaded for objects. See L<overload>. |
| 157 | |
| 158 | =head2 Terms and List Operators (Leftward) |
| 159 | X<list operator> X<operator, list> X<term> |
| 160 | |
| 161 | A TERM has the highest precedence in Perl. They include variables, |
| 162 | quote and quote-like operators, any expression in parentheses, |
| 163 | and any function whose arguments are parenthesized. Actually, there |
| 164 | aren't really functions in this sense, just list operators and unary |
| 165 | operators behaving as functions because you put parentheses around |
| 166 | the arguments. These are all documented in L<perlfunc>. |
| 167 | |
| 168 | If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.) |
| 169 | is followed by a left parenthesis as the next token, the operator and |
| 170 | arguments within parentheses are taken to be of highest precedence, |
| 171 | just like a normal function call. |
| 172 | |
| 173 | In the absence of parentheses, the precedence of list operators such as |
| 174 | C<print>, C<sort>, or C<chmod> is either very high or very low depending on |
| 175 | whether you are looking at the left side or the right side of the operator. |
| 176 | For example, in |
| 177 | |
| 178 | @ary = (1, 3, sort 4, 2); |
| 179 | print @ary; # prints 1324 |
| 180 | |
| 181 | the commas on the right of the C<sort> are evaluated before the C<sort>, |
| 182 | but the commas on the left are evaluated after. In other words, |
| 183 | list operators tend to gobble up all arguments that follow, and |
| 184 | then act like a simple TERM with regard to the preceding expression. |
| 185 | Be careful with parentheses: |
| 186 | |
| 187 | # These evaluate exit before doing the print: |
| 188 | print($foo, exit); # Obviously not what you want. |
| 189 | print $foo, exit; # Nor is this. |
| 190 | |
| 191 | # These do the print before evaluating exit: |
| 192 | (print $foo), exit; # This is what you want. |
| 193 | print($foo), exit; # Or this. |
| 194 | print ($foo), exit; # Or even this. |
| 195 | |
| 196 | Also note that |
| 197 | |
| 198 | print ($foo & 255) + 1, "\n"; |
| 199 | |
| 200 | probably doesn't do what you expect at first glance. The parentheses |
| 201 | enclose the argument list for C<print> which is evaluated (printing |
| 202 | the result of S<C<$foo & 255>>). Then one is added to the return value |
| 203 | of C<print> (usually 1). The result is something like this: |
| 204 | |
| 205 | 1 + 1, "\n"; # Obviously not what you meant. |
| 206 | |
| 207 | To do what you meant properly, you must write: |
| 208 | |
| 209 | print(($foo & 255) + 1, "\n"); |
| 210 | |
| 211 | See L</Named Unary Operators> for more discussion of this. |
| 212 | |
| 213 | Also parsed as terms are the S<C<do {}>> and S<C<eval {}>> constructs, as |
| 214 | well as subroutine and method calls, and the anonymous |
| 215 | constructors C<[]> and C<{}>. |
| 216 | |
| 217 | See also L</Quote and Quote-like Operators> toward the end of this section, |
| 218 | as well as L</"I/O Operators">. |
| 219 | |
| 220 | =head2 The Arrow Operator |
| 221 | X<arrow> X<dereference> X<< -> >> |
| 222 | |
| 223 | "C<< -> >>" is an infix dereference operator, just as it is in C |
| 224 | and C++. If the right side is either a C<[...]>, C<{...}>, or a |
| 225 | C<(...)> subscript, then the left side must be either a hard or |
| 226 | symbolic reference to an array, a hash, or a subroutine respectively. |
| 227 | (Or technically speaking, a location capable of holding a hard |
| 228 | reference, if it's an array or hash reference being used for |
| 229 | assignment.) See L<perlreftut> and L<perlref>. |
| 230 | |
| 231 | Otherwise, the right side is a method name or a simple scalar |
| 232 | variable containing either the method name or a subroutine reference, |
| 233 | and (if it is a method name) the left side must be either an object (a |
| 234 | blessed reference) or a class name (that is, a package name). See |
| 235 | L<perlobj>. |
| 236 | |
| 237 | The dereferencing cases (as opposed to method-calling cases) are |
| 238 | somewhat extended by the C<postderef> feature. For the |
| 239 | details of that feature, consult L<perlref/Postfix Dereference Syntax>. |
| 240 | |
| 241 | =head2 Auto-increment and Auto-decrement |
| 242 | X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<--> |
| 243 | |
| 244 | C<"++"> and C<"--"> work as in C. That is, if placed before a variable, |
| 245 | they increment or decrement the variable by one before returning the |
| 246 | value, and if placed after, increment or decrement after returning the |
| 247 | value. |
| 248 | |
| 249 | $i = 0; $j = 0; |
| 250 | print $i++; # prints 0 |
| 251 | print ++$j; # prints 1 |
| 252 | |
| 253 | Note that just as in C, Perl doesn't define B<when> the variable is |
| 254 | incremented or decremented. You just know it will be done sometime |
| 255 | before or after the value is returned. This also means that modifying |
| 256 | a variable twice in the same statement will lead to undefined behavior. |
| 257 | Avoid statements like: |
| 258 | |
| 259 | $i = $i ++; |
| 260 | print ++ $i + $i ++; |
| 261 | |
| 262 | Perl will not guarantee what the result of the above statements is. |
| 263 | |
| 264 | The auto-increment operator has a little extra builtin magic to it. If |
| 265 | you increment a variable that is numeric, or that has ever been used in |
| 266 | a numeric context, you get a normal increment. If, however, the |
| 267 | variable has been used in only string contexts since it was set, and |
| 268 | has a value that is not the empty string and matches the pattern |
| 269 | C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each |
| 270 | character within its range, with carry: |
| 271 | |
| 272 | print ++($foo = "99"); # prints "100" |
| 273 | print ++($foo = "a0"); # prints "a1" |
| 274 | print ++($foo = "Az"); # prints "Ba" |
| 275 | print ++($foo = "zz"); # prints "aaa" |
| 276 | |
| 277 | C<undef> is always treated as numeric, and in particular is changed |
| 278 | to C<0> before incrementing (so that a post-increment of an undef value |
| 279 | will return C<0> rather than C<undef>). |
| 280 | |
| 281 | The auto-decrement operator is not magical. |
| 282 | |
| 283 | =head2 Exponentiation |
| 284 | X<**> X<exponentiation> X<power> |
| 285 | |
| 286 | Binary C<"**"> is the exponentiation operator. It binds even more |
| 287 | tightly than unary minus, so C<-2**4> is C<-(2**4)>, not C<(-2)**4>. |
| 288 | (This is |
| 289 | implemented using C's C<pow(3)> function, which actually works on doubles |
| 290 | internally.) |
| 291 | |
| 292 | Note that certain exponentiation expressions are ill-defined: |
| 293 | these include C<0**0>, C<1**Inf>, and C<Inf**0>. Do not expect |
| 294 | any particular results from these special cases, the results |
| 295 | are platform-dependent. |
| 296 | |
| 297 | =head2 Symbolic Unary Operators |
| 298 | X<unary operator> X<operator, unary> |
| 299 | |
| 300 | Unary C<"!"> performs logical negation, that is, "not". See also |
| 301 | L<C<not>|/Logical Not> for a lower precedence version of this. |
| 302 | X<!> |
| 303 | |
| 304 | Unary C<"-"> performs arithmetic negation if the operand is numeric, |
| 305 | including any string that looks like a number. If the operand is |
| 306 | an identifier, a string consisting of a minus sign concatenated |
| 307 | with the identifier is returned. Otherwise, if the string starts |
| 308 | with a plus or minus, a string starting with the opposite sign is |
| 309 | returned. One effect of these rules is that C<-bareword> is equivalent |
| 310 | to the string C<"-bareword">. If, however, the string begins with a |
| 311 | non-alphabetic character (excluding C<"+"> or C<"-">), Perl will attempt |
| 312 | to convert |
| 313 | the string to a numeric, and the arithmetic negation is performed. If the |
| 314 | string cannot be cleanly converted to a numeric, Perl will give the warning |
| 315 | B<Argument "the string" isn't numeric in negation (-) at ...>. |
| 316 | X<-> X<negation, arithmetic> |
| 317 | |
| 318 | Unary C<"~"> performs bitwise negation, that is, 1's complement. For |
| 319 | example, S<C<0666 & ~027>> is 0640. (See also L</Integer Arithmetic> and |
| 320 | L</Bitwise String Operators>.) Note that the width of the result is |
| 321 | platform-dependent: C<~0> is 32 bits wide on a 32-bit platform, but 64 |
| 322 | bits wide on a 64-bit platform, so if you are expecting a certain bit |
| 323 | width, remember to use the C<"&"> operator to mask off the excess bits. |
| 324 | X<~> X<negation, binary> |
| 325 | |
| 326 | Starting in Perl 5.28, it is a fatal error to try to complement a string |
| 327 | containing a character with an ordinal value above 255. |
| 328 | |
| 329 | If the "bitwise" feature is enabled via S<C<use |
| 330 | feature 'bitwise'>> or C<use v5.28>, then unary |
| 331 | C<"~"> always treats its argument as a number, and an |
| 332 | alternate form of the operator, C<"~.">, always treats its argument as a |
| 333 | string. So C<~0> and C<~"0"> will both give 2**32-1 on 32-bit platforms, |
| 334 | whereas C<~.0> and C<~."0"> will both yield C<"\xff">. Until Perl 5.28, |
| 335 | this feature produced a warning in the C<"experimental::bitwise"> category. |
| 336 | |
| 337 | Unary C<"+"> has no effect whatsoever, even on strings. It is useful |
| 338 | syntactically for separating a function name from a parenthesized expression |
| 339 | that would otherwise be interpreted as the complete list of function |
| 340 | arguments. (See examples above under L</Terms and List Operators (Leftward)>.) |
| 341 | X<+> |
| 342 | |
| 343 | Unary C<"\"> creates references. If its operand is a single sigilled |
| 344 | thing, it creates a reference to that object. If its operand is a |
| 345 | parenthesised list, then it creates references to the things mentioned |
| 346 | in the list. Otherwise it puts its operand in list context, and creates |
| 347 | a list of references to the scalars in the list provided by the operand. |
| 348 | See L<perlreftut> |
| 349 | and L<perlref>. Do not confuse this behavior with the behavior of |
| 350 | backslash within a string, although both forms do convey the notion |
| 351 | of protecting the next thing from interpolation. |
| 352 | X<\> X<reference> X<backslash> |
| 353 | |
| 354 | =head2 Binding Operators |
| 355 | X<binding> X<operator, binding> X<=~> X<!~> |
| 356 | |
| 357 | Binary C<"=~"> binds a scalar expression to a pattern match. Certain operations |
| 358 | search or modify the string C<$_> by default. This operator makes that kind |
| 359 | of operation work on some other string. The right argument is a search |
| 360 | pattern, substitution, or transliteration. The left argument is what is |
| 361 | supposed to be searched, substituted, or transliterated instead of the default |
| 362 | C<$_>. When used in scalar context, the return value generally indicates the |
| 363 | success of the operation. The exceptions are substitution (C<s///>) |
| 364 | and transliteration (C<y///>) with the C</r> (non-destructive) option, |
| 365 | which cause the B<r>eturn value to be the result of the substitution. |
| 366 | Behavior in list context depends on the particular operator. |
| 367 | See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for |
| 368 | examples using these operators. |
| 369 | |
| 370 | If the right argument is an expression rather than a search pattern, |
| 371 | substitution, or transliteration, it is interpreted as a search pattern at run |
| 372 | time. Note that this means that its |
| 373 | contents will be interpolated twice, so |
| 374 | |
| 375 | '\\' =~ q'\\'; |
| 376 | |
| 377 | is not ok, as the regex engine will end up trying to compile the |
| 378 | pattern C<\>, which it will consider a syntax error. |
| 379 | |
| 380 | Binary C<"!~"> is just like C<"=~"> except the return value is negated in |
| 381 | the logical sense. |
| 382 | |
| 383 | Binary C<"!~"> with a non-destructive substitution (C<s///r>) or transliteration |
| 384 | (C<y///r>) is a syntax error. |
| 385 | |
| 386 | =head2 Multiplicative Operators |
| 387 | X<operator, multiplicative> |
| 388 | |
| 389 | Binary C<"*"> multiplies two numbers. |
| 390 | X<*> |
| 391 | |
| 392 | Binary C<"/"> divides two numbers. |
| 393 | X</> X<slash> |
| 394 | |
| 395 | Binary C<"%"> is the modulo operator, which computes the division |
| 396 | remainder of its first argument with respect to its second argument. |
| 397 | Given integer |
| 398 | operands C<$m> and C<$n>: If C<$n> is positive, then S<C<$m % $n>> is |
| 399 | C<$m> minus the largest multiple of C<$n> less than or equal to |
| 400 | C<$m>. If C<$n> is negative, then S<C<$m % $n>> is C<$m> minus the |
| 401 | smallest multiple of C<$n> that is not less than C<$m> (that is, the |
| 402 | result will be less than or equal to zero). If the operands |
| 403 | C<$m> and C<$n> are floating point values and the absolute value of |
| 404 | C<$n> (that is C<abs($n)>) is less than S<C<(UV_MAX + 1)>>, only |
| 405 | the integer portion of C<$m> and C<$n> will be used in the operation |
| 406 | (Note: here C<UV_MAX> means the maximum of the unsigned integer type). |
| 407 | If the absolute value of the right operand (C<abs($n)>) is greater than |
| 408 | or equal to S<C<(UV_MAX + 1)>>, C<"%"> computes the floating-point remainder |
| 409 | C<$r> in the equation S<C<($r = $m - $i*$n)>> where C<$i> is a certain |
| 410 | integer that makes C<$r> have the same sign as the right operand |
| 411 | C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>) |
| 412 | and the absolute value less than that of C<$n>. |
| 413 | Note that when S<C<use integer>> is in scope, C<"%"> gives you direct access |
| 414 | to the modulo operator as implemented by your C compiler. This |
| 415 | operator is not as well defined for negative operands, but it will |
| 416 | execute faster. |
| 417 | X<%> X<remainder> X<modulo> X<mod> |
| 418 | |
| 419 | Binary C<x> is the repetition operator. In scalar context, or if the |
| 420 | left operand is neither enclosed in parentheses nor a C<qw//> list, |
| 421 | it performs a string repetition. In that case it supplies scalar |
| 422 | context to the left operand, and returns a string consisting of the |
| 423 | left operand string repeated the number of times specified by the right |
| 424 | operand. If the C<x> is in list context, and the left operand is either |
| 425 | enclosed in parentheses or a C<qw//> list, it performs a list repetition. |
| 426 | In that case it supplies list context to the left operand, and returns |
| 427 | a list consisting of the left operand list repeated the number of times |
| 428 | specified by the right operand. |
| 429 | If the right operand is zero or negative (raising a warning on |
| 430 | negative), it returns an empty string |
| 431 | or an empty list, depending on the context. |
| 432 | X<x> |
| 433 | |
| 434 | print '-' x 80; # print row of dashes |
| 435 | |
| 436 | print "\t" x ($tab/8), ' ' x ($tab%8); # tab over |
| 437 | |
| 438 | @ones = (1) x 80; # a list of 80 1's |
| 439 | @ones = (5) x @ones; # set all elements to 5 |
| 440 | |
| 441 | |
| 442 | =head2 Additive Operators |
| 443 | X<operator, additive> |
| 444 | |
| 445 | Binary C<"+"> returns the sum of two numbers. |
| 446 | X<+> |
| 447 | |
| 448 | Binary C<"-"> returns the difference of two numbers. |
| 449 | X<-> |
| 450 | |
| 451 | Binary C<"."> concatenates two strings. |
| 452 | X<string, concatenation> X<concatenation> |
| 453 | X<cat> X<concat> X<concatenate> X<.> |
| 454 | |
| 455 | =head2 Shift Operators |
| 456 | X<shift operator> X<operator, shift> X<<< << >>> |
| 457 | X<<< >> >>> X<right shift> X<left shift> X<bitwise shift> |
| 458 | X<shl> X<shr> X<shift, right> X<shift, left> |
| 459 | |
| 460 | Binary C<<< "<<" >>> returns the value of its left argument shifted left by the |
| 461 | number of bits specified by the right argument. Arguments should be |
| 462 | integers. (See also L</Integer Arithmetic>.) |
| 463 | |
| 464 | Binary C<<< ">>" >>> returns the value of its left argument shifted right by |
| 465 | the number of bits specified by the right argument. Arguments should |
| 466 | be integers. (See also L</Integer Arithmetic>.) |
| 467 | |
| 468 | If S<C<use integer>> (see L</Integer Arithmetic>) is in force then |
| 469 | signed C integers are used (I<arithmetic shift>), otherwise unsigned C |
| 470 | integers are used (I<logical shift>), even for negative shiftees. |
| 471 | In arithmetic right shift the sign bit is replicated on the left, |
| 472 | in logical shift zero bits come in from the left. |
| 473 | |
| 474 | Either way, the implementation isn't going to generate results larger |
| 475 | than the size of the integer type Perl was built with (32 bits or 64 bits). |
| 476 | |
| 477 | Shifting by negative number of bits means the reverse shift: left |
| 478 | shift becomes right shift, right shift becomes left shift. This is |
| 479 | unlike in C, where negative shift is undefined. |
| 480 | |
| 481 | Shifting by more bits than the size of the integers means most of the |
| 482 | time zero (all bits fall off), except that under S<C<use integer>> |
| 483 | right overshifting a negative shiftee results in -1. This is unlike |
| 484 | in C, where shifting by too many bits is undefined. A common C |
| 485 | behavior is "shift by modulo wordbits", so that for example |
| 486 | |
| 487 | 1 >> 64 == 1 >> (64 % 64) == 1 >> 0 == 1 # Common C behavior. |
| 488 | |
| 489 | but that is completely accidental. |
| 490 | |
| 491 | If you get tired of being subject to your platform's native integers, |
| 492 | the S<C<use bigint>> pragma neatly sidesteps the issue altogether: |
| 493 | |
| 494 | print 20 << 20; # 20971520 |
| 495 | print 20 << 40; # 5120 on 32-bit machines, |
| 496 | # 21990232555520 on 64-bit machines |
| 497 | use bigint; |
| 498 | print 20 << 100; # 25353012004564588029934064107520 |
| 499 | |
| 500 | =head2 Named Unary Operators |
| 501 | X<operator, named unary> |
| 502 | |
| 503 | The various named unary operators are treated as functions with one |
| 504 | argument, with optional parentheses. |
| 505 | |
| 506 | If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.) |
| 507 | is followed by a left parenthesis as the next token, the operator and |
| 508 | arguments within parentheses are taken to be of highest precedence, |
| 509 | just like a normal function call. For example, |
| 510 | because named unary operators are higher precedence than C<||>: |
| 511 | |
| 512 | chdir $foo || die; # (chdir $foo) || die |
| 513 | chdir($foo) || die; # (chdir $foo) || die |
| 514 | chdir ($foo) || die; # (chdir $foo) || die |
| 515 | chdir +($foo) || die; # (chdir $foo) || die |
| 516 | |
| 517 | but, because C<"*"> is higher precedence than named operators: |
| 518 | |
| 519 | chdir $foo * 20; # chdir ($foo * 20) |
| 520 | chdir($foo) * 20; # (chdir $foo) * 20 |
| 521 | chdir ($foo) * 20; # (chdir $foo) * 20 |
| 522 | chdir +($foo) * 20; # chdir ($foo * 20) |
| 523 | |
| 524 | rand 10 * 20; # rand (10 * 20) |
| 525 | rand(10) * 20; # (rand 10) * 20 |
| 526 | rand (10) * 20; # (rand 10) * 20 |
| 527 | rand +(10) * 20; # rand (10 * 20) |
| 528 | |
| 529 | Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are |
| 530 | treated like named unary operators, but they don't follow this functional |
| 531 | parenthesis rule. That means, for example, that C<-f($file).".bak"> is |
| 532 | equivalent to S<C<-f "$file.bak">>. |
| 533 | X<-X> X<filetest> X<operator, filetest> |
| 534 | |
| 535 | See also L</"Terms and List Operators (Leftward)">. |
| 536 | |
| 537 | =head2 Relational Operators |
| 538 | X<relational operator> X<operator, relational> |
| 539 | |
| 540 | Perl operators that return true or false generally return values |
| 541 | that can be safely used as numbers. For example, the relational |
| 542 | operators in this section and the equality operators in the next |
| 543 | one return C<1> for true and a special version of the defined empty |
| 544 | string, C<"">, which counts as a zero but is exempt from warnings |
| 545 | about improper numeric conversions, just as S<C<"0 but true">> is. |
| 546 | |
| 547 | Binary C<< "<" >> returns true if the left argument is numerically less than |
| 548 | the right argument. |
| 549 | X<< < >> |
| 550 | |
| 551 | Binary C<< ">" >> returns true if the left argument is numerically greater |
| 552 | than the right argument. |
| 553 | X<< > >> |
| 554 | |
| 555 | Binary C<< "<=" >> returns true if the left argument is numerically less than |
| 556 | or equal to the right argument. |
| 557 | X<< <= >> |
| 558 | |
| 559 | Binary C<< ">=" >> returns true if the left argument is numerically greater |
| 560 | than or equal to the right argument. |
| 561 | X<< >= >> |
| 562 | |
| 563 | Binary C<"lt"> returns true if the left argument is stringwise less than |
| 564 | the right argument. |
| 565 | X<< lt >> |
| 566 | |
| 567 | Binary C<"gt"> returns true if the left argument is stringwise greater |
| 568 | than the right argument. |
| 569 | X<< gt >> |
| 570 | |
| 571 | Binary C<"le"> returns true if the left argument is stringwise less than |
| 572 | or equal to the right argument. |
| 573 | X<< le >> |
| 574 | |
| 575 | Binary C<"ge"> returns true if the left argument is stringwise greater |
| 576 | than or equal to the right argument. |
| 577 | X<< ge >> |
| 578 | |
| 579 | A sequence of relational operators, such as S<C<"$x E<lt> $y E<lt>= |
| 580 | $z">>, performs chained comparisons, in the manner described above in |
| 581 | the section L</"Operator Precedence and Associativity">. |
| 582 | Beware that they do not chain with equality operators, which have lower |
| 583 | precedence. |
| 584 | |
| 585 | =head2 Equality Operators |
| 586 | X<equality> X<equal> X<equals> X<operator, equality> |
| 587 | |
| 588 | Binary C<< "==" >> returns true if the left argument is numerically equal to |
| 589 | the right argument. |
| 590 | X<==> |
| 591 | |
| 592 | Binary C<< "!=" >> returns true if the left argument is numerically not equal |
| 593 | to the right argument. |
| 594 | X<!=> |
| 595 | |
| 596 | Binary C<"eq"> returns true if the left argument is stringwise equal to |
| 597 | the right argument. |
| 598 | X<eq> |
| 599 | |
| 600 | Binary C<"ne"> returns true if the left argument is stringwise not equal |
| 601 | to the right argument. |
| 602 | X<ne> |
| 603 | |
| 604 | A sequence of the above equality operators, such as S<C<"$x == $y == |
| 605 | $z">>, performs chained comparisons, in the manner described above in |
| 606 | the section L</"Operator Precedence and Associativity">. |
| 607 | Beware that they do not chain with relational operators, which have |
| 608 | higher precedence. |
| 609 | |
| 610 | Binary C<< "<=>" >> returns -1, 0, or 1 depending on whether the left |
| 611 | argument is numerically less than, equal to, or greater than the right |
| 612 | argument. If your platform supports C<NaN>'s (not-a-numbers) as numeric |
| 613 | values, using them with C<< "<=>" >> returns undef. C<NaN> is not |
| 614 | C<< "<" >>, C<< "==" >>, C<< ">" >>, C<< "<=" >> or C<< ">=" >> anything |
| 615 | (even C<NaN>), so those 5 return false. S<C<< NaN != NaN >>> returns |
| 616 | true, as does S<C<NaN !=> I<anything else>>. If your platform doesn't |
| 617 | support C<NaN>'s then C<NaN> is just a string with numeric value 0. |
| 618 | X<< <=> >> |
| 619 | X<spaceship> |
| 620 | |
| 621 | $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x' |
| 622 | $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x' |
| 623 | |
| 624 | (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all |
| 625 | support C<"NaN">.) |
| 626 | |
| 627 | Binary C<"cmp"> returns -1, 0, or 1 depending on whether the left |
| 628 | argument is stringwise less than, equal to, or greater than the right |
| 629 | argument. |
| 630 | |
| 631 | Here we can see the difference between <=> and cmp, |
| 632 | |
| 633 | print 10 <=> 2 #prints 1 |
| 634 | print 10 cmp 2 #prints -1 |
| 635 | |
| 636 | (likewise between gt and >, lt and <, etc.) |
| 637 | X<cmp> |
| 638 | |
| 639 | Binary C<"~~"> does a smartmatch between its arguments. Smart matching |
| 640 | is described in the next section. |
| 641 | X<~~> |
| 642 | |
| 643 | The two-sided ordering operators C<"E<lt>=E<gt>"> and C<"cmp">, and the |
| 644 | smartmatch operator C<"~~">, are non-associative with respect to each |
| 645 | other and with respect to the equality operators of the same precedence. |
| 646 | |
| 647 | C<"lt">, C<"le">, C<"ge">, C<"gt"> and C<"cmp"> use the collation (sort) |
| 648 | order specified by the current C<LC_COLLATE> locale if a S<C<use |
| 649 | locale>> form that includes collation is in effect. See L<perllocale>. |
| 650 | Do not mix these with Unicode, |
| 651 | only use them with legacy 8-bit locale encodings. |
| 652 | The standard C<L<Unicode::Collate>> and |
| 653 | C<L<Unicode::Collate::Locale>> modules offer much more powerful |
| 654 | solutions to collation issues. |
| 655 | |
| 656 | For case-insensitive comparisons, look at the L<perlfunc/fc> case-folding |
| 657 | function, available in Perl v5.16 or later: |
| 658 | |
| 659 | if ( fc($x) eq fc($y) ) { ... } |
| 660 | |
| 661 | =head2 Class Instance Operator |
| 662 | X<isa operator> |
| 663 | |
| 664 | Binary C<isa> evaluates to true when the left argument is an object instance of |
| 665 | the class (or a subclass derived from that class) given by the right argument. |
| 666 | If the left argument is not defined, not a blessed object instance, nor does |
| 667 | not derive from the class given by the right argument, the operator evaluates |
| 668 | as false. The right argument may give the class either as a bareword or a |
| 669 | scalar expression that yields a string class name: |
| 670 | |
| 671 | if( $obj isa Some::Class ) { ... } |
| 672 | |
| 673 | if( $obj isa "Different::Class" ) { ... } |
| 674 | if( $obj isa $name_of_class ) { ... } |
| 675 | |
| 676 | This feature is available from Perl 5.31.6 onwards when enabled by |
| 677 | C<use feature 'isa'>. This feature is enabled automatically by a |
| 678 | C<use v5.36> (or higher) declaration in the current scope. |
| 679 | |
| 680 | =head2 Smartmatch Operator |
| 681 | |
| 682 | First available in Perl 5.10.1 (the 5.10.0 version behaved differently), |
| 683 | binary C<~~> does a "smartmatch" between its arguments. This is mostly |
| 684 | used implicitly in the C<when> construct described in L<perlsyn>, although |
| 685 | not all C<when> clauses call the smartmatch operator. Unique among all of |
| 686 | Perl's operators, the smartmatch operator can recurse. The smartmatch |
| 687 | operator is L<experimental|perlpolicy/experimental> and its behavior is |
| 688 | subject to change. |
| 689 | |
| 690 | It is also unique in that all other Perl operators impose a context |
| 691 | (usually string or numeric context) on their operands, autoconverting |
| 692 | those operands to those imposed contexts. In contrast, smartmatch |
| 693 | I<infers> contexts from the actual types of its operands and uses that |
| 694 | type information to select a suitable comparison mechanism. |
| 695 | |
| 696 | The C<~~> operator compares its operands "polymorphically", determining how |
| 697 | to compare them according to their actual types (numeric, string, array, |
| 698 | hash, etc.). Like the equality operators with which it shares the same |
| 699 | precedence, C<~~> returns 1 for true and C<""> for false. It is often best |
| 700 | read aloud as "in", "inside of", or "is contained in", because the left |
| 701 | operand is often looked for I<inside> the right operand. That makes the |
| 702 | order of the operands to the smartmatch operand often opposite that of |
| 703 | the regular match operator. In other words, the "smaller" thing is usually |
| 704 | placed in the left operand and the larger one in the right. |
| 705 | |
| 706 | The behavior of a smartmatch depends on what type of things its arguments |
| 707 | are, as determined by the following table. The first row of the table |
| 708 | whose types apply determines the smartmatch behavior. Because what |
| 709 | actually happens is mostly determined by the type of the second operand, |
| 710 | the table is sorted on the right operand instead of on the left. |
| 711 | |
| 712 | Left Right Description and pseudocode |
| 713 | =============================================================== |
| 714 | Any undef check whether Any is undefined |
| 715 | like: !defined Any |
| 716 | |
| 717 | Any Object invoke ~~ overloading on Object, or die |
| 718 | |
| 719 | Right operand is an ARRAY: |
| 720 | |
| 721 | Left Right Description and pseudocode |
| 722 | =============================================================== |
| 723 | ARRAY1 ARRAY2 recurse on paired elements of ARRAY1 and ARRAY2[2] |
| 724 | like: (ARRAY1[0] ~~ ARRAY2[0]) |
| 725 | && (ARRAY1[1] ~~ ARRAY2[1]) && ... |
| 726 | HASH ARRAY any ARRAY elements exist as HASH keys |
| 727 | like: grep { exists HASH->{$_} } ARRAY |
| 728 | Regexp ARRAY any ARRAY elements pattern match Regexp |
| 729 | like: grep { /Regexp/ } ARRAY |
| 730 | undef ARRAY undef in ARRAY |
| 731 | like: grep { !defined } ARRAY |
| 732 | Any ARRAY smartmatch each ARRAY element[3] |
| 733 | like: grep { Any ~~ $_ } ARRAY |
| 734 | |
| 735 | Right operand is a HASH: |
| 736 | |
| 737 | Left Right Description and pseudocode |
| 738 | =============================================================== |
| 739 | HASH1 HASH2 all same keys in both HASHes |
| 740 | like: keys HASH1 == |
| 741 | grep { exists HASH2->{$_} } keys HASH1 |
| 742 | ARRAY HASH any ARRAY elements exist as HASH keys |
| 743 | like: grep { exists HASH->{$_} } ARRAY |
| 744 | Regexp HASH any HASH keys pattern match Regexp |
| 745 | like: grep { /Regexp/ } keys HASH |
| 746 | undef HASH always false (undef cannot be a key) |
| 747 | like: 0 == 1 |
| 748 | Any HASH HASH key existence |
| 749 | like: exists HASH->{Any} |
| 750 | |
| 751 | Right operand is CODE: |
| 752 | |
| 753 | Left Right Description and pseudocode |
| 754 | =============================================================== |
| 755 | ARRAY CODE sub returns true on all ARRAY elements[1] |
| 756 | like: !grep { !CODE->($_) } ARRAY |
| 757 | HASH CODE sub returns true on all HASH keys[1] |
| 758 | like: !grep { !CODE->($_) } keys HASH |
| 759 | Any CODE sub passed Any returns true |
| 760 | like: CODE->(Any) |
| 761 | |
| 762 | Right operand is a Regexp: |
| 763 | |
| 764 | Left Right Description and pseudocode |
| 765 | =============================================================== |
| 766 | ARRAY Regexp any ARRAY elements match Regexp |
| 767 | like: grep { /Regexp/ } ARRAY |
| 768 | HASH Regexp any HASH keys match Regexp |
| 769 | like: grep { /Regexp/ } keys HASH |
| 770 | Any Regexp pattern match |
| 771 | like: Any =~ /Regexp/ |
| 772 | |
| 773 | Other: |
| 774 | |
| 775 | Left Right Description and pseudocode |
| 776 | =============================================================== |
| 777 | Object Any invoke ~~ overloading on Object, |
| 778 | or fall back to... |
| 779 | |
| 780 | Any Num numeric equality |
| 781 | like: Any == Num |
| 782 | Num nummy[4] numeric equality |
| 783 | like: Num == nummy |
| 784 | undef Any check whether undefined |
| 785 | like: !defined(Any) |
| 786 | Any Any string equality |
| 787 | like: Any eq Any |
| 788 | |
| 789 | |
| 790 | Notes: |
| 791 | |
| 792 | =over |
| 793 | |
| 794 | =item 1. |
| 795 | Empty hashes or arrays match. |
| 796 | |
| 797 | =item 2. |
| 798 | That is, each element smartmatches the element of the same index in the other array.[3] |
| 799 | |
| 800 | =item 3. |
| 801 | If a circular reference is found, fall back to referential equality. |
| 802 | |
| 803 | =item 4. |
| 804 | Either an actual number, or a string that looks like one. |
| 805 | |
| 806 | =back |
| 807 | |
| 808 | The smartmatch implicitly dereferences any non-blessed hash or array |
| 809 | reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases. |
| 810 | For blessed references, the C<I<Object>> entries apply. Smartmatches |
| 811 | involving hashes only consider hash keys, never hash values. |
| 812 | |
| 813 | The "like" code entry is not always an exact rendition. For example, the |
| 814 | smartmatch operator short-circuits whenever possible, but C<grep> does |
| 815 | not. Also, C<grep> in scalar context returns the number of matches, but |
| 816 | C<~~> returns only true or false. |
| 817 | |
| 818 | Unlike most operators, the smartmatch operator knows to treat C<undef> |
| 819 | specially: |
| 820 | |
| 821 | use v5.10.1; |
| 822 | @array = (1, 2, 3, undef, 4, 5); |
| 823 | say "some elements undefined" if undef ~~ @array; |
| 824 | |
| 825 | Each operand is considered in a modified scalar context, the modification |
| 826 | being that array and hash variables are passed by reference to the |
| 827 | operator, which implicitly dereferences them. Both elements |
| 828 | of each pair are the same: |
| 829 | |
| 830 | use v5.10.1; |
| 831 | |
| 832 | my %hash = (red => 1, blue => 2, green => 3, |
| 833 | orange => 4, yellow => 5, purple => 6, |
| 834 | black => 7, grey => 8, white => 9); |
| 835 | |
| 836 | my @array = qw(red blue green); |
| 837 | |
| 838 | say "some array elements in hash keys" if @array ~~ %hash; |
| 839 | say "some array elements in hash keys" if \@array ~~ \%hash; |
| 840 | |
| 841 | say "red in array" if "red" ~~ @array; |
| 842 | say "red in array" if "red" ~~ \@array; |
| 843 | |
| 844 | say "some keys end in e" if /e$/ ~~ %hash; |
| 845 | say "some keys end in e" if /e$/ ~~ \%hash; |
| 846 | |
| 847 | Two arrays smartmatch if each element in the first array smartmatches |
| 848 | (that is, is "in") the corresponding element in the second array, |
| 849 | recursively. |
| 850 | |
| 851 | use v5.10.1; |
| 852 | my @little = qw(red blue green); |
| 853 | my @bigger = ("red", "blue", [ "orange", "green" ] ); |
| 854 | if (@little ~~ @bigger) { # true! |
| 855 | say "little is contained in bigger"; |
| 856 | } |
| 857 | |
| 858 | Because the smartmatch operator recurses on nested arrays, this |
| 859 | will still report that "red" is in the array. |
| 860 | |
| 861 | use v5.10.1; |
| 862 | my @array = qw(red blue green); |
| 863 | my $nested_array = [[[[[[[ @array ]]]]]]]; |
| 864 | say "red in array" if "red" ~~ $nested_array; |
| 865 | |
| 866 | If two arrays smartmatch each other, then they are deep |
| 867 | copies of each others' values, as this example reports: |
| 868 | |
| 869 | use v5.12.0; |
| 870 | my @a = (0, 1, 2, [3, [4, 5], 6], 7); |
| 871 | my @b = (0, 1, 2, [3, [4, 5], 6], 7); |
| 872 | |
| 873 | if (@a ~~ @b && @b ~~ @a) { |
| 874 | say "a and b are deep copies of each other"; |
| 875 | } |
| 876 | elsif (@a ~~ @b) { |
| 877 | say "a smartmatches in b"; |
| 878 | } |
| 879 | elsif (@b ~~ @a) { |
| 880 | say "b smartmatches in a"; |
| 881 | } |
| 882 | else { |
| 883 | say "a and b don't smartmatch each other at all"; |
| 884 | } |
| 885 | |
| 886 | |
| 887 | If you were to set S<C<$b[3] = 4>>, then instead of reporting that "a and b |
| 888 | are deep copies of each other", it now reports that C<"b smartmatches in a">. |
| 889 | That's because the corresponding position in C<@a> contains an array that |
| 890 | (eventually) has a 4 in it. |
| 891 | |
| 892 | Smartmatching one hash against another reports whether both contain the |
| 893 | same keys, no more and no less. This could be used to see whether two |
| 894 | records have the same field names, without caring what values those fields |
| 895 | might have. For example: |
| 896 | |
| 897 | use v5.10.1; |
| 898 | sub make_dogtag { |
| 899 | state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 }; |
| 900 | |
| 901 | my ($class, $init_fields) = @_; |
| 902 | |
| 903 | die "Must supply (only) name, rank, and serial number" |
| 904 | unless $init_fields ~~ $REQUIRED_FIELDS; |
| 905 | |
| 906 | ... |
| 907 | } |
| 908 | |
| 909 | However, this only does what you mean if C<$init_fields> is indeed a hash |
| 910 | reference. The condition C<$init_fields ~~ $REQUIRED_FIELDS> also allows the |
| 911 | strings C<"name">, C<"rank">, C<"serial_num"> as well as any array reference |
| 912 | that contains C<"name"> or C<"rank"> or C<"serial_num"> anywhere to pass |
| 913 | through. |
| 914 | |
| 915 | The smartmatch operator is most often used as the implicit operator of a |
| 916 | C<when> clause. See the section on "Switch Statements" in L<perlsyn>. |
| 917 | |
| 918 | =head3 Smartmatching of Objects |
| 919 | |
| 920 | To avoid relying on an object's underlying representation, if the |
| 921 | smartmatch's right operand is an object that doesn't overload C<~~>, |
| 922 | it raises the exception "C<Smartmatching a non-overloaded object |
| 923 | breaks encapsulation>". That's because one has no business digging |
| 924 | around to see whether something is "in" an object. These are all |
| 925 | illegal on objects without a C<~~> overload: |
| 926 | |
| 927 | %hash ~~ $object |
| 928 | 42 ~~ $object |
| 929 | "fred" ~~ $object |
| 930 | |
| 931 | However, you can change the way an object is smartmatched by overloading |
| 932 | the C<~~> operator. This is allowed to |
| 933 | extend the usual smartmatch semantics. |
| 934 | For objects that do have an C<~~> overload, see L<overload>. |
| 935 | |
| 936 | Using an object as the left operand is allowed, although not very useful. |
| 937 | Smartmatching rules take precedence over overloading, so even if the |
| 938 | object in the left operand has smartmatch overloading, this will be |
| 939 | ignored. A left operand that is a non-overloaded object falls back on a |
| 940 | string or numeric comparison of whatever the C<ref> operator returns. That |
| 941 | means that |
| 942 | |
| 943 | $object ~~ X |
| 944 | |
| 945 | does I<not> invoke the overload method with C<I<X>> as an argument. |
| 946 | Instead the above table is consulted as normal, and based on the type of |
| 947 | C<I<X>>, overloading may or may not be invoked. For simple strings or |
| 948 | numbers, "in" becomes equivalent to this: |
| 949 | |
| 950 | $object ~~ $number ref($object) == $number |
| 951 | $object ~~ $string ref($object) eq $string |
| 952 | |
| 953 | For example, this reports that the handle smells IOish |
| 954 | (but please don't really do this!): |
| 955 | |
| 956 | use IO::Handle; |
| 957 | my $fh = IO::Handle->new(); |
| 958 | if ($fh ~~ /\bIO\b/) { |
| 959 | say "handle smells IOish"; |
| 960 | } |
| 961 | |
| 962 | That's because it treats C<$fh> as a string like |
| 963 | C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that. |
| 964 | |
| 965 | =head2 Bitwise And |
| 966 | X<operator, bitwise, and> X<bitwise and> X<&> |
| 967 | |
| 968 | Binary C<"&"> returns its operands ANDed together bit by bit. Although no |
| 969 | warning is currently raised, the result is not well defined when this operation |
| 970 | is performed on operands that aren't either numbers (see |
| 971 | L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String Operators>). |
| 972 | |
| 973 | Note that C<"&"> has lower priority than relational operators, so for example |
| 974 | the parentheses are essential in a test like |
| 975 | |
| 976 | print "Even\n" if ($x & 1) == 0; |
| 977 | |
| 978 | If the "bitwise" feature is enabled via S<C<use feature 'bitwise'>> or |
| 979 | C<use v5.28>, then this operator always treats its operands as numbers. |
| 980 | Before Perl 5.28 this feature produced a warning in the |
| 981 | C<"experimental::bitwise"> category. |
| 982 | |
| 983 | =head2 Bitwise Or and Exclusive Or |
| 984 | X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor> |
| 985 | X<bitwise xor> X<^> |
| 986 | |
| 987 | Binary C<"|"> returns its operands ORed together bit by bit. |
| 988 | |
| 989 | Binary C<"^"> returns its operands XORed together bit by bit. |
| 990 | |
| 991 | Although no warning is currently raised, the results are not well |
| 992 | defined when these operations are performed on operands that aren't either |
| 993 | numbers (see L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String |
| 994 | Operators>). |
| 995 | |
| 996 | Note that C<"|"> and C<"^"> have lower priority than relational operators, so |
| 997 | for example the parentheses are essential in a test like |
| 998 | |
| 999 | print "false\n" if (8 | 2) != 10; |
| 1000 | |
| 1001 | If the "bitwise" feature is enabled via S<C<use feature 'bitwise'>> or |
| 1002 | C<use v5.28>, then this operator always treats its operands as numbers. |
| 1003 | Before Perl 5.28. this feature produced a warning in the |
| 1004 | C<"experimental::bitwise"> category. |
| 1005 | |
| 1006 | =head2 C-style Logical And |
| 1007 | X<&&> X<logical and> X<operator, logical, and> |
| 1008 | |
| 1009 | Binary C<"&&"> performs a short-circuit logical AND operation. That is, |
| 1010 | if the left operand is false, the right operand is not even evaluated. |
| 1011 | Scalar or list context propagates down to the right operand if it |
| 1012 | is evaluated. |
| 1013 | |
| 1014 | =head2 C-style Logical Or |
| 1015 | X<||> X<operator, logical, or> |
| 1016 | |
| 1017 | Binary C<"||"> performs a short-circuit logical OR operation. That is, |
| 1018 | if the left operand is true, the right operand is not even evaluated. |
| 1019 | Scalar or list context propagates down to the right operand if it |
| 1020 | is evaluated. |
| 1021 | |
| 1022 | =head2 Logical Defined-Or |
| 1023 | X<//> X<operator, logical, defined-or> |
| 1024 | |
| 1025 | Although it has no direct equivalent in C, Perl's C<//> operator is related |
| 1026 | to its C-style "or". In fact, it's exactly the same as C<||>, except that it |
| 1027 | tests the left hand side's definedness instead of its truth. Thus, |
| 1028 | S<C<< EXPR1 // EXPR2 >>> returns the value of C<< EXPR1 >> if it's defined, |
| 1029 | otherwise, the value of C<< EXPR2 >> is returned. |
| 1030 | (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >> |
| 1031 | in the context of C<< // >> itself). Usually, |
| 1032 | this is the same result as S<C<< defined(EXPR1) ? EXPR1 : EXPR2 >>> (except that |
| 1033 | the ternary-operator form can be used as a lvalue, while S<C<< EXPR1 // EXPR2 >>> |
| 1034 | cannot). This is very useful for |
| 1035 | providing default values for variables. If you actually want to test if |
| 1036 | at least one of C<$x> and C<$y> is defined, use S<C<defined($x // $y)>>. |
| 1037 | |
| 1038 | The C<||>, C<//> and C<&&> operators return the last value evaluated |
| 1039 | (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably |
| 1040 | portable way to find out the home directory might be: |
| 1041 | |
| 1042 | $home = $ENV{HOME} |
| 1043 | // $ENV{LOGDIR} |
| 1044 | // (getpwuid($<))[7] |
| 1045 | // die "You're homeless!\n"; |
| 1046 | |
| 1047 | In particular, this means that you shouldn't use this |
| 1048 | for selecting between two aggregates for assignment: |
| 1049 | |
| 1050 | @a = @b || @c; # This doesn't do the right thing |
| 1051 | @a = scalar(@b) || @c; # because it really means this. |
| 1052 | @a = @b ? @b : @c; # This works fine, though. |
| 1053 | |
| 1054 | As alternatives to C<&&> and C<||> when used for |
| 1055 | control flow, Perl provides the C<and> and C<or> operators (see below). |
| 1056 | The short-circuit behavior is identical. The precedence of C<"and"> |
| 1057 | and C<"or"> is much lower, however, so that you can safely use them after a |
| 1058 | list operator without the need for parentheses: |
| 1059 | |
| 1060 | unlink "alpha", "beta", "gamma" |
| 1061 | or gripe(), next LINE; |
| 1062 | |
| 1063 | With the C-style operators that would have been written like this: |
| 1064 | |
| 1065 | unlink("alpha", "beta", "gamma") |
| 1066 | || (gripe(), next LINE); |
| 1067 | |
| 1068 | It would be even more readable to write that this way: |
| 1069 | |
| 1070 | unless(unlink("alpha", "beta", "gamma")) { |
| 1071 | gripe(); |
| 1072 | next LINE; |
| 1073 | } |
| 1074 | |
| 1075 | Using C<"or"> for assignment is unlikely to do what you want; see below. |
| 1076 | |
| 1077 | =head2 Range Operators |
| 1078 | X<operator, range> X<range> X<..> X<...> |
| 1079 | |
| 1080 | Binary C<".."> is the range operator, which is really two different |
| 1081 | operators depending on the context. In list context, it returns a |
| 1082 | list of values counting (up by ones) from the left value to the right |
| 1083 | value. If the left value is greater than the right value then it |
| 1084 | returns the empty list. The range operator is useful for writing |
| 1085 | S<C<foreach (1..10)>> loops and for doing slice operations on arrays. In |
| 1086 | the current implementation, no temporary array is created when the |
| 1087 | range operator is used as the expression in C<foreach> loops, but older |
| 1088 | versions of Perl might burn a lot of memory when you write something |
| 1089 | like this: |
| 1090 | |
| 1091 | for (1 .. 1_000_000) { |
| 1092 | # code |
| 1093 | } |
| 1094 | |
| 1095 | The range operator also works on strings, using the magical |
| 1096 | auto-increment, see below. |
| 1097 | |
| 1098 | In scalar context, C<".."> returns a boolean value. The operator is |
| 1099 | bistable, like a flip-flop, and emulates the line-range (comma) |
| 1100 | operator of B<sed>, B<awk>, and various editors. Each C<".."> operator |
| 1101 | maintains its own boolean state, even across calls to a subroutine |
| 1102 | that contains it. It is false as long as its left operand is false. |
| 1103 | Once the left operand is true, the range operator stays true until the |
| 1104 | right operand is true, I<AFTER> which the range operator becomes false |
| 1105 | again. It doesn't become false till the next time the range operator |
| 1106 | is evaluated. It can test the right operand and become false on the |
| 1107 | same evaluation it became true (as in B<awk>), but it still returns |
| 1108 | true once. If you don't want it to test the right operand until the |
| 1109 | next evaluation, as in B<sed>, just use three dots (C<"...">) instead of |
| 1110 | two. In all other regards, C<"..."> behaves just like C<".."> does. |
| 1111 | |
| 1112 | The right operand is not evaluated while the operator is in the |
| 1113 | "false" state, and the left operand is not evaluated while the |
| 1114 | operator is in the "true" state. The precedence is a little lower |
| 1115 | than || and &&. The value returned is either the empty string for |
| 1116 | false, or a sequence number (beginning with 1) for true. The sequence |
| 1117 | number is reset for each range encountered. The final sequence number |
| 1118 | in a range has the string C<"E0"> appended to it, which doesn't affect |
| 1119 | its numeric value, but gives you something to search for if you want |
| 1120 | to exclude the endpoint. You can exclude the beginning point by |
| 1121 | waiting for the sequence number to be greater than 1. |
| 1122 | |
| 1123 | If either operand of scalar C<".."> is a constant expression, |
| 1124 | that operand is considered true if it is equal (C<==>) to the current |
| 1125 | input line number (the C<$.> variable). |
| 1126 | |
| 1127 | To be pedantic, the comparison is actually S<C<int(EXPR) == int(EXPR)>>, |
| 1128 | but that is only an issue if you use a floating point expression; when |
| 1129 | implicitly using C<$.> as described in the previous paragraph, the |
| 1130 | comparison is S<C<int(EXPR) == int($.)>> which is only an issue when C<$.> |
| 1131 | is set to a floating point value and you are not reading from a file. |
| 1132 | Furthermore, S<C<"span" .. "spat">> or S<C<2.18 .. 3.14>> will not do what |
| 1133 | you want in scalar context because each of the operands are evaluated |
| 1134 | using their integer representation. |
| 1135 | |
| 1136 | Examples: |
| 1137 | |
| 1138 | As a scalar operator: |
| 1139 | |
| 1140 | if (101 .. 200) { print; } # print 2nd hundred lines, short for |
| 1141 | # if ($. == 101 .. $. == 200) { print; } |
| 1142 | |
| 1143 | next LINE if (1 .. /^$/); # skip header lines, short for |
| 1144 | # next LINE if ($. == 1 .. /^$/); |
| 1145 | # (typically in a loop labeled LINE) |
| 1146 | |
| 1147 | s/^/> / if (/^$/ .. eof()); # quote body |
| 1148 | |
| 1149 | # parse mail messages |
| 1150 | while (<>) { |
| 1151 | $in_header = 1 .. /^$/; |
| 1152 | $in_body = /^$/ .. eof; |
| 1153 | if ($in_header) { |
| 1154 | # do something |
| 1155 | } else { # in body |
| 1156 | # do something else |
| 1157 | } |
| 1158 | } continue { |
| 1159 | close ARGV if eof; # reset $. each file |
| 1160 | } |
| 1161 | |
| 1162 | Here's a simple example to illustrate the difference between |
| 1163 | the two range operators: |
| 1164 | |
| 1165 | @lines = (" - Foo", |
| 1166 | "01 - Bar", |
| 1167 | "1 - Baz", |
| 1168 | " - Quux"); |
| 1169 | |
| 1170 | foreach (@lines) { |
| 1171 | if (/0/ .. /1/) { |
| 1172 | print "$_\n"; |
| 1173 | } |
| 1174 | } |
| 1175 | |
| 1176 | This program will print only the line containing "Bar". If |
| 1177 | the range operator is changed to C<...>, it will also print the |
| 1178 | "Baz" line. |
| 1179 | |
| 1180 | And now some examples as a list operator: |
| 1181 | |
| 1182 | for (101 .. 200) { print } # print $_ 100 times |
| 1183 | @foo = @foo[0 .. $#foo]; # an expensive no-op |
| 1184 | @foo = @foo[$#foo-4 .. $#foo]; # slice last 5 items |
| 1185 | |
| 1186 | Because each operand is evaluated in integer form, S<C<2.18 .. 3.14>> will |
| 1187 | return two elements in list context. |
| 1188 | |
| 1189 | @list = (2.18 .. 3.14); # same as @list = (2 .. 3); |
| 1190 | |
| 1191 | The range operator in list context can make use of the magical |
| 1192 | auto-increment algorithm if both operands are strings, subject to the |
| 1193 | following rules: |
| 1194 | |
| 1195 | =over |
| 1196 | |
| 1197 | =item * |
| 1198 | |
| 1199 | With one exception (below), if both strings look like numbers to Perl, |
| 1200 | the magic increment will not be applied, and the strings will be treated |
| 1201 | as numbers (more specifically, integers) instead. |
| 1202 | |
| 1203 | For example, C<"-2".."2"> is the same as C<-2..2>, and |
| 1204 | C<"2.18".."3.14"> produces C<2, 3>. |
| 1205 | |
| 1206 | =item * |
| 1207 | |
| 1208 | The exception to the above rule is when the left-hand string begins with |
| 1209 | C<0> and is longer than one character, in this case the magic increment |
| 1210 | I<will> be applied, even though strings like C<"01"> would normally look |
| 1211 | like a number to Perl. |
| 1212 | |
| 1213 | For example, C<"01".."04"> produces C<"01", "02", "03", "04">, and |
| 1214 | C<"00".."-1"> produces C<"00"> through C<"99"> - this may seem |
| 1215 | surprising, but see the following rules for why it works this way. |
| 1216 | To get dates with leading zeros, you can say: |
| 1217 | |
| 1218 | @z2 = ("01" .. "31"); |
| 1219 | print $z2[$mday]; |
| 1220 | |
| 1221 | If you want to force strings to be interpreted as numbers, you could say |
| 1222 | |
| 1223 | @numbers = ( 0+$first .. 0+$last ); |
| 1224 | |
| 1225 | B<Note:> In Perl versions 5.30 and below, I<any> string on the left-hand |
| 1226 | side beginning with C<"0">, including the string C<"0"> itself, would |
| 1227 | cause the magic string increment behavior. This means that on these Perl |
| 1228 | versions, C<"0".."-1"> would produce C<"0"> through C<"99">, which was |
| 1229 | inconsistent with C<0..-1>, which produces the empty list. This also means |
| 1230 | that C<"0".."9"> now produces a list of integers instead of a list of |
| 1231 | strings. |
| 1232 | |
| 1233 | =item * |
| 1234 | |
| 1235 | If the initial value specified isn't part of a magical increment |
| 1236 | sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>), |
| 1237 | only the initial value will be returned. |
| 1238 | |
| 1239 | For example, C<"ax".."az"> produces C<"ax", "ay", "az">, but |
| 1240 | C<"*x".."az"> produces only C<"*x">. |
| 1241 | |
| 1242 | =item * |
| 1243 | |
| 1244 | For other initial values that are strings that do follow the rules of the |
| 1245 | magical increment, the corresponding sequence will be returned. |
| 1246 | |
| 1247 | For example, you can say |
| 1248 | |
| 1249 | @alphabet = ("A" .. "Z"); |
| 1250 | |
| 1251 | to get all normal letters of the English alphabet, or |
| 1252 | |
| 1253 | $hexdigit = (0 .. 9, "a" .. "f")[$num & 15]; |
| 1254 | |
| 1255 | to get a hexadecimal digit. |
| 1256 | |
| 1257 | =item * |
| 1258 | |
| 1259 | If the final value specified is not in the sequence that the magical |
| 1260 | increment would produce, the sequence goes until the next value would |
| 1261 | be longer than the final value specified. If the length of the final |
| 1262 | string is shorter than the first, the empty list is returned. |
| 1263 | |
| 1264 | For example, C<"a".."--"> is the same as C<"a".."zz">, C<"0".."xx"> |
| 1265 | produces C<"0"> through C<"99">, and C<"aaa".."--"> returns the empty |
| 1266 | list. |
| 1267 | |
| 1268 | =back |
| 1269 | |
| 1270 | As of Perl 5.26, the list-context range operator on strings works as expected |
| 1271 | in the scope of L<< S<C<"use feature 'unicode_strings">>|feature/The |
| 1272 | 'unicode_strings' feature >>. In previous versions, and outside the scope of |
| 1273 | that feature, it exhibits L<perlunicode/The "Unicode Bug">: its behavior |
| 1274 | depends on the internal encoding of the range endpoint. |
| 1275 | |
| 1276 | Because the magical increment only works on non-empty strings matching |
| 1277 | C</^[a-zA-Z]*[0-9]*\z/>, the following will only return an alpha: |
| 1278 | |
| 1279 | use charnames "greek"; |
| 1280 | my @greek_small = ("\N{alpha}" .. "\N{omega}"); |
| 1281 | |
| 1282 | To get the 25 traditional lowercase Greek letters, including both sigmas, |
| 1283 | you could use this instead: |
| 1284 | |
| 1285 | use charnames "greek"; |
| 1286 | my @greek_small = map { chr } ( ord("\N{alpha}") |
| 1287 | .. |
| 1288 | ord("\N{omega}") |
| 1289 | ); |
| 1290 | |
| 1291 | However, because there are I<many> other lowercase Greek characters than |
| 1292 | just those, to match lowercase Greek characters in a regular expression, |
| 1293 | you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the |
| 1294 | L<experimental feature|perlrecharclass/Extended Bracketed Character |
| 1295 | Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>). |
| 1296 | |
| 1297 | =head2 Conditional Operator |
| 1298 | X<operator, conditional> X<operator, ternary> X<ternary> X<?:> |
| 1299 | |
| 1300 | Ternary C<"?:"> is the conditional operator, just as in C. It works much |
| 1301 | like an if-then-else. If the argument before the C<?> is true, the |
| 1302 | argument before the C<:> is returned, otherwise the argument after the |
| 1303 | C<:> is returned. For example: |
| 1304 | |
| 1305 | printf "I have %d dog%s.\n", $n, |
| 1306 | ($n == 1) ? "" : "s"; |
| 1307 | |
| 1308 | Scalar or list context propagates downward into the 2nd |
| 1309 | or 3rd argument, whichever is selected. |
| 1310 | |
| 1311 | $x = $ok ? $y : $z; # get a scalar |
| 1312 | @x = $ok ? @y : @z; # get an array |
| 1313 | $x = $ok ? @y : @z; # oops, that's just a count! |
| 1314 | |
| 1315 | The operator may be assigned to if both the 2nd and 3rd arguments are |
| 1316 | legal lvalues (meaning that you can assign to them): |
| 1317 | |
| 1318 | ($x_or_y ? $x : $y) = $z; |
| 1319 | |
| 1320 | Because this operator produces an assignable result, using assignments |
| 1321 | without parentheses will get you in trouble. For example, this: |
| 1322 | |
| 1323 | $x % 2 ? $x += 10 : $x += 2 |
| 1324 | |
| 1325 | Really means this: |
| 1326 | |
| 1327 | (($x % 2) ? ($x += 10) : $x) += 2 |
| 1328 | |
| 1329 | Rather than this: |
| 1330 | |
| 1331 | ($x % 2) ? ($x += 10) : ($x += 2) |
| 1332 | |
| 1333 | That should probably be written more simply as: |
| 1334 | |
| 1335 | $x += ($x % 2) ? 10 : 2; |
| 1336 | |
| 1337 | =head2 Assignment Operators |
| 1338 | X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=> |
| 1339 | X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=> |
| 1340 | X<%=> X<^=> X<x=> X<&.=> X<|.=> X<^.=> |
| 1341 | |
| 1342 | C<"="> is the ordinary assignment operator. |
| 1343 | |
| 1344 | Assignment operators work as in C. That is, |
| 1345 | |
| 1346 | $x += 2; |
| 1347 | |
| 1348 | is equivalent to |
| 1349 | |
| 1350 | $x = $x + 2; |
| 1351 | |
| 1352 | although without duplicating any side effects that dereferencing the lvalue |
| 1353 | might trigger, such as from C<tie()>. Other assignment operators work similarly. |
| 1354 | The following are recognized: |
| 1355 | |
| 1356 | **= += *= &= &.= <<= &&= |
| 1357 | -= /= |= |.= >>= ||= |
| 1358 | .= %= ^= ^.= //= |
| 1359 | x= |
| 1360 | |
| 1361 | Although these are grouped by family, they all have the precedence |
| 1362 | of assignment. These combined assignment operators can only operate on |
| 1363 | scalars, whereas the ordinary assignment operator can assign to arrays, |
| 1364 | hashes, lists and even references. (See L<"Context"|perldata/Context> |
| 1365 | and L<perldata/List value constructors>, and L<perlref/Assigning to |
| 1366 | References>.) |
| 1367 | |
| 1368 | Unlike in C, the scalar assignment operator produces a valid lvalue. |
| 1369 | Modifying an assignment is equivalent to doing the assignment and |
| 1370 | then modifying the variable that was assigned to. This is useful |
| 1371 | for modifying a copy of something, like this: |
| 1372 | |
| 1373 | ($tmp = $global) =~ tr/13579/24680/; |
| 1374 | |
| 1375 | Although as of 5.14, that can be also be accomplished this way: |
| 1376 | |
| 1377 | use v5.14; |
| 1378 | $tmp = ($global =~ tr/13579/24680/r); |
| 1379 | |
| 1380 | Likewise, |
| 1381 | |
| 1382 | ($x += 2) *= 3; |
| 1383 | |
| 1384 | is equivalent to |
| 1385 | |
| 1386 | $x += 2; |
| 1387 | $x *= 3; |
| 1388 | |
| 1389 | Similarly, a list assignment in list context produces the list of |
| 1390 | lvalues assigned to, and a list assignment in scalar context returns |
| 1391 | the number of elements produced by the expression on the right hand |
| 1392 | side of the assignment. |
| 1393 | |
| 1394 | The three dotted bitwise assignment operators (C<&.=> C<|.=> C<^.=>) are new in |
| 1395 | Perl 5.22. See L</Bitwise String Operators>. |
| 1396 | |
| 1397 | =head2 Comma Operator |
| 1398 | X<comma> X<operator, comma> X<,> |
| 1399 | |
| 1400 | Binary C<","> is the comma operator. In scalar context it evaluates |
| 1401 | its left argument, throws that value away, then evaluates its right |
| 1402 | argument and returns that value. This is just like C's comma operator. |
| 1403 | |
| 1404 | In list context, it's just the list argument separator, and inserts |
| 1405 | both its arguments into the list. These arguments are also evaluated |
| 1406 | from left to right. |
| 1407 | |
| 1408 | The C<< => >> operator (sometimes pronounced "fat comma") is a synonym |
| 1409 | for the comma except that it causes a |
| 1410 | word on its left to be interpreted as a string if it begins with a letter |
| 1411 | or underscore and is composed only of letters, digits and underscores. |
| 1412 | This includes operands that might otherwise be interpreted as operators, |
| 1413 | constants, single number v-strings or function calls. If in doubt about |
| 1414 | this behavior, the left operand can be quoted explicitly. |
| 1415 | |
| 1416 | Otherwise, the C<< => >> operator behaves exactly as the comma operator |
| 1417 | or list argument separator, according to context. |
| 1418 | |
| 1419 | For example: |
| 1420 | |
| 1421 | use constant FOO => "something"; |
| 1422 | |
| 1423 | my %h = ( FOO => 23 ); |
| 1424 | |
| 1425 | is equivalent to: |
| 1426 | |
| 1427 | my %h = ("FOO", 23); |
| 1428 | |
| 1429 | It is I<NOT>: |
| 1430 | |
| 1431 | my %h = ("something", 23); |
| 1432 | |
| 1433 | The C<< => >> operator is helpful in documenting the correspondence |
| 1434 | between keys and values in hashes, and other paired elements in lists. |
| 1435 | |
| 1436 | %hash = ( $key => $value ); |
| 1437 | login( $username => $password ); |
| 1438 | |
| 1439 | The special quoting behavior ignores precedence, and hence may apply to |
| 1440 | I<part> of the left operand: |
| 1441 | |
| 1442 | print time.shift => "bbb"; |
| 1443 | |
| 1444 | That example prints something like C<"1314363215shiftbbb">, because the |
| 1445 | C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring |
| 1446 | the fact that C<time.shift> is the entire left operand. |
| 1447 | |
| 1448 | =head2 List Operators (Rightward) |
| 1449 | X<operator, list, rightward> X<list operator> |
| 1450 | |
| 1451 | On the right side of a list operator, the comma has very low precedence, |
| 1452 | such that it controls all comma-separated expressions found there. |
| 1453 | The only operators with lower precedence are the logical operators |
| 1454 | C<"and">, C<"or">, and C<"not">, which may be used to evaluate calls to list |
| 1455 | operators without the need for parentheses: |
| 1456 | |
| 1457 | open HANDLE, "< :encoding(UTF-8)", "filename" |
| 1458 | or die "Can't open: $!\n"; |
| 1459 | |
| 1460 | However, some people find that code harder to read than writing |
| 1461 | it with parentheses: |
| 1462 | |
| 1463 | open(HANDLE, "< :encoding(UTF-8)", "filename") |
| 1464 | or die "Can't open: $!\n"; |
| 1465 | |
| 1466 | in which case you might as well just use the more customary C<"||"> operator: |
| 1467 | |
| 1468 | open(HANDLE, "< :encoding(UTF-8)", "filename") |
| 1469 | || die "Can't open: $!\n"; |
| 1470 | |
| 1471 | See also discussion of list operators in L</Terms and List Operators (Leftward)>. |
| 1472 | |
| 1473 | =head2 Logical Not |
| 1474 | X<operator, logical, not> X<not> |
| 1475 | |
| 1476 | Unary C<"not"> returns the logical negation of the expression to its right. |
| 1477 | It's the equivalent of C<"!"> except for the very low precedence. |
| 1478 | |
| 1479 | =head2 Logical And |
| 1480 | X<operator, logical, and> X<and> |
| 1481 | |
| 1482 | Binary C<"and"> returns the logical conjunction of the two surrounding |
| 1483 | expressions. It's equivalent to C<&&> except for the very low |
| 1484 | precedence. This means that it short-circuits: the right |
| 1485 | expression is evaluated only if the left expression is true. |
| 1486 | |
| 1487 | =head2 Logical or and Exclusive Or |
| 1488 | X<operator, logical, or> X<operator, logical, xor> |
| 1489 | X<operator, logical, exclusive or> |
| 1490 | X<or> X<xor> |
| 1491 | |
| 1492 | Binary C<"or"> returns the logical disjunction of the two surrounding |
| 1493 | expressions. It's equivalent to C<||> except for the very low precedence. |
| 1494 | This makes it useful for control flow: |
| 1495 | |
| 1496 | print FH $data or die "Can't write to FH: $!"; |
| 1497 | |
| 1498 | This means that it short-circuits: the right expression is evaluated |
| 1499 | only if the left expression is false. Due to its precedence, you must |
| 1500 | be careful to avoid using it as replacement for the C<||> operator. |
| 1501 | It usually works out better for flow control than in assignments: |
| 1502 | |
| 1503 | $x = $y or $z; # bug: this is wrong |
| 1504 | ($x = $y) or $z; # really means this |
| 1505 | $x = $y || $z; # better written this way |
| 1506 | |
| 1507 | However, when it's a list-context assignment and you're trying to use |
| 1508 | C<||> for control flow, you probably need C<"or"> so that the assignment |
| 1509 | takes higher precedence. |
| 1510 | |
| 1511 | @info = stat($file) || die; # oops, scalar sense of stat! |
| 1512 | @info = stat($file) or die; # better, now @info gets its due |
| 1513 | |
| 1514 | Then again, you could always use parentheses. |
| 1515 | |
| 1516 | Binary C<"xor"> returns the exclusive-OR of the two surrounding expressions. |
| 1517 | It cannot short-circuit (of course). |
| 1518 | |
| 1519 | There is no low precedence operator for defined-OR. |
| 1520 | |
| 1521 | =head2 C Operators Missing From Perl |
| 1522 | X<operator, missing from perl> X<&> X<*> |
| 1523 | X<typecasting> X<(TYPE)> |
| 1524 | |
| 1525 | Here is what C has that Perl doesn't: |
| 1526 | |
| 1527 | =over 8 |
| 1528 | |
| 1529 | =item unary & |
| 1530 | |
| 1531 | Address-of operator. (But see the C<"\"> operator for taking a reference.) |
| 1532 | |
| 1533 | =item unary * |
| 1534 | |
| 1535 | Dereference-address operator. (Perl's prefix dereferencing |
| 1536 | operators are typed: C<$>, C<@>, C<%>, and C<&>.) |
| 1537 | |
| 1538 | =item (TYPE) |
| 1539 | |
| 1540 | Type-casting operator. |
| 1541 | |
| 1542 | =back |
| 1543 | |
| 1544 | =head2 Quote and Quote-like Operators |
| 1545 | X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m> |
| 1546 | X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>> |
| 1547 | X<escape sequence> X<escape> |
| 1548 | |
| 1549 | While we usually think of quotes as literal values, in Perl they |
| 1550 | function as operators, providing various kinds of interpolating and |
| 1551 | pattern matching capabilities. Perl provides customary quote characters |
| 1552 | for these behaviors, but also provides a way for you to choose your |
| 1553 | quote character for any of them. In the following table, a C<{}> represents |
| 1554 | any pair of delimiters you choose. |
| 1555 | |
| 1556 | Customary Generic Meaning Interpolates |
| 1557 | '' q{} Literal no |
| 1558 | "" qq{} Literal yes |
| 1559 | `` qx{} Command yes* |
| 1560 | qw{} Word list no |
| 1561 | // m{} Pattern match yes* |
| 1562 | qr{} Pattern yes* |
| 1563 | s{}{} Substitution yes* |
| 1564 | tr{}{} Transliteration no (but see below) |
| 1565 | y{}{} Transliteration no (but see below) |
| 1566 | <<EOF here-doc yes* |
| 1567 | |
| 1568 | * unless the delimiter is ''. |
| 1569 | |
| 1570 | Non-bracketing delimiters use the same character fore and aft, but the four |
| 1571 | sorts of ASCII brackets (round, angle, square, curly) all nest, which means |
| 1572 | that |
| 1573 | |
| 1574 | q{foo{bar}baz} |
| 1575 | |
| 1576 | is the same as |
| 1577 | |
| 1578 | 'foo{bar}baz' |
| 1579 | |
| 1580 | Note, however, that this does not always work for quoting Perl code: |
| 1581 | |
| 1582 | $s = q{ if($x eq "}") ... }; # WRONG |
| 1583 | |
| 1584 | is a syntax error. The C<L<Text::Balanced>> module (standard as of v5.8, |
| 1585 | and from CPAN before then) is able to do this properly. |
| 1586 | |
| 1587 | There can (and in some cases, must) be whitespace between the operator |
| 1588 | and the quoting |
| 1589 | characters, except when C<#> is being used as the quoting character. |
| 1590 | C<q#foo#> is parsed as the string C<foo>, while S<C<q #foo#>> is the |
| 1591 | operator C<q> followed by a comment. Its argument will be taken |
| 1592 | from the next line. This allows you to write: |
| 1593 | |
| 1594 | s {foo} # Replace foo |
| 1595 | {bar} # with bar. |
| 1596 | |
| 1597 | The cases where whitespace must be used are when the quoting character |
| 1598 | is a word character (meaning it matches C</\w/>): |
| 1599 | |
| 1600 | q XfooX # Works: means the string 'foo' |
| 1601 | qXfooX # WRONG! |
| 1602 | |
| 1603 | The following escape sequences are available in constructs that interpolate, |
| 1604 | and in transliterations whose delimiters aren't single quotes (C<"'">). |
| 1605 | In all the ones with braces, any number of blanks and/or tabs adjoining |
| 1606 | and within the braces are allowed (and ignored). |
| 1607 | X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}> |
| 1608 | X<\o{}> |
| 1609 | |
| 1610 | Sequence Note Description |
| 1611 | \t tab (HT, TAB) |
| 1612 | \n newline (NL) |
| 1613 | \r return (CR) |
| 1614 | \f form feed (FF) |
| 1615 | \b backspace (BS) |
| 1616 | \a alarm (bell) (BEL) |
| 1617 | \e escape (ESC) |
| 1618 | \x{263A} [1,8] hex char (example shown: SMILEY) |
| 1619 | \x{ 263A } Same, but shows optional blanks inside and |
| 1620 | adjoining the braces |
| 1621 | \x1b [2,8] restricted range hex char (example: ESC) |
| 1622 | \N{name} [3] named Unicode character or character sequence |
| 1623 | \N{U+263D} [4,8] Unicode character (example: FIRST QUARTER MOON) |
| 1624 | \c[ [5] control char (example: chr(27)) |
| 1625 | \o{23072} [6,8] octal char (example: SMILEY) |
| 1626 | \033 [7,8] restricted range octal char (example: ESC) |
| 1627 | |
| 1628 | Note that any escape sequence using braces inside interpolated |
| 1629 | constructs may have optional blanks (tab or space characters) adjoining |
| 1630 | with and inside of the braces, as illustrated above by the second |
| 1631 | S<C<\x{ }>> example. |
| 1632 | |
| 1633 | =over 4 |
| 1634 | |
| 1635 | =item [1] |
| 1636 | |
| 1637 | The result is the character specified by the hexadecimal number between |
| 1638 | the braces. See L</[8]> below for details on which character. |
| 1639 | |
| 1640 | Blanks (tab or space characters) may separate the number from either or |
| 1641 | both of the braces. |
| 1642 | |
| 1643 | Otherwise, only hexadecimal digits are valid between the braces. If an |
| 1644 | invalid character is encountered, a warning will be issued and the |
| 1645 | invalid character and all subsequent characters (valid or invalid) |
| 1646 | within the braces will be discarded. |
| 1647 | |
| 1648 | If there are no valid digits between the braces, the generated character is |
| 1649 | the NULL character (C<\x{00}>). However, an explicit empty brace (C<\x{}>) |
| 1650 | will not cause a warning (currently). |
| 1651 | |
| 1652 | =item [2] |
| 1653 | |
| 1654 | The result is the character specified by the hexadecimal number in the range |
| 1655 | 0x00 to 0xFF. See L</[8]> below for details on which character. |
| 1656 | |
| 1657 | Only hexadecimal digits are valid following C<\x>. When C<\x> is followed |
| 1658 | by fewer than two valid digits, any valid digits will be zero-padded. This |
| 1659 | means that C<\x7> will be interpreted as C<\x07>, and a lone C<"\x"> will be |
| 1660 | interpreted as C<\x00>. Except at the end of a string, having fewer than |
| 1661 | two valid digits will result in a warning. Note that although the warning |
| 1662 | says the illegal character is ignored, it is only ignored as part of the |
| 1663 | escape and will still be used as the subsequent character in the string. |
| 1664 | For example: |
| 1665 | |
| 1666 | Original Result Warns? |
| 1667 | "\x7" "\x07" no |
| 1668 | "\x" "\x00" no |
| 1669 | "\x7q" "\x07q" yes |
| 1670 | "\xq" "\x00q" yes |
| 1671 | |
| 1672 | =item [3] |
| 1673 | |
| 1674 | The result is the Unicode character or character sequence given by I<name>. |
| 1675 | See L<charnames>. |
| 1676 | |
| 1677 | =item [4] |
| 1678 | |
| 1679 | S<C<\N{U+I<hexadecimal number>}>> means the Unicode character whose Unicode code |
| 1680 | point is I<hexadecimal number>. |
| 1681 | |
| 1682 | =item [5] |
| 1683 | |
| 1684 | The character following C<\c> is mapped to some other character as shown in the |
| 1685 | table: |
| 1686 | |
| 1687 | Sequence Value |
| 1688 | \c@ chr(0) |
| 1689 | \cA chr(1) |
| 1690 | \ca chr(1) |
| 1691 | \cB chr(2) |
| 1692 | \cb chr(2) |
| 1693 | ... |
| 1694 | \cZ chr(26) |
| 1695 | \cz chr(26) |
| 1696 | \c[ chr(27) |
| 1697 | # See below for chr(28) |
| 1698 | \c] chr(29) |
| 1699 | \c^ chr(30) |
| 1700 | \c_ chr(31) |
| 1701 | \c? chr(127) # (on ASCII platforms; see below for link to |
| 1702 | # EBCDIC discussion) |
| 1703 | |
| 1704 | In other words, it's the character whose code point has had 64 xor'd with |
| 1705 | its uppercase. C<\c?> is DELETE on ASCII platforms because |
| 1706 | S<C<ord("?") ^ 64>> is 127, and |
| 1707 | C<\c@> is NULL because the ord of C<"@"> is 64, so xor'ing 64 itself produces 0. |
| 1708 | |
| 1709 | Also, C<\c\I<X>> yields S<C< chr(28) . "I<X>">> for any I<X>, but cannot come at the |
| 1710 | end of a string, because the backslash would be parsed as escaping the end |
| 1711 | quote. |
| 1712 | |
| 1713 | On ASCII platforms, the resulting characters from the list above are the |
| 1714 | complete set of ASCII controls. This isn't the case on EBCDIC platforms; see |
| 1715 | L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the |
| 1716 | differences between these for ASCII versus EBCDIC platforms. |
| 1717 | |
| 1718 | Use of any other character following the C<"c"> besides those listed above is |
| 1719 | discouraged, and as of Perl v5.20, the only characters actually allowed |
| 1720 | are the printable ASCII ones, minus the left brace C<"{">. What happens |
| 1721 | for any of the allowed other characters is that the value is derived by |
| 1722 | xor'ing with the seventh bit, which is 64, and a warning raised if |
| 1723 | enabled. Using the non-allowed characters generates a fatal error. |
| 1724 | |
| 1725 | To get platform independent controls, you can use C<\N{...}>. |
| 1726 | |
| 1727 | =item [6] |
| 1728 | |
| 1729 | The result is the character specified by the octal number between the braces. |
| 1730 | See L</[8]> below for details on which character. |
| 1731 | |
| 1732 | Blanks (tab or space characters) may separate the number from either or |
| 1733 | both of the braces. |
| 1734 | |
| 1735 | Otherwise, if a character that isn't an octal digit is encountered, a |
| 1736 | warning is raised, and the value is based on the octal digits before it, |
| 1737 | discarding it and all following characters up to the closing brace. It |
| 1738 | is a fatal error if there are no octal digits at all. |
| 1739 | |
| 1740 | =item [7] |
| 1741 | |
| 1742 | The result is the character specified by the three-digit octal number in the |
| 1743 | range 000 to 777 (but best to not use above 077, see next paragraph). See |
| 1744 | L</[8]> below for details on which character. |
| 1745 | |
| 1746 | Some contexts allow 2 or even 1 digit, but any usage without exactly |
| 1747 | three digits, the first being a zero, may give unintended results. (For |
| 1748 | example, in a regular expression it may be confused with a backreference; |
| 1749 | see L<perlrebackslash/Octal escapes>.) Starting in Perl 5.14, you may |
| 1750 | use C<\o{}> instead, which avoids all these problems. Otherwise, it is best to |
| 1751 | use this construct only for ordinals C<\077> and below, remembering to pad to |
| 1752 | the left with zeros to make three digits. For larger ordinals, either use |
| 1753 | C<\o{}>, or convert to something else, such as to hex and use C<\N{U+}> |
| 1754 | (which is portable between platforms with different character sets) or |
| 1755 | C<\x{}> instead. |
| 1756 | |
| 1757 | =item [8] |
| 1758 | |
| 1759 | Several constructs above specify a character by a number. That number |
| 1760 | gives the character's position in the character set encoding (indexed from 0). |
| 1761 | This is called synonymously its ordinal, code position, or code point. Perl |
| 1762 | works on platforms that have a native encoding currently of either ASCII/Latin1 |
| 1763 | or EBCDIC, each of which allow specification of 256 characters. In general, if |
| 1764 | the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's |
| 1765 | native encoding. If the number is 256 (0x100, 0400) or above, Perl interprets |
| 1766 | it as a Unicode code point and the result is the corresponding Unicode |
| 1767 | character. For example C<\x{50}> and C<\o{120}> both are the number 80 in |
| 1768 | decimal, which is less than 256, so the number is interpreted in the native |
| 1769 | character set encoding. In ASCII the character in the 80th position (indexed |
| 1770 | from 0) is the letter C<"P">, and in EBCDIC it is the ampersand symbol C<"&">. |
| 1771 | C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted |
| 1772 | as a Unicode code point no matter what the native encoding is. The name of the |
| 1773 | character in the 256th position (indexed by 0) in Unicode is |
| 1774 | C<LATIN CAPITAL LETTER A WITH MACRON>. |
| 1775 | |
| 1776 | An exception to the above rule is that S<C<\N{U+I<hex number>}>> is |
| 1777 | always interpreted as a Unicode code point, so that C<\N{U+0050}> is C<"P"> even |
| 1778 | on EBCDIC platforms. |
| 1779 | |
| 1780 | =back |
| 1781 | |
| 1782 | B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for |
| 1783 | the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may |
| 1784 | use C<\N{VT}>, C<\ck>, C<\N{U+0b}>, or C<\x0b>. (C<\v> |
| 1785 | does have meaning in regular expression patterns in Perl, see L<perlre>.) |
| 1786 | |
| 1787 | The following escape sequences are available in constructs that interpolate, |
| 1788 | but not in transliterations. |
| 1789 | X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F> |
| 1790 | |
| 1791 | \l lowercase next character only |
| 1792 | \u titlecase (not uppercase!) next character only |
| 1793 | \L lowercase all characters till \E or end of string |
| 1794 | \U uppercase all characters till \E or end of string |
| 1795 | \F foldcase all characters till \E or end of string |
| 1796 | \Q quote (disable) pattern metacharacters till \E or |
| 1797 | end of string |
| 1798 | \E end either case modification or quoted section |
| 1799 | (whichever was last seen) |
| 1800 | |
| 1801 | See L<perlfunc/quotemeta> for the exact definition of characters that |
| 1802 | are quoted by C<\Q>. |
| 1803 | |
| 1804 | C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one |
| 1805 | C<\E> for each. For example: |
| 1806 | |
| 1807 | say "This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?"; |
| 1808 | This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it? |
| 1809 | |
| 1810 | If a S<C<use locale>> form that includes C<LC_CTYPE> is in effect (see |
| 1811 | L<perllocale>), the case map used by C<\l>, C<\L>, C<\u>, and C<\U> is |
| 1812 | taken from the current locale. If Unicode (for example, C<\N{}> or code |
| 1813 | points of 0x100 or beyond) is being used, the case map used by C<\l>, |
| 1814 | C<\L>, C<\u>, and C<\U> is as defined by Unicode. That means that |
| 1815 | case-mapping a single character can sometimes produce a sequence of |
| 1816 | several characters. |
| 1817 | Under S<C<use locale>>, C<\F> produces the same results as C<\L> |
| 1818 | for all locales but a UTF-8 one, where it instead uses the Unicode |
| 1819 | definition. |
| 1820 | |
| 1821 | All systems use the virtual C<"\n"> to represent a line terminator, |
| 1822 | called a "newline". There is no such thing as an unvarying, physical |
| 1823 | newline character. It is only an illusion that the operating system, |
| 1824 | device drivers, C libraries, and Perl all conspire to preserve. Not all |
| 1825 | systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF. For example, |
| 1826 | on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed, |
| 1827 | and on systems without a line terminator, |
| 1828 | printing C<"\n"> might emit no actual data. In general, use C<"\n"> when |
| 1829 | you mean a "newline" for your system, but use the literal ASCII when you |
| 1830 | need an exact character. For example, most networking protocols expect |
| 1831 | and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators, |
| 1832 | and although they often accept just C<"\012">, they seldom tolerate just |
| 1833 | C<"\015">. If you get in the habit of using C<"\n"> for networking, |
| 1834 | you may be burned some day. |
| 1835 | X<newline> X<line terminator> X<eol> X<end of line> |
| 1836 | X<\n> X<\r> X<\r\n> |
| 1837 | |
| 1838 | For constructs that do interpolate, variables beginning with "C<$>" |
| 1839 | or "C<@>" are interpolated. Subscripted variables such as C<$a[3]> or |
| 1840 | C<< $href->{key}[0] >> are also interpolated, as are array and hash slices. |
| 1841 | But method calls such as C<< $obj->meth >> are not. |
| 1842 | |
| 1843 | Interpolating an array or slice interpolates the elements in order, |
| 1844 | separated by the value of C<$">, so is equivalent to interpolating |
| 1845 | S<C<join $", @array>>. "Punctuation" arrays such as C<@*> are usually |
| 1846 | interpolated only if the name is enclosed in braces C<@{*}>, but the |
| 1847 | arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces. |
| 1848 | |
| 1849 | For double-quoted strings, the quoting from C<\Q> is applied after |
| 1850 | interpolation and escapes are processed. |
| 1851 | |
| 1852 | "abc\Qfoo\tbar$s\Exyz" |
| 1853 | |
| 1854 | is equivalent to |
| 1855 | |
| 1856 | "abc" . quotemeta("foo\tbar$s") . "xyz" |
| 1857 | |
| 1858 | For the pattern of regex operators (C<qr//>, C<m//> and C<s///>), |
| 1859 | the quoting from C<\Q> is applied after interpolation is processed, |
| 1860 | but before escapes are processed. This allows the pattern to match |
| 1861 | literally (except for C<$> and C<@>). For example, the following matches: |
| 1862 | |
| 1863 | '\s\t' =~ /\Q\s\t/ |
| 1864 | |
| 1865 | Because C<$> or C<@> trigger interpolation, you'll need to use something |
| 1866 | like C</\Quser\E\@\Qhost/> to match them literally. |
| 1867 | |
| 1868 | Patterns are subject to an additional level of interpretation as a |
| 1869 | regular expression. This is done as a second pass, after variables are |
| 1870 | interpolated, so that regular expressions may be incorporated into the |
| 1871 | pattern from the variables. If this is not what you want, use C<\Q> to |
| 1872 | interpolate a variable literally. |
| 1873 | |
| 1874 | Apart from the behavior described above, Perl does not expand |
| 1875 | multiple levels of interpolation. In particular, contrary to the |
| 1876 | expectations of shell programmers, back-quotes do I<NOT> interpolate |
| 1877 | within double quotes, nor do single quotes impede evaluation of |
| 1878 | variables when used within double quotes. |
| 1879 | |
| 1880 | =head2 Regexp Quote-Like Operators |
| 1881 | X<operator, regexp> |
| 1882 | |
| 1883 | Here are the quote-like operators that apply to pattern |
| 1884 | matching and related activities. |
| 1885 | |
| 1886 | =over 8 |
| 1887 | |
| 1888 | =item C<qr/I<STRING>/msixpodualn> |
| 1889 | X<qr> X</i> X</m> X</o> X</s> X</x> X</p> |
| 1890 | |
| 1891 | This operator quotes (and possibly compiles) its I<STRING> as a regular |
| 1892 | expression. I<STRING> is interpolated the same way as I<PATTERN> |
| 1893 | in C<m/I<PATTERN>/>. If C<"'"> is used as the delimiter, no variable |
| 1894 | interpolation is done. Returns a Perl value which may be used instead of the |
| 1895 | corresponding C</I<STRING>/msixpodualn> expression. The returned value is a |
| 1896 | normalized version of the original pattern. It magically differs from |
| 1897 | a string containing the same characters: C<ref(qr/x/)> returns "Regexp"; |
| 1898 | however, dereferencing it is not well defined (you currently get the |
| 1899 | normalized version of the original pattern, but this may change). |
| 1900 | |
| 1901 | |
| 1902 | For example, |
| 1903 | |
| 1904 | $rex = qr/my.STRING/is; |
| 1905 | print $rex; # prints (?si-xm:my.STRING) |
| 1906 | s/$rex/foo/; |
| 1907 | |
| 1908 | is equivalent to |
| 1909 | |
| 1910 | s/my.STRING/foo/is; |
| 1911 | |
| 1912 | The result may be used as a subpattern in a match: |
| 1913 | |
| 1914 | $re = qr/$pattern/; |
| 1915 | $string =~ /foo${re}bar/; # can be interpolated in other |
| 1916 | # patterns |
| 1917 | $string =~ $re; # or used standalone |
| 1918 | $string =~ /$re/; # or this way |
| 1919 | |
| 1920 | Since Perl may compile the pattern at the moment of execution of the C<qr()> |
| 1921 | operator, using C<qr()> may have speed advantages in some situations, |
| 1922 | notably if the result of C<qr()> is used standalone: |
| 1923 | |
| 1924 | sub match { |
| 1925 | my $patterns = shift; |
| 1926 | my @compiled = map qr/$_/i, @$patterns; |
| 1927 | grep { |
| 1928 | my $success = 0; |
| 1929 | foreach my $pat (@compiled) { |
| 1930 | $success = 1, last if /$pat/; |
| 1931 | } |
| 1932 | $success; |
| 1933 | } @_; |
| 1934 | } |
| 1935 | |
| 1936 | Precompilation of the pattern into an internal representation at |
| 1937 | the moment of C<qr()> avoids the need to recompile the pattern every |
| 1938 | time a match C</$pat/> is attempted. (Perl has many other internal |
| 1939 | optimizations, but none would be triggered in the above example if |
| 1940 | we did not use C<qr()> operator.) |
| 1941 | |
| 1942 | Options (specified by the following modifiers) are: |
| 1943 | |
| 1944 | m Treat string as multiple lines. |
| 1945 | s Treat string as single line. (Make . match a newline) |
| 1946 | i Do case-insensitive pattern matching. |
| 1947 | x Use extended regular expressions; specifying two |
| 1948 | x's means \t and the SPACE character are ignored within |
| 1949 | square-bracketed character classes |
| 1950 | p When matching preserve a copy of the matched string so |
| 1951 | that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be |
| 1952 | defined (ignored starting in v5.20 as these are always |
| 1953 | defined starting in that release) |
| 1954 | o Compile pattern only once. |
| 1955 | a ASCII-restrict: Use ASCII for \d, \s, \w and [[:posix:]] |
| 1956 | character classes; specifying two a's adds the further |
| 1957 | restriction that no ASCII character will match a |
| 1958 | non-ASCII one under /i. |
| 1959 | l Use the current run-time locale's rules. |
| 1960 | u Use Unicode rules. |
| 1961 | d Use Unicode or native charset, as in 5.12 and earlier. |
| 1962 | n Non-capture mode. Don't let () fill in $1, $2, etc... |
| 1963 | |
| 1964 | If a precompiled pattern is embedded in a larger pattern then the effect |
| 1965 | of C<"msixpluadn"> will be propagated appropriately. The effect that the |
| 1966 | C</o> modifier has is not propagated, being restricted to those patterns |
| 1967 | explicitly using it. |
| 1968 | |
| 1969 | The C</a>, C</d>, C</l>, and C</u> modifiers (added in Perl 5.14) |
| 1970 | control the character set rules, but C</a> is the only one you are likely |
| 1971 | to want to specify explicitly; the other three are selected |
| 1972 | automatically by various pragmas. |
| 1973 | |
| 1974 | See L<perlre> for additional information on valid syntax for I<STRING>, and |
| 1975 | for a detailed look at the semantics of regular expressions. In |
| 1976 | particular, all modifiers except the largely obsolete C</o> are further |
| 1977 | explained in L<perlre/Modifiers>. C</o> is described in the next section. |
| 1978 | |
| 1979 | =item C<m/I<PATTERN>/msixpodualngc> |
| 1980 | X<m> X<operator, match> |
| 1981 | X<regexp, options> X<regexp> X<regex, options> X<regex> |
| 1982 | X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> |
| 1983 | |
| 1984 | =item C</I<PATTERN>/msixpodualngc> |
| 1985 | |
| 1986 | Searches a string for a pattern match, and in scalar context returns |
| 1987 | true if it succeeds, false if it fails. If no string is specified |
| 1988 | via the C<=~> or C<!~> operator, the C<$_> string is searched. (The |
| 1989 | string specified with C<=~> need not be an lvalue--it may be the |
| 1990 | result of an expression evaluation, but remember the C<=~> binds |
| 1991 | rather tightly.) See also L<perlre>. |
| 1992 | |
| 1993 | Options are as described in C<qr//> above; in addition, the following match |
| 1994 | process modifiers are available: |
| 1995 | |
| 1996 | g Match globally, i.e., find all occurrences. |
| 1997 | c Do not reset search position on a failed match when /g is |
| 1998 | in effect. |
| 1999 | |
| 2000 | If C<"/"> is the delimiter then the initial C<m> is optional. With the C<m> |
| 2001 | you can use any pair of non-whitespace (ASCII) characters |
| 2002 | as delimiters. This is particularly useful for matching path names |
| 2003 | that contain C<"/">, to avoid LTS (leaning toothpick syndrome). If C<"?"> is |
| 2004 | the delimiter, then a match-only-once rule applies, |
| 2005 | described in C<m?I<PATTERN>?> below. If C<"'"> (single quote) is the delimiter, |
| 2006 | no variable interpolation is performed on the I<PATTERN>. |
| 2007 | When using a delimiter character valid in an identifier, whitespace is required |
| 2008 | after the C<m>. |
| 2009 | |
| 2010 | I<PATTERN> may contain variables, which will be interpolated |
| 2011 | every time the pattern search is evaluated, except |
| 2012 | for when the delimiter is a single quote. (Note that C<$(>, C<$)>, and |
| 2013 | C<$|> are not interpolated because they look like end-of-string tests.) |
| 2014 | Perl will not recompile the pattern unless an interpolated |
| 2015 | variable that it contains changes. You can force Perl to skip the |
| 2016 | test and never recompile by adding a C</o> (which stands for "once") |
| 2017 | after the trailing delimiter. |
| 2018 | Once upon a time, Perl would recompile regular expressions |
| 2019 | unnecessarily, and this modifier was useful to tell it not to do so, in the |
| 2020 | interests of speed. But now, the only reasons to use C</o> are one of: |
| 2021 | |
| 2022 | =over |
| 2023 | |
| 2024 | =item 1 |
| 2025 | |
| 2026 | The variables are thousands of characters long and you know that they |
| 2027 | don't change, and you need to wring out the last little bit of speed by |
| 2028 | having Perl skip testing for that. (There is a maintenance penalty for |
| 2029 | doing this, as mentioning C</o> constitutes a promise that you won't |
| 2030 | change the variables in the pattern. If you do change them, Perl won't |
| 2031 | even notice.) |
| 2032 | |
| 2033 | =item 2 |
| 2034 | |
| 2035 | you want the pattern to use the initial values of the variables |
| 2036 | regardless of whether they change or not. (But there are saner ways |
| 2037 | of accomplishing this than using C</o>.) |
| 2038 | |
| 2039 | =item 3 |
| 2040 | |
| 2041 | If the pattern contains embedded code, such as |
| 2042 | |
| 2043 | use re 'eval'; |
| 2044 | $code = 'foo(?{ $x })'; |
| 2045 | /$code/ |
| 2046 | |
| 2047 | then perl will recompile each time, even though the pattern string hasn't |
| 2048 | changed, to ensure that the current value of C<$x> is seen each time. |
| 2049 | Use C</o> if you want to avoid this. |
| 2050 | |
| 2051 | =back |
| 2052 | |
| 2053 | The bottom line is that using C</o> is almost never a good idea. |
| 2054 | |
| 2055 | =item The empty pattern C<//> |
| 2056 | |
| 2057 | If the I<PATTERN> evaluates to the empty string, the last |
| 2058 | I<successfully> matched regular expression in the current dynamic |
| 2059 | scope is used instead (see also L<perlvar/Scoping Rules of Regex Variables>). |
| 2060 | In this case, only the C<g> and C<c> flags on the empty pattern are |
| 2061 | honored; the other flags are taken from the original pattern. If no |
| 2062 | match has previously succeeded, this will (silently) act instead as a |
| 2063 | genuine empty pattern (which will always match). Using a user supplied |
| 2064 | string as a pattern has the risk that if the string is empty that it |
| 2065 | triggers the "last successful match" behavior, which can be very |
| 2066 | confusing. In such cases you are recommended to replace C<m/$pattern/> |
| 2067 | with C<m/(?:$pattern)/> to avoid this behavior. |
| 2068 | |
| 2069 | The last successful pattern may be accessed as a variable via |
| 2070 | C<${^LAST_SUCCESSFUL_PATTERN}>. Matching against it, or the empty |
| 2071 | pattern should have the same effect, with the exception that when there |
| 2072 | is no last successful pattern the empty pattern will silently match, |
| 2073 | whereas using the C<${^LAST_SUCCESSFUL_PATTERN}> variable will produce |
| 2074 | undefined warnings (if warnings are enabled). You can check |
| 2075 | C<defined(${^LAST_SUCCESSFUL_PATTERN})> to test if there is a "last |
| 2076 | successful match" in the current scope. |
| 2077 | |
| 2078 | Note that it's possible to confuse Perl into thinking C<//> (the empty |
| 2079 | regex) is really C<//> (the defined-or operator). Perl is usually pretty |
| 2080 | good about this, but some pathological cases might trigger this, such as |
| 2081 | C<$x///> (is that S<C<($x) / (//)>> or S<C<$x // />>?) and S<C<print $fh //>> |
| 2082 | (S<C<print $fh(//>> or S<C<print($fh //>>?). In all of these examples, Perl |
| 2083 | will assume you meant defined-or. If you meant the empty regex, just |
| 2084 | use parentheses or spaces to disambiguate, or even prefix the empty |
| 2085 | regex with an C<m> (so C<//> becomes C<m//>). |
| 2086 | |
| 2087 | =item Matching in list context |
| 2088 | |
| 2089 | If the C</g> option is not used, C<m//> in list context returns a |
| 2090 | list consisting of the subexpressions matched by the parentheses in the |
| 2091 | pattern, that is, (C<$1>, C<$2>, C<$3>...) (Note that here C<$1> etc. are |
| 2092 | also set). When there are no parentheses in the pattern, the return |
| 2093 | value is the list C<(1)> for success. |
| 2094 | With or without parentheses, an empty list is returned upon failure. |
| 2095 | |
| 2096 | Examples: |
| 2097 | |
| 2098 | open(TTY, "+</dev/tty") |
| 2099 | || die "can't access /dev/tty: $!"; |
| 2100 | |
| 2101 | <TTY> =~ /^y/i && foo(); # do foo if desired |
| 2102 | |
| 2103 | if (/Version: *([0-9.]*)/) { $version = $1; } |
| 2104 | |
| 2105 | next if m#^/usr/spool/uucp#; |
| 2106 | |
| 2107 | # poor man's grep |
| 2108 | $arg = shift; |
| 2109 | while (<>) { |
| 2110 | print if /$arg/; |
| 2111 | } |
| 2112 | if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/)) |
| 2113 | |
| 2114 | This last example splits C<$foo> into the first two words and the |
| 2115 | remainder of the line, and assigns those three fields to C<$F1>, C<$F2>, and |
| 2116 | C<$Etc>. The conditional is true if any variables were assigned; that is, |
| 2117 | if the pattern matched. |
| 2118 | |
| 2119 | The C</g> modifier specifies global pattern matching--that is, |
| 2120 | matching as many times as possible within the string. How it behaves |
| 2121 | depends on the context. In list context, it returns a list of the |
| 2122 | substrings matched by any capturing parentheses in the regular |
| 2123 | expression. If there are no parentheses, it returns a list of all |
| 2124 | the matched strings, as if there were parentheses around the whole |
| 2125 | pattern. |
| 2126 | |
| 2127 | In scalar context, each execution of C<m//g> finds the next match, |
| 2128 | returning true if it matches, and false if there is no further match. |
| 2129 | The position after the last match can be read or set using the C<pos()> |
| 2130 | function; see L<perlfunc/pos>. A failed match normally resets the |
| 2131 | search position to the beginning of the string, but you can avoid that |
| 2132 | by adding the C</c> modifier (for example, C<m//gc>). Modifying the target |
| 2133 | string also resets the search position. |
| 2134 | |
| 2135 | =item C<\G I<assertion>> |
| 2136 | |
| 2137 | You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a |
| 2138 | zero-width assertion that matches the exact position where the |
| 2139 | previous C<m//g>, if any, left off. Without the C</g> modifier, the |
| 2140 | C<\G> assertion still anchors at C<pos()> as it was at the start of |
| 2141 | the operation (see L<perlfunc/pos>), but the match is of course only |
| 2142 | attempted once. Using C<\G> without C</g> on a target string that has |
| 2143 | not previously had a C</g> match applied to it is the same as using |
| 2144 | the C<\A> assertion to match the beginning of the string. Note also |
| 2145 | that, currently, C<\G> is only properly supported when anchored at the |
| 2146 | very beginning of the pattern. |
| 2147 | |
| 2148 | Examples: |
| 2149 | |
| 2150 | # list context |
| 2151 | ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g); |
| 2152 | |
| 2153 | # scalar context |
| 2154 | local $/ = ""; |
| 2155 | while ($paragraph = <>) { |
| 2156 | while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) { |
| 2157 | $sentences++; |
| 2158 | } |
| 2159 | } |
| 2160 | say $sentences; |
| 2161 | |
| 2162 | Here's another way to check for sentences in a paragraph: |
| 2163 | |
| 2164 | my $sentence_rx = qr{ |
| 2165 | (?: (?<= ^ ) | (?<= \s ) ) # after start-of-string or |
| 2166 | # whitespace |
| 2167 | \p{Lu} # capital letter |
| 2168 | .*? # a bunch of anything |
| 2169 | (?<= \S ) # that ends in non- |
| 2170 | # whitespace |
| 2171 | (?<! \b [DMS]r ) # but isn't a common abbr. |
| 2172 | (?<! \b Mrs ) |
| 2173 | (?<! \b Sra ) |
| 2174 | (?<! \b St ) |
| 2175 | [.?!] # followed by a sentence |
| 2176 | # ender |
| 2177 | (?= $ | \s ) # in front of end-of-string |
| 2178 | # or whitespace |
| 2179 | }sx; |
| 2180 | local $/ = ""; |
| 2181 | while (my $paragraph = <>) { |
| 2182 | say "NEW PARAGRAPH"; |
| 2183 | my $count = 0; |
| 2184 | while ($paragraph =~ /($sentence_rx)/g) { |
| 2185 | printf "\tgot sentence %d: <%s>\n", ++$count, $1; |
| 2186 | } |
| 2187 | } |
| 2188 | |
| 2189 | Here's how to use C<m//gc> with C<\G>: |
| 2190 | |
| 2191 | $_ = "ppooqppqq"; |
| 2192 | while ($i++ < 2) { |
| 2193 | print "1: '"; |
| 2194 | print $1 while /(o)/gc; print "', pos=", pos, "\n"; |
| 2195 | print "2: '"; |
| 2196 | print $1 if /\G(q)/gc; print "', pos=", pos, "\n"; |
| 2197 | print "3: '"; |
| 2198 | print $1 while /(p)/gc; print "', pos=", pos, "\n"; |
| 2199 | } |
| 2200 | print "Final: '$1', pos=",pos,"\n" if /\G(.)/; |
| 2201 | |
| 2202 | The last example should print: |
| 2203 | |
| 2204 | 1: 'oo', pos=4 |
| 2205 | 2: 'q', pos=5 |
| 2206 | 3: 'pp', pos=7 |
| 2207 | 1: '', pos=7 |
| 2208 | 2: 'q', pos=8 |
| 2209 | 3: '', pos=8 |
| 2210 | Final: 'q', pos=8 |
| 2211 | |
| 2212 | Notice that the final match matched C<q> instead of C<p>, which a match |
| 2213 | without the C<\G> anchor would have done. Also note that the final match |
| 2214 | did not update C<pos>. C<pos> is only updated on a C</g> match. If the |
| 2215 | final match did indeed match C<p>, it's a good bet that you're running an |
| 2216 | ancient (pre-5.6.0) version of Perl. |
| 2217 | |
| 2218 | A useful idiom for C<lex>-like scanners is C</\G.../gc>. You can |
| 2219 | combine several regexps like this to process a string part-by-part, |
| 2220 | doing different actions depending on which regexp matched. Each |
| 2221 | regexp tries to match where the previous one leaves off. |
| 2222 | |
| 2223 | $_ = <<'EOL'; |
| 2224 | $url = URI::URL->new( "http://example.com/" ); |
| 2225 | die if $url eq "xXx"; |
| 2226 | EOL |
| 2227 | |
| 2228 | LOOP: { |
| 2229 | print(" digits"), redo LOOP if /\G\d+\b[,.;]?\s*/gc; |
| 2230 | print(" lowercase"), redo LOOP |
| 2231 | if /\G\p{Ll}+\b[,.;]?\s*/gc; |
| 2232 | print(" UPPERCASE"), redo LOOP |
| 2233 | if /\G\p{Lu}+\b[,.;]?\s*/gc; |
| 2234 | print(" Capitalized"), redo LOOP |
| 2235 | if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc; |
| 2236 | print(" MiXeD"), redo LOOP if /\G\pL+\b[,.;]?\s*/gc; |
| 2237 | print(" alphanumeric"), redo LOOP |
| 2238 | if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc; |
| 2239 | print(" line-noise"), redo LOOP if /\G\W+/gc; |
| 2240 | print ". That's all!\n"; |
| 2241 | } |
| 2242 | |
| 2243 | Here is the output (split into several lines): |
| 2244 | |
| 2245 | line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE |
| 2246 | line-noise lowercase line-noise lowercase line-noise lowercase |
| 2247 | lowercase line-noise lowercase lowercase line-noise lowercase |
| 2248 | lowercase line-noise MiXeD line-noise. That's all! |
| 2249 | |
| 2250 | =item C<m?I<PATTERN>?msixpodualngc> |
| 2251 | X<?> X<operator, match-once> |
| 2252 | |
| 2253 | This is just like the C<m/I<PATTERN>/> search, except that it matches |
| 2254 | only once between calls to the C<reset()> operator. This is a useful |
| 2255 | optimization when you want to see only the first occurrence of |
| 2256 | something in each file of a set of files, for instance. Only C<m??> |
| 2257 | patterns local to the current package are reset. |
| 2258 | |
| 2259 | while (<>) { |
| 2260 | if (m?^$?) { |
| 2261 | # blank line between header and body |
| 2262 | } |
| 2263 | } continue { |
| 2264 | reset if eof; # clear m?? status for next file |
| 2265 | } |
| 2266 | |
| 2267 | Another example switched the first "latin1" encoding it finds |
| 2268 | to "utf8" in a pod file: |
| 2269 | |
| 2270 | s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x; |
| 2271 | |
| 2272 | The match-once behavior is controlled by the match delimiter being |
| 2273 | C<?>; with any other delimiter this is the normal C<m//> operator. |
| 2274 | |
| 2275 | In the past, the leading C<m> in C<m?I<PATTERN>?> was optional, but omitting it |
| 2276 | would produce a deprecation warning. As of v5.22.0, omitting it produces a |
| 2277 | syntax error. If you encounter this construct in older code, you can just add |
| 2278 | C<m>. |
| 2279 | |
| 2280 | =item C<s/I<PATTERN>/I<REPLACEMENT>/msixpodualngcer> |
| 2281 | X<s> X<substitute> X<substitution> X<replace> X<regexp, replace> |
| 2282 | X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r> |
| 2283 | |
| 2284 | Searches a string for a pattern, and if found, replaces that pattern |
| 2285 | with the replacement text and returns the number of substitutions |
| 2286 | made. Otherwise it returns false (a value that is both an empty string (C<"">) |
| 2287 | and numeric zero (C<0>) as described in L</Relational Operators>). |
| 2288 | |
| 2289 | If the C</r> (non-destructive) option is used then it runs the |
| 2290 | substitution on a copy of the string and instead of returning the |
| 2291 | number of substitutions, it returns the copy whether or not a |
| 2292 | substitution occurred. The original string is never changed when |
| 2293 | C</r> is used. The copy will always be a plain string, even if the |
| 2294 | input is an object or a tied variable. |
| 2295 | |
| 2296 | If no string is specified via the C<=~> or C<!~> operator, the C<$_> |
| 2297 | variable is searched and modified. Unless the C</r> option is used, |
| 2298 | the string specified must be a scalar variable, an array element, a |
| 2299 | hash element, or an assignment to one of those; that is, some sort of |
| 2300 | scalar lvalue. |
| 2301 | |
| 2302 | If the delimiter chosen is a single quote, no variable interpolation is |
| 2303 | done on either the I<PATTERN> or the I<REPLACEMENT>. Otherwise, if the |
| 2304 | I<PATTERN> contains a C<$> that looks like a variable rather than an |
| 2305 | end-of-string test, the variable will be interpolated into the pattern |
| 2306 | at run-time. If you want the pattern compiled only once the first time |
| 2307 | the variable is interpolated, use the C</o> option. If the pattern |
| 2308 | evaluates to the empty string, the last successfully executed regular |
| 2309 | expression is used instead. See L<perlre> for further explanation on these. |
| 2310 | |
| 2311 | Options are as with C<m//> with the addition of the following replacement |
| 2312 | specific options: |
| 2313 | |
| 2314 | e Evaluate the right side as an expression. |
| 2315 | ee Evaluate the right side as a string then eval the |
| 2316 | result. |
| 2317 | r Return substitution and leave the original string |
| 2318 | untouched. |
| 2319 | |
| 2320 | Any non-whitespace delimiter may replace the slashes. Add space after |
| 2321 | the C<s> when using a character allowed in identifiers. If single quotes |
| 2322 | are used, no interpretation is done on the replacement string (the C</e> |
| 2323 | modifier overrides this, however). Note that Perl treats backticks |
| 2324 | as normal delimiters; the replacement text is not evaluated as a command. |
| 2325 | If the I<PATTERN> is delimited by bracketing quotes, the I<REPLACEMENT> has |
| 2326 | its own pair of quotes, which may or may not be bracketing quotes, for example, |
| 2327 | C<s(foo)(bar)> or C<< s<foo>/bar/ >>. A C</e> will cause the |
| 2328 | replacement portion to be treated as a full-fledged Perl expression |
| 2329 | and evaluated right then and there. It is, however, syntax checked at |
| 2330 | compile-time. A second C<e> modifier will cause the replacement portion |
| 2331 | to be C<eval>ed before being run as a Perl expression. |
| 2332 | |
| 2333 | Examples: |
| 2334 | |
| 2335 | s/\bgreen\b/mauve/g; # don't change wintergreen |
| 2336 | |
| 2337 | $path =~ s|/usr/bin|/usr/local/bin|; |
| 2338 | |
| 2339 | s/Login: $foo/Login: $bar/; # run-time pattern |
| 2340 | |
| 2341 | ($foo = $bar) =~ s/this/that/; # copy first, then |
| 2342 | # change |
| 2343 | ($foo = "$bar") =~ s/this/that/; # convert to string, |
| 2344 | # copy, then change |
| 2345 | $foo = $bar =~ s/this/that/r; # Same as above using /r |
| 2346 | $foo = $bar =~ s/this/that/r |
| 2347 | =~ s/that/the other/r; # Chained substitutes |
| 2348 | # using /r |
| 2349 | @foo = map { s/this/that/r } @bar # /r is very useful in |
| 2350 | # maps |
| 2351 | |
| 2352 | $count = ($paragraph =~ s/Mister\b/Mr./g); # get change-cnt |
| 2353 | |
| 2354 | $_ = 'abc123xyz'; |
| 2355 | s/\d+/$&*2/e; # yields 'abc246xyz' |
| 2356 | s/\d+/sprintf("%5d",$&)/e; # yields 'abc 246xyz' |
| 2357 | s/\w/$& x 2/eg; # yields 'aabbcc 224466xxyyzz' |
| 2358 | |
| 2359 | s/%(.)/$percent{$1}/g; # change percent escapes; no /e |
| 2360 | s/%(.)/$percent{$1} || $&/ge; # expr now, so /e |
| 2361 | s/^=(\w+)/pod($1)/ge; # use function call |
| 2362 | |
| 2363 | $_ = 'abc123xyz'; |
| 2364 | $x = s/abc/def/r; # $x is 'def123xyz' and |
| 2365 | # $_ remains 'abc123xyz'. |
| 2366 | |
| 2367 | # expand variables in $_, but dynamics only, using |
| 2368 | # symbolic dereferencing |
| 2369 | s/\$(\w+)/${$1}/g; |
| 2370 | |
| 2371 | # Add one to the value of any numbers in the string |
| 2372 | s/(\d+)/1 + $1/eg; |
| 2373 | |
| 2374 | # Titlecase words in the last 30 characters only (presuming |
| 2375 | # that the substring doesn't start in the middle of a word) |
| 2376 | substr($str, -30) =~ s/\b(\p{Alpha})(\p{Alpha}*)\b/\u$1\L$2/g; |
| 2377 | |
| 2378 | # This will expand any embedded scalar variable |
| 2379 | # (including lexicals) in $_ : First $1 is interpolated |
| 2380 | # to the variable name, and then evaluated |
| 2381 | s/(\$\w+)/$1/eeg; |
| 2382 | |
| 2383 | # Delete (most) C comments. |
| 2384 | $program =~ s { |
| 2385 | /\* # Match the opening delimiter. |
| 2386 | .*? # Match a minimal number of characters. |
| 2387 | \*/ # Match the closing delimiter. |
| 2388 | } []gsx; |
| 2389 | |
| 2390 | s/^\s*(.*?)\s*$/$1/; # trim whitespace in $_, |
| 2391 | # expensively |
| 2392 | |
| 2393 | for ($variable) { # trim whitespace in $variable, |
| 2394 | # cheap |
| 2395 | s/^\s+//; |
| 2396 | s/\s+$//; |
| 2397 | } |
| 2398 | |
| 2399 | s/([^ ]*) *([^ ]*)/$2 $1/; # reverse 1st two fields |
| 2400 | |
| 2401 | $foo !~ s/A/a/g; # Lowercase all A's in $foo; return |
| 2402 | # 0 if any were found and changed; |
| 2403 | # otherwise return 1 |
| 2404 | |
| 2405 | Note the use of C<$> instead of C<\> in the last example. Unlike |
| 2406 | B<sed>, we use the \<I<digit>> form only in the left hand side. |
| 2407 | Anywhere else it's $<I<digit>>. |
| 2408 | |
| 2409 | Occasionally, you can't use just a C</g> to get all the changes |
| 2410 | to occur that you might want. Here are two common cases: |
| 2411 | |
| 2412 | # put commas in the right places in an integer |
| 2413 | 1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g; |
| 2414 | |
| 2415 | # expand tabs to 8-column spacing |
| 2416 | 1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e; |
| 2417 | |
| 2418 | X</c>While C<s///> accepts the C</c> flag, it has no effect beyond |
| 2419 | producing a warning if warnings are enabled. |
| 2420 | |
| 2421 | =back |
| 2422 | |
| 2423 | =head2 Quote-Like Operators |
| 2424 | X<operator, quote-like> |
| 2425 | |
| 2426 | =over 4 |
| 2427 | |
| 2428 | =item C<q/I<STRING>/> |
| 2429 | X<q> X<quote, single> X<'> X<''> |
| 2430 | |
| 2431 | =item C<'I<STRING>'> |
| 2432 | |
| 2433 | A single-quoted, literal string. A backslash represents a backslash |
| 2434 | unless followed by the delimiter or another backslash, in which case |
| 2435 | the delimiter or backslash is interpolated. |
| 2436 | |
| 2437 | $foo = q!I said, "You said, 'She said it.'"!; |
| 2438 | $bar = q('This is it.'); |
| 2439 | $baz = '\n'; # a two-character string |
| 2440 | |
| 2441 | =item C<qq/I<STRING>/> |
| 2442 | X<qq> X<quote, double> X<"> X<""> |
| 2443 | |
| 2444 | =item C<"I<STRING>"> |
| 2445 | |
| 2446 | A double-quoted, interpolated string. |
| 2447 | |
| 2448 | $_ .= qq |
| 2449 | (*** The previous line contains the naughty word "$1".\n) |
| 2450 | if /\b(tcl|java|python)\b/i; # :-) |
| 2451 | $baz = "\n"; # a one-character string |
| 2452 | |
| 2453 | =item C<qx/I<STRING>/> |
| 2454 | X<qx> X<`> X<``> X<backtick> |
| 2455 | |
| 2456 | =item C<`I<STRING>`> |
| 2457 | |
| 2458 | A string which is (possibly) interpolated and then executed as a |
| 2459 | system command, via F</bin/sh> or its equivalent if required. Shell |
| 2460 | wildcards, pipes, and redirections will be honored. Similarly to |
| 2461 | C<system>, if the string contains no shell metacharacters then it will |
| 2462 | executed directly. The collected standard output of the command is |
| 2463 | returned; standard error is unaffected. In scalar context, it comes |
| 2464 | back as a single (potentially multi-line) string, or C<undef> if the |
| 2465 | shell (or command) could not be started. In list context, returns a |
| 2466 | list of lines (however you've defined lines with C<$/> or |
| 2467 | C<$INPUT_RECORD_SEPARATOR>), or an empty list if the shell (or command) |
| 2468 | could not be started. |
| 2469 | |
| 2470 | Because backticks do not affect standard error, use shell file descriptor |
| 2471 | syntax (assuming the shell supports this) if you care to address this. |
| 2472 | To capture a command's STDERR and STDOUT together: |
| 2473 | |
| 2474 | $output = `cmd 2>&1`; |
| 2475 | |
| 2476 | To capture a command's STDOUT but discard its STDERR: |
| 2477 | |
| 2478 | $output = `cmd 2>/dev/null`; |
| 2479 | |
| 2480 | To capture a command's STDERR but discard its STDOUT (ordering is |
| 2481 | important here): |
| 2482 | |
| 2483 | $output = `cmd 2>&1 1>/dev/null`; |
| 2484 | |
| 2485 | To exchange a command's STDOUT and STDERR in order to capture the STDERR |
| 2486 | but leave its STDOUT to come out the old STDERR: |
| 2487 | |
| 2488 | $output = `cmd 3>&1 1>&2 2>&3 3>&-`; |
| 2489 | |
| 2490 | To read both a command's STDOUT and its STDERR separately, it's easiest |
| 2491 | to redirect them separately to files, and then read from those files |
| 2492 | when the program is done: |
| 2493 | |
| 2494 | system("program args 1>program.stdout 2>program.stderr"); |
| 2495 | |
| 2496 | The STDIN filehandle used by the command is inherited from Perl's STDIN. |
| 2497 | For example: |
| 2498 | |
| 2499 | open(SPLAT, "stuff") || die "can't open stuff: $!"; |
| 2500 | open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!"; |
| 2501 | print STDOUT `sort`; |
| 2502 | |
| 2503 | will print the sorted contents of the file named F<"stuff">. |
| 2504 | |
| 2505 | Using single-quote as a delimiter protects the command from Perl's |
| 2506 | double-quote interpolation, passing it on to the shell instead: |
| 2507 | |
| 2508 | $perl_info = qx(ps $$); # that's Perl's $$ |
| 2509 | $shell_info = qx'ps $$'; # that's the new shell's $$ |
| 2510 | |
| 2511 | How that string gets evaluated is entirely subject to the command |
| 2512 | interpreter on your system. On most platforms, you will have to protect |
| 2513 | shell metacharacters if you want them treated literally. This is in |
| 2514 | practice difficult to do, as it's unclear how to escape which characters. |
| 2515 | See L<perlsec> for a clean and safe example of a manual C<fork()> and C<exec()> |
| 2516 | to emulate backticks safely. |
| 2517 | |
| 2518 | On some platforms (notably DOS-like ones), the shell may not be |
| 2519 | capable of dealing with multiline commands, so putting newlines in |
| 2520 | the string may not get you what you want. You may be able to evaluate |
| 2521 | multiple commands in a single line by separating them with the command |
| 2522 | separator character, if your shell supports that (for example, C<;> on |
| 2523 | many Unix shells and C<&> on the Windows NT C<cmd> shell). |
| 2524 | |
| 2525 | Perl will attempt to flush all files opened for |
| 2526 | output before starting the child process, but this may not be supported |
| 2527 | on some platforms (see L<perlport>). To be safe, you may need to set |
| 2528 | C<$|> (C<$AUTOFLUSH> in C<L<English>>) or call the C<autoflush()> method of |
| 2529 | C<L<IO::Handle>> on any open handles. |
| 2530 | |
| 2531 | Beware that some command shells may place restrictions on the length |
| 2532 | of the command line. You must ensure your strings don't exceed this |
| 2533 | limit after any necessary interpolations. See the platform-specific |
| 2534 | release notes for more details about your particular environment. |
| 2535 | |
| 2536 | Using this operator can lead to programs that are difficult to port, |
| 2537 | because the shell commands called vary between systems, and may in |
| 2538 | fact not be present at all. As one example, the C<type> command under |
| 2539 | the POSIX shell is very different from the C<type> command under DOS. |
| 2540 | That doesn't mean you should go out of your way to avoid backticks |
| 2541 | when they're the right way to get something done. Perl was made to be |
| 2542 | a glue language, and one of the things it glues together is commands. |
| 2543 | Just understand what you're getting yourself into. |
| 2544 | |
| 2545 | Like C<system>, backticks put the child process exit code in C<$?>. |
| 2546 | If you'd like to manually inspect failure, you can check all possible |
| 2547 | failure modes by inspecting C<$?> like this: |
| 2548 | |
| 2549 | if ($? == -1) { |
| 2550 | print "failed to execute: $!\n"; |
| 2551 | } |
| 2552 | elsif ($? & 127) { |
| 2553 | printf "child died with signal %d, %s coredump\n", |
| 2554 | ($? & 127), ($? & 128) ? 'with' : 'without'; |
| 2555 | } |
| 2556 | else { |
| 2557 | printf "child exited with value %d\n", $? >> 8; |
| 2558 | } |
| 2559 | |
| 2560 | Use the L<open> pragma to control the I/O layers used when reading the |
| 2561 | output of the command, for example: |
| 2562 | |
| 2563 | use open IN => ":encoding(UTF-8)"; |
| 2564 | my $x = `cmd-producing-utf-8`; |
| 2565 | |
| 2566 | C<qx//> can also be called like a function with L<perlfunc/readpipe>. |
| 2567 | |
| 2568 | See L</"I/O Operators"> for more discussion. |
| 2569 | |
| 2570 | =item C<qw/I<STRING>/> |
| 2571 | X<qw> X<quote, list> X<quote, words> |
| 2572 | |
| 2573 | Evaluates to a list of the words extracted out of I<STRING>, using embedded |
| 2574 | whitespace as the word delimiters. It can be understood as being roughly |
| 2575 | equivalent to: |
| 2576 | |
| 2577 | split(" ", q/STRING/); |
| 2578 | |
| 2579 | the differences being that it only splits on ASCII whitespace, |
| 2580 | generates a real list at compile time, and |
| 2581 | in scalar context it returns the last element in the list. So |
| 2582 | this expression: |
| 2583 | |
| 2584 | qw(foo bar baz) |
| 2585 | |
| 2586 | is semantically equivalent to the list: |
| 2587 | |
| 2588 | "foo", "bar", "baz" |
| 2589 | |
| 2590 | Some frequently seen examples: |
| 2591 | |
| 2592 | use POSIX qw( setlocale localeconv ) |
| 2593 | @EXPORT = qw( foo bar baz ); |
| 2594 | |
| 2595 | A common mistake is to try to separate the words with commas or to |
| 2596 | put comments into a multi-line C<qw>-string. For this reason, the |
| 2597 | S<C<use warnings>> pragma and the B<-w> switch (that is, the C<$^W> variable) |
| 2598 | produces warnings if the I<STRING> contains the C<","> or the C<"#"> character. |
| 2599 | |
| 2600 | =item C<tr/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr> |
| 2601 | X<tr> X<y> X<transliterate> X</c> X</d> X</s> |
| 2602 | |
| 2603 | =item C<y/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr> |
| 2604 | |
| 2605 | Transliterates all occurrences of the characters found (or not found |
| 2606 | if the C</c> modifier is specified) in the search list with the |
| 2607 | positionally corresponding character in the replacement list, possibly |
| 2608 | deleting some, depending on the modifiers specified. It returns the |
| 2609 | number of characters replaced or deleted. If no string is specified via |
| 2610 | the C<=~> or C<!~> operator, the C<$_> string is transliterated. |
| 2611 | |
| 2612 | For B<sed> devotees, C<y> is provided as a synonym for C<tr>. |
| 2613 | |
| 2614 | If the C</r> (non-destructive) option is present, a new copy of the string |
| 2615 | is made and its characters transliterated, and this copy is returned no |
| 2616 | matter whether it was modified or not: the original string is always |
| 2617 | left unchanged. The new copy is always a plain string, even if the input |
| 2618 | string is an object or a tied variable. |
| 2619 | |
| 2620 | Unless the C</r> option is used, the string specified with C<=~> must be a |
| 2621 | scalar variable, an array element, a hash element, or an assignment to one |
| 2622 | of those; in other words, an lvalue. |
| 2623 | |
| 2624 | The characters delimitting I<SEARCHLIST> and I<REPLACEMENTLIST> |
| 2625 | can be any printable character, not just forward slashes. If they |
| 2626 | are single quotes (C<tr'I<SEARCHLIST>'I<REPLACEMENTLIST>'>), the only |
| 2627 | interpolation is removal of C<\> from pairs of C<\\>; so hyphens are |
| 2628 | interpreted literally rather than specifying a character range. |
| 2629 | |
| 2630 | Otherwise, a character range may be specified with a hyphen, so |
| 2631 | C<tr/A-J/0-9/> does the same replacement as |
| 2632 | C<tr/ACEGIBDFHJ/0246813579/>. |
| 2633 | |
| 2634 | If the I<SEARCHLIST> is delimited by bracketing quotes, the |
| 2635 | I<REPLACEMENTLIST> must have its own pair of quotes, which may or may |
| 2636 | not be bracketing quotes; for example, C<tr(aeiouy)(yuoiea)> or |
| 2637 | C<tr[+\-*/]"ABCD">. This final example shows a way to visually clarify |
| 2638 | what is going on for people who are more familiar with regular |
| 2639 | expression patterns than with C<tr>, and who may think forward slash |
| 2640 | delimiters imply that C<tr> is more like a regular expression pattern |
| 2641 | than it actually is. (Another option might be to use C<tr[...][...]>.) |
| 2642 | |
| 2643 | C<tr> isn't fully like bracketed character classes, just |
| 2644 | (significantly) more like them than it is to full patterns. For |
| 2645 | example, characters appearing more than once in either list behave |
| 2646 | differently here than in patterns, and C<tr> lists do not allow |
| 2647 | backslashed character classes such as C<\d> or C<\pL>, nor variable |
| 2648 | interpolation, so C<"$"> and C<"@"> are always treated as literals. |
| 2649 | |
| 2650 | The allowed elements are literals plus C<\'> (meaning a single quote). |
| 2651 | If the delimiters aren't single quotes, also allowed are any of the |
| 2652 | escape sequences accepted in double-quoted strings. Escape sequence |
| 2653 | details are in L<the table near the beginning of this section|/Quote and |
| 2654 | Quote-like Operators>. |
| 2655 | |
| 2656 | A hyphen at the beginning or end, or preceded by a backslash is also |
| 2657 | always considered a literal. Precede a delimiter character with a |
| 2658 | backslash to allow it. |
| 2659 | |
| 2660 | The C<tr> operator is not equivalent to the C<L<tr(1)>> utility. |
| 2661 | C<tr[a-z][A-Z]> will uppercase the 26 letters "a" through "z", but for |
| 2662 | case changing not confined to ASCII, use L<C<lc>|perlfunc/lc>, |
| 2663 | L<C<uc>|perlfunc/uc>, L<C<lcfirst>|perlfunc/lcfirst>, |
| 2664 | L<C<ucfirst>|perlfunc/ucfirst> (all documented in L<perlfunc>), or the |
| 2665 | L<substitution operator |
| 2666 | C<sE<sol>I<PATTERN>E<sol>I<REPLACEMENT>E<sol>>|/sE<sol>PATTERNE<sol>REPLACEMENTE<sol>msixpodualngcer> |
| 2667 | (with C<\U>, C<\u>, C<\L>, and C<\l> string-interpolation escapes in the |
| 2668 | I<REPLACEMENT> portion). |
| 2669 | |
| 2670 | Most ranges are unportable between character sets, but certain ones |
| 2671 | signal Perl to do special handling to make them portable. There are two |
| 2672 | classes of portable ranges. The first are any subsets of the ranges |
| 2673 | C<A-Z>, C<a-z>, and C<0-9>, when expressed as literal characters. |
| 2674 | |
| 2675 | tr/h-k/H-K/ |
| 2676 | |
| 2677 | capitalizes the letters C<"h">, C<"i">, C<"j">, and C<"k"> and nothing |
| 2678 | else, no matter what the platform's character set is. In contrast, all |
| 2679 | of |
| 2680 | |
| 2681 | tr/\x68-\x6B/\x48-\x4B/ |
| 2682 | tr/h-\x6B/H-\x4B/ |
| 2683 | tr/\x68-k/\x48-K/ |
| 2684 | |
| 2685 | do the same capitalizations as the previous example when run on ASCII |
| 2686 | platforms, but something completely different on EBCDIC ones. |
| 2687 | |
| 2688 | The second class of portable ranges is invoked when one or both of the |
| 2689 | range's end points are expressed as C<\N{...}> |
| 2690 | |
| 2691 | $string =~ tr/\N{U+20}-\N{U+7E}//d; |
| 2692 | |
| 2693 | removes from C<$string> all the platform's characters which are |
| 2694 | equivalent to any of Unicode U+0020, U+0021, ... U+007D, U+007E. This |
| 2695 | is a portable range, and has the same effect on every platform it is |
| 2696 | run on. In this example, these are the ASCII |
| 2697 | printable characters. So after this is run, C<$string> has only |
| 2698 | controls and characters which have no ASCII equivalents. |
| 2699 | |
| 2700 | But, even for portable ranges, it is not generally obvious what is |
| 2701 | included without having to look things up in the manual. A sound |
| 2702 | principle is to use only ranges that both begin from, and end at, either |
| 2703 | ASCII alphabetics of equal case (C<b-e>, C<B-E>), or digits (C<1-4>). |
| 2704 | Anything else is unclear (and unportable unless C<\N{...}> is used). If |
| 2705 | in doubt, spell out the character sets in full. |
| 2706 | |
| 2707 | Options: |
| 2708 | |
| 2709 | c Complement the SEARCHLIST. |
| 2710 | d Delete found but unreplaced characters. |
| 2711 | r Return the modified string and leave the original string |
| 2712 | untouched. |
| 2713 | s Squash duplicate replaced characters. |
| 2714 | |
| 2715 | If the C</d> modifier is specified, any characters specified by |
| 2716 | I<SEARCHLIST> not found in I<REPLACEMENTLIST> are deleted. (Note that |
| 2717 | this is slightly more flexible than the behavior of some B<tr> programs, |
| 2718 | which delete anything they find in the I<SEARCHLIST>, period.) |
| 2719 | |
| 2720 | If the C</s> modifier is specified, sequences of characters, all in a |
| 2721 | row, that were transliterated to the same character are squashed down to |
| 2722 | a single instance of that character. |
| 2723 | |
| 2724 | my $x = "aaabbbca"; |
| 2725 | $x =~ tr/ab/dd/s; # $x now is "dcd" |
| 2726 | |
| 2727 | If the C</d> modifier is used, the I<REPLACEMENTLIST> is always interpreted |
| 2728 | exactly as specified. Otherwise, if the I<REPLACEMENTLIST> is shorter |
| 2729 | than the I<SEARCHLIST>, the final character, if any, is replicated until |
| 2730 | it is long enough. There won't be a final character if and only if the |
| 2731 | I<REPLACEMENTLIST> is empty, in which case I<REPLACEMENTLIST> is |
| 2732 | copied from I<SEARCHLIST>. An empty I<REPLACEMENTLIST> is useful |
| 2733 | for counting characters in a class, or for squashing character sequences |
| 2734 | in a class. |
| 2735 | |
| 2736 | tr/abcd// tr/abcd/abcd/ |
| 2737 | tr/abcd/AB/ tr/abcd/ABBB/ |
| 2738 | tr/abcd//d s/[abcd]//g |
| 2739 | tr/abcd/AB/d (tr/ab/AB/ + s/[cd]//g) - but run together |
| 2740 | |
| 2741 | If the C</c> modifier is specified, the characters to be transliterated |
| 2742 | are the ones NOT in I<SEARCHLIST>, that is, it is complemented. If |
| 2743 | C</d> and/or C</s> are also specified, they apply to the complemented |
| 2744 | I<SEARCHLIST>. Recall, that if I<REPLACEMENTLIST> is empty (except |
| 2745 | under C</d>) a copy of I<SEARCHLIST> is used instead. That copy is made |
| 2746 | after complementing under C</c>. I<SEARCHLIST> is sorted by code point |
| 2747 | order after complementing, and any I<REPLACEMENTLIST> is applied to |
| 2748 | that sorted result. This means that under C</c>, the order of the |
| 2749 | characters specified in I<SEARCHLIST> is irrelevant. This can |
| 2750 | lead to different results on EBCDIC systems if I<REPLACEMENTLIST> |
| 2751 | contains more than one character, hence it is generally non-portable to |
| 2752 | use C</c> with such a I<REPLACEMENTLIST>. |
| 2753 | |
| 2754 | Another way of describing the operation is this: |
| 2755 | If C</c> is specified, the I<SEARCHLIST> is sorted by code point order, |
| 2756 | then complemented. If I<REPLACEMENTLIST> is empty and C</d> is not |
| 2757 | specified, I<REPLACEMENTLIST> is replaced by a copy of I<SEARCHLIST> (as |
| 2758 | modified under C</c>), and these potentially modified lists are used as |
| 2759 | the basis for what follows. Any character in the target string that |
| 2760 | isn't in I<SEARCHLIST> is passed through unchanged. Every other |
| 2761 | character in the target string is replaced by the character in |
| 2762 | I<REPLACEMENTLIST> that positionally corresponds to its mate in |
| 2763 | I<SEARCHLIST>, except that under C</s>, the 2nd and following characters |
| 2764 | are squeezed out in a sequence of characters in a row that all translate |
| 2765 | to the same character. If I<SEARCHLIST> is longer than |
| 2766 | I<REPLACEMENTLIST>, characters in the target string that match a |
| 2767 | character in I<SEARCHLIST> that doesn't have a correspondence in |
| 2768 | I<REPLACEMENTLIST> are either deleted from the target string if C</d> is |
| 2769 | specified; or replaced by the final character in I<REPLACEMENTLIST> if |
| 2770 | C</d> isn't specified. |
| 2771 | |
| 2772 | Some examples: |
| 2773 | |
| 2774 | $ARGV[1] =~ tr/A-Z/a-z/; # canonicalize to lower case ASCII |
| 2775 | |
| 2776 | $cnt = tr/*/*/; # count the stars in $_ |
| 2777 | $cnt = tr/*//; # same thing |
| 2778 | |
| 2779 | $cnt = $sky =~ tr/*/*/; # count the stars in $sky |
| 2780 | $cnt = $sky =~ tr/*//; # same thing |
| 2781 | |
| 2782 | $cnt = $sky =~ tr/*//c; # count all the non-stars in $sky |
| 2783 | $cnt = $sky =~ tr/*/*/c; # same, but transliterate each non-star |
| 2784 | # into a star, leaving the already-stars |
| 2785 | # alone. Afterwards, everything in $sky |
| 2786 | # is a star. |
| 2787 | |
| 2788 | $cnt = tr/0-9//; # count the ASCII digits in $_ |
| 2789 | |
| 2790 | tr/a-zA-Z//s; # bookkeeper -> bokeper |
| 2791 | tr/o/o/s; # bookkeeper -> bokkeeper |
| 2792 | tr/oe/oe/s; # bookkeeper -> bokkeper |
| 2793 | tr/oe//s; # bookkeeper -> bokkeper |
| 2794 | tr/oe/o/s; # bookkeeper -> bokkopor |
| 2795 | |
| 2796 | ($HOST = $host) =~ tr/a-z/A-Z/; |
| 2797 | $HOST = $host =~ tr/a-z/A-Z/r; # same thing |
| 2798 | |
| 2799 | $HOST = $host =~ tr/a-z/A-Z/r # chained with s///r |
| 2800 | =~ s/:/ -p/r; |
| 2801 | |
| 2802 | tr/a-zA-Z/ /cs; # change non-alphas to single space |
| 2803 | |
| 2804 | @stripped = map tr/a-zA-Z/ /csr, @original; |
| 2805 | # /r with map |
| 2806 | |
| 2807 | tr [\200-\377] |
| 2808 | [\000-\177]; # wickedly delete 8th bit |
| 2809 | |
| 2810 | $foo !~ tr/A/a/ # transliterate all the A's in $foo to 'a', |
| 2811 | # return 0 if any were found and changed. |
| 2812 | # Otherwise return 1 |
| 2813 | |
| 2814 | If multiple transliterations are given for a character, only the |
| 2815 | first one is used: |
| 2816 | |
| 2817 | tr/AAA/XYZ/ |
| 2818 | |
| 2819 | will transliterate any A to X. |
| 2820 | |
| 2821 | Because the transliteration table is built at compile time, neither |
| 2822 | the I<SEARCHLIST> nor the I<REPLACEMENTLIST> are subjected to double quote |
| 2823 | interpolation. That means that if you want to use variables, you |
| 2824 | must use an C<eval()>: |
| 2825 | |
| 2826 | eval "tr/$oldlist/$newlist/"; |
| 2827 | die $@ if $@; |
| 2828 | |
| 2829 | eval "tr/$oldlist/$newlist/, 1" or die $@; |
| 2830 | |
| 2831 | =item C<< <<I<EOF> >> |
| 2832 | X<here-doc> X<heredoc> X<here-document> X<<< << >>> |
| 2833 | |
| 2834 | A line-oriented form of quoting is based on the shell "here-document" |
| 2835 | syntax. Following a C<< << >> you specify a string to terminate |
| 2836 | the quoted material, and all lines following the current line down to |
| 2837 | the terminating string are the value of the item. |
| 2838 | |
| 2839 | Prefixing the terminating string with a C<~> specifies that you |
| 2840 | want to use L</Indented Here-docs> (see below). |
| 2841 | |
| 2842 | The terminating string may be either an identifier (a word), or some |
| 2843 | quoted text. An unquoted identifier works like double quotes. |
| 2844 | There may not be a space between the C<< << >> and the identifier, |
| 2845 | unless the identifier is explicitly quoted. The terminating string |
| 2846 | must appear by itself (unquoted and with no surrounding whitespace) |
| 2847 | on the terminating line. |
| 2848 | |
| 2849 | If the terminating string is quoted, the type of quotes used determine |
| 2850 | the treatment of the text. |
| 2851 | |
| 2852 | =over 4 |
| 2853 | |
| 2854 | =item Double Quotes |
| 2855 | |
| 2856 | Double quotes indicate that the text will be interpolated using exactly |
| 2857 | the same rules as normal double quoted strings. |
| 2858 | |
| 2859 | print <<EOF; |
| 2860 | The price is $Price. |
| 2861 | EOF |
| 2862 | |
| 2863 | print << "EOF"; # same as above |
| 2864 | The price is $Price. |
| 2865 | EOF |
| 2866 | |
| 2867 | |
| 2868 | =item Single Quotes |
| 2869 | |
| 2870 | Single quotes indicate the text is to be treated literally with no |
| 2871 | interpolation of its content. This is similar to single quoted |
| 2872 | strings except that backslashes have no special meaning, with C<\\> |
| 2873 | being treated as two backslashes and not one as they would in every |
| 2874 | other quoting construct. |
| 2875 | |
| 2876 | Just as in the shell, a backslashed bareword following the C<<< << >>> |
| 2877 | means the same thing as a single-quoted string does: |
| 2878 | |
| 2879 | $cost = <<'VISTA'; # hasta la ... |
| 2880 | That'll be $10 please, ma'am. |
| 2881 | VISTA |
| 2882 | |
| 2883 | $cost = <<\VISTA; # Same thing! |
| 2884 | That'll be $10 please, ma'am. |
| 2885 | VISTA |
| 2886 | |
| 2887 | This is the only form of quoting in perl where there is no need |
| 2888 | to worry about escaping content, something that code generators |
| 2889 | can and do make good use of. |
| 2890 | |
| 2891 | =item Backticks |
| 2892 | |
| 2893 | The content of the here doc is treated just as it would be if the |
| 2894 | string were embedded in backticks. Thus the content is interpolated |
| 2895 | as though it were double quoted and then executed via the shell, with |
| 2896 | the results of the execution returned. |
| 2897 | |
| 2898 | print << `EOC`; # execute command and get results |
| 2899 | echo hi there |
| 2900 | EOC |
| 2901 | |
| 2902 | =back |
| 2903 | |
| 2904 | =over 4 |
| 2905 | |
| 2906 | =item Indented Here-docs |
| 2907 | |
| 2908 | The here-doc modifier C<~> allows you to indent your here-docs to make |
| 2909 | the code more readable: |
| 2910 | |
| 2911 | if ($some_var) { |
| 2912 | print <<~EOF; |
| 2913 | This is a here-doc |
| 2914 | EOF |
| 2915 | } |
| 2916 | |
| 2917 | This will print... |
| 2918 | |
| 2919 | This is a here-doc |
| 2920 | |
| 2921 | ...with no leading whitespace. |
| 2922 | |
| 2923 | The line containing the delimiter that marks the end of the here-doc |
| 2924 | determines the indentation template for the whole thing. Compilation |
| 2925 | croaks if any non-empty line inside the here-doc does not begin with the |
| 2926 | precise indentation of the terminating line. (An empty line consists of |
| 2927 | the single character "\n".) For example, suppose the terminating line |
| 2928 | begins with a tab character followed by 4 space characters. Every |
| 2929 | non-empty line in the here-doc must begin with a tab followed by 4 |
| 2930 | spaces. They are stripped from each line, and any leading white space |
| 2931 | remaining on a line serves as the indentation for that line. Currently, |
| 2932 | only the TAB and SPACE characters are treated as whitespace for this |
| 2933 | purpose. Tabs and spaces may be mixed, but are matched exactly; tabs |
| 2934 | remain tabs and are not expanded. |
| 2935 | |
| 2936 | Additional beginning whitespace (beyond what preceded the |
| 2937 | delimiter) will be preserved: |
| 2938 | |
| 2939 | print <<~EOF; |
| 2940 | This text is not indented |
| 2941 | This text is indented with two spaces |
| 2942 | This text is indented with two tabs |
| 2943 | EOF |
| 2944 | |
| 2945 | Finally, the modifier may be used with all of the forms |
| 2946 | mentioned above: |
| 2947 | |
| 2948 | <<~\EOF; |
| 2949 | <<~'EOF' |
| 2950 | <<~"EOF" |
| 2951 | <<~`EOF` |
| 2952 | |
| 2953 | And whitespace may be used between the C<~> and quoted delimiters: |
| 2954 | |
| 2955 | <<~ 'EOF'; # ... "EOF", `EOF` |
| 2956 | |
| 2957 | =back |
| 2958 | |
| 2959 | It is possible to stack multiple here-docs in a row: |
| 2960 | |
| 2961 | print <<"foo", <<"bar"; # you can stack them |
| 2962 | I said foo. |
| 2963 | foo |
| 2964 | I said bar. |
| 2965 | bar |
| 2966 | |
| 2967 | myfunc(<< "THIS", 23, <<'THAT'); |
| 2968 | Here's a line |
| 2969 | or two. |
| 2970 | THIS |
| 2971 | and here's another. |
| 2972 | THAT |
| 2973 | |
| 2974 | Just don't forget that you have to put a semicolon on the end |
| 2975 | to finish the statement, as Perl doesn't know you're not going to |
| 2976 | try to do this: |
| 2977 | |
| 2978 | print <<ABC |
| 2979 | 179231 |
| 2980 | ABC |
| 2981 | + 20; |
| 2982 | |
| 2983 | If you want to remove the line terminator from your here-docs, |
| 2984 | use C<chomp()>. |
| 2985 | |
| 2986 | chomp($string = <<'END'); |
| 2987 | This is a string. |
| 2988 | END |
| 2989 | |
| 2990 | If you want your here-docs to be indented with the rest of the code, |
| 2991 | use the C<<< <<~FOO >>> construct described under L</Indented Here-docs>: |
| 2992 | |
| 2993 | $quote = <<~'FINIS'; |
| 2994 | The Road goes ever on and on, |
| 2995 | down from the door where it began. |
| 2996 | FINIS |
| 2997 | |
| 2998 | If you use a here-doc within a delimited construct, such as in C<s///eg>, |
| 2999 | the quoted material must still come on the line following the |
| 3000 | C<<< <<FOO >>> marker, which means it may be inside the delimited |
| 3001 | construct: |
| 3002 | |
| 3003 | s/this/<<E . 'that' |
| 3004 | the other |
| 3005 | E |
| 3006 | . 'more '/eg; |
| 3007 | |
| 3008 | It works this way as of Perl 5.18. Historically, it was inconsistent, and |
| 3009 | you would have to write |
| 3010 | |
| 3011 | s/this/<<E . 'that' |
| 3012 | . 'more '/eg; |
| 3013 | the other |
| 3014 | E |
| 3015 | |
| 3016 | outside of string evals. |
| 3017 | |
| 3018 | Additionally, quoting rules for the end-of-string identifier are |
| 3019 | unrelated to Perl's quoting rules. C<q()>, C<qq()>, and the like are not |
| 3020 | supported in place of C<''> and C<"">, and the only interpolation is for |
| 3021 | backslashing the quoting character: |
| 3022 | |
| 3023 | print << "abc\"def"; |
| 3024 | testing... |
| 3025 | abc"def |
| 3026 | |
| 3027 | Finally, quoted strings cannot span multiple lines. The general rule is |
| 3028 | that the identifier must be a string literal. Stick with that, and you |
| 3029 | should be safe. |
| 3030 | |
| 3031 | =back |
| 3032 | |
| 3033 | =head2 Gory details of parsing quoted constructs |
| 3034 | X<quote, gory details> |
| 3035 | |
| 3036 | When presented with something that might have several different |
| 3037 | interpretations, Perl uses the B<DWIM> (that's "Do What I Mean") |
| 3038 | principle to pick the most probable interpretation. This strategy |
| 3039 | is so successful that Perl programmers often do not suspect the |
| 3040 | ambivalence of what they write. But from time to time, Perl's |
| 3041 | notions differ substantially from what the author honestly meant. |
| 3042 | |
| 3043 | This section hopes to clarify how Perl handles quoted constructs. |
| 3044 | Although the most common reason to learn this is to unravel labyrinthine |
| 3045 | regular expressions, because the initial steps of parsing are the |
| 3046 | same for all quoting operators, they are all discussed together. |
| 3047 | |
| 3048 | The most important Perl parsing rule is the first one discussed |
| 3049 | below: when processing a quoted construct, Perl first finds the end |
| 3050 | of that construct, then interprets its contents. If you understand |
| 3051 | this rule, you may skip the rest of this section on the first |
| 3052 | reading. The other rules are likely to contradict the user's |
| 3053 | expectations much less frequently than this first one. |
| 3054 | |
| 3055 | Some passes discussed below are performed concurrently, but because |
| 3056 | their results are the same, we consider them individually. For different |
| 3057 | quoting constructs, Perl performs different numbers of passes, from |
| 3058 | one to four, but these passes are always performed in the same order. |
| 3059 | |
| 3060 | =over 4 |
| 3061 | |
| 3062 | =item Finding the end |
| 3063 | |
| 3064 | The first pass is finding the end of the quoted construct. This results |
| 3065 | in saving to a safe location a copy of the text (between the starting |
| 3066 | and ending delimiters), normalized as necessary to avoid needing to know |
| 3067 | what the original delimiters were. |
| 3068 | |
| 3069 | If the construct is a here-doc, the ending delimiter is a line |
| 3070 | that has a terminating string as the content. Therefore C<<<EOF> is |
| 3071 | terminated by C<EOF> immediately followed by C<"\n"> and starting |
| 3072 | from the first column of the terminating line. |
| 3073 | When searching for the terminating line of a here-doc, nothing |
| 3074 | is skipped. In other words, lines after the here-doc syntax |
| 3075 | are compared with the terminating string line by line. |
| 3076 | |
| 3077 | For the constructs except here-docs, single characters are used as starting |
| 3078 | and ending delimiters. If the starting delimiter is an opening punctuation |
| 3079 | (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the |
| 3080 | corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>). |
| 3081 | If the starting delimiter is an unpaired character like C</> or a closing |
| 3082 | punctuation, the ending delimiter is the same as the starting delimiter. |
| 3083 | Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates |
| 3084 | both C<qq[]> and C<qq]]> constructs. |
| 3085 | |
| 3086 | When searching for single-character delimiters, escaped delimiters |
| 3087 | and C<\\> are skipped. For example, while searching for terminating C</>, |
| 3088 | combinations of C<\\> and C<\/> are skipped. If the delimiters are |
| 3089 | bracketing, nested pairs are also skipped. For example, while searching |
| 3090 | for a closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>, |
| 3091 | and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well. |
| 3092 | However, when backslashes are used as the delimiters (like C<qq\\> and |
| 3093 | C<tr\\\>), nothing is skipped. |
| 3094 | During the search for the end, backslashes that escape delimiters or |
| 3095 | other backslashes are removed (exactly speaking, they are not copied to the |
| 3096 | safe location). |
| 3097 | |
| 3098 | For constructs with three-part delimiters (C<s///>, C<y///>, and |
| 3099 | C<tr///>), the search is repeated once more. |
| 3100 | If the first delimiter is not an opening punctuation, the three delimiters must |
| 3101 | be the same, such as C<s!!!> and C<tr)))>, |
| 3102 | in which case the second delimiter |
| 3103 | terminates the left part and starts the right part at once. |
| 3104 | If the left part is delimited by bracketing punctuation (that is C<()>, |
| 3105 | C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of |
| 3106 | delimiters such as C<s(){}> and C<tr[]//>. In these cases, whitespace |
| 3107 | and comments are allowed between the two parts, although the comment must follow |
| 3108 | at least one whitespace character; otherwise a character expected as the |
| 3109 | start of the comment may be regarded as the starting delimiter of the right part. |
| 3110 | |
| 3111 | During this search no attention is paid to the semantics of the construct. |
| 3112 | Thus: |
| 3113 | |
| 3114 | "$hash{"$foo/$bar"}" |
| 3115 | |
| 3116 | or: |
| 3117 | |
| 3118 | m/ |
| 3119 | bar # NOT a comment, this slash / terminated m//! |
| 3120 | /x |
| 3121 | |
| 3122 | do not form legal quoted expressions. The quoted part ends on the |
| 3123 | first C<"> and C</>, and the rest happens to be a syntax error. |
| 3124 | Because the slash that terminated C<m//> was followed by a C<SPACE>, |
| 3125 | the example above is not C<m//x>, but rather C<m//> with no C</x> |
| 3126 | modifier. So the embedded C<#> is interpreted as a literal C<#>. |
| 3127 | |
| 3128 | Also no attention is paid to C<\c\> (multichar control char syntax) during |
| 3129 | this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part |
| 3130 | of C<\/>, and the following C</> is not recognized as a delimiter. |
| 3131 | Instead, use C<\034> or C<\x1c> at the end of quoted constructs. |
| 3132 | |
| 3133 | =item Interpolation |
| 3134 | X<interpolation> |
| 3135 | |
| 3136 | The next step is interpolation in the text obtained, which is now |
| 3137 | delimiter-independent. There are multiple cases. |
| 3138 | |
| 3139 | =over 4 |
| 3140 | |
| 3141 | =item C<<<'EOF'> |
| 3142 | |
| 3143 | No interpolation is performed. |
| 3144 | Note that the combination C<\\> is left intact, since escaped delimiters |
| 3145 | are not available for here-docs. |
| 3146 | |
| 3147 | =item C<m''>, the pattern of C<s'''> |
| 3148 | |
| 3149 | No interpolation is performed at this stage. |
| 3150 | Any backslashed sequences including C<\\> are treated at the stage |
| 3151 | of L</"Parsing regular expressions">. |
| 3152 | |
| 3153 | =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''> |
| 3154 | |
| 3155 | The only interpolation is removal of C<\> from pairs of C<\\>. |
| 3156 | Therefore C<"-"> in C<tr'''> and C<y'''> is treated literally |
| 3157 | as a hyphen and no character range is available. |
| 3158 | C<\1> in the replacement of C<s'''> does not work as C<$1>. |
| 3159 | |
| 3160 | =item C<tr///>, C<y///> |
| 3161 | |
| 3162 | No variable interpolation occurs. String modifying combinations for |
| 3163 | case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized. |
| 3164 | The other escape sequences such as C<\200> and C<\t> and backslashed |
| 3165 | characters such as C<\\> and C<\-> are converted to appropriate literals. |
| 3166 | The character C<"-"> is treated specially and therefore C<\-> is treated |
| 3167 | as a literal C<"-">. |
| 3168 | |
| 3169 | =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF"> |
| 3170 | |
| 3171 | C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are |
| 3172 | converted to corresponding Perl constructs. Thus, C<"$foo\Qbaz$bar"> |
| 3173 | is converted to S<C<$foo . (quotemeta("baz" . $bar))>> internally. |
| 3174 | The other escape sequences such as C<\200> and C<\t> and backslashed |
| 3175 | characters such as C<\\> and C<\-> are replaced with appropriate |
| 3176 | expansions. |
| 3177 | |
| 3178 | Let it be stressed that I<whatever falls between C<\Q> and C<\E>> |
| 3179 | is interpolated in the usual way. Something like C<"\Q\\E"> has |
| 3180 | no C<\E> inside. Instead, it has C<\Q>, C<\\>, and C<E>, so the |
| 3181 | result is the same as for C<"\\\\E">. As a general rule, backslashes |
| 3182 | between C<\Q> and C<\E> may lead to counterintuitive results. So, |
| 3183 | C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same |
| 3184 | as C<"\\\t"> (since TAB is not alphanumeric). Note also that: |
| 3185 | |
| 3186 | $str = '\t'; |
| 3187 | return "\Q$str"; |
| 3188 | |
| 3189 | may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">. |
| 3190 | |
| 3191 | Interpolated scalars and arrays are converted internally to the C<join> and |
| 3192 | C<"."> catenation operations. Thus, S<C<"$foo XXX '@arr'">> becomes: |
| 3193 | |
| 3194 | $foo . " XXX '" . (join $", @arr) . "'"; |
| 3195 | |
| 3196 | All operations above are performed simultaneously, left to right. |
| 3197 | |
| 3198 | Because the result of S<C<"\Q I<STRING> \E">> has all metacharacters |
| 3199 | quoted, there is no way to insert a literal C<$> or C<@> inside a |
| 3200 | C<\Q\E> pair. If protected by C<\>, C<$> will be quoted to become |
| 3201 | C<"\\\$">; if not, it is interpreted as the start of an interpolated |
| 3202 | scalar. |
| 3203 | |
| 3204 | Note also that the interpolation code needs to make a decision on |
| 3205 | where the interpolated scalar ends. For instance, whether |
| 3206 | S<C<< "a $x -> {c}" >>> really means: |
| 3207 | |
| 3208 | "a " . $x . " -> {c}"; |
| 3209 | |
| 3210 | or: |
| 3211 | |
| 3212 | "a " . $x -> {c}; |
| 3213 | |
| 3214 | Most of the time, the longest possible text that does not include |
| 3215 | spaces between components and which contains matching braces or |
| 3216 | brackets. because the outcome may be determined by voting based |
| 3217 | on heuristic estimators, the result is not strictly predictable. |
| 3218 | Fortunately, it's usually correct for ambiguous cases. |
| 3219 | |
| 3220 | =item The replacement of C<s///> |
| 3221 | |
| 3222 | Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation |
| 3223 | happens as with C<qq//> constructs. |
| 3224 | |
| 3225 | It is at this step that C<\1> is begrudgingly converted to C<$1> in |
| 3226 | the replacement text of C<s///>, in order to correct the incorrigible |
| 3227 | I<sed> hackers who haven't picked up the saner idiom yet. A warning |
| 3228 | is emitted if the S<C<use warnings>> pragma or the B<-w> command-line flag |
| 3229 | (that is, the C<$^W> variable) was set. |
| 3230 | |
| 3231 | =item C<RE> in C<m?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>, |
| 3232 | |
| 3233 | Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>, |
| 3234 | and interpolation happens (almost) as with C<qq//> constructs. |
| 3235 | |
| 3236 | Processing of C<\N{...}> is also done here, and compiled into an intermediate |
| 3237 | form for the regex compiler. (This is because, as mentioned below, the regex |
| 3238 | compilation may be done at execution time, and C<\N{...}> is a compile-time |
| 3239 | construct.) |
| 3240 | |
| 3241 | However any other combinations of C<\> followed by a character |
| 3242 | are not substituted but only skipped, in order to parse them |
| 3243 | as regular expressions at the following step. |
| 3244 | As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly |
| 3245 | treated as an array symbol (for example C<@foo>), |
| 3246 | even though the same text in C<qq//> gives interpolation of C<\c@>. |
| 3247 | |
| 3248 | Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control |
| 3249 | back to the perl parser, in a similar way that an interpolated array |
| 3250 | subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be. |
| 3251 | |
| 3252 | Moreover, inside C<(?{BLOCK})>, S<C<(?# comment )>>, and |
| 3253 | a C<#>-comment in a C</x>-regular expression, no processing is |
| 3254 | performed whatsoever. This is the first step at which the presence |
| 3255 | of the C</x> modifier is relevant. |
| 3256 | |
| 3257 | Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+> |
| 3258 | and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are |
| 3259 | voted (by several different estimators) to be either an array element |
| 3260 | or C<$var> followed by an RE alternative. This is where the notation |
| 3261 | C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as |
| 3262 | array element C<-9>, not as a regular expression from the variable |
| 3263 | C<$arr> followed by a digit, which would be the interpretation of |
| 3264 | C</$arr[0-9]/>. Since voting among different estimators may occur, |
| 3265 | the result is not predictable. |
| 3266 | |
| 3267 | The lack of processing of C<\\> creates specific restrictions on |
| 3268 | the post-processed text. If the delimiter is C</>, one cannot get |
| 3269 | the combination C<\/> into the result of this step. C</> will |
| 3270 | finish the regular expression, C<\/> will be stripped to C</> on |
| 3271 | the previous step, and C<\\/> will be left as is. Because C</> is |
| 3272 | equivalent to C<\/> inside a regular expression, this does not |
| 3273 | matter unless the delimiter happens to be character special to the |
| 3274 | RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<m?foo?>; or an |
| 3275 | alphanumeric char, as in: |
| 3276 | |
| 3277 | m m ^ a \s* b mmx; |
| 3278 | |
| 3279 | In the RE above, which is intentionally obfuscated for illustration, the |
| 3280 | delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the |
| 3281 | RE is the same as for S<C<m/ ^ a \s* b /mx>>. There's more than one |
| 3282 | reason you're encouraged to restrict your delimiters to non-alphanumeric, |
| 3283 | non-whitespace choices. |
| 3284 | |
| 3285 | =back |
| 3286 | |
| 3287 | This step is the last one for all constructs except regular expressions, |
| 3288 | which are processed further. |
| 3289 | |
| 3290 | =item Parsing regular expressions |
| 3291 | X<regexp, parse> |
| 3292 | |
| 3293 | Previous steps were performed during the compilation of Perl code, |
| 3294 | but this one happens at run time, although it may be optimized to |
| 3295 | be calculated at compile time if appropriate. After preprocessing |
| 3296 | described above, and possibly after evaluation if concatenation, |
| 3297 | joining, casing translation, or metaquoting are involved, the |
| 3298 | resulting I<string> is passed to the RE engine for compilation. |
| 3299 | |
| 3300 | Whatever happens in the RE engine might be better discussed in L<perlre>, |
| 3301 | but for the sake of continuity, we shall do so here. |
| 3302 | |
| 3303 | This is another step where the presence of the C</x> modifier is |
| 3304 | relevant. The RE engine scans the string from left to right and |
| 3305 | converts it into a finite automaton. |
| 3306 | |
| 3307 | Backslashed characters are either replaced with corresponding |
| 3308 | literal strings (as with C<\{>), or else they generate special nodes |
| 3309 | in the finite automaton (as with C<\b>). Characters special to the |
| 3310 | RE engine (such as C<|>) generate corresponding nodes or groups of |
| 3311 | nodes. C<(?#...)> comments are ignored. All the rest is either |
| 3312 | converted to literal strings to match, or else is ignored (as is |
| 3313 | whitespace and C<#>-style comments if C</x> is present). |
| 3314 | |
| 3315 | Parsing of the bracketed character class construct, C<[...]>, is |
| 3316 | rather different than the rule used for the rest of the pattern. |
| 3317 | The terminator of this construct is found using the same rules as |
| 3318 | for finding the terminator of a C<{}>-delimited construct, the only |
| 3319 | exception being that C<]> immediately following C<[> is treated as |
| 3320 | though preceded by a backslash. |
| 3321 | |
| 3322 | The terminator of runtime C<(?{...})> is found by temporarily switching |
| 3323 | control to the perl parser, which should stop at the point where the |
| 3324 | logically balancing terminating C<}> is found. |
| 3325 | |
| 3326 | It is possible to inspect both the string given to RE engine and the |
| 3327 | resulting finite automaton. See the arguments C<debug>/C<debugcolor> |
| 3328 | in the S<C<use L<re>>> pragma, as well as Perl's B<-Dr> command-line |
| 3329 | switch documented in L<perlrun/"Command Switches">. |
| 3330 | |
| 3331 | =item Optimization of regular expressions |
| 3332 | X<regexp, optimization> |
| 3333 | |
| 3334 | This step is listed for completeness only. Since it does not change |
| 3335 | semantics, details of this step are not documented and are subject |
| 3336 | to change without notice. This step is performed over the finite |
| 3337 | automaton that was generated during the previous pass. |
| 3338 | |
| 3339 | It is at this stage that C<split()> silently optimizes C</^/> to |
| 3340 | mean C</^/m>. |
| 3341 | |
| 3342 | =back |
| 3343 | |
| 3344 | =head2 I/O Operators |
| 3345 | X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle> |
| 3346 | X<< <> >> X<< <<>> >> X<@ARGV> |
| 3347 | |
| 3348 | There are several I/O operators you should know about. |
| 3349 | |
| 3350 | A string enclosed by backticks (grave accents) first undergoes |
| 3351 | double-quote interpolation. It is then interpreted as an external |
| 3352 | command, and the output of that command is the value of the |
| 3353 | backtick string, like in a shell. In scalar context, a single string |
| 3354 | consisting of all output is returned. In list context, a list of |
| 3355 | values is returned, one per line of output. (You can set C<$/> to use |
| 3356 | a different line terminator.) The command is executed each time the |
| 3357 | pseudo-literal is evaluated. The status value of the command is |
| 3358 | returned in C<$?> (see L<perlvar> for the interpretation of C<$?>). |
| 3359 | Unlike in B<csh>, no translation is done on the return data--newlines |
| 3360 | remain newlines. Unlike in any of the shells, single quotes do not |
| 3361 | hide variable names in the command from interpretation. To pass a |
| 3362 | literal dollar-sign through to the shell you need to hide it with a |
| 3363 | backslash. The generalized form of backticks is C<qx//>, or you can |
| 3364 | call the L<perlfunc/readpipe> function. (Because |
| 3365 | backticks always undergo shell expansion as well, see L<perlsec> for |
| 3366 | security concerns.) |
| 3367 | X<qx> X<`> X<``> X<backtick> X<glob> |
| 3368 | |
| 3369 | In scalar context, evaluating a filehandle in angle brackets yields |
| 3370 | the next line from that file (the newline, if any, included), or |
| 3371 | C<undef> at end-of-file or on error. When C<$/> is set to C<undef> |
| 3372 | (sometimes known as file-slurp mode) and the file is empty, it |
| 3373 | returns C<''> the first time, followed by C<undef> subsequently. |
| 3374 | |
| 3375 | Ordinarily you must assign the returned value to a variable, but |
| 3376 | there is one situation where an automatic assignment happens. If |
| 3377 | and only if the input symbol is the only thing inside the conditional |
| 3378 | of a C<while> statement (even if disguised as a C<for(;;)> loop), |
| 3379 | the value is automatically assigned to the global variable C<$_>, |
| 3380 | destroying whatever was there previously. (This may seem like an |
| 3381 | odd thing to you, but you'll use the construct in almost every Perl |
| 3382 | script you write.) The C<$_> variable is not implicitly localized. |
| 3383 | You'll have to put a S<C<local $_;>> before the loop if you want that |
| 3384 | to happen. Furthermore, if the input symbol or an explicit assignment |
| 3385 | of the input symbol to a scalar is used as a C<while>/C<for> condition, |
| 3386 | then the condition actually tests for definedness of the expression's |
| 3387 | value, not for its regular truth value. |
| 3388 | |
| 3389 | Thus the following lines are equivalent: |
| 3390 | |
| 3391 | while (defined($_ = <STDIN>)) { print; } |
| 3392 | while ($_ = <STDIN>) { print; } |
| 3393 | while (<STDIN>) { print; } |
| 3394 | for (;<STDIN>;) { print; } |
| 3395 | print while defined($_ = <STDIN>); |
| 3396 | print while ($_ = <STDIN>); |
| 3397 | print while <STDIN>; |
| 3398 | |
| 3399 | This also behaves similarly, but assigns to a lexical variable |
| 3400 | instead of to C<$_>: |
| 3401 | |
| 3402 | while (my $line = <STDIN>) { print $line } |
| 3403 | |
| 3404 | In these loop constructs, the assigned value (whether assignment |
| 3405 | is automatic or explicit) is then tested to see whether it is |
| 3406 | defined. The defined test avoids problems where the line has a string |
| 3407 | value that would be treated as false by Perl; for example a "" or |
| 3408 | a C<"0"> with no trailing newline. If you really mean for such values |
| 3409 | to terminate the loop, they should be tested for explicitly: |
| 3410 | |
| 3411 | while (($_ = <STDIN>) ne '0') { ... } |
| 3412 | while (<STDIN>) { last unless $_; ... } |
| 3413 | |
| 3414 | In other boolean contexts, C<< <I<FILEHANDLE>> >> without an |
| 3415 | explicit C<defined> test or comparison elicits a warning if the |
| 3416 | S<C<use warnings>> pragma or the B<-w> |
| 3417 | command-line switch (the C<$^W> variable) is in effect. |
| 3418 | |
| 3419 | The filehandles STDIN, STDOUT, and STDERR are predefined. (The |
| 3420 | filehandles C<stdin>, C<stdout>, and C<stderr> will also work except |
| 3421 | in packages, where they would be interpreted as local identifiers |
| 3422 | rather than global.) Additional filehandles may be created with |
| 3423 | the C<open()> function, amongst others. See L<perlopentut> and |
| 3424 | L<perlfunc/open> for details on this. |
| 3425 | X<stdin> X<stdout> X<sterr> |
| 3426 | |
| 3427 | If a C<< <I<FILEHANDLE>> >> is used in a context that is looking for |
| 3428 | a list, a list comprising all input lines is returned, one line per |
| 3429 | list element. It's easy to grow to a rather large data space this |
| 3430 | way, so use with care. |
| 3431 | |
| 3432 | C<< <I<FILEHANDLE>> >> may also be spelled C<readline(*I<FILEHANDLE>)>. |
| 3433 | See L<perlfunc/readline>. |
| 3434 | |
| 3435 | The null filehandle C<< <> >> (sometimes called the diamond operator) is |
| 3436 | special: it can be used to emulate the |
| 3437 | behavior of B<sed> and B<awk>, and any other Unix filter program |
| 3438 | that takes a list of filenames, doing the same to each line |
| 3439 | of input from all of them. Input from C<< <> >> comes either from |
| 3440 | standard input, or from each file listed on the command line. Here's |
| 3441 | how it works: the first time C<< <> >> is evaluated, the C<@ARGV> array is |
| 3442 | checked, and if it is empty, C<$ARGV[0]> is set to C<"-">, which when opened |
| 3443 | gives you standard input. The C<@ARGV> array is then processed as a list |
| 3444 | of filenames. The loop |
| 3445 | |
| 3446 | while (<>) { |
| 3447 | ... # code for each line |
| 3448 | } |
| 3449 | |
| 3450 | is equivalent to the following Perl-like pseudo code: |
| 3451 | |
| 3452 | unshift(@ARGV, '-') unless @ARGV; |
| 3453 | while ($ARGV = shift) { |
| 3454 | open(ARGV, $ARGV); |
| 3455 | while (<ARGV>) { |
| 3456 | ... # code for each line |
| 3457 | } |
| 3458 | } |
| 3459 | |
| 3460 | except that it isn't so cumbersome to say, and will actually work. |
| 3461 | It really does shift the C<@ARGV> array and put the current filename |
| 3462 | into the C<$ARGV> variable. It also uses filehandle I<ARGV> |
| 3463 | internally. C<< <> >> is just a synonym for C<< <ARGV> >>, which |
| 3464 | is magical. (The pseudo code above doesn't work because it treats |
| 3465 | C<< <ARGV> >> as non-magical.) |
| 3466 | |
| 3467 | Since the null filehandle uses the two argument form of L<perlfunc/open> |
| 3468 | it interprets special characters, so if you have a script like this: |
| 3469 | |
| 3470 | while (<>) { |
| 3471 | print; |
| 3472 | } |
| 3473 | |
| 3474 | and call it with S<C<perl dangerous.pl 'rm -rfv *|'>>, it actually opens a |
| 3475 | pipe, executes the C<rm> command and reads C<rm>'s output from that pipe. |
| 3476 | If you want all items in C<@ARGV> to be interpreted as file names, you |
| 3477 | can use the module C<ARGV::readonly> from CPAN, or use the double |
| 3478 | diamond bracket: |
| 3479 | |
| 3480 | while (<<>>) { |
| 3481 | print; |
| 3482 | } |
| 3483 | |
| 3484 | Using double angle brackets inside of a while causes the open to use the |
| 3485 | three argument form (with the second argument being C<< < >>), so all |
| 3486 | arguments in C<ARGV> are treated as literal filenames (including C<"-">). |
| 3487 | (Note that for convenience, if you use C<< <<>> >> and if C<@ARGV> is |
| 3488 | empty, it will still read from the standard input.) |
| 3489 | |
| 3490 | You can modify C<@ARGV> before the first C<< <> >> as long as the array ends up |
| 3491 | containing the list of filenames you really want. Line numbers (C<$.>) |
| 3492 | continue as though the input were one big happy file. See the example |
| 3493 | in L<perlfunc/eof> for how to reset line numbers on each file. |
| 3494 | |
| 3495 | If you want to set C<@ARGV> to your own list of files, go right ahead. |
| 3496 | This sets C<@ARGV> to all plain text files if no C<@ARGV> was given: |
| 3497 | |
| 3498 | @ARGV = grep { -f && -T } glob('*') unless @ARGV; |
| 3499 | |
| 3500 | You can even set them to pipe commands. For example, this automatically |
| 3501 | filters compressed arguments through B<gzip>: |
| 3502 | |
| 3503 | @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV; |
| 3504 | |
| 3505 | If you want to pass switches into your script, you can use one of the |
| 3506 | C<Getopts> modules or put a loop on the front like this: |
| 3507 | |
| 3508 | while ($_ = $ARGV[0], /^-/) { |
| 3509 | shift; |
| 3510 | last if /^--$/; |
| 3511 | if (/^-D(.*)/) { $debug = $1 } |
| 3512 | if (/^-v/) { $verbose++ } |
| 3513 | # ... # other switches |
| 3514 | } |
| 3515 | |
| 3516 | while (<>) { |
| 3517 | # ... # code for each line |
| 3518 | } |
| 3519 | |
| 3520 | The C<< <> >> symbol will return C<undef> for end-of-file only once. |
| 3521 | If you call it again after this, it will assume you are processing another |
| 3522 | C<@ARGV> list, and if you haven't set C<@ARGV>, will read input from STDIN. |
| 3523 | |
| 3524 | If what the angle brackets contain is a simple scalar variable (for example, |
| 3525 | C<$foo>), then that variable contains the name of the |
| 3526 | filehandle to input from, or its typeglob, or a reference to the |
| 3527 | same. For example: |
| 3528 | |
| 3529 | $fh = \*STDIN; |
| 3530 | $line = <$fh>; |
| 3531 | |
| 3532 | If what's within the angle brackets is neither a filehandle nor a simple |
| 3533 | scalar variable containing a filehandle name, typeglob, or typeglob |
| 3534 | reference, it is interpreted as a filename pattern to be globbed, and |
| 3535 | either a list of filenames or the next filename in the list is returned, |
| 3536 | depending on context. This distinction is determined on syntactic |
| 3537 | grounds alone. That means C<< <$x> >> is always a C<readline()> from |
| 3538 | an indirect handle, but C<< <$hash{key}> >> is always a C<glob()>. |
| 3539 | That's because C<$x> is a simple scalar variable, but C<$hash{key}> is |
| 3540 | not--it's a hash element. Even C<< <$x > >> (note the extra space) |
| 3541 | is treated as C<glob("$x ")>, not C<readline($x)>. |
| 3542 | |
| 3543 | One level of double-quote interpretation is done first, but you can't |
| 3544 | say C<< <$foo> >> because that's an indirect filehandle as explained |
| 3545 | in the previous paragraph. (In older versions of Perl, programmers |
| 3546 | would insert curly brackets to force interpretation as a filename glob: |
| 3547 | C<< <${foo}> >>. These days, it's considered cleaner to call the |
| 3548 | internal function directly as C<glob($foo)>, which is probably the right |
| 3549 | way to have done it in the first place.) For example: |
| 3550 | |
| 3551 | while (<*.c>) { |
| 3552 | chmod 0644, $_; |
| 3553 | } |
| 3554 | |
| 3555 | is roughly equivalent to: |
| 3556 | |
| 3557 | open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|"); |
| 3558 | while (<FOO>) { |
| 3559 | chomp; |
| 3560 | chmod 0644, $_; |
| 3561 | } |
| 3562 | |
| 3563 | except that the globbing is actually done internally using the standard |
| 3564 | C<L<File::Glob>> extension. Of course, the shortest way to do the above is: |
| 3565 | |
| 3566 | chmod 0644, <*.c>; |
| 3567 | |
| 3568 | A (file)glob evaluates its (embedded) argument only when it is |
| 3569 | starting a new list. All values must be read before it will start |
| 3570 | over. In list context, this isn't important because you automatically |
| 3571 | get them all anyway. However, in scalar context the operator returns |
| 3572 | the next value each time it's called, or C<undef> when the list has |
| 3573 | run out. As with filehandle reads, an automatic C<defined> is |
| 3574 | generated when the glob occurs in the test part of a C<while>, |
| 3575 | because legal glob returns (for example, |
| 3576 | a file called F<0>) would otherwise |
| 3577 | terminate the loop. Again, C<undef> is returned only once. So if |
| 3578 | you're expecting a single value from a glob, it is much better to |
| 3579 | say |
| 3580 | |
| 3581 | ($file) = <blurch*>; |
| 3582 | |
| 3583 | than |
| 3584 | |
| 3585 | $file = <blurch*>; |
| 3586 | |
| 3587 | because the latter will alternate between returning a filename and |
| 3588 | returning false. |
| 3589 | |
| 3590 | If you're trying to do variable interpolation, it's definitely better |
| 3591 | to use the C<glob()> function, because the older notation can cause people |
| 3592 | to become confused with the indirect filehandle notation. |
| 3593 | |
| 3594 | @files = glob("$dir/*.[ch]"); |
| 3595 | @files = glob($files[$i]); |
| 3596 | |
| 3597 | If an angle-bracket-based globbing expression is used as the condition of |
| 3598 | a C<while> or C<for> loop, then it will be implicitly assigned to C<$_>. |
| 3599 | If either a globbing expression or an explicit assignment of a globbing |
| 3600 | expression to a scalar is used as a C<while>/C<for> condition, then |
| 3601 | the condition actually tests for definedness of the expression's value, |
| 3602 | not for its regular truth value. |
| 3603 | |
| 3604 | =head2 Constant Folding |
| 3605 | X<constant folding> X<folding> |
| 3606 | |
| 3607 | Like C, Perl does a certain amount of expression evaluation at |
| 3608 | compile time whenever it determines that all arguments to an |
| 3609 | operator are static and have no side effects. In particular, string |
| 3610 | concatenation happens at compile time between literals that don't do |
| 3611 | variable substitution. Backslash interpolation also happens at |
| 3612 | compile time. You can say |
| 3613 | |
| 3614 | 'Now is the time for all' |
| 3615 | . "\n" |
| 3616 | . 'good men to come to.' |
| 3617 | |
| 3618 | and this all reduces to one string internally. Likewise, if |
| 3619 | you say |
| 3620 | |
| 3621 | foreach $file (@filenames) { |
| 3622 | if (-s $file > 5 + 100 * 2**16) { } |
| 3623 | } |
| 3624 | |
| 3625 | the compiler precomputes the number which that expression |
| 3626 | represents so that the interpreter won't have to. |
| 3627 | |
| 3628 | =head2 No-ops |
| 3629 | X<no-op> X<nop> |
| 3630 | |
| 3631 | Perl doesn't officially have a no-op operator, but the bare constants |
| 3632 | C<0> and C<1> are special-cased not to produce a warning in void |
| 3633 | context, so you can for example safely do |
| 3634 | |
| 3635 | 1 while foo(); |
| 3636 | |
| 3637 | =head2 Bitwise String Operators |
| 3638 | X<operator, bitwise, string> X<&.> X<|.> X<^.> X<~.> |
| 3639 | |
| 3640 | Bitstrings of any size may be manipulated by the bitwise operators |
| 3641 | (C<~ | & ^>). |
| 3642 | |
| 3643 | If the operands to a binary bitwise op are strings of different |
| 3644 | sizes, B<|> and B<^> ops act as though the shorter operand had |
| 3645 | additional zero bits on the right, while the B<&> op acts as though |
| 3646 | the longer operand were truncated to the length of the shorter. |
| 3647 | The granularity for such extension or truncation is one or more |
| 3648 | bytes. |
| 3649 | |
| 3650 | # ASCII-based examples |
| 3651 | print "j p \n" ^ " a h"; # prints "JAPH\n" |
| 3652 | print "JA" | " ph\n"; # prints "japh\n" |
| 3653 | print "japh\nJunk" & '_____'; # prints "JAPH\n"; |
| 3654 | print 'p N$' ^ " E<H\n"; # prints "Perl\n"; |
| 3655 | |
| 3656 | If you are intending to manipulate bitstrings, be certain that |
| 3657 | you're supplying bitstrings: If an operand is a number, that will imply |
| 3658 | a B<numeric> bitwise operation. You may explicitly show which type of |
| 3659 | operation you intend by using C<""> or C<0+>, as in the examples below. |
| 3660 | |
| 3661 | $foo = 150 | 105; # yields 255 (0x96 | 0x69 is 0xFF) |
| 3662 | $foo = '150' | 105; # yields 255 |
| 3663 | $foo = 150 | '105'; # yields 255 |
| 3664 | $foo = '150' | '105'; # yields string '155' (under ASCII) |
| 3665 | |
| 3666 | $baz = 0+$foo & 0+$bar; # both ops explicitly numeric |
| 3667 | $biz = "$foo" ^ "$bar"; # both ops explicitly stringy |
| 3668 | |
| 3669 | This somewhat unpredictable behavior can be avoided with the "bitwise" |
| 3670 | feature, new in Perl 5.22. You can enable it via S<C<use feature |
| 3671 | 'bitwise'>> or C<use v5.28>. Before Perl 5.28, it used to emit a warning |
| 3672 | in the C<"experimental::bitwise"> category. Under this feature, the four |
| 3673 | standard bitwise operators (C<~ | & ^>) are always numeric. Adding a dot |
| 3674 | after each operator (C<~. |. &. ^.>) forces it to treat its operands as |
| 3675 | strings: |
| 3676 | |
| 3677 | use feature "bitwise"; |
| 3678 | $foo = 150 | 105; # yields 255 (0x96 | 0x69 is 0xFF) |
| 3679 | $foo = '150' | 105; # yields 255 |
| 3680 | $foo = 150 | '105'; # yields 255 |
| 3681 | $foo = '150' | '105'; # yields 255 |
| 3682 | $foo = 150 |. 105; # yields string '155' |
| 3683 | $foo = '150' |. 105; # yields string '155' |
| 3684 | $foo = 150 |.'105'; # yields string '155' |
| 3685 | $foo = '150' |.'105'; # yields string '155' |
| 3686 | |
| 3687 | $baz = $foo & $bar; # both operands numeric |
| 3688 | $biz = $foo ^. $bar; # both operands stringy |
| 3689 | |
| 3690 | The assignment variants of these operators (C<&= |= ^= &.= |.= ^.=>) |
| 3691 | behave likewise under the feature. |
| 3692 | |
| 3693 | It is a fatal error if an operand contains a character whose ordinal |
| 3694 | value is above 0xFF, and hence not expressible except in UTF-8. The |
| 3695 | operation is performed on a non-UTF-8 copy for other operands encoded in |
| 3696 | UTF-8. See L<perlunicode/Byte and Character Semantics>. |
| 3697 | |
| 3698 | See L<perlfunc/vec> for information on how to manipulate individual bits |
| 3699 | in a bit vector. |
| 3700 | |
| 3701 | =head2 Integer Arithmetic |
| 3702 | X<integer> |
| 3703 | |
| 3704 | By default, Perl assumes that it must do most of its arithmetic in |
| 3705 | floating point. But by saying |
| 3706 | |
| 3707 | use integer; |
| 3708 | |
| 3709 | you may tell the compiler to use integer operations |
| 3710 | (see L<integer> for a detailed explanation) from here to the end of |
| 3711 | the enclosing BLOCK. An inner BLOCK may countermand this by saying |
| 3712 | |
| 3713 | no integer; |
| 3714 | |
| 3715 | which lasts until the end of that BLOCK. Note that this doesn't |
| 3716 | mean everything is an integer, merely that Perl will use integer |
| 3717 | operations for arithmetic, comparison, and bitwise operators. For |
| 3718 | example, even under S<C<use integer>>, if you take the C<sqrt(2)>, you'll |
| 3719 | still get C<1.4142135623731> or so. |
| 3720 | |
| 3721 | Used on numbers, the bitwise operators (C<&> C<|> C<^> C<~> C<< << >> |
| 3722 | C<< >> >>) always produce integral results. (But see also |
| 3723 | L</Bitwise String Operators>.) However, S<C<use integer>> still has meaning for |
| 3724 | them. By default, their results are interpreted as unsigned integers, but |
| 3725 | if S<C<use integer>> is in effect, their results are interpreted |
| 3726 | as signed integers. For example, C<~0> usually evaluates to a large |
| 3727 | integral value. However, S<C<use integer; ~0>> is C<-1> on two's-complement |
| 3728 | machines. |
| 3729 | |
| 3730 | =head2 Floating-point Arithmetic |
| 3731 | |
| 3732 | X<floating-point> X<floating point> X<float> X<real> |
| 3733 | |
| 3734 | While S<C<use integer>> provides integer-only arithmetic, there is no |
| 3735 | analogous mechanism to provide automatic rounding or truncation to a |
| 3736 | certain number of decimal places. For rounding to a certain number |
| 3737 | of digits, C<sprintf()> or C<printf()> is usually the easiest route. |
| 3738 | See L<perlfaq4>. |
| 3739 | |
| 3740 | Floating-point numbers are only approximations to what a mathematician |
| 3741 | would call real numbers. There are infinitely more reals than floats, |
| 3742 | so some corners must be cut. For example: |
| 3743 | |
| 3744 | printf "%.20g\n", 123456789123456789; |
| 3745 | # produces 123456789123456784 |
| 3746 | |
| 3747 | Testing for exact floating-point equality or inequality is not a |
| 3748 | good idea. Here's a (relatively expensive) work-around to compare |
| 3749 | whether two floating-point numbers are equal to a particular number of |
| 3750 | decimal places. See Knuth, volume II, for a more robust treatment of |
| 3751 | this topic. |
| 3752 | |
| 3753 | sub fp_equal { |
| 3754 | my ($X, $Y, $POINTS) = @_; |
| 3755 | my ($tX, $tY); |
| 3756 | $tX = sprintf("%.${POINTS}g", $X); |
| 3757 | $tY = sprintf("%.${POINTS}g", $Y); |
| 3758 | return $tX eq $tY; |
| 3759 | } |
| 3760 | |
| 3761 | The POSIX module (part of the standard perl distribution) implements |
| 3762 | C<ceil()>, C<floor()>, and other mathematical and trigonometric functions. |
| 3763 | The C<L<Math::Complex>> module (part of the standard perl distribution) |
| 3764 | defines mathematical functions that work on both the reals and the |
| 3765 | imaginary numbers. C<Math::Complex> is not as efficient as POSIX, but |
| 3766 | POSIX can't work with complex numbers. |
| 3767 | |
| 3768 | Rounding in financial applications can have serious implications, and |
| 3769 | the rounding method used should be specified precisely. In these |
| 3770 | cases, it probably pays not to trust whichever system rounding is |
| 3771 | being used by Perl, but to instead implement the rounding function you |
| 3772 | need yourself. |
| 3773 | |
| 3774 | =head2 Bigger Numbers |
| 3775 | X<number, arbitrary precision> |
| 3776 | |
| 3777 | The standard C<L<Math::BigInt>>, C<L<Math::BigRat>>, and |
| 3778 | C<L<Math::BigFloat>> modules, |
| 3779 | along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide |
| 3780 | variable-precision arithmetic and overloaded operators, although |
| 3781 | they're currently pretty slow. At the cost of some space and |
| 3782 | considerable speed, they avoid the normal pitfalls associated with |
| 3783 | limited-precision representations. |
| 3784 | |
| 3785 | use 5.010; |
| 3786 | use bigint; # easy interface to Math::BigInt |
| 3787 | $x = 123456789123456789; |
| 3788 | say $x * $x; |
| 3789 | +15241578780673678515622620750190521 |
| 3790 | |
| 3791 | Or with rationals: |
| 3792 | |
| 3793 | use 5.010; |
| 3794 | use bigrat; |
| 3795 | $x = 3/22; |
| 3796 | $y = 4/6; |
| 3797 | say "x/y is ", $x/$y; |
| 3798 | say "x*y is ", $x*$y; |
| 3799 | x/y is 9/44 |
| 3800 | x*y is 1/11 |
| 3801 | |
| 3802 | Several modules let you calculate with unlimited or fixed precision |
| 3803 | (bound only by memory and CPU time). There |
| 3804 | are also some non-standard modules that |
| 3805 | provide faster implementations via external C libraries. |
| 3806 | |
| 3807 | Here is a short, but incomplete summary: |
| 3808 | |
| 3809 | Math::String treat string sequences like numbers |
| 3810 | Math::FixedPrecision calculate with a fixed precision |
| 3811 | Math::Currency for currency calculations |
| 3812 | Bit::Vector manipulate bit vectors fast (uses C) |
| 3813 | Math::BigIntFast Bit::Vector wrapper for big numbers |
| 3814 | Math::Pari provides access to the Pari C library |
| 3815 | Math::Cephes uses the external Cephes C library (no |
| 3816 | big numbers) |
| 3817 | Math::Cephes::Fraction fractions via the Cephes library |
| 3818 | Math::GMP another one using an external C library |
| 3819 | Math::GMPz an alternative interface to libgmp's big ints |
| 3820 | Math::GMPq an interface to libgmp's fraction numbers |
| 3821 | Math::GMPf an interface to libgmp's floating point numbers |
| 3822 | |
| 3823 | Choose wisely. |
| 3824 | |
| 3825 | =cut |