[perl5.git] / lib / utf8_heavy.pl

package utf8;
use strict;
use warnings;

sub DEBUG () { 0 }

sub DESTROY {}

my %Cache;

sub croak { require Carp; Carp::croak(@_) }

##
## "SWASH" == "SWATCH HASH". A "swatch" is a swatch of the Unicode landscape.
## It's a data structure that encodes a set of Unicode characters.
##

{
    # If a floating point number is within this distance from the value of a
    # fraction, it is considered to be that fraction, even if many more digits
    # are specified that don't exactly match.
    my $min_floating_slop;

    sub SWASHNEW {
        my ($class, $type, $list, $minbits, $none) = @_;
        local $^D = 0 if $^D;

        print STDERR __LINE__, ": ", join(", ", @_), "\n" if DEBUG;

        ##
        ## Get the list of codepoints for the type.
        ## Called from swash_init (see utf8.c) or SWASHNEW itself.
        ##
        ## Callers of swash_init:
        ##     op.c:pmtrans             -- for tr/// and y///
        ##     regexec.c:regclass_swash -- for /[]/, \p, and \P
        ##     utf8.c:is_utf8_common    -- for common Unicode properties
        ##     utf8.c:to_utf8_case      -- for lc, uc, ucfirst, etc. and //i
        ##
        ## Given a $type, our goal is to fill $list with the set of codepoint
        ## ranges. If $type is false, $list passed is used.
        ##
        ## $minbits:
        ##     For binary properties, $minbits must be 1.
        ##     For character mappings (case and transliteration), $minbits must
        ##     be a number except 1.
        ##
        ## $list (or that filled according to $type):
        ##     Refer to perlunicode.pod, "User-Defined Character Properties."
        ##     
        ##     For binary properties, only characters with the property value
        ##     of True should be listed. The 3rd column, if any, will be ignored
        ##
        ## $none is undocumented, so I'm (khw) trying to do some documentation
        ## of it now.  It appears to be if there is a mapping in an input file
        ## that maps to 'XXXX', then that is replaced by $none+1, expressed in
        ## hexadecimal.  The only place I found it possibly used was in
        ## S_pmtrans in op.c.
        ##
        ## To make the parsing of $type clear, this code takes the a rather
        ## unorthodox approach of last'ing out of the block once we have the
        ## info we need. Were this to be a subroutine, the 'last' would just
        ## be a 'return'.
        ##
        my $file; ## file to load data from, and also part of the %Cache key.
        my $ListSorted = 0;

        # Change this to get a different set of Unicode tables
        my $unicore_dir = 'unicore';

        if ($type)
        {
            $type =~ s/^\s+//;
            $type =~ s/\s+$//;

            print STDERR __LINE__, ": type = $type\n" if DEBUG;

        GETFILE:
            {
                ##
                ## It could be a user-defined property.
                ##

                my $caller1 = $type =~ s/(.+)::// ? $1 : caller(1);

                if (defined $caller1 && $type =~ /^(?:\w+)$/) {
                    my $prop = "${caller1}::$type";
                    if (exists &{$prop}) {
                        no strict 'refs';
                        
                        $list = &{$prop};
                        last GETFILE;
                    }
                }

                require "$unicore_dir/Heavy.pl";

                # Everything is caseless matching
                my $property_and_table = lc $type;
                print STDERR __LINE__, ": $property_and_table\n" if DEBUG;

                # See if is of the compound form 'property=value', where the
                # value indicates the table we should use.
                my ($property, $table, @remainder) =
                                    split /\s*[:=]\s*/, $property_and_table, -1;
                return $type if @remainder;

                my $prefix;
                if (! defined $table) {
                        
                    # Here, is the single form.  The property becomes empty, and
                    # the whole value is the table.
                    $table = $property;
                    $prefix = $property = "";
                } else {
                    print STDERR __LINE__, ": $property\n" if DEBUG;

                    # Here it is the compound property=table form.  The property
                    # name is always loosely matched, which means remove any of
                    # these:
                    $property =~ s/[_\s-]//g;

                    # And convert to canonical form.  Quit if not valid.
                    $property = $utf8::loose_property_name_of{$property};
                    return $type unless defined $property;

                    $prefix = "$property=";

                    # If the rhs looks like it is a number...
                    print STDERR __LINE__, ": table=$table\n" if DEBUG;
                    if ($table =~ qr{ ^ [ \s 0-9 _  + / . -]+ $ }x) {
                        print STDERR __LINE__, ": table=$table\n" if DEBUG;

                        # Don't allow leading nor trailing slashes 
                        return $type if $table =~ / ^ \/ | \/ $ /x;

                        # Split on slash, in case it is a rational, like \p{1/5}
                        my @parts = split qr{ \s* / \s* }x, $table, -1;
                        print __LINE__, ": $type\n" if @parts > 2 && DEBUG;

                        # Can have maximum of one slash
                        return $type if @parts > 2;

                        foreach my $part (@parts) {
                            print __LINE__, ": part=$part\n" if DEBUG;

                            $part =~ s/^\+\s*//;    # Remove leading plus
                            $part =~ s/^-\s*/-/;    # Remove blanks after unary
                                                    # minus

                            # Remove underscores between digits.
                            $part =~ s/( ?<= [0-9] ) _ (?= [0-9] ) //xg;

                            # No leading zeros (but don't make a single '0'
                            # into a null string)
                            $part =~ s/ ^ ( -? ) 0+ /$1/x;
                            $part .= '0' if $part eq '-' || $part eq "";

                            # No trailing zeros after a decimal point
                            $part =~ s/ ( \. .*? ) 0+ $ /$1/x;

                            # Begin with a 0 if a leading decimal point
                            $part =~ s/ ^ ( -? ) \. /${1}0./x;

                            # Ensure not a trailing decimal point: turn into an
                            # integer
                            $part =~ s/ \. $ //x;

                            print STDERR __LINE__, ": part=$part\n" if DEBUG;
                            #return $type if $part eq "";
                            
                            # Result better look like a number.  (This test is
                            # needed because, for example could have a plus in
                            # the middle.)
                            return $type if $part
                                            !~ / ^ -? [0-9]+ ( \. [0-9]+)? $ /x;
                        }

                        #  If a rational...
                        if (@parts == 2) {

                            # If denominator is negative, get rid of it, and ...
                            if ($parts[1] =~ s/^-//) {

                                # If numerator is also negative, convert the
                                # whole thing to positive, or move the minus to
                                # the numerator
                                if ($parts[0] !~ s/^-//) {
                                    $parts[0] = '-' . $parts[0];
                                }
                            }
                            $table = join '/', @parts;
                        }
                        elsif ($property ne 'nv' || $parts[0] !~ /\./) {

                            # Here is not numeric value, or doesn't have a
                            # decimal point.  No further manipulation is
                            # necessary.  (Note the hard-coded property name.
                            # This could fail if other properties eventually
                            # had fractions as well; perhaps the cjk ones
                            # could evolve to do that.  This hard-coding could
                            # be fixed by mktables generating a list of
                            # properties that could have fractions.)
                            $table = $parts[0];
                        } else {

                            # Here is a floating point numeric_value.  Try to
                            # convert to rational.  First see if is in the list
                            # of known ones.
                            if (exists $utf8::nv_floating_to_rational{$parts[0]}) {
                                $table = $utf8::nv_floating_to_rational{$parts[0]};
                            } else {

                                # Here not in the list.  See if is close
                                # enough to something in the list.  First
                                # determine what 'close enough' means.  It has
                                # to be as tight as what mktables says is the
                                # maximum slop, and as tight as how many
                                # digits we were passed.  That is, if the user
                                # said .667, .6667, .66667, etc.  we match as
                                # many digits as they passed until get to
                                # where it doesn't matter any more due to the
                                # machine's precision.  If they said .6666668,
                                # we fail.
                                (my $fraction = $parts[0]) =~ s/^.*\.//;
                                my $epsilon = 10 ** - (length($fraction));
                                if ($epsilon > $utf8::max_floating_slop) {
                                    $epsilon = $utf8::max_floating_slop;
                                }

                                # But it can't be tighter than the minimum
                                # precision for this machine.  If haven't
                                # already calculated that minimum, do so now.
                                if (! defined $min_floating_slop) {

                                    # Keep going down an order of magnitude
                                    # until find that adding this quantity to
                                    # 1 remains 1; but put an upper limit on
                                    # this so in case this algorithm doesn't
                                    # work properly on some platform, that we
                                    # won't loop forever.
                                    my $count = 0;
                                    $min_floating_slop = 1;
                                    while (1+ $min_floating_slop != 1
                                           && $count++ < 50)
                                    {
                                        my $next = $min_floating_slop / 10;
                                        last if $next == 0; # If underflows,
                                                            # use previous one
                                        $min_floating_slop = $next;
                                        print STDERR __LINE__, ": min_float_slop=$min_floating_slop\n" if DEBUG;
                                    }

                                    # Back off a couple orders of magnitude,
                                    # just to be safe.
                                    $min_floating_slop *= 100;
                                }
                                    
                                if ($epsilon < $min_floating_slop) {
                                    $epsilon = $min_floating_slop;
                                }
                                print STDERR __LINE__, ": fraction=.$fraction; epsilon=$epsilon\n" if DEBUG;

                                undef $table;

                                # And for each possible rational in the table,
                                # see if it is within epsilon of the input.
                                foreach my $official
                                        (keys %utf8::nv_floating_to_rational)
                                {
                                    print STDERR __LINE__, ": epsilon=$epsilon, official=$official, diff=", abs($parts[0] - $official), "\n" if DEBUG;
                                    if (abs($parts[0] - $official) < $epsilon) {
                                      $table =
                                      $utf8::nv_floating_to_rational{$official};
                                        last;
                                    }
                                }

                                # Quit if didn't find one.
                                return $type unless defined $table;
                            }
                        }
                        print STDERR __LINE__, ": $property=$table\n" if DEBUG;
                    }
                }

                # Combine lhs (if any) and rhs to get something that matches
                # the syntax of the lookups.
                $property_and_table = "$prefix$table";
                print STDERR __LINE__, ": $property_and_table\n" if DEBUG;

                # First try stricter matching.
                $file = $utf8::stricter_to_file_of{$property_and_table};

                # If didn't find it, try again with looser matching by editing
                # out the applicable characters on the rhs and looking up
                # again.
                if (! defined $file) {
                    $table =~ s/ [_\s-] //xg;
                    $property_and_table = "$prefix$table";
                    print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
                    $file = $utf8::loose_to_file_of{$property_and_table};
                }

                # Add the constant and go fetch it in.
                if (defined $file) {
                    if ($utf8::why_deprecated{$file}) {
                        warnings::warnif('deprecated', "Use of '$type' in \\p{} or \\P{} is deprecated because: $utf8::why_deprecated{$file};");
                    }
                    $file= "$unicore_dir/lib/$file.pl";
                    last GETFILE;
                }
                print STDERR __LINE__, ": didn't find $property_and_table\n" if DEBUG;

                ##
                ## See if it's a user-level "To".
                ##

                my $caller0 = caller(0);

                if (defined $caller0 && $type =~ /^To(?:\w+)$/) {
                    my $map = $caller0 . "::" . $type;

                    if (exists &{$map}) {
                        no strict 'refs';
                        
                        $list = &{$map};
                        last GETFILE;
                    }
                }

                ##
                ## Last attempt -- see if it's a standard "To" name
                ## (e.g. "ToLower")  ToTitle is used by ucfirst().
                ## The user-level way to access ToDigit() and ToFold()
                ## is to use Unicode::UCD.
                ##
                if ($type =~ /^To(Digit|Fold|Lower|Title|Upper)$/) {
                    $file = "$unicore_dir/To/$1.pl";
                    ## would like to test to see if $file actually exists....
                    last GETFILE;
                }

                ##
                ## If we reach this line, it's because we couldn't figure
                ## out what to do with $type. Ouch.
                ##

                return $type;
            }

            if (defined $file) {
                print STDERR __LINE__, ": found it (file='$file')\n" if DEBUG;

                ##
                ## If we reach here, it was due to a 'last GETFILE' above
                ## (exception: user-defined properties and mappings), so we
                ## have a filename, so now we load it if we haven't already.
                ## If we have, return the cached results. The cache key is the
                ## class and file to load.
                ##
                my $found = $Cache{$class, $file};
                if ($found and ref($found) eq $class) {
                    print STDERR __LINE__, ": Returning cached '$file' for \\p{$type}\n" if DEBUG;
                    return $found;
                }

                local $@;
                local $!;
                $list = do $file; die $@ if $@;
            }

            $ListSorted = 1; ## we know that these lists are sorted
        }

        my $extras;
        my $bits = $minbits;

        my $ORIG = $list;
        if ($list) {
            my @tmp = split(/^/m, $list);
            my %seen;
            no warnings;
            $extras = join '', grep /^[^0-9a-fA-F]/, @tmp;
            $list = join '',
                map  { $_->[1] }
                sort { $a->[0] <=> $b->[0] }
                map  { /^([0-9a-fA-F]+)/; [ CORE::hex($1), $_ ] }
                grep { /^([0-9a-fA-F]+)/ and not $seen{$1}++ } @tmp; # XXX doesn't do ranges right
        }

        if ($none) {
            my $hextra = sprintf "%04x", $none + 1;
            $list =~ s/\tXXXX$/\t$hextra/mg;
        }

        if ($minbits != 1 && $minbits < 32) { # not binary property
            my $top = 0;
            while ($list =~ /^([0-9a-fA-F]+)(?:[\t]([0-9a-fA-F]+)?)(?:[ \t]([0-9a-fA-F]+))?/mg) {
                my $min = CORE::hex $1;
                my $max = defined $2 ? CORE::hex $2 : $min;
                my $val = defined $3 ? CORE::hex $3 : 0;
                $val += $max - $min if defined $3;
                $top = $val if $val > $top;
            }
            my $topbits =
                $top > 0xffff ? 32 :
                $top > 0xff ? 16 : 8;
            $bits = $topbits if $bits < $topbits;
        }

        my @extras;
        if ($extras) {
            for my $x ($extras) {
                pos $x = 0;
                while ($x =~ /^([^0-9a-fA-F\n])(.*)/mg) {
                    my $char = $1;
                    my $name = $2;
                    print STDERR __LINE__, ": $1 => $2\n" if DEBUG;
                    if ($char =~ /[-+!&]/) {
                        my ($c,$t) = split(/::/, $name, 2);	# bogus use of ::, really
                        my $subobj;
                        if ($c eq 'utf8') {
                            $subobj = utf8->SWASHNEW($t, "", $minbits, 0);
                        }
                        elsif (exists &$name) {
                            $subobj = utf8->SWASHNEW($name, "", $minbits, 0);
                        }
                        elsif ($c =~ /^([0-9a-fA-F]+)/) {
                            $subobj = utf8->SWASHNEW("", $c, $minbits, 0);
                        }
                        return $subobj unless ref $subobj;
                        push @extras, $name => $subobj;
                        $bits = $subobj->{BITS} if $bits < $subobj->{BITS};
                    }
                }
            }
        }

        if (DEBUG) {
            print STDERR __LINE__, ": CLASS = $class, TYPE => $type, BITS => $bits, NONE => $none";
            print STDERR "\nLIST =>\n$list" if defined $list;
            print STDERR "\nEXTRAS =>\n$extras" if defined $extras;
            print STDERR "\n";
        }

        my $SWASH = bless {
            TYPE => $type,
            BITS => $bits,
            EXTRAS => $extras,
            LIST => $list,
            NONE => $none,
            @extras,
        } => $class;

        if ($file) {
            $Cache{$class, $file} = $SWASH;
        }

        return $SWASH;
    }
}

