| 1 | =head1 NAME |
| 2 | |
| 3 | perlunifaq - Perl Unicode FAQ |
| 4 | |
| 5 | =head1 Q and A |
| 6 | |
| 7 | This is a list of questions and answers about Unicode in Perl, intended to be |
| 8 | read after L<perlunitut>. |
| 9 | |
| 10 | =head2 perlunitut isn't really a Unicode tutorial, is it? |
| 11 | |
| 12 | No, and this isn't really a Unicode FAQ. |
| 13 | |
| 14 | Perl has an abstracted interface for all supported character encodings, so this |
| 15 | is actually a generic C<Encode> tutorial and C<Encode> FAQ. But many people |
| 16 | think that Unicode is special and magical, and I didn't want to disappoint |
| 17 | them, so I decided to call the document a Unicode tutorial. |
| 18 | |
| 19 | =head2 What character encodings does Perl support? |
| 20 | |
| 21 | To find out which character encodings your Perl supports, run: |
| 22 | |
| 23 | perl -MEncode -le "print for Encode->encodings(':all')" |
| 24 | |
| 25 | =head2 Which version of perl should I use? |
| 26 | |
| 27 | Well, if you can, upgrade to the most recent, but certainly C<5.8.1> or newer. |
| 28 | The tutorial and FAQ assume the latest release. |
| 29 | |
| 30 | You should also check your modules, and upgrade them if necessary. For example, |
| 31 | HTML::Entities requires version >= 1.32 to function correctly, even though the |
| 32 | changelog is silent about this. |
| 33 | |
| 34 | =head2 What about binary data, like images? |
| 35 | |
| 36 | Well, apart from a bare C<binmode $fh>, you shouldn't treat them specially. |
| 37 | (The binmode is needed because otherwise Perl may convert line endings on Win32 |
| 38 | systems.) |
| 39 | |
| 40 | Be careful, though, to never combine text strings with binary strings. If you |
| 41 | need text in a binary stream, encode your text strings first using the |
| 42 | appropriate encoding, then join them with binary strings. See also: "What if I |
| 43 | don't encode?". |
| 44 | |
| 45 | =head2 When should I decode or encode? |
| 46 | |
| 47 | Whenever you're communicating text with anything that is external to your perl |
| 48 | process, like a database, a text file, a socket, or another program. Even if |
| 49 | the thing you're communicating with is also written in Perl. |
| 50 | |
| 51 | =head2 What if I don't decode? |
| 52 | |
| 53 | Whenever your encoded, binary string is used together with a text string, Perl |
| 54 | will assume that your binary string was encoded with ISO-8859-1, also known as |
| 55 | latin-1. If it wasn't latin-1, then your data is unpleasantly converted. For |
| 56 | example, if it was UTF-8, the individual bytes of multibyte characters are seen |
| 57 | as separate characters, and then again converted to UTF-8. Such double encoding |
| 58 | can be compared to double HTML encoding (C<&gt;>), or double URI encoding |
| 59 | (C<%253E>). |
| 60 | |
| 61 | This silent implicit decoding is known as "upgrading". That may sound |
| 62 | positive, but it's best to avoid it. |
| 63 | |
| 64 | =head2 What if I don't encode? |
| 65 | |
| 66 | Your text string will be sent using the bytes in Perl's internal format. In |
| 67 | some cases, Perl will warn you that you're doing something wrong, with a |
| 68 | friendly warning: |
| 69 | |
| 70 | Wide character in print at example.pl line 2. |
| 71 | |
| 72 | Because the internal format is often UTF-8, these bugs are hard to spot, |
| 73 | because UTF-8 is usually the encoding you wanted! But don't be lazy, and don't |
| 74 | use the fact that Perl's internal format is UTF-8 to your advantage. Encode |
| 75 | explicitly to avoid weird bugs, and to show to maintenance programmers that you |
| 76 | thought this through. |
| 77 | |
| 78 | =head2 Is there a way to automatically decode or encode? |
| 79 | |
| 80 | If all data that comes from a certain handle is encoded in exactly the same |
| 81 | way, you can tell the PerlIO system to automatically decode everything, with |
| 82 | the C<encoding> layer. If you do this, you can't accidentally forget to decode |
| 83 | or encode anymore, on things that use the layered handle. |
| 84 | |
| 85 | You can provide this layer when C<open>ing the file: |
| 86 | |
| 87 | open my $fh, '>:encoding(UTF-8)', $filename; # auto encoding on write |
| 88 | open my $fh, '<:encoding(UTF-8)', $filename; # auto decoding on read |
| 89 | |
| 90 | Or if you already have an open filehandle: |
| 91 | |
| 92 | binmode $fh, ':encoding(UTF-8)'; |
| 93 | |
| 94 | Some database drivers for DBI can also automatically encode and decode, but |
| 95 | that is sometimes limited to the UTF-8 encoding. |
| 96 | |
| 97 | =head2 What if I don't know which encoding was used? |
| 98 | |
| 99 | Do whatever you can to find out, and if you have to: guess. (Don't forget to |
| 100 | document your guess with a comment.) |
| 101 | |
| 102 | You could open the document in a web browser, and change the character set or |
| 103 | character encoding until you can visually confirm that all characters look the |
| 104 | way they should. |
| 105 | |
| 106 | There is no way to reliably detect the encoding automatically, so if people |
| 107 | keep sending you data without charset indication, you may have to educate them. |
| 108 | |
| 109 | =head2 Can I use Unicode in my Perl sources? |
| 110 | |
| 111 | Yes, you can! If your sources are UTF-8 encoded, you can indicate that with the |
| 112 | C<use utf8> pragma. |
| 113 | |
| 114 | use utf8; |
| 115 | |
| 116 | This doesn't do anything to your input, or to your output. It only influences |
| 117 | the way your sources are read. You can use Unicode in string literals, in |
| 118 | identifiers (but they still have to be "word characters" according to C<\w>), |
| 119 | and even in custom delimiters. |
| 120 | |
| 121 | =head2 Data::Dumper doesn't restore the UTF8 flag; is it broken? |
| 122 | |
| 123 | No, Data::Dumper's Unicode abilities are as they should be. There have been |
| 124 | some complaints that it should restore the UTF8 flag when the data is read |
| 125 | again with C<eval>. However, you should really not look at the flag, and |
| 126 | nothing indicates that Data::Dumper should break this rule. |
| 127 | |
| 128 | Here's what happens: when Perl reads in a string literal, it sticks to 8 bit |
| 129 | encoding as long as it can. (But perhaps originally it was internally encoded |
| 130 | as UTF-8, when you dumped it.) When it has to give that up because other |
| 131 | characters are added to the text string, it silently upgrades the string to |
| 132 | UTF-8. |
| 133 | |
| 134 | If you properly encode your strings for output, none of this is of your |
| 135 | concern, and you can just C<eval> dumped data as always. |
| 136 | |
| 137 | =head2 Why do regex character classes sometimes match only in the ASCII range? |
| 138 | |
| 139 | Starting in Perl 5.14 (and partially in Perl 5.12), just put a |
| 140 | C<use feature 'unicode_strings'> near the beginning of your program. |
| 141 | Within its lexical scope you shouldn't have this problem. It also is |
| 142 | automatically enabled under C<use feature ':5.12'> or C<use v5.12> or |
| 143 | using C<-E> on the command line for Perl 5.12 or higher. |
| 144 | |
| 145 | The rationale for requiring this is to not break older programs that |
| 146 | rely on the way things worked before Unicode came along. Those older |
| 147 | programs knew only about the ASCII character set, and so may not work |
| 148 | properly for additional characters. When a string is encoded in UTF-8, |
| 149 | Perl assumes that the program is prepared to deal with Unicode, but when |
| 150 | the string isn't, Perl assumes that only ASCII |
| 151 | is wanted, and so those characters that are not ASCII |
| 152 | characters aren't recognized as to what they would be in Unicode. |
| 153 | C<use feature 'unicode_strings'> tells Perl to treat all characters as |
| 154 | Unicode, whether the string is encoded in UTF-8 or not, thus avoiding |
| 155 | the problem. |
| 156 | |
| 157 | However, on earlier Perls, or if you pass strings to subroutines outside |
| 158 | the feature's scope, you can force Unicode semantics by changing the |
| 159 | encoding to UTF-8 by doing C<utf8::upgrade($string)>. This can be used |
| 160 | safely on any string, as it checks and does not change strings that have |
| 161 | already been upgraded. |
| 162 | |
| 163 | For a more detailed discussion, see L<Unicode::Semantics> on CPAN. |
| 164 | |
| 165 | =head2 Why do some characters not uppercase or lowercase correctly? |
| 166 | |
| 167 | See the answer to the previous question. |
| 168 | |
| 169 | =head2 How can I determine if a string is a text string or a binary string? |
| 170 | |
| 171 | You can't. Some use the UTF8 flag for this, but that's misuse, and makes well |
| 172 | behaved modules like Data::Dumper look bad. The flag is useless for this |
| 173 | purpose, because it's off when an 8 bit encoding (by default ISO-8859-1) is |
| 174 | used to store the string. |
| 175 | |
| 176 | This is something you, the programmer, has to keep track of; sorry. You could |
| 177 | consider adopting a kind of "Hungarian notation" to help with this. |
| 178 | |
| 179 | =head2 How do I convert from encoding FOO to encoding BAR? |
| 180 | |
| 181 | By first converting the FOO-encoded byte string to a text string, and then the |
| 182 | text string to a BAR-encoded byte string: |
| 183 | |
| 184 | my $text_string = decode('FOO', $foo_string); |
| 185 | my $bar_string = encode('BAR', $text_string); |
| 186 | |
| 187 | or by skipping the text string part, and going directly from one binary |
| 188 | encoding to the other: |
| 189 | |
| 190 | use Encode qw(from_to); |
| 191 | from_to($string, 'FOO', 'BAR'); # changes contents of $string |
| 192 | |
| 193 | or by letting automatic decoding and encoding do all the work: |
| 194 | |
| 195 | open my $foofh, '<:encoding(FOO)', 'example.foo.txt'; |
| 196 | open my $barfh, '>:encoding(BAR)', 'example.bar.txt'; |
| 197 | print { $barfh } $_ while <$foofh>; |
| 198 | |
| 199 | =head2 What are C<decode_utf8> and C<encode_utf8>? |
| 200 | |
| 201 | These are alternate syntaxes for C<decode('utf8', ...)> and C<encode('utf8', |
| 202 | ...)>. |
| 203 | |
| 204 | =head2 What is a "wide character"? |
| 205 | |
| 206 | This is a term used both for characters with an ordinal value greater than 127, |
| 207 | characters with an ordinal value greater than 255, or any character occupying |
| 208 | more than one byte, depending on the context. |
| 209 | |
| 210 | The Perl warning "Wide character in ..." is caused by a character with an |
| 211 | ordinal value greater than 255. With no specified encoding layer, Perl tries to |
| 212 | fit things in ISO-8859-1 for backward compatibility reasons. When it can't, it |
| 213 | emits this warning (if warnings are enabled), and outputs UTF-8 encoded data |
| 214 | instead. |
| 215 | |
| 216 | To avoid this warning and to avoid having different output encodings in a single |
| 217 | stream, always specify an encoding explicitly, for example with a PerlIO layer: |
| 218 | |
| 219 | binmode STDOUT, ":encoding(UTF-8)"; |
| 220 | |
| 221 | =head1 INTERNALS |
| 222 | |
| 223 | =head2 What is "the UTF8 flag"? |
| 224 | |
| 225 | Please, unless you're hacking the internals, or debugging weirdness, don't |
| 226 | think about the UTF8 flag at all. That means that you very probably shouldn't |
| 227 | use C<is_utf8>, C<_utf8_on> or C<_utf8_off> at all. |
| 228 | |
| 229 | The UTF8 flag, also called SvUTF8, is an internal flag that indicates that the |
| 230 | current internal representation is UTF-8. Without the flag, it is assumed to be |
| 231 | ISO-8859-1. Perl converts between these automatically. (Actually Perl usually |
| 232 | assumes the representation is ASCII; see L</Why do regex character classes |
| 233 | sometimes match only in the ASCII range?> above.) |
| 234 | |
| 235 | One of Perl's internal formats happens to be UTF-8. Unfortunately, Perl can't |
| 236 | keep a secret, so everyone knows about this. That is the source of much |
| 237 | confusion. It's better to pretend that the internal format is some unknown |
| 238 | encoding, and that you always have to encode and decode explicitly. |
| 239 | |
| 240 | =head2 What about the C<use bytes> pragma? |
| 241 | |
| 242 | Don't use it. It makes no sense to deal with bytes in a text string, and it |
| 243 | makes no sense to deal with characters in a byte string. Do the proper |
| 244 | conversions (by decoding/encoding), and things will work out well: you get |
| 245 | character counts for decoded data, and byte counts for encoded data. |
| 246 | |
| 247 | C<use bytes> is usually a failed attempt to do something useful. Just forget |
| 248 | about it. |
| 249 | |
| 250 | =head2 What about the C<use encoding> pragma? |
| 251 | |
| 252 | Don't use it. Unfortunately, it assumes that the programmer's environment and |
| 253 | that of the user will use the same encoding. It will use the same encoding for |
| 254 | the source code and for STDIN and STDOUT. When a program is copied to another |
| 255 | machine, the source code does not change, but the STDIO environment might. |
| 256 | |
| 257 | If you need non-ASCII characters in your source code, make it a UTF-8 encoded |
| 258 | file and C<use utf8>. |
| 259 | |
| 260 | If you need to set the encoding for STDIN, STDOUT, and STDERR, for example |
| 261 | based on the user's locale, C<use open>. |
| 262 | |
| 263 | =head2 What is the difference between C<:encoding> and C<:utf8>? |
| 264 | |
| 265 | Because UTF-8 is one of Perl's internal formats, you can often just skip the |
| 266 | encoding or decoding step, and manipulate the UTF8 flag directly. |
| 267 | |
| 268 | Instead of C<:encoding(UTF-8)>, you can simply use C<:utf8>, which skips the |
| 269 | encoding step if the data was already represented as UTF8 internally. This is |
| 270 | widely accepted as good behavior when you're writing, but it can be dangerous |
| 271 | when reading, because it causes internal inconsistency when you have invalid |
| 272 | byte sequences. Using C<:utf8> for input can sometimes result in security |
| 273 | breaches, so please use C<:encoding(UTF-8)> instead. |
| 274 | |
| 275 | Instead of C<decode> and C<encode>, you could use C<_utf8_on> and C<_utf8_off>, |
| 276 | but this is considered bad style. Especially C<_utf8_on> can be dangerous, for |
| 277 | the same reason that C<:utf8> can. |
| 278 | |
| 279 | There are some shortcuts for oneliners; |
| 280 | see L<-C|perlrun/-C [numberE<sol>list]> in L<perlrun>. |
| 281 | |
| 282 | =head2 What's the difference between C<UTF-8> and C<utf8>? |
| 283 | |
| 284 | C<UTF-8> is the official standard. C<utf8> is Perl's way of being liberal in |
| 285 | what it accepts. If you have to communicate with things that aren't so liberal, |
| 286 | you may want to consider using C<UTF-8>. If you have to communicate with things |
| 287 | that are too liberal, you may have to use C<utf8>. The full explanation is in |
| 288 | L<Encode>. |
| 289 | |
| 290 | C<UTF-8> is internally known as C<utf-8-strict>. The tutorial uses UTF-8 |
| 291 | consistently, even where utf8 is actually used internally, because the |
| 292 | distinction can be hard to make, and is mostly irrelevant. |
| 293 | |
| 294 | For example, utf8 can be used for code points that don't exist in Unicode, like |
| 295 | 9999999, but if you encode that to UTF-8, you get a substitution character (by |
| 296 | default; see L<Encode/"Handling Malformed Data"> for more ways of dealing with |
| 297 | this.) |
| 298 | |
| 299 | Okay, if you insist: the "internal format" is utf8, not UTF-8. (When it's not |
| 300 | some other encoding.) |
| 301 | |
| 302 | =head2 I lost track; what encoding is the internal format really? |
| 303 | |
| 304 | It's good that you lost track, because you shouldn't depend on the internal |
| 305 | format being any specific encoding. But since you asked: by default, the |
| 306 | internal format is either ISO-8859-1 (latin-1), or utf8, depending on the |
| 307 | history of the string. On EBCDIC platforms, this may be different even. |
| 308 | |
| 309 | Perl knows how it stored the string internally, and will use that knowledge |
| 310 | when you C<encode>. In other words: don't try to find out what the internal |
| 311 | encoding for a certain string is, but instead just encode it into the encoding |
| 312 | that you want. |
| 313 | |
| 314 | =head1 AUTHOR |
| 315 | |
| 316 | Juerd Waalboer <#####@juerd.nl> |
| 317 | |
| 318 | =head1 SEE ALSO |
| 319 | |
| 320 | L<perlunicode>, L<perluniintro>, L<Encode> |
| 321 | |