[perl5.git] / lib / Exporter.pm

package Exporter;

require 5.001;

$ExportLevel = 0;
$Verbose = 0 unless $Verbose;

require Carp;

sub export {

    # First make import warnings look like they're coming from the "use".
    local $SIG{__WARN__} = sub {
	my $text = shift;
	$text =~ s/ at \S*Exporter.pm line \d+.*\n//;
	local $Carp::CarpLevel = 1;	# ignore package calling us too.
	Carp::carp($text);
    };
    local $SIG{__DIE__} = sub {
	Carp::croak("$_[0]Illegal null symbol in \@${1}::EXPORT")
	    if $_[0] =~ /^Unable to create sub named "(.*?)::"/;
    };

    my($pkg, $callpkg, @imports) = @_;
    my($type, $sym, $oops);
    *exports = *{"${pkg}::EXPORT"};

    if (@imports) {
	if (!%exports) {
	    grep(s/^&//, @exports);
	    @exports{@exports} = (1) x @exports;
	    my $ok = \@{"${pkg}::EXPORT_OK"};
	    if (@$ok) {
		grep(s/^&//, @$ok);
		@exports{@$ok} = (1) x @$ok;
	    }
	}

	if ($imports[0] =~ m#^[/!:]#){
	    my $tagsref = \%{"${pkg}::EXPORT_TAGS"};
	    my $tagdata;
	    my %imports;
	    my($remove, $spec, @names, @allexports);
	    # negated first item implies starting with default set:
	    unshift @imports, ':DEFAULT' if $imports[0] =~ m/^!/;
	    foreach $spec (@imports){
		$remove = $spec =~ s/^!//;

		if ($spec =~ s/^://){
		    if ($spec eq 'DEFAULT'){
			@names = @exports;
		    }
		    elsif ($tagdata = $tagsref->{$spec}) {
			@names = @$tagdata;
		    }
		    else {
			warn qq["$spec" is not defined in %${pkg}::EXPORT_TAGS];
			++$oops;
			next;
		    }
		}
		elsif ($spec =~ m:^/(.*)/$:){
		    my $patn = $1;
		    @allexports = keys %exports unless @allexports; # only do keys once
		    @names = grep(/$patn/, @allexports); # not anchored by default
		}
		else {
		    @names = ($spec); # is a normal symbol name
		}

		warn "Import ".($remove ? "del":"add").": @names "
		    if $Verbose;

		if ($remove) {
		   foreach $sym (@names) { delete $imports{$sym} } 
		}
		else {
		    @imports{@names} = (1) x @names;
		}
	    }
	    @imports = keys %imports;
	}

	foreach $sym (@imports) {
	    if (!$exports{$sym}) {
		if ($sym =~ m/^\d/) {
		    $pkg->require_version($sym);
		    # If the version number was the only thing specified
		    # then we should act as if nothing was specified:
		    if (@imports == 1) {
			@imports = @exports;
			last;
		    }
		    # We need a way to emulate 'use Foo ()' but still
		    # allow an easy version check: "use Foo 1.23, ''";
		    if (@imports == 2 and !$imports[1]) {
			@imports = ();
			last;
		    }
		} elsif ($sym !~ s/^&// || !$exports{$sym}) {
		    warn qq["$sym" is not exported by the $pkg module];
		    $oops++;
		}
	    }
	}
	Carp::croak("Can't continue after import errors") if $oops;
    }
    else {
	@imports = @exports;
    }

    *fail = *{"${pkg}::EXPORT_FAIL"};
    if (@fail) {
	if (!%fail) {
	    # Build cache of symbols. Optimise the lookup by adding
	    # barewords twice... both with and without a leading &.
	    # (Technique could be applied to %exports cache at cost of memory)
	    my @expanded = map { /^\w/ ? ($_, '&'.$_) : $_ } @fail;
	    warn "${pkg}::EXPORT_FAIL cached: @expanded" if $Verbose;
	    @fail{@expanded} = (1) x @expanded;
	}
	my @failed;
	foreach $sym (@imports) { push(@failed, $sym) if $fail{$sym} }
	if (@failed) {
	    @failed = $pkg->export_fail(@failed);
	    foreach $sym (@failed) {
		warn qq["$sym" is not implemented by the $pkg module ],
			"on this architecture";
	    }
	    Carp::croak("Can't continue after import errors") if @failed;
	}
    }

    warn "Importing into $callpkg from $pkg: ",
		join(", ",sort @imports) if $Verbose;

    foreach $sym (@imports) {
	# shortcut for the common case of no type character
	(*{"${callpkg}::$sym"} = \&{"${pkg}::$sym"}, next)
	    unless $sym =~ s/^(\W)//;
	$type = $1;
	*{"${callpkg}::$sym"} =
	    $type eq '&' ? \&{"${pkg}::$sym"} :
	    $type eq '$' ? \${"${pkg}::$sym"} :
	    $type eq '@' ? \@{"${pkg}::$sym"} :
	    $type eq '%' ? \%{"${pkg}::$sym"} :
	    $type eq '*' ?  *{"${pkg}::$sym"} :
		Carp::croak("Can't export symbol: $type$sym");
    }
}

sub import {
    my $pkg = shift;
    my $callpkg = caller($ExportLevel);
    export $pkg, $callpkg, @_;
}


# Utility functions

sub _push_tags {
    my($pkg, $var, $syms) = @_;
    my $nontag;
    *export_tags = \%{"${pkg}::EXPORT_TAGS"};
    push(@{"${pkg}::$var"},
	map { $export_tags{$_} ? @{$export_tags{$_}} : scalar(++$nontag,$_) }
		(@$syms) ? @$syms : keys %export_tags);
    # This may change to a die one day
    Carp::carp("Some names are not tags") if $nontag and $^W;
}

sub export_tags    { _push_tags((caller)[0], "EXPORT",    \@_) }
sub export_ok_tags { _push_tags((caller)[0], "EXPORT_OK", \@_) }


# Default methods

sub export_fail {
    @_;
}

sub require_version {
    my($self, $wanted) = @_;
    my $pkg = ref $self || $self;
    my $version = ${"${pkg}::VERSION"};
    if (!$version or $version < $wanted) {
	$version ||= "(undef)";
	my $file = $INC{"$pkg.pm"};
	$file &&= " ($file)";
	Carp::croak("$pkg $wanted required--this is only version $version$file")
    }
    $version;
}

1;

# A simple self test harness. Change 'require Carp' to 'use Carp ()' for testing.
# package main; eval(join('',<DATA>)) or die $@ unless caller;
__END__
package Test;
$INC{'Exporter.pm'} = 1;
@ISA = qw(Exporter);
@EXPORT      = qw(A1 A2 A3 A4 A5);
@EXPORT_OK   = qw(B1 B2 B3 B4 B5);
%EXPORT_TAGS = (T1=>[qw(A1 A2 B1 B2)], T2=>[qw(A1 A2 B3 B4)], T3=>[qw(X3)]);
@EXPORT_FAIL = qw(B4);
Exporter::export_ok_tags('T3', 'unknown_tag');
sub export_fail {
    map { "Test::$_" } @_	# edit symbols just as an example
}

package main;
$Exporter::Verbose = 1;
#import Test;
#import Test qw(X3);		# export ok via export_ok_tags()
#import Test qw(:T1 !A2 /5/ !/3/ B5);
import Test qw(:T2 !B4);
import Test qw(:T2);		# should fail
1;

=head1 NAME

Exporter - Implements default import method for modules

=head1 SYNOPSIS

In module ModuleName.pm:

  package ModuleName;
  require Exporter;
  @ISA = qw(Exporter);

  @EXPORT = qw(...);            # symbols to export by default
  @EXPORT_OK = qw(...);         # symbols to export on request
  %EXPORT_TAGS = tag => [...];  # define names for sets of symbols

In other files which wish to use ModuleName:

  use ModuleName;               # import default symbols into my package

  use ModuleName qw(...);       # import listed symbols into my package

  use ModuleName ();            # do not import any symbols

=head1 DESCRIPTION

The Exporter module implements a default C<import> method which
many modules choose inherit rather than implement their own.

Perl automatically calls the C<import> method when processing a
C<use> statement for a module. Modules and C<use> are documented
in L<perlfunc> and L<perlmod>. Understanding the concept of
modules and how the C<use> statement operates is important to
understanding the Exporter.

=head2 Selecting What To Export

Do B<not> export method names!

Do B<not> export anything else by default without a good reason!

Exports pollute the namespace of the module user.  If you must export
try to use @EXPORT_OK in preference to @EXPORT and avoid short or
common symbol names to reduce the risk of name clashes.

Generally anything not exported is still accessible from outside the
module using the ModuleName::item_name (or $blessed_ref->method)
syntax.  By convention you can use a leading underscore on names to
informally indicate that they are 'internal' and not for public use.

(It is actually possible to get private functions by saying:

  my $subref = sub { ... };
  &$subref;

But there's no way to call that directly as a method, since a method
must have a name in the symbol table.)

As a general rule, if the module is trying to be object oriented
then export nothing. If it's just a collection of functions then
@EXPORT_OK anything but use @EXPORT with caution.

Other module design guidelines can be found in L<perlmod>.

=head2 Specialised Import Lists

If the first entry in an import list begins with !, : or / then the
list is treated as a series of specifications which either add to or
delete from the list of names to import. They are processed left to
right. Specifications are in the form:

    [!]name         This name only
    [!]:DEFAULT     All names in @EXPORT
    [!]:tag         All names in $EXPORT_TAGS{tag} anonymous list
    [!]/pattern/    All names in @EXPORT and @EXPORT_OK which match

A leading ! indicates that matching names should be deleted from the
list of names to import.  If the first specification is a deletion it
is treated as though preceded by :DEFAULT. If you just want to import
extra names in addition to the default set you will still need to
include :DEFAULT explicitly.

e.g., Module.pm defines:

    @EXPORT      = qw(A1 A2 A3 A4 A5);
    @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
    %EXPORT_TAGS = (T1 => [qw(A1 A2 B1 B2)], T2 => [qw(A1 A2 B3 B4)]);

    Note that you cannot use tags in @EXPORT or @EXPORT_OK.
    Names in EXPORT_TAGS must also appear in @EXPORT or @EXPORT_OK.

An application using Module can say something like:

    use Module qw(:DEFAULT :T2 !B3 A3);

Other examples include:

    use Socket qw(!/^[AP]F_/ !SOMAXCONN !SOL_SOCKET);
    use POSIX  qw(:errno_h :termios_h !TCSADRAIN !/^EXIT/);

Remember that most patterns (using //) will need to be anchored
with a leading ^, e.g., C</^EXIT/> rather than C</EXIT/>.

You can say C<BEGIN { $Exporter::Verbose=1 }> to see how the
specifications are being processed and what is actually being imported
into modules.

=head2 Module Version Checking

The Exporter module will convert an attempt to import a number from a
module into a call to $module_name->require_version($value). This can
be used to validate that the version of the module being used is
greater than or equal to the required version.

The Exporter module supplies a default require_version method which
checks the value of $VERSION in the exporting module.

Since the default require_version method treats the $VERSION number as
a simple numeric value it will regard version 1.10 as lower than
1.9. For this reason it is strongly recommended that you use numbers
with at least two decimal places, e.g., 1.09.

=head2 Managing Unknown Symbols

In some situations you may want to prevent certain symbols from being
exported. Typically this applies to extensions which have functions
or constants that may not exist on some systems.

The names of any symbols that cannot be exported should be listed
in the C<@EXPORT_FAIL> array.

If a module attempts to import any of these symbols the Exporter will
will give the module an opportunity to handle the situation before
generating an error. The Exporter will call an export_fail method
with a list of the failed symbols:

  @failed_symbols = $module_name->export_fail(@failed_symbols);

If the export_fail method returns an empty list then no error is
recorded and all the requested symbols are exported. If the returned
list is not empty then an error is generated for each symbol and the
export fails. The Exporter provides a default export_fail method which
simply returns the list unchanged.

Uses for the export_fail method include giving better error messages
for some symbols and performing lazy architectural checks (put more
symbols into @EXPORT_FAIL by default and then take them out if someone
actually tries to use them and an expensive check shows that they are
usable on that platform).

=head2 Tag Handling Utility Functions

Since the symbols listed within %EXPORT_TAGS must also appear in either
@EXPORT or @EXPORT_OK, two utility functions are provided which allow
you to easily add tagged sets of symbols to @EXPORT or @EXPORT_OK:

  %EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);

  Exporter::export_tags('foo');     # add aa, bb and cc to @EXPORT
  Exporter::export_ok_tags('bar');  # add aa, cc and dd to @EXPORT_OK

Any names which are not tags are added to @EXPORT or @EXPORT_OK
unchanged but will trigger a warning (with C<-w>) to avoid misspelt tags
names being silently added to @EXPORT or @EXPORT_OK. Future versions
may make this a fatal error.

=cut
Commit	Line	Data
8990e307 LW	1	package Exporter;
8990e307 LW	2
748a9306	3	require 5.001;
8990e307	4
a0d0e21e	5	$ExportLevel = 0;
c07a80fd	6	$Verbose = 0 unless $Verbose;
748a9306 LW	7
748a9306 LW	8	require Carp;
a0d0e21e LW	9
a0d0e21e LW	10	sub export {
748a9306 LW	11
	12	# First make import warnings look like they're coming from the "use".
	13	local $SIG{__WARN__} = sub {
	14	my $text = shift;
2b5b2650	15	$text =~ s/ at \SExporter.pm line \d+.\n//;
748a9306 LW	16	local $Carp::CarpLevel = 1; # ignore package calling us too.
	17	Carp::carp($text);
	18	};
4633a7c4 LW	19	local $SIG{__DIE__} = sub {
	20	Carp::croak("$_[0]Illegal null symbol in \@${1}::EXPORT")
	21	if $_[0] =~ /^Unable to create sub named "(.*?)::"/;
	22	};
748a9306	23
2b5b2650	24	my($pkg, $callpkg, @imports) = @_;
	25	my($type, $sym, $oops);
	26	exports = {"${pkg}::EXPORT"};
	27
8990e307	28	if (@imports) {
8990e307 LW	29	if (!%exports) {
8990e307 LW	30	grep(s/^&//, @exports);
2b5b2650	31	@exports{@exports} = (1) x @exports;
	32	my $ok = \@{"${pkg}::EXPORT_OK"};
	33	if (@$ok) {
	34	grep(s/^&//, @$ok);
	35	@exports{@$ok} = (1) x @$ok;
a0d0e21e	36	}
8990e307	37	}
748a9306 LW	38
748a9306 LW	39	if ($imports[0] =~ m#^[/!:]#){
748a9306 LW	40	my $tagsref = \%{"${pkg}::EXPORT_TAGS"};
	41	my $tagdata;
	42	my %imports;
2b5b2650	43	my($remove, $spec, @names, @allexports);
748a9306	44	# negated first item implies starting with default set:
2b5b2650	45	unshift @imports, ':DEFAULT' if $imports[0] =~ m/^!/;
	46	foreach $spec (@imports){
	47	$remove = $spec =~ s/^!//;
748a9306	48
2b5b2650	49	if ($spec =~ s/^://){
2b5b2650	50	if ($spec eq 'DEFAULT'){
748a9306 LW	51	@names = @exports;
748a9306 LW	52	}
2b5b2650	53	elsif ($tagdata = $tagsref->{$spec}) {
748a9306 LW	54	@names = @$tagdata;
748a9306 LW	55	}
2b5b2650	56	else {
	57	warn qq["$spec" is not defined in %${pkg}::EXPORT_TAGS];
	58	++$oops;
	59	next;
	60	}
	61	}
	62	elsif ($spec =~ m:^/(.*)/$:){
	63	my $patn = $1;
	64	@allexports = keys %exports unless @allexports; # only do keys once
	65	@names = grep(/$patn/, @allexports); # not anchored by default
748a9306	66	}
2b5b2650	67	else {
	68	@names = ($spec); # is a normal symbol name
	69	}
	70
	71	warn "Import ".($remove ? "del":"add").": @names "
	72	if $Verbose;
748a9306	73
2b5b2650	74	if ($remove) {
2b5b2650	75	foreach $sym (@names) { delete $imports{$sym} }
748a9306 LW	76	}
748a9306 LW	77	else {
2b5b2650	78	@imports{@names} = (1) x @names;
748a9306 LW	79	}
	80	}
	81	@imports = keys %imports;
	82	}
	83
8990e307 LW	84	foreach $sym (@imports) {
8990e307 LW	85	if (!$exports{$sym}) {
e50aee73 AD	86	if ($sym =~ m/^\d/) {
	87	$pkg->require_version($sym);
	88	# If the version number was the only thing specified
	89	# then we should act as if nothing was specified:
	90	if (@imports == 1) {
	91	@imports = @exports;
	92	last;
	93	}
3221d3b0	94	# We need a way to emulate 'use Foo ()' but still
	95	# allow an easy version check: "use Foo 1.23, ''";
	96	if (@imports == 2 and !$imports[1]) {
	97	@imports = ();
	98	last;
	99	}
e50aee73	100	} elsif ($sym !~ s/^&// \|\| !$exports{$sym}) {
2b5b2650	101	warn qq["$sym" is not exported by the $pkg module];
8990e307	102	$oops++;
8990e307 LW	103	}
	104	}
	105	}
2b5b2650	106	Carp::croak("Can't continue after import errors") if $oops;
8990e307 LW	107	}
	108	else {
	109	@imports = @exports;
	110	}
2b5b2650	111
	112	fail = {"${pkg}::EXPORT_FAIL"};
	113	if (@fail) {
	114	if (!%fail) {
	115	# Build cache of symbols. Optimise the lookup by adding
	116	# barewords twice... both with and without a leading &.
	117	# (Technique could be applied to %exports cache at cost of memory)
	118	my @expanded = map { /^\w/ ? ($_, '&'.$_) : $_ } @fail;
	119	warn "${pkg}::EXPORT_FAIL cached: @expanded" if $Verbose;
	120	@fail{@expanded} = (1) x @expanded;
	121	}
	122	my @failed;
	123	foreach $sym (@imports) { push(@failed, $sym) if $fail{$sym} }
	124	if (@failed) {
	125	@failed = $pkg->export_fail(@failed);
	126	foreach $sym (@failed) {
	127	warn qq["$sym" is not implemented by the $pkg module ],
	128	"on this architecture";
	129	}
	130	Carp::croak("Can't continue after import errors") if @failed;
	131	}
	132	}
	133
c07a80fd	134	warn "Importing into $callpkg from $pkg: ",
2b5b2650	135	join(", ",sort @imports) if $Verbose;
2b5b2650	136
8990e307	137	foreach $sym (@imports) {
2b5b2650	138	# shortcut for the common case of no type character
	139	(*{"${callpkg}::$sym"} = \&{"${pkg}::$sym"}, next)
	140	unless $sym =~ s/^(\W)//;
	141	$type = $1;
748a9306 LW	142	*{"${callpkg}::$sym"} =
	143	$type eq '&' ? \&{"${pkg}::$sym"} :
	144	$type eq '$' ? \${"${pkg}::$sym"} :
	145	$type eq '@' ? \@{"${pkg}::$sym"} :
	146	$type eq '%' ? \%{"${pkg}::$sym"} :
	147	$type eq '' ? {"${pkg}::$sym"} :
2b5b2650	148	Carp::croak("Can't export symbol: $type$sym");
8990e307	149	}
2b5b2650	150	}
8990e307	151
a0d0e21e	152	sub import {
748a9306	153	my $pkg = shift;
2b5b2650	154	my $callpkg = caller($ExportLevel);
748a9306 LW	155	export $pkg, $callpkg, @_;
	156	}
	157
2b5b2650	158
	159	# Utility functions
	160
	161	sub _push_tags {
	162	my($pkg, $var, $syms) = @_;
	163	my $nontag;
c07a80fd	164	*export_tags = \%{"${pkg}::EXPORT_TAGS"};
2b5b2650	165	push(@{"${pkg}::$var"},
	166	map { $export_tags{$_} ? @{$export_tags{$_}} : scalar(++$nontag,$_) }
	167	(@$syms) ? @$syms : keys %export_tags);
	168	# This may change to a die one day
	169	Carp::carp("Some names are not tags") if $nontag and $^W;
	170	}
	171
	172	sub export_tags { _push_tags((caller)[0], "EXPORT", \@_) }
	173	sub export_ok_tags { _push_tags((caller)[0], "EXPORT_OK", \@_) }
	174
	175
	176	# Default methods
	177
	178	sub export_fail {
	179	@_;
a0d0e21e LW	180	}
a0d0e21e LW	181
e50aee73 AD	182	sub require_version {
	183	my($self, $wanted) = @_;
	184	my $pkg = ref $self \|\| $self;
3221d3b0	185	my $version = ${"${pkg}::VERSION"};
	186	if (!$version or $version < $wanted) {
	187	$version \|\|= "(undef)";
	188	my $file = $INC{"$pkg.pm"};
	189	$file &&= " ($file)";
	190	Carp::croak("$pkg $wanted required--this is only version $version$file")
	191	}
e50aee73 AD	192	$version;
	193	}
	194
8990e307	195	1;
2b5b2650	196
	197	# A simple self test harness. Change 'require Carp' to 'use Carp ()' for testing.
	198	# package main; eval(join('',<DATA>)) or die $@ unless caller;
	199	__END__
	200	package Test;
	201	$INC{'Exporter.pm'} = 1;
	202	@ISA = qw(Exporter);
	203	@EXPORT = qw(A1 A2 A3 A4 A5);
	204	@EXPORT_OK = qw(B1 B2 B3 B4 B5);
	205	%EXPORT_TAGS = (T1=>[qw(A1 A2 B1 B2)], T2=>[qw(A1 A2 B3 B4)], T3=>[qw(X3)]);
	206	@EXPORT_FAIL = qw(B4);
	207	Exporter::export_ok_tags('T3', 'unknown_tag');
	208	sub export_fail {
	209	map { "Test::$_" } @_ # edit symbols just as an example
	210	}
	211
	212	package main;
	213	$Exporter::Verbose = 1;
	214	#import Test;
	215	#import Test qw(X3); # export ok via export_ok_tags()
	216	#import Test qw(:T1 !A2 /5/ !/3/ B5);
	217	import Test qw(:T2 !B4);
	218	import Test qw(:T2); # should fail
	219	1;
	220
	221	=head1 NAME
	222
	223	Exporter - Implements default import method for modules
	224
	225	=head1 SYNOPSIS
	226
	227	In module ModuleName.pm:
	228
	229	package ModuleName;
	230	require Exporter;
	231	@ISA = qw(Exporter);
	232
	233	@EXPORT = qw(...); # symbols to export by default
	234	@EXPORT_OK = qw(...); # symbols to export on request
	235	%EXPORT_TAGS = tag => [...]; # define names for sets of symbols
	236
	237	In other files which wish to use ModuleName:
	238
	239	use ModuleName; # import default symbols into my package
	240
	241	use ModuleName qw(...); # import listed symbols into my package
	242
	243	use ModuleName (); # do not import any symbols
	244
	245	=head1 DESCRIPTION
	246
	247	The Exporter module implements a default C<import> method which
	248	many modules choose inherit rather than implement their own.
	249
	250	Perl automatically calls the C<import> method when processing a
	251	C<use> statement for a module. Modules and C<use> are documented
	252	in L<perlfunc> and L<perlmod>. Understanding the concept of
	253	modules and how the C<use> statement operates is important to
	254	understanding the Exporter.
	255
	256	=head2 Selecting What To Export
	257
	258	Do B<not> export method names!
	259
260	Do B<not> export anything else by default without a good reason!
261
262	Exports pollute the namespace of the module user. If you must export
263	try to use @EXPORT_OK in preference to @EXPORT and avoid short or
264	common symbol names to reduce the risk of name clashes.
265
266	Generally anything not exported is still accessible from outside the
267	module using the ModuleName::item_name (or $blessed_ref->method)
268	syntax. By convention you can use a leading underscore on names to
269	informally indicate that they are 'internal' and not for public use.
270
271	(It is actually possible to get private functions by saying:
272
273	my $subref = sub { ... };
274	&$subref;
275
276	But there's no way to call that directly as a method, since a method
277	must have a name in the symbol table.)
278
279	As a general rule, if the module is trying to be object oriented
280	then export nothing. If it's just a collection of functions then
281	@EXPORT_OK anything but use @EXPORT with caution.
282
283	Other module design guidelines can be found in L<perlmod>.
284
285	=head2 Specialised Import Lists
286
287	If the first entry in an import list begins with !, : or / then the
288	list is treated as a series of specifications which either add to or
289	delete from the list of names to import. They are processed left to
290	right. Specifications are in the form:
291
292	[!]name This name only
293	[!]:DEFAULT All names in @EXPORT
294	[!]:tag All names in $EXPORT_TAGS{tag} anonymous list
295	[!]/pattern/ All names in @EXPORT and @EXPORT_OK which match
296
297	A leading ! indicates that matching names should be deleted from the
298	list of names to import. If the first specification is a deletion it
299	is treated as though preceded by :DEFAULT. If you just want to import
300	extra names in addition to the default set you will still need to
301	include :DEFAULT explicitly.
302
303	e.g., Module.pm defines:
304
305	@EXPORT = qw(A1 A2 A3 A4 A5);
306	@EXPORT_OK = qw(B1 B2 B3 B4 B5);
307	%EXPORT_TAGS = (T1 => [qw(A1 A2 B1 B2)], T2 => [qw(A1 A2 B3 B4)]);
308
309	Note that you cannot use tags in @EXPORT or @EXPORT_OK.
310	Names in EXPORT_TAGS must also appear in @EXPORT or @EXPORT_OK.
311
312	An application using Module can say something like:
313
314	use Module qw(:DEFAULT :T2 !B3 A3);
315
316	Other examples include:
317
318	use Socket qw(!/^[AP]F_/ !SOMAXCONN !SOL_SOCKET);
319	use POSIX qw(:errno_h :termios_h !TCSADRAIN !/^EXIT/);
320
321	Remember that most patterns (using //) will need to be anchored
322	with a leading ^, e.g., C</^EXIT/> rather than C</EXIT/>.
323
324	You can say C<BEGIN { $Exporter::Verbose=1 }> to see how the
325	specifications are being processed and what is actually being imported
326	into modules.
327
328	=head2 Module Version Checking
329
330	The Exporter module will convert an attempt to import a number from a
331	module into a call to $module_name->require_version($value). This can
332	be used to validate that the version of the module being used is
333	greater than or equal to the required version.
334
335	The Exporter module supplies a default require_version method which
336	checks the value of $VERSION in the exporting module.
337
338	Since the default require_version method treats the $VERSION number as
d5e40bcc	339	a simple numeric value it will regard version 1.10 as lower than
	340	1.9. For this reason it is strongly recommended that you use numbers
	341	with at least two decimal places, e.g., 1.09.
2b5b2650	342
	343	=head2 Managing Unknown Symbols
	344
	345	In some situations you may want to prevent certain symbols from being
	346	exported. Typically this applies to extensions which have functions
	347	or constants that may not exist on some systems.
	348
	349	The names of any symbols that cannot be exported should be listed
	350	in the C<@EXPORT_FAIL> array.
	351
	352	If a module attempts to import any of these symbols the Exporter will
	353	will give the module an opportunity to handle the situation before
	354	generating an error. The Exporter will call an export_fail method
	355	with a list of the failed symbols:
	356
	357	@failed_symbols = $module_name->export_fail(@failed_symbols);
	358
	359	If the export_fail method returns an empty list then no error is
	360	recorded and all the requested symbols are exported. If the returned
	361	list is not empty then an error is generated for each symbol and the
	362	export fails. The Exporter provides a default export_fail method which
	363	simply returns the list unchanged.
	364
	365	Uses for the export_fail method include giving better error messages
	366	for some symbols and performing lazy architectural checks (put more
	367	symbols into @EXPORT_FAIL by default and then take them out if someone
	368	actually tries to use them and an expensive check shows that they are
	369	usable on that platform).
	370
	371	=head2 Tag Handling Utility Functions
	372
	373	Since the symbols listed within %EXPORT_TAGS must also appear in either
	374	@EXPORT or @EXPORT_OK, two utility functions are provided which allow
	375	you to easily add tagged sets of symbols to @EXPORT or @EXPORT_OK:
	376
	377	%EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);
	378
	379	Exporter::export_tags('foo'); # add aa, bb and cc to @EXPORT
	380	Exporter::export_ok_tags('bar'); # add aa, cc and dd to @EXPORT_OK
	381
	382	Any names which are not tags are added to @EXPORT or @EXPORT_OK
d5e40bcc	383	unchanged but will trigger a warning (with C<-w>) to avoid misspelt tags
2b5b2650	384	names being silently added to @EXPORT or @EXPORT_OK. Future versions
	385	may make this a fatal error.
	386
	387	=cut