# Now SWASHGET is recasted into a C function S_swash_get (see utf8.c).

1;
Commit	Line	Data
a0ed51b3	1	package utf8;
cf25bb62 JH	2	use strict;
cf25bb62 JH	3	use warnings;
a0ed51b3	4
15732964	5	sub DEBUG () { 0 }
a0ed51b3 LW	6
	7	sub DESTROY {}
	8
5beb625e JH	9	my %Cache;
5beb625e JH	10
86916d66 JH	11	sub croak { require Carp; Carp::croak(@_) }
86916d66 JH	12
5beb625e	13	##
3a2263fe RGS	14	## "SWASH" == "SWATCH HASH". A "swatch" is a swatch of the Unicode landscape.
3a2263fe RGS	15	## It's a data structure that encodes a set of Unicode characters.
5beb625e JH	16	##
5beb625e JH	17
99870f4d KW	18	{
	19	# If a floating point number is within this distance from the value of a
	20	# fraction, it is considered to be that fraction, even if many more digits
	21	# are specified that don't exactly match.
	22	my $min_floating_slop;
	23
	24	sub SWASHNEW {
	25	my ($class, $type, $list, $minbits, $none) = @_;
	26	local $^D = 0 if $^D;
	27
	28	print STDERR __LINE__, ": ", join(", ", @_), "\n" if DEBUG;
	29
	30	##
	31	## Get the list of codepoints for the type.
	32	## Called from swash_init (see utf8.c) or SWASHNEW itself.
	33	##
	34	## Callers of swash_init:
	35	## op.c:pmtrans -- for tr/// and y///
	36	## regexec.c:regclass_swash -- for /[]/, \p, and \P
	37	## utf8.c:is_utf8_common -- for common Unicode properties
	38	## utf8.c:to_utf8_case -- for lc, uc, ucfirst, etc. and //i
	39	##
	40	## Given a $type, our goal is to fill $list with the set of codepoint
	41	## ranges. If $type is false, $list passed is used.
	42	##
	43	## $minbits:
	44	## For binary properties, $minbits must be 1.
	45	## For character mappings (case and transliteration), $minbits must
	46	## be a number except 1.
	47	##
	48	## $list (or that filled according to $type):
	49	## Refer to perlunicode.pod, "User-Defined Character Properties."
	50	##
	51	## For binary properties, only characters with the property value
	52	## of True should be listed. The 3rd column, if any, will be ignored
	53	##
	54	## $none is undocumented, so I'm (khw) trying to do some documentation
	55	## of it now. It appears to be if there is a mapping in an input file
	56	## that maps to 'XXXX', then that is replaced by $none+1, expressed in
	57	## hexadecimal. The only place I found it possibly used was in
	58	## S_pmtrans in op.c.
	59	##
	60	## To make the parsing of $type clear, this code takes the a rather
	61	## unorthodox approach of last'ing out of the block once we have the
	62	## info we need. Were this to be a subroutine, the 'last' would just
	63	## be a 'return'.
	64	##
	65	my $file; ## file to load data from, and also part of the %Cache key.
	66	my $ListSorted = 0;
	67
	68	# Change this to get a different set of Unicode tables
	69	my $unicore_dir = 'unicore';
	70
	71	if ($type)
cf25bb62	72	{
99870f4d KW	73	$type =~ s/^\s+//;
	74	$type =~ s/\s+$//;
	75
	76	print STDERR __LINE__, ": type = $type\n" if DEBUG;
	77
	78	GETFILE:
	79	{
	80	##
	81	## It could be a user-defined property.
	82	##
	83
	84	my $caller1 = $type =~ s/(.+)::// ? $1 : caller(1);
	85
	86	if (defined $caller1 && $type =~ /^(?:\w+)$/) {
	87	my $prop = "${caller1}::$type";
	88	if (exists &{$prop}) {
	89	no strict 'refs';
	90
	91	$list = &{$prop};
	92	last GETFILE;
	93	}
	94	}
	95
	96	require "$unicore_dir/Heavy.pl";
	97
	98	# Everything is caseless matching
	99	my $property_and_table = lc $type;
	100	print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
	101
	102	# See if is of the compound form 'property=value', where the
	103	# value indicates the table we should use.
	104	my ($property, $table, @remainder) =
	105	split /\s[:=]\s/, $property_and_table, -1;
	106	return $type if @remainder;
	107
	108	my $prefix;
	109	if (! defined $table) {
	110
	111	# Here, is the single form. The property becomes empty, and
	112	# the whole value is the table.
	113	$table = $property;
	114	$prefix = $property = "";
	115	} else {
	116	print STDERR __LINE__, ": $property\n" if DEBUG;
	117
	118	# Here it is the compound property=table form. The property
	119	# name is always loosely matched, which means remove any of
	120	# these:
	121	$property =~ s/[_\s-]//g;
	122
	123	# And convert to canonical form. Quit if not valid.
	124	$property = $utf8::loose_property_name_of{$property};
	125	return $type unless defined $property;
	126
	127	$prefix = "$property=";
	128
	129	# If the rhs looks like it is a number...
	130	print STDERR __LINE__, ": table=$table\n" if DEBUG;
	131	if ($table =~ qr{ ^ [ \s 0-9 _ + / . -]+ $ }x) {
	132	print STDERR __LINE__, ": table=$table\n" if DEBUG;
	133
	134	# Don't allow leading nor trailing slashes
	135	return $type if $table =~ / ^ \/ \| \/ $ /x;
	136
137	# Split on slash, in case it is a rational, like \p{1/5}
138	my @parts = split qr{ \s* / \s* }x, $table, -1;
139	print __LINE__, ": $type\n" if @parts > 2 && DEBUG;
140
141	# Can have maximum of one slash
142	return $type if @parts > 2;
143
144	foreach my $part (@parts) {
145	print __LINE__, ": part=$part\n" if DEBUG;
146
147	$part =~ s/^\+\s*//; # Remove leading plus
148	$part =~ s/^-\s*/-/; # Remove blanks after unary
149	# minus
150
151	# Remove underscores between digits.
152	$part =~ s/( ?<= [0-9] ) _ (?= [0-9] ) //xg;
153
154	# No leading zeros (but don't make a single '0'
155	# into a null string)
156	$part =~ s/ ^ ( -? ) 0+ /$1/x;
157	$part .= '0' if $part eq '-' \|\| $part eq "";
158
159	# No trailing zeros after a decimal point
160	$part =~ s/ ( \. .*? ) 0+ $ /$1/x;
161
162	# Begin with a 0 if a leading decimal point
163	$part =~ s/ ^ ( -? ) \. /${1}0./x;
164
165	# Ensure not a trailing decimal point: turn into an
166	# integer
167	$part =~ s/ \. $ //x;
168
169	print STDERR __LINE__, ": part=$part\n" if DEBUG;
170	#return $type if $part eq "";
171
172	# Result better look like a number. (This test is
173	# needed because, for example could have a plus in
174	# the middle.)
175	return $type if $part
176	!~ / ^ -? [0-9]+ ( \. [0-9]+)? $ /x;
177	}
178
179	# If a rational...
180	if (@parts == 2) {
181
182	# If denominator is negative, get rid of it, and ...
183	if ($parts[1] =~ s/^-//) {
184
185	# If numerator is also negative, convert the
186	# whole thing to positive, or move the minus to
187	# the numerator
188	if ($parts[0] !~ s/^-//) {
189	$parts[0] = '-' . $parts[0];
190	}
191	}
192	$table = join '/', @parts;
193	}
194	elsif ($property ne 'nv' \|\| $parts[0] !~ /\./) {
195
196	# Here is not numeric value, or doesn't have a
197	# decimal point. No further manipulation is
198	# necessary. (Note the hard-coded property name.
199	# This could fail if other properties eventually
200	# had fractions as well; perhaps the cjk ones
201	# could evolve to do that. This hard-coding could
202	# be fixed by mktables generating a list of
203	# properties that could have fractions.)
204	$table = $parts[0];
205	} else {
206
207	# Here is a floating point numeric_value. Try to
208	# convert to rational. First see if is in the list
209	# of known ones.
210	if (exists $utf8::nv_floating_to_rational{$parts[0]}) {
211	$table = $utf8::nv_floating_to_rational{$parts[0]};
212	} else {
213
214	# Here not in the list. See if is close
215	# enough to something in the list. First
216	# determine what 'close enough' means. It has
217	# to be as tight as what mktables says is the
218	# maximum slop, and as tight as how many
219	# digits we were passed. That is, if the user
220	# said .667, .6667, .66667, etc. we match as
221	# many digits as they passed until get to
222	# where it doesn't matter any more due to the
223	# machine's precision. If they said .6666668,
224	# we fail.
225	(my $fraction = $parts[0]) =~ s/^.*\.//;
226	my $epsilon = 10 ** - (length($fraction));
227	if ($epsilon > $utf8::max_floating_slop) {
228	$epsilon = $utf8::max_floating_slop;
229	}
230
231	# But it can't be tighter than the minimum
232	# precision for this machine. If haven't
233	# already calculated that minimum, do so now.
234	if (! defined $min_floating_slop) {
235
236	# Keep going down an order of magnitude
237	# until find that adding this quantity to
238	# 1 remains 1; but put an upper limit on
239	# this so in case this algorithm doesn't
240	# work properly on some platform, that we
241	# won't loop forever.
242	my $count = 0;
243	$min_floating_slop = 1;
244	while (1+ $min_floating_slop != 1
245	&& $count++ < 50)
246	{
247	my $next = $min_floating_slop / 10;
248	last if $next == 0; # If underflows,
249	# use previous one
250	$min_floating_slop = $next;
251	print STDERR __LINE__, ": min_float_slop=$min_floating_slop\n" if DEBUG;
252	}
253
254	# Back off a couple orders of magnitude,
255	# just to be safe.
256	$min_floating_slop *= 100;
257	}
258
259	if ($epsilon < $min_floating_slop) {
260	$epsilon = $min_floating_slop;
261	}
262	print STDERR __LINE__, ": fraction=.$fraction; epsilon=$epsilon\n" if DEBUG;
263
264	undef $table;
265
266	# And for each possible rational in the table,
267	# see if it is within epsilon of the input.
268	foreach my $official
269	(keys %utf8::nv_floating_to_rational)
270	{
271	print STDERR __LINE__, ": epsilon=$epsilon, official=$official, diff=", abs($parts[0] - $official), "\n" if DEBUG;
272	if (abs($parts[0] - $official) < $epsilon) {
273	$table =
274	$utf8::nv_floating_to_rational{$official};
275	last;
276	}
277	}
278
279	# Quit if didn't find one.
280	return $type unless defined $table;
281	}
282	}
283	print STDERR __LINE__, ": $property=$table\n" if DEBUG;
284	}
285	}
286
287	# Combine lhs (if any) and rhs to get something that matches
288	# the syntax of the lookups.
289	$property_and_table = "$prefix$table";
290	print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
291
292	# First try stricter matching.
293	$file = $utf8::stricter_to_file_of{$property_and_table};
294
295	# If didn't find it, try again with looser matching by editing
296	# out the applicable characters on the rhs and looking up
297	# again.
298	if (! defined $file) {
299	$table =~ s/ [_\s-] //xg;
300	$property_and_table = "$prefix$table";
301	print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
302	$file = $utf8::loose_to_file_of{$property_and_table};
303	}
304
305	# Add the constant and go fetch it in.
306	if (defined $file) {
307	if ($utf8::why_deprecated{$file}) {
308	warnings::warnif('deprecated', "Use of '$type' in \\p{} or \\P{} is deprecated because: $utf8::why_deprecated{$file};");
309	}
310	$file= "$unicore_dir/lib/$file.pl";
311	last GETFILE;
312	}
313	print STDERR __LINE__, ": didn't find $property_and_table\n" if DEBUG;
314
315	##
316	## See if it's a user-level "To".
317	##
318
319	my $caller0 = caller(0);
320
321	if (defined $caller0 && $type =~ /^To(?:\w+)$/) {
322	my $map = $caller0 . "::" . $type;
323
324	if (exists &{$map}) {
325	no strict 'refs';
326
327	$list = &{$map};
328	last GETFILE;
329	}
330	}
331
332	##
333	## Last attempt -- see if it's a standard "To" name
334	## (e.g. "ToLower") ToTitle is used by ucfirst().
335	## The user-level way to access ToDigit() and ToFold()
336	## is to use Unicode::UCD.
337	##
338	if ($type =~ /^To(Digit\|Fold\|Lower\|Title\|Upper)$/) {
339	$file = "$unicore_dir/To/$1.pl";
340	## would like to test to see if $file actually exists....
341	last GETFILE;
342	}
343
344	##
345	## If we reach this line, it's because we couldn't figure
346	## out what to do with $type. Ouch.
347	##
348
349	return $type;
cf25bb62 JH	350	}
cf25bb62 JH	351
99870f4d KW	352	if (defined $file) {
	353	print STDERR __LINE__, ": found it (file='$file')\n" if DEBUG;
	354
	355	##
	356	## If we reach here, it was due to a 'last GETFILE' above
	357	## (exception: user-defined properties and mappings), so we
	358	## have a filename, so now we load it if we haven't already.
	359	## If we have, return the cached results. The cache key is the
	360	## class and file to load.
	361	##
	362	my $found = $Cache{$class, $file};
	363	if ($found and ref($found) eq $class) {
	364	print STDERR __LINE__, ": Returning cached '$file' for \\p{$type}\n" if DEBUG;
	365	return $found;
	366	}
	367
	368	local $@;
	369	local $!;
	370	$list = do $file; die $@ if $@;
0a0ffbce	371	}
cf25bb62	372
99870f4d	373	$ListSorted = 1; ## we know that these lists are sorted
cf25bb62 JH	374	}
cf25bb62 JH	375
99870f4d KW	376	my $extras;
	377	my $bits = $minbits;
	378
	379	my $ORIG = $list;
	380	if ($list) {
	381	my @tmp = split(/^/m, $list);
	382	my %seen;
	383	no warnings;
	384	$extras = join '', grep /^[^0-9a-fA-F]/, @tmp;
	385	$list = join '',
	386	map { $_->[1] }
	387	sort { $a->[0] <=> $b->[0] }
	388	map { /^([0-9a-fA-F]+)/; [ CORE::hex($1), $_ ] }
	389	grep { /^([0-9a-fA-F]+)/ and not $seen{$1}++ } @tmp; # XXX doesn't do ranges right
	390	}
a0ed51b3	391
99870f4d KW	392	if ($none) {
	393	my $hextra = sprintf "%04x", $none + 1;
	394	$list =~ s/\tXXXX$/\t$hextra/mg;
	395	}
a0ed51b3	396
99870f4d KW	397	if ($minbits != 1 && $minbits < 32) { # not binary property
	398	my $top = 0;
	399	while ($list =~ /^([0-9a-fA-F]+)(?:[\t]([0-9a-fA-F]+)?)(?:[ \t]([0-9a-fA-F]+))?/mg) {
	400	my $min = CORE::hex $1;
	401	my $max = defined $2 ? CORE::hex $2 : $min;
	402	my $val = defined $3 ? CORE::hex $3 : 0;
	403	$val += $max - $min if defined $3;
	404	$top = $val if $val > $top;
	405	}
	406	my $topbits =
	407	$top > 0xffff ? 32 :
	408	$top > 0xff ? 16 : 8;
	409	$bits = $topbits if $bits < $topbits;
	410	}
a0ed51b3	411
99870f4d KW	412	my @extras;
	413	if ($extras) {
	414	for my $x ($extras) {
	415	pos $x = 0;
	416	while ($x =~ /^([^0-9a-fA-F\n])(.*)/mg) {
	417	my $char = $1;
	418	my $name = $2;
	419	print STDERR __LINE__, ": $1 => $2\n" if DEBUG;
	420	if ($char =~ /[-+!&]/) {
	421	my ($c,$t) = split(/::/, $name, 2); # bogus use of ::, really
	422	my $subobj;
	423	if ($c eq 'utf8') {
	424	$subobj = utf8->SWASHNEW($t, "", $minbits, 0);
	425	}
	426	elsif (exists &$name) {
	427	$subobj = utf8->SWASHNEW($name, "", $minbits, 0);
	428	}
	429	elsif ($c =~ /^([0-9a-fA-F]+)/) {
	430	$subobj = utf8->SWASHNEW("", $c, $minbits, 0);
	431	}
	432	return $subobj unless ref $subobj;
	433	push @extras, $name => $subobj;
	434	$bits = $subobj->{BITS} if $bits < $subobj->{BITS};
	435	}
	436	}
	437	}
	438	}
a0ed51b3	439
99870f4d KW	440	if (DEBUG) {
	441	print STDERR __LINE__, ": CLASS = $class, TYPE => $type, BITS => $bits, NONE => $none";
	442	print STDERR "\nLIST =>\n$list" if defined $list;
	443	print STDERR "\nEXTRAS =>\n$extras" if defined $extras;
	444	print STDERR "\n";
	445	}
a0ed51b3	446
99870f4d KW	447	my $SWASH = bless {
	448	TYPE => $type,
	449	BITS => $bits,
	450	EXTRAS => $extras,
	451	LIST => $list,
	452	NONE => $none,
	453	@extras,
	454	} => $class;
	455
	456	if ($file) {
	457	$Cache{$class, $file} = $SWASH;
	458	}
5beb625e	459
99870f4d	460	return $SWASH;
5beb625e	461	}
a0ed51b3 LW	462	}
a0ed51b3 LW	463
979f2922	464	# Now SWASHGET is recasted into a C function S_swash_get (see utf8.c).
a0ed51b3 LW	465
a0ed51b3 LW	466	1;