[perl5.git] / Porting / bump-perl-version

#!/usr/bin/perl
#
# bump-perl-version, DAPM 14 Jul 2009
#
# A utility to find, and optionally bump, references to the perl version
# number in various files within the perl source
#
# It's designed to work in two phases. First, when run with -s (scan),
# it searches all the files in MANIFEST looking for strings that appear to
# match the current perl version (or which it knows are *supposed* to
# contain the current version), and produces a list of them to stdout,
# along with a suggested edit. For example:
#
#     $ Porting/bump-perl-version -s 5.10.0 5.10.1 > /tmp/scan
#     $ cat /tmp/scan
#     Porting/config.sh
#     
#     52: -archlib='/opt/perl/lib/5.10.0/i686-linux-64int'
#         +archlib='/opt/perl/lib/5.10.1/i686-linux-64int'
#     ....
#
# At this point there will be false positives. Edit the file to remove
# those changes you don't want made. Then in the second phase, feed that
# list in, and it will change those lines in the files:
#
#     $ Porting/bump-perl-version -u < /tmp/scan
#
# (so line 52 of Porting/config.sh is now updated)

# This utility 'knows' about certain files and formats, and so can spot
# 'hidden' version numbers, like PERL_SUBVERSION=9.
#
# A third variant makes use of this knowledge to check that all the things
# it knows about are at the current version:
#
#    $ Porting/bump-perl-version -c 5.10.0
#
# XXX this script hasn't been tested against a major version bump yet,
# eg 5.11.0 to 5.12.0; there may be things it missed - DAPM 14 Jul 09
#
# Note there are various files and directories that it skips; these are
# ones that are unlikely to contain anything needing bumping, but which
# will generate lots fo false positives (eg pod/*). These are listed on
# STDERR as they are skipped.

use strict;
use warnings;
use Getopt::Std;
use ExtUtils::Manifest;


sub usage { die <<EOF }

@_

usage: $0 -c <C.C.C>
          -s <C.C.C> <N.N.N>
	  -u

    -c check files and warn if any known string values (eg
	PERL_SUBVERSION) don't match the specified version

    -s scan files and produce list of possible change lines to stdout

    -u read in the scan file from stdin, and change all the lines specified

    C.C.C the current perl version, eg 5.10.0
    N.N.N the new     perl version, eg 5.10.1
EOF

my %opts;
getopts('csu', \%opts) or usage;
if ($opts{u}) {
    @ARGV == 0 or usage('no version version numbers should be speciied');
    # fake to stop warnings when calculating $oldx etc
    @ARGV = qw(99.99.99 99.99.99);
}
elsif ($opts{c}) {
    @ARGV == 1 or usage('required one version number');
    push @ARGV, $ARGV[0];
}
else {
    @ARGV == 2 or usage('require two version numbers');
}
usage('only one of -c, -s and -u') if keys %opts > 1;

my ($oldx, $oldy, $oldz) = $ARGV[0] =~ /^(\d+)\.(\d+)\.(\d+)$/
	or usage("bad version: $ARGV[0]");
my ($newx, $newy, $newz) = $ARGV[1] =~ /^(\d+)\.(\d+)\.(\d+)$/
	or usage("bad version: $ARGV[1]");

my $old_decimal = sprintf "%d.%03d%03d", $oldx, $oldy, $oldz; # 5.011001

# each entry is
#   0 a regexp that matches strings that might contain versions;
#   1 a sub that returns two strings based on $1 etc values:
#     * string containing captured values (for -c)
#     * a string containing the replacement value
#   2 what we expect the sub to return as its first arg; undef implies
#     don't match
#   3 a regex restricting which files this applies to (undef is all files)
#
# Note that @maps entries are checks in order, and only the first to match
# is used.

