[perl5.git] / lib / charnames.pm

package charnames;
use strict;
use warnings;
use Carp;
our $VERSION = '1.01';

use bytes ();		# for $bytes::hint_bits
$charnames::hint_bits = 0x20000;

my %alias1 = (
		# Icky 3.2 names with parentheses.
		'LINE FEED'		=> 'LINE FEED (LF)',
		'FORM FEED'		=> 'FORM FEED (FF)',
		'CARRIAGE RETURN'	=> 'CARRIAGE RETURN (CR)',
		'NEXT LINE'		=> 'NEXT LINE (NEL)',
		# Convenience.
		'LF'			=> 'LINE FEED (LF)',
		'FF'			=> 'FORM FEED (FF)',
		'CR'			=> 'CARRIAGE RETURN (LF)',
		'NEL'			=> 'NEXT LINE (NEL)',
	        # More convenience.  For futher convencience,
	        # it is suggested some way using using the NamesList
		# aliases is implemented.
	        'ZWNJ'			=> 'ZERO WIDTH NON-JOINER',
	        'ZWJ'			=> 'ZERO WIDTH JOINER',
		'BOM'			=> 'BYTE ORDER MARK',
	    );

my %alias2 = (
		# Pre-3.2 compatibility (only for the first 256 characters).
		'HORIZONTAL TABULATION'	=> 'CHARACTER TABULATION',
		'VERTICAL TABULATION'	=> 'LINE TABULATION',
		'FILE SEPARATOR'	=> 'INFORMATION SEPARATOR FOUR',
		'GROUP SEPARATOR'	=> 'INFORMATION SEPARATOR THREE',
		'RECORD SEPARATOR'	=> 'INFORMATION SEPARATOR TWO',
		'UNIT SEPARATOR'	=> 'INFORMATION SEPARATOR ONE',
		'PARTIAL LINE DOWN'	=> 'PARTIAL LINE FORWARD',
		'PARTIAL LINE UP'	=> 'PARTIAL LINE BACKWARD',
	    );

my $txt;

# This is not optimized in any way yet
sub charnames
{
  my $name = shift;

  if (exists $alias1{$name}) {
      $name = $alias1{$name};
  }
  if (exists $alias2{$name}) {
      require warnings;
      warnings::warnif('deprecated', qq{Unicode character name "$name" is deprecated, use "$alias2{$name}" instead});
      $name = $alias2{$name};
  }

  my $ord;
  my @off;
  my $fname;

  if ($name eq "BYTE ORDER MARK") {
      $fname = $name;
      $ord = 0xFEFF;
  } else {
      ## Suck in the code/name list as a big string.
      ## Lines look like:
      ##     "0052\t\tLATIN CAPITAL LETTER R\n"
      $txt = do "unicore/Name.pl" unless $txt;

      ## @off will hold the index into the code/name string of the start and
      ## end of the name as we find it.
      
      ## If :full, look for the the name exactly
      if ($^H{charnames_full} and $txt =~ /\t\t\Q$name\E$/m) {
	  @off = ($-[0], $+[0]);
      }

      ## If we didn't get above, and :short allowed, look for the short name.
      ## The short name is like "greek:Sigma"
      unless (@off) {
	  if ($^H{charnames_short} and $name =~ /^(.+?):(.+)/s) {
	      my ($script, $cname) = ($1,$2);
	      my $case = ( $cname =~ /[[:upper:]]/ ? "CAPITAL" : "SMALL");
	      if ($txt =~ m/\t\t\U$script\E (?:$case )?LETTER \U\Q$cname\E$/m) {
		  @off = ($-[0], $+[0]);
	      }
	  }
      }
      
      ## If we still don't have it, check for the name among the loaded
      ## scripts.
      if (not @off)
      {
	  my $case = ( $name =~ /[[:upper:]]/ ? "CAPITAL" : "SMALL");
	  for my $script ( @{$^H{charnames_scripts}} )
	  {
	      if ($txt =~ m/\t\t$script (?:$case )?LETTER \U\Q$name\E$/m) {
		  @off = ($-[0], $+[0]);
		  last;
	      }
	  }
      }
      
      ## If we don't have it by now, give up.
      unless (@off) {
	  carp "Unknown charname '$name'";
	  return "\x{FFFD}";
      }
      
      ##
      ## Now know where in the string the name starts.
      ## The code, in hex, is before that.
      ##
      ## The code can be 4-6 characters long, so we've got to sort of
      ## go look for it, just after the newline that comes before $off[0].
      ##
      ## This would be much easier if unicore/Name.pl had info in
      ## a name/code order, instead of code/name order.
      ##
      ## The +1 after the rindex() is to skip past the newline we're finding,
      ## or, if the rindex() fails, to put us to an offset of zero.
      ##
      my $hexstart = rindex($txt, "\n", $off[0]) + 1;

      ## we know where it starts, so turn into number -
      ## the ordinal for the char.
      $ord = hex substr($txt, $hexstart, $off[0] - $hexstart);
  }

  if ($^H & $bytes::hint_bits) {	# "use bytes" in effect?
    use bytes;
    return chr $ord if $ord <= 255;
    my $hex = sprintf "%04x", $ord;
    if (not defined $fname) {
	$fname = substr $txt, $off[0] + 2, $off[1] - $off[0] - 2;
    }
    croak "Character 0x$hex with name '$fname' is above 0xFF";
  }

  no warnings 'utf8'; # allow even illegal characters
  return pack "U", $ord;
}

sub import
{
  shift; ## ignore class name

  if (not @_)
  {
      carp("`use charnames' needs explicit imports list");
  }
  $^H |= $charnames::hint_bits;
  $^H{charnames} = \&charnames ;

  ##
  ## fill %h keys with our @_ args.
  ##
  my %h;
  @h{@_} = (1) x @_;

  $^H{charnames_full} = delete $h{':full'};
  $^H{charnames_short} = delete $h{':short'};
  $^H{charnames_scripts} = [map uc, keys %h];

  ##
  ## If utf8? warnings are enabled, and some scripts were given,
  ## see if at least we can find one letter of each script.
  ##
  if (warnings::enabled('utf8') && @{$^H{charnames_scripts}})
  {
      $txt = do "unicore/Name.pl" unless $txt;

      for my $script (@{$^H{charnames_scripts}})
      {
          if (not $txt =~ m/\t\t$script (?:CAPITAL |SMALL )?LETTER /) {
              warnings::warn('utf8',  "No such script: '$script'");
          }
      }
  }
}

require Unicode::UCD; # for Unicode::UCD::_getcode()

my %viacode;

sub viacode
{
    if (@_ != 1) {
        carp "charnames::viacode() expects one argument";
        return ()
    }

    my $arg = shift;
    my $code = Unicode::UCD::_getcode($arg);

    my $hex;

    if (defined $code) {
        $hex = sprintf "%04X", $arg;
    } else {
        carp("unexpected arg \"$arg\" to charnames::viacode()");
        return;
    }

    if ($code > 0x10FFFF) {
	carp "Unicode characters only allocated up to 0x10FFFF (you asked for $hex)";
	return;
    }

    return $viacode{$hex} if exists $viacode{$hex};

    $txt = do "unicore/Name.pl" unless $txt;

    if ($txt =~ m/^$hex\t\t(.+)/m) {
        return $viacode{$hex} = $1;
    } else {
        return;
    }
}

my %vianame;

sub vianame
{
    if (@_ != 1) {
        carp "charnames::vianame() expects one name argument";
        return ()
    }

    my $arg = shift;

    return $vianame{$arg} if exists $vianame{$arg};

    $txt = do "unicore/Name.pl" unless $txt;

    if ($txt =~ m/^([0-9A-F]+)\t\t($arg)/m) {
        return $vianame{$arg} = hex $1;
    } else {
        return;
    }
}


1;
__END__

=head1 NAME

charnames - define character names for C<\N{named}> string literal escapes

