[perl5.git] / lib / AutoLoader.pm

package AutoLoader;

use 5.005_64;
our(@EXPORT, @EXPORT_OK, $VERSION);

my $is_dosish;
my $is_vms;

BEGIN {
    require Exporter;
    @EXPORT = @EXPORT = ();
    @EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
    $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32';
    $is_vms = $^O eq 'VMS';
    $VERSION = '5.57';
}

AUTOLOAD {
    my $sub = $AUTOLOAD;
    my $filename;
    # Braces used to preserve $1 et al.
    {
	# Try to find the autoloaded file from the package-qualified
	# name of the sub. e.g., if the sub needed is
	# Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
	# something like '/usr/lib/perl5/Getopt/Long.pm', and the
	# autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
	#
	# However, if @INC is a relative path, this might not work.  If,
	# for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
	# 'lib/Getopt/Long.pm', and we want to require
	# 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
	# In this case, we simple prepend the 'auto/' and let the
	# C<require> take care of the searching for us.

	my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
	$pkg =~ s#::#/#g;
	if (defined($filename = $INC{"$pkg.pm"})) {
	    $filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;

	    # if the file exists, then make sure that it is a
	    # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
	    # or './lib/auto/foo/bar.al'.  This avoids C<require> searching
	    # (and failing) to find the 'lib/auto/foo/bar.al' because it
	    # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').

	    if (-r $filename) {
		unless ($filename =~ m|^/|s) {
		    if ($is_dosish) {
			unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
			     $filename = "./$filename";
			}
		    }
		    elsif ($is_vms) {
			# XXX todo by VMSmiths
			$filename = "./$filename";
		    }
		    else {
			$filename = "./$filename";
		    }
		}
	    }
	    else {
		$filename = undef;
	    }
	}
	unless (defined $filename) {
	    # let C<require> do the searching
	    $filename = "auto/$sub.al";
	    $filename =~ s#::#/#g;
	}
    }
    my $save = $@;
    eval { local $SIG{__DIE__}; require $filename };
    if ($@) {
	if (substr($sub,-9) eq '::DESTROY') {
	    *$sub = sub {};
	} else {
	    # The load might just have failed because the filename was too
	    # long for some old SVR3 systems which treat long names as errors.
	    # If we can succesfully truncate a long name then it's worth a go.
	    # There is a slight risk that we could pick up the wrong file here
	    # but autosplit should have warned about that when splitting.
	    if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
		eval { local $SIG{__DIE__}; require $filename };
	    }
	    if ($@){
		$@ =~ s/ at .*\n//;
		my $error = $@;
		require Carp;
		Carp::croak($error);
	    }
	}
    }
    $@ = $save;
    goto &$sub;
}

sub import {
    my $pkg = shift;
    my $callpkg = caller;

    #
    # Export symbols, but not by accident of inheritance.
    #

    if ($pkg eq 'AutoLoader') {
      local $Exporter::ExportLevel = 1;
      Exporter::import $pkg, @_;
    }

    #
    # Try to find the autosplit index file.  Eg., if the call package
    # is POSIX, then $INC{POSIX.pm} is something like
    # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
    # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
    #
    # However, if @INC is a relative path, this might not work.  If,
    # for example, @INC = ('lib'), then
    # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
    # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
    #

    (my $calldir = $callpkg) =~ s#::#/#g;
    my $path = $INC{$calldir . '.pm'};
    if (defined($path)) {
	# Try absolute path name.
	$path =~ s#^(.*)$calldir\.pm$#$1auto/$calldir/autosplit.ix#;
	eval { require $path; };
	# If that failed, try relative path with normal @INC searching.
	if ($@) {
	    $path ="auto/$calldir/autosplit.ix";
	    eval { require $path; };
	}
	if ($@) {
	    my $error = $@;
	    require Carp;
	    Carp::carp($error);
	}
    } 
}

1;

__END__

=head1 NAME

AutoLoader - load subroutines only on demand

=head1 SYNOPSIS

    package Foo;
    use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine

    package Bar;
    use AutoLoader;              # don't import AUTOLOAD, define our own
    sub AUTOLOAD {
        ...
        $AutoLoader::AUTOLOAD = "...";
        goto &AutoLoader::AUTOLOAD;
    }

=head1 DESCRIPTION

