| 1 | =head1 NAME |
| 2 | |
| 3 | perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes |
| 4 | |
| 5 | =head1 DESCRIPTION |
| 6 | |
| 7 | The top level documentation about Perl regular expressions |
| 8 | is found in L<perlre>. |
| 9 | |
| 10 | This document describes all backslash and escape sequences. After |
| 11 | explaining the role of the backslash, it lists all the sequences that have |
| 12 | a special meaning in Perl regular expressions (in alphabetical order), |
| 13 | then describes each of them. |
| 14 | |
| 15 | Most sequences are described in detail in different documents; the primary |
| 16 | purpose of this document is to have a quick reference guide describing all |
| 17 | backslash and escape sequences. |
| 18 | |
| 19 | =head2 The backslash |
| 20 | |
| 21 | In a regular expression, the backslash can perform one of two tasks: |
| 22 | it either takes away the special meaning of the character following it |
| 23 | (for instance, C<\|> matches a vertical bar, it's not an alternation), |
| 24 | or it is the start of a backslash or escape sequence. |
| 25 | |
| 26 | The rules determining what it is are quite simple: if the character |
| 27 | following the backslash is an ASCII punctuation (non-word) character (that is, |
| 28 | anything that is not a letter, digit or underscore), then the backslash just |
| 29 | takes away the special meaning (if any) of the character following it. |
| 30 | |
| 31 | If the character following the backslash is an ASCII letter or an ASCII digit, |
| 32 | then the sequence may be special; if so, it's listed below. A few letters have |
| 33 | not been used yet, so escaping them with a backslash doesn't change them to be |
| 34 | special. A future version of Perl may assign a special meaning to them, so if |
| 35 | you have warnings turned on, Perl will issue a warning if you use such a |
| 36 | sequence. [1]. |
| 37 | |
| 38 | It is however guaranteed that backslash or escape sequences never have a |
| 39 | punctuation character following the backslash, not now, and not in a future |
| 40 | version of Perl 5. So it is safe to put a backslash in front of a non-word |
| 41 | character. |
| 42 | |
| 43 | Note that the backslash itself is special; if you want to match a backslash, |
| 44 | you have to escape the backslash with a backslash: C</\\/> matches a single |
| 45 | backslash. |
| 46 | |
| 47 | =over 4 |
| 48 | |
| 49 | =item [1] |
| 50 | |
| 51 | There is one exception. If you use an alphanumerical character as the |
| 52 | delimiter of your pattern (which you probably shouldn't do for readability |
| 53 | reasons), you will have to escape the delimiter if you want to match |
| 54 | it. Perl won't warn then. See also L<perlop/Gory details of parsing |
| 55 | quoted constructs>. |
| 56 | |
| 57 | =back |
| 58 | |
| 59 | |
| 60 | =head2 All the sequences and escapes |
| 61 | |
| 62 | Those not usable within a bracketed character class (like C<[\da-z]>) are marked |
| 63 | as C<Not in [].> |
| 64 | |
| 65 | \000 Octal escape sequence. See also \o{}. |
| 66 | \1 Absolute backreference. Not in []. |
| 67 | \a Alarm or bell. |
| 68 | \A Beginning of string. Not in []. |
| 69 | \b Word/non-word boundary. (Backspace in []). |
| 70 | \B Not a word/non-word boundary. Not in []. |
| 71 | \cX Control-X |
| 72 | \C Single octet, even under UTF-8. Not in []. |
| 73 | \d Character class for digits. |
| 74 | \D Character class for non-digits. |
| 75 | \e Escape character. |
| 76 | \E Turn off \Q, \L and \U processing. Not in []. |
| 77 | \f Form feed. |
| 78 | \g{}, \g1 Named, absolute or relative backreference. Not in [] |
| 79 | \G Pos assertion. Not in []. |
| 80 | \h Character class for horizontal whitespace. |
| 81 | \H Character class for non horizontal whitespace. |
| 82 | \k{}, \k<>, \k'' Named backreference. Not in []. |
| 83 | \K Keep the stuff left of \K. Not in []. |
| 84 | \l Lowercase next character. Not in []. |
| 85 | \L Lowercase till \E. Not in []. |
| 86 | \n (Logical) newline character. |
| 87 | \N Any character but newline. Experimental. Not in []. |
| 88 | \N{} Named or numbered (Unicode) character or sequence. |
| 89 | \o{} Octal escape sequence. |
| 90 | \p{}, \pP Character with the given Unicode property. |
| 91 | \P{}, \PP Character without the given Unicode property. |
| 92 | \Q Quotemeta till \E. Not in []. |
| 93 | \r Return character. |
| 94 | \R Generic new line. Not in []. |
| 95 | \s Character class for whitespace. |
| 96 | \S Character class for non whitespace. |
| 97 | \t Tab character. |
| 98 | \u Titlecase next character. Not in []. |
| 99 | \U Uppercase till \E. Not in []. |
| 100 | \v Character class for vertical whitespace. |
| 101 | \V Character class for non vertical whitespace. |
| 102 | \w Character class for word characters. |
| 103 | \W Character class for non-word characters. |
| 104 | \x{}, \x00 Hexadecimal escape sequence. |
| 105 | \X Unicode "extended grapheme cluster". Not in []. |
| 106 | \z End of string. Not in []. |
| 107 | \Z End of string. Not in []. |
| 108 | |
| 109 | =head2 Character Escapes |
| 110 | |
| 111 | =head3 Fixed characters |
| 112 | |
| 113 | A handful of characters have a dedicated I<character escape>. The following |
| 114 | table shows them, along with their ASCII code points (in decimal and hex), |
| 115 | their ASCII name, the control escape on ASCII platforms and a short |
| 116 | description. (For EBCDIC platforms, see L<perlebcdic/OPERATOR DIFFERENCES>.) |
| 117 | |
| 118 | Seq. Code Point ASCII Cntrl Description. |
| 119 | Dec Hex |
| 120 | \a 7 07 BEL \cG alarm or bell |
| 121 | \b 8 08 BS \cH backspace [1] |
| 122 | \e 27 1B ESC \c[ escape character |
| 123 | \f 12 0C FF \cL form feed |
| 124 | \n 10 0A LF \cJ line feed [2] |
| 125 | \r 13 0D CR \cM carriage return |
| 126 | \t 9 09 TAB \cI tab |
| 127 | |
| 128 | =over 4 |
| 129 | |
| 130 | =item [1] |
| 131 | |
| 132 | C<\b> is the backspace character only inside a character class. Outside a |
| 133 | character class, C<\b> is a word/non-word boundary. |
| 134 | |
| 135 | =item [2] |
| 136 | |
| 137 | C<\n> matches a logical newline. Perl will convert between C<\n> and your |
| 138 | OS's native newline character when reading from or writing to text files. |
| 139 | |
| 140 | =back |
| 141 | |
| 142 | =head4 Example |
| 143 | |
| 144 | $str =~ /\t/; # Matches if $str contains a (horizontal) tab. |
| 145 | |
| 146 | =head3 Control characters |
| 147 | |
| 148 | C<\c> is used to denote a control character; the character following C<\c> |
| 149 | determines the value of the construct. For example the value of C<\cA> is |
| 150 | C<chr(1)>, and the value of C<\cb> is C<chr(2)>, etc. |
| 151 | The gory details are in L<perlop/"Regexp Quote-Like Operators">. A complete |
| 152 | list of what C<chr(1)>, etc. means for ASCII and EBCDIC platforms is in |
| 153 | L<perlebcdic/OPERATOR DIFFERENCES>. |
| 154 | |
| 155 | Note that C<\c\> alone at the end of a regular expression (or doubled-quoted |
| 156 | string) is not valid. The backslash must be followed by another character. |
| 157 | That is, C<\c\I<X>> means C<chr(28) . 'I<X>'> for all characters I<X>. |
| 158 | |
| 159 | To write platform-independent code, you must use C<\N{I<NAME>}> instead, like |
| 160 | C<\N{ESCAPE}> or C<\N{U+001B}>, see L<charnames>. |
| 161 | |
| 162 | Mnemonic: I<c>ontrol character. |
| 163 | |
| 164 | =head4 Example |
| 165 | |
| 166 | $str =~ /\cK/; # Matches if $str contains a vertical tab (control-K). |
| 167 | |
| 168 | =head3 Named or numbered characters and character sequences |
| 169 | |
| 170 | Unicode characters have a Unicode name and numeric ordinal value. Use the |
| 171 | C<\N{}> construct to specify a character by either of these values. |
| 172 | Certain sequences of characters also have names. |
| 173 | |
| 174 | To specify by name, the name of the character or character sequence goes |
| 175 | between the curly braces. In this case, you have to C<use charnames> to |
| 176 | load the Unicode names of the characters, otherwise Perl will complain. |
| 177 | |
| 178 | To specify a character by Unicode code point, use the form |
| 179 | C<\N{U+I<wide hex character>}>, where I<wide hex character> is a number in |
| 180 | hexadecimal that gives the ordinal number that Unicode has assigned to the |
| 181 | desired character. It is customary (but not required) to use leading zeros to |
| 182 | pad the number to 4 digits. Thus C<\N{U+0041}> means |
| 183 | C<LATIN CAPITAL LETTER A>, and you will rarely see it written without the two |
| 184 | leading zeros. C<\N{U+0041}> means "A" even on EBCDIC machines (where the |
| 185 | ordinal value of "A" is not 0x41). |
| 186 | |
| 187 | It is even possible to give your own names to characters and character |
| 188 | sequences. For details, see L<charnames>. |
| 189 | |
| 190 | (There is an expanded internal form that you may see in debug output: |
| 191 | C<\N{U+I<wide hex character>.I<wide hex character>...}>. |
| 192 | The C<...> means any number of these I<wide hex character>s separated by dots. |
| 193 | This represents the sequence formed by the characters. This is an internal |
| 194 | form only, subject to change, and you should not try to use it yourself.) |
| 195 | |
| 196 | Mnemonic: I<N>amed character. |
| 197 | |
| 198 | Note that a character or character sequence that is expressed as a named |
| 199 | or numbered character is considered as a character without special |
| 200 | meaning by the regex engine, and will match "as is". |
| 201 | |
| 202 | =head4 Example |
| 203 | |
| 204 | use charnames ':full'; # Loads the Unicode names. |
| 205 | $str =~ /\N{THAI CHARACTER SO SO}/; # Matches the Thai SO SO character |
| 206 | |
| 207 | use charnames 'Cyrillic'; # Loads Cyrillic names. |
| 208 | $str =~ /\N{ZHE}\N{KA}/; # Match "ZHE" followed by "KA". |
| 209 | |
| 210 | =head3 Octal escapes |
| 211 | |
| 212 | There are two forms of octal escapes. Each is used to specify a character by |
| 213 | its ordinal, specified in octal notation. |
| 214 | |
| 215 | One form, available starting in Perl 5.14 looks like C<\o{...}>, where the dots |
| 216 | represent one or more octal digits. It can be used for any Unicode character. |
| 217 | |
| 218 | It was introduced to avoid the potential problems with the other form, |
| 219 | available in all Perls. That form consists of a backslash followed by three |
| 220 | octal digits. One problem with this form is that it can look exactly like an |
| 221 | old-style backreference (see |
| 222 | L</Disambiguation rules between old-style octal escapes and backreferences> |
| 223 | below.) You can avoid this by making the first of the three digits always a |
| 224 | zero, but that makes \077 the largest ordinal unambiguously specifiable by this |
| 225 | form. |
| 226 | |
| 227 | In some contexts, a backslash followed by two or even one octal digits may be |
| 228 | interpreted as an octal escape, sometimes with a warning, and because of some |
| 229 | bugs, sometimes with surprising results. Also, if you are creating a regex |
| 230 | out of smaller snippets concatentated together, and you use fewer than three |
| 231 | digits, the beginning of one snippet may be interpreted as adding digits to the |
| 232 | ending of the snippet before it. See L</Absolute referencing> for more |
| 233 | discussion and examples of the snippet problem. |
| 234 | |
| 235 | Note that a character that is expressed as an octal escape is considered |
| 236 | as a character without special meaning by the regex engine, and will match |
| 237 | "as is". |
| 238 | |
| 239 | To summarize, the C<\o{}> form is always safe to use, and the other form is |
| 240 | safe to use for ordinals up through \077 when you use exactly three digits to |
| 241 | specify them. |
| 242 | |
| 243 | Mnemonic: I<0>ctal or I<o>ctal. |
| 244 | |
| 245 | =head4 Examples (assuming an ASCII platform) |
| 246 | |
| 247 | $str = "Perl"; |
| 248 | $str =~ /\o{120}/; # Match, "\120" is "P". |
| 249 | $str =~ /\120/; # Same. |
| 250 | $str =~ /\o{120}+/; # Match, "\120" is "P", it's repeated at least once |
| 251 | $str =~ /\120+/; # Same. |
| 252 | $str =~ /P\053/; # No match, "\053" is "+" and taken literally. |
| 253 | /\o{23073}/ # Black foreground, white background smiling face. |
| 254 | /\o{4801234567}/ # Raises a warning, and yields chr(4) |
| 255 | |
| 256 | =head4 Disambiguation rules between old-style octal escapes and backreferences |
| 257 | |
| 258 | Octal escapes of the C<\000> form outside of bracketed character classes |
| 259 | potentially clash with old-style backreferences. (see L</Absolute referencing> |
| 260 | below). They both consist of a backslash followed by numbers. So Perl has to |
| 261 | use heuristics to determine whether it is a backreference or an octal escape. |
| 262 | Perl uses the following rules to disambiguate: |
| 263 | |
| 264 | =over 4 |
| 265 | |
| 266 | =item 1 |
| 267 | |
| 268 | If the backslash is followed by a single digit, it's a backreference. |
| 269 | |
| 270 | =item 2 |
| 271 | |
| 272 | If the first digit following the backslash is a 0, it's an octal escape. |
| 273 | |
| 274 | =item 3 |
| 275 | |
| 276 | If the number following the backslash is N (in decimal), and Perl already has |
| 277 | seen N capture groups, Perl will consider this to be a backreference. |
| 278 | Otherwise, it will consider it to be an octal escape. Note that if N has more |
| 279 | than three digits, Perl only takes the first three for the octal escape; |
| 280 | the rest are matched as is. |
| 281 | |
| 282 | my $pat = "(" x 999; |
| 283 | $pat .= "a"; |
| 284 | $pat .= ")" x 999; |
| 285 | /^($pat)\1000$/; # Matches 'aa'; there are 1000 capture groups. |
| 286 | /^$pat\1000$/; # Matches 'a@0'; there are 999 capture groups |
| 287 | # and \1000 is seen as \100 (a '@') and a '0' |
| 288 | |
| 289 | =back |
| 290 | |
| 291 | You can the force a backreference interpretation always by using the C<\g{...}> |
| 292 | form. You can the force an octal interpretation always by using the C<\o{...}> |
| 293 | form, or for numbers up through \077 (= 63 decimal), by using three digits, |
| 294 | beginning with a "0". |
| 295 | |
| 296 | =head3 Hexadecimal escapes |
| 297 | |
| 298 | Like octal escapes, there are two forms of hexadecimal escapes, but both start |
| 299 | with the same thing, C<\x>. This is followed by either exactly two hexadecimal |
| 300 | digits forming a number, or a hexadecimal number of arbitrary length surrounded |
| 301 | by curly braces. The hexadecimal number is the code point of the character you |
| 302 | want to express. |
| 303 | |
| 304 | Note that a character that is expressed as one of these escapes is considered |
| 305 | as a character without special meaning by the regex engine, and will match |
| 306 | "as is". |
| 307 | |
| 308 | Mnemonic: heI<x>adecimal. |
| 309 | |
| 310 | =head4 Examples (assuming an ASCII platform) |
| 311 | |
| 312 | $str = "Perl"; |
| 313 | $str =~ /\x50/; # Match, "\x50" is "P". |
| 314 | $str =~ /\x50+/; # Match, "\x50" is "P", it is repeated at least once |
| 315 | $str =~ /P\x2B/; # No match, "\x2B" is "+" and taken literally. |
| 316 | |
| 317 | /\x{2603}\x{2602}/ # Snowman with an umbrella. |
| 318 | # The Unicode character 2603 is a snowman, |
| 319 | # the Unicode character 2602 is an umbrella. |
| 320 | /\x{263B}/ # Black smiling face. |
| 321 | /\x{263b}/ # Same, the hex digits A - F are case insensitive. |
| 322 | |
| 323 | =head2 Modifiers |
| 324 | |
| 325 | A number of backslash sequences have to do with changing the character, |
| 326 | or characters following them. C<\l> will lowercase the character following |
| 327 | it, while C<\u> will uppercase (or, more accurately, titlecase) the |
| 328 | character following it. (They perform similar functionality as the |
| 329 | functions C<lcfirst> and C<ucfirst>). |
| 330 | |
| 331 | To uppercase or lowercase several characters, one might want to use |
| 332 | C<\L> or C<\U>, which will lowercase/uppercase all characters following |
| 333 | them, until either the end of the pattern, or the next occurrence of |
| 334 | C<\E>, whatever comes first. They perform similar functionality as the |
| 335 | functions C<lc> and C<uc> do. |
| 336 | |
| 337 | C<\Q> is used to escape all characters following, up to the next C<\E> |
| 338 | or the end of the pattern. C<\Q> adds a backslash to any character that |
| 339 | isn't a letter, digit or underscore. This will ensure that any character |
| 340 | between C<\Q> and C<\E> is matched literally, and will not be interpreted |
| 341 | by the regexp engine. |
| 342 | |
| 343 | Mnemonic: I<L>owercase, I<U>ppercase, I<Q>uotemeta, I<E>nd. |
| 344 | |
| 345 | =head4 Examples |
| 346 | |
| 347 | $sid = "sid"; |
| 348 | $greg = "GrEg"; |
| 349 | $miranda = "(Miranda)"; |
| 350 | $str =~ /\u$sid/; # Matches 'Sid' |
| 351 | $str =~ /\L$greg/; # Matches 'greg' |
| 352 | $str =~ /\Q$miranda\E/; # Matches '(Miranda)', as if the pattern |
| 353 | # had been written as /\(Miranda\)/ |
| 354 | |
| 355 | =head2 Character classes |
| 356 | |
| 357 | Perl regular expressions have a large range of character classes. Some of |
| 358 | the character classes are written as a backslash sequence. We will briefly |
| 359 | discuss those here; full details of character classes can be found in |
| 360 | L<perlrecharclass>. |
| 361 | |
| 362 | C<\w> is a character class that matches any single I<word> character |
| 363 | (letters, digits, Unicode marks, and connector punctuation (like the |
| 364 | underscore)). C<\d> is a character class that matches any decimal |
| 365 | digit, while the character class C<\s> matches any whitespace character. |
| 366 | New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal |
| 367 | and vertical whitespace characters. |
| 368 | |
| 369 | The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are |
| 370 | character classes that match, respectively, any character that isn't a |
| 371 | word character, digit, whitespace, horizontal whitespace, or vertical |
| 372 | whitespace. |
| 373 | |
| 374 | Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical. |
| 375 | |
| 376 | =head3 Unicode classes |
| 377 | |
| 378 | C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to |
| 379 | match a character that matches the given Unicode property; properties |
| 380 | include things like "letter", or "thai character". Capitalizing the |
| 381 | sequence to C<\PP> and C<\P{Property}> make the sequence match a character |
| 382 | that doesn't match the given Unicode property. For more details, see |
| 383 | L<perlrecharclass/Backslash sequences> and |
| 384 | L<perlunicode/Unicode Character Properties>. |
| 385 | |
| 386 | Mnemonic: I<p>roperty. |
| 387 | |
| 388 | =head2 Referencing |
| 389 | |
| 390 | If capturing parenthesis are used in a regular expression, we can refer |
| 391 | to the part of the source string that was matched, and match exactly the |
| 392 | same thing. There are three ways of referring to such I<backreference>: |
| 393 | absolutely, relatively, and by name. |
| 394 | |
| 395 | =for later add link to perlrecapture |
| 396 | |
| 397 | =head3 Absolute referencing |
| 398 | |
| 399 | Either C<\gI<N>> (starting in Perl 5.10.0), or C<\I<N>> (old-style) where I<N> |
| 400 | is a positive (unsigned) decimal number of any length is an absolute reference |
| 401 | to a capturing group. |
| 402 | |
| 403 | I<N> refers to the Nth set of parentheses, so C<\gI<N>> refers to whatever has |
| 404 | been matched by that set of parentheses. Thus C<\g1> refers to the first |
| 405 | capture group in the regex. |
| 406 | |
| 407 | The C<\gI<N>> form can be equivalently written as C<\g{I<N>}> |
| 408 | which avoids ambiguity when building a regex by concatenating shorter |
| 409 | strings. Otherwise if you had a regex C<qr/$a$b/>, and C<$a> contained |
| 410 | C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which is |
| 411 | probably not what you intended. |
| 412 | |
| 413 | In the C<\I<N>> form, I<N> must not begin with a "0", and there must be at |
| 414 | least I<N> capturing groups, or else I<N> will be considered an octal escape |
| 415 | (but something like C<\18> is the same as C<\0018>, that is the octal escape |
| 416 | C<"\001"> followed by a literal digit C<"8">). |
| 417 | |
| 418 | Mnemonic: I<g>roup. |
| 419 | |
| 420 | =head4 Examples |
| 421 | |
| 422 | /(\w+) \g1/; # Finds a duplicated word, (e.g. "cat cat"). |
| 423 | /(\w+) \1/; # Same thing; written old-style |
| 424 | /(.)(.)\g2\g1/; # Match a four letter palindrome (e.g. "ABBA"). |
| 425 | |
| 426 | |
| 427 | =head3 Relative referencing |
| 428 | |
| 429 | C<\g-I<N>> (starting in Perl 5.10.0) is used for relative addressing. (It can |
| 430 | be written as C<\g{-I<N>>.) It refers to the I<N>th group before the |
| 431 | C<\g{-I<N>}>. |
| 432 | |
| 433 | The big advantage of this form is that it makes it much easier to write |
| 434 | patterns with references that can be interpolated in larger patterns, |
| 435 | even if the larger pattern also contains capture groups. |
| 436 | |
| 437 | =head4 Examples |
| 438 | |
| 439 | /(A) # Group 1 |
| 440 | ( # Group 2 |
| 441 | (B) # Group 3 |
| 442 | \g{-1} # Refers to group 3 (B) |
| 443 | \g{-3} # Refers to group 1 (A) |
| 444 | ) |
| 445 | /x; # Matches "ABBA". |
| 446 | |
| 447 | my $qr = qr /(.)(.)\g{-2}\g{-1}/; # Matches 'abab', 'cdcd', etc. |
| 448 | /$qr$qr/ # Matches 'ababcdcd'. |
| 449 | |
| 450 | =head3 Named referencing |
| 451 | |
| 452 | C<\g{I<name>}> (starting in Perl 5.10.0) can be used to back refer to a |
| 453 | named capture group, dispensing completely with having to think about capture |
| 454 | buffer positions. |
| 455 | |
| 456 | To be compatible with .Net regular expressions, C<\g{name}> may also be |
| 457 | written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>. |
| 458 | |
| 459 | To prevent any ambiguity, I<name> must not start with a digit nor contain a |
| 460 | hyphen. |
| 461 | |
| 462 | =head4 Examples |
| 463 | |
| 464 | /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat") |
| 465 | /(?<word>\w+) \k{word}/ # Same. |
| 466 | /(?<word>\w+) \k<word>/ # Same. |
| 467 | /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/ |
| 468 | # Match a four letter palindrome (e.g. "ABBA") |
| 469 | |
| 470 | =head2 Assertions |
| 471 | |
| 472 | Assertions are conditions that have to be true; they don't actually |
| 473 | match parts of the substring. There are six assertions that are written as |
| 474 | backslash sequences. |
| 475 | |
| 476 | =over 4 |
| 477 | |
| 478 | =item \A |
| 479 | |
| 480 | C<\A> only matches at the beginning of the string. If the C</m> modifier |
| 481 | isn't used, then C</\A/> is equivalent to C</^/>. However, if the C</m> |
| 482 | modifier is used, then C</^/> matches internal newlines, but the meaning |
| 483 | of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning |
| 484 | of the string regardless whether the C</m> modifier is used. |
| 485 | |
| 486 | =item \z, \Z |
| 487 | |
| 488 | C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't |
| 489 | used, then C</\Z/> is equivalent to C</$/>, that is, it matches at the |
| 490 | end of the string, or before the newline at the end of the string. If the |
| 491 | C</m> modifier is used, then C</$/> matches at internal newlines, but the |
| 492 | meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at |
| 493 | the end of the string (or just before a trailing newline) regardless whether |
| 494 | the C</m> modifier is used. |
| 495 | |
| 496 | C<\z> is just like C<\Z>, except that it will not match before a trailing |
| 497 | newline. C<\z> will only match at the end of the string - regardless of the |
| 498 | modifiers used, and not before a newline. |
| 499 | |
| 500 | =item \G |
| 501 | |
| 502 | C<\G> is usually only used in combination with the C</g> modifier. If the |
| 503 | C</g> modifier is used (and the match is done in scalar context), Perl will |
| 504 | remember where in the source string the last match ended, and the next time, |
| 505 | it will start the match from where it ended the previous time. |
| 506 | |
| 507 | C<\G> matches the point where the previous match ended, or the beginning |
| 508 | of the string if there was no previous match. |
| 509 | |
| 510 | =for later add link to perlremodifiers |
| 511 | |
| 512 | Mnemonic: I<G>lobal. |
| 513 | |
| 514 | =item \b, \B |
| 515 | |
| 516 | C<\b> matches at any place between a word and a non-word character; C<\B> |
| 517 | matches at any place between characters where C<\b> doesn't match. C<\b> |
| 518 | and C<\B> assume there's a non-word character before the beginning and after |
| 519 | the end of the source string; so C<\b> will match at the beginning (or end) |
| 520 | of the source string if the source string begins (or ends) with a word |
| 521 | character. Otherwise, C<\B> will match. |
| 522 | |
| 523 | Mnemonic: I<b>oundary. |
| 524 | |
| 525 | =back |
| 526 | |
| 527 | =head4 Examples |
| 528 | |
| 529 | "cat" =~ /\Acat/; # Match. |
| 530 | "cat" =~ /cat\Z/; # Match. |
| 531 | "cat\n" =~ /cat\Z/; # Match. |
| 532 | "cat\n" =~ /cat\z/; # No match. |
| 533 | |
| 534 | "cat" =~ /\bcat\b/; # Matches. |
| 535 | "cats" =~ /\bcat\b/; # No match. |
| 536 | "cat" =~ /\bcat\B/; # No match. |
| 537 | "cats" =~ /\bcat\B/; # Match. |
| 538 | |
| 539 | while ("cat dog" =~ /(\w+)/g) { |
| 540 | print $1; # Prints 'catdog' |
| 541 | } |
| 542 | while ("cat dog" =~ /\G(\w+)/g) { |
| 543 | print $1; # Prints 'cat' |
| 544 | } |
| 545 | |
| 546 | =head2 Misc |
| 547 | |
| 548 | Here we document the backslash sequences that don't fall in one of the |
| 549 | categories above. They are: |
| 550 | |
| 551 | =over 4 |
| 552 | |
| 553 | =item \C |
| 554 | |
| 555 | C<\C> always matches a single octet, even if the source string is encoded |
| 556 | in UTF-8 format, and the character to be matched is a multi-octet character. |
| 557 | C<\C> was introduced in perl 5.6. |
| 558 | |
| 559 | Mnemonic: oI<C>tet. |
| 560 | |
| 561 | =item \K |
| 562 | |
| 563 | This is new in perl 5.10.0. Anything that is matched left of C<\K> is |
| 564 | not included in C<$&> - and will not be replaced if the pattern is |
| 565 | used in a substitution. This will allow you to write C<s/PAT1 \K PAT2/REPL/x> |
| 566 | instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>. |
| 567 | |
| 568 | Mnemonic: I<K>eep. |
| 569 | |
| 570 | =item \N |
| 571 | |
| 572 | This is a new experimental feature in perl 5.12.0. It matches any character |
| 573 | that is not a newline. It is a short-hand for writing C<[^\n]>, and is |
| 574 | identical to the C<.> metasymbol, except under the C</s> flag, which changes |
| 575 | the meaning of C<.>, but not C<\N>. |
| 576 | |
| 577 | Note that C<\N{...}> can mean a |
| 578 | L<named or numbered character |
| 579 | |/Named or numbered characters and character sequences>. |
| 580 | |
| 581 | Mnemonic: Complement of I<\n>. |
| 582 | |
| 583 | =item \R |
| 584 | X<\R> |
| 585 | |
| 586 | C<\R> matches a I<generic newline>, that is, anything that is considered |
| 587 | a newline by Unicode. This includes all characters matched by C<\v> |
| 588 | (vertical whitespace), and the multi character sequence C<"\x0D\x0A"> |
| 589 | (carriage return followed by a line feed, aka the network newline, or |
| 590 | the newline used in Windows text files). C<\R> is equivalent to |
| 591 | C<< (?>\x0D\x0A)|\v) >>. Since C<\R> can match a sequence of more than one |
| 592 | character, it cannot be put inside a bracketed character class; C</[\R]/> is an |
| 593 | error; use C<\v> instead. C<\R> was introduced in perl 5.10.0. |
| 594 | |
| 595 | Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>, |
| 596 | and more importantly because Unicode recommends such a regular expression |
| 597 | metacharacter, and suggests C<\R> as the notation. |
| 598 | |
| 599 | =item \X |
| 600 | X<\X> |
| 601 | |
| 602 | This matches a Unicode I<extended grapheme cluster>. |
| 603 | |
| 604 | C<\X> matches quite well what normal (non-Unicode-programmer) usage |
| 605 | would consider a single character. As an example, consider a G with some sort |
| 606 | of diacritic mark, such as an arrow. There is no such single character in |
| 607 | Unicode, but one can be composed by using a G followed by a Unicode "COMBINING |
| 608 | UPWARDS ARROW BELOW", and would be displayed by Unicode-aware software as if it |
| 609 | were a single character. |
| 610 | |
| 611 | Mnemonic: eI<X>tended Unicode character. |
| 612 | |
| 613 | =back |
| 614 | |
| 615 | =head4 Examples |
| 616 | |
| 617 | "\x{256}" =~ /^\C\C$/; # Match as chr (256) takes 2 octets in UTF-8. |
| 618 | |
| 619 | $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz' |
| 620 | $str =~ s/(.)\K\g1//g; # Delete duplicated characters. |
| 621 | |
| 622 | "\n" =~ /^\R$/; # Match, \n is a generic newline. |
| 623 | "\r" =~ /^\R$/; # Match, \r is a generic newline. |
| 624 | "\r\n" =~ /^\R$/; # Match, \r\n is a generic newline. |
| 625 | |
| 626 | "P\x{0307}" =~ /^\X$/ # \X matches a P with a dot above. |
| 627 | |
| 628 | =cut |