| 1 | package version::regex; |
| 2 | |
| 3 | use strict; |
| 4 | |
| 5 | use vars qw($VERSION $CLASS $STRICT $LAX); |
| 6 | |
| 7 | $VERSION = 0.9907; |
| 8 | |
| 9 | #--------------------------------------------------------------------------# |
| 10 | # Version regexp components |
| 11 | #--------------------------------------------------------------------------# |
| 12 | |
| 13 | # Fraction part of a decimal version number. This is a common part of |
| 14 | # both strict and lax decimal versions |
| 15 | |
| 16 | my $FRACTION_PART = qr/\.[0-9]+/; |
| 17 | |
| 18 | # First part of either decimal or dotted-decimal strict version number. |
| 19 | # Unsigned integer with no leading zeroes (except for zero itself) to |
| 20 | # avoid confusion with octal. |
| 21 | |
| 22 | my $STRICT_INTEGER_PART = qr/0|[1-9][0-9]*/; |
| 23 | |
| 24 | # First part of either decimal or dotted-decimal lax version number. |
| 25 | # Unsigned integer, but allowing leading zeros. Always interpreted |
| 26 | # as decimal. However, some forms of the resulting syntax give odd |
| 27 | # results if used as ordinary Perl expressions, due to how perl treats |
| 28 | # octals. E.g. |
| 29 | # version->new("010" ) == 10 |
| 30 | # version->new( 010 ) == 8 |
| 31 | # version->new( 010.2) == 82 # "8" . "2" |
| 32 | |
| 33 | my $LAX_INTEGER_PART = qr/[0-9]+/; |
| 34 | |
| 35 | # Second and subsequent part of a strict dotted-decimal version number. |
| 36 | # Leading zeroes are permitted, and the number is always decimal. |
| 37 | # Limited to three digits to avoid overflow when converting to decimal |
| 38 | # form and also avoid problematic style with excessive leading zeroes. |
| 39 | |
| 40 | my $STRICT_DOTTED_DECIMAL_PART = qr/\.[0-9]{1,3}/; |
| 41 | |
| 42 | # Second and subsequent part of a lax dotted-decimal version number. |
| 43 | # Leading zeroes are permitted, and the number is always decimal. No |
| 44 | # limit on the numerical value or number of digits, so there is the |
| 45 | # possibility of overflow when converting to decimal form. |
| 46 | |
| 47 | my $LAX_DOTTED_DECIMAL_PART = qr/\.[0-9]+/; |
| 48 | |
| 49 | # Alpha suffix part of lax version number syntax. Acts like a |
| 50 | # dotted-decimal part. |
| 51 | |
| 52 | my $LAX_ALPHA_PART = qr/_[0-9]+/; |
| 53 | |
| 54 | #--------------------------------------------------------------------------# |
| 55 | # Strict version regexp definitions |
| 56 | #--------------------------------------------------------------------------# |
| 57 | |
| 58 | # Strict decimal version number. |
| 59 | |
| 60 | my $STRICT_DECIMAL_VERSION = |
| 61 | qr/ $STRICT_INTEGER_PART $FRACTION_PART? /x; |
| 62 | |
| 63 | # Strict dotted-decimal version number. Must have both leading "v" and |
| 64 | # at least three parts, to avoid confusion with decimal syntax. |
| 65 | |
| 66 | my $STRICT_DOTTED_DECIMAL_VERSION = |
| 67 | qr/ v $STRICT_INTEGER_PART $STRICT_DOTTED_DECIMAL_PART{2,} /x; |
| 68 | |
| 69 | # Complete strict version number syntax -- should generally be used |
| 70 | # anchored: qr/ \A $STRICT \z /x |
| 71 | |
| 72 | $STRICT = |
| 73 | qr/ $STRICT_DECIMAL_VERSION | $STRICT_DOTTED_DECIMAL_VERSION /x; |
| 74 | |
| 75 | #--------------------------------------------------------------------------# |
| 76 | # Lax version regexp definitions |
| 77 | #--------------------------------------------------------------------------# |
| 78 | |
| 79 | # Lax decimal version number. Just like the strict one except for |
| 80 | # allowing an alpha suffix or allowing a leading or trailing |
| 81 | # decimal-point |
| 82 | |
| 83 | my $LAX_DECIMAL_VERSION = |
| 84 | qr/ $LAX_INTEGER_PART (?: \. | $FRACTION_PART $LAX_ALPHA_PART? )? |
| 85 | | |
| 86 | $FRACTION_PART $LAX_ALPHA_PART? |
| 87 | /x; |
| 88 | |
| 89 | # Lax dotted-decimal version number. Distinguished by having either |
| 90 | # leading "v" or at least three non-alpha parts. Alpha part is only |
| 91 | # permitted if there are at least two non-alpha parts. Strangely |
| 92 | # enough, without the leading "v", Perl takes .1.2 to mean v0.1.2, |
| 93 | # so when there is no "v", the leading part is optional |
| 94 | |
| 95 | my $LAX_DOTTED_DECIMAL_VERSION = |
| 96 | qr/ |
| 97 | v $LAX_INTEGER_PART (?: $LAX_DOTTED_DECIMAL_PART+ $LAX_ALPHA_PART? )? |
| 98 | | |
| 99 | $LAX_INTEGER_PART? $LAX_DOTTED_DECIMAL_PART{2,} $LAX_ALPHA_PART? |
| 100 | /x; |
| 101 | |
| 102 | # Complete lax version number syntax -- should generally be used |
| 103 | # anchored: qr/ \A $LAX \z /x |
| 104 | # |
| 105 | # The string 'undef' is a special case to make for easier handling |
| 106 | # of return values from ExtUtils::MM->parse_version |
| 107 | |
| 108 | $LAX = |
| 109 | qr/ undef | $LAX_DECIMAL_VERSION | $LAX_DOTTED_DECIMAL_VERSION /x; |
| 110 | |
| 111 | #--------------------------------------------------------------------------# |
| 112 | |
| 113 | # Preloaded methods go here. |
| 114 | sub is_strict { defined $_[0] && $_[0] =~ qr/ \A $STRICT \z /x } |
| 115 | sub is_lax { defined $_[0] && $_[0] =~ qr/ \A $LAX \z /x } |
| 116 | |
| 117 | 1; |