[perl5.git] / lib / Digest.pm

package Digest;

use strict;
use vars qw($VERSION %MMAP $AUTOLOAD);

$VERSION = "1.12";

%MMAP = (
  "SHA-1"      => ["Digest::SHA1", ["Digest::SHA", 1], ["Digest::SHA2", 1]],
  "SHA-224"    => [["Digest::SHA", 224]],
  "SHA-256"    => [["Digest::SHA", 256], ["Digest::SHA2", 256]],
  "SHA-384"    => [["Digest::SHA", 384], ["Digest::SHA2", 384]],
  "SHA-512"    => [["Digest::SHA", 512], ["Digest::SHA2", 512]],
  "HMAC-MD5"   => "Digest::HMAC_MD5",
  "HMAC-SHA-1" => "Digest::HMAC_SHA1",
  "CRC-16"     => [["Digest::CRC", type => "crc16"]],
  "CRC-32"     => [["Digest::CRC", type => "crc32"]],
  "CRC-CCITT"  => [["Digest::CRC", type => "crcccitt"]],
);

sub new
{
    shift;  # class ignored
    my $algorithm = shift;
    my $impl = $MMAP{$algorithm} || do {
	$algorithm =~ s/\W+//;
	"Digest::$algorithm";
    };
    $impl = [$impl] unless ref($impl);
    my $err;
    for  (@$impl) {
	my $class = $_;
	my @args;
	($class, @args) = @$class if ref($class);
	no strict 'refs';
	unless (exists ${"$class\::"}{"VERSION"}) {
	    eval "require $class";
	    if ($@) {
		$err ||= $@;
		next;
	    }
	}
	return $class->new(@args, @_);
    }
    die $err;
}

sub AUTOLOAD
{
    my $class = shift;
    my $algorithm = substr($AUTOLOAD, rindex($AUTOLOAD, '::')+2);
    $class->new($algorithm, @_);
}

1;

__END__

=head1 NAME

Digest - Modules that calculate message digests

=head1 SYNOPSIS

  $md5  = Digest->new("MD5");
  $sha1 = Digest->new("SHA-1");
  $sha256 = Digest->new("SHA-256");
  $sha384 = Digest->new("SHA-384");
  $sha512 = Digest->new("SHA-512");

  $hmac = Digest->HMAC_MD5($key);

=head1 DESCRIPTION

The C<Digest::> modules calculate digests, also called "fingerprints"
or "hashes", of some data, called a message.  The digest is (usually)
some small/fixed size string.  The actual size of the digest depend of
the algorithm used.  The message is simply a sequence of arbitrary
bytes or bits.

An important property of the digest algorithms is that the digest is
I<likely> to change if the message change in some way.  Another
property is that digest functions are one-way functions, i.e. it
should be I<hard> to find a message that correspond to some given
digest.  Algorithms differ in how "likely" and how "hard", as well as
how efficient they are to compute.

All C<Digest::> modules provide the same programming interface.  A
functional interface for simple use, as well as an object oriented
interface that can handle messages of arbitrary length and which can
read files directly.

The digest can be delivered in three formats:

=over 8

=item I<binary>

This is the most compact form, but it is not well suited for printing
or embedding in places that can't handle arbitrary data.

=item I<hex>

A twice as long string of lowercase hexadecimal digits.

=item I<base64>

A string of portable printable characters.  This is the base64 encoded
representation of the digest with any trailing padding removed.  The
string will be about 30% longer than the binary version.
L<MIME::Base64> tells you more about this encoding.

=back


The functional interface is simply importable functions with the same
name as the algorithm.  The functions take the message as argument and
return the digest.  Example:

  use Digest::MD5 qw(md5);
  $digest = md5($message);

There are also versions of the functions with "_hex" or "_base64"
appended to the name, which returns the digest in the indicated form.

=head1 OO INTERFACE

The following methods are available for all C<Digest::> modules:

=over 4

=item $ctx = Digest->XXX($arg,...)

=item $ctx = Digest->new(XXX => $arg,...)

=item $ctx = Digest::XXX->new($arg,...)

The constructor returns some object that encapsulate the state of the
message-digest algorithm.  You can add data to the object and finally
ask for the digest.  The "XXX" should of course be replaced by the proper
name of the digest algorithm you want to use.