=head1 SYNOPSIS

  use charnames ':full';
  print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";

  use charnames ':short';
  print "\N{greek:Sigma} is an upper-case sigma.\n";

  use charnames qw(cyrillic greek);
  print "\N{sigma} is Greek sigma, and \N{be} is Cyrillic b.\n";

  print charnames::viacode(0x1234); # prints "ETHIOPIC SYLLABLE SEE"
  printf "%04X", charnames::vianame("GOTHIC LETTER AHSA"); # prints "10330"

=head1 DESCRIPTION

Pragma C<use charnames> supports arguments C<:full>, C<:short> and
script names.  If C<:full> is present, for expansion of
C<\N{CHARNAME}}> string C<CHARNAME> is first looked in the list of
standard Unicode names of chars.  If C<:short> is present, and
C<CHARNAME> has the form C<SCRIPT:CNAME>, then C<CNAME> is looked up
as a letter in script C<SCRIPT>.  If pragma C<use charnames> is used
with script name arguments, then for C<\N{CHARNAME}}> the name
C<CHARNAME> is looked up as a letter in the given scripts (in the
specified order).

For lookup of C<CHARNAME> inside a given script C<SCRIPTNAME>
this pragma looks for the names

  SCRIPTNAME CAPITAL LETTER CHARNAME
  SCRIPTNAME SMALL LETTER CHARNAME
  SCRIPTNAME LETTER CHARNAME

in the table of standard Unicode names.  If C<CHARNAME> is lowercase,
then the C<CAPITAL> variant is ignored, otherwise the C<SMALL> variant
is ignored.

Note that C<\N{...}> is compile-time, it's a special form of string
constant used inside double-quoted strings: in other words, you cannot
use variables inside the C<\N{...}>.  If you want similar run-time
functionality, use charnames::vianame().

For the C0 and C1 control characters (U+0000..U+001F, U+0080..U+009F)
as of Unicode 3.1, there are no official Unicode names but you can
use instead the ISO 6429 names (LINE FEED, ESCAPE, and so forth).
In Unicode 3.2 some naming changes will happen since ISO 6429 has been
updated.  Also note that the U+UU80, U+0081, U+0084, and U+0099
do not have names even in ISO 6429.

=head1 CUSTOM TRANSLATORS

The mechanism of translation of C<\N{...}> escapes is general and not
hardwired into F<charnames.pm>.  A module can install custom
translations (inside the scope which C<use>s the module) with the
following magic incantation:

    use charnames ();		# for $charnames::hint_bits
    sub import {
	shift;
	$^H |= $charnames::hint_bits;
	$^H{charnames} = \&translator;
    }

Here translator() is a subroutine which takes C<CHARNAME> as an
argument, and returns text to insert into the string instead of the
C<\N{CHARNAME}> escape.  Since the text to insert should be different
in C<bytes> mode and out of it, the function should check the current
state of C<bytes>-flag as in:

    use bytes ();			# for $bytes::hint_bits
    sub translator {
	if ($^H & $bytes::hint_bits) {
	    return bytes_translator(@_);
	}
	else {
	    return utf8_translator(@_);
	}
    }

=head1 charnames::viacode(code)

Returns the full name of the character indicated by the numeric code.
The example

    print charnames::viacode(0x2722);

prints "FOUR TEARDROP-SPOKED ASTERISK".

Returns undef if no name is known for the code.

This works only for the standard names, and does not yet apply 
to custom translators.

Notice that the name returned for of U+FEFF is "ZERO WIDTH NO-BREAK
SPACE", not "BYTE ORDER MARK".

=head1 charnames::vianame(code)

Returns the code point indicated by the name.
The example

    printf "%04X", charnames::vianame("FOUR TEARDROP-SPOKED ASTERISK");

prints "2722".

Returns undef if no name is known for the name.

This works only for the standard names, and does not yet aply 
to custom translators.

=head1 ALIASES

A few aliases have been defined for convenience: instead of having
to use the official names

    LINE FEED (LF)
    FORM FEED (FF)
    CARRIAGE RETURN (CR)
    NEXT LINE (NEL)

