[perl5.git] / t / run / switches.t

#!./perl -w

# Tests for the command-line switches:
# -0, -c, -l, -s, -m, -M, -V, -v, -h, -i, -E and all unknown
# Some switches have their own tests, see MANIFEST.

BEGIN {
    chdir 't' if -d 't';
    @INC = '../lib';
}

BEGIN { require "./test.pl"; }

plan(tests => 71);

use Config;

# due to a bug in VMS's piping which makes it impossible for runperl()
# to emulate echo -n (ie. stdin always winds up with a newline), these 
# tests almost totally fail.
$TODO = "runperl() unable to emulate echo -n due to pipe bug" if $^O eq 'VMS';

my $r;
my @tmpfiles = ();
END { unlink_all @tmpfiles }

# Tests for -0

$r = runperl(
    switches	=> [ '-0', ],
    stdin	=> 'foo\0bar\0baz\0',
    prog	=> 'print qq(<$_>) while <>',
);
is( $r, "<foo\0><bar\0><baz\0>", "-0" );

$r = runperl(
    switches	=> [ '-l', '-0', '-p' ],
    stdin	=> 'foo\0bar\0baz\0',
    prog	=> '1',
);
is( $r, "foo\nbar\nbaz\n", "-0 after a -l" );

$r = runperl(
    switches	=> [ '-0', '-l', '-p' ],
    stdin	=> 'foo\0bar\0baz\0',
    prog	=> '1',
);
is( $r, "foo\0bar\0baz\0", "-0 before a -l" );

$r = runperl(
    switches	=> [ sprintf("-0%o", ord 'x') ],
    stdin	=> 'fooxbarxbazx',
    prog	=> 'print qq(<$_>) while <>',
);
is( $r, "<foox><barx><bazx>", "-0 with octal number" );

$r = runperl(
    switches	=> [ '-00', '-p' ],
    stdin	=> 'abc\ndef\n\nghi\njkl\nmno\n\npq\n',
    prog	=> 's/\n/-/g;$_.=q(/)',
);
is( $r, 'abc-def--/ghi-jkl-mno--/pq-/', '-00 (paragraph mode)' );

$r = runperl(
    switches	=> [ '-0777', '-p' ],
    stdin	=> 'abc\ndef\n\nghi\njkl\nmno\n\npq\n',
    prog	=> 's/\n/-/g;$_.=q(/)',
);
is( $r, 'abc-def--ghi-jkl-mno--pq-/', '-0777 (slurp mode)' );

$r = runperl(
    switches	=> [ '-066' ],
    prog	=> 'BEGIN { print qq{($/)} } print qq{[$/]}',
);
is( $r, "(\066)[\066]", '$/ set at compile-time' );

# Tests for -c

my $filename = tempfile();
SKIP: {
    local $TODO = '';   # this one works on VMS

    open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
    print $f <<'SWTEST';
BEGIN { print "block 1\n"; }
CHECK { print "block 2\n"; }
INIT  { print "block 3\n"; }
	print "block 4\n";
END   { print "block 5\n"; }
SWTEST
    close $f or die "Could not close: $!";
    $r = runperl(
	switches	=> [ '-c' ],
	progfile	=> $filename,
	stderr		=> 1,
    );
    # Because of the stderr redirection, we can't tell reliably the order
    # in which the output is given
    ok(
	$r =~ /$filename syntax OK/
	&& $r =~ /\bblock 1\b/
	&& $r =~ /\bblock 2\b/
	&& $r !~ /\bblock 3\b/
	&& $r !~ /\bblock 4\b/
	&& $r !~ /\bblock 5\b/,
	'-c'
    );
}

# Tests for -l

$r = runperl(
    switches	=> [ sprintf("-l%o", ord 'x') ],
    prog	=> 'print for qw/foo bar/'
);
is( $r, 'fooxbarx', '-l with octal number' );

# Tests for -s

$r = runperl(
    switches	=> [ '-s' ],
    prog	=> 'for (qw/abc def ghi/) {print defined $$_ ? $$_ : q(-)}',
    args	=> [ '--', '-abc=2', '-def', ],
);
is( $r, '21-', '-s switch parsing' );