The two first forms are simply syntactic sugar which automatically
load the right module on first use.  The second form allow you to use
algorithm names which contains letters which are not legal perl
identifiers, e.g. "SHA-1".  If no implementation for the given algorithm
can be found, then an exception is raised.

If new() is called as an instance method (i.e. $ctx->new) it will just
reset the state the object to the state of a newly created object.  No
new object is created in this case, and the return value is the
reference to the object (i.e. $ctx).

=item $other_ctx = $ctx->clone

The clone method creates a copy of the digest state object and returns
a reference to the copy.

=item $ctx->reset

This is just an alias for $ctx->new.

=item $ctx->add( $data, ... )

The $data provided as argument are appended to the message we
calculate the digest for.  The return value is the $ctx object itself.

=item $ctx->addfile( $io_handle )

The $io_handle is read until EOF and the content is appended to the
message we calculate the digest for.  The return value is the $ctx
object itself.

=item $ctx->add_bits( $data, $nbits )

=item $ctx->add_bits( $bitstring )

The bits provided are appended to the message we calculate the digest
for.  The return value is the $ctx object itself.

The two argument form of add_bits() will add the first $nbits bits
from data.  For the last potentially partial byte only the high order
C<< $nbits % 8 >> bits are used.  If $nbits is greater than C<<
length($data) * 8 >>, then this method would do the same as C<<
$ctx->add($data) >>, i.e. $nbits is silently ignored.

The one argument form of add_bits() takes a $bitstring of "1" and "0"
chars as argument.  It's a shorthand for C<< $ctx->add_bits(pack("B*",
$bitstring), length($bitstring)) >>.

This example shows two calls that should have the same effect:

   $ctx->add_bits("111100001010");
   $ctx->add_bits("\xF0\xA0", 12);

Most digest algorithms are byte based.  For those it is not possible
to add bits that are not a multiple of 8, and the add_bits() method
will croak if you try.

=item $ctx->digest

Return the binary digest for the message.

Note that the C<digest> operation is effectively a destructive,
read-once operation. Once it has been performed, the $ctx object is
automatically C<reset> and can be used to calculate another digest
value.  Call $ctx->clone->digest if you want to calculate the digest
without resetting the digest state.

=item $ctx->hexdigest

Same as $ctx->digest, but will return the digest in hexadecimal form.

=item $ctx->b64digest

Same as $ctx->digest, but will return the digest as a base64 encoded
string.

=back

=head1 Digest speed

This table should give some indication on the relative speed of
different algorithms.  It is sorted by throughput based on a benchmark
done with of some implementations of this API:

 Algorithm      Size    Implementation                  MB/s

 MD4            128     Digest::MD4 v1.3               165.0
 MD5            128     Digest::MD5 v2.33               98.8
 SHA-256        256     Digest::SHA2 v1.1.0             66.7
 SHA-1          160     Digest::SHA v4.3.1              58.9
 SHA-1          160     Digest::SHA1 v2.10              48.8
 SHA-256        256     Digest::SHA v4.3.1              41.3
 Haval-256      256     Digest::Haval256 v1.0.4         39.8
 SHA-384        384     Digest::SHA2 v1.1.0             19.6
 SHA-512        512     Digest::SHA2 v1.1.0             19.3
 SHA-384        384     Digest::SHA v4.3.1              19.2
 SHA-512        512     Digest::SHA v4.3.1              19.2
 Whirlpool      512     Digest::Whirlpool v1.0.2        13.0
 MD2            128     Digest::MD2 v2.03                9.5

 Adler-32        32     Digest::Adler32 v0.03            1.3
 CRC-16          16     Digest::CRC v0.05                1.1
 CRC-32          32     Digest::CRC v0.05                1.1
 MD5            128     Digest::Perl::MD5 v1.5           1.0
 CRC-CCITT       16     Digest::CRC v0.05                0.8

These numbers was achieved Apr 2004 with ActivePerl-5.8.3 running
under Linux on a P4 2.8 GHz CPU.  The last 5 entries differ by being
pure perl implementations of the algorithms, which explains why they
are so slow.

=head1 SEE ALSO

