| 1 | =head1 NAME |
| 2 | X<operator> |
| 3 | |
| 4 | perlop - Perl operators and precedence |
| 5 | |
| 6 | =head1 DESCRIPTION |
| 7 | |
| 8 | In Perl, the operator determines what operation is performed, |
| 9 | independent of the type of the operands. For example C<$x + $y> |
| 10 | is always a numeric addition, and if C<$x> or C<$y> do not contain |
| 11 | numbers, an attempt is made to convert them to numbers first. |
| 12 | |
| 13 | This is in contrast to many other dynamic languages, where the |
| 14 | operation is determined by the type of the first argument. It also |
| 15 | means that Perl has two versions of some operators, one for numeric |
| 16 | and one for string comparison. For example C<$x == $y> compares |
| 17 | two numbers for equality, and C<$x eq $y> compares two strings. |
| 18 | |
| 19 | There are a few exceptions though: C<x> can be either string |
| 20 | repetition or list repetition, depending on the type of the left |
| 21 | operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit |
| 22 | operations. |
| 23 | |
| 24 | =head2 Operator Precedence and Associativity |
| 25 | X<operator, precedence> X<precedence> X<associativity> |
| 26 | |
| 27 | Operator precedence and associativity work in Perl more or less like |
| 28 | they do in mathematics. |
| 29 | |
| 30 | I<Operator precedence> means some operators are evaluated before |
| 31 | others. For example, in C<2 + 4 * 5>, the multiplication has higher |
| 32 | precedence so C<4 * 5> is evaluated first yielding C<2 + 20 == |
| 33 | 22> and not C<6 * 5 == 30>. |
| 34 | |
| 35 | I<Operator associativity> defines what happens if a sequence of the |
| 36 | same operators is used one after another: whether the evaluator will |
| 37 | evaluate the left operations first or the right. For example, in C<8 |
| 38 | - 4 - 2>, subtraction is left associative so Perl evaluates the |
| 39 | expression left to right. C<8 - 4> is evaluated first making the |
| 40 | expression C<4 - 2 == 2> and not C<8 - 2 == 6>. |
| 41 | |
| 42 | Perl operators have the following associativity and precedence, |
| 43 | listed from highest precedence to lowest. Operators borrowed from |
| 44 | C keep the same precedence relationship with each other, even where |
| 45 | C's precedence is slightly screwy. (This makes learning Perl easier |
| 46 | for C folks.) With very few exceptions, these all operate on scalar |
| 47 | values only, not array values. |
| 48 | |
| 49 | left terms and list operators (leftward) |
| 50 | left -> |
| 51 | nonassoc ++ -- |
| 52 | right ** |
| 53 | right ! ~ \ and unary + and - |
| 54 | left =~ !~ |
| 55 | left * / % x |
| 56 | left + - . |
| 57 | left << >> |
| 58 | nonassoc named unary operators |
| 59 | nonassoc < > <= >= lt gt le ge |
| 60 | nonassoc == != <=> eq ne cmp ~~ |
| 61 | left & |
| 62 | left | ^ |
| 63 | left && |
| 64 | left || // |
| 65 | nonassoc .. ... |
| 66 | right ?: |
| 67 | right = += -= *= etc. goto last next redo dump |
| 68 | left , => |
| 69 | nonassoc list operators (rightward) |
| 70 | right not |
| 71 | left and |
| 72 | left or xor |
| 73 | |
| 74 | In the following sections, these operators are covered in precedence order. |
| 75 | |
| 76 | Many operators can be overloaded for objects. See L<overload>. |
| 77 | |
| 78 | =head2 Terms and List Operators (Leftward) |
| 79 | X<list operator> X<operator, list> X<term> |
| 80 | |
| 81 | A TERM has the highest precedence in Perl. They include variables, |
| 82 | quote and quote-like operators, any expression in parentheses, |
| 83 | and any function whose arguments are parenthesized. Actually, there |
| 84 | aren't really functions in this sense, just list operators and unary |
| 85 | operators behaving as functions because you put parentheses around |
| 86 | the arguments. These are all documented in L<perlfunc>. |
| 87 | |
| 88 | If any list operator (print(), etc.) or any unary operator (chdir(), etc.) |
| 89 | is followed by a left parenthesis as the next token, the operator and |
| 90 | arguments within parentheses are taken to be of highest precedence, |
| 91 | just like a normal function call. |
| 92 | |
| 93 | In the absence of parentheses, the precedence of list operators such as |
| 94 | C<print>, C<sort>, or C<chmod> is either very high or very low depending on |
| 95 | whether you are looking at the left side or the right side of the operator. |
| 96 | For example, in |
| 97 | |
| 98 | @ary = (1, 3, sort 4, 2); |
| 99 | print @ary; # prints 1324 |
| 100 | |
| 101 | the commas on the right of the sort are evaluated before the sort, |
| 102 | but the commas on the left are evaluated after. In other words, |
| 103 | list operators tend to gobble up all arguments that follow, and |
| 104 | then act like a simple TERM with regard to the preceding expression. |
| 105 | Be careful with parentheses: |
| 106 | |
| 107 | # These evaluate exit before doing the print: |
| 108 | print($foo, exit); # Obviously not what you want. |
| 109 | print $foo, exit; # Nor is this. |
| 110 | |
| 111 | # These do the print before evaluating exit: |
| 112 | (print $foo), exit; # This is what you want. |
| 113 | print($foo), exit; # Or this. |
| 114 | print ($foo), exit; # Or even this. |
| 115 | |
| 116 | Also note that |
| 117 | |
| 118 | print ($foo & 255) + 1, "\n"; |
| 119 | |
| 120 | probably doesn't do what you expect at first glance. The parentheses |
| 121 | enclose the argument list for C<print> which is evaluated (printing |
| 122 | the result of C<$foo & 255>). Then one is added to the return value |
| 123 | of C<print> (usually 1). The result is something like this: |
| 124 | |
| 125 | 1 + 1, "\n"; # Obviously not what you meant. |
| 126 | |
| 127 | To do what you meant properly, you must write: |
| 128 | |
| 129 | print(($foo & 255) + 1, "\n"); |
| 130 | |
| 131 | See L<Named Unary Operators> for more discussion of this. |
| 132 | |
| 133 | Also parsed as terms are the C<do {}> and C<eval {}> constructs, as |
| 134 | well as subroutine and method calls, and the anonymous |
| 135 | constructors C<[]> and C<{}>. |
| 136 | |
| 137 | See also L<Quote and Quote-like Operators> toward the end of this section, |
| 138 | as well as L</"I/O Operators">. |
| 139 | |
| 140 | =head2 The Arrow Operator |
| 141 | X<arrow> X<dereference> X<< -> >> |
| 142 | |
| 143 | "C<< -> >>" is an infix dereference operator, just as it is in C |
| 144 | and C++. If the right side is either a C<[...]>, C<{...}>, or a |
| 145 | C<(...)> subscript, then the left side must be either a hard or |
| 146 | symbolic reference to an array, a hash, or a subroutine respectively. |
| 147 | (Or technically speaking, a location capable of holding a hard |
| 148 | reference, if it's an array or hash reference being used for |
| 149 | assignment.) See L<perlreftut> and L<perlref>. |
| 150 | |
| 151 | Otherwise, the right side is a method name or a simple scalar |
| 152 | variable containing either the method name or a subroutine reference, |
| 153 | and the left side must be either an object (a blessed reference) |
| 154 | or a class name (that is, a package name). See L<perlobj>. |
| 155 | |
| 156 | The dereferencing cases (as opposed to method-calling cases) are |
| 157 | somewhat extended by the experimental C<postderef> feature. For the |
| 158 | details of that feature, consult L<perlref/Postfix Dereference Syntax>. |
| 159 | |
| 160 | =head2 Auto-increment and Auto-decrement |
| 161 | X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<--> |
| 162 | |
| 163 | "++" and "--" work as in C. That is, if placed before a variable, |
| 164 | they increment or decrement the variable by one before returning the |
| 165 | value, and if placed after, increment or decrement after returning the |
| 166 | value. |
| 167 | |
| 168 | $i = 0; $j = 0; |
| 169 | print $i++; # prints 0 |
| 170 | print ++$j; # prints 1 |
| 171 | |
| 172 | Note that just as in C, Perl doesn't define B<when> the variable is |
| 173 | incremented or decremented. You just know it will be done sometime |
| 174 | before or after the value is returned. This also means that modifying |
| 175 | a variable twice in the same statement will lead to undefined behavior. |
| 176 | Avoid statements like: |
| 177 | |
| 178 | $i = $i ++; |
| 179 | print ++ $i + $i ++; |
| 180 | |
| 181 | Perl will not guarantee what the result of the above statements is. |
| 182 | |
| 183 | The auto-increment operator has a little extra builtin magic to it. If |
| 184 | you increment a variable that is numeric, or that has ever been used in |
| 185 | a numeric context, you get a normal increment. If, however, the |
| 186 | variable has been used in only string contexts since it was set, and |
| 187 | has a value that is not the empty string and matches the pattern |
| 188 | C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each |
| 189 | character within its range, with carry: |
| 190 | |
| 191 | print ++($foo = "99"); # prints "100" |
| 192 | print ++($foo = "a0"); # prints "a1" |
| 193 | print ++($foo = "Az"); # prints "Ba" |
| 194 | print ++($foo = "zz"); # prints "aaa" |
| 195 | |
| 196 | C<undef> is always treated as numeric, and in particular is changed |
| 197 | to C<0> before incrementing (so that a post-increment of an undef value |
| 198 | will return C<0> rather than C<undef>). |
| 199 | |
| 200 | The auto-decrement operator is not magical. |
| 201 | |
| 202 | =head2 Exponentiation |
| 203 | X<**> X<exponentiation> X<power> |
| 204 | |
| 205 | Binary "**" is the exponentiation operator. It binds even more |
| 206 | tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is |
| 207 | implemented using C's pow(3) function, which actually works on doubles |
| 208 | internally.) |
| 209 | |
| 210 | Note that certain exponentiation expressions are ill-defined: |
| 211 | these include C<0**0>, C<1**Inf>, and C<Inf**0>. Do not expect |
| 212 | any particular results from these special cases, the results |
| 213 | are platform-dependent. |
| 214 | |
| 215 | =head2 Symbolic Unary Operators |
| 216 | X<unary operator> X<operator, unary> |
| 217 | |
| 218 | Unary "!" performs logical negation, that is, "not". See also C<not> for a lower |
| 219 | precedence version of this. |
| 220 | X<!> |
| 221 | |
| 222 | Unary "-" performs arithmetic negation if the operand is numeric, |
| 223 | including any string that looks like a number. If the operand is |
| 224 | an identifier, a string consisting of a minus sign concatenated |
| 225 | with the identifier is returned. Otherwise, if the string starts |
| 226 | with a plus or minus, a string starting with the opposite sign is |
| 227 | returned. One effect of these rules is that -bareword is equivalent |
| 228 | to the string "-bareword". If, however, the string begins with a |
| 229 | non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert |
| 230 | the string to a numeric and the arithmetic negation is performed. If the |
| 231 | string cannot be cleanly converted to a numeric, Perl will give the warning |
| 232 | B<Argument "the string" isn't numeric in negation (-) at ...>. |
| 233 | X<-> X<negation, arithmetic> |
| 234 | |
| 235 | Unary "~" performs bitwise negation, that is, 1's complement. For |
| 236 | example, C<0666 & ~027> is 0640. (See also L<Integer Arithmetic> and |
| 237 | L<Bitwise String Operators>.) Note that the width of the result is |
| 238 | platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64 |
| 239 | bits wide on a 64-bit platform, so if you are expecting a certain bit |
| 240 | width, remember to use the "&" operator to mask off the excess bits. |
| 241 | X<~> X<negation, binary> |
| 242 | |
| 243 | When complementing strings, if all characters have ordinal values under |
| 244 | 256, then their complements will, also. But if they do not, all |
| 245 | characters will be in either 32- or 64-bit complements, depending on your |
| 246 | architecture. So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on |
| 247 | 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines. |
| 248 | |
| 249 | Unary "+" has no effect whatsoever, even on strings. It is useful |
| 250 | syntactically for separating a function name from a parenthesized expression |
| 251 | that would otherwise be interpreted as the complete list of function |
| 252 | arguments. (See examples above under L<Terms and List Operators (Leftward)>.) |
| 253 | X<+> |
| 254 | |
| 255 | Unary "\" creates a reference to whatever follows it. See L<perlreftut> |
| 256 | and L<perlref>. Do not confuse this behavior with the behavior of |
| 257 | backslash within a string, although both forms do convey the notion |
| 258 | of protecting the next thing from interpolation. |
| 259 | X<\> X<reference> X<backslash> |
| 260 | |
| 261 | =head2 Binding Operators |
| 262 | X<binding> X<operator, binding> X<=~> X<!~> |
| 263 | |
| 264 | Binary "=~" binds a scalar expression to a pattern match. Certain operations |
| 265 | search or modify the string $_ by default. This operator makes that kind |
| 266 | of operation work on some other string. The right argument is a search |
| 267 | pattern, substitution, or transliteration. The left argument is what is |
| 268 | supposed to be searched, substituted, or transliterated instead of the default |
| 269 | $_. When used in scalar context, the return value generally indicates the |
| 270 | success of the operation. The exceptions are substitution (s///) |
| 271 | and transliteration (y///) with the C</r> (non-destructive) option, |
| 272 | which cause the B<r>eturn value to be the result of the substitution. |
| 273 | Behavior in list context depends on the particular operator. |
| 274 | See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for |
| 275 | examples using these operators. |
| 276 | |
| 277 | If the right argument is an expression rather than a search pattern, |
| 278 | substitution, or transliteration, it is interpreted as a search pattern at run |
| 279 | time. Note that this means that its |
| 280 | contents will be interpolated twice, so |
| 281 | |
| 282 | '\\' =~ q'\\'; |
| 283 | |
| 284 | is not ok, as the regex engine will end up trying to compile the |
| 285 | pattern C<\>, which it will consider a syntax error. |
| 286 | |
| 287 | Binary "!~" is just like "=~" except the return value is negated in |
| 288 | the logical sense. |
| 289 | |
| 290 | Binary "!~" with a non-destructive substitution (s///r) or transliteration |
| 291 | (y///r) is a syntax error. |
| 292 | |
| 293 | =head2 Multiplicative Operators |
| 294 | X<operator, multiplicative> |
| 295 | |
| 296 | Binary "*" multiplies two numbers. |
| 297 | X<*> |
| 298 | |
| 299 | Binary "/" divides two numbers. |
| 300 | X</> X<slash> |
| 301 | |
| 302 | Binary "%" is the modulo operator, which computes the division |
| 303 | remainder of its first argument with respect to its second argument. |
| 304 | Given integer |
| 305 | operands C<$m> and C<$n>: If C<$n> is positive, then C<$m % $n> is |
| 306 | C<$m> minus the largest multiple of C<$n> less than or equal to |
| 307 | C<$m>. If C<$n> is negative, then C<$m % $n> is C<$m> minus the |
| 308 | smallest multiple of C<$n> that is not less than C<$m> (that is, the |
| 309 | result will be less than or equal to zero). If the operands |
| 310 | C<$m> and C<$n> are floating point values and the absolute value of |
| 311 | C<$n> (that is C<abs($n)>) is less than C<(UV_MAX + 1)>, only |
| 312 | the integer portion of C<$m> and C<$n> will be used in the operation |
| 313 | (Note: here C<UV_MAX> means the maximum of the unsigned integer type). |
| 314 | If the absolute value of the right operand (C<abs($n)>) is greater than |
| 315 | or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder |
| 316 | C<$r> in the equation C<($r = $m - $i*$n)> where C<$i> is a certain |
| 317 | integer that makes C<$r> have the same sign as the right operand |
| 318 | C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>) |
| 319 | and the absolute value less than that of C<$n>. |
| 320 | Note that when C<use integer> is in scope, "%" gives you direct access |
| 321 | to the modulo operator as implemented by your C compiler. This |
| 322 | operator is not as well defined for negative operands, but it will |
| 323 | execute faster. |
| 324 | X<%> X<remainder> X<modulo> X<mod> |
| 325 | |
| 326 | Binary "x" is the repetition operator. In scalar context or if the left |
| 327 | operand is not enclosed in parentheses, it returns a string consisting |
| 328 | of the left operand repeated the number of times specified by the right |
| 329 | operand. In list context, if the left operand is enclosed in |
| 330 | parentheses or is a list formed by C<qw/STRING/>, it repeats the list. |
| 331 | If the right operand is zero or negative (raising a warning on |
| 332 | negative), it returns an empty string |
| 333 | or an empty list, depending on the context. |
| 334 | X<x> |
| 335 | |
| 336 | print '-' x 80; # print row of dashes |
| 337 | |
| 338 | print "\t" x ($tab/8), ' ' x ($tab%8); # tab over |
| 339 | |
| 340 | @ones = (1) x 80; # a list of 80 1's |
| 341 | @ones = (5) x @ones; # set all elements to 5 |
| 342 | |
| 343 | |
| 344 | =head2 Additive Operators |
| 345 | X<operator, additive> |
| 346 | |
| 347 | Binary C<+> returns the sum of two numbers. |
| 348 | X<+> |
| 349 | |
| 350 | Binary C<-> returns the difference of two numbers. |
| 351 | X<-> |
| 352 | |
| 353 | Binary C<.> concatenates two strings. |
| 354 | X<string, concatenation> X<concatenation> |
| 355 | X<cat> X<concat> X<concatenate> X<.> |
| 356 | |
| 357 | =head2 Shift Operators |
| 358 | X<shift operator> X<operator, shift> X<<< << >>> |
| 359 | X<<< >> >>> X<right shift> X<left shift> X<bitwise shift> |
| 360 | X<shl> X<shr> X<shift, right> X<shift, left> |
| 361 | |
| 362 | Binary C<<< << >>> returns the value of its left argument shifted left by the |
| 363 | number of bits specified by the right argument. Arguments should be |
| 364 | integers. (See also L<Integer Arithmetic>.) |
| 365 | |
| 366 | Binary C<<< >> >>> returns the value of its left argument shifted right by |
| 367 | the number of bits specified by the right argument. Arguments should |
| 368 | be integers. (See also L<Integer Arithmetic>.) |
| 369 | |
| 370 | Note that both C<<< << >>> and C<<< >> >>> in Perl are implemented directly using |
| 371 | C<<< << >>> and C<<< >> >>> in C. If C<use integer> (see L<Integer Arithmetic>) is |
| 372 | in force then signed C integers are used, else unsigned C integers are |
| 373 | used. Either way, the implementation isn't going to generate results |
| 374 | larger than the size of the integer type Perl was built with (32 bits |
| 375 | or 64 bits). |
| 376 | |
| 377 | The result of overflowing the range of the integers is undefined |
| 378 | because it is undefined also in C. In other words, using 32-bit |
| 379 | integers, C<< 1 << 32 >> is undefined. Shifting by a negative number |
| 380 | of bits is also undefined. |
| 381 | |
| 382 | If you get tired of being subject to your platform's native integers, |
| 383 | the C<use bigint> pragma neatly sidesteps the issue altogether: |
| 384 | |
| 385 | print 20 << 20; # 20971520 |
| 386 | print 20 << 40; # 5120 on 32-bit machines, |
| 387 | # 21990232555520 on 64-bit machines |
| 388 | use bigint; |
| 389 | print 20 << 100; # 25353012004564588029934064107520 |
| 390 | |
| 391 | =head2 Named Unary Operators |
| 392 | X<operator, named unary> |
| 393 | |
| 394 | The various named unary operators are treated as functions with one |
| 395 | argument, with optional parentheses. |
| 396 | |
| 397 | If any list operator (print(), etc.) or any unary operator (chdir(), etc.) |
| 398 | is followed by a left parenthesis as the next token, the operator and |
| 399 | arguments within parentheses are taken to be of highest precedence, |
| 400 | just like a normal function call. For example, |
| 401 | because named unary operators are higher precedence than C<||>: |
| 402 | |
| 403 | chdir $foo || die; # (chdir $foo) || die |
| 404 | chdir($foo) || die; # (chdir $foo) || die |
| 405 | chdir ($foo) || die; # (chdir $foo) || die |
| 406 | chdir +($foo) || die; # (chdir $foo) || die |
| 407 | |
| 408 | but, because * is higher precedence than named operators: |
| 409 | |
| 410 | chdir $foo * 20; # chdir ($foo * 20) |
| 411 | chdir($foo) * 20; # (chdir $foo) * 20 |
| 412 | chdir ($foo) * 20; # (chdir $foo) * 20 |
| 413 | chdir +($foo) * 20; # chdir ($foo * 20) |
| 414 | |
| 415 | rand 10 * 20; # rand (10 * 20) |
| 416 | rand(10) * 20; # (rand 10) * 20 |
| 417 | rand (10) * 20; # (rand 10) * 20 |
| 418 | rand +(10) * 20; # rand (10 * 20) |
| 419 | |
| 420 | Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are |
| 421 | treated like named unary operators, but they don't follow this functional |
| 422 | parenthesis rule. That means, for example, that C<-f($file).".bak"> is |
| 423 | equivalent to C<-f "$file.bak">. |
| 424 | X<-X> X<filetest> X<operator, filetest> |
| 425 | |
| 426 | See also L<"Terms and List Operators (Leftward)">. |
| 427 | |
| 428 | =head2 Relational Operators |
| 429 | X<relational operator> X<operator, relational> |
| 430 | |
| 431 | Perl operators that return true or false generally return values |
| 432 | that can be safely used as numbers. For example, the relational |
| 433 | operators in this section and the equality operators in the next |
| 434 | one return C<1> for true and a special version of the defined empty |
| 435 | string, C<"">, which counts as a zero but is exempt from warnings |
| 436 | about improper numeric conversions, just as C<"0 but true"> is. |
| 437 | |
| 438 | Binary "<" returns true if the left argument is numerically less than |
| 439 | the right argument. |
| 440 | X<< < >> |
| 441 | |
| 442 | Binary ">" returns true if the left argument is numerically greater |
| 443 | than the right argument. |
| 444 | X<< > >> |
| 445 | |
| 446 | Binary "<=" returns true if the left argument is numerically less than |
| 447 | or equal to the right argument. |
| 448 | X<< <= >> |
| 449 | |
| 450 | Binary ">=" returns true if the left argument is numerically greater |
| 451 | than or equal to the right argument. |
| 452 | X<< >= >> |
| 453 | |
| 454 | Binary "lt" returns true if the left argument is stringwise less than |
| 455 | the right argument. |
| 456 | X<< lt >> |
| 457 | |
| 458 | Binary "gt" returns true if the left argument is stringwise greater |
| 459 | than the right argument. |
| 460 | X<< gt >> |
| 461 | |
| 462 | Binary "le" returns true if the left argument is stringwise less than |
| 463 | or equal to the right argument. |
| 464 | X<< le >> |
| 465 | |
| 466 | Binary "ge" returns true if the left argument is stringwise greater |
| 467 | than or equal to the right argument. |
| 468 | X<< ge >> |
| 469 | |
| 470 | =head2 Equality Operators |
| 471 | X<equality> X<equal> X<equals> X<operator, equality> |
| 472 | |
| 473 | Binary "==" returns true if the left argument is numerically equal to |
| 474 | the right argument. |
| 475 | X<==> |
| 476 | |
| 477 | Binary "!=" returns true if the left argument is numerically not equal |
| 478 | to the right argument. |
| 479 | X<!=> |
| 480 | |
| 481 | Binary "<=>" returns -1, 0, or 1 depending on whether the left |
| 482 | argument is numerically less than, equal to, or greater than the right |
| 483 | argument. If your platform supports NaNs (not-a-numbers) as numeric |
| 484 | values, using them with "<=>" returns undef. NaN is not "<", "==", ">", |
| 485 | "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN |
| 486 | returns true, as does NaN != anything else. If your platform doesn't |
| 487 | support NaNs then NaN is just a string with numeric value 0. |
| 488 | X<< <=> >> X<spaceship> |
| 489 | |
| 490 | $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x' |
| 491 | $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x' |
| 492 | |
| 493 | (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all |
| 494 | support "NaN".) |
| 495 | |
| 496 | Binary "eq" returns true if the left argument is stringwise equal to |
| 497 | the right argument. |
| 498 | X<eq> |
| 499 | |
| 500 | Binary "ne" returns true if the left argument is stringwise not equal |
| 501 | to the right argument. |
| 502 | X<ne> |
| 503 | |
| 504 | Binary "cmp" returns -1, 0, or 1 depending on whether the left |
| 505 | argument is stringwise less than, equal to, or greater than the right |
| 506 | argument. |
| 507 | X<cmp> |
| 508 | |
| 509 | Binary "~~" does a smartmatch between its arguments. Smart matching |
| 510 | is described in the next section. |
| 511 | X<~~> |
| 512 | |
| 513 | "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified |
| 514 | by the current locale if a legacy C<use locale> (but not |
| 515 | C<use locale ':not_characters'>) is in effect. See |
| 516 | L<perllocale>. Do not mix these with Unicode, only with legacy binary |
| 517 | encodings. The standard L<Unicode::Collate> and |
| 518 | L<Unicode::Collate::Locale> modules offer much more powerful solutions to |
| 519 | collation issues. |
| 520 | |
| 521 | =head2 Smartmatch Operator |
| 522 | |
| 523 | First available in Perl 5.10.1 (the 5.10.0 version behaved differently), |
| 524 | binary C<~~> does a "smartmatch" between its arguments. This is mostly |
| 525 | used implicitly in the C<when> construct described in L<perlsyn>, although |
| 526 | not all C<when> clauses call the smartmatch operator. Unique among all of |
| 527 | Perl's operators, the smartmatch operator can recurse. The smartmatch |
| 528 | operator is L<experimental|perlpolicy/experimental> and its behavior is |
| 529 | subject to change. |
| 530 | |
| 531 | It is also unique in that all other Perl operators impose a context |
| 532 | (usually string or numeric context) on their operands, autoconverting |
| 533 | those operands to those imposed contexts. In contrast, smartmatch |
| 534 | I<infers> contexts from the actual types of its operands and uses that |
| 535 | type information to select a suitable comparison mechanism. |
| 536 | |
| 537 | The C<~~> operator compares its operands "polymorphically", determining how |
| 538 | to compare them according to their actual types (numeric, string, array, |
| 539 | hash, etc.) Like the equality operators with which it shares the same |
| 540 | precedence, C<~~> returns 1 for true and C<""> for false. It is often best |
| 541 | read aloud as "in", "inside of", or "is contained in", because the left |
| 542 | operand is often looked for I<inside> the right operand. That makes the |
| 543 | order of the operands to the smartmatch operand often opposite that of |
| 544 | the regular match operator. In other words, the "smaller" thing is usually |
| 545 | placed in the left operand and the larger one in the right. |
| 546 | |
| 547 | The behavior of a smartmatch depends on what type of things its arguments |
| 548 | are, as determined by the following table. The first row of the table |
| 549 | whose types apply determines the smartmatch behavior. Because what |
| 550 | actually happens is mostly determined by the type of the second operand, |
| 551 | the table is sorted on the right operand instead of on the left. |
| 552 | |
| 553 | Left Right Description and pseudocode |
| 554 | =============================================================== |
| 555 | Any undef check whether Any is undefined |
| 556 | like: !defined Any |
| 557 | |
| 558 | Any Object invoke ~~ overloading on Object, or die |
| 559 | |
| 560 | Right operand is an ARRAY: |
| 561 | |
| 562 | Left Right Description and pseudocode |
| 563 | =============================================================== |
| 564 | ARRAY1 ARRAY2 recurse on paired elements of ARRAY1 and ARRAY2[2] |
| 565 | like: (ARRAY1[0] ~~ ARRAY2[0]) |
| 566 | && (ARRAY1[1] ~~ ARRAY2[1]) && ... |
| 567 | HASH ARRAY any ARRAY elements exist as HASH keys |
| 568 | like: grep { exists HASH->{$_} } ARRAY |
| 569 | Regexp ARRAY any ARRAY elements pattern match Regexp |
| 570 | like: grep { /Regexp/ } ARRAY |
| 571 | undef ARRAY undef in ARRAY |
| 572 | like: grep { !defined } ARRAY |
| 573 | Any ARRAY smartmatch each ARRAY element[3] |
| 574 | like: grep { Any ~~ $_ } ARRAY |
| 575 | |
| 576 | Right operand is a HASH: |
| 577 | |
| 578 | Left Right Description and pseudocode |
| 579 | =============================================================== |
| 580 | HASH1 HASH2 all same keys in both HASHes |
| 581 | like: keys HASH1 == |
| 582 | grep { exists HASH2->{$_} } keys HASH1 |
| 583 | ARRAY HASH any ARRAY elements exist as HASH keys |
| 584 | like: grep { exists HASH->{$_} } ARRAY |
| 585 | Regexp HASH any HASH keys pattern match Regexp |
| 586 | like: grep { /Regexp/ } keys HASH |
| 587 | undef HASH always false (undef can't be a key) |
| 588 | like: 0 == 1 |
| 589 | Any HASH HASH key existence |
| 590 | like: exists HASH->{Any} |
| 591 | |
| 592 | Right operand is CODE: |
| 593 | |
| 594 | Left Right Description and pseudocode |
| 595 | =============================================================== |
| 596 | ARRAY CODE sub returns true on all ARRAY elements[1] |
| 597 | like: !grep { !CODE->($_) } ARRAY |
| 598 | HASH CODE sub returns true on all HASH keys[1] |
| 599 | like: !grep { !CODE->($_) } keys HASH |
| 600 | Any CODE sub passed Any returns true |
| 601 | like: CODE->(Any) |
| 602 | |
| 603 | Right operand is a Regexp: |
| 604 | |
| 605 | Left Right Description and pseudocode |
| 606 | =============================================================== |
| 607 | ARRAY Regexp any ARRAY elements match Regexp |
| 608 | like: grep { /Regexp/ } ARRAY |
| 609 | HASH Regexp any HASH keys match Regexp |
| 610 | like: grep { /Regexp/ } keys HASH |
| 611 | Any Regexp pattern match |
| 612 | like: Any =~ /Regexp/ |
| 613 | |
| 614 | Other: |
| 615 | |
| 616 | Left Right Description and pseudocode |
| 617 | =============================================================== |
| 618 | Object Any invoke ~~ overloading on Object, |
| 619 | or fall back to... |
| 620 | |
| 621 | Any Num numeric equality |
| 622 | like: Any == Num |
| 623 | Num nummy[4] numeric equality |
| 624 | like: Num == nummy |
| 625 | undef Any check whether undefined |
| 626 | like: !defined(Any) |
| 627 | Any Any string equality |
| 628 | like: Any eq Any |
| 629 | |
| 630 | |
| 631 | Notes: |
| 632 | |
| 633 | =over |
| 634 | |
| 635 | =item 1. |
| 636 | Empty hashes or arrays match. |
| 637 | |
| 638 | =item 2. |
| 639 | That is, each element smartmatches the element of the same index in the other array.[3] |
| 640 | |
| 641 | =item 3. |
| 642 | If a circular reference is found, fall back to referential equality. |
| 643 | |
| 644 | =item 4. |
| 645 | Either an actual number, or a string that looks like one. |
| 646 | |
| 647 | =back |
| 648 | |
| 649 | The smartmatch implicitly dereferences any non-blessed hash or array |
| 650 | reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases. |
| 651 | For blessed references, the C<I<Object>> entries apply. Smartmatches |
| 652 | involving hashes only consider hash keys, never hash values. |
| 653 | |
| 654 | The "like" code entry is not always an exact rendition. For example, the |
| 655 | smartmatch operator short-circuits whenever possible, but C<grep> does |
| 656 | not. Also, C<grep> in scalar context returns the number of matches, but |
| 657 | C<~~> returns only true or false. |
| 658 | |
| 659 | Unlike most operators, the smartmatch operator knows to treat C<undef> |
| 660 | specially: |
| 661 | |
| 662 | use v5.10.1; |
| 663 | @array = (1, 2, 3, undef, 4, 5); |
| 664 | say "some elements undefined" if undef ~~ @array; |
| 665 | |
| 666 | Each operand is considered in a modified scalar context, the modification |
| 667 | being that array and hash variables are passed by reference to the |
| 668 | operator, which implicitly dereferences them. Both elements |
| 669 | of each pair are the same: |
| 670 | |
| 671 | use v5.10.1; |
| 672 | |
| 673 | my %hash = (red => 1, blue => 2, green => 3, |
| 674 | orange => 4, yellow => 5, purple => 6, |
| 675 | black => 7, grey => 8, white => 9); |
| 676 | |
| 677 | my @array = qw(red blue green); |
| 678 | |
| 679 | say "some array elements in hash keys" if @array ~~ %hash; |
| 680 | say "some array elements in hash keys" if \@array ~~ \%hash; |
| 681 | |
| 682 | say "red in array" if "red" ~~ @array; |
| 683 | say "red in array" if "red" ~~ \@array; |
| 684 | |
| 685 | say "some keys end in e" if /e$/ ~~ %hash; |
| 686 | say "some keys end in e" if /e$/ ~~ \%hash; |
| 687 | |
| 688 | Two arrays smartmatch if each element in the first array smartmatches |
| 689 | (that is, is "in") the corresponding element in the second array, |
| 690 | recursively. |
| 691 | |
| 692 | use v5.10.1; |
| 693 | my @little = qw(red blue green); |
| 694 | my @bigger = ("red", "blue", [ "orange", "green" ] ); |
| 695 | if (@little ~~ @bigger) { # true! |
| 696 | say "little is contained in bigger"; |
| 697 | } |
| 698 | |
| 699 | Because the smartmatch operator recurses on nested arrays, this |
| 700 | will still report that "red" is in the array. |
| 701 | |
| 702 | use v5.10.1; |
| 703 | my @array = qw(red blue green); |
| 704 | my $nested_array = [[[[[[[ @array ]]]]]]]; |
| 705 | say "red in array" if "red" ~~ $nested_array; |
| 706 | |
| 707 | If two arrays smartmatch each other, then they are deep |
| 708 | copies of each others' values, as this example reports: |
| 709 | |
| 710 | use v5.12.0; |
| 711 | my @a = (0, 1, 2, [3, [4, 5], 6], 7); |
| 712 | my @b = (0, 1, 2, [3, [4, 5], 6], 7); |
| 713 | |
| 714 | if (@a ~~ @b && @b ~~ @a) { |
| 715 | say "a and b are deep copies of each other"; |
| 716 | } |
| 717 | elsif (@a ~~ @b) { |
| 718 | say "a smartmatches in b"; |
| 719 | } |
| 720 | elsif (@b ~~ @a) { |
| 721 | say "b smartmatches in a"; |
| 722 | } |
| 723 | else { |
| 724 | say "a and b don't smartmatch each other at all"; |
| 725 | } |
| 726 | |
| 727 | |
| 728 | If you were to set C<$b[3] = 4>, then instead of reporting that "a and b |
| 729 | are deep copies of each other", it now reports that "b smartmatches in a". |
| 730 | That because the corresponding position in C<@a> contains an array that |
| 731 | (eventually) has a 4 in it. |
| 732 | |
| 733 | Smartmatching one hash against another reports whether both contain the |
| 734 | same keys, no more and no less. This could be used to see whether two |
| 735 | records have the same field names, without caring what values those fields |
| 736 | might have. For example: |
| 737 | |
| 738 | use v5.10.1; |
| 739 | sub make_dogtag { |
| 740 | state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 }; |
| 741 | |
| 742 | my ($class, $init_fields) = @_; |
| 743 | |
| 744 | die "Must supply (only) name, rank, and serial number" |
| 745 | unless $init_fields ~~ $REQUIRED_FIELDS; |
| 746 | |
| 747 | ... |
| 748 | } |
| 749 | |
| 750 | or, if other non-required fields are allowed, use ARRAY ~~ HASH: |
| 751 | |
| 752 | use v5.10.1; |
| 753 | sub make_dogtag { |
| 754 | state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 }; |
| 755 | |
| 756 | my ($class, $init_fields) = @_; |
| 757 | |
| 758 | die "Must supply (at least) name, rank, and serial number" |
| 759 | unless [keys %{$init_fields}] ~~ $REQUIRED_FIELDS; |
| 760 | |
| 761 | ... |
| 762 | } |
| 763 | |
| 764 | The smartmatch operator is most often used as the implicit operator of a |
| 765 | C<when> clause. See the section on "Switch Statements" in L<perlsyn>. |
| 766 | |
| 767 | =head3 Smartmatching of Objects |
| 768 | |
| 769 | To avoid relying on an object's underlying representation, if the |
| 770 | smartmatch's right operand is an object that doesn't overload C<~~>, |
| 771 | it raises the exception "C<Smartmatching a non-overloaded object |
| 772 | breaks encapsulation>". That's because one has no business digging |
| 773 | around to see whether something is "in" an object. These are all |
| 774 | illegal on objects without a C<~~> overload: |
| 775 | |
| 776 | %hash ~~ $object |
| 777 | 42 ~~ $object |
| 778 | "fred" ~~ $object |
| 779 | |
| 780 | However, you can change the way an object is smartmatched by overloading |
| 781 | the C<~~> operator. This is allowed to |
| 782 | extend the usual smartmatch semantics. |
| 783 | For objects that do have an C<~~> overload, see L<overload>. |
| 784 | |
| 785 | Using an object as the left operand is allowed, although not very useful. |
| 786 | Smartmatching rules take precedence over overloading, so even if the |
| 787 | object in the left operand has smartmatch overloading, this will be |
| 788 | ignored. A left operand that is a non-overloaded object falls back on a |
| 789 | string or numeric comparison of whatever the C<ref> operator returns. That |
| 790 | means that |
| 791 | |
| 792 | $object ~~ X |
| 793 | |
| 794 | does I<not> invoke the overload method with C<I<X>> as an argument. |
| 795 | Instead the above table is consulted as normal, and based on the type of |
| 796 | C<I<X>>, overloading may or may not be invoked. For simple strings or |
| 797 | numbers, in becomes equivalent to this: |
| 798 | |
| 799 | $object ~~ $number ref($object) == $number |
| 800 | $object ~~ $string ref($object) eq $string |
| 801 | |
| 802 | For example, this reports that the handle smells IOish |
| 803 | (but please don't really do this!): |
| 804 | |
| 805 | use IO::Handle; |
| 806 | my $fh = IO::Handle->new(); |
| 807 | if ($fh ~~ /\bIO\b/) { |
| 808 | say "handle smells IOish"; |
| 809 | } |
| 810 | |
| 811 | That's because it treats C<$fh> as a string like |
| 812 | C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that. |
| 813 | |
| 814 | =head2 Bitwise And |
| 815 | X<operator, bitwise, and> X<bitwise and> X<&> |
| 816 | |
| 817 | Binary "&" returns its operands ANDed together bit by bit. Although no |
| 818 | warning is currently raised, the result is not well defined when this operation |
| 819 | is performed on operands that aren't either numbers (see |
| 820 | L<Integer Arithmetic>) or bitstrings (see L<Bitwise String Operators>). |
| 821 | |
| 822 | Note that "&" has lower priority than relational operators, so for example |
| 823 | the parentheses are essential in a test like |
| 824 | |
| 825 | print "Even\n" if ($x & 1) == 0; |
| 826 | |
| 827 | =head2 Bitwise Or and Exclusive Or |
| 828 | X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor> |
| 829 | X<bitwise xor> X<^> |
| 830 | |
| 831 | Binary "|" returns its operands ORed together bit by bit. |
| 832 | |
| 833 | Binary "^" returns its operands XORed together bit by bit. |
| 834 | |
| 835 | Although no warning is currently raised, the results are not well |
| 836 | defined when these operations are performed on operands that aren't either |
| 837 | numbers (see L<Integer Arithmetic>) or bitstrings (see L<Bitwise String |
| 838 | Operators>). |
| 839 | |
| 840 | Note that "|" and "^" have lower priority than relational operators, so |
| 841 | for example the brackets are essential in a test like |
| 842 | |
| 843 | print "false\n" if (8 | 2) != 10; |
| 844 | |
| 845 | =head2 C-style Logical And |
| 846 | X<&&> X<logical and> X<operator, logical, and> |
| 847 | |
| 848 | Binary "&&" performs a short-circuit logical AND operation. That is, |
| 849 | if the left operand is false, the right operand is not even evaluated. |
| 850 | Scalar or list context propagates down to the right operand if it |
| 851 | is evaluated. |
| 852 | |
| 853 | =head2 C-style Logical Or |
| 854 | X<||> X<operator, logical, or> |
| 855 | |
| 856 | Binary "||" performs a short-circuit logical OR operation. That is, |
| 857 | if the left operand is true, the right operand is not even evaluated. |
| 858 | Scalar or list context propagates down to the right operand if it |
| 859 | is evaluated. |
| 860 | |
| 861 | =head2 Logical Defined-Or |
| 862 | X<//> X<operator, logical, defined-or> |
| 863 | |
| 864 | Although it has no direct equivalent in C, Perl's C<//> operator is related |
| 865 | to its C-style or. In fact, it's exactly the same as C<||>, except that it |
| 866 | tests the left hand side's definedness instead of its truth. Thus, |
| 867 | C<< EXPR1 // EXPR2 >> returns the value of C<< EXPR1 >> if it's defined, |
| 868 | otherwise, the value of C<< EXPR2 >> is returned. |
| 869 | (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >> |
| 870 | in the context of C<< // >> itself). Usually, |
| 871 | this is the same result as C<< defined(EXPR1) ? EXPR1 : EXPR2 >> (except that |
| 872 | the ternary-operator form can be used as a lvalue, while C<< EXPR1 // EXPR2 >> |
| 873 | cannot). This is very useful for |
| 874 | providing default values for variables. If you actually want to test if |
| 875 | at least one of C<$x> and C<$y> is defined, use C<defined($x // $y)>. |
| 876 | |
| 877 | The C<||>, C<//> and C<&&> operators return the last value evaluated |
| 878 | (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably |
| 879 | portable way to find out the home directory might be: |
| 880 | |
| 881 | $home = $ENV{HOME} |
| 882 | // $ENV{LOGDIR} |
| 883 | // (getpwuid($<))[7] |
| 884 | // die "You're homeless!\n"; |
| 885 | |
| 886 | In particular, this means that you shouldn't use this |
| 887 | for selecting between two aggregates for assignment: |
| 888 | |
| 889 | @a = @b || @c; # this is wrong |
| 890 | @a = scalar(@b) || @c; # really meant this |
| 891 | @a = @b ? @b : @c; # this works fine, though |
| 892 | |
| 893 | As alternatives to C<&&> and C<||> when used for |
| 894 | control flow, Perl provides the C<and> and C<or> operators (see below). |
| 895 | The short-circuit behavior is identical. The precedence of "and" |
| 896 | and "or" is much lower, however, so that you can safely use them after a |
| 897 | list operator without the need for parentheses: |
| 898 | |
| 899 | unlink "alpha", "beta", "gamma" |
| 900 | or gripe(), next LINE; |
| 901 | |
| 902 | With the C-style operators that would have been written like this: |
| 903 | |
| 904 | unlink("alpha", "beta", "gamma") |
| 905 | || (gripe(), next LINE); |
| 906 | |
| 907 | It would be even more readable to write that this way: |
| 908 | |
| 909 | unless(unlink("alpha", "beta", "gamma")) { |
| 910 | gripe(); |
| 911 | next LINE; |
| 912 | } |
| 913 | |
| 914 | Using "or" for assignment is unlikely to do what you want; see below. |
| 915 | |
| 916 | =head2 Range Operators |
| 917 | X<operator, range> X<range> X<..> X<...> |
| 918 | |
| 919 | Binary ".." is the range operator, which is really two different |
| 920 | operators depending on the context. In list context, it returns a |
| 921 | list of values counting (up by ones) from the left value to the right |
| 922 | value. If the left value is greater than the right value then it |
| 923 | returns the empty list. The range operator is useful for writing |
| 924 | C<foreach (1..10)> loops and for doing slice operations on arrays. In |
| 925 | the current implementation, no temporary array is created when the |
| 926 | range operator is used as the expression in C<foreach> loops, but older |
| 927 | versions of Perl might burn a lot of memory when you write something |
| 928 | like this: |
| 929 | |
| 930 | for (1 .. 1_000_000) { |
| 931 | # code |
| 932 | } |
| 933 | |
| 934 | The range operator also works on strings, using the magical |
| 935 | auto-increment, see below. |
| 936 | |
| 937 | In scalar context, ".." returns a boolean value. The operator is |
| 938 | bistable, like a flip-flop, and emulates the line-range (comma) |
| 939 | operator of B<sed>, B<awk>, and various editors. Each ".." operator |
| 940 | maintains its own boolean state, even across calls to a subroutine |
| 941 | that contains it. It is false as long as its left operand is false. |
| 942 | Once the left operand is true, the range operator stays true until the |
| 943 | right operand is true, I<AFTER> which the range operator becomes false |
| 944 | again. It doesn't become false till the next time the range operator |
| 945 | is evaluated. It can test the right operand and become false on the |
| 946 | same evaluation it became true (as in B<awk>), but it still returns |
| 947 | true once. If you don't want it to test the right operand until the |
| 948 | next evaluation, as in B<sed>, just use three dots ("...") instead of |
| 949 | two. In all other regards, "..." behaves just like ".." does. |
| 950 | |
| 951 | The right operand is not evaluated while the operator is in the |
| 952 | "false" state, and the left operand is not evaluated while the |
| 953 | operator is in the "true" state. The precedence is a little lower |
| 954 | than || and &&. The value returned is either the empty string for |
| 955 | false, or a sequence number (beginning with 1) for true. The sequence |
| 956 | number is reset for each range encountered. The final sequence number |
| 957 | in a range has the string "E0" appended to it, which doesn't affect |
| 958 | its numeric value, but gives you something to search for if you want |
| 959 | to exclude the endpoint. You can exclude the beginning point by |
| 960 | waiting for the sequence number to be greater than 1. |
| 961 | |
| 962 | If either operand of scalar ".." is a constant expression, |
| 963 | that operand is considered true if it is equal (C<==>) to the current |
| 964 | input line number (the C<$.> variable). |
| 965 | |
| 966 | To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>, |
| 967 | but that is only an issue if you use a floating point expression; when |
| 968 | implicitly using C<$.> as described in the previous paragraph, the |
| 969 | comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.> |
| 970 | is set to a floating point value and you are not reading from a file. |
| 971 | Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what |
| 972 | you want in scalar context because each of the operands are evaluated |
| 973 | using their integer representation. |
| 974 | |
| 975 | Examples: |
| 976 | |
| 977 | As a scalar operator: |
| 978 | |
| 979 | if (101 .. 200) { print; } # print 2nd hundred lines, short for |
| 980 | # if ($. == 101 .. $. == 200) { print; } |
| 981 | |
| 982 | next LINE if (1 .. /^$/); # skip header lines, short for |
| 983 | # next LINE if ($. == 1 .. /^$/); |
| 984 | # (typically in a loop labeled LINE) |
| 985 | |
| 986 | s/^/> / if (/^$/ .. eof()); # quote body |
| 987 | |
| 988 | # parse mail messages |
| 989 | while (<>) { |
| 990 | $in_header = 1 .. /^$/; |
| 991 | $in_body = /^$/ .. eof; |
| 992 | if ($in_header) { |
| 993 | # do something |
| 994 | } else { # in body |
| 995 | # do something else |
| 996 | } |
| 997 | } continue { |
| 998 | close ARGV if eof; # reset $. each file |
| 999 | } |
| 1000 | |
| 1001 | Here's a simple example to illustrate the difference between |
| 1002 | the two range operators: |
| 1003 | |
| 1004 | @lines = (" - Foo", |
| 1005 | "01 - Bar", |
| 1006 | "1 - Baz", |
| 1007 | " - Quux"); |
| 1008 | |
| 1009 | foreach (@lines) { |
| 1010 | if (/0/ .. /1/) { |
| 1011 | print "$_\n"; |
| 1012 | } |
| 1013 | } |
| 1014 | |
| 1015 | This program will print only the line containing "Bar". If |
| 1016 | the range operator is changed to C<...>, it will also print the |
| 1017 | "Baz" line. |
| 1018 | |
| 1019 | And now some examples as a list operator: |
| 1020 | |
| 1021 | for (101 .. 200) { print } # print $_ 100 times |
| 1022 | @foo = @foo[0 .. $#foo]; # an expensive no-op |
| 1023 | @foo = @foo[$#foo-4 .. $#foo]; # slice last 5 items |
| 1024 | |
| 1025 | The range operator (in list context) makes use of the magical |
| 1026 | auto-increment algorithm if the operands are strings. You |
| 1027 | can say |
| 1028 | |
| 1029 | @alphabet = ("A" .. "Z"); |
| 1030 | |
| 1031 | to get all normal letters of the English alphabet, or |
| 1032 | |
| 1033 | $hexdigit = (0 .. 9, "a" .. "f")[$num & 15]; |
| 1034 | |
| 1035 | to get a hexadecimal digit, or |
| 1036 | |
| 1037 | @z2 = ("01" .. "31"); |
| 1038 | print $z2[$mday]; |
| 1039 | |
| 1040 | to get dates with leading zeros. |
| 1041 | |
| 1042 | If the final value specified is not in the sequence that the magical |
| 1043 | increment would produce, the sequence goes until the next value would |
| 1044 | be longer than the final value specified. |
| 1045 | |
| 1046 | If the initial value specified isn't part of a magical increment |
| 1047 | sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>), |
| 1048 | only the initial value will be returned. So the following will only |
| 1049 | return an alpha: |
| 1050 | |
| 1051 | use charnames "greek"; |
| 1052 | my @greek_small = ("\N{alpha}" .. "\N{omega}"); |
| 1053 | |
| 1054 | To get the 25 traditional lowercase Greek letters, including both sigmas, |
| 1055 | you could use this instead: |
| 1056 | |
| 1057 | use charnames "greek"; |
| 1058 | my @greek_small = map { chr } ( ord("\N{alpha}") |
| 1059 | .. |
| 1060 | ord("\N{omega}") |
| 1061 | ); |
| 1062 | |
| 1063 | However, because there are I<many> other lowercase Greek characters than |
| 1064 | just those, to match lowercase Greek characters in a regular expression, |
| 1065 | you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the |
| 1066 | L<experimental feature|perlrecharclass/Extended Bracketed Character |
| 1067 | Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>). |
| 1068 | |
| 1069 | Because each operand is evaluated in integer form, C<2.18 .. 3.14> will |
| 1070 | return two elements in list context. |
| 1071 | |
| 1072 | @list = (2.18 .. 3.14); # same as @list = (2 .. 3); |
| 1073 | |
| 1074 | =head2 Conditional Operator |
| 1075 | X<operator, conditional> X<operator, ternary> X<ternary> X<?:> |
| 1076 | |
| 1077 | Ternary "?:" is the conditional operator, just as in C. It works much |
| 1078 | like an if-then-else. If the argument before the ? is true, the |
| 1079 | argument before the : is returned, otherwise the argument after the : |
| 1080 | is returned. For example: |
| 1081 | |
| 1082 | printf "I have %d dog%s.\n", $n, |
| 1083 | ($n == 1) ? "" : "s"; |
| 1084 | |
| 1085 | Scalar or list context propagates downward into the 2nd |
| 1086 | or 3rd argument, whichever is selected. |
| 1087 | |
| 1088 | $x = $ok ? $y : $z; # get a scalar |
| 1089 | @x = $ok ? @y : @z; # get an array |
| 1090 | $x = $ok ? @y : @z; # oops, that's just a count! |
| 1091 | |
| 1092 | The operator may be assigned to if both the 2nd and 3rd arguments are |
| 1093 | legal lvalues (meaning that you can assign to them): |
| 1094 | |
| 1095 | ($x_or_y ? $x : $y) = $z; |
| 1096 | |
| 1097 | Because this operator produces an assignable result, using assignments |
| 1098 | without parentheses will get you in trouble. For example, this: |
| 1099 | |
| 1100 | $x % 2 ? $x += 10 : $x += 2 |
| 1101 | |
| 1102 | Really means this: |
| 1103 | |
| 1104 | (($x % 2) ? ($x += 10) : $x) += 2 |
| 1105 | |
| 1106 | Rather than this: |
| 1107 | |
| 1108 | ($x % 2) ? ($x += 10) : ($x += 2) |
| 1109 | |
| 1110 | That should probably be written more simply as: |
| 1111 | |
| 1112 | $x += ($x % 2) ? 10 : 2; |
| 1113 | |
| 1114 | =head2 Assignment Operators |
| 1115 | X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=> |
| 1116 | X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=> |
| 1117 | X<%=> X<^=> X<x=> |
| 1118 | |
| 1119 | "=" is the ordinary assignment operator. |
| 1120 | |
| 1121 | Assignment operators work as in C. That is, |
| 1122 | |
| 1123 | $x += 2; |
| 1124 | |
| 1125 | is equivalent to |
| 1126 | |
| 1127 | $x = $x + 2; |
| 1128 | |
| 1129 | although without duplicating any side effects that dereferencing the lvalue |
| 1130 | might trigger, such as from tie(). Other assignment operators work similarly. |
| 1131 | The following are recognized: |
| 1132 | |
| 1133 | **= += *= &= <<= &&= |
| 1134 | -= /= |= >>= ||= |
| 1135 | .= %= ^= //= |
| 1136 | x= |
| 1137 | |
| 1138 | Although these are grouped by family, they all have the precedence |
| 1139 | of assignment. These combined assignment operators can only operate on |
| 1140 | scalars, whereas the ordinary assignment operator can assign to arrays, |
| 1141 | hashes, lists and even references. (See L<"Context"|perldata/Context> |
| 1142 | and L<perldata/List value constructors>, and L<perlref/Assigning to |
| 1143 | References>.) |
| 1144 | |
| 1145 | Unlike in C, the scalar assignment operator produces a valid lvalue. |
| 1146 | Modifying an assignment is equivalent to doing the assignment and |
| 1147 | then modifying the variable that was assigned to. This is useful |
| 1148 | for modifying a copy of something, like this: |
| 1149 | |
| 1150 | ($tmp = $global) =~ tr/13579/24680/; |
| 1151 | |
| 1152 | Although as of 5.14, that can be also be accomplished this way: |
| 1153 | |
| 1154 | use v5.14; |
| 1155 | $tmp = ($global =~ tr/13579/24680/r); |
| 1156 | |
| 1157 | Likewise, |
| 1158 | |
| 1159 | ($x += 2) *= 3; |
| 1160 | |
| 1161 | is equivalent to |
| 1162 | |
| 1163 | $x += 2; |
| 1164 | $x *= 3; |
| 1165 | |
| 1166 | Similarly, a list assignment in list context produces the list of |
| 1167 | lvalues assigned to, and a list assignment in scalar context returns |
| 1168 | the number of elements produced by the expression on the right hand |
| 1169 | side of the assignment. |
| 1170 | |
| 1171 | =head2 Comma Operator |
| 1172 | X<comma> X<operator, comma> X<,> |
| 1173 | |
| 1174 | Binary "," is the comma operator. In scalar context it evaluates |
| 1175 | its left argument, throws that value away, then evaluates its right |
| 1176 | argument and returns that value. This is just like C's comma operator. |
| 1177 | |
| 1178 | In list context, it's just the list argument separator, and inserts |
| 1179 | both its arguments into the list. These arguments are also evaluated |
| 1180 | from left to right. |
| 1181 | |
| 1182 | The C<< => >> operator is a synonym for the comma except that it causes a |
| 1183 | word on its left to be interpreted as a string if it begins with a letter |
| 1184 | or underscore and is composed only of letters, digits and underscores. |
| 1185 | This includes operands that might otherwise be interpreted as operators, |
| 1186 | constants, single number v-strings or function calls. If in doubt about |
| 1187 | this behavior, the left operand can be quoted explicitly. |
| 1188 | |
| 1189 | Otherwise, the C<< => >> operator behaves exactly as the comma operator |
| 1190 | or list argument separator, according to context. |
| 1191 | |
| 1192 | For example: |
| 1193 | |
| 1194 | use constant FOO => "something"; |
| 1195 | |
| 1196 | my %h = ( FOO => 23 ); |
| 1197 | |
| 1198 | is equivalent to: |
| 1199 | |
| 1200 | my %h = ("FOO", 23); |
| 1201 | |
| 1202 | It is I<NOT>: |
| 1203 | |
| 1204 | my %h = ("something", 23); |
| 1205 | |
| 1206 | The C<< => >> operator is helpful in documenting the correspondence |
| 1207 | between keys and values in hashes, and other paired elements in lists. |
| 1208 | |
| 1209 | %hash = ( $key => $value ); |
| 1210 | login( $username => $password ); |
| 1211 | |
| 1212 | The special quoting behavior ignores precedence, and hence may apply to |
| 1213 | I<part> of the left operand: |
| 1214 | |
| 1215 | print time.shift => "bbb"; |
| 1216 | |
| 1217 | That example prints something like "1314363215shiftbbb", because the |
| 1218 | C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring |
| 1219 | the fact that C<time.shift> is the entire left operand. |
| 1220 | |
| 1221 | =head2 List Operators (Rightward) |
| 1222 | X<operator, list, rightward> X<list operator> |
| 1223 | |
| 1224 | On the right side of a list operator, the comma has very low precedence, |
| 1225 | such that it controls all comma-separated expressions found there. |
| 1226 | The only operators with lower precedence are the logical operators |
| 1227 | "and", "or", and "not", which may be used to evaluate calls to list |
| 1228 | operators without the need for parentheses: |
| 1229 | |
| 1230 | open HANDLE, "< :utf8", "filename" or die "Can't open: $!\n"; |
| 1231 | |
| 1232 | However, some people find that code harder to read than writing |
| 1233 | it with parentheses: |
| 1234 | |
| 1235 | open(HANDLE, "< :utf8", "filename") or die "Can't open: $!\n"; |
| 1236 | |
| 1237 | in which case you might as well just use the more customary "||" operator: |
| 1238 | |
| 1239 | open(HANDLE, "< :utf8", "filename") || die "Can't open: $!\n"; |
| 1240 | |
| 1241 | See also discussion of list operators in L<Terms and List Operators (Leftward)>. |
| 1242 | |
| 1243 | =head2 Logical Not |
| 1244 | X<operator, logical, not> X<not> |
| 1245 | |
| 1246 | Unary "not" returns the logical negation of the expression to its right. |
| 1247 | It's the equivalent of "!" except for the very low precedence. |
| 1248 | |
| 1249 | =head2 Logical And |
| 1250 | X<operator, logical, and> X<and> |
| 1251 | |
| 1252 | Binary "and" returns the logical conjunction of the two surrounding |
| 1253 | expressions. It's equivalent to C<&&> except for the very low |
| 1254 | precedence. This means that it short-circuits: the right |
| 1255 | expression is evaluated only if the left expression is true. |
| 1256 | |
| 1257 | =head2 Logical or and Exclusive Or |
| 1258 | X<operator, logical, or> X<operator, logical, xor> |
| 1259 | X<operator, logical, exclusive or> |
| 1260 | X<or> X<xor> |
| 1261 | |
| 1262 | Binary "or" returns the logical disjunction of the two surrounding |
| 1263 | expressions. It's equivalent to C<||> except for the very low precedence. |
| 1264 | This makes it useful for control flow: |
| 1265 | |
| 1266 | print FH $data or die "Can't write to FH: $!"; |
| 1267 | |
| 1268 | This means that it short-circuits: the right expression is evaluated |
| 1269 | only if the left expression is false. Due to its precedence, you must |
| 1270 | be careful to avoid using it as replacement for the C<||> operator. |
| 1271 | It usually works out better for flow control than in assignments: |
| 1272 | |
| 1273 | $x = $y or $z; # bug: this is wrong |
| 1274 | ($x = $y) or $z; # really means this |
| 1275 | $x = $y || $z; # better written this way |
| 1276 | |
| 1277 | However, when it's a list-context assignment and you're trying to use |
| 1278 | C<||> for control flow, you probably need "or" so that the assignment |
| 1279 | takes higher precedence. |
| 1280 | |
| 1281 | @info = stat($file) || die; # oops, scalar sense of stat! |
| 1282 | @info = stat($file) or die; # better, now @info gets its due |
| 1283 | |
| 1284 | Then again, you could always use parentheses. |
| 1285 | |
| 1286 | Binary C<xor> returns the exclusive-OR of the two surrounding expressions. |
| 1287 | It cannot short-circuit (of course). |
| 1288 | |
| 1289 | There is no low precedence operator for defined-OR. |
| 1290 | |
| 1291 | =head2 C Operators Missing From Perl |
| 1292 | X<operator, missing from perl> X<&> X<*> |
| 1293 | X<typecasting> X<(TYPE)> |
| 1294 | |
| 1295 | Here is what C has that Perl doesn't: |
| 1296 | |
| 1297 | =over 8 |
| 1298 | |
| 1299 | =item unary & |
| 1300 | |
| 1301 | Address-of operator. (But see the "\" operator for taking a reference.) |
| 1302 | |
| 1303 | =item unary * |
| 1304 | |
| 1305 | Dereference-address operator. (Perl's prefix dereferencing |
| 1306 | operators are typed: $, @, %, and &.) |
| 1307 | |
| 1308 | =item (TYPE) |
| 1309 | |
| 1310 | Type-casting operator. |
| 1311 | |
| 1312 | =back |
| 1313 | |
| 1314 | =head2 Quote and Quote-like Operators |
| 1315 | X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m> |
| 1316 | X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>> |
| 1317 | X<escape sequence> X<escape> |
| 1318 | |
| 1319 | While we usually think of quotes as literal values, in Perl they |
| 1320 | function as operators, providing various kinds of interpolating and |
| 1321 | pattern matching capabilities. Perl provides customary quote characters |
| 1322 | for these behaviors, but also provides a way for you to choose your |
| 1323 | quote character for any of them. In the following table, a C<{}> represents |
| 1324 | any pair of delimiters you choose. |
| 1325 | |
| 1326 | Customary Generic Meaning Interpolates |
| 1327 | '' q{} Literal no |
| 1328 | "" qq{} Literal yes |
| 1329 | `` qx{} Command yes* |
| 1330 | qw{} Word list no |
| 1331 | // m{} Pattern match yes* |
| 1332 | qr{} Pattern yes* |
| 1333 | s{}{} Substitution yes* |
| 1334 | tr{}{} Transliteration no (but see below) |
| 1335 | y{}{} Transliteration no (but see below) |
| 1336 | <<EOF here-doc yes* |
| 1337 | |
| 1338 | * unless the delimiter is ''. |
| 1339 | |
| 1340 | Non-bracketing delimiters use the same character fore and aft, but the four |
| 1341 | sorts of ASCII brackets (round, angle, square, curly) all nest, which means |
| 1342 | that |
| 1343 | |
| 1344 | q{foo{bar}baz} |
| 1345 | |
| 1346 | is the same as |
| 1347 | |
| 1348 | 'foo{bar}baz' |
| 1349 | |
| 1350 | Note, however, that this does not always work for quoting Perl code: |
| 1351 | |
| 1352 | $s = q{ if($x eq "}") ... }; # WRONG |
| 1353 | |
| 1354 | is a syntax error. The C<Text::Balanced> module (standard as of v5.8, |
| 1355 | and from CPAN before then) is able to do this properly. |
| 1356 | |
| 1357 | There can be whitespace between the operator and the quoting |
| 1358 | characters, except when C<#> is being used as the quoting character. |
| 1359 | C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the |
| 1360 | operator C<q> followed by a comment. Its argument will be taken |
| 1361 | from the next line. This allows you to write: |
| 1362 | |
| 1363 | s {foo} # Replace foo |
| 1364 | {bar} # with bar. |
| 1365 | |
| 1366 | The following escape sequences are available in constructs that interpolate, |
| 1367 | and in transliterations: |
| 1368 | X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}> |
| 1369 | X<\o{}> |
| 1370 | |
| 1371 | Sequence Note Description |
| 1372 | \t tab (HT, TAB) |
| 1373 | \n newline (NL) |
| 1374 | \r return (CR) |
| 1375 | \f form feed (FF) |
| 1376 | \b backspace (BS) |
| 1377 | \a alarm (bell) (BEL) |
| 1378 | \e escape (ESC) |
| 1379 | \x{263A} [1,8] hex char (example: SMILEY) |
| 1380 | \x1b [2,8] restricted range hex char (example: ESC) |
| 1381 | \N{name} [3] named Unicode character or character sequence |
| 1382 | \N{U+263D} [4,8] Unicode character (example: FIRST QUARTER MOON) |
| 1383 | \c[ [5] control char (example: chr(27)) |
| 1384 | \o{23072} [6,8] octal char (example: SMILEY) |
| 1385 | \033 [7,8] restricted range octal char (example: ESC) |
| 1386 | |
| 1387 | =over 4 |
| 1388 | |
| 1389 | =item [1] |
| 1390 | |
| 1391 | The result is the character specified by the hexadecimal number between |
| 1392 | the braces. See L</[8]> below for details on which character. |
| 1393 | |
| 1394 | Only hexadecimal digits are valid between the braces. If an invalid |
| 1395 | character is encountered, a warning will be issued and the invalid |
| 1396 | character and all subsequent characters (valid or invalid) within the |
| 1397 | braces will be discarded. |
| 1398 | |
| 1399 | If there are no valid digits between the braces, the generated character is |
| 1400 | the NULL character (C<\x{00}>). However, an explicit empty brace (C<\x{}>) |
| 1401 | will not cause a warning (currently). |
| 1402 | |
| 1403 | =item [2] |
| 1404 | |
| 1405 | The result is the character specified by the hexadecimal number in the range |
| 1406 | 0x00 to 0xFF. See L</[8]> below for details on which character. |
| 1407 | |
| 1408 | Only hexadecimal digits are valid following C<\x>. When C<\x> is followed |
| 1409 | by fewer than two valid digits, any valid digits will be zero-padded. This |
| 1410 | means that C<\x7> will be interpreted as C<\x07>, and a lone <\x> will be |
| 1411 | interpreted as C<\x00>. Except at the end of a string, having fewer than |
| 1412 | two valid digits will result in a warning. Note that although the warning |
| 1413 | says the illegal character is ignored, it is only ignored as part of the |
| 1414 | escape and will still be used as the subsequent character in the string. |
| 1415 | For example: |
| 1416 | |
| 1417 | Original Result Warns? |
| 1418 | "\x7" "\x07" no |
| 1419 | "\x" "\x00" no |
| 1420 | "\x7q" "\x07q" yes |
| 1421 | "\xq" "\x00q" yes |
| 1422 | |
| 1423 | =item [3] |
| 1424 | |
| 1425 | The result is the Unicode character or character sequence given by I<name>. |
| 1426 | See L<charnames>. |
| 1427 | |
| 1428 | =item [4] |
| 1429 | |
| 1430 | C<\N{U+I<hexadecimal number>}> means the Unicode character whose Unicode code |
| 1431 | point is I<hexadecimal number>. |
| 1432 | |
| 1433 | =item [5] |
| 1434 | |
| 1435 | The character following C<\c> is mapped to some other character as shown in the |
| 1436 | table: |
| 1437 | |
| 1438 | Sequence Value |
| 1439 | \c@ chr(0) |
| 1440 | \cA chr(1) |
| 1441 | \ca chr(1) |
| 1442 | \cB chr(2) |
| 1443 | \cb chr(2) |
| 1444 | ... |
| 1445 | \cZ chr(26) |
| 1446 | \cz chr(26) |
| 1447 | \c[ chr(27) |
| 1448 | \c] chr(29) |
| 1449 | \c^ chr(30) |
| 1450 | \c_ chr(31) |
| 1451 | \c? chr(127) # (on ASCII platforms) |
| 1452 | |
| 1453 | In other words, it's the character whose code point has had 64 xor'd with |
| 1454 | its uppercase. C<\c?> is DELETE on ASCII platforms because |
| 1455 | S<C<ord("?") ^ 64>> is 127, and |
| 1456 | C<\c@> is NULL because the ord of "@" is 64, so xor'ing 64 itself produces 0. |
| 1457 | |
| 1458 | Also, C<\c\I<X>> yields C< chr(28) . "I<X>"> for any I<X>, but cannot come at the |
| 1459 | end of a string, because the backslash would be parsed as escaping the end |
| 1460 | quote. |
| 1461 | |
| 1462 | On ASCII platforms, the resulting characters from the list above are the |
| 1463 | complete set of ASCII controls. This isn't the case on EBCDIC platforms; see |
| 1464 | L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the |
| 1465 | differences between these for ASCII versus EBCDIC platforms. |
| 1466 | |
| 1467 | Use of any other character following the C<"c"> besides those listed above is |
| 1468 | discouraged, and as of Perl v5.20, the only characters actually allowed |
| 1469 | are the printable ASCII ones, minus the left brace C<"{">. What happens |
| 1470 | for any of the allowed other characters is that the value is derived by |
| 1471 | xor'ing with the seventh bit, which is 64, and a warning raised if |
| 1472 | enabled. Using the non-allowed characters generates a fatal error. |
| 1473 | |
| 1474 | To get platform independent controls, you can use C<\N{...}>. |
| 1475 | |
| 1476 | =item [6] |
| 1477 | |
| 1478 | The result is the character specified by the octal number between the braces. |
| 1479 | See L</[8]> below for details on which character. |
| 1480 | |
| 1481 | If a character that isn't an octal digit is encountered, a warning is raised, |
| 1482 | and the value is based on the octal digits before it, discarding it and all |
| 1483 | following characters up to the closing brace. It is a fatal error if there are |
| 1484 | no octal digits at all. |
| 1485 | |
| 1486 | =item [7] |
| 1487 | |
| 1488 | The result is the character specified by the three-digit octal number in the |
| 1489 | range 000 to 777 (but best to not use above 077, see next paragraph). See |
| 1490 | L</[8]> below for details on which character. |
| 1491 | |
| 1492 | Some contexts allow 2 or even 1 digit, but any usage without exactly |
| 1493 | three digits, the first being a zero, may give unintended results. (For |
| 1494 | example, in a regular expression it may be confused with a backreference; |
| 1495 | see L<perlrebackslash/Octal escapes>.) Starting in Perl 5.14, you may |
| 1496 | use C<\o{}> instead, which avoids all these problems. Otherwise, it is best to |
| 1497 | use this construct only for ordinals C<\077> and below, remembering to pad to |
| 1498 | the left with zeros to make three digits. For larger ordinals, either use |
| 1499 | C<\o{}>, or convert to something else, such as to hex and use C<\x{}> |
| 1500 | instead. |
| 1501 | |
| 1502 | =item [8] |
| 1503 | |
| 1504 | Several constructs above specify a character by a number. That number |
| 1505 | gives the character's position in the character set encoding (indexed from 0). |
| 1506 | This is called synonymously its ordinal, code position, or code point. Perl |
| 1507 | works on platforms that have a native encoding currently of either ASCII/Latin1 |
| 1508 | or EBCDIC, each of which allow specification of 256 characters. In general, if |
| 1509 | the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's |
| 1510 | native encoding. If the number is 256 (0x100, 0400) or above, Perl interprets |
| 1511 | it as a Unicode code point and the result is the corresponding Unicode |
| 1512 | character. For example C<\x{50}> and C<\o{120}> both are the number 80 in |
| 1513 | decimal, which is less than 256, so the number is interpreted in the native |
| 1514 | character set encoding. In ASCII the character in the 80th position (indexed |
| 1515 | from 0) is the letter "P", and in EBCDIC it is the ampersand symbol "&". |
| 1516 | C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted |
| 1517 | as a Unicode code point no matter what the native encoding is. The name of the |
| 1518 | character in the 256th position (indexed by 0) in Unicode is |
| 1519 | C<LATIN CAPITAL LETTER A WITH MACRON>. |
| 1520 | |
| 1521 | There are a couple of exceptions to the above rule. S<C<\N{U+I<hex number>}>> is |
| 1522 | always interpreted as a Unicode code point, so that C<\N{U+0050}> is "P" even |
| 1523 | on EBCDIC platforms. And if L<C<S<use encoding>>|encoding> is in effect, the |
| 1524 | number is considered to be in that encoding, and is translated from that into |
| 1525 | the platform's native encoding if there is a corresponding native character; |
| 1526 | otherwise to Unicode. |
| 1527 | |
| 1528 | =back |
| 1529 | |
| 1530 | B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for |
| 1531 | the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may |
| 1532 | use C<\ck> or |
| 1533 | C<\x0b>. (C<\v> |
| 1534 | does have meaning in regular expression patterns in Perl, see L<perlre>.) |
| 1535 | |
| 1536 | The following escape sequences are available in constructs that interpolate, |
| 1537 | but not in transliterations. |
| 1538 | X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F> |
| 1539 | |
| 1540 | \l lowercase next character only |
| 1541 | \u titlecase (not uppercase!) next character only |
| 1542 | \L lowercase all characters till \E or end of string |
| 1543 | \U uppercase all characters till \E or end of string |
| 1544 | \F foldcase all characters till \E or end of string |
| 1545 | \Q quote (disable) pattern metacharacters till \E or |
| 1546 | end of string |
| 1547 | \E end either case modification or quoted section |
| 1548 | (whichever was last seen) |
| 1549 | |
| 1550 | See L<perlfunc/quotemeta> for the exact definition of characters that |
| 1551 | are quoted by C<\Q>. |
| 1552 | |
| 1553 | C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one |
| 1554 | C<\E> for each. For example: |
| 1555 | |
| 1556 | say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?"; |
| 1557 | This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it? |
| 1558 | |
| 1559 | If C<use locale> is in effect (but not C<use locale ':not_characters'>), |
| 1560 | the case map used by C<\l>, C<\L>, |
| 1561 | C<\u>, and C<\U> is taken from the current locale. See L<perllocale>. |
| 1562 | If Unicode (for example, C<\N{}> or code points of 0x100 or |
| 1563 | beyond) is being used, the case map used by C<\l>, C<\L>, C<\u>, and |
| 1564 | C<\U> is as defined by Unicode. That means that case-mapping |
| 1565 | a single character can sometimes produce several characters. |
| 1566 | Under C<use locale>, C<\F> produces the same results as C<\L> |
| 1567 | for all locales but a UTF-8 one, where it instead uses the Unicode |
| 1568 | definition. |
| 1569 | |
| 1570 | All systems use the virtual C<"\n"> to represent a line terminator, |
| 1571 | called a "newline". There is no such thing as an unvarying, physical |
| 1572 | newline character. It is only an illusion that the operating system, |
| 1573 | device drivers, C libraries, and Perl all conspire to preserve. Not all |
| 1574 | systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF. For example, |
| 1575 | on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed, |
| 1576 | and on systems without line terminator, |
| 1577 | printing C<"\n"> might emit no actual data. In general, use C<"\n"> when |
| 1578 | you mean a "newline" for your system, but use the literal ASCII when you |
| 1579 | need an exact character. For example, most networking protocols expect |
| 1580 | and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators, |
| 1581 | and although they often accept just C<"\012">, they seldom tolerate just |
| 1582 | C<"\015">. If you get in the habit of using C<"\n"> for networking, |
| 1583 | you may be burned some day. |
| 1584 | X<newline> X<line terminator> X<eol> X<end of line> |
| 1585 | X<\n> X<\r> X<\r\n> |
| 1586 | |
| 1587 | For constructs that do interpolate, variables beginning with "C<$>" |
| 1588 | or "C<@>" are interpolated. Subscripted variables such as C<$a[3]> or |
| 1589 | C<< $href->{key}[0] >> are also interpolated, as are array and hash slices. |
| 1590 | But method calls such as C<< $obj->meth >> are not. |
| 1591 | |
| 1592 | Interpolating an array or slice interpolates the elements in order, |
| 1593 | separated by the value of C<$">, so is equivalent to interpolating |
| 1594 | C<join $", @array>. "Punctuation" arrays such as C<@*> are usually |
| 1595 | interpolated only if the name is enclosed in braces C<@{*}>, but the |
| 1596 | arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces. |
| 1597 | |
| 1598 | For double-quoted strings, the quoting from C<\Q> is applied after |
| 1599 | interpolation and escapes are processed. |
| 1600 | |
| 1601 | "abc\Qfoo\tbar$s\Exyz" |
| 1602 | |
| 1603 | is equivalent to |
| 1604 | |
| 1605 | "abc" . quotemeta("foo\tbar$s") . "xyz" |
| 1606 | |
| 1607 | For the pattern of regex operators (C<qr//>, C<m//> and C<s///>), |
| 1608 | the quoting from C<\Q> is applied after interpolation is processed, |
| 1609 | but before escapes are processed. This allows the pattern to match |
| 1610 | literally (except for C<$> and C<@>). For example, the following matches: |
| 1611 | |
| 1612 | '\s\t' =~ /\Q\s\t/ |
| 1613 | |
| 1614 | Because C<$> or C<@> trigger interpolation, you'll need to use something |
| 1615 | like C</\Quser\E\@\Qhost/> to match them literally. |
| 1616 | |
| 1617 | Patterns are subject to an additional level of interpretation as a |
| 1618 | regular expression. This is done as a second pass, after variables are |
| 1619 | interpolated, so that regular expressions may be incorporated into the |
| 1620 | pattern from the variables. If this is not what you want, use C<\Q> to |
| 1621 | interpolate a variable literally. |
| 1622 | |
| 1623 | Apart from the behavior described above, Perl does not expand |
| 1624 | multiple levels of interpolation. In particular, contrary to the |
| 1625 | expectations of shell programmers, back-quotes do I<NOT> interpolate |
| 1626 | within double quotes, nor do single quotes impede evaluation of |
| 1627 | variables when used within double quotes. |
| 1628 | |
| 1629 | =head2 Regexp Quote-Like Operators |
| 1630 | X<operator, regexp> |
| 1631 | |
| 1632 | Here are the quote-like operators that apply to pattern |
| 1633 | matching and related activities. |
| 1634 | |
| 1635 | =over 8 |
| 1636 | |
| 1637 | =item qr/STRING/msixpodualn |
| 1638 | X<qr> X</i> X</m> X</o> X</s> X</x> X</p> |
| 1639 | |
| 1640 | This operator quotes (and possibly compiles) its I<STRING> as a regular |
| 1641 | expression. I<STRING> is interpolated the same way as I<PATTERN> |
| 1642 | in C<m/PATTERN/>. If "'" is used as the delimiter, no interpolation |
| 1643 | is done. Returns a Perl value which may be used instead of the |
| 1644 | corresponding C</STRING/msixpodualn> expression. The returned value is a |
| 1645 | normalized version of the original pattern. It magically differs from |
| 1646 | a string containing the same characters: C<ref(qr/x/)> returns "Regexp"; |
| 1647 | however, dereferencing it is not well defined (you currently get the |
| 1648 | normalized version of the original pattern, but this may change). |
| 1649 | |
| 1650 | |
| 1651 | For example, |
| 1652 | |
| 1653 | $rex = qr/my.STRING/is; |
| 1654 | print $rex; # prints (?si-xm:my.STRING) |
| 1655 | s/$rex/foo/; |
| 1656 | |
| 1657 | is equivalent to |
| 1658 | |
| 1659 | s/my.STRING/foo/is; |
| 1660 | |
| 1661 | The result may be used as a subpattern in a match: |
| 1662 | |
| 1663 | $re = qr/$pattern/; |
| 1664 | $string =~ /foo${re}bar/; # can be interpolated in other |
| 1665 | # patterns |
| 1666 | $string =~ $re; # or used standalone |
| 1667 | $string =~ /$re/; # or this way |
| 1668 | |
| 1669 | Since Perl may compile the pattern at the moment of execution of the qr() |
| 1670 | operator, using qr() may have speed advantages in some situations, |
| 1671 | notably if the result of qr() is used standalone: |
| 1672 | |
| 1673 | sub match { |
| 1674 | my $patterns = shift; |
| 1675 | my @compiled = map qr/$_/i, @$patterns; |
| 1676 | grep { |
| 1677 | my $success = 0; |
| 1678 | foreach my $pat (@compiled) { |
| 1679 | $success = 1, last if /$pat/; |
| 1680 | } |
| 1681 | $success; |
| 1682 | } @_; |
| 1683 | } |
| 1684 | |
| 1685 | Precompilation of the pattern into an internal representation at |
| 1686 | the moment of qr() avoids a need to recompile the pattern every |
| 1687 | time a match C</$pat/> is attempted. (Perl has many other internal |
| 1688 | optimizations, but none would be triggered in the above example if |
| 1689 | we did not use qr() operator.) |
| 1690 | |
| 1691 | Options (specified by the following modifiers) are: |
| 1692 | |
| 1693 | m Treat string as multiple lines. |
| 1694 | s Treat string as single line. (Make . match a newline) |
| 1695 | i Do case-insensitive pattern matching. |
| 1696 | x Use extended regular expressions. |
| 1697 | p When matching preserve a copy of the matched string so |
| 1698 | that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be |
| 1699 | defined. |
| 1700 | o Compile pattern only once. |
| 1701 | a ASCII-restrict: Use ASCII for \d, \s, \w; specifying two |
| 1702 | a's further restricts /i matching so that no ASCII |
| 1703 | character will match a non-ASCII one. |
| 1704 | l Use the locale. |
| 1705 | u Use Unicode rules. |
| 1706 | d Use Unicode or native charset, as in 5.12 and earlier. |
| 1707 | n Non-capture mode. Don't let () fill in $1, $2, etc... |
| 1708 | |
| 1709 | If a precompiled pattern is embedded in a larger pattern then the effect |
| 1710 | of "msixpluadn" will be propagated appropriately. The effect the "o" |
| 1711 | modifier has is not propagated, being restricted to those patterns |
| 1712 | explicitly using it. |
| 1713 | |
| 1714 | The last four modifiers listed above, added in Perl 5.14, |
| 1715 | control the character set rules, but C</a> is the only one you are likely |
| 1716 | to want to specify explicitly; the other three are selected |
| 1717 | automatically by various pragmas. |
| 1718 | |
| 1719 | See L<perlre> for additional information on valid syntax for STRING, and |
| 1720 | for a detailed look at the semantics of regular expressions. In |
| 1721 | particular, all modifiers except the largely obsolete C</o> are further |
| 1722 | explained in L<perlre/Modifiers>. C</o> is described in the next section. |
| 1723 | |
| 1724 | =item m/PATTERN/msixpodualngc |
| 1725 | X<m> X<operator, match> |
| 1726 | X<regexp, options> X<regexp> X<regex, options> X<regex> |
| 1727 | X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> |
| 1728 | |
| 1729 | =item /PATTERN/msixpodualngc |
| 1730 | |
| 1731 | Searches a string for a pattern match, and in scalar context returns |
| 1732 | true if it succeeds, false if it fails. If no string is specified |
| 1733 | via the C<=~> or C<!~> operator, the $_ string is searched. (The |
| 1734 | string specified with C<=~> need not be an lvalue--it may be the |
| 1735 | result of an expression evaluation, but remember the C<=~> binds |
| 1736 | rather tightly.) See also L<perlre>. |
| 1737 | |
| 1738 | Options are as described in C<qr//> above; in addition, the following match |
| 1739 | process modifiers are available: |
| 1740 | |
| 1741 | g Match globally, i.e., find all occurrences. |
| 1742 | c Do not reset search position on a failed match when /g is |
| 1743 | in effect. |
| 1744 | |
| 1745 | If "/" is the delimiter then the initial C<m> is optional. With the C<m> |
| 1746 | you can use any pair of non-whitespace (ASCII) characters |
| 1747 | as delimiters. This is particularly useful for matching path names |
| 1748 | that contain "/", to avoid LTS (leaning toothpick syndrome). If "?" is |
| 1749 | the delimiter, then a match-only-once rule applies, |
| 1750 | described in C<m?PATTERN?> below. If "'" (single quote) is the delimiter, |
| 1751 | no interpolation is performed on the PATTERN. |
| 1752 | When using a character valid in an identifier, whitespace is required |
| 1753 | after the C<m>. |
| 1754 | |
| 1755 | PATTERN may contain variables, which will be interpolated |
| 1756 | every time the pattern search is evaluated, except |
| 1757 | for when the delimiter is a single quote. (Note that C<$(>, C<$)>, and |
| 1758 | C<$|> are not interpolated because they look like end-of-string tests.) |
| 1759 | Perl will not recompile the pattern unless an interpolated |
| 1760 | variable that it contains changes. You can force Perl to skip the |
| 1761 | test and never recompile by adding a C</o> (which stands for "once") |
| 1762 | after the trailing delimiter. |
| 1763 | Once upon a time, Perl would recompile regular expressions |
| 1764 | unnecessarily, and this modifier was useful to tell it not to do so, in the |
| 1765 | interests of speed. But now, the only reasons to use C</o> are one of: |
| 1766 | |
| 1767 | =over |
| 1768 | |
| 1769 | =item 1 |
| 1770 | |
| 1771 | The variables are thousands of characters long and you know that they |
| 1772 | don't change, and you need to wring out the last little bit of speed by |
| 1773 | having Perl skip testing for that. (There is a maintenance penalty for |
| 1774 | doing this, as mentioning C</o> constitutes a promise that you won't |
| 1775 | change the variables in the pattern. If you do change them, Perl won't |
| 1776 | even notice.) |
| 1777 | |
| 1778 | =item 2 |
| 1779 | |
| 1780 | you want the pattern to use the initial values of the variables |
| 1781 | regardless of whether they change or not. (But there are saner ways |
| 1782 | of accomplishing this than using C</o>.) |
| 1783 | |
| 1784 | =item 3 |
| 1785 | |
| 1786 | If the pattern contains embedded code, such as |
| 1787 | |
| 1788 | use re 'eval'; |
| 1789 | $code = 'foo(?{ $x })'; |
| 1790 | /$code/ |
| 1791 | |
| 1792 | then perl will recompile each time, even though the pattern string hasn't |
| 1793 | changed, to ensure that the current value of C<$x> is seen each time. |
| 1794 | Use C</o> if you want to avoid this. |
| 1795 | |
| 1796 | =back |
| 1797 | |
| 1798 | The bottom line is that using C</o> is almost never a good idea. |
| 1799 | |
| 1800 | =item The empty pattern // |
| 1801 | |
| 1802 | If the PATTERN evaluates to the empty string, the last |
| 1803 | I<successfully> matched regular expression is used instead. In this |
| 1804 | case, only the C<g> and C<c> flags on the empty pattern are honored; |
| 1805 | the other flags are taken from the original pattern. If no match has |
| 1806 | previously succeeded, this will (silently) act instead as a genuine |
| 1807 | empty pattern (which will always match). |
| 1808 | |
| 1809 | Note that it's possible to confuse Perl into thinking C<//> (the empty |
| 1810 | regex) is really C<//> (the defined-or operator). Perl is usually pretty |
| 1811 | good about this, but some pathological cases might trigger this, such as |
| 1812 | C<$x///> (is that C<($x) / (//)> or C<$x // />?) and C<print $fh //> |
| 1813 | (C<print $fh(//> or C<print($fh //>?). In all of these examples, Perl |
| 1814 | will assume you meant defined-or. If you meant the empty regex, just |
| 1815 | use parentheses or spaces to disambiguate, or even prefix the empty |
| 1816 | regex with an C<m> (so C<//> becomes C<m//>). |
| 1817 | |
| 1818 | =item Matching in list context |
| 1819 | |
| 1820 | If the C</g> option is not used, C<m//> in list context returns a |
| 1821 | list consisting of the subexpressions matched by the parentheses in the |
| 1822 | pattern, that is, (C<$1>, C<$2>, C<$3>...) (Note that here C<$1> etc. are |
| 1823 | also set). When there are no parentheses in the pattern, the return |
| 1824 | value is the list C<(1)> for success. |
| 1825 | With or without parentheses, an empty list is returned upon failure. |
| 1826 | |
| 1827 | Examples: |
| 1828 | |
| 1829 | open(TTY, "+</dev/tty") |
| 1830 | || die "can't access /dev/tty: $!"; |
| 1831 | |
| 1832 | <TTY> =~ /^y/i && foo(); # do foo if desired |
| 1833 | |
| 1834 | if (/Version: *([0-9.]*)/) { $version = $1; } |
| 1835 | |
| 1836 | next if m#^/usr/spool/uucp#; |
| 1837 | |
| 1838 | # poor man's grep |
| 1839 | $arg = shift; |
| 1840 | while (<>) { |
| 1841 | print if /$arg/o; # compile only once (no longer needed!) |
| 1842 | } |
| 1843 | |
| 1844 | if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/)) |
| 1845 | |
| 1846 | This last example splits $foo into the first two words and the |
| 1847 | remainder of the line, and assigns those three fields to $F1, $F2, and |
| 1848 | $Etc. The conditional is true if any variables were assigned; that is, |
| 1849 | if the pattern matched. |
| 1850 | |
| 1851 | The C</g> modifier specifies global pattern matching--that is, |
| 1852 | matching as many times as possible within the string. How it behaves |
| 1853 | depends on the context. In list context, it returns a list of the |
| 1854 | substrings matched by any capturing parentheses in the regular |
| 1855 | expression. If there are no parentheses, it returns a list of all |
| 1856 | the matched strings, as if there were parentheses around the whole |
| 1857 | pattern. |
| 1858 | |
| 1859 | In scalar context, each execution of C<m//g> finds the next match, |
| 1860 | returning true if it matches, and false if there is no further match. |
| 1861 | The position after the last match can be read or set using the C<pos()> |
| 1862 | function; see L<perlfunc/pos>. A failed match normally resets the |
| 1863 | search position to the beginning of the string, but you can avoid that |
| 1864 | by adding the C</c> modifier (for example, C<m//gc>). Modifying the target |
| 1865 | string also resets the search position. |
| 1866 | |
| 1867 | =item \G assertion |
| 1868 | |
| 1869 | You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a |
| 1870 | zero-width assertion that matches the exact position where the |
| 1871 | previous C<m//g>, if any, left off. Without the C</g> modifier, the |
| 1872 | C<\G> assertion still anchors at C<pos()> as it was at the start of |
| 1873 | the operation (see L<perlfunc/pos>), but the match is of course only |
| 1874 | attempted once. Using C<\G> without C</g> on a target string that has |
| 1875 | not previously had a C</g> match applied to it is the same as using |
| 1876 | the C<\A> assertion to match the beginning of the string. Note also |
| 1877 | that, currently, C<\G> is only properly supported when anchored at the |
| 1878 | very beginning of the pattern. |
| 1879 | |
| 1880 | Examples: |
| 1881 | |
| 1882 | # list context |
| 1883 | ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g); |
| 1884 | |
| 1885 | # scalar context |
| 1886 | local $/ = ""; |
| 1887 | while ($paragraph = <>) { |
| 1888 | while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) { |
| 1889 | $sentences++; |
| 1890 | } |
| 1891 | } |
| 1892 | say $sentences; |
| 1893 | |
| 1894 | Here's another way to check for sentences in a paragraph: |
| 1895 | |
| 1896 | my $sentence_rx = qr{ |
| 1897 | (?: (?<= ^ ) | (?<= \s ) ) # after start-of-string or |
| 1898 | # whitespace |
| 1899 | \p{Lu} # capital letter |
| 1900 | .*? # a bunch of anything |
| 1901 | (?<= \S ) # that ends in non- |
| 1902 | # whitespace |
| 1903 | (?<! \b [DMS]r ) # but isn't a common abbr. |
| 1904 | (?<! \b Mrs ) |
| 1905 | (?<! \b Sra ) |
| 1906 | (?<! \b St ) |
| 1907 | [.?!] # followed by a sentence |
| 1908 | # ender |
| 1909 | (?= $ | \s ) # in front of end-of-string |
| 1910 | # or whitespace |
| 1911 | }sx; |
| 1912 | local $/ = ""; |
| 1913 | while (my $paragraph = <>) { |
| 1914 | say "NEW PARAGRAPH"; |
| 1915 | my $count = 0; |
| 1916 | while ($paragraph =~ /($sentence_rx)/g) { |
| 1917 | printf "\tgot sentence %d: <%s>\n", ++$count, $1; |
| 1918 | } |
| 1919 | } |
| 1920 | |
| 1921 | Here's how to use C<m//gc> with C<\G>: |
| 1922 | |
| 1923 | $_ = "ppooqppqq"; |
| 1924 | while ($i++ < 2) { |
| 1925 | print "1: '"; |
| 1926 | print $1 while /(o)/gc; print "', pos=", pos, "\n"; |
| 1927 | print "2: '"; |
| 1928 | print $1 if /\G(q)/gc; print "', pos=", pos, "\n"; |
| 1929 | print "3: '"; |
| 1930 | print $1 while /(p)/gc; print "', pos=", pos, "\n"; |
| 1931 | } |
| 1932 | print "Final: '$1', pos=",pos,"\n" if /\G(.)/; |
| 1933 | |
| 1934 | The last example should print: |
| 1935 | |
| 1936 | 1: 'oo', pos=4 |
| 1937 | 2: 'q', pos=5 |
| 1938 | 3: 'pp', pos=7 |
| 1939 | 1: '', pos=7 |
| 1940 | 2: 'q', pos=8 |
| 1941 | 3: '', pos=8 |
| 1942 | Final: 'q', pos=8 |
| 1943 | |
| 1944 | Notice that the final match matched C<q> instead of C<p>, which a match |
| 1945 | without the C<\G> anchor would have done. Also note that the final match |
| 1946 | did not update C<pos>. C<pos> is only updated on a C</g> match. If the |
| 1947 | final match did indeed match C<p>, it's a good bet that you're running a |
| 1948 | very old (pre-5.6.0) version of Perl. |
| 1949 | |
| 1950 | A useful idiom for C<lex>-like scanners is C</\G.../gc>. You can |
| 1951 | combine several regexps like this to process a string part-by-part, |
| 1952 | doing different actions depending on which regexp matched. Each |
| 1953 | regexp tries to match where the previous one leaves off. |
| 1954 | |
| 1955 | $_ = <<'EOL'; |
| 1956 | $url = URI::URL->new( "http://example.com/" ); |
| 1957 | die if $url eq "xXx"; |
| 1958 | EOL |
| 1959 | |
| 1960 | LOOP: { |
| 1961 | print(" digits"), redo LOOP if /\G\d+\b[,.;]?\s*/gc; |
| 1962 | print(" lowercase"), redo LOOP |
| 1963 | if /\G\p{Ll}+\b[,.;]?\s*/gc; |
| 1964 | print(" UPPERCASE"), redo LOOP |
| 1965 | if /\G\p{Lu}+\b[,.;]?\s*/gc; |
| 1966 | print(" Capitalized"), redo LOOP |
| 1967 | if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc; |
| 1968 | print(" MiXeD"), redo LOOP if /\G\pL+\b[,.;]?\s*/gc; |
| 1969 | print(" alphanumeric"), redo LOOP |
| 1970 | if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc; |
| 1971 | print(" line-noise"), redo LOOP if /\G\W+/gc; |
| 1972 | print ". That's all!\n"; |
| 1973 | } |
| 1974 | |
| 1975 | Here is the output (split into several lines): |
| 1976 | |
| 1977 | line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE |
| 1978 | line-noise lowercase line-noise lowercase line-noise lowercase |
| 1979 | lowercase line-noise lowercase lowercase line-noise lowercase |
| 1980 | lowercase line-noise MiXeD line-noise. That's all! |
| 1981 | |
| 1982 | =item m?PATTERN?msixpodualngc |
| 1983 | X<?> X<operator, match-once> |
| 1984 | |
| 1985 | =item ?PATTERN?msixpodualngc |
| 1986 | |
| 1987 | This is just like the C<m/PATTERN/> search, except that it matches |
| 1988 | only once between calls to the reset() operator. This is a useful |
| 1989 | optimization when you want to see only the first occurrence of |
| 1990 | something in each file of a set of files, for instance. Only C<m??> |
| 1991 | patterns local to the current package are reset. |
| 1992 | |
| 1993 | while (<>) { |
| 1994 | if (m?^$?) { |
| 1995 | # blank line between header and body |
| 1996 | } |
| 1997 | } continue { |
| 1998 | reset if eof; # clear m?? status for next file |
| 1999 | } |
| 2000 | |
| 2001 | Another example switched the first "latin1" encoding it finds |
| 2002 | to "utf8" in a pod file: |
| 2003 | |
| 2004 | s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x; |
| 2005 | |
| 2006 | The match-once behavior is controlled by the match delimiter being |
| 2007 | C<?>; with any other delimiter this is the normal C<m//> operator. |
| 2008 | |
| 2009 | In the past, the leading C<m> in C<m?PATTERN?> was optional, but omitting it |
| 2010 | would produce a deprecation warning. As of v5.22.0, omitting it produces a |
| 2011 | syntax error. If you encounter this construct in older code, you can just add |
| 2012 | C<m>. |
| 2013 | |
| 2014 | =item s/PATTERN/REPLACEMENT/msixpodualngcer |
| 2015 | X<substitute> X<substitution> X<replace> X<regexp, replace> |
| 2016 | X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r> |
| 2017 | |
| 2018 | Searches a string for a pattern, and if found, replaces that pattern |
| 2019 | with the replacement text and returns the number of substitutions |
| 2020 | made. Otherwise it returns false (specifically, the empty string). |
| 2021 | |
| 2022 | If the C</r> (non-destructive) option is used then it runs the |
| 2023 | substitution on a copy of the string and instead of returning the |
| 2024 | number of substitutions, it returns the copy whether or not a |
| 2025 | substitution occurred. The original string is never changed when |
| 2026 | C</r> is used. The copy will always be a plain string, even if the |
| 2027 | input is an object or a tied variable. |
| 2028 | |
| 2029 | If no string is specified via the C<=~> or C<!~> operator, the C<$_> |
| 2030 | variable is searched and modified. Unless the C</r> option is used, |
| 2031 | the string specified must be a scalar variable, an array element, a |
| 2032 | hash element, or an assignment to one of those; that is, some sort of |
| 2033 | scalar lvalue. |
| 2034 | |
| 2035 | If the delimiter chosen is a single quote, no interpolation is |
| 2036 | done on either the PATTERN or the REPLACEMENT. Otherwise, if the |
| 2037 | PATTERN contains a $ that looks like a variable rather than an |
| 2038 | end-of-string test, the variable will be interpolated into the pattern |
| 2039 | at run-time. If you want the pattern compiled only once the first time |
| 2040 | the variable is interpolated, use the C</o> option. If the pattern |
| 2041 | evaluates to the empty string, the last successfully executed regular |
| 2042 | expression is used instead. See L<perlre> for further explanation on these. |
| 2043 | |
| 2044 | Options are as with m// with the addition of the following replacement |
| 2045 | specific options: |
| 2046 | |
| 2047 | e Evaluate the right side as an expression. |
| 2048 | ee Evaluate the right side as a string then eval the |
| 2049 | result. |
| 2050 | r Return substitution and leave the original string |
| 2051 | untouched. |
| 2052 | |
| 2053 | Any non-whitespace delimiter may replace the slashes. Add space after |
| 2054 | the C<s> when using a character allowed in identifiers. If single quotes |
| 2055 | are used, no interpretation is done on the replacement string (the C</e> |
| 2056 | modifier overrides this, however). Note that Perl treats backticks |
| 2057 | as normal delimiters; the replacement text is not evaluated as a command. |
| 2058 | If the PATTERN is delimited by bracketing quotes, the REPLACEMENT has |
| 2059 | its own pair of quotes, which may or may not be bracketing quotes, for example, |
| 2060 | C<s(foo)(bar)> or C<< s<foo>/bar/ >>. A C</e> will cause the |
| 2061 | replacement portion to be treated as a full-fledged Perl expression |
| 2062 | and evaluated right then and there. It is, however, syntax checked at |
| 2063 | compile-time. A second C<e> modifier will cause the replacement portion |
| 2064 | to be C<eval>ed before being run as a Perl expression. |
| 2065 | |
| 2066 | Examples: |
| 2067 | |
| 2068 | s/\bgreen\b/mauve/g; # don't change wintergreen |
| 2069 | |
| 2070 | $path =~ s|/usr/bin|/usr/local/bin|; |
| 2071 | |
| 2072 | s/Login: $foo/Login: $bar/; # run-time pattern |
| 2073 | |
| 2074 | ($foo = $bar) =~ s/this/that/; # copy first, then |
| 2075 | # change |
| 2076 | ($foo = "$bar") =~ s/this/that/; # convert to string, |
| 2077 | # copy, then change |
| 2078 | $foo = $bar =~ s/this/that/r; # Same as above using /r |
| 2079 | $foo = $bar =~ s/this/that/r |
| 2080 | =~ s/that/the other/r; # Chained substitutes |
| 2081 | # using /r |
| 2082 | @foo = map { s/this/that/r } @bar # /r is very useful in |
| 2083 | # maps |
| 2084 | |
| 2085 | $count = ($paragraph =~ s/Mister\b/Mr./g); # get change-cnt |
| 2086 | |
| 2087 | $_ = 'abc123xyz'; |
| 2088 | s/\d+/$&*2/e; # yields 'abc246xyz' |
| 2089 | s/\d+/sprintf("%5d",$&)/e; # yields 'abc 246xyz' |
| 2090 | s/\w/$& x 2/eg; # yields 'aabbcc 224466xxyyzz' |
| 2091 | |
| 2092 | s/%(.)/$percent{$1}/g; # change percent escapes; no /e |
| 2093 | s/%(.)/$percent{$1} || $&/ge; # expr now, so /e |
| 2094 | s/^=(\w+)/pod($1)/ge; # use function call |
| 2095 | |
| 2096 | $_ = 'abc123xyz'; |
| 2097 | $x = s/abc/def/r; # $x is 'def123xyz' and |
| 2098 | # $_ remains 'abc123xyz'. |
| 2099 | |
| 2100 | # expand variables in $_, but dynamics only, using |
| 2101 | # symbolic dereferencing |
| 2102 | s/\$(\w+)/${$1}/g; |
| 2103 | |
| 2104 | # Add one to the value of any numbers in the string |
| 2105 | s/(\d+)/1 + $1/eg; |
| 2106 | |
| 2107 | # Titlecase words in the last 30 characters only |
| 2108 | substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g; |
| 2109 | |
| 2110 | # This will expand any embedded scalar variable |
| 2111 | # (including lexicals) in $_ : First $1 is interpolated |
| 2112 | # to the variable name, and then evaluated |
| 2113 | s/(\$\w+)/$1/eeg; |
| 2114 | |
| 2115 | # Delete (most) C comments. |
| 2116 | $program =~ s { |
| 2117 | /\* # Match the opening delimiter. |
| 2118 | .*? # Match a minimal number of characters. |
| 2119 | \*/ # Match the closing delimiter. |
| 2120 | } []gsx; |
| 2121 | |
| 2122 | s/^\s*(.*?)\s*$/$1/; # trim whitespace in $_, |
| 2123 | # expensively |
| 2124 | |
| 2125 | for ($variable) { # trim whitespace in $variable, |
| 2126 | # cheap |
| 2127 | s/^\s+//; |
| 2128 | s/\s+$//; |
| 2129 | } |
| 2130 | |
| 2131 | s/([^ ]*) *([^ ]*)/$2 $1/; # reverse 1st two fields |
| 2132 | |
| 2133 | Note the use of $ instead of \ in the last example. Unlike |
| 2134 | B<sed>, we use the \<I<digit>> form in only the left hand side. |
| 2135 | Anywhere else it's $<I<digit>>. |
| 2136 | |
| 2137 | Occasionally, you can't use just a C</g> to get all the changes |
| 2138 | to occur that you might want. Here are two common cases: |
| 2139 | |
| 2140 | # put commas in the right places in an integer |
| 2141 | 1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g; |
| 2142 | |
| 2143 | # expand tabs to 8-column spacing |
| 2144 | 1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e; |
| 2145 | |
| 2146 | =back |
| 2147 | |
| 2148 | =head2 Quote-Like Operators |
| 2149 | X<operator, quote-like> |
| 2150 | |
| 2151 | =over 4 |
| 2152 | |
| 2153 | =item q/STRING/ |
| 2154 | X<q> X<quote, single> X<'> X<''> |
| 2155 | |
| 2156 | =item 'STRING' |
| 2157 | |
| 2158 | A single-quoted, literal string. A backslash represents a backslash |
| 2159 | unless followed by the delimiter or another backslash, in which case |
| 2160 | the delimiter or backslash is interpolated. |
| 2161 | |
| 2162 | $foo = q!I said, "You said, 'She said it.'"!; |
| 2163 | $bar = q('This is it.'); |
| 2164 | $baz = '\n'; # a two-character string |
| 2165 | |
| 2166 | =item qq/STRING/ |
| 2167 | X<qq> X<quote, double> X<"> X<""> |
| 2168 | |
| 2169 | =item "STRING" |
| 2170 | |
| 2171 | A double-quoted, interpolated string. |
| 2172 | |
| 2173 | $_ .= qq |
| 2174 | (*** The previous line contains the naughty word "$1".\n) |
| 2175 | if /\b(tcl|java|python)\b/i; # :-) |
| 2176 | $baz = "\n"; # a one-character string |
| 2177 | |
| 2178 | =item qx/STRING/ |
| 2179 | X<qx> X<`> X<``> X<backtick> |
| 2180 | |
| 2181 | =item `STRING` |
| 2182 | |
| 2183 | A string which is (possibly) interpolated and then executed as a |
| 2184 | system command with F</bin/sh> or its equivalent. Shell wildcards, |
| 2185 | pipes, and redirections will be honored. The collected standard |
| 2186 | output of the command is returned; standard error is unaffected. In |
| 2187 | scalar context, it comes back as a single (potentially multi-line) |
| 2188 | string, or undef if the command failed. In list context, returns a |
| 2189 | list of lines (however you've defined lines with $/ or |
| 2190 | $INPUT_RECORD_SEPARATOR), or an empty list if the command failed. |
| 2191 | |
| 2192 | Because backticks do not affect standard error, use shell file descriptor |
| 2193 | syntax (assuming the shell supports this) if you care to address this. |
| 2194 | To capture a command's STDERR and STDOUT together: |
| 2195 | |
| 2196 | $output = `cmd 2>&1`; |
| 2197 | |
| 2198 | To capture a command's STDOUT but discard its STDERR: |
| 2199 | |
| 2200 | $output = `cmd 2>/dev/null`; |
| 2201 | |
| 2202 | To capture a command's STDERR but discard its STDOUT (ordering is |
| 2203 | important here): |
| 2204 | |
| 2205 | $output = `cmd 2>&1 1>/dev/null`; |
| 2206 | |
| 2207 | To exchange a command's STDOUT and STDERR in order to capture the STDERR |
| 2208 | but leave its STDOUT to come out the old STDERR: |
| 2209 | |
| 2210 | $output = `cmd 3>&1 1>&2 2>&3 3>&-`; |
| 2211 | |
| 2212 | To read both a command's STDOUT and its STDERR separately, it's easiest |
| 2213 | to redirect them separately to files, and then read from those files |
| 2214 | when the program is done: |
| 2215 | |
| 2216 | system("program args 1>program.stdout 2>program.stderr"); |
| 2217 | |
| 2218 | The STDIN filehandle used by the command is inherited from Perl's STDIN. |
| 2219 | For example: |
| 2220 | |
| 2221 | open(SPLAT, "stuff") || die "can't open stuff: $!"; |
| 2222 | open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!"; |
| 2223 | print STDOUT `sort`; |
| 2224 | |
| 2225 | will print the sorted contents of the file named F<"stuff">. |
| 2226 | |
| 2227 | Using single-quote as a delimiter protects the command from Perl's |
| 2228 | double-quote interpolation, passing it on to the shell instead: |
| 2229 | |
| 2230 | $perl_info = qx(ps $$); # that's Perl's $$ |
| 2231 | $shell_info = qx'ps $$'; # that's the new shell's $$ |
| 2232 | |
| 2233 | How that string gets evaluated is entirely subject to the command |
| 2234 | interpreter on your system. On most platforms, you will have to protect |
| 2235 | shell metacharacters if you want them treated literally. This is in |
| 2236 | practice difficult to do, as it's unclear how to escape which characters. |
| 2237 | See L<perlsec> for a clean and safe example of a manual fork() and exec() |
| 2238 | to emulate backticks safely. |
| 2239 | |
| 2240 | On some platforms (notably DOS-like ones), the shell may not be |
| 2241 | capable of dealing with multiline commands, so putting newlines in |
| 2242 | the string may not get you what you want. You may be able to evaluate |
| 2243 | multiple commands in a single line by separating them with the command |
| 2244 | separator character, if your shell supports that (for example, C<;> on |
| 2245 | many Unix shells and C<&> on the Windows NT C<cmd> shell). |
| 2246 | |
| 2247 | Perl will attempt to flush all files opened for |
| 2248 | output before starting the child process, but this may not be supported |
| 2249 | on some platforms (see L<perlport>). To be safe, you may need to set |
| 2250 | C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of |
| 2251 | C<IO::Handle> on any open handles. |
| 2252 | |
| 2253 | Beware that some command shells may place restrictions on the length |
| 2254 | of the command line. You must ensure your strings don't exceed this |
| 2255 | limit after any necessary interpolations. See the platform-specific |
| 2256 | release notes for more details about your particular environment. |
| 2257 | |
| 2258 | Using this operator can lead to programs that are difficult to port, |
| 2259 | because the shell commands called vary between systems, and may in |
| 2260 | fact not be present at all. As one example, the C<type> command under |
| 2261 | the POSIX shell is very different from the C<type> command under DOS. |
| 2262 | That doesn't mean you should go out of your way to avoid backticks |
| 2263 | when they're the right way to get something done. Perl was made to be |
| 2264 | a glue language, and one of the things it glues together is commands. |
| 2265 | Just understand what you're getting yourself into. |
| 2266 | |
| 2267 | See L</"I/O Operators"> for more discussion. |
| 2268 | |
| 2269 | =item qw/STRING/ |
| 2270 | X<qw> X<quote, list> X<quote, words> |
| 2271 | |
| 2272 | Evaluates to a list of the words extracted out of STRING, using embedded |
| 2273 | whitespace as the word delimiters. It can be understood as being roughly |
| 2274 | equivalent to: |
| 2275 | |
| 2276 | split(" ", q/STRING/); |
| 2277 | |
| 2278 | the differences being that it generates a real list at compile time, and |
| 2279 | in scalar context it returns the last element in the list. So |
| 2280 | this expression: |
| 2281 | |
| 2282 | qw(foo bar baz) |
| 2283 | |
| 2284 | is semantically equivalent to the list: |
| 2285 | |
| 2286 | "foo", "bar", "baz" |
| 2287 | |
| 2288 | Some frequently seen examples: |
| 2289 | |
| 2290 | use POSIX qw( setlocale localeconv ) |
| 2291 | @EXPORT = qw( foo bar baz ); |
| 2292 | |
| 2293 | A common mistake is to try to separate the words with comma or to |
| 2294 | put comments into a multi-line C<qw>-string. For this reason, the |
| 2295 | C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable) |
| 2296 | produces warnings if the STRING contains the "," or the "#" character. |
| 2297 | |
| 2298 | =item tr/SEARCHLIST/REPLACEMENTLIST/cdsr |
| 2299 | X<tr> X<y> X<transliterate> X</c> X</d> X</s> |
| 2300 | |
| 2301 | =item y/SEARCHLIST/REPLACEMENTLIST/cdsr |
| 2302 | |
| 2303 | Transliterates all occurrences of the characters found in the search list |
| 2304 | with the corresponding character in the replacement list. It returns |
| 2305 | the number of characters replaced or deleted. If no string is |
| 2306 | specified via the C<=~> or C<!~> operator, the $_ string is transliterated. |
| 2307 | |
| 2308 | If the C</r> (non-destructive) option is present, a new copy of the string |
| 2309 | is made and its characters transliterated, and this copy is returned no |
| 2310 | matter whether it was modified or not: the original string is always |
| 2311 | left unchanged. The new copy is always a plain string, even if the input |
| 2312 | string is an object or a tied variable. |
| 2313 | |
| 2314 | Unless the C</r> option is used, the string specified with C<=~> must be a |
| 2315 | scalar variable, an array element, a hash element, or an assignment to one |
| 2316 | of those; in other words, an lvalue. |
| 2317 | |
| 2318 | A character range may be specified with a hyphen, so C<tr/A-J/0-9/> |
| 2319 | does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>. |
| 2320 | For B<sed> devotees, C<y> is provided as a synonym for C<tr>. If the |
| 2321 | SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has |
| 2322 | its own pair of quotes, which may or may not be bracketing quotes; |
| 2323 | for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>. |
| 2324 | |
| 2325 | Note that C<tr> does B<not> do regular expression character classes such as |
| 2326 | C<\d> or C<\pL>. The C<tr> operator is not equivalent to the tr(1) |
| 2327 | utility. If you want to map strings between lower/upper cases, see |
| 2328 | L<perlfunc/lc> and L<perlfunc/uc>, and in general consider using the C<s> |
| 2329 | operator if you need regular expressions. The C<\U>, C<\u>, C<\L>, and |
| 2330 | C<\l> string-interpolation escapes on the right side of a substitution |
| 2331 | operator will perform correct case-mappings, but C<tr[a-z][A-Z]> will not |
| 2332 | (except sometimes on legacy 7-bit data). |
| 2333 | |
| 2334 | Note also that the whole range idea is rather unportable between |
| 2335 | character sets--and even within character sets they may cause results |
| 2336 | you probably didn't expect. A sound principle is to use only ranges |
| 2337 | that begin from and end at either alphabets of equal case (a-e, A-E), |
| 2338 | or digits (0-4). Anything else is unsafe. If in doubt, spell out the |
| 2339 | character sets in full. |
| 2340 | |
| 2341 | Options: |
| 2342 | |
| 2343 | c Complement the SEARCHLIST. |
| 2344 | d Delete found but unreplaced characters. |
| 2345 | s Squash duplicate replaced characters. |
| 2346 | r Return the modified string and leave the original string |
| 2347 | untouched. |
| 2348 | |
| 2349 | If the C</c> modifier is specified, the SEARCHLIST character set |
| 2350 | is complemented. If the C</d> modifier is specified, any characters |
| 2351 | specified by SEARCHLIST not found in REPLACEMENTLIST are deleted. |
| 2352 | (Note that this is slightly more flexible than the behavior of some |
| 2353 | B<tr> programs, which delete anything they find in the SEARCHLIST, |
| 2354 | period.) If the C</s> modifier is specified, sequences of characters |
| 2355 | that were transliterated to the same character are squashed down |
| 2356 | to a single instance of the character. |
| 2357 | |
| 2358 | If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted |
| 2359 | exactly as specified. Otherwise, if the REPLACEMENTLIST is shorter |
| 2360 | than the SEARCHLIST, the final character is replicated till it is long |
| 2361 | enough. If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated. |
| 2362 | This latter is useful for counting characters in a class or for |
| 2363 | squashing character sequences in a class. |
| 2364 | |
| 2365 | Examples: |
| 2366 | |
| 2367 | $ARGV[1] =~ tr/A-Z/a-z/; # canonicalize to lower case ASCII |
| 2368 | |
| 2369 | $cnt = tr/*/*/; # count the stars in $_ |
| 2370 | |
| 2371 | $cnt = $sky =~ tr/*/*/; # count the stars in $sky |
| 2372 | |
| 2373 | $cnt = tr/0-9//; # count the digits in $_ |
| 2374 | |
| 2375 | tr/a-zA-Z//s; # bookkeeper -> bokeper |
| 2376 | |
| 2377 | ($HOST = $host) =~ tr/a-z/A-Z/; |
| 2378 | $HOST = $host =~ tr/a-z/A-Z/r; # same thing |
| 2379 | |
| 2380 | $HOST = $host =~ tr/a-z/A-Z/r # chained with s///r |
| 2381 | =~ s/:/ -p/r; |
| 2382 | |
| 2383 | tr/a-zA-Z/ /cs; # change non-alphas to single space |
| 2384 | |
| 2385 | @stripped = map tr/a-zA-Z/ /csr, @original; |
| 2386 | # /r with map |
| 2387 | |
| 2388 | tr [\200-\377] |
| 2389 | [\000-\177]; # wickedly delete 8th bit |
| 2390 | |
| 2391 | If multiple transliterations are given for a character, only the |
| 2392 | first one is used: |
| 2393 | |
| 2394 | tr/AAA/XYZ/ |
| 2395 | |
| 2396 | will transliterate any A to X. |
| 2397 | |
| 2398 | Because the transliteration table is built at compile time, neither |
| 2399 | the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote |
| 2400 | interpolation. That means that if you want to use variables, you |
| 2401 | must use an eval(): |
| 2402 | |
| 2403 | eval "tr/$oldlist/$newlist/"; |
| 2404 | die $@ if $@; |
| 2405 | |
| 2406 | eval "tr/$oldlist/$newlist/, 1" or die $@; |
| 2407 | |
| 2408 | =item <<EOF |
| 2409 | X<here-doc> X<heredoc> X<here-document> X<<< << >>> |
| 2410 | |
| 2411 | A line-oriented form of quoting is based on the shell "here-document" |
| 2412 | syntax. Following a C<< << >> you specify a string to terminate |
| 2413 | the quoted material, and all lines following the current line down to |
| 2414 | the terminating string are the value of the item. |
| 2415 | |
| 2416 | The terminating string may be either an identifier (a word), or some |
| 2417 | quoted text. An unquoted identifier works like double quotes. |
| 2418 | There may not be a space between the C<< << >> and the identifier, |
| 2419 | unless the identifier is explicitly quoted. (If you put a space it |
| 2420 | will be treated as a null identifier, which is valid, and matches the |
| 2421 | first empty line.) The terminating string must appear by itself |
| 2422 | (unquoted and with no surrounding whitespace) on the terminating line. |
| 2423 | |
| 2424 | If the terminating string is quoted, the type of quotes used determine |
| 2425 | the treatment of the text. |
| 2426 | |
| 2427 | =over 4 |
| 2428 | |
| 2429 | =item Double Quotes |
| 2430 | |
| 2431 | Double quotes indicate that the text will be interpolated using exactly |
| 2432 | the same rules as normal double quoted strings. |
| 2433 | |
| 2434 | print <<EOF; |
| 2435 | The price is $Price. |
| 2436 | EOF |
| 2437 | |
| 2438 | print << "EOF"; # same as above |
| 2439 | The price is $Price. |
| 2440 | EOF |
| 2441 | |
| 2442 | |
| 2443 | =item Single Quotes |
| 2444 | |
| 2445 | Single quotes indicate the text is to be treated literally with no |
| 2446 | interpolation of its content. This is similar to single quoted |
| 2447 | strings except that backslashes have no special meaning, with C<\\> |
| 2448 | being treated as two backslashes and not one as they would in every |
| 2449 | other quoting construct. |
| 2450 | |
| 2451 | Just as in the shell, a backslashed bareword following the C<<< << >>> |
| 2452 | means the same thing as a single-quoted string does: |
| 2453 | |
| 2454 | $cost = <<'VISTA'; # hasta la ... |
| 2455 | That'll be $10 please, ma'am. |
| 2456 | VISTA |
| 2457 | |
| 2458 | $cost = <<\VISTA; # Same thing! |
| 2459 | That'll be $10 please, ma'am. |
| 2460 | VISTA |
| 2461 | |
| 2462 | This is the only form of quoting in perl where there is no need |
| 2463 | to worry about escaping content, something that code generators |
| 2464 | can and do make good use of. |
| 2465 | |
| 2466 | =item Backticks |
| 2467 | |
| 2468 | The content of the here doc is treated just as it would be if the |
| 2469 | string were embedded in backticks. Thus the content is interpolated |
| 2470 | as though it were double quoted and then executed via the shell, with |
| 2471 | the results of the execution returned. |
| 2472 | |
| 2473 | print << `EOC`; # execute command and get results |
| 2474 | echo hi there |
| 2475 | EOC |
| 2476 | |
| 2477 | =back |
| 2478 | |
| 2479 | It is possible to stack multiple here-docs in a row: |
| 2480 | |
| 2481 | print <<"foo", <<"bar"; # you can stack them |
| 2482 | I said foo. |
| 2483 | foo |
| 2484 | I said bar. |
| 2485 | bar |
| 2486 | |
| 2487 | myfunc(<< "THIS", 23, <<'THAT'); |
| 2488 | Here's a line |
| 2489 | or two. |
| 2490 | THIS |
| 2491 | and here's another. |
| 2492 | THAT |
| 2493 | |
| 2494 | Just don't forget that you have to put a semicolon on the end |
| 2495 | to finish the statement, as Perl doesn't know you're not going to |
| 2496 | try to do this: |
| 2497 | |
| 2498 | print <<ABC |
| 2499 | 179231 |
| 2500 | ABC |
| 2501 | + 20; |
| 2502 | |
| 2503 | If you want to remove the line terminator from your here-docs, |
| 2504 | use C<chomp()>. |
| 2505 | |
| 2506 | chomp($string = <<'END'); |
| 2507 | This is a string. |
| 2508 | END |
| 2509 | |
| 2510 | If you want your here-docs to be indented with the rest of the code, |
| 2511 | you'll need to remove leading whitespace from each line manually: |
| 2512 | |
| 2513 | ($quote = <<'FINIS') =~ s/^\s+//gm; |
| 2514 | The Road goes ever on and on, |
| 2515 | down from the door where it began. |
| 2516 | FINIS |
| 2517 | |
| 2518 | If you use a here-doc within a delimited construct, such as in C<s///eg>, |
| 2519 | the quoted material must still come on the line following the |
| 2520 | C<<< <<FOO >>> marker, which means it may be inside the delimited |
| 2521 | construct: |
| 2522 | |
| 2523 | s/this/<<E . 'that' |
| 2524 | the other |
| 2525 | E |
| 2526 | . 'more '/eg; |
| 2527 | |
| 2528 | It works this way as of Perl 5.18. Historically, it was inconsistent, and |
| 2529 | you would have to write |
| 2530 | |
| 2531 | s/this/<<E . 'that' |
| 2532 | . 'more '/eg; |
| 2533 | the other |
| 2534 | E |
| 2535 | |
| 2536 | outside of string evals. |
| 2537 | |
| 2538 | Additionally, quoting rules for the end-of-string identifier are |
| 2539 | unrelated to Perl's quoting rules. C<q()>, C<qq()>, and the like are not |
| 2540 | supported in place of C<''> and C<"">, and the only interpolation is for |
| 2541 | backslashing the quoting character: |
| 2542 | |
| 2543 | print << "abc\"def"; |
| 2544 | testing... |
| 2545 | abc"def |
| 2546 | |
| 2547 | Finally, quoted strings cannot span multiple lines. The general rule is |
| 2548 | that the identifier must be a string literal. Stick with that, and you |
| 2549 | should be safe. |
| 2550 | |
| 2551 | =back |
| 2552 | |
| 2553 | =head2 Gory details of parsing quoted constructs |
| 2554 | X<quote, gory details> |
| 2555 | |
| 2556 | When presented with something that might have several different |
| 2557 | interpretations, Perl uses the B<DWIM> (that's "Do What I Mean") |
| 2558 | principle to pick the most probable interpretation. This strategy |
| 2559 | is so successful that Perl programmers often do not suspect the |
| 2560 | ambivalence of what they write. But from time to time, Perl's |
| 2561 | notions differ substantially from what the author honestly meant. |
| 2562 | |
| 2563 | This section hopes to clarify how Perl handles quoted constructs. |
| 2564 | Although the most common reason to learn this is to unravel labyrinthine |
| 2565 | regular expressions, because the initial steps of parsing are the |
| 2566 | same for all quoting operators, they are all discussed together. |
| 2567 | |
| 2568 | The most important Perl parsing rule is the first one discussed |
| 2569 | below: when processing a quoted construct, Perl first finds the end |
| 2570 | of that construct, then interprets its contents. If you understand |
| 2571 | this rule, you may skip the rest of this section on the first |
| 2572 | reading. The other rules are likely to contradict the user's |
| 2573 | expectations much less frequently than this first one. |
| 2574 | |
| 2575 | Some passes discussed below are performed concurrently, but because |
| 2576 | their results are the same, we consider them individually. For different |
| 2577 | quoting constructs, Perl performs different numbers of passes, from |
| 2578 | one to four, but these passes are always performed in the same order. |
| 2579 | |
| 2580 | =over 4 |
| 2581 | |
| 2582 | =item Finding the end |
| 2583 | |
| 2584 | The first pass is finding the end of the quoted construct, where |
| 2585 | the information about the delimiters is used in parsing. |
| 2586 | During this search, text between the starting and ending delimiters |
| 2587 | is copied to a safe location. The text copied gets delimiter-independent. |
| 2588 | |
| 2589 | If the construct is a here-doc, the ending delimiter is a line |
| 2590 | that has a terminating string as the content. Therefore C<<<EOF> is |
| 2591 | terminated by C<EOF> immediately followed by C<"\n"> and starting |
| 2592 | from the first column of the terminating line. |
| 2593 | When searching for the terminating line of a here-doc, nothing |
| 2594 | is skipped. In other words, lines after the here-doc syntax |
| 2595 | are compared with the terminating string line by line. |
| 2596 | |
| 2597 | For the constructs except here-docs, single characters are used as starting |
| 2598 | and ending delimiters. If the starting delimiter is an opening punctuation |
| 2599 | (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the |
| 2600 | corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>). |
| 2601 | If the starting delimiter is an unpaired character like C</> or a closing |
| 2602 | punctuation, the ending delimiter is same as the starting delimiter. |
| 2603 | Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates |
| 2604 | both C<qq[]> and C<qq]]> constructs. |
| 2605 | |
| 2606 | When searching for single-character delimiters, escaped delimiters |
| 2607 | and C<\\> are skipped. For example, while searching for terminating C</>, |
| 2608 | combinations of C<\\> and C<\/> are skipped. If the delimiters are |
| 2609 | bracketing, nested pairs are also skipped. For example, while searching |
| 2610 | for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>, |
| 2611 | and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well. |
| 2612 | However, when backslashes are used as the delimiters (like C<qq\\> and |
| 2613 | C<tr\\\>), nothing is skipped. |
| 2614 | During the search for the end, backslashes that escape delimiters or |
| 2615 | other backslashes are removed (exactly speaking, they are not copied to the |
| 2616 | safe location). |
| 2617 | |
| 2618 | For constructs with three-part delimiters (C<s///>, C<y///>, and |
| 2619 | C<tr///>), the search is repeated once more. |
| 2620 | If the first delimiter is not an opening punctuation, the three delimiters must |
| 2621 | be the same, such as C<s!!!> and C<tr)))>, |
| 2622 | in which case the second delimiter |
| 2623 | terminates the left part and starts the right part at once. |
| 2624 | If the left part is delimited by bracketing punctuation (that is C<()>, |
| 2625 | C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of |
| 2626 | delimiters such as C<s(){}> and C<tr[]//>. In these cases, whitespace |
| 2627 | and comments are allowed between the two parts, though the comment must follow |
| 2628 | at least one whitespace character; otherwise a character expected as the |
| 2629 | start of the comment may be regarded as the starting delimiter of the right part. |
| 2630 | |
| 2631 | During this search no attention is paid to the semantics of the construct. |
| 2632 | Thus: |
| 2633 | |
| 2634 | "$hash{"$foo/$bar"}" |
| 2635 | |
| 2636 | or: |
| 2637 | |
| 2638 | m/ |
| 2639 | bar # NOT a comment, this slash / terminated m//! |
| 2640 | /x |
| 2641 | |
| 2642 | do not form legal quoted expressions. The quoted part ends on the |
| 2643 | first C<"> and C</>, and the rest happens to be a syntax error. |
| 2644 | Because the slash that terminated C<m//> was followed by a C<SPACE>, |
| 2645 | the example above is not C<m//x>, but rather C<m//> with no C</x> |
| 2646 | modifier. So the embedded C<#> is interpreted as a literal C<#>. |
| 2647 | |
| 2648 | Also no attention is paid to C<\c\> (multichar control char syntax) during |
| 2649 | this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part |
| 2650 | of C<\/>, and the following C</> is not recognized as a delimiter. |
| 2651 | Instead, use C<\034> or C<\x1c> at the end of quoted constructs. |
| 2652 | |
| 2653 | =item Interpolation |
| 2654 | X<interpolation> |
| 2655 | |
| 2656 | The next step is interpolation in the text obtained, which is now |
| 2657 | delimiter-independent. There are multiple cases. |
| 2658 | |
| 2659 | =over 4 |
| 2660 | |
| 2661 | =item C<<<'EOF'> |
| 2662 | |
| 2663 | No interpolation is performed. |
| 2664 | Note that the combination C<\\> is left intact, since escaped delimiters |
| 2665 | are not available for here-docs. |
| 2666 | |
| 2667 | =item C<m''>, the pattern of C<s'''> |
| 2668 | |
| 2669 | No interpolation is performed at this stage. |
| 2670 | Any backslashed sequences including C<\\> are treated at the stage |
| 2671 | to L</"parsing regular expressions">. |
| 2672 | |
| 2673 | =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''> |
| 2674 | |
| 2675 | The only interpolation is removal of C<\> from pairs of C<\\>. |
| 2676 | Therefore C<-> in C<tr'''> and C<y'''> is treated literally |
| 2677 | as a hyphen and no character range is available. |
| 2678 | C<\1> in the replacement of C<s'''> does not work as C<$1>. |
| 2679 | |
| 2680 | =item C<tr///>, C<y///> |
| 2681 | |
| 2682 | No variable interpolation occurs. String modifying combinations for |
| 2683 | case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized. |
| 2684 | The other escape sequences such as C<\200> and C<\t> and backslashed |
| 2685 | characters such as C<\\> and C<\-> are converted to appropriate literals. |
| 2686 | The character C<-> is treated specially and therefore C<\-> is treated |
| 2687 | as a literal C<->. |
| 2688 | |
| 2689 | =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF"> |
| 2690 | |
| 2691 | C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are |
| 2692 | converted to corresponding Perl constructs. Thus, C<"$foo\Qbaz$bar"> |
| 2693 | is converted to C<$foo . (quotemeta("baz" . $bar))> internally. |
| 2694 | The other escape sequences such as C<\200> and C<\t> and backslashed |
| 2695 | characters such as C<\\> and C<\-> are replaced with appropriate |
| 2696 | expansions. |
| 2697 | |
| 2698 | Let it be stressed that I<whatever falls between C<\Q> and C<\E>> |
| 2699 | is interpolated in the usual way. Something like C<"\Q\\E"> has |
| 2700 | no C<\E> inside. Instead, it has C<\Q>, C<\\>, and C<E>, so the |
| 2701 | result is the same as for C<"\\\\E">. As a general rule, backslashes |
| 2702 | between C<\Q> and C<\E> may lead to counterintuitive results. So, |
| 2703 | C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same |
| 2704 | as C<"\\\t"> (since TAB is not alphanumeric). Note also that: |
| 2705 | |
| 2706 | $str = '\t'; |
| 2707 | return "\Q$str"; |
| 2708 | |
| 2709 | may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">. |
| 2710 | |
| 2711 | Interpolated scalars and arrays are converted internally to the C<join> and |
| 2712 | C<.> catenation operations. Thus, C<"$foo XXX '@arr'"> becomes: |
| 2713 | |
| 2714 | $foo . " XXX '" . (join $", @arr) . "'"; |
| 2715 | |
| 2716 | All operations above are performed simultaneously, left to right. |
| 2717 | |
| 2718 | Because the result of C<"\Q STRING \E"> has all metacharacters |
| 2719 | quoted, there is no way to insert a literal C<$> or C<@> inside a |
| 2720 | C<\Q\E> pair. If protected by C<\>, C<$> will be quoted to became |
| 2721 | C<"\\\$">; if not, it is interpreted as the start of an interpolated |
| 2722 | scalar. |
| 2723 | |
| 2724 | Note also that the interpolation code needs to make a decision on |
| 2725 | where the interpolated scalar ends. For instance, whether |
| 2726 | C<< "a $x -> {c}" >> really means: |
| 2727 | |
| 2728 | "a " . $x . " -> {c}"; |
| 2729 | |
| 2730 | or: |
| 2731 | |
| 2732 | "a " . $x -> {c}; |
| 2733 | |
| 2734 | Most of the time, the longest possible text that does not include |
| 2735 | spaces between components and which contains matching braces or |
| 2736 | brackets. because the outcome may be determined by voting based |
| 2737 | on heuristic estimators, the result is not strictly predictable. |
| 2738 | Fortunately, it's usually correct for ambiguous cases. |
| 2739 | |
| 2740 | =item the replacement of C<s///> |
| 2741 | |
| 2742 | Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation |
| 2743 | happens as with C<qq//> constructs. |
| 2744 | |
| 2745 | It is at this step that C<\1> is begrudgingly converted to C<$1> in |
| 2746 | the replacement text of C<s///>, in order to correct the incorrigible |
| 2747 | I<sed> hackers who haven't picked up the saner idiom yet. A warning |
| 2748 | is emitted if the C<use warnings> pragma or the B<-w> command-line flag |
| 2749 | (that is, the C<$^W> variable) was set. |
| 2750 | |
| 2751 | =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>, |
| 2752 | |
| 2753 | Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>, |
| 2754 | and interpolation happens (almost) as with C<qq//> constructs. |
| 2755 | |
| 2756 | Processing of C<\N{...}> is also done here, and compiled into an intermediate |
| 2757 | form for the regex compiler. (This is because, as mentioned below, the regex |
| 2758 | compilation may be done at execution time, and C<\N{...}> is a compile-time |
| 2759 | construct.) |
| 2760 | |
| 2761 | However any other combinations of C<\> followed by a character |
| 2762 | are not substituted but only skipped, in order to parse them |
| 2763 | as regular expressions at the following step. |
| 2764 | As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly |
| 2765 | treated as an array symbol (for example C<@foo>), |
| 2766 | even though the same text in C<qq//> gives interpolation of C<\c@>. |
| 2767 | |
| 2768 | Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control |
| 2769 | back to the perl parser, in a similar way that an interpolated array |
| 2770 | subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be. |
| 2771 | |
| 2772 | Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and |
| 2773 | a C<#>-comment in a C<//x>-regular expression, no processing is |
| 2774 | performed whatsoever. This is the first step at which the presence |
| 2775 | of the C<//x> modifier is relevant. |
| 2776 | |
| 2777 | Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+> |
| 2778 | and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are |
| 2779 | voted (by several different estimators) to be either an array element |
| 2780 | or C<$var> followed by an RE alternative. This is where the notation |
| 2781 | C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as |
| 2782 | array element C<-9>, not as a regular expression from the variable |
| 2783 | C<$arr> followed by a digit, which would be the interpretation of |
| 2784 | C</$arr[0-9]/>. Since voting among different estimators may occur, |
| 2785 | the result is not predictable. |
| 2786 | |
| 2787 | The lack of processing of C<\\> creates specific restrictions on |
| 2788 | the post-processed text. If the delimiter is C</>, one cannot get |
| 2789 | the combination C<\/> into the result of this step. C</> will |
| 2790 | finish the regular expression, C<\/> will be stripped to C</> on |
| 2791 | the previous step, and C<\\/> will be left as is. Because C</> is |
| 2792 | equivalent to C<\/> inside a regular expression, this does not |
| 2793 | matter unless the delimiter happens to be character special to the |
| 2794 | RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an |
| 2795 | alphanumeric char, as in: |
| 2796 | |
| 2797 | m m ^ a \s* b mmx; |
| 2798 | |
| 2799 | In the RE above, which is intentionally obfuscated for illustration, the |
| 2800 | delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the |
| 2801 | RE is the same as for C<m/ ^ a \s* b /mx>. There's more than one |
| 2802 | reason you're encouraged to restrict your delimiters to non-alphanumeric, |
| 2803 | non-whitespace choices. |
| 2804 | |
| 2805 | =back |
| 2806 | |
| 2807 | This step is the last one for all constructs except regular expressions, |
| 2808 | which are processed further. |
| 2809 | |
| 2810 | =item parsing regular expressions |
| 2811 | X<regexp, parse> |
| 2812 | |
| 2813 | Previous steps were performed during the compilation of Perl code, |
| 2814 | but this one happens at run time, although it may be optimized to |
| 2815 | be calculated at compile time if appropriate. After preprocessing |
| 2816 | described above, and possibly after evaluation if concatenation, |
| 2817 | joining, casing translation, or metaquoting are involved, the |
| 2818 | resulting I<string> is passed to the RE engine for compilation. |
| 2819 | |
| 2820 | Whatever happens in the RE engine might be better discussed in L<perlre>, |
| 2821 | but for the sake of continuity, we shall do so here. |
| 2822 | |
| 2823 | This is another step where the presence of the C<//x> modifier is |
| 2824 | relevant. The RE engine scans the string from left to right and |
| 2825 | converts it to a finite automaton. |
| 2826 | |
| 2827 | Backslashed characters are either replaced with corresponding |
| 2828 | literal strings (as with C<\{>), or else they generate special nodes |
| 2829 | in the finite automaton (as with C<\b>). Characters special to the |
| 2830 | RE engine (such as C<|>) generate corresponding nodes or groups of |
| 2831 | nodes. C<(?#...)> comments are ignored. All the rest is either |
| 2832 | converted to literal strings to match, or else is ignored (as is |
| 2833 | whitespace and C<#>-style comments if C<//x> is present). |
| 2834 | |
| 2835 | Parsing of the bracketed character class construct, C<[...]>, is |
| 2836 | rather different than the rule used for the rest of the pattern. |
| 2837 | The terminator of this construct is found using the same rules as |
| 2838 | for finding the terminator of a C<{}>-delimited construct, the only |
| 2839 | exception being that C<]> immediately following C<[> is treated as |
| 2840 | though preceded by a backslash. |
| 2841 | |
| 2842 | The terminator of runtime C<(?{...})> is found by temporarily switching |
| 2843 | control to the perl parser, which should stop at the point where the |
| 2844 | logically balancing terminating C<}> is found. |
| 2845 | |
| 2846 | It is possible to inspect both the string given to RE engine and the |
| 2847 | resulting finite automaton. See the arguments C<debug>/C<debugcolor> |
| 2848 | in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line |
| 2849 | switch documented in L<perlrun/"Command Switches">. |
| 2850 | |
| 2851 | =item Optimization of regular expressions |
| 2852 | X<regexp, optimization> |
| 2853 | |
| 2854 | This step is listed for completeness only. Since it does not change |
| 2855 | semantics, details of this step are not documented and are subject |
| 2856 | to change without notice. This step is performed over the finite |
| 2857 | automaton that was generated during the previous pass. |
| 2858 | |
| 2859 | It is at this stage that C<split()> silently optimizes C</^/> to |
| 2860 | mean C</^/m>. |
| 2861 | |
| 2862 | =back |
| 2863 | |
| 2864 | =head2 I/O Operators |
| 2865 | X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle> |
| 2866 | X<< <> >> X<< <<>> >> X<@ARGV> |
| 2867 | |
| 2868 | There are several I/O operators you should know about. |
| 2869 | |
| 2870 | A string enclosed by backticks (grave accents) first undergoes |
| 2871 | double-quote interpolation. It is then interpreted as an external |
| 2872 | command, and the output of that command is the value of the |
| 2873 | backtick string, like in a shell. In scalar context, a single string |
| 2874 | consisting of all output is returned. In list context, a list of |
| 2875 | values is returned, one per line of output. (You can set C<$/> to use |
| 2876 | a different line terminator.) The command is executed each time the |
| 2877 | pseudo-literal is evaluated. The status value of the command is |
| 2878 | returned in C<$?> (see L<perlvar> for the interpretation of C<$?>). |
| 2879 | Unlike in B<csh>, no translation is done on the return data--newlines |
| 2880 | remain newlines. Unlike in any of the shells, single quotes do not |
| 2881 | hide variable names in the command from interpretation. To pass a |
| 2882 | literal dollar-sign through to the shell you need to hide it with a |
| 2883 | backslash. The generalized form of backticks is C<qx//>. (Because |
| 2884 | backticks always undergo shell expansion as well, see L<perlsec> for |
| 2885 | security concerns.) |
| 2886 | X<qx> X<`> X<``> X<backtick> X<glob> |
| 2887 | |
| 2888 | In scalar context, evaluating a filehandle in angle brackets yields |
| 2889 | the next line from that file (the newline, if any, included), or |
| 2890 | C<undef> at end-of-file or on error. When C<$/> is set to C<undef> |
| 2891 | (sometimes known as file-slurp mode) and the file is empty, it |
| 2892 | returns C<''> the first time, followed by C<undef> subsequently. |
| 2893 | |
| 2894 | Ordinarily you must assign the returned value to a variable, but |
| 2895 | there is one situation where an automatic assignment happens. If |
| 2896 | and only if the input symbol is the only thing inside the conditional |
| 2897 | of a C<while> statement (even if disguised as a C<for(;;)> loop), |
| 2898 | the value is automatically assigned to the global variable $_, |
| 2899 | destroying whatever was there previously. (This may seem like an |
| 2900 | odd thing to you, but you'll use the construct in almost every Perl |
| 2901 | script you write.) The $_ variable is not implicitly localized. |
| 2902 | You'll have to put a C<local $_;> before the loop if you want that |
| 2903 | to happen. |
| 2904 | |
| 2905 | The following lines are equivalent: |
| 2906 | |
| 2907 | while (defined($_ = <STDIN>)) { print; } |
| 2908 | while ($_ = <STDIN>) { print; } |
| 2909 | while (<STDIN>) { print; } |
| 2910 | for (;<STDIN>;) { print; } |
| 2911 | print while defined($_ = <STDIN>); |
| 2912 | print while ($_ = <STDIN>); |
| 2913 | print while <STDIN>; |
| 2914 | |
| 2915 | This also behaves similarly, but assigns to a lexical variable |
| 2916 | instead of to C<$_>: |
| 2917 | |
| 2918 | while (my $line = <STDIN>) { print $line } |
| 2919 | |
| 2920 | In these loop constructs, the assigned value (whether assignment |
| 2921 | is automatic or explicit) is then tested to see whether it is |
| 2922 | defined. The defined test avoids problems where the line has a string |
| 2923 | value that would be treated as false by Perl; for example a "" or |
| 2924 | a "0" with no trailing newline. If you really mean for such values |
| 2925 | to terminate the loop, they should be tested for explicitly: |
| 2926 | |
| 2927 | while (($_ = <STDIN>) ne '0') { ... } |
| 2928 | while (<STDIN>) { last unless $_; ... } |
| 2929 | |
| 2930 | In other boolean contexts, C<< <FILEHANDLE> >> without an |
| 2931 | explicit C<defined> test or comparison elicits a warning if the |
| 2932 | C<use warnings> pragma or the B<-w> |
| 2933 | command-line switch (the C<$^W> variable) is in effect. |
| 2934 | |
| 2935 | The filehandles STDIN, STDOUT, and STDERR are predefined. (The |
| 2936 | filehandles C<stdin>, C<stdout>, and C<stderr> will also work except |
| 2937 | in packages, where they would be interpreted as local identifiers |
| 2938 | rather than global.) Additional filehandles may be created with |
| 2939 | the open() function, amongst others. See L<perlopentut> and |
| 2940 | L<perlfunc/open> for details on this. |
| 2941 | X<stdin> X<stdout> X<sterr> |
| 2942 | |
| 2943 | If a <FILEHANDLE> is used in a context that is looking for |
| 2944 | a list, a list comprising all input lines is returned, one line per |
| 2945 | list element. It's easy to grow to a rather large data space this |
| 2946 | way, so use with care. |
| 2947 | |
| 2948 | <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>. |
| 2949 | See L<perlfunc/readline>. |
| 2950 | |
| 2951 | The null filehandle <> is special: it can be used to emulate the |
| 2952 | behavior of B<sed> and B<awk>, and any other Unix filter program |
| 2953 | that takes a list of filenames, doing the same to each line |
| 2954 | of input from all of them. Input from <> comes either from |
| 2955 | standard input, or from each file listed on the command line. Here's |
| 2956 | how it works: the first time <> is evaluated, the @ARGV array is |
| 2957 | checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened |
| 2958 | gives you standard input. The @ARGV array is then processed as a list |
| 2959 | of filenames. The loop |
| 2960 | |
| 2961 | while (<>) { |
| 2962 | ... # code for each line |
| 2963 | } |
| 2964 | |
| 2965 | is equivalent to the following Perl-like pseudo code: |
| 2966 | |
| 2967 | unshift(@ARGV, '-') unless @ARGV; |
| 2968 | while ($ARGV = shift) { |
| 2969 | open(ARGV, $ARGV); |
| 2970 | while (<ARGV>) { |
| 2971 | ... # code for each line |
| 2972 | } |
| 2973 | } |
| 2974 | |
| 2975 | except that it isn't so cumbersome to say, and will actually work. |
| 2976 | It really does shift the @ARGV array and put the current filename |
| 2977 | into the $ARGV variable. It also uses filehandle I<ARGV> |
| 2978 | internally. <> is just a synonym for <ARGV>, which |
| 2979 | is magical. (The pseudo code above doesn't work because it treats |
| 2980 | <ARGV> as non-magical.) |
| 2981 | |
| 2982 | Since the null filehandle uses the two argument form of L<perlfunc/open> |
| 2983 | it interprets special characters, so if you have a script like this: |
| 2984 | |
| 2985 | while (<>) { |
| 2986 | print; |
| 2987 | } |
| 2988 | |
| 2989 | and call it with C<perl dangerous.pl 'rm -rfv *|'>, it actually opens a |
| 2990 | pipe, executes the C<rm> command and reads C<rm>'s output from that pipe. |
| 2991 | If you want all items in C<@ARGV> to be interpreted as file names, you |
| 2992 | can use the module C<ARGV::readonly> from CPAN, or use the double bracket: |
| 2993 | |
| 2994 | while (<<>>) { |
| 2995 | print; |
| 2996 | } |
| 2997 | |
| 2998 | Using double angle brackets inside of a while causes the open to use the |
| 2999 | three argument form (with the second argument being C<< < >>), so all |
| 3000 | arguments in ARGV are treated as literal filenames (including "-"). |
| 3001 | (Note that for convenience, if you use C<< <<>> >> and if @ARGV is |
| 3002 | empty, it will still read from the standard input.) |
| 3003 | |
| 3004 | You can modify @ARGV before the first <> as long as the array ends up |
| 3005 | containing the list of filenames you really want. Line numbers (C<$.>) |
| 3006 | continue as though the input were one big happy file. See the example |
| 3007 | in L<perlfunc/eof> for how to reset line numbers on each file. |
| 3008 | |
| 3009 | If you want to set @ARGV to your own list of files, go right ahead. |
| 3010 | This sets @ARGV to all plain text files if no @ARGV was given: |
| 3011 | |
| 3012 | @ARGV = grep { -f && -T } glob('*') unless @ARGV; |
| 3013 | |
| 3014 | You can even set them to pipe commands. For example, this automatically |
| 3015 | filters compressed arguments through B<gzip>: |
| 3016 | |
| 3017 | @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV; |
| 3018 | |
| 3019 | If you want to pass switches into your script, you can use one of the |
| 3020 | Getopts modules or put a loop on the front like this: |
| 3021 | |
| 3022 | while ($_ = $ARGV[0], /^-/) { |
| 3023 | shift; |
| 3024 | last if /^--$/; |
| 3025 | if (/^-D(.*)/) { $debug = $1 } |
| 3026 | if (/^-v/) { $verbose++ } |
| 3027 | # ... # other switches |
| 3028 | } |
| 3029 | |
| 3030 | while (<>) { |
| 3031 | # ... # code for each line |
| 3032 | } |
| 3033 | |
| 3034 | The <> symbol will return C<undef> for end-of-file only once. |
| 3035 | If you call it again after this, it will assume you are processing another |
| 3036 | @ARGV list, and if you haven't set @ARGV, will read input from STDIN. |
| 3037 | |
| 3038 | If what the angle brackets contain is a simple scalar variable (for example, |
| 3039 | <$foo>), then that variable contains the name of the |
| 3040 | filehandle to input from, or its typeglob, or a reference to the |
| 3041 | same. For example: |
| 3042 | |
| 3043 | $fh = \*STDIN; |
| 3044 | $line = <$fh>; |
| 3045 | |
| 3046 | If what's within the angle brackets is neither a filehandle nor a simple |
| 3047 | scalar variable containing a filehandle name, typeglob, or typeglob |
| 3048 | reference, it is interpreted as a filename pattern to be globbed, and |
| 3049 | either a list of filenames or the next filename in the list is returned, |
| 3050 | depending on context. This distinction is determined on syntactic |
| 3051 | grounds alone. That means C<< <$x> >> is always a readline() from |
| 3052 | an indirect handle, but C<< <$hash{key}> >> is always a glob(). |
| 3053 | That's because $x is a simple scalar variable, but C<$hash{key}> is |
| 3054 | not--it's a hash element. Even C<< <$x > >> (note the extra space) |
| 3055 | is treated as C<glob("$x ")>, not C<readline($x)>. |
| 3056 | |
| 3057 | One level of double-quote interpretation is done first, but you can't |
| 3058 | say C<< <$foo> >> because that's an indirect filehandle as explained |
| 3059 | in the previous paragraph. (In older versions of Perl, programmers |
| 3060 | would insert curly brackets to force interpretation as a filename glob: |
| 3061 | C<< <${foo}> >>. These days, it's considered cleaner to call the |
| 3062 | internal function directly as C<glob($foo)>, which is probably the right |
| 3063 | way to have done it in the first place.) For example: |
| 3064 | |
| 3065 | while (<*.c>) { |
| 3066 | chmod 0644, $_; |
| 3067 | } |
| 3068 | |
| 3069 | is roughly equivalent to: |
| 3070 | |
| 3071 | open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|"); |
| 3072 | while (<FOO>) { |
| 3073 | chomp; |
| 3074 | chmod 0644, $_; |
| 3075 | } |
| 3076 | |
| 3077 | except that the globbing is actually done internally using the standard |
| 3078 | C<File::Glob> extension. Of course, the shortest way to do the above is: |
| 3079 | |
| 3080 | chmod 0644, <*.c>; |
| 3081 | |
| 3082 | A (file)glob evaluates its (embedded) argument only when it is |
| 3083 | starting a new list. All values must be read before it will start |
| 3084 | over. In list context, this isn't important because you automatically |
| 3085 | get them all anyway. However, in scalar context the operator returns |
| 3086 | the next value each time it's called, or C<undef> when the list has |
| 3087 | run out. As with filehandle reads, an automatic C<defined> is |
| 3088 | generated when the glob occurs in the test part of a C<while>, |
| 3089 | because legal glob returns (for example, |
| 3090 | a file called F<0>) would otherwise |
| 3091 | terminate the loop. Again, C<undef> is returned only once. So if |
| 3092 | you're expecting a single value from a glob, it is much better to |
| 3093 | say |
| 3094 | |
| 3095 | ($file) = <blurch*>; |
| 3096 | |
| 3097 | than |
| 3098 | |
| 3099 | $file = <blurch*>; |
| 3100 | |
| 3101 | because the latter will alternate between returning a filename and |
| 3102 | returning false. |
| 3103 | |
| 3104 | If you're trying to do variable interpolation, it's definitely better |
| 3105 | to use the glob() function, because the older notation can cause people |
| 3106 | to become confused with the indirect filehandle notation. |
| 3107 | |
| 3108 | @files = glob("$dir/*.[ch]"); |
| 3109 | @files = glob($files[$i]); |
| 3110 | |
| 3111 | =head2 Constant Folding |
| 3112 | X<constant folding> X<folding> |
| 3113 | |
| 3114 | Like C, Perl does a certain amount of expression evaluation at |
| 3115 | compile time whenever it determines that all arguments to an |
| 3116 | operator are static and have no side effects. In particular, string |
| 3117 | concatenation happens at compile time between literals that don't do |
| 3118 | variable substitution. Backslash interpolation also happens at |
| 3119 | compile time. You can say |
| 3120 | |
| 3121 | 'Now is the time for all' |
| 3122 | . "\n" |
| 3123 | . 'good men to come to.' |
| 3124 | |
| 3125 | and this all reduces to one string internally. Likewise, if |
| 3126 | you say |
| 3127 | |
| 3128 | foreach $file (@filenames) { |
| 3129 | if (-s $file > 5 + 100 * 2**16) { } |
| 3130 | } |
| 3131 | |
| 3132 | the compiler precomputes the number which that expression |
| 3133 | represents so that the interpreter won't have to. |
| 3134 | |
| 3135 | =head2 No-ops |
| 3136 | X<no-op> X<nop> |
| 3137 | |
| 3138 | Perl doesn't officially have a no-op operator, but the bare constants |
| 3139 | C<0> and C<1> are special-cased not to produce a warning in void |
| 3140 | context, so you can for example safely do |
| 3141 | |
| 3142 | 1 while foo(); |
| 3143 | |
| 3144 | =head2 Bitwise String Operators |
| 3145 | X<operator, bitwise, string> |
| 3146 | |
| 3147 | Bitstrings of any size may be manipulated by the bitwise operators |
| 3148 | (C<~ | & ^>). |
| 3149 | |
| 3150 | If the operands to a binary bitwise op are strings of different |
| 3151 | sizes, B<|> and B<^> ops act as though the shorter operand had |
| 3152 | additional zero bits on the right, while the B<&> op acts as though |
| 3153 | the longer operand were truncated to the length of the shorter. |
| 3154 | The granularity for such extension or truncation is one or more |
| 3155 | bytes. |
| 3156 | |
| 3157 | # ASCII-based examples |
| 3158 | print "j p \n" ^ " a h"; # prints "JAPH\n" |
| 3159 | print "JA" | " ph\n"; # prints "japh\n" |
| 3160 | print "japh\nJunk" & '_____'; # prints "JAPH\n"; |
| 3161 | print 'p N$' ^ " E<H\n"; # prints "Perl\n"; |
| 3162 | |
| 3163 | If you are intending to manipulate bitstrings, be certain that |
| 3164 | you're supplying bitstrings: If an operand is a number, that will imply |
| 3165 | a B<numeric> bitwise operation. You may explicitly show which type of |
| 3166 | operation you intend by using C<""> or C<0+>, as in the examples below. |
| 3167 | |
| 3168 | $foo = 150 | 105; # yields 255 (0x96 | 0x69 is 0xFF) |
| 3169 | $foo = '150' | 105; # yields 255 |
| 3170 | $foo = 150 | '105'; # yields 255 |
| 3171 | $foo = '150' | '105'; # yields string '155' (under ASCII) |
| 3172 | |
| 3173 | $baz = 0+$foo & 0+$bar; # both ops explicitly numeric |
| 3174 | $biz = "$foo" ^ "$bar"; # both ops explicitly stringy |
| 3175 | |
| 3176 | See L<perlfunc/vec> for information on how to manipulate individual bits |
| 3177 | in a bit vector. |
| 3178 | |
| 3179 | =head2 Integer Arithmetic |
| 3180 | X<integer> |
| 3181 | |
| 3182 | By default, Perl assumes that it must do most of its arithmetic in |
| 3183 | floating point. But by saying |
| 3184 | |
| 3185 | use integer; |
| 3186 | |
| 3187 | you may tell the compiler to use integer operations |
| 3188 | (see L<integer> for a detailed explanation) from here to the end of |
| 3189 | the enclosing BLOCK. An inner BLOCK may countermand this by saying |
| 3190 | |
| 3191 | no integer; |
| 3192 | |
| 3193 | which lasts until the end of that BLOCK. Note that this doesn't |
| 3194 | mean everything is an integer, merely that Perl will use integer |
| 3195 | operations for arithmetic, comparison, and bitwise operators. For |
| 3196 | example, even under C<use integer>, if you take the C<sqrt(2)>, you'll |
| 3197 | still get C<1.4142135623731> or so. |
| 3198 | |
| 3199 | Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<", |
| 3200 | and ">>") always produce integral results. (But see also |
| 3201 | L<Bitwise String Operators>.) However, C<use integer> still has meaning for |
| 3202 | them. By default, their results are interpreted as unsigned integers, but |
| 3203 | if C<use integer> is in effect, their results are interpreted |
| 3204 | as signed integers. For example, C<~0> usually evaluates to a large |
| 3205 | integral value. However, C<use integer; ~0> is C<-1> on two's-complement |
| 3206 | machines. |
| 3207 | |
| 3208 | =head2 Floating-point Arithmetic |
| 3209 | |
| 3210 | X<floating-point> X<floating point> X<float> X<real> |
| 3211 | |
| 3212 | While C<use integer> provides integer-only arithmetic, there is no |
| 3213 | analogous mechanism to provide automatic rounding or truncation to a |
| 3214 | certain number of decimal places. For rounding to a certain number |
| 3215 | of digits, sprintf() or printf() is usually the easiest route. |
| 3216 | See L<perlfaq4>. |
| 3217 | |
| 3218 | Floating-point numbers are only approximations to what a mathematician |
| 3219 | would call real numbers. There are infinitely more reals than floats, |
| 3220 | so some corners must be cut. For example: |
| 3221 | |
| 3222 | printf "%.20g\n", 123456789123456789; |
| 3223 | # produces 123456789123456784 |
| 3224 | |
| 3225 | Testing for exact floating-point equality or inequality is not a |
| 3226 | good idea. Here's a (relatively expensive) work-around to compare |
| 3227 | whether two floating-point numbers are equal to a particular number of |
| 3228 | decimal places. See Knuth, volume II, for a more robust treatment of |
| 3229 | this topic. |
| 3230 | |
| 3231 | sub fp_equal { |
| 3232 | my ($X, $Y, $POINTS) = @_; |
| 3233 | my ($tX, $tY); |
| 3234 | $tX = sprintf("%.${POINTS}g", $X); |
| 3235 | $tY = sprintf("%.${POINTS}g", $Y); |
| 3236 | return $tX eq $tY; |
| 3237 | } |
| 3238 | |
| 3239 | The POSIX module (part of the standard perl distribution) implements |
| 3240 | ceil(), floor(), and other mathematical and trigonometric functions. |
| 3241 | The Math::Complex module (part of the standard perl distribution) |
| 3242 | defines mathematical functions that work on both the reals and the |
| 3243 | imaginary numbers. Math::Complex not as efficient as POSIX, but |
| 3244 | POSIX can't work with complex numbers. |
| 3245 | |
| 3246 | Rounding in financial applications can have serious implications, and |
| 3247 | the rounding method used should be specified precisely. In these |
| 3248 | cases, it probably pays not to trust whichever system rounding is |
| 3249 | being used by Perl, but to instead implement the rounding function you |
| 3250 | need yourself. |
| 3251 | |
| 3252 | =head2 Bigger Numbers |
| 3253 | X<number, arbitrary precision> |
| 3254 | |
| 3255 | The standard C<Math::BigInt>, C<Math::BigRat>, and C<Math::BigFloat> modules, |
| 3256 | along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide |
| 3257 | variable-precision arithmetic and overloaded operators, although |
| 3258 | they're currently pretty slow. At the cost of some space and |
| 3259 | considerable speed, they avoid the normal pitfalls associated with |
| 3260 | limited-precision representations. |
| 3261 | |
| 3262 | use 5.010; |
| 3263 | use bigint; # easy interface to Math::BigInt |
| 3264 | $x = 123456789123456789; |
| 3265 | say $x * $x; |
| 3266 | +15241578780673678515622620750190521 |
| 3267 | |
| 3268 | Or with rationals: |
| 3269 | |
| 3270 | use 5.010; |
| 3271 | use bigrat; |
| 3272 | $x = 3/22; |
| 3273 | $y = 4/6; |
| 3274 | say "x/y is ", $x/$y; |
| 3275 | say "x*y is ", $x*$y; |
| 3276 | x/y is 9/44 |
| 3277 | x*y is 1/11 |
| 3278 | |
| 3279 | Several modules let you calculate with (bound only by memory and CPU time) |
| 3280 | unlimited or fixed precision. There |
| 3281 | are also some non-standard modules that |
| 3282 | provide faster implementations via external C libraries. |
| 3283 | |
| 3284 | Here is a short, but incomplete summary: |
| 3285 | |
| 3286 | Math::String treat string sequences like numbers |
| 3287 | Math::FixedPrecision calculate with a fixed precision |
| 3288 | Math::Currency for currency calculations |
| 3289 | Bit::Vector manipulate bit vectors fast (uses C) |
| 3290 | Math::BigIntFast Bit::Vector wrapper for big numbers |
| 3291 | Math::Pari provides access to the Pari C library |
| 3292 | Math::Cephes uses the external Cephes C library (no |
| 3293 | big numbers) |
| 3294 | Math::Cephes::Fraction fractions via the Cephes library |
| 3295 | Math::GMP another one using an external C library |
| 3296 | Math::GMPz an alternative interface to libgmp's big ints |
| 3297 | Math::GMPq an interface to libgmp's fraction numbers |
| 3298 | Math::GMPf an interface to libgmp's floating point numbers |
| 3299 | |
| 3300 | Choose wisely. |
| 3301 | |
| 3302 | =cut |