The B<AutoLoader> module works with the B<AutoSplit> module and the
C<__END__> token to defer the loading of some subroutines until they are
used rather than loading them all at once.

To use B<AutoLoader>, the author of a module has to place the
definitions of subroutines to be autoloaded after an C<__END__> token.
(See L<perldata>.)  The B<AutoSplit> module can then be run manually to
extract the definitions into individual files F<auto/funcname.al>.

B<AutoLoader> implements an AUTOLOAD subroutine.  When an undefined
subroutine in is called in a client module of B<AutoLoader>,
B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
file with a name related to the location of the file from which the
client module was read.  As an example, if F<POSIX.pm> is located in
F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
the C<.al> file has the same name as the subroutine, sans package.  If
such a file exists, AUTOLOAD will read and evaluate it,
thus (presumably) defining the needed subroutine.  AUTOLOAD will then
C<goto> the newly defined subroutine.

Once this process completes for a given function, it is defined, so
future calls to the subroutine will bypass the AUTOLOAD mechanism.

=head2 Subroutine Stubs

In order for object method lookup and/or prototype checking to operate
correctly even when methods have not yet been defined it is necessary to
"forward declare" each subroutine (as in C<sub NAME;>).  See
L<perlsub/"SYNOPSIS">.  Such forward declaration creates "subroutine
stubs", which are place holders with no code.

The AutoSplit and B<AutoLoader> modules automate the creation of forward
declarations.  The AutoSplit module creates an 'index' file containing
forward declarations of all the AutoSplit subroutines.  When the
AutoLoader module is 'use'd it loads these declarations into its callers
package.

Because of this mechanism it is important that B<AutoLoader> is always
C<use>d and not C<require>d.

=head2 Using B<AutoLoader>'s AUTOLOAD Subroutine

In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
explicitly import it:

    use AutoLoader 'AUTOLOAD';

=head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine

Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
They typically need to check for some special cases (such as constants)
and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.

Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
Instead, they should define their own AUTOLOAD subroutines along these
lines:

    use AutoLoader;
    use Carp;

    sub AUTOLOAD {
        my $sub = $AUTOLOAD;
        (my $constname = $sub) =~ s/.*:://;
        my $val = constant($constname, @_ ? $_[0] : 0);
        if ($! != 0) {
            if ($! =~ /Invalid/ || $!{EINVAL}) {
                $AutoLoader::AUTOLOAD = $sub;
                goto &AutoLoader::AUTOLOAD;
            }
            else {
                croak "Your vendor has not defined constant $constname";
            }
        }
        *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
        goto &$sub;
    }

If any module's own AUTOLOAD subroutine has no need to fallback to the
AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
subroutines), then that module should not use B<AutoLoader> at all.

=head2 Package Lexicals

Package lexicals declared with C<my> in the main block of a package
using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
the fact that the given scope ends at the C<__END__> marker.  A module
using such variables as package globals will not work properly under the
B<AutoLoader>.

The C<vars> pragma (see L<perlmod/"vars">) may be used in such
situations as an alternative to explicitly qualifying all globals with
the package namespace.  Variables pre-declared with this pragma will be
visible to any autoloaded routines (but will not be invisible outside
the package, unfortunately).

=head2 B<AutoLoader> vs. B<SelfLoader>

The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
loading of subroutines.

B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
While this avoids the use of a hierarchy of disk files and the
associated open/close for each routine loaded, B<SelfLoader> suffers a
startup speed disadvantage in the one-time parsing of the lines after
C<__DATA__>, after which routines are cached.  B<SelfLoader> can also
handle multiple packages in a file.

B<AutoLoader> only reads code as it is requested, and in many cases
should be faster, but requires a mechanism like B<AutoSplit> be used to
create the individual files.  L<ExtUtils::MakeMaker> will invoke
B<AutoSplit> automatically if B<AutoLoader> is used in a module source
file.

=head1 CAVEATS

AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
old modules which use B<AutoLoader> should be changed to the new calling
style.  Typically this just means changing a require to a use, adding
the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
from C<@ISA>.

On systems with restrictions on file name length, the file corresponding
to a subroutine may have a shorter name that the routine itself.  This
can lead to conflicting file names.  The I<AutoSplit> package warns of
these potential conflicts when used to split a module.

AutoLoader may fail to find the autosplit files (or even find the wrong
ones) in cases where C<@INC> contains relative paths, B<and> the program
does C<chdir>.