L<Digest::Adler32>, L<Digest::CRC>, L<Digest::Haval256>,
L<Digest::HMAC>, L<Digest::MD2>, L<Digest::MD4>, L<Digest::MD5>,
L<Digest::SHA>, L<Digest::SHA1>, L<Digest::SHA2>, L<Digest::Whirlpool>

New digest implementations should consider subclassing from L<Digest::base>.

L<MIME::Base64>

=head1 AUTHOR

Gisle Aas <gisle@aas.no>

The C<Digest::> interface is based on the interface originally
developed by Neil Winton for his C<MD5> module.

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

    Copyright 1998-2001,2003-2004 Gisle Aas.
    Copyright 1995-1996 Neil Winton.

=cut
Commit	Line	Data
3357b1b1 JH	1	package Digest;
	2
	3	use strict;
	4	use vars qw($VERSION %MMAP $AUTOLOAD);
	5
f8b4793a	6	$VERSION = "1.12";
3357b1b1 JH	7
3357b1b1 JH	8	%MMAP = (
b12d758c	9	"SHA-1" => ["Digest::SHA1", ["Digest::SHA", 1], ["Digest::SHA2", 1]],
3cea4b92	10	"SHA-224" => [["Digest::SHA", 224]],
b12d758c NC	11	"SHA-256" => [["Digest::SHA", 256], ["Digest::SHA2", 256]],
	12	"SHA-384" => [["Digest::SHA", 384], ["Digest::SHA2", 384]],
	13	"SHA-512" => [["Digest::SHA", 512], ["Digest::SHA2", 512]],
3357b1b1 JH	14	"HMAC-MD5" => "Digest::HMAC_MD5",
3357b1b1 JH	15	"HMAC-SHA-1" => "Digest::HMAC_SHA1",
371dcd31 RGS	16	"CRC-16" => [["Digest::CRC", type => "crc16"]],
	17	"CRC-32" => [["Digest::CRC", type => "crc32"]],
	18	"CRC-CCITT" => [["Digest::CRC", type => "crcccitt"]],
3357b1b1 JH	19	);
	20
	21	sub new
	22	{
	23	shift; # class ignored
	24	my $algorithm = shift;
b12d758c NC	25	my $impl = $MMAP{$algorithm} \|\| do {
	26	$algorithm =~ s/\W+//;
	27	"Digest::$algorithm";
	28	};
	29	$impl = [$impl] unless ref($impl);
	30	my $err;
	31	for (@$impl) {
	32	my $class = $_;
	33	my @args;
	34	($class, @args) = @$class if ref($class);
	35	no strict 'refs';
	36	unless (exists ${"$class\::"}{"VERSION"}) {
	37	eval "require $class";
	38	if ($@) {
	39	$err \|\|= $@;
	40	next;
	41	}
	42	}
	43	return $class->new(@args, @_);
3357b1b1	44	}
b12d758c	45	die $err;
3357b1b1 JH	46	}
	47
	48	sub AUTOLOAD
	49	{
	50	my $class = shift;
	51	my $algorithm = substr($AUTOLOAD, rindex($AUTOLOAD, '::')+2);
	52	$class->new($algorithm, @_);
	53	}
	54
	55	1;
	56
	57	__END__
	58
	59	=head1 NAME
	60
e19eb3c1	61	Digest - Modules that calculate message digests
3357b1b1 JH	62
	63	=head1 SYNOPSIS
	64
e19eb3c1	65	$md5 = Digest->new("MD5");
3357b1b1	66	$sha1 = Digest->new("SHA-1");
e19eb3c1 NC	67	$sha256 = Digest->new("SHA-256");
	68	$sha384 = Digest->new("SHA-384");
	69	$sha512 = Digest->new("SHA-512");
3357b1b1 JH	70
	71	$hmac = Digest->HMAC_MD5($key);
	72
	73	=head1 DESCRIPTION
	74
	75	The C<Digest::> modules calculate digests, also called "fingerprints"
	76	or "hashes", of some data, called a message. The digest is (usually)
	77	some small/fixed size string. The actual size of the digest depend of
	78	the algorithm used. The message is simply a sequence of arbitrary