my @maps =  (
    [
	qr{^((?:api_)?version(?:=|\s+)'?) (\d+) ('?) (?!\.)}x,
	sub { $2, "$1$newy$3" },
	$oldy,
	qr/config/,
    ],
    [
	qr{^(subversion(?:=|\s+)'?) (\d+) ('?)  (?!\.)}x,
	sub { $2, "$1$newz$3" },
	$oldz,
	qr/config/,
    ],
    [
	qr{^(api_subversion(?:=|\s+)'?) (\d+) ('?)  (?!\.)}x,
	sub { $2, "${1}0$3" },
	0,
	qr/config/,
    ],
    [
	qr{^(api_versionstring(?:=|\s+)'?) ([\d\.]+) ('?) (?!\.)}x,
	sub { $2, "$1$newx.$newy.0$3" },
	"$oldx.$oldy.0",
	qr/config/,
    ],
    [
	qr{(version\s+'?) (\d+) ('?\s+subversion\s+'?) (\d+) ('?)  (?!\.)}x,
	sub { "$2-$4", "$1$newy$3$newz$5" },
	"$oldy-$oldz",
	qr/config/,
    ],
    [
	qr{\b (PERL_(?:API_)?VERSION(?:=|\s+)'?) (\d+) ('?)  (?!\.)}x,
	sub { $2, "$1$newy$3"},
	$oldy,
    ],
    [
	qr{\b (PERL_SUBVERSION(?:=|\s+)'?) (\d+) ('?)  (?!\.)}x,
	sub { $2, "$1$newz$3"},
	$oldz,
    ],
    [
	qr{\b (PERL_API_SUBVERSION(?:=|\s+)'?) (\d+) ('?)  (?!\.)}x,
	sub { $2, "${1}0$3"},
	0,
    ],
    # these two formats are in README.vms
    [
	qr{\b perl-(\d+\^\.\d+\^\.\d+) \b}x,
	sub { $1, "perl-$newx^.$newy^.$newz"},
	undef,
    ],
    [
	qr{\b ($oldx _ $oldy _$oldz) \b}x,
	sub { $1, ($newx . '_' . $newy . '_' . $newz)},
	undef,
    ],
    # 5.8.9
    [
	qr{ $oldx\.$oldy\.$oldz \b}x,
	sub {"", "$newx.$newy.$newz"},
	undef,
    ],

    # 5.008009
    [
	qr{ $old_decimal \b}x,
	sub {"", sprintf "%d.%03d%03d", $newx, $newy, $newz },
	undef,
    ],

    # perl511.dll, perl511.lib, perl511s.lib
    [
	qr{\b perl (\d\d\d) (s?) \. }x,
	sub {$1, "perl$newx$newy$2." },
	"$oldx$oldy",
	qr/win32/,      # README.win32, win32/*
    ],

);


# files and dirs that we likely don't want to change version numbers on.

my %SKIP_FILES = map { ($_ => 1) } qw(
    Changes
    MANIFEST
    Porting/how_to_write_a_perldelta.pod
    Porting/release_managers_guide.pod
	Porting/release_schedule.pod
    Porting/bump-perl-version
    Porting/mergelog
    Porting/mergelog-tool
    pod.lst
    pp_ctl.c
);
my @SKIP_DIRS = qw(
    ext
    lib
    pod
    t
);

my @mani_files = sort keys %{ExtUtils::Manifest::maniread('MANIFEST')};
my %mani_files = map { ($_ => 1) } @mani_files;
die "No entries found in MANIFEST; aborting\n" unless @mani_files;

if ($opts{c} or $opts{s}) {
    do_scan();
}
elsif ($opts{u}) {
    do_update();
}
else {
    usage('one of -c, -s or -u must be specifcied');
}
exit 0;


sub do_scan {
    for my $file (@mani_files) {
	next if grep $file =~ m{$_/}, @SKIP_DIRS;
	if ($SKIP_FILES{$file}) {
	    warn "(skipping $file)\n";
	    next;
	}
	open my $fh, '<', $file or die "Aborting: can't open $file: $!\n";
	my $header = 0;

	while (<$fh>) {
	    for my $map (@maps) {
		my ($pat, $sub, $expected, $file_pat) = @$map;

		next if defined $file_pat and $file !~ $file_pat;
		next unless $_ =~ $pat;
		my ($got, $replacement) = $sub->();

		if ($opts{c}) {
		    # only report unexpected 
		    next unless defined $expected and $got ne $expected;
		}
		my $newstr = $_;
    		$newstr =~ s/$pat/$replacement/
		    or die "Internal error: substitution failed: [$pat]\n";
		if ($_ ne $newstr) {
		    print "\n$file\n" unless $header;
		    $header=1;
		    printf "\n%5d: -%s       +%s", $., $_, $newstr;
		}
		last;
	    }
	}
    }
    warn "(skipped  $_/*)\n" for @SKIP_DIRS;
}