(yes, with parentheses) one can use

    LINE FEED
    FORM FEED
    CARRIAGE RETURN
    NEXT LINE
    LF
    FF
    CR
    NEL

One can also use

    BYTE ORDER MARK
    BOM

and

    ZWNJ
    ZWJ

for ZERO WIDTH NON-JOINER and ZERO WIDTH JOINER.

For backward compatibility one can use the old names for
certain C0 and C1 controls

    old                         new

    HORIZONTAL TABULATION       CHARACTER TABULATION
    VERTICAL TABULATION         LINE TABULATION
    FILE SEPARATOR              INFORMATION SEPARATOR FOUR
    GROUP SEPARATOR             INFORMATION SEPARATOR THREE
    RECORD SEPARATOR            INFORMATION SEPARATOR TWO
    UNIT SEPARATOR              INFORMATION SEPARATOR ONE
    PARTIAL LINE DOWN           PARTIAL LINE FORWARD
    PARTIAL LINE UP             PARTIAL LINE BACKWARD

but the old names in addition to giving the character
will also give a warning about being deprecated.

=head1 ILLEGAL CHARACTERS

If you ask for a character that does not exist, a warning is given
and the Unicode I<replacement character> "\x{FFFD}" is returned.

=head1 BUGS

Since evaluation of the translation function happens in a middle of
compilation (of a string literal), the translation function should not
do any C<eval>s or C<require>s.  This restriction should be lifted in
a future version of Perl.

=cut
Commit	Line	Data
423cee85	1	package charnames;
b177ca84 JF	2	use strict;
	3	use warnings;
	4	use Carp;
	5	our $VERSION = '1.01';
b75c8c73	6
d5448623 GS	7	use bytes (); # for $bytes::hint_bits
d5448623 GS	8	$charnames::hint_bits = 0x20000;
423cee85	9
52ea3e69 JH	10	my %alias1 = (
	11	# Icky 3.2 names with parentheses.
	12	'LINE FEED' => 'LINE FEED (LF)',
	13	'FORM FEED' => 'FORM FEED (FF)',
	14	'CARRIAGE RETURN' => 'CARRIAGE RETURN (CR)',
	15	'NEXT LINE' => 'NEXT LINE (NEL)',
	16	# Convenience.
	17	'LF' => 'LINE FEED (LF)',
	18	'FF' => 'FORM FEED (FF)',
	19	'CR' => 'CARRIAGE RETURN (LF)',
51e9e896	20	'NEL' => 'NEXT LINE (NEL)',
24b5d5cc JH	21	# More convenience. For futher convencience,
	22	# it is suggested some way using using the NamesList
	23	# aliases is implemented.
	24	'ZWNJ' => 'ZERO WIDTH NON-JOINER',
	25	'ZWJ' => 'ZERO WIDTH JOINER',
52ea3e69 JH	26	'BOM' => 'BYTE ORDER MARK',
	27	);
	28
	29	my %alias2 = (
	30	# Pre-3.2 compatibility (only for the first 256 characters).
	31	'HORIZONTAL TABULATION' => 'CHARACTER TABULATION',
	32	'VERTICAL TABULATION' => 'LINE TABULATION',
	33	'FILE SEPARATOR' => 'INFORMATION SEPARATOR FOUR',
	34	'GROUP SEPARATOR' => 'INFORMATION SEPARATOR THREE',
	35	'RECORD SEPARATOR' => 'INFORMATION SEPARATOR TWO',
	36	'UNIT SEPARATOR' => 'INFORMATION SEPARATOR ONE',
	37	'PARTIAL LINE DOWN' => 'PARTIAL LINE FORWARD',
	38	'PARTIAL LINE UP' => 'PARTIAL LINE BACKWARD',
	39	);
	40
423cee85 JH	41	my $txt;
	42
	43	# This is not optimized in any way yet