=head1 SEE ALSO

L<SelfLoader> - an autoloader that doesn't use external files.

=cut
Commit	Line	Data
8990e307	1	package AutoLoader;
21c92a1d	2
17f410f9 GS	3	use 5.005_64;
17f410f9 GS	4	our(@EXPORT, @EXPORT_OK, $VERSION);
f06db76b	5
adaafad2 GS	6	my $is_dosish;
	7	my $is_vms;
	8
1be0b951 CS	9	BEGIN {
1be0b951 CS	10	require Exporter;
e3d0cac0 IZ	11	@EXPORT = @EXPORT = ();
e3d0cac0 IZ	12	@EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
adaafad2 GS	13	$is_dosish = $^O eq 'dos' \|\| $^O eq 'os2' \|\| $^O eq 'MSWin32';
adaafad2 GS	14	$is_vms = $^O eq 'VMS';
9426adcd	15	$VERSION = '5.57';
1be0b951	16	}
f06db76b	17
8990e307	18	AUTOLOAD {
7d4fbd98 GS	19	my $sub = $AUTOLOAD;
7d4fbd98 GS	20	my $filename;
5a556d17 NIS	21	# Braces used to preserve $1 et al.
5a556d17 NIS	22	{
adaafad2 GS	23	# Try to find the autoloaded file from the package-qualified
	24	# name of the sub. e.g., if the sub needed is
	25	# Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
	26	# something like '/usr/lib/perl5/Getopt/Long.pm', and the
	27	# autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
	28	#
	29	# However, if @INC is a relative path, this might not work. If,
	30	# for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
	31	# 'lib/Getopt/Long.pm', and we want to require
	32	# 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
	33	# In this case, we simple prepend the 'auto/' and let the
	34	# C<require> take care of the searching for us.
	35
7d4fbd98	36	my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
adaafad2	37	$pkg =~ s#::#/#g;
7d4fbd98	38	if (defined($filename = $INC{"$pkg.pm"})) {
14a089c5	39	$filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
adaafad2 GS	40
	41	# if the file exists, then make sure that it is a
	42	# a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
	43	# or './lib/auto/foo/bar.al'. This avoids C<require> searching
	44	# (and failing) to find the 'lib/auto/foo/bar.al' because it
	45	# looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').
	46
7d4fbd98	47	if (-r $filename) {
14a089c5	48	unless ($filename =~ m\|^/\|s) {
adaafad2	49	if ($is_dosish) {
14a089c5	50	unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
7d4fbd98	51	$filename = "./$filename";
adaafad2 GS	52	}
	53	}
	54	elsif ($is_vms) {
7d4fbd98 GS	55	# XXX todo by VMSmiths
7d4fbd98 GS	56	$filename = "./$filename";
adaafad2 GS	57	}
adaafad2 GS	58	else {
7d4fbd98	59	$filename = "./$filename";
adaafad2 GS	60	}
	61	}
	62	}
	63	else {
7d4fbd98	64	$filename = undef;
adaafad2 GS	65	}
adaafad2 GS	66	}
7d4fbd98	67	unless (defined $filename) {
adaafad2	68	# let C<require> do the searching
7d4fbd98 GS	69	$filename = "auto/$sub.al";
7d4fbd98 GS	70	$filename =~ s#::#/#g;
adaafad2	71	}
5a556d17	72	}
e14baed2	73	my $save = $@;
7d4fbd98	74	eval { local $SIG{__DIE__}; require $filename };
8990e307	75	if ($@) {
7d4fbd98 GS	76	if (substr($sub,-9) eq '::DESTROY') {
7d4fbd98 GS	77	*$sub = sub {};
e14baed2	78	} else {
	79	# The load might just have failed because the filename was too
	80	# long for some old SVR3 systems which treat long names as errors.
	81	# If we can succesfully truncate a long name then it's worth a go.
	82	# There is a slight risk that we could pick up the wrong file here
	83	# but autosplit should have warned about that when splitting.
7d4fbd98 GS	84	if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
7d4fbd98 GS	85	eval { local $SIG{__DIE__}; require $filename };
e14baed2	86	}
	87	if ($@){
	88	$@ =~ s/ at .*\n//;
fb73857a	89	my $error = $@;
	90	require Carp;
	91	Carp::croak($error);
e14baed2	92	}
a0d0e21e	93	}
8990e307	94	}
e14baed2	95	$@ = $save;
7d4fbd98	96	goto &$sub;
8990e307	97	}
1be0b951	98
c2960299	99	sub import {
1be0b951 CS	100	my $pkg = shift;
	101	my $callpkg = caller;
	102
	103	#
	104	# Export symbols, but not by accident of inheritance.
	105	#
	106
e3d0cac0 IZ	107	if ($pkg eq 'AutoLoader') {
	108	local $Exporter::ExportLevel = 1;
	109	Exporter::import $pkg, @_;
	110	}
1be0b951 CS	111
1be0b951 CS	112	#
c2960299 AD	113	# Try to find the autosplit index file. Eg., if the call package
	114	# is POSIX, then $INC{POSIX.pm} is something like
	115	# '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
	116	# '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
	117	#
	118	# However, if @INC is a relative path, this might not work. If,
	119	# for example, @INC = ('lib'), then
	120	# $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
	121	# 'auto/POSIX/autosplit.ix' (without the leading 'lib').
	122	#
1be0b951	123
1c1c7f20	124	(my $calldir = $callpkg) =~ s#::#/#g;
1be0b951 CS	125	my $path = $INC{$calldir . '.pm'};
1be0b951 CS	126	if (defined($path)) {
c2960299	127	# Try absolute path name.
1be0b951	128	$path =~ s#^(.*)$calldir\.pm$#$1auto/$calldir/autosplit.ix#;
c2960299 AD	129	eval { require $path; };
	130	# If that failed, try relative path with normal @INC searching.
	131	if ($@) {
1be0b951	132	$path ="auto/$calldir/autosplit.ix";
c2960299 AD	133	eval { require $path; };
c2960299 AD	134	}
fb73857a	135	if ($@) {
	136	my $error = $@;
	137	require Carp;
	138	Carp::carp($error);
	139	}
f06db76b	140	}
f06db76b	141	}
8990e307 LW	142
8990e307 LW	143	1;
1be0b951 CS	144
	145	__END__
	146
	147	=head1 NAME
	148
	149	AutoLoader - load subroutines only on demand
	150
	151	=head1 SYNOPSIS
	152
	153	package Foo;
	154	use AutoLoader 'AUTOLOAD'; # import the default AUTOLOAD subroutine
	155
	156	package Bar;
	157	use AutoLoader; # don't import AUTOLOAD, define our own
	158	sub AUTOLOAD {
	159	...
	160	$AutoLoader::AUTOLOAD = "...";
	161	goto &AutoLoader::AUTOLOAD;
	162	}
	163
	164	=head1 DESCRIPTION
	165
	166	The B<AutoLoader> module works with the B<AutoSplit> module and the
	167	C<__END__> token to defer the loading of some subroutines until they are
	168	used rather than loading them all at once.
	169
	170	To use B<AutoLoader>, the author of a module has to place the
	171	definitions of subroutines to be autoloaded after an C<__END__> token.
	172	(See L<perldata>.) The B<AutoSplit> module can then be run manually to
	173	extract the definitions into individual files F<auto/funcname.al>.
	174
	175	B<AutoLoader> implements an AUTOLOAD subroutine. When an undefined
	176	subroutine in is called in a client module of B<AutoLoader>,
	177	B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
	178	file with a name related to the location of the file from which the
	179	client module was read. As an example, if F<POSIX.pm> is located in
	180	F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
	181	subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
	182	the C<.al> file has the same name as the subroutine, sans package. If
	183	such a file exists, AUTOLOAD will read and evaluate it,
	184	thus (presumably) defining the needed subroutine. AUTOLOAD will then
	185	C<goto> the newly defined subroutine.
	186