sub do_update {

    my %changes;
    my $file;
    my $line;

    # read in config

    while (<STDIN>) {
	next unless /\S/;
	if (/^(\S+)$/) {
	    $file = $1;
	    die "No such file in MANIFEST: '$file'\n" unless $mani_files{$file};
	    die "file already seen; '$file'\n" if exists $changes{$file};
	    undef $line;
	}
	elsif (/^\s+(\d+): -(.*)/) {
	    my $old;
	    ($line, $old) = ($1,$2);
	    die "$.: old line without preceeding filename\n"
			    unless defined $file;
	    die "Dup line number: $line\n" if exists $changes{$file}{$line};
	    $changes{$file}{$line}[0] = $old;
	}
	elsif (/^\s+\+(.*)/) {
	    my $new = $1;
	    die "$.: replacement line seen without old line\n" unless $line;
	    $changes{$file}{$line}[1] = $new;
	    undef $line;
	}
	else {
	    die "Unexpected line at ;line $.: $_\n";
	}
    }

    # suck in file contents to memory, then update that in-memory copy

    my %contents;
    for my $file (sort keys %changes) {
	open my $fh, '<', $file or die "open '$file': $!\n";
	binmode $fh;
	$contents{$file} = [ <$fh> ];
	chomp @{$contents{$file}};
	close $fh or die "close: '$file': $!\n";

	my $entries = $changes{$file};
	for my $line (keys %$entries) {
	    die "$file: no such line: $line\n"
		    unless defined $contents{$file}[$line-1];
	    if ($contents{$file}[$line-1] ne $entries->{$line}[0]) {
		die "$file: line mismatch at line $line:\n"
			. "File:   [$contents{$file}[$line-1]]\n"
			. "Config: [$entries->{$line}[0]]\n"
	    }
	    $contents{$file}[$line-1] = $entries->{$line}[1];
	}
    }

    # check the temp files don't already exist

    for my $file (sort keys %contents) {
	my $nfile = "$file-new";
	die "$nfile already exists in MANIFEST; aborting\n"
	    if $mani_files{$nfile};
    }

    # write out the new files

    for my $file (sort keys %contents) {
	my $nfile = "$file-new";
	open my $fh, '>', $nfile or die "create '$nfile' failed: $!\n";
	binmode $fh;
	print $fh $_, "\n" for @{$contents{$file}};
	close $fh or die "failed to close $nfile; aborting: $!\n";

	my @stat = stat $file or die "Can't stat $file: $!\n";
	my $mode = $stat[2];
	die "stat $file fgailed to give a mode!\n" unless defined $mode;
	chmod $mode & 0777, $nfile or die "chmod $nfile failed; aborting: $!\n";
    }

    # and rename them

    for my $file (sort keys %contents) {
	my $nfile = "$file-new";
	warn "updating $file ...\n";
	rename $nfile, $file or die "rename $nfile $file: $!\n";
    }
}
Commit	Line	Data
ae1b7029 DM	1	#!/usr/bin/perl
	2	#
	3	# bump-perl-version, DAPM 14 Jul 2009
	4	#
	5	# A utility to find, and optionally bump, references to the perl version
	6	# number in various files within the perl source
	7	#
	8	# It's designed to work in two phases. First, when run with -s (scan),
	9	# it searches all the files in MANIFEST looking for strings that appear to
	10	# match the current perl version (or which it knows are supposed to
	11	# contain the current version), and produces a list of them to stdout,
	12	# along with a suggested edit. For example:
	13	#
	14	# $ Porting/bump-perl-version -s 5.10.0 5.10.1 > /tmp/scan
	15	# $ cat /tmp/scan
	16	# Porting/config.sh
	17	#
	18	# 52: -archlib='/opt/perl/lib/5.10.0/i686-linux-64int'
	19	# +archlib='/opt/perl/lib/5.10.1/i686-linux-64int'
	20	# ....
	21	#
	22	# At this point there will be false positives. Edit the file to remove
	23	# those changes you don't want made. Then in the second phase, feed that
	24	# list in, and it will change those lines in the files:
	25	#
	26	# $ Porting/bump-perl-version -u < /tmp/scan
	27	#
	28	# (so line 52 of Porting/config.sh is now updated)
	29
	30	# This utility 'knows' about certain files and formats, and so can spot
	31	# 'hidden' version numbers, like PERL_SUBVERSION=9.
	32	#
	33	# A third variant makes use of this knowledge to check that all the things
	34	# it knows about are at the current version:
	35	#
	36	# $ Porting/bump-perl-version -c 5.10.0
	37	#
	38	# XXX this script hasn't been tested against a major version bump yet,
	39	# eg 5.11.0 to 5.12.0; there may be things it missed - DAPM 14 Jul 09
	40	#
	41	# Note there are various files and directories that it skips; these are
	42	# ones that are unlikely to contain anything needing bumping, but which
	43	# will generate lots fo false positives (eg pod/*). These are listed on
	44	# STDERR as they are skipped.
	45
	46	use strict;
	47	use warnings;
	48	use Getopt::Std;
	49	use ExtUtils::Manifest;
	50
	51
	52	sub usage { die <<EOF }
	53
	54	@_
	55
	56	usage: $0 -c <C.C.C>
	57	-s <C.C.C> <N.N.N>
	58	-u
	59
	60	-c check files and warn if any known string values (eg
	61	PERL_SUBVERSION) don't match the specified version
	62
	63	-s scan files and produce list of possible change lines to stdout
	64