b177ca84 JF	44	sub charnames
	45	{
	46	my $name = shift;
	47
52ea3e69 JH	48	if (exists $alias1{$name}) {
	49	$name = $alias1{$name};
	50	}
	51	if (exists $alias2{$name}) {
	52	require warnings;
	53	warnings::warnif('deprecated', qq{Unicode character name "$name" is deprecated, use "$alias2{$name}" instead});
	54	$name = $alias2{$name};
	55	}
b177ca84	56
52ea3e69	57	my $ord;
423cee85	58	my @off;
52ea3e69 JH	59	my $fname;
	60
	61	if ($name eq "BYTE ORDER MARK") {
	62	$fname = $name;
d7d589a8	63	$ord = 0xFEFF;
52ea3e69 JH	64	} else {
	65	## Suck in the code/name list as a big string.
	66	## Lines look like:
	67	## "0052\t\tLATIN CAPITAL LETTER R\n"
	68	$txt = do "unicore/Name.pl" unless $txt;
b177ca84	69
52ea3e69 JH	70	## @off will hold the index into the code/name string of the start and
	71	## end of the name as we find it.
	72
	73	## If :full, look for the the name exactly
	74	if ($^H{charnames_full} and $txt =~ /\t\t\Q$name\E$/m) {
	75	@off = ($-[0], $+[0]);
423cee85	76	}
b177ca84	77
52ea3e69 JH	78	## If we didn't get above, and :short allowed, look for the short name.
	79	## The short name is like "greek:Sigma"
	80	unless (@off) {
	81	if ($^H{charnames_short} and $name =~ /^(.+?):(.+)/s) {
	82	my ($script, $cname) = ($1,$2);
	83	my $case = ( $cname =~ /[[:upper:]]/ ? "CAPITAL" : "SMALL");
	84	if ($txt =~ m/\t\t\U$script\E (?:$case )?LETTER \U\Q$cname\E$/m) {
	85	@off = ($-[0], $+[0]);
	86	}
	87	}
	88	}
	89
	90	## If we still don't have it, check for the name among the loaded
	91	## scripts.
	92	if (not @off)
b177ca84	93	{
52ea3e69 JH	94	my $case = ( $name =~ /[[:upper:]]/ ? "CAPITAL" : "SMALL");
	95	for my $script ( @{$^H{charnames_scripts}} )
	96	{
	97	if ($txt =~ m/\t\t$script (?:$case )?LETTER \U\Q$name\E$/m) {
	98	@off = ($-[0], $+[0]);
	99	last;
	100	}
	101	}
b177ca84	102	}
52ea3e69 JH	103
	104	## If we don't have it by now, give up.
	105	unless (@off) {
	106	carp "Unknown charname '$name'";
	107	return "\x{FFFD}";
	108	}
	109
	110	##
	111	## Now know where in the string the name starts.
274085e3	112	## The code, in hex, is before that.
52ea3e69 JH	113	##
	114	## The code can be 4-6 characters long, so we've got to sort of
	115	## go look for it, just after the newline that comes before $off[0].
	116	##
	117	## This would be much easier if unicore/Name.pl had info in
	118	## a name/code order, instead of code/name order.
	119	##
	120	## The +1 after the rindex() is to skip past the newline we're finding,
	121	## or, if the rindex() fails, to put us to an offset of zero.
	122	##
	123	my $hexstart = rindex($txt, "\n", $off[0]) + 1;
	124
	125	## we know where it starts, so turn into number -
	126	## the ordinal for the char.
	127	$ord = hex substr($txt, $hexstart, $off[0] - $hexstart);
423cee85	128	}
b177ca84	129
d5448623	130	if ($^H & $bytes::hint_bits) { # "use bytes" in effect?
8058d7ab	131	use bytes;
d41ff1b8	132	return chr $ord if $ord <= 255;
f0175764	133	my $hex = sprintf "%04x", $ord;
52ea3e69 JH	134	if (not defined $fname) {
	135	$fname = substr $txt, $off[0] + 2, $off[1] - $off[0] - 2;
	136	}
f0175764	137	croak "Character 0x$hex with name '$fname' is above 0xFF";
423cee85	138	}
f0175764	139
52ea3e69	140	no warnings 'utf8'; # allow even illegal characters
bfa383d6	141	return pack "U", $ord;
423cee85 JH	142	}
423cee85 JH	143
b177ca84 JF	144	sub import
	145	{
	146	shift; ## ignore class name
	147
	148	if (not @_)
	149	{
	150	carp("`use charnames' needs explicit imports list");
	151	}
d5448623	152	$^H \|= $charnames::hint_bits;
423cee85	153	$^H{charnames} = \&charnames ;
b177ca84 JF	154
	155	##
	156	## fill %h keys with our @_ args.
	157	##
423cee85 JH	158	my %h;
423cee85 JH	159	@h{@_} = (1) x @_;
b177ca84	160
423cee85 JH	161	$^H{charnames_full} = delete $h{':full'};
	162	$^H{charnames_short} = delete $h{':short'};
	163	$^H{charnames_scripts} = [map uc, keys %h];
b177ca84 JF	164
	165	##
	166	## If utf8? warnings are enabled, and some scripts were given,
	167	## see if at least we can find one letter of each script.
	168	##
	169	if (warnings::enabled('utf8') && @{$^H{charnames_scripts}})
	170	{
	171	$txt = do "unicore/Name.pl" unless $txt;
	172
	173	for my $script (@{$^H{charnames_scripts}})
	174	{
	175	if (not $txt =~ m/\t\t$script (?:CAPITAL \|SMALL )?LETTER /) {
	176	warnings::warn('utf8', "No such script: '$script'");
	177	}
	178	}
bd62941a	179	}
423cee85 JH	180	}
423cee85 JH	181
f0175764 JH	182	require Unicode::UCD; # for Unicode::UCD::_getcode()
f0175764 JH	183
4e2cda5d JH	184	my %viacode;
4e2cda5d JH	185
b177ca84 JF	186	sub viacode
	187	{
	188	if (@_ != 1) {
274085e3	189	carp "charnames::viacode() expects one argument";
b177ca84 JF	190	return ()
b177ca84 JF	191	}
f0175764	192
b177ca84	193	my $arg = shift;
f0175764	194	my $code = Unicode::UCD::_getcode($arg);
b177ca84 JF	195
b177ca84 JF	196	my $hex;
f0175764 JH	197
f0175764 JH	198	if (defined $code) {
b177ca84 JF	199	$hex = sprintf "%04X", $arg;
	200	} else {
	201	carp("unexpected arg \"$arg\" to charnames::viacode()");
daf0d493	202	return;
b177ca84 JF	203	}
b177ca84 JF	204
f0175764 JH	205	if ($code > 0x10FFFF) {
f0175764 JH	206	carp "Unicode characters only allocated up to 0x10FFFF (you asked for $hex)";
11881cb4	207	return;
f0175764 JH	208	}
f0175764 JH	209
4e2cda5d JH	210	return $viacode{$hex} if exists $viacode{$hex};
4e2cda5d JH	211
b177ca84 JF	212	$txt = do "unicore/Name.pl" unless $txt;
	213
	214	if ($txt =~ m/^$hex\t\t(.+)/m) {
4e2cda5d	215	return $viacode{$hex} = $1;
b177ca84	216	} else {
11881cb4	217	return;
daf0d493 JH	218	}
	219	}
	220
