| 1 | =head1 NAME |
| 2 | |
| 3 | perlfaq8 - System Interaction ($Revision: 1.25 $, $Date: 2005/06/04 04:12:40 $) |
| 4 | |
| 5 | =head1 DESCRIPTION |
| 6 | |
| 7 | This section of the Perl FAQ covers questions involving operating |
| 8 | system interaction. Topics include interprocess communication (IPC), |
| 9 | control over the user-interface (keyboard, screen and pointing |
| 10 | devices), and most anything else not related to data manipulation. |
| 11 | |
| 12 | Read the FAQs and documentation specific to the port of perl to your |
| 13 | operating system (eg, L<perlvms>, L<perlplan9>, ...). These should |
| 14 | contain more detailed information on the vagaries of your perl. |
| 15 | |
| 16 | =head2 How do I find out which operating system I'm running under? |
| 17 | |
| 18 | The $^O variable ($OSNAME if you use English) contains an indication of |
| 19 | the name of the operating system (not its release number) that your perl |
| 20 | binary was built for. |
| 21 | |
| 22 | =head2 How come exec() doesn't return? |
| 23 | |
| 24 | Because that's what it does: it replaces your currently running |
| 25 | program with a different one. If you want to keep going (as is |
| 26 | probably the case if you're asking this question) use system() |
| 27 | instead. |
| 28 | |
| 29 | =head2 How do I do fancy stuff with the keyboard/screen/mouse? |
| 30 | |
| 31 | How you access/control keyboards, screens, and pointing devices |
| 32 | ("mice") is system-dependent. Try the following modules: |
| 33 | |
| 34 | =over 4 |
| 35 | |
| 36 | =item Keyboard |
| 37 | |
| 38 | Term::Cap Standard perl distribution |
| 39 | Term::ReadKey CPAN |
| 40 | Term::ReadLine::Gnu CPAN |
| 41 | Term::ReadLine::Perl CPAN |
| 42 | Term::Screen CPAN |
| 43 | |
| 44 | =item Screen |
| 45 | |
| 46 | Term::Cap Standard perl distribution |
| 47 | Curses CPAN |
| 48 | Term::ANSIColor CPAN |
| 49 | |
| 50 | =item Mouse |
| 51 | |
| 52 | Tk CPAN |
| 53 | |
| 54 | =back |
| 55 | |
| 56 | Some of these specific cases are shown below. |
| 57 | |
| 58 | =head2 How do I print something out in color? |
| 59 | |
| 60 | In general, you don't, because you don't know whether |
| 61 | the recipient has a color-aware display device. If you |
| 62 | know that they have an ANSI terminal that understands |
| 63 | color, you can use the Term::ANSIColor module from CPAN: |
| 64 | |
| 65 | use Term::ANSIColor; |
| 66 | print color("red"), "Stop!\n", color("reset"); |
| 67 | print color("green"), "Go!\n", color("reset"); |
| 68 | |
| 69 | Or like this: |
| 70 | |
| 71 | use Term::ANSIColor qw(:constants); |
| 72 | print RED, "Stop!\n", RESET; |
| 73 | print GREEN, "Go!\n", RESET; |
| 74 | |
| 75 | =head2 How do I read just one key without waiting for a return key? |
| 76 | |
| 77 | Controlling input buffering is a remarkably system-dependent matter. |
| 78 | On many systems, you can just use the B<stty> command as shown in |
| 79 | L<perlfunc/getc>, but as you see, that's already getting you into |
| 80 | portability snags. |
| 81 | |
| 82 | open(TTY, "+</dev/tty") or die "no tty: $!"; |
| 83 | system "stty cbreak </dev/tty >/dev/tty 2>&1"; |
| 84 | $key = getc(TTY); # perhaps this works |
| 85 | # OR ELSE |
| 86 | sysread(TTY, $key, 1); # probably this does |
| 87 | system "stty -cbreak </dev/tty >/dev/tty 2>&1"; |
| 88 | |
| 89 | The Term::ReadKey module from CPAN offers an easy-to-use interface that |
| 90 | should be more efficient than shelling out to B<stty> for each key. |
| 91 | It even includes limited support for Windows. |
| 92 | |
| 93 | use Term::ReadKey; |
| 94 | ReadMode('cbreak'); |
| 95 | $key = ReadKey(0); |
| 96 | ReadMode('normal'); |
| 97 | |
| 98 | However, using the code requires that you have a working C compiler |
| 99 | and can use it to build and install a CPAN module. Here's a solution |
| 100 | using the standard POSIX module, which is already on your systems |
| 101 | (assuming your system supports POSIX). |
| 102 | |
| 103 | use HotKey; |
| 104 | $key = readkey(); |
| 105 | |
| 106 | And here's the HotKey module, which hides the somewhat mystifying calls |
| 107 | to manipulate the POSIX termios structures. |
| 108 | |
| 109 | # HotKey.pm |
| 110 | package HotKey; |
| 111 | |
| 112 | @ISA = qw(Exporter); |
| 113 | @EXPORT = qw(cbreak cooked readkey); |
| 114 | |
| 115 | use strict; |
| 116 | use POSIX qw(:termios_h); |
| 117 | my ($term, $oterm, $echo, $noecho, $fd_stdin); |
| 118 | |
| 119 | $fd_stdin = fileno(STDIN); |
| 120 | $term = POSIX::Termios->new(); |
| 121 | $term->getattr($fd_stdin); |
| 122 | $oterm = $term->getlflag(); |
| 123 | |
| 124 | $echo = ECHO | ECHOK | ICANON; |
| 125 | $noecho = $oterm & ~$echo; |
| 126 | |
| 127 | sub cbreak { |
| 128 | $term->setlflag($noecho); # ok, so i don't want echo either |
| 129 | $term->setcc(VTIME, 1); |
| 130 | $term->setattr($fd_stdin, TCSANOW); |
| 131 | } |
| 132 | |
| 133 | sub cooked { |
| 134 | $term->setlflag($oterm); |
| 135 | $term->setcc(VTIME, 0); |
| 136 | $term->setattr($fd_stdin, TCSANOW); |
| 137 | } |
| 138 | |
| 139 | sub readkey { |
| 140 | my $key = ''; |
| 141 | cbreak(); |
| 142 | sysread(STDIN, $key, 1); |
| 143 | cooked(); |
| 144 | return $key; |
| 145 | } |
| 146 | |
| 147 | END { cooked() } |
| 148 | |
| 149 | 1; |
| 150 | |
| 151 | =head2 How do I check whether input is ready on the keyboard? |
| 152 | |
| 153 | The easiest way to do this is to read a key in nonblocking mode with the |
| 154 | Term::ReadKey module from CPAN, passing it an argument of -1 to indicate |
| 155 | not to block: |
| 156 | |
| 157 | use Term::ReadKey; |
| 158 | |
| 159 | ReadMode('cbreak'); |
| 160 | |
| 161 | if (defined ($char = ReadKey(-1)) ) { |
| 162 | # input was waiting and it was $char |
| 163 | } else { |
| 164 | # no input was waiting |
| 165 | } |
| 166 | |
| 167 | ReadMode('normal'); # restore normal tty settings |
| 168 | |
| 169 | =head2 How do I clear the screen? |
| 170 | |
| 171 | If you only have do so infrequently, use C<system>: |
| 172 | |
| 173 | system("clear"); |
| 174 | |
| 175 | If you have to do this a lot, save the clear string |
| 176 | so you can print it 100 times without calling a program |
| 177 | 100 times: |
| 178 | |
| 179 | $clear_string = `clear`; |
| 180 | print $clear_string; |
| 181 | |
| 182 | If you're planning on doing other screen manipulations, like cursor |
| 183 | positions, etc, you might wish to use Term::Cap module: |
| 184 | |
| 185 | use Term::Cap; |
| 186 | $terminal = Term::Cap->Tgetent( {OSPEED => 9600} ); |
| 187 | $clear_string = $terminal->Tputs('cl'); |
| 188 | |
| 189 | =head2 How do I get the screen size? |
| 190 | |
| 191 | If you have Term::ReadKey module installed from CPAN, |
| 192 | you can use it to fetch the width and height in characters |
| 193 | and in pixels: |
| 194 | |
| 195 | use Term::ReadKey; |
| 196 | ($wchar, $hchar, $wpixels, $hpixels) = GetTerminalSize(); |
| 197 | |
| 198 | This is more portable than the raw C<ioctl>, but not as |
| 199 | illustrative: |
| 200 | |
| 201 | require 'sys/ioctl.ph'; |
| 202 | die "no TIOCGWINSZ " unless defined &TIOCGWINSZ; |
| 203 | open(TTY, "+</dev/tty") or die "No tty: $!"; |
| 204 | unless (ioctl(TTY, &TIOCGWINSZ, $winsize='')) { |
| 205 | die sprintf "$0: ioctl TIOCGWINSZ (%08x: $!)\n", &TIOCGWINSZ; |
| 206 | } |
| 207 | ($row, $col, $xpixel, $ypixel) = unpack('S4', $winsize); |
| 208 | print "(row,col) = ($row,$col)"; |
| 209 | print " (xpixel,ypixel) = ($xpixel,$ypixel)" if $xpixel || $ypixel; |
| 210 | print "\n"; |
| 211 | |
| 212 | =head2 How do I ask the user for a password? |
| 213 | |
| 214 | (This question has nothing to do with the web. See a different |
| 215 | FAQ for that.) |
| 216 | |
| 217 | There's an example of this in L<perlfunc/crypt>). First, you put the |
| 218 | terminal into "no echo" mode, then just read the password normally. |
| 219 | You may do this with an old-style ioctl() function, POSIX terminal |
| 220 | control (see L<POSIX> or its documentation the Camel Book), or a call |
| 221 | to the B<stty> program, with varying degrees of portability. |
| 222 | |
| 223 | You can also do this for most systems using the Term::ReadKey module |
| 224 | from CPAN, which is easier to use and in theory more portable. |
| 225 | |
| 226 | use Term::ReadKey; |
| 227 | |
| 228 | ReadMode('noecho'); |
| 229 | $password = ReadLine(0); |
| 230 | |
| 231 | =head2 How do I read and write the serial port? |
| 232 | |
| 233 | This depends on which operating system your program is running on. In |
| 234 | the case of Unix, the serial ports will be accessible through files in |
| 235 | /dev; on other systems, device names will doubtless differ. |
| 236 | Several problem areas common to all device interaction are the |
| 237 | following: |
| 238 | |
| 239 | =over 4 |
| 240 | |
| 241 | =item lockfiles |
| 242 | |
| 243 | Your system may use lockfiles to control multiple access. Make sure |
| 244 | you follow the correct protocol. Unpredictable behavior can result |
| 245 | from multiple processes reading from one device. |
| 246 | |
| 247 | =item open mode |
| 248 | |
| 249 | If you expect to use both read and write operations on the device, |
| 250 | you'll have to open it for update (see L<perlfunc/"open"> for |
| 251 | details). You may wish to open it without running the risk of |
| 252 | blocking by using sysopen() and C<O_RDWR|O_NDELAY|O_NOCTTY> from the |
| 253 | Fcntl module (part of the standard perl distribution). See |
| 254 | L<perlfunc/"sysopen"> for more on this approach. |
| 255 | |
| 256 | =item end of line |
| 257 | |
| 258 | Some devices will be expecting a "\r" at the end of each line rather |
| 259 | than a "\n". In some ports of perl, "\r" and "\n" are different from |
| 260 | their usual (Unix) ASCII values of "\012" and "\015". You may have to |
| 261 | give the numeric values you want directly, using octal ("\015"), hex |
| 262 | ("0x0D"), or as a control-character specification ("\cM"). |
| 263 | |
| 264 | print DEV "atv1\012"; # wrong, for some devices |
| 265 | print DEV "atv1\015"; # right, for some devices |
| 266 | |
| 267 | Even though with normal text files a "\n" will do the trick, there is |
| 268 | still no unified scheme for terminating a line that is portable |
| 269 | between Unix, DOS/Win, and Macintosh, except to terminate I<ALL> line |
| 270 | ends with "\015\012", and strip what you don't need from the output. |
| 271 | This applies especially to socket I/O and autoflushing, discussed |
| 272 | next. |
| 273 | |
| 274 | =item flushing output |
| 275 | |
| 276 | If you expect characters to get to your device when you print() them, |
| 277 | you'll want to autoflush that filehandle. You can use select() |
| 278 | and the C<$|> variable to control autoflushing (see L<perlvar/$E<verbar>> |
| 279 | and L<perlfunc/select>, or L<perlfaq5>, "How do I flush/unbuffer an |
| 280 | output filehandle? Why must I do this?"): |
| 281 | |
| 282 | $oldh = select(DEV); |
| 283 | $| = 1; |
| 284 | select($oldh); |
| 285 | |
| 286 | You'll also see code that does this without a temporary variable, as in |
| 287 | |
| 288 | select((select(DEV), $| = 1)[0]); |
| 289 | |
| 290 | Or if you don't mind pulling in a few thousand lines |
| 291 | of code just because you're afraid of a little $| variable: |
| 292 | |
| 293 | use IO::Handle; |
| 294 | DEV->autoflush(1); |
| 295 | |
| 296 | As mentioned in the previous item, this still doesn't work when using |
| 297 | socket I/O between Unix and Macintosh. You'll need to hard code your |
| 298 | line terminators, in that case. |
| 299 | |
| 300 | =item non-blocking input |
| 301 | |
| 302 | If you are doing a blocking read() or sysread(), you'll have to |
| 303 | arrange for an alarm handler to provide a timeout (see |
| 304 | L<perlfunc/alarm>). If you have a non-blocking open, you'll likely |
| 305 | have a non-blocking read, which means you may have to use a 4-arg |
| 306 | select() to determine whether I/O is ready on that device (see |
| 307 | L<perlfunc/"select">. |
| 308 | |
| 309 | =back |
| 310 | |
| 311 | While trying to read from his caller-id box, the notorious Jamie Zawinski |
| 312 | <jwz@netscape.com>, after much gnashing of teeth and fighting with sysread, |
| 313 | sysopen, POSIX's tcgetattr business, and various other functions that |
| 314 | go bump in the night, finally came up with this: |
| 315 | |
| 316 | sub open_modem { |
| 317 | use IPC::Open2; |
| 318 | my $stty = `/bin/stty -g`; |
| 319 | open2( \*MODEM_IN, \*MODEM_OUT, "cu -l$modem_device -s2400 2>&1"); |
| 320 | # starting cu hoses /dev/tty's stty settings, even when it has |
| 321 | # been opened on a pipe... |
| 322 | system("/bin/stty $stty"); |
| 323 | $_ = <MODEM_IN>; |
| 324 | chomp; |
| 325 | if ( !m/^Connected/ ) { |
| 326 | print STDERR "$0: cu printed `$_' instead of `Connected'\n"; |
| 327 | } |
| 328 | } |
| 329 | |
| 330 | =head2 How do I decode encrypted password files? |
| 331 | |
| 332 | You spend lots and lots of money on dedicated hardware, but this is |
| 333 | bound to get you talked about. |
| 334 | |
| 335 | Seriously, you can't if they are Unix password files--the Unix |
| 336 | password system employs one-way encryption. It's more like hashing than |
| 337 | encryption. The best you can check is whether something else hashes to |
| 338 | the same string. You can't turn a hash back into the original string. |
| 339 | Programs like Crack |
| 340 | can forcibly (and intelligently) try to guess passwords, but don't |
| 341 | (can't) guarantee quick success. |
| 342 | |
| 343 | If you're worried about users selecting bad passwords, you should |
| 344 | proactively check when they try to change their password (by modifying |
| 345 | passwd(1), for example). |
| 346 | |
| 347 | =head2 How do I start a process in the background? |
| 348 | |
| 349 | Several modules can start other processes that do not block |
| 350 | your Perl program. You can use IPC::Open3, Parallel::Jobs, |
| 351 | IPC::Run, and some of the POE modules. See CPAN for more |
| 352 | details. |
| 353 | |
| 354 | You could also use |
| 355 | |
| 356 | system("cmd &") |
| 357 | |
| 358 | or you could use fork as documented in L<perlfunc/"fork">, with |
| 359 | further examples in L<perlipc>. Some things to be aware of, if you're |
| 360 | on a Unix-like system: |
| 361 | |
| 362 | =over 4 |
| 363 | |
| 364 | =item STDIN, STDOUT, and STDERR are shared |
| 365 | |
| 366 | Both the main process and the backgrounded one (the "child" process) |
| 367 | share the same STDIN, STDOUT and STDERR filehandles. If both try to |
| 368 | access them at once, strange things can happen. You may want to close |
| 369 | or reopen these for the child. You can get around this with |
| 370 | C<open>ing a pipe (see L<perlfunc/"open">) but on some systems this |
| 371 | means that the child process cannot outlive the parent. |
| 372 | |
| 373 | =item Signals |
| 374 | |
| 375 | You'll have to catch the SIGCHLD signal, and possibly SIGPIPE too. |
| 376 | SIGCHLD is sent when the backgrounded process finishes. SIGPIPE is |
| 377 | sent when you write to a filehandle whose child process has closed (an |
| 378 | untrapped SIGPIPE can cause your program to silently die). This is |
| 379 | not an issue with C<system("cmd&")>. |
| 380 | |
| 381 | =item Zombies |
| 382 | |
| 383 | You have to be prepared to "reap" the child process when it finishes. |
| 384 | |
| 385 | $SIG{CHLD} = sub { wait }; |
| 386 | |
| 387 | $SIG{CHLD} = 'IGNORE'; |
| 388 | |
| 389 | You can also use a double fork. You immediately wait() for your |
| 390 | first child, and the init daemon will wait() for your grandchild once |
| 391 | it exits. |
| 392 | |
| 393 | unless ($pid = fork) { |
| 394 | unless (fork) { |
| 395 | exec "what you really wanna do"; |
| 396 | die "exec failed!"; |
| 397 | } |
| 398 | exit 0; |
| 399 | } |
| 400 | waitpid($pid,0); |
| 401 | |
| 402 | |
| 403 | See L<perlipc/"Signals"> for other examples of code to do this. |
| 404 | Zombies are not an issue with C<system("prog &")>. |
| 405 | |
| 406 | =back |
| 407 | |
| 408 | =head2 How do I trap control characters/signals? |
| 409 | |
| 410 | You don't actually "trap" a control character. Instead, that character |
| 411 | generates a signal which is sent to your terminal's currently |
| 412 | foregrounded process group, which you then trap in your process. |
| 413 | Signals are documented in L<perlipc/"Signals"> and the |
| 414 | section on "Signals" in the Camel. |
| 415 | |
| 416 | You can set the values of the %SIG hash to be the functions you want |
| 417 | to handle the signal. After perl catches the signal, it looks in %SIG |
| 418 | for a key with the same name as the signal, then calls the subroutine |
| 419 | value for that key. |
| 420 | |
| 421 | # as an anonymous subroutine |
| 422 | |
| 423 | $SIG{INT} = sub { syswrite(STDERR, "ouch\n", 5 ) }; |
| 424 | |
| 425 | # or a reference to a function |
| 426 | |
| 427 | $SIG{INT} = \&ouch; |
| 428 | |
| 429 | # or the name of the function as a string |
| 430 | |
| 431 | $SIG{INT} = "ouch"; |
| 432 | |
| 433 | Perl versions before 5.8 had in its C source code signal handlers which |
| 434 | would catch the signal and possibly run a Perl function that you had set |
| 435 | in %SIG. This violated the rules of signal handling at that level |
| 436 | causing perl to dump core. Since version 5.8.0, perl looks at %SIG |
| 437 | *after* the signal has been caught, rather than while it is being caught. |
| 438 | Previous versions of this answer were incorrect. |
| 439 | |
| 440 | |
| 441 | =head2 How do I modify the shadow password file on a Unix system? |
| 442 | |
| 443 | If perl was installed correctly and your shadow library was written |
| 444 | properly, the getpw*() functions described in L<perlfunc> should in |
| 445 | theory provide (read-only) access to entries in the shadow password |
| 446 | file. To change the file, make a new shadow password file (the format |
| 447 | varies from system to system--see L<passwd> for specifics) and use |
| 448 | pwd_mkdb(8) to install it (see L<pwd_mkdb> for more details). |
| 449 | |
| 450 | =head2 How do I set the time and date? |
| 451 | |
| 452 | Assuming you're running under sufficient permissions, you should be |
| 453 | able to set the system-wide date and time by running the date(1) |
| 454 | program. (There is no way to set the time and date on a per-process |
| 455 | basis.) This mechanism will work for Unix, MS-DOS, Windows, and NT; |
| 456 | the VMS equivalent is C<set time>. |
| 457 | |
| 458 | However, if all you want to do is change your time zone, you can |
| 459 | probably get away with setting an environment variable: |
| 460 | |
| 461 | $ENV{TZ} = "MST7MDT"; # unixish |
| 462 | $ENV{'SYS$TIMEZONE_DIFFERENTIAL'}="-5" # vms |
| 463 | system "trn comp.lang.perl.misc"; |
| 464 | |
| 465 | =head2 How can I sleep() or alarm() for under a second? |
| 466 | |
| 467 | If you want finer granularity than the 1 second that the sleep() |
| 468 | function provides, the easiest way is to use the select() function as |
| 469 | documented in L<perlfunc/"select">. Try the Time::HiRes and |
| 470 | the BSD::Itimer modules (available from CPAN, and starting from |
| 471 | Perl 5.8 Time::HiRes is part of the standard distribution). |
| 472 | |
| 473 | =head2 How can I measure time under a second? |
| 474 | |
| 475 | In general, you may not be able to. The Time::HiRes module (available |
| 476 | from CPAN, and starting from Perl 5.8 part of the standard distribution) |
| 477 | provides this functionality for some systems. |
| 478 | |
| 479 | If your system supports both the syscall() function in Perl as well as |
| 480 | a system call like gettimeofday(2), then you may be able to do |
| 481 | something like this: |
| 482 | |
| 483 | require 'sys/syscall.ph'; |
| 484 | |
| 485 | $TIMEVAL_T = "LL"; |
| 486 | |
| 487 | $done = $start = pack($TIMEVAL_T, ()); |
| 488 | |
| 489 | syscall(&SYS_gettimeofday, $start, 0) != -1 |
| 490 | or die "gettimeofday: $!"; |
| 491 | |
| 492 | ########################## |
| 493 | # DO YOUR OPERATION HERE # |
| 494 | ########################## |
| 495 | |
| 496 | syscall( &SYS_gettimeofday, $done, 0) != -1 |
| 497 | or die "gettimeofday: $!"; |
| 498 | |
| 499 | @start = unpack($TIMEVAL_T, $start); |
| 500 | @done = unpack($TIMEVAL_T, $done); |
| 501 | |
| 502 | # fix microseconds |
| 503 | for ($done[1], $start[1]) { $_ /= 1_000_000 } |
| 504 | |
| 505 | $delta_time = sprintf "%.4f", ($done[0] + $done[1] ) |
| 506 | - |
| 507 | ($start[0] + $start[1] ); |
| 508 | |
| 509 | =head2 How can I do an atexit() or setjmp()/longjmp()? (Exception handling) |
| 510 | |
| 511 | Release 5 of Perl added the END block, which can be used to simulate |
| 512 | atexit(). Each package's END block is called when the program or |
| 513 | thread ends (see L<perlmod> manpage for more details). |
| 514 | |
| 515 | For example, you can use this to make sure your filter program |
| 516 | managed to finish its output without filling up the disk: |
| 517 | |
| 518 | END { |
| 519 | close(STDOUT) || die "stdout close failed: $!"; |
| 520 | } |
| 521 | |
| 522 | The END block isn't called when untrapped signals kill the program, |
| 523 | though, so if you use END blocks you should also use |
| 524 | |
| 525 | use sigtrap qw(die normal-signals); |
| 526 | |
| 527 | Perl's exception-handling mechanism is its eval() operator. You can |
| 528 | use eval() as setjmp and die() as longjmp. For details of this, see |
| 529 | the section on signals, especially the time-out handler for a blocking |
| 530 | flock() in L<perlipc/"Signals"> or the section on "Signals" in |
| 531 | the Camel Book. |
| 532 | |
| 533 | If exception handling is all you're interested in, try the |
| 534 | exceptions.pl library (part of the standard perl distribution). |
| 535 | |
| 536 | If you want the atexit() syntax (and an rmexit() as well), try the |
| 537 | AtExit module available from CPAN. |
| 538 | |
| 539 | =head2 Why doesn't my sockets program work under System V (Solaris)? What does the error message "Protocol not supported" mean? |
| 540 | |
| 541 | Some Sys-V based systems, notably Solaris 2.X, redefined some of the |
| 542 | standard socket constants. Since these were constant across all |
| 543 | architectures, they were often hardwired into perl code. The proper |
| 544 | way to deal with this is to "use Socket" to get the correct values. |
| 545 | |
| 546 | Note that even though SunOS and Solaris are binary compatible, these |
| 547 | values are different. Go figure. |
| 548 | |
| 549 | =head2 How can I call my system's unique C functions from Perl? |
| 550 | |
| 551 | In most cases, you write an external module to do it--see the answer |
| 552 | to "Where can I learn about linking C with Perl? [h2xs, xsubpp]". |
| 553 | However, if the function is a system call, and your system supports |
| 554 | syscall(), you can use the syscall function (documented in |
| 555 | L<perlfunc>). |
| 556 | |
| 557 | Remember to check the modules that came with your distribution, and |
| 558 | CPAN as well---someone may already have written a module to do it. On |
| 559 | Windows, try Win32::API. On Macs, try Mac::Carbon. If no module |
| 560 | has an interface to the C function, you can inline a bit of C in your |
| 561 | Perl source with Inline::C. |
| 562 | |
| 563 | =head2 Where do I get the include files to do ioctl() or syscall()? |
| 564 | |
| 565 | Historically, these would be generated by the h2ph tool, part of the |
| 566 | standard perl distribution. This program converts cpp(1) directives |
| 567 | in C header files to files containing subroutine definitions, like |
| 568 | &SYS_getitimer, which you can use as arguments to your functions. |
| 569 | It doesn't work perfectly, but it usually gets most of the job done. |
| 570 | Simple files like F<errno.h>, F<syscall.h>, and F<socket.h> were fine, |
| 571 | but the hard ones like F<ioctl.h> nearly always need to hand-edited. |
| 572 | Here's how to install the *.ph files: |
| 573 | |
| 574 | 1. become super-user |
| 575 | 2. cd /usr/include |
| 576 | 3. h2ph *.h */*.h |
| 577 | |
| 578 | If your system supports dynamic loading, for reasons of portability and |
| 579 | sanity you probably ought to use h2xs (also part of the standard perl |
| 580 | distribution). This tool converts C header files to Perl extensions. |
| 581 | See L<perlxstut> for how to get started with h2xs. |
| 582 | |
| 583 | If your system doesn't support dynamic loading, you still probably |
| 584 | ought to use h2xs. See L<perlxstut> and L<ExtUtils::MakeMaker> for |
| 585 | more information (in brief, just use B<make perl> instead of a plain |
| 586 | B<make> to rebuild perl with a new static extension). |
| 587 | |
| 588 | =head2 Why do setuid perl scripts complain about kernel problems? |
| 589 | |
| 590 | Some operating systems have bugs in the kernel that make setuid |
| 591 | scripts inherently insecure. Perl gives you a number of options |
| 592 | (described in L<perlsec>) to work around such systems. |
| 593 | |
| 594 | =head2 How can I open a pipe both to and from a command? |
| 595 | |
| 596 | The IPC::Open2 module (part of the standard perl distribution) is an |
| 597 | easy-to-use approach that internally uses pipe(), fork(), and exec() to do |
| 598 | the job. Make sure you read the deadlock warnings in its documentation, |
| 599 | though (see L<IPC::Open2>). See |
| 600 | L<perlipc/"Bidirectional Communication with Another Process"> and |
| 601 | L<perlipc/"Bidirectional Communication with Yourself"> |
| 602 | |
| 603 | You may also use the IPC::Open3 module (part of the standard perl |
| 604 | distribution), but be warned that it has a different order of |
| 605 | arguments from IPC::Open2 (see L<IPC::Open3>). |
| 606 | |
| 607 | =head2 Why can't I get the output of a command with system()? |
| 608 | |
| 609 | You're confusing the purpose of system() and backticks (``). system() |
| 610 | runs a command and returns exit status information (as a 16 bit value: |
| 611 | the low 7 bits are the signal the process died from, if any, and |
| 612 | the high 8 bits are the actual exit value). Backticks (``) run a |
| 613 | command and return what it sent to STDOUT. |
| 614 | |
| 615 | $exit_status = system("mail-users"); |
| 616 | $output_string = `ls`; |
| 617 | |
| 618 | =head2 How can I capture STDERR from an external command? |
| 619 | |
| 620 | There are three basic ways of running external commands: |
| 621 | |
| 622 | system $cmd; # using system() |
| 623 | $output = `$cmd`; # using backticks (``) |
| 624 | open (PIPE, "cmd |"); # using open() |
| 625 | |
| 626 | With system(), both STDOUT and STDERR will go the same place as the |
| 627 | script's STDOUT and STDERR, unless the system() command redirects them. |
| 628 | Backticks and open() read B<only> the STDOUT of your command. |
| 629 | |
| 630 | You can also use the open3() function from IPC::Open3. Benjamin |
| 631 | Goldberg provides some sample code: |
| 632 | |
| 633 | To capture a program's STDOUT, but discard its STDERR: |
| 634 | |
| 635 | use IPC::Open3; |
| 636 | use File::Spec; |
| 637 | use Symbol qw(gensym); |
| 638 | open(NULL, ">", File::Spec->devnull); |
| 639 | my $pid = open3(gensym, \*PH, ">&NULL", "cmd"); |
| 640 | while( <PH> ) { } |
| 641 | waitpid($pid, 0); |
| 642 | |
| 643 | To capture a program's STDERR, but discard its STDOUT: |
| 644 | |
| 645 | use IPC::Open3; |
| 646 | use File::Spec; |
| 647 | use Symbol qw(gensym); |
| 648 | open(NULL, ">", File::Spec->devnull); |
| 649 | my $pid = open3(gensym, ">&NULL", \*PH, "cmd"); |
| 650 | while( <PH> ) { } |
| 651 | waitpid($pid, 0); |
| 652 | |
| 653 | To capture a program's STDERR, and let its STDOUT go to our own STDERR: |
| 654 | |
| 655 | use IPC::Open3; |
| 656 | use Symbol qw(gensym); |
| 657 | my $pid = open3(gensym, ">&STDERR", \*PH, "cmd"); |
| 658 | while( <PH> ) { } |
| 659 | waitpid($pid, 0); |
| 660 | |
| 661 | To read both a command's STDOUT and its STDERR separately, you can |
| 662 | redirect them to temp files, let the command run, then read the temp |
| 663 | files: |
| 664 | |
| 665 | use IPC::Open3; |
| 666 | use Symbol qw(gensym); |
| 667 | use IO::File; |
| 668 | local *CATCHOUT = IO::File->new_tempfile; |
| 669 | local *CATCHERR = IO::File->new_tempfile; |
| 670 | my $pid = open3(gensym, ">&CATCHOUT", ">&CATCHERR", "cmd"); |
| 671 | waitpid($pid, 0); |
| 672 | seek $_, 0, 0 for \*CATCHOUT, \*CATCHERR; |
| 673 | while( <CATCHOUT> ) {} |
| 674 | while( <CATCHERR> ) {} |
| 675 | |
| 676 | But there's no real need for *both* to be tempfiles... the following |
| 677 | should work just as well, without deadlocking: |
| 678 | |
| 679 | use IPC::Open3; |
| 680 | use Symbol qw(gensym); |
| 681 | use IO::File; |
| 682 | local *CATCHERR = IO::File->new_tempfile; |
| 683 | my $pid = open3(gensym, \*CATCHOUT, ">&CATCHERR", "cmd"); |
| 684 | while( <CATCHOUT> ) {} |
| 685 | waitpid($pid, 0); |
| 686 | seek CATCHERR, 0, 0; |
| 687 | while( <CATCHERR> ) {} |
| 688 | |
| 689 | And it'll be faster, too, since we can begin processing the program's |
| 690 | stdout immediately, rather than waiting for the program to finish. |
| 691 | |
| 692 | With any of these, you can change file descriptors before the call: |
| 693 | |
| 694 | open(STDOUT, ">logfile"); |
| 695 | system("ls"); |
| 696 | |
| 697 | or you can use Bourne shell file-descriptor redirection: |
| 698 | |
| 699 | $output = `$cmd 2>some_file`; |
| 700 | open (PIPE, "cmd 2>some_file |"); |
| 701 | |
| 702 | You can also use file-descriptor redirection to make STDERR a |
| 703 | duplicate of STDOUT: |
| 704 | |
| 705 | $output = `$cmd 2>&1`; |
| 706 | open (PIPE, "cmd 2>&1 |"); |
| 707 | |
| 708 | Note that you I<cannot> simply open STDERR to be a dup of STDOUT |
| 709 | in your Perl program and avoid calling the shell to do the redirection. |
| 710 | This doesn't work: |
| 711 | |
| 712 | open(STDERR, ">&STDOUT"); |
| 713 | $alloutput = `cmd args`; # stderr still escapes |
| 714 | |
| 715 | This fails because the open() makes STDERR go to where STDOUT was |
| 716 | going at the time of the open(). The backticks then make STDOUT go to |
| 717 | a string, but don't change STDERR (which still goes to the old |
| 718 | STDOUT). |
| 719 | |
| 720 | Note that you I<must> use Bourne shell (sh(1)) redirection syntax in |
| 721 | backticks, not csh(1)! Details on why Perl's system() and backtick |
| 722 | and pipe opens all use the Bourne shell are in the |
| 723 | F<versus/csh.whynot> article in the "Far More Than You Ever Wanted To |
| 724 | Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz . To |
| 725 | capture a command's STDERR and STDOUT together: |
| 726 | |
| 727 | $output = `cmd 2>&1`; # either with backticks |
| 728 | $pid = open(PH, "cmd 2>&1 |"); # or with an open pipe |
| 729 | while (<PH>) { } # plus a read |
| 730 | |
| 731 | To capture a command's STDOUT but discard its STDERR: |
| 732 | |
| 733 | $output = `cmd 2>/dev/null`; # either with backticks |
| 734 | $pid = open(PH, "cmd 2>/dev/null |"); # or with an open pipe |
| 735 | while (<PH>) { } # plus a read |
| 736 | |
| 737 | To capture a command's STDERR but discard its STDOUT: |
| 738 | |
| 739 | $output = `cmd 2>&1 1>/dev/null`; # either with backticks |
| 740 | $pid = open(PH, "cmd 2>&1 1>/dev/null |"); # or with an open pipe |
| 741 | while (<PH>) { } # plus a read |
| 742 | |
| 743 | To exchange a command's STDOUT and STDERR in order to capture the STDERR |
| 744 | but leave its STDOUT to come out our old STDERR: |
| 745 | |
| 746 | $output = `cmd 3>&1 1>&2 2>&3 3>&-`; # either with backticks |
| 747 | $pid = open(PH, "cmd 3>&1 1>&2 2>&3 3>&-|");# or with an open pipe |
| 748 | while (<PH>) { } # plus a read |
| 749 | |
| 750 | To read both a command's STDOUT and its STDERR separately, it's easiest |
| 751 | to redirect them separately to files, and then read from those files |
| 752 | when the program is done: |
| 753 | |
| 754 | system("program args 1>program.stdout 2>program.stderr"); |
| 755 | |
| 756 | Ordering is important in all these examples. That's because the shell |
| 757 | processes file descriptor redirections in strictly left to right order. |
| 758 | |
| 759 | system("prog args 1>tmpfile 2>&1"); |
| 760 | system("prog args 2>&1 1>tmpfile"); |
| 761 | |
| 762 | The first command sends both standard out and standard error to the |
| 763 | temporary file. The second command sends only the old standard output |
| 764 | there, and the old standard error shows up on the old standard out. |
| 765 | |
| 766 | =head2 Why doesn't open() return an error when a pipe open fails? |
| 767 | |
| 768 | If the second argument to a piped open() contains shell |
| 769 | metacharacters, perl fork()s, then exec()s a shell to decode the |
| 770 | metacharacters and eventually run the desired program. If the program |
| 771 | couldn't be run, it's the shell that gets the message, not Perl. All |
| 772 | your Perl program can find out is whether the shell itself could be |
| 773 | successfully started. You can still capture the shell's STDERR and |
| 774 | check it for error messages. See L<"How can I capture STDERR from an |
| 775 | external command?"> elsewhere in this document, or use the |
| 776 | IPC::Open3 module. |
| 777 | |
| 778 | If there are no shell metacharacters in the argument of open(), Perl |
| 779 | runs the command directly, without using the shell, and can correctly |
| 780 | report whether the command started. |
| 781 | |
| 782 | =head2 What's wrong with using backticks in a void context? |
| 783 | |
| 784 | Strictly speaking, nothing. Stylistically speaking, it's not a good |
| 785 | way to write maintainable code. Perl has several operators for |
| 786 | running external commands. Backticks are one; they collect the output |
| 787 | from the command for use in your program. The C<system> function is |
| 788 | another; it doesn't do this. |
| 789 | |
| 790 | Writing backticks in your program sends a clear message to the readers |
| 791 | of your code that you wanted to collect the output of the command. |
| 792 | Why send a clear message that isn't true? |
| 793 | |
| 794 | Consider this line: |
| 795 | |
| 796 | `cat /etc/termcap`; |
| 797 | |
| 798 | You forgot to check C<$?> to see whether the program even ran |
| 799 | correctly. Even if you wrote |
| 800 | |
| 801 | print `cat /etc/termcap`; |
| 802 | |
| 803 | this code could and probably should be written as |
| 804 | |
| 805 | system("cat /etc/termcap") == 0 |
| 806 | or die "cat program failed!"; |
| 807 | |
| 808 | which will get the output quickly (as it is generated, instead of only |
| 809 | at the end) and also check the return value. |
| 810 | |
| 811 | system() also provides direct control over whether shell wildcard |
| 812 | processing may take place, whereas backticks do not. |
| 813 | |
| 814 | =head2 How can I call backticks without shell processing? |
| 815 | |
| 816 | This is a bit tricky. You can't simply write the command |
| 817 | like this: |
| 818 | |
| 819 | @ok = `grep @opts '$search_string' @filenames`; |
| 820 | |
| 821 | As of Perl 5.8.0, you can use open() with multiple arguments. |
| 822 | Just like the list forms of system() and exec(), no shell |
| 823 | escapes happen. |
| 824 | |
| 825 | open( GREP, "-|", 'grep', @opts, $search_string, @filenames ); |
| 826 | chomp(@ok = <GREP>); |
| 827 | close GREP; |
| 828 | |
| 829 | You can also: |
| 830 | |
| 831 | my @ok = (); |
| 832 | if (open(GREP, "-|")) { |
| 833 | while (<GREP>) { |
| 834 | chomp; |
| 835 | push(@ok, $_); |
| 836 | } |
| 837 | close GREP; |
| 838 | } else { |
| 839 | exec 'grep', @opts, $search_string, @filenames; |
| 840 | } |
| 841 | |
| 842 | Just as with system(), no shell escapes happen when you exec() a list. |
| 843 | Further examples of this can be found in L<perlipc/"Safe Pipe Opens">. |
| 844 | |
| 845 | Note that if you're use Microsoft, no solution to this vexing issue |
| 846 | is even possible. Even if Perl were to emulate fork(), you'd still |
| 847 | be stuck, because Microsoft does not have a argc/argv-style API. |
| 848 | |
| 849 | =head2 Why can't my script read from STDIN after I gave it EOF (^D on Unix, ^Z on MS-DOS)? |
| 850 | |
| 851 | Some stdio's set error and eof flags that need clearing. The |
| 852 | POSIX module defines clearerr() that you can use. That is the |
| 853 | technically correct way to do it. Here are some less reliable |
| 854 | workarounds: |
| 855 | |
| 856 | =over 4 |
| 857 | |
| 858 | =item 1 |
| 859 | |
| 860 | Try keeping around the seekpointer and go there, like this: |
| 861 | |
| 862 | $where = tell(LOG); |
| 863 | seek(LOG, $where, 0); |
| 864 | |
| 865 | =item 2 |
| 866 | |
| 867 | If that doesn't work, try seeking to a different part of the file and |
| 868 | then back. |
| 869 | |
| 870 | =item 3 |
| 871 | |
| 872 | If that doesn't work, try seeking to a different part of |
| 873 | the file, reading something, and then seeking back. |
| 874 | |
| 875 | =item 4 |
| 876 | |
| 877 | If that doesn't work, give up on your stdio package and use sysread. |
| 878 | |
| 879 | =back |
| 880 | |
| 881 | =head2 How can I convert my shell script to perl? |
| 882 | |
| 883 | Learn Perl and rewrite it. Seriously, there's no simple converter. |
| 884 | Things that are awkward to do in the shell are easy to do in Perl, and |
| 885 | this very awkwardness is what would make a shell->perl converter |
| 886 | nigh-on impossible to write. By rewriting it, you'll think about what |
| 887 | you're really trying to do, and hopefully will escape the shell's |
| 888 | pipeline datastream paradigm, which while convenient for some matters, |
| 889 | causes many inefficiencies. |
| 890 | |
| 891 | =head2 Can I use perl to run a telnet or ftp session? |
| 892 | |
| 893 | Try the Net::FTP, TCP::Client, and Net::Telnet modules (available from |
| 894 | CPAN). http://www.cpan.org/scripts/netstuff/telnet.emul.shar |
| 895 | will also help for emulating the telnet protocol, but Net::Telnet is |
| 896 | quite probably easier to use.. |
| 897 | |
| 898 | If all you want to do is pretend to be telnet but don't need |
| 899 | the initial telnet handshaking, then the standard dual-process |
| 900 | approach will suffice: |
| 901 | |
| 902 | use IO::Socket; # new in 5.004 |
| 903 | $handle = IO::Socket::INET->new('www.perl.com:80') |
| 904 | || die "can't connect to port 80 on www.perl.com: $!"; |
| 905 | $handle->autoflush(1); |
| 906 | if (fork()) { # XXX: undef means failure |
| 907 | select($handle); |
| 908 | print while <STDIN>; # everything from stdin to socket |
| 909 | } else { |
| 910 | print while <$handle>; # everything from socket to stdout |
| 911 | } |
| 912 | close $handle; |
| 913 | exit; |
| 914 | |
| 915 | =head2 How can I write expect in Perl? |
| 916 | |
| 917 | Once upon a time, there was a library called chat2.pl (part of the |
| 918 | standard perl distribution), which never really got finished. If you |
| 919 | find it somewhere, I<don't use it>. These days, your best bet is to |
| 920 | look at the Expect module available from CPAN, which also requires two |
| 921 | other modules from CPAN, IO::Pty and IO::Stty. |
| 922 | |
| 923 | =head2 Is there a way to hide perl's command line from programs such as "ps"? |
| 924 | |
| 925 | First of all note that if you're doing this for security reasons (to |
| 926 | avoid people seeing passwords, for example) then you should rewrite |
| 927 | your program so that critical information is never given as an |
| 928 | argument. Hiding the arguments won't make your program completely |
| 929 | secure. |
| 930 | |
| 931 | To actually alter the visible command line, you can assign to the |
| 932 | variable $0 as documented in L<perlvar>. This won't work on all |
| 933 | operating systems, though. Daemon programs like sendmail place their |
| 934 | state there, as in: |
| 935 | |
| 936 | $0 = "orcus [accepting connections]"; |
| 937 | |
| 938 | =head2 I {changed directory, modified my environment} in a perl script. How come the change disappeared when I exited the script? How do I get my changes to be visible? |
| 939 | |
| 940 | =over 4 |
| 941 | |
| 942 | =item Unix |
| 943 | |
| 944 | In the strictest sense, it can't be done--the script executes as a |
| 945 | different process from the shell it was started from. Changes to a |
| 946 | process are not reflected in its parent--only in any children |
| 947 | created after the change. There is shell magic that may allow you to |
| 948 | fake it by eval()ing the script's output in your shell; check out the |
| 949 | comp.unix.questions FAQ for details. |
| 950 | |
| 951 | =back |
| 952 | |
| 953 | =head2 How do I close a process's filehandle without waiting for it to complete? |
| 954 | |
| 955 | Assuming your system supports such things, just send an appropriate signal |
| 956 | to the process (see L<perlfunc/"kill">). It's common to first send a TERM |
| 957 | signal, wait a little bit, and then send a KILL signal to finish it off. |
| 958 | |
| 959 | =head2 How do I fork a daemon process? |
| 960 | |
| 961 | If by daemon process you mean one that's detached (disassociated from |
| 962 | its tty), then the following process is reported to work on most |
| 963 | Unixish systems. Non-Unix users should check their Your_OS::Process |
| 964 | module for other solutions. |
| 965 | |
| 966 | =over 4 |
| 967 | |
| 968 | =item * |
| 969 | |
| 970 | Open /dev/tty and use the TIOCNOTTY ioctl on it. See L<tty> |
| 971 | for details. Or better yet, you can just use the POSIX::setsid() |
| 972 | function, so you don't have to worry about process groups. |
| 973 | |
| 974 | =item * |
| 975 | |
| 976 | Change directory to / |
| 977 | |
| 978 | =item * |
| 979 | |
| 980 | Reopen STDIN, STDOUT, and STDERR so they're not connected to the old |
| 981 | tty. |
| 982 | |
| 983 | =item * |
| 984 | |
| 985 | Background yourself like this: |
| 986 | |
| 987 | fork && exit; |
| 988 | |
| 989 | =back |
| 990 | |
| 991 | The Proc::Daemon module, available from CPAN, provides a function to |
| 992 | perform these actions for you. |
| 993 | |
| 994 | =head2 How do I find out if I'm running interactively or not? |
| 995 | |
| 996 | Good question. Sometimes C<-t STDIN> and C<-t STDOUT> can give clues, |
| 997 | sometimes not. |
| 998 | |
| 999 | if (-t STDIN && -t STDOUT) { |
| 1000 | print "Now what? "; |
| 1001 | } |
| 1002 | |
| 1003 | On POSIX systems, you can test whether your own process group matches |
| 1004 | the current process group of your controlling terminal as follows: |
| 1005 | |
| 1006 | use POSIX qw/getpgrp tcgetpgrp/; |
| 1007 | open(TTY, "/dev/tty") or die $!; |
| 1008 | $tpgrp = tcgetpgrp(fileno(*TTY)); |
| 1009 | $pgrp = getpgrp(); |
| 1010 | if ($tpgrp == $pgrp) { |
| 1011 | print "foreground\n"; |
| 1012 | } else { |
| 1013 | print "background\n"; |
| 1014 | } |
| 1015 | |
| 1016 | =head2 How do I timeout a slow event? |
| 1017 | |
| 1018 | Use the alarm() function, probably in conjunction with a signal |
| 1019 | handler, as documented in L<perlipc/"Signals"> and the section on |
| 1020 | "Signals" in the Camel. You may instead use the more flexible |
| 1021 | Sys::AlarmCall module available from CPAN. |
| 1022 | |
| 1023 | The alarm() function is not implemented on all versions of Windows. |
| 1024 | Check the documentation for your specific version of Perl. |
| 1025 | |
| 1026 | =head2 How do I set CPU limits? |
| 1027 | |
| 1028 | Use the BSD::Resource module from CPAN. |
| 1029 | |
| 1030 | =head2 How do I avoid zombies on a Unix system? |
| 1031 | |
| 1032 | Use the reaper code from L<perlipc/"Signals"> to call wait() when a |
| 1033 | SIGCHLD is received, or else use the double-fork technique described |
| 1034 | in L<perlfaq8/"How do I start a process in the background?">. |
| 1035 | |
| 1036 | =head2 How do I use an SQL database? |
| 1037 | |
| 1038 | The DBI module provides an abstract interface to most database |
| 1039 | servers and types, including Oracle, DB2, Sybase, mysql, Postgresql, |
| 1040 | ODBC, and flat files. The DBI module accesses each database type |
| 1041 | through a database driver, or DBD. You can see a complete list of |
| 1042 | available drivers on CPAN: http://www.cpan.org/modules/by-module/DBD/ . |
| 1043 | You can read more about DBI on http://dbi.perl.org . |
| 1044 | |
| 1045 | Other modules provide more specific access: Win32::ODBC, Alzabo, iodbc, |
| 1046 | and others found on CPAN Search: http://search.cpan.org . |
| 1047 | |
| 1048 | =head2 How do I make a system() exit on control-C? |
| 1049 | |
| 1050 | You can't. You need to imitate the system() call (see L<perlipc> for |
| 1051 | sample code) and then have a signal handler for the INT signal that |
| 1052 | passes the signal on to the subprocess. Or you can check for it: |
| 1053 | |
| 1054 | $rc = system($cmd); |
| 1055 | if ($rc & 127) { die "signal death" } |
| 1056 | |
| 1057 | =head2 How do I open a file without blocking? |
| 1058 | |
| 1059 | If you're lucky enough to be using a system that supports |
| 1060 | non-blocking reads (most Unixish systems do), you need only to use the |
| 1061 | O_NDELAY or O_NONBLOCK flag from the Fcntl module in conjunction with |
| 1062 | sysopen(): |
| 1063 | |
| 1064 | use Fcntl; |
| 1065 | sysopen(FH, "/foo/somefile", O_WRONLY|O_NDELAY|O_CREAT, 0644) |
| 1066 | or die "can't open /foo/somefile: $!": |
| 1067 | |
| 1068 | =head2 How do I tell the difference between errors from the shell and perl? |
| 1069 | |
| 1070 | (answer contributed by brian d foy, C<< <bdfoy@cpan.org> >> |
| 1071 | |
| 1072 | When you run a Perl script, something else is running the script for you, |
| 1073 | and that something else may output error messages. The script might |
| 1074 | emit its own warnings and error messages. Most of the time you cannot |
| 1075 | tell who said what. |
| 1076 | |
| 1077 | You probably cannot fix the thing that runs perl, but you can change how |
| 1078 | perl outputs its warnings by defining a custom warning and die functions. |
| 1079 | |
| 1080 | Consider this script, which has an error you may not notice immediately. |
| 1081 | |
| 1082 | #!/usr/locl/bin/perl |
| 1083 | |
| 1084 | print "Hello World\n"; |
| 1085 | |
| 1086 | I get an error when I run this from my shell (which happens to be |
| 1087 | bash). That may look like perl forgot it has a print() function, |
| 1088 | but my shebang line is not the path to perl, so the shell runs the |
| 1089 | script, and I get the error. |
| 1090 | |
| 1091 | $ ./test |
| 1092 | ./test: line 3: print: command not found |
| 1093 | |
| 1094 | A quick and dirty fix involves a little bit of code, but this may be all |
| 1095 | you need to figure out the problem. |
| 1096 | |
| 1097 | #!/usr/bin/perl -w |
| 1098 | |
| 1099 | BEGIN { |
| 1100 | $SIG{__WARN__} = sub{ print STDERR "Perl: ", @_; }; |
| 1101 | $SIG{__DIE__} = sub{ print STDERR "Perl: ", @_; exit 1}; |
| 1102 | } |
| 1103 | |
| 1104 | $a = 1 + undef; |
| 1105 | $x / 0; |
| 1106 | __END__ |
| 1107 | |
| 1108 | The perl message comes out with "Perl" in front. The BEGIN block |
| 1109 | works at compile time so all of the compilation errors and warnings |
| 1110 | get the "Perl:" prefix too. |
| 1111 | |
| 1112 | Perl: Useless use of division (/) in void context at ./test line 9. |
| 1113 | Perl: Name "main::a" used only once: possible typo at ./test line 8. |
| 1114 | Perl: Name "main::x" used only once: possible typo at ./test line 9. |
| 1115 | Perl: Use of uninitialized value in addition (+) at ./test line 8. |
| 1116 | Perl: Use of uninitialized value in division (/) at ./test line 9. |
| 1117 | Perl: Illegal division by zero at ./test line 9. |
| 1118 | Perl: Illegal division by zero at -e line 3. |
| 1119 | |
| 1120 | If I don't see that "Perl:", it's not from perl. |
| 1121 | |
| 1122 | You could also just know all the perl errors, and although there are |
| 1123 | some people who may know all of them, you probably don't. However, they |
| 1124 | all should be in the perldiag manpage. If you don't find the error in |
| 1125 | there, it probably isn't a perl error. |
| 1126 | |
| 1127 | Looking up every message is not the easiest way, so let perl to do it |
| 1128 | for you. Use the diagnostics pragma with turns perl's normal messages |
| 1129 | into longer discussions on the topic. |
| 1130 | |
| 1131 | use diagnostics; |
| 1132 | |
| 1133 | If you don't get a paragraph or two of expanded discussion, it |
| 1134 | might not be perl's message. |
| 1135 | |
| 1136 | =head2 How do I install a module from CPAN? |
| 1137 | |
| 1138 | The easiest way is to have a module also named CPAN do it for you. |
| 1139 | This module comes with perl version 5.004 and later. |
| 1140 | |
| 1141 | $ perl -MCPAN -e shell |
| 1142 | |
| 1143 | cpan shell -- CPAN exploration and modules installation (v1.59_54) |
| 1144 | ReadLine support enabled |
| 1145 | |
| 1146 | cpan> install Some::Module |
| 1147 | |
| 1148 | To manually install the CPAN module, or any well-behaved CPAN module |
| 1149 | for that matter, follow these steps: |
| 1150 | |
| 1151 | =over 4 |
| 1152 | |
| 1153 | =item 1 |
| 1154 | |
| 1155 | Unpack the source into a temporary area. |
| 1156 | |
| 1157 | =item 2 |
| 1158 | |
| 1159 | perl Makefile.PL |
| 1160 | |
| 1161 | =item 3 |
| 1162 | |
| 1163 | make |
| 1164 | |
| 1165 | =item 4 |
| 1166 | |
| 1167 | make test |
| 1168 | |
| 1169 | =item 5 |
| 1170 | |
| 1171 | make install |
| 1172 | |
| 1173 | =back |
| 1174 | |
| 1175 | If your version of perl is compiled without dynamic loading, then you |
| 1176 | just need to replace step 3 (B<make>) with B<make perl> and you will |
| 1177 | get a new F<perl> binary with your extension linked in. |
| 1178 | |
| 1179 | See L<ExtUtils::MakeMaker> for more details on building extensions. |
| 1180 | See also the next question, "What's the difference between require |
| 1181 | and use?". |
| 1182 | |
| 1183 | =head2 What's the difference between require and use? |
| 1184 | |
| 1185 | Perl offers several different ways to include code from one file into |
| 1186 | another. Here are the deltas between the various inclusion constructs: |
| 1187 | |
| 1188 | 1) do $file is like eval `cat $file`, except the former |
| 1189 | 1.1: searches @INC and updates %INC. |
| 1190 | 1.2: bequeaths an *unrelated* lexical scope on the eval'ed code. |
| 1191 | |
| 1192 | 2) require $file is like do $file, except the former |
| 1193 | 2.1: checks for redundant loading, skipping already loaded files. |
| 1194 | 2.2: raises an exception on failure to find, compile, or execute $file. |
| 1195 | |
| 1196 | 3) require Module is like require "Module.pm", except the former |
| 1197 | 3.1: translates each "::" into your system's directory separator. |
| 1198 | 3.2: primes the parser to disambiguate class Module as an indirect object. |
| 1199 | |
| 1200 | 4) use Module is like require Module, except the former |
| 1201 | 4.1: loads the module at compile time, not run-time. |
| 1202 | 4.2: imports symbols and semantics from that package to the current one. |
| 1203 | |
| 1204 | In general, you usually want C<use> and a proper Perl module. |
| 1205 | |
| 1206 | =head2 How do I keep my own module/library directory? |
| 1207 | |
| 1208 | When you build modules, use the PREFIX and LIB options when generating |
| 1209 | Makefiles: |
| 1210 | |
| 1211 | perl Makefile.PL PREFIX=/mydir/perl LIB=/mydir/perl/lib |
| 1212 | |
| 1213 | then either set the PERL5LIB environment variable before you run |
| 1214 | scripts that use the modules/libraries (see L<perlrun>) or say |
| 1215 | |
| 1216 | use lib '/mydir/perl/lib'; |
| 1217 | |
| 1218 | This is almost the same as |
| 1219 | |
| 1220 | BEGIN { |
| 1221 | unshift(@INC, '/mydir/perl/lib'); |
| 1222 | } |
| 1223 | |
| 1224 | except that the lib module checks for machine-dependent subdirectories. |
| 1225 | See Perl's L<lib> for more information. |
| 1226 | |
| 1227 | =head2 How do I add the directory my program lives in to the module/library search path? |
| 1228 | |
| 1229 | use FindBin; |
| 1230 | use lib "$FindBin::Bin"; |
| 1231 | use your_own_modules; |
| 1232 | |
| 1233 | =head2 How do I add a directory to my include path (@INC) at runtime? |
| 1234 | |
| 1235 | Here are the suggested ways of modifying your include path: |
| 1236 | |
| 1237 | the PERLLIB environment variable |
| 1238 | the PERL5LIB environment variable |
| 1239 | the perl -Idir command line flag |
| 1240 | the use lib pragma, as in |
| 1241 | use lib "$ENV{HOME}/myown_perllib"; |
| 1242 | |
| 1243 | The latter is particularly useful because it knows about machine |
| 1244 | dependent architectures. The lib.pm pragmatic module was first |
| 1245 | included with the 5.002 release of Perl. |
| 1246 | |
| 1247 | =head2 What is socket.ph and where do I get it? |
| 1248 | |
| 1249 | It's a perl4-style file defining values for system networking |
| 1250 | constants. Sometimes it is built using h2ph when Perl is installed, |
| 1251 | but other times it is not. Modern programs C<use Socket;> instead. |
| 1252 | |
| 1253 | =head1 AUTHOR AND COPYRIGHT |
| 1254 | |
| 1255 | Copyright (c) 1997-2005 Tom Christiansen, Nathan Torkington, and |
| 1256 | other authors as noted. All rights reserved. |
| 1257 | |
| 1258 | This documentation is free; you can redistribute it and/or modify it |
| 1259 | under the same terms as Perl itself. |
| 1260 | |
| 1261 | Irrespective of its distribution, all code examples in this file |
| 1262 | are hereby placed into the public domain. You are permitted and |
| 1263 | encouraged to use this code in your own programs for fun |
| 1264 | or for profit as you see fit. A simple comment in the code giving |
| 1265 | credit would be courteous but is not required. |