65	-u read in the scan file from stdin, and change all the lines specified
66
67	C.C.C the current perl version, eg 5.10.0
68	N.N.N the new perl version, eg 5.10.1
69	EOF
70
71	my %opts;
72	getopts('csu', \%opts) or usage;
73	if ($opts{u}) {
74	@ARGV == 0 or usage('no version version numbers should be speciied');
75	# fake to stop warnings when calculating $oldx etc
76	@ARGV = qw(99.99.99 99.99.99);
77	}
78	elsif ($opts{c}) {
79	@ARGV == 1 or usage('required one version number');
80	push @ARGV, $ARGV[0];
81	}
82	else {
83	@ARGV == 2 or usage('require two version numbers');
84	}
85	usage('only one of -c, -s and -u') if keys %opts > 1;
86
87	my ($oldx, $oldy, $oldz) = $ARGV[0] =~ /^(\d+)\.(\d+)\.(\d+)$/
88	or usage("bad version: $ARGV[0]");
89	my ($newx, $newy, $newz) = $ARGV[1] =~ /^(\d+)\.(\d+)\.(\d+)$/
90	or usage("bad version: $ARGV[1]");
91
92	my $old_decimal = sprintf "%d.%03d%03d", $oldx, $oldy, $oldz; # 5.011001
93
94	# each entry is
95	# 0 a regexp that matches strings that might contain versions;
96	# 1 a sub that returns two strings based on $1 etc values:
97	# * string containing captured values (for -c)
98	# * a string containing the replacement value
99	# 2 what we expect the sub to return as its first arg; undef implies
100	# don't match
101	# 3 a regex restricting which files this applies to (undef is all files)
102	#
103	# Note that @maps entries are checks in order, and only the first to match
104	# is used.
105
106	my @maps = (
107	[
108	qr{^((?:api_)?version(?:=\|\s+)'?) (\d+) ('?) (?!\.)}x,
109	sub { $2, "$1$newy$3" },
110	$oldy,
111	qr/config/,
112	],
113	[
114	qr{^(subversion(?:=\|\s+)'?) (\d+) ('?) (?!\.)}x,
115	sub { $2, "$1$newz$3" },
116	$oldz,
117	qr/config/,
118	],
119	[
120	qr{^(api_subversion(?:=\|\s+)'?) (\d+) ('?) (?!\.)}x,
121	sub { $2, "${1}0$3" },
122	0,
123	qr/config/,
124	],
125	[
126	qr{^(api_versionstring(?:=\|\s+)'?) ([\d\.]+) ('?) (?!\.)}x,
127	sub { $2, "$1$newx.$newy.0$3" },
128	"$oldx.$oldy.0",
129	qr/config/,
130	],
131	[
132	qr{(version\s+'?) (\d+) ('?\s+subversion\s+'?) (\d+) ('?) (?!\.)}x,
133	sub { "$2-$4", "$1$newy$3$newz$5" },
134	"$oldy-$oldz",
135	qr/config/,
136	],
137	[
138	qr{\b (PERL_(?:API_)?VERSION(?:=\|\s+)'?) (\d+) ('?) (?!\.)}x,
139	sub { $2, "$1$newy$3"},
140	$oldy,
141	],
142	[
143	qr{\b (PERL_SUBVERSION(?:=\|\s+)'?) (\d+) ('?) (?!\.)}x,
144	sub { $2, "$1$newz$3"},
145	$oldz,
146	],
147	[
148	qr{\b (PERL_API_SUBVERSION(?:=\|\s+)'?) (\d+) ('?) (?!\.)}x,
149	sub { $2, "${1}0$3"},
150	0,
151	],
152	# these two formats are in README.vms
153	[
154	qr{\b perl-(\d+\^\.\d+\^\.\d+) \b}x,
155	sub { $1, "perl-$newx^.$newy^.$newz"},
156	undef,
157	],
158	[
159	qr{\b ($oldx _ $oldy _$oldz) \b}x,
160	sub { $1, ($newx . '_' . $newy . '_' . $newz)},
161	undef,
162	],
163	# 5.8.9
164	[
8b8cdb3a	165	qr{ $oldx\.$oldy\.$oldz \b}x,
ae1b7029 DM	166	sub {"", "$newx.$newy.$newz"},
	167	undef,
	168	],
	169
	170	# 5.008009
	171	[
8b8cdb3a	172	qr{ $old_decimal \b}x,
ae1b7029 DM	173	sub {"", sprintf "%d.%03d%03d", $newx, $newy, $newz },
	174	undef,
	175	],
	176
7dfca73b JD	177	# perl511.dll, perl511.lib, perl511s.lib
	178	[
	179	qr{\b perl (\d\d\d) (s?) \. }x,
	180	sub {$1, "perl$newx$newy$2." },
	181	"$oldx$oldy",
	182	qr/win32/, # README.win32, win32/*
	183	],
	184
ae1b7029 DM	185	);
	186
	187
	188	# files and dirs that we likely don't want to change version numbers on.
	189
	190	my %SKIP_FILES = map { ($_ => 1) } qw(
	191	Changes
	192	MANIFEST
	193	Porting/how_to_write_a_perldelta.pod
5bd03515	194	Porting/release_managers_guide.pod
795c888f	195	Porting/release_schedule.pod
8b8cdb3a	196	Porting/bump-perl-version
ae1b7029 DM	197	Porting/mergelog
	198	Porting/mergelog-tool
	199	pod.lst
5bd03515	200	pp_ctl.c
ae1b7029 DM	201	);
	202	my @SKIP_DIRS = qw(
	203	ext
	204	lib
	205	pod
	206	t
	207	);
	208
	209	my @mani_files = sort keys %{ExtUtils::Manifest::maniread('MANIFEST')};
	210	my %mani_files = map { ($_ => 1) } @mani_files;
	211	die "No entries found in MANIFEST; aborting\n" unless @mani_files;
	212
	213	if ($opts{c} or $opts{s}) {
	214	do_scan();
	215	}
	216	elsif ($opts{u}) {
	217	do_update();
	218	}
	219	else {
	220	usage('one of -c, -s or -u must be specifcied');
	221	}
	222	exit 0;
	223
	224
	225
	226
	227	sub do_scan {
	228	for my $file (@mani_files) {
	229	next if grep $file =~ m{$_/}, @SKIP_DIRS;
	230	if ($SKIP_FILES{$file}) {
	231	warn "(skipping $file)\n";
	232	next;
	233	}
	234	open my $fh, '<', $file or die "Aborting: can't open $file: $!\n";
	235	my $header = 0;
	236
	237	while (<$fh>) {
	238	for my $map (@maps) {
	239	my ($pat, $sub, $expected, $file_pat) = @$map;
	240
	241	next if defined $file_pat and $file !~ $file_pat;
	242	next unless $_ =~ $pat;
	243	my ($got, $replacement) = $sub->();
	244
	245	if ($opts{c}) {
	246	# only report unexpected
	247	next unless defined $expected and $got ne $expected;
	248	}
	249	my $newstr = $_;
	250	$newstr =~ s/$pat/$replacement/
	251	or die "Internal error: substitution failed: [$pat]\n";
	252	if ($_ ne $newstr) {
	253	print "\n$file\n" unless $header;
	254	$header=1;
	255	printf "\n%5d: -%s +%s", $., $_, $newstr;
	256	}
	257	last;
	258	}
	259	}
	260	}
	261	warn "(skipped $_/*)\n" for @SKIP_DIRS;
	262	}
	263
	264	sub do_update {
265
266	my %changes;
267	my $file;
268	my $line;
269
270	# read in config
271
272	while (<STDIN>) {
273	next unless /\S/;
274	if (/^(\S+)$/) {
275	$file = $1;
276	die "No such file in MANIFEST: '$file'\n" unless $mani_files{$file};
277	die "file already seen; '$file'\n" if exists $changes{$file};
278	undef $line;
279	}
280	elsif (/^\s+(\d+): -(.*)/) {
281	my $old;
282	($line, $old) = ($1,$2);
283	die "$.: old line without preceeding filename\n"
284	unless defined $file;
285	die "Dup line number: $line\n" if exists $changes{$file}{$line};
286	$changes{$file}{$line}[0] = $old;
287	}
288	elsif (/^\s+\+(.*)/) {
289	my $new = $1;
290	die "$.: replacement line seen without old line\n" unless $line;
291	$changes{$file}{$line}[1] = $new;
292	undef $line;
293	}
294	else {
295	die "Unexpected line at ;line $.: $_\n";
296	}
297	}
298
299	# suck in file contents to memory, then update that in-memory copy
300
301	my %contents;
302	for my $file (sort keys %changes) {
303	open my $fh, '<', $file or die "open '$file': $!\n";
33c1015f	304	binmode $fh;
ae1b7029 DM	305	$contents{$file} = [ <$fh> ];
	306	chomp @{$contents{$file}};
	307	close $fh or die "close: '$file': $!\n";
	308
	309	my $entries = $changes{$file};
	310	for my $line (keys %$entries) {
	311	die "$file: no such line: $line\n"
	312	unless defined $contents{$file}[$line-1];
	313	if ($contents{$file}[$line-1] ne $entries->{$line}[0]) {
	314	die "$file: line mismatch at line $line:\n"
	315	. "File: [$contents{$file}[$line-1]]\n"
	316	. "Config: [$entries->{$line}[0]]\n"
	317	}
	318	$contents{$file}[$line-1] = $entries->{$line}[1];
	319	}
	320	}
	321
	322	# check the temp files don't already exist
	323
	324	for my $file (sort keys %contents) {
	325	my $nfile = "$file-new";
	326	die "$nfile already exists in MANIFEST; aborting\n"
	327	if $mani_files{$nfile};
	328	}
	329
	330	# write out the new files
	331
	332	for my $file (sort keys %contents) {
	333	my $nfile = "$file-new";
	334	open my $fh, '>', $nfile or die "create '$nfile' failed: $!\n";
33c1015f	335	binmode $fh;
ae1b7029 DM	336	print $fh $_, "\n" for @{$contents{$file}};
	337	close $fh or die "failed to close $nfile; aborting: $!\n";
	338
	339	my @stat = stat $file or die "Can't stat $file: $!\n";
	340	my $mode = $stat[2];
	341	die "stat $file fgailed to give a mode!\n" unless defined $mode;
	342	chmod $mode & 0777, $nfile or die "chmod $nfile failed; aborting: $!\n";
	343	}
	344
	345	# and rename them
	346
	347	for my $file (sort keys %contents) {
	348	my $nfile = "$file-new";
	349	warn "updating $file ...\n";
	350	rename $nfile, $file or die "rename $nfile $file: $!\n";
	351	}
	352	}
	353