This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables: if modify during run, regen tables
[perl5.git] / pod / perlre.pod
... / ...
CommitLineData
1=head1 NAME
2X<regular expression> X<regex> X<regexp>
3
4perlre - Perl regular expressions
5
6=head1 DESCRIPTION
7
8This page describes the syntax of regular expressions in Perl.
9
10If you haven't used regular expressions before, a quick-start
11introduction is available in L<perlrequick>, and a longer tutorial
12introduction is available in L<perlretut>.
13
14For reference on how regular expressions are used in matching
15operations, plus various examples of the same, see discussions of
16C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17Operators">.
18
19
20=head2 Modifiers
21
22Matching operations can have various modifiers. Modifiers
23that relate to the interpretation of the regular expression inside
24are listed below. Modifiers that alter the way a regular expression
25is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26L<perlop/"Gory details of parsing quoted constructs">.
27
28=over 4
29
30=item m
31X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33Treat string as multiple lines. That is, change "^" and "$" from matching
34the start or end of the string to matching the start or end of any
35line anywhere within the string.
36
37=item s
38X</s> X<regex, single-line> X<regexp, single-line>
39X<regular expression, single-line>
40
41Treat string as single line. That is, change "." to match any character
42whatsoever, even a newline, which normally it would not match.
43
44Used together, as C</ms>, they let the "." match any character whatsoever,
45while still allowing "^" and "$" to match, respectively, just after
46and just before newlines within the string.
47
48=item i
49X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50X<regular expression, case-insensitive>
51
52Do case-insensitive pattern matching.
53
54If C<use locale> is in effect, the case map is taken from the current
55locale. See L<perllocale>.
56
57=item x
58X</x>
59
60Extend your pattern's legibility by permitting whitespace and comments.
61
62=item p
63X</p> X<regex, preserve> X<regexp, preserve>
64
65Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66${^POSTMATCH} are available for use after matching.
67
68=item g and c
69X</g> X</c>
70
71Global matching, and keep the Current position after failed matching.
72Unlike i, m, s and x, these two flags affect the way the regex is used
73rather than the regex itself. See
74L<perlretut/"Using regular expressions in Perl"> for further explanation
75of the g and c modifiers.
76
77=back
78
79These are usually written as "the C</x> modifier", even though the delimiter
80in question might not really be a slash. Any of these
81modifiers may also be embedded within the regular expression itself using
82the C<(?...)> construct. See below.
83
84The C</x> modifier itself needs a little more explanation. It tells
85the regular expression parser to ignore most whitespace that is neither
86backslashed nor within a character class. You can use this to break up
87your regular expression into (slightly) more readable parts. The C<#>
88character is also treated as a metacharacter introducing a comment,
89just as in ordinary Perl code. This also means that if you want real
90whitespace or C<#> characters in the pattern (outside a character
91class, where they are unaffected by C</x>), then you'll either have to
92escape them (using backslashes or C<\Q...\E>) or encode them using octal,
93hex, or C<\N{}> escapes. Taken together, these features go a long way towards
94making Perl's regular expressions more readable. Note that you have to
95be careful not to include the pattern delimiter in the comment--perl has
96no way of knowing you did not intend to close the pattern early. See
97the C-comment deletion code in L<perlop>. Also note that anything inside
98a C<\Q...\E> stays unaffected by C</x>. And note that C</x> doesn't affect
99whether space interpretation within a single multi-character construct. For
100example in C<\x{...}>, regardless of the C</x> modifier, there can be no
101spaces. Same for a L<quantifier|/Quantifiers> such as C<{3}> or
102C<{5,}>. Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
103but can between the C<(> and C<?>. Within any delimiters for such a
104construct, allowed spaces are not affected by C</x>, and depend on the
105construct. For example, C<\x{...}> can't have spaces because hexadecimal
106numbers don't have spaces in them. But, Unicode properties can have spaces, so
107in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
108L<perluniprops/Properties accessible through \p{} and \P{}>.
109X</x>
110
111=head2 Regular Expressions
112
113=head3 Metacharacters
114
115The patterns used in Perl pattern matching evolved from those supplied in
116the Version 8 regex routines. (The routines are derived
117(distantly) from Henry Spencer's freely redistributable reimplementation
118of the V8 routines.) See L<Version 8 Regular Expressions> for
119details.
120
121In particular the following metacharacters have their standard I<egrep>-ish
122meanings:
123X<metacharacter>
124X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
125
126
127 \ Quote the next metacharacter
128 ^ Match the beginning of the line
129 . Match any character (except newline)
130 $ Match the end of the line (or before newline at the end)
131 | Alternation
132 () Grouping
133 [] Bracketed Character class
134
135By default, the "^" character is guaranteed to match only the
136beginning of the string, the "$" character only the end (or before the
137newline at the end), and Perl does certain optimizations with the
138assumption that the string contains only one line. Embedded newlines
139will not be matched by "^" or "$". You may, however, wish to treat a
140string as a multi-line buffer, such that the "^" will match after any
141newline within the string (except if the newline is the last character in
142the string), and "$" will match before any newline. At the
143cost of a little more overhead, you can do this by using the /m modifier
144on the pattern match operator. (Older programs did this by setting C<$*>,
145but this practice has been removed in perl 5.9.)
146X<^> X<$> X</m>
147
148To simplify multi-line substitutions, the "." character never matches a
149newline unless you use the C</s> modifier, which in effect tells Perl to pretend
150the string is a single line--even if it isn't.
151X<.> X</s>
152
153=head3 Quantifiers
154
155The following standard quantifiers are recognized:
156X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
157
158 * Match 0 or more times
159 + Match 1 or more times
160 ? Match 1 or 0 times
161 {n} Match exactly n times
162 {n,} Match at least n times
163 {n,m} Match at least n but not more than m times
164
165(If a curly bracket occurs in any other context, it is treated
166as a regular character. In particular, the lower bound
167is not optional.) The "*" quantifier is equivalent to C<{0,}>, the "+"
168quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>. n and m are limited
169to non-negative integral values less than a preset limit defined when perl is built.
170This is usually 32766 on the most common platforms. The actual limit can
171be seen in the error message generated by code such as this:
172
173 $_ **= $_ , / {$_} / for 2 .. 42;
174
175By default, a quantified subpattern is "greedy", that is, it will match as
176many times as possible (given a particular starting location) while still
177allowing the rest of the pattern to match. If you want it to match the
178minimum number of times possible, follow the quantifier with a "?". Note
179that the meanings don't change, just the "greediness":
180X<metacharacter> X<greedy> X<greediness>
181X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
182
183 *? Match 0 or more times, not greedily
184 +? Match 1 or more times, not greedily
185 ?? Match 0 or 1 time, not greedily
186 {n}? Match exactly n times, not greedily
187 {n,}? Match at least n times, not greedily
188 {n,m}? Match at least n but not more than m times, not greedily
189
190By default, when a quantified subpattern does not allow the rest of the
191overall pattern to match, Perl will backtrack. However, this behaviour is
192sometimes undesirable. Thus Perl provides the "possessive" quantifier form
193as well.
194
195 *+ Match 0 or more times and give nothing back
196 ++ Match 1 or more times and give nothing back
197 ?+ Match 0 or 1 time and give nothing back
198 {n}+ Match exactly n times and give nothing back (redundant)
199 {n,}+ Match at least n times and give nothing back
200 {n,m}+ Match at least n but not more than m times and give nothing back
201
202For instance,
203
204 'aaaa' =~ /a++a/
205
206will never match, as the C<a++> will gobble up all the C<a>'s in the
207string and won't leave any for the remaining part of the pattern. This
208feature can be extremely useful to give perl hints about where it
209shouldn't backtrack. For instance, the typical "match a double-quoted
210string" problem can be most efficiently performed when written as:
211
212 /"(?:[^"\\]++|\\.)*+"/
213
214as we know that if the final quote does not match, backtracking will not
215help. See the independent subexpression C<< (?>...) >> for more details;
216possessive quantifiers are just syntactic sugar for that construct. For
217instance the above example could also be written as follows:
218
219 /"(?>(?:(?>[^"\\]+)|\\.)*)"/
220
221=head3 Escape sequences
222
223Because patterns are processed as double quoted strings, the following
224also work:
225
226 \t tab (HT, TAB)
227 \n newline (LF, NL)
228 \r return (CR)
229 \f form feed (FF)
230 \a alarm (bell) (BEL)
231 \e escape (think troff) (ESC)
232 \cK control char (example: VT)
233 \x{}, \x00 character whose ordinal is the given hexadecimal number
234 \N{name} named Unicode character or character sequence
235 \N{U+263D} Unicode character (example: FIRST QUARTER MOON)
236 \o{}, \000 character whose ordinal is the given octal number
237 \l lowercase next char (think vi)
238 \u uppercase next char (think vi)
239 \L lowercase till \E (think vi)
240 \U uppercase till \E (think vi)
241 \Q quote (disable) pattern metacharacters till \E
242 \E end either case modification or quoted section, think vi
243
244Details are in L<perlop/Quote and Quote-like Operators>.
245
246=head3 Character Classes and other Special Escapes
247
248In addition, Perl defines the following:
249X<\g> X<\k> X<\K> X<backreference>
250
251 Sequence Note Description
252 [...] [1] Match a character according to the rules of the
253 bracketed character class defined by the "...".
254 Example: [a-z] matches "a" or "b" or "c" ... or "z"
255 [[:...:]] [2] Match a character according to the rules of the POSIX
256 character class "..." within the outer bracketed
257 character class. Example: [[:upper:]] matches any
258 uppercase character.
259 \w [3] Match a "word" character (alphanumeric plus "_")
260 \W [3] Match a non-"word" character
261 \s [3] Match a whitespace character
262 \S [3] Match a non-whitespace character
263 \d [3] Match a decimal digit character
264 \D [3] Match a non-digit character
265 \pP [3] Match P, named property. Use \p{Prop} for longer names
266 \PP [3] Match non-P
267 \X [4] Match Unicode "eXtended grapheme cluster"
268 \C Match a single C-language char (octet) even if that is
269 part of a larger UTF-8 character. Thus it breaks up
270 characters into their UTF-8 bytes, so you may end up
271 with malformed pieces of UTF-8. Unsupported in
272 lookbehind.
273 \1 [5] Backreference to a specific capture group or buffer.
274 '1' may actually be any positive integer.
275 \g1 [5] Backreference to a specific or previous group,
276 \g{-1} [5] The number may be negative indicating a relative
277 previous group and may optionally be wrapped in
278 curly brackets for safer parsing.
279 \g{name} [5] Named backreference
280 \k<name> [5] Named backreference
281 \K [6] Keep the stuff left of the \K, don't include it in $&
282 \N [7] Any character but \n (experimental). Not affected by
283 /s modifier
284 \v [3] Vertical whitespace
285 \V [3] Not vertical whitespace
286 \h [3] Horizontal whitespace
287 \H [3] Not horizontal whitespace
288 \R [4] Linebreak
289
290=over 4
291
292=item [1]
293
294See L<perlrecharclass/Bracketed Character Classes> for details.
295
296=item [2]
297
298See L<perlrecharclass/POSIX Character Classes> for details.
299
300=item [3]
301
302See L<perlrecharclass/Backslash sequences> for details.
303
304=item [4]
305
306See L<perlrebackslash/Misc> for details.
307
308=item [5]
309
310See L</Capture groups> below for details.
311
312=item [6]
313
314See L</Extended Patterns> below for details.
315
316=item [7]
317
318Note that C<\N> has two meanings. When of the form C<\N{NAME}>, it matches the
319character or character sequence whose name is C<NAME>; and similarly
320when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
321code point is I<hex>. Otherwise it matches any character but C<\n>.
322
323=back
324
325=head3 Assertions
326
327Perl defines the following zero-width assertions:
328X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
329X<regexp, zero-width assertion>
330X<regular expression, zero-width assertion>
331X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
332
333 \b Match a word boundary
334 \B Match except at a word boundary
335 \A Match only at beginning of string
336 \Z Match only at end of string, or before newline at the end
337 \z Match only at end of string
338 \G Match only at pos() (e.g. at the end-of-match position
339 of prior m//g)
340
341A word boundary (C<\b>) is a spot between two characters
342that has a C<\w> on one side of it and a C<\W> on the other side
343of it (in either order), counting the imaginary characters off the
344beginning and end of the string as matching a C<\W>. (Within
345character classes C<\b> represents backspace rather than a word
346boundary, just as it normally does in any double-quoted string.)
347The C<\A> and C<\Z> are just like "^" and "$", except that they
348won't match multiple times when the C</m> modifier is used, while
349"^" and "$" will match at every internal line boundary. To match
350the actual end of the string and not ignore an optional trailing
351newline, use C<\z>.
352X<\b> X<\A> X<\Z> X<\z> X</m>
353
354The C<\G> assertion can be used to chain global matches (using
355C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
356It is also useful when writing C<lex>-like scanners, when you have
357several patterns that you want to match against consequent substrings
358of your string, see the previous reference. The actual location
359where C<\G> will match can also be influenced by using C<pos()> as
360an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
361matches is modified somewhat, in that contents to the left of C<\G> is
362not counted when determining the length of the match. Thus the following
363will not match forever:
364X<\G>
365
366 my $string = 'ABC';
367 pos($string) = 1;
368 while ($string =~ /(.\G)/g) {
369 print $1;
370 }
371
372It will print 'A' and then terminate, as it considers the match to
373be zero-width, and thus will not match at the same position twice in a
374row.
375
376It is worth noting that C<\G> improperly used can result in an infinite
377loop. Take care when using patterns that include C<\G> in an alternation.
378
379=head3 Capture groups
380
381The bracketing construct C<( ... )> creates capture groups (also referred to as
382capture buffers). To refer to the current contents of a group later on, within
383the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
384for the second, and so on.
385This is called a I<backreference>.
386X<regex, capture buffer> X<regexp, capture buffer>
387X<regex, capture group> X<regexp, capture group>
388X<regular expression, capture buffer> X<backreference>
389X<regular expression, capture group> X<backreference>
390X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
391X<named capture buffer> X<regular expression, named capture buffer>
392X<named capture group> X<regular expression, named capture group>
393X<%+> X<$+{name}> X<< \k<name> >>
394There is no limit to the number of captured substrings that you may use.
395Groups are numbered with the leftmost open parenthesis being number 1, etc. If
396a group did not match, the associated backreference won't match either. (This
397can happen if the group is optional, or in a different branch of an
398alternation.)
399You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
400this form, described below.
401
402You can also refer to capture groups relatively, by using a negative number, so
403that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
404group, and C<\g-2> and C<\g{-2}> both refer to the group before it. For
405example:
406
407 /
408 (Y) # group 1
409 ( # group 2
410 (X) # group 3
411 \g{-1} # backref to group 3
412 \g{-3} # backref to group 1
413 )
414 /x
415
416would match the same as C</(Y) ( (X) \g3 \g1 )/x>. This allows you to
417interpolate regexes into larger regexes and not have to worry about the
418capture groups being renumbered.
419
420You can dispense with numbers altogether and create named capture groups.
421The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
422reference. (To be compatible with .Net regular expressions, C<\g{I<name>}> may
423also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
424I<name> must not begin with a number, nor contain hyphens.
425When different groups within the same pattern have the same name, any reference
426to that name assumes the leftmost defined group. Named groups count in
427absolute and relative numbering, and so can also be referred to by those
428numbers.
429(It's possible to do things with named capture groups that would otherwise
430require C<(??{})>.)
431
432Capture group contents are dynamically scoped and available to you outside the
433pattern until the end of the enclosing block or until the next successful
434match, whichever comes first. (See L<perlsyn/"Compound Statements">.)
435You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
436etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
437
438Braces are required in referring to named capture groups, but are optional for
439absolute or relative numbered ones. Braces are safer when creating a regex by
440concatenating smaller strings. For example if you have C<qr/$a$b/>, and C<$a>
441contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
442is probably not what you intended.
443
444The C<\g> and C<\k> notations were introduced in Perl 5.10.0. Prior to that
445there were no named nor relative numbered capture groups. Absolute numbered
446groups were referred to using C<\1>, C<\2>, etc, and this notation is still
447accepted (and likely always will be). But it leads to some ambiguities if
448there are more than 9 capture groups, as C<\10> could mean either the tenth
449capture group, or the character whose ordinal in octal is 010 (a backspace in
450ASCII). Perl resolves this ambiguity by interpreting C<\10> as a backreference
451only if at least 10 left parentheses have opened before it. Likewise C<\11> is
452a backreference only if at least 11 left parentheses have opened before it.
453And so on. C<\1> through C<\9> are always interpreted as backreferences.
454There are several examples below that illustrate these perils. You can avoid
455the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
456and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
457digits padded with leading zeros, since a leading zero implies an octal
458constant.
459
460The C<\I<digit>> notation also works in certain circumstances outside
461the pattern. See L</Warning on \1 Instead of $1> below for details.)
462
463Examples:
464
465 s/^([^ ]*) *([^ ]*)/$2 $1/; # swap first two words
466
467 /(.)\g1/ # find first doubled char
468 and print "'$1' is the first doubled character\n";
469
470 /(?<char>.)\k<char>/ # ... a different way
471 and print "'$+{char}' is the first doubled character\n";
472
473 /(?'char'.)\g1/ # ... mix and match
474 and print "'$1' is the first doubled character\n";
475
476 if (/Time: (..):(..):(..)/) { # parse out values
477 $hours = $1;
478 $minutes = $2;
479 $seconds = $3;
480 }
481
482 /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/ # \g10 is a backreference
483 /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/ # \10 is octal
484 /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/ # \10 is a backreference
485 /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
486
487 $a = '(.)\1'; # Creates problems when concatenated.
488 $b = '(.)\g{1}'; # Avoids the problems.
489 "aa" =~ /${a}/; # True
490 "aa" =~ /${b}/; # True
491 "aa0" =~ /${a}0/; # False!
492 "aa0" =~ /${b}0/; # True
493 "aa\x08" =~ /${a}0/; # True!
494 "aa\x08" =~ /${b}0/; # False
495
496Several special variables also refer back to portions of the previous
497match. C<$+> returns whatever the last bracket match matched.
498C<$&> returns the entire matched string. (At one point C<$0> did
499also, but now it returns the name of the program.) C<$`> returns
500everything before the matched string. C<$'> returns everything
501after the matched string. And C<$^N> contains whatever was matched by
502the most-recently closed group (submatch). C<$^N> can be used in
503extended patterns (see below), for example to assign a submatch to a
504variable.
505X<$+> X<$^N> X<$&> X<$`> X<$'>
506
507These special variables, like the C<%+> hash and the numbered match variables
508(C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
509until the end of the enclosing block or until the next successful
510match, whichever comes first. (See L<perlsyn/"Compound Statements">.)
511X<$+> X<$^N> X<$&> X<$`> X<$'>
512X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
513
514B<NOTE>: Failed matches in Perl do not reset the match variables,
515which makes it easier to write code that tests for a series of more
516specific cases and remembers the best match.
517
518B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
519C<$'> anywhere in the program, it has to provide them for every
520pattern match. This may substantially slow your program. Perl
521uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
522price for each pattern that contains capturing parentheses. (To
523avoid this cost while retaining the grouping behaviour, use the
524extended regular expression C<(?: ... )> instead.) But if you never
525use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
526parentheses will not be penalized. So avoid C<$&>, C<$'>, and C<$`>
527if you can, but if you can't (and some algorithms really appreciate
528them), once you've used them once, use them at will, because you've
529already paid the price. As of 5.005, C<$&> is not so costly as the
530other two.
531X<$&> X<$`> X<$'>
532
533As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
534C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
535and C<$'>, B<except> that they are only guaranteed to be defined after a
536successful match that was executed with the C</p> (preserve) modifier.
537The use of these variables incurs no global performance penalty, unlike
538their punctuation char equivalents, however at the trade-off that you
539have to tell perl when you want to use them.
540X</p> X<p modifier>
541
542=head2 Quoting metacharacters
543
544Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
545C<\w>, C<\n>. Unlike some other regular expression languages, there
546are no backslashed symbols that aren't alphanumeric. So anything
547that looks like \\, \(, \), \<, \>, \{, or \} is always
548interpreted as a literal character, not a metacharacter. This was
549once used in a common idiom to disable or quote the special meanings
550of regular expression metacharacters in a string that you want to
551use for a pattern. Simply quote all non-"word" characters:
552
553 $pattern =~ s/(\W)/\\$1/g;
554
555(If C<use locale> is set, then this depends on the current locale.)
556Today it is more common to use the quotemeta() function or the C<\Q>
557metaquoting escape sequence to disable all metacharacters' special
558meanings like this:
559
560 /$unquoted\Q$quoted\E$unquoted/
561
562Beware that if you put literal backslashes (those not inside
563interpolated variables) between C<\Q> and C<\E>, double-quotish
564backslash interpolation may lead to confusing results. If you
565I<need> to use literal backslashes within C<\Q...\E>,
566consult L<perlop/"Gory details of parsing quoted constructs">.
567
568=head2 Extended Patterns
569
570Perl also defines a consistent extension syntax for features not
571found in standard tools like B<awk> and B<lex>. The syntax is a
572pair of parentheses with a question mark as the first thing within
573the parentheses. The character after the question mark indicates
574the extension.
575
576The stability of these extensions varies widely. Some have been
577part of the core language for many years. Others are experimental
578and may change without warning or be completely removed. Check
579the documentation on an individual feature to verify its current
580status.
581
582A question mark was chosen for this and for the minimal-matching
583construct because 1) question marks are rare in older regular
584expressions, and 2) whenever you see one, you should stop and
585"question" exactly what is going on. That's psychology...
586
587=over 10
588
589=item C<(?#text)>
590X<(?#)>
591
592A comment. The text is ignored. If the C</x> modifier enables
593whitespace formatting, a simple C<#> will suffice. Note that Perl closes
594the comment as soon as it sees a C<)>, so there is no way to put a literal
595C<)> in the comment.
596
597=item C<(?dlupimsx-imsx)>
598
599=item C<(?^lupimsx)>
600X<(?)> X<(?^)>
601
602One or more embedded pattern-match modifiers, to be turned on (or
603turned off, if preceded by C<->) for the remainder of the pattern or
604the remainder of the enclosing pattern group (if any).
605
606This is particularly useful for dynamic patterns, such as those read in from a
607configuration file, taken from an argument, or specified in a table
608somewhere. Consider the case where some patterns want to be case
609sensitive and some do not: The case insensitive ones merely need to
610include C<(?i)> at the front of the pattern. For example:
611
612 $pattern = "foobar";
613 if ( /$pattern/i ) { }
614
615 # more flexible:
616
617 $pattern = "(?i)foobar";
618 if ( /$pattern/ ) { }
619
620These modifiers are restored at the end of the enclosing group. For example,
621
622 ( (?i) blah ) \s+ \g1
623
624will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
625repetition of the previous word, assuming the C</x> modifier, and no C</i>
626modifier outside this group.
627
628These modifiers do not carry over into named subpatterns called in the
629enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
630change the case-sensitivity of the "NAME" pattern.
631
632Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
633after the C<"?"> is a shorthand equivalent to C<d-imsx>. Flags (except
634C<"d">) may follow the caret to override it.
635But a minus sign is not legal with it.
636
637Also, starting in Perl 5.14, are modifiers C<"d">, C<"l">, and C<"u">,
638which for 5.14 may not be used as suffix modifiers.
639
640C<"l"> means to use a locale (see L<perllocale>) when pattern matching.
641The locale used will be the one in effect at the time of execution of
642the pattern match. This may not be the same as the compilation-time
643locale, and can differ from one match to another if there is an
644intervening call of the
645L<setlocale() function|perllocale/The setlocale function>.
646This modifier is automatically set if the regular expression is compiled
647within the scope of a C<"use locale"> pragma.
648
649C<"u"> has no effect currently. It is automatically set if the regular
650expression is compiled within the scope of a
651L<C<"use feature 'unicode_strings">|feature> pragma.
652
653C<"d"> means to use the traditional Perl pattern matching behavior.
654This is dualistic (hence the name C<"d">, which also could stand for
655"default"). When this is in effect, Perl matches utf8-encoded strings
656using Unicode rules, and matches non-utf8-encoded strings using the
657platform's native character set rules.
658See L<perlunicode/The "Unicode Bug">. It is automatically selected by
659default if the regular expression is compiled neither within the scope
660of a C<"use locale"> pragma nor a <C<"use feature 'unicode_strings">
661pragma.
662
663Note that the C<d>, C<l>, C<p>, and C<u> modifiers are special in that
664they can only be enabled, not disabled, and the C<d>, C<l>, and C<u>
665modifiers are mutually exclusive; a maximum of one may appear in the
666construct. Specifying one de-specifies the others. Thus, for example,
667C<(?-p)> and C<(?-d:...)> are meaningless and will warn when compiled
668under C<use warnings>.
669
670Note also that the C<p> modifier is special in that its presence
671anywhere in a pattern has a global effect.
672
673=item C<(?:pattern)>
674X<(?:)>
675
676=item C<(?dluimsx-imsx:pattern)>
677
678=item C<(?^luimsx:pattern)>
679X<(?^:)>
680
681This is for clustering, not capturing; it groups subexpressions like
682"()", but doesn't make backreferences as "()" does. So
683
684 @fields = split(/\b(?:a|b|c)\b/)
685
686is like
687
688 @fields = split(/\b(a|b|c)\b/)
689
690but doesn't spit out extra fields. It's also cheaper not to capture
691characters if you don't need to.
692
693Any letters between C<?> and C<:> act as flags modifiers as with
694C<(?dluimsx-imsx)>. For example,
695
696 /(?s-i:more.*than).*million/i
697
698is equivalent to the more verbose
699
700 /(?:(?s-i)more.*than).*million/i
701
702Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
703after the C<"?"> is a shorthand equivalent to C<d-imsx>. Any positive
704flags (except C<"d">) may follow the caret, so
705
706 (?^x:foo)
707
708is equivalent to
709
710 (?x-ims:foo)
711
712The caret tells Perl that this cluster doesn't inherit the flags of any
713surrounding pattern, but to go back to the system defaults (C<d-imsx>),
714modified by any flags specified.
715
716The caret allows for simpler stringification of compiled regular
717expressions. These look like
718
719 (?^:pattern)
720
721with any non-default flags appearing between the caret and the colon.
722A test that looks at such stringification thus doesn't need to have the
723system default flags hard-coded in it, just the caret. If new flags are
724added to Perl, the meaning of the caret's expansion will change to include
725the default for those flags, so the test will still work, unchanged.
726
727Specifying a negative flag after the caret is an error, as the flag is
728redundant.
729
730Mnemonic for C<(?^...)>: A fresh beginning since the usual use of a caret is
731to match at the beginning.
732
733=item C<(?|pattern)>
734X<(?|)> X<Branch reset>
735
736This is the "branch reset" pattern, which has the special property
737that the capture groups are numbered from the same starting point
738in each alternation branch. It is available starting from perl 5.10.0.
739
740Capture groups are numbered from left to right, but inside this
741construct the numbering is restarted for each branch.
742
743The numbering within each branch will be as normal, and any groups
744following this construct will be numbered as though the construct
745contained only one branch, that being the one with the most capture
746groups in it.
747
748This construct will be useful when you want to capture one of a
749number of alternative matches.
750
751Consider the following pattern. The numbers underneath show in
752which group the captured content will be stored.
753
754
755 # before ---------------branch-reset----------- after
756 / ( a ) (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
757 # 1 2 2 3 2 3 4
758
759Be careful when using the branch reset pattern in combination with
760named captures. Named captures are implemented as being aliases to
761numbered groups holding the captures, and that interferes with the
762implementation of the branch reset pattern. If you are using named
763captures in a branch reset pattern, it's best to use the same names,
764in the same order, in each of the alternations:
765
766 /(?| (?<a> x ) (?<b> y )
767 | (?<a> z ) (?<b> w )) /x
768
769Not doing so may lead to surprises:
770
771 "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
772 say $+ {a}; # Prints '12'
773 say $+ {b}; # *Also* prints '12'.
774
775The problem here is that both the group named C<< a >> and the group
776named C<< b >> are aliases for the group belonging to C<< $1 >>.
777
778=item Look-Around Assertions
779X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
780
781Look-around assertions are zero width patterns which match a specific
782pattern without including it in C<$&>. Positive assertions match when
783their subpattern matches, negative assertions match when their subpattern
784fails. Look-behind matches text up to the current match position,
785look-ahead matches text following the current match position.
786
787=over 4
788
789=item C<(?=pattern)>
790X<(?=)> X<look-ahead, positive> X<lookahead, positive>
791
792A zero-width positive look-ahead assertion. For example, C</\w+(?=\t)/>
793matches a word followed by a tab, without including the tab in C<$&>.
794
795=item C<(?!pattern)>
796X<(?!)> X<look-ahead, negative> X<lookahead, negative>
797
798A zero-width negative look-ahead assertion. For example C</foo(?!bar)/>
799matches any occurrence of "foo" that isn't followed by "bar". Note
800however that look-ahead and look-behind are NOT the same thing. You cannot
801use this for look-behind.
802
803If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
804will not do what you want. That's because the C<(?!foo)> is just saying that
805the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
806match. You would have to do something like C</(?!foo)...bar/> for that. We
807say "like" because there's the case of your "bar" not having three characters
808before it. You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
809Sometimes it's still easier just to say:
810
811 if (/bar/ && $` !~ /foo$/)
812
813For look-behind see below.
814
815=item C<(?<=pattern)> C<\K>
816X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
817
818A zero-width positive look-behind assertion. For example, C</(?<=\t)\w+/>
819matches a word that follows a tab, without including the tab in C<$&>.
820Works only for fixed-width look-behind.
821
822There is a special form of this construct, called C<\K>, which causes the
823regex engine to "keep" everything it had matched prior to the C<\K> and
824not include it in C<$&>. This effectively provides variable length
825look-behind. The use of C<\K> inside of another look-around assertion
826is allowed, but the behaviour is currently not well defined.
827
828For various reasons C<\K> may be significantly more efficient than the
829equivalent C<< (?<=...) >> construct, and it is especially useful in
830situations where you want to efficiently remove something following
831something else in a string. For instance
832
833 s/(foo)bar/$1/g;
834
835can be rewritten as the much more efficient
836
837 s/foo\Kbar//g;
838
839=item C<(?<!pattern)>
840X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
841
842A zero-width negative look-behind assertion. For example C</(?<!bar)foo/>
843matches any occurrence of "foo" that does not follow "bar". Works
844only for fixed-width look-behind.
845
846=back
847
848=item C<(?'NAME'pattern)>
849
850=item C<< (?<NAME>pattern) >>
851X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
852
853A named capture group. Identical in every respect to normal capturing
854parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
855used after a successful match to refer to a named group. See C<perlvar>
856for more details on the C<%+> and C<%-> hashes.
857
858If multiple distinct capture groups have the same name then the
859$+{NAME} will refer to the leftmost defined group in the match.
860
861The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
862
863B<NOTE:> While the notation of this construct is the same as the similar
864function in .NET regexes, the behavior is not. In Perl the groups are
865numbered sequentially regardless of being named or not. Thus in the
866pattern
867
868 /(x)(?<foo>y)(z)/
869
870$+{foo} will be the same as $2, and $3 will contain 'z' instead of
871the opposite which is what a .NET regex hacker might expect.
872
873Currently NAME is restricted to simple identifiers only.
874In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
875its Unicode extension (see L<utf8>),
876though it isn't extended by the locale (see L<perllocale>).
877
878B<NOTE:> In order to make things easier for programmers with experience
879with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
880may be used instead of C<< (?<NAME>pattern) >>; however this form does not
881support the use of single quotes as a delimiter for the name.
882
883=item C<< \k<NAME> >>
884
885=item C<< \k'NAME' >>
886
887Named backreference. Similar to numeric backreferences, except that
888the group is designated by name and not number. If multiple groups
889have the same name then it refers to the leftmost defined group in
890the current match.
891
892It is an error to refer to a name not defined by a C<< (?<NAME>) >>
893earlier in the pattern.
894
895Both forms are equivalent.
896
897B<NOTE:> In order to make things easier for programmers with experience
898with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
899may be used instead of C<< \k<NAME> >>.
900
901=item C<(?{ code })>
902X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
903
904B<WARNING>: This extended regular expression feature is considered
905experimental, and may be changed without notice. Code executed that
906has side effects may not perform identically from version to version
907due to the effect of future optimisations in the regex engine.
908
909This zero-width assertion evaluates any embedded Perl code. It
910always succeeds, and its C<code> is not interpolated. Currently,
911the rules to determine where the C<code> ends are somewhat convoluted.
912
913This feature can be used together with the special variable C<$^N> to
914capture the results of submatches in variables without having to keep
915track of the number of nested parentheses. For example:
916
917 $_ = "The brown fox jumps over the lazy dog";
918 /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
919 print "color = $color, animal = $animal\n";
920
921Inside the C<(?{...})> block, C<$_> refers to the string the regular
922expression is matching against. You can also use C<pos()> to know what is
923the current position of matching within this string.
924
925The C<code> is properly scoped in the following sense: If the assertion
926is backtracked (compare L<"Backtracking">), all changes introduced after
927C<local>ization are undone, so that
928
929 $_ = 'a' x 8;
930 m<
931 (?{ $cnt = 0 }) # Initialize $cnt.
932 (
933 a
934 (?{
935 local $cnt = $cnt + 1; # Update $cnt, backtracking-safe.
936 })
937 )*
938 aaaa
939 (?{ $res = $cnt }) # On success copy to
940 # non-localized location.
941 >x;
942
943will set C<$res = 4>. Note that after the match, C<$cnt> returns to the globally
944introduced value, because the scopes that restrict C<local> operators
945are unwound.
946
947This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
948switch. If I<not> used in this way, the result of evaluation of
949C<code> is put into the special variable C<$^R>. This happens
950immediately, so C<$^R> can be used from other C<(?{ code })> assertions
951inside the same regular expression.
952
953The assignment to C<$^R> above is properly localized, so the old
954value of C<$^R> is restored if the assertion is backtracked; compare
955L<"Backtracking">.
956
957For reasons of security, this construct is forbidden if the regular
958expression involves run-time interpolation of variables, unless the
959perilous C<use re 'eval'> pragma has been used (see L<re>), or the
960variables contain results of C<qr//> operator (see
961L<perlop/"qr/STRINGE<sol>msixpo">).
962
963This restriction is due to the wide-spread and remarkably convenient
964custom of using run-time determined strings as patterns. For example:
965
966 $re = <>;
967 chomp $re;
968 $string =~ /$re/;
969
970Before Perl knew how to execute interpolated code within a pattern,
971this operation was completely safe from a security point of view,
972although it could raise an exception from an illegal pattern. If
973you turn on the C<use re 'eval'>, though, it is no longer secure,
974so you should only do so if you are also using taint checking.
975Better yet, use the carefully constrained evaluation within a Safe
976compartment. See L<perlsec> for details about both these mechanisms.
977
978B<WARNING>: Use of lexical (C<my>) variables in these blocks is
979broken. The result is unpredictable and will make perl unstable. The
980workaround is to use global (C<our>) variables.
981
982B<WARNING>: Because Perl's regex engine is currently not re-entrant,
983interpolated code may not invoke the regex engine either directly with
984C<m//> or C<s///>), or indirectly with functions such as
985C<split>. Invoking the regex engine in these blocks will make perl
986unstable.
987
988=item C<(??{ code })>
989X<(??{})>
990X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
991
992B<WARNING>: This extended regular expression feature is considered
993experimental, and may be changed without notice. Code executed that
994has side effects may not perform identically from version to version
995due to the effect of future optimisations in the regex engine.
996
997This is a "postponed" regular subexpression. The C<code> is evaluated
998at run time, at the moment this subexpression may match. The result
999of evaluation is considered as a regular expression and matched as
1000if it were inserted instead of this construct. Note that this means
1001that the contents of capture groups defined inside an eval'ed pattern
1002are not available outside of the pattern, and vice versa, there is no
1003way for the inner pattern to refer to a capture group defined outside.
1004Thus,
1005
1006 ('a' x 100)=~/(??{'(.)' x 100})/
1007
1008B<will> match, it will B<not> set $1.
1009
1010The C<code> is not interpolated. As before, the rules to determine
1011where the C<code> ends are currently somewhat convoluted.
1012
1013The following pattern matches a parenthesized group:
1014
1015 $re = qr{
1016 \(
1017 (?:
1018 (?> [^()]+ ) # Non-parens without backtracking
1019 |
1020 (??{ $re }) # Group with matching parens
1021 )*
1022 \)
1023 }x;
1024
1025See also C<(?PARNO)> for a different, more efficient way to accomplish
1026the same task.
1027
1028For reasons of security, this construct is forbidden if the regular
1029expression involves run-time interpolation of variables, unless the
1030perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1031variables contain results of C<qr//> operator (see
1032L<perlop/"qrE<sol>STRINGE<sol>msixpo">).
1033
1034Because perl's regex engine is not currently re-entrant, delayed
1035code may not invoke the regex engine either directly with C<m//> or C<s///>),
1036or indirectly with functions such as C<split>.
1037
1038Recursing deeper than 50 times without consuming any input string will
1039result in a fatal error. The maximum depth is compiled into perl, so
1040changing it requires a custom build.
1041
1042=item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1043X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1044X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1045X<regex, relative recursion>
1046
1047Similar to C<(??{ code })> except it does not involve compiling any code,
1048instead it treats the contents of a capture group as an independent
1049pattern that must match at the current position. Capture groups
1050contained by the pattern will have the value as determined by the
1051outermost recursion.
1052
1053PARNO is a sequence of digits (not starting with 0) whose value reflects
1054the paren-number of the capture group to recurse to. C<(?R)> recurses to
1055the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1056C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1057to be relative, with negative numbers indicating preceding capture groups
1058and positive ones following. Thus C<(?-1)> refers to the most recently
1059declared group, and C<(?+1)> indicates the next group to be declared.
1060Note that the counting for relative recursion differs from that of
1061relative backreferences, in that with recursion unclosed groups B<are>
1062included.
1063
1064The following pattern matches a function foo() which may contain
1065balanced parentheses as the argument.
1066
1067 $re = qr{ ( # paren group 1 (full function)
1068 foo
1069 ( # paren group 2 (parens)
1070 \(
1071 ( # paren group 3 (contents of parens)
1072 (?:
1073 (?> [^()]+ ) # Non-parens without backtracking
1074 |
1075 (?2) # Recurse to start of paren group 2
1076 )*
1077 )
1078 \)
1079 )
1080 )
1081 }x;
1082
1083If the pattern was used as follows
1084
1085 'foo(bar(baz)+baz(bop))'=~/$re/
1086 and print "\$1 = $1\n",
1087 "\$2 = $2\n",
1088 "\$3 = $3\n";
1089
1090the output produced should be the following:
1091
1092 $1 = foo(bar(baz)+baz(bop))
1093 $2 = (bar(baz)+baz(bop))
1094 $3 = bar(baz)+baz(bop)
1095
1096If there is no corresponding capture group defined, then it is a
1097fatal error. Recursing deeper than 50 times without consuming any input
1098string will also result in a fatal error. The maximum depth is compiled
1099into perl, so changing it requires a custom build.
1100
1101The following shows how using negative indexing can make it
1102easier to embed recursive patterns inside of a C<qr//> construct
1103for later use:
1104
1105 my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1106 if (/foo $parens \s+ + \s+ bar $parens/x) {
1107 # do something here...
1108 }
1109
1110B<Note> that this pattern does not behave the same way as the equivalent
1111PCRE or Python construct of the same form. In Perl you can backtrack into
1112a recursed group, in PCRE and Python the recursed into group is treated
1113as atomic. Also, modifiers are resolved at compile time, so constructs
1114like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1115be processed.
1116
1117=item C<(?&NAME)>
1118X<(?&NAME)>
1119
1120Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1121parenthesis to recurse to is determined by name. If multiple parentheses have
1122the same name, then it recurses to the leftmost.
1123
1124It is an error to refer to a name that is not declared somewhere in the
1125pattern.
1126
1127B<NOTE:> In order to make things easier for programmers with experience
1128with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1129may be used instead of C<< (?&NAME) >>.
1130
1131=item C<(?(condition)yes-pattern|no-pattern)>
1132X<(?()>
1133
1134=item C<(?(condition)yes-pattern)>
1135
1136Conditional expression. C<(condition)> should be either an integer in
1137parentheses (which is valid if the corresponding pair of parentheses
1138matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1139name in angle brackets or single quotes (which is valid if a group
1140with the given name matched), or the special symbol (R) (true when
1141evaluated inside of recursion or eval). Additionally the R may be
1142followed by a number, (which will be true when evaluated when recursing
1143inside of the appropriate group), or by C<&NAME>, in which case it will
1144be true only when evaluated during recursion in the named group.
1145
1146Here's a summary of the possible predicates:
1147
1148=over 4
1149
1150=item (1) (2) ...
1151
1152Checks if the numbered capturing group has matched something.
1153
1154=item (<NAME>) ('NAME')
1155
1156Checks if a group with the given name has matched something.
1157
1158=item (?{ CODE })
1159
1160Treats the code block as the condition.
1161
1162=item (R)
1163
1164Checks if the expression has been evaluated inside of recursion.
1165
1166=item (R1) (R2) ...
1167
1168Checks if the expression has been evaluated while executing directly
1169inside of the n-th capture group. This check is the regex equivalent of
1170
1171 if ((caller(0))[3] eq 'subname') { ... }
1172
1173In other words, it does not check the full recursion stack.
1174
1175=item (R&NAME)
1176
1177Similar to C<(R1)>, this predicate checks to see if we're executing
1178directly inside of the leftmost group with a given name (this is the same
1179logic used by C<(?&NAME)> to disambiguate). It does not check the full
1180stack, but only the name of the innermost active recursion.
1181
1182=item (DEFINE)
1183
1184In this case, the yes-pattern is never directly executed, and no
1185no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1186See below for details.
1187
1188=back
1189
1190For example:
1191
1192 m{ ( \( )?
1193 [^()]+
1194 (?(1) \) )
1195 }x
1196
1197matches a chunk of non-parentheses, possibly included in parentheses
1198themselves.
1199
1200A special form is the C<(DEFINE)> predicate, which never executes directly
1201its yes-pattern, and does not allow a no-pattern. This allows to define
1202subpatterns which will be executed only by using the recursion mechanism.
1203This way, you can define a set of regular expression rules that can be
1204bundled into any pattern you choose.
1205
1206It is recommended that for this usage you put the DEFINE block at the
1207end of the pattern, and that you name any subpatterns defined within it.
1208
1209Also, it's worth noting that patterns defined this way probably will
1210not be as efficient, as the optimiser is not very clever about
1211handling them.
1212
1213An example of how this might be used is as follows:
1214
1215 /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1216 (?(DEFINE)
1217 (?<NAME_PAT>....)
1218 (?<ADRESS_PAT>....)
1219 )/x
1220
1221Note that capture groups matched inside of recursion are not accessible
1222after the recursion returns, so the extra layer of capturing groups is
1223necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1224C<$+{NAME}> would be.
1225
1226=item C<< (?>pattern) >>
1227X<backtrack> X<backtracking> X<atomic> X<possessive>
1228
1229An "independent" subexpression, one which matches the substring
1230that a I<standalone> C<pattern> would match if anchored at the given
1231position, and it matches I<nothing other than this substring>. This
1232construct is useful for optimizations of what would otherwise be
1233"eternal" matches, because it will not backtrack (see L<"Backtracking">).
1234It may also be useful in places where the "grab all you can, and do not
1235give anything back" semantic is desirable.
1236
1237For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1238(anchored at the beginning of string, as above) will match I<all>
1239characters C<a> at the beginning of string, leaving no C<a> for
1240C<ab> to match. In contrast, C<a*ab> will match the same as C<a+b>,
1241since the match of the subgroup C<a*> is influenced by the following
1242group C<ab> (see L<"Backtracking">). In particular, C<a*> inside
1243C<a*ab> will match fewer characters than a standalone C<a*>, since
1244this makes the tail match.
1245
1246An effect similar to C<< (?>pattern) >> may be achieved by writing
1247C<(?=(pattern))\g1>. This matches the same substring as a standalone
1248C<a+>, and the following C<\g1> eats the matched string; it therefore
1249makes a zero-length assertion into an analogue of C<< (?>...) >>.
1250(The difference between these two constructs is that the second one
1251uses a capturing group, thus shifting ordinals of backreferences
1252in the rest of a regular expression.)
1253
1254Consider this pattern:
1255
1256 m{ \(
1257 (
1258 [^()]+ # x+
1259 |
1260 \( [^()]* \)
1261 )+
1262 \)
1263 }x
1264
1265That will efficiently match a nonempty group with matching parentheses
1266two levels deep or less. However, if there is no such group, it
1267will take virtually forever on a long string. That's because there
1268are so many different ways to split a long string into several
1269substrings. This is what C<(.+)+> is doing, and C<(.+)+> is similar
1270to a subpattern of the above pattern. Consider how the pattern
1271above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1272seconds, but that each extra letter doubles this time. This
1273exponential performance will make it appear that your program has
1274hung. However, a tiny change to this pattern
1275
1276 m{ \(
1277 (
1278 (?> [^()]+ ) # change x+ above to (?> x+ )
1279 |
1280 \( [^()]* \)
1281 )+
1282 \)
1283 }x
1284
1285which uses C<< (?>...) >> matches exactly when the one above does (verifying
1286this yourself would be a productive exercise), but finishes in a fourth
1287the time when used on a similar string with 1000000 C<a>s. Be aware,
1288however, that this pattern currently triggers a warning message under
1289the C<use warnings> pragma or B<-w> switch saying it
1290C<"matches null string many times in regex">.
1291
1292On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1293effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1294This was only 4 times slower on a string with 1000000 C<a>s.
1295
1296The "grab all you can, and do not give anything back" semantic is desirable
1297in many situations where on the first sight a simple C<()*> looks like
1298the correct solution. Suppose we parse text with comments being delimited
1299by C<#> followed by some optional (horizontal) whitespace. Contrary to
1300its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1301the comment delimiter, because it may "give up" some whitespace if
1302the remainder of the pattern can be made to match that way. The correct
1303answer is either one of these:
1304
1305 (?>#[ \t]*)
1306 #[ \t]*(?![ \t])
1307
1308For example, to grab non-empty comments into $1, one should use either
1309one of these:
1310
1311 / (?> \# [ \t]* ) ( .+ ) /x;
1312 / \# [ \t]* ( [^ \t] .* ) /x;
1313
1314Which one you pick depends on which of these expressions better reflects
1315the above specification of comments.
1316
1317In some literature this construct is called "atomic matching" or
1318"possessive matching".
1319
1320Possessive quantifiers are equivalent to putting the item they are applied
1321to inside of one of these constructs. The following equivalences apply:
1322
1323 Quantifier Form Bracketing Form
1324 --------------- ---------------
1325 PAT*+ (?>PAT*)
1326 PAT++ (?>PAT+)
1327 PAT?+ (?>PAT?)
1328 PAT{min,max}+ (?>PAT{min,max})
1329
1330=back
1331
1332=head2 Special Backtracking Control Verbs
1333
1334B<WARNING:> These patterns are experimental and subject to change or
1335removal in a future version of Perl. Their usage in production code should
1336be noted to avoid problems during upgrades.
1337
1338These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1339otherwise stated the ARG argument is optional; in some cases, it is
1340forbidden.
1341
1342Any pattern containing a special backtracking verb that allows an argument
1343has the special behaviour that when executed it sets the current package's
1344C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1345rules apply:
1346
1347On failure, the C<$REGERROR> variable will be set to the ARG value of the
1348verb pattern, if the verb was involved in the failure of the match. If the
1349ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1350name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1351none. Also, the C<$REGMARK> variable will be set to FALSE.
1352
1353On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1354the C<$REGMARK> variable will be set to the name of the last
1355C<(*MARK:NAME)> pattern executed. See the explanation for the
1356C<(*MARK:NAME)> verb below for more details.
1357
1358B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1359and most other regex related variables. They are not local to a scope, nor
1360readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1361Use C<local> to localize changes to them to a specific scope if necessary.
1362
1363If a pattern does not contain a special backtracking verb that allows an
1364argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1365
1366=over 4
1367
1368=item Verbs that take an argument
1369
1370=over 4
1371
1372=item C<(*PRUNE)> C<(*PRUNE:NAME)>
1373X<(*PRUNE)> X<(*PRUNE:NAME)>
1374
1375This zero-width pattern prunes the backtracking tree at the current point
1376when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1377where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1378A may backtrack as necessary to match. Once it is reached, matching
1379continues in B, which may also backtrack as necessary; however, should B
1380not match, then no further backtracking will take place, and the pattern
1381will fail outright at the current starting position.
1382
1383The following example counts all the possible matching strings in a
1384pattern (without actually matching any of them).
1385
1386 'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1387 print "Count=$count\n";
1388
1389which produces:
1390
1391 aaab
1392 aaa
1393 aa
1394 a
1395 aab
1396 aa
1397 a
1398 ab
1399 a
1400 Count=9
1401
1402If we add a C<(*PRUNE)> before the count like the following
1403
1404 'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1405 print "Count=$count\n";
1406
1407we prevent backtracking and find the count of the longest matching
1408at each matching starting point like so:
1409
1410 aaab
1411 aab
1412 ab
1413 Count=3
1414
1415Any number of C<(*PRUNE)> assertions may be used in a pattern.
1416
1417See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1418control backtracking. In some cases, the use of C<(*PRUNE)> can be
1419replaced with a C<< (?>pattern) >> with no functional difference; however,
1420C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1421C<< (?>pattern) >> alone.
1422
1423
1424=item C<(*SKIP)> C<(*SKIP:NAME)>
1425X<(*SKIP)>
1426
1427This zero-width pattern is similar to C<(*PRUNE)>, except that on
1428failure it also signifies that whatever text that was matched leading up
1429to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1430of this pattern. This effectively means that the regex engine "skips" forward
1431to this position on failure and tries to match again, (assuming that
1432there is sufficient room to match).
1433
1434The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1435C<(*MARK:NAME)> was encountered while matching, then it is that position
1436which is used as the "skip point". If no C<(*MARK)> of that name was
1437encountered, then the C<(*SKIP)> operator has no effect. When used
1438without a name the "skip point" is where the match point was when
1439executing the (*SKIP) pattern.
1440
1441Compare the following to the examples in C<(*PRUNE)>, note the string
1442is twice as long:
1443
1444 'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1445 print "Count=$count\n";
1446
1447outputs
1448
1449 aaab
1450 aaab
1451 Count=2
1452
1453Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1454executed, the next starting point will be where the cursor was when the
1455C<(*SKIP)> was executed.
1456
1457=item C<(*MARK:NAME)> C<(*:NAME)>
1458X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1459
1460This zero-width pattern can be used to mark the point reached in a string
1461when a certain part of the pattern has been successfully matched. This
1462mark may be given a name. A later C<(*SKIP)> pattern will then skip
1463forward to that point if backtracked into on failure. Any number of
1464C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1465
1466In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1467can be used to "label" a pattern branch, so that after matching, the
1468program can determine which branches of the pattern were involved in the
1469match.
1470
1471When a match is successful, the C<$REGMARK> variable will be set to the
1472name of the most recently executed C<(*MARK:NAME)> that was involved
1473in the match.
1474
1475This can be used to determine which branch of a pattern was matched
1476without using a separate capture group for each branch, which in turn
1477can result in a performance improvement, as perl cannot optimize
1478C</(?:(x)|(y)|(z))/> as efficiently as something like
1479C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1480
1481When a match has failed, and unless another verb has been involved in
1482failing the match and has provided its own name to use, the C<$REGERROR>
1483variable will be set to the name of the most recently executed
1484C<(*MARK:NAME)>.
1485
1486See C<(*SKIP)> for more details.
1487
1488As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1489
1490=item C<(*THEN)> C<(*THEN:NAME)>
1491
1492This is similar to the "cut group" operator C<::> from Perl 6. Like
1493C<(*PRUNE)>, this verb always matches, and when backtracked into on
1494failure, it causes the regex engine to try the next alternation in the
1495innermost enclosing group (capturing or otherwise).
1496
1497Its name comes from the observation that this operation combined with the
1498alternation operator (C<|>) can be used to create what is essentially a
1499pattern-based if/then/else block:
1500
1501 ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1502
1503Note that if this operator is used and NOT inside of an alternation then
1504it acts exactly like the C<(*PRUNE)> operator.
1505
1506 / A (*PRUNE) B /
1507
1508is the same as
1509
1510 / A (*THEN) B /
1511
1512but
1513
1514 / ( A (*THEN) B | C (*THEN) D ) /
1515
1516is not the same as
1517
1518 / ( A (*PRUNE) B | C (*PRUNE) D ) /
1519
1520as after matching the A but failing on the B the C<(*THEN)> verb will
1521backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1522
1523=item C<(*COMMIT)>
1524X<(*COMMIT)>
1525
1526This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1527zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1528into on failure it causes the match to fail outright. No further attempts
1529to find a valid match by advancing the start pointer will occur again.
1530For example,
1531
1532 'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1533 print "Count=$count\n";
1534
1535outputs
1536
1537 aaab
1538 Count=1
1539
1540In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1541does not match, the regex engine will not try any further matching on the
1542rest of the string.
1543
1544=back
1545
1546=item Verbs without an argument
1547
1548=over 4
1549
1550=item C<(*FAIL)> C<(*F)>
1551X<(*FAIL)> X<(*F)>
1552
1553This pattern matches nothing and always fails. It can be used to force the
1554engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1555fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1556
1557It is probably useful only when combined with C<(?{})> or C<(??{})>.
1558
1559=item C<(*ACCEPT)>
1560X<(*ACCEPT)>
1561
1562B<WARNING:> This feature is highly experimental. It is not recommended
1563for production code.
1564
1565This pattern matches nothing and causes the end of successful matching at
1566the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1567whether there is actually more to match in the string. When inside of a
1568nested pattern, such as recursion, or in a subpattern dynamically generated
1569via C<(??{})>, only the innermost pattern is ended immediately.
1570
1571If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1572marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1573For instance:
1574
1575 'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1576
1577will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1578be set. If another branch in the inner parentheses were matched, such as in the
1579string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1580
1581=back
1582
1583=back
1584
1585=head2 Backtracking
1586X<backtrack> X<backtracking>
1587
1588NOTE: This section presents an abstract approximation of regular
1589expression behavior. For a more rigorous (and complicated) view of
1590the rules involved in selecting a match among possible alternatives,
1591see L<Combining RE Pieces>.
1592
1593A fundamental feature of regular expression matching involves the
1594notion called I<backtracking>, which is currently used (when needed)
1595by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1596C<+?>, C<{n,m}>, and C<{n,m}?>. Backtracking is often optimized
1597internally, but the general principle outlined here is valid.
1598
1599For a regular expression to match, the I<entire> regular expression must
1600match, not just part of it. So if the beginning of a pattern containing a
1601quantifier succeeds in a way that causes later parts in the pattern to
1602fail, the matching engine backs up and recalculates the beginning
1603part--that's why it's called backtracking.
1604
1605Here is an example of backtracking: Let's say you want to find the
1606word following "foo" in the string "Food is on the foo table.":
1607
1608 $_ = "Food is on the foo table.";
1609 if ( /\b(foo)\s+(\w+)/i ) {
1610 print "$2 follows $1.\n";
1611 }
1612
1613When the match runs, the first part of the regular expression (C<\b(foo)>)
1614finds a possible match right at the beginning of the string, and loads up
1615$1 with "Foo". However, as soon as the matching engine sees that there's
1616no whitespace following the "Foo" that it had saved in $1, it realizes its
1617mistake and starts over again one character after where it had the
1618tentative match. This time it goes all the way until the next occurrence
1619of "foo". The complete regular expression matches this time, and you get
1620the expected output of "table follows foo."
1621
1622Sometimes minimal matching can help a lot. Imagine you'd like to match
1623everything between "foo" and "bar". Initially, you write something
1624like this:
1625
1626 $_ = "The food is under the bar in the barn.";
1627 if ( /foo(.*)bar/ ) {
1628 print "got <$1>\n";
1629 }
1630
1631Which perhaps unexpectedly yields:
1632
1633 got <d is under the bar in the >
1634
1635That's because C<.*> was greedy, so you get everything between the
1636I<first> "foo" and the I<last> "bar". Here it's more effective
1637to use minimal matching to make sure you get the text between a "foo"
1638and the first "bar" thereafter.
1639
1640 if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1641 got <d is under the >
1642
1643Here's another example. Let's say you'd like to match a number at the end
1644of a string, and you also want to keep the preceding part of the match.
1645So you write this:
1646
1647 $_ = "I have 2 numbers: 53147";
1648 if ( /(.*)(\d*)/ ) { # Wrong!
1649 print "Beginning is <$1>, number is <$2>.\n";
1650 }
1651
1652That won't work at all, because C<.*> was greedy and gobbled up the
1653whole string. As C<\d*> can match on an empty string the complete
1654regular expression matched successfully.
1655
1656 Beginning is <I have 2 numbers: 53147>, number is <>.
1657
1658Here are some variants, most of which don't work:
1659
1660 $_ = "I have 2 numbers: 53147";
1661 @pats = qw{
1662 (.*)(\d*)
1663 (.*)(\d+)
1664 (.*?)(\d*)
1665 (.*?)(\d+)
1666 (.*)(\d+)$
1667 (.*?)(\d+)$
1668 (.*)\b(\d+)$
1669 (.*\D)(\d+)$
1670 };
1671
1672 for $pat (@pats) {
1673 printf "%-12s ", $pat;
1674 if ( /$pat/ ) {
1675 print "<$1> <$2>\n";
1676 } else {
1677 print "FAIL\n";
1678 }
1679 }
1680
1681That will print out:
1682
1683 (.*)(\d*) <I have 2 numbers: 53147> <>
1684 (.*)(\d+) <I have 2 numbers: 5314> <7>
1685 (.*?)(\d*) <> <>
1686 (.*?)(\d+) <I have > <2>
1687 (.*)(\d+)$ <I have 2 numbers: 5314> <7>
1688 (.*?)(\d+)$ <I have 2 numbers: > <53147>
1689 (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1690 (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1691
1692As you see, this can be a bit tricky. It's important to realize that a
1693regular expression is merely a set of assertions that gives a definition
1694of success. There may be 0, 1, or several different ways that the
1695definition might succeed against a particular string. And if there are
1696multiple ways it might succeed, you need to understand backtracking to
1697know which variety of success you will achieve.
1698
1699When using look-ahead assertions and negations, this can all get even
1700trickier. Imagine you'd like to find a sequence of non-digits not
1701followed by "123". You might try to write that as
1702
1703 $_ = "ABC123";
1704 if ( /^\D*(?!123)/ ) { # Wrong!
1705 print "Yup, no 123 in $_\n";
1706 }
1707
1708But that isn't going to match; at least, not the way you're hoping. It
1709claims that there is no 123 in the string. Here's a clearer picture of
1710why that pattern matches, contrary to popular expectations:
1711
1712 $x = 'ABC123';
1713 $y = 'ABC445';
1714
1715 print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1716 print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1717
1718 print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1719 print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1720
1721This prints
1722
1723 2: got ABC
1724 3: got AB
1725 4: got ABC
1726
1727You might have expected test 3 to fail because it seems to a more
1728general purpose version of test 1. The important difference between
1729them is that test 3 contains a quantifier (C<\D*>) and so can use
1730backtracking, whereas test 1 will not. What's happening is
1731that you've asked "Is it true that at the start of $x, following 0 or more
1732non-digits, you have something that's not 123?" If the pattern matcher had
1733let C<\D*> expand to "ABC", this would have caused the whole pattern to
1734fail.
1735
1736The search engine will initially match C<\D*> with "ABC". Then it will
1737try to match C<(?!123> with "123", which fails. But because
1738a quantifier (C<\D*>) has been used in the regular expression, the
1739search engine can backtrack and retry the match differently
1740in the hope of matching the complete regular expression.
1741
1742The pattern really, I<really> wants to succeed, so it uses the
1743standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1744time. Now there's indeed something following "AB" that is not
1745"123". It's "C123", which suffices.
1746
1747We can deal with this by using both an assertion and a negation.
1748We'll say that the first part in $1 must be followed both by a digit
1749and by something that's not "123". Remember that the look-aheads
1750are zero-width expressions--they only look, but don't consume any
1751of the string in their match. So rewriting this way produces what
1752you'd expect; that is, case 5 will fail, but case 6 succeeds:
1753
1754 print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1755 print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1756
1757 6: got ABC
1758
1759In other words, the two zero-width assertions next to each other work as though
1760they're ANDed together, just as you'd use any built-in assertions: C</^$/>
1761matches only if you're at the beginning of the line AND the end of the
1762line simultaneously. The deeper underlying truth is that juxtaposition in
1763regular expressions always means AND, except when you write an explicit OR
1764using the vertical bar. C</ab/> means match "a" AND (then) match "b",
1765although the attempted matches are made at different positions because "a"
1766is not a zero-width assertion, but a one-width assertion.
1767
1768B<WARNING>: Particularly complicated regular expressions can take
1769exponential time to solve because of the immense number of possible
1770ways they can use backtracking to try for a match. For example, without
1771internal optimizations done by the regular expression engine, this will
1772take a painfully long time to run:
1773
1774 'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1775
1776And if you used C<*>'s in the internal groups instead of limiting them
1777to 0 through 5 matches, then it would take forever--or until you ran
1778out of stack space. Moreover, these internal optimizations are not
1779always applicable. For example, if you put C<{0,5}> instead of C<*>
1780on the external group, no current optimization is applicable, and the
1781match takes a long time to finish.
1782
1783A powerful tool for optimizing such beasts is what is known as an
1784"independent group",
1785which does not backtrack (see L<C<< (?>pattern) >>>). Note also that
1786zero-length look-ahead/look-behind assertions will not backtrack to make
1787the tail match, since they are in "logical" context: only
1788whether they match is considered relevant. For an example
1789where side-effects of look-ahead I<might> have influenced the
1790following match, see L<C<< (?>pattern) >>>.
1791
1792=head2 Version 8 Regular Expressions
1793X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1794
1795In case you're not familiar with the "regular" Version 8 regex
1796routines, here are the pattern-matching rules not described above.
1797
1798Any single character matches itself, unless it is a I<metacharacter>
1799with a special meaning described here or above. You can cause
1800characters that normally function as metacharacters to be interpreted
1801literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1802character; "\\" matches a "\"). This escape mechanism is also required
1803for the character used as the pattern delimiter.
1804
1805A series of characters matches that series of characters in the target
1806string, so the pattern C<blurfl> would match "blurfl" in the target
1807string.
1808
1809You can specify a character class, by enclosing a list of characters
1810in C<[]>, which will match any character from the list. If the
1811first character after the "[" is "^", the class matches any character not
1812in the list. Within a list, the "-" character specifies a
1813range, so that C<a-z> represents all characters between "a" and "z",
1814inclusive. If you want either "-" or "]" itself to be a member of a
1815class, put it at the start of the list (possibly after a "^"), or
1816escape it with a backslash. "-" is also taken literally when it is
1817at the end of the list, just before the closing "]". (The
1818following all specify the same class of three characters: C<[-az]>,
1819C<[az-]>, and C<[a\-z]>. All are different from C<[a-z]>, which
1820specifies a class containing twenty-six characters, even on EBCDIC-based
1821character sets.) Also, if you try to use the character
1822classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1823a range, the "-" is understood literally.
1824
1825Note also that the whole range idea is rather unportable between
1826character sets--and even within character sets they may cause results
1827you probably didn't expect. A sound principle is to use only ranges
1828that begin from and end at either alphabetics of equal case ([a-e],
1829[A-E]), or digits ([0-9]). Anything else is unsafe. If in doubt,
1830spell out the character sets in full.
1831
1832Characters may be specified using a metacharacter syntax much like that
1833used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1834"\f" a form feed, etc. More generally, \I<nnn>, where I<nnn> is a string
1835of three octal digits, matches the character whose coded character set value
1836is I<nnn>. Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1837matches the character whose ordinal is I<nn>. The expression \cI<x>
1838matches the character control-I<x>. Finally, the "." metacharacter
1839matches any character except "\n" (unless you use C</s>).
1840
1841You can specify a series of alternatives for a pattern using "|" to
1842separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1843or "foe" in the target string (as would C<f(e|i|o)e>). The
1844first alternative includes everything from the last pattern delimiter
1845("(", "[", or the beginning of the pattern) up to the first "|", and
1846the last alternative contains everything from the last "|" to the next
1847pattern delimiter. That's why it's common practice to include
1848alternatives in parentheses: to minimize confusion about where they
1849start and end.
1850
1851Alternatives are tried from left to right, so the first
1852alternative found for which the entire expression matches, is the one that
1853is chosen. This means that alternatives are not necessarily greedy. For
1854example: when matching C<foo|foot> against "barefoot", only the "foo"
1855part will match, as that is the first alternative tried, and it successfully
1856matches the target string. (This might not seem important, but it is
1857important when you are capturing matched text using parentheses.)
1858
1859Also remember that "|" is interpreted as a literal within square brackets,
1860so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1861
1862Within a pattern, you may designate subpatterns for later reference
1863by enclosing them in parentheses, and you may refer back to the
1864I<n>th subpattern later in the pattern using the metacharacter
1865\I<n>. Subpatterns are numbered based on the left to right order
1866of their opening parenthesis. A backreference matches whatever
1867actually matched the subpattern in the string being examined, not
1868the rules for that subpattern. Therefore, C<(0|0x)\d*\s\g1\d*> will
1869match "0x1234 0x4321", but not "0x1234 01234", because subpattern
18701 matched "0x", even though the rule C<0|0x> could potentially match
1871the leading 0 in the second number.
1872
1873=head2 Warning on \1 Instead of $1
1874
1875Some people get too used to writing things like:
1876
1877 $pattern =~ s/(\W)/\\\1/g;
1878
1879This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
1880shocking the
1881B<sed> addicts, but it's a dirty habit to get into. That's because in
1882PerlThink, the righthand side of an C<s///> is a double-quoted string. C<\1> in
1883the usual double-quoted string means a control-A. The customary Unix
1884meaning of C<\1> is kludged in for C<s///>. However, if you get into the habit
1885of doing that, you get yourself into trouble if you then add an C</e>
1886modifier.
1887
1888 s/(\d+)/ \1 + 1 /eg; # causes warning under -w
1889
1890Or if you try to do
1891
1892 s/(\d+)/\1000/;
1893
1894You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1895C<${1}000>. The operation of interpolation should not be confused
1896with the operation of matching a backreference. Certainly they mean two
1897different things on the I<left> side of the C<s///>.
1898
1899=head2 Repeated Patterns Matching a Zero-length Substring
1900
1901B<WARNING>: Difficult material (and prose) ahead. This section needs a rewrite.
1902
1903Regular expressions provide a terse and powerful programming language. As
1904with most other power tools, power comes together with the ability
1905to wreak havoc.
1906
1907A common abuse of this power stems from the ability to make infinite
1908loops using regular expressions, with something as innocuous as:
1909
1910 'foo' =~ m{ ( o? )* }x;
1911
1912The C<o?> matches at the beginning of C<'foo'>, and since the position
1913in the string is not moved by the match, C<o?> would match again and again
1914because of the C<*> quantifier. Another common way to create a similar cycle
1915is with the looping modifier C<//g>:
1916
1917 @matches = ( 'foo' =~ m{ o? }xg );
1918
1919or
1920
1921 print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1922
1923or the loop implied by split().
1924
1925However, long experience has shown that many programming tasks may
1926be significantly simplified by using repeated subexpressions that
1927may match zero-length substrings. Here's a simple example being:
1928
1929 @chars = split //, $string; # // is not magic in split
1930 ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1931
1932Thus Perl allows such constructs, by I<forcefully breaking
1933the infinite loop>. The rules for this are different for lower-level
1934loops given by the greedy quantifiers C<*+{}>, and for higher-level
1935ones like the C</g> modifier or split() operator.
1936
1937The lower-level loops are I<interrupted> (that is, the loop is
1938broken) when Perl detects that a repeated expression matched a
1939zero-length substring. Thus
1940
1941 m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1942
1943is made equivalent to
1944
1945 m{ (?: NON_ZERO_LENGTH )*
1946 |
1947 (?: ZERO_LENGTH )?
1948 }x;
1949
1950The higher level-loops preserve an additional state between iterations:
1951whether the last match was zero-length. To break the loop, the following
1952match after a zero-length match is prohibited to have a length of zero.
1953This prohibition interacts with backtracking (see L<"Backtracking">),
1954and so the I<second best> match is chosen if the I<best> match is of
1955zero length.
1956
1957For example:
1958
1959 $_ = 'bar';
1960 s/\w??/<$&>/g;
1961
1962results in C<< <><b><><a><><r><> >>. At each position of the string the best
1963match given by non-greedy C<??> is the zero-length match, and the I<second
1964best> match is what is matched by C<\w>. Thus zero-length matches
1965alternate with one-character-long matches.
1966
1967Similarly, for repeated C<m/()/g> the second-best match is the match at the
1968position one notch further in the string.
1969
1970The additional state of being I<matched with zero-length> is associated with
1971the matched string, and is reset by each assignment to pos().
1972Zero-length matches at the end of the previous match are ignored
1973during C<split>.
1974
1975=head2 Combining RE Pieces
1976
1977Each of the elementary pieces of regular expressions which were described
1978before (such as C<ab> or C<\Z>) could match at most one substring
1979at the given position of the input string. However, in a typical regular
1980expression these elementary pieces are combined into more complicated
1981patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1982(in these examples C<S> and C<T> are regular subexpressions).
1983
1984Such combinations can include alternatives, leading to a problem of choice:
1985if we match a regular expression C<a|ab> against C<"abc">, will it match
1986substring C<"a"> or C<"ab">? One way to describe which substring is
1987actually matched is the concept of backtracking (see L<"Backtracking">).
1988However, this description is too low-level and makes you think
1989in terms of a particular implementation.
1990
1991Another description starts with notions of "better"/"worse". All the
1992substrings which may be matched by the given regular expression can be
1993sorted from the "best" match to the "worst" match, and it is the "best"
1994match which is chosen. This substitutes the question of "what is chosen?"
1995by the question of "which matches are better, and which are worse?".
1996
1997Again, for elementary pieces there is no such question, since at most
1998one match at a given position is possible. This section describes the
1999notion of better/worse for combining operators. In the description
2000below C<S> and C<T> are regular subexpressions.
2001
2002=over 4
2003
2004=item C<ST>
2005
2006Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2007substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2008which can be matched by C<T>.
2009
2010If C<A> is better match for C<S> than C<A'>, C<AB> is a better
2011match than C<A'B'>.
2012
2013If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2014C<B> is better match for C<T> than C<B'>.
2015
2016=item C<S|T>
2017
2018When C<S> can match, it is a better match than when only C<T> can match.
2019
2020Ordering of two matches for C<S> is the same as for C<S>. Similar for
2021two matches for C<T>.
2022
2023=item C<S{REPEAT_COUNT}>
2024
2025Matches as C<SSS...S> (repeated as many times as necessary).
2026
2027=item C<S{min,max}>
2028
2029Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2030
2031=item C<S{min,max}?>
2032
2033Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2034
2035=item C<S?>, C<S*>, C<S+>
2036
2037Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2038
2039=item C<S??>, C<S*?>, C<S+?>
2040
2041Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2042
2043=item C<< (?>S) >>
2044
2045Matches the best match for C<S> and only that.
2046
2047=item C<(?=S)>, C<(?<=S)>
2048
2049Only the best match for C<S> is considered. (This is important only if
2050C<S> has capturing parentheses, and backreferences are used somewhere
2051else in the whole regular expression.)
2052
2053=item C<(?!S)>, C<(?<!S)>
2054
2055For this grouping operator there is no need to describe the ordering, since
2056only whether or not C<S> can match is important.
2057
2058=item C<(??{ EXPR })>, C<(?PARNO)>
2059
2060The ordering is the same as for the regular expression which is
2061the result of EXPR, or the pattern contained by capture group PARNO.
2062
2063=item C<(?(condition)yes-pattern|no-pattern)>
2064
2065Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2066already determined. The ordering of the matches is the same as for the
2067chosen subexpression.
2068
2069=back
2070
2071The above recipes describe the ordering of matches I<at a given position>.
2072One more rule is needed to understand how a match is determined for the
2073whole regular expression: a match at an earlier position is always better
2074than a match at a later position.
2075
2076=head2 Creating Custom RE Engines
2077
2078Overloaded constants (see L<overload>) provide a simple way to extend
2079the functionality of the RE engine.
2080
2081Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2082matches at a boundary between whitespace characters and non-whitespace
2083characters. Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2084at these positions, so we want to have each C<\Y|> in the place of the
2085more complicated version. We can create a module C<customre> to do
2086this:
2087
2088 package customre;
2089 use overload;
2090
2091 sub import {
2092 shift;
2093 die "No argument to customre::import allowed" if @_;
2094 overload::constant 'qr' => \&convert;
2095 }
2096
2097 sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2098
2099 # We must also take care of not escaping the legitimate \\Y|
2100 # sequence, hence the presence of '\\' in the conversion rules.
2101 my %rules = ( '\\' => '\\\\',
2102 'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2103 sub convert {
2104 my $re = shift;
2105 $re =~ s{
2106 \\ ( \\ | Y . )
2107 }
2108 { $rules{$1} or invalid($re,$1) }sgex;
2109 return $re;
2110 }
2111
2112Now C<use customre> enables the new escape in constant regular
2113expressions, i.e., those without any runtime variable interpolations.
2114As documented in L<overload>, this conversion will work only over
2115literal parts of regular expressions. For C<\Y|$re\Y|> the variable
2116part of this regular expression needs to be converted explicitly
2117(but only if the special meaning of C<\Y|> should be enabled inside $re):
2118
2119 use customre;
2120 $re = <>;
2121 chomp $re;
2122 $re = customre::convert $re;
2123 /\Y|$re\Y|/;
2124
2125=head1 PCRE/Python Support
2126
2127As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2128to the regex syntax. While Perl programmers are encouraged to use the
2129Perl specific syntax, the following are also accepted:
2130
2131=over 4
2132
2133=item C<< (?PE<lt>NAMEE<gt>pattern) >>
2134
2135Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2136
2137=item C<< (?P=NAME) >>
2138
2139Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2140
2141=item C<< (?P>NAME) >>
2142
2143Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2144
2145=back
2146
2147=head1 BUGS
2148
2149There are numerous problems with case insensitive matching of characters
2150outside the ASCII range, especially with those whose folds are multiple
2151characters, such as ligatures like C<LATIN SMALL LIGATURE FF>.
2152
2153In a bracketed character class with case insensitive matching, ranges only work
2154for ASCII characters. For example,
2155C<m/[\N{CYRILLIC CAPITAL LETTER A}-\N{CYRILLIC CAPITAL LETTER YA}]/i>
2156doesn't match all the Russian upper and lower case letters.
2157
2158Many regular expression constructs don't work on EBCDIC platforms.
2159
2160This document varies from difficult to understand to completely
2161and utterly opaque. The wandering prose riddled with jargon is
2162hard to fathom in several places.
2163
2164This document needs a rewrite that separates the tutorial content
2165from the reference content.
2166
2167=head1 SEE ALSO
2168
2169L<perlrequick>.
2170
2171L<perlretut>.
2172
2173L<perlop/"Regexp Quote-Like Operators">.
2174
2175L<perlop/"Gory details of parsing quoted constructs">.
2176
2177L<perlfaq6>.
2178
2179L<perlfunc/pos>.
2180
2181L<perllocale>.
2182
2183L<perlebcdic>.
2184
2185I<Mastering Regular Expressions> by Jeffrey Friedl, published
2186by O'Reilly and Associates.