Commit | Line | Data |
---|---|---|
68dc0745 | 1 | =head1 NAME |
2 | ||
d92eb7b0 | 3 | perlfaq4 - Data Manipulation ($Revision: 1.49 $, $Date: 1999/05/23 20:37:49 $) |
68dc0745 | 4 | |
5 | =head1 DESCRIPTION | |
6 | ||
a6dd486b | 7 | The section of the FAQ answers questions related to the manipulation |
68dc0745 | 8 | of data as numbers, dates, strings, arrays, hashes, and miscellaneous |
9 | data issues. | |
10 | ||
11 | =head1 Data: Numbers | |
12 | ||
46fc3d4c | 13 | =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)? |
14 | ||
5a964f20 | 15 | The infinite set that a mathematician thinks of as the real numbers can |
a6dd486b | 16 | only be approximated on a computer, since the computer only has a finite |
5a964f20 TC |
17 | number of bits to store an infinite number of, um, numbers. |
18 | ||
46fc3d4c | 19 | Internally, your computer represents floating-point numbers in binary. |
92c2ed05 GS |
20 | Floating-point numbers read in from a file or appearing as literals |
21 | in your program are converted from their decimal floating-point | |
a6dd486b | 22 | representation (eg, 19.95) to an internal binary representation. |
46fc3d4c | 23 | |
24 | However, 19.95 can't be precisely represented as a binary | |
25 | floating-point number, just like 1/3 can't be exactly represented as a | |
26 | decimal floating-point number. The computer's binary representation | |
27 | of 19.95, therefore, isn't exactly 19.95. | |
28 | ||
29 | When a floating-point number gets printed, the binary floating-point | |
30 | representation is converted back to decimal. These decimal numbers | |
31 | are displayed in either the format you specify with printf(), or the | |
a6dd486b | 32 | current output format for numbers. (See L<perlvar/"$#"> if you use |
46fc3d4c | 33 | print. C<$#> has a different default value in Perl5 than it did in |
87275199 | 34 | Perl4. Changing C<$#> yourself is deprecated.) |
46fc3d4c | 35 | |
36 | This affects B<all> computer languages that represent decimal | |
37 | floating-point numbers in binary, not just Perl. Perl provides | |
38 | arbitrary-precision decimal numbers with the Math::BigFloat module | |
39 | (part of the standard Perl distribution), but mathematical operations | |
40 | are consequently slower. | |
41 | ||
80ba158a | 42 | If precision is important, such as when dealing with money, it's good |
1affb2ee MS |
43 | to work with integers and then divide at the last possible moment. |
44 | For example, work in pennies (1995) instead of dollars and cents | |
6b927632 | 45 | (19.95) and divide by 100 at the end. |
1affb2ee | 46 | |
46fc3d4c | 47 | To get rid of the superfluous digits, just use a format (eg, |
48 | C<printf("%.2f", 19.95)>) to get the required precision. | |
65acb1b1 | 49 | See L<perlop/"Floating-point Arithmetic">. |
46fc3d4c | 50 | |
68dc0745 | 51 | =head2 Why isn't my octal data interpreted correctly? |
52 | ||
53 | Perl only understands octal and hex numbers as such when they occur | |
33ce146f PP |
54 | as literals in your program. Octal literals in perl must start with |
55 | a leading "0" and hexadecimal literals must start with a leading "0x". | |
56 | If they are read in from somewhere and assigned, no automatic | |
57 | conversion takes place. You must explicitly use oct() or hex() if you | |
58 | want the values converted to decimal. oct() interprets | |
68dc0745 | 59 | both hex ("0x350") numbers and octal ones ("0350" or even without the |
60 | leading "0", like "377"), while hex() only converts hexadecimal ones, | |
61 | with or without a leading "0x", like "0x255", "3A", "ff", or "deadbeef". | |
33ce146f PP |
62 | The inverse mapping from decimal to octal can be done with either the |
63 | "%o" or "%O" sprintf() formats. To get from decimal to hex try either | |
64 | the "%x" or the "%X" formats to sprintf(). | |
68dc0745 | 65 | |
66 | This problem shows up most often when people try using chmod(), mkdir(), | |
33ce146f PP |
67 | umask(), or sysopen(), which by widespread tradition typically take |
68 | permissions in octal. | |
68dc0745 | 69 | |
33ce146f | 70 | chmod(644, $file); # WRONG |
68dc0745 | 71 | chmod(0644, $file); # right |
72 | ||
33ce146f PP |
73 | Note the mistake in the first line was specifying the decimal literal |
74 | 644, rather than the intended octal literal 0644. The problem can | |
75 | be seen with: | |
76 | ||
434f7166 | 77 | printf("%#o",644); # prints 01204 |
33ce146f PP |
78 | |
79 | Surely you had not intended C<chmod(01204, $file);> - did you? If you | |
80 | want to use numeric literals as arguments to chmod() et al. then please | |
81 | try to express them as octal constants, that is with a leading zero and | |
82 | with the following digits restricted to the set 0..7. | |
83 | ||
65acb1b1 | 84 | =head2 Does Perl have a round() function? What about ceil() and floor()? Trig functions? |
68dc0745 | 85 | |
92c2ed05 GS |
86 | Remember that int() merely truncates toward 0. For rounding to a |
87 | certain number of digits, sprintf() or printf() is usually the easiest | |
88 | route. | |
89 | ||
90 | printf("%.3f", 3.1415926535); # prints 3.142 | |
68dc0745 | 91 | |
87275199 | 92 | The POSIX module (part of the standard Perl distribution) implements |
68dc0745 | 93 | ceil(), floor(), and a number of other mathematical and trigonometric |
94 | functions. | |
95 | ||
92c2ed05 GS |
96 | use POSIX; |
97 | $ceil = ceil(3.5); # 4 | |
98 | $floor = floor(3.5); # 3 | |
99 | ||
a6dd486b | 100 | In 5.000 to 5.003 perls, trigonometry was done in the Math::Complex |
87275199 | 101 | module. With 5.004, the Math::Trig module (part of the standard Perl |
46fc3d4c | 102 | distribution) implements the trigonometric functions. Internally it |
103 | uses the Math::Complex module and some functions can break out from | |
104 | the real axis into the complex plane, for example the inverse sine of | |
105 | 2. | |
68dc0745 | 106 | |
107 | Rounding in financial applications can have serious implications, and | |
108 | the rounding method used should be specified precisely. In these | |
109 | cases, it probably pays not to trust whichever system rounding is | |
110 | being used by Perl, but to instead implement the rounding function you | |
111 | need yourself. | |
112 | ||
65acb1b1 TC |
113 | To see why, notice how you'll still have an issue on half-way-point |
114 | alternation: | |
115 | ||
116 | for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i} | |
117 | ||
118 | 0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7 | |
119 | 0.8 0.8 0.9 0.9 1.0 1.0 | |
120 | ||
121 | Don't blame Perl. It's the same as in C. IEEE says we have to do this. | |
122 | Perl numbers whose absolute values are integers under 2**31 (on 32 bit | |
123 | machines) will work pretty much like mathematical integers. Other numbers | |
124 | are not guaranteed. | |
125 | ||
68dc0745 | 126 | =head2 How do I convert bits into ints? |
127 | ||
92c2ed05 | 128 | To turn a string of 1s and 0s like C<10110110> into a scalar containing |
d92eb7b0 | 129 | its binary value, use the pack() and unpack() functions (documented in |
87275199 | 130 | L<perlfunc/"pack"> and L<perlfunc/"unpack">): |
68dc0745 | 131 | |
d92eb7b0 GS |
132 | $decimal = unpack('c', pack('B8', '10110110')); |
133 | ||
134 | This packs the string C<10110110> into an eight bit binary structure. | |
87275199 | 135 | This is then unpacked as a character, which returns its ordinal value. |
d92eb7b0 GS |
136 | |
137 | This does the same thing: | |
138 | ||
139 | $decimal = ord(pack('B8', '10110110')); | |
68dc0745 | 140 | |
141 | Here's an example of going the other way: | |
142 | ||
d92eb7b0 | 143 | $binary_string = unpack('B*', "\x29"); |
68dc0745 | 144 | |
65acb1b1 TC |
145 | =head2 Why doesn't & work the way I want it to? |
146 | ||
147 | The behavior of binary arithmetic operators depends on whether they're | |
148 | used on numbers or strings. The operators treat a string as a series | |
149 | of bits and work with that (the string C<"3"> is the bit pattern | |
150 | C<00110011>). The operators work with the binary form of a number | |
151 | (the number C<3> is treated as the bit pattern C<00000011>). | |
152 | ||
153 | So, saying C<11 & 3> performs the "and" operation on numbers (yielding | |
154 | C<1>). Saying C<"11" & "3"> performs the "and" operation on strings | |
155 | (yielding C<"1">). | |
156 | ||
157 | Most problems with C<&> and C<|> arise because the programmer thinks | |
158 | they have a number but really it's a string. The rest arise because | |
159 | the programmer says: | |
160 | ||
161 | if ("\020\020" & "\101\101") { | |
162 | # ... | |
163 | } | |
164 | ||
165 | but a string consisting of two null bytes (the result of C<"\020\020" | |
166 | & "\101\101">) is not a false value in Perl. You need: | |
167 | ||
168 | if ( ("\020\020" & "\101\101") !~ /[^\000]/) { | |
169 | # ... | |
170 | } | |
171 | ||
68dc0745 | 172 | =head2 How do I multiply matrices? |
173 | ||
174 | Use the Math::Matrix or Math::MatrixReal modules (available from CPAN) | |
175 | or the PDL extension (also available from CPAN). | |
176 | ||
177 | =head2 How do I perform an operation on a series of integers? | |
178 | ||
179 | To call a function on each element in an array, and collect the | |
180 | results, use: | |
181 | ||
182 | @results = map { my_func($_) } @array; | |
183 | ||
184 | For example: | |
185 | ||
186 | @triple = map { 3 * $_ } @single; | |
187 | ||
188 | To call a function on each element of an array, but ignore the | |
189 | results: | |
190 | ||
191 | foreach $iterator (@array) { | |
65acb1b1 | 192 | some_func($iterator); |
68dc0745 | 193 | } |
194 | ||
195 | To call a function on each integer in a (small) range, you B<can> use: | |
196 | ||
65acb1b1 | 197 | @results = map { some_func($_) } (5 .. 25); |
68dc0745 | 198 | |
199 | but you should be aware that the C<..> operator creates an array of | |
200 | all integers in the range. This can take a lot of memory for large | |
201 | ranges. Instead use: | |
202 | ||
203 | @results = (); | |
204 | for ($i=5; $i < 500_005; $i++) { | |
65acb1b1 | 205 | push(@results, some_func($i)); |
68dc0745 | 206 | } |
207 | ||
87275199 GS |
208 | This situation has been fixed in Perl5.005. Use of C<..> in a C<for> |
209 | loop will iterate over the range, without creating the entire range. | |
210 | ||
211 | for my $i (5 .. 500_005) { | |
212 | push(@results, some_func($i)); | |
213 | } | |
214 | ||
215 | will not create a list of 500,000 integers. | |
216 | ||
68dc0745 | 217 | =head2 How can I output Roman numerals? |
218 | ||
219 | Get the http://www.perl.com/CPAN/modules/by-module/Roman module. | |
220 | ||
221 | =head2 Why aren't my random numbers random? | |
222 | ||
65acb1b1 TC |
223 | If you're using a version of Perl before 5.004, you must call C<srand> |
224 | once at the start of your program to seed the random number generator. | |
225 | 5.004 and later automatically call C<srand> at the beginning. Don't | |
226 | call C<srand> more than once--you make your numbers less random, rather | |
227 | than more. | |
92c2ed05 | 228 | |
65acb1b1 TC |
229 | Computers are good at being predictable and bad at being random |
230 | (despite appearances caused by bugs in your programs :-). | |
a6dd486b JB |
231 | http://www.perl.com/CPAN/doc/FMTEYEWTK/random , courtesy of Tom |
232 | Phoenix, talks more about this. John von Neumann said, ``Anyone who | |
65acb1b1 TC |
233 | attempts to generate random numbers by deterministic means is, of |
234 | course, living in a state of sin.'' | |
235 | ||
236 | If you want numbers that are more random than C<rand> with C<srand> | |
237 | provides, you should also check out the Math::TrulyRandom module from | |
238 | CPAN. It uses the imperfections in your system's timer to generate | |
239 | random numbers, but this takes quite a while. If you want a better | |
92c2ed05 | 240 | pseudorandom generator than comes with your operating system, look at |
65acb1b1 | 241 | ``Numerical Recipes in C'' at http://www.nr.com/ . |
68dc0745 | 242 | |
243 | =head1 Data: Dates | |
244 | ||
245 | =head2 How do I find the week-of-the-year/day-of-the-year? | |
246 | ||
247 | The day of the year is in the array returned by localtime() (see | |
248 | L<perlfunc/"localtime">): | |
249 | ||
250 | $day_of_year = (localtime(time()))[7]; | |
251 | ||
d92eb7b0 GS |
252 | =head2 How do I find the current century or millennium? |
253 | ||
254 | Use the following simple functions: | |
255 | ||
256 | sub get_century { | |
257 | return int((((localtime(shift || time))[5] + 1999))/100); | |
258 | } | |
259 | sub get_millennium { | |
260 | return 1+int((((localtime(shift || time))[5] + 1899))/1000); | |
261 | } | |
262 | ||
263 | On some systems, you'll find that the POSIX module's strftime() function | |
264 | has been extended in a non-standard way to use a C<%C> format, which they | |
265 | sometimes claim is the "century". It isn't, because on most such systems, | |
266 | this is only the first two digits of the four-digit year, and thus cannot | |
267 | be used to reliably determine the current century or millennium. | |
268 | ||
92c2ed05 | 269 | =head2 How can I compare two dates and find the difference? |
68dc0745 | 270 | |
92c2ed05 GS |
271 | If you're storing your dates as epoch seconds then simply subtract one |
272 | from the other. If you've got a structured date (distinct year, day, | |
d92eb7b0 GS |
273 | month, hour, minute, seconds values), then for reasons of accessibility, |
274 | simplicity, and efficiency, merely use either timelocal or timegm (from | |
275 | the Time::Local module in the standard distribution) to reduce structured | |
276 | dates to epoch seconds. However, if you don't know the precise format of | |
277 | your dates, then you should probably use either of the Date::Manip and | |
278 | Date::Calc modules from CPAN before you go hacking up your own parsing | |
279 | routine to handle arbitrary date formats. | |
68dc0745 | 280 | |
281 | =head2 How can I take a string and turn it into epoch seconds? | |
282 | ||
283 | If it's a regular enough string that it always has the same format, | |
92c2ed05 GS |
284 | you can split it up and pass the parts to C<timelocal> in the standard |
285 | Time::Local module. Otherwise, you should look into the Date::Calc | |
286 | and Date::Manip modules from CPAN. | |
68dc0745 | 287 | |
288 | =head2 How can I find the Julian Day? | |
289 | ||
2a2bf5f4 JH |
290 | Use the Time::JulianDay module (part of the Time-modules bundle |
291 | available from CPAN.) | |
d92eb7b0 | 292 | |
89435c96 MS |
293 | Before you immerse yourself too deeply in this, be sure to verify that |
294 | it is the I<Julian> Day you really want. Are you interested in a way | |
295 | of getting serial days so that you just can tell how many days they | |
296 | are apart or so that you can do also other date arithmetic? If you | |
d92eb7b0 | 297 | are interested in performing date arithmetic, this can be done using |
2a2bf5f4 | 298 | modules Date::Manip or Date::Calc. |
89435c96 MS |
299 | |
300 | There is too many details and much confusion on this issue to cover in | |
301 | this FAQ, but the term is applied (correctly) to a calendar now | |
302 | supplanted by the Gregorian Calendar, with the Julian Calendar failing | |
303 | to adjust properly for leap years on centennial years (among other | |
304 | annoyances). The term is also used (incorrectly) to mean: [1] days in | |
305 | the Gregorian Calendar; and [2] days since a particular starting time | |
306 | or `epoch', usually 1970 in the Unix world and 1980 in the | |
307 | MS-DOS/Windows world. If you find that it is not the first meaning | |
308 | that you really want, then check out the Date::Manip and Date::Calc | |
309 | modules. (Thanks to David Cassell for most of this text.) | |
be94a901 | 310 | |
65acb1b1 TC |
311 | =head2 How do I find yesterday's date? |
312 | ||
313 | The C<time()> function returns the current time in seconds since the | |
d92eb7b0 | 314 | epoch. Take twenty-four hours off that: |
65acb1b1 TC |
315 | |
316 | $yesterday = time() - ( 24 * 60 * 60 ); | |
317 | ||
318 | Then you can pass this to C<localtime()> and get the individual year, | |
319 | month, day, hour, minute, seconds values. | |
320 | ||
d92eb7b0 GS |
321 | Note very carefully that the code above assumes that your days are |
322 | twenty-four hours each. For most people, there are two days a year | |
323 | when they aren't: the switch to and from summer time throws this off. | |
324 | A solution to this issue is offered by Russ Allbery. | |
325 | ||
326 | sub yesterday { | |
327 | my $now = defined $_[0] ? $_[0] : time; | |
328 | my $then = $now - 60 * 60 * 24; | |
329 | my $ndst = (localtime $now)[8] > 0; | |
330 | my $tdst = (localtime $then)[8] > 0; | |
331 | $then - ($tdst - $ndst) * 60 * 60; | |
332 | } | |
333 | # Should give you "this time yesterday" in seconds since epoch relative to | |
334 | # the first argument or the current time if no argument is given and | |
335 | # suitable for passing to localtime or whatever else you need to do with | |
336 | # it. $ndst is whether we're currently in daylight savings time; $tdst is | |
337 | # whether the point 24 hours ago was in daylight savings time. If $tdst | |
338 | # and $ndst are the same, a boundary wasn't crossed, and the correction | |
339 | # will subtract 0. If $tdst is 1 and $ndst is 0, subtract an hour more | |
340 | # from yesterday's time since we gained an extra hour while going off | |
341 | # daylight savings time. If $tdst is 0 and $ndst is 1, subtract a | |
342 | # negative hour (add an hour) to yesterday's time since we lost an hour. | |
343 | # | |
344 | # All of this is because during those days when one switches off or onto | |
345 | # DST, a "day" isn't 24 hours long; it's either 23 or 25. | |
346 | # | |
347 | # The explicit settings of $ndst and $tdst are necessary because localtime | |
348 | # only says it returns the system tm struct, and the system tm struct at | |
87275199 | 349 | # least on Solaris doesn't guarantee any particular positive value (like, |
d92eb7b0 GS |
350 | # say, 1) for isdst, just a positive value. And that value can |
351 | # potentially be negative, if DST information isn't available (this sub | |
352 | # just treats those cases like no DST). | |
353 | # | |
354 | # Note that between 2am and 3am on the day after the time zone switches | |
355 | # off daylight savings time, the exact hour of "yesterday" corresponding | |
356 | # to the current hour is not clearly defined. Note also that if used | |
357 | # between 2am and 3am the day after the change to daylight savings time, | |
358 | # the result will be between 3am and 4am of the previous day; it's | |
359 | # arguable whether this is correct. | |
360 | # | |
361 | # This sub does not attempt to deal with leap seconds (most things don't). | |
362 | # | |
363 | # Copyright relinquished 1999 by Russ Allbery <rra@stanford.edu> | |
364 | # This code is in the public domain | |
365 | ||
87275199 | 366 | =head2 Does Perl have a Year 2000 problem? Is Perl Y2K compliant? |
68dc0745 | 367 | |
65acb1b1 TC |
368 | Short answer: No, Perl does not have a Year 2000 problem. Yes, Perl is |
369 | Y2K compliant (whatever that means). The programmers you've hired to | |
370 | use it, however, probably are not. | |
371 | ||
372 | Long answer: The question belies a true understanding of the issue. | |
373 | Perl is just as Y2K compliant as your pencil--no more, and no less. | |
374 | Can you use your pencil to write a non-Y2K-compliant memo? Of course | |
375 | you can. Is that the pencil's fault? Of course it isn't. | |
92c2ed05 | 376 | |
87275199 | 377 | The date and time functions supplied with Perl (gmtime and localtime) |
65acb1b1 TC |
378 | supply adequate information to determine the year well beyond 2000 |
379 | (2038 is when trouble strikes for 32-bit machines). The year returned | |
90fdbbb7 | 380 | by these functions when used in a list context is the year minus 1900. |
65acb1b1 TC |
381 | For years between 1910 and 1999 this I<happens> to be a 2-digit decimal |
382 | number. To avoid the year 2000 problem simply do not treat the year as | |
383 | a 2-digit number. It isn't. | |
68dc0745 | 384 | |
5a964f20 | 385 | When gmtime() and localtime() are used in scalar context they return |
68dc0745 | 386 | a timestamp string that contains a fully-expanded year. For example, |
387 | C<$timestamp = gmtime(1005613200)> sets $timestamp to "Tue Nov 13 01:00:00 | |
388 | 2001". There's no year 2000 problem here. | |
389 | ||
5a964f20 TC |
390 | That doesn't mean that Perl can't be used to create non-Y2K compliant |
391 | programs. It can. But so can your pencil. It's the fault of the user, | |
392 | not the language. At the risk of inflaming the NRA: ``Perl doesn't | |
393 | break Y2K, people do.'' See http://language.perl.com/news/y2k.html for | |
394 | a longer exposition. | |
395 | ||
68dc0745 | 396 | =head1 Data: Strings |
397 | ||
398 | =head2 How do I validate input? | |
399 | ||
400 | The answer to this question is usually a regular expression, perhaps | |
5a964f20 | 401 | with auxiliary logic. See the more specific questions (numbers, mail |
68dc0745 | 402 | addresses, etc.) for details. |
403 | ||
404 | =head2 How do I unescape a string? | |
405 | ||
92c2ed05 GS |
406 | It depends just what you mean by ``escape''. URL escapes are dealt |
407 | with in L<perlfaq9>. Shell escapes with the backslash (C<\>) | |
a6dd486b | 408 | character are removed with |
68dc0745 | 409 | |
410 | s/\\(.)/$1/g; | |
411 | ||
92c2ed05 | 412 | This won't expand C<"\n"> or C<"\t"> or any other special escapes. |
68dc0745 | 413 | |
414 | =head2 How do I remove consecutive pairs of characters? | |
415 | ||
92c2ed05 | 416 | To turn C<"abbcccd"> into C<"abccd">: |
68dc0745 | 417 | |
d92eb7b0 GS |
418 | s/(.)\1/$1/g; # add /s to include newlines |
419 | ||
420 | Here's a solution that turns "abbcccd" to "abcd": | |
421 | ||
422 | y///cs; # y == tr, but shorter :-) | |
68dc0745 | 423 | |
424 | =head2 How do I expand function calls in a string? | |
425 | ||
426 | This is documented in L<perlref>. In general, this is fraught with | |
427 | quoting and readability problems, but it is possible. To interpolate | |
5a964f20 | 428 | a subroutine call (in list context) into a string: |
68dc0745 | 429 | |
430 | print "My sub returned @{[mysub(1,2,3)]} that time.\n"; | |
431 | ||
432 | If you prefer scalar context, similar chicanery is also useful for | |
433 | arbitrary expressions: | |
434 | ||
435 | print "That yields ${\($n + 5)} widgets\n"; | |
436 | ||
92c2ed05 GS |
437 | Version 5.004 of Perl had a bug that gave list context to the |
438 | expression in C<${...}>, but this is fixed in version 5.005. | |
439 | ||
440 | See also ``How can I expand variables in text strings?'' in this | |
441 | section of the FAQ. | |
46fc3d4c | 442 | |
68dc0745 | 443 | =head2 How do I find matching/nesting anything? |
444 | ||
92c2ed05 GS |
445 | This isn't something that can be done in one regular expression, no |
446 | matter how complicated. To find something between two single | |
447 | characters, a pattern like C</x([^x]*)x/> will get the intervening | |
448 | bits in $1. For multiple ones, then something more like | |
449 | C</alpha(.*?)omega/> would be needed. But none of these deals with | |
450 | nested patterns, nor can they. For that you'll have to write a | |
451 | parser. | |
452 | ||
453 | If you are serious about writing a parser, there are a number of | |
6a2af475 GS |
454 | modules or oddities that will make your life a lot easier. There are |
455 | the CPAN modules Parse::RecDescent, Parse::Yapp, and Text::Balanced; | |
83df6a1d JH |
456 | and the byacc program. Starting from perl 5.8 the Text::Balanced |
457 | is part of the standard distribution. | |
68dc0745 | 458 | |
92c2ed05 GS |
459 | One simple destructive, inside-out approach that you might try is to |
460 | pull out the smallest nesting parts one at a time: | |
5a964f20 | 461 | |
d92eb7b0 | 462 | while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) { |
5a964f20 TC |
463 | # do something with $1 |
464 | } | |
465 | ||
65acb1b1 TC |
466 | A more complicated and sneaky approach is to make Perl's regular |
467 | expression engine do it for you. This is courtesy Dean Inada, and | |
468 | rather has the nature of an Obfuscated Perl Contest entry, but it | |
469 | really does work: | |
470 | ||
471 | # $_ contains the string to parse | |
472 | # BEGIN and END are the opening and closing markers for the | |
473 | # nested text. | |
c47ff5f1 | 474 | |
65acb1b1 TC |
475 | @( = ('(',''); |
476 | @) = (')',''); | |
477 | ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs; | |
478 | @$ = (eval{/$re/},$@!~/unmatched/); | |
479 | print join("\n",@$[0..$#$]) if( $$[-1] ); | |
480 | ||
68dc0745 | 481 | =head2 How do I reverse a string? |
482 | ||
5a964f20 | 483 | Use reverse() in scalar context, as documented in |
68dc0745 | 484 | L<perlfunc/reverse>. |
485 | ||
486 | $reversed = reverse $string; | |
487 | ||
488 | =head2 How do I expand tabs in a string? | |
489 | ||
5a964f20 | 490 | You can do it yourself: |
68dc0745 | 491 | |
492 | 1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e; | |
493 | ||
87275199 | 494 | Or you can just use the Text::Tabs module (part of the standard Perl |
68dc0745 | 495 | distribution). |
496 | ||
497 | use Text::Tabs; | |
498 | @expanded_lines = expand(@lines_with_tabs); | |
499 | ||
500 | =head2 How do I reformat a paragraph? | |
501 | ||
87275199 | 502 | Use Text::Wrap (part of the standard Perl distribution): |
68dc0745 | 503 | |
504 | use Text::Wrap; | |
505 | print wrap("\t", ' ', @paragraphs); | |
506 | ||
92c2ed05 | 507 | The paragraphs you give to Text::Wrap should not contain embedded |
46fc3d4c | 508 | newlines. Text::Wrap doesn't justify the lines (flush-right). |
509 | ||
68dc0745 | 510 | =head2 How can I access/change the first N letters of a string? |
511 | ||
512 | There are many ways. If you just want to grab a copy, use | |
92c2ed05 | 513 | substr(): |
68dc0745 | 514 | |
515 | $first_byte = substr($a, 0, 1); | |
516 | ||
517 | If you want to modify part of a string, the simplest way is often to | |
518 | use substr() as an lvalue: | |
519 | ||
520 | substr($a, 0, 3) = "Tom"; | |
521 | ||
92c2ed05 | 522 | Although those with a pattern matching kind of thought process will |
a6dd486b | 523 | likely prefer |
68dc0745 | 524 | |
525 | $a =~ s/^.../Tom/; | |
526 | ||
527 | =head2 How do I change the Nth occurrence of something? | |
528 | ||
92c2ed05 GS |
529 | You have to keep track of N yourself. For example, let's say you want |
530 | to change the fifth occurrence of C<"whoever"> or C<"whomever"> into | |
d92eb7b0 GS |
531 | C<"whosoever"> or C<"whomsoever">, case insensitively. These |
532 | all assume that $_ contains the string to be altered. | |
68dc0745 | 533 | |
534 | $count = 0; | |
535 | s{((whom?)ever)}{ | |
536 | ++$count == 5 # is it the 5th? | |
537 | ? "${2}soever" # yes, swap | |
538 | : $1 # renege and leave it there | |
d92eb7b0 | 539 | }ige; |
68dc0745 | 540 | |
5a964f20 TC |
541 | In the more general case, you can use the C</g> modifier in a C<while> |
542 | loop, keeping count of matches. | |
543 | ||
544 | $WANT = 3; | |
545 | $count = 0; | |
d92eb7b0 | 546 | $_ = "One fish two fish red fish blue fish"; |
5a964f20 TC |
547 | while (/(\w+)\s+fish\b/gi) { |
548 | if (++$count == $WANT) { | |
549 | print "The third fish is a $1 one.\n"; | |
5a964f20 TC |
550 | } |
551 | } | |
552 | ||
92c2ed05 | 553 | That prints out: C<"The third fish is a red one."> You can also use a |
5a964f20 TC |
554 | repetition count and repeated pattern like this: |
555 | ||
556 | /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i; | |
557 | ||
68dc0745 | 558 | =head2 How can I count the number of occurrences of a substring within a string? |
559 | ||
a6dd486b | 560 | There are a number of ways, with varying efficiency. If you want a |
68dc0745 | 561 | count of a certain single character (X) within a string, you can use the |
562 | C<tr///> function like so: | |
563 | ||
368c9434 | 564 | $string = "ThisXlineXhasXsomeXx'sXinXit"; |
68dc0745 | 565 | $count = ($string =~ tr/X//); |
d92eb7b0 | 566 | print "There are $count X characters in the string"; |
68dc0745 | 567 | |
568 | This is fine if you are just looking for a single character. However, | |
569 | if you are trying to count multiple character substrings within a | |
570 | larger string, C<tr///> won't work. What you can do is wrap a while() | |
571 | loop around a global pattern match. For example, let's count negative | |
572 | integers: | |
573 | ||
574 | $string = "-9 55 48 -2 23 -76 4 14 -44"; | |
575 | while ($string =~ /-\d+/g) { $count++ } | |
576 | print "There are $count negative numbers in the string"; | |
577 | ||
578 | =head2 How do I capitalize all the words on one line? | |
579 | ||
580 | To make the first letter of each word upper case: | |
3fe9a6f1 | 581 | |
68dc0745 | 582 | $line =~ s/\b(\w)/\U$1/g; |
583 | ||
46fc3d4c | 584 | This has the strange effect of turning "C<don't do it>" into "C<Don'T |
a6dd486b JB |
585 | Do It>". Sometimes you might want this. Other times you might need a |
586 | more thorough solution (Suggested by brian d. foy): | |
46fc3d4c | 587 | |
588 | $string =~ s/ ( | |
589 | (^\w) #at the beginning of the line | |
590 | | # or | |
591 | (\s\w) #preceded by whitespace | |
592 | ) | |
593 | /\U$1/xg; | |
594 | $string =~ /([\w']+)/\u\L$1/g; | |
595 | ||
68dc0745 | 596 | To make the whole line upper case: |
3fe9a6f1 | 597 | |
68dc0745 | 598 | $line = uc($line); |
599 | ||
600 | To force each word to be lower case, with the first letter upper case: | |
3fe9a6f1 | 601 | |
68dc0745 | 602 | $line =~ s/(\w+)/\u\L$1/g; |
603 | ||
5a964f20 TC |
604 | You can (and probably should) enable locale awareness of those |
605 | characters by placing a C<use locale> pragma in your program. | |
92c2ed05 | 606 | See L<perllocale> for endless details on locales. |
5a964f20 | 607 | |
65acb1b1 | 608 | This is sometimes referred to as putting something into "title |
d92eb7b0 | 609 | case", but that's not quite accurate. Consider the proper |
65acb1b1 TC |
610 | capitalization of the movie I<Dr. Strangelove or: How I Learned to |
611 | Stop Worrying and Love the Bomb>, for example. | |
612 | ||
68dc0745 | 613 | =head2 How can I split a [character] delimited string except when inside |
614 | [character]? (Comma-separated files) | |
615 | ||
616 | Take the example case of trying to split a string that is comma-separated | |
617 | into its different fields. (We'll pretend you said comma-separated, not | |
618 | comma-delimited, which is different and almost never what you mean.) You | |
619 | can't use C<split(/,/)> because you shouldn't split if the comma is inside | |
620 | quotes. For example, take a data line like this: | |
621 | ||
622 | SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped" | |
623 | ||
624 | Due to the restriction of the quotes, this is a fairly complex | |
625 | problem. Thankfully, we have Jeffrey Friedl, author of a highly | |
626 | recommended book on regular expressions, to handle these for us. He | |
627 | suggests (assuming your string is contained in $text): | |
628 | ||
629 | @new = (); | |
630 | push(@new, $+) while $text =~ m{ | |
631 | "([^\"\\]*(?:\\.[^\"\\]*)*)",? # groups the phrase inside the quotes | |
632 | | ([^,]+),? | |
633 | | , | |
634 | }gx; | |
635 | push(@new, undef) if substr($text,-1,1) eq ','; | |
636 | ||
46fc3d4c | 637 | If you want to represent quotation marks inside a |
638 | quotation-mark-delimited field, escape them with backslashes (eg, | |
2ceaccd7 | 639 | C<"like \"this\"">. Unescaping them is a task addressed earlier in |
46fc3d4c | 640 | this section. |
641 | ||
87275199 | 642 | Alternatively, the Text::ParseWords module (part of the standard Perl |
68dc0745 | 643 | distribution) lets you say: |
644 | ||
645 | use Text::ParseWords; | |
646 | @new = quotewords(",", 0, $text); | |
647 | ||
a6dd486b | 648 | There's also a Text::CSV (Comma-Separated Values) module on CPAN. |
65acb1b1 | 649 | |
68dc0745 | 650 | =head2 How do I strip blank space from the beginning/end of a string? |
651 | ||
a6dd486b | 652 | Although the simplest approach would seem to be |
68dc0745 | 653 | |
654 | $string =~ s/^\s*(.*?)\s*$/$1/; | |
655 | ||
a6dd486b | 656 | not only is this unnecessarily slow and destructive, it also fails with |
d92eb7b0 | 657 | embedded newlines. It is much faster to do this operation in two steps: |
68dc0745 | 658 | |
659 | $string =~ s/^\s+//; | |
660 | $string =~ s/\s+$//; | |
661 | ||
662 | Or more nicely written as: | |
663 | ||
664 | for ($string) { | |
665 | s/^\s+//; | |
666 | s/\s+$//; | |
667 | } | |
668 | ||
5e3006a4 | 669 | This idiom takes advantage of the C<foreach> loop's aliasing |
5a964f20 TC |
670 | behavior to factor out common code. You can do this |
671 | on several strings at once, or arrays, or even the | |
d92eb7b0 | 672 | values of a hash if you use a slice: |
5a964f20 TC |
673 | |
674 | # trim whitespace in the scalar, the array, | |
675 | # and all the values in the hash | |
676 | foreach ($scalar, @array, @hash{keys %hash}) { | |
677 | s/^\s+//; | |
678 | s/\s+$//; | |
679 | } | |
680 | ||
65acb1b1 TC |
681 | =head2 How do I pad a string with blanks or pad a number with zeroes? |
682 | ||
d92eb7b0 GS |
683 | (This answer contributed by Uri Guttman, with kibitzing from |
684 | Bart Lateur.) | |
65acb1b1 TC |
685 | |
686 | In the following examples, C<$pad_len> is the length to which you wish | |
d92eb7b0 GS |
687 | to pad the string, C<$text> or C<$num> contains the string to be padded, |
688 | and C<$pad_char> contains the padding character. You can use a single | |
689 | character string constant instead of the C<$pad_char> variable if you | |
690 | know what it is in advance. And in the same way you can use an integer in | |
691 | place of C<$pad_len> if you know the pad length in advance. | |
65acb1b1 | 692 | |
d92eb7b0 GS |
693 | The simplest method uses the C<sprintf> function. It can pad on the left |
694 | or right with blanks and on the left with zeroes and it will not | |
695 | truncate the result. The C<pack> function can only pad strings on the | |
696 | right with blanks and it will truncate the result to a maximum length of | |
697 | C<$pad_len>. | |
65acb1b1 | 698 | |
d92eb7b0 GS |
699 | # Left padding a string with blanks (no truncation): |
700 | $padded = sprintf("%${pad_len}s", $text); | |
65acb1b1 | 701 | |
d92eb7b0 GS |
702 | # Right padding a string with blanks (no truncation): |
703 | $padded = sprintf("%-${pad_len}s", $text); | |
65acb1b1 | 704 | |
d92eb7b0 GS |
705 | # Left padding a number with 0 (no truncation): |
706 | $padded = sprintf("%0${pad_len}d", $num); | |
65acb1b1 | 707 | |
d92eb7b0 GS |
708 | # Right padding a string with blanks using pack (will truncate): |
709 | $padded = pack("A$pad_len",$text); | |
65acb1b1 | 710 | |
d92eb7b0 GS |
711 | If you need to pad with a character other than blank or zero you can use |
712 | one of the following methods. They all generate a pad string with the | |
713 | C<x> operator and combine that with C<$text>. These methods do | |
714 | not truncate C<$text>. | |
65acb1b1 | 715 | |
d92eb7b0 | 716 | Left and right padding with any character, creating a new string: |
65acb1b1 | 717 | |
d92eb7b0 GS |
718 | $padded = $pad_char x ( $pad_len - length( $text ) ) . $text; |
719 | $padded = $text . $pad_char x ( $pad_len - length( $text ) ); | |
65acb1b1 | 720 | |
d92eb7b0 | 721 | Left and right padding with any character, modifying C<$text> directly: |
65acb1b1 | 722 | |
d92eb7b0 GS |
723 | substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) ); |
724 | $text .= $pad_char x ( $pad_len - length( $text ) ); | |
65acb1b1 | 725 | |
68dc0745 | 726 | =head2 How do I extract selected columns from a string? |
727 | ||
728 | Use substr() or unpack(), both documented in L<perlfunc>. | |
5a964f20 TC |
729 | If you prefer thinking in terms of columns instead of widths, |
730 | you can use this kind of thing: | |
731 | ||
732 | # determine the unpack format needed to split Linux ps output | |
733 | # arguments are cut columns | |
734 | my $fmt = cut2fmt(8, 14, 20, 26, 30, 34, 41, 47, 59, 63, 67, 72); | |
735 | ||
736 | sub cut2fmt { | |
737 | my(@positions) = @_; | |
738 | my $template = ''; | |
739 | my $lastpos = 1; | |
740 | for my $place (@positions) { | |
741 | $template .= "A" . ($place - $lastpos) . " "; | |
742 | $lastpos = $place; | |
743 | } | |
744 | $template .= "A*"; | |
745 | return $template; | |
746 | } | |
68dc0745 | 747 | |
748 | =head2 How do I find the soundex value of a string? | |
749 | ||
87275199 | 750 | Use the standard Text::Soundex module distributed with Perl. |
a6dd486b | 751 | Before you do so, you may want to determine whether `soundex' is in |
d92eb7b0 GS |
752 | fact what you think it is. Knuth's soundex algorithm compresses words |
753 | into a small space, and so it does not necessarily distinguish between | |
754 | two words which you might want to appear separately. For example, the | |
755 | last names `Knuth' and `Kant' are both mapped to the soundex code K530. | |
756 | If Text::Soundex does not do what you are looking for, you might want | |
757 | to consider the String::Approx module available at CPAN. | |
68dc0745 | 758 | |
759 | =head2 How can I expand variables in text strings? | |
760 | ||
761 | Let's assume that you have a string like: | |
762 | ||
763 | $text = 'this has a $foo in it and a $bar'; | |
5a964f20 TC |
764 | |
765 | If those were both global variables, then this would | |
766 | suffice: | |
767 | ||
65acb1b1 | 768 | $text =~ s/\$(\w+)/${$1}/g; # no /e needed |
68dc0745 | 769 | |
5a964f20 TC |
770 | But since they are probably lexicals, or at least, they could |
771 | be, you'd have to do this: | |
68dc0745 | 772 | |
773 | $text =~ s/(\$\w+)/$1/eeg; | |
65acb1b1 | 774 | die if $@; # needed /ee, not /e |
68dc0745 | 775 | |
5a964f20 TC |
776 | It's probably better in the general case to treat those |
777 | variables as entries in some special hash. For example: | |
778 | ||
779 | %user_defs = ( | |
780 | foo => 23, | |
781 | bar => 19, | |
782 | ); | |
783 | $text =~ s/\$(\w+)/$user_defs{$1}/g; | |
68dc0745 | 784 | |
92c2ed05 | 785 | See also ``How do I expand function calls in a string?'' in this section |
46fc3d4c | 786 | of the FAQ. |
787 | ||
68dc0745 | 788 | =head2 What's wrong with always quoting "$vars"? |
789 | ||
a6dd486b JB |
790 | The problem is that those double-quotes force stringification-- |
791 | coercing numbers and references into strings--even when you | |
792 | don't want them to be strings. Think of it this way: double-quote | |
65acb1b1 TC |
793 | expansion is used to produce new strings. If you already |
794 | have a string, why do you need more? | |
68dc0745 | 795 | |
796 | If you get used to writing odd things like these: | |
797 | ||
798 | print "$var"; # BAD | |
799 | $new = "$old"; # BAD | |
800 | somefunc("$var"); # BAD | |
801 | ||
802 | You'll be in trouble. Those should (in 99.8% of the cases) be | |
803 | the simpler and more direct: | |
804 | ||
805 | print $var; | |
806 | $new = $old; | |
807 | somefunc($var); | |
808 | ||
809 | Otherwise, besides slowing you down, you're going to break code when | |
810 | the thing in the scalar is actually neither a string nor a number, but | |
811 | a reference: | |
812 | ||
813 | func(\@array); | |
814 | sub func { | |
815 | my $aref = shift; | |
816 | my $oref = "$aref"; # WRONG | |
817 | } | |
818 | ||
819 | You can also get into subtle problems on those few operations in Perl | |
820 | that actually do care about the difference between a string and a | |
821 | number, such as the magical C<++> autoincrement operator or the | |
822 | syscall() function. | |
823 | ||
5a964f20 TC |
824 | Stringification also destroys arrays. |
825 | ||
826 | @lines = `command`; | |
827 | print "@lines"; # WRONG - extra blanks | |
828 | print @lines; # right | |
829 | ||
c47ff5f1 | 830 | =head2 Why don't my <<HERE documents work? |
68dc0745 | 831 | |
832 | Check for these three things: | |
833 | ||
834 | =over 4 | |
835 | ||
836 | =item 1. There must be no space after the << part. | |
837 | ||
838 | =item 2. There (probably) should be a semicolon at the end. | |
839 | ||
840 | =item 3. You can't (easily) have any space in front of the tag. | |
841 | ||
842 | =back | |
843 | ||
5a964f20 TC |
844 | If you want to indent the text in the here document, you |
845 | can do this: | |
846 | ||
847 | # all in one | |
848 | ($VAR = <<HERE_TARGET) =~ s/^\s+//gm; | |
849 | your text | |
850 | goes here | |
851 | HERE_TARGET | |
852 | ||
853 | But the HERE_TARGET must still be flush against the margin. | |
854 | If you want that indented also, you'll have to quote | |
855 | in the indentation. | |
856 | ||
857 | ($quote = <<' FINIS') =~ s/^\s+//gm; | |
858 | ...we will have peace, when you and all your works have | |
859 | perished--and the works of your dark master to whom you | |
860 | would deliver us. You are a liar, Saruman, and a corrupter | |
861 | of men's hearts. --Theoden in /usr/src/perl/taint.c | |
862 | FINIS | |
863 | $quote =~ s/\s*--/\n--/; | |
864 | ||
865 | A nice general-purpose fixer-upper function for indented here documents | |
866 | follows. It expects to be called with a here document as its argument. | |
867 | It looks to see whether each line begins with a common substring, and | |
a6dd486b JB |
868 | if so, strips that substring off. Otherwise, it takes the amount of leading |
869 | whitespace found on the first line and removes that much off each | |
5a964f20 TC |
870 | subsequent line. |
871 | ||
872 | sub fix { | |
873 | local $_ = shift; | |
a6dd486b | 874 | my ($white, $leader); # common whitespace and common leading string |
5a964f20 TC |
875 | if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\1\2?.*\n)+$/) { |
876 | ($white, $leader) = ($2, quotemeta($1)); | |
877 | } else { | |
878 | ($white, $leader) = (/^(\s+)/, ''); | |
879 | } | |
880 | s/^\s*?$leader(?:$white)?//gm; | |
881 | return $_; | |
882 | } | |
883 | ||
c8db1d39 | 884 | This works with leading special strings, dynamically determined: |
5a964f20 TC |
885 | |
886 | $remember_the_main = fix<<' MAIN_INTERPRETER_LOOP'; | |
887 | @@@ int | |
888 | @@@ runops() { | |
889 | @@@ SAVEI32(runlevel); | |
890 | @@@ runlevel++; | |
d92eb7b0 | 891 | @@@ while ( op = (*op->op_ppaddr)() ); |
5a964f20 TC |
892 | @@@ TAINT_NOT; |
893 | @@@ return 0; | |
894 | @@@ } | |
895 | MAIN_INTERPRETER_LOOP | |
896 | ||
a6dd486b | 897 | Or with a fixed amount of leading whitespace, with remaining |
5a964f20 TC |
898 | indentation correctly preserved: |
899 | ||
900 | $poem = fix<<EVER_ON_AND_ON; | |
901 | Now far ahead the Road has gone, | |
902 | And I must follow, if I can, | |
903 | Pursuing it with eager feet, | |
904 | Until it joins some larger way | |
905 | Where many paths and errands meet. | |
906 | And whither then? I cannot say. | |
907 | --Bilbo in /usr/src/perl/pp_ctl.c | |
908 | EVER_ON_AND_ON | |
909 | ||
68dc0745 | 910 | =head1 Data: Arrays |
911 | ||
65acb1b1 TC |
912 | =head2 What is the difference between a list and an array? |
913 | ||
914 | An array has a changeable length. A list does not. An array is something | |
915 | you can push or pop, while a list is a set of values. Some people make | |
916 | the distinction that a list is a value while an array is a variable. | |
917 | Subroutines are passed and return lists, you put things into list | |
918 | context, you initialize arrays with lists, and you foreach() across | |
919 | a list. C<@> variables are arrays, anonymous arrays are arrays, arrays | |
920 | in scalar context behave like the number of elements in them, subroutines | |
a6dd486b | 921 | access their arguments through the array C<@_>, and push/pop/shift only work |
65acb1b1 TC |
922 | on arrays. |
923 | ||
924 | As a side note, there's no such thing as a list in scalar context. | |
925 | When you say | |
926 | ||
927 | $scalar = (2, 5, 7, 9); | |
928 | ||
d92eb7b0 GS |
929 | you're using the comma operator in scalar context, so it uses the scalar |
930 | comma operator. There never was a list there at all! This causes the | |
931 | last value to be returned: 9. | |
65acb1b1 | 932 | |
68dc0745 | 933 | =head2 What is the difference between $array[1] and @array[1]? |
934 | ||
a6dd486b | 935 | The former is a scalar value; the latter an array slice, making |
68dc0745 | 936 | it a list with one (scalar) value. You should use $ when you want a |
937 | scalar value (most of the time) and @ when you want a list with one | |
938 | scalar value in it (very, very rarely; nearly never, in fact). | |
939 | ||
940 | Sometimes it doesn't make a difference, but sometimes it does. | |
941 | For example, compare: | |
942 | ||
943 | $good[0] = `some program that outputs several lines`; | |
944 | ||
945 | with | |
946 | ||
947 | @bad[0] = `same program that outputs several lines`; | |
948 | ||
9f1b1f2d GS |
949 | The C<use warnings> pragma and the B<-w> flag will warn you about these |
950 | matters. | |
68dc0745 | 951 | |
d92eb7b0 | 952 | =head2 How can I remove duplicate elements from a list or array? |
68dc0745 | 953 | |
954 | There are several possible ways, depending on whether the array is | |
955 | ordered and whether you wish to preserve the ordering. | |
956 | ||
957 | =over 4 | |
958 | ||
551e1d92 RB |
959 | =item a) |
960 | ||
961 | If @in is sorted, and you want @out to be sorted: | |
5a964f20 | 962 | (this assumes all true values in the array) |
68dc0745 | 963 | |
a4341a65 | 964 | $prev = "not equal to $in[0]"; |
3bc5ef3e | 965 | @out = grep($_ ne $prev && ($prev = $_, 1), @in); |
68dc0745 | 966 | |
c8db1d39 | 967 | This is nice in that it doesn't use much extra memory, simulating |
3bc5ef3e HG |
968 | uniq(1)'s behavior of removing only adjacent duplicates. The ", 1" |
969 | guarantees that the expression is true (so that grep picks it up) | |
970 | even if the $_ is 0, "", or undef. | |
68dc0745 | 971 | |
551e1d92 RB |
972 | =item b) |
973 | ||
974 | If you don't know whether @in is sorted: | |
68dc0745 | 975 | |
976 | undef %saw; | |
977 | @out = grep(!$saw{$_}++, @in); | |
978 | ||
551e1d92 RB |
979 | =item c) |
980 | ||
981 | Like (b), but @in contains only small integers: | |
68dc0745 | 982 | |
983 | @out = grep(!$saw[$_]++, @in); | |
984 | ||
551e1d92 RB |
985 | =item d) |
986 | ||
987 | A way to do (b) without any loops or greps: | |
68dc0745 | 988 | |
989 | undef %saw; | |
990 | @saw{@in} = (); | |
991 | @out = sort keys %saw; # remove sort if undesired | |
992 | ||
551e1d92 RB |
993 | =item e) |
994 | ||
995 | Like (d), but @in contains only small positive integers: | |
68dc0745 | 996 | |
997 | undef @ary; | |
998 | @ary[@in] = @in; | |
87275199 | 999 | @out = grep {defined} @ary; |
68dc0745 | 1000 | |
1001 | =back | |
1002 | ||
65acb1b1 TC |
1003 | But perhaps you should have been using a hash all along, eh? |
1004 | ||
ddbc1f16 | 1005 | =head2 How can I tell whether a certain element is contained in a list or array? |
5a964f20 TC |
1006 | |
1007 | Hearing the word "in" is an I<in>dication that you probably should have | |
1008 | used a hash, not a list or array, to store your data. Hashes are | |
1009 | designed to answer this question quickly and efficiently. Arrays aren't. | |
68dc0745 | 1010 | |
5a964f20 TC |
1011 | That being said, there are several ways to approach this. If you |
1012 | are going to make this query many times over arbitrary string values, | |
1013 | the fastest way is probably to invert the original array and keep an | |
68dc0745 | 1014 | associative array lying about whose keys are the first array's values. |
1015 | ||
1016 | @blues = qw/azure cerulean teal turquoise lapis-lazuli/; | |
1017 | undef %is_blue; | |
1018 | for (@blues) { $is_blue{$_} = 1 } | |
1019 | ||
1020 | Now you can check whether $is_blue{$some_color}. It might have been a | |
1021 | good idea to keep the blues all in a hash in the first place. | |
1022 | ||
1023 | If the values are all small integers, you could use a simple indexed | |
1024 | array. This kind of an array will take up less space: | |
1025 | ||
1026 | @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31); | |
1027 | undef @is_tiny_prime; | |
d92eb7b0 GS |
1028 | for (@primes) { $is_tiny_prime[$_] = 1 } |
1029 | # or simply @istiny_prime[@primes] = (1) x @primes; | |
68dc0745 | 1030 | |
1031 | Now you check whether $is_tiny_prime[$some_number]. | |
1032 | ||
1033 | If the values in question are integers instead of strings, you can save | |
1034 | quite a lot of space by using bit strings instead: | |
1035 | ||
1036 | @articles = ( 1..10, 150..2000, 2017 ); | |
1037 | undef $read; | |
7b8d334a | 1038 | for (@articles) { vec($read,$_,1) = 1 } |
68dc0745 | 1039 | |
1040 | Now check whether C<vec($read,$n,1)> is true for some C<$n>. | |
1041 | ||
1042 | Please do not use | |
1043 | ||
a6dd486b | 1044 | ($is_there) = grep $_ eq $whatever, @array; |
68dc0745 | 1045 | |
1046 | or worse yet | |
1047 | ||
a6dd486b | 1048 | ($is_there) = grep /$whatever/, @array; |
68dc0745 | 1049 | |
1050 | These are slow (checks every element even if the first matches), | |
1051 | inefficient (same reason), and potentially buggy (what if there are | |
d92eb7b0 | 1052 | regex characters in $whatever?). If you're only testing once, then |
65acb1b1 TC |
1053 | use: |
1054 | ||
1055 | $is_there = 0; | |
1056 | foreach $elt (@array) { | |
1057 | if ($elt eq $elt_to_find) { | |
1058 | $is_there = 1; | |
1059 | last; | |
1060 | } | |
1061 | } | |
1062 | if ($is_there) { ... } | |
68dc0745 | 1063 | |
1064 | =head2 How do I compute the difference of two arrays? How do I compute the intersection of two arrays? | |
1065 | ||
1066 | Use a hash. Here's code to do both and more. It assumes that | |
1067 | each element is unique in a given array: | |
1068 | ||
1069 | @union = @intersection = @difference = (); | |
1070 | %count = (); | |
1071 | foreach $element (@array1, @array2) { $count{$element}++ } | |
1072 | foreach $element (keys %count) { | |
1073 | push @union, $element; | |
1074 | push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element; | |
1075 | } | |
1076 | ||
d92eb7b0 | 1077 | Note that this is the I<symmetric difference>, that is, all elements in |
a6dd486b | 1078 | either A or in B but not in both. Think of it as an xor operation. |
d92eb7b0 | 1079 | |
65acb1b1 TC |
1080 | =head2 How do I test whether two arrays or hashes are equal? |
1081 | ||
1082 | The following code works for single-level arrays. It uses a stringwise | |
1083 | comparison, and does not distinguish defined versus undefined empty | |
1084 | strings. Modify if you have other needs. | |
1085 | ||
1086 | $are_equal = compare_arrays(\@frogs, \@toads); | |
1087 | ||
1088 | sub compare_arrays { | |
1089 | my ($first, $second) = @_; | |
9f1b1f2d | 1090 | no warnings; # silence spurious -w undef complaints |
65acb1b1 TC |
1091 | return 0 unless @$first == @$second; |
1092 | for (my $i = 0; $i < @$first; $i++) { | |
1093 | return 0 if $first->[$i] ne $second->[$i]; | |
1094 | } | |
1095 | return 1; | |
1096 | } | |
1097 | ||
1098 | For multilevel structures, you may wish to use an approach more | |
1099 | like this one. It uses the CPAN module FreezeThaw: | |
1100 | ||
1101 | use FreezeThaw qw(cmpStr); | |
1102 | @a = @b = ( "this", "that", [ "more", "stuff" ] ); | |
1103 | ||
1104 | printf "a and b contain %s arrays\n", | |
1105 | cmpStr(\@a, \@b) == 0 | |
1106 | ? "the same" | |
1107 | : "different"; | |
1108 | ||
1109 | This approach also works for comparing hashes. Here | |
1110 | we'll demonstrate two different answers: | |
1111 | ||
1112 | use FreezeThaw qw(cmpStr cmpStrHard); | |
1113 | ||
1114 | %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] ); | |
1115 | $a{EXTRA} = \%b; | |
1116 | $b{EXTRA} = \%a; | |
1117 | ||
1118 | printf "a and b contain %s hashes\n", | |
1119 | cmpStr(\%a, \%b) == 0 ? "the same" : "different"; | |
1120 | ||
1121 | printf "a and b contain %s hashes\n", | |
1122 | cmpStrHard(\%a, \%b) == 0 ? "the same" : "different"; | |
1123 | ||
1124 | ||
1125 | The first reports that both those the hashes contain the same data, | |
1126 | while the second reports that they do not. Which you prefer is left as | |
1127 | an exercise to the reader. | |
1128 | ||
68dc0745 | 1129 | =head2 How do I find the first array element for which a condition is true? |
1130 | ||
1131 | You can use this if you care about the index: | |
1132 | ||
65acb1b1 | 1133 | for ($i= 0; $i < @array; $i++) { |
68dc0745 | 1134 | if ($array[$i] eq "Waldo") { |
1135 | $found_index = $i; | |
1136 | last; | |
1137 | } | |
1138 | } | |
1139 | ||
1140 | Now C<$found_index> has what you want. | |
1141 | ||
1142 | =head2 How do I handle linked lists? | |
1143 | ||
1144 | In general, you usually don't need a linked list in Perl, since with | |
1145 | regular arrays, you can push and pop or shift and unshift at either end, | |
5a964f20 | 1146 | or you can use splice to add and/or remove arbitrary number of elements at |
87275199 | 1147 | arbitrary points. Both pop and shift are both O(1) operations on Perl's |
5a964f20 TC |
1148 | dynamic arrays. In the absence of shifts and pops, push in general |
1149 | needs to reallocate on the order every log(N) times, and unshift will | |
1150 | need to copy pointers each time. | |
68dc0745 | 1151 | |
1152 | If you really, really wanted, you could use structures as described in | |
1153 | L<perldsc> or L<perltoot> and do just what the algorithm book tells you | |
65acb1b1 TC |
1154 | to do. For example, imagine a list node like this: |
1155 | ||
1156 | $node = { | |
1157 | VALUE => 42, | |
1158 | LINK => undef, | |
1159 | }; | |
1160 | ||
1161 | You could walk the list this way: | |
1162 | ||
1163 | print "List: "; | |
1164 | for ($node = $head; $node; $node = $node->{LINK}) { | |
1165 | print $node->{VALUE}, " "; | |
1166 | } | |
1167 | print "\n"; | |
1168 | ||
a6dd486b | 1169 | You could add to the list this way: |
65acb1b1 TC |
1170 | |
1171 | my ($head, $tail); | |
1172 | $tail = append($head, 1); # grow a new head | |
1173 | for $value ( 2 .. 10 ) { | |
1174 | $tail = append($tail, $value); | |
1175 | } | |
1176 | ||
1177 | sub append { | |
1178 | my($list, $value) = @_; | |
1179 | my $node = { VALUE => $value }; | |
1180 | if ($list) { | |
1181 | $node->{LINK} = $list->{LINK}; | |
1182 | $list->{LINK} = $node; | |
1183 | } else { | |
1184 | $_[0] = $node; # replace caller's version | |
1185 | } | |
1186 | return $node; | |
1187 | } | |
1188 | ||
1189 | But again, Perl's built-in are virtually always good enough. | |
68dc0745 | 1190 | |
1191 | =head2 How do I handle circular lists? | |
1192 | ||
1193 | Circular lists could be handled in the traditional fashion with linked | |
1194 | lists, or you could just do something like this with an array: | |
1195 | ||
1196 | unshift(@array, pop(@array)); # the last shall be first | |
1197 | push(@array, shift(@array)); # and vice versa | |
1198 | ||
1199 | =head2 How do I shuffle an array randomly? | |
1200 | ||
45bbf655 JH |
1201 | If you either have Perl 5.8.0 or later installed, or if you have |
1202 | Scalar-List-Utils 1.03 or later installed, you can say: | |
1203 | ||
1204 | use List::Util 'shuffle'; | |
1205 | ||
1206 | @shuffled = shuffle(@list); | |
1207 | ||
1208 | If not, you can use this: | |
5a964f20 TC |
1209 | |
1210 | # fisher_yates_shuffle( \@array ) : | |
1211 | # generate a random permutation of @array in place | |
1212 | sub fisher_yates_shuffle { | |
1213 | my $array = shift; | |
1214 | my $i; | |
1215 | for ($i = @$array; --$i; ) { | |
1216 | my $j = int rand ($i+1); | |
5a964f20 TC |
1217 | @$array[$i,$j] = @$array[$j,$i]; |
1218 | } | |
1219 | } | |
1220 | ||
1221 | fisher_yates_shuffle( \@array ); # permutes @array in place | |
1222 | ||
45bbf655 JH |
1223 | Note that the above implementation shuffles an array in place, |
1224 | unlike the List::Util::shuffle() which takes a list and returns | |
1225 | a new shuffled list. | |
1226 | ||
d92eb7b0 | 1227 | You've probably seen shuffling algorithms that work using splice, |
a6dd486b | 1228 | randomly picking another element to swap the current element with |
68dc0745 | 1229 | |
1230 | srand; | |
1231 | @new = (); | |
1232 | @old = 1 .. 10; # just a demo | |
1233 | while (@old) { | |
1234 | push(@new, splice(@old, rand @old, 1)); | |
1235 | } | |
1236 | ||
5a964f20 TC |
1237 | This is bad because splice is already O(N), and since you do it N times, |
1238 | you just invented a quadratic algorithm; that is, O(N**2). This does | |
1239 | not scale, although Perl is so efficient that you probably won't notice | |
1240 | this until you have rather largish arrays. | |
68dc0745 | 1241 | |
1242 | =head2 How do I process/modify each element of an array? | |
1243 | ||
1244 | Use C<for>/C<foreach>: | |
1245 | ||
1246 | for (@lines) { | |
5a964f20 TC |
1247 | s/foo/bar/; # change that word |
1248 | y/XZ/ZX/; # swap those letters | |
68dc0745 | 1249 | } |
1250 | ||
1251 | Here's another; let's compute spherical volumes: | |
1252 | ||
5a964f20 | 1253 | for (@volumes = @radii) { # @volumes has changed parts |
68dc0745 | 1254 | $_ **= 3; |
1255 | $_ *= (4/3) * 3.14159; # this will be constant folded | |
1256 | } | |
1257 | ||
5a964f20 TC |
1258 | If you want to do the same thing to modify the values of the hash, |
1259 | you may not use the C<values> function, oddly enough. You need a slice: | |
1260 | ||
1261 | for $orbit ( @orbits{keys %orbits} ) { | |
1262 | ($orbit **= 3) *= (4/3) * 3.14159; | |
1263 | } | |
1264 | ||
68dc0745 | 1265 | =head2 How do I select a random element from an array? |
1266 | ||
1267 | Use the rand() function (see L<perlfunc/rand>): | |
1268 | ||
5a964f20 | 1269 | # at the top of the program: |
68dc0745 | 1270 | srand; # not needed for 5.004 and later |
5a964f20 TC |
1271 | |
1272 | # then later on | |
68dc0745 | 1273 | $index = rand @array; |
1274 | $element = $array[$index]; | |
1275 | ||
5a964f20 TC |
1276 | Make sure you I<only call srand once per program, if then>. |
1277 | If you are calling it more than once (such as before each | |
1278 | call to rand), you're almost certainly doing something wrong. | |
1279 | ||
68dc0745 | 1280 | =head2 How do I permute N elements of a list? |
1281 | ||
1282 | Here's a little program that generates all permutations | |
1283 | of all the words on each line of input. The algorithm embodied | |
5a964f20 | 1284 | in the permute() function should work on any list: |
68dc0745 | 1285 | |
1286 | #!/usr/bin/perl -n | |
5a964f20 TC |
1287 | # tsc-permute: permute each word of input |
1288 | permute([split], []); | |
1289 | sub permute { | |
1290 | my @items = @{ $_[0] }; | |
1291 | my @perms = @{ $_[1] }; | |
1292 | unless (@items) { | |
1293 | print "@perms\n"; | |
68dc0745 | 1294 | } else { |
5a964f20 TC |
1295 | my(@newitems,@newperms,$i); |
1296 | foreach $i (0 .. $#items) { | |
1297 | @newitems = @items; | |
1298 | @newperms = @perms; | |
1299 | unshift(@newperms, splice(@newitems, $i, 1)); | |
1300 | permute([@newitems], [@newperms]); | |
68dc0745 | 1301 | } |
1302 | } | |
1303 | } | |
1304 | ||
b8d2732a RH |
1305 | Unfortunately, this algorithm is very inefficient. The Algorithm::Permute |
1306 | module from CPAN runs at least an order of magnitude faster. If you don't | |
1307 | have a C compiler (or a binary distribution of Algorithm::Permute), then | |
1308 | you can use List::Permutor which is written in pure Perl, and is still | |
f8620f40 | 1309 | several times faster than the algorithm above. |
b8d2732a | 1310 | |
68dc0745 | 1311 | =head2 How do I sort an array by (anything)? |
1312 | ||
1313 | Supply a comparison function to sort() (described in L<perlfunc/sort>): | |
1314 | ||
1315 | @list = sort { $a <=> $b } @list; | |
1316 | ||
1317 | The default sort function is cmp, string comparison, which would | |
c47ff5f1 | 1318 | sort C<(1, 2, 10)> into C<(1, 10, 2)>. C<< <=> >>, used above, is |
68dc0745 | 1319 | the numerical comparison operator. |
1320 | ||
1321 | If you have a complicated function needed to pull out the part you | |
1322 | want to sort on, then don't do it inside the sort function. Pull it | |
1323 | out first, because the sort BLOCK can be called many times for the | |
1324 | same element. Here's an example of how to pull out the first word | |
1325 | after the first number on each item, and then sort those words | |
1326 | case-insensitively. | |
1327 | ||
1328 | @idx = (); | |
1329 | for (@data) { | |
1330 | ($item) = /\d+\s*(\S+)/; | |
1331 | push @idx, uc($item); | |
1332 | } | |
1333 | @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ]; | |
1334 | ||
a6dd486b | 1335 | which could also be written this way, using a trick |
68dc0745 | 1336 | that's come to be known as the Schwartzian Transform: |
1337 | ||
1338 | @sorted = map { $_->[0] } | |
1339 | sort { $a->[1] cmp $b->[1] } | |
d92eb7b0 | 1340 | map { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data; |
68dc0745 | 1341 | |
1342 | If you need to sort on several fields, the following paradigm is useful. | |
1343 | ||
1344 | @sorted = sort { field1($a) <=> field1($b) || | |
1345 | field2($a) cmp field2($b) || | |
1346 | field3($a) cmp field3($b) | |
1347 | } @data; | |
1348 | ||
1349 | This can be conveniently combined with precalculation of keys as given | |
1350 | above. | |
1351 | ||
1352 | See http://www.perl.com/CPAN/doc/FMTEYEWTK/sort.html for more about | |
1353 | this approach. | |
1354 | ||
1355 | See also the question below on sorting hashes. | |
1356 | ||
1357 | =head2 How do I manipulate arrays of bits? | |
1358 | ||
1359 | Use pack() and unpack(), or else vec() and the bitwise operations. | |
1360 | ||
1361 | For example, this sets $vec to have bit N set if $ints[N] was set: | |
1362 | ||
1363 | $vec = ''; | |
1364 | foreach(@ints) { vec($vec,$_,1) = 1 } | |
1365 | ||
1366 | And here's how, given a vector in $vec, you can | |
1367 | get those bits into your @ints array: | |
1368 | ||
1369 | sub bitvec_to_list { | |
1370 | my $vec = shift; | |
1371 | my @ints; | |
1372 | # Find null-byte density then select best algorithm | |
1373 | if ($vec =~ tr/\0// / length $vec > 0.95) { | |
1374 | use integer; | |
1375 | my $i; | |
1376 | # This method is faster with mostly null-bytes | |
1377 | while($vec =~ /[^\0]/g ) { | |
1378 | $i = -9 + 8 * pos $vec; | |
1379 | push @ints, $i if vec($vec, ++$i, 1); | |
1380 | push @ints, $i if vec($vec, ++$i, 1); | |
1381 | push @ints, $i if vec($vec, ++$i, 1); | |
1382 | push @ints, $i if vec($vec, ++$i, 1); | |
1383 | push @ints, $i if vec($vec, ++$i, 1); | |
1384 | push @ints, $i if vec($vec, ++$i, 1); | |
1385 | push @ints, $i if vec($vec, ++$i, 1); | |
1386 | push @ints, $i if vec($vec, ++$i, 1); | |
1387 | } | |
1388 | } else { | |
1389 | # This method is a fast general algorithm | |
1390 | use integer; | |
1391 | my $bits = unpack "b*", $vec; | |
1392 | push @ints, 0 if $bits =~ s/^(\d)// && $1; | |
1393 | push @ints, pos $bits while($bits =~ /1/g); | |
1394 | } | |
1395 | return \@ints; | |
1396 | } | |
1397 | ||
1398 | This method gets faster the more sparse the bit vector is. | |
1399 | (Courtesy of Tim Bunce and Winfried Koenig.) | |
1400 | ||
65acb1b1 TC |
1401 | Here's a demo on how to use vec(): |
1402 | ||
1403 | # vec demo | |
1404 | $vector = "\xff\x0f\xef\xfe"; | |
1405 | print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ", | |
1406 | unpack("N", $vector), "\n"; | |
1407 | $is_set = vec($vector, 23, 1); | |
1408 | print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n"; | |
1409 | pvec($vector); | |
1410 | ||
1411 | set_vec(1,1,1); | |
1412 | set_vec(3,1,1); | |
1413 | set_vec(23,1,1); | |
1414 | ||
1415 | set_vec(3,1,3); | |
1416 | set_vec(3,2,3); | |
1417 | set_vec(3,4,3); | |
1418 | set_vec(3,4,7); | |
1419 | set_vec(3,8,3); | |
1420 | set_vec(3,8,7); | |
1421 | ||
1422 | set_vec(0,32,17); | |
1423 | set_vec(1,32,17); | |
1424 | ||
1425 | sub set_vec { | |
1426 | my ($offset, $width, $value) = @_; | |
1427 | my $vector = ''; | |
1428 | vec($vector, $offset, $width) = $value; | |
1429 | print "offset=$offset width=$width value=$value\n"; | |
1430 | pvec($vector); | |
1431 | } | |
1432 | ||
1433 | sub pvec { | |
1434 | my $vector = shift; | |
1435 | my $bits = unpack("b*", $vector); | |
1436 | my $i = 0; | |
1437 | my $BASE = 8; | |
1438 | ||
1439 | print "vector length in bytes: ", length($vector), "\n"; | |
1440 | @bytes = unpack("A8" x length($vector), $bits); | |
1441 | print "bits are: @bytes\n\n"; | |
1442 | } | |
1443 | ||
68dc0745 | 1444 | =head2 Why does defined() return true on empty arrays and hashes? |
1445 | ||
65acb1b1 TC |
1446 | The short story is that you should probably only use defined on scalars or |
1447 | functions, not on aggregates (arrays and hashes). See L<perlfunc/defined> | |
1448 | in the 5.004 release or later of Perl for more detail. | |
68dc0745 | 1449 | |
1450 | =head1 Data: Hashes (Associative Arrays) | |
1451 | ||
1452 | =head2 How do I process an entire hash? | |
1453 | ||
1454 | Use the each() function (see L<perlfunc/each>) if you don't care | |
1455 | whether it's sorted: | |
1456 | ||
5a964f20 | 1457 | while ( ($key, $value) = each %hash) { |
68dc0745 | 1458 | print "$key = $value\n"; |
1459 | } | |
1460 | ||
1461 | If you want it sorted, you'll have to use foreach() on the result of | |
1462 | sorting the keys as shown in an earlier question. | |
1463 | ||
1464 | =head2 What happens if I add or remove keys from a hash while iterating over it? | |
1465 | ||
d92eb7b0 GS |
1466 | Don't do that. :-) |
1467 | ||
1468 | [lwall] In Perl 4, you were not allowed to modify a hash at all while | |
87275199 | 1469 | iterating over it. In Perl 5 you can delete from it, but you still |
d92eb7b0 GS |
1470 | can't add to it, because that might cause a doubling of the hash table, |
1471 | in which half the entries get copied up to the new top half of the | |
87275199 | 1472 | table, at which point you've totally bamboozled the iterator code. |
d92eb7b0 GS |
1473 | Even if the table doesn't double, there's no telling whether your new |
1474 | entry will be inserted before or after the current iterator position. | |
1475 | ||
a6dd486b | 1476 | Either treasure up your changes and make them after the iterator finishes |
d92eb7b0 GS |
1477 | or use keys to fetch all the old keys at once, and iterate over the list |
1478 | of keys. | |
68dc0745 | 1479 | |
1480 | =head2 How do I look up a hash element by value? | |
1481 | ||
1482 | Create a reverse hash: | |
1483 | ||
1484 | %by_value = reverse %by_key; | |
1485 | $key = $by_value{$value}; | |
1486 | ||
1487 | That's not particularly efficient. It would be more space-efficient | |
1488 | to use: | |
1489 | ||
1490 | while (($key, $value) = each %by_key) { | |
1491 | $by_value{$value} = $key; | |
1492 | } | |
1493 | ||
d92eb7b0 GS |
1494 | If your hash could have repeated values, the methods above will only find |
1495 | one of the associated keys. This may or may not worry you. If it does | |
1496 | worry you, you can always reverse the hash into a hash of arrays instead: | |
1497 | ||
1498 | while (($key, $value) = each %by_key) { | |
1499 | push @{$key_list_by_value{$value}}, $key; | |
1500 | } | |
68dc0745 | 1501 | |
1502 | =head2 How can I know how many entries are in a hash? | |
1503 | ||
1504 | If you mean how many keys, then all you have to do is | |
1505 | take the scalar sense of the keys() function: | |
1506 | ||
3fe9a6f1 | 1507 | $num_keys = scalar keys %hash; |
68dc0745 | 1508 | |
a6dd486b | 1509 | The keys() function also resets the iterator, which in void context is |
d92eb7b0 GS |
1510 | faster for tied hashes than would be iterating through the whole |
1511 | hash, one key-value pair at a time. | |
68dc0745 | 1512 | |
1513 | =head2 How do I sort a hash (optionally by value instead of key)? | |
1514 | ||
1515 | Internally, hashes are stored in a way that prevents you from imposing | |
1516 | an order on key-value pairs. Instead, you have to sort a list of the | |
1517 | keys or values: | |
1518 | ||
1519 | @keys = sort keys %hash; # sorted by key | |
1520 | @keys = sort { | |
1521 | $hash{$a} cmp $hash{$b} | |
1522 | } keys %hash; # and by value | |
1523 | ||
1524 | Here we'll do a reverse numeric sort by value, and if two keys are | |
a6dd486b JB |
1525 | identical, sort by length of key, or if that fails, by straight ASCII |
1526 | comparison of the keys (well, possibly modified by your locale--see | |
68dc0745 | 1527 | L<perllocale>). |
1528 | ||
1529 | @keys = sort { | |
1530 | $hash{$b} <=> $hash{$a} | |
1531 | || | |
1532 | length($b) <=> length($a) | |
1533 | || | |
1534 | $a cmp $b | |
1535 | } keys %hash; | |
1536 | ||
1537 | =head2 How can I always keep my hash sorted? | |
1538 | ||
1539 | You can look into using the DB_File module and tie() using the | |
1540 | $DB_BTREE hash bindings as documented in L<DB_File/"In Memory Databases">. | |
5a964f20 | 1541 | The Tie::IxHash module from CPAN might also be instructive. |
68dc0745 | 1542 | |
1543 | =head2 What's the difference between "delete" and "undef" with hashes? | |
1544 | ||
1545 | Hashes are pairs of scalars: the first is the key, the second is the | |
1546 | value. The key will be coerced to a string, although the value can be | |
1547 | any kind of scalar: string, number, or reference. If a key C<$key> is | |
1548 | present in the array, C<exists($key)> will return true. The value for | |
1549 | a given key can be C<undef>, in which case C<$array{$key}> will be | |
1550 | C<undef> while C<$exists{$key}> will return true. This corresponds to | |
1551 | (C<$key>, C<undef>) being in the hash. | |
1552 | ||
1553 | Pictures help... here's the C<%ary> table: | |
1554 | ||
1555 | keys values | |
1556 | +------+------+ | |
1557 | | a | 3 | | |
1558 | | x | 7 | | |
1559 | | d | 0 | | |
1560 | | e | 2 | | |
1561 | +------+------+ | |
1562 | ||
1563 | And these conditions hold | |
1564 | ||
1565 | $ary{'a'} is true | |
1566 | $ary{'d'} is false | |
1567 | defined $ary{'d'} is true | |
1568 | defined $ary{'a'} is true | |
87275199 | 1569 | exists $ary{'a'} is true (Perl5 only) |
68dc0745 | 1570 | grep ($_ eq 'a', keys %ary) is true |
1571 | ||
1572 | If you now say | |
1573 | ||
1574 | undef $ary{'a'} | |
1575 | ||
1576 | your table now reads: | |
1577 | ||
1578 | ||
1579 | keys values | |
1580 | +------+------+ | |
1581 | | a | undef| | |
1582 | | x | 7 | | |
1583 | | d | 0 | | |
1584 | | e | 2 | | |
1585 | +------+------+ | |
1586 | ||
1587 | and these conditions now hold; changes in caps: | |
1588 | ||
1589 | $ary{'a'} is FALSE | |
1590 | $ary{'d'} is false | |
1591 | defined $ary{'d'} is true | |
1592 | defined $ary{'a'} is FALSE | |
87275199 | 1593 | exists $ary{'a'} is true (Perl5 only) |
68dc0745 | 1594 | grep ($_ eq 'a', keys %ary) is true |
1595 | ||
1596 | Notice the last two: you have an undef value, but a defined key! | |
1597 | ||
1598 | Now, consider this: | |
1599 | ||
1600 | delete $ary{'a'} | |
1601 | ||
1602 | your table now reads: | |
1603 | ||
1604 | keys values | |
1605 | +------+------+ | |
1606 | | x | 7 | | |
1607 | | d | 0 | | |
1608 | | e | 2 | | |
1609 | +------+------+ | |
1610 | ||
1611 | and these conditions now hold; changes in caps: | |
1612 | ||
1613 | $ary{'a'} is false | |
1614 | $ary{'d'} is false | |
1615 | defined $ary{'d'} is true | |
1616 | defined $ary{'a'} is false | |
87275199 | 1617 | exists $ary{'a'} is FALSE (Perl5 only) |
68dc0745 | 1618 | grep ($_ eq 'a', keys %ary) is FALSE |
1619 | ||
1620 | See, the whole entry is gone! | |
1621 | ||
1622 | =head2 Why don't my tied hashes make the defined/exists distinction? | |
1623 | ||
1624 | They may or may not implement the EXISTS() and DEFINED() methods | |
1625 | differently. For example, there isn't the concept of undef with hashes | |
1626 | that are tied to DBM* files. This means the true/false tables above | |
1627 | will give different results when used on such a hash. It also means | |
1628 | that exists and defined do the same thing with a DBM* file, and what | |
1629 | they end up doing is not what they do with ordinary hashes. | |
1630 | ||
1631 | =head2 How do I reset an each() operation part-way through? | |
1632 | ||
5a964f20 | 1633 | Using C<keys %hash> in scalar context returns the number of keys in |
68dc0745 | 1634 | the hash I<and> resets the iterator associated with the hash. You may |
1635 | need to do this if you use C<last> to exit a loop early so that when you | |
46fc3d4c | 1636 | re-enter it, the hash iterator has been reset. |
68dc0745 | 1637 | |
1638 | =head2 How can I get the unique keys from two hashes? | |
1639 | ||
d92eb7b0 GS |
1640 | First you extract the keys from the hashes into lists, then solve |
1641 | the "removing duplicates" problem described above. For example: | |
68dc0745 | 1642 | |
1643 | %seen = (); | |
1644 | for $element (keys(%foo), keys(%bar)) { | |
1645 | $seen{$element}++; | |
1646 | } | |
1647 | @uniq = keys %seen; | |
1648 | ||
1649 | Or more succinctly: | |
1650 | ||
1651 | @uniq = keys %{{%foo,%bar}}; | |
1652 | ||
1653 | Or if you really want to save space: | |
1654 | ||
1655 | %seen = (); | |
1656 | while (defined ($key = each %foo)) { | |
1657 | $seen{$key}++; | |
1658 | } | |
1659 | while (defined ($key = each %bar)) { | |
1660 | $seen{$key}++; | |
1661 | } | |
1662 | @uniq = keys %seen; | |
1663 | ||
1664 | =head2 How can I store a multidimensional array in a DBM file? | |
1665 | ||
1666 | Either stringify the structure yourself (no fun), or else | |
1667 | get the MLDBM (which uses Data::Dumper) module from CPAN and layer | |
1668 | it on top of either DB_File or GDBM_File. | |
1669 | ||
1670 | =head2 How can I make my hash remember the order I put elements into it? | |
1671 | ||
1672 | Use the Tie::IxHash from CPAN. | |
1673 | ||
46fc3d4c | 1674 | use Tie::IxHash; |
1675 | tie(%myhash, Tie::IxHash); | |
1676 | for ($i=0; $i<20; $i++) { | |
1677 | $myhash{$i} = 2*$i; | |
1678 | } | |
1679 | @keys = keys %myhash; | |
1680 | # @keys = (0,1,2,3,...) | |
1681 | ||
68dc0745 | 1682 | =head2 Why does passing a subroutine an undefined element in a hash create it? |
1683 | ||
1684 | If you say something like: | |
1685 | ||
1686 | somefunc($hash{"nonesuch key here"}); | |
1687 | ||
1688 | Then that element "autovivifies"; that is, it springs into existence | |
1689 | whether you store something there or not. That's because functions | |
1690 | get scalars passed in by reference. If somefunc() modifies C<$_[0]>, | |
1691 | it has to be ready to write it back into the caller's version. | |
1692 | ||
87275199 | 1693 | This has been fixed as of Perl5.004. |
68dc0745 | 1694 | |
1695 | Normally, merely accessing a key's value for a nonexistent key does | |
1696 | I<not> cause that key to be forever there. This is different than | |
1697 | awk's behavior. | |
1698 | ||
fc36a67e | 1699 | =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays? |
68dc0745 | 1700 | |
65acb1b1 TC |
1701 | Usually a hash ref, perhaps like this: |
1702 | ||
1703 | $record = { | |
1704 | NAME => "Jason", | |
1705 | EMPNO => 132, | |
1706 | TITLE => "deputy peon", | |
1707 | AGE => 23, | |
1708 | SALARY => 37_000, | |
1709 | PALS => [ "Norbert", "Rhys", "Phineas"], | |
1710 | }; | |
1711 | ||
1712 | References are documented in L<perlref> and the upcoming L<perlreftut>. | |
1713 | Examples of complex data structures are given in L<perldsc> and | |
1714 | L<perllol>. Examples of structures and object-oriented classes are | |
1715 | in L<perltoot>. | |
68dc0745 | 1716 | |
1717 | =head2 How can I use a reference as a hash key? | |
1718 | ||
1719 | You can't do this directly, but you could use the standard Tie::Refhash | |
87275199 | 1720 | module distributed with Perl. |
68dc0745 | 1721 | |
1722 | =head1 Data: Misc | |
1723 | ||
1724 | =head2 How do I handle binary data correctly? | |
1725 | ||
1726 | Perl is binary clean, so this shouldn't be a problem. For example, | |
1727 | this works fine (assuming the files are found): | |
1728 | ||
1729 | if (`cat /vmunix` =~ /gzip/) { | |
1730 | print "Your kernel is GNU-zip enabled!\n"; | |
1731 | } | |
1732 | ||
d92eb7b0 GS |
1733 | On less elegant (read: Byzantine) systems, however, you have |
1734 | to play tedious games with "text" versus "binary" files. See | |
1735 | L<perlfunc/"binmode"> or L<perlopentut>. Most of these ancient-thinking | |
1736 | systems are curses out of Microsoft, who seem to be committed to putting | |
1737 | the backward into backward compatibility. | |
68dc0745 | 1738 | |
1739 | If you're concerned about 8-bit ASCII data, then see L<perllocale>. | |
1740 | ||
54310121 | 1741 | If you want to deal with multibyte characters, however, there are |
68dc0745 | 1742 | some gotchas. See the section on Regular Expressions. |
1743 | ||
1744 | =head2 How do I determine whether a scalar is a number/whole/integer/float? | |
1745 | ||
1746 | Assuming that you don't care about IEEE notations like "NaN" or | |
1747 | "Infinity", you probably just want to use a regular expression. | |
1748 | ||
65acb1b1 TC |
1749 | if (/\D/) { print "has nondigits\n" } |
1750 | if (/^\d+$/) { print "is a whole number\n" } | |
1751 | if (/^-?\d+$/) { print "is an integer\n" } | |
1752 | if (/^[+-]?\d+$/) { print "is a +/- integer\n" } | |
1753 | if (/^-?\d+\.?\d*$/) { print "is a real number\n" } | |
1754 | if (/^-?(?:\d+(?:\.\d*)?|\.\d+)$/) { print "is a decimal number" } | |
1755 | if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/) | |
1756 | { print "a C float" } | |
68dc0745 | 1757 | |
5a964f20 TC |
1758 | If you're on a POSIX system, Perl's supports the C<POSIX::strtod> |
1759 | function. Its semantics are somewhat cumbersome, so here's a C<getnum> | |
1760 | wrapper function for more convenient access. This function takes | |
1761 | a string and returns the number it found, or C<undef> for input that | |
1762 | isn't a C float. The C<is_numeric> function is a front end to C<getnum> | |
1763 | if you just want to say, ``Is this a float?'' | |
1764 | ||
1765 | sub getnum { | |
1766 | use POSIX qw(strtod); | |
1767 | my $str = shift; | |
1768 | $str =~ s/^\s+//; | |
1769 | $str =~ s/\s+$//; | |
1770 | $! = 0; | |
1771 | my($num, $unparsed) = strtod($str); | |
1772 | if (($str eq '') || ($unparsed != 0) || $!) { | |
1773 | return undef; | |
1774 | } else { | |
1775 | return $num; | |
1776 | } | |
1777 | } | |
1778 | ||
072dc14b | 1779 | sub is_numeric { defined getnum($_[0]) } |
5a964f20 | 1780 | |
6cecdcac GS |
1781 | Or you could check out the String::Scanf module on CPAN instead. The |
1782 | POSIX module (part of the standard Perl distribution) provides the | |
bf4acbe4 | 1783 | C<strtod> and C<strtol> for converting strings to double and longs, |
6cecdcac | 1784 | respectively. |
68dc0745 | 1785 | |
1786 | =head2 How do I keep persistent data across program calls? | |
1787 | ||
1788 | For some specific applications, you can use one of the DBM modules. | |
65acb1b1 | 1789 | See L<AnyDBM_File>. More generically, you should consult the FreezeThaw, |
83df6a1d JH |
1790 | Storable, or Class::Eroot modules from CPAN. Starting from Perl 5.8 |
1791 | Storable is part of the standard distribution. Here's one example using | |
65acb1b1 TC |
1792 | Storable's C<store> and C<retrieve> functions: |
1793 | ||
1794 | use Storable; | |
1795 | store(\%hash, "filename"); | |
1796 | ||
1797 | # later on... | |
1798 | $href = retrieve("filename"); # by ref | |
1799 | %hash = %{ retrieve("filename") }; # direct to hash | |
68dc0745 | 1800 | |
1801 | =head2 How do I print out or copy a recursive data structure? | |
1802 | ||
65acb1b1 TC |
1803 | The Data::Dumper module on CPAN (or the 5.005 release of Perl) is great |
1804 | for printing out data structures. The Storable module, found on CPAN, | |
1805 | provides a function called C<dclone> that recursively copies its argument. | |
1806 | ||
1807 | use Storable qw(dclone); | |
1808 | $r2 = dclone($r1); | |
68dc0745 | 1809 | |
65acb1b1 TC |
1810 | Where $r1 can be a reference to any kind of data structure you'd like. |
1811 | It will be deeply copied. Because C<dclone> takes and returns references, | |
1812 | you'd have to add extra punctuation if you had a hash of arrays that | |
1813 | you wanted to copy. | |
68dc0745 | 1814 | |
65acb1b1 | 1815 | %newhash = %{ dclone(\%oldhash) }; |
68dc0745 | 1816 | |
1817 | =head2 How do I define methods for every class/object? | |
1818 | ||
1819 | Use the UNIVERSAL class (see L<UNIVERSAL>). | |
1820 | ||
1821 | =head2 How do I verify a credit card checksum? | |
1822 | ||
1823 | Get the Business::CreditCard module from CPAN. | |
1824 | ||
65acb1b1 TC |
1825 | =head2 How do I pack arrays of doubles or floats for XS code? |
1826 | ||
1827 | The kgbpack.c code in the PGPLOT module on CPAN does just this. | |
1828 | If you're doing a lot of float or double processing, consider using | |
1829 | the PDL module from CPAN instead--it makes number-crunching easy. | |
1830 | ||
68dc0745 | 1831 | =head1 AUTHOR AND COPYRIGHT |
1832 | ||
65acb1b1 | 1833 | Copyright (c) 1997-1999 Tom Christiansen and Nathan Torkington. |
5a964f20 TC |
1834 | All rights reserved. |
1835 | ||
5a7beb56 JH |
1836 | This documentation is free; you can redistribute it and/or modify it |
1837 | under the same terms as Perl itself. | |
5a964f20 TC |
1838 | |
1839 | Irrespective of its distribution, all code examples in this file | |
1840 | are hereby placed into the public domain. You are permitted and | |
1841 | encouraged to use this code in your own programs for fun | |
1842 | or for profit as you see fit. A simple comment in the code giving | |
1843 | credit would be courteous but is not required. |