f610777f	187	Once this process completes for a given function, it is defined, so
1be0b951 CS	188	future calls to the subroutine will bypass the AUTOLOAD mechanism.
	189
	190	=head2 Subroutine Stubs
	191
	192	In order for object method lookup and/or prototype checking to operate
	193	correctly even when methods have not yet been defined it is necessary to
	194	"forward declare" each subroutine (as in C<sub NAME;>). See
	195	L<perlsub/"SYNOPSIS">. Such forward declaration creates "subroutine
	196	stubs", which are place holders with no code.
	197
	198	The AutoSplit and B<AutoLoader> modules automate the creation of forward
	199	declarations. The AutoSplit module creates an 'index' file containing
	200	forward declarations of all the AutoSplit subroutines. When the
	201	AutoLoader module is 'use'd it loads these declarations into its callers
	202	package.
	203
	204	Because of this mechanism it is important that B<AutoLoader> is always
	205	C<use>d and not C<require>d.
	206
	207	=head2 Using B<AutoLoader>'s AUTOLOAD Subroutine
	208
	209	In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
	210	explicitly import it:
	211
	212	use AutoLoader 'AUTOLOAD';
	213
	214	=head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine
	215
	216	Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
	217	They typically need to check for some special cases (such as constants)
	218	and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.
	219
	220	Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
	221	Instead, they should define their own AUTOLOAD subroutines along these
	222	lines:
	223
	224	use AutoLoader;
