| 1 | =head1 NAME |
| 2 | |
| 3 | perldata - Perl data types |
| 4 | |
| 5 | =head1 DESCRIPTION |
| 6 | |
| 7 | =head2 Variable names |
| 8 | X<variable, name> X<variable name> X<data type> X<type> |
| 9 | |
| 10 | Perl has three built-in data types: scalars, arrays of scalars, and |
| 11 | associative arrays of scalars, known as "hashes". A scalar is a |
| 12 | single string (of any size, limited only by the available memory), |
| 13 | number, or a reference to something (which will be discussed |
| 14 | in L<perlref>). Normal arrays are ordered lists of scalars indexed |
| 15 | by number, starting with 0. Hashes are unordered collections of scalar |
| 16 | values indexed by their associated string key. |
| 17 | |
| 18 | Values are usually referred to by name, or through a named reference. |
| 19 | The first character of the name tells you to what sort of data |
| 20 | structure it refers. The rest of the name tells you the particular |
| 21 | value to which it refers. Usually this name is a single I<identifier>, |
| 22 | that is, a string beginning with a letter or underscore, and |
| 23 | containing letters, underscores, and digits. In some cases, it may |
| 24 | be a chain of identifiers, separated by C<::> (or by the slightly |
| 25 | archaic C<'>); all but the last are interpreted as names of packages, |
| 26 | to locate the namespace in which to look up the final identifier |
| 27 | (see L<perlmod/Packages> for details). For a more in-depth discussion |
| 28 | on identifiers, see L</Identifier parsing>. It's possible to |
| 29 | substitute for a simple identifier, an expression that produces a reference |
| 30 | to the value at runtime. This is described in more detail below |
| 31 | and in L<perlref>. |
| 32 | X<identifier> |
| 33 | |
| 34 | Perl also has its own built-in variables whose names don't follow |
| 35 | these rules. They have strange names so they don't accidentally |
| 36 | collide with one of your normal variables. Strings that match |
| 37 | parenthesized parts of a regular expression are saved under names |
| 38 | containing only digits after the C<$> (see L<perlop> and L<perlre>). |
| 39 | In addition, several special variables that provide windows into |
| 40 | the inner working of Perl have names containing punctuation characters. |
| 41 | These are documented in L<perlvar>. |
| 42 | X<variable, built-in> |
| 43 | |
| 44 | Scalar values are always named with '$', even when referring to a |
| 45 | scalar that is part of an array or a hash. The '$' symbol works |
| 46 | semantically like the English word "the" in that it indicates a |
| 47 | single value is expected. |
| 48 | X<scalar> |
| 49 | |
| 50 | $days # the simple scalar value "days" |
| 51 | $days[28] # the 29th element of array @days |
| 52 | $days{'Feb'} # the 'Feb' value from hash %days |
| 53 | $#days # the last index of array @days |
| 54 | |
| 55 | Entire arrays (and slices of arrays and hashes) are denoted by '@', |
| 56 | which works much as the word "these" or "those" does in English, |
| 57 | in that it indicates multiple values are expected. |
| 58 | X<array> |
| 59 | |
| 60 | @days # ($days[0], $days[1],... $days[n]) |
| 61 | @days[3,4,5] # same as ($days[3],$days[4],$days[5]) |
| 62 | @days{'a','c'} # same as ($days{'a'},$days{'c'}) |
| 63 | |
| 64 | Entire hashes are denoted by '%': |
| 65 | X<hash> |
| 66 | |
| 67 | %days # (key1, val1, key2, val2 ...) |
| 68 | |
| 69 | In addition, subroutines are named with an initial '&', though this |
| 70 | is optional when unambiguous, just as the word "do" is often redundant |
| 71 | in English. Symbol table entries can be named with an initial '*', |
| 72 | but you don't really care about that yet (if ever :-). |
| 73 | |
| 74 | Every variable type has its own namespace, as do several |
| 75 | non-variable identifiers. This means that you can, without fear |
| 76 | of conflict, use the same name for a scalar variable, an array, or |
| 77 | a hash--or, for that matter, for a filehandle, a directory handle, a |
| 78 | subroutine name, a format name, or a label. This means that $foo |
| 79 | and @foo are two different variables. It also means that C<$foo[1]> |
| 80 | is a part of @foo, not a part of $foo. This may seem a bit weird, |
| 81 | but that's okay, because it is weird. |
| 82 | X<namespace> |
| 83 | |
| 84 | Because variable references always start with '$', '@', or '%', the |
| 85 | "reserved" words aren't in fact reserved with respect to variable |
| 86 | names. They I<are> reserved with respect to labels and filehandles, |
| 87 | however, which don't have an initial special character. You can't |
| 88 | have a filehandle named "log", for instance. Hint: you could say |
| 89 | C<open(LOG,'logfile')> rather than C<open(log,'logfile')>. Using |
| 90 | uppercase filehandles also improves readability and protects you |
| 91 | from conflict with future reserved words. Case I<is> significant--"FOO", |
| 92 | "Foo", and "foo" are all different names. Names that start with a |
| 93 | letter or underscore may also contain digits and underscores. |
| 94 | X<identifier, case sensitivity> |
| 95 | X<case> |
| 96 | |
| 97 | It is possible to replace such an alphanumeric name with an expression |
| 98 | that returns a reference to the appropriate type. For a description |
| 99 | of this, see L<perlref>. |
| 100 | |
| 101 | Names that start with a digit may contain only more digits. Names |
| 102 | that do not start with a letter, underscore, digit or a caret are |
| 103 | limited to one character, e.g., C<$%> or |
| 104 | C<$$>. (Most of these one character names have a predefined |
| 105 | significance to Perl. For instance, C<$$> is the current process |
| 106 | id. And all such names are reserved for Perl's possible use.) |
| 107 | |
| 108 | =head2 Identifier parsing |
| 109 | X<identifiers> |
| 110 | |
| 111 | Up until Perl 5.18, the actual rules of what a valid identifier |
| 112 | was were a bit fuzzy. However, in general, anything defined here should |
| 113 | work on previous versions of Perl, while the opposite -- edge cases |
| 114 | that work in previous versions, but aren't defined here -- probably |
| 115 | won't work on newer versions. |
| 116 | As an important side note, please note that the following only applies |
| 117 | to bareword identifiers as found in Perl source code, not identifiers |
| 118 | introduced through symbolic references, which have much fewer |
| 119 | restrictions. |
| 120 | If working under the effect of the C<use utf8;> pragma, the following |
| 121 | rules apply: |
| 122 | |
| 123 | / (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) |
| 124 | (?[ ( \p{Word} & \p{XID_Continue} ) ]) * /x |
| 125 | |
| 126 | That is, a "start" character followed by any number of "continue" |
| 127 | characters. Perl requires every character in an identifier to also |
| 128 | match C<\w> (this prevents some problematic cases); and Perl |
| 129 | additionally accepts identfier names beginning with an underscore. |
| 130 | |
| 131 | If not under C<use utf8>, the source is treated as ASCII + 128 extra |
| 132 | generic characters, and identifiers should match |
| 133 | |
| 134 | / (?aa) (?!\d) \w+ /x |
| 135 | |
| 136 | That is, any word character in the ASCII range, as long as the first |
| 137 | character is not a digit. |
| 138 | |
| 139 | There are two package separators in Perl: A double colon (C<::>) and a single |
| 140 | quote (C<'>). Normal identifiers can start or end with a double colon, and |
| 141 | can contain several parts delimited by double colons. |
| 142 | Single quotes have similar rules, but with the exception that they are not |
| 143 | legal at the end of an identifier: That is, C<$'foo> and C<$foo'bar> are |
| 144 | legal, but C<$foo'bar'> is not. |
| 145 | |
| 146 | Additionally, if the identifier is preceded by a sigil -- |
| 147 | that is, if the identifier is part of a variable name -- it |
| 148 | may optionally be enclosed in braces. |
| 149 | |
| 150 | While you can mix double colons with singles quotes, the quotes must come |
| 151 | after the colons: C<$::::'foo> and C<$foo::'bar> are legal, but C<$::'::foo> |
| 152 | and C<$foo'::bar> are not. |
| 153 | |
| 154 | Put together, a grammar to match a basic identifier becomes |
| 155 | |
| 156 | / |
| 157 | (?(DEFINE) |
| 158 | (?<variable> |
| 159 | (?&sigil) |
| 160 | (?: |
| 161 | (?&normal_identifier) |
| 162 | | \{ \s* (?&normal_identifier) \s* \} |
| 163 | ) |
| 164 | ) |
| 165 | (?<normal_identifier> |
| 166 | (?: :: )* '? |
| 167 | (?&basic_identifier) |
| 168 | (?: (?= (?: :: )+ '? | (?: :: )* ' ) (?&normal_identifier) )? |
| 169 | (?: :: )* |
| 170 | ) |
| 171 | (?<basic_identifier> |
| 172 | # is use utf8 on? |
| 173 | (?(?{ (caller(0))[8] & $utf8::hint_bits }) |
| 174 | (?&Perl_XIDS) (?&Perl_XIDC)* |
| 175 | | (?aa) (?!\d) \w+ |
| 176 | ) |
| 177 | ) |
| 178 | (?<sigil> [&*\$\@\%]) |
| 179 | (?<Perl_XIDS> (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) ) |
| 180 | (?<Perl_XIDC> (?[ \p{Word} & \p{XID_Continue} ]) ) |
| 181 | ) |
| 182 | /x |
| 183 | |
| 184 | Meanwhile, special identifiers don't follow the above rules; For the most |
| 185 | part, all of the identifiers in this category have a special meaning given |
| 186 | by Perl. Because they have special parsing rules, these generally can't be |
| 187 | fully-qualified. They come in six forms (but don't use forms 5 and 6): |
| 188 | |
| 189 | =over |
| 190 | |
| 191 | =item 1. |
| 192 | |
| 193 | A sigil, followed solely by digits matching C<\p{POSIX_Digit}>, like |
| 194 | C<$0>, C<$1>, or C<$10000>. |
| 195 | |
| 196 | =item 2. |
| 197 | |
| 198 | A sigil followed by a single character matching the C<\p{POSIX_Punct}> |
| 199 | property, like C<$!> or C<%+>, except the character C<"{"> doesn't work. |
| 200 | |
| 201 | =item 3. |
| 202 | |
| 203 | A sigil, followed by a caret and any one of the characters |
| 204 | C<[][A-Z^_?\]>, like C<$^V> or C<$^]>. |
| 205 | |
| 206 | =item 4. |
| 207 | |
| 208 | Similar to the above, a sigil, followed by bareword text in braces, |
| 209 | where the first character is a caret. The next character is any one of |
| 210 | the characters C<[][A-Z^_?\]>, followed by ASCII word characters. An |
| 211 | example is C<${^GLOBAL_PHASE}>. |
| 212 | |
| 213 | =item 5. |
| 214 | |
| 215 | A sigil, followed by any single character in the range C<[\xA1-\xAC\xAE-\xFF]> |
| 216 | when not under C<S<"use utf8">>. (Under C<S<"use utf8">>, the normal |
| 217 | identifier rules given earlier in this section apply.) Use of |
| 218 | non-graphic characters (the C1 controls, the NO-BREAK SPACE, and the |
| 219 | SOFT HYPHEN) has been disallowed since v5.26.0. |
| 220 | The use of the other characters is unwise, as these are all |
| 221 | reserved to have special meaning to Perl, and none of them currently |
| 222 | do have special meaning, though this could change without notice. |
| 223 | |
| 224 | Note that an implication of this form is that there are identifiers only |
| 225 | legal under C<S<"use utf8">>, and vice-versa, for example the identifier |
| 226 | C<$E<233>tat> is legal under C<S<"use utf8">>, but is otherwise |
| 227 | considered to be the single character variable C<$E<233>> followed by |
| 228 | the bareword C<"tat">, the combination of which is a syntax error. |
| 229 | |
| 230 | =item 6. |
| 231 | |
| 232 | This is a combination of the previous two forms. It is valid only when |
| 233 | not under S<C<"use utf8">> (normal identifier rules apply when under |
| 234 | S<C<"use utf8">>). The form is a sigil, followed by text in braces, |
| 235 | where the first character is any one of the characters in the range |
| 236 | C<[\x80-\xFF]> followed by ASCII word characters up to the trailing |
| 237 | brace. |
| 238 | |
| 239 | The same caveats as the previous form apply: The non-graphic |
| 240 | characters are no longer allowed with S<"use utf8">, it is unwise |
| 241 | to use this form at all, and utf8ness makes a big difference. |
| 242 | |
| 243 | =back |
| 244 | |
| 245 | Prior to Perl v5.24, non-graphical ASCII control characters were also |
| 246 | allowed in some situations; this had been deprecated since v5.20. |
| 247 | |
| 248 | =head2 Context |
| 249 | X<context> X<scalar context> X<list context> |
| 250 | |
| 251 | The interpretation of operations and values in Perl sometimes depends |
| 252 | on the requirements of the context around the operation or value. |
| 253 | There are two major contexts: list and scalar. Certain operations |
| 254 | return list values in contexts wanting a list, and scalar values |
| 255 | otherwise. If this is true of an operation it will be mentioned in |
| 256 | the documentation for that operation. In other words, Perl overloads |
| 257 | certain operations based on whether the expected return value is |
| 258 | singular or plural. Some words in English work this way, like "fish" |
| 259 | and "sheep". |
| 260 | |
| 261 | In a reciprocal fashion, an operation provides either a scalar or a |
| 262 | list context to each of its arguments. For example, if you say |
| 263 | |
| 264 | int( <STDIN> ) |
| 265 | |
| 266 | the integer operation provides scalar context for the <> |
| 267 | operator, which responds by reading one line from STDIN and passing it |
| 268 | back to the integer operation, which will then find the integer value |
| 269 | of that line and return that. If, on the other hand, you say |
| 270 | |
| 271 | sort( <STDIN> ) |
| 272 | |
| 273 | then the sort operation provides list context for <>, which |
| 274 | will proceed to read every line available up to the end of file, and |
| 275 | pass that list of lines back to the sort routine, which will then |
| 276 | sort those lines and return them as a list to whatever the context |
| 277 | of the sort was. |
| 278 | |
| 279 | Assignment is a little bit special in that it uses its left argument |
| 280 | to determine the context for the right argument. Assignment to a |
| 281 | scalar evaluates the right-hand side in scalar context, while |
| 282 | assignment to an array or hash evaluates the righthand side in list |
| 283 | context. Assignment to a list (or slice, which is just a list |
| 284 | anyway) also evaluates the right-hand side in list context. |
| 285 | |
| 286 | When you use the C<use warnings> pragma or Perl's B<-w> command-line |
| 287 | option, you may see warnings |
| 288 | about useless uses of constants or functions in "void context". |
| 289 | Void context just means the value has been discarded, such as a |
| 290 | statement containing only C<"fred";> or C<getpwuid(0);>. It still |
| 291 | counts as scalar context for functions that care whether or not |
| 292 | they're being called in list context. |
| 293 | |
| 294 | User-defined subroutines may choose to care whether they are being |
| 295 | called in a void, scalar, or list context. Most subroutines do not |
| 296 | need to bother, though. That's because both scalars and lists are |
| 297 | automatically interpolated into lists. See L<perlfunc/wantarray> |
| 298 | for how you would dynamically discern your function's calling |
| 299 | context. |
| 300 | |
| 301 | =head2 Scalar values |
| 302 | X<scalar> X<number> X<string> X<reference> |
| 303 | |
| 304 | All data in Perl is a scalar, an array of scalars, or a hash of |
| 305 | scalars. A scalar may contain one single value in any of three |
| 306 | different flavors: a number, a string, or a reference. In general, |
| 307 | conversion from one form to another is transparent. Although a |
| 308 | scalar may not directly hold multiple values, it may contain a |
| 309 | reference to an array or hash which in turn contains multiple values. |
| 310 | |
| 311 | Scalars aren't necessarily one thing or another. There's no place |
| 312 | to declare a scalar variable to be of type "string", type "number", |
| 313 | type "reference", or anything else. Because of the automatic |
| 314 | conversion of scalars, operations that return scalars don't need |
| 315 | to care (and in fact, cannot care) whether their caller is looking |
| 316 | for a string, a number, or a reference. Perl is a contextually |
| 317 | polymorphic language whose scalars can be strings, numbers, or |
| 318 | references (which includes objects). Although strings and numbers |
| 319 | are considered pretty much the same thing for nearly all purposes, |
| 320 | references are strongly-typed, uncastable pointers with builtin |
| 321 | reference-counting and destructor invocation. |
| 322 | |
| 323 | X<truth> X<falsehood> X<true> X<false> X<!> X<not> X<negation> X<0> |
| 324 | X<boolean> X<bool> |
| 325 | A scalar value is interpreted as FALSE in the Boolean sense |
| 326 | if it is undefined, the null string or the number 0 (or its |
| 327 | string equivalent, "0"), and TRUE if it is anything else. The |
| 328 | Boolean context is just a special kind of scalar context where no |
| 329 | conversion to a string or a number is ever performed. |
| 330 | Negation of a true value by C<!> or C<not> returns a special false value. |
| 331 | When evaluated as a string it is treated as C<"">, but as a number, it |
| 332 | is treated as 0. Most Perl operators |
| 333 | that return true or false behave this way. |
| 334 | |
| 335 | There are actually two varieties of null strings (sometimes referred |
| 336 | to as "empty" strings), a defined one and an undefined one. The |
| 337 | defined version is just a string of length zero, such as C<"">. |
| 338 | The undefined version is the value that indicates that there is |
| 339 | no real value for something, such as when there was an error, or |
| 340 | at end of file, or when you refer to an uninitialized variable or |
| 341 | element of an array or hash. Although in early versions of Perl, |
| 342 | an undefined scalar could become defined when first used in a |
| 343 | place expecting a defined value, this no longer happens except for |
| 344 | rare cases of autovivification as explained in L<perlref>. You can |
| 345 | use the defined() operator to determine whether a scalar value is |
| 346 | defined (this has no meaning on arrays or hashes), and the undef() |
| 347 | operator to produce an undefined value. |
| 348 | X<defined> X<undefined> X<undef> X<null> X<string, null> |
| 349 | |
| 350 | To find out whether a given string is a valid non-zero number, it's |
| 351 | sometimes enough to test it against both numeric 0 and also lexical |
| 352 | "0" (although this will cause noises if warnings are on). That's |
| 353 | because strings that aren't numbers count as 0, just as they do in B<awk>: |
| 354 | |
| 355 | if ($str == 0 && $str ne "0") { |
| 356 | warn "That doesn't look like a number"; |
| 357 | } |
| 358 | |
| 359 | That method may be best because otherwise you won't treat IEEE |
| 360 | notations like C<NaN> or C<Infinity> properly. At other times, you |
| 361 | might prefer to determine whether string data can be used numerically |
| 362 | by calling the POSIX::strtod() function or by inspecting your string |
| 363 | with a regular expression (as documented in L<perlre>). |
| 364 | |
| 365 | warn "has nondigits" if /\D/; |
| 366 | warn "not a natural number" unless /^\d+$/; # rejects -3 |
| 367 | warn "not an integer" unless /^-?\d+$/; # rejects +3 |
| 368 | warn "not an integer" unless /^[+-]?\d+$/; |
| 369 | warn "not a decimal number" unless /^-?\d+\.?\d*$/; # rejects .2 |
| 370 | warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/; |
| 371 | warn "not a C float" |
| 372 | unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/; |
| 373 | |
| 374 | The length of an array is a scalar value. You may find the length |
| 375 | of array @days by evaluating C<$#days>, as in B<csh>. However, this |
| 376 | isn't the length of the array; it's the subscript of the last element, |
| 377 | which is a different value since there is ordinarily a 0th element. |
| 378 | Assigning to C<$#days> actually changes the length of the array. |
| 379 | Shortening an array this way destroys intervening values. Lengthening |
| 380 | an array that was previously shortened does not recover values |
| 381 | that were in those elements. |
| 382 | X<$#> X<array, length> |
| 383 | |
| 384 | You can also gain some minuscule measure of efficiency by pre-extending |
| 385 | an array that is going to get big. You can also extend an array |
| 386 | by assigning to an element that is off the end of the array. You |
| 387 | can truncate an array down to nothing by assigning the null list |
| 388 | () to it. The following are equivalent: |
| 389 | |
| 390 | @whatever = (); |
| 391 | $#whatever = -1; |
| 392 | |
| 393 | If you evaluate an array in scalar context, it returns the length |
| 394 | of the array. (Note that this is not true of lists, which return |
| 395 | the last value, like the C comma operator, nor of built-in functions, |
| 396 | which return whatever they feel like returning.) The following is |
| 397 | always true: |
| 398 | X<array, length> |
| 399 | |
| 400 | scalar(@whatever) == $#whatever + 1; |
| 401 | |
| 402 | Some programmers choose to use an explicit conversion so as to |
| 403 | leave nothing to doubt: |
| 404 | |
| 405 | $element_count = scalar(@whatever); |
| 406 | |
| 407 | If you evaluate a hash in scalar context, it returns a false value if |
| 408 | the hash is empty. If there are any key/value pairs, it returns a |
| 409 | true value. A more precise definition is version dependent. |
| 410 | |
| 411 | Prior to Perl 5.25 the value returned was a string consisting of the |
| 412 | number of used buckets and the number of allocated buckets, separated |
| 413 | by a slash. This is pretty much useful only to find out whether |
| 414 | Perl's internal hashing algorithm is performing poorly on your data |
| 415 | set. For example, you stick 10,000 things in a hash, but evaluating |
| 416 | %HASH in scalar context reveals C<"1/16">, which means only one out |
| 417 | of sixteen buckets has been touched, and presumably contains all |
| 418 | 10,000 of your items. This isn't supposed to happen. |
| 419 | |
| 420 | As of Perl 5.25 the return was changed to be the count of keys in the |
| 421 | hash. If you need access to the old behavior you can use |
| 422 | C<Hash::Util::bucket_ratio()> instead. |
| 423 | |
| 424 | If a tied hash is evaluated in scalar context, the C<SCALAR> method is |
| 425 | called (with a fallback to C<FIRSTKEY>). |
| 426 | X<hash, scalar context> X<hash, bucket> X<bucket> |
| 427 | |
| 428 | You can preallocate space for a hash by assigning to the keys() function. |
| 429 | This rounds up the allocated buckets to the next power of two: |
| 430 | |
| 431 | keys(%users) = 1000; # allocate 1024 buckets |
| 432 | |
| 433 | =head2 Scalar value constructors |
| 434 | X<scalar, literal> X<scalar, constant> |
| 435 | |
| 436 | Numeric literals are specified in any of the following floating point or |
| 437 | integer formats: |
| 438 | |
| 439 | 12345 |
| 440 | 12345.67 |
| 441 | .23E-10 # a very small number |
| 442 | 3.14_15_92 # a very important number |
| 443 | 4_294_967_296 # underscore for legibility |
| 444 | 0xff # hex |
| 445 | 0xdead_beef # more hex |
| 446 | 0377 # octal (only numbers, begins with 0) |
| 447 | 0b011011 # binary |
| 448 | 0x1.999ap-4 # hexadecimal floating point (the 'p' is required) |
| 449 | |
| 450 | You are allowed to use underscores (underbars) in numeric literals |
| 451 | between digits for legibility (but not multiple underscores in a row: |
| 452 | C<23__500> is not legal; C<23_500> is). |
| 453 | You could, for example, group binary |
| 454 | digits by threes (as for a Unix-style mode argument such as 0b110_100_100) |
| 455 | or by fours (to represent nibbles, as in 0b1010_0110) or in other groups. |
| 456 | X<number, literal> |
| 457 | |
| 458 | String literals are usually delimited by either single or double |
| 459 | quotes. They work much like quotes in the standard Unix shells: |
| 460 | double-quoted string literals are subject to backslash and variable |
| 461 | substitution; single-quoted strings are not (except for C<\'> and |
| 462 | C<\\>). The usual C-style backslash rules apply for making |
| 463 | characters such as newline, tab, etc., as well as some more exotic |
| 464 | forms. See L<perlop/"Quote and Quote-like Operators"> for a list. |
| 465 | X<string, literal> |
| 466 | |
| 467 | Hexadecimal, octal, or binary, representations in string literals |
| 468 | (e.g. '0xff') are not automatically converted to their integer |
| 469 | representation. The hex() and oct() functions make these conversions |
| 470 | for you. See L<perlfunc/hex> and L<perlfunc/oct> for more details. |
| 471 | |
| 472 | Hexadecimal floating point can start just like a hexadecimal literal, |
| 473 | and it can be followed by an optional fractional hexadecimal part, |
| 474 | but it must be followed by C<p>, an optional sign, and a power of two. |
| 475 | The format is useful for accurately presenting floating point values, |
| 476 | avoiding conversions to or from decimal floating point, and therefore |
| 477 | avoiding possible loss in precision. Notice that while most current |
| 478 | platforms use the 64-bit IEEE 754 floating point, not all do. Another |
| 479 | potential source of (low-order) differences are the floating point |
| 480 | rounding modes, which can differ between CPUs, operating systems, |
| 481 | and compilers, and which Perl doesn't control. |
| 482 | |
| 483 | You can also embed newlines directly in your strings, i.e., they can end |
| 484 | on a different line than they begin. This is nice, but if you forget |
| 485 | your trailing quote, the error will not be reported until Perl finds |
| 486 | another line containing the quote character, which may be much further |
| 487 | on in the script. Variable substitution inside strings is limited to |
| 488 | scalar variables, arrays, and array or hash slices. (In other words, |
| 489 | names beginning with $ or @, followed by an optional bracketed |
| 490 | expression as a subscript.) The following code segment prints out "The |
| 491 | price is $Z<>100." |
| 492 | X<interpolation> |
| 493 | |
| 494 | $Price = '$100'; # not interpolated |
| 495 | print "The price is $Price.\n"; # interpolated |
| 496 | |
| 497 | There is no double interpolation in Perl, so the C<$100> is left as is. |
| 498 | |
| 499 | By default floating point numbers substituted inside strings use the |
| 500 | dot (".") as the decimal separator. If C<use locale> is in effect, |
| 501 | and POSIX::setlocale() has been called, the character used for the |
| 502 | decimal separator is affected by the LC_NUMERIC locale. |
| 503 | See L<perllocale> and L<POSIX>. |
| 504 | |
| 505 | As in some shells, you can enclose the variable name in braces to |
| 506 | disambiguate it from following alphanumerics (and underscores). |
| 507 | You must also do |
| 508 | this when interpolating a variable into a string to separate the |
| 509 | variable name from a following double-colon or an apostrophe, since |
| 510 | these would be otherwise treated as a package separator: |
| 511 | X<interpolation> |
| 512 | |
| 513 | $who = "Larry"; |
| 514 | print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n"; |
| 515 | print "We use ${who}speak when ${who}'s here.\n"; |
| 516 | |
| 517 | Without the braces, Perl would have looked for a $whospeak, a |
| 518 | C<$who::0>, and a C<$who's> variable. The last two would be the |
| 519 | $0 and the $s variables in the (presumably) non-existent package |
| 520 | C<who>. |
| 521 | |
| 522 | In fact, a simple identifier within such curlies is forced to be |
| 523 | a string, and likewise within a hash subscript. Neither need |
| 524 | quoting. Our earlier example, C<$days{'Feb'}> can be written as |
| 525 | C<$days{Feb}> and the quotes will be assumed automatically. But |
| 526 | anything more complicated in the subscript will be interpreted as an |
| 527 | expression. This means for example that C<$version{2.0}++> is |
| 528 | equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>. |
| 529 | |
| 530 | =head3 Special floating point: infinity (Inf) and not-a-number (NaN) |
| 531 | |
| 532 | Floating point values include the special values C<Inf> and C<NaN>, |
| 533 | for infinity and not-a-number. The infinity can be also negative. |
| 534 | |
| 535 | The infinity is the result of certain math operations that overflow |
| 536 | the floating point range, like 9**9**9. The not-a-number is the |
| 537 | result when the result is undefined or unrepresentable. Though note |
| 538 | that you cannot get C<NaN> from some common "undefined" or |
| 539 | "out-of-range" operations like dividing by zero, or square root of |
| 540 | a negative number, since Perl generates fatal errors for those. |
| 541 | |
| 542 | The infinity and not-a-number have their own special arithmetic rules. |
| 543 | The general rule is that they are "contagious": C<Inf> plus one is |
| 544 | C<Inf>, and C<NaN> plus one is C<NaN>. Where things get interesting |
| 545 | is when you combine infinities and not-a-numbers: C<Inf> minus C<Inf> |
| 546 | and C<Inf> divided by C<Inf> are C<NaN> (while C<Inf> plus C<Inf> is |
| 547 | C<Inf> and C<Inf> times C<Inf> is C<Inf>). C<NaN> is also curious |
| 548 | in that it does not equal any number, I<including> itself: |
| 549 | C<NaN> != C<NaN>. |
| 550 | |
| 551 | Perl doesn't understand C<Inf> and C<NaN> as numeric literals, but |
| 552 | you can have them as strings, and Perl will convert them as needed: |
| 553 | "Inf" + 1. (You can, however, import them from the POSIX extension; |
| 554 | C<use POSIX qw(Inf NaN);> and then use them as literals.) |
| 555 | |
| 556 | Note that on input (string to number) Perl accepts C<Inf> and C<NaN> |
| 557 | in many forms. Case is ignored, and the Win32-specific forms like |
| 558 | C<1.#INF> are understood, but on output the values are normalized to |
| 559 | C<Inf> and C<NaN>. |
| 560 | |
| 561 | =head3 Version Strings |
| 562 | X<version string> X<vstring> X<v-string> |
| 563 | |
| 564 | A literal of the form C<v1.20.300.4000> is parsed as a string composed |
| 565 | of characters with the specified ordinals. This form, known as |
| 566 | v-strings, provides an alternative, more readable way to construct |
| 567 | strings, rather than use the somewhat less readable interpolation form |
| 568 | C<"\x{1}\x{14}\x{12c}\x{fa0}">. This is useful for representing |
| 569 | Unicode strings, and for comparing version "numbers" using the string |
| 570 | comparison operators, C<cmp>, C<gt>, C<lt> etc. If there are two or |
| 571 | more dots in the literal, the leading C<v> may be omitted. |
| 572 | |
| 573 | print v9786; # prints SMILEY, "\x{263a}" |
| 574 | print v102.111.111; # prints "foo" |
| 575 | print 102.111.111; # same |
| 576 | |
| 577 | Such literals are accepted by both C<require> and C<use> for |
| 578 | doing a version check. Note that using the v-strings for IPv4 |
| 579 | addresses is not portable unless you also use the |
| 580 | inet_aton()/inet_ntoa() routines of the Socket package. |
| 581 | |
| 582 | Note that since Perl 5.8.1 the single-number v-strings (like C<v65>) |
| 583 | are not v-strings before the C<< => >> operator (which is usually used |
| 584 | to separate a hash key from a hash value); instead they are interpreted |
| 585 | as literal strings ('v65'). They were v-strings from Perl 5.6.0 to |
| 586 | Perl 5.8.0, but that caused more confusion and breakage than good. |
| 587 | Multi-number v-strings like C<v65.66> and C<65.66.67> continue to |
| 588 | be v-strings always. |
| 589 | |
| 590 | =head3 Special Literals |
| 591 | X<special literal> X<__END__> X<__DATA__> X<END> X<DATA> |
| 592 | X<end> X<data> X<^D> X<^Z> |
| 593 | |
| 594 | The special literals __FILE__, __LINE__, and __PACKAGE__ |
| 595 | represent the current filename, line number, and package name at that |
| 596 | point in your program. __SUB__ gives a reference to the current |
| 597 | subroutine. They may be used only as separate tokens; they |
| 598 | will not be interpolated into strings. If there is no current package |
| 599 | (due to an empty C<package;> directive), __PACKAGE__ is the undefined |
| 600 | value. (But the empty C<package;> is no longer supported, as of version |
| 601 | 5.10.) Outside of a subroutine, __SUB__ is the undefined value. __SUB__ |
| 602 | is only available in 5.16 or higher, and only with a C<use v5.16> or |
| 603 | C<use feature "current_sub"> declaration. |
| 604 | X<__FILE__> X<__LINE__> X<__PACKAGE__> X<__SUB__> |
| 605 | X<line> X<file> X<package> |
| 606 | |
| 607 | The two control characters ^D and ^Z, and the tokens __END__ and __DATA__ |
| 608 | may be used to indicate the logical end of the script before the actual |
| 609 | end of file. Any following text is ignored. |
| 610 | |
| 611 | Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>, |
| 612 | where C<PACKNAME> is the package that was current when the __DATA__ |
| 613 | token was encountered. The filehandle is left open pointing to the |
| 614 | line after __DATA__. The program should C<close DATA> when it is done |
| 615 | reading from it. (Leaving it open leaks filehandles if the module is |
| 616 | reloaded for any reason, so it's a safer practice to close it.) For |
| 617 | compatibility with older scripts written before __DATA__ was |
| 618 | introduced, __END__ behaves like __DATA__ in the top level script (but |
| 619 | not in files loaded with C<require> or C<do>) and leaves the remaining |
| 620 | contents of the file accessible via C<main::DATA>. |
| 621 | |
| 622 | The C<DATA> file handle by default has whatever PerlIO layers were |
| 623 | in place when Perl read the file to parse the source. Normally that |
| 624 | means that the file is being read bytewise, as if it were encoded in |
| 625 | Latin-1, but there are two major ways for it to be otherwise. Firstly, |
| 626 | if the C<__END__>/C<__DATA__> token is in the scope of a C<use utf8> |
| 627 | pragma then the C<DATA> handle will be in UTF-8 mode. And secondly, |
| 628 | if the source is being read from perl's standard input then the C<DATA> |
| 629 | file handle is actually aliased to the C<STDIN> file handle, and may |
| 630 | be in UTF-8 mode because of the C<PERL_UNICODE> environment variable or |
| 631 | perl's command-line switches. |
| 632 | |
| 633 | See L<SelfLoader> for more description of __DATA__, and |
| 634 | an example of its use. Note that you cannot read from the DATA |
| 635 | filehandle in a BEGIN block: the BEGIN block is executed as soon |
| 636 | as it is seen (during compilation), at which point the corresponding |
| 637 | __DATA__ (or __END__) token has not yet been seen. |
| 638 | |
| 639 | =head3 Barewords |
| 640 | X<bareword> |
| 641 | |
| 642 | A word that has no other interpretation in the grammar will |
| 643 | be treated as if it were a quoted string. These are known as |
| 644 | "barewords". As with filehandles and labels, a bareword that consists |
| 645 | entirely of lowercase letters risks conflict with future reserved |
| 646 | words, and if you use the C<use warnings> pragma or the B<-w> switch, |
| 647 | Perl will warn you about any such words. Perl limits barewords (like |
| 648 | identifiers) to about 250 characters. Future versions of Perl are likely |
| 649 | to eliminate these arbitrary limitations. |
| 650 | |
| 651 | Some people may wish to outlaw barewords entirely. If you |
| 652 | say |
| 653 | |
| 654 | use strict 'subs'; |
| 655 | |
| 656 | then any bareword that would NOT be interpreted as a subroutine call |
| 657 | produces a compile-time error instead. The restriction lasts to the |
| 658 | end of the enclosing block. An inner block may countermand this |
| 659 | by saying C<no strict 'subs'>. |
| 660 | |
| 661 | =head3 Array Interpolation |
| 662 | X<array, interpolation> X<interpolation, array> X<$"> |
| 663 | |
| 664 | Arrays and slices are interpolated into double-quoted strings |
| 665 | by joining the elements with the delimiter specified in the C<$"> |
| 666 | variable (C<$LIST_SEPARATOR> if "use English;" is specified), |
| 667 | space by default. The following are equivalent: |
| 668 | |
| 669 | $temp = join($", @ARGV); |
| 670 | system "echo $temp"; |
| 671 | |
| 672 | system "echo @ARGV"; |
| 673 | |
| 674 | Within search patterns (which also undergo double-quotish substitution) |
| 675 | there is an unfortunate ambiguity: Is C</$foo[bar]/> to be interpreted as |
| 676 | C</${foo}[bar]/> (where C<[bar]> is a character class for the regular |
| 677 | expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array |
| 678 | @foo)? If @foo doesn't otherwise exist, then it's obviously a |
| 679 | character class. If @foo exists, Perl takes a good guess about C<[bar]>, |
| 680 | and is almost always right. If it does guess wrong, or if you're just |
| 681 | plain paranoid, you can force the correct interpretation with curly |
| 682 | braces as above. |
| 683 | |
| 684 | If you're looking for the information on how to use here-documents, |
| 685 | which used to be here, that's been moved to |
| 686 | L<perlop/Quote and Quote-like Operators>. |
| 687 | |
| 688 | =head2 List value constructors |
| 689 | X<list> |
| 690 | |
| 691 | List values are denoted by separating individual values by commas |
| 692 | (and enclosing the list in parentheses where precedence requires it): |
| 693 | |
| 694 | (LIST) |
| 695 | |
| 696 | In a context not requiring a list value, the value of what appears |
| 697 | to be a list literal is simply the value of the final element, as |
| 698 | with the C comma operator. For example, |
| 699 | |
| 700 | @foo = ('cc', '-E', $bar); |
| 701 | |
| 702 | assigns the entire list value to array @foo, but |
| 703 | |
| 704 | $foo = ('cc', '-E', $bar); |
| 705 | |
| 706 | assigns the value of variable $bar to the scalar variable $foo. |
| 707 | Note that the value of an actual array in scalar context is the |
| 708 | length of the array; the following assigns the value 3 to $foo: |
| 709 | |
| 710 | @foo = ('cc', '-E', $bar); |
| 711 | $foo = @foo; # $foo gets 3 |
| 712 | |
| 713 | You may have an optional comma before the closing parenthesis of a |
| 714 | list literal, so that you can say: |
| 715 | |
| 716 | @foo = ( |
| 717 | 1, |
| 718 | 2, |
| 719 | 3, |
| 720 | ); |
| 721 | |
| 722 | To use a here-document to assign an array, one line per element, |
| 723 | you might use an approach like this: |
| 724 | |
| 725 | @sauces = <<End_Lines =~ m/(\S.*\S)/g; |
| 726 | normal tomato |
| 727 | spicy tomato |
| 728 | green chile |
| 729 | pesto |
| 730 | white wine |
| 731 | End_Lines |
| 732 | |
| 733 | LISTs do automatic interpolation of sublists. That is, when a LIST is |
| 734 | evaluated, each element of the list is evaluated in list context, and |
| 735 | the resulting list value is interpolated into LIST just as if each |
| 736 | individual element were a member of LIST. Thus arrays and hashes lose their |
| 737 | identity in a LIST--the list |
| 738 | |
| 739 | (@foo,@bar,&SomeSub,%glarch) |
| 740 | |
| 741 | contains all the elements of @foo followed by all the elements of @bar, |
| 742 | followed by all the elements returned by the subroutine named SomeSub |
| 743 | called in list context, followed by the key/value pairs of %glarch. |
| 744 | To make a list reference that does I<NOT> interpolate, see L<perlref>. |
| 745 | |
| 746 | The null list is represented by (). Interpolating it in a list |
| 747 | has no effect. Thus ((),(),()) is equivalent to (). Similarly, |
| 748 | interpolating an array with no elements is the same as if no |
| 749 | array had been interpolated at that point. |
| 750 | |
| 751 | This interpolation combines with the facts that the opening |
| 752 | and closing parentheses are optional (except when necessary for |
| 753 | precedence) and lists may end with an optional comma to mean that |
| 754 | multiple commas within lists are legal syntax. The list C<1,,3> is a |
| 755 | concatenation of two lists, C<1,> and C<3>, the first of which ends |
| 756 | with that optional comma. C<1,,3> is C<(1,),(3)> is C<1,3> (And |
| 757 | similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.) Not that |
| 758 | we'd advise you to use this obfuscation. |
| 759 | |
| 760 | A list value may also be subscripted like a normal array. You must |
| 761 | put the list in parentheses to avoid ambiguity. For example: |
| 762 | |
| 763 | # Stat returns list value. |
| 764 | $time = (stat($file))[8]; |
| 765 | |
| 766 | # SYNTAX ERROR HERE. |
| 767 | $time = stat($file)[8]; # OOPS, FORGOT PARENTHESES |
| 768 | |
| 769 | # Find a hex digit. |
| 770 | $hexdigit = ('a','b','c','d','e','f')[$digit-10]; |
| 771 | |
| 772 | # A "reverse comma operator". |
| 773 | return (pop(@foo),pop(@foo))[0]; |
| 774 | |
| 775 | Lists may be assigned to only when each element of the list |
| 776 | is itself legal to assign to: |
| 777 | |
| 778 | ($a, $b, $c) = (1, 2, 3); |
| 779 | |
| 780 | ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00); |
| 781 | |
| 782 | An exception to this is that you may assign to C<undef> in a list. |
| 783 | This is useful for throwing away some of the return values of a |
| 784 | function: |
| 785 | |
| 786 | ($dev, $ino, undef, undef, $uid, $gid) = stat($file); |
| 787 | |
| 788 | As of Perl 5.22, you can also use C<(undef)x2> instead of C<undef, undef>. |
| 789 | (You can also do C<($x) x 2>, which is less useful, because it assigns to |
| 790 | the same variable twice, clobbering the first value assigned.) |
| 791 | |
| 792 | When you assign a list of scalars to an array, all previous values in that |
| 793 | array are wiped out and the number of elements in the array will now be equal to |
| 794 | the number of elements in the right-hand list -- the list from which |
| 795 | assignment was made. The array will automatically resize itself to precisely |
| 796 | accommodate each element in the right-hand list. |
| 797 | |
| 798 | use warnings; |
| 799 | my (@xyz, $x, $y, $z); |
| 800 | |
| 801 | @xyz = (1, 2, 3); |
| 802 | print "@xyz\n"; # 1 2 3 |
| 803 | |
| 804 | @xyz = ('al', 'be', 'ga', 'de'); |
| 805 | print "@xyz\n"; # al be ga de |
| 806 | |
| 807 | @xyz = (101, 102); |
| 808 | print "@xyz\n"; # 101 102 |
| 809 | |
| 810 | When, however, you assign a list of scalars to another list of scalars, the |
| 811 | results differ according to whether the left-hand list -- the list being |
| 812 | assigned to -- has the same, more or fewer elements than the right-hand list. |
| 813 | |
| 814 | ($x, $y, $z) = (1, 2, 3); |
| 815 | print "$x $y $z\n"; # 1 2 3 |
| 816 | |
| 817 | ($x, $y, $z) = ('al', 'be', 'ga', 'de'); |
| 818 | print "$x $y $z\n"; # al be ga |
| 819 | |
| 820 | ($x, $y, $z) = (101, 102); |
| 821 | print "$x $y $z\n"; # 101 102 |
| 822 | # Use of uninitialized value $z in concatenation (.) |
| 823 | # or string at [program] line [line number]. |
| 824 | |
| 825 | If the number of scalars in the left-hand list is less than that in the |
| 826 | right-hand list, the "extra" scalars in the right-hand list will simply not be |
| 827 | assigned. |
| 828 | |
| 829 | If the number of scalars in the left-hand list is greater than that in the |
| 830 | left-hand list, the "missing" scalars will become undefined. |
| 831 | |
| 832 | ($x, $y, $z) = (101, 102); |
| 833 | for my $el ($x, $y, $z) { |
| 834 | (defined $el) ? print "$el " : print "<undef>"; |
| 835 | } |
| 836 | print "\n"; |
| 837 | # 101 102 <undef> |
| 838 | |
| 839 | List assignment in scalar context returns the number of elements |
| 840 | produced by the expression on the right side of the assignment: |
| 841 | |
| 842 | $x = (($foo,$bar) = (3,2,1)); # set $x to 3, not 2 |
| 843 | $x = (($foo,$bar) = f()); # set $x to f()'s return count |
| 844 | |
| 845 | This is handy when you want to do a list assignment in a Boolean |
| 846 | context, because most list functions return a null list when finished, |
| 847 | which when assigned produces a 0, which is interpreted as FALSE. |
| 848 | |
| 849 | It's also the source of a useful idiom for executing a function or |
| 850 | performing an operation in list context and then counting the number of |
| 851 | return values, by assigning to an empty list and then using that |
| 852 | assignment in scalar context. For example, this code: |
| 853 | |
| 854 | $count = () = $string =~ /\d+/g; |
| 855 | |
| 856 | will place into $count the number of digit groups found in $string. |
| 857 | This happens because the pattern match is in list context (since it |
| 858 | is being assigned to the empty list), and will therefore return a list |
| 859 | of all matching parts of the string. The list assignment in scalar |
| 860 | context will translate that into the number of elements (here, the |
| 861 | number of times the pattern matched) and assign that to $count. Note |
| 862 | that simply using |
| 863 | |
| 864 | $count = $string =~ /\d+/g; |
| 865 | |
| 866 | would not have worked, since a pattern match in scalar context will |
| 867 | only return true or false, rather than a count of matches. |
| 868 | |
| 869 | The final element of a list assignment may be an array or a hash: |
| 870 | |
| 871 | ($a, $b, @rest) = split; |
| 872 | my($a, $b, %rest) = @_; |
| 873 | |
| 874 | You can actually put an array or hash anywhere in the list, but the first one |
| 875 | in the list will soak up all the values, and anything after it will become |
| 876 | undefined. This may be useful in a my() or local(). |
| 877 | |
| 878 | A hash can be initialized using a literal list holding pairs of |
| 879 | items to be interpreted as a key and a value: |
| 880 | |
| 881 | # same as map assignment above |
| 882 | %map = ('red',0x00f,'blue',0x0f0,'green',0xf00); |
| 883 | |
| 884 | While literal lists and named arrays are often interchangeable, that's |
| 885 | not the case for hashes. Just because you can subscript a list value like |
| 886 | a normal array does not mean that you can subscript a list value as a |
| 887 | hash. Likewise, hashes included as parts of other lists (including |
| 888 | parameters lists and return lists from functions) always flatten out into |
| 889 | key/value pairs. That's why it's good to use references sometimes. |
| 890 | |
| 891 | It is often more readable to use the C<< => >> operator between key/value |
| 892 | pairs. The C<< => >> operator is mostly just a more visually distinctive |
| 893 | synonym for a comma, but it also arranges for its left-hand operand to be |
| 894 | interpreted as a string if it's a bareword that would be a legal simple |
| 895 | identifier. C<< => >> doesn't quote compound identifiers, that contain |
| 896 | double colons. This makes it nice for initializing hashes: |
| 897 | |
| 898 | %map = ( |
| 899 | red => 0x00f, |
| 900 | blue => 0x0f0, |
| 901 | green => 0xf00, |
| 902 | ); |
| 903 | |
| 904 | or for initializing hash references to be used as records: |
| 905 | |
| 906 | $rec = { |
| 907 | witch => 'Mable the Merciless', |
| 908 | cat => 'Fluffy the Ferocious', |
| 909 | date => '10/31/1776', |
| 910 | }; |
| 911 | |
| 912 | or for using call-by-named-parameter to complicated functions: |
| 913 | |
| 914 | $field = $query->radio_group( |
| 915 | name => 'group_name', |
| 916 | values => ['eenie','meenie','minie'], |
| 917 | default => 'meenie', |
| 918 | linebreak => 'true', |
| 919 | labels => \%labels |
| 920 | ); |
| 921 | |
| 922 | Note that just because a hash is initialized in that order doesn't |
| 923 | mean that it comes out in that order. See L<perlfunc/sort> for examples |
| 924 | of how to arrange for an output ordering. |
| 925 | |
| 926 | If a key appears more than once in the initializer list of a hash, the last |
| 927 | occurrence wins: |
| 928 | |
| 929 | %circle = ( |
| 930 | center => [5, 10], |
| 931 | center => [27, 9], |
| 932 | radius => 100, |
| 933 | color => [0xDF, 0xFF, 0x00], |
| 934 | radius => 54, |
| 935 | ); |
| 936 | |
| 937 | # same as |
| 938 | %circle = ( |
| 939 | center => [27, 9], |
| 940 | color => [0xDF, 0xFF, 0x00], |
| 941 | radius => 54, |
| 942 | ); |
| 943 | |
| 944 | This can be used to provide overridable configuration defaults: |
| 945 | |
| 946 | # values in %args take priority over %config_defaults |
| 947 | %config = (%config_defaults, %args); |
| 948 | |
| 949 | =head2 Subscripts |
| 950 | |
| 951 | An array can be accessed one scalar at a |
| 952 | time by specifying a dollar sign (C<$>), then the |
| 953 | name of the array (without the leading C<@>), then the subscript inside |
| 954 | square brackets. For example: |
| 955 | |
| 956 | @myarray = (5, 50, 500, 5000); |
| 957 | print "The Third Element is", $myarray[2], "\n"; |
| 958 | |
| 959 | The array indices start with 0. A negative subscript retrieves its |
| 960 | value from the end. In our example, C<$myarray[-1]> would have been |
| 961 | 5000, and C<$myarray[-2]> would have been 500. |
| 962 | |
| 963 | Hash subscripts are similar, only instead of square brackets curly brackets |
| 964 | are used. For example: |
| 965 | |
| 966 | %scientists = |
| 967 | ( |
| 968 | "Newton" => "Isaac", |
| 969 | "Einstein" => "Albert", |
| 970 | "Darwin" => "Charles", |
| 971 | "Feynman" => "Richard", |
| 972 | ); |
| 973 | |
| 974 | print "Darwin's First Name is ", $scientists{"Darwin"}, "\n"; |
| 975 | |
| 976 | You can also subscript a list to get a single element from it: |
| 977 | |
| 978 | $dir = (getpwnam("daemon"))[7]; |
| 979 | |
| 980 | =head2 Multi-dimensional array emulation |
| 981 | |
| 982 | Multidimensional arrays may be emulated by subscripting a hash with a |
| 983 | list. The elements of the list are joined with the subscript separator |
| 984 | (see L<perlvar/$;>). |
| 985 | |
| 986 | $foo{$a,$b,$c} |
| 987 | |
| 988 | is equivalent to |
| 989 | |
| 990 | $foo{join($;, $a, $b, $c)} |
| 991 | |
| 992 | The default subscript separator is "\034", the same as SUBSEP in B<awk>. |
| 993 | |
| 994 | =head2 Slices |
| 995 | X<slice> X<array, slice> X<hash, slice> |
| 996 | |
| 997 | A slice accesses several elements of a list, an array, or a hash |
| 998 | simultaneously using a list of subscripts. It's more convenient |
| 999 | than writing out the individual elements as a list of separate |
| 1000 | scalar values. |
| 1001 | |
| 1002 | ($him, $her) = @folks[0,-1]; # array slice |
| 1003 | @them = @folks[0 .. 3]; # array slice |
| 1004 | ($who, $home) = @ENV{"USER", "HOME"}; # hash slice |
| 1005 | ($uid, $dir) = (getpwnam("daemon"))[2,7]; # list slice |
| 1006 | |
| 1007 | Since you can assign to a list of variables, you can also assign to |
| 1008 | an array or hash slice. |
| 1009 | |
| 1010 | @days[3..5] = qw/Wed Thu Fri/; |
| 1011 | @colors{'red','blue','green'} |
| 1012 | = (0xff0000, 0x0000ff, 0x00ff00); |
| 1013 | @folks[0, -1] = @folks[-1, 0]; |
| 1014 | |
| 1015 | The previous assignments are exactly equivalent to |
| 1016 | |
| 1017 | ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/; |
| 1018 | ($colors{'red'}, $colors{'blue'}, $colors{'green'}) |
| 1019 | = (0xff0000, 0x0000ff, 0x00ff00); |
| 1020 | ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]); |
| 1021 | |
| 1022 | Since changing a slice changes the original array or hash that it's |
| 1023 | slicing, a C<foreach> construct will alter some--or even all--of the |
| 1024 | values of the array or hash. |
| 1025 | |
| 1026 | foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } |
| 1027 | |
| 1028 | foreach (@hash{qw[key1 key2]}) { |
| 1029 | s/^\s+//; # trim leading whitespace |
| 1030 | s/\s+$//; # trim trailing whitespace |
| 1031 | s/(\w+)/\u\L$1/g; # "titlecase" words |
| 1032 | } |
| 1033 | |
| 1034 | As a special exception, when you slice a list (but not an array or a hash), |
| 1035 | if the list evaluates to empty, then taking a slice of that empty list will |
| 1036 | always yield the empty list in turn. Thus: |
| 1037 | |
| 1038 | @a = ()[0,1]; # @a has no elements |
| 1039 | @b = (@a)[0,1]; # @b has no elements |
| 1040 | @c = (sub{}->())[0,1]; # @c has no elements |
| 1041 | @d = ('a','b')[0,1]; # @d has two elements |
| 1042 | @e = (@d)[0,1,8,9]; # @e has four elements |
| 1043 | @f = (@d)[8,9]; # @f has two elements |
| 1044 | |
| 1045 | This makes it easy to write loops that terminate when a null list |
| 1046 | is returned: |
| 1047 | |
| 1048 | while ( ($home, $user) = (getpwent)[7,0] ) { |
| 1049 | printf "%-8s %s\n", $user, $home; |
| 1050 | } |
| 1051 | |
| 1052 | As noted earlier in this document, the scalar sense of list assignment |
| 1053 | is the number of elements on the right-hand side of the assignment. |
| 1054 | The null list contains no elements, so when the password file is |
| 1055 | exhausted, the result is 0, not 2. |
| 1056 | |
| 1057 | Slices in scalar context return the last item of the slice. |
| 1058 | |
| 1059 | @a = qw/first second third/; |
| 1060 | %h = (first => 'A', second => 'B'); |
| 1061 | $t = @a[0, 1]; # $t is now 'second' |
| 1062 | $u = @h{'first', 'second'}; # $u is now 'B' |
| 1063 | |
| 1064 | If you're confused about why you use an '@' there on a hash slice |
| 1065 | instead of a '%', think of it like this. The type of bracket (square |
| 1066 | or curly) governs whether it's an array or a hash being looked at. |
| 1067 | On the other hand, the leading symbol ('$' or '@') on the array or |
| 1068 | hash indicates whether you are getting back a singular value (a |
| 1069 | scalar) or a plural one (a list). |
| 1070 | |
| 1071 | =head3 Key/Value Hash Slices |
| 1072 | |
| 1073 | Starting in Perl 5.20, a hash slice operation |
| 1074 | with the % symbol is a variant of slice operation |
| 1075 | returning a list of key/value pairs rather than just values: |
| 1076 | |
| 1077 | %h = (blonk => 2, foo => 3, squink => 5, bar => 8); |
| 1078 | %subset = %h{'foo', 'bar'}; # key/value hash slice |
| 1079 | # %subset is now (foo => 3, bar => 8) |
| 1080 | %removed = delete %h{'foo', 'bar'}; |
| 1081 | # %removed is now (foo => 3, bar => 8) |
| 1082 | # %h is now (blonk => 2, squink => 5) |
| 1083 | |
| 1084 | However, the result of such a slice cannot be localized or used |
| 1085 | in assignment. These are otherwise very much consistent with hash slices |
| 1086 | using the @ symbol. |
| 1087 | |
| 1088 | =head3 Index/Value Array Slices |
| 1089 | |
| 1090 | Similar to key/value hash slices (and also introduced |
| 1091 | in Perl 5.20), the % array slice syntax returns a list |
| 1092 | of index/value pairs: |
| 1093 | |
| 1094 | @a = "a".."z"; |
| 1095 | @list = %a[3,4,6]; |
| 1096 | # @list is now (3, "d", 4, "e", 6, "g") |
| 1097 | @removed = delete %a[3,4,6] |
| 1098 | # @removed is now (3, "d", 4, "e", 6, "g") |
| 1099 | # @list[3,4,6] are now undef |
| 1100 | |
| 1101 | Note that calling L<C<delete>|perlfunc/delete EXPR> on array values is |
| 1102 | strongly discouraged. |
| 1103 | |
| 1104 | =head2 Typeglobs and Filehandles |
| 1105 | X<typeglob> X<filehandle> X<*> |
| 1106 | |
| 1107 | Perl uses an internal type called a I<typeglob> to hold an entire |
| 1108 | symbol table entry. The type prefix of a typeglob is a C<*>, because |
| 1109 | it represents all types. This used to be the preferred way to |
| 1110 | pass arrays and hashes by reference into a function, but now that |
| 1111 | we have real references, this is seldom needed. |
| 1112 | |
| 1113 | The main use of typeglobs in modern Perl is create symbol table aliases. |
| 1114 | This assignment: |
| 1115 | |
| 1116 | *this = *that; |
| 1117 | |
| 1118 | makes $this an alias for $that, @this an alias for @that, %this an alias |
| 1119 | for %that, &this an alias for &that, etc. Much safer is to use a reference. |
| 1120 | This: |
| 1121 | |
| 1122 | local *Here::blue = \$There::green; |
| 1123 | |
| 1124 | temporarily makes $Here::blue an alias for $There::green, but doesn't |
| 1125 | make @Here::blue an alias for @There::green, or %Here::blue an alias for |
| 1126 | %There::green, etc. See L<perlmod/"Symbol Tables"> for more examples |
| 1127 | of this. Strange though this may seem, this is the basis for the whole |
| 1128 | module import/export system. |
| 1129 | |
| 1130 | Another use for typeglobs is to pass filehandles into a function or |
| 1131 | to create new filehandles. If you need to use a typeglob to save away |
| 1132 | a filehandle, do it this way: |
| 1133 | |
| 1134 | $fh = *STDOUT; |
| 1135 | |
| 1136 | or perhaps as a real reference, like this: |
| 1137 | |
| 1138 | $fh = \*STDOUT; |
| 1139 | |
| 1140 | See L<perlsub> for examples of using these as indirect filehandles |
| 1141 | in functions. |
| 1142 | |
| 1143 | Typeglobs are also a way to create a local filehandle using the local() |
| 1144 | operator. These last until their block is exited, but may be passed back. |
| 1145 | For example: |
| 1146 | |
| 1147 | sub newopen { |
| 1148 | my $path = shift; |
| 1149 | local *FH; # not my! |
| 1150 | open (FH, $path) or return undef; |
| 1151 | return *FH; |
| 1152 | } |
| 1153 | $fh = newopen('/etc/passwd'); |
| 1154 | |
| 1155 | Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much |
| 1156 | for filehandle manipulations, although they're still needed to pass brand |
| 1157 | new file and directory handles into or out of functions. That's because |
| 1158 | C<*HANDLE{IO}> only works if HANDLE has already been used as a handle. |
| 1159 | In other words, C<*FH> must be used to create new symbol table entries; |
| 1160 | C<*foo{THING}> cannot. When in doubt, use C<*FH>. |
| 1161 | |
| 1162 | All functions that are capable of creating filehandles (open(), |
| 1163 | opendir(), pipe(), socketpair(), sysopen(), socket(), and accept()) |
| 1164 | automatically create an anonymous filehandle if the handle passed to |
| 1165 | them is an uninitialized scalar variable. This allows the constructs |
| 1166 | such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to |
| 1167 | create filehandles that will conveniently be closed automatically when |
| 1168 | the scope ends, provided there are no other references to them. This |
| 1169 | largely eliminates the need for typeglobs when opening filehandles |
| 1170 | that must be passed around, as in the following example: |
| 1171 | |
| 1172 | sub myopen { |
| 1173 | open my $fh, "@_" |
| 1174 | or die "Can't open '@_': $!"; |
| 1175 | return $fh; |
| 1176 | } |
| 1177 | |
| 1178 | { |
| 1179 | my $f = myopen("</etc/motd"); |
| 1180 | print <$f>; |
| 1181 | # $f implicitly closed here |
| 1182 | } |
| 1183 | |
| 1184 | Note that if an initialized scalar variable is used instead the |
| 1185 | result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent |
| 1186 | to C<open( *{'zzz'}, ...)>. |
| 1187 | C<use strict 'refs'> forbids such practice. |
| 1188 | |
| 1189 | Another way to create anonymous filehandles is with the Symbol |
| 1190 | module or with the IO::Handle module and its ilk. These modules |
| 1191 | have the advantage of not hiding different types of the same name |
| 1192 | during the local(). See the bottom of L<perlfunc/open> for an |
| 1193 | example. |
| 1194 | |
| 1195 | =head1 SEE ALSO |
| 1196 | |
| 1197 | See L<perlvar> for a description of Perl's built-in variables and |
| 1198 | a discussion of legal variable names. See L<perlref>, L<perlsub>, |
| 1199 | and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and |
| 1200 | the C<*foo{THING}> syntax. |