| 1 | =head1 NAME |
| 2 | |
| 3 | perldata - Perl data types |
| 4 | |
| 5 | =head1 DESCRIPTION |
| 6 | |
| 7 | =head2 Variable names |
| 8 | |
| 9 | Perl has three built-in data types: scalars, arrays of scalars, and |
| 10 | associative arrays of scalars, known as "hashes". Normal arrays |
| 11 | are ordered lists of scalars indexed by number, starting with 0 and with |
| 12 | negative subscripts counting from the end. Hashes are unordered |
| 13 | collections of scalar values indexed by their associated string key. |
| 14 | |
| 15 | Values are usually referred to by name, or through a named reference. |
| 16 | The first character of the name tells you to what sort of data |
| 17 | structure it refers. The rest of the name tells you the particular |
| 18 | value to which it refers. Usually this name is a single I<identifier>, |
| 19 | that is, a string beginning with a letter or underscore, and |
| 20 | containing letters, underscores, and digits. In some cases, it may |
| 21 | be a chain of identifiers, separated by C<::> (or by the slightly |
| 22 | archaic C<'>); all but the last are interpreted as names of packages, |
| 23 | to locate the namespace in which to look up the final identifier |
| 24 | (see L<perlmod/Packages> for details). It's possible to substitute |
| 25 | for a simple identifier, an expression that produces a reference |
| 26 | to the value at runtime. This is described in more detail below |
| 27 | and in L<perlref>. |
| 28 | |
| 29 | Perl also has its own built-in variables whose names don't follow |
| 30 | these rules. They have strange names so they don't accidentally |
| 31 | collide with one of your normal variables. Strings that match |
| 32 | parenthesized parts of a regular expression are saved under names |
| 33 | containing only digits after the C<$> (see L<perlop> and L<perlre>). |
| 34 | In addition, several special variables that provide windows into |
| 35 | the inner working of Perl have names containing punctuation characters |
| 36 | and control characters. These are documented in L<perlvar>. |
| 37 | |
| 38 | Scalar values are always named with '$', even when referring to a |
| 39 | scalar that is part of an array or a hash. The '$' symbol works |
| 40 | semantically like the English word "the" in that it indicates a |
| 41 | single value is expected. |
| 42 | |
| 43 | $days # the simple scalar value "days" |
| 44 | $days[28] # the 29th element of array @days |
| 45 | $days{'Feb'} # the 'Feb' value from hash %days |
| 46 | $#days # the last index of array @days |
| 47 | |
| 48 | Entire arrays (and slices of arrays and hashes) are denoted by '@', |
| 49 | which works much like the word "these" or "those" does in English, |
| 50 | in that it indicates multiple values are expected. |
| 51 | |
| 52 | @days # ($days[0], $days[1],... $days[n]) |
| 53 | @days[3,4,5] # same as ($days[3],$days[4],$days[5]) |
| 54 | @days{'a','c'} # same as ($days{'a'},$days{'c'}) |
| 55 | |
| 56 | Entire hashes are denoted by '%': |
| 57 | |
| 58 | %days # (key1, val1, key2, val2 ...) |
| 59 | |
| 60 | In addition, subroutines are named with an initial '&', though this |
| 61 | is optional when unambiguous, just as the word "do" is often redundant |
| 62 | in English. Symbol table entries can be named with an initial '*', |
| 63 | but you don't really care about that yet (if ever :-). |
| 64 | |
| 65 | Every variable type has its own namespace, as do several |
| 66 | non-variable identifiers. This means that you can, without fear |
| 67 | of conflict, use the same name for a scalar variable, an array, or |
| 68 | a hash--or, for that matter, for a filehandle, a directory handle, a |
| 69 | subroutine name, a format name, or a label. This means that $foo |
| 70 | and @foo are two different variables. It also means that C<$foo[1]> |
| 71 | is a part of @foo, not a part of $foo. This may seem a bit weird, |
| 72 | but that's okay, because it is weird. |
| 73 | |
| 74 | Because variable references always start with '$', '@', or '%', the |
| 75 | "reserved" words aren't in fact reserved with respect to variable |
| 76 | names. They I<are> reserved with respect to labels and filehandles, |
| 77 | however, which don't have an initial special character. You can't |
| 78 | have a filehandle named "log", for instance. Hint: you could say |
| 79 | C<open(LOG,'logfile')> rather than C<open(log,'logfile')>. Using |
| 80 | uppercase filehandles also improves readability and protects you |
| 81 | from conflict with future reserved words. Case I<is> significant--"FOO", |
| 82 | "Foo", and "foo" are all different names. Names that start with a |
| 83 | letter or underscore may also contain digits and underscores. |
| 84 | |
| 85 | It is possible to replace such an alphanumeric name with an expression |
| 86 | that returns a reference to the appropriate type. For a description |
| 87 | of this, see L<perlref>. |
| 88 | |
| 89 | Names that start with a digit may contain only more digits. Names |
| 90 | that do not start with a letter, underscore, or digit are limited to |
| 91 | one character, e.g., C<$%> or C<$$>. (Most of these one character names |
| 92 | have a predefined significance to Perl. For instance, C<$$> is the |
| 93 | current process id.) |
| 94 | |
| 95 | =head2 Context |
| 96 | |
| 97 | The interpretation of operations and values in Perl sometimes depends |
| 98 | on the requirements of the context around the operation or value. |
| 99 | There are two major contexts: list and scalar. Certain operations |
| 100 | return list values in contexts wanting a list, and scalar values |
| 101 | otherwise. If this is true of an operation it will be mentioned in |
| 102 | the documentation for that operation. In other words, Perl overloads |
| 103 | certain operations based on whether the expected return value is |
| 104 | singular or plural. Some words in English work this way, like "fish" |
| 105 | and "sheep". |
| 106 | |
| 107 | In a reciprocal fashion, an operation provides either a scalar or a |
| 108 | list context to each of its arguments. For example, if you say |
| 109 | |
| 110 | int( <STDIN> ) |
| 111 | |
| 112 | the integer operation provides scalar context for the E<lt><gt> |
| 113 | operator, which responds by reading one line from STDIN and passing it |
| 114 | back to the integer operation, which will then find the integer value |
| 115 | of that line and return that. If, on the other hand, you say |
| 116 | |
| 117 | sort( <STDIN> ) |
| 118 | |
| 119 | then the sort operation provides list context for E<lt><gt>, which |
| 120 | will proceed to read every line available up to the end of file, and |
| 121 | pass that list of lines back to the sort routine, which will then |
| 122 | sort those lines and return them as a list to whatever the context |
| 123 | of the sort was. |
| 124 | |
| 125 | Assignment is a little bit special in that it uses its left argument |
| 126 | to determine the context for the right argument. Assignment to a |
| 127 | scalar evaluates the right-hand side in scalar context, while |
| 128 | assignment to an array or hash evaluates the righthand side in list |
| 129 | context. Assignment to a list (or slice, which is just a list |
| 130 | anyway) also evaluates the righthand side in list context. |
| 131 | |
| 132 | When you use Perl's B<-w> command-line option, you may see warnings |
| 133 | about useless uses of constants or functions in "void context". |
| 134 | Void context just means the value has been discarded, such as a |
| 135 | statement containing only C<"fred";> or C<getpwuid(0);>. It still |
| 136 | counts as scalar context for functions that care whether or not |
| 137 | they're being called in list context. |
| 138 | |
| 139 | User-defined subroutines may choose to care whether they are being |
| 140 | called in a void, scalar, or list context. Most subroutines do not |
| 141 | need to bother, though. That's because both scalars and lists are |
| 142 | automatically interpolated into lists. See L<perlfunc/wantarray> |
| 143 | for how you would dynamically discern your function's calling |
| 144 | context. |
| 145 | |
| 146 | =head2 Scalar values |
| 147 | |
| 148 | All data in Perl is a scalar, an array of scalars, or a hash of |
| 149 | scalars. A scalar may contain one single value in any of three |
| 150 | different flavors: a number, a string, or a reference. In general, |
| 151 | conversion from one form to another is transparent. Although a |
| 152 | scalar may not directly hold multiple values, it may contain a |
| 153 | reference to an array or hash which in turn contains multiple values. |
| 154 | |
| 155 | Scalars aren't necessarily one thing or another. There's no place |
| 156 | to declare a scalar variable to be of type "string", type "number", |
| 157 | type "reference", or anything else. Because of the automatic |
| 158 | conversion of scalars, operations that return scalars don't need |
| 159 | to care (and in fact, cannot care) whether their caller is looking |
| 160 | for a string, a number, or a reference. Perl is a contextually |
| 161 | polymorphic language whose scalars can be strings, numbers, or |
| 162 | references (which includes objects). Although strings and numbers |
| 163 | are considered pretty much the same thing for nearly all purposes, |
| 164 | references are strongly-typed, uncastable pointers with builtin |
| 165 | reference-counting and destructor invocation. |
| 166 | |
| 167 | A scalar value is interpreted as TRUE in the Boolean sense if it is not |
| 168 | the null string or the number 0 (or its string equivalent, "0"). The |
| 169 | Boolean context is just a special kind of scalar context where no |
| 170 | conversion to a string or a number is ever performed. |
| 171 | |
| 172 | There are actually two varieties of null strings (sometimes referred |
| 173 | to as "empty" strings), a defined one and an undefined one. The |
| 174 | defined version is just a string of length zero, such as C<"">. |
| 175 | The undefined version is the value that indicates that there is |
| 176 | no real value for something, such as when there was an error, or |
| 177 | at end of file, or when you refer to an uninitialized variable or |
| 178 | element of an array or hash. Although in early versions of Perl, |
| 179 | an undefined scalar could become defined when first used in a |
| 180 | place expecting a defined value, this no longer happens except for |
| 181 | rare cases of autovivification as explained in L<perlref>. You can |
| 182 | use the defined() operator to determine whether a scalar value is |
| 183 | defined (this has no meaning on arrays or hashes), and the undef() |
| 184 | operator to produce an undefined value. |
| 185 | |
| 186 | To find out whether a given string is a valid non-zero number, it's |
| 187 | sometimes enough to test it against both numeric 0 and also lexical |
| 188 | "0" (although this will cause B<-w> noises). That's because strings |
| 189 | that aren't numbers count as 0, just as they do in B<awk>: |
| 190 | |
| 191 | if ($str == 0 && $str ne "0") { |
| 192 | warn "That doesn't look like a number"; |
| 193 | } |
| 194 | |
| 195 | That method may be best because otherwise you won't treat IEEE |
| 196 | notations like C<NaN> or C<Infinity> properly. At other times, you |
| 197 | might prefer to determine whether string data can be used numerically |
| 198 | by calling the POSIX::strtod() function or by inspecting your string |
| 199 | with a regular expression (as documented in L<perlre>). |
| 200 | |
| 201 | warn "has nondigits" if /\D/; |
| 202 | warn "not a natural number" unless /^\d+$/; # rejects -3 |
| 203 | warn "not an integer" unless /^-?\d+$/; # rejects +3 |
| 204 | warn "not an integer" unless /^[+-]?\d+$/; |
| 205 | warn "not a decimal number" unless /^-?\d+\.?\d*$/; # rejects .2 |
| 206 | warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/; |
| 207 | warn "not a C float" |
| 208 | unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/; |
| 209 | |
| 210 | The length of an array is a scalar value. You may find the length |
| 211 | of array @days by evaluating C<$#days>, as in B<csh>. Technically |
| 212 | speaking, this isn't the length of the array; it's the subscript |
| 213 | of the last element, since there is ordinarily a 0th element. |
| 214 | Assigning to C<$#days> actually changes the length of the array. |
| 215 | Shortening an array this way destroys intervening values. Lengthening |
| 216 | an array that was previously shortened does not recover values |
| 217 | that were in those elements. (It used to do so in Perl 4, but we |
| 218 | had to break this to make sure destructors were called when expected.) |
| 219 | |
| 220 | You can also gain some miniscule measure of efficiency by pre-extending |
| 221 | an array that is going to get big. You can also extend an array |
| 222 | by assigning to an element that is off the end of the array. You |
| 223 | can truncate an array down to nothing by assigning the null list |
| 224 | () to it. The following are equivalent: |
| 225 | |
| 226 | @whatever = (); |
| 227 | $#whatever = -1; |
| 228 | |
| 229 | If you evaluate an array in scalar context, it returns the length |
| 230 | of the array. (Note that this is not true of lists, which return |
| 231 | the last value, like the C comma operator, nor of built-in functions, |
| 232 | which return whatever they feel like returning.) The following is |
| 233 | always true: |
| 234 | |
| 235 | scalar(@whatever) == $#whatever - $[ + 1; |
| 236 | |
| 237 | Version 5 of Perl changed the semantics of C<$[>: files that don't set |
| 238 | the value of C<$[> no longer need to worry about whether another |
| 239 | file changed its value. (In other words, use of C<$[> is deprecated.) |
| 240 | So in general you can assume that |
| 241 | |
| 242 | scalar(@whatever) == $#whatever + 1; |
| 243 | |
| 244 | Some programmers choose to use an explicit conversion so as to |
| 245 | leave nothing to doubt: |
| 246 | |
| 247 | $element_count = scalar(@whatever); |
| 248 | |
| 249 | If you evaluate a hash in scalar context, it returns false if the |
| 250 | hash is empty. If there are any key/value pairs, it returns true; |
| 251 | more precisely, the value returned is a string consisting of the |
| 252 | number of used buckets and the number of allocated buckets, separated |
| 253 | by a slash. This is pretty much useful only to find out whether |
| 254 | Perl's internal hashing algorithm is performing poorly on your data |
| 255 | set. For example, you stick 10,000 things in a hash, but evaluating |
| 256 | %HASH in scalar context reveals C<"1/16">, which means only one out |
| 257 | of sixteen buckets has been touched, and presumably contains all |
| 258 | 10,000 of your items. This isn't supposed to happen. |
| 259 | |
| 260 | You can preallocate space for a hash by assigning to the keys() function. |
| 261 | This rounds up the allocated bucked to the next power of two: |
| 262 | |
| 263 | keys(%users) = 1000; # allocate 1024 buckets |
| 264 | |
| 265 | =head2 Scalar value constructors |
| 266 | |
| 267 | Numeric literals are specified in any of the following floating point or |
| 268 | integer formats: |
| 269 | |
| 270 | 12345 |
| 271 | 12345.67 |
| 272 | .23E-10 # a very small number |
| 273 | 4_294_967_296 # underline for legibility |
| 274 | 0xff # hex |
| 275 | 0377 # octal |
| 276 | 0b011011 # binary |
| 277 | |
| 278 | String literals are usually delimited by either single or double |
| 279 | quotes. They work much like quotes in the standard Unix shells: |
| 280 | double-quoted string literals are subject to backslash and variable |
| 281 | substitution; single-quoted strings are not (except for C<\'> and |
| 282 | C<\\>). The usual C-style backslash rules apply for making |
| 283 | characters such as newline, tab, etc., as well as some more exotic |
| 284 | forms. See L<perlop/"Quote and Quotelike Operators"> for a list. |
| 285 | |
| 286 | Hexadecimal, octal, or binary, representations in string literals |
| 287 | (e.g. '0xff') are not automatically converted to their integer |
| 288 | representation. The hex() and oct() functions make these conversions |
| 289 | for you. See L<perlfunc/hex> and L<perlfunc/oct> for more details. |
| 290 | |
| 291 | You can also embed newlines directly in your strings, i.e., they can end |
| 292 | on a different line than they begin. This is nice, but if you forget |
| 293 | your trailing quote, the error will not be reported until Perl finds |
| 294 | another line containing the quote character, which may be much further |
| 295 | on in the script. Variable substitution inside strings is limited to |
| 296 | scalar variables, arrays, and array or hash slices. (In other words, |
| 297 | names beginning with $ or @, followed by an optional bracketed |
| 298 | expression as a subscript.) The following code segment prints out "The |
| 299 | price is $Z<>100." |
| 300 | |
| 301 | $Price = '$100'; # not interpreted |
| 302 | print "The price is $Price.\n"; # interpreted |
| 303 | |
| 304 | As in some shells, you can enclose the variable name in braces to |
| 305 | disambiguate it from following alphanumerics. You must also do |
| 306 | this when interpolating a variable into a string to separate the |
| 307 | variable name from a following double-colon or an apostrophe, since |
| 308 | these would be otherwise treated as a package separator: |
| 309 | |
| 310 | $who = "Larry"; |
| 311 | print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n"; |
| 312 | print "We use ${who}speak when ${who}'s here.\n"; |
| 313 | |
| 314 | Without the braces, Perl would have looked for a $whospeak, a |
| 315 | C<$who::0>, and a C<$who's> variable. The last two would be the |
| 316 | $0 and the $s variables in the (presumably) non-existent package |
| 317 | C<who>. |
| 318 | |
| 319 | In fact, an identifier within such curlies is forced to be a string, |
| 320 | as is any simple identifier within a hash subscript. Neither need |
| 321 | quoting. Our earlier example, C<$days{'Feb'}> can be written as |
| 322 | C<$days{Feb}> and the quotes will be assumed automatically. But |
| 323 | anything more complicated in the subscript will be interpreted as |
| 324 | an expression. |
| 325 | |
| 326 | The special literals __FILE__, __LINE__, and __PACKAGE__ |
| 327 | represent the current filename, line number, and package name at that |
| 328 | point in your program. They may be used only as separate tokens; they |
| 329 | will not be interpolated into strings. If there is no current package |
| 330 | (due to an empty C<package;> directive), __PACKAGE__ is the undefined value. |
| 331 | |
| 332 | The tokens __END__ and __DATA__ may be used to indicate the logical |
| 333 | end of the script before the actual end of file. Any following |
| 334 | text is ignored, but may be read via a DATA filehandle: main::DATA |
| 335 | for __END__, or PACKNAME::DATA (where PACKNAME is the current |
| 336 | package) for __DATA__. The two control characters ^D and ^Z are |
| 337 | synonyms for __END__ in the main program, __DATA__ in a separate |
| 338 | module. See L<SelfLoader> for more description of __DATA__, and |
| 339 | an example of its use. Note that you cannot read from the DATA |
| 340 | filehandle in a BEGIN block: the BEGIN block is executed as soon |
| 341 | as it is seen (during compilation), at which point the corresponding |
| 342 | __DATA__ (or __END__) token has not yet been seen. |
| 343 | |
| 344 | A word that has no other interpretation in the grammar will |
| 345 | be treated as if it were a quoted string. These are known as |
| 346 | "barewords". As with filehandles and labels, a bareword that consists |
| 347 | entirely of lowercase letters risks conflict with future reserved |
| 348 | words, and if you use the B<-w> switch, Perl will warn you about any |
| 349 | such words. Some people may wish to outlaw barewords entirely. If you |
| 350 | say |
| 351 | |
| 352 | use strict 'subs'; |
| 353 | |
| 354 | then any bareword that would NOT be interpreted as a subroutine call |
| 355 | produces a compile-time error instead. The restriction lasts to the |
| 356 | end of the enclosing block. An inner block may countermand this |
| 357 | by saying C<no strict 'subs'>. |
| 358 | |
| 359 | Arrays and slices are interpolated into double-quoted strings |
| 360 | by joining the elements with the delimiter specified in the C<$"> |
| 361 | variable (C<$LIST_SEPARATOR> in English), space by default. The |
| 362 | following are equivalent: |
| 363 | |
| 364 | $temp = join($", @ARGV); |
| 365 | system "echo $temp"; |
| 366 | |
| 367 | system "echo @ARGV"; |
| 368 | |
| 369 | Within search patterns (which also undergo double-quotish substitution) |
| 370 | there is an unfortunate ambiguity: Is C</$foo[bar]/> to be interpreted as |
| 371 | C</${foo}[bar]/> (where C<[bar]> is a character class for the regular |
| 372 | expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array |
| 373 | @foo)? If @foo doesn't otherwise exist, then it's obviously a |
| 374 | character class. If @foo exists, Perl takes a good guess about C<[bar]>, |
| 375 | and is almost always right. If it does guess wrong, or if you're just |
| 376 | plain paranoid, you can force the correct interpretation with curly |
| 377 | braces as above. |
| 378 | |
| 379 | A line-oriented form of quoting is based on the shell "here-document" |
| 380 | syntax. Following a C<E<lt>E<lt>> you specify a string to terminate |
| 381 | the quoted material, and all lines following the current line down to |
| 382 | the terminating string are the value of the item. The terminating |
| 383 | string may be either an identifier (a word), or some quoted text. If |
| 384 | quoted, the type of quotes you use determines the treatment of the |
| 385 | text, just as in regular quoting. An unquoted identifier works like |
| 386 | double quotes. There must be no space between the C<E<lt>E<lt>> and |
| 387 | the identifier. (If you put a space it will be treated as a null |
| 388 | identifier, which is valid, and matches the first empty line.) The |
| 389 | terminating string must appear by itself (unquoted and with no |
| 390 | surrounding whitespace) on the terminating line. |
| 391 | |
| 392 | print <<EOF; |
| 393 | The price is $Price. |
| 394 | EOF |
| 395 | |
| 396 | print <<"EOF"; # same as above |
| 397 | The price is $Price. |
| 398 | EOF |
| 399 | |
| 400 | print <<`EOC`; # execute commands |
| 401 | echo hi there |
| 402 | echo lo there |
| 403 | EOC |
| 404 | |
| 405 | print <<"foo", <<"bar"; # you can stack them |
| 406 | I said foo. |
| 407 | foo |
| 408 | I said bar. |
| 409 | bar |
| 410 | |
| 411 | myfunc(<<"THIS", 23, <<'THAT'); |
| 412 | Here's a line |
| 413 | or two. |
| 414 | THIS |
| 415 | and here's another. |
| 416 | THAT |
| 417 | |
| 418 | Just don't forget that you have to put a semicolon on the end |
| 419 | to finish the statement, as Perl doesn't know you're not going to |
| 420 | try to do this: |
| 421 | |
| 422 | print <<ABC |
| 423 | 179231 |
| 424 | ABC |
| 425 | + 20; |
| 426 | |
| 427 | If you want your here-docs to be indented with the |
| 428 | rest of the code, you'll need to remove leading whitespace |
| 429 | from each line manually: |
| 430 | |
| 431 | ($quote = <<'FINIS') =~ s/^\s+//gm; |
| 432 | The Road goes ever on and on, |
| 433 | down from the door where it began. |
| 434 | FINIS |
| 435 | |
| 436 | =head2 List value constructors |
| 437 | |
| 438 | List values are denoted by separating individual values by commas |
| 439 | (and enclosing the list in parentheses where precedence requires it): |
| 440 | |
| 441 | (LIST) |
| 442 | |
| 443 | In a context not requiring a list value, the value of what appears |
| 444 | to be a list literal is simply the value of the final element, as |
| 445 | with the C comma operator. For example, |
| 446 | |
| 447 | @foo = ('cc', '-E', $bar); |
| 448 | |
| 449 | assigns the entire list value to array @foo, but |
| 450 | |
| 451 | $foo = ('cc', '-E', $bar); |
| 452 | |
| 453 | assigns the value of variable $bar to the scalar variable $foo. |
| 454 | Note that the value of an actual array in scalar context is the |
| 455 | length of the array; the following assigns the value 3 to $foo: |
| 456 | |
| 457 | @foo = ('cc', '-E', $bar); |
| 458 | $foo = @foo; # $foo gets 3 |
| 459 | |
| 460 | You may have an optional comma before the closing parenthesis of a |
| 461 | list literal, so that you can say: |
| 462 | |
| 463 | @foo = ( |
| 464 | 1, |
| 465 | 2, |
| 466 | 3, |
| 467 | ); |
| 468 | |
| 469 | To use a here-document to assign an array, one line per element, |
| 470 | you might use an approach like this: |
| 471 | |
| 472 | @sauces = <<End_Lines =~ m/(\S.*\S)/g; |
| 473 | normal tomato |
| 474 | spicy tomato |
| 475 | green chile |
| 476 | pesto |
| 477 | white wine |
| 478 | End_Lines |
| 479 | |
| 480 | LISTs do automatic interpolation of sublists. That is, when a LIST is |
| 481 | evaluated, each element of the list is evaluated in list context, and |
| 482 | the resulting list value is interpolated into LIST just as if each |
| 483 | individual element were a member of LIST. Thus arrays and hashes lose their |
| 484 | identity in a LIST--the list |
| 485 | |
| 486 | (@foo,@bar,&SomeSub,%glarch) |
| 487 | |
| 488 | contains all the elements of @foo followed by all the elements of @bar, |
| 489 | followed by all the elements returned by the subroutine named SomeSub |
| 490 | called in list context, followed by the key/value pairs of %glarch. |
| 491 | To make a list reference that does I<NOT> interpolate, see L<perlref>. |
| 492 | |
| 493 | The null list is represented by (). Interpolating it in a list |
| 494 | has no effect. Thus ((),(),()) is equivalent to (). Similarly, |
| 495 | interpolating an array with no elements is the same as if no |
| 496 | array had been interpolated at that point. |
| 497 | |
| 498 | A list value may also be subscripted like a normal array. You must |
| 499 | put the list in parentheses to avoid ambiguity. For example: |
| 500 | |
| 501 | # Stat returns list value. |
| 502 | $time = (stat($file))[8]; |
| 503 | |
| 504 | # SYNTAX ERROR HERE. |
| 505 | $time = stat($file)[8]; # OOPS, FORGOT PARENTHESES |
| 506 | |
| 507 | # Find a hex digit. |
| 508 | $hexdigit = ('a','b','c','d','e','f')[$digit-10]; |
| 509 | |
| 510 | # A "reverse comma operator". |
| 511 | return (pop(@foo),pop(@foo))[0]; |
| 512 | |
| 513 | Lists may be assigned to only when each element of the list |
| 514 | is itself legal to assign to: |
| 515 | |
| 516 | ($a, $b, $c) = (1, 2, 3); |
| 517 | |
| 518 | ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00); |
| 519 | |
| 520 | An exception to this is that you may assign to C<undef> in a list. |
| 521 | This is useful for throwing away some of the return values of a |
| 522 | function: |
| 523 | |
| 524 | ($dev, $ino, undef, undef, $uid, $gid) = stat($file); |
| 525 | |
| 526 | List assignment in scalar context returns the number of elements |
| 527 | produced by the expression on the right side of the assignment: |
| 528 | |
| 529 | $x = (($foo,$bar) = (3,2,1)); # set $x to 3, not 2 |
| 530 | $x = (($foo,$bar) = f()); # set $x to f()'s return count |
| 531 | |
| 532 | This is handy when you want to do a list assignment in a Boolean |
| 533 | context, because most list functions return a null list when finished, |
| 534 | which when assigned produces a 0, which is interpreted as FALSE. |
| 535 | |
| 536 | The final element may be an array or a hash: |
| 537 | |
| 538 | ($a, $b, @rest) = split; |
| 539 | my($a, $b, %rest) = @_; |
| 540 | |
| 541 | You can actually put an array or hash anywhere in the list, but the first one |
| 542 | in the list will soak up all the values, and anything after it will become |
| 543 | undefined. This may be useful in a my() or local(). |
| 544 | |
| 545 | A hash can be initialized using a literal list holding pairs of |
| 546 | items to be interpreted as a key and a value: |
| 547 | |
| 548 | # same as map assignment above |
| 549 | %map = ('red',0x00f,'blue',0x0f0,'green',0xf00); |
| 550 | |
| 551 | While literal lists and named arrays are often interchangeable, that's |
| 552 | not the case for hashes. Just because you can subscript a list value like |
| 553 | a normal array does not mean that you can subscript a list value as a |
| 554 | hash. Likewise, hashes included as parts of other lists (including |
| 555 | parameters lists and return lists from functions) always flatten out into |
| 556 | key/value pairs. That's why it's good to use references sometimes. |
| 557 | |
| 558 | It is often more readable to use the C<=E<gt>> operator between key/value |
| 559 | pairs. The C<=E<gt>> operator is mostly just a more visually distinctive |
| 560 | synonym for a comma, but it also arranges for its left-hand operand to be |
| 561 | interpreted as a string--if it's a bareword that would be a legal identifier. |
| 562 | This makes it nice for initializing hashes: |
| 563 | |
| 564 | %map = ( |
| 565 | red => 0x00f, |
| 566 | blue => 0x0f0, |
| 567 | green => 0xf00, |
| 568 | ); |
| 569 | |
| 570 | or for initializing hash references to be used as records: |
| 571 | |
| 572 | $rec = { |
| 573 | witch => 'Mable the Merciless', |
| 574 | cat => 'Fluffy the Ferocious', |
| 575 | date => '10/31/1776', |
| 576 | }; |
| 577 | |
| 578 | or for using call-by-named-parameter to complicated functions: |
| 579 | |
| 580 | $field = $query->radio_group( |
| 581 | name => 'group_name', |
| 582 | values => ['eenie','meenie','minie'], |
| 583 | default => 'meenie', |
| 584 | linebreak => 'true', |
| 585 | labels => \%labels |
| 586 | ); |
| 587 | |
| 588 | Note that just because a hash is initialized in that order doesn't |
| 589 | mean that it comes out in that order. See L<perlfunc/sort> for examples |
| 590 | of how to arrange for an output ordering. |
| 591 | |
| 592 | =head2 Slices |
| 593 | |
| 594 | A common way access an array or a hash is one scalar element at a time. |
| 595 | You can also subscript a list to get a single element from it. |
| 596 | |
| 597 | $whoami = $ENV{"USER"}; # one element from the hash |
| 598 | $parent = $ISA[0]; # one element from the array |
| 599 | $dir = (getpwnam("daemon"))[7]; # likewise, but with list |
| 600 | |
| 601 | A slice accesses several elements of a list, an array, or a hash |
| 602 | simultaneously using a list of subscripts. It's a more convenient |
| 603 | that writing out the individual elements as a list of separate |
| 604 | scalar values. |
| 605 | |
| 606 | ($him, $her) = @folks[0,-1]; # array slice |
| 607 | @them = @folks[0 .. 3]; # array slice |
| 608 | ($who, $home) = @ENV{"USER", "HOME"}; # hash slice |
| 609 | ($uid, $dir) = (getpwnam("daemon"))[2,7]; # list slice |
| 610 | |
| 611 | Since you can assign to a list of variables, you can also assign to |
| 612 | an array or hash slice. |
| 613 | |
| 614 | @days[3..5] = qw/Wed Thu Fri/; |
| 615 | @colors{'red','blue','green'} |
| 616 | = (0xff0000, 0x0000ff, 0x00ff00); |
| 617 | @folks[0, -1] = @folks[-1, 0]; |
| 618 | |
| 619 | The previous assignments are exactly equivalent to |
| 620 | |
| 621 | ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/; |
| 622 | ($colors{'red'}, $colors{'blue'}, $colors{'green'}) |
| 623 | = (0xff0000, 0x0000ff, 0x00ff00); |
| 624 | ($folks[0], $folks[-1]) = ($folks[0], $folks[-1]); |
| 625 | |
| 626 | Since changing a slice changes the original array or hash that it's |
| 627 | slicing, a C<foreach> construct will alter through some--or even |
| 628 | all--of the values of the array or hash. |
| 629 | |
| 630 | foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } |
| 631 | |
| 632 | foreach (@hash{keys %hash}) { |
| 633 | s/^\s+//; # trim leading whitespace |
| 634 | s/\s+$//; # trim trailing whitespace |
| 635 | s/(\w+)/\u\L$1/g; # "titlecase" words |
| 636 | } |
| 637 | |
| 638 | You couldn't just loop through C<values %hash> to do this because |
| 639 | that function produces a new list which is a copy of the values, |
| 640 | so changing them doesn't change the original. |
| 641 | |
| 642 | As a special rule, if a list slice would produce a list consisting |
| 643 | entirely of undefined values, the null list is produced instead. |
| 644 | This makes it easy to write loops that terminate when a null list |
| 645 | is returned: |
| 646 | |
| 647 | while ( ($home, $user) = (getpwent)[7,0]) { |
| 648 | printf "%-8s %s\n", $user, $home; |
| 649 | } |
| 650 | |
| 651 | As noted earlier in this document, the scalar sense of list assignment |
| 652 | is the number of elements on the right-hand side of the assignment. |
| 653 | The null list contains no elements, so when the password file is |
| 654 | exhausted, the result is 0, not 2. |
| 655 | |
| 656 | If you're confused about why you use an '@' there on a hash slice |
| 657 | instead of a '%', think of it like this. The type of bracket (square |
| 658 | or curly) governs whether it's an array or a hash being looked at. |
| 659 | On the other hand, the leading symbol ('$' or '@') on the array or |
| 660 | hash indicates whether you are getting back a singular value (a |
| 661 | scalar) or a plural one (a list). |
| 662 | |
| 663 | =head2 Typeglobs and Filehandles |
| 664 | |
| 665 | Perl uses an internal type called a I<typeglob> to hold an entire |
| 666 | symbol table entry. The type prefix of a typeglob is a C<*>, because |
| 667 | it represents all types. This used to be the preferred way to |
| 668 | pass arrays and hashes by reference into a function, but now that |
| 669 | we have real references, this is seldom needed. |
| 670 | |
| 671 | The main use of typeglobs in modern Perl is create symbol table aliases. |
| 672 | This assignment: |
| 673 | |
| 674 | *this = *that; |
| 675 | |
| 676 | makes $this an alias for $that, @this an alias for @that, %this an alias |
| 677 | for %that, &this an alias for &that, etc. Much safer is to use a reference. |
| 678 | This: |
| 679 | |
| 680 | local *Here::blue = \$There::green; |
| 681 | |
| 682 | temporarily makes $Here::blue an alias for $There::green, but doesn't |
| 683 | make @Here::blue an alias for @There::green, or %Here::blue an alias for |
| 684 | %There::green, etc. See L<perlmod/"Symbol Tables"> for more examples |
| 685 | of this. Strange though this may seem, this is the basis for the whole |
| 686 | module import/export system. |
| 687 | |
| 688 | Another use for typeglobs is to pass filehandles into a function or |
| 689 | to create new filehandles. If you need to use a typeglob to save away |
| 690 | a filehandle, do it this way: |
| 691 | |
| 692 | $fh = *STDOUT; |
| 693 | |
| 694 | or perhaps as a real reference, like this: |
| 695 | |
| 696 | $fh = \*STDOUT; |
| 697 | |
| 698 | See L<perlsub> for examples of using these as indirect filehandles |
| 699 | in functions. |
| 700 | |
| 701 | Typeglobs are also a way to create a local filehandle using the local() |
| 702 | operator. These last until their block is exited, but may be passed back. |
| 703 | For example: |
| 704 | |
| 705 | sub newopen { |
| 706 | my $path = shift; |
| 707 | local *FH; # not my! |
| 708 | open (FH, $path) or return undef; |
| 709 | return *FH; |
| 710 | } |
| 711 | $fh = newopen('/etc/passwd'); |
| 712 | |
| 713 | Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much |
| 714 | for filehandle manipulations, although they're still needed to pass brand |
| 715 | new file and directory handles into or out of functions. That's because |
| 716 | C<*HANDLE{IO}> only works if HANDLE has already been used as a handle. |
| 717 | In other words, C<*FH> must be used to create new symbol table entries; |
| 718 | C<*foo{THING}> cannot. When in doubt, use C<*FH>. |
| 719 | |
| 720 | Another way to create anonymous filehandles is with the Symbol |
| 721 | module or with the IO::Handle module and its ilk. These modules |
| 722 | have the advantage of not hiding different types of the same name |
| 723 | during the local(). See the bottom of L<perlfunc/open()> for an |
| 724 | example. |
| 725 | |
| 726 | =head1 SEE ALSO |
| 727 | |
| 728 | See L<perlvar> for a description of Perl's built-in variables and |
| 729 | a discussion of legal variable names. See L<perlref>, L<perlsub>, |
| 730 | and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and |
| 731 | the C<*foo{THING}> syntax. |