-#!./perl
-BEGIN { @INC = ('lib') }
-use Config;
+#!./perl -w
+BEGIN {
+ @INC = qw(lib);
+
+ # This needs to be at BEGIN time, before any use of Config
+ require './install_lib.pl';
+}
+use strict;
+
use Getopt::Long;
-use File::Find;
-require Cwd;
+require File::Path;
+use ExtUtils::Packlist;
+use Pod::Man;
+use vars qw(%opts $packlist);
+
+require './Porting/pod_lib.pl';
+my %man1 = (map {($_->[0], $_->[1])} @{get_pod_metadata()->{master}});
-umask 022;
+$ENV{SHELL} = 'sh' if $^O eq 'os2';
-$ver = $];
-$release = substr($ver,0,3); # Not used presently.
-$patchlevel = substr($ver,3,2);
+my $patchlevel = substr($],3,2);
die "Patchlevel of perl ($patchlevel)",
- "and patchlevel of config.sh ($Config{'PATCHLEVEL'}) don't match\n"
- if $patchlevel != $Config{'PATCHLEVEL'};
+ "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
+ if $patchlevel != $Config{'PERL_VERSION'};
-$usage =
+my $usage =
"Usage: installman --man1dir=/usr/wherever --man1ext=1
- --man3dir=/usr/wherever --man3ext=3
- --notify --help
+ --man3dir=/usr/wherever --man3ext=3
+ --notify --verbose --silent --help
Defaults are:
man1dir = $Config{'installman1dir'};
man1ext = $Config{'man1ext'};
man3dir = $Config{'installman3dir'};
man3ext = $Config{'man3ext'};
- --notify (or -n) just lists commands that would be executed.\n";
+ --notify (or -n) just lists commands that would be executed.
+ --verbose (or -V) report all progress.
+ --silent (or -S) be silent. Only report errors.\n";
-GetOptions( qw( man1dir=s man1ext=s man3dir=s man3ext=s notify help))
+GetOptions( \%opts,
+ qw( man1dir=s man1ext=s man3dir=s man3ext=s
+ destdir:s notify n help silent S verbose V))
|| die $usage;
+die $usage if $opts{help};
+$opts{destdir} //= '';
-# These are written funny to avoid -w typo warnings.
-$man1dir = defined($opt_man1dir) ? $opt_man1dir : $Config{'installman1dir'};
-$man1ext = defined($opt_man1ext) ? $opt_man1ext : $Config{'man1ext'};
-$man3dir = defined($opt_man3dir) ? $opt_man3dir : $Config{'installman3dir'};
-$man3ext = defined($opt_man3ext) ? $opt_man3ext : $Config{'man3ext'};
-
-$notify = defined($opt_notify) ? $opt_notify : 0;
+foreach my $pre (qw(man1 man3)) {
+ $opts{"${pre}dir"} //= $opts{destdir} . $Config{"install${pre}dir"};
+ $opts{"${pre}ext"} //= $Config{"${pre}ext"};
+}
+$opts{silent} ||= $opts{S};
+$opts{notify} ||= $opts{n};
+$opts{verbose} ||= $opts{V} || $opts{notify};
#Sanity checks
--x "./perl" || warn "./perl not found! Have you run make?\n";
--d $Config{'installprivlib'}
+-x "./perl$Config{exe_ext}"
+ or warn "./perl$Config{exe_ext} not found! Have you run make?\n";
+-d "$opts{destdir}$Config{'installprivlib'}"
|| warn "Perl library directory $Config{'installprivlib'} not found.
Have you run make install?. (Installing anyway.)\n";
--x 't/TEST' || warn "WARNING: You've never run 'make test'!!!",
+-x "t/perl$Config{exe_ext}" || warn "WARNING: You've never run 'make test'!!!",
" (Installing anyway.)\n";
+$packlist = ExtUtils::Packlist->new("$opts{destdir}$Config{installarchlib}/.packlist");
+
# Install the main pod pages.
-runpod2man('pod', $man1dir, $man1ext);
+pod2man(\%man1, $opts{man1dir}, $opts{man1ext}, 'pod');
# Install the pods for library modules.
-runpod2man('lib', $man3dir, $man3ext);
-
-sub runpod2man {
- my($poddir, $mandir, $manext) = @_;
- my($builddir) = Cwd::getcwd();
-
- if ($mandir eq ' ' or $mandir eq '') {
- print STDERR "Skipping installation of $poddir man pages.\n";
- return;
- }
-
- chdir $poddir || die "Unable to cd to $poddir directory!\n$!\n";
-
- # We insist on using the current version of pod2man in case there
- # are enhancements or changes from previous installed versions.
- # The error message doesn't include the '..' because the user
- # won't be aware that we've chdir to $poddir.
- -x "../pod/pod2man" || die "Executable pod/pod2man not found.\n";
-
- # We want to be sure to use the current perl. We can't rely on
- # the installed perl because it might not be actually installed
- # yet. (The user may have set the $install* Configure variables
- # to point to some temporary home, from which the executable gets
- # installed by occult means.)
- $pod2man = "../perl -I ../lib ../pod/pod2man";
-
- &makedir($mandir);
- # Make a list of all the .pm and .pod files in the directory. We will
- # always run pod2man from the lib directory and feed it the full pathname
- # of the pod. This might be useful for pod2man someday.
- @modpods = ();
- find(\&lsmodpods, '.');
- foreach $mod (@modpods) {
- $manpage = $mod;
- # Convert name from File/Basename.pm to File::Basename.3 format,
- # if necessary.
- $manpage =~ s#\.p(m|od)$##;
- $manpage =~ s#/#::#g;
- $manpage = "${mandir}/${manpage}.${manext}";
- # Print $release $patchlevel stuff? or should pod2man do that?
- &cmd("$pod2man $mod > $manpage");
- }
- chdir "$builddir" || die "Unable to cd back to $builddir directory!\n$!\n";
+{
+ my $found = pods_to_install();
+ pod2man($found->{$_}, $opts{man3dir}, $opts{man3ext}, 'lib')
+ foreach qw(MODULE PRAGMA);
}
-sub lsmodpods {
- my $dir = $File::Find::dir;
- my $name = $File::Find::name;
- if (-f $_) {
- $name =~ s#^\./##;
- push(@modpods, $name) if ($name =~ /\.p(m|od)$/);
+# Install the pods embedded in the installed scripts
+my $has_man1dir = $opts{man1dir} ne '' && -d $opts{man1dir};
+my $fh = open_or_die('utils.lst');
+while (<$fh>) {
+ next if /^#/;
+ chomp;
+ my ($path, $leaf) = m|^(\S*/(\S+))|;
+ # Have we already installed the manpage for this? (eg perldoc, a2p)
+ next if $man1{$leaf};
+ pod2man({$leaf, $path}, $opts{man1dir}, $opts{man1ext});
+ if ($has_man1dir) {
+ if (my ($link) = m|#.*link\s*=\s*\S+/(\S+)|) {
+ my $old = "$opts{man1dir}/$leaf.$opts{man1ext}";
+ my $new = "$opts{man1dir}/$link.$opts{man1ext}";
+ unlink($new);
+ link($old, $new);
+ $old =~ s/^\Q$opts{destdir}\E// if $opts{destdir};
+ $new =~ s/^\Q$opts{destdir}\E// if $opts{destdir};
+ $packlist->{$new} = { from => $old, type => 'link' };
+ }
}
}
+close $fh or my_die("close 'utils.lst': $!");
-print STDERR " Installation complete\n";
-
-exit 0;
-
-
-###############################################################################
-# Utility subroutines from installperl
-
-sub cmd {
- local($cmd) = @_;
- print STDERR " $cmd\n";
- unless ($notify) {
- system $cmd;
- warn "Command failed!!!\n" if $?;
+sub pod2man {
+ my($modpods, $mandir, $manext, $where) = @_;
+ if ($mandir eq ' ' or $mandir eq '') {
+ if ($where) {
+ warn "Skipping installation of $where man pages.\n"
+ } else {
+ warn "Skipping installation of $_ man page.\n"
+ foreach values %$modpods;
+ }
+ return;
}
-}
-
-sub link {
- local($from,$to) = @_;
-
- print STDERR " ln $from $to\n";
- link($from,$to) || warn "Couldn't link $from to $to: $!\n" unless $notify;
-}
-
-sub chmod {
- local($mode,$name) = @_;
- printf STDERR " chmod %o %s\n", $mode, $name;
- chmod($mode,$name) || warn sprintf("Couldn't chmod %o %s: $!\n",$mode,$name)
- unless $notify;
-}
-
-sub makedir {
- local($dir) = @_;
- unless (-d $dir) {
- local($shortdir) = $dir;
+ if ($opts{verbose}) {
+ if ($where) {
+ print "installing from $where\n";
+ } else {
+ print "installing $_\n"
+ foreach sort keys %$modpods;
+ }
+ }
- $shortdir =~ s#(.*)/.*#$1#;
- &makedir($shortdir);
+ File::Path::mkpath($mandir, $opts{verbose}, 0777) unless $opts{notify};
+
+ foreach my $manpage (sort keys %$modpods) {
+ my $mod = $modpods->{$manpage};
+
+ # Skip files without pod docs
+ my $has_pod;
+ my $fh = open_or_die($mod);
+ while (my $line = <$fh>) {
+ if ($line =~ /^=head1\b/) {
+ ++$has_pod;
+ last;
+ }
+ }
+ close $fh or my_die("close '$mod': $!");
+ # Sadly it doesn't seem possible to re-use this handle for the call
+ # to parse_from_file() below, as Pod::Man relies on source_filename(),
+ # which Pod::Simple only sets accurately if it opens the file itself.
+
+ unless ($has_pod)
+ {
+ warn "no documentation in $mod\n";
+ next;
+ }
+
+ if ($^O eq 'os2' || $^O eq 'amigaos' || $^O eq 'uwin' || $^O eq 'cygwin') {
+ $manpage =~ s#::#.#g;
+ }
+ my $tmp = "${mandir}/${manpage}.tmp";
+ $manpage = "${mandir}/${manpage}.${manext}";
- print STDERR " mkdir $dir\n";
- mkdir($dir, 0777) || warn "Couldn't create $dir: $!\n" unless $notify;
+ my $parser = Pod::Man->new( section => $manext,
+ official=> 1,
+ center => 'Perl Programmers Reference Guide'
+ );
+ my $xmanpage = $manpage;
+ $xmanpage =~ s/^\Q$opts{'destdir'}\E// if $opts{'destdir'};
+ print " $xmanpage\n";
+ if (!$opts{notify} && $parser->parse_from_file($mod, $tmp)) {
+ if (-s $tmp) {
+ if (rename($tmp, $manpage)) {
+ $packlist->{$xmanpage} = { type => 'file' };
+ next;
+ }
+ }
+ unlink($tmp);
+ }
}
}
-sub samepath {
- local($p1, $p2) = @_;
- local($dev1, $ino1, $dev2, $ino2);
-
- if ($p1 ne $p2) {
- ($dev1, $ino1) = stat($p1);
- ($dev2, $ino2) = stat($p2);
- ($dev1 == $dev2 && $ino1 == $ino2);
- }
- else {
- 1;
+$packlist->write() unless $opts{notify};
+print " Installation complete\n" if $opts{verbose};
+
+sub rename {
+ my($from,$to) = @_;
+ if (-f $to and not unlink($to)) {
+ my($i);
+ for ($i = 1; $i < 50; $i++) {
+ last if CORE::rename($to, "$to.$i");
+ }
+ warn("Cannot rename to '$to.$i': $!"), return 0
+ if $i >= 50; # Give up!
}
+ link($from,$to) || return 0;
+ unlink($from);
}
+
+# Local variables:
+# cperl-indent-level: 4
+# indent-tabs-mode: nil
+# End:
+#
+# ex: set ts=8 sts=4 sw=4 et: