+sub generate_descrip_mms_1 {
+ local $Text::Wrap::columns = 150;
+ my $count = 0;
+ my @lines = map {"pod" . $count++ . " = $_"}
+ split /\n/, wrap('', '', join " ", map "[.lib.pods]$_.pod",
+ sort keys %Pods, keys %Readmepods);
+ @lines, "pod = " . join ' ', map {"\$(pod$_)"} 0 .. $count - 1;
+}
+
+sub generate_descrip_mms_2 {
+ map {<<"SNIP"}
+[.lib.pods]$_.pod : [.pod]$_.pod
+ \@ If F\$Search("[.lib]pods.dir").eqs."" Then Create/Directory [.lib.pods]
+ Copy/NoConfirm/Log \$(MMS\$SOURCE) [.lib.pods]
+SNIP
+ sort keys %Pods, keys %Readmepods;
+}
+
+sub generate_nmake_1 {
+ # XXX Fix this with File::Spec
+ (map {sprintf "\tcopy ..\\README.%-8s ..\\pod\\perl$_.pod\n", $_}
+ sort keys %Readmes),
+ (map {"\tcopy ..\\pod\\$Copies{$_} ..\\pod\\$_\n"} sort keys %Copies);
+}
+
+# This doesn't have a trailing newline
+sub generate_nmake_2 {
+ # Spot the special case
+ local $Text::Wrap::columns = 76;
+ my $line = wrap ("\t ", "\t ",
+ join " ", sort keys %Copies, keys %Generated,
+ map {"perl$_.pod"} keys %Readmes);
+ $line =~ s/$/ \\/mg;
+ $line =~ s/ \\$//;
+ $line;
+}
+
+sub generate_pod_mak {
+ my $variable = shift;
+ my @lines;
+ my $line = join "\\\n", "\U$variable = ",
+ map {"\t$_.$variable\t"} sort keys %Pods;
+ # Special case
+ $line =~ s/.*perltoc.html.*\n//m;
+ $line;
+}
+
+sub verify_contiguous {
+ my ($name, $content, $what) = @_;
+ my $sections = () = $content =~ m/\0+/g;
+ croak("$0: $name contains no $what") if $sections < 1;
+ croak("$0: $name contains discontiguous $what") if $sections > 1;
+}
+
+sub do_manifest {
+ my ($name, $prev) = @_;
+ my @manifest =
+ grep {! m!^pod/[^.]+\.pod.*!}
+ grep {! m!^README\.(\S+)! || $Ignore{$1}} split "\n", $prev;
+ join "\n", (
+ # Dictionary order - fold and handle non-word chars as nothing
+ map { $_->[0] }
+ sort { $a->[1] cmp $b->[1] || $a->[0] cmp $b->[0] }
+ map { my $f = lc $_; $f =~ s/[^a-z0-9\s]//g; [ $_, $f ] }
+ @manifest,
+ &generate_manifest_pod(),
+ &generate_manifest_readme()), '';
+}
+
+sub do_nmake {
+ my ($name, $makefile) = @_;
+ $makefile =~ s/^\tcopy \.\.\\README.*\n/\0/gm;
+ verify_contiguous($name, $makefile, 'README copies');
+ # Now remove the other copies that follow
+ 1 while $makefile =~ s/\0\tcopy .*\n/\0/gm;
+ $makefile =~ s/\0+/join ("", &generate_nmake_1)/se;
+
+ $makefile =~ s{(-cd \$\(PODDIR\) && del /f[^\n]+).*?(-cd \.\.\\utils && del /f)}
+ {"$1\n" . &generate_nmake_2."\n\t$2"}se;
+ $makefile;
+}
+
+# shut up used only once warning
+*do_dmake = *do_dmake = \&do_nmake;
+
+sub do_perlpod {
+ my ($name, $pod) = @_;
+
+ unless ($pod =~ s{(For\ ease\ of\ access,\ .*\n)
+ (?:\s+[a-z]{4,}.*\n # fooo
+ |=head.*\n # =head foo
+ |\s*\n # blank line
+ )+
+ }
+ {$1 . join "", &generate_perlpod}mxe) {
+ die "$0: Failed to insert amendments in do_perlpod";
+ }
+ $pod;
+}
+
+sub do_podmak {
+ my ($name, $body) = @_;
+ foreach my $variable (qw(pod man html tex)) {
+ die "$0: could not find $variable in $name"
+ unless $body =~ s{\n\U$variable\E = (?:[^\n]*\\\n)*[^\n]*}
+ {"\n" . generate_pod_mak ($variable)}se;
+ }
+ $body;
+}
+
+sub do_vms {
+ my ($name, $makefile) = @_;
+ $makefile =~ s/\npod\d* =[^\n]*/\0/gs;
+ verify_contiguous($name, $makefile, 'pod assignments');
+ $makefile =~ s/\0+/join "\n", '', &generate_descrip_mms_1/se;
+
+ die "$0: $name contains NUL bytes" if $makefile =~ /\0/;
+
+# Looking for the macro defining the current perldelta:
+#PERLDELTA_CURRENT = [.pod]perl5139delta.pod
+
+ $makefile =~ s/\nPERLDELTA_CURRENT\s+=\s+\Q[.pod]perl\E\d+delta\.pod\n
+ /\0/sx;
+ verify_contiguous($name, $makefile, 'current perldelta macro');
+ $makefile =~ s/\0+/join "\n", '', "PERLDELTA_CURRENT = [.pod]$delta_target", ''/se;
+
+# Looking for rules like this
+# [.lib.pods]perl.pod : [.pod]perl.pod
+# @ If F$Search("[.lib]pods.dir").eqs."" Then Create/Directory [.lib.pods]
+# Copy/NoConfirm/Log $(MMS$SOURCE) [.lib.pods]
+
+ $makefile =~ s/\n\Q[.lib.pods]\Eperl[^\n\.]*\.pod[^\n]+\n
+ [^\n]+\n # Another line
+ [^\n]+\Q[.lib.pods]\E\n # ends [.lib.pods]
+ /\0/gsx;
+ verify_contiguous($name, $makefile, 'copy rules');
+ $makefile =~ s/\0+/join "\n", '', &generate_descrip_mms_2/se;
+
+ $makefile;
+}
+
+sub do_unix {
+ my ($name, $makefile_SH) = @_;
+
+ $makefile_SH =~ s{^(perltoc_pod_prereqs = extra.pods).*}
+ {join ' ', $1, map "pod/$_",
+ sort keys %Copies, grep {!/perltoc/} keys %Generated
+ }mge;
+
+# pod/perl511delta.pod: pod/perldelta.pod
+# cd pod && $(LNS) perldelta.pod perl511delta.pod
+
+ $makefile_SH =~ s!(
+pod/perl[a-z0-9_]+\.pod: pod/perl[a-z0-9_]+\.pod
+ \$\(LNS\) perl[a-z0-9_]+\.pod pod/perl[a-z0-9_]+\.pod
+)+!\0!gm;
+
+ verify_contiguous($name, $makefile_SH, 'copy rules');
+
+ my @copy_rules = map "
+pod/$_: pod/$Copies{$_}
+ \$(LNS) $Copies{$_} pod/$_
+", keys %Copies;
+
+ $makefile_SH =~ s/\0+/join '', @copy_rules/se;
+ $makefile_SH;
+
+}
+
+# Do stuff
+
+my $built;
+while (my ($target, $name) = each %Targets) {
+ print "Working on target $target\n" if $Verbose;
+ next unless $Build{$target};
+ $built++;
+ my ($orig, $mode);
+ print "Now processing $name\n" if $Verbose;
+ if ($target ne "toc") {
+ local $/;
+ open my $thing, '<', $name or die "Can't open $name: $!";
+ binmode $thing;
+ $orig = <$thing>;
+ die "$0: $name contains NUL bytes" if $orig =~ /\0/;
+ }
+
+ my $new = do {
+ no strict 'refs';
+ &{"do_$target"}($target, $orig);
+ };
+
+ if (defined $orig) {
+ if ($new eq $orig) {
+ if ($Test) {
+ printf "ok %d # $name is up to date\n", $built + 1;
+ } elsif ($Verbose) {
+ print "Was not modified\n";
+ }
+ next;
+ } elsif ($Test) {
+ printf "not ok %d # $name is up to date\n", $built + 1;
+ next;