$filename = tempfile();
SKIP: {
    open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
    print $f <<'SWTEST';
#!perl -s
BEGIN { print $x,$y; exit }
SWTEST
    close $f or die "Could not close: $!";
    $r = runperl(
	progfile    => $filename,
	args	    => [ '-x=foo -y' ],
    );
    is( $r, 'foo1', '-s on the shebang line' );
}

# Bug ID 20011106.084
$filename = tempfile();
SKIP: {
    open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
    print $f <<'SWTEST';
#!perl -sn
BEGIN { print $x; exit }
SWTEST
    close $f or die "Could not close: $!";
    $r = runperl(
	progfile    => $filename,
	args	    => [ '-x=foo' ],
    );
    is( $r, 'foo', '-sn on the shebang line' );
}

# Tests for -m and -M

my $package = tempfile();
$filename = "$package.pm";
SKIP: {
    open my $f, ">$filename" or skip( "Can't write temp file $filename: $!",4 );
    print $f <<"SWTESTPM";
package $package;
sub import { print map "<\$_>", \@_ }
1;
SWTESTPM
    close $f or die "Could not close: $!";
    $r = runperl(
	switches    => [ "-M$package" ],
	prog	    => '1',
    );
    is( $r, "<$package>", '-M' );
    $r = runperl(
	switches    => [ "-M$package=foo" ],
	prog	    => '1',
    );
    is( $r, "<$package><foo>", '-M with import parameter' );
    $r = runperl(
	switches    => [ "-m$package" ],
	prog	    => '1',
    );

    {
        local $TODO = '';  # this one works on VMS
        is( $r, '', '-m' );
    }
    $r = runperl(
	switches    => [ "-m$package=foo,bar" ],
	prog	    => '1',
    );
    is( $r, "<$package><foo><bar>", '-m with import parameters' );
    push @tmpfiles, $filename;

  {
    local $TODO = '';  # these work on VMS

    is( runperl( switches => [ '-MTie::Hash' ], stderr => 1, prog => 1 ),
	  '', "-MFoo::Bar allowed" );

    like( runperl( switches => [ "-M:$package" ], stderr => 1,
		   prog => 'die q{oops}' ),
	  qr/Invalid module name [\w:]+ with -M option\b/,
          "-M:Foo not allowed" );

    like( runperl( switches => [ '-mA:B:C' ], stderr => 1,
		   prog => 'die q{oops}' ),
	  qr/Invalid module name [\w:]+ with -m option\b/,
          "-mFoo:Bar not allowed" );

    like( runperl( switches => [ '-m-A:B:C' ], stderr => 1,
		   prog => 'die q{oops}' ),
	  qr/Invalid module name [\w:]+ with -m option\b/,
          "-m-Foo:Bar not allowed" );

    like( runperl( switches => [ '-m-' ], stderr => 1,
		   prog => 'die q{oops}' ),
	  qr/Module name required with -m option\b/,
  	  "-m- not allowed" );

    like( runperl( switches => [ '-M-=' ], stderr => 1,
		   prog => 'die q{oops}' ),
	  qr/Module name required with -M option\b/,
  	  "-M- not allowed" );
  }  # disable TODO on VMS
}

# Tests for -V

{
    local $TODO = '';   # these ones should work on VMS

    # basic perl -V should generate significant output.
    # we don't test actual format too much since it could change
    like( runperl( switches => ['-V'] ), qr/(\n.*){20}/,
          '-V generates 20+ lines' );

    like( runperl( switches => ['-V'] ),
	  qr/\ASummary of my perl5 .*configuration:/,
          '-V looks okay' );

    # lookup a known config var
    chomp( $r=runperl( switches => ['-V:osname'] ) );
    is( $r, "osname='$^O';", 'perl -V:osname');

    # lookup a nonexistent var
    chomp( $r=runperl( switches => ['-V:this_var_makes_switches_test_fail'] ) );
    is( $r, "this_var_makes_switches_test_fail='UNKNOWN';",
        'perl -V:unknown var');

    # regexp lookup
    # platforms that don't like this quoting can either skip this test
    # or fix test.pl _quote_args
    $r = runperl( switches => ['"-V:i\D+size"'] );
    # should be unlike( $r, qr/^$|not found|UNKNOWN/ );
    like( $r, qr/^(?!.*(not found|UNKNOWN))./, 'perl -V:re got a result' );

    # make sure each line we got matches the re
    ok( !( grep !/^i\D+size=/, split /^/, $r ), '-V:re correct' );
}

# Tests for -v

{
    local $TODO = '';   # these ones should work on VMS
    # there are definitely known build configs where this test will fail
    # DG/UX comes to mind. Maybe we should remove these special cases?
    my $v = sprintf "%vd", $^V;
    my $ver = $Config{PERL_VERSION};
    my $rel = $Config{PERL_SUBVERSION};
    like( runperl( switches => ['-v'] ),
	  qr/This is perl 5, version \Q$ver\E, subversion \Q$rel\E \(v\Q$v\E(?:[-*\w]+| \([^)]+\))?\) built for \Q$Config{archname}\E.+Copyright.+Larry Wall.+Artistic License.+GNU General Public License/s,
          '-v looks okay' );

}

# Tests for -h

{
    local $TODO = '';   # these ones should work on VMS

    like( runperl( switches => ['-h'] ),
	  qr/Usage: .+(?i:perl(?:$Config{_exe})?).+switches.+programfile.+arguments/,
          '-h looks okay' );

}

# Tests for switches which do not exist

foreach my $switch (split //, "ABbGgHJjKkLNOoPQqRrYyZz123456789_")
{
    local $TODO = '';   # these ones should work on VMS

    like( runperl( switches => ["-$switch"], stderr => 1,
		   prog => 'die q{oops}' ),
	  qr/\QUnrecognized switch: -$switch  (-h will show valid options)./,
          "-$switch correctly unknown" );

}

# Tests for -i

{
    local $TODO = '';   # these ones should work on VMS

    sub do_i_unlink { unlink_all("file", "file.bak") }

    open(FILE, ">file") or die "$0: Failed to create 'file': $!";
    print FILE <<__EOF__;
foo yada dada
bada foo bing
king kong foo
__EOF__
    close FILE;

    END { do_i_unlink() }

    runperl( switches => ['-pi.bak'], prog => 's/foo/bar/', args => ['file'] );

    open(FILE, "file") or die "$0: Failed to open 'file': $!";
    chomp(my @file = <FILE>);
    close FILE;

    open(BAK, "file.bak") or die "$0: Failed to open 'file': $!";
    chomp(my @bak = <BAK>);
    close BAK;

    is(join(":", @file),
       "bar yada dada:bada bar bing:king kong bar",
       "-i new file");
    is(join(":", @bak),
       "foo yada dada:bada foo bing:king kong foo",
       "-i backup file");
}

# Tests for -E

$TODO = '';  # the -E tests work on VMS

$r = runperl(
    switches	=> [ '-E', '"say q(Hello, world!)"']
);
is( $r, "Hello, world!\n", "-E say" );


$r = runperl(
    switches	=> [ '-E', '"undef ~~ undef and say q(Hello, world!)"']
);
is( $r, "Hello, world!\n", "-E ~~" );

$r = runperl(
    switches	=> [ '-E', '"given(undef) {when(undef) { say q(Hello, world!)"}}']
);
is( $r, "Hello, world!\n", "-E given" );

$r = runperl(
    switches    => [ '-nE', q("} END { say q/affe/") ],
    stdin       => 'zomtek',
);
is( $r, "affe\n", '-E works outside of the block created by -n' );

$r = runperl(
    switches	=> [ '-E', q("*{'bar'} = sub{}; print 'Hello, world!',qq|\n|;")]
);
is( $r, "Hello, world!\n", "-E does not enable strictures" );

# RT #30660

$filename = tempfile();
SKIP: {
    open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
    print $f <<'SWTEST';
#!perl -w    -iok
print "$^I\n";
SWTEST
    close $f or die "Could not close: $!";
    $r = runperl(
	progfile    => $filename,
    );
    like( $r, qr/ok/, 'Spaces on the #! line (#30660)' );
}
Commit	Line	Data
8a73d5dd RGS	1	#!./perl -w
8a73d5dd RGS	2
feafb1eb	3	# Tests for the command-line switches:
fed0ca7f	4	# -0, -c, -l, -s, -m, -M, -V, -v, -h, -i, -E and all unknown
48eaf804	5	# Some switches have their own tests, see MANIFEST.
8a73d5dd RGS	6
	7	BEGIN {
	8	chdir 't' if -d 't';
	9	@INC = '../lib';
	10	}
	11
768fd157	12	BEGIN { require "./test.pl"; }
8a73d5dd	13
53eb19dd	14	plan(tests => 71);
8a73d5dd	15
a09a0aa2 JH	16	use Config;
a09a0aa2 JH	17
b734d6c9	18	# due to a bug in VMS's piping which makes it impossible for runperl()
e54d2dfa JH	19	# to emulate echo -n (ie. stdin always winds up with a newline), these
e54d2dfa JH	20	# tests almost totally fail.
b734d6c9 MS	21	$TODO = "runperl() unable to emulate echo -n due to pipe bug" if $^O eq 'VMS';
b734d6c9 MS	22
8a73d5dd RGS	23	my $r;
8a73d5dd RGS	24	my @tmpfiles = ();
a29d0261	25	END { unlink_all @tmpfiles }
8a73d5dd RGS	26
	27	# Tests for -0
	28
	29	$r = runperl(
	30	switches => [ '-0', ],
	31	stdin => 'foo\0bar\0baz\0',
	32	prog => 'print qq(<$_>) while <>',
	33	);
	34	is( $r, "<foo\0><bar\0><baz\0>", "-0" );
	35
	36	$r = runperl(
	37	switches => [ '-l', '-0', '-p' ],
	38	stdin => 'foo\0bar\0baz\0',
	39	prog => '1',
	40	);
	41	is( $r, "foo\nbar\nbaz\n", "-0 after a -l" );
	42
	43	$r = runperl(
	44	switches => [ '-0', '-l', '-p' ],
	45	stdin => 'foo\0bar\0baz\0',
	46	prog => '1',
	47	);
	48	is( $r, "foo\0bar\0baz\0", "-0 before a -l" );
	49
	50	$r = runperl(
	51	switches => [ sprintf("-0%o", ord 'x') ],
	52	stdin => 'fooxbarxbazx',
	53	prog => 'print qq(<$_>) while <>',
	54	);
	55	is( $r, "<foox><barx><bazx>", "-0 with octal number" );
	56
	57	$r = runperl(
	58	switches => [ '-00', '-p' ],
	59	stdin => 'abc\ndef\n\nghi\njkl\nmno\n\npq\n',
	60	prog => 's/\n/-/g;$_.=q(/)',
	61	);
	62	is( $r, 'abc-def--/ghi-jkl-mno--/pq-/', '-00 (paragraph mode)' );
	63
	64	$r = runperl(
	65	switches => [ '-0777', '-p' ],
	66	stdin => 'abc\ndef\n\nghi\njkl\nmno\n\npq\n',
	67	prog => 's/\n/-/g;$_.=q(/)',
	68	);
	69	is( $r, 'abc-def--ghi-jkl-mno--pq-/', '-0777 (slurp mode)' );
	70
7f9e821f RGS	71	$r = runperl(
7f9e821f RGS	72	switches => [ '-066' ],
0fbedf1d	73	prog => 'BEGIN { print qq{($/)} } print qq{[$/]}',
7f9e821f RGS	74	);
	75	is( $r, "(\066)[\066]", '$/ set at compile-time' );
	76
8a73d5dd RGS	77	# Tests for -c
8a73d5dd RGS	78
2d90ac95	79	my $filename = tempfile();
8a73d5dd	80	SKIP: {
b734d6c9 MS	81	local $TODO = ''; # this one works on VMS
b734d6c9 MS	82
8a73d5dd RGS	83	open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
	84	print $f <<'SWTEST';
	85	BEGIN { print "block 1\n"; }
	86	CHECK { print "block 2\n"; }
	87	INIT { print "block 3\n"; }
	88	print "block 4\n";
	89	END { print "block 5\n"; }
	90	SWTEST
d1e4d418	91	close $f or die "Could not close: $!";
8a73d5dd RGS	92	$r = runperl(
	93	switches => [ '-c' ],
	94	progfile => $filename,
	95	stderr => 1,
	96	);
	97	# Because of the stderr redirection, we can't tell reliably the order
	98	# in which the output is given
	99	ok(
	100	$r =~ /$filename syntax OK/
	101	&& $r =~ /\bblock 1\b/
	102	&& $r =~ /\bblock 2\b/
	103	&& $r !~ /\bblock 3\b/
	104	&& $r !~ /\bblock 4\b/
	105	&& $r !~ /\bblock 5\b/,
	106	'-c'
	107	);
8a73d5dd RGS	108	}
	109
	110	# Tests for -l
	111
	112	$r = runperl(
	113	switches => [ sprintf("-l%o", ord 'x') ],
	114	prog => 'print for qw/foo bar/'
	115	);
	116	is( $r, 'fooxbarx', '-l with octal number' );
	117
	118	# Tests for -s
	119
	120	$r = runperl(
	121	switches => [ '-s' ],
	122	prog => 'for (qw/abc def ghi/) {print defined $$_ ? $$_ : q(-)}',
	123	args => [ '--', '-abc=2', '-def', ],
	124	);
	125	is( $r, '21-', '-s switch parsing' );
	126
2d90ac95	127	$filename = tempfile();
8a73d5dd RGS	128	SKIP: {
	129	open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
	130	print $f <<'SWTEST';
59e235cb GA	131	#!perl -s
	132	BEGIN { print $x,$y; exit }
	133	SWTEST
	134	close $f or die "Could not close: $!";
	135	$r = runperl(
	136	progfile => $filename,
	137	args => [ '-x=foo -y' ],
	138	);
	139	is( $r, 'foo1', '-s on the shebang line' );
59e235cb GA	140	}
	141
	142	# Bug ID 20011106.084
2d90ac95	143	$filename = tempfile();
59e235cb GA	144	SKIP: {
	145	open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
	146	print $f <<'SWTEST';
f0b2cf55 YST	147	#!perl -sn
f0b2cf55 YST	148	BEGIN { print $x; exit }
8a73d5dd	149	SWTEST
d1e4d418	150	close $f or die "Could not close: $!";
8a73d5dd	151	$r = runperl(
8a73d5dd RGS	152	progfile => $filename,
	153	args => [ '-x=foo' ],
	154	);
59e235cb	155	is( $r, 'foo', '-sn on the shebang line' );
8a73d5dd RGS	156	}
	157
	158	# Tests for -m and -M
	159
2d90ac95 NC	160	my $package = tempfile();
2d90ac95 NC	161	$filename = "$package.pm";
8a73d5dd RGS	162	SKIP: {
8a73d5dd RGS	163	open my $f, ">$filename" or skip( "Can't write temp file $filename: $!",4 );
2d90ac95 NC	164	print $f <<"SWTESTPM";
	165	package $package;
	166	sub import { print map "<\$_>", \@_ }
8a73d5dd RGS	167	1;
8a73d5dd RGS	168	SWTESTPM
d1e4d418	169	close $f or die "Could not close: $!";
8a73d5dd	170	$r = runperl(
2d90ac95	171	switches => [ "-M$package" ],
8a73d5dd RGS	172	prog => '1',
8a73d5dd RGS	173	);
2d90ac95	174	is( $r, "<$package>", '-M' );
8a73d5dd	175	$r = runperl(
2d90ac95	176	switches => [ "-M$package=foo" ],
8a73d5dd RGS	177	prog => '1',
8a73d5dd RGS	178	);
2d90ac95	179	is( $r, "<$package><foo>", '-M with import parameter' );
8a73d5dd	180	$r = runperl(
2d90ac95	181	switches => [ "-m$package" ],
8a73d5dd RGS	182	prog => '1',
8a73d5dd RGS	183	);
b734d6c9 MS	184
	185	{
	186	local $TODO = ''; # this one works on VMS
	187	is( $r, '', '-m' );
	188	}
8a73d5dd	189	$r = runperl(
2d90ac95	190	switches => [ "-m$package=foo,bar" ],
8a73d5dd RGS	191	prog => '1',
8a73d5dd RGS	192	);
2d90ac95	193	is( $r, "<$package><foo><bar>", '-m with import parameters' );
8a73d5dd	194	push @tmpfiles, $filename;
0544e6df	195
3012b817 CB	196	{
	197	local $TODO = ''; # these work on VMS
	198
0544e6df RB	199	is( runperl( switches => [ '-MTie::Hash' ], stderr => 1, prog => 1 ),
	200	'', "-MFoo::Bar allowed" );
	201
2d90ac95	202	like( runperl( switches => [ "-M:$package" ], stderr => 1,
3d7a9343	203	prog => 'die q{oops}' ),
0544e6df RB	204	qr/Invalid module name [\w:]+ with -M option\b/,
	205	"-M:Foo not allowed" );
	206
	207	like( runperl( switches => [ '-mA:B:C' ], stderr => 1,
3d7a9343	208	prog => 'die q{oops}' ),
0544e6df RB	209	qr/Invalid module name [\w:]+ with -m option\b/,
	210	"-mFoo:Bar not allowed" );
	211
	212	like( runperl( switches => [ '-m-A:B:C' ], stderr => 1,
3d7a9343	213	prog => 'die q{oops}' ),
0544e6df RB	214	qr/Invalid module name [\w:]+ with -m option\b/,
	215	"-m-Foo:Bar not allowed" );
	216
	217	like( runperl( switches => [ '-m-' ], stderr => 1,
3d7a9343	218	prog => 'die q{oops}' ),
0544e6df RB	219	qr/Module name required with -m option\b/,
	220	"-m- not allowed" );
	221
	222	like( runperl( switches => [ '-M-=' ], stderr => 1,
3d7a9343	223	prog => 'die q{oops}' ),
0544e6df RB	224	qr/Module name required with -M option\b/,
0544e6df RB	225	"-M- not allowed" );
3012b817	226	} # disable TODO on VMS
8a73d5dd	227	}
e54d2dfa JH	228
	229	# Tests for -V
	230
	231	{
	232	local $TODO = ''; # these ones should work on VMS
	233
	234	# basic perl -V should generate significant output.
ceda46a1	235	# we don't test actual format too much since it could change
e54d2dfa JH	236	like( runperl( switches => ['-V'] ), qr/(\n.*){20}/,
	237	'-V generates 20+ lines' );
	238
ceda46a1 JH	239	like( runperl( switches => ['-V'] ),
	240	qr/\ASummary of my perl5 .*configuration:/,
	241	'-V looks okay' );
	242
e54d2dfa JH	243	# lookup a known config var
	244	chomp( $r=runperl( switches => ['-V:osname'] ) );
	245	is( $r, "osname='$^O';", 'perl -V:osname');
	246
	247	# lookup a nonexistent var
	248	chomp( $r=runperl( switches => ['-V:this_var_makes_switches_test_fail'] ) );
	249	is( $r, "this_var_makes_switches_test_fail='UNKNOWN';",
	250	'perl -V:unknown var');
	251
	252	# regexp lookup
	253	# platforms that don't like this quoting can either skip this test
	254	# or fix test.pl _quote_args
	255	$r = runperl( switches => ['"-V:i\D+size"'] );
	256	# should be unlike( $r, qr/^$\|not found\|UNKNOWN/ );
	257	like( $r, qr/^(?!.*(not found\|UNKNOWN))./, 'perl -V:re got a result' );
	258
	259	# make sure each line we got matches the re
	260	ok( !( grep !/^i\D+size=/, split /^/, $r ), '-V:re correct' );
	261	}
ceda46a1 JH	262
	263	# Tests for -v
	264
	265	{
	266	local $TODO = ''; # these ones should work on VMS
46807d8e YO	267	# there are definitely known build configs where this test will fail
46807d8e YO	268	# DG/UX comes to mind. Maybe we should remove these special cases?
ceda46a1	269	my $v = sprintf "%vd", $^V;
ded326e4 DG	270	my $ver = $Config{PERL_VERSION};
ded326e4 DG	271	my $rel = $Config{PERL_SUBVERSION};
ceda46a1	272	like( runperl( switches => ['-v'] ),
ded326e4	273	qr/This is perl 5, version \Q$ver\E, subversion \Q$rel\E \(v\Q$v\E(?:[-*\w]+\| \([^)]+\))?\) built for \Q$Config{archname}\E.+Copyright.+Larry Wall.+Artistic License.+GNU General Public License/s,
ceda46a1 JH	274	'-v looks okay' );
	275
	276	}
