| 1 | =head1 NAME |
| 2 | |
| 3 | perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes |
| 4 | |
| 5 | =head1 DESCRIPTION |
| 6 | |
| 7 | The top level documentation about Perl regular expressions |
| 8 | is found in L<perlre>. |
| 9 | |
| 10 | This document describes all backslash and escape sequences. After |
| 11 | explaining the role of the backslash, it lists all the sequences that have |
| 12 | a special meaning in Perl regular expressions (in alphabetical order), |
| 13 | then describes each of them. |
| 14 | |
| 15 | Most sequences are described in detail in different documents; the primary |
| 16 | purpose of this document is to have a quick reference guide describing all |
| 17 | backslash and escape sequences. |
| 18 | |
| 19 | =head2 The backslash |
| 20 | |
| 21 | In a regular expression, the backslash can perform one of two tasks: |
| 22 | it either takes away the special meaning of the character following it |
| 23 | (for instance, C<\|> matches a vertical bar, it's not an alternation), |
| 24 | or it is the start of a backslash or escape sequence. |
| 25 | |
| 26 | The rules determining what it is are quite simple: if the character |
| 27 | following the backslash is an ASCII punctuation (non-word) character (that is, |
| 28 | anything that is not a letter, digit, or underscore), then the backslash just |
| 29 | takes away any special meaning of the character following it. |
| 30 | |
| 31 | If the character following the backslash is an ASCII letter or an ASCII digit, |
| 32 | then the sequence may be special; if so, it's listed below. A few letters have |
| 33 | not been used yet, so escaping them with a backslash doesn't change them to be |
| 34 | special. A future version of Perl may assign a special meaning to them, so if |
| 35 | you have warnings turned on, Perl issues a warning if you use such a |
| 36 | sequence. [1]. |
| 37 | |
| 38 | It is however guaranteed that backslash or escape sequences never have a |
| 39 | punctuation character following the backslash, not now, and not in a future |
| 40 | version of Perl 5. So it is safe to put a backslash in front of a non-word |
| 41 | character. |
| 42 | |
| 43 | Note that the backslash itself is special; if you want to match a backslash, |
| 44 | you have to escape the backslash with a backslash: C</\\/> matches a single |
| 45 | backslash. |
| 46 | |
| 47 | =over 4 |
| 48 | |
| 49 | =item [1] |
| 50 | |
| 51 | There is one exception. If you use an alphanumeric character as the |
| 52 | delimiter of your pattern (which you probably shouldn't do for readability |
| 53 | reasons), you have to escape the delimiter if you want to match |
| 54 | it. Perl won't warn then. See also L<perlop/Gory details of parsing |
| 55 | quoted constructs>. |
| 56 | |
| 57 | =back |
| 58 | |
| 59 | |
| 60 | =head2 All the sequences and escapes |
| 61 | |
| 62 | Those not usable within a bracketed character class (like C<[\da-z]>) are marked |
| 63 | as C<Not in [].> |
| 64 | |
| 65 | \000 Octal escape sequence. See also \o{}. |
| 66 | \1 Absolute backreference. Not in []. |
| 67 | \a Alarm or bell. |
| 68 | \A Beginning of string. Not in []. |
| 69 | \b{}, \b Boundary. (\b is a backspace in []). |
| 70 | \B{}, \B Not a boundary. Not in []. |
| 71 | \cX Control-X. |
| 72 | \d Match any digit character. |
| 73 | \D Match any character that isn't a digit. |
| 74 | \e Escape character. |
| 75 | \E Turn off \Q, \L and \U processing. Not in []. |
| 76 | \f Form feed. |
| 77 | \F Foldcase till \E. Not in []. |
| 78 | \g{}, \g1 Named, absolute or relative backreference. |
| 79 | Not in []. |
| 80 | \G Pos assertion. Not in []. |
| 81 | \h Match any horizontal whitespace character. |
| 82 | \H Match any character that isn't horizontal whitespace. |
| 83 | \k{}, \k<>, \k'' Named backreference. Not in []. |
| 84 | \K Keep the stuff left of \K. Not in []. |
| 85 | \l Lowercase next character. Not in []. |
| 86 | \L Lowercase till \E. Not in []. |
| 87 | \n (Logical) newline character. |
| 88 | \N Match any character but newline. Not in []. |
| 89 | \N{} Named or numbered (Unicode) character or sequence. |
| 90 | \o{} Octal escape sequence. |
| 91 | \p{}, \pP Match any character with the given Unicode property. |
| 92 | \P{}, \PP Match any character without the given property. |
| 93 | \Q Quote (disable) pattern metacharacters till \E. Not |
| 94 | in []. |
| 95 | \r Return character. |
| 96 | \R Generic new line. Not in []. |
| 97 | \s Match any whitespace character. |
| 98 | \S Match any character that isn't a whitespace. |
| 99 | \t Tab character. |
| 100 | \u Titlecase next character. Not in []. |
| 101 | \U Uppercase till \E. Not in []. |
| 102 | \v Match any vertical whitespace character. |
| 103 | \V Match any character that isn't vertical whitespace |
| 104 | \w Match any word character. |
| 105 | \W Match any character that isn't a word character. |
| 106 | \x{}, \x00 Hexadecimal escape sequence. |
| 107 | \X Unicode "extended grapheme cluster". Not in []. |
| 108 | \z End of string. Not in []. |
| 109 | \Z End of string. Not in []. |
| 110 | |
| 111 | =head2 Character Escapes |
| 112 | |
| 113 | =head3 Fixed characters |
| 114 | |
| 115 | A handful of characters have a dedicated I<character escape>. The following |
| 116 | table shows them, along with their ASCII code points (in decimal and hex), |
| 117 | their ASCII name, the control escape on ASCII platforms and a short |
| 118 | description. (For EBCDIC platforms, see L<perlebcdic/OPERATOR DIFFERENCES>.) |
| 119 | |
| 120 | Seq. Code Point ASCII Cntrl Description. |
| 121 | Dec Hex |
| 122 | \a 7 07 BEL \cG alarm or bell |
| 123 | \b 8 08 BS \cH backspace [1] |
| 124 | \e 27 1B ESC \c[ escape character |
| 125 | \f 12 0C FF \cL form feed |
| 126 | \n 10 0A LF \cJ line feed [2] |
| 127 | \r 13 0D CR \cM carriage return |
| 128 | \t 9 09 TAB \cI tab |
| 129 | |
| 130 | =over 4 |
| 131 | |
| 132 | =item [1] |
| 133 | |
| 134 | C<\b> is the backspace character only inside a character class. Outside a |
| 135 | character class, C<\b> alone is a word-character/non-word-character |
| 136 | boundary, and C<\b{}> is some other type of boundary. |
| 137 | |
| 138 | =item [2] |
| 139 | |
| 140 | C<\n> matches a logical newline. Perl converts between C<\n> and your |
| 141 | OS's native newline character when reading from or writing to text files. |
| 142 | |
| 143 | =back |
| 144 | |
| 145 | =head4 Example |
| 146 | |
| 147 | $str =~ /\t/; # Matches if $str contains a (horizontal) tab. |
| 148 | |
| 149 | =head3 Control characters |
| 150 | |
| 151 | C<\c> is used to denote a control character; the character following C<\c> |
| 152 | determines the value of the construct. For example the value of C<\cA> is |
| 153 | C<chr(1)>, and the value of C<\cb> is C<chr(2)>, etc. |
| 154 | The gory details are in L<perlop/"Regexp Quote-Like Operators">. A complete |
| 155 | list of what C<chr(1)>, etc. means for ASCII and EBCDIC platforms is in |
| 156 | L<perlebcdic/OPERATOR DIFFERENCES>. |
| 157 | |
| 158 | Note that C<\c\> alone at the end of a regular expression (or doubled-quoted |
| 159 | string) is not valid. The backslash must be followed by another character. |
| 160 | That is, C<\c\I<X>> means C<chr(28) . 'I<X>'> for all characters I<X>. |
| 161 | |
| 162 | To write platform-independent code, you must use C<\N{I<NAME>}> instead, like |
| 163 | C<\N{ESCAPE}> or C<\N{U+001B}>, see L<charnames>. |
| 164 | |
| 165 | Mnemonic: I<c>ontrol character. |
| 166 | |
| 167 | =head4 Example |
| 168 | |
| 169 | $str =~ /\cK/; # Matches if $str contains a vertical tab (control-K). |
| 170 | |
| 171 | =head3 Named or numbered characters and character sequences |
| 172 | |
| 173 | Unicode characters have a Unicode name and numeric code point (ordinal) |
| 174 | value. Use the |
| 175 | C<\N{}> construct to specify a character by either of these values. |
| 176 | Certain sequences of characters also have names. |
| 177 | |
| 178 | To specify by name, the name of the character or character sequence goes |
| 179 | between the curly braces. |
| 180 | |
| 181 | To specify a character by Unicode code point, use the form C<\N{U+I<code |
| 182 | point>}>, where I<code point> is a number in hexadecimal that gives the |
| 183 | code point that Unicode has assigned to the desired character. It is |
| 184 | customary but not required to use leading zeros to pad the number to 4 |
| 185 | digits. Thus C<\N{U+0041}> means C<LATIN CAPITAL LETTER A>, and you will |
| 186 | rarely see it written without the two leading zeros. C<\N{U+0041}> means |
| 187 | "A" even on EBCDIC machines (where the ordinal value of "A" is not 0x41). |
| 188 | |
| 189 | Blanks may freely be inserted adjacent to but within the braces |
| 190 | enclosing the name or code point. So S<C<\N{ U+0041 }>> is perfectly |
| 191 | legal. |
| 192 | |
| 193 | It is even possible to give your own names to characters and character |
| 194 | sequences by using the L<charnames> module. These custom names are |
| 195 | lexically scoped, and so a given code point may have different names |
| 196 | in different scopes. The name used is what is in effect at the time the |
| 197 | C<\N{}> is expanded. For patterns in double-quotish context, that means |
| 198 | at the time the pattern is parsed. But for patterns that are delimitted |
| 199 | by single quotes, the expansion is deferred until pattern compilation |
| 200 | time, which may very well have a different C<charnames> translator in |
| 201 | effect. |
| 202 | |
| 203 | (There is an expanded internal form that you may see in debug output: |
| 204 | C<\N{U+I<code point>.I<code point>...}>. |
| 205 | The C<...> means any number of these I<code point>s separated by dots. |
| 206 | This represents the sequence formed by the characters. This is an internal |
| 207 | form only, subject to change, and you should not try to use it yourself.) |
| 208 | |
| 209 | Mnemonic: I<N>amed character. |
| 210 | |
| 211 | Note that a character or character sequence expressed as a named |
| 212 | or numbered character is considered a character without special |
| 213 | meaning by the regex engine, and will match "as is". |
| 214 | |
| 215 | =head4 Example |
| 216 | |
| 217 | $str =~ /\N{THAI CHARACTER SO SO}/; # Matches the Thai SO SO character |
| 218 | |
| 219 | use charnames 'Cyrillic'; # Loads Cyrillic names. |
| 220 | $str =~ /\N{ZHE}\N{KA}/; # Match "ZHE" followed by "KA". |
| 221 | |
| 222 | =head3 Octal escapes |
| 223 | |
| 224 | There are two forms of octal escapes. Each is used to specify a character by |
| 225 | its code point specified in base 8. |
| 226 | |
| 227 | One form, available starting in Perl 5.14 looks like C<\o{...}>, where the dots |
| 228 | represent one or more octal digits. It can be used for any Unicode character. |
| 229 | |
| 230 | It was introduced to avoid the potential problems with the other form, |
| 231 | available in all Perls. That form consists of a backslash followed by three |
| 232 | octal digits. One problem with this form is that it can look exactly like an |
| 233 | old-style backreference (see |
| 234 | L</Disambiguation rules between old-style octal escapes and backreferences> |
| 235 | below.) You can avoid this by making the first of the three digits always a |
| 236 | zero, but that makes \077 the largest code point specifiable. |
| 237 | |
| 238 | In some contexts, a backslash followed by two or even one octal digits may be |
| 239 | interpreted as an octal escape, sometimes with a warning, and because of some |
| 240 | bugs, sometimes with surprising results. Also, if you are creating a regex |
| 241 | out of smaller snippets concatenated together, and you use fewer than three |
| 242 | digits, the beginning of one snippet may be interpreted as adding digits to the |
| 243 | ending of the snippet before it. See L</Absolute referencing> for more |
| 244 | discussion and examples of the snippet problem. |
| 245 | |
| 246 | Note that a character expressed as an octal escape is considered |
| 247 | a character without special meaning by the regex engine, and will match |
| 248 | "as is". |
| 249 | |
| 250 | To summarize, the C<\o{}> form is always safe to use, and the other form is |
| 251 | safe to use for code points through \077 when you use exactly three digits to |
| 252 | specify them. |
| 253 | |
| 254 | Mnemonic: I<0>ctal or I<o>ctal. |
| 255 | |
| 256 | =head4 Examples (assuming an ASCII platform) |
| 257 | |
| 258 | $str = "Perl"; |
| 259 | $str =~ /\o{120}/; # Match, "\120" is "P". |
| 260 | $str =~ /\120/; # Same. |
| 261 | $str =~ /\o{120}+/; # Match, "\120" is "P", |
| 262 | # it's repeated at least once. |
| 263 | $str =~ /\120+/; # Same. |
| 264 | $str =~ /P\053/; # No match, "\053" is "+" and taken literally. |
| 265 | /\o{23073}/ # Black foreground, white background smiling face. |
| 266 | /\o{4801234567}/ # Raises a warning, and yields chr(4). |
| 267 | /\o{ 400}/ # LATIN CAPITAL LETTER A WITH MACRON |
| 268 | /\o{ 400 }/ # Same. These show blanks are allowed adjacent to |
| 269 | # the braces |
| 270 | |
| 271 | =head4 Disambiguation rules between old-style octal escapes and backreferences |
| 272 | |
| 273 | Octal escapes of the C<\000> form outside of bracketed character classes |
| 274 | potentially clash with old-style backreferences (see L</Absolute referencing> |
| 275 | below). They both consist of a backslash followed by numbers. So Perl has to |
| 276 | use heuristics to determine whether it is a backreference or an octal escape. |
| 277 | Perl uses the following rules to disambiguate: |
| 278 | |
| 279 | =over 4 |
| 280 | |
| 281 | =item 1 |
| 282 | |
| 283 | If the backslash is followed by a single digit, it's a backreference. |
| 284 | |
| 285 | =item 2 |
| 286 | |
| 287 | If the first digit following the backslash is a 0, it's an octal escape. |
| 288 | |
| 289 | =item 3 |
| 290 | |
| 291 | If the number following the backslash is N (in decimal), and Perl already |
| 292 | has seen N capture groups, Perl considers this a backreference. Otherwise, |
| 293 | it considers it an octal escape. If N has more than three digits, Perl |
| 294 | takes only the first three for the octal escape; the rest are matched as is. |
| 295 | |
| 296 | my $pat = "(" x 999; |
| 297 | $pat .= "a"; |
| 298 | $pat .= ")" x 999; |
| 299 | /^($pat)\1000$/; # Matches 'aa'; there are 1000 capture groups. |
| 300 | /^$pat\1000$/; # Matches 'a@0'; there are 999 capture groups |
| 301 | # and \1000 is seen as \100 (a '@') and a '0'. |
| 302 | |
| 303 | =back |
| 304 | |
| 305 | You can force a backreference interpretation always by using the C<\g{...}> |
| 306 | form. You can the force an octal interpretation always by using the C<\o{...}> |
| 307 | form, or for numbers up through \077 (= 63 decimal), by using three digits, |
| 308 | beginning with a "0". |
| 309 | |
| 310 | =head3 Hexadecimal escapes |
| 311 | |
| 312 | Like octal escapes, there are two forms of hexadecimal escapes, but both start |
| 313 | with the sequence C<\x>. This is followed by either exactly two hexadecimal |
| 314 | digits forming a number, or a hexadecimal number of arbitrary length surrounded |
| 315 | by curly braces. The hexadecimal number is the code point of the character you |
| 316 | want to express. |
| 317 | |
| 318 | Note that a character expressed as one of these escapes is considered a |
| 319 | character without special meaning by the regex engine, and will match |
| 320 | "as is". |
| 321 | |
| 322 | Mnemonic: heI<x>adecimal. |
| 323 | |
| 324 | =head4 Examples (assuming an ASCII platform) |
| 325 | |
| 326 | $str = "Perl"; |
| 327 | $str =~ /\x50/; # Match, "\x50" is "P". |
| 328 | $str =~ /\x50+/; # Match, "\x50" is "P", it is repeated at least once |
| 329 | $str =~ /P\x2B/; # No match, "\x2B" is "+" and taken literally. |
| 330 | |
| 331 | /\x{2603}\x{2602}/ # Snowman with an umbrella. |
| 332 | # The Unicode character 2603 is a snowman, |
| 333 | # the Unicode character 2602 is an umbrella. |
| 334 | /\x{263B}/ # Black smiling face. |
| 335 | /\x{263b}/ # Same, the hex digits A - F are case insensitive. |
| 336 | /\x{ 263b }/ # Same, showing optional blanks adjacent to the |
| 337 | # braces |
| 338 | |
| 339 | =head2 Modifiers |
| 340 | |
| 341 | A number of backslash sequences have to do with changing the character, |
| 342 | or characters following them. C<\l> will lowercase the character following |
| 343 | it, while C<\u> will uppercase (or, more accurately, titlecase) the |
| 344 | character following it. They provide functionality similar to the |
| 345 | functions C<lcfirst> and C<ucfirst>. |
| 346 | |
| 347 | To uppercase or lowercase several characters, one might want to use |
| 348 | C<\L> or C<\U>, which will lowercase/uppercase all characters following |
| 349 | them, until either the end of the pattern or the next occurrence of |
| 350 | C<\E>, whichever comes first. They provide functionality similar to what |
| 351 | the functions C<lc> and C<uc> provide. |
| 352 | |
| 353 | C<\Q> is used to quote (disable) pattern metacharacters, up to the next |
| 354 | C<\E> or the end of the pattern. C<\Q> adds a backslash to any character |
| 355 | that could have special meaning to Perl. In the ASCII range, it quotes |
| 356 | every character that isn't a letter, digit, or underscore. See |
| 357 | L<perlfunc/quotemeta> for details on what gets quoted for non-ASCII |
| 358 | code points. Using this ensures that any character between C<\Q> and |
| 359 | C<\E> will be matched literally, not interpreted as a metacharacter by |
| 360 | the regex engine. |
| 361 | |
| 362 | C<\F> can be used to casefold all characters following, up to the next C<\E> |
| 363 | or the end of the pattern. It provides the functionality similar to |
| 364 | the C<fc> function. |
| 365 | |
| 366 | Mnemonic: I<L>owercase, I<U>ppercase, I<F>old-case, I<Q>uotemeta, I<E>nd. |
| 367 | |
| 368 | =head4 Examples |
| 369 | |
| 370 | $sid = "sid"; |
| 371 | $greg = "GrEg"; |
| 372 | $miranda = "(Miranda)"; |
| 373 | $str =~ /\u$sid/; # Matches 'Sid' |
| 374 | $str =~ /\L$greg/; # Matches 'greg' |
| 375 | $str =~ /\Q$miranda\E/; # Matches '(Miranda)', as if the pattern |
| 376 | # had been written as /\(Miranda\)/ |
| 377 | |
| 378 | =head2 Character classes |
| 379 | |
| 380 | Perl regular expressions have a large range of character classes. Some of |
| 381 | the character classes are written as a backslash sequence. We will briefly |
| 382 | discuss those here; full details of character classes can be found in |
| 383 | L<perlrecharclass>. |
| 384 | |
| 385 | C<\w> is a character class that matches any single I<word> character |
| 386 | (letters, digits, Unicode marks, and connector punctuation (like the |
| 387 | underscore)). C<\d> is a character class that matches any decimal |
| 388 | digit, while the character class C<\s> matches any whitespace character. |
| 389 | New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal |
| 390 | and vertical whitespace characters. |
| 391 | |
| 392 | The exact set of characters matched by C<\d>, C<\s>, and C<\w> varies |
| 393 | depending on various pragma and regular expression modifiers. It is |
| 394 | possible to restrict the match to the ASCII range by using the C</a> |
| 395 | regular expression modifier. See L<perlrecharclass>. |
| 396 | |
| 397 | The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are |
| 398 | character classes that match, respectively, any character that isn't a |
| 399 | word character, digit, whitespace, horizontal whitespace, or vertical |
| 400 | whitespace. |
| 401 | |
| 402 | Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical. |
| 403 | |
| 404 | =head3 Unicode classes |
| 405 | |
| 406 | C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to |
| 407 | match a character that matches the given Unicode property; properties |
| 408 | include things like "letter", or "thai character". Capitalizing the |
| 409 | sequence to C<\PP> and C<\P{Property}> make the sequence match a character |
| 410 | that doesn't match the given Unicode property. For more details, see |
| 411 | L<perlrecharclass/Backslash sequences> and |
| 412 | L<perlunicode/Unicode Character Properties>. |
| 413 | |
| 414 | Mnemonic: I<p>roperty. |
| 415 | |
| 416 | =head2 Referencing |
| 417 | |
| 418 | If capturing parenthesis are used in a regular expression, we can refer |
| 419 | to the part of the source string that was matched, and match exactly the |
| 420 | same thing. There are three ways of referring to such I<backreference>: |
| 421 | absolutely, relatively, and by name. |
| 422 | |
| 423 | =for later add link to perlrecapture |
| 424 | |
| 425 | =head3 Absolute referencing |
| 426 | |
| 427 | Either C<\gI<N>> (starting in Perl 5.10.0), or C<\I<N>> (old-style) where I<N> |
| 428 | is a positive (unsigned) decimal number of any length is an absolute reference |
| 429 | to a capturing group. |
| 430 | |
| 431 | I<N> refers to the Nth set of parentheses, so C<\gI<N>> refers to whatever has |
| 432 | been matched by that set of parentheses. Thus C<\g1> refers to the first |
| 433 | capture group in the regex. |
| 434 | |
| 435 | The C<\gI<N>> form can be equivalently written as C<\g{I<N>}> |
| 436 | which avoids ambiguity when building a regex by concatenating shorter |
| 437 | strings. Otherwise if you had a regex C<qr/$a$b/>, and C<$a> contained |
| 438 | C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which is |
| 439 | probably not what you intended. |
| 440 | |
| 441 | In the C<\I<N>> form, I<N> must not begin with a "0", and there must be at |
| 442 | least I<N> capturing groups, or else I<N> is considered an octal escape |
| 443 | (but something like C<\18> is the same as C<\0018>; that is, the octal escape |
| 444 | C<"\001"> followed by a literal digit C<"8">). |
| 445 | |
| 446 | Mnemonic: I<g>roup. |
| 447 | |
| 448 | =head4 Examples |
| 449 | |
| 450 | /(\w+) \g1/; # Finds a duplicated word, (e.g. "cat cat"). |
| 451 | /(\w+) \1/; # Same thing; written old-style. |
| 452 | /(\w+) \g{1}/; # Same, using the safer braced notation |
| 453 | /(\w+) \g{ 1 }/;# Same, showing optional blanks adjacent to the braces |
| 454 | /(.)(.)\g2\g1/; # Match a four letter palindrome (e.g. "ABBA"). |
| 455 | |
| 456 | |
| 457 | =head3 Relative referencing |
| 458 | |
| 459 | C<\g-I<N>> (starting in Perl 5.10.0) is used for relative addressing. (It can |
| 460 | be written as C<\g{-I<N>}>.) It refers to the I<N>th group before the |
| 461 | C<\g{-I<N>}>. |
| 462 | |
| 463 | The big advantage of this form is that it makes it much easier to write |
| 464 | patterns with references that can be interpolated in larger patterns, |
| 465 | even if the larger pattern also contains capture groups. |
| 466 | |
| 467 | =head4 Examples |
| 468 | |
| 469 | /(A) # Group 1 |
| 470 | ( # Group 2 |
| 471 | (B) # Group 3 |
| 472 | \g{-1} # Refers to group 3 (B) |
| 473 | \g{-3} # Refers to group 1 (A) |
| 474 | \g{ -3 } # Same, showing optional blanks adjacent to the braces |
| 475 | ) |
| 476 | /x; # Matches "ABBA". |
| 477 | |
| 478 | my $qr = qr /(.)(.)\g{-2}\g{-1}/; # Matches 'abab', 'cdcd', etc. |
| 479 | /$qr$qr/ # Matches 'ababcdcd'. |
| 480 | |
| 481 | =head3 Named referencing |
| 482 | |
| 483 | C<\g{I<name>}> (starting in Perl 5.10.0) can be used to back refer to a |
| 484 | named capture group, dispensing completely with having to think about capture |
| 485 | buffer positions. |
| 486 | |
| 487 | To be compatible with .Net regular expressions, C<\g{name}> may also be |
| 488 | written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>. |
| 489 | |
| 490 | To prevent any ambiguity, I<name> must not start with a digit nor contain a |
| 491 | hyphen. |
| 492 | |
| 493 | =head4 Examples |
| 494 | |
| 495 | /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat") |
| 496 | /(?<word>\w+) \k{word}/ # Same. |
| 497 | /(?<word>\w+) \g{ word }/ # Same, showing optional blanks adjacent to |
| 498 | # the braces |
| 499 | /(?<word>\w+) \k{ word }/ # Same. |
| 500 | /(?<word>\w+) \k<word>/ # Same. There are no braces, so no blanks |
| 501 | # are permitted |
| 502 | /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/ |
| 503 | # Match a four letter palindrome (e.g. |
| 504 | # "ABBA") |
| 505 | |
| 506 | =head2 Assertions |
| 507 | |
| 508 | Assertions are conditions that have to be true; they don't actually |
| 509 | match parts of the substring. There are six assertions that are written as |
| 510 | backslash sequences. |
| 511 | |
| 512 | =over 4 |
| 513 | |
| 514 | =item \A |
| 515 | |
| 516 | C<\A> only matches at the beginning of the string. If the C</m> modifier |
| 517 | isn't used, then C</\A/> is equivalent to C</^/>. However, if the C</m> |
| 518 | modifier is used, then C</^/> matches internal newlines, but the meaning |
| 519 | of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning |
| 520 | of the string regardless whether the C</m> modifier is used. |
| 521 | |
| 522 | =item \z, \Z |
| 523 | |
| 524 | C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't |
| 525 | used, then C</\Z/> is equivalent to C</$/>; that is, it matches at the |
| 526 | end of the string, or one before the newline at the end of the string. If the |
| 527 | C</m> modifier is used, then C</$/> matches at internal newlines, but the |
| 528 | meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at |
| 529 | the end of the string (or just before a trailing newline) regardless whether |
| 530 | the C</m> modifier is used. |
| 531 | |
| 532 | C<\z> is just like C<\Z>, except that it does not match before a trailing |
| 533 | newline. C<\z> matches at the end of the string only, regardless of the |
| 534 | modifiers used, and not just before a newline. It is how to anchor the |
| 535 | match to the true end of the string under all conditions. |
| 536 | |
| 537 | =item \G |
| 538 | |
| 539 | C<\G> is usually used only in combination with the C</g> modifier. If the |
| 540 | C</g> modifier is used and the match is done in scalar context, Perl |
| 541 | remembers where in the source string the last match ended, and the next time, |
| 542 | it will start the match from where it ended the previous time. |
| 543 | |
| 544 | C<\G> matches the point where the previous match on that string ended, |
| 545 | or the beginning of that string if there was no previous match. |
| 546 | |
| 547 | =for later add link to perlremodifiers |
| 548 | |
| 549 | Mnemonic: I<G>lobal. |
| 550 | |
| 551 | =item \b{}, \b, \B{}, \B |
| 552 | |
| 553 | C<\b{...}>, available starting in v5.22, matches a boundary (between two |
| 554 | characters, or before the first character of the string, or after the |
| 555 | final character of the string) based on the Unicode rules for the |
| 556 | boundary type specified inside the braces. The boundary |
| 557 | types are given a few paragraphs below. C<\B{...}> matches at any place |
| 558 | between characters where C<\b{...}> of the same type doesn't match. |
| 559 | |
| 560 | C<\b> when not immediately followed by a C<"{"> is available in all |
| 561 | Perls. It matches at any place |
| 562 | between a word (something matched by C<\w>) and a non-word character |
| 563 | (C<\W>); C<\B> when not immediately followed by a C<"{"> matches at any |
| 564 | place between characters where C<\b> doesn't match. To get better |
| 565 | word matching of natural language text, see L</\b{wb}> below. |
| 566 | |
| 567 | C<\b> |
| 568 | and C<\B> assume there's a non-word character before the beginning and after |
| 569 | the end of the source string; so C<\b> will match at the beginning (or end) |
| 570 | of the source string if the source string begins (or ends) with a word |
| 571 | character. Otherwise, C<\B> will match. |
| 572 | |
| 573 | Do not use something like C<\b=head\d\b> and expect it to match the |
| 574 | beginning of a line. It can't, because for there to be a boundary before |
| 575 | the non-word "=", there must be a word character immediately previous. |
| 576 | All plain C<\b> and C<\B> boundary determinations look for word |
| 577 | characters alone, not for |
| 578 | non-word characters nor for string ends. It may help to understand how |
| 579 | C<\b> and C<\B> work by equating them as follows: |
| 580 | |
| 581 | \b really means (?:(?<=\w)(?!\w)|(?<!\w)(?=\w)) |
| 582 | \B really means (?:(?<=\w)(?=\w)|(?<!\w)(?!\w)) |
| 583 | |
| 584 | In contrast, C<\b{...}> and C<\B{...}> may or may not match at the |
| 585 | beginning and end of the line, depending on the boundary type. These |
| 586 | implement the Unicode default boundaries, specified in |
| 587 | L<https://www.unicode.org/reports/tr14/> and |
| 588 | L<https://www.unicode.org/reports/tr29/>. |
| 589 | The boundary types are: |
| 590 | |
| 591 | =over |
| 592 | |
| 593 | =item C<\b{gcb}> or C<\b{g}> |
| 594 | |
| 595 | This matches a Unicode "Grapheme Cluster Boundary". (Actually Perl |
| 596 | always uses the improved "extended" grapheme cluster"). These are |
| 597 | explained below under C<L</\X>>. In fact, C<\X> is another way to get |
| 598 | the same functionality. It is equivalent to C</.+?\b{gcb}/>. Use |
| 599 | whichever is most convenient for your situation. |
| 600 | |
| 601 | =item C<\b{lb}> |
| 602 | |
| 603 | This matches according to the default Unicode Line Breaking Algorithm |
| 604 | (L<https://www.unicode.org/reports/tr14/>), as customized in that |
| 605 | document |
| 606 | (L<Example 7 of revision 35|https://www.unicode.org/reports/tr14/tr14-35.html#Example7>) |
| 607 | for better handling of numeric expressions. |
| 608 | |
| 609 | This is suitable for many purposes, but the L<Unicode::LineBreak> module |
| 610 | is available on CPAN that provides many more features, including |
| 611 | customization. |
| 612 | |
| 613 | =item C<\b{sb}> |
| 614 | |
| 615 | This matches a Unicode "Sentence Boundary". This is an aid to parsing |
| 616 | natural language sentences. It gives good, but imperfect results. For |
| 617 | example, it thinks that "Mr. Smith" is two sentences. More details are |
| 618 | at L<https://www.unicode.org/reports/tr29/>. Note also that it thinks |
| 619 | that anything matching L</\R> (except form feed and vertical tab) is a |
| 620 | sentence boundary. C<\b{sb}> works with text designed for |
| 621 | word-processors which wrap lines |
| 622 | automatically for display, but hard-coded line boundaries are considered |
| 623 | to be essentially the ends of text blocks (paragraphs really), and hence |
| 624 | the ends of sentences. C<\b{sb}> doesn't do well with text containing |
| 625 | embedded newlines, like the source text of the document you are reading. |
| 626 | Such text needs to be preprocessed to get rid of the line separators |
| 627 | before looking for sentence boundaries. Some people view this as a bug |
| 628 | in the Unicode standard, and this behavior is quite subject to change in |
| 629 | future Perl versions. |
| 630 | |
| 631 | =item C<\b{wb}> |
| 632 | |
| 633 | This matches a Unicode "Word Boundary", but tailored to Perl |
| 634 | expectations. This gives better (though not |
| 635 | perfect) results for natural language processing than plain C<\b> |
| 636 | (without braces) does. For example, it understands that apostrophes can |
| 637 | be in the middle of words and that parentheses aren't (see the examples |
| 638 | below). More details are at L<https://www.unicode.org/reports/tr29/>. |
| 639 | |
| 640 | The current Unicode definition of a Word Boundary matches between every |
| 641 | white space character. Perl tailors this, starting in version 5.24, to |
| 642 | generally not break up spans of white space, just as plain C<\b> has |
| 643 | always functioned. This allows C<\b{wb}> to be a drop-in replacement for |
| 644 | C<\b>, but with generally better results for natural language |
| 645 | processing. (The exception to this tailoring is when a span of white |
| 646 | space is immediately followed by something like U+0303, COMBINING TILDE. |
| 647 | If the final space character in the span is a horizontal white space, it |
| 648 | is broken out so that it attaches instead to the combining character. |
| 649 | To be precise, if a span of white space that ends in a horizontal space |
| 650 | has the character immediately following it have any of the Word |
| 651 | Boundary property values "Extend", "Format" or "ZWJ", the boundary between the |
| 652 | final horizontal space character and the rest of the span matches |
| 653 | C<\b{wb}>. In all other cases the boundary between two white space |
| 654 | characters matches C<\B{wb}>.) |
| 655 | |
| 656 | =back |
| 657 | |
| 658 | It is important to realize when you use these Unicode boundaries, |
| 659 | that you are taking a risk that a future version of Perl which contains |
| 660 | a later version of the Unicode Standard will not work precisely the same |
| 661 | way as it did when your code was written. These rules are not |
| 662 | considered stable and have been somewhat more subject to change than the |
| 663 | rest of the Standard. Unicode reserves the right to change them at |
| 664 | will, and Perl reserves the right to update its implementation to |
| 665 | Unicode's new rules. In the past, some changes have been because new |
| 666 | characters have been added to the Standard which have different |
| 667 | characteristics than all previous characters, so new rules are |
| 668 | formulated for handling them. These should not cause any backward |
| 669 | compatibility issues. But some changes have changed the treatment of |
| 670 | existing characters because the Unicode Technical Committee has decided |
| 671 | that the change is warranted for whatever reason. This could be to fix |
| 672 | a bug, or because they think better results are obtained with the new |
| 673 | rule. |
| 674 | |
| 675 | It is also important to realize that these are default boundary |
| 676 | definitions, and that implementations may wish to tailor the results for |
| 677 | particular purposes and locales. For example, some languages, such as |
| 678 | Japanese and Thai, require dictionary lookup to accurately determine |
| 679 | word boundaries. |
| 680 | |
| 681 | Mnemonic: I<b>oundary. |
| 682 | |
| 683 | =back |
| 684 | |
| 685 | =head4 Examples |
| 686 | |
| 687 | "cat" =~ /\Acat/; # Match. |
| 688 | "cat" =~ /cat\Z/; # Match. |
| 689 | "cat\n" =~ /cat\Z/; # Match. |
| 690 | "cat\n" =~ /cat\z/; # No match. |
| 691 | |
| 692 | "cat" =~ /\bcat\b/; # Matches. |
| 693 | "cats" =~ /\bcat\b/; # No match. |
| 694 | "cat" =~ /\bcat\B/; # No match. |
| 695 | "cats" =~ /\bcat\B/; # Match. |
| 696 | |
| 697 | while ("cat dog" =~ /(\w+)/g) { |
| 698 | print $1; # Prints 'catdog' |
| 699 | } |
| 700 | while ("cat dog" =~ /\G(\w+)/g) { |
| 701 | print $1; # Prints 'cat' |
| 702 | } |
| 703 | |
| 704 | my $s = "He said, \"Is pi 3.14? (I'm not sure).\""; |
| 705 | print join("|", $s =~ m/ ( .+? \b ) /xg), "\n"; |
| 706 | print join("|", $s =~ m/ ( .+? \b{wb} ) /xg), "\n"; |
| 707 | prints |
| 708 | He| |said|, "|Is| |pi| |3|.|14|? (|I|'|m| |not| |sure |
| 709 | He| |said|,| |"|Is| |pi| |3.14|?| |(|I'm| |not| |sure|)|.|" |
| 710 | |
| 711 | =head2 Misc |
| 712 | |
| 713 | Here we document the backslash sequences that don't fall in one of the |
| 714 | categories above. These are: |
| 715 | |
| 716 | =over 4 |
| 717 | |
| 718 | =item \K |
| 719 | |
| 720 | This appeared in perl 5.10.0. Anything matched left of C<\K> is |
| 721 | not included in C<$&>, and will not be replaced if the pattern is |
| 722 | used in a substitution. This lets you write C<s/PAT1 \K PAT2/REPL/x> |
| 723 | instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>. |
| 724 | |
| 725 | Mnemonic: I<K>eep. |
| 726 | |
| 727 | =item \N |
| 728 | |
| 729 | This feature, available starting in v5.12, matches any character |
| 730 | that is B<not> a newline. It is a short-hand for writing C<[^\n]>, and is |
| 731 | identical to the C<.> metasymbol, except under the C</s> flag, which changes |
| 732 | the meaning of C<.>, but not C<\N>. |
| 733 | |
| 734 | Note that C<\N{...}> can mean a |
| 735 | L<named or numbered character |
| 736 | |/Named or numbered characters and character sequences>. |
| 737 | |
| 738 | Mnemonic: Complement of I<\n>. |
| 739 | |
| 740 | =item \R |
| 741 | X<\R> |
| 742 | |
| 743 | C<\R> matches a I<generic newline>; that is, anything considered a |
| 744 | linebreak sequence by Unicode. This includes all characters matched by |
| 745 | C<\v> (vertical whitespace), and the multi character sequence C<"\x0D\x0A"> |
| 746 | (carriage return followed by a line feed, sometimes called the network |
| 747 | newline; it's the end of line sequence used in Microsoft text files opened |
| 748 | in binary mode). C<\R> is equivalent to C<< (?>\x0D\x0A|\v) >>. (The |
| 749 | reason it doesn't backtrack is that the sequence is considered |
| 750 | inseparable. That means that |
| 751 | |
| 752 | "\x0D\x0A" =~ /^\R\x0A$/ # No match |
| 753 | |
| 754 | fails, because the C<\R> matches the entire string, and won't backtrack |
| 755 | to match just the C<"\x0D">.) Since |
| 756 | C<\R> can match a sequence of more than one character, it cannot be put |
| 757 | inside a bracketed character class; C</[\R]/> is an error; use C<\v> |
| 758 | instead. C<\R> was introduced in perl 5.10.0. |
| 759 | |
| 760 | Note that this does not respect any locale that might be in effect; it |
| 761 | matches according to the platform's native character set. |
| 762 | |
| 763 | Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>, |
| 764 | and more importantly because Unicode recommends such a regular expression |
| 765 | metacharacter, and suggests C<\R> as its notation. |
| 766 | |
| 767 | =item \X |
| 768 | X<\X> |
| 769 | |
| 770 | This matches a Unicode I<extended grapheme cluster>. |
| 771 | |
| 772 | C<\X> matches quite well what normal (non-Unicode-programmer) usage |
| 773 | would consider a single character. As an example, consider a G with some sort |
| 774 | of diacritic mark, such as an arrow. There is no such single character in |
| 775 | Unicode, but one can be composed by using a G followed by a Unicode "COMBINING |
| 776 | UPWARDS ARROW BELOW", and would be displayed by Unicode-aware software as if it |
| 777 | were a single character. |
| 778 | |
| 779 | The match is greedy and non-backtracking, so that the cluster is never |
| 780 | broken up into smaller components. |
| 781 | |
| 782 | See also L<C<\b{gcb}>|/\b{}, \b, \B{}, \B>. |
| 783 | |
| 784 | Mnemonic: eI<X>tended Unicode character. |
| 785 | |
| 786 | =back |
| 787 | |
| 788 | =head4 Examples |
| 789 | |
| 790 | $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz' |
| 791 | $str =~ s/(.)\K\g1//g; # Delete duplicated characters. |
| 792 | |
| 793 | "\n" =~ /^\R$/; # Match, \n is a generic newline. |
| 794 | "\r" =~ /^\R$/; # Match, \r is a generic newline. |
| 795 | "\r\n" =~ /^\R$/; # Match, \r\n is a generic newline. |
| 796 | |
| 797 | "P\x{307}" =~ /^\X$/ # \X matches a P with a dot above. |
| 798 | |
| 799 | =cut |