This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables revamp
authorKarl Williamson <khw@khw-desktop.(none)>
Sun, 22 Nov 2009 06:45:28 +0000 (23:45 -0700)
committerKarl Williamson <khw@khw-desktop.(none)>
Sun, 22 Nov 2009 06:45:28 +0000 (23:45 -0700)
12 files changed:
MANIFEST
lib/unicore/Makefile
lib/unicore/README.perl
lib/unicore/mktables
lib/unicore/mktables.lst
lib/utf8_heavy.pl
pod/perluniprops.pod [new file with mode: 0644]
t/re/pat_advanced.t
t/re/regexp_unicode_prop.t
t/re/uniprops.t [new file with mode: 0644]
t/uni/cache.t
t/uni/class.t

index b857ae1..5cedb1f 100644 (file)
--- a/MANIFEST
+++ b/MANIFEST
@@ -3975,6 +3975,7 @@ pod/perltrap.pod          Perl traps for the unwary
 pod/perlunicode.pod            Perl Unicode support
 pod/perlunifaq.pod             Perl Unicode FAQ
 pod/perluniintro.pod           Perl Unicode introduction
+pod/perluniprops.pod           Perl Unicode property index
 pod/perlunitut.pod             Perl Unicode tutorial
 pod/perlutil.pod               utilities packaged with the Perl distribution
 pod/perlvar.pod                        Perl predefined variables
@@ -4544,6 +4545,7 @@ t/re/substr_thr.t         See if substr works in another thread
 t/re/subst.t                   See if substitution works
 t/re/substT.t                  See if substitution works with -T
 t/re/subst_wamp.t              See if substitution works with $& present
+t/re/uniprops.t                        Test unicode \p{} regex constructs
 t/run/cloexec.t                        Test close-on-exec.
 t/run/exit.t                   Test perl's exit status.
 t/run/fresh_perl.t             Tests that require a fresh perl.
index b73d3b8..0dd77b7 100644 (file)
@@ -1,12 +1,6 @@
 all:
-       ../../miniperl -I../../lib ./mktables
-
-TestProp.pl: mktables UnicodeData.txt Scripts.txt Blocks.txt PropList.txt
-       ../../miniperl -I../../lib ./mktables -maketest
-
-test:   TestProp.pl
-       ../../miniperl -I../../lib TestProp.pl
+       ../../miniperl -I../../lib ./mktables -P ../../pod -T ../../t/re/uniprops.t -makelist
 
 clean:
-       rm -f *.pl */*.pl */*/*.pl
-       rm -f Properties
+       rm -fr *.pl To lib
+       rm -f ../../pod/perluniprops.pod ../../t/re/uniprops.t mktables.lst
index 96b2caa..7515825 100644 (file)
@@ -1,11 +1,17 @@
 The *.txt files were copied from
 
-       http://www.unicode.org/Public/5.1.0/ucd
+       ftp://www.unicode.org/Public/UNIDATA
 
-and subdirectories 'extracted' and 'auxiliary' as of Unicode 5.1.0 (March 2008).
+with subdirectories 'extracted' and 'auxiliary'
 
-The big file, Unihan.txt (28 MB, 5.8 MB zip) was not included due to space
-considerations.  Also NOT included were any *.html files and *Test.txt files.
+The Unihan files were not included due to space considerations.  Also NOT
+included were any *.html files and *Test.txt files.  It is possible to add the
+Unihan files, and edit mktables (see instructions near its beginning) to look
+at them.
+
+The file 'version' should exist and be a single line with the Unicode version,
+like:
+5.2.0
 
 To be 8.3 filesystem friendly, the names of some of the input files have been
 changed from the values that are in the Unicode DB:
@@ -27,42 +33,68 @@ mv extracted/DerivedLineBreak.txt extracted/DLineBreak.txt
 mv extracted/DerivedNumericType.txt extracted/DNumType.txt
 mv extracted/DerivedNumericValues.txt extracted/DNumValues.txt
 
-The names of files, such as test files, that are not used by mktables are not
-changed, and will not work correctly on 8.3 filesystems.
+If you have the Unihan database (5.2 and above), you should also do the
+following:
 
-The file 'version' should exist and be a single line with the Unicode version,
-like
-5.1.0
+mv Unihan_DictionaryIndices.txt UnihanIndicesDictionary.txt
+mv Unihan_DictionaryLikeData.txt UnihanDataDictionaryLike.txt
+mv Unihan_IRGSources.txt UnihanIRGSources.txt
+mv Unihan_NumericValues.txt UnihanNumericValues.txt
+mv Unihan_OtherMappings.txt UnihanOtherMappings.txt
+mv Unihan_RadicalStrokeCounts.txt UnihanRadicalStrokeCounts.txt
+mv Unihan_Readings.txt UnihanReadings.txt
+mv Unihan_Variants.txt UnihanVariants.txt
+
+If you download everything, the names of files, such as test files, that are
+not used by mktables are not changed by the above, and will not work correctly
+as-is on 8.3 filesystems.
+
+mktables is used to generate the tables used by the rest of Perl.  It will warn
+you about any *.txt files in the directory substructure that it doesn't know
+about.  You should remove any so-identified, or edit mktables to add them to
+its lists to process.  You can run
+
+    mktables -globlist
+
+to have it try to process these tables generically.
+
+If any files are added, deleted, or their names change, you must run
 
-NOTE: If you modify the input file set you should also run
     mktables -makelist
-    
-which will recreate the mktables.lst file which is used to speed up
-the build process.    
+
+to generate a new list of all the files.
 
 FOR PUMPKINS
 
-The files are inter-related.  If you take the latest UnicodeData.txt, for example,
-but leave the older versions of other files, there can be subtle problems.
+The files are inter-related.  If you take the latest UnicodeData.txt, for
+example, but leave the older versions of other files, there can be subtle
+problems.
+
+When moving to a new version of Unicode, you need to update 'version' by hand
+
+       p4 edit version
+       ...
+
+You should look in the Unicode release notes (which are probably towards the
+bottom of http://www.unicode.org/reports/tr44/) to see if any properties have
+newly been moved to be Obsolete, Deprecated, or Stabilized.  The full names for
+these should be added to the respective lists near the beginning of mktables,
+using an 'if' to add them for just this Unicode version going forward, so that
+mktables can continue to be used for earlier Unicode versions. 
+
+When putting out a new Perl release, think about if any of the Deprecated
+properties should be moved to Suppressed.
 
 The *.pl files are generated from the *.txt files by the mktables script,
 more recently done during the Perl build process, but if you want to try
 the old manual way:
        
        cd lib/unicore
-       cp .../UnicodeOriginal/*.txt .
-       rm NormalizationTest.txt Unihan.txt Derived*.txt
-       p4 edit Properties *.pl */*.pl
-       perl ./mktables
+       p4 edit *.pl */*.pl */*/*.pl
+       perl ./mktables -P ../../pod -T ../../t/re/uniprops.t -makelist
        p4 revert -a
        cd ../..
        perl Porting/manicheck
-
-You need to update version by hand
-
-       p4 edit version
-       ...
        
 If any new (or deleted, unlikely but not impossible) *.pl files are indicated:
 
@@ -78,4 +110,4 @@ And finally:
        p4 submit
 
 -- 
-jhi@iki.fi; updated by nick@ccl4.org
+jhi@iki.fi; updated by nick@ccl4.org, public@khwilliamson.com
index 6ab4e70..abd44f5 100644 (file)
-## !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
-## Any files created or read by this program should be listed in 'mktables.lst'
-
 #!/usr/bin/perl -w
-require 5.008; # Needs pack "U". Probably safest to run on 5.8.x
+
+# !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
+# Any files created or read by this program should be listed in 'mktables.lst'
+# Use -makelist to regenerate it.
+
+require 5.008;        # Needs pack "U". Probably safest to run on 5.8.x
 use strict;
+use warnings;
 use Carp;
+use File::Find;
+use File::Path;
 use File::Spec;
-use Text::Tabs ();  ## using this makes the files about half the size
-
-##
-## mktables -- create the runtime Perl Unicode files (lib/unicore/**/*.pl)
-## from the Unicode database files (lib/unicore/*.txt).
-##
-
-## "Fuzzy" means this section in Unicode TR18:
-##
-##    The recommended names for UCD properties and property values are in
-##    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
-##    [PropValue]. There are both abbreviated names and longer, more
-##    descriptive names. It is strongly recommended that both names be
-##    recognized, and that loose matching of property names be used,
-##    whereby the case distinctions, whitespace, hyphens, and underbar
-##    are ignored.
-
-## Base names already used in lib/gc_sc (for avoiding 8.3 conflicts)
-my %BaseNames;
-
-##
-## Process any args.
-##
-my $Verbose        = 0;
-my $MakeTestScript = 0;
-my $AlwaysWrite    = 0;
-my $UseDir         = "";
-my $FileList       = "$0.lst";
-my $MakeList       = 0;
-
-while (@ARGV)
-{
+use Text::Tabs;
+
+sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
+
+##########################################################################
+#
+# mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
+# from the Unicode database files (lib/unicore/.../*.txt),  It also generates
+# a pod file and a .t file
+#
+# The structure of this file is:
+#   First these introductory comments; then
+#   code needed for everywhere, such as debugging stuff; then
+#   code to handle input parameters; then
+#   data structures likely to be of external interest (some of which depend on
+#       the input parameters, so follows them; then
+#   more data structures and subroutine and package (class) definitions; then
+#   the small actual loop to process the input files and finish up; then
+#   a __DATA__ section, for the .t tests
+#
+# This program works on all releases of Unicode through at least 5.2.  The
+# outputs have been scrutinized most intently for release 5.1.  The others
+# have been checked for somewhat more than just sanity.  It can handle all
+# existing Unicode character properties in those releases.
+#
+# This program needs to be able to run under miniperl.  Therefore, it uses a
+# minimum of other modules, and hence implements some things itself that could
+# be gotten from CPAN
+#
+# This program uses inputs published by the Unicode Consortium.  These can
+# change incompatibly between releases without the Perl maintainers realizing
+# it.  Therefore this program is now designed to try to flag these.  It looks
+# at the directories where the inputs are, and flags any unrecognized files.
+# It keeps track of all the properties in the files it handles, and flags any
+# that it doesn't know how to handle.  It also flags any input lines that
+# don't match the expected syntax, among other checks.
+# It is also designed so if a new input file matches one of the known
+# templates, one hopefully just needs to add it to a list to have it
+# processed.
+#
+# It tries to keep fatal errors to a minimum, to generate something usable for
+# testing purposes.  It always looks for files that could be inputs, and will
+# warn about any that it doesn't know how to handle (the -q option suppresses
+# the warning).
+#
+# This program is mostly about Unicode character (or code point) properties.
+# A property describes some attribute or quality of a code point, like if it
+# is lowercase or not, its name, what version of Unicode it was first defined
+# in, or what its uppercase equivalent is.  Unicode deals with these disparate
+# possibilities by making all properties into mappings from each code point
+# into some corresponding value.  In the case of it being lowercase or not,
+# the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
+# property maps each Unicode code point to a single value, called a "property
+# value".  (Hence each Unicode property is a true mathematical function with
+# exactly one value per code point.)
+#
+# When using a property in a regular expression, what is desired isn't the
+# mapping of the code point to its property's value, but the reverse (or the
+# mathematical "inverse relation"): starting with the property value, "Does a
+# code point map to it?"  These are written in a "compound" form:
+# \p{property=value}, e.g., \p{category=punctuation}.  This program generates
+# files containing the lists of code points that map to each such regular
+# expression property value, one file per list
+#
+# There is also a single form shortcut that Perl adds for many of the commonly
+# used properties.  This happens for all binary properties, plus script,
+# general_category, and block properties.
+#
+# Thus the outputs of this program are files.  There are map files, mostly in
+# the 'To' directory; and there are list files for use in regular expression
+# matching, all in subdirectories of the 'lib' directory, with each
+# subdirectory being named for the property that the lists in it are for.
+# Bookkeeping, test, and documentation files are also generated.
+
+my $matches_directory = 'lib';   # Where match (\p{}) files go.
+my $map_directory = 'To';        # Where map files go.
+
+# DATA STRUCTURES
+#
+# The major data structures of this program are Property, of course, but also
+# Table.  There are two kinds of tables, very similar to each other.
+# "Match_Table" is the data structure giving the list of code points that have
+# a particular property value, mentioned above.  There is also a "Map_Table"
+# data structure which gives the property's mapping from code point to value.
+# There are two structures because the match tables need to be combined in
+# various ways, such as constructing unions, intersections, complements, etc.,
+# and the map ones don't.  And there would be problems, perhaps subtle, if
+# a map table were inadvertently operated on in some of those ways.
+# The use of separate classes with operations defined on one but not the other
+# prevents accidentally confusing the two.
+#
+# At the heart of each table's data structure is a "Range_List", which is just
+# an ordered list of "Ranges", plus ancillary information, and methods to
+# operate on them.  A Range is a compact way to store property information.
+# Each range has a starting code point, an ending code point, and a value that
+# is meant to apply to all the code points between the two end points,
+# inclusive.  For a map table, this value is the property value for those
+# code points.  Two such ranges could be written like this:
+#   0x41 .. 0x5A, 'Upper',
+#   0x61 .. 0x7A, 'Lower'
+#
+# Each range also has a type used as a convenience to classify the values.
+# Most ranges in this program will be Type 0, or normal, but there are some
+# ranges that have a non-zero type.  These are used only in map tables, and
+# are for mappings that don't fit into the normal scheme of things.  Mappings
+# that require a hash entry to communicate with utf8.c are one example;
+# another example is mappings for charnames.pm to use which indicate a name
+# that is algorithmically determinable from its code point (and vice-versa).
+# These are used to significantly compact these tables, instead of listing
+# each one of the tens of thousands individually.
+#
+# In a match table, the value of a range is irrelevant (and hence the type as
+# well, which will always be 0), and arbitrarily set to the null string.
+# Using the example above, there would be two match tables for those two
+# entries, one named Upper would contain the 0x41..0x5A range, and the other
+# named Lower would contain 0x61..0x7A.
+#
+# Actually, there are two types of range lists, "Range_Map" is the one
+# associated with map tables, and "Range_List" with match tables.
+# Again, this is so that methods can be defined on one and not the other so as
+# to prevent operating on them in incorrect ways.
+#
+# Eventually, most tables are written out to files to be read by utf8_heavy.pl
+# in the perl core.  All tables could in theory be written, but some are
+# suppressed because there is no current practical use for them.  It is easy
+# to change which get written by changing various lists that are near the top
+# of the actual code in this file.  The table data structures contain enough
+# ancillary information to allow them to be treated as separate entities for
+# writing, such as the path to each one's file.  There is a heading in each
+# map table that gives the format of its entries, and what the map is for all
+# the code points missing from it.  (This allows tables to be more compact.)
+
+# The Property data structure contains one or more tables.  All properties
+# contain a map table (except the $perl property which is a
+# pseudo-property containing only match tables), and any properties that
+# are usable in regular expression matches also contain various matching
+# tables, one for each value the property can have.  A binary property can
+# have two values, True and False (or Y and N, which are preferred by Unicode
+# terminology).  Thus each of these properties will have a map table that
+# takes every code point and maps it to Y or N (but having ranges cuts the
+# number of entries in that table way down), and two match tables, one
+# which has a list of all the code points that map to Y, and one for all the
+# code points that map to N.  (For each of these, a third table is also
+# generated for the pseudo Perl property.  It contains the identical code
+# points as the Y table, but can be written, not in the compound form, but in
+# a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
+# properties have several possible values, some have many, and properties like
+# Name have a different value for every named code point.  Those will not,
+# unless the controlling lists are changed, have their match tables written
+# out.  But all the ones which can be used in regular expression \p{} and \P{}
+# constructs will.  Generally a property will have either its map table or its
+# match tables written but not both.  Again, what gets written is controlled
+# by lists which can easily be changed.
+
+# For information about the Unicode properties, see Unicode's UAX44 document:
+
+my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
+
+# As stated earlier, this program will work on any release of Unicode so far.
+# Most obvious problems in earlier data have NOT been corrected except when
+# necessary to make Perl or this program work reasonably.  For example, no
+# folding information was given in early releases, so this program uses the
+# substitute of lower case, just so that a regular expression with the /i
+# option will do something that actually gives the right results in many
+# cases.  There are also a couple other corrections for version 1.1.5,
+# commented at the point they are made.  As an example of corrections that
+# weren't made (but could be) is this statement from DerivedAge.txt: "The
+# supplementary private use code points and the non-character code points were
+# assigned in version 2.0, but not specifically listed in the UCD until
+# versions 3.0 and 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0)
+# More information on Unicode version glitches is further down in these
+# introductory comments.
+#
+# This program works on all properties as of 5.2, though the files for some
+# are suppressed from apparent lack of demand for.  You can change which are
+# output by changing lists in this program.
+
+# The old version of mktables emphasized the term "Fuzzy" to mean Unocde's
+# loose matchings rules (from Unicode TR18):
+#
+#    The recommended names for UCD properties and property values are in
+#    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
+#    [PropValue]. There are both abbreviated names and longer, more
+#    descriptive names. It is strongly recommended that both names be
+#    recognized, and that loose matching of property names be used,
+#    whereby the case distinctions, whitespace, hyphens, and underbar
+#    are ignored.
+# The program still allows Fuzzy to override its determination of if loose
+# matching should be used, but it isn't currently used, as it is no longer
+# needed; the calculations it makes are good enough.
+
+# SUMMARY OF HOW IT WORKS:
+#
+#   Process arguments
+#
+#   A list is constructed containing each input file that is to be processed
+#
+#   Each file on the list is processed in a loop, using the associated handler
+#   code for each:
+#        The PropertyAliases.txt and PropValueAliases.txt files are processed
+#            first.  These files name the properties and property values.
+#            Objects are created of all the property and property value names
+#            that the rest of the input should expect, including all synonyms.
+#        The other input files give mappings from properties to property
+#           values.  That is, they list code points and say what the mapping
+#           is under the given property.  Some files give the mappings for
+#           just one property; and some for many.  This program goes through
+#           each file and populates the properties from them.  Some properties
+#           are listed in more than one file, and Unicode has set up a
+#           precedence as to which has priority if there is a conflict.  Thus
+#           the order of processing matters, and this program handles the
+#           conflict possibility by processing the overriding input files
+#           last, so that if necessary they replace earlier values.
+#        After this is all done, the program creates the property mappings not
+#            furnished by Unicode, but derivable from what it does give.
+#        The tables of code points that match each property value in each
+#            property that is accessible by regular expressions are created.
+#        The Perl-defined properties are created and populated.  Many of these
+#            require data determined from the earlier steps
+#        Any Perl-defined synonyms are created, and name clashes between Perl
+#            and Unicode are reconciled.
+#        All the properties are written to files
+#        Any other files are written, and final warnings issued.
+
+# As mentioned above, some properties are given in more than one file.  In
+# particular, the files in the extracted directory are supposedly just
+# reformattings of the others.  But they contain information not easily
+# derivable from the other files, including results for Unihan, which this
+# program doesn't ordinarily look at, and for unassigned code points.  They
+# also have historically had errors or been incomplete.  In an attempt to
+# create the best possible data, this program thus processes them first to
+# glean information missing from the other files; then processes those other
+# files to override any errors in the extracted ones.
+
+# For clarity, a number of operators have been overloaded to work on tables:
+#   ~ means invert (take all characters not in the set).  The more
+#       conventional '!' is not used because of the possibility of confusing
+#       it with the actual boolean operation.
+#   + means union
+#   - means subtraction
+#   & means intersection
+# The precedence of these is the order listed.  Parentheses should be
+# copiously used.  These are not a general scheme.  The operations aren't
+# defined for a number of things, deliberately, to avoid getting into trouble.
+# Operations are done on references and affect the underlying structures, so
+# that the copy constructors for them have been overloaded to not return a new
+# clone, but the input object itself.
+
+# The bool operator is deliberately not overloaded to avoid confusion with
+# "should it mean if the object merely exists, or also is non-empty?".
+
+#
+# WHY CERTAIN DESIGN DECISIONS WERE MADE
+
+# XXX These comments need more work.
+#
+# Why have files written out for binary 'N' matches?
+#   For binary properties, if you know the mapping for either Y or N; the
+#   other is trivial to construct, so could be done at Perl run-time instead
+#   of having a file for it.  That is, if someone types in \p{foo: N}, Perl
+#   could translate that to \P{foo: Y} and not need a file.   The problem is
+#   communicating to Perl that a given property is binary.  Perl can't figure
+#   it out from looking at the N (or No), as some non-binary properties have
+#   these as property values.
+# Why
+# There are several types of properties, based on what form their values can
+# take on.  These are described in more detail below in the DATA STRUCTURES
+# section of these comments, but for now, you should know that there are
+# string properties, whose values are strings of one or more code points (such
+# as the Uppercase_mapping property); every other property maps to some other
+# form, like true or false, or a number, or a name, etc.  The reason there are
+# two directories for map files is because of the way utf8.c works.  It
+# expects that any files there are string properties, that is that the
+# mappings are each to one code point, with mappings in multiple code points
+# handled specially in an extra hash data structure.  Digit.pl is a table that
+# is written there for historical reasons, even though it doesn't fit that
+# mold.  Thus it can't currently be looked at by the Perl core.
+#
+# There are no match tables generated for matches of the null string.  These
+# would like like \p{JSN=}.  Perhaps something like them could be added if
+# necessary.  The JSN does have a real code point U+110B that maps to the null
+# string, but it is a contributory property, and therefore not output by
+# default.
+#
+# FUTURE ISSUES
+#
+# The program would break if Unicode were to change its names so that
+# interior white space, underscores, or dashes differences were significant
+# within property and property value names.
+#
+# It might be easier to use the xml versions of the UCD if this program ever
+# would need heavy revision, and the ability to handle old versions was not
+# required.
+#
+# There is the potential for name collisions, in that Perl has chosen names
+# that Unicode could decide it also likes.  There have been such collisions in
+# the past, with mostly Perl deciding to adopt the Unicode definition of the
+# name.  However in the 5.2 Unicode beta testing, there were a number of such
+# collisions, which were withdrawn before the final release, because of Perl's
+# and other's protests.  These all involved new properties which began with
+# 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
+# many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
+# Unicode document, so they are unlikely to be used by Unicode for another
+# purpose.  However, they might try something beginning with 'In', or use any
+# of the other Perl-defined properties.  This program will warn you of name
+# collisions, and refuse to generate tables with them, but manual intervention
+# will be required in this event.  One scheme that could be implemented, if
+# necessary, would be to have this program generate another file, or add a
+# field to mktables.lst that gives the date of first definition of a property.
+# Each new release of Unicode would use that file as a basis for the next
+# iteration.  And the Perl synonym addition code could sort based on the age
+# of the property, so older properties get priority, and newer ones that clash
+# would be refused; hence existing code would not be impacted, and some other
+# synonym would have to be used for the new property.  This is ugly, and
+# manual intervention would certainly be easier to do in the short run; lets
+# hope it never comes to this.
+
+# A NOTE ON UNIHAN
+#
+# This program can generate tables from the Unihan database.  But it doesn't
+# by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
+# version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
+# database was split into 8 different files, all beginning with the letters
+# 'Unihan'.  This program will read those file(s) if present, but it needs to
+# know which of the many properties in the file(s) should have tables created
+# for them.  It will create tables for any properties listed in
+# PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
+# @cjk_properties array and the @cjk_property_values array.  Thus, if a
+# property you want is not in those files of the release you are building
+# against, you must add it to those two arrays.  Starting in 4.0, the
+# Unicode_Radical_Stroke was listed in those files, so if the Unihan database
+# is present in the directory, a table will be generated for that property.
+# In 5.2, several more properties were added.  For your convenience, the two
+# arrays are initialized with all the 5.2 listed properties that are also in
+# earlier releases.  But these are commented out.  You can just uncomment the
+# ones you want, or use them as a template for adding entries for other
+# properties.
+#
+# You may need to adjust the entries to suit your purposes.  setup_unihan(),
+# and filter_unihan_line() are the functions where this is done.  This program
+# already does some adjusting to make the lines look more like the rest of the
+# Unicode DB;  You can see what that is in filter_unihan_line()
+#
+# There is a bug in the 3.2 data file in which some values for the
+# kPrimaryNumeric property have commas and an unexpected comment.  A filter
+# could be added for these; or for a particular installation, the Unihan.txt
+# file could be edited to fix them.
+# have to be
+#
+# HOW TO ADD A FILE
+
+# Unicode Versions Notes
+
+# alpha's numbers halve in 2.1.9, answer cjk block at 4E00 were removed from PropList; not changed, could add gc Letter, put back in in 3.1.0
+# Some versions of 2.1.x Jamo.txt have the wrong value for 1105, which causes
+# real problems for the algorithms for Jamo calculations, so it is changed
+# here.
+#   White space vs Space.  in 3.2 perl has +205F=medium math space, fixed in 4.0, and ok in 3.1.1 because not there in unicode. synonym introduced in 4.1
+# ATBL = 202.  202 changed to ATB, and all code points stayed there.  So if you were useing ATBL you were out of luck.
+# Hrkt Katakana_Or_Hiragana came in 4.01, before was Unknown.
+#
+# The default for missing code points for BidiClass is complicated.  Starting
+# in 3.1.1, the derived file DBidiClass.txt handles this, but this program
+# tries to do the best it can for earlier releases.  It is done in
+# process_PropertyAliases()
+#
+##############################################################################
+
+my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
+                        # and errors
+my $MAX_LINE_WIDTH = 78;
+
+# Debugging aid to skip most files so as to not be distracted by them when
+# concentrating on the ones being debugged.  Add
+# non_skip => 1,
+# to the constructor for those files you want processed when you set this.
+# Files with a first version number of 0 are special: they are always
+# processed regardless of the state of this flag.
+my $debug_skip = 0;
+
+# Set to 1 to enable tracing.
+our $to_trace = 0;
+
+{ # Closure for trace: debugging aid
+    my $print_caller = 1;        # ? Include calling subroutine name
+    my $main_with_colon = 'main::';
+    my $main_colon_length = length($main_with_colon);
+
+    sub trace {
+        return unless $to_trace;        # Do nothing if global flag not set
+
+        my @input = @_;
+
+        local $DB::trace = 0;
+        $DB::trace = 0;          # Quiet 'used only once' message
+
+        my $line_number;
+
+        # Loop looking up the stack to get the first non-trace caller
+        my $caller_line;
+        my $caller_name;
+        my $i = 0;
+        do {
+            $line_number = $caller_line;
+            (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
+            $caller = $main_with_colon unless defined $caller;
+
+            $caller_name = $caller;
+
+            # get rid of pkg
+            $caller_name =~ s/.*:://;
+            if (substr($caller_name, 0, $main_colon_length)
+                eq $main_with_colon)
+            {
+                $caller_name = substr($caller_name, $main_colon_length);
+            }
+
+        } until ($caller_name ne 'trace');
+
+        # If the stack was empty, we were called from the top level
+        $caller_name = 'main' if ($caller_name eq ""
+                                    || $caller_name eq 'trace');
+
+        my $output = "";
+        foreach my $string (@input) {
+            #print STDERR __LINE__, ": ", join ", ", @input, "\n";
+            if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
+                $output .= simple_dumper($string);
+            }
+            else {
+                $string = "$string" if ref $string;
+                $string = $UNDEF unless defined $string;
+                chomp $string;
+                $string = '""' if $string eq "";
+                $output .= " " if $output ne ""
+                                && $string ne ""
+                                && substr($output, -1, 1) ne " "
+                                && substr($string, 0, 1) ne " ";
+                $output .= $string;
+            }
+        }
+
+        if ($print_caller) {
+            if (defined $line_number) {
+                    print STDERR sprintf "%4d: ", $line_number;
+            }
+            else {
+                    print STDERR "     ";
+            }
+            $caller_name .= ": ";
+            print STDERR $caller_name;
+        }
+
+        print STDERR $output, "\n";
+        return;
+    }
+}
+
+# This is for a rarely used development feature that allows you to compare two
+# versions of the Unicode standard without having to deal with changes caused
+# by the code points introduced in the later verson.  Change the 0 to a SINGLE
+# dotted Unicode release number (e.g. 2.1).  Only code points introduced in
+# that release and earlier will be used; later ones are thrown away.  You use
+# the version number of the earliest one you want to compare; then run this
+# program on directory structures containing each release, and compare the
+# outputs.  These outputs will therefore include only the code points common
+# to both releases, and you can see the changes caused just by the underlying
+# release semantic changes.  For versions earlier than 3.2, you must copy a
+# version of DAge.txt into the directory.
+my $string_compare_versions = DEBUG && 0; #  e.g., v2.1;
+my $compare_versions = DEBUG
+                       && $string_compare_versions
+                       && pack "C*", split /\./, $string_compare_versions;
+
+sub uniques {
+    # Returns non-duplicated input values.  From "Perl Best Practices:
+    # Encapsulated Cleverness".  p. 455 in first edition.
+
+    my %seen;
+    return grep { ! $seen{$_}++ } @_;
+}
+
+$0 = File::Spec->canonpath($0);
+
+my $make_test_script = 0;      # ? Should we output a test script
+my $write_unchanged_files = 0; # ? Should we update the output files even if
+                               #    we don't think they have changed
+my $use_directory = "";        # ? Should we chdir somewhere.
+my $pod_directory;             # input directory to store the pod file.
+my $pod_file = 'perluniprops';
+my $t_path;                     # Path to the .t test file
+my $file_list = 'mktables.lst'; # File to store input and output file names.
+                               # This is used to speed up the build, by not
+                               # executing the main body of the program if
+                               # nothing on the list has changed since the
+                               # previous build
+my $make_list = 1;             # ? Should we write $file_list.  Set to always
+                               # make a list so that when the pumpking is
+                               # preparing a release, s/he won't have to do
+                               # special things
+my $glob_list = 0;             # ? Should we try to include unknown .txt files
+                               # in the input.
+my $output_range_counts = 1;   # ? Should we include the number of code points
+                               # in ranges in the output
+# Verbosity levels; 0 is quiet
+my $NORMAL_VERBOSITY = 1;
+my $PROGRESS = 2;
+my $VERBOSE = 3;
+
+my $verbosity = $NORMAL_VERBOSITY;
+
+# Process arguments
+while (@ARGV) {
     my $arg = shift @ARGV;
     if ($arg eq '-v') {
-        $Verbose = 1;
-    } elsif ($arg eq '-q') {
-        $Verbose = 0;
-    } elsif ($arg eq '-w') {
-        $AlwaysWrite = 1;      # update the files even if they havent changed
-        $FileList = "";
-    } elsif ($arg eq '-check') {
+        $verbosity = $VERBOSE;
+    }
+    elsif ($arg eq '-p') {
+        $verbosity = $PROGRESS;
+        $| = 1;     # Flush buffers as we go.
+    }
+    elsif ($arg eq '-q') {
+        $verbosity = 0;
+    }
+    elsif ($arg eq '-w') {
+        $write_unchanged_files = 1; # update the files even if havent changed
+    }
+    elsif ($arg eq '-check') {
         my $this = shift @ARGV;
         my $ok = shift @ARGV;
         if ($this ne $ok) {
             print "Skipping as check params are not the same.\n";
             exit(0);
         }
-    } elsif ($arg eq '-maketest') {
-        $MakeTestScript = 1;
-    } elsif ($arg eq '-makelist') {
-        $MakeList = 1;        
-    } elsif ($arg eq '-C' && defined ($UseDir = shift)) {
-       -d $UseDir or die "Unknown directory '$UseDir'";
-    } elsif ($arg eq '-L' && defined ($FileList = shift)) {
-        -e $FileList or die "Filelist '$FileList' doesn't appear to exist!";
-    } else {
-        die "usage: $0 [-v|-q|-w|-C dir|-L filelist] [-maketest] [-makelist]\n",
-            "  -v          : Verbose Mode\n",
-            "  -q          : Quiet Mode\n",
-            "  -w          : Write files regardless\n",
-            "  -maketest   : Make test script\n",
-            "  -makelist   : Rewrite the file list based on current setup\n",
-            "  -L filelist : Use this file list, (defaults to $0.lst)\n",
-            "  -C dir      : Change to this directory before proceeding\n",
-            "  -check A B  : Executes only if A and B are the same\n";   
-    }
-}
-
-if ($FileList) {
-    print "Reading file list '$FileList'\n"
-        if $Verbose;
-    open my $fh,"<",$FileList or die "Failed to read '$FileList':$!";
-    my @input;
-    my @output;
-    for my $list ( \@input, \@output ) {
-        while (<$fh>) {
-            s/^ \s+ | \s+ $//xg;
-            next if /^ \s* (?: \# .* )? $/x;
-            last if /^ =+ $/x;
-            my ( $file ) = split /\t/, $_;
-            push @$list, $file;
-        }
-        my %dupe;
-        @$list = grep !$dupe{ $_ }++, @$list;
-    }
-    close $fh;
-    die "No input or output files in '$FileList'!"
-        if !@input or !@output;
-    if ( $MakeList ) {
-        foreach my $file (@output) {
-            unlink $file;
-        }
-    }            
-    if ( $Verbose ) {
-        print "Expecting ".scalar( @input )." input files. ",
-              "Checking ".scalar( @output )." output files.\n";
-    }
-    # we set maxtime to be the youngest input file, including $0 itself.
-    my $maxtime = -M $0; # do this before the chdir!
-    if ($UseDir) {
-        chdir $UseDir or die "Failed to chdir to '$UseDir':$!";
-    }
-    foreach my $in (@input) {
-        my $time = -M $in;
-        die "Missing input file '$in'" unless defined $time;
-        $maxtime = $time if $maxtime < $time;
-    }
-
-    # now we check to see if any output files are older than maxtime, if
-    # they are we need to continue on, otherwise we can presumably bail.
-    my $ok = 1;
-    foreach my $out (@output) {
-        if ( ! -e $out ) {
-            print "'$out' is missing.\n"
-                if $Verbose;
-            $ok = 0;
-            last;
-        }
-        if ( -M $out > $maxtime ) {
-            print "'$out' is too old.\n"
-                if $Verbose;
-            $ok = 0;
-            last;
-        }
     }
-    if ($ok) {
-        print "Files seem to be ok, not bothering to rebuild.\n";
-        exit(0);
+    elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
+        -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
+    }
+    elsif ($arg eq '-maketest'
+             || ($arg eq '-T' && defined ($t_path = shift))) {
+        $make_test_script = 1;
+        $t_path = 'TestProp.pl' unless defined $t_path;
+    }
+    elsif ($arg eq '-makelist') {
+        $make_list = 1;
+    }
+    elsif ($arg eq '-C' && defined ($use_directory = shift)) {
+        -d $use_directory or croak "Unknown directory '$use_directory'";
+    }
+    elsif ($arg eq '-L') {
+
+        # Existence not tested until have chdir'd
+        $file_list = shift;
+    }
+    elsif ($arg eq '-globlist') {
+        $glob_list = 1;
+    }
+    elsif ($arg eq '-c') {
+        $output_range_counts = ! $output_range_counts
+    }
+    else {
+        my $with_c = 'with';
+        $with_c .= 'out' if $output_range_counts;   # Complements the state
+        croak <<END;
+usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
+          [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
+          [-check A B ]
+  -c          : Output comments $with_c number of code points in ranges
+  -q          : Quiet Mode: Only output serious warnings.
+  -p          : Set verbosity level to normal plus show progress.
+  -v          : Set Verbosity level high:  Show progress and non-serious
+                warnings
+  -w          : Write files regardless
+  -C dir      : Change to this directory before proceeding. All relative paths
+                except those specified by the -P and -T options will be done
+                with respect to this directory.
+  -P dir      : Output $pod_file file to directory 'dir'.
+  -T path     : Create a .t test file as 'path'
+  -L filelist : Use alternate 'filelist' instead of standard one
+  -globlist   : Take as input all non-Test *.txt files in current and sub
+                directories
+  -maketest   : Make test script
+  -makelist   : Rewrite the file list $file_list based on current setup
+  -check A B  : Executes $0 only if A and B are the same
+END
+    }
+}
+
+# Stores the most-recently changed file.  If none have changed, can skip the
+# build
+my $youngest = -M $0;   # Do this before the chdir!
+
+# Change directories now, because need to read 'version' early.
+if ($use_directory) {
+    if ($pod_directory
+        && ! File::Spec->file_name_is_absolute($pod_directory))
+    {
+        $pod_directory = File::Spec->rel2abs($pod_directory);
+    }
+    if ($t_path
+        && ! File::Spec->file_name_is_absolute($t_path))
+    {
+        $t_path = File::Spec->rel2abs($t_path);
     }
-    print "Must rebuild tables.\n"
-        if $Verbose;
-} else {
-    if ($Verbose) {
-        print "Not checking filelist.\n";
+    chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
+    if ($pod_directory
+        && File::Spec->file_name_is_absolute($pod_directory))
+    {
+        $pod_directory = File::Spec->abs2rel($pod_directory);
     }
-    if ($UseDir) {
-        chdir $UseDir or die "Failed to chdir to '$UseDir':$!";
+    if ($t_path
+        && File::Spec->file_name_is_absolute($t_path))
+    {
+        $t_path = File::Spec->abs2rel($t_path);
     }
 }
 
-foreach my $lib ('To', 'lib',
-                map {File::Spec->catdir("lib",$_)}
-                qw(gc_sc dt bc hst ea jt lb nt ccc)) {
-  next if -d $lib;
-  mkdir $lib, 0755 or die "mkdir '$lib': $!";
+# Get Unicode version into regular and v-string.  This is done now because
+# various tables below get populated based on it.  These tables are populated
+# here to be near the top of the file, and so easily seeable by those needing
+# to modify things.
+open my $VERSION, "<", "version"
+                    or croak "$0: can't open required file 'version': $!\n";
+my $string_version = <$VERSION>;
+close $VERSION;
+chomp $string_version;
+my $v_version = pack "C*", split /\./, $string_version;        # v string
+
+# The following are the complete names of properties with property values that
+# are known to not match any code points in some versions of Unicode, but that
+# may change in the future so they should be matchable, hence an empty file is
+# generated for them.
+my @tables_that_may_be_empty = (
+                                'Joining_Type=Left_Joining',
+                                );
+push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
+push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
+push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
+                                                    if $v_version ge v4.1.0;
+
+# The lists below are hashes, so the key is the item in the list, and the
+# value is the reason why it is in the list.  This makes generation of
+# documentation easier.
+
+my %why_suppressed;  # No file generated for these.
+
+# Files aren't generated for empty extraneous properties.  This is arguable.
+# Extraneous properties generally come about because a property is no longer
+# used in a newer version of Unicode.  If we generated a file without code
+# points, programs that used to work on that property will still execute
+# without errors.  It just won't ever match (or will always match, with \P{}).
+# This means that the logic is now likely wrong.  I (khw) think its better to
+# find this out by getting an error message.  Just move them to the table
+# above to change this behavior
+my %why_suppress_if_empty_warn_if_not = (
+
+   # It is the only property that has ever officially been removed from the
+   # Standard.  The database never contained any code points for it.
+   'Special_Case_Condition' => 'Obsolete',
+
+   # Apparently never official, but there were code points in some versions of
+   # old-style PropList.txt
+   'Non_Break' => 'Obsolete',
+);
+
+# These would normally go in the warn table just above, but they were changed
+# a long time before this program was written, so warnings about them are
+# moot.
+if ($v_version gt v3.2.0) {
+    push @tables_that_may_be_empty,
+                                'Canonical_Combining_Class=Attached_Below_Left'
+}
+
+# These are listed in the Property aliases file in 5.2, but Unihan is ignored
+# unless explicitly added.
+if ($v_version ge v5.2.0) {
+    my $unihan = 'Unihan; remove from list if using Unihan';
+    foreach my $table qw ( 
+                           kAccountingNumeric
+                           kOtherNumeric
+                           kPrimaryNumeric
+                           kCompatibilityVariant
+                           kIICore
+                           kIRG_GSource
+                           kIRG_HSource
+                           kIRG_JSource
+                           kIRG_KPSource
+                           kIRG_MSource
+                           kIRG_KSource
+                           kIRG_TSource
+                           kIRG_USource
+                           kIRG_VSource
+                           kRSUnicode
+                        )
+    {
+        $why_suppress_if_empty_warn_if_not{$table} = $unihan;
+    }
 }
 
-my $LastUnicodeCodepoint = 0x10FFFF; # As of Unicode 5.1.
+# Properties that this program ignores.
+my @unimplemented_properties = (
+'Unicode_Radical_Stroke'    # Remove if changing to handle this one.
+);
 
-my $HEADER=<<"EOF";
-# !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!! 
-# This file is built by $0 from e.g. UnicodeData.txt.
-# Any changes made here will be lost!
+# There are several types of obsolete properties defined by Unicode.  These
+# must be hand-edited for every new Unicode release.
+my %why_deprecated;  # Generates a deprecated warning message if used.
+my %why_stabilized;  # Documentation only
+my %why_obsolete;    # Documentation only
+
+{   # Closure
+    my $simple = 'Perl uses the more complete version of this property';
+    my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
+
+    my $other_properties = 'other properties';
+    my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
+    my $why_no_expand  = "Easily computed, and yet doesn't cover the common encoding forms (UTF-16/8)",
+
+    %why_deprecated = (
+        'Grapheme_Link' => 'Deprecated by Unicode.  Use ccc=vr (Canonical_Combining_Class=Virama) instead',
+        'Jamo_Short_Name' => $contributory,
+        'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
+        'Other_Alphabetic' => $contributory,
+        'Other_Default_Ignorable_Code_Point' => $contributory,
+        'Other_Grapheme_Extend' => $contributory,
+        'Other_ID_Continue' => $contributory,
+        'Other_ID_Start' => $contributory,
+        'Other_Lowercase' => $contributory,
+        'Other_Math' => $contributory,
+        'Other_Uppercase' => $contributory,
+    );
+
+    %why_suppressed = (
+        # There is a lib/unicore/Decomposition.pl (used by normalize.pm) which
+        # contains the same information, but without the algorithmically
+        # determinable Hangul syllables'.  This file is not published, so it's
+        # existence is not noted in the comment.
+        'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
+
+        'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
+        'Unicode_1_Name' => "$simple, and no apparent demand for it, but can access it through Unicode::UCD::charinfo.  If there is no later name for a code point, then this one is used instead in charnames",
+
+        'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
+        'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
+        'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
+        'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
+
+        'Name' => "Accessible via 'use charnames;'",
+        'Name_Alias' => "Accessible via 'use charnames;'",
+
+        # These are sort of jumping the gun; deprecation is proposed for
+        # Unicode version 6.0, but they have never been exposed by Perl, and
+        # likely are soon to be deprecated, so best not to expose them.
+        FC_NFKC_Closure => 'Use NFKC_Casefold instead',
+        Expands_On_NFC => $why_no_expand,
+        Expands_On_NFD => $why_no_expand,
+        Expands_On_NFKC => $why_no_expand,
+        Expands_On_NFKD => $why_no_expand,
+    );
+
+    # The following are suppressed because they were made contributory or
+    # deprecated by Unicode before Perl ever thought about supporting them.
+    foreach my $property ('Jamo_Short_Name', 'Grapheme_Link') {
+        $why_suppressed{$property} = $why_deprecated{$property};
+    }
 
+    # Customize the message for all the 'Other_' properties
+    foreach my $property (keys %why_deprecated) {
+        next if (my $main_property = $property) !~ s/^Other_//;
+        $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
+    }
+}
+
+if ($v_version ge 4.0.0) {
+    $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
+}
+if ($v_version ge 5.2.0) {
+    $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
+}
+
+# Probably obsolete forever
+if ($v_version ge v4.1.0) {
+    $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common"';
+}
+
+# This program can create files for enumerated-like properties, such as
+# 'Numeric_Type'.  This file would be the same format as for a string
+# property, with a mapping from code point to its value, so you could look up,
+# for example, the script a code point is in.  But no one so far wants this
+# mapping, or they have found another way to get it since this is a new
+# feature.  So no file is generated except if it is in this list.
+my @output_mapped_properties = split "\n", <<END;
+END
+
+# If you are using the Unihan database, you need to add the properties that
+# you want to extract from it to this table.  For your convenience, the
+# properties in the 5.2 PropertyAliases.txt file are listed, commented out
+my @cjk_properties = split "\n", <<'END';
+#cjkAccountingNumeric; kAccountingNumeric
+#cjkOtherNumeric; kOtherNumeric
+#cjkPrimaryNumeric; kPrimaryNumeric
+#cjkCompatibilityVariant; kCompatibilityVariant
+#cjkIICore ; kIICore
+#cjkIRG_GSource; kIRG_GSource
+#cjkIRG_HSource; kIRG_HSource
+#cjkIRG_JSource; kIRG_JSource
+#cjkIRG_KPSource; kIRG_KPSource
+#cjkIRG_KSource; kIRG_KSource
+#cjkIRG_TSource; kIRG_TSource
+#cjkIRG_USource; kIRG_USource
+#cjkIRG_VSource; kIRG_VSource
+#cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
+END
+
+# Similarly for the property values.  For your convenience, the lines in the
+# 5.2 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
+# '#' marks
+my @cjk_property_values = split "\n", <<'END';
+## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
+## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
+## @missing: 0000..10FFFF; cjkIICore; <none>
+## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
+## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
+## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
+## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
+## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
+## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
+## @missing: 0000..10FFFF; cjkIRG_USource; <none>
+## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
+## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
+## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
+## @missing: 0000..10FFFF; cjkRSUnicode; <none>
+END
+
+# The input files don't list every code point.  Those not listed are to be
+# defaulted to some value.  Below are hard-coded what those values are for
+# non-binary properties as of 5.1.  Starting in 5.0, there are
+# machine-parsable comment lines in the files the give the defaults; so this
+# list shouldn't have to be extended.  The claim is that all missing entries
+# for binary properties will default to 'N'.  Unicode tried to change that in
+# 5.2, but the beta period produced enough protest that they backed off.
+#
+# The defaults for the fields that appear in UnicodeData.txt in this hash must
+# be in the form that it expects.  The others may be synonyms.
+my $CODE_POINT = '<code point>';
+my %default_mapping = (
+    Age => "Unassigned",
+    # Bidi_Class => Complicated; set in code
+    Bidi_Mirroring_Glyph => "",
+    Block => 'No_Block',
+    Canonical_Combining_Class => 0,
+    Case_Folding => $CODE_POINT,
+    Decomposition_Mapping => $CODE_POINT,
+    Decomposition_Type => 'None',
+    East_Asian_Width => "Neutral",
+    FC_NFKC_Closure => $CODE_POINT,
+    General_Category => 'Cn',
+    Grapheme_Cluster_Break => 'Other',
+    Hangul_Syllable_Type => 'NA',
+    ISO_Comment => "",
+    Jamo_Short_Name => "",
+    Joining_Group => "No_Joining_Group",
+    # Joining_Type => Complicated; set in code
+    kIICore => 'N',   #                       Is converted to binary
+    #Line_Break => Complicated; set in code
+    Lowercase_Mapping => $CODE_POINT,
+    Name => "",
+    Name_Alias => "",
+    NFC_QC => 'Yes',
+    NFD_QC => 'Yes',
+    NFKC_QC => 'Yes',
+    NFKD_QC => 'Yes',
+    Numeric_Type => 'None',
+    Numeric_Value => 'NaN',
+    Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
+    Sentence_Break => 'Other',
+    Simple_Case_Folding => $CODE_POINT,
+    Simple_Lowercase_Mapping => $CODE_POINT,
+    Simple_Titlecase_Mapping => $CODE_POINT,
+    Simple_Uppercase_Mapping => $CODE_POINT,
+    Titlecase_Mapping => $CODE_POINT,
+    Unicode_1_Name => "",
+    Unicode_Radical_Stroke => "",
+    Uppercase_Mapping => $CODE_POINT,
+    Word_Break => 'Other',
+);
+
+# Below are files that Unicode furnishes, but this program ignores, and why
+my %ignored_files = (
+    'CJKRadicals.txt' => 'Unihan data',
+    'Index.txt' => 'An index, not actual data',
+    'NamedSqProv.txt' => 'Not officially part of the Unicode standard; Append it to NamedSequences.txt if you want to process the contents.',
+    'NamesList.txt' => 'Just adds commentary',
+    'NormalizationCorrections.txt' => 'Data is already in other files.',
+    'Props.txt' => 'Adds nothing to PropList.txt; only in very early releases',
+    'ReadMe.txt' => 'Just comments',
+    'README.TXT' => 'Just comments',
+    'StandardizedVariants.txt' => 'Only for glyph changes, not a Unicode character property.  Does not fit into current scheme where one code point is mapped',
+);
+
+################ End of externally interesting definitions ###############
+
+my $HEADER=<<"EOF";
+# !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
+# This file is machine-generated by $0 from the Unicode database,
+# Version $string_version.  Any changes made here will be lost!
 EOF
 
 my $INTERNAL_ONLY=<<"EOF";
+
+# !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
 # This file is for internal use by the Perl program only.  The format and even
-# name or existence of this file are subject to change without notice.  Don't
-# use it directly.
+# the name or existence of this file are subject to change without notice.
+# Don't use it directly.
+EOF
+
+my $DEVELOPMENT_ONLY=<<"EOF";
+# !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
+# This file contains information artificially constrained to code points
+# present in Unicode release $string_compare_versions.
+# IT CANNOT BE RELIED ON.  It is for use during development only and should
+# not be used for production.  
 
 EOF
 
-sub force_unlink {
-    my $filename = shift;
-    return unless -e $filename;
-    return if CORE::unlink($filename);
-    # We might need write permission
-    chmod 0777, $filename;
-    CORE::unlink($filename) or die "Couldn't unlink $filename: $!\n";
+my $LAST_UNICODE_CODEPOINT_STRING = "10FFFF";
+my $LAST_UNICODE_CODEPOINT = hex $LAST_UNICODE_CODEPOINT_STRING;
+my $MAX_UNICODE_CODEPOINTS = $LAST_UNICODE_CODEPOINT + 1;
+
+# Matches legal code point.  4-6 hex numbers, If there are 6, the first
+# two must be 10; if there are 5, the first must not be a 0.  Written this way
+# to decrease backtracking
+my $code_point_re =
+        qr/ \b (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
+
+# This matches the beginning of the line in the Unicode db files that give the
+# defaults for code points not listed (i.e., missing) in the file.  The code
+# depends on this ending with a semi-colon, so it can assume it is a valid
+# field when the line is split() by semi-colons
+my $missing_defaults_prefix =
+            qr/^#\s+\@missing:\s+0000\.\.$LAST_UNICODE_CODEPOINT_STRING\s*;/;
+
+# Property types.  Unicode has more types, but these are sufficient for our
+# purposes.
+my $UNKNOWN = -1;   # initialized to illegal value
+my $NON_STRING = 1; # Either binary or enum
+my $BINARY = 2;
+my $ENUM = 3;       # Include catalog
+my $STRING = 4;     # Anything else: string or misc
+
+# Some input files have lines that give default values for code points not
+# contained in the file.  Sometimes these should be ignored.
+my $NO_DEFAULTS = 0;        # Must evaluate to false
+my $NOT_IGNORED = 1;
+my $IGNORED = 2;
+
+# Range types.  Each range has a type.  Most ranges are type 0, for normal,
+# and will appear in the main body of the tables in the output files, but
+# there are other types of ranges as well, listed below, that are specially
+# handled.   There are pseudo-types as well that will never be stored as a
+# type, but will affect the calculation of the type.
+
+# 0 is for normal, non-specials
+my $MULTI_CP = 1;           # Sequence of more than code point
+my $HANGUL_SYLLABLE = 2;
+my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
+my $NULL = 4;               # The map is to the null string; utf8.c can't
+                            # handle these, nor is there an accepted syntax
+                            # for them in \p{} constructs
+my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; meanst that ranges that would
+                             # otherwise be $MULTI_CP type are instead type 0
+
+# process_generic_property_file() can accept certain overrides in its input.
+# Each of these must begin AND end with $CMD_DELIM.
+my $CMD_DELIM = "\a";
+my $REPLACE_CMD = 'replace';    # Override the Replace
+my $MAP_TYPE_CMD = 'map_type';  # Override the Type
+
+my $NO = 0;
+my $YES = 1;
+
+# Values for the Replace argument to add_range.
+# $NO                      # Don't replace; add only the code points not
+                           # already present.
+my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
+                           # the comments at the subroutine definition.
+my $UNCONDITIONALLY = 2;   # Replace without conditions.
+my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
+                           # already there
+
+# Flags to give property statuses.  The phrases are to remind maintainers that
+# if the flag is changed, the indefinite article referring to it in the
+# documentation may need to be as well.
+my $NORMAL = "";
+my $SUPPRESSED = 'z';   # The character should never actually be seen, since
+                        # it is suppressed
+my $DEPRECATED = 'D';
+my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
+my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
+my $DISCOURAGED = 'X';
+my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
+my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
+my $STRICTER = 'T';
+my $a_bold_stricter = "a 'B<$STRICTER>'";
+my $A_bold_stricter = "A 'B<$STRICTER>'";
+my $STABILIZED = 'S';
+my $a_bold_stabilized = "an 'B<$STABILIZED>'";
+my $A_bold_stabilized = "An 'B<$STABILIZED>'";
+my $OBSOLETE = 'O';
+my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
+my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
+
+my %status_past_participles = (
+    $DISCOURAGED => 'discouraged',
+    $SUPPRESSED => 'should never be generated',
+    $STABILIZED => 'stabilized',
+    $OBSOLETE => 'obsolete',
+    $DEPRECATED => 'deprecated'
+);
+
+# The format of the values of the map tables:
+my $BINARY_FORMAT = 'b';
+my $DECIMAL_FORMAT = 'd';
+my $FLOAT_FORMAT = 'f';
+my $INTEGER_FORMAT = 'i';
+my $HEX_FORMAT = 'x';
+my $RATIONAL_FORMAT = 'r';
+my $STRING_FORMAT = 's';
+
+my %map_table_formats = (
+    $BINARY_FORMAT => 'binary',
+    $DECIMAL_FORMAT => 'single decimal digit',
+    $FLOAT_FORMAT => 'floating point number',
+    $INTEGER_FORMAT => 'integer',
+    $HEX_FORMAT => 'positive hex whole number; a code point',
+    $RATIONAL_FORMAT => 'rational: an integer or a fraction',
+    $STRING_FORMAT => 'arbitrary string',
+);
+
+# Unicode didn't put such derived files in a separate directory at first.
+my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
+my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
+my $AUXILIARY = 'auxiliary';
+
+# Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
+my %loose_to_file_of;       # loosely maps table names to their respective
+                            # files
+my %stricter_to_file_of;    # same; but for stricter mapping.
+my %nv_floating_to_rational; # maps numeric values floating point numbers to
+                             # their rational equivalent
+my %loose_property_name_of; # Loosely maps property names to standard form
+
+# These constants names and values were taken from the Unicode standard,
+# version 5.1, section 3.12.  They are used in conjunction with Hangul
+# syllables
+my $SBase = 0xAC00;
+my $LBase = 0x1100;
+my $VBase = 0x1161;
+my $TBase = 0x11A7;
+my $SCount = 11172;
+my $LCount = 19;
+my $VCount = 21;
+my $TCount = 28;
+my $NCount = $VCount * $TCount;
+
+# For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
+# with the above published constants.
+my %Jamo;
+my %Jamo_L;     # Leading consonants
+my %Jamo_V;     # Vowels
+my %Jamo_T;     # Trailing consonants
+
+my @unhandled_properties;  # Will contain a list of properties found in
+                           # the input that we didn't process.
+my @match_properties;      # properties that have match tables, to be
+                           # listed in the pod
+my @map_properties;        # Properties that get map files written
+my @named_sequences;       # NamedSequences.txt contents.
+my %potential_files;       # Generated list of all .txt files in the directory
+                           # structure so we can warn if something is being
+                           # ignored.
+my @files_actually_output; # List of files we generated.
+my @more_Names;            # Some code point names are compound; this is used
+                           # to store the extra components of them.
+my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
+                           # the minimum before we consider it equivalent to a
+                           # candidate rational
+my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
+
+# These store references to certain commonly used property objects
+my $gc;
+my $perl;
+my $block;
+
+# Are there conflicting names because of beginning with 'In_', or 'Is_'
+my $has_In_conflicts = 0;
+my $has_Is_conflicts = 0;
+
+sub internal_file_to_platform ($) {
+    # Convert our file paths which have '/' separators to those of the
+    # platform.
+
+    my $file = shift;
+    return undef unless defined $file;
+
+    return File::Spec->join(split '/', $file);
 }
 
-##
-## Given a filename and a reference to an array of lines,
-## write the lines to the file only if the contents have not changed.
-## Filename can be given as an arrayref of directory names
-##
-sub WriteIfChanged($\@)
-{
-    my $file  = shift;
-    my $lines = shift;
+sub file_exists ($) {   # platform independent '-e'.  This program internally
+                        # uses slash as a path separator.
+    my $file = shift;
+    return 0 if ! defined $file;
+    return -e internal_file_to_platform($file);
+}
 
-    $file = File::Spec->catfile(@$file) if ref $file;
+# This 'require' doesn't necessarily work in miniperl, and even if it does,
+# the native perl version of it (which is what would operate under miniperl)
+# is extremely slow, as it does a string eval every call.
+my $has_fast_scalar_util = $\18 !~ /miniperl/
+                            && defined eval "require Scalar::Util";
 
-    my $TextToWrite = join '', @$lines;
-    if (open IN, $file) {
-        local($/) = undef;
-        my $PreviousText = <IN>;
-        close IN;
-        if ($PreviousText eq $TextToWrite) {
-            print "$file unchanged.\n" if $Verbose;
-            return unless $AlwaysWrite;
-        }
+sub objaddr($) {
+    # Returns the address of the blessed input object.  Uses the XS version if
+    # available.  It doesn't check for blessedness because that would do a
+    # string eval every call, and the program is structured so that this is
+    # never called for a non-blessed object.
+
+    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
+
+    # Check at least that is a ref.
+    my $pkg = ref($_[0]) or return undef;
+
+    # Change to a fake package to defeat any overloaded stringify
+    bless $_[0], 'main::Fake';
+
+    # Numifying a ref gives its address.
+    my $addr = 0 + $_[0];
+
+    # Return to original class
+    bless $_[0], $pkg;
+    return $addr;
+}
+
+sub max ($$) {
+    my $a = shift;
+    my $b = shift;
+    return $a if $a >= $b;
+    return $b;
+}
+
+sub min ($$) {
+    my $a = shift;
+    my $b = shift;
+    return $a if $a <= $b;
+    return $b;
+}
+
+sub clarify_number ($) {
+    # This returns the input number with underscores inserted every 3 digits
+    # in large (5 digits or more) numbers.  Input must be entirely digits, not
+    # checked.
+
+    my $number = shift;
+    my $pos = length($number) - 3;
+    return $number if $pos <= 1;
+    while ($pos > 0) {
+        substr($number, $pos, 0) = '_';
+        $pos -= 3;
     }
-    force_unlink ($file);
-    if (not open OUT, ">$file") {
-        die "$0: can't open $file for output: $!\n";
-    }
-    print "$file written.\n" if $Verbose;
-
-    print OUT $TextToWrite;
-    close OUT;
-}
-
-##
-## The main datastructure (a "Table") represents a set of code points that
-## are part of a particular quality (that are part of \pL, \p{InGreek},
-## etc.). They are kept as ranges of code points (starting and ending of
-## each range).
-##
-## For example, a range ASCII LETTERS would be represented as:
-##   [ [ 0x41 => 0x5A, 'UPPER' ],
-##     [ 0x61 => 0x7A, 'LOWER, ] ]
-##
-sub RANGE_START() { 0 } ## index into range element
-sub RANGE_END()   { 1 } ## index into range element
-sub RANGE_NAME()  { 2 } ## index into range element
-
-## Conceptually, these should really be folded into the 'Table' objects
-my %TableInfo;
-my %TableDesc;
-my %FuzzyNames;
-my %AliasInfo;
-my %CanonicalToOrig;
-
-##
-## Turn something like
-##    OLD-ITALIC
-## into
-##    OldItalic
-##
-sub CanonicalName($)
-{
-    my $orig = shift;
-    my $name = lc $orig;
-    $name =~ s/(?<![a-z])(\w)/\u$1/g;
-    $name =~ s/[-_\s]+//g;
-
-    $CanonicalToOrig{$name} = $orig if not $CanonicalToOrig{$name};
-    return $name;
+    return $number;
 }
 
 
-##
-## Store the alias definitions for later use.
-##
-my %PropertyAlias;
-my %PropValueAlias;
-
-my %PA_reverse;
-my %PVA_reverse;
-
-sub Build_Aliases()
-{
-    ##
-    ## Most of the work with aliases doesn't occur here,
-    ## but rather in utf8_heavy.pl, which uses PVA.pl,
+package Carp;
 
-    # Placate the warnings about used only once. (They are used again, but
-    # via a typeglob lookup)
-    %utf8::PropertyAlias = ();
-    %utf8::PA_reverse = ();
-    %utf8::PropValueAlias = ();
-    %utf8::PVA_reverse = ();
-    %utf8::PVA_abbr_map = ();
+# These routines give a uniform treatment of messages in this program.  They
+# are placed in the Carp package to cause the stack trace to not include them,
+# although an alternative would be to use another package and set @CARP_NOT
+# for it.
 
-    open PA, "< PropertyAliases.txt"
-       or confess "Can't open PropertyAliases.txt: $!";
-    while (<PA>) {
-       s/#.*//;
-       s/\s+$//;
-       next if /^$/;
+our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
 
-       my ($abbrev, $name) = split /\s*;\s*/;
-        next if $abbrev eq "n/a";
-       $PropertyAlias{$abbrev} = $name;
-        $PA_reverse{$name} = $abbrev;
+sub my_carp {
+    my $message = shift || "";
+    my $nofold = shift || 0;
 
-       # The %utf8::... versions use japhy's code originally from utf8_pva.pl
-       # However, it's moved here so that we build the tables at runtime.
-       tr/ _-//d for $abbrev, $name;
-       $utf8::PropertyAlias{lc $abbrev} = $name;
-       $utf8::PA_reverse{lc $name} = $abbrev;
-    }
-    close PA;
+    if ($message) {
+        $message = main::join_lines($message);
+        $message =~ s/^$0: *//;     # Remove initial program name
+        $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
+        $message = "\n$0: $message;";
 
-    open PVA, "< PropValueAliases.txt"
-       or confess "Can't open PropValueAliases.txt: $!";
-    while (<PVA>) {
-       s/#.*//;
-       s/\s+$//;
-       next if /^$/;
+        # Fold the message with program name, semi-colon end punctuation
+        # (which looks good with the message that carp appends to it), and a
+        # hanging indent for continuation lines.
+        $message = main::simple_fold($message, "", 4) unless $nofold;
+        $message =~ s/\n$//;        # Remove the trailing nl so what carp
+                                    # appends is to the same line
+    }
 
-       my ($prop, @data) = split /\s*;\s*/;
+    return $message if defined wantarray;   # If a caller just wants the msg
 
-       if ($prop eq 'ccc') {
-           $PropValueAlias{$prop}{$data[1]} = [ @data[0,2] ];
-           $PVA_reverse{$prop}{$data[2]} = [ @data[0,1] ];
-       }
-       else {
-            next if $data[0] eq "n/a";
-           $PropValueAlias{$prop}{$data[0]} = $data[1];
-            $PVA_reverse{$prop}{$data[1]} = $data[0];
-       }
+    carp $message;
+    return;
+}
 
-       shift @data if $prop eq 'ccc';
-       next if $data[0] eq "n/a";
+sub my_carp_bug {
+    # This is called when it is clear that the problem is caused by a bug in
+    # this program.
 
-       $data[1] =~ tr/ _-//d;
-       $utf8::PropValueAlias{$prop}{lc $data[0]} = $data[1];
-       $utf8::PVA_reverse{$prop}{lc $data[1]} = $data[0];
+    my $message = shift;
+    $message =~ s/^$0: *//;
+    $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
+    carp $message;
+    return;
+}
 
-       my $abbr_class = ($prop eq 'gc' or $prop eq 'sc') ? 'gc_sc' : $prop;
-       $utf8::PVA_abbr_map{$abbr_class}{lc $data[0]} = $data[0];
+sub carp_too_few_args {
+    if (@_ != 2) {
+        my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
+        return;
     }
-    close PVA;
 
-    # backwards compatibility for L& -> LC
-    $utf8::PropValueAlias{gc}{'l&'} = $utf8::PropValueAlias{gc}{lc};
-    $utf8::PVA_abbr_map{gc_sc}{'l&'} = $utf8::PVA_abbr_map{gc_sc}{lc};
+    my $args_ref = shift;
+    my $count = shift;
 
+    my_carp_bug("Need at least $count arguments to "
+        . (caller 1)[3]
+        . ".  Instead got: '"
+        . join ', ', @$args_ref
+        . "'.  No action taken.");
+    return;
 }
 
+sub carp_extra_args {
+    my $args_ref = shift;
+    my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
 
-##
-## Associates a property ("Greek", "Lu", "Assigned",...) with a Table.
-##
-## Called like:
-##       New_Prop(In => 'Greek', $Table, Desc => 'Greek Block', Fuzzy => 1);
-##
-## Normally, these parameters are set when the Table is created (when the
-## Table->New constructor is called), but there are times when it needs to
-## be done after-the-fact...)
-##
-sub New_Prop($$$@)
-{
-    my $Type = shift; ## "Is" or "In";
-    my $Name = shift;
-    my $Table = shift;
+    unless (ref $args_ref) {
+        my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
+        return;
+    }
+    my ($package, $file, $line) = caller;
+    my $subroutine = (caller 1)[3];
 
-    ## remaining args are optional key/val
-    my %Args = @_;
-
-    my $Fuzzy = delete $Args{Fuzzy};
-    my $Desc  = delete $Args{Desc}; # description
-
-    $Name = CanonicalName($Name) if $Fuzzy;
-
-    ## sanity check a few args
-    if (%Args or ($Type ne 'Is' and $Type ne 'In') or not ref $Table) {
-        confess "$0: bad args to New_Prop"
-    }
-
-    if (not $TableInfo{$Type}->{$Name})
-    {
-        $TableInfo{$Type}->{$Name} = $Table;
-        $TableDesc{$Type}->{$Name} = $Desc;
-        if ($Fuzzy) {
-            $FuzzyNames{$Type}->{$Name} = $Name;
+    my $list;
+    if (ref $args_ref eq 'HASH') {
+        foreach my $key (keys %$args_ref) {
+            $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
         }
+        $list = join ', ', each %{$args_ref};
     }
+    elsif (ref $args_ref eq 'ARRAY') {
+        foreach my $arg (@$args_ref) {
+            $arg = $UNDEF unless defined $arg;
+        }
+        $list = join ', ', @$args_ref;
+    }
+    else {
+        my_carp_bug("Can't cope with ref "
+                . ref($args_ref)
+                . " . argument to 'carp_extra_args'.  Not checking arguments.");
+        return;
+    }
+
+    my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
+    return;
 }
 
+package main;
+
+{ # Closure
+
+    # This program uses the inside-out method for objects, as recommended in
+    # "Perl Best Practices".  This closure aids in generating those.  There
+    # are two routines.  setup_package() is called once per package to set
+    # things up, and then set_access() is called for each hash representing a
+    # field in the object.  These routines arrange for the object to be
+    # properly destroyed when no longer used, and for standard accessor
+    # functions to be generated.  If you need more complex accessors, just
+    # write your own and leave those accesses out of the call to set_access().
+    # More details below.
+
+    my %constructor_fields; # fields that are to be used in constructors; see
+                            # below
+
+    # The values of this hash will be the package names as keys to other
+    # hashes containing the name of each field in the package as keys, and
+    # references to their respective hashes as values.
+    my %package_fields;
+
+    sub setup_package {
+        # Sets up the package, creating standard DESTROY and dump methods
+        # (unless already defined).  The dump method is used in debugging by
+        # simple_dumper().
+        # The optional parameters are:
+        #   a)  a reference to a hash, that gets populated by later
+        #       set_access() calls with one of the accesses being
+        #       'constructor'.  The caller can then refer to this, but it is
+        #       not otherwise used by these two routines.
+        #   b)  a reference to a callback routine to call during destruction
+        #       of the object, before any fields are actually destroyed
+
+        my %args = @_;
+        my $constructor_ref = delete $args{'Constructor_Fields'};
+        my $destroy_callback = delete $args{'Destroy_Callback'};
+        Carp::carp_extra_args(\@_) if main::DEBUG && %args;
+
+        my %fields;
+        my $package = (caller)[0];
+
+        $package_fields{$package} = \%fields;
+        $constructor_fields{$package} = $constructor_ref;
+
+        unless ($package->can('DESTROY')) {
+            my $destroy_name = "${package}::DESTROY";
+            no strict "refs";
+
+            # Use typeglob to give the anonymous subroutine the name we want
+            *$destroy_name = sub {
+                my $self = shift;
+                my $addr = main::objaddr($self);
+
+                $self->$destroy_callback if $destroy_callback;
+                foreach my $field (keys %{$package_fields{$package}}) {
+                    #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
+                    delete $package_fields{$package}{$field}{$addr};
+                }
+                return;
+            }
+        }
+
+        unless ($package->can('dump')) {
+            my $dump_name = "${package}::dump";
+            no strict "refs";
+            *$dump_name = sub {
+                my $self = shift;
+                return dump_inside_out($self, $package_fields{$package}, @_);
+            }
+        }
+        return;
+    }
+
+    sub set_access {
+        # Arrange for the input field to be garbage collected when no longer
+        # needed.  Also, creates standard accessor functions for the field
+        # based on the optional parameters-- none if none of these parameters:
+        #   'addable'    creates an 'add_NAME()' accessor function.
+        #   'readable' or 'readable_array'   creates a 'NAME()' accessor
+        #                function.
+        #   'settable'   creates a 'set_NAME()' accessor function.
+        #   'constructor' doesn't create an accessor function, but adds the
+        #                field to the hash that was previously passed to
+        #                setup_package();
+        # Any of the accesses can be abbreviated down, so that 'a', 'ad',
+        # 'add' etc. all mean 'addable'.
+        # The read accessor function will work on both array and scalar
+        # values.  If another accessor in the parameter list is 'a', the read
+        # access assumes an array.  You can also force it to be array access
+        # by specifying 'readable_array' instead of 'readable'
+        #
+        # A sort-of 'protected' access can be set-up by preceding the addable,
+        # readable or settable with some initial portion of 'protected_' (but,
+        # the underscore is required), like 'p_a', 'pro_set', etc.  The
+        # "protection" is only by convention.  All that happens is that the
+        # accessor functions' names begin with an underscore.  So instead of
+        # calling set_foo, the call is _set_foo.  (Real protection could be
+        # accomplished by having a new subroutine, end_package called at the
+        # end of each package, and then storing the __LINE__ ranges and
+        # checking them on every accessor.  But that is way overkill.)
+
+        # We create anonymous subroutines as the accessors and then use
+        # typeglobs to assign them to the proper package and name
+
+        my $name = shift;   # Name of the field
+        my $field = shift;  # Reference to the inside-out hash containing the
+                            # field
+
+        my $package = (caller)[0];
+
+        if (! exists $package_fields{$package}) {
+            croak "$0: Must call 'setup_package' before 'set_access'";
+        }
 
-##
-## Creates a new Table object.
-##
-## Args are key/value pairs:
-##    In => Name         -- Name of "In" property to be associated with
-##    Is => Name         -- Name of "Is" property to be associated with
-##    Fuzzy => Boolean   -- True if name can be accessed "fuzzily"
-##    Desc  => String    -- Description of the property
-##
-## No args are required.
-##
-sub Table::New
-{
-    my $class = shift;
-    my %Args = @_;
+        # Stash the field so DESTROY can get it.
+        $package_fields{$package}{$name} = $field;
 
-    my $Table = bless [], $class;
+        # Remaining arguments are the accessors.  For each...
+        foreach my $access (@_) {
+            my $access = lc $access;
 
-    my $Fuzzy = delete $Args{Fuzzy};
-    my $Desc  = delete $Args{Desc};
+            my $protected = "";
 
-    for my $Type ('Is', 'In')
-    {
-        if (my $Name = delete $Args{$Type}) {
-            New_Prop($Type => $Name, $Table, Desc => $Desc, Fuzzy => $Fuzzy);
+            # Match the input as far as it goes.
+            if ($access =~ /^(p[^_]*)_/) {
+                $protected = $1;
+                if (substr('protected_', 0, length $protected)
+                    eq $protected)
+                {
+
+                    # Add 1 for the underscore not included in $protected
+                    $access = substr($access, length($protected) + 1);
+                    $protected = '_';
+                }
+                else {
+                    $protected = "";
+                }
+            }
+
+            if (substr('addable', 0, length $access) eq $access) {
+                my $subname = "${package}::${protected}add_$name";
+                no strict "refs";
+
+                # add_ accessor.  Don't add if already there, which we
+                # determine using 'eq' for scalars and '==' otherwise.
+                *$subname = sub {
+                    use strict "refs";
+                    return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
+                    my $self = shift;
+                    my $value = shift;
+                    Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+                    if (ref $value) {
+                        return if grep { $value == $_ }
+                                            @{$field->{main::objaddr $self}};
+                    }
+                    else {
+                        return if grep { $value eq $_ }
+                                            @{$field->{main::objaddr $self}};
+                    }
+                    push @{$field->{main::objaddr $self}}, $value;
+                    return;
+                }
+            }
+            elsif (substr('constructor', 0, length $access) eq $access) {
+                if ($protected) {
+                    Carp::my_carp_bug("Can't set-up 'protected' constructors")
+                }
+                else {
+                    $constructor_fields{$package}{$name} = $field;
+                }
+            }
+            elsif (substr('readable_array', 0, length $access) eq $access) {
+
+                # Here has read access.  If one of the other parameters for
+                # access is array, or this one specifies array (by being more
+                # than just 'readable_'), then create a subroutine that
+                # assumes the data is an array.  Otherwise just a scalar
+                my $subname = "${package}::${protected}$name";
+                if (grep { /^a/i } @_
+                    or length($access) > length('readable_'))
+                {
+                    no strict "refs";
+                    *$subname = sub {
+                        use strict "refs";
+                        my $self = shift;
+                        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+                        my $addr = main::objaddr $self;
+                        if (ref $field->{$addr} ne 'ARRAY') {
+                            my $type = ref $field->{$addr};
+                            $type = 'scalar' unless $type;
+                            Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
+                            return;
+                        }
+                        return scalar @{$field->{$addr}} unless wantarray;
+
+                        # Make a copy; had problems with caller modifying the
+                        # original otherwise
+                        my @return = @{$field->{$addr}};
+                        return @return;
+                    }
+                }
+                else {
+
+                    # Here not an array value, a simpler function.
+                    no strict "refs";
+                    *$subname = sub {
+                        use strict "refs";
+                        my $self = shift;
+                        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+                        return $field->{main::objaddr $self};
+                    }
+                }
+            }
+            elsif (substr('settable', 0, length $access) eq $access) {
+                my $subname = "${package}::${protected}set_$name";
+                no strict "refs";
+                *$subname = sub {
+                    use strict "refs";
+                    return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
+                    my $self = shift;
+                    my $value = shift;
+                    Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+                    $field->{main::objaddr $self} = $value;
+                    return;
+                }
+            }
+            else {
+                Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
+            }
         }
+        return;
     }
-
-    ## shouldn't have any left over
-    if (%Args) {
-        confess "$0: bad args to Table->New"
-    }
-
-    return $Table;
-}
-
-
-##
-## Returns the maximum code point currently in the table.
-##
-sub Table::Max
-{
-    my $last = $_[0]->[-1];      ## last code point
-    confess "oops" unless $last; ## must have code points to have a max
-    return $last->[RANGE_END];
-}
-
-##
-## Replaces the codepoints in the Table with those in the Table given
-## as an arg. (NOTE: this is not a "deep copy").
-##
-sub Table::Replace($$)
-{
-    my $Table = shift; #self
-    my $New   = shift;
-
-    @$Table = @$New;
-}
-
-##
-## Given a new code point, make the last range of the Table extend to
-## include the new (and all intervening) code points.
-##
-## Takes the time to make sure that the extension is valid.
-##
-sub Table::Extend
-{
-    my $Table = shift; #self
-    my $codepoint = shift;
-
-    my $PrevMax = $Table->Max;
-
-    confess "oops ($codepoint <= $PrevMax)" if $codepoint <= $PrevMax;
-
-    $Table->ExtendNoCheck($codepoint);
-}
-
-
-##
-## Given a new code point, make the last range of the Table extend to
-## include the new (and all intervening) code points.
-##
-## Does NOT check that the extension is valid.  Assumes that the caller
-## has already made this check.
-##
-sub Table::ExtendNoCheck
-{
-    ## Optmized adding: Assumes $Table and $codepoint as parms
-    $_[0]->[-1]->[RANGE_END] = $_[1];
-}
-
-##
-## Given a code point range start and end (and optional name), blindly
-## append them to the list of ranges for the Table.
-##
-## NOTE: Code points must be added in strictly ascending numeric order.
-##
-sub Table::RawAppendRange
-{
-    my $Table = shift; #self
-    my $start = shift;
-    my $end   = shift;
-    my $name  = shift;
-    $name = "" if not defined $name; ## warning: $name can be "0"
-
-    push @$Table, [ $start,    # RANGE_START
-                    $end,      # RANGE_END
-                    $name   ]; # RANGE_NAME
-}
-
-##
-## Given a code point (and optional name), add it to the Table.
-##
-## NOTE: Code points must be added in strictly ascending numeric order.
-##
-sub Table::Append
-{
-    my $Table     = shift; #self
-    my $codepoint = shift;
-    my $name      = shift;
-    $name = "" if not defined $name; ## warning: $name can be "0"
-
-    ##
-    ## If we've already got a range working, and this code point is the next
-    ## one in line, and if the name is the same, just extend the current range.
-    ##
-    my $last = $Table->[-1];
-    if ($last
-        and
-        $last->[RANGE_END] == $codepoint - 1
-        and
-        $last->[RANGE_NAME] eq $name)
-    {
-        $Table->ExtendNoCheck($codepoint);
-    }
-    else
-    {
-        $Table->RawAppendRange($codepoint, $codepoint, $name);
-    }
-}
-
-##
-## Given a code point range starting value and ending value (and name),
-## Add the range to the Table.
-##
-## NOTE: Code points must be added in strictly ascending numeric order.
-##
-sub Table::AppendRange
-{
-    my $Table = shift; #self
-    my $start = shift;
-    my $end   = shift;
-    my $name  = shift;
-    $name = "" if not defined $name; ## warning: $name can be "0"
-
-    $Table->Append($start, $name);
-    $Table->Extend($end) if $end > $start;
-}
-
-##
-## Return a new Table that represents all code points not in the Table.
-##
-sub Table::Invert
-{
-    my $Table = shift; #self
-
-    my $New = Table->New();
-    my $max = -1;
-    for my $range (@$Table)
-    {
-        my $start = $range->[RANGE_START];
-        my $end   = $range->[RANGE_END];
-        if ($start-1 >= $max+1) {
-            $New->AppendRange($max+1, $start-1, "");
-        }
-        $max = $end;
-    }
-    if ($max+1 < $LastUnicodeCodepoint) {
-        $New->AppendRange($max+1, $LastUnicodeCodepoint);
-    }
-    return $New;
-}
-
-##
-## Merges any number of other tables with $self, returning the new table.
-## (existing tables are not modified)
-##
-##
-## Args may be Tables, or individual code points (as integers).
-##
-## Can be called as either a constructor or a method.
-##
-sub Table::Merge
-{
-    shift(@_) if not ref $_[0]; ## if called as a constructor, lose the class
-    my @Tables = @_;
-
-    ## Accumulate all records from all tables
-    my @Records;
-    for my $Arg (@Tables)
-    {
-        if (ref $Arg) {
-            ## arg is a table -- get its ranges
-            push @Records, @$Arg;
-        } else {
-            ## arg is a codepoint, make a range
-            push @Records, [ $Arg, $Arg ]
+}
+
+package Input_file;
+
+# All input files use this object, which stores various attributes about them,
+# and provides for convenient, uniform handling.  The run method wraps the
+# processing.  It handles all the bookkeeping of opening, reading, and closing
+# the file, returning only significant input lines.
+#
+# Each object gets a handler which processes the body of the file, and is
+# called by run().  Most should use the generic, default handler, which has
+# code scrubbed to handle things you might not expect.  A handler should
+# basically be a while(next_line()) {...} loop.
+#
+# You can also set up handlers to
+#   1) call before the first line is read for pre processing
+#   2) call to adjust each line of the input before the main handler gets them
+#   3) call upon EOF before the main handler exits its loop
+#   4) call at the end for post processing
+#
+# $_ is used to store the input line, and is to be filtered by the
+# each_line_handler()s.  So, if the format of the line is not in the desired
+# format for the main handler, these are used to do that adjusting.  They can
+# be stacked (by enclosing them in an [ anonymous array ] in the constructor,
+# so the $_ output of one is used as the input to the next.  None of the other
+# handlers are stackable, but could easily be changed to be so.
+#
+# Most of the handlers can call insert_lines() or insert_adjusted_lines()
+# which insert the parameters as lines to be processed before the next input
+# file line is read.  This allows the EOF handler to flush buffers, for
+# example.  The difference between the two routines is that the lines inserted
+# by insert_lines() are subjected to the each_line_handler()s.  (So if you
+# called it from such a handler, you would get infinite recursion.)  Lines
+# inserted by insert_adjusted_lines() go directly to the main handler without
+# any adjustments.  If the  post-processing handler calls any of these, there
+# will be no effect.  Some error checking for these conditions could be added,
+# but it hasn't been done.
+#
+# carp_bad_line() should be called to warn of bad input lines, which clears $_
+# to prevent further processing of the line.  This routine will output the
+# message as a warning once, and then keep a count of the lines that have the
+# same message, and output that count at the end of the file's processing.
+# This keeps the number of messages down to a manageable amount.
+#
+# get_missings() should be called to retrieve any @missing input lines.
+# Messages will be raised if this isn't done if the options aren't to ignore
+# missings.
+
+sub trace { return main::trace(@_); }
+
+
+{ # Closure
+    # Keep track of fields that are to be put into the constructor.
+    my %constructor_fields;
+
+    main::setup_package(Constructor_Fields => \%constructor_fields);
+
+    my %file; # Input file name, required
+    main::set_access('file', \%file, qw{ c r });
+
+    my %first_released; # Unicode version file was first released in, required
+    main::set_access('first_released', \%first_released, qw{ c r });
+
+    my %handler;    # Subroutine to process the input file, defaults to
+                    # 'process_generic_property_file'
+    main::set_access('handler', \%handler, qw{ c });
+
+    my %property;
+    # name of property this file is for.  defaults to none, meaning not
+    # applicable, or is otherwise determinable, for example, from each line.
+    main::set_access('property', \%property, qw{ c });
+
+    my %optional;
+    # If this is true, the file is optional.  If not present, no warning is
+    # output.  If it is present, the string given by this parameter is
+    # evaluated, and if false the file is not processed.
+    main::set_access('optional', \%optional, 'c', 'r');
+
+    my %non_skip;
+    # This is used for debugging, to skip processing of all but a few input
+    # files.  Add 'non_skip => 1' to the constructor for those files you want
+    # processed when you set the $debug_skip global.
+    main::set_access('non_skip', \%non_skip, 'c');
+
+    my %each_line_handler;
+    # list of subroutines to look at and filter each non-comment line in the
+    # file.  defaults to none.  The subroutines are called in order, each is
+    # to adjust $_ for the next one, and the final one adjusts it for
+    # 'handler'
+    main::set_access('each_line_handler', \%each_line_handler, 'c');
+
+    my %has_missings_defaults;
+    # ? Are there lines in the file giving default values for code points
+    # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
+    # the norm, but IGNORED means it has such lines, but the handler doesn't
+    # use them.  Having these three states allows us to catch changes to the
+    # UCD that this program should track
+    main::set_access('has_missings_defaults',
+                                        \%has_missings_defaults, qw{ c r });
+
+    my %pre_handler;
+    # Subroutine to call before doing anything else in the file.  If undef, no
+    # such handler is called.
+    main::set_access('pre_handler', \%pre_handler, qw{ c });
+
+    my %eof_handler;
+    # Subroutine to call upon getting an EOF on the input file, but before
+    # that is returned to the main handler.  This is to allow buffers to be
+    # flushed.  The handler is expected to call insert_lines() or
+    # insert_adjusted() with the buffered material
+    main::set_access('eof_handler', \%eof_handler, qw{ c r });
+
+    my %post_handler;
+    # Subroutine to call after all the lines of the file are read in and
+    # processed.  If undef, no such handler is called.
+    main::set_access('post_handler', \%post_handler, qw{ c });
+
+    my %progress_message;
+    # Message to print to display progress in lieu of the standard one
+    main::set_access('progress_message', \%progress_message, qw{ c });
+
+    my %handle;
+    # cache open file handle, internal.  Is undef if file hasn't been
+    # processed at all, empty if has;
+    main::set_access('handle', \%handle);
+
+    my %added_lines;
+    # cache of lines added virtually to the file, internal
+    main::set_access('added_lines', \%added_lines);
+
+    my %errors;
+    # cache of errors found, internal
+    main::set_access('errors', \%errors);
+
+    my %missings;
+    # storage of '@missing' defaults lines
+    main::set_access('missings', \%missings);
+
+    sub new {
+        my $class = shift;
+
+        my $self = bless \do{ my $anonymous_scalar }, $class;
+        my $addr = main::objaddr($self);
+
+        # Set defaults
+        $handler{$addr} = \&main::process_generic_property_file;
+        $non_skip{$addr} = 0;
+        $has_missings_defaults{$addr} = $NO_DEFAULTS;
+        $handle{$addr} = undef;
+        $added_lines{$addr} = [ ];
+        $each_line_handler{$addr} = [ ];
+        $errors{$addr} = { };
+        $missings{$addr} = [ ];
+
+        # Two positional parameters.
+        $file{$addr} = main::internal_file_to_platform(shift);
+        $first_released{$addr} = shift;
+
+        # The rest of the arguments are key => value pairs
+        # %constructor_fields has been set up earlier to list all possible
+        # ones.  Either set or push, depending on how the default has been set
+        # up just above.
+        my %args = @_;
+        foreach my $key (keys %args) {
+            my $argument = $args{$key};
+
+            # Note that the fields are the lower case of the constructor keys
+            my $hash = $constructor_fields{lc $key};
+            if (! defined $hash) {
+                Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
+                next;
+            }
+            if (ref $hash->{$addr} eq 'ARRAY') {
+                if (ref $argument eq 'ARRAY') {
+                    foreach my $argument (@{$argument}) {
+                        next if ! defined $argument;
+                        push @{$hash->{$addr}}, $argument;
+                    }
+                }
+                else {
+                    push @{$hash->{$addr}}, $argument if defined $argument;
+                }
+            }
+            else {
+                $hash->{$addr} = $argument;
+            }
+            delete $args{$key};
+        };
+
+        # If the file has a property for it, it means that the property is not
+        # listed in the file's entries.  So add a handler to the list of line
+        # handlers to insert the property name into the lines, to provide a
+        # uniform interface to the final processing subroutine.
+        # the final code doesn't have to worry about that.
+        if ($property{$addr}) {
+            push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
+        }
+
+        if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
+            print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
         }
+
+        return $self;
     }
 
-    ## sort by range start, with longer ranges coming first.
-    my ($first, @Rest) = sort {
-        ($a->[RANGE_START] <=> $b->[RANGE_START])
-          or
-        ($b->[RANGE_END]   <=> $b->[RANGE_END])
-    } @Records;
 
-    my $New = Table->New();
+    use overload
+        fallback => 0,
+        qw("") => "_operator_stringify",
+        "." => \&main::_operator_dot,
+    ;
 
-    ## Ensuring the first range is there makes the subsequent loop easier
-    $New->AppendRange($first->[RANGE_START],
-                      $first->[RANGE_END]);
+    sub _operator_stringify {
+        my $self = shift;
 
-    ## Fold in records so long as they add new information.
-    for my $set (@Rest)
-    {
-        my $start = $set->[RANGE_START];
-        my $end   = $set->[RANGE_END];
-        if ($start > $New->Max) {
-            $New->AppendRange($start, $end);
-        } elsif ($end > $New->Max) {
-            $New->ExtendNoCheck($end);
-        }
+        return __PACKAGE__ . " object for " . $self->file;
     }
 
-    return $New;
-}
+    # flag to make sure extracted files are processed early
+    my $seen_non_extracted_non_age = 0;
 
-##
-## Given a filename, write a representation of the Table to a file.
-## May have an optional comment as a 2nd arg.
-## Filename may actually be an arrayref of directories
-##
-sub Table::Write
-{
-    my $Table    = shift; #self
-    my $filename = shift;
-    my $comment  = shift;
+    sub run {
+        # Process the input object $self.  This opens and closes the file and
+        # calls all the handlers for it.  Currently,  this can only be called
+        # once per file, as it destroy's the EOF handler
 
-    my @OUT = $HEADER;
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
 
-    # files in subdirectories are internal-use-only
-    push @OUT, $INTERNAL_ONLY if ref $filename;
+        my $addr = main::objaddr $self;
 
-    if (defined $comment) {
-        $comment =~ s/\s+\Z//;
-        $comment =~ s/^/# /gm;
-        push @OUT, "#\n$comment\n#\n";
-    }
-    push @OUT, "return <<'END';\n";
+        my $file = $file{$addr};
 
-    for my $set (@$Table)
-    {
-        my $start = $set->[RANGE_START];
-        my $end   = $set->[RANGE_END];
-        my $name  = $set->[RANGE_NAME];
+        # Don't process if not expecting this file (because released later
+        # than this Unicode version), and isn't there.  This means if someone
+        # copies it into an earlier version's directory, we will go ahead and
+        # process it.
+        return if $first_released{$addr} gt $v_version && ! -e $file;
+
+        # If in debugging mode and this file doesn't have the non-skip
+        # flag set, and isn't one of the critical files, skip it.
+        if ($debug_skip
+            && $first_released{$addr} ne v0
+            && ! $non_skip{$addr})
+        {
+            print "Skipping $file in debugging\n" if $verbosity;
+            return;
+        }
+
+        # File could be optional
+        if ($optional{$addr}){
+            return unless -e $file;
+            my $result = eval $optional{$addr};
+            if (! defined $result) {
+                Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
+                return;
+            }
+            if (! $result) {
+                if ($verbosity) {
+                    print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
+                }
+                return;
+            }
+        }
+
+        if (! defined $file || ! -e $file) {
+
+            # If the file doesn't exist, see if have internal data for it
+            # (based on first_released being 0).
+            if ($first_released{$addr} eq v0) {
+                $handle{$addr} = 'pretend_is_open';
+            }
+            else {
+                if (! $optional{$addr}  # File could be optional
+                    && $v_version ge $first_released{$addr})
+                {
+                    print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
+                }
+                return;
+            }
+        }
+        else {
+
+            # Here, the file exists
+            if ($seen_non_extracted_non_age) {
+                if ($file =~ /$EXTRACTED/) {
+                    Carp::my_carp_bug(join_lines(<<END
+$file should be processed just after the 'Prop..Alias' files, and before
+anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
+have subtle problems
+END
+                    ));
+                }
+            }
+            elsif ($EXTRACTED_DIR
+                    && $first_released{$addr} ne v0
+                    && $file !~ /$EXTRACTED/
+                    && $file ne 'DAge.txt')
+            {
+                # We don't set this (by the 'if' above) if we have no
+                # extracted directory, so if running on an early version,
+                # this test won't work.  Not worth worrying about.
+                $seen_non_extracted_non_age = 1;
+            }
+
+            # And mark the file as having being processed, and warn if it
+            # isn't a file we are expecting.  As we process the files,
+            # they are deleted from the hash, so any that remain at the
+            # end of the program are files that we didn't process.
+            Carp::my_carp("Was not expecting '$file'.") if
+                    ! delete $potential_files{File::Spec->rel2abs($file)}
+                    && ! defined $handle{$addr};
+
+            # Open the file, converting the slashes used in this program
+            # into the proper form for the OS
+            my $file_handle;
+            if (not open $file_handle, "<", $file) {
+                Carp::my_carp("Can't open $file.  Skipping: $!");
+                return 0;
+            }
+            $handle{$addr} = $file_handle; # Cache the open file handle
+        }
+
+        if ($verbosity >= $PROGRESS) {
+            if ($progress_message{$addr}) {
+                print "$progress_message{$addr}\n";
+            }
+            else {
+                # If using a virtual file, say so.
+                print "Processing ", (-e $file)
+                                       ? $file
+                                       : "substitute $file",
+                                     "\n";
+            }
+        }
+
+
+        # Call any special handler for before the file.
+        &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
+
+        # Then the main handler
+        &{$handler{$addr}}($self);
+
+        # Then any special post-file handler.
+        &{$post_handler{$addr}}($self) if $post_handler{$addr};
+
+        # If any errors have been accumulated, output the counts (as the first
+        # error message in each class was output when it was encountered).
+        if ($errors{$addr}) {
+            my $total = 0;
+            my $types = 0;
+            foreach my $error (keys %{$errors{$addr}}) {
+                $total += $errors{$addr}->{$error};
+                delete $errors{$addr}->{$error};
+                $types++;
+            }
+            if ($total > 1) {
+                my $message
+                        = "A total of $total lines had errors in $file.  ";
+
+                $message .= ($types == 1)
+                            ? '(Only the first one was displayed.)'
+                            : '(Only the first of each type was displayed.)';
+                Carp::my_carp($message);
+            }
+        }
+
+        if (@{$missings{$addr}}) {
+            Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
+        }
+
+        # If a real file handle, close it.
+        close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
+                                                        ref $handle{$addr};
+        $handle{$addr} = "";   # Uses empty to indicate that has already seen
+                               # the file, as opposed to undef
+        return;
+    }
+
+    sub next_line {
+        # Sets $_ to be the next logical input line, if any.  Returns non-zero
+        # if such a line exists.  'logical' means that any lines that have
+        # been added via insert_lines() will be returned in $_ before the file
+        # is read again.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        # Here the file is open (or if the handle is not a ref, is an open
+        # 'virtual' file).  Get the next line; any inserted lines get priority
+        # over the file itself.
+        my $adjusted;
+
+        LINE:
+        while (1) { # Loop until find non-comment, non-empty line
+            #local $to_trace = 1 if main::DEBUG;
+            my $inserted_ref = shift @{$added_lines{$addr}};
+            if (defined $inserted_ref) {
+                ($adjusted, $_) = @{$inserted_ref};
+                trace $adjusted, $_ if main::DEBUG && $to_trace;
+                return 1 if $adjusted;
+            }
+            else {
+                last if ! ref $handle{$addr}; # Don't read unless is real file
+                last if ! defined ($_ = readline $handle{$addr});
+            }
+            chomp;
+            trace $_ if main::DEBUG && $to_trace;
+
+            # See if this line is the comment line that defines what property
+            # value that code points that are not listed in the file should
+            # have.  The format or existence of these lines is not guaranteed
+            # by Unicode since they are comments, but the documentation says
+            # that this was added for machine-readability, so probably won't
+            # change.  This works starting in Unicode Version 5.0.  They look
+            # like:
+            #
+            # @missing: 0000..10FFFF; Not_Reordered
+            # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
+            # @missing: 0000..10FFFF; ; NaN
+            #
+            # Save the line for a later get_missings() call.
+            if (/$missing_defaults_prefix/) {
+                if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
+                    $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
+                }
+                elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
+                    my @defaults = split /\s* ; \s*/x, $_;
+
+                    # The first field is the @missing, which ends in a
+                    # semi-colon, so can safely shift.
+                    shift @defaults;
+
+                    # Some of these lines may have empty field placeholders
+                    # which get in the way.  An example is:
+                    # @missing: 0000..10FFFF; ; NaN
+                    # Remove them.  Process starting from the top so the
+                    # splice doesn't affect things still to be looked at.
+                    for (my $i = @defaults - 1; $i >= 0; $i--) {
+                        next if $defaults[$i] ne "";
+                        splice @defaults, $i, 1;
+                    }
+
+                    # What's left should be just the property (maybe) and the
+                    # default.  Having only one element means it doesn't have
+                    # the property.
+                    my $default;
+                    my $property;
+                    if (@defaults >= 1) {
+                        if (@defaults == 1) {
+                            $default = $defaults[0];
+                        }
+                        else {
+                            $property = $defaults[0];
+                            $default = $defaults[1];
+                        }
+                    }
+
+                    if (@defaults < 1
+                        || @defaults > 2
+                        || ($default =~ /^</
+                            && $default !~ /^<code *point>$/i
+                            && $default !~ /^<none>$/i))
+                    {
+                        $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
+                    }
+                    else {
+
+                        # If the property is missing from the line, it should
+                        # be the one for the whole file
+                        $property = $property{$addr} if ! defined $property;
+
+                        # Change <none> to the null string, which is what it
+                        # really means.  If the default is the code point
+                        # itself, set it to <code point>, which is what
+                        # Unicode uses (but sometimes they've forgotten the
+                        # space)
+                        if ($default =~ /^<none>$/i) {
+                            $default = "";
+                        }
+                        elsif ($default =~ /^<code *point>$/i) {
+                            $default = $CODE_POINT;
+                        }
+
+                        # Store them as a sub-arrays with both components.
+                        push @{$missings{$addr}}, [ $default, $property ];
+                    }
+                }
+
+                # There is nothing for the caller to process on this comment
+                # line.
+                next;
+            }
+
+            # Remove comments and trailing space, and skip this line if the
+            # result is empty
+            s/#.*//;
+            s/\s+$//;
+            next if /^$/;
+
+            # Call any handlers for this line, and skip further processing of
+            # the line if the handler sets the line to null.
+            foreach my $sub_ref (@{$each_line_handler{$addr}}) {
+                &{$sub_ref}($self);
+                next LINE if /^$/;
+            }
+
+            # Here the line is ok.  return success.
+            return 1;
+        } # End of looping through lines.
+
+        # If there is an EOF handler, call it (only once) and if it generates
+        # more lines to process go back in the loop to handle them.
+        if ($eof_handler{$addr}) {
+            &{$eof_handler{$addr}}($self);
+            $eof_handler{$addr} = "";   # Currently only get one shot at it.
+            goto LINE if $added_lines{$addr};
+        }
+
+        # Return failure -- no more lines.
+        return 0;
+
+    }
+
+#   Not currently used, not fully tested.
+#    sub peek {
+#        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
+#        # record.  Not callable from an each_line_handler(), nor does it call
+#        # an each_line_handler() on the line.
+#
+#        my $self = shift;
+#        my $addr = main::objaddr $self;
+#
+#        foreach my $inserted_ref (@{$added_lines{$addr}}) {
+#            my ($adjusted, $line) = @{$inserted_ref};
+#            next if $adjusted;
+#
+#            # Remove comments and trailing space, and return a non-empty
+#            # resulting line
+#            $line =~ s/#.*//;
+#            $line =~ s/\s+$//;
+#            return $line if $line ne "";
+#        }
+#
+#        return if ! ref $handle{$addr}; # Don't read unless is real file
+#        while (1) { # Loop until find non-comment, non-empty line
+#            local $to_trace = 1 if main::DEBUG;
+#            trace $_ if main::DEBUG && $to_trace;
+#            return if ! defined (my $line = readline $handle{$addr});
+#            chomp $line;
+#            push @{$added_lines{$addr}}, [ 0, $line ];
+#
+#            $line =~ s/#.*//;
+#            $line =~ s/\s+$//;
+#            return $line if $line ne "";
+#        }
+#
+#        return;
+#    }
+
+
+    sub insert_lines {
+        # Lines can be inserted so that it looks like they were in the input
+        # file at the place it was when this routine is called.  See also
+        # insert_adjusted_lines().  Lines inserted via this routine go through
+        # any each_line_handler()
+
+        my $self = shift;
+
+        # Each inserted line is an array, with the first element being 0 to
+        # indicate that this line hasn't been adjusted, and needs to be
+        # processed.
+        push @{$added_lines{main::objaddr $self}}, map { [ 0, $_ ] } @_;
+        return;
+    }
+
+    sub insert_adjusted_lines {
+        # Lines can be inserted so that it looks like they were in the input
+        # file at the place it was when this routine is called.  See also
+        # insert_lines().  Lines inserted via this routine are already fully
+        # adjusted, ready to be processed; each_line_handler()s handlers will
+        # not be called.  This means this is not a completely general
+        # facility, as only the last each_line_handler on the stack should
+        # call this.  It could be made more general, by passing to each of the
+        # line_handlers their position on the stack, which they would pass on
+        # to this routine, and that would replace the boolean first element in
+        # the anonymous array pushed here, so that the next_line routine could
+        # use that to call only those handlers whose index is after it on the
+        # stack.  But this is overkill for what is needed now.
+
+        my $self = shift;
+        trace $_[0] if main::DEBUG && $to_trace;
+
+        # Each inserted line is an array, with the first element being 1 to
+        # indicate that this line has been adjusted
+        push @{$added_lines{main::objaddr $self}}, map { [ 1, $_ ] } @_;
+        return;
+    }
+
+    sub get_missings {
+        # Returns the stored up @missings lines' values, and clears the list.
+        # The values are in an array, consisting of the default in the first
+        # element, and the property in the 2nd.  However, since these lines
+        # can be stacked up, the return is an array of all these arrays.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        # If not accepting a list return, just return the first one.
+        return shift @{$missings{$addr}} unless wantarray;
+
+        my @return = @{$missings{$addr}};
+        undef @{$missings{$addr}};
+        return @return;
+    }
+
+    sub _insert_property_into_line {
+        # Add a property field to $_, if this file requires it.
+
+        my $property = $property{main::objaddr shift};
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        $_ =~ s/(;|$)/; $property$1/;
+        return;
+    }
+
+    sub carp_bad_line {
+        # Output consistent error messages, using either a generic one, or the
+        # one given by the optional parameter.  To avoid gazillions of the
+        # same message in case the syntax of a  file is way off, this routine
+        # only outputs the first instance of each message, incrementing a
+        # count so the totals can be output at the end of the file.
+
+        my $self = shift;
+        my $message = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        $message = 'Unexpected line' unless $message;
+
+        # No trailing punctuation so as to fit with our addenda.
+        $message =~ s/[.:;,]$//;
+
+        # If haven't seen this exact message before, output it now.  Otherwise
+        # increment the count of how many times it has occurred
+        unless ($errors{$addr}->{$message}) {
+            Carp::my_carp("$message in '$_' in "
+                            . $file{main::objaddr $self}
+                            . " at line $..  Skipping this line;");
+            $errors{$addr}->{$message} = 1;
+        }
+        else {
+            $errors{$addr}->{$message}++;
+        }
+
+        # Clear the line to prevent any further (meaningful) processing of it.
+        $_ = "";
+
+        return;
+    }
+} # End closure
+
+package Multi_Default;
+
+# Certain properties in early versions of Unicode had more than one possible
+# default for code points missing from the files.  In these cases, one
+# default applies to everything left over after all the others are applied,
+# and for each of the others, there is a description of which class of code
+# points applies to it.  This object helps implement this by storing the
+# defaults, and for all but that final default, an eval string that generates
+# the class that it applies to.
+
+
+{   # Closure
+
+    main::setup_package();
+
+    my %class_defaults;
+    # The defaults structure for the classes
+    main::set_access('class_defaults', \%class_defaults);
+
+    my %other_default;
+    # The default that applies to everything left over.
+    main::set_access('other_default', \%other_default, 'r');
+
+
+    sub new {
+        # The constructor is called with default => eval pairs, terminated by
+        # the left-over default. e.g.
+        # Multi_Default->new(
+        #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
+        #               -  0x200D',
+        #        'R' => 'some other expression that evaluates to code points',
+        #        .
+        #        .
+        #        .
+        #        'U'));
+
+        my $class = shift;
+
+        my $self = bless \do{my $anonymous_scalar}, $class;
+        my $addr = main::objaddr($self);
+
+        while (@_ > 1) {
+            my $default = shift;
+            my $eval = shift;
+            $class_defaults{$addr}->{$default} = $eval;
+        }
+
+        $other_default{$addr} = shift;
+
+        return $self;
+    }
+
+    sub get_next_defaults {
+        # Iterates and returns the next class of defaults.
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        return each %{$class_defaults{$addr}};
+    }
+}
+
+package Alias;
+
+# An alias is one of the names that a table goes by.  This class defines them
+# including some attributes.  Everything is currently setup in the
+# constructor.
+
+
+{   # Closure
+
+    main::setup_package();
+
+    my %name;
+    main::set_access('name', \%name, 'r');
+
+    my %loose_match;
+    # Determined by the constructor code if this name should match loosely or
+    # not.  The constructor parameters can override this, but it isn't fully
+    # implemented, as should have ability to override Unicode one's via
+    # something like a set_loose_match()
+    main::set_access('loose_match', \%loose_match, 'r');
+
+    my %make_pod_entry;
+    # Some aliases should not get their own entries because they are covered
+    # by a wild-card, and some we want to discourage use of.  Binary
+    main::set_access('make_pod_entry', \%make_pod_entry, 'r');
+
+    my %status;
+    # Aliases have a status, like deprecated, or even suppressed (which means
+    # they don't appear in documentation).  Enum
+    main::set_access('status', \%status, 'r');
+
+    my %externally_ok;
+    # Similarly, some aliases should not be considered as usable ones for
+    # external use, such as file names, or we don't want documentation to
+    # recommend them.  Boolean
+    main::set_access('externally_ok', \%externally_ok, 'r');
+
+    sub new {
+        my $class = shift;
+
+        my $self = bless \do { my $anonymous_scalar }, $class;
+        my $addr = main::objaddr($self);
+
+        $name{$addr} = shift;
+        $loose_match{$addr} = shift;
+        $make_pod_entry{$addr} = shift;
+        $externally_ok{$addr} = shift;
+        $status{$addr} = shift;
+
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        # Null names are never ok externally
+        $externally_ok{$addr} = 0 if $name{$addr} eq "";
+
+        return $self;
+    }
+}
+
+package Range;
+
+# A range is the basic unit for storing code points, and is described in the
+# comments at the beginning of the program.  Each range has a starting code
+# point; an ending code point (not less than the starting one); a value
+# that applies to every code point in between the two end-points, inclusive;
+# and an enum type that applies to the value.  The type is for the user's
+# convenience, and has no meaning here, except that a non-zero type is
+# considered to not obey the normal Unicode rules for having standard forms.
+#
+# The same structure is used for both map and match tables, even though in the
+# latter, the value (and hence type) is irrelevant and could be used as a
+# comment.  In map tables, the value is what all the code points in the range
+# map to.  Type 0 values have the standardized version of the value stored as
+# well, so as to not have to recalculate it a lot.
+
+sub trace { return main::trace(@_); }
+
+{   # Closure
+
+    main::setup_package();
+
+    my %start;
+    main::set_access('start', \%start, 'r', 's');
+
+    my %end;
+    main::set_access('end', \%end, 'r', 's');
+
+    my %value;
+    main::set_access('value', \%value, 'r');
+
+    my %type;
+    main::set_access('type', \%type, 'r');
+
+    my %standard_form;
+    # The value in internal standard form.  Defined only if the type is 0.
+    main::set_access('standard_form', \%standard_form);
+
+    # Note that if these fields change, the dump() method should as well
+
+    sub new {
+        return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
+        my $class = shift;
+
+        my $self = bless \do { my $anonymous_scalar }, $class;
+        my $addr = main::objaddr($self);
+
+        $start{$addr} = shift;
+        $end{$addr} = shift;
+
+        my %args = @_;
+
+        my $value = delete $args{'Value'};  # Can be 0
+        $value = "" unless defined $value;
+        $value{$addr} = $value;
+
+        $type{$addr} = delete $args{'Type'} || 0;
+
+        Carp::carp_extra_args(\%args) if main::DEBUG && %args;
+
+        if (! $type{$addr}) {
+            $standard_form{$addr} = main::standardize($value);
+        }
+
+        return $self;
+    }
+
+    use overload
+        fallback => 0,
+        qw("") => "_operator_stringify",
+        "." => \&main::_operator_dot,
+    ;
+
+    sub _operator_stringify {
+        my $self = shift;
+        my $addr = main::objaddr $self;
+
+        # Output it like '0041..0065 (value)'
+        my $return = sprintf("%04X", $start{$addr})
+                        .  '..'
+                        . sprintf("%04X", $end{$addr});
+        my $value = $value{$addr};
+        my $type = $type{$addr};
+        $return .= ' (';
+        $return .= "$value";
+        $return .= ", Type=$type" if $type != 0;
+        $return .= ')';
+
+        return $return;
+    }
+
+    sub standard_form {
+        # The standard form is the value itself if the standard form is
+        # undefined (that is if the value is special)
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        return $standard_form{$addr} if defined $standard_form{$addr};
+        return $value{$addr};
+    }
+
+    sub dump {
+        # Human, not machine readable.  For machine readable, comment out this
+        # entire routine and let the standard one take effect.
+        my $self = shift;
+        my $indent = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        my $return = $indent
+                    . sprintf("%04X", $start{$addr})
+                    . '..'
+                    . sprintf("%04X", $end{$addr})
+                    . " '$value{$addr}';";
+        if (! defined $standard_form{$addr}) {
+            $return .= "(type=$type{$addr})";
+        }
+        elsif ($standard_form{$addr} ne $value{$addr}) {
+            $return .= "(standard '$standard_form{$addr}')";
+        }
+        return $return;
+    }
+} # End closure
+
+package _Range_List_Base;
+
+# Base class for range lists.  A range list is simply an ordered list of
+# ranges, so that the ranges with the lowest starting numbers are first in it.
+#
+# When a new range is added that is adjacent to an existing range that has the
+# same value and type, it merges with it to form a larger range.
+#
+# Ranges generally do not overlap, except that there can be multiple entries
+# of single code point ranges.  This is because of NameAliases.txt.
+#
+# In this program, there is a standard value such that if two different
+# values, have the same standard value, they are considered equivalent.  This
+# value was chosen so that it gives correct results on Unicode data
+
+# There are a number of methods to manipulate range lists, and some operators
+# are overloaded to handle them.
+
+# Because of the slowness of pure Perl objaddr() on miniperl, and measurements
+# showing this package was using a lot of real time calculating that, the code
+# was changed to only calculate it once per call stack.  This is done by
+# consistently using the package variable $addr in routines, and only calling
+# objaddr() if it isn't defined, and setting that to be local, so that callees
+# will have it already.  It would be a good thing to change this. XXX
+
+sub trace { return main::trace(@_); }
+
+{ # Closure
+
+    our $addr;
+
+    main::setup_package();
+
+    my %ranges;
+    # The list of ranges
+    main::set_access('ranges', \%ranges, 'readable_array');
+
+    my %max;
+    # The highest code point in the list.  This was originally a method, but
+    # actual measurements said it was used a lot.
+    main::set_access('max', \%max, 'r');
+
+    my %each_range_iterator;
+    # Iterator position for each_range()
+    main::set_access('each_range_iterator', \%each_range_iterator);
+
+    my %owner_name_of;
+    # Name of parent this is attached to, if any.  Solely for better error
+    # messages.
+    main::set_access('owner_name_of', \%owner_name_of, 'p_r');
+
+    my %_search_ranges_cache;
+    # A cache of the previous result from _search_ranges(), for better
+    # performance
+    main::set_access('_search_ranges_cache', \%_search_ranges_cache);
+
+    sub new {
+        my $class = shift;
+        my %args = @_;
+
+        # Optional initialization data for the range list.
+        my $initialize = delete $args{'Initialize'};
+
+        my $self;
+
+        # Use _union() to initialize.  _union() returns an object of this
+        # class, which means that it will call this constructor recursively.
+        # But it won't have this $initialize parameter so that it won't
+        # infinitely loop on this.
+        return _union($class, $initialize, %args) if defined $initialize;
+
+        $self = bless \do { my $anonymous_scalar }, $class;
+        local $addr = main::objaddr($self);
+
+        # Optional parent object, only for debug info.
+        $owner_name_of{$addr} = delete $args{'Owner'};
+        $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
+
+        # Stringify, in case it is an object.
+        $owner_name_of{$addr} = "$owner_name_of{$addr}";
+
+        # This is used only for error messages, and so a colon is added
+        $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
+
+        Carp::carp_extra_args(\%args) if main::DEBUG && %args;
+
+        # Max is initialized to a negative value that isn't adjacent to 0,
+        # for simpler tests
+        $max{$addr} = -2;
+
+        $_search_ranges_cache{$addr} = 0;
+        $ranges{$addr} = [];
+
+        return $self;
+    }
+
+    use overload
+        fallback => 0,
+        qw("") => "_operator_stringify",
+        "." => \&main::_operator_dot,
+    ;
+
+    sub _operator_stringify {
+        my $self = shift;
+        local $addr = main::objaddr($self) if !defined $addr;
+
+        return "Range_List attached to '$owner_name_of{$addr}'"
+                                                if $owner_name_of{$addr};
+        return "anonymous Range_List " . \$self;
+    }
+
+    sub _union {
+        # Returns the union of the input code points.  It can be called as
+        # either a constructor or a method.  If called as a method, the result
+        # will be a new() instance of the calling object, containing the union
+        # of that object with the other parameter's code points;  if called as
+        # a constructor, the first parameter gives the class the new object
+        # should be, and the second parameter gives the code points to go into
+        # it.
+        # In either case, there are two parameters looked at by this routine;
+        # any additional parameters are passed to the new() constructor.
+        #
+        # The code points can come in the form of some object that contains
+        # ranges, and has a conventionally named method to access them; or
+        # they can be an array of individual code points (as integers); or
+        # just a single code point.
+        #
+        # If they are ranges, this routine doesn't make any effort to preserve
+        # the range values of one input over the other.  Therefore this base
+        # class should not allow _union to be called from other than
+        # initialization code, so as to prevent two tables from being added
+        # together where the range values matter.  The general form of this
+        # routine therefore belongs in a derived class, but it was moved here
+        # to avoid duplication of code.  The failure to overload this in this
+        # class keeps it safe.
+        #
+
+        my $self;
+        my @args;   # Arguments to pass to the constructor
+
+        my $class = shift;
+
+        # If a method call, will start the union with the object itself, and
+        # the class of the new object will be the same as self.
+        if (ref $class) {
+            $self = $class;
+            $class = ref $self;
+            push @args, $self;
+        }
+
+        # Add the other required parameter.
+        push @args, shift;
+        # Rest of parameters are passed on to the constructor
+
+        # Accumulate all records from both lists.
+        my @records;
+        for my $arg (@args) {
+            #local $to_trace = 0 if main::DEBUG;
+            trace "argument = $arg" if main::DEBUG && $to_trace;
+            if (! defined $arg) {
+                my $message = "";
+                if (defined $self) {
+                    $message .= $owner_name_of{main::objaddr $self};
+                }
+                Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
+                return;
+            }
+            $arg = [ $arg ] if ! ref $arg;
+            my $type = ref $arg;
+            if ($type eq 'ARRAY') {
+                foreach my $element (@$arg) {
+                    push @records, Range->new($element, $element);
+                }
+            }
+            elsif ($arg->isa('Range')) {
+                push @records, $arg;
+            }
+            elsif ($arg->can('ranges')) {
+                push @records, $arg->ranges;
+            }
+            else {
+                my $message = "";
+                if (defined $self) {
+                    $message .= $owner_name_of{main::objaddr $self};
+                }
+                Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
+                return;
+            }
+        }
+
+        # Sort with the range containing the lowest ordinal first, but if
+        # two ranges start at the same code point, sort with the bigger range
+        # of the two first, because it takes fewer cycles.
+        @records = sort { ($a->start <=> $b->start)
+                                      or
+                                    # if b is shorter than a, b->end will be
+                                    # less than a->end, and we want to select
+                                    # a, so want to return -1
+                                    ($b->end <=> $a->end)
+                                   } @records;
+
+        my $new = $class->new(@_);
+
+        # Fold in records so long as they add new information.
+        for my $set (@records) {
+            my $start = $set->start;
+            my $end   = $set->end;
+            my $value   = $set->value;
+            if ($start > $new->max) {
+                $new->_add_delete('+', $start, $end, $value);
+            }
+            elsif ($end > $new->max) {
+                $new->_add_delete('+', $new->max +1, $end, $value);
+            }
+        }
+
+        return $new;
+    }
+
+    sub range_count {        # Return the number of ranges in the range list
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        local $addr = main::objaddr($self) if ! defined $addr;
+
+        return scalar @{$ranges{$addr}};
+    }
+
+    sub min {
+        # Returns the minimum code point currently in the range list, or if
+        # the range list is empty, 2 beyond the max possible.  This is a
+        # method because used so rarely, that not worth saving between calls,
+        # and having to worry about changing it as ranges are added and
+        # deleted.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        local $addr = main::objaddr($self) if ! defined $addr;
+
+        # If the range list is empty, return a large value that isn't adjacent
+        # to any that could be in the range list, for simpler tests
+        return $LAST_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
+        return $ranges{$addr}->[0]->start;
+    }
+
+    sub contains {
+        # Boolean: Is argument in the range list?  If so returns $i such that:
+        #   range[$i]->end < $codepoint <= range[$i+1]->end
+        # which is one beyond what you want; this is so that the 0th range
+        # doesn't return false
+        my $self = shift;
+        my $codepoint = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        local $addr = main::objaddr $self if ! defined $addr;
+
+        my $i = $self->_search_ranges($codepoint);
+        return 0 unless defined $i;
+
+        # The search returns $i, such that
+        #   range[$i-1]->end < $codepoint <= range[$i]->end
+        # So is in the table if and only iff it is at least the start position
+        # of range $i.
+        return 0 if $ranges{$addr}->[$i]->start > $codepoint;
+        return $i + 1;
+    }
+
+    sub value_of {
+        # Returns the value associated with the code point, undef if none
+
+        my $self = shift;
+        my $codepoint = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        local $addr = main::objaddr $self if ! defined $addr;
+
+        my $i = $self->contains($codepoint);
+        return unless $i;
+
+        # contains() returns 1 beyond where we should look
+        return $ranges{$addr}->[$i-1]->value;
+    }
+
+    sub _search_ranges {
+        # Find the range in the list which contains a code point, or where it
+        # should go if were to add it.  That is, it returns $i, such that:
+        #   range[$i-1]->end < $codepoint <= range[$i]->end
+        # Returns undef if no such $i is possible (e.g. at end of table), or
+        # if there is an error.
+
+        my $self = shift;
+        my $code_point = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        local $addr = main::objaddr $self if ! defined $addr;
+
+        return if $code_point > $max{$addr};
+        my $r = $ranges{$addr};                # The current list of ranges
+        my $range_list_size = scalar @$r;
+        my $i;
+
+        use integer;        # want integer division
+
+        # Use the cached result as the starting guess for this one, because,
+        # an experiment on 5.1 showed that 90% of the time the cache was the
+        # same as the result on the next call (and 7% it was one less).
+        $i = $_search_ranges_cache{$addr};
+        $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
+                                            # from an intervening deletion
+        #local $to_trace = 1 if main::DEBUG;
+        trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
+        return $i if $code_point <= $r->[$i]->end
+                     && ($i == 0 || $r->[$i-1]->end < $code_point);
+
+        # Here the cache doesn't yield the correct $i.  Try adding 1.
+        if ($i < $range_list_size - 1
+            && $r->[$i]->end < $code_point &&
+            $code_point <= $r->[$i+1]->end)
+        {
+            $i++;
+            trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
+            $_search_ranges_cache{$addr} = $i;
+            return $i;
+        }
+
+        # Here, adding 1 also didn't work.  We do a binary search to
+        # find the correct position, starting with current $i
+        my $lower = 0;
+        my $upper = $range_list_size - 1;
+        while (1) {
+            trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
+
+            if ($code_point <= $r->[$i]->end) {
+
+                # Here we have met the upper constraint.  We can quit if we
+                # also meet the lower one.
+                last if $i == 0 || $r->[$i-1]->end < $code_point;
+
+                $upper = $i;        # Still too high.
+
+            }
+            else {
+
+                # Here, $r[$i]->end < $code_point, so look higher up.
+                $lower = $i;
+            }
+
+            # Split search domain in half to try again.
+            my $temp = ($upper + $lower) / 2;
+
+            # No point in continuing unless $i changes for next time
+            # in the loop.
+            if ($temp == $i) {
+
+                # We can't reach the highest element because of the averaging.
+                # So if one below the upper edge, force it there and try one
+                # more time.
+                if ($i == $range_list_size - 2) {
+
+                    trace "Forcing to upper edge" if main::DEBUG && $to_trace;
+                    $i = $range_list_size - 1;
+
+                    # Change $lower as well so if fails next time through,
+                    # taking the average will yield the same $i, and we will
+                    # quit with the error message just below.
+                    $lower = $i;
+                    next;
+                }
+                Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
+                return;
+            }
+            $i = $temp;
+        } # End of while loop
+
+        if (main::DEBUG && $to_trace) {
+            trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
+            trace "i=  [ $i ]", $r->[$i];
+            trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
+        }
+
+        # Here we have found the offset.  Cache it as a starting point for the
+        # next call.
+        $_search_ranges_cache{$addr} = $i;
+        return $i;
+    }
+
+    sub _add_delete {
+        # Add, replace or delete ranges to or from a list.  The $type
+        # parameter gives which:
+        #   '+' => insert or replace a range, returning a list of any changed
+        #          ranges.
+        #   '-' => delete a range, returning a list of any deleted ranges.
+        #
+        # The next three parameters give respectively the start, end, and
+        # value associated with the range.  'value' should be null unless the
+        # operation is '+';
+        #
+        # The range list is kept sorted so that the range with the lowest
+        # starting position is first in the list, and generally, adjacent
+        # ranges with the same values are merged into single larger one (see
+        # exceptions below).
+        #
+        # There are more parameters, all are key => value pairs:
+        #   Type    gives the type of the value.  It is only valid for '+'.
+        #           All ranges have types; if this parameter is omitted, 0 is
+        #           assumed.  Ranges with type 0 are assumed to obey the
+        #           Unicode rules for casing, etc; ranges with other types are
+        #           not.  Otherwise, the type is arbitrary, for the caller's
+        #           convenience, and looked at only by this routine to keep
+        #           adjacent ranges of different types from being merged into
+        #           a single larger range, and when Replace =>
+        #           $IF_NOT_EQUIVALENT is specified (see just below).
+        #   Replace  determines what to do if the range list already contains
+        #            ranges which coincide with all or portions of the input
+        #            range.  It is only valid for '+':
+        #       => $NO            means that the new value is not to replace
+        #                         any existing ones, but any empty gaps of the
+        #                         range list coinciding with the input range
+        #                         will be filled in with the new value.
+        #       => $UNCONDITIONALLY  means to replace the existing values with
+        #                         this one unconditionally.  However, if the
+        #                         new and old values are identical, the
+        #                         replacement is skipped to save cycles
+        #       => $IF_NOT_EQUIVALENT means to replace the existing values
+        #                         with this one if they are not equivalent.
+        #                         Ranges are equivalent if their types are the
+        #                         same, and they are the same string, or if
+        #                         both are type 0 ranges, if their Unicode
+        #                         standard forms are identical.  In this last
+        #                         case, the routine chooses the more "modern"
+        #                         one to use.  This is because some of the
+        #                         older files are formatted with values that
+        #                         are, for example, ALL CAPs, whereas the
+        #                         derived files have a more modern style,
+        #                         which looks better.  By looking for this
+        #                         style when the pre-existing and replacement
+        #                         standard forms are the same, we can move to
+        #                         the modern style
+        #       => $MULTIPLE      means that if this range duplicates an
+        #                         existing one, but has a different value,
+        #                         don't replace the existing one, but insert
+        #                         this, one so that the same range can occur
+        #                         multiple times.
+        #       => anything else  is the same as => $IF_NOT_EQUIVALENT
+        #
+        # "same value" means identical for type-0 ranges, and it means having
+        # the same standard forms for non-type-0 ranges.
+
+        return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
+
+        my $self = shift;
+        my $operation = shift;   # '+' for add/replace; '-' for delete;
+        my $start = shift;
+        my $end   = shift;
+        my $value = shift;
+
+        my %args = @_;
+
+        $value = "" if not defined $value;        # warning: $value can be "0"
+
+        my $replace = delete $args{'Replace'};
+        $replace = $IF_NOT_EQUIVALENT unless defined $replace;
+
+        my $type = delete $args{'Type'};
+        $type = 0 unless defined $type;
+
+        Carp::carp_extra_args(\%args) if main::DEBUG && %args;
+
+        local $addr = main::objaddr($self) if ! defined $addr;
+
+        if ($operation ne '+' && $operation ne '-') {
+            Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
+            return;
+        }
+        unless (defined $start && defined $end) {
+            Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
+            return;
+        }
+        unless ($end >= $start) {
+            Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
+            return;
+        }
+        #local $to_trace = 1 if main::DEBUG;
+
+        if ($operation eq '-') {
+            if ($replace != $IF_NOT_EQUIVALENT) {
+                Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
+                $replace = $IF_NOT_EQUIVALENT;
+            }
+            if ($type) {
+                Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
+                $type = 0;
+            }
+            if ($value ne "") {
+                Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
+                $value = "";
+            }
+        }
+
+        my $r = $ranges{$addr};               # The current list of ranges
+        my $range_list_size = scalar @$r;     # And its size
+        my $max = $max{$addr};                # The current high code point in
+                                              # the list of ranges
+
+        # Do a special case requiring fewer machine cycles when the new range
+        # starts after the current highest point.  The Unicode input data is
+        # structured so this is common.
+        if ($start > $max) {
+
+            trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
+            return if $operation eq '-'; # Deleting a non-existing range is a
+                                         # no-op
+
+            # If the new range doesn't logically extend the current final one
+            # in the range list, create a new range at the end of the range
+            # list.  (max cleverly is initialized to a negative number not
+            # adjacent to 0 if the range list is empty, so even adding a range
+            # to an empty range list starting at 0 will have this 'if'
+            # succeed.)
+            if ($start > $max + 1        # non-adjacent means can't extend.
+                || @{$r}[-1]->value ne $value # values differ, can't extend.
+                || @{$r}[-1]->type != $type # types differ, can't extend.
+            ) {
+                push @$r, Range->new($start, $end,
+                                     Value => $value,
+                                     Type => $type);
+            }
+            else {
+
+                # Here, the new range starts just after the current highest in
+                # the range list, and they have the same type and value.
+                # Extend the current range to incorporate the new one.
+                @{$r}[-1]->set_end($end);
+            }
+
+            # This becomes the new maximum.
+            $max{$addr} = $end;
+
+            return;
+        }
+        #local $to_trace = 0 if main::DEBUG;
+
+        trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
+
+        # Here, the input range isn't after the whole rest of the range list.
+        # Most likely 'splice' will be needed.  The rest of the routine finds
+        # the needed splice parameters, and if necessary, does the splice.
+        # First, find the offset parameter needed by the splice function for
+        # the input range.  Note that the input range may span multiple
+        # existing ones, but we'll worry about that later.  For now, just find
+        # the beginning.  If the input range is to be inserted starting in a
+        # position not currently in the range list, it must (obviously) come
+        # just after the range below it, and just before the range above it.
+        # Slightly less obviously, it will occupy the position currently
+        # occupied by the range that is to come after it.  More formally, we
+        # are looking for the position, $i, in the array of ranges, such that:
+        #
+        # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
+        #
+        # (The ordered relationships within existing ranges are also shown in
+        # the equation above).  However, if the start of the input range is
+        # within an existing range, the splice offset should point to that
+        # existing range's position in the list; that is $i satisfies a
+        # somewhat different equation, namely:
+        #
+        #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
+        #
+        # More briefly, $start can come before or after r[$i]->start, and at
+        # this point, we don't know which it will be.  However, these
+        # two equations share these constraints:
+        #
+        #   r[$i-1]->end < $start <= r[$i]->end
+        #
+        # And that is good enough to find $i.
+
+        my $i = $self->_search_ranges($start);
+        if (! defined $i) {
+            Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
+            return;
+        }
+
+        # The search function returns $i such that:
+        #
+        # r[$i-1]->end < $start <= r[$i]->end
+        #
+        # That means that $i points to the first range in the range list
+        # that could possibly be affected by this operation.  We still don't
+        # know if the start of the input range is within r[$i], or if it
+        # points to empty space between r[$i-1] and r[$i].
+        trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
+
+        # Special case the insertion of data that is not to replace any
+        # existing data.
+        if ($replace == $NO) {  # If $NO, has to be operation '+'
+            #local $to_trace = 1 if main::DEBUG;
+            trace "Doesn't replace" if main::DEBUG && $to_trace;
+
+            # Here, the new range is to take effect only on those code points
+            # that aren't already in an existing range.  This can be done by
+            # looking through the existing range list and finding the gaps in
+            # the ranges that this new range affects, and then calling this
+            # function recursively on each of those gaps, leaving untouched
+            # anything already in the list.  Gather up a list of the changed
+            # gaps first so that changes to the internal state as new ranges
+            # are added won't be a problem.
+            my @gap_list;
+
+            # First, if the starting point of the input range is outside an
+            # existing one, there is a gap from there to the beginning of the
+            # existing range -- add a span to fill the part that this new
+            # range occupies
+            if ($start < $r->[$i]->start) {
+                push @gap_list, Range->new($start,
+                                           main::min($end,
+                                                     $r->[$i]->start - 1),
+                                           Type => $type);
+                trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
+            }
+
+            # Then look through the range list for other gaps until we reach
+            # the highest range affected by the input one.
+            my $j;
+            for ($j = $i+1; $j < $range_list_size; $j++) {
+                trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
+                last if $end < $r->[$j]->start;
+
+                # If there is a gap between when this range starts and the
+                # previous one ends, add a span to fill it.  Note that just
+                # because there are two ranges doesn't mean there is a
+                # non-zero gap between them.  It could be that they have
+                # different values or types
+                if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
+                    push @gap_list,
+                        Range->new($r->[$j-1]->end + 1,
+                                   $r->[$j]->start - 1,
+                                   Type => $type);
+                    trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
+                }
+            }
+
+            # Here, we have either found an existing range in the range list,
+            # beyond the area affected by the input one, or we fell off the
+            # end of the loop because the input range affects the whole rest
+            # of the range list.  In either case, $j is 1 higher than the
+            # highest affected range.  If $j == $i, it means that there are no
+            # affected ranges, that the entire insertion is in the gap between
+            # r[$i-1], and r[$i], which we already have taken care of before
+            # the loop.
+            # On the other hand, if there are affected ranges, it might be
+            # that there is a gap that needs filling after the final such
+            # range to the end of the input range
+            if ($r->[$j-1]->end < $end) {
+                    push @gap_list, Range->new(main::max($start,
+                                                         $r->[$j-1]->end + 1),
+                                               $end,
+                                               Type => $type);
+                    trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
+            }
+
+            # Call recursively to fill in all the gaps.
+            foreach my $gap (@gap_list) {
+                $self->_add_delete($operation,
+                                   $gap->start,
+                                   $gap->end,
+                                   $value,
+                                   Type => $type);
+            }
+
+            return;
+        }
+
+        # Here, we have taken care of the case where $replace is $NO, which
+        # means that whatever action we now take is done unconditionally.  It
+        # still could be that this call will result in a no-op, if duplicates
+        # aren't allowed, and we are inserting a range that merely duplicates
+        # data already in the range list; or also if deleting a non-existent
+        # range.
+        # $i still points to the first potential affected range.  Now find the
+        # highest range affected, which will determine the length parameter to
+        # splice.  (The input range can span multiple existing ones.)  While
+        # we are looking through the range list, see also if this is an
+        # insertion that will change the values of at least one of the
+        # affected ranges.  We don't need to do this check unless this is an
+        # insertion of non-multiples, and also since this is a boolean, we
+        # don't need to do it if have already determined that it will make a
+        # change; just unconditionally change them.  $cdm is created to be 1
+        # if either of these is true. (The 'c' in the name comes from below)
+        my $cdm = ($operation eq '-' || $replace == $MULTIPLE);
+        my $j;        # This will point to the highest affected range
+
+        # For non-zero types, the standard form is the value itself;
+        my $standard_form = ($type) ? $value : main::standardize($value);
+
+        for ($j = $i; $j < $range_list_size; $j++) {
+            trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
+
+            # If find a range that it doesn't overlap into, we can stop
+            # searching
+            last if $end < $r->[$j]->start;
+
+            # Here, overlaps the range at $j.  If the value's don't match,
+            # and this is supposedly an insertion, it becomes a change
+            # instead.  This is what the 'c' stands for in $cdm.
+            if (! $cdm) {
+                if ($r->[$j]->standard_form ne $standard_form) {
+                    $cdm = 1;
+                }
+                else {
+
+                    # Here, the two values are essentially the same.  If the
+                    # two are actually identical, replacing wouldn't change
+                    # anything so skip it.
+                    my $pre_existing = $r->[$j]->value;
+                    if ($pre_existing ne $value) {
+
+                        # Here the new and old standardized values are the
+                        # same, but the non-standardized values aren't.  If
+                        # replacing unconditionally, then replace
+                        if( $replace == $UNCONDITIONALLY) {
+                            $cdm = 1;
+                        }
+                        else {
+
+                            # Here, are replacing conditionally.  Decide to
+                            # replace or not based on which appears to look
+                            # the "nicest".  If one is mixed case and the
+                            # other isn't, choose the mixed case one.
+                            my $new_mixed = $value =~ /[A-Z]/
+                                            && $value =~ /[a-z]/;
+                            my $old_mixed = $pre_existing =~ /[A-Z]/
+                                            && $pre_existing =~ /[a-z]/;
+
+                            if ($old_mixed != $new_mixed) {
+                                $cdm = 1 if $new_mixed;
+                                if (main::DEBUG && $to_trace) {
+                                    if ($cdm) {
+                                        trace "Replacing $pre_existing with $value";
+                                    }
+                                    else {
+                                        trace "Retaining $pre_existing over $value";
+                                    }
+                                }
+                            }
+                            else {
+
+                                # Here casing wasn't different between the two.
+                                # If one has hyphens or underscores and the
+                                # other doesn't, choose the one with the
+                                # punctuation.
+                                my $new_punct = $value =~ /[-_]/;
+                                my $old_punct = $pre_existing =~ /[-_]/;
+
+                                if ($old_punct != $new_punct) {
+                                    $cdm = 1 if $new_punct;
+                                    if (main::DEBUG && $to_trace) {
+                                        if ($cdm) {
+                                            trace "Replacing $pre_existing with $value";
+                                        }
+                                        else {
+                                            trace "Retaining $pre_existing over $value";
+                                        }
+                                    }
+                                }   # else existing one is just as "good";
+                                    # retain it to save cycles.
+                            }
+                        }
+                    }
+                }
+            }
+        } # End of loop looking for highest affected range.
+
+        # Here, $j points to one beyond the highest range that this insertion
+        # affects (hence to beyond the range list if that range is the final
+        # one in the range list).
+
+        # The splice length is all the affected ranges.  Get it before
+        # subtracting, for efficiency, so we don't have to later add 1.
+        my $length = $j - $i;
+
+        $j--;        # $j now points to the highest affected range.
+        trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
+
+        # If inserting a multiple record, this is where it goes, after all the
+        # existing ones for this range.  This implies an insertion, and no
+        # change to any existing ranges.  Note that $j can be -1 if this new
+        # range doesn't actually duplicate any existing, and comes at the
+        # beginning of the list, in which case we can handle it like any other
+        # insertion, and is easier to do so.
+        if ($replace == $MULTIPLE && $j >= 0) {
+
+            # This restriction could be remedied with a little extra work, but
+            # it won't hopefully ever be necessary
+            if ($r->[$j]->start != $r->[$j]->end) {
+                Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple when the other range ($r->[$j]) contains more than one code point.  No action taken.");
+                return;
+            }
+
+            # Don't add an exact duplicate, as it isn't really a multiple
+            return if $value eq $r->[$j]->value && $type eq $r->[$j]->type;
+
+            trace "Adding multiple record at $j+1 with $start..$end, $value" if main::DEBUG && $to_trace;
+            my @return = splice @$r,
+                                $j+1,
+                                0,
+                                Range->new($start,
+                                           $end,
+                                           Value => $value,
+                                           Type => $type);
+            if (main::DEBUG && $to_trace) {
+                trace "After splice:";
+                trace 'j-2=[', $j-2, ']', $r->[$j-2] if $j >= 2;
+                trace 'j-1=[', $j-1, ']', $r->[$j-1] if $j >= 1;
+                trace "j  =[", $j, "]", $r->[$j] if $j >= 0;
+                trace 'j+1=[', $j+1, ']', $r->[$j+1] if $j < @$r - 1;
+                trace 'j+2=[', $j+2, ']', $r->[$j+2] if $j < @$r - 2;
+                trace 'j+3=[', $j+3, ']', $r->[$j+3] if $j < @$r - 3;
+            }
+            return @return;
+        }
+
+        # Here, have taken care of $NO and $MULTIPLE replaces.
+        # $j points to the highest affected range.  But it can be < $i or even
+        # -1.  These happen only if the insertion is entirely in the gap
+        # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
+        # above exited first time through with $end < $r->[$i]->start.  (And
+        # then we subtracted one from j)  This implies also that $start <
+        # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
+        # $start, so the entire input range is in the gap.
+        if ($j < $i) {
+
+            # Here the entire input range is in the gap before $i.
+
+            if (main::DEBUG && $to_trace) {
+                if ($i) {
+                    trace "Entire range is between $r->[$i-1] and $r->[$i]";
+                }
+                else {
+                    trace "Entire range is before $r->[$i]";
+                }
+            }
+            return if $operation ne '+'; # Deletion of a non-existent range is
+                                         # a no-op
+        }
+        else {
+
+            # Here the entire input range is not in the gap before $i.  There
+            # is an affected one, and $j points to the highest such one.
+
+            # At this point, here is the situation:
+            # This is not an insertion of a multiple, nor of tentative ($NO)
+            # data.
+            #   $i  points to the first element in the current range list that
+            #            may be affected by this operation.  In fact, we know
+            #            that the range at $i is affected because we are in
+            #            the else branch of this 'if'
+            #   $j  points to the highest affected range.
+            # In other words,
+            #   r[$i-1]->end < $start <= r[$i]->end
+            # And:
+            #   r[$i-1]->end < $start <= $end <= r[$j]->end
+            #
+            # Also:
+            #   $cdm is a boolean which is set true if and only if this is a
+            #        change or deletion (multiple was handled above).  In
+            #        other words, it could be renamed to be just $cd.
+
+            # We now have enough information to decide if this call is a no-op
+            # or not.  It is a no-op if it is a deletion of a non-existent
+            # range, or an insertion of already existing data.
+
+            if (main::DEBUG && $to_trace && ! $cdm
+                                         && $i == $j
+                                         && $start >= $r->[$i]->start)
+            {
+                    trace "no-op";
+            }
+            return if ! $cdm      # change or delete => not no-op
+                      && $i == $j # more than one affected range => not no-op
+
+                      # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
+                      # Further, $start and/or $end is >= r[$i]->start
+                      # The test below hence guarantees that
+                      #     r[$i]->start < $start <= $end <= r[$i]->end
+                      # This means the input range is contained entirely in
+                      # the one at $i, so is a no-op
+                      && $start >= $r->[$i]->start;
+        }
+
+        # Here, we know that some action will have to be taken.  We have
+        # calculated the offset and length (though adjustments may be needed)
+        # for the splice.  Now start constructing the replacement list.
+        my @replacement;
+        my $splice_start = $i;
+
+        my $extends_below;
+        my $extends_above;
+
+        # See if should extend any adjacent ranges.
+        if ($operation eq '-') { # Don't extend deletions
+            $extends_below = $extends_above = 0;
+        }
+        else {  # Here, should extend any adjacent ranges.  See if there are
+                # any.
+            $extends_below = ($i > 0
+                            # can't extend unless adjacent
+                            && $r->[$i-1]->end == $start -1
+                            # can't extend unless are same standard value
+                            && $r->[$i-1]->standard_form eq $standard_form
+                            # can't extend unless share type
+                            && $r->[$i-1]->type == $type);
+            $extends_above = ($j+1 < $range_list_size
+                            && $r->[$j+1]->start == $end +1
+                            && $r->[$j+1]->standard_form eq $standard_form
+                            && $r->[$j-1]->type == $type);
+        }
+        if ($extends_below && $extends_above) { # Adds to both
+            $splice_start--;     # start replace at element below
+            $length += 2;        # will replace on both sides
+            trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
+
+            # The result will fill in any gap, replacing both sides, and
+            # create one large range.
+            @replacement = Range->new($r->[$i-1]->start,
+                                      $r->[$j+1]->end,
+                                      Value => $value,
+                                      Type => $type);
+        }
+        else {
+
+            # Here we know that the result won't just be the conglomeration of
+            # a new range with both its adjacent neighbors.  But it could
+            # extend one of them.
+
+            if ($extends_below) {
+
+                # Here the new element adds to the one below, but not to the
+                # one above.  If inserting, and only to that one range,  can
+                # just change its ending to include the new one.
+                if ($length == 0 && ! $cdm) {
+                    $r->[$i-1]->set_end($end);
+                    trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
+                    return;
+                }
+                else {
+                    trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
+                    $splice_start--;        # start replace at element below
+                    $length++;              # will replace the element below
+                    $start = $r->[$i-1]->start;
+                }
+            }
+            elsif ($extends_above) {
+
+                # Here the new element adds to the one above, but not below.
+                # Mirror the code above
+                if ($length == 0 && ! $cdm) {
+                    $r->[$j+1]->set_start($start);
+                    trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
+                    return;
+                }
+                else {
+                    trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
+                    $length++;        # will replace the element above
+                    $end = $r->[$j+1]->end;
+                }
+            }
+
+            trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
+
+            # Finally, here we know there will have to be a splice.
+            # If the change or delete affects only the highest portion of the
+            # first affected range, the range will have to be split.  The
+            # splice will remove the whole range, but will replace it by a new
+            # range containing just the unaffected part.  So, in this case,
+            # add to the replacement list just this unaffected portion.
+            if (! $extends_below
+                && $start > $r->[$i]->start && $start <= $r->[$i]->end)
+            {
+                push @replacement,
+                    Range->new($r->[$i]->start,
+                               $start - 1,
+                               Value => $r->[$i]->value,
+                               Type => $r->[$i]->type);
+            }
+
+            # In the case of an insert or change, but not a delete, we have to
+            # put in the new stuff;  this comes next.
+            if ($operation eq '+') {
+                push @replacement, Range->new($start,
+                                              $end,
+                                              Value => $value,
+                                              Type => $type);
+            }
+
+            trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
+            #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
+
+            # And finally, if we're changing or deleting only a portion of the
+            # highest affected range, it must be split, as the lowest one was.
+            if (! $extends_above
+                && $j >= 0  # Remember that j can be -1 if before first
+                            # current element
+                && $end >= $r->[$j]->start
+                && $end < $r->[$j]->end)
+            {
+                push @replacement,
+                    Range->new($end + 1,
+                               $r->[$j]->end,
+                               Value => $r->[$j]->value,
+                               Type => $r->[$j]->type);
+            }
+        }
+
+        # And do the splice, as calculated above
+        if (main::DEBUG && $to_trace) {
+            trace "replacing $length element(s) at $i with ";
+            foreach my $replacement (@replacement) {
+                trace "    $replacement";
+            }
+            trace "Before splice:";
+            trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
+            trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
+            trace "i  =[", $i, "]", $r->[$i];
+            trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
+            trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
+        }
+
+        my @return = splice @$r, $splice_start, $length, @replacement;
+
+        if (main::DEBUG && $to_trace) {
+            trace "After splice:";
+            trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
+            trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
+            trace "i  =[", $i, "]", $r->[$i];
+            trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
+            trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
+            trace "removed @return";
+        }
+
+        # An actual deletion could have changed the maximum in the list.
+        # There was no deletion if the splice didn't return something, but
+        # otherwise recalculate it.  This is done too rarely to worry about
+        # performance.
+        if ($operation eq '-' && @return) {
+            $max{$addr} = $r->[-1]->end;
+        }
+        return @return;
+    }
+
+    sub reset_each_range {  # reset the iterator for each_range();
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        local $addr = main::objaddr $self if ! defined $addr;
+
+        undef $each_range_iterator{$addr};
+        return;
+    }
+
+    sub each_range {
+        # Iterate over each range in a range list.  Results are undefined if
+        # the range list is changed during the iteration.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        local $addr = main::objaddr($self) if ! defined $addr;
+
+        return if $self->is_empty;
+
+        $each_range_iterator{$addr} = -1
+                                if ! defined $each_range_iterator{$addr};
+        $each_range_iterator{$addr}++;
+        return $ranges{$addr}->[$each_range_iterator{$addr}]
+                        if $each_range_iterator{$addr} < @{$ranges{$addr}};
+        undef $each_range_iterator{$addr};
+        return;
+    }
+
+    sub count {        # Returns count of code points in range list
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        local $addr = main::objaddr($self) if ! defined $addr;
+
+        my $count = 0;
+        foreach my $range (@{$ranges{$addr}}) {
+            $count += $range->end - $range->start + 1;
+        }
+        return $count;
+    }
+
+    sub delete_range {    # Delete a range
+        my $self = shift;
+        my $start = shift;
+        my $end = shift;
+
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        return $self->_add_delete('-', $start, $end, "");
+    }
+
+    sub is_empty { # Returns boolean as to if a range list is empty
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        local $addr = main::objaddr($self) if ! defined $addr;
+        return scalar @{$ranges{$addr}} == 0;
+    }
+
+    sub hash {
+        # Quickly returns a scalar suitable for separating tables into
+        # buckets, i.e. it is a hash function of the contents of a table, so
+        # there are relatively few conflicts.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        local $addr = main::objaddr($self) if ! defined $addr;
+
+        # These are quickly computable.  Return looks like 'min..max;count'
+        return $self->min . "..$max{$addr};" . scalar @{$ranges{$addr}};
+    }
+} # End closure for _Range_List_Base
+
+package Range_List;
+use base '_Range_List_Base';
+
+# A Range_List is a range list for match tables; i.e. the range values are
+# not significant.  Thus a number of operations can be safely added to it,
+# such as inversion, intersection.  Note that union is also an unsafe
+# operation when range values are cared about, and that method is in the base
+# class, not here.  But things are set up so that that method is callable only
+# during initialization.  Only in this derived class, is there an operation
+# that combines two tables.  A Range_Map can thus be used to initialize a
+# Range_List, and its mappings will be in the list, but are not significant to
+# this class.
+
+sub trace { return main::trace(@_); }
+
+{ # Closure
+
+    use overload
+        fallback => 0,
+        '+' => sub { my $self = shift;
+                    my $other = shift;
+
+                    return $self->_union($other)
+                },
+        '&' => sub { my $self = shift;
+                    my $other = shift;
+
+                    return $self->_intersect($other, 0);
+                },
+        '~' => "_invert",
+        '-' => "_subtract",
+    ;
+
+    sub _invert {
+        # Returns a new Range_List that gives all code points not in $self.
+
+        my $self = shift;
+
+        my $new = Range_List->new;
+
+        # Go through each range in the table, finding the gaps between them
+        my $max = -1;   # Set so no gap before range beginning at 0
+        for my $range ($self->ranges) {
+            my $start = $range->start;
+            my $end   = $range->end;
+
+            # If there is a gap before this range, the inverse will contain
+            # that gap.
+            if ($start > $max + 1) {
+                $new->add_range($max + 1, $start - 1);
+            }
+            $max = $end;
+        }
+
+        # And finally, add the gap from the end of the table to the max
+        # possible code point
+        if ($max < $LAST_UNICODE_CODEPOINT) {
+            $new->add_range($max + 1, $LAST_UNICODE_CODEPOINT);
+        }
+        return $new;
+    }
+
+    sub _subtract {
+        # Returns a new Range_List with the argument deleted from it.  The
+        # argument can be a single code point, a range, or something that has
+        # a range, with the _range_list() method on it returning them
+
+        my $self = shift;
+        my $other = shift;
+        my $reversed = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        if ($reversed) {
+            Carp::my_carp_bug("Can't cope with a "
+             .  __PACKAGE__
+             . " being the second parameter in a '-'.  Subtraction ignored.");
+            return $self;
+        }
+
+        my $new = Range_List->new(Initialize => $self);
+
+        if (! ref $other) { # Single code point
+            $new->delete_range($other, $other);
+        }
+        elsif ($other->isa('Range')) {
+            $new->delete_range($other->start, $other->end);
+        }
+        elsif ($other->can('_range_list')) {
+            foreach my $range ($other->_range_list->ranges) {
+                $new->delete_range($range->start, $range->end);
+            }
+        }
+        else {
+            Carp::my_carp_bug("Can't cope with a "
+                        . ref($other)
+                        . " argument to '-'.  Subtraction ignored."
+                        );
+            return $self;
+        }
+
+        return $new;
+    }
+
+    sub _intersect {
+        # Returns either a boolean giving whether the two inputs' range lists
+        # intersect (overlap), or a new Range_List containing the intersection
+        # of the two lists.  The optional final parameter being true indicates
+        # to do the check instead of the intersection.
+
+        my $a_object = shift;
+        my $b_object = shift;
+        my $check_if_overlapping = shift;
+        $check_if_overlapping = 0 unless defined $check_if_overlapping;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        if (! defined $b_object) {
+            my $message = "";
+            $message .= $a_object->_owner_name_of if defined $a_object;
+            Carp::my_carp_bug($message .= "Called with undefined value.  Intersection not done.");
+            return;
+        }
+
+        # a & b = !(!a | !b), or in our terminology = ~ ( ~a + -b )
+        # Thus the intersection could be much more simply be written:
+        #   return ~(~$a_object + ~$b_object);
+        # But, this is slower, and when taking the inverse of a large
+        # range_size_1 table, back when such tables were always stored that
+        # way, it became prohibitively slow, hence the code was changed to the
+        # below
+
+        if ($b_object->isa('Range')) {
+            $b_object = Range_List->new(Initialize => $b_object,
+                                        Owner => $a_object->_owner_name_of);
+        }
+        $b_object = $b_object->_range_list if $b_object->can('_range_list');
+
+        my @a_ranges = $a_object->ranges;
+        my @b_ranges = $b_object->ranges;
+
+        #local $to_trace = 1 if main::DEBUG;
+        trace "intersecting $a_object with ", scalar @a_ranges, "ranges and $b_object with", scalar @b_ranges, " ranges" if main::DEBUG && $to_trace;
+
+        # Start with the first range in each list
+        my $a_i = 0;
+        my $range_a = $a_ranges[$a_i];
+        my $b_i = 0;
+        my $range_b = $b_ranges[$b_i];
+
+        my $new = __PACKAGE__->new(Owner => $a_object->_owner_name_of)
+                                                if ! $check_if_overlapping;
+
+        # If either list is empty, there is no intersection and no overlap
+        if (! defined $range_a || ! defined $range_b) {
+            return $check_if_overlapping ? 0 : $new;
+        }
+        trace "range_a[$a_i]=$range_a; range_b[$b_i]=$range_b" if main::DEBUG && $to_trace;
+
+        # Otherwise, must calculate the intersection/overlap.  Start with the
+        # very first code point in each list
+        my $a = $range_a->start;
+        my $b = $range_b->start;
+
+        # Loop through all the ranges of each list; in each iteration, $a and
+        # $b are the current code points in their respective lists
+        while (1) {
+
+            # If $a and $b are the same code point, ...
+            if ($a == $b) {
+
+                # it means the lists overlap.  If just checking for overlap
+                # know the answer now,
+                return 1 if $check_if_overlapping;
+
+                # The intersection includes this code point plus anything else
+                # common to both current ranges.
+                my $start = $a;
+                my $end = main::min($range_a->end, $range_b->end);
+                if (! $check_if_overlapping) {
+                    trace "adding intersection range ", sprintf("%04X", $start) . ".." . sprintf("%04X", $end) if main::DEBUG && $to_trace;
+                    $new->add_range($start, $end);
+                }
+
+                # Skip ahead to the end of the current intersect
+                $a = $b = $end;
+
+                # If the current intersect ends at the end of either range (as
+                # it must for at least one of them), the next possible one
+                # will be the beginning code point in it's list's next range.
+                if ($a == $range_a->end) {
+                    $range_a = $a_ranges[++$a_i];
+                    last unless defined $range_a;
+                    $a = $range_a->start;
+                }
+                if ($b == $range_b->end) {
+                    $range_b = $b_ranges[++$b_i];
+                    last unless defined $range_b;
+                    $b = $range_b->start;
+                }
+
+                trace "range_a[$a_i]=$range_a; range_b[$b_i]=$range_b" if main::DEBUG && $to_trace;
+            }
+            elsif ($a < $b) {
+
+                # Not equal, but if the range containing $a encompasses $b,
+                # change $a to be the middle of the range where it does equal
+                # $b, so the next iteration will get the intersection
+                if ($range_a->end >= $b) {
+                    $a = $b;
+                }
+                else {
+
+                    # Here, the current range containing $a is entirely below
+                    # $b.  Go try to find a range that could contain $b.
+                    $a_i = $a_object->_search_ranges($b);
+
+                    # If no range found, quit.
+                    last unless defined $a_i;
+
+                    # The search returns $a_i, such that
+                    #   range_a[$a_i-1]->end < $b <= range_a[$a_i]->end
+                    # Set $a to the beginning of this new range, and repeat.
+                    $range_a = $a_ranges[$a_i];
+                    $a = $range_a->start;
+                }
+            }
+            else { # Here, $b < $a.
+
+                # Mirror image code to the leg just above
+                if ($range_b->end >= $a) {
+                    $b = $a;
+                }
+                else {
+                    $b_i = $b_object->_search_ranges($a);
+                    last unless defined $b_i;
+                    $range_b = $b_ranges[$b_i];
+                    $b = $range_b->start;
+                }
+            }
+        } # End of looping through ranges.
+
+        # Intersection fully computed, or now know that there is no overlap
+        return $check_if_overlapping ? 0 : $new;
+    }
+
+    sub overlaps {
+        # Returns boolean giving whether the two arguments overlap somewhere
+
+        my $self = shift;
+        my $other = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        return $self->_intersect($other, 1);
+    }
+
+    sub add_range {
+        # Add a range to the list.
+
+        my $self = shift;
+        my $start = shift;
+        my $end = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        return $self->_add_delete('+', $start, $end, "");
+    }
+
+    my $non_ASCII = (ord('A') == 65);   # Assumes test on same platform
+
+    sub is_code_point_usable {
+        # This used only for making the test script.  See if the input
+        # proposed trial code point is one that Perl will handle.  If second
+        # parameter is 0, it won't select some code points for various
+        # reasons, noted below.
+
+        my $code = shift;
+        my $try_hard = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        return 0 if $code < 0;                # Never use a negative
+
+        # For non-ASCII, we shun the characters that don't have Perl encoding-
+        # independent symbols for them.  'A' is such a symbol, so is "\n".
+        # Note, this program hopefully will work on 5.8 Perls, and \v is not
+        # such a symbol in them.
+        return $try_hard if $non_ASCII
+                            && $code <= 0xFF
+                            && ($code >= 0x7F
+                                || ($code >= 0x0E && $code <= 0x1F)
+                                || ($code >= 0x01 && $code <= 0x06)
+                                || $code == 0x0B);  # \v introduced after 5.8
+
+        # shun null.  I'm (khw) not sure why this was done, but NULL would be
+        # the character very frequently used.
+        return $try_hard if $code == 0x0000;
+
+        return 0 if $try_hard;  # XXX Temporary until fix utf8.c
+
+        # shun non-character code points.
+        return $try_hard if $code >= 0xFDD0 && $code <= 0xFDEF;
+        return $try_hard if ($code & 0xFFFE) == 0xFFFE; # includes FFFF
+
+        return $try_hard if $code > $LAST_UNICODE_CODEPOINT;   # keep in range
+        return $try_hard if $code >= 0xD800 && $code <= 0xDFFF; # no surrogate
+
+        return 1;
+    }
+
+    sub get_valid_code_point {
+        # Return a code point that's part of the range list.  Returns nothing
+        # if the table is empty or we can't find a suitable code point.  This
+        # used only for making the test script.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr($self);
+
+        # On first pass, don't choose less desirable code points; if no good
+        # one is found, repeat, allowing a less desirable one to be selected.
+        for my $try_hard (0, 1) {
+
+            # Look through all the ranges for a usable code point.
+            for my $set ($self->ranges) {
+
+                # Try the edge cases first, starting with the end point of the
+                # range.
+                my $end = $set->end;
+                return $end if is_code_point_usable($end, $try_hard);
+
+                # End point didn't, work.  Start at the beginning and try
+                # every one until find one that does work.
+                for my $trial ($set->start .. $end - 1) {
+                    return $trial if is_code_point_usable($trial, $try_hard);
+                }
+            }
+        }
+        return ();  # If none found, give up.
+    }
+
+    sub get_invalid_code_point {
+        # Return a code point that's not part of the table.  Returns nothing
+        # if the table covers all code points or a suitable code point can't
+        # be found.  This used only for making the test script.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        # Just find a valid code point of the inverse, if any.
+        return Range_List->new(Initialize => ~ $self)->get_valid_code_point;
+    }
+} # end closure for Range_List
+
+package Range_Map;
+use base '_Range_List_Base';
+
+# A Range_Map is a range list in which the range values (called maps) are
+# significant, and hence shouldn't be manipulated by our other code, which
+# could be ambiguous or lose things.  For example, in taking the union of two
+# lists, which share code points, but which have differing values, which one
+# has precedence in the union?
+# It turns out that these operations aren't really necessary for map tables,
+# and so this class was created to make sure they aren't accidentally
+# applied to them.
+
+{ # Closure
+
+    sub add_map {
+        # Add a range containing a mapping value to the list
+
+        my $self = shift;
+        # Rest of parameters passed on
+
+        return $self->_add_delete('+', @_);
+    }
+
+    sub add_duplicate {
+        # Adds entry to a range list which can duplicate an existing entry
+
+        my $self = shift;
+        my $code_point = shift;
+        my $value = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        return $self->add_map($code_point, $code_point,
+                                $value, Replace => $MULTIPLE);
+    }
+} # End of closure for package Range_Map
+
+package _Base_Table;
+
+# A table is the basic data structure that gets written out into a file for
+# use by the Perl core.  This is the abstract base class implementing the
+# common elements from the derived ones.  A list of the methods to be
+# furnished by an implementing class is just after the constructor.
+
+sub standardize { return main::standardize($_[0]); }
+sub trace { return main::trace(@_); }
+
+{ # Closure
+
+    main::setup_package();
+
+    my %range_list;
+    # Object containing the ranges of the table.
+    main::set_access('range_list', \%range_list, 'p_r', 'p_s');
+
+    my %full_name;
+    # The full table name.
+    main::set_access('full_name', \%full_name, 'r');
+
+    my %name;
+    # The table name, almost always shorter
+    main::set_access('name', \%name, 'r');
+
+    my %short_name;
+    # The shortest of all the aliases for this table, with underscores removed
+    main::set_access('short_name', \%short_name);
+
+    my %nominal_short_name_length;
+    # The length of short_name before removing underscores
+    main::set_access('nominal_short_name_length',
+                    \%nominal_short_name_length);
+
+    my %property;
+    # Parent property this table is attached to.
+    main::set_access('property', \%property, 'r');
+
+    my %aliases;
+    # Ordered list of aliases of the table's name.  The first ones in the list
+    # are output first in comments
+    main::set_access('aliases', \%aliases, 'readable_array');
+
+    my %comment;
+    # A comment associated with the table for human readers of the files
+    main::set_access('comment', \%comment, 's');
+
+    my %description;
+    # A comment giving a short description of the table's meaning for human
+    # readers of the files.
+    main::set_access('description', \%description, 'readable_array');
+
+    my %note;
+    # A comment giving a short note about the table for human readers of the
+    # files.
+    main::set_access('note', \%note, 'readable_array');
+
+    my %internal_only;
+    # Boolean; if set means any file that contains this table is marked as for
+    # internal-only use.
+    main::set_access('internal_only', \%internal_only);
+
+    my %find_table_from_alias;
+    # The parent property passes this pointer to a hash which this class adds
+    # all its aliases to, so that the parent can quickly take an alias and
+    # find this table.
+    main::set_access('find_table_from_alias', \%find_table_from_alias, 'p_r');
+
+    my %locked;
+    # After this table is made equivalent to another one; we shouldn't go
+    # changing the contents because that could mean it's no longer equivalent
+    main::set_access('locked', \%locked, 'r');
+
+    my %file_path;
+    # This gives the final path to the file containing the table.  Each
+    # directory in the path is an element in the array
+    main::set_access('file_path', \%file_path, 'readable_array');
+
+    my %status;
+    # What is the table's status, normal, $OBSOLETE, etc.  Enum
+    main::set_access('status', \%status, 'r');
+
+    my %status_info;
+    # A comment about its being obsolete, or whatever non normal status it has
+    main::set_access('status_info', \%status_info, 'r');
+
+    my %range_size_1;
+    # Is the table to be output with each range only a single code point?
+    # This is done to avoid breaking existing code that may have come to rely
+    # on this behavior in previous versions of this program.)
+    main::set_access('range_size_1', \%range_size_1, 'r', 's');
+
+    my %perl_extension;
+    # A boolean set iff this table is a Perl extension to the Unicode
+    # standard.
+    main::set_access('perl_extension', \%perl_extension, 'r');
+
+    sub new {
+        # All arguments are key => value pairs, which you can see below, most
+        # of which match fields documented above.  Otherwise: Pod_Entry,
+        # Externally_Ok, and Fuzzy apply to the names of the table, and are
+        # documented in the Alias package
+
+        return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
+
+        my $class = shift;
+
+        my $self = bless \do { my $anonymous_scalar }, $class;
+        my $addr = main::objaddr($self);
+
+        my %args = @_;
+
+        $name{$addr} = delete $args{'Name'};
+        $find_table_from_alias{$addr} = delete $args{'_Alias_Hash'};
+        $full_name{$addr} = delete $args{'Full_Name'};
+        $internal_only{$addr} = delete $args{'Internal_Only_Warning'} || 0;
+        $perl_extension{$addr} = delete $args{'Perl_Extension'} || 0;
+        $property{$addr} = delete $args{'_Property'};
+        $range_list{$addr} = delete $args{'_Range_List'};
+        $status{$addr} = delete $args{'Status'} || $NORMAL;
+        $status_info{$addr} = delete $args{'_Status_Info'} || "";
+        $range_size_1{$addr} = delete $args{'Range_Size_1'} || 0;
+
+        my $description = delete $args{'Description'};
+        my $externally_ok = delete $args{'Externally_Ok'};
+        my $loose_match = delete $args{'Fuzzy'};
+        my $note = delete $args{'Note'};
+        my $make_pod_entry = delete $args{'Pod_Entry'};
+
+        # Shouldn't have any left over
+        Carp::carp_extra_args(\%args) if main::DEBUG && %args;
+
+        # Can't use || above because conceivably the name could be 0, and
+        # can't use // operator in case this program gets used in Perl 5.8
+        $full_name{$addr} = $name{$addr} if ! defined $full_name{$addr};
+
+        $aliases{$addr} = [ ];
+        $comment{$addr} = [ ];
+        $description{$addr} = [ ];
+        $note{$addr} = [ ];
+        $file_path{$addr} = [ ];
+        $locked{$addr} = "";
+
+        push @{$description{$addr}}, $description if $description;
+        push @{$note{$addr}}, $note if $note;
+
+        # If hasn't set its status already, see if it is on one of the lists
+        # of properties or tables that have particular statuses; if not, is
+        # normal.  The lists are prioritized so the most serious ones are
+        # checked first
+        my $complete_name = $self->complete_name;
+        if (! $status{$addr}) {
+            if (exists $why_suppressed{$complete_name}) {
+                $status{$addr} = $SUPPRESSED;
+            }
+            elsif (exists $why_deprecated{$complete_name}) {
+                $status{$addr} = $DEPRECATED;
+            }
+            elsif (exists $why_stabilized{$complete_name}) {
+                $status{$addr} = $STABILIZED;
+            }
+            elsif (exists $why_obsolete{$complete_name}) {
+                $status{$addr} = $OBSOLETE;
+            }
+
+            # Existence above doesn't necessarily mean there is a message
+            # associated with it.  Use the most serious message.
+            if ($status{$addr}) {
+                if ($why_suppressed{$complete_name}) {
+                    $status_info{$addr}
+                                = $why_suppressed{$complete_name};
+                }
+                elsif ($why_deprecated{$complete_name}) {
+                    $status_info{$addr}
+                                = $why_deprecated{$complete_name};
+                }
+                elsif ($why_stabilized{$complete_name}) {
+                    $status_info{$addr}
+                                = $why_stabilized{$complete_name};
+                }
+                elsif ($why_obsolete{$complete_name}) {
+                    $status_info{$addr}
+                                = $why_obsolete{$complete_name};
+                }
+            }
+        }
+
+        # By convention what typically gets printed only or first is what's
+        # first in the list, so put the full name there for good output
+        # clarity.  Other routines rely on the full name being first on the
+        # list
+        $self->add_alias($full_name{$addr},
+                            Externally_Ok => $externally_ok,
+                            Fuzzy => $loose_match,
+                            Pod_Entry => $make_pod_entry,
+                            Status => $status{$addr},
+                            );
+
+        # Then comes the other name, if meaningfully different.
+        if (standardize($full_name{$addr}) ne standardize($name{$addr})) {
+            $self->add_alias($name{$addr},
+                            Externally_Ok => $externally_ok,
+                            Fuzzy => $loose_match,
+                            Pod_Entry => $make_pod_entry,
+                            Status => $status{$addr},
+                            );
+        }
+
+        return $self;
+    }
+
+    # Here are the methods that are required to be defined by any derived
+    # class
+    for my $sub qw(
+                    append_to_body
+                    complete_name
+                    pre_body
+                )
+                # append_to_body and pre_body are called in the write() method
+                # to add stuff after the main body of the table, but before
+                # its close; and to prepend stuff before the beginning of the
+                # table.
+                # complete_name returns the complete name of the property and
+                # table, like Script=Latin
+    {
+        no strict "refs";
+        *$sub = sub {
+            Carp::my_carp_bug( __LINE__
+                              . ": Must create method '$sub()' for "
+                              . ref shift);
+            return;
+        }
+    }
+
+    use overload
+        fallback => 0,
+        "." => \&main::_operator_dot,
+        '!=' => \&main::_operator_not_equal,
+        '==' => \&main::_operator_equal,
+    ;
+
+    sub ranges {
+        # Returns the array of ranges associated with this table.
+
+        return $range_list{main::objaddr shift}->ranges;
+    }
+
+    sub add_alias {
+        # Add a synonym for this table.
+
+        return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
+
+        my $self = shift;
+        my $name = shift;       # The name to add.
+        my $pointer = shift;    # What the alias hash should point to.  For
+                                # map tables, this is the parent property;
+                                # for match tables, it is the table itself.
+
+        my %args = @_;
+        my $loose_match = delete $args{'Fuzzy'};
+
+        my $make_pod_entry = delete $args{'Pod_Entry'};
+        $make_pod_entry = $YES unless defined $make_pod_entry;
+
+        my $externally_ok = delete $args{'Externally_Ok'};
+        $externally_ok = 1 unless defined $externally_ok;
+
+        my $status = delete $args{'Status'};
+        $status = $NORMAL unless defined $status;
+
+        Carp::carp_extra_args(\%args) if main::DEBUG && %args;
+
+        # Capitalize the first letter of the alias unless it is one of the CJK
+        # ones which specifically begins with a lower 'k'.  Do this because
+        # Unicode has varied whether they capitalize first letters or not, and
+        # have later changed their minds and capitalized them, but not the
+        # other way around.  So do it always and avoid changes from release to
+        # release
+        $name = ucfirst($name) unless $name =~ /^k[A-Z]/;
+
+        my $addr = main::objaddr $self;
+
+        # Figure out if should be loosely matched if not already specified.
+        if (! defined $loose_match) {
+
+            # Is a loose_match if isn't null, and doesn't begin with an
+            # underscore and isn't just a number
+            if ($name ne ""
+                && substr($name, 0, 1) ne '_'
+                && $name !~ qr{^[0-9_.+-/]+$})
+            {
+                $loose_match = 1;
+            }
+            else {
+                $loose_match = 0;
+            }
+        }
+
+        # If this alias has already been defined, do nothing.
+        return if defined $find_table_from_alias{$addr}->{$name};
+
+        # That includes if it is standardly equivalent to an existing alias,
+        # in which case, add this name to the list, so won't have to search
+        # for it again.
+        my $standard_name = main::standardize($name);
+        if (defined $find_table_from_alias{$addr}->{$standard_name}) {
+            $find_table_from_alias{$addr}->{$name}
+                        = $find_table_from_alias{$addr}->{$standard_name};
+            return;
+        }
+
+        # Set the index hash for this alias for future quick reference.
+        $find_table_from_alias{$addr}->{$name} = $pointer;
+        $find_table_from_alias{$addr}->{$standard_name} = $pointer;
+        local $to_trace = 0 if main::DEBUG;
+        trace "adding alias $name to $pointer" if main::DEBUG && $to_trace;
+        trace "adding alias $standard_name to $pointer" if main::DEBUG && $to_trace;
+
+
+        # Put the new alias at the end of the list of aliases unless the final
+        # element begins with an underscore (meaning it is for internal perl
+        # use) or is all numeric, in which case, put the new one before that
+        # one.  This floats any all-numeric or underscore-beginning aliases to
+        # the end.  This is done so that they are listed last in output lists,
+        # to encourage the user to use a better name (either more descriptive
+        # or not an internal-only one) instead.  This ordering is relied on
+        # implicitly elsewhere in this program, like in short_name()
+        my $list = $aliases{$addr};
+        my $insert_position = (@$list == 0
+                                || (substr($list->[-1]->name, 0, 1) ne '_'
+                                    && $list->[-1]->name =~ /\D/))
+                            ? @$list
+                            : @$list - 1;
+        splice @$list,
+                $insert_position,
+                0,
+                Alias->new($name, $loose_match, $make_pod_entry,
+                                                    $externally_ok, $status);
+
+        # This name may be shorter than any existing ones, so clear the cache
+        # of the shortest, so will have to be recalculated.
+        undef $short_name{main::objaddr $self};
+        return;
+    }
+
+    sub short_name {
+        # Returns a name suitable for use as the base part of a file name.
+        # That is, shorter wins.  It can return undef if there is no suitable
+        # name.  The name has all non-essential underscores removed.
+
+        # The optional second parameter is a reference to a scalar in which
+        # this routine will store the length the returned name had before the
+        # underscores were removed, or undef if the return is undef.
+
+        # The shortest name can change if new aliases are added.  So using
+        # this should be deferred until after all these are added.  The code
+        # that does that should clear this one's cache.
+        # Any name with alphabetics is preferred over an all numeric one, even
+        # if longer.
+
+        my $self = shift;
+        my $nominal_length_ptr = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        # For efficiency, don't recalculate, but this means that adding new
+        # aliases could change what the shortest is, so the code that does
+        # that needs to undef this.
+        if (defined $short_name{$addr}) {
+            if ($nominal_length_ptr) {
+                $$nominal_length_ptr = $nominal_short_name_length{$addr};
+            }
+            return $short_name{$addr};
+        }
+
+        # Look at each alias
+        foreach my $alias ($self->aliases()) {
+
+            # Don't use an alias that isn't ok to use for an external name.
+            next if ! $alias->externally_ok;
+
+            my $name = main::Standardize($alias->name);
+            trace $self, $name if main::DEBUG && $to_trace;
+
+            # Take the first one, or a shorter one that isn't numeric.  This
+            # relies on numeric aliases always being last in the array
+            # returned by aliases().  Any alpha one will have precedence.
+            if (! defined $short_name{$addr}
+                || ($name =~ /\D/
+                    && length($name) < length($short_name{$addr})))
+            {
+                # Remove interior underscores.
+                ($short_name{$addr} = $name) =~ s/ (?<= . ) _ (?= . ) //xg;
+
+                $nominal_short_name_length{$addr} = length $name;
+            }
+        }
+
+        # If no suitable external name return undef
+        if (! defined $short_name{$addr}) {
+            $$nominal_length_ptr = undef if $nominal_length_ptr;
+            return;
+        }
+
+        # Don't allow a null external name.
+        if ($short_name{$addr} eq "") {
+            $short_name{$addr} = '_';
+            $nominal_short_name_length{$addr} = 1;
+        }
+
+        trace $self, $short_name{$addr} if main::DEBUG && $to_trace;
+
+        if ($nominal_length_ptr) {
+            $$nominal_length_ptr = $nominal_short_name_length{$addr};
+        }
+        return $short_name{$addr};
+    }
+
+    sub external_name {
+        # Returns the external name that this table should be known by.  This
+        # is usually the short_name, but not if the short_name is undefined.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $short = $self->short_name;
+        return $short if defined $short;
+
+        return '_';
+    }
+
+    sub add_description { # Adds the parameter as a short description.
+
+        my $self = shift;
+        my $description = shift;
+        chomp $description;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        push @{$description{main::objaddr $self}}, $description;
+
+        return;
+    }
+
+    sub add_note { # Adds the parameter as a short note.
+
+        my $self = shift;
+        my $note = shift;
+        chomp $note;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        push @{$note{main::objaddr $self}}, $note;
+
+        return;
+    }
+
+    sub add_comment { # Adds the parameter as a comment.
+
+        my $self = shift;
+        my $comment = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        chomp $comment;
+        push @{$comment{main::objaddr $self}}, $comment;
+
+        return;
+    }
+
+    sub comment {
+        # Return the current comment for this table.  If called in list
+        # context, returns the array of comments.  In scalar, returns a string
+        # of each element joined together with a period ending each.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my @list = @{$comment{main::objaddr $self}};
+        return @list if wantarray;
+        my $return = "";
+        foreach my $sentence (@list) {
+            $return .= '.  ' if $return;
+            $return .= $sentence;
+            $return =~ s/\.$//;
+        }
+        $return .= '.' if $return;
+        return $return;
+    }
+
+    sub initialize {
+        # Initialize the table with the argument which is any valid
+        # initialization for range lists.
+
+        my $self = shift;
+        my $initialization = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        # Replace the current range list with a new one of the same exact
+        # type.
+        my $class = ref $range_list{main::objaddr $self};
+        $range_list{main::objaddr $self} = $class->new(Owner => $self,
+                                        Initialize => $initialization);
+        return;
+
+    }
+
+    sub header {
+        # The header that is output for the table in the file it is written
+        # in.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $return = "";
+        $return .= $DEVELOPMENT_ONLY if $compare_versions;
+        $return .= $HEADER;
+        $return .= $INTERNAL_ONLY if $internal_only{main::objaddr $self};
+        return $return;
+    }
+
+    sub write {
+        # Write a representation of the table to its file.
+
+        my $self = shift;
+        my $tab_stops = shift;       # The number of tab stops over to put any
+                                     # comment.
+        my $suppress_value = shift;  # Optional, if the value associated with
+                                     # a range equals this one, don't write
+                                     # the range
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr($self);
+
+        # Start with the header
+        my @OUT = $self->header;
+
+        # Then the comments
+        push @OUT, "\n", main::simple_fold($comment{$addr}, '# '), "\n"
+                                                        if $comment{$addr};
+
+        # Then any pre-body stuff.
+        my $pre_body = $self->pre_body;
+        push @OUT, $pre_body, "\n" if $pre_body;
+
+        # The main body looks like a 'here' document
+        push @OUT, "return <<'END';\n";
+
+        if ($range_list{$addr}->is_empty) {
+
+            # This is a kludge for empty tables to silence a warning in
+            # utf8.c, which can't really deal with empty tables, but it can
+            # deal with a table that matches nothing, as the inverse of 'Any'
+            # does.
+            push @OUT, "!utf8::IsAny\n";
+        }
+        else {
+            my $range_size_1 = $range_size_1{$addr};
+
+            # Output each range as part of the here document.
+            for my $set ($range_list{$addr}->ranges) {
+                my $start = $set->start;
+                my $end   = $set->end;
+                my $value  = $set->value;
+
+                # Don't output ranges whose value is the one to suppress
+                next if defined $suppress_value && $value eq $suppress_value;
+
+                # If has or wants a single point range output
+                if ($start == $end || $range_size_1) {
+                    for my $i ($start .. $end) {
+                        push @OUT, sprintf "%04X\t\t%s\n", $i, $value;
+                    }
+                }
+                else  {
+                    push @OUT, sprintf "%04X\t%04X\t%s", $start, $end, $value;
+
+                    # Add a comment with the size of the range, if requested.
+                    # Expand Tabs to make sure they all start in the same
+                    # column, and then unexpand to use mostly tabs.
+                    if (! $output_range_counts) {
+                        $OUT[-1] .= "\n";
+                    }
+                    else {
+                        $OUT[-1] = Text::Tabs::expand($OUT[-1]);
+                        my $count = main::clarify_number($end - $start + 1);
+                        use integer;
+
+                        my $width = $tab_stops * 8 - 1;
+                        $OUT[-1] = sprintf("%-*s # [%s]\n",
+                                            $width,
+                                            $OUT[-1],
+                                            $count);
+                        $OUT[-1] = Text::Tabs::unexpand($OUT[-1]);
+                    }
+                }
+            } # End of loop through all the table's ranges
+        }
+
+        # Add anything that goes after the main body, but within the here
+        # document,
+        my $append_to_body = $self->append_to_body;
+        push @OUT, $append_to_body if $append_to_body;
+
+        # And finish the here document.
+        push @OUT, "END\n";
+
+        # All these files have a .pl suffix
+        $file_path{$addr}->[-1] .= '.pl';
+
+        main::write($file_path{$addr}, \@OUT);
+        return;
+    }
+
+    sub set_status {    # Set the table's status
+        my $self = shift;
+        my $status = shift; # The status enum value
+        my $info = shift;   # Any message associated with it.
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr($self);
+
+        $status{$addr} = $status;
+        $status_info{$addr} = $info;
+        return;
+    }
+
+    sub lock {
+        # Don't allow changes to the table from now on.  This stores a stack
+        # trace of where it was called, so that later attempts to modify it
+        # can immediately show where it got locked.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        $locked{$addr} = "";
+
+        my $line = (caller(0))[2];
+        my $i = 1;
+
+        # Accumulate the stack trace
+        while (1) {
+            my ($pkg, $file, $caller_line, $caller) = caller $i++;
+
+            last unless defined $caller;
+
+            $locked{$addr} .= "    called from $caller() at line $line\n";
+            $line = $caller_line;
+        }
+        $locked{$addr} .= "    called from main at line $line\n";
+
+        return;
+    }
+
+    sub carp_if_locked {
+        # Return whether a table is locked or not, and, by the way, complain
+        # if is locked
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        return 0 if ! $locked{$addr};
+        Carp::my_carp_bug("Can't modify a locked table. Stack trace of locking:\n$locked{$addr}\n\n");
+        return 1;
+    }
+
+    sub set_file_path { # Set the final directory path for this table
+        my $self = shift;
+        # Rest of parameters passed on
+
+        @{$file_path{main::objaddr $self}} = @_;
+        return
+    }
+
+    # Accessors for the range list stored in this table.  First for
+    # unconditional
+    for my $sub qw(
+                    contains
+                    count
+                    each_range
+                    hash
+                    is_empty
+                    max
+                    min
+                    range_count
+                    reset_each_range
+                    value_of
+                )
+    {
+        no strict "refs";
+        *$sub = sub {
+            use strict "refs";
+            my $self = shift;
+            return $range_list{main::objaddr $self}->$sub(@_);
+        }
+    }
+
+    # Then for ones that should fail if locked
+    for my $sub qw(
+                    delete_range
+                )
+    {
+        no strict "refs";
+        *$sub = sub {
+            use strict "refs";
+            my $self = shift;
+
+            return if $self->carp_if_locked;
+            return $range_list{main::objaddr $self}->$sub(@_);
+        }
+    }
+
+} # End closure
+
+package Map_Table;
+use base '_Base_Table';
+
+# A Map Table is a table that contains the mappings from code points to
+# values.  There are two weird cases:
+# 1) Anomalous entries are ones that aren't maps of ranges of code points, but
+#    are written in the table's file at the end of the table nonetheless.  It
+#    requires specially constructed code to handle these; utf8.c can not read
+#    these in, so they should not go in $map_directory.  As of this writing,
+#    the only case that these happen is for named sequences used in
+#    charnames.pm.   But this code doesn't enforce any syntax on these, so
+#    something else could come along that uses it.
+# 2) Specials are anything that doesn't fit syntactically into the body of the
+#    table.  The ranges for these have a map type of non-zero.  The code below
+#    knows about and handles each possible type.   In most cases, these are
+#    written as part of the header.
+#
+# A map table deliberately can't be manipulated at will unlike match tables.
+# This is because of the ambiguities having to do with what to do with
+# overlapping code points.  And there just isn't a need for those things;
+# what one wants to do is just query, add, replace, or delete mappings, plus
+# write the final result.
+# However, there is a method to get the list of possible ranges that aren't in
+# this table to use for defaulting missing code point mappings.  And,
+# map_add_or_replace_non_nulls() does allow one to add another table to this
+# one, but it is clearly very specialized, and defined that the other's
+# non-null values replace this one's if there is any overlap.
+
+sub trace { return main::trace(@_); }
+
+{ # Closure
+
+    main::setup_package();
+
+    my %default_map;
+    # Many input files omit some entries; this gives what the mapping for the
+    # missing entries should be
+    main::set_access('default_map', \%default_map, 'r');
+
+    my %anomalous_entries;
+    # Things that go in the body of the table which don't fit the normal
+    # scheme of things, like having a range.  Not much can be done with these
+    # once there except to output them.  This was created to handle named
+    # sequences.
+    main::set_access('anomalous_entry', \%anomalous_entries, 'a');
+    main::set_access('anomalous_entries',       # Append singular, read plural
+                    \%anomalous_entries,
+                    'readable_array');
+
+    my %format;
+    # The format of the entries of the table.  This is calculated from the
+    # data in the table (or passed in the constructor).  This is an enum e.g.,
+    # $STRING_FORMAT
+    main::set_access('format', \%format);
+
+    my %core_access;
+    # This is a string, solely for documentation, indicating how one can get
+    # access to this property via the Perl core.
+    main::set_access('core_access', \%core_access, 'r', 's');
+
+    my %has_specials;
+    # Boolean set when non-zero map-type ranges are added to this table,
+    # which happens in only a few tables.  This is purely for performance, to
+    # avoid having to search through every table upon output, so if all the
+    # non-zero maps got deleted before output, this would remain set, and the
+    # only penalty would be performance.  Currently, most map tables that get
+    # output have specials in them, so this doesn't help that much anyway.
+    main::set_access('has_specials', \%has_specials);
+
+    my %to_output_map;
+    # Boolean as to whether or not to write out this map table
+    main::set_access('to_output_map', \%to_output_map, 's');
+
+
+    sub new {
+        my $class = shift;
+        my $name = shift;
+
+        my %args = @_;
+
+        # Optional initialization data for the table.
+        my $initialize = delete $args{'Initialize'};
+
+        my $core_access = delete $args{'Core_Access'};
+        my $default_map = delete $args{'Default_Map'};
+        my $format = delete $args{'Format'};
+        my $property = delete $args{'_Property'};
+        # Rest of parameters passed on
+
+        my $range_list = Range_Map->new(Owner => $property);
+
+        my $self = $class->SUPER::new(
+                                    Name => $name,
+                                    _Property => $property,
+                                    _Range_List => $range_list,
+                                    %args);
+
+        my $addr = main::objaddr $self;
+
+        $anomalous_entries{$addr} = [];
+        $core_access{$addr} = $core_access;
+        $default_map{$addr} = $default_map;
+        $format{$addr} = $format;
+
+        $self->initialize($initialize) if defined $initialize;
+
+        return $self;
+    }
+
+    use overload
+        fallback => 0,
+        qw("") => "_operator_stringify",
+    ;
+
+    sub _operator_stringify {
+        my $self = shift;
+
+        my $name = $self->property->full_name;
+        $name = '""' if $name eq "";
+        return "Map table for Property '$name'";
+    }
+
+    sub complete_name {
+        # The complete name for a map table is just its full name, as that
+        # completely identifies the property it represents
+
+        return shift->full_name;
+    }
+
+    sub add_alias {
+        # Add a synonym for this table (which means the property itself)
+        my $self = shift;
+        my $name = shift;
+        # Rest of parameters passed on.
+
+        $self->SUPER::add_alias($name, $self->property, @_);
+        return;
+    }
+
+    sub add_map {
+        # Add a range of code points to the list of specially-handled code
+        # points.  $MULTI_CP is assumed if the type of special is not passed
+        # in.
+
+        my $self = shift;
+        my $lower = shift;
+        my $upper = shift;
+        my $string = shift;
+        my %args = @_;
+
+        my $type = delete $args{'Type'} || 0;
+        # Rest of parameters passed on
+
+        # Can't change the table if locked.
+        return if $self->carp_if_locked;
+
+        my $addr = main::objaddr $self;
+
+        $has_specials{$addr} = 1 if $type;
+
+        $self->_range_list->add_map($lower, $upper,
+                                    $string,
+                                    @_,
+                                    Type => $type);
+        return;
+    }
+
+    sub append_to_body {
+        # Adds to the written HERE document of the table's body any anomalous
+        # entries in the table..
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        return "" unless @{$anomalous_entries{$addr}};
+        return join("\n", @{$anomalous_entries{$addr}}) . "\n";
+    }
+
+    sub map_add_or_replace_non_nulls {
+        # This adds the mappings in the table $other to $self.  Non-null
+        # mappings from $other override those in $self.  It essentially merges
+        # the two tables, with the second having priority except for null
+        # mappings.
+
+        my $self = shift;
+        my $other = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        return if $self->carp_if_locked;
+
+        if (! $other->isa(__PACKAGE__)) {
+            Carp::my_carp_bug("$other should be a "
+                        . __PACKAGE__
+                        . ".  Not a '"
+                        . ref($other)
+                        . "'.  Not added;");
+            return;
+        }
+
+        my $addr = main::objaddr $self;
+        my $other_addr = main::objaddr $other;
+
+        local $to_trace = 0 if main::DEBUG;
+
+        my $self_range_list = $self->_range_list;
+        my $other_range_list = $other->_range_list;
+        foreach my $range ($other_range_list->ranges) {
+            my $value = $range->value;
+            next if $value eq "";
+            $self_range_list->_add_delete('+',
+                                          $range->start,
+                                          $range->end,
+                                          $value,
+                                          Type => $range->type,
+                                          Replace => $UNCONDITIONALLY);
+        }
+
+        # Copy the specials information from the other table to $self
+        if ($has_specials{$other_addr}) {
+            $has_specials{$addr} = 1;
+        }
+
+        return;
+    }
+
+    sub set_default_map {
+        # Define what code points that are missing from the input files should
+        # map to
+
+        my $self = shift;
+        my $map = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        # Convert the input to the standard equivalent, if any (won't have any
+        # for $STRING properties)
+        my $standard = $self->_find_table_from_alias->{$map};
+        $map = $standard->name if defined $standard;
+
+        # Warn if there already is a non-equivalent default map for this
+        # property.  Note that a default map can be a ref, which means that
+        # what it actually means is delayed until later in the program, and it
+        # IS permissible to override it here without a message.
+        my $default_map = $default_map{$addr};
+        if (defined $default_map
+            && ! ref($default_map)
+            && $default_map ne $map
+            && main::Standardize($map) ne $default_map)
+        {
+            my $property = $self->property;
+            my $map_table = $property->table($map);
+            my $default_table = $property->table($default_map);
+            if (defined $map_table
+                && defined $default_table
+                && $map_table != $default_table)
+            {
+                Carp::my_carp("Changing the default mapping for "
+                            . $property
+                            . " from $default_map to $map'");
+            }
+        }
+
+        $default_map{$addr} = $map;
+
+        # Don't also create any missing table for this map at this point,
+        # because if we did, it could get done before the main table add is
+        # done for PropValueAliases.txt; instead the caller will have to make
+        # sure it exists, if desired.
+        return;
+    }
+
+    sub to_output_map {
+        # Returns boolean: should we write this map table?
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        # If overridden, use that
+        return $to_output_map{$addr} if defined $to_output_map{$addr};
+
+        my $full_name = $self->full_name;
+
+        # If table says to output, do so; if says to suppress it, do do.
+        return 1 if grep { $_ eq $full_name } @output_mapped_properties;
+        return 0 if $self->status eq $SUPPRESSED;
+
+        my $type = $self->property->type;
+
+        # Don't want to output binary map tables even for debugging.
+        return 0 if $type == $BINARY;
+
+        # But do want to output string ones.
+        return 1 if $type == $STRING;
+
+        # Otherwise is an $ENUM, don't output it
+        return 0;
+    }
+
+    sub inverse_list {
+        # Returns a Range_List that is gaps of the current table.  That is,
+        # the inversion
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $current = Range_List->new(Initialize => $self->_range_list,
+                                Owner => $self->property);
+        return ~ $current;
+    }
+
+    sub set_final_comment {
+        # Just before output, create the comment that heads the file
+        # containing this table.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        # No sense generating a comment if aren't going to write it out.
+        return if ! $self->to_output_map;
+
+        my $addr = main::objaddr $self;
+
+        my $property = $self->property;
+
+        # Get all the possible names for this property.  Don't use any that
+        # aren't ok for use in a file name, etc.  This is perhaps causing that
+        # flag to do double duty, and may have to be changed in the future to
+        # have our own flag for just this purpose; but it works now to exclude
+        # Perl generated synonyms from the lists for properties, where the
+        # name is always the proper Unicode one.
+        my @property_aliases = grep { $_->externally_ok } $self->aliases;
+
+        my $count = $self->count;
+        my $default_map = $default_map{$addr};
+
+        # The ranges that map to the default aren't output, so subtract that
+        # to get those actually output.  A property with matching tables
+        # already has the information calculated.
+        if ($property->type != $STRING) {
+            $count -= $property->table($default_map)->count;
+        }
+        elsif (defined $default_map) {
+
+            # But for $STRING properties, must calculate now.  Subtract the
+            # count from each range that maps to the default.
+            foreach my $range ($self->_range_list->ranges) {
+        local $to_trace = 1 if main::DEBUG;
+        trace $self, $range;
+                if ($range->value eq $default_map) {
+                    $count -= $range->end +1 - $range->start;
+                }
+            }
+
+        }
+
+        # Get a  string version of $count with underscores in large numbers,
+        # for clarity.
+        my $string_count = main::clarify_number($count);
+
+        my $code_points = ($count == 1)
+                        ? 'single code point'
+                        : "$string_count code points";
+
+        my $mapping;
+        my $these_mappings;
+        my $are;
+        if (@property_aliases <= 1) {
+            $mapping = 'mapping';
+            $these_mappings = 'this mapping';
+            $are = 'is'
+        }
+        else {
+            $mapping = 'synonymous mappings';
+            $these_mappings = 'these mappings';
+            $are = 'are'
+        }
+        my $cp;
+        if ($count >= $MAX_UNICODE_CODEPOINTS) {
+            $cp = "any code point in Unicode Version $string_version";
+        }
+        else {
+            my $map_to;
+            if ($default_map eq "") {
+                $map_to = 'the null string';
+            }
+            elsif ($default_map eq $CODE_POINT) {
+                $map_to = "itself";
+            }
+            else {
+                $map_to = "'$default_map'";
+            }
+            if ($count == 1) {
+                $cp = "the single code point";
+            }
+            else {
+                $cp = "one of the $code_points";
+            }
+            $cp .= " in Unicode Version $string_version for which the mapping is not to $map_to";
+        }
+
+        my $comment = "";
+
+        my $status = $self->status;
+        if ($status) {
+            my $warn = uc $status_past_participles{$status};
+            $comment .= <<END;
+
+!!!!!!!   $warn !!!!!!!!!!!!!!!!!!!
+ All property or property=value combinations contained in this file are $warn.
+ See $unicode_reference_url for what this means.
+
+END
+        }
+        $comment .= "This file returns the $mapping:\n";
+
+        for my $i (0 .. @property_aliases - 1) {
+            $comment .= sprintf("%-8s%s\n",
+                                " ",
+                                $property_aliases[$i]->name . '(cp)'
+                                );
+        }
+        $comment .=
+                "\nwhere 'cp' is $cp.  Note that $these_mappings $are ";
+
+        my $access = $core_access{$addr};
+        if ($access) {
+            $comment .= "accessible through the Perl core via $access.";
+        }
+        else {
+            $comment .= "not accessible through the Perl core directly.";
+        }
+
+        # And append any commentary already set from the actual property.
+        $comment .= "\n\n" . $self->comment if $self->comment;
+        if ($self->description) {
+            $comment .= "\n\n" . join " ", $self->description;
+        }
+        if ($self->note) {
+            $comment .= "\n\n" . join " ", $self->note;
+        }
+        $comment .= "\n";
+
+        if (! $self->perl_extension) {
+            $comment .= <<END;
+
+For information about what this property really means, see:
+$unicode_reference_url
+END
+        }
+
+        if ($count) {        # Format differs for empty table
+                $comment.= "\nThe format of the ";
+            if ($self->range_size_1) {
+                $comment.= <<END;
+main body of lines of this file is: CODE_POINT\\t\\tMAPPING where CODE_POINT
+is in hex; MAPPING is what CODE_POINT maps to.
+END
+            }
+            else {
+
+                # There are tables which end up only having one element per
+                # range, but it is not worth keeping track of for making just
+                # this comment a little better.
+                $comment.= <<END;
+non-comment portions of the main body of lines of this file is:
+START\\tSTOP\\tMAPPING where START is the starting code point of the
+range, in hex; STOP is the ending point, or if omitted, the range has just one
+code point; MAPPING is what each code point between START and STOP maps to.
+END
+                if ($output_range_counts) {
+                    $comment .= <<END;
+Numbers in comments in [brackets] indicate how many code points are in the
+range (omitted when the range is a single code point or if the mapping is to
+the null string).
+END
+                }
+            }
+        }
+        $self->set_comment(main::join_lines($comment));
+        return;
+    }
+
+    my %swash_keys; # Makes sure don't duplicate swash names.
+
+    sub pre_body {
+        # Returns the string that should be output in the file before the main
+        # body of this table.  This includes some hash entries identifying the
+        # format of the body, and what the single value should be for all
+        # ranges missing from it.  It also includes any code points which have
+        # map_types that don't go in the main table.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        my $name = $self->property->swash_name;
+
+        if (defined $swash_keys{$name}) {
+            Carp::my_carp(join_lines(<<END
+Already created a swash name '$name' for $swash_keys{$name}.  This means that
+the same name desired for $self shouldn't be used.  Bad News.  This must be
+fixed before production use, but proceeding anyway
+END
+            ));
+        }
+        $swash_keys{$name} = "$self";
+
+        my $default_map = $default_map{$addr};
+
+        my $pre_body = "";
+        if ($has_specials{$addr}) {
+
+            # Here, some maps with non-zero type have been added to the table.
+            # Go through the table and handle each of them.  None will appear
+            # in the body of the table, so delete each one as we go.  The
+            # code point count has already been calculated, so ok to delete
+            # now.
+
+            my @multi_code_point_maps;
+            my $has_hangul_syllables = 0;
+
+            # The key is the base name of the code point, and the value is an
+            # array giving all the ranges that use this base name.  Each range
+            # is actually a hash giving the 'low' and 'high' values of it.
+            my %names_ending_in_code_point;
+
+            # Inverse mapping.  The list of ranges that have these kinds of
+            # names.  Each element contains the low, high, and base names in a
+            # hash.
+            my @code_points_ending_in_code_point;
+
+            my $range_map = $self->_range_list;
+            foreach my $range ($range_map->ranges) {
+                next unless $range->type != 0;
+                my $low = $range->start;
+                my $high = $range->end;
+                my $map = $range->value;
+                my $type = $range->type;
+
+                # No need to output the range if it maps to the default.  And
+                # the write method won't output it either, so no need to
+                # delete it to keep it from being output, and is faster to
+                # skip than to delete anyway.
+                next if $map eq $default_map;
+
+                # Delete the range to keep write() from trying to output it
+                $range_map->delete_range($low, $high);
+
+                # Switch based on the map type...
+                if ($type == $HANGUL_SYLLABLE) {
+
+                    # These are entirely algorithmically determinable based on
+                    # some constants furnished by Unicode; for now, just set a
+                    # flag to indicate that have them.  Below we will output
+                    # the code that does the algorithm.
+                    $has_hangul_syllables = 1;
+                }
+                elsif ($type == $CP_IN_NAME) {
+
+                    # If the name ends in the code point it represents, are
+                    # also algorithmically determinable, but need information
+                    # about the map to do so.  Both the map and its inverse
+                    # are stored in data structures output in the file.
+                    push @{$names_ending_in_code_point{$map}->{'low'}}, $low;
+                    push @{$names_ending_in_code_point{$map}->{'high'}}, $high;
+
+                    push @code_points_ending_in_code_point, { low => $low,
+                                                              high => $high,
+                                                              name => $map
+                                                            };
+                }
+                elsif ($range->type == $MULTI_CP || $range->type == $NULL) {
+
+                    # Multi-code point maps and null string maps have an entry
+                    # for each code point in the range.  They use the same
+                    # output format.
+                    for my $code_point ($low .. $high) {
+
+                        # The pack() below can't cope with surrogates.
+                        if ($code_point >= 0xD800 && $code_point <= 0xDFFF) {
+                            Carp::my_carp("Surrogage code point '$code_point' in mapping to '$map' in $self.  No map created");
+                            next;
+                        }
+
+                        # Generate the hash entries for these in the form that
+                        # utf8.c understands.
+                        my $tostr = "";
+                        foreach my $to (split " ", $map) {
+                            if ($to !~ /^$code_point_re$/) {
+                                Carp::my_carp("Illegal code point '$to' in mapping '$map' from $code_point in $self.  No map created");
+                                next;
+                            }
+                            $tostr .= sprintf "\\x{%s}", $to;
+                        }
+
+                        # I (khw) have never waded through this line to
+                        # understand it well enough to comment it.
+                        my $utf8 = sprintf(qq["%s" => "$tostr",],
+                                join("", map { sprintf "\\x%02X", $_ }
+                                    unpack("U0C*", pack("U", $code_point))));
+
+                        # Add a comment so that a human reader can more easily
+                        # see what's going on.
+                        push @multi_code_point_maps,
+                                sprintf("%-45s # U+%04X => %s", $utf8,
+                                                                $code_point,
+                                                                $map);
+                    }
+                }
+                else {
+                    Carp::my_carp("Unrecognized map type '$range->type' in '$range' in $self.  Using type 0 instead");
+                    $range_map->add_map($low, $high, $map, Replace => $UNCONDITIONALLY, Type => 0);
+                }
+            } # End of loop through all ranges
+
+            # Here have gone through the whole file.  If actually generated
+            # anything for each map type, add its respective header and
+            # trailer
+            if (@multi_code_point_maps) {
+                $pre_body .= <<END;
+
+# Some code points require special handling because their mappings are each to
+# multiple code points.  These do not appear in the main body, but are defined
+# in the hash below.
+
+# The key: UTF-8 _bytes_, the value: UTF-8 (speed hack)
+%utf8::ToSpec$name = (
+END
+                $pre_body .= join("\n", @multi_code_point_maps) . "\n);\n";
+            }
+
+            if ($has_hangul_syllables || @code_points_ending_in_code_point) {
+
+                # Convert these structures to output format.
+                my $code_points_ending_in_code_point =
+                    main::simple_dumper(\@code_points_ending_in_code_point,
+                                        ' ' x 8);
+                my $names = main::simple_dumper(\%names_ending_in_code_point,
+                                                ' ' x 8);
+
+                # Do the same with the Hangul names,
+                my $jamo;
+                my $jamo_l;
+                my $jamo_v;
+                my $jamo_t;
+                my $jamo_re;
+                if ($has_hangul_syllables) {
+
+                    # Construct a regular expression of all the possible
+                    # combinations of the Hangul syllables.
+                    my @L_re;   # Leading consonants
+                    for my $i ($LBase .. $LBase + $LCount - 1) {
+                        push @L_re, $Jamo{$i}
+                    }
+                    my @V_re;   # Middle vowels
+                    for my $i ($VBase .. $VBase + $VCount - 1) {
+                        push @V_re, $Jamo{$i}
+                    }
+                    my @T_re;   # Trailing consonants
+                    for my $i ($TBase + 1 .. $TBase + $TCount - 1) {
+                        push @T_re, $Jamo{$i}
+                    }
+
+                    # The whole re is made up of the L V T combination.
+                    $jamo_re = '('
+                               . join ('|', sort @L_re)
+                               . ')('
+                               . join ('|', sort @V_re)
+                               . ')('
+                               . join ('|', sort @T_re)
+                               . ')?';
+
+                    # These hashes needed by the algorithm were generated
+                    # during reading of the Jamo.txt file
+                    $jamo = main::simple_dumper(\%Jamo, ' ' x 8);
+                    $jamo_l = main::simple_dumper(\%Jamo_L, ' ' x 8);
+                    $jamo_v = main::simple_dumper(\%Jamo_V, ' ' x 8);
+                    $jamo_t = main::simple_dumper(\%Jamo_T, ' ' x 8);
+                }
+
+                $pre_body .= <<END;
+
+# To achieve significant memory savings when this file is read in,
+# algorithmically derivable code points are omitted from the main body below.
+# Instead, the following routines can be used to translate between name and
+# code point and vice versa
+
+{ # Closure
+
+    # Matches legal code point.  4-6 hex numbers, If there are 6, the
+    # first two must be '10'; if there are 5, the first must not be a '0'.
+    my \$code_point_re = qr/$code_point_re/;
+
+    # In the following hash, the keys are the bases of names which includes
+    # the code point in the name, like CJK UNIFIED IDEOGRAPH-4E01.  The values
+    # of each key is another hash which is used to get the low and high ends
+    # for each range of code points that apply to the name
+    my %names_ending_in_code_point = (
+$names
+    );
+
+    # And the following array gives the inverse mapping from code points to
+    # names.  Lowest code points are first
+    my \@code_points_ending_in_code_point = (
+$code_points_ending_in_code_point
+    );
+END
+                # Earlier releases didn't have Jamos.  No sense outputting
+                # them unless will be used.
+                if ($has_hangul_syllables) {
+                    $pre_body .= <<END;
+
+    # Convert from code point to Jamo short name for use in composing Hangul
+    # syllable names
+    my %Jamo = (
+$jamo
+    );
+
+    # Leading consonant (can be null)
+    my %Jamo_L = (
+$jamo_l
+    );
+
+    # Vowel
+    my %Jamo_V = (
+$jamo_v
+    );
+
+    # Optional trailing consonant
+    my %Jamo_T = (
+$jamo_t
+    );
+
+    # Computed re that splits up a Hangul name into LVT or LV syllables
+    my \$syllable_re = qr/$jamo_re/;
+
+    my \$HANGUL_SYLLABLE = "HANGUL SYLLABLE ";
+    my \$HANGUL_SYLLABLE_LENGTH = length \$HANGUL_SYLLABLE;
+
+    # These constants names and values were taken from the Unicode standard,
+    # version 5.1, section 3.12.  They are used in conjunction with Hangul
+    # syllables
+    my \$SBase = 0xAC00;
+    my \$LBase = 0x1100;
+    my \$VBase = 0x1161;
+    my \$TBase = 0x11A7;
+    my \$SCount = 11172;
+    my \$LCount = 19;
+    my \$VCount = 21;
+    my \$TCount = 28;
+    my \$NCount = \$VCount * \$TCount;
+END
+                } # End of has Jamos
+
+                $pre_body .= << 'END';
+
+    sub name_to_code_point_special {
+        my $name = shift;
+
+        # Returns undef if not one of the specially handled names; otherwise
+        # returns the code point equivalent to the input name
+END
+                if ($has_hangul_syllables) {
+                    $pre_body .= << 'END';
+
+        if (substr($name, 0, $HANGUL_SYLLABLE_LENGTH) eq $HANGUL_SYLLABLE) {
+            $name = substr($name, $HANGUL_SYLLABLE_LENGTH);
+            return if $name !~ qr/^$syllable_re$/;
+            my $L = $Jamo_L{$1};
+            my $V = $Jamo_V{$2};
+            my $T = (defined $3) ? $Jamo_T{$3} : 0;
+            return ($L * $VCount + $V) * $TCount + $T + $SBase;
+        }
+END
+                }
+                $pre_body .= << 'END';
+
+        # Name must end in '-code_point' for this to handle.
+        if ($name !~ /^ (.*) - ($code_point_re) $/x) {
+            return;
+        }
+
+        my $base = $1;
+        my $code_point = CORE::hex $2;
+
+        # Name must be one of the ones which has the code point in it.
+        return if ! $names_ending_in_code_point{$base};
+
+        # Look through the list of ranges that apply to this name to see if
+        # the code point is in one of them.
+        for (my $i = 0; $i < scalar @{$names_ending_in_code_point{$base}{'low'}}; $i++) {
+            return if $names_ending_in_code_point{$base}{'low'}->[$i] > $code_point;
+            next if $names_ending_in_code_point{$base}{'high'}->[$i] < $code_point;
+
+            # Here, the code point is in the range.
+            return $code_point;
+        }
+
+        # Here, looked like the name had a code point number in it, but
+        # did not match one of the valid ones.
+        return;
+    }
+
+    sub code_point_to_name_special {
+        my $code_point = shift;
+
+        # Returns the name of a code point if algorithmically determinable;
+        # undef if not
+END
+                if ($has_hangul_syllables) {
+                    $pre_body .= << 'END';
+
+        # If in the Hangul range, calculate the name based on Unicode's
+        # algorithm
+        if ($code_point >= $SBase && $code_point <= $SBase + $SCount -1) {
+            use integer;
+            my $SIndex = $code_point - $SBase;
+            my $L = $LBase + $SIndex / $NCount;
+            my $V = $VBase + ($SIndex % $NCount) / $TCount;
+            my $T = $TBase + $SIndex % $TCount;
+            $name = "$HANGUL_SYLLABLE $Jamo{$L}$Jamo{$V}";
+            $name .= $Jamo{$T} if $T != $TBase;
+            return $name;
+        }
+END
+                }
+                $pre_body .= << 'END';
+
+        # Look through list of these code points for one in range.
+        foreach my $hash (@code_points_ending_in_code_point) {
+            return if $code_point < $hash->{'low'};
+            if ($code_point <= $hash->{'high'}) {
+                return sprintf("%s-%04X", $hash->{'name'}, $code_point);
+            }
+        }
+        return;            # None found
+    }
+} # End closure
+
+END
+            } # End of has hangul or code point in name maps.
+        } # End of has specials
+
+        # Calculate the format of the table if not already done.
+        my $format = $format{$addr};
+        my $property = $self->property;
+        my $type = $property->type;
+        if (! defined $format) {
+            if ($type == $BINARY) {
+
+                # Don't bother checking the values, because we elsewhere
+                # verify that a binary table has only 2 values.
+                $format = $BINARY_FORMAT;
+            }
+            else {
+                my @ranges = $self->_range_list->ranges;
+
+                # default an empty table based on its type and default map
+                if (! @ranges) {
+
+                    # But it turns out that the only one we can say is a
+                    # non-string (besides binary, handled above) is when the
+                    # table is a string and the default map is to a code point
+                    if ($type == $STRING && $default_map eq $CODE_POINT) {
+                        $format = $HEX_FORMAT;
+                    }
+                    else {
+                        $format = $STRING_FORMAT;
+                    }
+                }
+                else {
+
+                    # Start with the most restrictive format, and as we find
+                    # something that doesn't fit with that, change to the next
+                    # most restrictive, and so on.
+                    $format = $DECIMAL_FORMAT;
+                    foreach my $range (@ranges) {
+                        my $map = $range->value;
+                        if ($map ne $default_map) {
+                            last if $format eq $STRING_FORMAT;  # already at
+                                                                # least
+                                                                # restrictive
+                            $format = $INTEGER_FORMAT
+                                                if $format eq $DECIMAL_FORMAT
+                                                    && $map !~ / ^ [0-9] $ /x;
+                            $format = $FLOAT_FORMAT
+                                            if $format eq $INTEGER_FORMAT
+                                                && $map !~ / ^ -? [0-9]+ $ /x;
+                            $format = $RATIONAL_FORMAT
+                                if $format eq $FLOAT_FORMAT
+                                    && $map !~ / ^ -? [0-9]+ \. [0-9]* $ /x;
+                            $format = $HEX_FORMAT
+                            if $format eq $RATIONAL_FORMAT
+                                && $map !~ / ^ -? [0-9]+ ( \/ [0-9]+ )? $ /x;
+                            $format = $STRING_FORMAT if $format eq $HEX_FORMAT
+                                                       && $map =~ /[^0-9A-F]/;
+                        }
+                    }
+                }
+            }
+        } # end of calculating format
+
+        my $return = <<END;
+# The name this swash is to be known by, with the format of the mappings in
+# the main body of the table, and what all code points missing from this file
+# map to.
+\$utf8::SwashInfo{'To$name'}{'format'} = '$format'; # $map_table_formats{$format}
+END
+        my $missing = $default_map;
+        if ($missing eq $CODE_POINT
+            && $format ne $HEX_FORMAT
+            && ! defined $format{$addr})    # Is expected if was manually set
+        {
+            Carp::my_carp_bug("Expecting hex format for mapping table for $self, instead got '$format'")
+        }
+        $format{$addr} = $format;
+        $return .= "\$utf8::SwashInfo{'To$name'}{'missing'} = '$missing';";
+        if ($missing eq $CODE_POINT) {
+            $return .= ' # code point maps to itself';
+        }
+        elsif ($missing eq "") {
+            $return .= ' # code point maps to the null string';
+        }
+        $return .= "\n";
+
+        $return .= $pre_body;
+
+        return $return;
+    }
+
+    sub write {
+        # Write the table to the file.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        return $self->SUPER::write(
+            ($self->property == $block)
+                ? 7     # block file needs more tab stops
+                : 3,
+            $default_map{$addr});   # don't write defaulteds
+    }
+
+    # Accessors for the underlying list that should fail if locked.
+    for my $sub qw(
+                    add_duplicate
+                )
+    {
+        no strict "refs";
+        *$sub = sub {
+            use strict "refs";
+            my $self = shift;
+
+            return if $self->carp_if_locked;
+            return $self->_range_list->$sub(@_);
+        }
+    }
+} # End closure for Map_Table
+
+package Match_Table;
+use base '_Base_Table';
+
+# A Match table is one which is a list of all the code points that have
+# the same property and property value, for use in \p{property=value}
+# constructs in regular expressions.  It adds very little data to the base
+# structure, but many methods, as these lists can be combined in many ways to
+# form new ones.
+# There are only a few concepts added:
+# 1) Equivalents and Relatedness.
+#    Two tables can match the identical code points, but have different names.
+#    This always happens when there is a perl single form extension
+#    \p{IsProperty} for the Unicode compound form \P{Property=True}.  The two
+#    tables are set to be related, with the Perl extension being a child, and
+#    the Unicode property being the parent.
+#
+#    It may be that two tables match the identical code points and we don't
+#    know if they are related or not.  This happens most frequently when the
+#    Block and Script properties have the exact range.  But note that a
+#    revision to Unicode could add new code points to the script, which would
+#    now have to be in a different block (as the block was filled, or there
+#    would have been 'Unknown' script code points in it and they wouldn't have
+#    been identical).  So we can't rely on any two properties from Unicode
+#    always matching the same code points from release to release, and thus
+#    these tables are considered coincidentally equivalent--not related.  When
+#    two tables are unrelated but equivalent, one is arbitrarily chosen as the
+#    'leader', and the others are 'equivalents'.  This concept is useful
+#    to minimize the number of tables written out.  Only one file is used for
+#    any identical set of code points, with entries in Heavy.pl mapping all
+#    the involved tables to it.
+#
+#    Related tables will always be identical; we set them up to be so.  Thus
+#    if the Unicode one is deprecated, the Perl one will be too.  Not so for
+#    unrelated tables.  Relatedness makes generating the documentation easier.
+#
+# 2) Conflicting.  It may be that there will eventually be name clashes, with
+#    the same name meaning different things.  For a while, there actually were
+#    conflicts, but they have so far been resolved by changing Perl's or
+#    Unicode's definitions to match the other, but when this code was written,
+#    it wasn't clear that that was what was going to happen.  (Unicode changed
+#    because of protests during their beta period.)  Name clashes are warned
+#    about during compilation, and the documentation.  The generated tables
+#    are sane, free of name clashes, because the code suppresses the Perl
+#    version.  But manual intervention to decide what the actual behavior
+#    should be may be required should this happen.  The introductory comments
+#    have more to say about this.
+
+sub standardize { return main::standardize($_[0]); }
+sub trace { return main::trace(@_); }
+
+
+{ # Closure
+
+    main::setup_package();
+
+    my %leader;
+    # The leader table of this one; initially $self.
+    main::set_access('leader', \%leader, 'r');
+
+    my %equivalents;
+    # An array of any tables that have this one as their leader
+    main::set_access('equivalents', \%equivalents, 'readable_array');
+
+    my %parent;
+    # The parent table to this one, initially $self.  This allows us to
+    # distinguish between equivalent tables that are related, and those which
+    # may not be, but share the same output file because they match the exact
+    # same set of code points in the current Unicode release.
+    main::set_access('parent', \%parent, 'r');
+
+    my %children;
+    # An array of any tables that have this one as their parent
+    main::set_access('children', \%children, 'readable_array');
+
+    my %conflicting;
+    # Array of any tables that would have the same name as this one with
+    # a different meaning.  This is used for the generated documentation.
+    main::set_access('conflicting', \%conflicting, 'readable_array');
+
+    my %matches_all;
+    # Set in the constructor for tables that are expected to match all code
+    # points.
+    main::set_access('matches_all', \%matches_all, 'r');
+
+    sub new {
+        my $class = shift;
+
+        my %args = @_;
+
+        # The property for which this table is a listing of property values.
+        my $property = delete $args{'_Property'};
+
+        # Optional
+        my $initialize = delete $args{'Initialize'};
+        my $matches_all = delete $args{'Matches_All'} || 0;
+        # Rest of parameters passed on.
+
+        my $range_list = Range_List->new(Initialize => $initialize,
+                                         Owner => $property);
+
+        my $self = $class->SUPER::new(%args,
+                                      _Property => $property,
+                                      _Range_List => $range_list,
+                                      );
+        my $addr = main::objaddr $self;
+
+        $conflicting{$addr} = [ ];
+        $equivalents{$addr} = [ ];
+        $children{$addr} = [ ];
+        $matches_all{$addr} = $matches_all;
+        $leader{$addr} = $self;
+        $parent{$addr} = $self;
+
+        return $self;
+    }
+
+    # See this program's beginning comment block about overloading these.
+    use overload
+        fallback => 0,
+        qw("") => "_operator_stringify",
+        '=' => sub {
+                    my $self = shift;
+
+                    return if $self->carp_if_locked;
+                    return $self;
+                },
+
+        '+' => sub {
+                        my $self = shift;
+                        my $other = shift;
+
+                        return $self->_range_list + $other;
+                    },
+        '&' => sub {
+                        my $self = shift;
+                        my $other = shift;
+
+                        return $self->_range_list & $other;
+                    },
+        '+=' => sub {
+                        my $self = shift;
+                        my $other = shift;
+
+                        return if $self->carp_if_locked;
+
+                        my $addr = main::objaddr $self;
+
+                        if (ref $other) {
+
+                            # Change the range list of this table to be the
+                            # union of the two.
+                            $self->_set_range_list($self->_range_list
+                                                    + $other);
+                        }
+                        else {    # $other is just a simple value
+                            $self->add_range($other, $other);
+                        }
+                        return $self;
+                    },
+        '-' => sub { my $self = shift;
+                    my $other = shift;
+                    my $reversed = shift;
+
+                    if ($reversed) {
+                        Carp::my_carp_bug("Can't cope with a "
+                            .  __PACKAGE__
+                            . " being the first parameter in a '-'.  Subtraction ignored.");
+                        return;
+                    }
+
+                    return $self->_range_list - $other;
+                },
+        '~' => sub { my $self = shift;
+                    return ~ $self->_range_list;
+                },
+    ;
+
+    sub _operator_stringify {
+        my $self = shift;
+
+        my $name= $self->complete_name;
+        return "Table '$name'";
+    }
+
+    sub add_alias {
+        # Add a synonym for this table.  See the comments in the base class
+
+        my $self = shift;
+        my $name = shift;
+        # Rest of parameters passed on.
+
+        $self->SUPER::add_alias($name, $self, @_);
+        return;
+    }
+
+    sub add_conflicting {
+        # Add the name of some other object to the list of ones that name
+        # clash with this match table.
+
+        my $self = shift;
+        my $conflicting_name = shift;   # The name of the conflicting object
+        my $p = shift || 'p';           # Optional, is this a \p{} or \P{} ?
+        my $conflicting_object = shift; # Optional, the conflicting object
+                                        # itself.  This is used to
+                                        # disambiguate the text if the input
+                                        # name is identical to any of the
+                                        # aliases $self is known by.
+                                        # Sometimes the conflicting object is
+                                        # merely hypothetical, so this has to
+                                        # be an optional parameter.
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        # Check if the conflicting name is exactly the same as any existing
+        # alias in this table (as long as there is a real object there to
+        # disambiguate with).
+        if (defined $conflicting_object) {
+            foreach my $alias ($self->aliases) {
+                if ($alias->name eq $conflicting_name) {
+
+                    # Here, there is an exact match.  This results in
+                    # ambiguous comments, so disambiguate by changing the
+                    # conflicting name to its object's complete equivalent.
+                    $conflicting_name = $conflicting_object->complete_name;
+                    last;
+                }
+            }
+        }
+
+        # Convert to the \p{...} final name
+        $conflicting_name = "\\$p" . "{$conflicting_name}";
+
+        # Only add once
+        return if grep { $conflicting_name eq $_ } @{$conflicting{$addr}};
+
+        push @{$conflicting{$addr}}, $conflicting_name;
+
+        return;
+    }
+
+    sub is_equivalent_to {
+        # Return boolean of whether or not the other object is a table of this
+        # type and has been marked equivalent to this one.
+
+        my $self = shift;
+        my $other = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        return 0 if ! defined $other; # Can happen for incomplete early
+                                      # releases
+        unless ($other->isa(__PACKAGE__)) {
+            my $ref_other = ref $other;
+            my $ref_self = ref $self;
+            Carp::my_carp_bug("Argument to 'is_equivalent_to' must be another $ref_self, not a '$ref_other'.  $other not set equivalent to $self.");
+            return 0;
+        }
+
+        # Two tables are equivalent if they have the same leader.
+        return $leader{main::objaddr $self}
+                == $leader{main::objaddr $other};
+        return;
+    }
+
+    sub matches_identically_to {
+        # Return a boolean as to whether or not two tables match identical
+        # sets of code points.
+
+        my $self = shift;
+        my $other = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        unless ($other->isa(__PACKAGE__)) {
+            my $ref_other = ref $other;
+            my $ref_self = ref $self;
+            Carp::my_carp_bug("Argument to 'matches_identically_to' must be another $ref_self, not a '$ref_other'.  $other not set equivalent to $self.");
+            return 0;
+        }
+
+        # These are ordered in increasing real time to figure out (at least
+        # until a patch changes that and doesn't change this)
+        return 0 if $self->max != $other->max;
+        return 0 if $self->min != $other->min;
+        return 0 if $self->range_count != $other->range_count;
+        return 0 if $self->count != $other->count;
+
+        # Here they could be identical because all the tests above passed.
+        # The loop below is somewhat simpler since we know they have the same
+        # number of elements.  Compare range by range, until reach the end or
+        # find something that differs.
+        my @a_ranges = $self->_range_list->ranges;
+        my @b_ranges = $other->_range_list->ranges;
+        for my $i (0 .. @a_ranges - 1) {
+            my $a = $a_ranges[$i];
+            my $b = $b_ranges[$i];
+            trace "self $a; other $b" if main::DEBUG && $to_trace;
+            return 0 if $a->start != $b->start || $a->end != $b->end;
+        }
+        return 1;
+    }
+
+    sub set_equivalent_to {
+        # Set $self equivalent to the parameter table.
+        # The required Related => 'x' parameter is a boolean indicating
+        # whether these tables are related or not.  If related, $other becomes
+        # the 'parent' of $self; if unrelated it becomes the 'leader'
+        #
+        # Related tables share all characteristics except names; equivalents
+        # not quite so many.
+        # If they are related, one must be a perl extension.  This is because
+        # we can't guarantee that Unicode won't change one or the other in a
+        # later release even if they are idential now.
+
+        my $self = shift;
+        my $other = shift;
+
+        my %args = @_;
+        my $related = delete $args{'Related'};
+
+        Carp::carp_extra_args(\%args) if main::DEBUG && %args;
+
+        return if ! defined $other;     # Keep on going; happens in some early
+                                        # Unicode releases.
+
+        if (! defined $related) {
+            Carp::my_carp_bug("set_equivalent_to must have 'Related => [01] parameter.  Assuming $self is not related to $other");
+            $related = 0;
+        }
+
+        # If already are equivalent, no need to re-do it;  if subroutine
+        # returns null, it found an error, also do nothing
+        my $are_equivalent = $self->is_equivalent_to($other);
+        return if ! defined $are_equivalent || $are_equivalent;
+
+        my $current_leader = ($related)
+                             ? $parent{main::objaddr $self}
+                             : $leader{main::objaddr $self};
+
+        if ($related &&
+            ! $other->perl_extension
+            && ! $current_leader->perl_extension)
+        {
+            Carp::my_carp_bug("set_equivalent_to should have 'Related => 0 for equivalencing two Unicode properties.  Assuming $self is not related to $other");
+            $related = 0;
+        }
+
+        my $leader = main::objaddr $current_leader;
+        my $other_addr = main::objaddr $other;
+
+        # Any tables that are equivalent to or children of this table must now
+        # instead be equivalent to or (children) to the new leader (parent),
+        # still equivalent.  The equivalency includes their matches_all info,
+        # and for related tables, their status
+        # All related tables are of necessity equivalent, but the converse
+        # isn't necessarily true
+        my $status = $other->status;
+        my $status_info = $other->status_info;
+        my $matches_all = $matches_all{other_addr};
+        foreach my $table ($current_leader, @{$equivalents{$leader}}) {
+            next if $table == $other;
+            trace "setting $other to be the leader of $table, status=$status" if main::DEBUG && $to_trace;
+
+            my $table_addr = main::objaddr $table;
+            $leader{$table_addr} = $other;
+            $matches_all{$table_addr} = $matches_all;
+            $self->_set_range_list($other->_range_list);
+            push @{$equivalents{$other_addr}}, $table;
+            if ($related) {
+                $parent{$table_addr} = $other;
+                push @{$children{$other_addr}}, $table;
+                $table->set_status($status, $status_info);
+            }
+        }
+
+        # Now that we've declared these to be equivalent, any changes to one
+        # of the tables would invalidate that equivalency.
+        $self->lock;
+        $other->lock;
+        return;
+    }
+
+    sub add_range { # Add a range to the list for this table.
+        my $self = shift;
+        # Rest of parameters passed on
+
+        return if $self->carp_if_locked;
+        return $self->_range_list->add_range(@_);
+    }
+
+    sub complete_name {
+        # The complete name for a match table includes it's property in a
+        # compound form 'property=table', except if the property is the
+        # pseudo-property, perl, in which case it is just the single form,
+        # 'table'
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $name = $self->full_name;
+        my $property = $self->property;
+        $name = '""' if $name eq "";  # A null name shouldn't happen, but this
+                                      # helps debug if it does
+        return $name if $property == $perl;
+
+        # (If change the '=' must also change the ':' in set_final_comment(),
+        # and the references to colon in its text)
+        return $property->full_name . '=' . $name;
+    }
+
+    sub pre_body {  # Does nothing for match tables.
+        return
+    }
+
+    sub append_to_body {  # Does nothing for match tables.
+        return
+    }
+
+    sub write {
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        return $self->SUPER::write(2); # 2 tab stops
+    }
+
+    sub set_final_comment {
+        # This creates a comment for the file that is to hold the match table
+        # $self.  It is somewhat convoluted to make the English read nicely,
+        # but, heh, it's just a comment.
+        # This should be called only with the leader match table of all the
+        # ones that share the same file.  It lists all such tables, ordered so
+        # that related ones are together.
+
+        my $leader = shift;   # Should only be called on the leader table of
+                              # an equivalent group
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $leader;
+
+        if ($leader{$addr} != $leader) {
+            Carp::my_carp_bug(<<END
+set_final_comment() must be called on a leader table, which $leader is not.
+It is equivalent to $leader{$addr}.  No comment created
+END
+            );
+            return;
+        }
+
+        # Get the number of code points matched by each of the tables in this
+        # file, and add underscores for clarity.
+        my $count = $leader->count;
+        my $string_count = main::clarify_number($count);
+
+        my $loose_count = 0;        # how many aliases loosely matched
+        my $compound_name = "";     # ? Are any names compound?, and if so, an
+                                    # example
+        my $properties_with_compound_names = 0;    # count of these
+
+
+        my %flags;              # The status flags used in the file
+        my $total_entries = 0;  # number of entries written in the comment
+        my $matches_comment = ""; # The portion of the comment about the
+                                  # \p{}'s
+        my @global_comments;    # List of all the tables' comments that are
+                                # there before this routine was called.
+
+        # Get list of all the parent tables that are equivalent to this one
+        # (including itself).
+        my @parents = grep { $parent{main::objaddr $_} == $_ }
+                            main::uniques($leader, @{$equivalents{$addr}});
+        my $has_unrelated = (@parents >= 2);  # boolean, ? are there unrelated
+                                              # tables
+
+        for my $parent (@parents) {
+
+            my $property = $parent->property;
+
+            # Special case 'N' tables in properties with two match tables when
+            # the other is a 'Y' one.  These are likely to be binary tables,
+            # but not necessarily.  In either case, \P{} will match the
+            # complement of \p{}, and so if something is a synonym of \p, the
+            # complement of that something will be the synonym of \P.  This
+            # would be true of any property with just two match tables, not
+            # just those whose values are Y and N; but that would require a
+            # little extra work, and there are none such so far in Unicode.
+            my $perl_p = 'p';        # which is it?  \p{} or \P{}
+            my @yes_perl_synonyms;   # list of any synonyms for the 'Y' table
+
+            if (scalar $property->tables == 2
+                && $parent == $property->table('N')
+                && defined (my $yes = $property->table('Y')))
+            {
+                my $yes_addr = main::objaddr $yes;
+                @yes_perl_synonyms
+                    = grep { $_->property == $perl }
+                                    main::uniques($yes,
+                                                $parent{$yes_addr},
+                                                $parent{$yes_addr}->children);
+
+                # But these synonyms are \P{} ,not \p{}
+                $perl_p = 'P';
+            }
+
+            my @description;        # Will hold the table description
+            my @note;               # Will hold the table notes.
+            my @conflicting;        # Will hold the table conflicts.
+
+            # Look at the parent, any yes synonyms, and all the children
+            for my $table ($parent,
+                           @yes_perl_synonyms,
+                           @{$children{main::objaddr $parent}})
+            {
+                my $table_addr = main::objaddr $table;
+                my $table_property = $table->property;
+
+                # Tables are separated by a blank line to create a grouping.
+                $matches_comment .= "\n" if $matches_comment;
+
+                # The table is named based on the property and value
+                # combination it is for, like script=greek.  But there may be
+                # a number of synonyms for each side, like 'sc' for 'script',
+                # and 'grek' for 'greek'.  Any combination of these is a valid
+                # name for this table.  In this case, there are three more,
+                # 'sc=grek', 'sc=greek', and 'script='grek'.  Rather than
+                # listing all possible combinations in the comment, we make
+                # sure that each synonym occurs at least once, and add
+                # commentary that the other combinations are possible.
+                my @property_aliases = $table_property->aliases;
+                my @table_aliases = $table->aliases;
+
+                Carp::my_carp_bug("$table doesn't have any names.  Proceeding anyway.") unless @table_aliases;
+
+                # The alias lists above are already ordered in the order we
+                # want to output them.  To ensure that each synonym is listed,
+                # we must use the max of the two numbers.
+                my $listed_combos = main::max(scalar @table_aliases,
+                                                scalar @property_aliases);
+                trace "$listed_combos, tables=", scalar @table_aliases, "; names=", scalar @property_aliases if main::DEBUG;
+
+                my $property_had_compound_name = 0;
+
+                for my $i (0 .. $listed_combos - 1) {
+                    $total_entries++;
+
+                    # The current alias for the property is the next one on
+                    # the list, or if beyond the end, start over.  Similarly
+                    # for the table (\p{prop=table})
+                    my $property_alias = $property_aliases
+                                            [$i % @property_aliases]->name;
+                    my $table_alias_object = $table_aliases
+                                                        [$i % @table_aliases];
+                    my $table_alias = $table_alias_object->name;
+                    my $loose_match = $table_alias_object->loose_match;
+
+                    if ($table_alias !~ /\D/) { # Clarify large numbers.
+                        $table_alias = main::clarify_number($table_alias)
+                    }
+
+                    # Add a comment for this alias combination
+                    my $current_match_comment;
+                    if ($table_property == $perl) {
+                        $current_match_comment = "\\$perl_p"
+                                                    . "{$table_alias}";
+                    }
+                    else {
+                        $current_match_comment
+                                        = "\\p{$property_alias=$table_alias}";
+                        $property_had_compound_name = 1;
+                    }
+
+                    # Flag any abnormal status for this table.
+                    my $flag = $property->status
+                                || $table->status
+                                || $table_alias_object->status;
+                    $flags{$flag} = $status_past_participles{$flag} if $flag;
+
+                    $loose_count++;
+
+                    # Pretty up the comment.  Note the \b; it says don't make
+                    # this line a continuation.
+                    $matches_comment .= sprintf("\b%-1s%-s%s\n",
+                                        $flag,
+                                        " " x 7,
+                                        $current_match_comment);
+                } # End of generating the entries for this table.
+
+                # Save these for output after this group of related tables.
+                push @description, $table->description;
+                push @note, $table->note;
+                push @conflicting, $table->conflicting;
+
+                # Compute an alternate compound name using the final property
+                # synonym and the first table synonym with a colon instead of
+                # the equal sign used elsewhere.
+                if ($property_had_compound_name) {
+                    $properties_with_compound_names ++;
+                    if (! $compound_name || @property_aliases > 1) {
+                        $compound_name = $property_aliases[-1]->name
+                                        . ': '
+                                        . $table_aliases[0]->name;
+                    }
+                }
+            } # End of looping through all children of this table
+
+            # Here have assembled in $matches_comment all the related tables
+            # to the current parent (preceded by the same info for all the
+            # previous parents).  Put out information that applies to all of
+            # the current family.
+            if (@conflicting) {
+
+                # But output the conflicting information now, as it applies to
+                # just this table.
+                my $conflicting = join ", ", @conflicting;
+                if ($conflicting) {
+                    $matches_comment .= <<END;
+
+    Note that contrary to what you might expect, the above is NOT the same as
+END
+                    $matches_comment .= "any of: " if @conflicting > 1;
+                    $matches_comment .= "$conflicting\n";
+                }
+            }
+            if (@description) {
+                $matches_comment .= "\n    Meaning: "
+                                    . join('; ', @description)
+                                    . "\n";
+            }
+            if (@note) {
+                $matches_comment .= "\n    Note: "
+                                    . join("\n    ", @note)
+                                    . "\n";
+            }
+        } # End of looping through all tables
+
+
+        my $code_points;
+        my $match;
+        my $any_of_these;
+        if ($count == 1) {
+            $match = 'matches';
+            $code_points = 'single code point';
+        }
+        else {
+            $match = 'match';
+            $code_points = "$string_count code points";
+        }
+
+        my $synonyms;
+        my $entries;
+        if ($total_entries <= 1) {
+            $synonyms = "";
+            $entries = 'entry';
+            $any_of_these = 'this'
+        }
+        else {
+            $synonyms = " any of the following regular expression constructs";
+            $entries = 'entries';
+            $any_of_these = 'any of these'
+        }
+
+        my $comment = "";
+        if ($has_unrelated) {
+            $comment .= <<END;
+This file is for tables that are not necessarily related:  To conserve
+resources, every table that matches the identical set of code points in this
+version of Unicode uses this file.  Each one is listed in a separate group
+below.  It could be that the tables will match the same set of code points in
+other Unicode releases, or it could be purely coincidence that they happen to
+be the same in Unicode $string_version, and hence may not in other versions.
+
+END
+        }
+
+        if (%flags) {
+            foreach my $flag (sort keys %flags) {
+                $comment .= <<END;
+'$flag' below means that this form is $flags{$flag}.  Consult $pod_file.pod
+END
+            }
+            $comment .= "\n";
+        }
+
+        $comment .= <<END;
+This file returns the $code_points in Unicode Version $string_version that
+$match$synonyms:
+
+$matches_comment
+$pod_file.pod should be consulted for the rules on using $any_of_these,
+including if adding or subtracting white space, underscore, and hyphen
+characters matters or doesn't matter, and other permissible syntactic
+variants.  Upper/lower case distinctions never matter.
+END
+
+        if ($compound_name) {
+            $comment .= <<END;
+
+A colon can be substituted for the equals sign, and
+END
+            if ($properties_with_compound_names > 1) {
+                $comment .= <<END;
+within each group above,
+END
+            }
+            $compound_name = sprintf("%-8s\\p{%s}", " ", $compound_name);
+
+            # Note the \b below, it says don't make that line a continuation.
+            $comment .= <<END;
+anything to the left of the equals (or colon) can be combined with anything to
+the right.  Thus, for example,
+$compound_name
+\bis also valid.
+END
+        }
+
+        # And append any comment(s) from the actual tables.  They are all
+        # gathered here, so may not read all that well.
+        $comment .= "\n" . join "\n\n", @global_comments if @global_comments;
+
+        if ($count) {   # The format differs if no code points, and needs no
+                        # explanation in that case
+                $comment.= <<END;
+
+The format of the lines of this file is:
+END
+            $comment.= <<END;
+START\\tSTOP\\twhere START is the starting code point of the range, in hex;
+STOP is the ending point, or if omitted, the range has just one code point.
+END
+            if ($output_range_counts) {
+                $comment .= <<END;
+Numbers in comments in [brackets] indicate how many code points are in the
+range.
+END
+            }
+        }
+
+        $leader->set_comment(main::join_lines($comment));
+        return;
+    }
+
+    # Accessors for the underlying list
+    for my $sub qw(
+                    get_valid_code_point
+                    get_invalid_code_point
+                )
+    {
+        no strict "refs";
+        *$sub = sub {
+            use strict "refs";
+            my $self = shift;
+
+            return $self->_range_list->$sub(@_);
+        }
+    }
+} # End closure for Match_Table
+
+package Property;
+
+# The Property class represents a Unicode property, or the $perl
+# pseudo-property.  It contains a map table initialized empty at construction
+# time, and for properties accessible through regular expressions, various
+# match tables, created through the add_match_table() method, and referenced
+# by the table('NAME') or tables() methods, the latter returning a list of all
+# of the match tables.  Otherwise table operations implicitly are for the map
+# table.
+#
+# Most of the data in the property is actually about its map table, so it
+# mostly just uses that table's accessors for most methods.  The two could
+# have been combined into one object, but for clarity because of their
+# differing semantics, they have been kept separate.  It could be argued that
+# the 'file' and 'directory' fields should be kept with the map table.
+#
+# Each property has a type.  This can be set in the constructor, or in the
+# set_type accessor, but mostly it is figured out by the data.  Every property
+# starts with unknown type, overridden by a parameter to the constructor, or
+# as match tables are added, or ranges added to the map table, the data is
+# inspected, and the type changed.  After the table is mostly or entirely
+# filled, compute_type() should be called to finalize they analysis.
+#
+# There are very few operations defined.  One can safely remove a range from
+# the map table, and property_add_or_replace_non_nulls() adds the maps from another
+# table to this one, replacing any in the intersection of the two.
+
+sub standardize { return main::standardize($_[0]); }
+sub trace { return main::trace(@_) if main::DEBUG && $to_trace }
+
+{   # Closure
+
+    # This hash will contain as keys, all the aliases of all properties, and
+    # as values, pointers to their respective property objects.  This allows
+    # quick look-up of a property from any of its names.
+    my %alias_to_property_of;
+
+    sub dump_alias_to_property_of {
+        # For debugging
+
+        print "\n", main::simple_dumper (\%alias_to_property_of), "\n";
+        return;
+    }
+
+    sub property_ref {
+        # This is a package subroutine, not called as a method.
+        # If the single parameter is a literal '*' it returns a list of all
+        # defined properties.
+        # Otherwise, the single parameter is a name, and it returns a pointer
+        # to the corresponding property object, or undef if none.
+        #
+        # Properties can have several different names.  The 'standard' form of
+        # each of them is stored in %alias_to_property_of as they are defined.
+        # But it's possible that this subroutine will be called with some
+        # variant, so if the initial lookup fails, it is repeated with the
+        # standarized form of the input name.  If found, besides returning the
+        # result, the input name is added to the list so future calls won't
+        # have to do the conversion again.
+
+        my $name = shift;
+
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        if (! defined $name) {
+            Carp::my_carp_bug("Undefined input property.  No action taken.");
+            return;
+        }
+
+        return main::uniques(values %alias_to_property_of) if $name eq '*';
+
+        # Return cached result if have it.
+        my $result = $alias_to_property_of{$name};
+        return $result if defined $result;
+
+        # Convert the input to standard form.
+        my $standard_name = standardize($name);
+
+        $result = $alias_to_property_of{$standard_name};
+        return unless defined $result;        # Don't cache undefs
+
+        # Cache the result before returning it.
+        $alias_to_property_of{$name} = $result;
+        return $result;
+    }
+
+
+    main::setup_package();
+
+    my %map;
+    # A pointer to the map table object for this property
+    main::set_access('map', \%map);
+
+    my %full_name;
+    # The property's full name.  This is a duplicate of the copy kept in the
+    # map table, but is needed because stringify needs it during
+    # construction of the map table, and then would have a chicken before egg
+    # problem.
+    main::set_access('full_name', \%full_name, 'r');
+
+    my %table_ref;
+    # This hash will contain as keys, all the aliases of any match tables
+    # attached to this property, and as values, the pointers to their
+    # respective tables.  This allows quick look-up of a table from any of its
+    # names.
+    main::set_access('table_ref', \%table_ref);
+
+    my %type;
+    # The type of the property, $ENUM, $BINARY, etc
+    main::set_access('type', \%type, 'r');
+
+    my %file;
+    # The filename where the map table will go (if actually written).
+    # Normally defaulted, but can be overridden.
+    main::set_access('file', \%file, 'r', 's');
+
+    my %directory;
+    # The directory where the map table will go (if actually written).
+    # Normally defaulted, but can be overridden.
+    main::set_access('directory', \%directory, 's');
+
+    my %pseudo_map_type;
+    # This is used to affect the calculation of the map types for all the
+    # ranges in the table.  It should be set to one of the values that signify
+    # to alter the calculation.
+    main::set_access('pseudo_map_type', \%pseudo_map_type, 'r');
+
+    my %has_only_code_point_maps;
+    # A boolean used to help in computing the type of data in the map table.
+    main::set_access('has_only_code_point_maps', \%has_only_code_point_maps);
+
+    my %unique_maps;
+    # A list of the first few distinct mappings this property has.  This is
+    # used to disambiguate between binary and enum property types, so don't
+    # have to keep more than three.
+    main::set_access('unique_maps', \%unique_maps);
+
+    sub new {
+        # The only required parameter is the positionally first, name.  All
+        # other parameters are key => value pairs.  See the documentation just
+        # above for the meanings of the ones not passed directly on to the map
+        # table constructor.
+
+        my $class = shift;
+        my $name = shift || "";
+
+        my $self = property_ref($name);
+        if (defined $self) {
+            my $options_string = join ", ", @_;
+            $options_string = ".  Ignoring options $options_string" if $options_string;
+            Carp::my_carp("$self is already in use.  Using existing one$options_string;");
+            return $self;
+        }
+
+        my %args = @_;
+
+        $self = bless \do { my $anonymous_scalar }, $class;
+        my $addr = main::objaddr $self;
+
+        $directory{$addr} = delete $args{'Directory'};
+        $file{$addr} = delete $args{'File'};
+        $full_name{$addr} = delete $args{'Full_Name'} || $name;
+        $type{$addr} = delete $args{'Type'} || $UNKNOWN;
+        $pseudo_map_type{$addr} = delete $args{'Map_Type'};
+        # Rest of parameters passed on.
+
+        $has_only_code_point_maps{$addr} = 1;
+        $table_ref{$addr} = { };
+        $unique_maps{$addr} = { };
+
+        $map{$addr} = Map_Table->new($name,
+                                    Full_Name => $full_name{$addr},
+                                    _Alias_Hash => \%alias_to_property_of,
+                                    _Property => $self,
+                                    %args);
+        return $self;
+    }
+
+    # See this program's beginning comment block about overloading the copy
+    # constructor.  Few operations are defined on properties, but a couple are
+    # useful.  It is safe to take the inverse of a property, and to remove a
+    # single code point from it.
+    use overload
+        fallback => 0,
+        qw("") => "_operator_stringify",
+        "." => \&main::_operator_dot,
+        '==' => \&main::_operator_equal,
+        '!=' => \&main::_operator_not_equal,
+        '=' => sub { return shift },
+        '-=' => "_minus_and_equal",
+    ;
+
+    sub _operator_stringify {
+        return "Property '" .  shift->full_name . "'";
+    }
+
+    sub _minus_and_equal {
+        # Remove a single code point from the map table of a property.
+
+        my $self = shift;
+        my $other = shift;
+        my $reversed = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        if (ref $other) {
+            Carp::my_carp_bug("Can't cope with a "
+                        . ref($other)
+                        . " argument to '-='.  Subtraction ignored.");
+            return $self;
+        }
+        elsif ($reversed) {   # Shouldnt happen in a -=, but just in case
+            Carp::my_carp_bug("Can't cope with a "
+            .  __PACKAGE__
+            . " being the first parameter in a '-='.  Subtraction ignored.");
+            return $self;
+        }
+        else {
+            $map{main::objaddr $self}->delete_range($other, $other);
+        }
+        return $self;
+    }
+
+    sub add_match_table {
+        # Add a new match table for this property, with name given by the
+        # parameter.  It returns a pointer to the table.
+
+        my $self = shift;
+        my $name = shift;
+        my %args = @_;
+
+        my $addr = main::objaddr $self;
+
+        my $table = $table_ref{$addr}{$name};
+        my $standard_name = main::standardize($name);
+        if (defined $table
+            || (defined ($table = $table_ref{$addr}{$standard_name})))
+        {
+            Carp::my_carp("Table '$name' in $self is already in use.  Using existing one");
+            $table_ref{$addr}{$name} = $table;
+            return $table;
+        }
+        else {
+
+            # See if this is a perl extension, if not passed in.
+            my $perl_extension = delete $args{'Perl_Extension'};
+            $perl_extension
+                        = $self->perl_extension if ! defined $perl_extension;
+
+            $table = Match_Table->new(
+                                Name => $name,
+                                Perl_Extension => $perl_extension,
+                                _Alias_Hash => $table_ref{$addr},
+                                _Property => $self,
+
+                                # gets property's status by default
+                                Status => $self->status,
+                                _Status_Info => $self->status_info,
+                                %args,
+                                Internal_Only_Warning => 1); # Override any
+                                                             # input param
+            return unless defined $table;
+        }
+
+        # Save the names for quick look up
+        $table_ref{$addr}{$standard_name} = $table;
+        $table_ref{$addr}{$name} = $table;
+
+        # Perhaps we can figure out the type of this property based on the
+        # fact of adding this match table.  First, string properties don't
+        # have match tables; second, a binary property can't have 3 match
+        # tables
+        if ($type{$addr} == $UNKNOWN) {
+            $type{$addr} = $NON_STRING;
+        }
+        elsif ($type{$addr} == $STRING) {
+            Carp::my_carp("$self Added a match table '$name' to a string property '$self'.  Changed it to a non-string property.  Bad News.");
+            $type{$addr} = $NON_STRING;
+        }
+        elsif ($type{$addr} != $ENUM) {
+            if (scalar main::uniques(values %{$table_ref{$addr}}) > 2
+                && $type{$addr} == $BINARY)
+            {
+                Carp::my_carp("$self now has more than 2 tables (with the addition of '$name'), and so is no longer binary.  Changing its type to 'enum'.  Bad News.");
+                $type{$addr} = $ENUM;
+            }
+        }
+
+        return $table;
+    }
+
+    sub table {
+        # Return a pointer to the match table (with name given by the
+        # parameter) associated with this property; undef if none.
+
+        my $self = shift;
+        my $name = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        return $table_ref{$addr}{$name} if defined $table_ref{$addr}{$name};
+
+        # If quick look-up failed, try again using the standard form of the
+        # input name.  If that succeeds, cache the result before returning so
+        # won't have to standardize this input name again.
+        my $standard_name = main::standardize($name);
+        return unless defined $table_ref{$addr}{$standard_name};
+
+        $table_ref{$addr}{$name} = $table_ref{$addr}{$standard_name};
+        return $table_ref{$addr}{$name};
+    }
+
+    sub tables {
+        # Return a list of pointers to all the match tables attached to this
+        # property
+
+        return main::uniques(values %{$table_ref{main::objaddr shift}});
+    }
+
+    sub directory {
+        # Returns the directory the map table for this property should be
+        # output in.  If a specific directory has been specified, that has
+        # priority;  'undef' is returned if the type isn't defined;
+        # or $map_directory for everything else.
+
+        my $addr = main::objaddr shift;
+
+        return $directory{$addr} if defined $directory{$addr};
+        return undef if $type{$addr} == $UNKNOWN;
+        return $map_directory;
+    }
+
+    sub swash_name {
+        # Return the name that is used to both:
+        #   1)  Name the file that the map table is written to.
+        #   2)  The name of swash related stuff inside that file.
+        # The reason for this is that the Perl core historically has used
+        # certain names that aren't the same as the Unicode property names.
+        # To continue using these, $file is hard-coded in this file for those,
+        # but otherwise the standard name is used.  This is different from the
+        # external_name, so that the rest of the files, like in lib can use
+        # the standard name always, without regard to historical precedent.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr $self;
+
+        return $file{$addr} if defined $file{$addr};
+        return $map{$addr}->external_name;
+    }
+
+    sub to_create_match_tables {
+        # Returns a boolean as to whether or not match tables should be
+        # created for this property.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        # The whole point of this pseudo property is match tables.
+        return 1 if $self == $perl;
+
+        my $addr = main::objaddr $self;
+
+        # Don't generate tables of code points that match the property values
+        # of a string property.  Such a list would most likely have many
+        # property values, each with just one or very few code points mapping
+        # to it.
+        return 0 if $type{$addr} == $STRING;
+
+        # Don't generate anything for unimplemented properties.
+        return 0 if grep { $self->complete_name eq $_ }
+                                                    @unimplemented_properties;
+        # Otherwise, do.
+        return 1;
+    }
+
+    sub property_add_or_replace_non_nulls {
+        # This adds the mappings in the property $other to $self.  Non-null
+        # mappings from $other override those in $self.  It essentially merges
+        # the two properties, with the second having priority except for null
+        # mappings.
+
+        my $self = shift;
+        my $other = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        if (! $other->isa(__PACKAGE__)) {
+            Carp::my_carp_bug("$other should be a "
+                            . __PACKAGE__
+                            . ".  Not a '"
+                            . ref($other)
+                            . "'.  Not added;");
+            return;
+        }
+
+        return $map{main::objaddr $self}->
+                map_add_or_replace_non_nulls($map{main::objaddr $other});
+    }
+
+    sub set_type {
+        # Set the type of the property.  Mostly this is figured out by the
+        # data in the table.  But this is used to set it explicitly.  The
+        # reason it is not a standard accessor is that when setting a binary
+        # property, we need to make sure that all the true/false aliases are
+        # present, as they were omitted in early Unicode releases.
+
+        my $self = shift;
+        my $type = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        if ($type != $ENUM && $type != $BINARY && $type != $STRING) {
+            Carp::my_carp("Unrecognized type '$type'.  Type not set");
+            return;
+        }
+
+        $type{main::objaddr $self} = $type;
+        return if $type != $BINARY;
+
+        my $yes = $self->table('Y');
+        $yes = $self->table('Yes') if ! defined $yes;
+        $yes = $self->add_match_table('Y') if ! defined $yes;
+        $yes->add_alias('Yes');
+        $yes->add_alias('T');
+        $yes->add_alias('True');
+
+        my $no = $self->table('N');
+        $no = $self->table('No') if ! defined $no;
+        $no = $self->add_match_table('N') if ! defined $no;
+        $no->add_alias('No');
+        $no->add_alias('F');
+        $no->add_alias('False');
+        return;
+    }
+
+    sub add_map {
+        # Add a map to the property's map table.  This also keeps
+        # track of the maps so that the property type can be determined from
+        # its data.
+
+        my $self = shift;
+        my $start = shift;  # First code point in range
+        my $end = shift;    # Final code point in range
+        my $map = shift;    # What the range maps to.
+        # Rest of parameters passed on.
+
+        my $addr = main::objaddr $self;
+
+        # If haven't the type of the property, gather information to figure it
+        # out.
+        if ($type{$addr} == $UNKNOWN) {
+
+            # If the map contains an interior blank or dash, or most other
+            # nonword characters, it will be a string property.  This
+            # heuristic may actually miss some string properties.  If so, they
+            # may need to have explicit set_types called for them.  This
+            # happens in the Unihan properties.
+            if ($map =~ / (?<= . ) [ -] (?= . ) /x
+                || $map =~ / [^\w.\/\ -]  /x)
+            {
+                $self->set_type($STRING);
+
+                # $unique_maps is used for disambiguating between ENUM and
+                # BINARY later; since we know the property is not going to be
+                # one of those, no point in keeping the data around
+                undef $unique_maps{$addr};
+            }
+            else {
+
+                # Not necessarily a string.  The final decision has to be
+                # deferred until all the data are in.  We keep track of if all
+                # the values are code points for that eventual decision.
+                $has_only_code_point_maps{$addr} &=
+                                            $map =~ / ^ $code_point_re $/x;
+
+                # For the purposes of disambiguating between binary and other
+                # enumerations at the end, we keep track of the first three
+                # distinct property values.  Once we get to three, we know
+                # it's not going to be binary, so no need to track more.
+                if (scalar keys %{$unique_maps{$addr}} < 3) {
+                    $unique_maps{$addr}{main::standardize($map)} = 1;
+                }
+            }
+        }
+
+        # Add the mapping by calling our map table's method
+        return $map{$addr}->add_map($start, $end, $map, @_);
+    }
+
+    sub compute_type {
+        # Compute the type of the property: $ENUM, $STRING, or $BINARY.  This
+        # should be called after the property is mostly filled with its maps.
+        # We have been keeping track of what the property values have been,
+        # and now have the necessary information to figure out the type.
+
+        my $self = shift;
+        Carp::carp_extra_args(\@_) if main::DEBUG && @_;
+
+        my $addr = main::objaddr($self);
+
+        my $type = $type{$addr};
+
+        # If already have figured these out, no need to do so again, but we do
+        # a double check on ENUMS to make sure that a string property hasn't
+        # improperly been classified as an ENUM, so continue on with those.
+        return if $type == $STRING || $type == $BINARY;
+
+        # If every map is to a code point, is a string property.
+        if ($type == $UNKNOWN
+            && ($has_only_code_point_maps{$addr}
+                || (defined $map{$addr}->default_map
+                    && $map{$addr}->default_map eq "")))
+        {
+            $self->set_type($STRING);
+        }
+        else {
+
+            # Otherwise, it is to some sort of enumeration.  (The case where
+            # it is a Unicode miscellaneous property, and treated like a
+            # string in this program is handled in add_map()).  Distinguish
+            # between binary and some other enumeration type.  Of course, if
+            # there are more than two values, it's not binary.  But more
+            # subtle is the test that the default mapping is defined means it
+            # isn't binary.  This in fact may change in the future if Unicode
+            # changes the way its data is structured.  But so far, no binary
+            # properties ever have @missing lines for them, so the default map
+            # isn't defined for them.  The few properties that are two-valued
+            # and aren't considered binary have the default map defined
+            # starting in Unicode 5.0, when the @missing lines appeared; and
+            # this program has special code to put in a default map for them
+            # for earlier than 5.0 releases.
+            if ($type == $ENUM
+                || scalar keys %{$unique_maps{$addr}} > 2
+                || defined $self->default_map)
+            {
+                my $tables = $self->tables;
+                my $count = $self->count;
+                if ($verbosity && $count > 500 && $tables/$count > .1) {
+                    Carp::my_carp_bug("It appears that $self should be a \$STRING property, not an \$ENUM because it has too many match tables: $count\n");
+                }
+                $self->set_type($ENUM);
+            }
+            else {
+                $self->set_type($BINARY);
+            }
+        }
+        undef $unique_maps{$addr};  # Garbage collect
+        return;
+    }
+
+    # Most of the accessors for a property actually apply to its map table.
+    # Setup up accessor functions for those, referring to %map
+    for my $sub qw(
+                    add_alias
+                    add_anomalous_entry
+                    add_comment
+                    add_conflicting
+                    add_description
+                    add_duplicate
+                    add_note
+                    aliases
+                    comment
+                    complete_name
+                    core_access
+                    count
+                    default_map
+                    delete_range
+                    description
+                    each_range
+                    external_name
+                    file_path
+                    format
+                    initialize
+                    inverse_list
+                    is_empty
+                    name
+                    note
+                    perl_extension
+                    property
+                    range_count
+                    ranges
+                    range_size_1
+                    reset_each_range
+                    set_comment
+                    set_core_access
+                    set_default_map
+                    set_file_path
+                    set_final_comment
+                    set_range_size_1
+                    set_status
+                    set_to_output_map
+                    short_name
+                    status
+                    status_info
+                    to_output_map
+                    value_of
+                    write
+                )
+                    # 'property' above is for symmetry, so that one can take
+                    # the property of a property and get itself, and so don't
+                    # have to distinguish between properties and tables in
+                    # calling code
+    {
+        no strict "refs";
+        *$sub = sub {
+            use strict "refs";
+            my $self = shift;
+            return $map{main::objaddr $self}->$sub(@_);
+        }
+    }
+
+
+} # End closure
+
+package main;
+
+sub join_lines($) {
+    # Returns lines of the input joined together, so that they can be folded
+    # properly.
+    # This causes continuation lines to be joined together into one long line
+    # for folding.  A continuation line is any line that doesn't begin with a
+    # space or "\b" (the latter is stripped from the output).  This is so
+    # lines can be be in a HERE document so as to fit nicely in the terminal
+    # width, but be joined together in one long line, and then folded with
+    # indents, '#' prefixes, etc, properly handled.
+    # A blank separates the joined lines except if there is a break; an extra
+    # blank is inserted after a period ending a line.
+
+    # Intialize the return with the first line.
+    my ($return, @lines) = split "\n", shift;
+
+    # If the first line is null, it was an empty line, add the \n back in
+    $return = "\n" if $return eq "";
+
+    # Now join the remainder of the physical lines.
+    for my $line (@lines) {
+
+        # An empty line means wanted a blank line, so add two \n's to get that
+        # effect, and go to the next line.
+        if (length $line == 0) {
+            $return .= "\n\n";
+            next;
+        }
+
+        # Look at the last character of what we have so far.
+        my $previous_char = substr($return, -1, 1);
+
+        # And at the next char to be output.
+        my $next_char = substr($line, 0, 1);
+
+        if ($previous_char ne "\n") {
+
+            # Here didn't end wth a nl.  If the next char a blank or \b, it
+            # means that here there is a break anyway.  So add a nl to the
+            # output.
+            if ($next_char eq " " || $next_char eq "\b") {
+                $previous_char = "\n";
+                $return .= $previous_char;
+            }
+
+            # Add an extra space after periods.
+            $return .= " " if $previous_char eq '.';
+        }
+
+        # Here $previous_char is still the latest character to be output.  If
+        # it isn't a nl, it means that the next line is to be a continuation
+        # line, with a blank inserted between them.
+        $return .= " " if $previous_char ne "\n";
+
+        # Get rid of any \b
+        substr($line, 0, 1) = "" if $next_char eq "\b";
+
+        # And append this next line.
+        $return .= $line;
+    }
+
+    return $return;
+}
+
+sub simple_fold($;$$$) {
+    # Returns a string of the input (string or an arr