b12d758c	79	bytes or bits.
3357b1b1 JH	80
	81	An important property of the digest algorithms is that the digest is
	82	I<likely> to change if the message change in some way. Another
	83	property is that digest functions are one-way functions, i.e. it
	84	should be I<hard> to find a message that correspond to some given
	85	digest. Algorithms differ in how "likely" and how "hard", as well as
	86	how efficient they are to compute.
	87
	88	All C<Digest::> modules provide the same programming interface. A
	89	functional interface for simple use, as well as an object oriented
	90	interface that can handle messages of arbitrary length and which can
	91	read files directly.
	92
	93	The digest can be delivered in three formats:
	94
	95	=over 8
	96
	97	=item I<binary>
	98
	99	This is the most compact form, but it is not well suited for printing
	100	or embedding in places that can't handle arbitrary data.
	101
	102	=item I<hex>
	103
e19eb3c1	104	A twice as long string of lowercase hexadecimal digits.
3357b1b1 JH	105
	106	=item I<base64>
	107
	108	A string of portable printable characters. This is the base64 encoded
	109	representation of the digest with any trailing padding removed. The
	110	string will be about 30% longer than the binary version.
	111	L<MIME::Base64> tells you more about this encoding.
	112
	113	=back
	114
	115
	116	The functional interface is simply importable functions with the same
	117	name as the algorithm. The functions take the message as argument and
	118	return the digest. Example:
	119
	120	use Digest::MD5 qw(md5);
	121	$digest = md5($message);
	122
	123	There are also versions of the functions with "_hex" or "_base64"
	124	appended to the name, which returns the digest in the indicated form.
	125
	126	=head1 OO INTERFACE
	127
	128	The following methods are available for all C<Digest::> modules:
	129
	130	=over 4
	131
	132	=item $ctx = Digest->XXX($arg,...)
	133
	134	=item $ctx = Digest->new(XXX => $arg,...)
	135
	136	=item $ctx = Digest::XXX->new($arg,...)
	137
	138	The constructor returns some object that encapsulate the state of the
	139	message-digest algorithm. You can add data to the object and finally
	140	ask for the digest. The "XXX" should of course be replaced by the proper
	141	name of the digest algorithm you want to use.
	142
	143	The two first forms are simply syntactic sugar which automatically
	144	load the right module on first use. The second form allow you to use
	145	algorithm names which contains letters which are not legal perl
897ff129 RGS	146	identifiers, e.g. "SHA-1". If no implementation for the given algorithm
897ff129 RGS	147	can be found, then an exception is raised.
3357b1b1	148
67859229	149	If new() is called as an instance method (i.e. $ctx->new) it will just
3357b1b1 JH	150	reset the state the object to the state of a newly created object. No
	151	new object is created in this case, and the return value is the
	152	reference to the object (i.e. $ctx).
	153
70ee4409 JH	154	=item $other_ctx = $ctx->clone
	155
	156	The clone method creates a copy of the digest state object and returns
	157	a reference to the copy.
	158
3357b1b1 JH	159	=item $ctx->reset
	160
	161	This is just an alias for $ctx->new.
	162
e19eb3c1	163	=item $ctx->add( $data, ... )
3357b1b1 JH	164
	165	The $data provided as argument are appended to the message we
	166	calculate the digest for. The return value is the $ctx object itself.
	167
e19eb3c1	168	=item $ctx->addfile( $io_handle )
3357b1b1 JH	169
	170	The $io_handle is read until EOF and the content is appended to the
	171	message we calculate the digest for. The return value is the $ctx
	172	object itself.
	173
e19eb3c1	174	=item $ctx->add_bits( $data, $nbits )
b12d758c	175
e19eb3c1	176	=item $ctx->add_bits( $bitstring )
b12d758c NC	177
	178	The bits provided are appended to the message we calculate the digest
	179	for. The return value is the $ctx object itself.
	180
	181	The two argument form of add_bits() will add the first $nbits bits
	182	from data. For the last potentially partial byte only the high order
	183	C<< $nbits % 8 >> bits are used. If $nbits is greater than C<<
	184	length($data) * 8 >>, then this method would do the same as C<<
	185	$ctx->add($data) >>, i.e. $nbits is silently ignored.
	186
	187	The one argument form of add_bits() takes a $bitstring of "1" and "0"
	188	chars as argument. It's a shorthand for C<< $ctx->add_bits(pack("B*",
	189	$bitstring), length($bitstring)) >>.
	190
	191	This example shows two calls that should have the same effect:
	192
	193	$ctx->add_bits("111100001010");
	194	$ctx->add_bits("\xF0\xA0", 12);
	195
	196	Most digest algorithms are byte based. For those it is not possible
	197	to add bits that are not a multiple of 8, and the add_bits() method
	198	will croak if you try.
	199
