| 1 | #!./perl |
| 2 | |
| 3 | BEGIN { |
| 4 | require 5.004; |
| 5 | chdir '..' if !-d 'lib' and -d '..\lib'; |
| 6 | @INC = 'lib'; |
| 7 | $ENV{PERL5LIB} = 'lib'; |
| 8 | } |
| 9 | |
| 10 | use strict; |
| 11 | my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin, |
| 12 | $nonono, $dostrip, $versiononly, $silent, $verbose, |
| 13 | $otherperls, $archname,$Is_NetWare, $nwinstall, $nopods); |
| 14 | use vars qw /$depth/; |
| 15 | |
| 16 | BEGIN { |
| 17 | $Is_VMS = $^O eq 'VMS'; |
| 18 | $Is_W32 = $^O eq 'MSWin32'; |
| 19 | $Is_OS2 = $^O eq 'os2'; |
| 20 | $Is_Cygwin = $^O eq 'cygwin'; |
| 21 | $Is_Darwin = $^O eq 'darwin'; |
| 22 | if ($Is_VMS) { eval 'use VMS::Filespec;' } |
| 23 | } |
| 24 | |
| 25 | my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : ''); |
| 26 | |
| 27 | use File::Find; |
| 28 | use File::Compare; |
| 29 | use File::Copy (); |
| 30 | use File::Path (); |
| 31 | use ExtUtils::Packlist; |
| 32 | use Config; |
| 33 | use subs qw(unlink link chmod); |
| 34 | |
| 35 | if ($Config{d_umask}) { |
| 36 | umask(022); # umasks like 077 aren't that useful for installations |
| 37 | } |
| 38 | |
| 39 | $Is_NetWare = $Config{osname} eq 'NetWare'; |
| 40 | if ($Is_NetWare) { |
| 41 | $Is_W32 = 0; |
| 42 | $scr_ext = '.pl'; |
| 43 | } |
| 44 | |
| 45 | # override the ones in the rest of the script |
| 46 | sub mkpath { |
| 47 | File::Path::mkpath(@_) unless $nonono; |
| 48 | } |
| 49 | |
| 50 | my $mainperldir = "/usr/bin"; |
| 51 | my $exe_ext = $Config{exe_ext}; |
| 52 | |
| 53 | # Allow ``make install PERLNAME=something_besides_perl'': |
| 54 | my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl'; |
| 55 | |
| 56 | # This is the base used for versioned names, like "perl5.6.0". |
| 57 | # It's separate because a common use of $PERLNAME is to install |
| 58 | # perl as "perl5", if that's used as base for versioned files you |
| 59 | # get "perl55.6.0". |
| 60 | my $perl_verbase = defined($ENV{PERLNAME_VERBASE}) |
| 61 | ? $ENV{PERLNAME_VERBASE} |
| 62 | : $perl; |
| 63 | |
| 64 | $otherperls = 1; |
| 65 | while (@ARGV) { |
| 66 | $nonono = 1 if $ARGV[0] eq '-n'; |
| 67 | $dostrip = 1 if $ARGV[0] eq '-s'; |
| 68 | $versiononly = 1 if $ARGV[0] eq '-v'; |
| 69 | $versiononly = 0 if $ARGV[0] eq '+v'; |
| 70 | $silent = 1 if $ARGV[0] eq '-S'; |
| 71 | $otherperls = 0 if $ARGV[0] eq '-o'; |
| 72 | $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n'; |
| 73 | $archname = 1 if $ARGV[0] eq '-A'; |
| 74 | $nwinstall = 1 if $ARGV[0] eq '-netware'; |
| 75 | $nopods = 1 if $ARGV[0] eq '-p'; |
| 76 | if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) { |
| 77 | print <<"EOT"; |
| 78 | Usage $0: [switches] |
| 79 | -n Don't actually run any commands; just print them. |
| 80 | -s Run strip on installed binaries. |
| 81 | -v Only install perl as a binary with the version number in the name. |
| 82 | (Override whatever config.sh says) |
| 83 | +v Install perl as "perl" and as a binary with the version number in |
| 84 | the name. (Override whatever config.sh says) |
| 85 | -S Silent mode. |
| 86 | -o Skip checking for other copies of perl in your PATH. |
| 87 | -V Verbose mode. |
| 88 | -A Also install perl with the architecture's name in the perl binary's |
| 89 | name. |
| 90 | -p Don't install the pod files. [This will break use diagnostics;] |
| 91 | -netware Install correctly on a Netware server. |
| 92 | EOT |
| 93 | exit; |
| 94 | } |
| 95 | shift; |
| 96 | } |
| 97 | |
| 98 | $versiononly = 1 if $Config{versiononly} && !defined $versiononly; |
| 99 | my (@scripts, @tolink); |
| 100 | open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!"; |
| 101 | while (<SCRIPTS>) { |
| 102 | next if /^#/; |
| 103 | next if /#\s*pod\s*=/; # Binary programs need separate treatment |
| 104 | chomp; |
| 105 | if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) { |
| 106 | push @scripts, $1; |
| 107 | push @tolink, [$1, $2]; |
| 108 | } else { |
| 109 | push @scripts, $_; |
| 110 | } |
| 111 | } |
| 112 | close SCRIPTS; |
| 113 | |
| 114 | if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; } |
| 115 | |
| 116 | my @pods = $nopods ? () : (<pod/*.pod>); |
| 117 | |
| 118 | # Specify here any .pm files that are actually architecture-dependent. |
| 119 | # (Those included with XS extensions under ext/ are automatically |
| 120 | # added later.) |
| 121 | # Now that the default privlib has the full perl version number included, |
| 122 | # we no longer have to play the trick of sticking version-specific .pm |
| 123 | # files under the archlib directory. |
| 124 | my %archpms = ( |
| 125 | Config => 1, |
| 126 | lib => 1, |
| 127 | Cwd => 1, |
| 128 | ); |
| 129 | |
| 130 | if ($^O eq 'dos') { |
| 131 | push(@scripts,'djgpp/fixpmain'); |
| 132 | $archpms{config} = $archpms{filehand} = 1; |
| 133 | } |
| 134 | |
| 135 | if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) |
| 136 | { |
| 137 | push(@scripts, map("$_.exe", @scripts)); |
| 138 | } |
| 139 | |
| 140 | find(sub { |
| 141 | if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) { |
| 142 | my($path, $modname) = ($1,$2); |
| 143 | |
| 144 | # strip trailing component first |
| 145 | $path =~ s{/[^/]*$}{}; |
| 146 | |
| 147 | # strip optional "/lib"; |
| 148 | $path =~ s{/lib\b}{}; |
| 149 | |
| 150 | # strip any leading / |
| 151 | $path =~ s{^/}{}; |
| 152 | |
| 153 | # reconstitute canonical module name |
| 154 | $modname = "$path/$modname" if length $path; |
| 155 | |
| 156 | # remember it |
| 157 | $archpms{$modname} = 1; |
| 158 | } |
| 159 | }, 'ext'); |
| 160 | |
| 161 | # print "[$_]\n" for sort keys %archpms; |
| 162 | |
| 163 | my $ver = $Config{version}; |
| 164 | my $release = substr($],0,3); # Not used currently. |
| 165 | my $patchlevel = substr($],3,2); |
| 166 | die "Patchlevel of perl ($patchlevel)", |
| 167 | "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n" |
| 168 | if $patchlevel != $Config{'PERL_VERSION'}; |
| 169 | |
| 170 | # Fetch some frequently-used items from %Config |
| 171 | my $installbin = $Config{installbin}; |
| 172 | my $installscript = $Config{installscript}; |
| 173 | my $installprivlib = $Config{installprivlib}; |
| 174 | my $installarchlib = $Config{installarchlib}; |
| 175 | my $installsitelib = $Config{installsitelib}; |
| 176 | my $installsitearch = $Config{installsitearch}; |
| 177 | my $installman1dir = $Config{installman1dir}; |
| 178 | my $man1ext = $Config{man1ext}; |
| 179 | my $libperl = $Config{libperl}; |
| 180 | # Shared library and dynamic loading suffixes. |
| 181 | my $so = $Config{so}; |
| 182 | my $dlext = $Config{dlext}; |
| 183 | my $dlsrc = $Config{dlsrc}; |
| 184 | if ($^O eq 'os390') { |
| 185 | my $pwd; |
| 186 | chomp($pwd=`pwd`); |
| 187 | my $archlibexp = $Config{archlibexp}; |
| 188 | my $usedl = $Config{usedl}; |
| 189 | if ($usedl eq 'define') { |
| 190 | `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`; |
| 191 | } |
| 192 | } |
| 193 | |
| 194 | if ($nwinstall) { |
| 195 | # This is required only if we are installing on a NetWare server |
| 196 | $installscript = $Config{installnwscripts}; |
| 197 | $installprivlib = $Config{installnwlib}; |
| 198 | $installarchlib = $Config{installnwlib}; |
| 199 | $installsitelib = $Config{installnwlib}; |
| 200 | } |
| 201 | |
| 202 | my $d_dosuid = $Config{d_dosuid}; |
| 203 | my $binexp = $Config{binexp}; |
| 204 | |
| 205 | if ($Is_VMS) { # Hang in there until File::Spec hits the big time |
| 206 | foreach ( \$installbin, \$installscript, \$installprivlib, |
| 207 | \$installarchlib, \$installsitelib, \$installsitearch, |
| 208 | \$installman1dir ) { |
| 209 | $$_ = unixify($$_); $$_ =~ s:/$::; |
| 210 | } |
| 211 | } |
| 212 | |
| 213 | # Do some quick sanity checks. |
| 214 | |
| 215 | if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; } |
| 216 | |
| 217 | $installbin || die "No installbin directory in config.sh\n"; |
| 218 | -d $installbin || mkpath($installbin, $verbose, 0777); |
| 219 | -d $installbin || $nonono || die "$installbin is not a directory\n"; |
| 220 | -w $installbin || $nonono || die "$installbin is not writable by you\n" |
| 221 | unless $installbin =~ m#^/afs/# || $nonono; |
| 222 | |
| 223 | if (!$Is_NetWare) { |
| 224 | -x 'perl' . $exe_ext || die "perl isn't executable!\n"; |
| 225 | -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid; |
| 226 | |
| 227 | -f 't/rantests' || $Is_W32 |
| 228 | || warn "WARNING: You've never run 'make test' or", |
| 229 | " some tests failed! (Installing anyway.)\n"; |
| 230 | } #if (!$Is_NetWare) |
| 231 | |
| 232 | if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) { |
| 233 | my $perldll; |
| 234 | |
| 235 | if ($Is_Cygwin) { |
| 236 | $perldll = $libperl; |
| 237 | $perldll =~ s/(\..*)?$/.$dlext/; |
| 238 | if ($Config{useshrplib} eq 'true') { |
| 239 | # install ld2 and perlld as well |
| 240 | foreach ('ld2', 'perlld') { |
| 241 | safe_unlink("$installbin/$_"); |
| 242 | copy("$_", "$installbin/$_"); |
| 243 | chmod(0755, "$installbin/$_"); |
| 244 | }; |
| 245 | }; |
| 246 | } else { |
| 247 | $perldll = 'perl57.' . $dlext; |
| 248 | } |
| 249 | |
| 250 | if ($dlsrc ne "dl_none.xs") { |
| 251 | -f $perldll || die "No perl DLL built\n"; |
| 252 | } |
| 253 | # Install the DLL |
| 254 | |
| 255 | safe_unlink("$installbin/$perldll"); |
| 256 | copy("$perldll", "$installbin/$perldll"); |
| 257 | chmod(0755, "$installbin/$perldll"); |
| 258 | |
| 259 | } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) |
| 260 | |
| 261 | # This will be used to store the packlist |
| 262 | my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist"); |
| 263 | |
| 264 | # First we install the version-numbered executables. |
| 265 | |
| 266 | if ($Is_VMS) { |
| 267 | safe_unlink("$installbin/$perl$exe_ext"); |
| 268 | copy("perl$exe_ext", "$installbin/$perl$exe_ext"); |
| 269 | chmod(0755, "$installbin/$perl$exe_ext"); |
| 270 | safe_unlink("$installbin/${perl}shr$exe_ext"); |
| 271 | copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext"); |
| 272 | chmod(0755, "$installbin/${perl}shr$exe_ext"); |
| 273 | } |
| 274 | elsif ($^O eq 'mpeix') { |
| 275 | # MPE lacks hard links and requires that executables with special |
| 276 | # capabilities reside in the MPE namespace. |
| 277 | safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath}); |
| 278 | # Install the primary executable into the MPE namespace as perlpath. |
| 279 | copy("perl$exe_ext", $Config{perlpath}); |
| 280 | chmod(0755, $Config{perlpath}); |
| 281 | # Create a backup copy with the version number. |
| 282 | link($Config{perlpath}, "$installbin/perl$ver$exe_ext"); |
| 283 | } |
| 284 | elsif ($^O ne 'dos') { |
| 285 | if (!$Is_NetWare) { |
| 286 | safe_unlink("$installbin/$perl_verbase$ver$exe_ext"); |
| 287 | copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext"); |
| 288 | strip("$installbin/$perl_verbase$ver$exe_ext"); |
| 289 | chmod(0755, "$installbin/$perl_verbase$ver$exe_ext"); |
| 290 | } |
| 291 | else { |
| 292 | # If installing onto a NetWare server |
| 293 | if ($nwinstall) { |
| 294 | # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm |
| 295 | mkpath($Config{installnwsystem}, 1, 0777); |
| 296 | copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem}); |
| 297 | copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem}); |
| 298 | copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem}); |
| 299 | copy("x2p\\a2p.nlm", $Config{installnwsystem}); |
| 300 | chmod(0755, "$Config{installnwsystem}\\perl.nlm"); |
| 301 | mkpath($Config{installnwlcgi}, 1, 0777); |
| 302 | copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi}); |
| 303 | } |
| 304 | } #if (!$Is_NetWare) |
| 305 | } |
| 306 | else { |
| 307 | safe_unlink("$installbin/$perl.exe"); |
| 308 | copy("perl.exe", "$installbin/$perl.exe"); |
| 309 | } |
| 310 | |
| 311 | safe_unlink("$installbin/s$perl_verbase$ver$exe_ext"); |
| 312 | if ($d_dosuid) { |
| 313 | copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext"); |
| 314 | chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext"); |
| 315 | } |
| 316 | |
| 317 | # Install library files. |
| 318 | |
| 319 | my ($do_installarchlib, $do_installprivlib) = (0, 0); |
| 320 | |
| 321 | mkpath($installprivlib, $verbose, 0777); |
| 322 | mkpath($installarchlib, $verbose, 0777); |
| 323 | mkpath($installsitelib, $verbose, 0777) if ($installsitelib); |
| 324 | mkpath($installsitearch, $verbose, 0777) if ($installsitearch); |
| 325 | |
| 326 | if (chdir "lib") { |
| 327 | $do_installarchlib = ! samepath($installarchlib, '.'); |
| 328 | $do_installprivlib = ! samepath($installprivlib, '.'); |
| 329 | $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/); |
| 330 | |
| 331 | if ($do_installarchlib || $do_installprivlib) { |
| 332 | find(\&installlib, '.'); |
| 333 | } |
| 334 | chdir ".." || die "Can't cd back to source directory: $!\n"; |
| 335 | } |
| 336 | else { |
| 337 | warn "Can't cd to lib to install lib files: $!\n"; |
| 338 | } |
| 339 | |
| 340 | # Install header files and libraries. |
| 341 | mkpath("$installarchlib/CORE", $verbose, 0777); |
| 342 | my @corefiles; |
| 343 | if ($Is_VMS) { # We did core file selection during build |
| 344 | my $coredir = "lib/$Config{archname}/$ver/CORE"; |
| 345 | $coredir =~ tr/./_/; |
| 346 | map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>; |
| 347 | } |
| 348 | else { |
| 349 | # [als] hard-coded 'libperl' name... not good! |
| 350 | @corefiles = <*.h libperl*.*>; |
| 351 | |
| 352 | # AIX needs perl.exp installed as well. |
| 353 | push(@corefiles,'perl.exp') if $^O eq 'aix'; |
| 354 | if ($^O eq 'mpeix') { |
| 355 | # MPE needs mpeixish.h installed as well. |
| 356 | mkpath("$installarchlib/CORE/mpeix", $verbose, 0777); |
| 357 | push(@corefiles,'mpeix/mpeixish.h'); |
| 358 | } |
| 359 | # If they have built sperl.o... |
| 360 | push(@corefiles,'sperl.o') if -f 'sperl.o'; |
| 361 | } |
| 362 | foreach my $file (@corefiles) { |
| 363 | # HP-UX (at least) needs to maintain execute permissions |
| 364 | # on dynamically-loadable libraries. So we do it for all. |
| 365 | if (copy_if_diff($file,"$installarchlib/CORE/$file")) { |
| 366 | if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) { |
| 367 | strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/; |
| 368 | chmod(0555, "$installarchlib/CORE/$file"); |
| 369 | } else { |
| 370 | chmod(0444, "$installarchlib/CORE/$file"); |
| 371 | } |
| 372 | } |
| 373 | } |
| 374 | |
| 375 | # Install main perl executables |
| 376 | # Make links to ordinary names if installbin directory isn't current directory. |
| 377 | |
| 378 | if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) { |
| 379 | safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext"); |
| 380 | if ($^O eq 'mpeix') { |
| 381 | # MPE doesn't support hard links, so use a symlink. |
| 382 | # We don't want another cloned copy. |
| 383 | symlink($Config{perlpath}, "$installbin/perl$exe_ext"); |
| 384 | } else { |
| 385 | link("$installbin/$perl_verbase$ver$exe_ext", |
| 386 | "$installbin/$perl$exe_ext"); |
| 387 | } |
| 388 | link("$installbin/s$perl_verbase$ver$exe_ext", |
| 389 | "$installbin/suid$perl$exe_ext") |
| 390 | if $d_dosuid; |
| 391 | } |
| 392 | |
| 393 | # For development purposes it can be very useful to have multiple perls |
| 394 | # build for different "architectures" (eg threading or not) simultaneously. |
| 395 | if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) { |
| 396 | my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext"; |
| 397 | safe_unlink("$installbin/$archperl"); |
| 398 | if ($^O eq 'mpeix') { |
| 399 | # MPE doesn't support hard links, so use a symlink. |
| 400 | # We don't want another cloned copy. |
| 401 | symlink($Config{perlpath}, "$installbin/$archperl"); |
| 402 | } else { |
| 403 | link("$installbin/$perl_verbase$ver$exe_ext", |
| 404 | "$installbin/$archperl"); |
| 405 | } |
| 406 | } |
| 407 | |
| 408 | # Offer to install perl in a "standard" location |
| 409 | |
| 410 | my $mainperl_is_instperl = 0; |
| 411 | |
| 412 | if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' && |
| 413 | !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR |
| 414 | && -w $mainperldir && ! samepath($mainperldir, $installbin)) { |
| 415 | my($usrbinperl) = "$mainperldir/$perl$exe_ext"; |
| 416 | my($instperl) = "$installbin/$perl$exe_ext"; |
| 417 | my($expinstperl) = "$binexp/$perl$exe_ext"; |
| 418 | |
| 419 | # First make sure $usrbinperl is not already the same as the perl we |
| 420 | # just installed. |
| 421 | if (-x $usrbinperl) { |
| 422 | # Try to be clever about mainperl being a symbolic link |
| 423 | # to binexp/perl if binexp and installbin are different. |
| 424 | $mainperl_is_instperl = |
| 425 | samepath($usrbinperl, $instperl) || |
| 426 | samepath($usrbinperl, $expinstperl) || |
| 427 | (($binexp ne $installbin) && |
| 428 | (-l $usrbinperl) && |
| 429 | ((readlink $usrbinperl) eq $expinstperl)); |
| 430 | } |
| 431 | if (! $mainperl_is_instperl) { |
| 432 | unlink($usrbinperl); |
| 433 | ( $Config{'d_link'} eq 'define' && |
| 434 | eval { CORE::link $instperl, $usrbinperl } ) || |
| 435 | eval { symlink $expinstperl, $usrbinperl } || |
| 436 | copy($instperl, $usrbinperl); |
| 437 | |
| 438 | $mainperl_is_instperl = 1; |
| 439 | } |
| 440 | } |
| 441 | |
| 442 | # Make links to ordinary names if installbin directory isn't current directory. |
| 443 | if (!$Is_NetWare) { |
| 444 | if (!$versiononly && ! samepath($installbin, 'x2p')) { |
| 445 | safe_unlink("$installbin/a2p$exe_ext"); |
| 446 | copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext"); |
| 447 | strip("$installbin/a2p$exe_ext"); |
| 448 | chmod(0755, "$installbin/a2p$exe_ext"); |
| 449 | } |
| 450 | } |
| 451 | |
| 452 | # cppstdin is just a script, but it is architecture-dependent, so |
| 453 | # it can't safely be shared. Place it in $installbin. |
| 454 | # Note that Configure doesn't build cppstin if it isn't needed, so |
| 455 | # we skip this if cppstdin doesn't exist. |
| 456 | if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) { |
| 457 | safe_unlink("$installbin/cppstdin"); |
| 458 | copy("cppstdin", "$installbin/cppstdin"); |
| 459 | chmod(0755, "$installbin/cppstdin"); |
| 460 | } |
| 461 | |
| 462 | sub script_alias { |
| 463 | my ($installscript, $orig, $alias, $scr_ext) = @_; |
| 464 | |
| 465 | safe_unlink("$installscript/$alias$scr_ext"); |
| 466 | if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') { |
| 467 | copy("$installscript/$orig$scr_ext", |
| 468 | "$installscript/$alias$scr_ext"); |
| 469 | } else { |
| 470 | link("$installscript/$orig$scr_ext", |
| 471 | "$installscript/$alias$scr_ext"); |
| 472 | } |
| 473 | } |
| 474 | |
| 475 | # Install scripts. |
| 476 | mkpath($installscript, $verbose, 0777); |
| 477 | if ($versiononly) { |
| 478 | for (@scripts) { |
| 479 | (my $base = $_) =~ s#.*/##; |
| 480 | $base .= $ver; |
| 481 | copy($_, "$installscript/$base"); |
| 482 | chmod(0755, "$installscript/$base"); |
| 483 | } |
| 484 | |
| 485 | for (@tolink) { |
| 486 | my ($from, $to) = map { "$_$ver" } @$_; |
| 487 | (my $frbase = $from) =~ s#.*/##; |
| 488 | (my $tobase = $to) =~ s#.*/##; |
| 489 | script_alias($installscript, $frbase, $tobase, $scr_ext); |
| 490 | } |
| 491 | } else { |
| 492 | for (@scripts) { |
| 493 | (my $base = $_) =~ s#.*/##; |
| 494 | copy($_, "$installscript/$base"); |
| 495 | chmod(0755, "$installscript/$base"); |
| 496 | } |
| 497 | |
| 498 | for (@tolink) { |
| 499 | my ($from, $to) = @$_; |
| 500 | (my $frbase = $from) =~ s#.*/##; |
| 501 | (my $tobase = $to) =~ s#.*/##; |
| 502 | script_alias($installscript, $frbase, $tobase, $scr_ext); |
| 503 | } |
| 504 | } |
| 505 | |
| 506 | # Install pod pages. Where? I guess in $installprivlib/pod |
| 507 | # ($installprivlib/pods for cygwin). |
| 508 | |
| 509 | my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod'; |
| 510 | if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) { |
| 511 | mkpath("${installprivlib}/$pod", $verbose, 0777); |
| 512 | |
| 513 | # If Perl 5.003's perldiag.pod is there, rename it. |
| 514 | if (open POD, "${installprivlib}/$pod/perldiag.pod") { |
| 515 | read POD, $_, 4000; |
| 516 | close POD; |
| 517 | # Some of Perl 5.003's diagnostic messages ended with periods. |
| 518 | if (/^=.*\.$/m) { |
| 519 | my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod", |
| 520 | "${installprivlib}/$pod/perldiag-5.003.pod"); |
| 521 | print " rename $from $to"; |
| 522 | rename($from, $to) |
| 523 | or warn "Couldn't rename $from to $to: $!\n" |
| 524 | unless $nonono; |
| 525 | } |
| 526 | } |
| 527 | |
| 528 | for (@pods) { |
| 529 | # $_ is a name like pod/perl.pod |
| 530 | (my $base = $_) =~ s#.*/##; |
| 531 | copy_if_diff($_, "${installprivlib}/$pod/${base}"); |
| 532 | } |
| 533 | |
| 534 | } |
| 535 | |
| 536 | # Check to make sure there aren't other perls around in installer's |
| 537 | # path. This is probably UNIX-specific. Check all absolute directories |
| 538 | # in the path except for where public executables are supposed to live. |
| 539 | # Also skip $mainperl if the user opted to have it be a link to the |
| 540 | # installed perl. |
| 541 | |
| 542 | if (!$versiononly && $otherperls) { |
| 543 | my ($path, @path); |
| 544 | my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ; |
| 545 | ($path = $ENV{"PATH"}) =~ s:\\:/:g ; |
| 546 | @path = split(/$dirsep/, $path); |
| 547 | if ($Is_VMS) { |
| 548 | my $i = 0; |
| 549 | while (exists $ENV{'DCL$PATH' . $i}) { |
| 550 | my $dir = unixpath($ENV{'DCL$PATH' . $i}); $dir =~ s-/$--; |
| 551 | push(@path,$dir); |
| 552 | } |
| 553 | } |
| 554 | my @otherperls; |
| 555 | my %otherperls; |
| 556 | for (@path) { |
| 557 | next unless m,^/,; |
| 558 | # Use &samepath here because some systems have other dirs linked |
| 559 | # to $mainperldir (like SunOS) |
| 560 | next if samepath($_, $binexp); |
| 561 | next if ($mainperl_is_instperl && samepath($_, $mainperldir)); |
| 562 | my $otherperl = "$_/$perl$exe_ext"; |
| 563 | next if $otherperls{$otherperl}++; |
| 564 | push(@otherperls, $otherperl) |
| 565 | if (-x $otherperl && ! -d $otherperl); |
| 566 | } |
| 567 | if (@otherperls) { |
| 568 | warn "\nWarning: $perl appears in your path in the following " . |
| 569 | "locations beyond where\nwe just installed it:\n"; |
| 570 | for (@otherperls) { |
| 571 | warn " ", $_, "\n"; |
| 572 | } |
| 573 | warn "\n"; |
| 574 | } |
| 575 | |
| 576 | } |
| 577 | |
| 578 | $packlist->write() unless $nonono; |
| 579 | print " Installation complete\n" if $verbose; |
| 580 | |
| 581 | exit 0; |
| 582 | |
| 583 | ############################################################################### |
| 584 | |
| 585 | sub yn { |
| 586 | my($prompt) = @_; |
| 587 | my($answer); |
| 588 | my($default) = $prompt =~ m/\[([yn])\]\s*$/i; |
| 589 | print STDERR $prompt; |
| 590 | chop($answer = <STDIN>); |
| 591 | $answer = $default if $answer =~ m/^\s*$/; |
| 592 | ($answer =~ m/^[yY]/); |
| 593 | } |
| 594 | |
| 595 | sub unlink { |
| 596 | my(@names) = @_; |
| 597 | my($cnt) = 0; |
| 598 | |
| 599 | return scalar(@names) if $Is_VMS; |
| 600 | |
| 601 | foreach my $name (@names) { |
| 602 | next unless -e $name; |
| 603 | chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare); |
| 604 | print " unlink $name\n" if $verbose; |
| 605 | ( CORE::unlink($name) and ++$cnt |
| 606 | or warn "Couldn't unlink $name: $!\n" ) unless $nonono; |
| 607 | } |
| 608 | return $cnt; |
| 609 | } |
| 610 | |
| 611 | sub safe_unlink { |
| 612 | return if $nonono or $Is_VMS; |
| 613 | my @names = @_; |
| 614 | foreach my $name (@names) { |
| 615 | next unless -e $name; |
| 616 | chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare); |
| 617 | print " unlink $name\n" if $verbose; |
| 618 | next if CORE::unlink($name); |
| 619 | warn "Couldn't unlink $name: $!\n"; |
| 620 | if ($! =~ /busy/i) { |
| 621 | print " mv $name $name.old\n" if $verbose; |
| 622 | safe_rename($name, "$name.old") |
| 623 | or warn "Couldn't rename $name: $!\n"; |
| 624 | } |
| 625 | } |
| 626 | } |
| 627 | |
| 628 | sub safe_rename { |
| 629 | my($from,$to) = @_; |
| 630 | if (-f $to and not unlink($to)) { |
| 631 | my($i); |
| 632 | for ($i = 1; $i < 50; $i++) { |
| 633 | last if rename($to, "$to.$i"); |
| 634 | } |
| 635 | warn("Cannot rename to `$to.$i': $!"), return 0 |
| 636 | if $i >= 50; # Give up! |
| 637 | } |
| 638 | link($from,$to) || return 0; |
| 639 | unlink($from); |
| 640 | } |
| 641 | |
| 642 | sub link { |
| 643 | my($from,$to) = @_; |
| 644 | my($success) = 0; |
| 645 | |
| 646 | print $verbose ? " ln $from $to\n" : " $to\n" unless $silent; |
| 647 | eval { |
| 648 | CORE::link($from, $to) |
| 649 | ? $success++ |
| 650 | : ($from =~ m#^/afs/# || $to =~ m#^/afs/#) |
| 651 | ? die "AFS" # okay inside eval {} |
| 652 | : die "Couldn't link $from to $to: $!\n" |
| 653 | unless $nonono; |
| 654 | $packlist->{$to} = { from => $from, type => 'link' }; |
| 655 | }; |
| 656 | if ($@) { |
| 657 | warn $@; |
| 658 | print $verbose ? " cp $from $to\n" : " $to\n" unless $silent; |
| 659 | print " creating new version of $to\n" |
| 660 | if $Is_VMS and -e $to and !$silent; |
| 661 | File::Copy::copy($from, $to) |
| 662 | ? $success++ |
| 663 | : warn "Couldn't copy $from to $to: $!\n" |
| 664 | unless $nonono; |
| 665 | $packlist->{$to} = { type => 'file' }; |
| 666 | } |
| 667 | $success; |
| 668 | } |
| 669 | |
| 670 | sub chmod { |
| 671 | my($mode,$name) = @_; |
| 672 | |
| 673 | return if ($^O eq 'dos'); |
| 674 | printf " chmod %o %s\n", $mode, $name if $verbose; |
| 675 | CORE::chmod($mode,$name) |
| 676 | || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name) |
| 677 | unless $nonono; |
| 678 | } |
| 679 | |
| 680 | sub copy { |
| 681 | my($from,$to) = @_; |
| 682 | |
| 683 | print $verbose ? " cp $from $to\n" : " $to\n" unless $silent; |
| 684 | print " creating new version of $to\n" if $Is_VMS and -e $to and !$silent; |
| 685 | File::Copy::copy($from, $to) |
| 686 | || warn "Couldn't copy $from to $to: $!\n" |
| 687 | unless $nonono; |
| 688 | $packlist->{$to} = { type => 'file' }; |
| 689 | } |
| 690 | |
| 691 | sub samepath { |
| 692 | my($p1, $p2) = @_; |
| 693 | |
| 694 | return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare); |
| 695 | |
| 696 | if ($p1 ne $p2) { |
| 697 | my($dev1, $ino1, $dev2, $ino2); |
| 698 | ($dev1, $ino1) = stat($p1); |
| 699 | ($dev2, $ino2) = stat($p2); |
| 700 | ($dev1 == $dev2 && $ino1 == $ino2); |
| 701 | } |
| 702 | else { |
| 703 | 1; |
| 704 | } |
| 705 | } |
| 706 | |
| 707 | sub installlib { |
| 708 | my $dir = $File::Find::dir; |
| 709 | $dir =~ s#^\.(?![^/])/?##; |
| 710 | local($depth) = $dir ? "lib/$dir" : "lib"; |
| 711 | |
| 712 | my $name = $_; |
| 713 | |
| 714 | # Ignore RCS and CVS directories. |
| 715 | if (($name eq 'CVS' or $name eq 'RCS') and -d $name) { |
| 716 | $File::Find::prune = 1; |
| 717 | return; |
| 718 | } |
| 719 | |
| 720 | # ignore patch backups, RCS files, emacs backup & temp files and the |
| 721 | # .exists files, .PL files, and .t files. |
| 722 | return if $name =~ m{\.orig$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.t$}; |
| 723 | |
| 724 | $name = "$dir/$name" if $dir ne ''; |
| 725 | |
| 726 | my $installlib = $installprivlib; |
| 727 | if ($dir =~ /^auto/ || |
| 728 | ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) || |
| 729 | ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) |
| 730 | ) { |
| 731 | $installlib = $installarchlib; |
| 732 | return unless $do_installarchlib; |
| 733 | } else { |
| 734 | return unless $do_installprivlib; |
| 735 | } |
| 736 | |
| 737 | if (-f $_) { |
| 738 | if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) { |
| 739 | $installlib = $installprivlib; |
| 740 | #We're installing *.al and *.ix files into $installprivlib, |
| 741 | #but we have to delete old *.al and *.ix files from the 5.000 |
| 742 | #distribution: |
| 743 | #This might not work because $archname might have changed. |
| 744 | unlink("$installarchlib/$name"); |
| 745 | } |
| 746 | $packlist->{"$installlib/$name"} = { type => 'file' }; |
| 747 | if (compare($_, "$installlib/$name") || $nonono) { |
| 748 | unlink("$installlib/$name"); |
| 749 | mkpath("$installlib/$dir", $verbose, 0777); |
| 750 | # HP-UX (at least) needs to maintain execute permissions |
| 751 | # on dynamically-loaded libraries. |
| 752 | if ($Is_NetWare && !$nwinstall) { |
| 753 | # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also |
| 754 | # if copied will give problems when building new extensions. |
| 755 | # Has to be copied if we are installing on a NetWare server and hence |
| 756 | # the check !$nwinstall |
| 757 | if (!(/\.(?:nlp|nlm|bs)$/)) { |
| 758 | copy_if_diff($_, "$installlib/$name") |
| 759 | and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444, |
| 760 | "$installlib/$name"); |
| 761 | } |
| 762 | } else { |
| 763 | if (copy_if_diff($_, "$installlib/$name")) { |
| 764 | if ($name =~ /\.(so|$dlext)$/o) { |
| 765 | strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/; |
| 766 | chmod(0555, "$installlib/$name"); |
| 767 | } else { |
| 768 | strip("-S", "$installlib/$name") |
| 769 | if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/); |
| 770 | chmod(0444, "$installlib/$name"); |
| 771 | } |
| 772 | } |
| 773 | } #if ($Is_NetWare) |
| 774 | } |
| 775 | } |
| 776 | } |
| 777 | |
| 778 | # Copy $from to $to, only if $from is different than $to. |
| 779 | # Also preserve modification times for .a libraries. |
| 780 | # On some systems, if you do |
| 781 | # ranlib libperl.a |
| 782 | # cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a |
| 783 | # and then try to link against the installed libperl.a, you might |
| 784 | # get an error message to the effect that the symbol table is older |
| 785 | # than the library. |
| 786 | # Return true if copying occurred. |
| 787 | |
| 788 | sub copy_if_diff { |
| 789 | my($from,$to)=@_; |
| 790 | return 1 if (($^O eq 'VMS') && (-d $from)); |
| 791 | -f $from || warn "$0: $from not found"; |
| 792 | $packlist->{$to} = { type => 'file' }; |
| 793 | if (compare($from, $to) || $nonono) { |
| 794 | safe_unlink($to); # In case we don't have write permissions. |
| 795 | if ($nonono) { |
| 796 | $from = $depth . "/" . $from if $depth; |
| 797 | } |
| 798 | copy($from, $to); |
| 799 | # Restore timestamps if it's a .a library or for OS/2. |
| 800 | if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) { |
| 801 | my ($atime, $mtime) = (stat $from)[8,9]; |
| 802 | utime $atime, $mtime, $to; |
| 803 | } |
| 804 | 1; |
| 805 | } |
| 806 | } |
| 807 | |
| 808 | sub strip |
| 809 | { |
| 810 | my(@args) = @_; |
| 811 | |
| 812 | return unless $dostrip; |
| 813 | |
| 814 | my @opts; |
| 815 | while (@args && $args[0] =~ /^(-\w+)$/) { |
| 816 | push @opts, shift @args; |
| 817 | } |
| 818 | |
| 819 | foreach my $file (@args) { |
| 820 | if (-f $file) { |
| 821 | if ($verbose) { |
| 822 | print " strip " . join(' ', @opts); |
| 823 | print " " if (@opts); |
| 824 | print "$file\n"; |
| 825 | } |
| 826 | system("strip", @opts, $file); |
| 827 | } else { |
| 828 | print "# file '$file' skipped\n" if $verbose; |
| 829 | } |
| 830 | } |
| 831 | } |