fb73857a	225	use Carp;
1be0b951 CS	226
1be0b951 CS	227	sub AUTOLOAD {
7d4fbd98 GS	228	my $sub = $AUTOLOAD;
7d4fbd98 GS	229	(my $constname = $sub) =~ s/.*:://;
1be0b951 CS	230	my $val = constant($constname, @_ ? $_[0] : 0);
1be0b951 CS	231	if ($! != 0) {
265f5c4a	232	if ($! =~ /Invalid/ \|\| $!{EINVAL}) {
7d4fbd98	233	$AutoLoader::AUTOLOAD = $sub;
1be0b951 CS	234	goto &AutoLoader::AUTOLOAD;
	235	}
	236	else {
	237	croak "Your vendor has not defined constant $constname";
	238	}
	239	}
7d4fbd98 GS	240	*$sub = sub { $val }; # same as: eval "sub $sub { $val }";
7d4fbd98 GS	241	goto &$sub;
1be0b951 CS	242	}
	243
	244	If any module's own AUTOLOAD subroutine has no need to fallback to the
	245	AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
	246	subroutines), then that module should not use B<AutoLoader> at all.
	247
	248	=head2 Package Lexicals
	249
	250	Package lexicals declared with C<my> in the main block of a package
	251	using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
	252	the fact that the given scope ends at the C<__END__> marker. A module
	253	using such variables as package globals will not work properly under the
	254	B<AutoLoader>.
	255
	256	The C<vars> pragma (see L<perlmod/"vars">) may be used in such
	257	situations as an alternative to explicitly qualifying all globals with
	258	the package namespace. Variables pre-declared with this pragma will be
	259	visible to any autoloaded routines (but will not be invisible outside
	260	the package, unfortunately).
	261
	262	=head2 B<AutoLoader> vs. B<SelfLoader>
	263
	264	The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
	265	loading of subroutines.
	266
	267	B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
	268	While this avoids the use of a hierarchy of disk files and the
	269	associated open/close for each routine loaded, B<SelfLoader> suffers a
	270	startup speed disadvantage in the one-time parsing of the lines after
	271	C<__DATA__>, after which routines are cached. B<SelfLoader> can also
	272	handle multiple packages in a file.
	273
	274	B<AutoLoader> only reads code as it is requested, and in many cases
f610777f	275	should be faster, but requires a mechanism like B<AutoSplit> be used to
1be0b951 CS	276	create the individual files. L<ExtUtils::MakeMaker> will invoke
	277	B<AutoSplit> automatically if B<AutoLoader> is used in a module source
	278	file.
	279
	280	=head1 CAVEATS
	281
	282	AutoLoaders prior to Perl 5.002 had a slightly different interface. Any
	283	old modules which use B<AutoLoader> should be changed to the new calling
	284	style. Typically this just means changing a require to a use, adding
	285	the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
	286	from C<@ISA>.
	287
	288	On systems with restrictions on file name length, the file corresponding
	289	to a subroutine may have a shorter name that the routine itself. This
	290	can lead to conflicting file names. The I<AutoSplit> package warns of
	291	these potential conflicts when used to split a module.
	292
adaafad2 GS	293	AutoLoader may fail to find the autosplit files (or even find the wrong
	294	ones) in cases where C<@INC> contains relative paths, B<and> the program
	295	does C<chdir>.
	296
1be0b951 CS	297	=head1 SEE ALSO
	298
	299	L<SelfLoader> - an autoloader that doesn't use external files.
	300
	301	=cut