4e2cda5d JH	221	my %vianame;
4e2cda5d JH	222
daf0d493 JH	223	sub vianame
	224	{
	225	if (@_ != 1) {
	226	carp "charnames::vianame() expects one name argument";
	227	return ()
	228	}
	229
	230	my $arg = shift;
	231
4e2cda5d JH	232	return $vianame{$arg} if exists $vianame{$arg};
4e2cda5d JH	233
daf0d493 JH	234	$txt = do "unicore/Name.pl" unless $txt;
	235
	236	if ($txt =~ m/^([0-9A-F]+)\t\t($arg)/m) {
4e2cda5d	237	return $vianame{$arg} = hex $1;
daf0d493 JH	238	} else {
daf0d493 JH	239	return;
b177ca84 JF	240	}
	241	}
	242
423cee85 JH	243
	244	1;
	245	__END__
	246
	247	=head1 NAME
	248
274085e3	249	charnames - define character names for C<\N{named}> string literal escapes
423cee85 JH	250
	251	=head1 SYNOPSIS
	252
	253	use charnames ':full';
4a2d328f	254	print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
423cee85 JH	255
423cee85 JH	256	use charnames ':short';
4a2d328f	257	print "\N{greek:Sigma} is an upper-case sigma.\n";
423cee85 JH	258
423cee85 JH	259	use charnames qw(cyrillic greek);
4a2d328f	260	print "\N{sigma} is Greek sigma, and \N{be} is Cyrillic b.\n";
423cee85	261
a23c04e4 JH	262	print charnames::viacode(0x1234); # prints "ETHIOPIC SYLLABLE SEE"
a23c04e4 JH	263	printf "%04X", charnames::vianame("GOTHIC LETTER AHSA"); # prints "10330"
b177ca84	264
423cee85 JH	265	=head1 DESCRIPTION
	266
	267	Pragma C<use charnames> supports arguments C<:full>, C<:short> and
	268	script names. If C<:full> is present, for expansion of
