| 1 | /* perly.y |
| 2 | * |
| 3 | * Copyright (c) 1991-2001, Larry Wall |
| 4 | * |
| 5 | * You may distribute under the terms of either the GNU General Public |
| 6 | * License or the Artistic License, as specified in the README file. |
| 7 | * |
| 8 | */ |
| 9 | |
| 10 | /* |
| 11 | * 'I see,' laughed Strider. 'I look foul and feel fair. Is that it? |
| 12 | * All that is gold does not glitter, not all those who wander are lost.' |
| 13 | */ |
| 14 | |
| 15 | %{ |
| 16 | #include "EXTERN.h" |
| 17 | #define PERL_IN_PERLY_C |
| 18 | #include "perl.h" |
| 19 | #ifdef EBCDIC |
| 20 | #undef YYDEBUG |
| 21 | #endif |
| 22 | #define dep() deprecate("\"do\" to call subroutines") |
| 23 | |
| 24 | /* stuff included here to make perly_c.diff apply better */ |
| 25 | |
| 26 | #define yydebug PL_yydebug |
| 27 | #define yynerrs PL_yynerrs |
| 28 | #define yyerrflag PL_yyerrflag |
| 29 | #define yychar PL_yychar |
| 30 | #define yyval PL_yyval |
| 31 | #define yylval PL_yylval |
| 32 | |
| 33 | struct ysv { |
| 34 | short* yyss; |
| 35 | YYSTYPE* yyvs; |
| 36 | int oldyydebug; |
| 37 | int oldyynerrs; |
| 38 | int oldyyerrflag; |
| 39 | int oldyychar; |
| 40 | YYSTYPE oldyyval; |
| 41 | YYSTYPE oldyylval; |
| 42 | }; |
| 43 | |
| 44 | static void yydestruct(pTHX_ void *ptr); |
| 45 | |
| 46 | %} |
| 47 | |
| 48 | %start prog |
| 49 | |
| 50 | %{ |
| 51 | #if 0 /* get this from perly.h instead */ |
| 52 | %} |
| 53 | |
| 54 | %union { |
| 55 | I32 ival; |
| 56 | char *pval; |
| 57 | OP *opval; |
| 58 | GV *gvval; |
| 59 | } |
| 60 | |
| 61 | %{ |
| 62 | #endif /* 0 */ |
| 63 | |
| 64 | #ifdef USE_PURE_BISON |
| 65 | #define YYLEX_PARAM (&yychar) |
| 66 | #define yylex yylex_r |
| 67 | #endif |
| 68 | |
| 69 | %} |
| 70 | |
| 71 | %token <ival> '{' |
| 72 | |
| 73 | %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF |
| 74 | %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB |
| 75 | %token <pval> LABEL |
| 76 | %token <ival> FORMAT SUB ANONSUB PACKAGE USE |
| 77 | %token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR |
| 78 | %token <ival> LOOPEX DOTDOT |
| 79 | %token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP |
| 80 | %token <ival> RELOP EQOP MULOP ADDOP |
| 81 | %token <ival> DOLSHARP DO HASHBRACK NOAMP |
| 82 | %token <ival> LOCAL MY MYSUB |
| 83 | %token COLONATTR |
| 84 | |
| 85 | %type <ival> prog decl format startsub startanonsub startformsub |
| 86 | %type <ival> progstart remember mremember '&' |
| 87 | %type <opval> block mblock lineseq line loop cond else |
| 88 | %type <opval> expr term subscripted scalar ary hsh arylen star amper sideff |
| 89 | %type <opval> argexpr nexpr texpr iexpr mexpr mnexpr mtexpr miexpr |
| 90 | %type <opval> listexpr listexprcom indirob listop method |
| 91 | %type <opval> formname subname proto subbody cont my_scalar |
| 92 | %type <opval> subattrlist myattrlist mysubrout myattrterm myterm |
| 93 | %type <opval> termbinop termunop anonymous termdo |
| 94 | %type <pval> label |
| 95 | |
| 96 | %nonassoc PREC_LOW |
| 97 | %nonassoc LOOPEX |
| 98 | |
| 99 | %left <ival> OROP |
| 100 | %left ANDOP |
| 101 | %right NOTOP |
| 102 | %nonassoc LSTOP LSTOPSUB |
| 103 | %left ',' |
| 104 | %right <ival> ASSIGNOP |
| 105 | %right '?' ':' |
| 106 | %nonassoc DOTDOT |
| 107 | %left OROR |
| 108 | %left ANDAND |
| 109 | %left <ival> BITOROP |
| 110 | %left <ival> BITANDOP |
| 111 | %nonassoc EQOP |
| 112 | %nonassoc RELOP |
| 113 | %nonassoc UNIOP UNIOPSUB |
| 114 | %left <ival> SHIFTOP |
| 115 | %left ADDOP |
| 116 | %left MULOP |
| 117 | %left <ival> MATCHOP |
| 118 | %right '!' '~' UMINUS REFGEN |
| 119 | %right <ival> POWOP |
| 120 | %nonassoc PREINC PREDEC POSTINC POSTDEC |
| 121 | %left ARROW |
| 122 | %nonassoc <ival> ')' |
| 123 | %left '(' |
| 124 | %left '[' '{' |
| 125 | |
| 126 | %% /* RULES */ |
| 127 | |
| 128 | /* The whole program */ |
| 129 | prog : progstart |
| 130 | /*CONTINUED*/ lineseq |
| 131 | { $$ = $1; newPROG(block_end($1,$2)); } |
| 132 | ; |
| 133 | |
| 134 | /* An ordinary block */ |
| 135 | block : '{' remember lineseq '}' |
| 136 | { if (PL_copline > (line_t)$1) |
| 137 | PL_copline = $1; |
| 138 | $$ = block_end($2, $3); } |
| 139 | ; |
| 140 | |
| 141 | remember: /* NULL */ /* start a full lexical scope */ |
| 142 | { $$ = block_start(TRUE); } |
| 143 | ; |
| 144 | |
| 145 | progstart: |
| 146 | { |
| 147 | #if defined(YYDEBUG) && defined(DEBUGGING) |
| 148 | yydebug = (DEBUG_p_TEST); |
| 149 | #endif |
| 150 | PL_expect = XSTATE; $$ = block_start(TRUE); |
| 151 | } |
| 152 | ; |
| 153 | |
| 154 | |
| 155 | mblock : '{' mremember lineseq '}' |
| 156 | { if (PL_copline > (line_t)$1) |
| 157 | PL_copline = $1; |
| 158 | $$ = block_end($2, $3); } |
| 159 | ; |
| 160 | |
| 161 | mremember: /* NULL */ /* start a partial lexical scope */ |
| 162 | { $$ = block_start(FALSE); } |
| 163 | ; |
| 164 | |
| 165 | /* A collection of "lines" in the program */ |
| 166 | lineseq : /* NULL */ |
| 167 | { $$ = Nullop; } |
| 168 | | lineseq decl |
| 169 | { $$ = $1; } |
| 170 | | lineseq line |
| 171 | { $$ = append_list(OP_LINESEQ, |
| 172 | (LISTOP*)$1, (LISTOP*)$2); |
| 173 | PL_pad_reset_pending = TRUE; |
| 174 | if ($1 && $2) PL_hints |= HINT_BLOCK_SCOPE; } |
| 175 | ; |
| 176 | |
| 177 | /* A "line" in the program */ |
| 178 | line : label cond |
| 179 | { $$ = newSTATEOP(0, $1, $2); } |
| 180 | | loop /* loops add their own labels */ |
| 181 | | label ';' |
| 182 | { if ($1 != Nullch) { |
| 183 | $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0)); |
| 184 | } |
| 185 | else { |
| 186 | $$ = Nullop; |
| 187 | PL_copline = NOLINE; |
| 188 | } |
| 189 | PL_expect = XSTATE; } |
| 190 | | label sideff ';' |
| 191 | { $$ = newSTATEOP(0, $1, $2); |
| 192 | PL_expect = XSTATE; } |
| 193 | ; |
| 194 | |
| 195 | /* An expression which may have a side-effect */ |
| 196 | sideff : error |
| 197 | { $$ = Nullop; } |
| 198 | | expr |
| 199 | { $$ = $1; } |
| 200 | | expr IF expr |
| 201 | { $$ = newLOGOP(OP_AND, 0, $3, $1); } |
| 202 | | expr UNLESS expr |
| 203 | { $$ = newLOGOP(OP_OR, 0, $3, $1); } |
| 204 | | expr WHILE expr |
| 205 | { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); } |
| 206 | | expr UNTIL iexpr |
| 207 | { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);} |
| 208 | | expr FOR expr |
| 209 | { $$ = newFOROP(0, Nullch, $2, |
| 210 | Nullop, $3, $1, Nullop); } |
| 211 | ; |
| 212 | |
| 213 | /* else and elsif blocks */ |
| 214 | else : /* NULL */ |
| 215 | { $$ = Nullop; } |
| 216 | | ELSE mblock |
| 217 | { ($2)->op_flags |= OPf_PARENS; $$ = scope($2); } |
| 218 | | ELSIF '(' mexpr ')' mblock else |
| 219 | { PL_copline = $1; |
| 220 | $$ = newCONDOP(0, $3, scope($5), $6); |
| 221 | PL_hints |= HINT_BLOCK_SCOPE; } |
| 222 | ; |
| 223 | |
| 224 | /* Real conditional expressions */ |
| 225 | cond : IF '(' remember mexpr ')' mblock else |
| 226 | { PL_copline = $1; |
| 227 | $$ = block_end($3, |
| 228 | newCONDOP(0, $4, scope($6), $7)); } |
| 229 | | UNLESS '(' remember miexpr ')' mblock else |
| 230 | { PL_copline = $1; |
| 231 | $$ = block_end($3, |
| 232 | newCONDOP(0, $4, scope($6), $7)); } |
| 233 | ; |
| 234 | |
| 235 | /* Continue blocks */ |
| 236 | cont : /* NULL */ |
| 237 | { $$ = Nullop; } |
| 238 | | CONTINUE block |
| 239 | { $$ = scope($2); } |
| 240 | ; |
| 241 | |
| 242 | /* Loops: while, until, for, and a bare block */ |
| 243 | loop : label WHILE '(' remember mtexpr ')' mblock cont |
| 244 | { PL_copline = $2; |
| 245 | $$ = block_end($4, |
| 246 | newSTATEOP(0, $1, |
| 247 | newWHILEOP(0, 1, (LOOP*)Nullop, |
| 248 | $2, $5, $7, $8))); } |
| 249 | | label UNTIL '(' remember miexpr ')' mblock cont |
| 250 | { PL_copline = $2; |
| 251 | $$ = block_end($4, |
| 252 | newSTATEOP(0, $1, |
| 253 | newWHILEOP(0, 1, (LOOP*)Nullop, |
| 254 | $2, $5, $7, $8))); } |
| 255 | | label FOR MY remember my_scalar '(' mexpr ')' mblock cont |
| 256 | { $$ = block_end($4, |
| 257 | newFOROP(0, $1, $2, $5, $7, $9, $10)); } |
| 258 | | label FOR scalar '(' remember mexpr ')' mblock cont |
| 259 | { $$ = block_end($5, |
| 260 | newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP), |
| 261 | $6, $8, $9)); } |
| 262 | | label FOR '(' remember mexpr ')' mblock cont |
| 263 | { $$ = block_end($4, |
| 264 | newFOROP(0, $1, $2, Nullop, $5, $7, $8)); } |
| 265 | | label FOR '(' remember mnexpr ';' mtexpr ';' mnexpr ')' mblock |
| 266 | /* basically fake up an initialize-while lineseq */ |
| 267 | { OP *forop; |
| 268 | PL_copline = $2; |
| 269 | forop = newSTATEOP(0, $1, |
| 270 | newWHILEOP(0, 1, (LOOP*)Nullop, |
| 271 | $2, scalar($7), |
| 272 | $11, $9)); |
| 273 | if ($5) { |
| 274 | forop = append_elem(OP_LINESEQ, |
| 275 | newSTATEOP(0, ($1?savepv($1):Nullch), |
| 276 | $5), |
| 277 | forop); |
| 278 | } |
| 279 | |
| 280 | $$ = block_end($4, forop); } |
| 281 | | label block cont /* a block is a loop that happens once */ |
| 282 | { $$ = newSTATEOP(0, $1, |
| 283 | newWHILEOP(0, 1, (LOOP*)Nullop, |
| 284 | NOLINE, Nullop, $2, $3)); } |
| 285 | ; |
| 286 | |
| 287 | /* Normal expression */ |
| 288 | nexpr : /* NULL */ |
| 289 | { $$ = Nullop; } |
| 290 | | sideff |
| 291 | ; |
| 292 | |
| 293 | /* Boolean expression */ |
| 294 | texpr : /* NULL means true */ |
| 295 | { (void)scan_num("1", &yylval); $$ = yylval.opval; } |
| 296 | | expr |
| 297 | ; |
| 298 | |
| 299 | /* Inverted boolean expression */ |
| 300 | iexpr : expr |
| 301 | { $$ = invert(scalar($1)); } |
| 302 | ; |
| 303 | |
| 304 | /* Expression with its own lexical scope */ |
| 305 | mexpr : expr |
| 306 | { $$ = $1; intro_my(); } |
| 307 | ; |
| 308 | |
| 309 | mnexpr : nexpr |
| 310 | { $$ = $1; intro_my(); } |
| 311 | ; |
| 312 | |
| 313 | mtexpr : texpr |
| 314 | { $$ = $1; intro_my(); } |
| 315 | ; |
| 316 | |
| 317 | miexpr : iexpr |
| 318 | { $$ = $1; intro_my(); } |
| 319 | ; |
| 320 | |
| 321 | /* Optional "MAIN:"-style loop labels */ |
| 322 | label : /* empty */ |
| 323 | { $$ = Nullch; } |
| 324 | | LABEL |
| 325 | ; |
| 326 | |
| 327 | /* Some kind of declaration - does not take part in the parse tree */ |
| 328 | decl : format |
| 329 | { $$ = 0; } |
| 330 | | subrout |
| 331 | { $$ = 0; } |
| 332 | | mysubrout |
| 333 | { $$ = 0; } |
| 334 | | package |
| 335 | { $$ = 0; } |
| 336 | | use |
| 337 | { $$ = 0; } |
| 338 | ; |
| 339 | |
| 340 | format : FORMAT startformsub formname block |
| 341 | { newFORM($2, $3, $4); } |
| 342 | ; |
| 343 | |
| 344 | formname: WORD { $$ = $1; } |
| 345 | | /* NULL */ { $$ = Nullop; } |
| 346 | ; |
| 347 | |
| 348 | /* Unimplemented "my sub foo { }" */ |
| 349 | mysubrout: MYSUB startsub subname proto subattrlist subbody |
| 350 | { newMYSUB($2, $3, $4, $5, $6); } |
| 351 | ; |
| 352 | |
| 353 | /* Subroutine definition */ |
| 354 | subrout : SUB startsub subname proto subattrlist subbody |
| 355 | { newATTRSUB($2, $3, $4, $5, $6); } |
| 356 | ; |
| 357 | |
| 358 | startsub: /* NULL */ /* start a regular subroutine scope */ |
| 359 | { $$ = start_subparse(FALSE, 0); } |
| 360 | ; |
| 361 | |
| 362 | startanonsub: /* NULL */ /* start an anonymous subroutine scope */ |
| 363 | { $$ = start_subparse(FALSE, CVf_ANON); } |
| 364 | ; |
| 365 | |
| 366 | startformsub: /* NULL */ /* start a format subroutine scope */ |
| 367 | { $$ = start_subparse(TRUE, 0); } |
| 368 | ; |
| 369 | |
| 370 | /* Name of a subroutine - must be a bareword, could be special */ |
| 371 | subname : WORD { STRLEN n_a; char *name = SvPV(((SVOP*)$1)->op_sv,n_a); |
| 372 | if (strEQ(name, "BEGIN") || strEQ(name, "END") |
| 373 | || strEQ(name, "INIT") || strEQ(name, "CHECK")) |
| 374 | CvSPECIAL_on(PL_compcv); |
| 375 | $$ = $1; } |
| 376 | ; |
| 377 | |
| 378 | /* Subroutine prototype */ |
| 379 | proto : /* NULL */ |
| 380 | { $$ = Nullop; } |
| 381 | | THING |
| 382 | ; |
| 383 | |
| 384 | /* Optional list of subroutine attributes */ |
| 385 | subattrlist: /* NULL */ |
| 386 | { $$ = Nullop; } |
| 387 | | COLONATTR THING |
| 388 | { $$ = $2; } |
| 389 | | COLONATTR |
| 390 | { $$ = Nullop; } |
| 391 | ; |
| 392 | |
| 393 | /* List of attributes for a "my" variable declaration */ |
| 394 | myattrlist: COLONATTR THING |
| 395 | { $$ = $2; } |
| 396 | | COLONATTR |
| 397 | { $$ = Nullop; } |
| 398 | ; |
| 399 | |
| 400 | /* Subroutine body - either null or a block */ |
| 401 | subbody : block { $$ = $1; } |
| 402 | | ';' { $$ = Nullop; PL_expect = XSTATE; } |
| 403 | ; |
| 404 | |
| 405 | package : PACKAGE WORD ';' |
| 406 | { package($2); } |
| 407 | | PACKAGE ';' |
| 408 | { package(Nullop); } |
| 409 | ; |
| 410 | |
| 411 | use : USE startsub |
| 412 | { CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ } |
| 413 | WORD WORD listexpr ';' |
| 414 | { utilize($1, $2, $4, $5, $6); } |
| 415 | ; |
| 416 | |
| 417 | /* Ordinary expressions; logical combinations */ |
| 418 | expr : expr ANDOP expr |
| 419 | { $$ = newLOGOP(OP_AND, 0, $1, $3); } |
| 420 | | expr OROP expr |
| 421 | { $$ = newLOGOP($2, 0, $1, $3); } |
| 422 | | argexpr %prec PREC_LOW |
| 423 | ; |
| 424 | |
| 425 | /* Expressions are a list of terms joined by commas */ |
| 426 | argexpr : argexpr ',' |
| 427 | { $$ = $1; } |
| 428 | | argexpr ',' term |
| 429 | { $$ = append_elem(OP_LIST, $1, $3); } |
| 430 | | term %prec PREC_LOW |
| 431 | ; |
| 432 | |
| 433 | /* List operators */ |
| 434 | listop : LSTOP indirob argexpr /* print $fh @args */ |
| 435 | { $$ = convert($1, OPf_STACKED, |
| 436 | prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); } |
| 437 | | FUNC '(' indirob expr ')' /* print ($fh @args */ |
| 438 | { $$ = convert($1, OPf_STACKED, |
| 439 | prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); } |
| 440 | | term ARROW method '(' listexprcom ')' /* $foo->bar(list) */ |
| 441 | { $$ = convert(OP_ENTERSUB, OPf_STACKED, |
| 442 | append_elem(OP_LIST, |
| 443 | prepend_elem(OP_LIST, scalar($1), $5), |
| 444 | newUNOP(OP_METHOD, 0, $3))); } |
| 445 | | term ARROW method /* $foo->bar */ |
| 446 | { $$ = convert(OP_ENTERSUB, OPf_STACKED, |
| 447 | append_elem(OP_LIST, scalar($1), |
| 448 | newUNOP(OP_METHOD, 0, $3))); } |
| 449 | | METHOD indirob listexpr /* new Class @args */ |
| 450 | { $$ = convert(OP_ENTERSUB, OPf_STACKED, |
| 451 | append_elem(OP_LIST, |
| 452 | prepend_elem(OP_LIST, $2, $3), |
| 453 | newUNOP(OP_METHOD, 0, $1))); } |
| 454 | | FUNCMETH indirob '(' listexprcom ')' /* method $object (@args) */ |
| 455 | { $$ = convert(OP_ENTERSUB, OPf_STACKED, |
| 456 | append_elem(OP_LIST, |
| 457 | prepend_elem(OP_LIST, $2, $4), |
| 458 | newUNOP(OP_METHOD, 0, $1))); } |
| 459 | | LSTOP listexpr /* print @args */ |
| 460 | { $$ = convert($1, 0, $2); } |
| 461 | | FUNC '(' listexprcom ')' /* print (@args) */ |
| 462 | { $$ = convert($1, 0, $3); } |
| 463 | | LSTOPSUB startanonsub block /* map { foo } ... */ |
| 464 | { $3 = newANONATTRSUB($2, 0, Nullop, $3); } |
| 465 | listexpr %prec LSTOP /* ... @bar */ |
| 466 | { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, |
| 467 | append_elem(OP_LIST, |
| 468 | prepend_elem(OP_LIST, $3, $5), $1)); } |
| 469 | ; |
| 470 | |
| 471 | /* Names of methods. May use $object->$methodname */ |
| 472 | method : METHOD |
| 473 | | scalar |
| 474 | ; |
| 475 | |
| 476 | /* Some kind of subscripted expression */ |
| 477 | subscripted: star '{' expr ';' '}' /* *main::{something} */ |
| 478 | /* In this and all the hash accessors, ';' is |
| 479 | * provided by the tokeniser */ |
| 480 | { $$ = newBINOP(OP_GELEM, 0, $1, scalar($3)); } |
| 481 | | scalar '[' expr ']' /* $array[$element] */ |
| 482 | { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); } |
| 483 | | term ARROW '[' expr ']' /* somearef->[$element] */ |
| 484 | { $$ = newBINOP(OP_AELEM, 0, |
| 485 | ref(newAVREF($1),OP_RV2AV), |
| 486 | scalar($4));} |
| 487 | | subscripted '[' expr ']' /* $foo->[$bar]->[$baz] */ |
| 488 | { $$ = newBINOP(OP_AELEM, 0, |
| 489 | ref(newAVREF($1),OP_RV2AV), |
| 490 | scalar($3));} |
| 491 | | scalar '{' expr ';' '}' /* $foo->{bar();} */ |
| 492 | { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3)); |
| 493 | PL_expect = XOPERATOR; } |
| 494 | | term ARROW '{' expr ';' '}' /* somehref->{bar();} */ |
| 495 | { $$ = newBINOP(OP_HELEM, 0, |
| 496 | ref(newHVREF($1),OP_RV2HV), |
| 497 | jmaybe($4)); |
| 498 | PL_expect = XOPERATOR; } |
| 499 | | subscripted '{' expr ';' '}' /* $foo->[bar]->{baz;} */ |
| 500 | { $$ = newBINOP(OP_HELEM, 0, |
| 501 | ref(newHVREF($1),OP_RV2HV), |
| 502 | jmaybe($3)); |
| 503 | PL_expect = XOPERATOR; } |
| 504 | | term ARROW '(' ')' /* $subref->() */ |
| 505 | { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, |
| 506 | newCVREF(0, scalar($1))); } |
| 507 | | term ARROW '(' expr ')' /* $subref->(@args) */ |
| 508 | { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, |
| 509 | append_elem(OP_LIST, $4, |
| 510 | newCVREF(0, scalar($1)))); } |
| 511 | |
| 512 | | subscripted '(' expr ')' /* $foo->{bar}->(@args) */ |
| 513 | { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, |
| 514 | append_elem(OP_LIST, $3, |
| 515 | newCVREF(0, scalar($1)))); } |
| 516 | | subscripted '(' ')' /* $foo->{bar}->() */ |
| 517 | { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, |
| 518 | newCVREF(0, scalar($1))); } |
| 519 | ; |
| 520 | |
| 521 | /* Binary operators between terms */ |
| 522 | termbinop : term ASSIGNOP term /* $x = $y */ |
| 523 | { $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); } |
| 524 | | term POWOP term /* $x ** $y */ |
| 525 | { $$ = newBINOP($2, 0, scalar($1), scalar($3)); } |
| 526 | | term MULOP term /* $x * $y, $x x $y */ |
| 527 | { if ($2 != OP_REPEAT) |
| 528 | scalar($1); |
| 529 | $$ = newBINOP($2, 0, $1, scalar($3)); } |
| 530 | | term ADDOP term /* $x + $y */ |
| 531 | { $$ = newBINOP($2, 0, scalar($1), scalar($3)); } |
| 532 | | term SHIFTOP term /* $x >> $y, $x << $y */ |
| 533 | { $$ = newBINOP($2, 0, scalar($1), scalar($3)); } |
| 534 | | term RELOP term /* $x > $y, etc. */ |
| 535 | { $$ = newBINOP($2, 0, scalar($1), scalar($3)); } |
| 536 | | term EQOP term /* $x == $y, $x eq $y */ |
| 537 | { $$ = newBINOP($2, 0, scalar($1), scalar($3)); } |
| 538 | | term BITANDOP term /* $x & $y */ |
| 539 | { $$ = newBINOP($2, 0, scalar($1), scalar($3)); } |
| 540 | | term BITOROP term /* $x | $y */ |
| 541 | { $$ = newBINOP($2, 0, scalar($1), scalar($3)); } |
| 542 | | term DOTDOT term /* $x..$y, $x...$y */ |
| 543 | { $$ = newRANGE($2, scalar($1), scalar($3));} |
| 544 | | term ANDAND term /* $x && $y */ |
| 545 | { $$ = newLOGOP(OP_AND, 0, $1, $3); } |
| 546 | | term OROR term /* $x || $y */ |
| 547 | { $$ = newLOGOP(OP_OR, 0, $1, $3); } |
| 548 | | term MATCHOP term /* $x =~ /$y/ */ |
| 549 | { $$ = bind_match($2, $1, $3); } |
| 550 | ; |
| 551 | |
| 552 | /* Unary operators and terms */ |
| 553 | termunop : '-' term %prec UMINUS /* -$x */ |
| 554 | { $$ = newUNOP(OP_NEGATE, 0, scalar($2)); } |
| 555 | | '+' term %prec UMINUS /* +$x */ |
| 556 | { $$ = $2; } |
| 557 | | '!' term /* !$x */ |
| 558 | { $$ = newUNOP(OP_NOT, 0, scalar($2)); } |
| 559 | | '~' term /* ~$x */ |
| 560 | { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));} |
| 561 | | term POSTINC /* $x++ */ |
| 562 | { $$ = newUNOP(OP_POSTINC, 0, |
| 563 | mod(scalar($1), OP_POSTINC)); } |
| 564 | | term POSTDEC /* $x-- */ |
| 565 | { $$ = newUNOP(OP_POSTDEC, 0, |
| 566 | mod(scalar($1), OP_POSTDEC)); } |
| 567 | | PREINC term /* ++$x */ |
| 568 | { $$ = newUNOP(OP_PREINC, 0, |
| 569 | mod(scalar($2), OP_PREINC)); } |
| 570 | | PREDEC term /* --$x */ |
| 571 | { $$ = newUNOP(OP_PREDEC, 0, |
| 572 | mod(scalar($2), OP_PREDEC)); } |
| 573 | |
| 574 | ; |
| 575 | |
| 576 | /* Constructors for anonymous data */ |
| 577 | anonymous: '[' expr ']' |
| 578 | { $$ = newANONLIST($2); } |
| 579 | | '[' ']' |
| 580 | { $$ = newANONLIST(Nullop); } |
| 581 | | HASHBRACK expr ';' '}' %prec '(' /* { foo => "Bar" } */ |
| 582 | { $$ = newANONHASH($2); } |
| 583 | | HASHBRACK ';' '}' %prec '(' /* { } (';' by tokener) */ |
| 584 | { $$ = newANONHASH(Nullop); } |
| 585 | | ANONSUB startanonsub proto subattrlist block %prec '(' |
| 586 | { $$ = newANONATTRSUB($2, $3, $4, $5); } |
| 587 | |
| 588 | ; |
| 589 | |
| 590 | /* Things called with "do" */ |
| 591 | termdo : DO term %prec UNIOP /* do $filename */ |
| 592 | { $$ = dofile($2); } |
| 593 | | DO block %prec '(' /* do { code */ |
| 594 | { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); } |
| 595 | | DO WORD '(' ')' /* do somesub() */ |
| 596 | { $$ = newUNOP(OP_ENTERSUB, |
| 597 | OPf_SPECIAL|OPf_STACKED, |
| 598 | prepend_elem(OP_LIST, |
| 599 | scalar(newCVREF( |
| 600 | (OPpENTERSUB_AMPER<<8), |
| 601 | scalar($2) |
| 602 | )),Nullop)); dep();} |
| 603 | | DO WORD '(' expr ')' /* do somesub(@args) */ |
| 604 | { $$ = newUNOP(OP_ENTERSUB, |
| 605 | OPf_SPECIAL|OPf_STACKED, |
| 606 | append_elem(OP_LIST, |
| 607 | $4, |
| 608 | scalar(newCVREF( |
| 609 | (OPpENTERSUB_AMPER<<8), |
| 610 | scalar($2) |
| 611 | )))); dep();} |
| 612 | | DO scalar '(' ')' /* do $subref () */ |
| 613 | { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED, |
| 614 | prepend_elem(OP_LIST, |
| 615 | scalar(newCVREF(0,scalar($2))), Nullop)); dep();} |
| 616 | | DO scalar '(' expr ')' /* do $subref (@args) */ |
| 617 | { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED, |
| 618 | prepend_elem(OP_LIST, |
| 619 | $4, |
| 620 | scalar(newCVREF(0,scalar($2))))); dep();} |
| 621 | |
| 622 | ; |
| 623 | |
| 624 | term : termbinop |
| 625 | | termunop |
| 626 | | anonymous |
| 627 | | termdo |
| 628 | | term '?' term ':' term |
| 629 | { $$ = newCONDOP(0, $1, $3, $5); } |
| 630 | | REFGEN term /* \$x, \@y, \%z */ |
| 631 | { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); } |
| 632 | | myattrterm %prec UNIOP |
| 633 | { $$ = $1; } |
| 634 | | LOCAL term %prec UNIOP |
| 635 | { $$ = localize($2,$1); } |
| 636 | | '(' expr ')' |
| 637 | { $$ = sawparens($2); } |
| 638 | | '(' ')' |
| 639 | { $$ = sawparens(newNULLLIST()); } |
| 640 | | scalar %prec '(' |
| 641 | { $$ = $1; } |
| 642 | | star %prec '(' |
| 643 | { $$ = $1; } |
| 644 | | hsh %prec '(' |
| 645 | { $$ = $1; } |
| 646 | | ary %prec '(' |
| 647 | { $$ = $1; } |
| 648 | | arylen %prec '(' /* $#x, $#{ something } */ |
| 649 | { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));} |
| 650 | | subscripted |
| 651 | { $$ = $1; } |
| 652 | | '(' expr ')' '[' expr ']' /* list slice */ |
| 653 | { $$ = newSLICEOP(0, $5, $2); } |
| 654 | | '(' ')' '[' expr ']' /* empty list slice! */ |
| 655 | { $$ = newSLICEOP(0, $4, Nullop); } |
| 656 | | ary '[' expr ']' /* array slice */ |
| 657 | { $$ = prepend_elem(OP_ASLICE, |
| 658 | newOP(OP_PUSHMARK, 0), |
| 659 | newLISTOP(OP_ASLICE, 0, |
| 660 | list($3), |
| 661 | ref($1, OP_ASLICE))); } |
| 662 | | ary '{' expr ';' '}' /* @hash{@keys} */ |
| 663 | { $$ = prepend_elem(OP_HSLICE, |
| 664 | newOP(OP_PUSHMARK, 0), |
| 665 | newLISTOP(OP_HSLICE, 0, |
| 666 | list($3), |
| 667 | ref(oopsHV($1), OP_HSLICE))); |
| 668 | PL_expect = XOPERATOR; } |
| 669 | | THING %prec '(' |
| 670 | { $$ = $1; } |
| 671 | | amper /* &foo; */ |
| 672 | { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); } |
| 673 | | amper '(' ')' /* &foo() */ |
| 674 | { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); } |
| 675 | | amper '(' expr ')' /* &foo(@args) */ |
| 676 | { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, |
| 677 | append_elem(OP_LIST, $3, scalar($1))); } |
| 678 | | NOAMP WORD listexpr /* foo(@args) */ |
| 679 | { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, |
| 680 | append_elem(OP_LIST, $3, scalar($2))); } |
| 681 | | LOOPEX /* loop exiting command (goto, last, dump, etc) */ |
| 682 | { $$ = newOP($1, OPf_SPECIAL); |
| 683 | PL_hints |= HINT_BLOCK_SCOPE; } |
| 684 | | LOOPEX term |
| 685 | { $$ = newLOOPEX($1,$2); } |
| 686 | | NOTOP argexpr /* not $foo */ |
| 687 | { $$ = newUNOP(OP_NOT, 0, scalar($2)); } |
| 688 | | UNIOP /* Unary op, $_ implied */ |
| 689 | { $$ = newOP($1, 0); } |
| 690 | | UNIOP block /* eval { foo }, I *think* */ |
| 691 | { $$ = newUNOP($1, 0, $2); } |
| 692 | | UNIOP term /* Unary op */ |
| 693 | { $$ = newUNOP($1, 0, $2); } |
| 694 | | UNIOPSUB term /* Sub treated as unop */ |
| 695 | { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, |
| 696 | append_elem(OP_LIST, $2, scalar($1))); } |
| 697 | | FUNC0 /* Nullary operator */ |
| 698 | { $$ = newOP($1, 0); } |
| 699 | | FUNC0 '(' ')' |
| 700 | { $$ = newOP($1, 0); } |
| 701 | | FUNC0SUB /* Sub treated as nullop */ |
| 702 | { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, |
| 703 | scalar($1)); } |
| 704 | | FUNC1 '(' ')' /* not () */ |
| 705 | { $$ = newOP($1, OPf_SPECIAL); } |
| 706 | | FUNC1 '(' expr ')' /* not($foo) */ |
| 707 | { $$ = newUNOP($1, 0, $3); } |
| 708 | | PMFUNC '(' term ')' /* split (/foo/) */ |
| 709 | { $$ = pmruntime($1, $3, Nullop); } |
| 710 | | PMFUNC '(' term ',' term ')' /* split (/foo/,$bar) */ |
| 711 | { $$ = pmruntime($1, $3, $5); } |
| 712 | | WORD |
| 713 | | listop |
| 714 | ; |
| 715 | |
| 716 | /* "my" declarations, with optional attributes */ |
| 717 | myattrterm: MY myterm myattrlist |
| 718 | { $$ = my_attrs($2,$3); } |
| 719 | | MY myterm |
| 720 | { $$ = localize($2,$1); } |
| 721 | ; |
| 722 | |
| 723 | /* Things that can be "my"'d */ |
| 724 | myterm : '(' expr ')' |
| 725 | { $$ = sawparens($2); } |
| 726 | | '(' ')' |
| 727 | { $$ = sawparens(newNULLLIST()); } |
| 728 | | scalar %prec '(' |
| 729 | { $$ = $1; } |
| 730 | | hsh %prec '(' |
| 731 | { $$ = $1; } |
| 732 | | ary %prec '(' |
| 733 | { $$ = $1; } |
| 734 | ; |
| 735 | |
| 736 | /* Basic list expressions */ |
| 737 | listexpr: /* NULL */ %prec PREC_LOW |
| 738 | { $$ = Nullop; } |
| 739 | | argexpr %prec PREC_LOW |
| 740 | { $$ = $1; } |
| 741 | ; |
| 742 | |
| 743 | listexprcom: /* NULL */ |
| 744 | { $$ = Nullop; } |
| 745 | | expr |
| 746 | { $$ = $1; } |
| 747 | | expr ',' |
| 748 | { $$ = $1; } |
| 749 | ; |
| 750 | |
| 751 | /* A little bit of trickery to make "for my $foo (@bar)" actually be |
| 752 | lexical */ |
| 753 | my_scalar: scalar |
| 754 | { PL_in_my = 0; $$ = my($1); } |
| 755 | ; |
| 756 | |
| 757 | amper : '&' indirob |
| 758 | { $$ = newCVREF($1,$2); } |
| 759 | ; |
| 760 | |
| 761 | scalar : '$' indirob |
| 762 | { $$ = newSVREF($2); } |
| 763 | ; |
| 764 | |
| 765 | ary : '@' indirob |
| 766 | { $$ = newAVREF($2); } |
| 767 | ; |
| 768 | |
| 769 | hsh : '%' indirob |
| 770 | { $$ = newHVREF($2); } |
| 771 | ; |
| 772 | |
| 773 | arylen : DOLSHARP indirob |
| 774 | { $$ = newAVREF($2); } |
| 775 | ; |
| 776 | |
| 777 | star : '*' indirob |
| 778 | { $$ = newGVREF(0,$2); } |
| 779 | ; |
| 780 | |
| 781 | /* Indirect objects */ |
| 782 | indirob : WORD |
| 783 | { $$ = scalar($1); } |
| 784 | | scalar %prec PREC_LOW |
| 785 | { $$ = scalar($1); } |
| 786 | | block |
| 787 | { $$ = scope($1); } |
| 788 | |
| 789 | | PRIVATEREF |
| 790 | { $$ = $1; } |
| 791 | ; |
| 792 | |
| 793 | %% /* PROGRAM */ |
| 794 | |
| 795 | /* more stuff added to make perly_c.diff easier to apply */ |
| 796 | |
| 797 | #ifdef yyparse |
| 798 | #undef yyparse |
| 799 | #endif |
| 800 | #define yyparse() Perl_yyparse(pTHX) |
| 801 | |