| 1 | =head1 NAME |
| 2 | X<syntax> |
| 3 | |
| 4 | perlsyn - Perl syntax |
| 5 | |
| 6 | =head1 DESCRIPTION |
| 7 | |
| 8 | A Perl program consists of a sequence of declarations and statements |
| 9 | which run from the top to the bottom. Loops, subroutines and other |
| 10 | control structures allow you to jump around within the code. |
| 11 | |
| 12 | Perl is a B<free-form> language, you can format and indent it however |
| 13 | you like. Whitespace mostly serves to separate tokens, unlike |
| 14 | languages like Python where it is an important part of the syntax. |
| 15 | |
| 16 | Many of Perl's syntactic elements are B<optional>. Rather than |
| 17 | requiring you to put parentheses around every function call and |
| 18 | declare every variable, you can often leave such explicit elements off |
| 19 | and Perl will figure out what you meant. This is known as B<Do What I |
| 20 | Mean>, abbreviated B<DWIM>. It allows programmers to be B<lazy> and to |
| 21 | code in a style with which they are comfortable. |
| 22 | |
| 23 | Perl B<borrows syntax> and concepts from many languages: awk, sed, C, |
| 24 | Bourne Shell, Smalltalk, Lisp and even English. Other |
| 25 | languages have borrowed syntax from Perl, particularly its regular |
| 26 | expression extensions. So if you have programmed in another language |
| 27 | you will see familiar pieces in Perl. They often work the same, but |
| 28 | see L<perltrap> for information about how they differ. |
| 29 | |
| 30 | =head2 Declarations |
| 31 | X<declaration> X<undef> X<undefined> X<uninitialized> |
| 32 | |
| 33 | The only things you need to declare in Perl are report formats and |
| 34 | subroutines (and sometimes not even subroutines). A variable holds |
| 35 | the undefined value (C<undef>) until it has been assigned a defined |
| 36 | value, which is anything other than C<undef>. When used as a number, |
| 37 | C<undef> is treated as C<0>; when used as a string, it is treated as |
| 38 | the empty string, C<"">; and when used as a reference that isn't being |
| 39 | assigned to, it is treated as an error. If you enable warnings, |
| 40 | you'll be notified of an uninitialized value whenever you treat |
| 41 | C<undef> as a string or a number. Well, usually. Boolean contexts, |
| 42 | such as: |
| 43 | |
| 44 | my $a; |
| 45 | if ($a) {} |
| 46 | |
| 47 | are exempt from warnings (because they care about truth rather than |
| 48 | definedness). Operators such as C<++>, C<-->, C<+=>, |
| 49 | C<-=>, and C<.=>, that operate on undefined left values such as: |
| 50 | |
| 51 | my $a; |
| 52 | $a++; |
| 53 | |
| 54 | are also always exempt from such warnings. |
| 55 | |
| 56 | A declaration can be put anywhere a statement can, but has no effect on |
| 57 | the execution of the primary sequence of statements--declarations all |
| 58 | take effect at compile time. Typically all the declarations are put at |
| 59 | the beginning or the end of the script. However, if you're using |
| 60 | lexically-scoped private variables created with C<my()>, you'll |
| 61 | have to make sure |
| 62 | your format or subroutine definition is within the same block scope |
| 63 | as the my if you expect to be able to access those private variables. |
| 64 | |
| 65 | Declaring a subroutine allows a subroutine name to be used as if it were a |
| 66 | list operator from that point forward in the program. You can declare a |
| 67 | subroutine without defining it by saying C<sub name>, thus: |
| 68 | X<subroutine, declaration> |
| 69 | |
| 70 | sub myname; |
| 71 | $me = myname $0 or die "can't get myname"; |
| 72 | |
| 73 | Note that myname() functions as a list operator, not as a unary operator; |
| 74 | so be careful to use C<or> instead of C<||> in this case. However, if |
| 75 | you were to declare the subroutine as C<sub myname ($)>, then |
| 76 | C<myname> would function as a unary operator, so either C<or> or |
| 77 | C<||> would work. |
| 78 | |
| 79 | Subroutines declarations can also be loaded up with the C<require> statement |
| 80 | or both loaded and imported into your namespace with a C<use> statement. |
| 81 | See L<perlmod> for details on this. |
| 82 | |
| 83 | A statement sequence may contain declarations of lexically-scoped |
| 84 | variables, but apart from declaring a variable name, the declaration acts |
| 85 | like an ordinary statement, and is elaborated within the sequence of |
| 86 | statements as if it were an ordinary statement. That means it actually |
| 87 | has both compile-time and run-time effects. |
| 88 | |
| 89 | =head2 Comments |
| 90 | X<comment> X<#> |
| 91 | |
| 92 | Text from a C<"#"> character until the end of the line is a comment, |
| 93 | and is ignored. Exceptions include C<"#"> inside a string or regular |
| 94 | expression. |
| 95 | |
| 96 | =head2 Simple Statements |
| 97 | X<statement> X<semicolon> X<expression> X<;> |
| 98 | |
| 99 | The only kind of simple statement is an expression evaluated for its |
| 100 | side effects. Every simple statement must be terminated with a |
| 101 | semicolon, unless it is the final statement in a block, in which case |
| 102 | the semicolon is optional. (A semicolon is still encouraged if the |
| 103 | block takes up more than one line, because you may eventually add |
| 104 | another line.) Note that there are some operators like C<eval {}> and |
| 105 | C<do {}> that look like compound statements, but aren't (they're just |
| 106 | TERMs in an expression), and thus need an explicit termination if used |
| 107 | as the last item in a statement. |
| 108 | |
| 109 | =head2 Truth and Falsehood |
| 110 | X<truth> X<falsehood> X<true> X<false> X<!> X<not> X<negation> X<0> |
| 111 | |
| 112 | The number 0, the strings C<'0'> and C<''>, the empty list C<()>, and |
| 113 | C<undef> are all false in a boolean context. All other values are true. |
| 114 | Negation of a true value by C<!> or C<not> returns a special false value. |
| 115 | When evaluated as a string it is treated as C<''>, but as a number, it |
| 116 | is treated as 0. |
| 117 | |
| 118 | =head2 Statement Modifiers |
| 119 | X<statement modifier> X<modifier> X<if> X<unless> X<while> |
| 120 | X<until> X<when> X<foreach> X<for> |
| 121 | |
| 122 | Any simple statement may optionally be followed by a I<SINGLE> modifier, |
| 123 | just before the terminating semicolon (or block ending). The possible |
| 124 | modifiers are: |
| 125 | |
| 126 | if EXPR |
| 127 | unless EXPR |
| 128 | while EXPR |
| 129 | until EXPR |
| 130 | when EXPR |
| 131 | for LIST |
| 132 | foreach LIST |
| 133 | |
| 134 | The C<EXPR> following the modifier is referred to as the "condition". |
| 135 | Its truth or falsehood determines how the modifier will behave. |
| 136 | |
| 137 | C<if> executes the statement once I<if> and only if the condition is |
| 138 | true. C<unless> is the opposite, it executes the statement I<unless> |
| 139 | the condition is true (i.e., if the condition is false). |
| 140 | |
| 141 | print "Basset hounds got long ears" if length $ear >= 10; |
| 142 | go_outside() and play() unless $is_raining; |
| 143 | |
| 144 | C<when> executes the statement I<when> C<$_> smart matches C<EXPR>, and |
| 145 | then either C<break>s out if it's enclosed in a C<given> scope or skips |
| 146 | to the C<next> element when it lies directly inside a C<for> loop. |
| 147 | See also L</"Switch statements">. |
| 148 | |
| 149 | given ($something) { |
| 150 | $abc = 1 when /^abc/; |
| 151 | $just_a = 1 when /^a/; |
| 152 | $other = 1; |
| 153 | } |
| 154 | |
| 155 | for (@names) { |
| 156 | admin($_) when [ qw/Alice Bob/ ]; |
| 157 | regular($_) when [ qw/Chris David Ellen/ ]; |
| 158 | } |
| 159 | |
| 160 | The C<foreach> modifier is an iterator: it executes the statement once |
| 161 | for each item in the LIST (with C<$_> aliased to each item in turn). |
| 162 | |
| 163 | print "Hello $_!\n" foreach qw(world Dolly nurse); |
| 164 | |
| 165 | C<while> repeats the statement I<while> the condition is true. |
| 166 | C<until> does the opposite, it repeats the statement I<until> the |
| 167 | condition is true (or while the condition is false): |
| 168 | |
| 169 | # Both of these count from 0 to 10. |
| 170 | print $i++ while $i <= 10; |
| 171 | print $j++ until $j > 10; |
| 172 | |
| 173 | The C<while> and C<until> modifiers have the usual "C<while> loop" |
| 174 | semantics (conditional evaluated first), except when applied to a |
| 175 | C<do>-BLOCK (or to the deprecated C<do>-SUBROUTINE statement), in |
| 176 | which case the block executes once before the conditional is |
| 177 | evaluated. This is so that you can write loops like: |
| 178 | |
| 179 | do { |
| 180 | $line = <STDIN>; |
| 181 | ... |
| 182 | } until $line eq ".\n"; |
| 183 | |
| 184 | See L<perlfunc/do>. Note also that the loop control statements described |
| 185 | later will I<NOT> work in this construct, because modifiers don't take |
| 186 | loop labels. Sorry. You can always put another block inside of it |
| 187 | (for C<next>) or around it (for C<last>) to do that sort of thing. |
| 188 | For C<next>, just double the braces: |
| 189 | X<next> X<last> X<redo> |
| 190 | |
| 191 | do {{ |
| 192 | next if $x == $y; |
| 193 | # do something here |
| 194 | }} until $x++ > $z; |
| 195 | |
| 196 | For C<last>, you have to be more elaborate: |
| 197 | X<last> |
| 198 | |
| 199 | LOOP: { |
| 200 | do { |
| 201 | last if $x = $y**2; |
| 202 | # do something here |
| 203 | } while $x++ <= $z; |
| 204 | } |
| 205 | |
| 206 | B<NOTE:> The behaviour of a C<my> statement modified with a statement |
| 207 | modifier conditional or loop construct (e.g. C<my $x if ...>) is |
| 208 | B<undefined>. The value of the C<my> variable may be C<undef>, any |
| 209 | previously assigned value, or possibly anything else. Don't rely on |
| 210 | it. Future versions of perl might do something different from the |
| 211 | version of perl you try it out on. Here be dragons. |
| 212 | X<my> |
| 213 | |
| 214 | =head2 Compound Statements |
| 215 | X<statement, compound> X<block> X<bracket, curly> X<curly bracket> X<brace> |
| 216 | X<{> X<}> X<if> X<unless> X<while> X<until> X<foreach> X<for> X<continue> |
| 217 | |
| 218 | In Perl, a sequence of statements that defines a scope is called a block. |
| 219 | Sometimes a block is delimited by the file containing it (in the case |
| 220 | of a required file, or the program as a whole), and sometimes a block |
| 221 | is delimited by the extent of a string (in the case of an eval). |
| 222 | |
| 223 | But generally, a block is delimited by curly brackets, also known as braces. |
| 224 | We will call this syntactic construct a BLOCK. |
| 225 | |
| 226 | The following compound statements may be used to control flow: |
| 227 | |
| 228 | if (EXPR) BLOCK |
| 229 | if (EXPR) BLOCK else BLOCK |
| 230 | if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK |
| 231 | LABEL while (EXPR) BLOCK |
| 232 | LABEL while (EXPR) BLOCK continue BLOCK |
| 233 | LABEL until (EXPR) BLOCK |
| 234 | LABEL until (EXPR) BLOCK continue BLOCK |
| 235 | LABEL for (EXPR; EXPR; EXPR) BLOCK |
| 236 | LABEL foreach VAR (LIST) BLOCK |
| 237 | LABEL foreach VAR (LIST) BLOCK continue BLOCK |
| 238 | LABEL BLOCK continue BLOCK |
| 239 | |
| 240 | Note that, unlike C and Pascal, these are defined in terms of BLOCKs, |
| 241 | not statements. This means that the curly brackets are I<required>--no |
| 242 | dangling statements allowed. If you want to write conditionals without |
| 243 | curly brackets there are several other ways to do it. The following |
| 244 | all do the same thing: |
| 245 | |
| 246 | if (!open(FOO)) { die "Can't open $FOO: $!"; } |
| 247 | die "Can't open $FOO: $!" unless open(FOO); |
| 248 | open(FOO) or die "Can't open $FOO: $!"; # FOO or bust! |
| 249 | open(FOO) ? 'hi mom' : die "Can't open $FOO: $!"; |
| 250 | # a bit exotic, that last one |
| 251 | |
| 252 | The C<if> statement is straightforward. Because BLOCKs are always |
| 253 | bounded by curly brackets, there is never any ambiguity about which |
| 254 | C<if> an C<else> goes with. If you use C<unless> in place of C<if>, |
| 255 | the sense of the test is reversed. |
| 256 | |
| 257 | The C<while> statement executes the block as long as the expression is |
| 258 | L<true|/"Truth and Falsehood">. |
| 259 | The C<until> statement executes the block as long as the expression is |
| 260 | false. |
| 261 | The LABEL is optional, and if present, consists of an identifier followed |
| 262 | by a colon. The LABEL identifies the loop for the loop control |
| 263 | statements C<next>, C<last>, and C<redo>. |
| 264 | If the LABEL is omitted, the loop control statement |
| 265 | refers to the innermost enclosing loop. This may include dynamically |
| 266 | looking back your call-stack at run time to find the LABEL. Such |
| 267 | desperate behavior triggers a warning if you use the C<use warnings> |
| 268 | pragma or the B<-w> flag. |
| 269 | |
| 270 | If there is a C<continue> BLOCK, it is always executed just before the |
| 271 | conditional is about to be evaluated again. Thus it can be used to |
| 272 | increment a loop variable, even when the loop has been continued via |
| 273 | the C<next> statement. |
| 274 | |
| 275 | Extension modules can also hook into the Perl parser to define new |
| 276 | kinds of compound statement. These are introduced by a keyword which |
| 277 | the extension recognises, and the syntax following the keyword is |
| 278 | defined entirely by the extension. If you are an implementor, see |
| 279 | L<perlapi/PL_keyword_plugin> for the mechanism. If you are using such |
| 280 | a module, see the module's documentation for details of the syntax that |
| 281 | it defines. |
| 282 | |
| 283 | =head2 Loop Control |
| 284 | X<loop control> X<loop, control> X<next> X<last> X<redo> X<continue> |
| 285 | |
| 286 | The C<next> command starts the next iteration of the loop: |
| 287 | |
| 288 | LINE: while (<STDIN>) { |
| 289 | next LINE if /^#/; # discard comments |
| 290 | ... |
| 291 | } |
| 292 | |
| 293 | The C<last> command immediately exits the loop in question. The |
| 294 | C<continue> block, if any, is not executed: |
| 295 | |
| 296 | LINE: while (<STDIN>) { |
| 297 | last LINE if /^$/; # exit when done with header |
| 298 | ... |
| 299 | } |
| 300 | |
| 301 | The C<redo> command restarts the loop block without evaluating the |
| 302 | conditional again. The C<continue> block, if any, is I<not> executed. |
| 303 | This command is normally used by programs that want to lie to themselves |
| 304 | about what was just input. |
| 305 | |
| 306 | For example, when processing a file like F</etc/termcap>. |
| 307 | If your input lines might end in backslashes to indicate continuation, you |
| 308 | want to skip ahead and get the next record. |
| 309 | |
| 310 | while (<>) { |
| 311 | chomp; |
| 312 | if (s/\\$//) { |
| 313 | $_ .= <>; |
| 314 | redo unless eof(); |
| 315 | } |
| 316 | # now process $_ |
| 317 | } |
| 318 | |
| 319 | which is Perl short-hand for the more explicitly written version: |
| 320 | |
| 321 | LINE: while (defined($line = <ARGV>)) { |
| 322 | chomp($line); |
| 323 | if ($line =~ s/\\$//) { |
| 324 | $line .= <ARGV>; |
| 325 | redo LINE unless eof(); # not eof(ARGV)! |
| 326 | } |
| 327 | # now process $line |
| 328 | } |
| 329 | |
| 330 | Note that if there were a C<continue> block on the above code, it would |
| 331 | get executed only on lines discarded by the regex (since redo skips the |
| 332 | continue block). A continue block is often used to reset line counters |
| 333 | or C<?pat?> one-time matches: |
| 334 | |
| 335 | # inspired by :1,$g/fred/s//WILMA/ |
| 336 | while (<>) { |
| 337 | ?(fred)? && s//WILMA $1 WILMA/; |
| 338 | ?(barney)? && s//BETTY $1 BETTY/; |
| 339 | ?(homer)? && s//MARGE $1 MARGE/; |
| 340 | } continue { |
| 341 | print "$ARGV $.: $_"; |
| 342 | close ARGV if eof(); # reset $. |
| 343 | reset if eof(); # reset ?pat? |
| 344 | } |
| 345 | |
| 346 | If the word C<while> is replaced by the word C<until>, the sense of the |
| 347 | test is reversed, but the conditional is still tested before the first |
| 348 | iteration. |
| 349 | |
| 350 | The loop control statements don't work in an C<if> or C<unless>, since |
| 351 | they aren't loops. You can double the braces to make them such, though. |
| 352 | |
| 353 | if (/pattern/) {{ |
| 354 | last if /fred/; |
| 355 | next if /barney/; # same effect as "last", but doesn't document as well |
| 356 | # do something here |
| 357 | }} |
| 358 | |
| 359 | This is caused by the fact that a block by itself acts as a loop that |
| 360 | executes once, see L<"Basic BLOCKs">. |
| 361 | |
| 362 | The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer |
| 363 | available. Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>. |
| 364 | |
| 365 | =head2 For Loops |
| 366 | X<for> X<foreach> |
| 367 | |
| 368 | Perl's C-style C<for> loop works like the corresponding C<while> loop; |
| 369 | that means that this: |
| 370 | |
| 371 | for ($i = 1; $i < 10; $i++) { |
| 372 | ... |
| 373 | } |
| 374 | |
| 375 | is the same as this: |
| 376 | |
| 377 | $i = 1; |
| 378 | while ($i < 10) { |
| 379 | ... |
| 380 | } continue { |
| 381 | $i++; |
| 382 | } |
| 383 | |
| 384 | There is one minor difference: if variables are declared with C<my> |
| 385 | in the initialization section of the C<for>, the lexical scope of |
| 386 | those variables is exactly the C<for> loop (the body of the loop |
| 387 | and the control sections). |
| 388 | X<my> |
| 389 | |
| 390 | Besides the normal array index looping, C<for> can lend itself |
| 391 | to many other interesting applications. Here's one that avoids the |
| 392 | problem you get into if you explicitly test for end-of-file on |
| 393 | an interactive file descriptor causing your program to appear to |
| 394 | hang. |
| 395 | X<eof> X<end-of-file> X<end of file> |
| 396 | |
| 397 | $on_a_tty = -t STDIN && -t STDOUT; |
| 398 | sub prompt { print "yes? " if $on_a_tty } |
| 399 | for ( prompt(); <STDIN>; prompt() ) { |
| 400 | # do something |
| 401 | } |
| 402 | |
| 403 | Using C<readline> (or the operator form, C<< <EXPR> >>) as the |
| 404 | conditional of a C<for> loop is shorthand for the following. This |
| 405 | behaviour is the same as a C<while> loop conditional. |
| 406 | X<readline> X<< <> >> |
| 407 | |
| 408 | for ( prompt(); defined( $_ = <STDIN> ); prompt() ) { |
| 409 | # do something |
| 410 | } |
| 411 | |
| 412 | =head2 Foreach Loops |
| 413 | X<for> X<foreach> |
| 414 | |
| 415 | The C<foreach> loop iterates over a normal list value and sets the |
| 416 | variable VAR to be each element of the list in turn. If the variable |
| 417 | is preceded with the keyword C<my>, then it is lexically scoped, and |
| 418 | is therefore visible only within the loop. Otherwise, the variable is |
| 419 | implicitly local to the loop and regains its former value upon exiting |
| 420 | the loop. If the variable was previously declared with C<my>, it uses |
| 421 | that variable instead of the global one, but it's still localized to |
| 422 | the loop. This implicit localisation occurs I<only> in a C<foreach> |
| 423 | loop. |
| 424 | X<my> X<local> |
| 425 | |
| 426 | The C<foreach> keyword is actually a synonym for the C<for> keyword, so |
| 427 | you can use C<foreach> for readability or C<for> for brevity. (Or because |
| 428 | the Bourne shell is more familiar to you than I<csh>, so writing C<for> |
| 429 | comes more naturally.) If VAR is omitted, C<$_> is set to each value. |
| 430 | X<$_> |
| 431 | |
| 432 | If any element of LIST is an lvalue, you can modify it by modifying |
| 433 | VAR inside the loop. Conversely, if any element of LIST is NOT an |
| 434 | lvalue, any attempt to modify that element will fail. In other words, |
| 435 | the C<foreach> loop index variable is an implicit alias for each item |
| 436 | in the list that you're looping over. |
| 437 | X<alias> |
| 438 | |
| 439 | If any part of LIST is an array, C<foreach> will get very confused if |
| 440 | you add or remove elements within the loop body, for example with |
| 441 | C<splice>. So don't do that. |
| 442 | X<splice> |
| 443 | |
| 444 | C<foreach> probably won't do what you expect if VAR is a tied or other |
| 445 | special variable. Don't do that either. |
| 446 | |
| 447 | Examples: |
| 448 | |
| 449 | for (@ary) { s/foo/bar/ } |
| 450 | |
| 451 | for my $elem (@elements) { |
| 452 | $elem *= 2; |
| 453 | } |
| 454 | |
| 455 | for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') { |
| 456 | print $count, "\n"; sleep(1); |
| 457 | } |
| 458 | |
| 459 | for (1..15) { print "Merry Christmas\n"; } |
| 460 | |
| 461 | foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) { |
| 462 | print "Item: $item\n"; |
| 463 | } |
| 464 | |
| 465 | Here's how a C programmer might code up a particular algorithm in Perl: |
| 466 | |
| 467 | for (my $i = 0; $i < @ary1; $i++) { |
| 468 | for (my $j = 0; $j < @ary2; $j++) { |
| 469 | if ($ary1[$i] > $ary2[$j]) { |
| 470 | last; # can't go to outer :-( |
| 471 | } |
| 472 | $ary1[$i] += $ary2[$j]; |
| 473 | } |
| 474 | # this is where that last takes me |
| 475 | } |
| 476 | |
| 477 | Whereas here's how a Perl programmer more comfortable with the idiom might |
| 478 | do it: |
| 479 | |
| 480 | OUTER: for my $wid (@ary1) { |
| 481 | INNER: for my $jet (@ary2) { |
| 482 | next OUTER if $wid > $jet; |
| 483 | $wid += $jet; |
| 484 | } |
| 485 | } |
| 486 | |
| 487 | See how much easier this is? It's cleaner, safer, and faster. It's |
| 488 | cleaner because it's less noisy. It's safer because if code gets added |
| 489 | between the inner and outer loops later on, the new code won't be |
| 490 | accidentally executed. The C<next> explicitly iterates the other loop |
| 491 | rather than merely terminating the inner one. And it's faster because |
| 492 | Perl executes a C<foreach> statement more rapidly than it would the |
| 493 | equivalent C<for> loop. |
| 494 | |
| 495 | =head2 Basic BLOCKs |
| 496 | X<block> |
| 497 | |
| 498 | A BLOCK by itself (labeled or not) is semantically equivalent to a |
| 499 | loop that executes once. Thus you can use any of the loop control |
| 500 | statements in it to leave or restart the block. (Note that this is |
| 501 | I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief |
| 502 | C<do{}> blocks, which do I<NOT> count as loops.) The C<continue> |
| 503 | block is optional. |
| 504 | |
| 505 | The BLOCK construct can be used to emulate case structures. |
| 506 | |
| 507 | SWITCH: { |
| 508 | if (/^abc/) { $abc = 1; last SWITCH; } |
| 509 | if (/^def/) { $def = 1; last SWITCH; } |
| 510 | if (/^xyz/) { $xyz = 1; last SWITCH; } |
| 511 | $nothing = 1; |
| 512 | } |
| 513 | |
| 514 | Such constructs are quite frequently used, because older versions |
| 515 | of Perl had no official C<switch> statement. |
| 516 | |
| 517 | =head2 Switch statements |
| 518 | X<switch> X<case> X<given> X<when> X<default> |
| 519 | |
| 520 | Starting from Perl 5.10, you can say |
| 521 | |
| 522 | use feature "switch"; |
| 523 | |
| 524 | which enables a switch feature that is closely based on the |
| 525 | Perl 6 proposal. |
| 526 | |
| 527 | The keywords C<given> and C<when> are analogous |
| 528 | to C<switch> and C<case> in other languages, so the code |
| 529 | above could be written as |
| 530 | |
| 531 | given($_) { |
| 532 | when (/^abc/) { $abc = 1; } |
| 533 | when (/^def/) { $def = 1; } |
| 534 | when (/^xyz/) { $xyz = 1; } |
| 535 | default { $nothing = 1; } |
| 536 | } |
| 537 | |
| 538 | This construct is very flexible and powerful. For example: |
| 539 | |
| 540 | use feature ":5.10"; |
| 541 | given($foo) { |
| 542 | when (undef) { |
| 543 | say '$foo is undefined'; |
| 544 | } |
| 545 | when ("foo") { |
| 546 | say '$foo is the string "foo"'; |
| 547 | } |
| 548 | when ([1,3,5,7,9]) { |
| 549 | say '$foo is an odd digit'; |
| 550 | continue; # Fall through |
| 551 | } |
| 552 | when ($_ < 100) { |
| 553 | say '$foo is numerically less than 100'; |
| 554 | } |
| 555 | when (\&complicated_check) { |
| 556 | say 'a complicated check for $foo is true'; |
| 557 | } |
| 558 | default { |
| 559 | die q(I don't know what to do with $foo); |
| 560 | } |
| 561 | } |
| 562 | |
| 563 | C<given(EXPR)> will assign the value of EXPR to C<$_> |
| 564 | within the lexical scope of the block, so it's similar to |
| 565 | |
| 566 | do { my $_ = EXPR; ... } |
| 567 | |
| 568 | except that the block is automatically broken out of by a |
| 569 | successful C<when> or an explicit C<break>. |
| 570 | |
| 571 | Most of the power comes from implicit smart matching: |
| 572 | |
| 573 | when($foo) |
| 574 | |
| 575 | is exactly equivalent to |
| 576 | |
| 577 | when($_ ~~ $foo) |
| 578 | |
| 579 | Most of the time, C<when(EXPR)> is treated as an implicit smart match of |
| 580 | C<$_>, i.e. C<$_ ~~ EXPR>. (See L</"Smart matching in detail"> for more |
| 581 | information on smart matching.) But when EXPR is one of the below |
| 582 | exceptional cases, it is used directly as a boolean: |
| 583 | |
| 584 | =over 4 |
| 585 | |
| 586 | =item * |
| 587 | |
| 588 | a subroutine or method call |
| 589 | |
| 590 | =item * |
| 591 | |
| 592 | a regular expression match, i.e. C</REGEX/> or C<$foo =~ /REGEX/>, |
| 593 | or a negated regular expression match (C<!/REGEX/> or C<$foo !~ /REGEX/>). |
| 594 | |
| 595 | =item * |
| 596 | |
| 597 | a comparison such as C<$_ E<lt> 10> or C<$x eq "abc"> |
| 598 | (or of course C<$_ ~~ $c>) |
| 599 | |
| 600 | =item * |
| 601 | |
| 602 | C<defined(...)>, C<exists(...)>, or C<eof(...)> |
| 603 | |
| 604 | =item * |
| 605 | |
| 606 | a negated expression C<!(...)> or C<not (...)>, or a logical |
| 607 | exclusive-or C<(...) xor (...)>. |
| 608 | |
| 609 | =item * |
| 610 | |
| 611 | a filetest operator, with the exception of C<-s>, C<-M>, C<-A>, and C<-C>, |
| 612 | that return numerical values, not boolean ones. |
| 613 | |
| 614 | =item * |
| 615 | |
| 616 | the C<..> and C<...> flip-flop operators. |
| 617 | |
| 618 | =back |
| 619 | |
| 620 | In those cases the value of EXPR is used directly as a boolean. |
| 621 | |
| 622 | Furthermore: |
| 623 | |
| 624 | =over 4 |
| 625 | |
| 626 | =item * |
| 627 | |
| 628 | If EXPR is C<... && ...> or C<... and ...>, the test |
| 629 | is applied recursively to both arguments. If I<both> |
| 630 | arguments pass the test, then the argument is treated |
| 631 | as boolean. |
| 632 | |
| 633 | =item * |
| 634 | |
| 635 | If EXPR is C<... || ...>, C<... // ...> or C<... or ...>, the test |
| 636 | is applied recursively to the first argument. |
| 637 | |
| 638 | =back |
| 639 | |
| 640 | These rules look complicated, but usually they will do what |
| 641 | you want. For example you could write: |
| 642 | |
| 643 | when (/^\d+$/ && $_ < 75) { ... } |
| 644 | |
| 645 | Another useful shortcut is that, if you use a literal array |
| 646 | or hash as the argument to C<given>, it is turned into a |
| 647 | reference. So C<given(@foo)> is the same as C<given(\@foo)>, |
| 648 | for example. |
| 649 | |
| 650 | C<default> behaves exactly like C<when(1 == 1)>, which is |
| 651 | to say that it always matches. |
| 652 | |
| 653 | =head3 Breaking out |
| 654 | |
| 655 | You can use the C<break> keyword to break out of the enclosing |
| 656 | C<given> block. Every C<when> block is implicitly ended with |
| 657 | a C<break>. |
| 658 | |
| 659 | =head3 Fall-through |
| 660 | |
| 661 | You can use the C<continue> keyword to fall through from one |
| 662 | case to the next: |
| 663 | |
| 664 | given($foo) { |
| 665 | when (/x/) { say '$foo contains an x'; continue } |
| 666 | when (/y/) { say '$foo contains a y' } |
| 667 | default { say '$foo does not contain a y' } |
| 668 | } |
| 669 | |
| 670 | =head3 Switching in a loop |
| 671 | |
| 672 | Instead of using C<given()>, you can use a C<foreach()> loop. |
| 673 | For example, here's one way to count how many times a particular |
| 674 | string occurs in an array: |
| 675 | |
| 676 | my $count = 0; |
| 677 | for (@array) { |
| 678 | when ("foo") { ++$count } |
| 679 | } |
| 680 | print "\@array contains $count copies of 'foo'\n"; |
| 681 | |
| 682 | At the end of all C<when> blocks, there is an implicit C<next>. |
| 683 | You can override that with an explicit C<last> if you're only |
| 684 | interested in the first match. |
| 685 | |
| 686 | This doesn't work if you explicitly specify a loop variable, |
| 687 | as in C<for $item (@array)>. You have to use the default |
| 688 | variable C<$_>. (You can use C<for my $_ (@array)>.) |
| 689 | |
| 690 | =head3 Smart matching in detail |
| 691 | |
| 692 | The behaviour of a smart match depends on what type of thing its arguments |
| 693 | are. The behaviour is determined by the following table: the first row |
| 694 | that applies determines the match behaviour (which is thus mostly |
| 695 | determined by the type of the right operand). Note that the smart match |
| 696 | implicitly dereferences any non-blessed hash or array ref, so the "Hash" |
| 697 | and "Array" entries apply in those cases. (For blessed references, the |
| 698 | "Object" entries apply.) |
| 699 | |
| 700 | Note that the "Matching Code" column is not always an exact rendition. For |
| 701 | example, the smart match operator short-circuits whenever possible, but |
| 702 | C<grep> does not. |
| 703 | |
| 704 | $a $b Type of Match Implied Matching Code |
| 705 | ====== ===== ===================== ============= |
| 706 | Any undef undefined !defined $a |
| 707 | |
| 708 | Any Object invokes ~~ overloading on $object, or dies |
| 709 | |
| 710 | Hash CodeRef sub truth for each key[1] !grep { !$b->($_) } keys %$a |
| 711 | Array CodeRef sub truth for each elt[1] !grep { !$b->($_) } @$a |
| 712 | Any CodeRef scalar sub truth $b->($a) |
| 713 | |
| 714 | Hash Hash hash keys identical (every key is found in both hashes) |
| 715 | Array Hash hash keys intersection grep { exists $b->{$_} } @$a |
| 716 | Regex Hash hash key grep grep /$a/, keys %$b |
| 717 | undef Hash always false (undef can't be a key) |
| 718 | Any Hash hash entry existence exists $b->{$a} |
| 719 | |
| 720 | Hash Array hash keys intersection grep { exists $a->{$_} } @$b |
| 721 | Array Array arrays are comparable[2] |
| 722 | Regex Array array grep grep /$a/, @$b |
| 723 | undef Array array contains undef grep !defined, @$b |
| 724 | Any Array match against an array element[3] |
| 725 | grep $a ~~ $_, @$b |
| 726 | |
| 727 | Hash Regex hash key grep grep /$b/, keys %$a |
| 728 | Array Regex array grep grep /$b/, @$a |
| 729 | Any Regex pattern match $a =~ /$b/ |
| 730 | |
| 731 | Object Any invokes ~~ overloading on $object, or falls back: |
| 732 | Any Num numeric equality $a == $b |
| 733 | Num numish[4] numeric equality $a == $b |
| 734 | undef Any undefined !defined($b) |
| 735 | Any Any string equality $a eq $b |
| 736 | |
| 737 | 1 - empty hashes or arrays will match. |
| 738 | 2 - that is, each element smart-matches the element of same index in the |
| 739 | other array. [3] |
| 740 | 3 - If a circular reference is found, we fall back to referential equality. |
| 741 | 4 - either a real number, or a string that looks like a number |
| 742 | |
| 743 | =head3 Custom matching via overloading |
| 744 | |
| 745 | You can change the way that an object is matched by overloading |
| 746 | the C<~~> operator. This may alter the usual smart match semantics. |
| 747 | |
| 748 | It should be noted that C<~~> will refuse to work on objects that |
| 749 | don't overload it (in order to avoid relying on the object's |
| 750 | underlying structure). |
| 751 | |
| 752 | Note also that smart match's matching rules take precedence over |
| 753 | overloading, so if C<$obj> has smart match overloading, then |
| 754 | |
| 755 | $obj ~~ X |
| 756 | |
| 757 | will not automatically invoke the overload method with X as an argument; |
| 758 | instead the table above is consulted as normal, and based in the type of X, |
| 759 | overloading may or may not be invoked. |
| 760 | |
| 761 | See L<overload>. |
| 762 | |
| 763 | =head3 Differences from Perl 6 |
| 764 | |
| 765 | The Perl 5 smart match and C<given>/C<when> constructs are not |
| 766 | absolutely identical to their Perl 6 analogues. The most visible |
| 767 | difference is that, in Perl 5, parentheses are required around |
| 768 | the argument to C<given()> and C<when()> (except when this last |
| 769 | one is used as a statement modifier). Parentheses in Perl 6 |
| 770 | are always optional in a control construct such as C<if()>, |
| 771 | C<while()>, or C<when()>; they can't be made optional in Perl |
| 772 | 5 without a great deal of potential confusion, because Perl 5 |
| 773 | would parse the expression |
| 774 | |
| 775 | given $foo { |
| 776 | ... |
| 777 | } |
| 778 | |
| 779 | as though the argument to C<given> were an element of the hash |
| 780 | C<%foo>, interpreting the braces as hash-element syntax. |
| 781 | |
| 782 | The table of smart matches is not identical to that proposed by the |
| 783 | Perl 6 specification, mainly due to the differences between Perl 6's |
| 784 | and Perl 5's data models. |
| 785 | |
| 786 | In Perl 6, C<when()> will always do an implicit smart match |
| 787 | with its argument, whilst it is convenient in Perl 5 to |
| 788 | suppress this implicit smart match in certain situations, |
| 789 | as documented above. (The difference is largely because Perl 5 |
| 790 | does not, even internally, have a boolean type.) |
| 791 | |
| 792 | =head2 Goto |
| 793 | X<goto> |
| 794 | |
| 795 | Although not for the faint of heart, Perl does support a C<goto> |
| 796 | statement. There are three forms: C<goto>-LABEL, C<goto>-EXPR, and |
| 797 | C<goto>-&NAME. A loop's LABEL is not actually a valid target for |
| 798 | a C<goto>; it's just the name of the loop. |
| 799 | |
| 800 | The C<goto>-LABEL form finds the statement labeled with LABEL and resumes |
| 801 | execution there. It may not be used to go into any construct that |
| 802 | requires initialization, such as a subroutine or a C<foreach> loop. It |
| 803 | also can't be used to go into a construct that is optimized away. It |
| 804 | can be used to go almost anywhere else within the dynamic scope, |
| 805 | including out of subroutines, but it's usually better to use some other |
| 806 | construct such as C<last> or C<die>. The author of Perl has never felt the |
| 807 | need to use this form of C<goto> (in Perl, that is--C is another matter). |
| 808 | |
| 809 | The C<goto>-EXPR form expects a label name, whose scope will be resolved |
| 810 | dynamically. This allows for computed C<goto>s per FORTRAN, but isn't |
| 811 | necessarily recommended if you're optimizing for maintainability: |
| 812 | |
| 813 | goto(("FOO", "BAR", "GLARCH")[$i]); |
| 814 | |
| 815 | The C<goto>-&NAME form is highly magical, and substitutes a call to the |
| 816 | named subroutine for the currently running subroutine. This is used by |
| 817 | C<AUTOLOAD()> subroutines that wish to load another subroutine and then |
| 818 | pretend that the other subroutine had been called in the first place |
| 819 | (except that any modifications to C<@_> in the current subroutine are |
| 820 | propagated to the other subroutine.) After the C<goto>, not even C<caller()> |
| 821 | will be able to tell that this routine was called first. |
| 822 | |
| 823 | In almost all cases like this, it's usually a far, far better idea to use the |
| 824 | structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of |
| 825 | resorting to a C<goto>. For certain applications, the catch and throw pair of |
| 826 | C<eval{}> and die() for exception processing can also be a prudent approach. |
| 827 | |
| 828 | =head2 PODs: Embedded Documentation |
| 829 | X<POD> X<documentation> |
| 830 | |
| 831 | Perl has a mechanism for intermixing documentation with source code. |
| 832 | While it's expecting the beginning of a new statement, if the compiler |
| 833 | encounters a line that begins with an equal sign and a word, like this |
| 834 | |
| 835 | =head1 Here There Be Pods! |
| 836 | |
| 837 | Then that text and all remaining text up through and including a line |
| 838 | beginning with C<=cut> will be ignored. The format of the intervening |
| 839 | text is described in L<perlpod>. |
| 840 | |
| 841 | This allows you to intermix your source code |
| 842 | and your documentation text freely, as in |
| 843 | |
| 844 | =item snazzle($) |
| 845 | |
| 846 | The snazzle() function will behave in the most spectacular |
| 847 | form that you can possibly imagine, not even excepting |
| 848 | cybernetic pyrotechnics. |
| 849 | |
| 850 | =cut back to the compiler, nuff of this pod stuff! |
| 851 | |
| 852 | sub snazzle($) { |
| 853 | my $thingie = shift; |
| 854 | ......... |
| 855 | } |
| 856 | |
| 857 | Note that pod translators should look at only paragraphs beginning |
| 858 | with a pod directive (it makes parsing easier), whereas the compiler |
| 859 | actually knows to look for pod escapes even in the middle of a |
| 860 | paragraph. This means that the following secret stuff will be |
| 861 | ignored by both the compiler and the translators. |
| 862 | |
| 863 | $a=3; |
| 864 | =secret stuff |
| 865 | warn "Neither POD nor CODE!?" |
| 866 | =cut back |
| 867 | print "got $a\n"; |
| 868 | |
| 869 | You probably shouldn't rely upon the C<warn()> being podded out forever. |
| 870 | Not all pod translators are well-behaved in this regard, and perhaps |
| 871 | the compiler will become pickier. |
| 872 | |
| 873 | One may also use pod directives to quickly comment out a section |
| 874 | of code. |
| 875 | |
| 876 | =head2 Plain Old Comments (Not!) |
| 877 | X<comment> X<line> X<#> X<preprocessor> X<eval> |
| 878 | |
| 879 | Perl can process line directives, much like the C preprocessor. Using |
| 880 | this, one can control Perl's idea of filenames and line numbers in |
| 881 | error or warning messages (especially for strings that are processed |
| 882 | with C<eval()>). The syntax for this mechanism is the same as for most |
| 883 | C preprocessors: it matches the regular expression |
| 884 | |
| 885 | # example: '# line 42 "new_filename.plx"' |
| 886 | /^\# \s* |
| 887 | line \s+ (\d+) \s* |
| 888 | (?:\s("?)([^"]+)\2)? \s* |
| 889 | $/x |
| 890 | |
| 891 | with C<$1> being the line number for the next line, and C<$3> being |
| 892 | the optional filename (specified with or without quotes). |
| 893 | |
| 894 | There is a fairly obvious gotcha included with the line directive: |
| 895 | Debuggers and profilers will only show the last source line to appear |
| 896 | at a particular line number in a given file. Care should be taken not |
| 897 | to cause line number collisions in code you'd like to debug later. |
| 898 | |
| 899 | Here are some examples that you should be able to type into your command |
| 900 | shell: |
| 901 | |
| 902 | % perl |
| 903 | # line 200 "bzzzt" |
| 904 | # the `#' on the previous line must be the first char on line |
| 905 | die 'foo'; |
| 906 | __END__ |
| 907 | foo at bzzzt line 201. |
| 908 | |
| 909 | % perl |
| 910 | # line 200 "bzzzt" |
| 911 | eval qq[\n#line 2001 ""\ndie 'foo']; print $@; |
| 912 | __END__ |
| 913 | foo at - line 2001. |
| 914 | |
| 915 | % perl |
| 916 | eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@; |
| 917 | __END__ |
| 918 | foo at foo bar line 200. |
| 919 | |
| 920 | % perl |
| 921 | # line 345 "goop" |
| 922 | eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'"; |
| 923 | print $@; |
| 924 | __END__ |
| 925 | foo at goop line 345. |
| 926 | |
| 927 | =cut |