4a2d328f	269	C<\N{CHARNAME}}> string C<CHARNAME> is first looked in the list of
423cee85 JH	270	standard Unicode names of chars. If C<:short> is present, and
	271	C<CHARNAME> has the form C<SCRIPT:CNAME>, then C<CNAME> is looked up
	272	as a letter in script C<SCRIPT>. If pragma C<use charnames> is used
4a2d328f	273	with script name arguments, then for C<\N{CHARNAME}}> the name
423cee85 JH	274	C<CHARNAME> is looked up as a letter in the given scripts (in the
	275	specified order).
	276
	277	For lookup of C<CHARNAME> inside a given script C<SCRIPTNAME>
d5448623	278	this pragma looks for the names
423cee85 JH	279
	280	SCRIPTNAME CAPITAL LETTER CHARNAME
	281	SCRIPTNAME SMALL LETTER CHARNAME
	282	SCRIPTNAME LETTER CHARNAME
	283
	284	in the table of standard Unicode names. If C<CHARNAME> is lowercase,
daf0d493 JH	285	then the C<CAPITAL> variant is ignored, otherwise the C<SMALL> variant
	286	is ignored.
	287
	288	Note that C<\N{...}> is compile-time, it's a special form of string
	289	constant used inside double-quoted strings: in other words, you cannot
4e2cda5d	290	use variables inside the C<\N{...}>. If you want similar run-time
daf0d493	291	functionality, use charnames::vianame().
423cee85	292
301a3cda JH	293	For the C0 and C1 control characters (U+0000..U+001F, U+0080..U+009F)
	294	as of Unicode 3.1, there are no official Unicode names but you can
	295	use instead the ISO 6429 names (LINE FEED, ESCAPE, and so forth).
	296	In Unicode 3.2 some naming changes will happen since ISO 6429 has been
	297	updated. Also note that the U+UU80, U+0081, U+0084, and U+0099
	298	do not have names even in ISO 6429.
	299
423cee85 JH	300	=head1 CUSTOM TRANSLATORS
423cee85 JH	301
d5448623	302	The mechanism of translation of C<\N{...}> escapes is general and not
423cee85	303	hardwired into F<charnames.pm>. A module can install custom
d5448623	304	translations (inside the scope which C<use>s the module) with the
423cee85 JH	305	following magic incantation:
423cee85 JH	306
d5448623 GS	307	use charnames (); # for $charnames::hint_bits
	308	sub import {
	309	shift;
	310	$^H \|= $charnames::hint_bits;
	311	$^H{charnames} = \&translator;
	312	}