b8e3af44 JH	277
	278	# Tests for -h
	279
	280	{
	281	local $TODO = ''; # these ones should work on VMS
	282
	283	like( runperl( switches => ['-h'] ),
a09a0aa2	284	qr/Usage: .+(?i:perl(?:$Config{_exe})?).+switches.+programfile.+arguments/,
b8e3af44 JH	285	'-h looks okay' );
	286
	287	}
	288
fed0ca7f	289	# Tests for switches which do not exist
b8e3af44	290
96889982	291	foreach my $switch (split //, "ABbGgHJjKkLNOoPQqRrYyZz123456789_")
b8e3af44 JH	292	{
	293	local $TODO = ''; # these ones should work on VMS
	294
fed0ca7f	295	like( runperl( switches => ["-$switch"], stderr => 1,
3d7a9343	296	prog => 'die q{oops}' ),
fed0ca7f NC	297	qr/\QUnrecognized switch: -$switch (-h will show valid options)./,
fed0ca7f NC	298	"-$switch correctly unknown" );
b8e3af44 JH	299
b8e3af44 JH	300	}
feafb1eb JH	301
	302	# Tests for -i
	303
	304	{
	305	local $TODO = ''; # these ones should work on VMS
	306
a29d0261	307	sub do_i_unlink { unlink_all("file", "file.bak") }
feafb1eb JH	308
	309	open(FILE, ">file") or die "$0: Failed to create 'file': $!";
	310	print FILE <<__EOF__;
	311	foo yada dada
	312	bada foo bing
	313	king kong foo
	314	__EOF__
	315	close FILE;
	316
	317	END { do_i_unlink() }
	318
	319	runperl( switches => ['-pi.bak'], prog => 's/foo/bar/', args => ['file'] );
	320
	321	open(FILE, "file") or die "$0: Failed to open 'file': $!";
	322	chomp(my @file = <FILE>);
	323	close FILE;
	324
	325	open(BAK, "file.bak") or die "$0: Failed to open 'file': $!";
	326	chomp(my @bak = <BAK>);
	327	close BAK;
	328
	329	is(join(":", @file),
	330	"bar yada dada:bada bar bing:king kong bar",
	331	"-i new file");
	332	is(join(":", @bak),
	333	"foo yada dada:bada foo bing:king kong foo",
	334	"-i backup file");
	335	}
bc9b29db RH	336
	337	# Tests for -E
	338
3012b817 CB	339	$TODO = ''; # the -E tests work on VMS
3012b817 CB	340
bc9b29db RH	341	$r = runperl(
	342	switches => [ '-E', '"say q(Hello, world!)"']
	343	);
	344	is( $r, "Hello, world!\n", "-E say" );
	345
	346
	347	$r = runperl(
bc9b29db RH	348	switches => [ '-E', '"undef ~~ undef and say q(Hello, world!)"']
	349	);
	350	is( $r, "Hello, world!\n", "-E ~~" );
	351
	352	$r = runperl(
	353	switches => [ '-E', '"given(undef) {when(undef) { say q(Hello, world!)"}}']
	354	);
	355	is( $r, "Hello, world!\n", "-E given" );
9f639728 FR	356
9f639728 FR	357	$r = runperl(
f21873d1	358	switches => [ '-nE', q("} END { say q/affe/") ],
9f639728 FR	359	stdin => 'zomtek',
	360	);
	361	is( $r, "affe\n", '-E works outside of the block created by -n' );
d3133c89	362
53eb19dd S	363	$r = runperl(
	364	switches => [ '-E', q("*{'bar'} = sub{}; print 'Hello, world!',qq\|\n\|;")]
	365	);
	366	is( $r, "Hello, world!\n", "-E does not enable strictures" );
	367
d3133c89 NC	368	# RT #30660
	369
	370	$filename = tempfile();
	371	SKIP: {
	372	open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
	373	print $f <<'SWTEST';
	374	#!perl -w -iok
	375	print "$^I\n";
	376	SWTEST
	377	close $f or die "Could not close: $!";
	378	$r = runperl(
	379	progfile => $filename,
	380	);
	381	like( $r, qr/ok/, 'Spaces on the #! line (#30660)' );
	382	}