| 1 | =head1 NAME |
| 2 | |
| 3 | perltie - how to hide an object class in a simple variable |
| 4 | |
| 5 | =head1 SYNOPSIS |
| 6 | |
| 7 | tie VARIABLE, CLASSNAME, LIST |
| 8 | |
| 9 | $object = tied VARIABLE |
| 10 | |
| 11 | untie VARIABLE |
| 12 | |
| 13 | =head1 DESCRIPTION |
| 14 | |
| 15 | Prior to release 5.0 of Perl, a programmer could use dbmopen() |
| 16 | to connect an on-disk database in the standard Unix dbm(3x) |
| 17 | format magically to a %HASH in their program. However, their Perl was either |
| 18 | built with one particular dbm library or another, but not both, and |
| 19 | you couldn't extend this mechanism to other packages or types of variables. |
| 20 | |
| 21 | Now you can. |
| 22 | |
| 23 | The tie() function binds a variable to a class (package) that will provide |
| 24 | the implementation for access methods for that variable. Once this magic |
| 25 | has been performed, accessing a tied variable automatically triggers |
| 26 | method calls in the proper class. The complexity of the class is |
| 27 | hidden behind magic methods calls. The method names are in ALL CAPS, |
| 28 | which is a convention that Perl uses to indicate that they're called |
| 29 | implicitly rather than explicitly--just like the BEGIN() and END() |
| 30 | functions. |
| 31 | |
| 32 | In the tie() call, C<VARIABLE> is the name of the variable to be |
| 33 | enchanted. C<CLASSNAME> is the name of a class implementing objects of |
| 34 | the correct type. Any additional arguments in the C<LIST> are passed to |
| 35 | the appropriate constructor method for that class--meaning TIESCALAR(), |
| 36 | TIEARRAY(), TIEHASH(), or TIEHANDLE(). (Typically these are arguments |
| 37 | such as might be passed to the dbminit() function of C.) The object |
| 38 | returned by the "new" method is also returned by the tie() function, |
| 39 | which would be useful if you wanted to access other methods in |
| 40 | C<CLASSNAME>. (You don't actually have to return a reference to a right |
| 41 | "type" (e.g., HASH or C<CLASSNAME>) so long as it's a properly blessed |
| 42 | object.) You can also retrieve a reference to the underlying object |
| 43 | using the tied() function. |
| 44 | |
| 45 | Unlike dbmopen(), the tie() function will not C<use> or C<require> a module |
| 46 | for you--you need to do that explicitly yourself. |
| 47 | |
| 48 | =head2 Tying Scalars |
| 49 | |
| 50 | A class implementing a tied scalar should define the following methods: |
| 51 | TIESCALAR, FETCH, STORE, and possibly DESTROY. |
| 52 | |
| 53 | Let's look at each in turn, using as an example a tie class for |
| 54 | scalars that allows the user to do something like: |
| 55 | |
| 56 | tie $his_speed, 'Nice', getppid(); |
| 57 | tie $my_speed, 'Nice', $$; |
| 58 | |
| 59 | And now whenever either of those variables is accessed, its current |
| 60 | system priority is retrieved and returned. If those variables are set, |
| 61 | then the process's priority is changed! |
| 62 | |
| 63 | We'll use Jarkko Hietaniemi <F<jhi@iki.fi>>'s BSD::Resource class (not |
| 64 | included) to access the PRIO_PROCESS, PRIO_MIN, and PRIO_MAX constants |
| 65 | from your system, as well as the getpriority() and setpriority() system |
| 66 | calls. Here's the preamble of the class. |
| 67 | |
| 68 | package Nice; |
| 69 | use Carp; |
| 70 | use BSD::Resource; |
| 71 | use strict; |
| 72 | $Nice::DEBUG = 0 unless defined $Nice::DEBUG; |
| 73 | |
| 74 | =over |
| 75 | |
| 76 | =item TIESCALAR classname, LIST |
| 77 | |
| 78 | This is the constructor for the class. That means it is |
| 79 | expected to return a blessed reference to a new scalar |
| 80 | (probably anonymous) that it's creating. For example: |
| 81 | |
| 82 | sub TIESCALAR { |
| 83 | my $class = shift; |
| 84 | my $pid = shift || $$; # 0 means me |
| 85 | |
| 86 | if ($pid !~ /^\d+$/) { |
| 87 | carp "Nice::Tie::Scalar got non-numeric pid $pid" if $^W; |
| 88 | return undef; |
| 89 | } |
| 90 | |
| 91 | unless (kill 0, $pid) { # EPERM or ERSCH, no doubt |
| 92 | carp "Nice::Tie::Scalar got bad pid $pid: $!" if $^W; |
| 93 | return undef; |
| 94 | } |
| 95 | |
| 96 | return bless \$pid, $class; |
| 97 | } |
| 98 | |
| 99 | This tie class has chosen to return an error rather than raising an |
| 100 | exception if its constructor should fail. While this is how dbmopen() works, |
| 101 | other classes may well not wish to be so forgiving. It checks the global |
| 102 | variable C<$^W> to see whether to emit a bit of noise anyway. |
| 103 | |
| 104 | =item FETCH this |
| 105 | |
| 106 | This method will be triggered every time the tied variable is accessed |
| 107 | (read). It takes no arguments beyond its self reference, which is the |
| 108 | object representing the scalar we're dealing with. Because in this case |
| 109 | we're using just a SCALAR ref for the tied scalar object, a simple $$self |
| 110 | allows the method to get at the real value stored there. In our example |
| 111 | below, that real value is the process ID to which we've tied our variable. |
| 112 | |
| 113 | sub FETCH { |
| 114 | my $self = shift; |
| 115 | confess "wrong type" unless ref $self; |
| 116 | croak "usage error" if @_; |
| 117 | my $nicety; |
| 118 | local($!) = 0; |
| 119 | $nicety = getpriority(PRIO_PROCESS, $$self); |
| 120 | if ($!) { croak "getpriority failed: $!" } |
| 121 | return $nicety; |
| 122 | } |
| 123 | |
| 124 | This time we've decided to blow up (raise an exception) if the renice |
| 125 | fails--there's no place for us to return an error otherwise, and it's |
| 126 | probably the right thing to do. |
| 127 | |
| 128 | =item STORE this, value |
| 129 | |
| 130 | This method will be triggered every time the tied variable is set |
| 131 | (assigned). Beyond its self reference, it also expects one (and only one) |
| 132 | argument--the new value the user is trying to assign. |
| 133 | |
| 134 | sub STORE { |
| 135 | my $self = shift; |
| 136 | confess "wrong type" unless ref $self; |
| 137 | my $new_nicety = shift; |
| 138 | croak "usage error" if @_; |
| 139 | |
| 140 | if ($new_nicety < PRIO_MIN) { |
| 141 | carp sprintf |
| 142 | "WARNING: priority %d less than minimum system priority %d", |
| 143 | $new_nicety, PRIO_MIN if $^W; |
| 144 | $new_nicety = PRIO_MIN; |
| 145 | } |
| 146 | |
| 147 | if ($new_nicety > PRIO_MAX) { |
| 148 | carp sprintf |
| 149 | "WARNING: priority %d greater than maximum system priority %d", |
| 150 | $new_nicety, PRIO_MAX if $^W; |
| 151 | $new_nicety = PRIO_MAX; |
| 152 | } |
| 153 | |
| 154 | unless (defined setpriority(PRIO_PROCESS, $$self, $new_nicety)) { |
| 155 | confess "setpriority failed: $!"; |
| 156 | } |
| 157 | return $new_nicety; |
| 158 | } |
| 159 | |
| 160 | =item DESTROY this |
| 161 | |
| 162 | This method will be triggered when the tied variable needs to be destructed. |
| 163 | As with other object classes, such a method is seldom necessary, because Perl |
| 164 | deallocates its moribund object's memory for you automatically--this isn't |
| 165 | C++, you know. We'll use a DESTROY method here for debugging purposes only. |
| 166 | |
| 167 | sub DESTROY { |
| 168 | my $self = shift; |
| 169 | confess "wrong type" unless ref $self; |
| 170 | carp "[ Nice::DESTROY pid $$self ]" if $Nice::DEBUG; |
| 171 | } |
| 172 | |
| 173 | =back |
| 174 | |
| 175 | That's about all there is to it. Actually, it's more than all there |
| 176 | is to it, because we've done a few nice things here for the sake |
| 177 | of completeness, robustness, and general aesthetics. Simpler |
| 178 | TIESCALAR classes are certainly possible. |
| 179 | |
| 180 | =head2 Tying Arrays |
| 181 | |
| 182 | A class implementing a tied ordinary array should define the following |
| 183 | methods: TIEARRAY, FETCH, STORE, FETCHSIZE, STORESIZE and perhaps DESTROY. |
| 184 | |
| 185 | FETCHSIZE and STORESIZE are used to provide C<$#array> and |
| 186 | equivalent C<scalar(@array)> access. |
| 187 | |
| 188 | The methods POP, PUSH, SHIFT, UNSHIFT, SPLICE are required if the perl |
| 189 | operator with the corresponding (but lowercase) name is to operate on the |
| 190 | tied array. The B<Tie::Array> class can be used as a base class to implement |
| 191 | these in terms of the basic five methods above. |
| 192 | |
| 193 | In addition EXTEND will be called when perl would have pre-extended |
| 194 | allocation in a real array. |
| 195 | |
| 196 | This means that tied arrays are now I<complete>. The example below needs |
| 197 | upgrading to illustrate this. (The documentation in B<Tie::Array> is more |
| 198 | complete.) |
| 199 | |
| 200 | For this discussion, we'll implement an array whose indices are fixed at |
| 201 | its creation. If you try to access anything beyond those bounds, you'll |
| 202 | take an exception. For example: |
| 203 | |
| 204 | require Bounded_Array; |
| 205 | tie @ary, 'Bounded_Array', 2; |
| 206 | $| = 1; |
| 207 | for $i (0 .. 10) { |
| 208 | print "setting index $i: "; |
| 209 | $ary[$i] = 10 * $i; |
| 210 | $ary[$i] = 10 * $i; |
| 211 | print "value of elt $i now $ary[$i]\n"; |
| 212 | } |
| 213 | |
| 214 | The preamble code for the class is as follows: |
| 215 | |
| 216 | package Bounded_Array; |
| 217 | use Carp; |
| 218 | use strict; |
| 219 | |
| 220 | =over |
| 221 | |
| 222 | =item TIEARRAY classname, LIST |
| 223 | |
| 224 | This is the constructor for the class. That means it is expected to |
| 225 | return a blessed reference through which the new array (probably an |
| 226 | anonymous ARRAY ref) will be accessed. |
| 227 | |
| 228 | In our example, just to show you that you don't I<really> have to return an |
| 229 | ARRAY reference, we'll choose a HASH reference to represent our object. |
| 230 | A HASH works out well as a generic record type: the C<{BOUND}> field will |
| 231 | store the maximum bound allowed, and the C<{ARRAY}> field will hold the |
| 232 | true ARRAY ref. If someone outside the class tries to dereference the |
| 233 | object returned (doubtless thinking it an ARRAY ref), they'll blow up. |
| 234 | This just goes to show you that you should respect an object's privacy. |
| 235 | |
| 236 | sub TIEARRAY { |
| 237 | my $class = shift; |
| 238 | my $bound = shift; |
| 239 | confess "usage: tie(\@ary, 'Bounded_Array', max_subscript)" |
| 240 | if @_ || $bound =~ /\D/; |
| 241 | return bless { |
| 242 | BOUND => $bound, |
| 243 | ARRAY => [], |
| 244 | }, $class; |
| 245 | } |
| 246 | |
| 247 | =item FETCH this, index |
| 248 | |
| 249 | This method will be triggered every time an individual element the tied array |
| 250 | is accessed (read). It takes one argument beyond its self reference: the |
| 251 | index whose value we're trying to fetch. |
| 252 | |
| 253 | sub FETCH { |
| 254 | my($self,$idx) = @_; |
| 255 | if ($idx > $self->{BOUND}) { |
| 256 | confess "Array OOB: $idx > $self->{BOUND}"; |
| 257 | } |
| 258 | return $self->{ARRAY}[$idx]; |
| 259 | } |
| 260 | |
| 261 | As you may have noticed, the name of the FETCH method (et al.) is the same |
| 262 | for all accesses, even though the constructors differ in names (TIESCALAR |
| 263 | vs TIEARRAY). While in theory you could have the same class servicing |
| 264 | several tied types, in practice this becomes cumbersome, and it's easiest |
| 265 | to keep them at simply one tie type per class. |
| 266 | |
| 267 | =item STORE this, index, value |
| 268 | |
| 269 | This method will be triggered every time an element in the tied array is set |
| 270 | (written). It takes two arguments beyond its self reference: the index at |
| 271 | which we're trying to store something and the value we're trying to put |
| 272 | there. For example: |
| 273 | |
| 274 | sub STORE { |
| 275 | my($self, $idx, $value) = @_; |
| 276 | print "[STORE $value at $idx]\n" if _debug; |
| 277 | if ($idx > $self->{BOUND} ) { |
| 278 | confess "Array OOB: $idx > $self->{BOUND}"; |
| 279 | } |
| 280 | return $self->{ARRAY}[$idx] = $value; |
| 281 | } |
| 282 | |
| 283 | =item DESTROY this |
| 284 | |
| 285 | This method will be triggered when the tied variable needs to be destructed. |
| 286 | As with the scalar tie class, this is almost never needed in a |
| 287 | language that does its own garbage collection, so this time we'll |
| 288 | just leave it out. |
| 289 | |
| 290 | =back |
| 291 | |
| 292 | The code we presented at the top of the tied array class accesses many |
| 293 | elements of the array, far more than we've set the bounds to. Therefore, |
| 294 | it will blow up once they try to access beyond the 2nd element of @ary, as |
| 295 | the following output demonstrates: |
| 296 | |
| 297 | setting index 0: value of elt 0 now 0 |
| 298 | setting index 1: value of elt 1 now 10 |
| 299 | setting index 2: value of elt 2 now 20 |
| 300 | setting index 3: Array OOB: 3 > 2 at Bounded_Array.pm line 39 |
| 301 | Bounded_Array::FETCH called at testba line 12 |
| 302 | |
| 303 | =head2 Tying Hashes |
| 304 | |
| 305 | As the first Perl data type to be tied (see dbmopen()), hashes have the |
| 306 | most complete and useful tie() implementation. A class implementing a |
| 307 | tied hash should define the following methods: TIEHASH is the constructor. |
| 308 | FETCH and STORE access the key and value pairs. EXISTS reports whether a |
| 309 | key is present in the hash, and DELETE deletes one. CLEAR empties the |
| 310 | hash by deleting all the key and value pairs. FIRSTKEY and NEXTKEY |
| 311 | implement the keys() and each() functions to iterate over all the keys. |
| 312 | And DESTROY is called when the tied variable is garbage collected. |
| 313 | |
| 314 | If this seems like a lot, then feel free to inherit from merely the |
| 315 | standard Tie::Hash module for most of your methods, redefining only the |
| 316 | interesting ones. See L<Tie::Hash> for details. |
| 317 | |
| 318 | Remember that Perl distinguishes between a key not existing in the hash, |
| 319 | and the key existing in the hash but having a corresponding value of |
| 320 | C<undef>. The two possibilities can be tested with the C<exists()> and |
| 321 | C<defined()> functions. |
| 322 | |
| 323 | Here's an example of a somewhat interesting tied hash class: it gives you |
| 324 | a hash representing a particular user's dot files. You index into the hash |
| 325 | with the name of the file (minus the dot) and you get back that dot file's |
| 326 | contents. For example: |
| 327 | |
| 328 | use DotFiles; |
| 329 | tie %dot, 'DotFiles'; |
| 330 | if ( $dot{profile} =~ /MANPATH/ || |
| 331 | $dot{login} =~ /MANPATH/ || |
| 332 | $dot{cshrc} =~ /MANPATH/ ) |
| 333 | { |
| 334 | print "you seem to set your MANPATH\n"; |
| 335 | } |
| 336 | |
| 337 | Or here's another sample of using our tied class: |
| 338 | |
| 339 | tie %him, 'DotFiles', 'daemon'; |
| 340 | foreach $f ( keys %him ) { |
| 341 | printf "daemon dot file %s is size %d\n", |
| 342 | $f, length $him{$f}; |
| 343 | } |
| 344 | |
| 345 | In our tied hash DotFiles example, we use a regular |
| 346 | hash for the object containing several important |
| 347 | fields, of which only the C<{LIST}> field will be what the |
| 348 | user thinks of as the real hash. |
| 349 | |
| 350 | =over 5 |
| 351 | |
| 352 | =item USER |
| 353 | |
| 354 | whose dot files this object represents |
| 355 | |
| 356 | =item HOME |
| 357 | |
| 358 | where those dot files live |
| 359 | |
| 360 | =item CLOBBER |
| 361 | |
| 362 | whether we should try to change or remove those dot files |
| 363 | |
| 364 | =item LIST |
| 365 | |
| 366 | the hash of dot file names and content mappings |
| 367 | |
| 368 | =back |
| 369 | |
| 370 | Here's the start of F<Dotfiles.pm>: |
| 371 | |
| 372 | package DotFiles; |
| 373 | use Carp; |
| 374 | sub whowasi { (caller(1))[3] . '()' } |
| 375 | my $DEBUG = 0; |
| 376 | sub debug { $DEBUG = @_ ? shift : 1 } |
| 377 | |
| 378 | For our example, we want to be able to emit debugging info to help in tracing |
| 379 | during development. We keep also one convenience function around |
| 380 | internally to help print out warnings; whowasi() returns the function name |
| 381 | that calls it. |
| 382 | |
| 383 | Here are the methods for the DotFiles tied hash. |
| 384 | |
| 385 | =over |
| 386 | |
| 387 | =item TIEHASH classname, LIST |
| 388 | |
| 389 | This is the constructor for the class. That means it is expected to |
| 390 | return a blessed reference through which the new object (probably but not |
| 391 | necessarily an anonymous hash) will be accessed. |
| 392 | |
| 393 | Here's the constructor: |
| 394 | |
| 395 | sub TIEHASH { |
| 396 | my $self = shift; |
| 397 | my $user = shift || $>; |
| 398 | my $dotdir = shift || ''; |
| 399 | croak "usage: @{[&whowasi]} [USER [DOTDIR]]" if @_; |
| 400 | $user = getpwuid($user) if $user =~ /^\d+$/; |
| 401 | my $dir = (getpwnam($user))[7] |
| 402 | || croak "@{[&whowasi]}: no user $user"; |
| 403 | $dir .= "/$dotdir" if $dotdir; |
| 404 | |
| 405 | my $node = { |
| 406 | USER => $user, |
| 407 | HOME => $dir, |
| 408 | LIST => {}, |
| 409 | CLOBBER => 0, |
| 410 | }; |
| 411 | |
| 412 | opendir(DIR, $dir) |
| 413 | || croak "@{[&whowasi]}: can't opendir $dir: $!"; |
| 414 | foreach $dot ( grep /^\./ && -f "$dir/$_", readdir(DIR)) { |
| 415 | $dot =~ s/^\.//; |
| 416 | $node->{LIST}{$dot} = undef; |
| 417 | } |
| 418 | closedir DIR; |
| 419 | return bless $node, $self; |
| 420 | } |
| 421 | |
| 422 | It's probably worth mentioning that if you're going to filetest the |
| 423 | return values out of a readdir, you'd better prepend the directory |
| 424 | in question. Otherwise, because we didn't chdir() there, it would |
| 425 | have been testing the wrong file. |
| 426 | |
| 427 | =item FETCH this, key |
| 428 | |
| 429 | This method will be triggered every time an element in the tied hash is |
| 430 | accessed (read). It takes one argument beyond its self reference: the key |
| 431 | whose value we're trying to fetch. |
| 432 | |
| 433 | Here's the fetch for our DotFiles example. |
| 434 | |
| 435 | sub FETCH { |
| 436 | carp &whowasi if $DEBUG; |
| 437 | my $self = shift; |
| 438 | my $dot = shift; |
| 439 | my $dir = $self->{HOME}; |
| 440 | my $file = "$dir/.$dot"; |
| 441 | |
| 442 | unless (exists $self->{LIST}->{$dot} || -f $file) { |
| 443 | carp "@{[&whowasi]}: no $dot file" if $DEBUG; |
| 444 | return undef; |
| 445 | } |
| 446 | |
| 447 | if (defined $self->{LIST}->{$dot}) { |
| 448 | return $self->{LIST}->{$dot}; |
| 449 | } else { |
| 450 | return $self->{LIST}->{$dot} = `cat $dir/.$dot`; |
| 451 | } |
| 452 | } |
| 453 | |
| 454 | It was easy to write by having it call the Unix cat(1) command, but it |
| 455 | would probably be more portable to open the file manually (and somewhat |
| 456 | more efficient). Of course, because dot files are a Unixy concept, we're |
| 457 | not that concerned. |
| 458 | |
| 459 | =item STORE this, key, value |
| 460 | |
| 461 | This method will be triggered every time an element in the tied hash is set |
| 462 | (written). It takes two arguments beyond its self reference: the index at |
| 463 | which we're trying to store something, and the value we're trying to put |
| 464 | there. |
| 465 | |
| 466 | Here in our DotFiles example, we'll be careful not to let |
| 467 | them try to overwrite the file unless they've called the clobber() |
| 468 | method on the original object reference returned by tie(). |
| 469 | |
| 470 | sub STORE { |
| 471 | carp &whowasi if $DEBUG; |
| 472 | my $self = shift; |
| 473 | my $dot = shift; |
| 474 | my $value = shift; |
| 475 | my $file = $self->{HOME} . "/.$dot"; |
| 476 | my $user = $self->{USER}; |
| 477 | |
| 478 | croak "@{[&whowasi]}: $file not clobberable" |
| 479 | unless $self->{CLOBBER}; |
| 480 | |
| 481 | open(F, "> $file") || croak "can't open $file: $!"; |
| 482 | print F $value; |
| 483 | close(F); |
| 484 | } |
| 485 | |
| 486 | If they wanted to clobber something, they might say: |
| 487 | |
| 488 | $ob = tie %daemon_dots, 'daemon'; |
| 489 | $ob->clobber(1); |
| 490 | $daemon_dots{signature} = "A true daemon\n"; |
| 491 | |
| 492 | Another way to lay hands on a reference to the underlying object is to |
| 493 | use the tied() function, so they might alternately have set clobber |
| 494 | using: |
| 495 | |
| 496 | tie %daemon_dots, 'daemon'; |
| 497 | tied(%daemon_dots)->clobber(1); |
| 498 | |
| 499 | The clobber method is simply: |
| 500 | |
| 501 | sub clobber { |
| 502 | my $self = shift; |
| 503 | $self->{CLOBBER} = @_ ? shift : 1; |
| 504 | } |
| 505 | |
| 506 | =item DELETE this, key |
| 507 | |
| 508 | This method is triggered when we remove an element from the hash, |
| 509 | typically by using the delete() function. Again, we'll |
| 510 | be careful to check whether they really want to clobber files. |
| 511 | |
| 512 | sub DELETE { |
| 513 | carp &whowasi if $DEBUG; |
| 514 | |
| 515 | my $self = shift; |
| 516 | my $dot = shift; |
| 517 | my $file = $self->{HOME} . "/.$dot"; |
| 518 | croak "@{[&whowasi]}: won't remove file $file" |
| 519 | unless $self->{CLOBBER}; |
| 520 | delete $self->{LIST}->{$dot}; |
| 521 | my $success = unlink($file); |
| 522 | carp "@{[&whowasi]}: can't unlink $file: $!" unless $success; |
| 523 | $success; |
| 524 | } |
| 525 | |
| 526 | The value returned by DELETE becomes the return value of the call |
| 527 | to delete(). If you want to emulate the normal behavior of delete(), |
| 528 | you should return whatever FETCH would have returned for this key. |
| 529 | In this example, we have chosen instead to return a value which tells |
| 530 | the caller whether the file was successfully deleted. |
| 531 | |
| 532 | =item CLEAR this |
| 533 | |
| 534 | This method is triggered when the whole hash is to be cleared, usually by |
| 535 | assigning the empty list to it. |
| 536 | |
| 537 | In our example, that would remove all the user's dot files! It's such a |
| 538 | dangerous thing that they'll have to set CLOBBER to something higher than |
| 539 | 1 to make it happen. |
| 540 | |
| 541 | sub CLEAR { |
| 542 | carp &whowasi if $DEBUG; |
| 543 | my $self = shift; |
| 544 | croak "@{[&whowasi]}: won't remove all dot files for $self->{USER}" |
| 545 | unless $self->{CLOBBER} > 1; |
| 546 | my $dot; |
| 547 | foreach $dot ( keys %{$self->{LIST}}) { |
| 548 | $self->DELETE($dot); |
| 549 | } |
| 550 | } |
| 551 | |
| 552 | =item EXISTS this, key |
| 553 | |
| 554 | This method is triggered when the user uses the exists() function |
| 555 | on a particular hash. In our example, we'll look at the C<{LIST}> |
| 556 | hash element for this: |
| 557 | |
| 558 | sub EXISTS { |
| 559 | carp &whowasi if $DEBUG; |
| 560 | my $self = shift; |
| 561 | my $dot = shift; |
| 562 | return exists $self->{LIST}->{$dot}; |
| 563 | } |
| 564 | |
| 565 | =item FIRSTKEY this |
| 566 | |
| 567 | This method will be triggered when the user is going |
| 568 | to iterate through the hash, such as via a keys() or each() |
| 569 | call. |
| 570 | |
| 571 | sub FIRSTKEY { |
| 572 | carp &whowasi if $DEBUG; |
| 573 | my $self = shift; |
| 574 | my $a = keys %{$self->{LIST}}; # reset each() iterator |
| 575 | each %{$self->{LIST}} |
| 576 | } |
| 577 | |
| 578 | =item NEXTKEY this, lastkey |
| 579 | |
| 580 | This method gets triggered during a keys() or each() iteration. It has a |
| 581 | second argument which is the last key that had been accessed. This is |
| 582 | useful if you're carrying about ordering or calling the iterator from more |
| 583 | than one sequence, or not really storing things in a hash anywhere. |
| 584 | |
| 585 | For our example, we're using a real hash so we'll do just the simple |
| 586 | thing, but we'll have to go through the LIST field indirectly. |
| 587 | |
| 588 | sub NEXTKEY { |
| 589 | carp &whowasi if $DEBUG; |
| 590 | my $self = shift; |
| 591 | return each %{ $self->{LIST} } |
| 592 | } |
| 593 | |
| 594 | =item DESTROY this |
| 595 | |
| 596 | This method is triggered when a tied hash is about to go out of |
| 597 | scope. You don't really need it unless you're trying to add debugging |
| 598 | or have auxiliary state to clean up. Here's a very simple function: |
| 599 | |
| 600 | sub DESTROY { |
| 601 | carp &whowasi if $DEBUG; |
| 602 | } |
| 603 | |
| 604 | =back |
| 605 | |
| 606 | Note that functions such as keys() and values() may return huge lists |
| 607 | when used on large objects, like DBM files. You may prefer to use the |
| 608 | each() function to iterate over such. Example: |
| 609 | |
| 610 | # print out history file offsets |
| 611 | use NDBM_File; |
| 612 | tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0); |
| 613 | while (($key,$val) = each %HIST) { |
| 614 | print $key, ' = ', unpack('L',$val), "\n"; |
| 615 | } |
| 616 | untie(%HIST); |
| 617 | |
| 618 | =head2 Tying FileHandles |
| 619 | |
| 620 | This is partially implemented now. |
| 621 | |
| 622 | A class implementing a tied filehandle should define the following |
| 623 | methods: TIEHANDLE, at least one of PRINT, PRINTF, WRITE, READLINE, GETC, |
| 624 | READ, and possibly CLOSE and DESTROY. The class can also provide: BINMODE, |
| 625 | OPEN, EOF, FILENO, SEEK, TELL - if the corresponding perl operators are |
| 626 | used on the handle. |
| 627 | |
| 628 | It is especially useful when perl is embedded in some other program, |
| 629 | where output to STDOUT and STDERR may have to be redirected in some |
| 630 | special way. See nvi and the Apache module for examples. |
| 631 | |
| 632 | In our example we're going to create a shouting handle. |
| 633 | |
| 634 | package Shout; |
| 635 | |
| 636 | =over |
| 637 | |
| 638 | =item TIEHANDLE classname, LIST |
| 639 | |
| 640 | This is the constructor for the class. That means it is expected to |
| 641 | return a blessed reference of some sort. The reference can be used to |
| 642 | hold some internal information. |
| 643 | |
| 644 | sub TIEHANDLE { print "<shout>\n"; my $i; bless \$i, shift } |
| 645 | |
| 646 | =item WRITE this, LIST |
| 647 | |
| 648 | This method will be called when the handle is written to via the |
| 649 | C<syswrite> function. |
| 650 | |
| 651 | sub WRITE { |
| 652 | $r = shift; |
| 653 | my($buf,$len,$offset) = @_; |
| 654 | print "WRITE called, \$buf=$buf, \$len=$len, \$offset=$offset"; |
| 655 | } |
| 656 | |
| 657 | =item PRINT this, LIST |
| 658 | |
| 659 | This method will be triggered every time the tied handle is printed to |
| 660 | with the C<print()> function. |
| 661 | Beyond its self reference it also expects the list that was passed to |
| 662 | the print function. |
| 663 | |
| 664 | sub PRINT { $r = shift; $$r++; print join($,,map(uc($_),@_)),$\ } |
| 665 | |
| 666 | =item PRINTF this, LIST |
| 667 | |
| 668 | This method will be triggered every time the tied handle is printed to |
| 669 | with the C<printf()> function. |
| 670 | Beyond its self reference it also expects the format and list that was |
| 671 | passed to the printf function. |
| 672 | |
| 673 | sub PRINTF { |
| 674 | shift; |
| 675 | my $fmt = shift; |
| 676 | print sprintf($fmt, @_)."\n"; |
| 677 | } |
| 678 | |
| 679 | =item READ this, LIST |
| 680 | |
| 681 | This method will be called when the handle is read from via the C<read> |
| 682 | or C<sysread> functions. |
| 683 | |
| 684 | sub READ { |
| 685 | my $self = shift; |
| 686 | my $$bufref = \$_[0]; |
| 687 | my(undef,$len,$offset) = @_; |
| 688 | print "READ called, \$buf=$bufref, \$len=$len, \$offset=$offset"; |
| 689 | # add to $$bufref, set $len to number of characters read |
| 690 | $len; |
| 691 | } |
| 692 | |
| 693 | =item READLINE this |
| 694 | |
| 695 | This method will be called when the handle is read from via <HANDLE>. |
| 696 | The method should return undef when there is no more data. |
| 697 | |
| 698 | sub READLINE { $r = shift; "READLINE called $$r times\n"; } |
| 699 | |
| 700 | =item GETC this |
| 701 | |
| 702 | This method will be called when the C<getc> function is called. |
| 703 | |
| 704 | sub GETC { print "Don't GETC, Get Perl"; return "a"; } |
| 705 | |
| 706 | =item CLOSE this |
| 707 | |
| 708 | This method will be called when the handle is closed via the C<close> |
| 709 | function. |
| 710 | |
| 711 | sub CLOSE { print "CLOSE called.\n" } |
| 712 | |
| 713 | =item DESTROY this |
| 714 | |
| 715 | As with the other types of ties, this method will be called when the |
| 716 | tied handle is about to be destroyed. This is useful for debugging and |
| 717 | possibly cleaning up. |
| 718 | |
| 719 | sub DESTROY { print "</shout>\n" } |
| 720 | |
| 721 | =back |
| 722 | |
| 723 | Here's how to use our little example: |
| 724 | |
| 725 | tie(*FOO,'Shout'); |
| 726 | print FOO "hello\n"; |
| 727 | $a = 4; $b = 6; |
| 728 | print FOO $a, " plus ", $b, " equals ", $a + $b, "\n"; |
| 729 | print <FOO>; |
| 730 | |
| 731 | =head2 The C<untie> Gotcha |
| 732 | |
| 733 | If you intend making use of the object returned from either tie() or |
| 734 | tied(), and if the tie's target class defines a destructor, there is a |
| 735 | subtle gotcha you I<must> guard against. |
| 736 | |
| 737 | As setup, consider this (admittedly rather contrived) example of a |
| 738 | tie; all it does is use a file to keep a log of the values assigned to |
| 739 | a scalar. |
| 740 | |
| 741 | package Remember; |
| 742 | |
| 743 | use strict; |
| 744 | use IO::File; |
| 745 | |
| 746 | sub TIESCALAR { |
| 747 | my $class = shift; |
| 748 | my $filename = shift; |
| 749 | my $handle = new IO::File "> $filename" |
| 750 | or die "Cannot open $filename: $!\n"; |
| 751 | |
| 752 | print $handle "The Start\n"; |
| 753 | bless {FH => $handle, Value => 0}, $class; |
| 754 | } |
| 755 | |
| 756 | sub FETCH { |
| 757 | my $self = shift; |
| 758 | return $self->{Value}; |
| 759 | } |
| 760 | |
| 761 | sub STORE { |
| 762 | my $self = shift; |
| 763 | my $value = shift; |
| 764 | my $handle = $self->{FH}; |
| 765 | print $handle "$value\n"; |
| 766 | $self->{Value} = $value; |
| 767 | } |
| 768 | |
| 769 | sub DESTROY { |
| 770 | my $self = shift; |
| 771 | my $handle = $self->{FH}; |
| 772 | print $handle "The End\n"; |
| 773 | close $handle; |
| 774 | } |
| 775 | |
| 776 | 1; |
| 777 | |
| 778 | Here is an example that makes use of this tie: |
| 779 | |
| 780 | use strict; |
| 781 | use Remember; |
| 782 | |
| 783 | my $fred; |
| 784 | tie $fred, 'Remember', 'myfile.txt'; |
| 785 | $fred = 1; |
| 786 | $fred = 4; |
| 787 | $fred = 5; |
| 788 | untie $fred; |
| 789 | system "cat myfile.txt"; |
| 790 | |
| 791 | This is the output when it is executed: |
| 792 | |
| 793 | The Start |
| 794 | 1 |
| 795 | 4 |
| 796 | 5 |
| 797 | The End |
| 798 | |
| 799 | So far so good. Those of you who have been paying attention will have |
| 800 | spotted that the tied object hasn't been used so far. So lets add an |
| 801 | extra method to the Remember class to allow comments to be included in |
| 802 | the file -- say, something like this: |
| 803 | |
| 804 | sub comment { |
| 805 | my $self = shift; |
| 806 | my $text = shift; |
| 807 | my $handle = $self->{FH}; |
| 808 | print $handle $text, "\n"; |
| 809 | } |
| 810 | |
| 811 | And here is the previous example modified to use the C<comment> method |
| 812 | (which requires the tied object): |
| 813 | |
| 814 | use strict; |
| 815 | use Remember; |
| 816 | |
| 817 | my ($fred, $x); |
| 818 | $x = tie $fred, 'Remember', 'myfile.txt'; |
| 819 | $fred = 1; |
| 820 | $fred = 4; |
| 821 | comment $x "changing..."; |
| 822 | $fred = 5; |
| 823 | untie $fred; |
| 824 | system "cat myfile.txt"; |
| 825 | |
| 826 | When this code is executed there is no output. Here's why: |
| 827 | |
| 828 | When a variable is tied, it is associated with the object which is the |
| 829 | return value of the TIESCALAR, TIEARRAY, or TIEHASH function. This |
| 830 | object normally has only one reference, namely, the implicit reference |
| 831 | from the tied variable. When untie() is called, that reference is |
| 832 | destroyed. Then, as in the first example above, the object's |
| 833 | destructor (DESTROY) is called, which is normal for objects that have |
| 834 | no more valid references; and thus the file is closed. |
| 835 | |
| 836 | In the second example, however, we have stored another reference to |
| 837 | the tied object in $x. That means that when untie() gets called |
| 838 | there will still be a valid reference to the object in existence, so |
| 839 | the destructor is not called at that time, and thus the file is not |
| 840 | closed. The reason there is no output is because the file buffers |
| 841 | have not been flushed to disk. |
| 842 | |
| 843 | Now that you know what the problem is, what can you do to avoid it? |
| 844 | Well, the good old C<-w> flag will spot any instances where you call |
| 845 | untie() and there are still valid references to the tied object. If |
| 846 | the second script above is run with the C<-w> flag, Perl prints this |
| 847 | warning message: |
| 848 | |
| 849 | untie attempted while 1 inner references still exist |
| 850 | |
| 851 | To get the script to work properly and silence the warning make sure |
| 852 | there are no valid references to the tied object I<before> untie() is |
| 853 | called: |
| 854 | |
| 855 | undef $x; |
| 856 | untie $fred; |
| 857 | |
| 858 | =head1 SEE ALSO |
| 859 | |
| 860 | See L<DB_File> or L<Config> for some interesting tie() implementations. |
| 861 | |
| 862 | =head1 BUGS |
| 863 | |
| 864 | Tied arrays are I<incomplete>. They are also distinctly lacking something |
| 865 | for the C<$#ARRAY> access (which is hard, as it's an lvalue), as well as |
| 866 | the other obvious array functions, like push(), pop(), shift(), unshift(), |
| 867 | and splice(). |
| 868 | |
| 869 | You cannot easily tie a multilevel data structure (such as a hash of |
| 870 | hashes) to a dbm file. The first problem is that all but GDBM and |
| 871 | Berkeley DB have size limitations, but beyond that, you also have problems |
| 872 | with how references are to be represented on disk. One experimental |
| 873 | module that does attempt to address this need partially is the MLDBM |
| 874 | module. Check your nearest CPAN site as described in L<perlmodlib> for |
| 875 | source code to MLDBM. |
| 876 | |
| 877 | =head1 AUTHOR |
| 878 | |
| 879 | Tom Christiansen |
| 880 | |
| 881 | TIEHANDLE by Sven Verdoolaege <F<skimo@dns.ufsia.ac.be>> and Doug MacEachern <F<dougm@osf.org>> |