423cee85 JH	313
	314	Here translator() is a subroutine which takes C<CHARNAME> as an
	315	argument, and returns text to insert into the string instead of the
4a2d328f	316	C<\N{CHARNAME}> escape. Since the text to insert should be different
d5448623 GS	317	in C<bytes> mode and out of it, the function should check the current
	318	state of C<bytes>-flag as in:
	319
	320	use bytes (); # for $bytes::hint_bits
	321	sub translator {
	322	if ($^H & $bytes::hint_bits) {
	323	return bytes_translator(@_);
	324	}
	325	else {
	326	return utf8_translator(@_);
	327	}
423cee85	328	}
423cee85	329
b177ca84 JF	330	=head1 charnames::viacode(code)
	331
	332	Returns the full name of the character indicated by the numeric code.
	333	The example
	334
	335	print charnames::viacode(0x2722);
	336
	337	prints "FOUR TEARDROP-SPOKED ASTERISK".
	338
daf0d493 JH	339	Returns undef if no name is known for the code.
daf0d493 JH	340
274085e3	341	This works only for the standard names, and does not yet apply
daf0d493 JH	342	to custom translators.
daf0d493 JH	343
274085e3 PN	344	Notice that the name returned for of U+FEFF is "ZERO WIDTH NO-BREAK
	345	SPACE", not "BYTE ORDER MARK".
	346
daf0d493 JH	347	=head1 charnames::vianame(code)
	348
	349	Returns the code point indicated by the name.
	350	The example
	351
	352	printf "%04X", charnames::vianame("FOUR TEARDROP-SPOKED ASTERISK");
	353
	354	prints "2722".
	355
	356	Returns undef if no name is known for the name.
b177ca84 JF	357
	358	This works only for the standard names, and does not yet aply
	359	to custom translators.
	360
52ea3e69 JH	361	=head1 ALIASES
	362
	363	A few aliases have been defined for convenience: instead of having
	364	to use the official names
	365
	366	LINE FEED (LF)
	367	FORM FEED (FF)
	368	CARRIAGE RETURN (CR)
	369	NEXT LINE (NEL)
	370
	371	(yes, with parentheses) one can use
	372
	373	LINE FEED
	374	FORM FEED
	375	CARRIAGE RETURN
	376	NEXT LINE
	377	LF
	378	FF
	379	CR
	380	NEL
	381
	382	One can also use
	383
	384	BYTE ORDER MARK
	385	BOM
	386
24b5d5cc JH	387	and
	388
	389	ZWNJ
	390	ZWJ
	391
	392	for ZERO WIDTH NON-JOINER and ZERO WIDTH JOINER.
52ea3e69 JH	393
	394	For backward compatibility one can use the old names for
	395	certain C0 and C1 controls
	396
	397	old new
	398
	399	HORIZONTAL TABULATION CHARACTER TABULATION
	400	VERTICAL TABULATION LINE TABULATION
	401	FILE SEPARATOR INFORMATION SEPARATOR FOUR
	402	GROUP SEPARATOR INFORMATION SEPARATOR THREE
	403	RECORD SEPARATOR INFORMATION SEPARATOR TWO
	404	UNIT SEPARATOR INFORMATION SEPARATOR ONE
	405	PARTIAL LINE DOWN PARTIAL LINE FORWARD
	406	PARTIAL LINE UP PARTIAL LINE BACKWARD
	407
	408	but the old names in addition to giving the character
	409	will also give a warning about being deprecated.
	410
f0175764 JH	411	=head1 ILLEGAL CHARACTERS
f0175764 JH	412
a23c04e4 JH	413	If you ask for a character that does not exist, a warning is given
a23c04e4 JH	414	and the Unicode I<replacement character> "\x{FFFD}" is returned.
f0175764	415
423cee85 JH	416	=head1 BUGS
	417
	418	Since evaluation of the translation function happens in a middle of
	419	compilation (of a string literal), the translation function should not
	420	do any C<eval>s or C<require>s. This restriction should be lifted in
	421	a future version of Perl.
	422
	423	=cut