3357b1b1 JH	200	=item $ctx->digest
	201
	202	Return the binary digest for the message.
	203
	204	Note that the C<digest> operation is effectively a destructive,
	205	read-once operation. Once it has been performed, the $ctx object is
	206	automatically C<reset> and can be used to calculate another digest
70ee4409	207	value. Call $ctx->clone->digest if you want to calculate the digest
3c4b39be	208	without resetting the digest state.
3357b1b1 JH	209
	210	=item $ctx->hexdigest
	211
	212	Same as $ctx->digest, but will return the digest in hexadecimal form.
	213
	214	=item $ctx->b64digest
	215
	216	Same as $ctx->digest, but will return the digest as a base64 encoded
	217	string.
	218
	219	=back
	220
e19eb3c1 NC	221	=head1 Digest speed
	222
	223	This table should give some indication on the relative speed of
	224	different algorithms. It is sorted by throughput based on a benchmark
	225	done with of some implementations of this API:
	226
371dcd31 RGS	227	Algorithm Size Implementation MB/s
	228
	229	MD4 128 Digest::MD4 v1.3 165.0
	230	MD5 128 Digest::MD5 v2.33 98.8
	231	SHA-256 256 Digest::SHA2 v1.1.0 66.7
	232	SHA-1 160 Digest::SHA v4.3.1 58.9
	233	SHA-1 160 Digest::SHA1 v2.10 48.8
	234	SHA-256 256 Digest::SHA v4.3.1 41.3
	235	Haval-256 256 Digest::Haval256 v1.0.4 39.8
	236	SHA-384 384 Digest::SHA2 v1.1.0 19.6
	237	SHA-512 512 Digest::SHA2 v1.1.0 19.3
	238	SHA-384 384 Digest::SHA v4.3.1 19.2
	239	SHA-512 512 Digest::SHA v4.3.1 19.2
	240	Whirlpool 512 Digest::Whirlpool v1.0.2 13.0
	241	MD2 128 Digest::MD2 v2.03 9.5
	242
	243	Adler-32 32 Digest::Adler32 v0.03 1.3
	244	CRC-16 16 Digest::CRC v0.05 1.1
	245	CRC-32 32 Digest::CRC v0.05 1.1
	246	MD5 128 Digest::Perl::MD5 v1.5 1.0
	247	CRC-CCITT 16 Digest::CRC v0.05 0.8
	248
	249	These numbers was achieved Apr 2004 with ActivePerl-5.8.3 running
	250	under Linux on a P4 2.8 GHz CPU. The last 5 entries differ by being
e19eb3c1 NC	251	pure perl implementations of the algorithms, which explains why they
	252	are so slow.
	253
3357b1b1 JH	254	=head1 SEE ALSO
3357b1b1 JH	255
371dcd31 RGS	256	L<Digest::Adler32>, L<Digest::CRC>, L<Digest::Haval256>,
	257	L<Digest::HMAC>, L<Digest::MD2>, L<Digest::MD4>, L<Digest::MD5>,
	258	L<Digest::SHA>, L<Digest::SHA1>, L<Digest::SHA2>, L<Digest::Whirlpool>
e19eb3c1 NC	259
e19eb3c1 NC	260	New digest implementations should consider subclassing from L<Digest::base>.
3357b1b1 JH	261
	262	L<MIME::Base64>
	263
	264	=head1 AUTHOR
	265
	266	Gisle Aas <gisle@aas.no>
	267
	268	The C<Digest::> interface is based on the interface originally
	269	developed by Neil Winton for his C<MD5> module.
	270
e19eb3c1 NC	271	This library is free software; you can redistribute it and/or
	272	modify it under the same terms as Perl itself.
	273
897ff129	274	Copyright 1998-2001,2003-2004 Gisle Aas.
e19eb3c1 NC	275	Copyright 1995-1996 Neil Winton.
e19eb3c1 NC	276
3357b1b1	277	=cut