perl5.git.perl.org Git - perl5.git/blob

1 #!/usr/bin/perl -w

2 #

3 # Regenerate (overwriting only if changed):

4 #

5 # mg_names.inc

6 # mg_raw.h

7 # mg_vtable.h

8 # pod/perlguts.pod

9 #

10 # from information stored in this file. pod/perlguts.pod is not completely

11 # regenerated. Only the magic table is replaced; the other parts remain

12 # untouched.

13 #

14 # Accepts the standard regen_lib -q and -v args.

15 #

16 # This script is normally invoked from regen.pl.

17 #

18 # Its output files contain:

19 #

20 # mg_names.inc

21 # included by dump.c - the textual representation for each magic type.

22 # Contains a list of

23 #

24 # { PERL_MAGIC_foo, "foo(f)" }

25 #

26 # pairs.

27 #

28 #

29 # mg_raw.h

30 # processed by generate_uudmap.c into mg_data.h which eventually

31 # populates PL_magic_vtables[].

32 #

33 # Contains a list of:

34 #

35 # { 'f', "want_vtbl_foo | FLAGS", "description for comments" }

36 #

37 # triplets. FLAGS can be:

38 # PERL_MAGIC_READONLY_ACCEPTABLE

39 # ok set this type of magic on an SvREADONLY() SV

40 # PERL_MAGIC_VALUE_MAGIC

41 # this is value magic (pos, taint etc)

42 # rather than container magic (%ENV, $1 etc)

43 #

44 #

45 # mg_vtable.h

46 # This contains five kinds of entries:

47 #

48 # #define PERL_MAGIC_arylen '#'

49 # ....

50 #

51 # enum { /* pass one of these to get_vtbl */

52 # want_vtbl_arylen,

53 # ...

54 # }

55 #

56 # PL_magic_vtable_names[] = {

57 # "arylen",

58 # ...

59 # }

60 #

61 # PL_magic_vtables[] = {

62 # /* per-magic sets of vtable function pointers */

63 # { get, set, len, clear, free, copy, dup, local },

64 # }

65 #

66 # define PL_vtbl_arylen PL_magic_vtables[want_vtbl_arylen]

67 # ....

68 #

69 #

70 #

71 # pod/perlguts.pod

72 # updates the list of magic types between

73 # =for mg_vtable.pl begin

74 # ...

75 # =for mg_vtable.pl end

78 use strict;

79 require 5.004;

81 BEGIN {

82 # Get function prototypes

83 require './regen/regen_lib.pl';

84 }

86 # =====================================================================

87 #

88 # START OF CONFIGURATION DATA

91 # %mg

92 #

93 # This hash is mainly concerned with populating all the other stuff

94 # ancillary to the vtable.

95 #

96 # The key is the name, e.g. 'regdata' for PERL_MAGIC_regdata

97 #

98 # The keys of the value hash are:

99 # char

100 # the magic's char identifier

101 #

102 # desc

103 # a description which appears in code comments in generated files

104 #

105 # readonly_acceptable

106 # If true, set PERL_MAGIC_READONLY_ACCEPTABLE flag;

107 # SvREADONLY() svs are allowed to have this magic added to them

108 #

109 # unknown_to_sv_magic

110 # if true, this isn't one of the standard magic types which

111 # Perl_sv_magic() knows how to deal with

112 #

113 # value_magic

114 # If true, set PERL_MAGIC_VALUE_MAGIC flag;

115 # this kind of magic is value (pos, taint etc) rather than

116 # container magic (%ENV, $1 etc)

117 #

118 # vtable

119 # name of the vtable lookup enum, e.g. 'foo' creates want_vtbl_foo

120

121 my %mg =

122 (

123 sv => { char => "\0", vtable => 'sv', readonly_acceptable => 1,

124 desc => 'Special scalar variable' },

125 # overload, or type "A" magic, used to be here. Hence overloaded is

126 # often called AMAGIC internally, even though it does not use "A"

127 # magic any more.

128 overload_table => { char => 'c', vtable => 'ovrld',

129 desc => 'Holds overload table (AMT) on stash' },

130 bm => { char => 'B', vtable => 'regexp', value_magic => 1,

131 readonly_acceptable => 1,

132 desc => 'Boyer-Moore (fast string search)' },

133 regdata => { char => 'D', vtable => 'regdata',

134 desc => "Regex match position data\n(\@+ and \@- vars)" },

135 regdatum => { char => 'd', vtable => 'regdatum',

136 desc => 'Regex match position data element' },

137 env => { char => 'E', vtable => 'env', desc => '%ENV hash' },

138 envelem => { char => 'e', vtable => 'envelem',

139 desc => '%ENV hash element' },

140 fm => { char => 'f', vtable => 'regexp', value_magic => 1,

141 readonly_acceptable => 1, desc => "Formline ('compiled' format)" },

142 regex_global => { char => 'g', vtable => 'mglob', value_magic => 1,

143 readonly_acceptable => 1, desc => 'm//g target' },

144 hints => { char => 'H', vtable => 'hints', desc => '%^H hash' },

145 hintselem => { char => 'h', vtable => 'hintselem',

146 desc => '%^H hash element' },

147 isa => { char => 'I', vtable => 'isa', desc => '@ISA array' },

148 isaelem => { char => 'i', vtable => 'isaelem',

149 desc => '@ISA array element' },

150 nkeys => { char => 'k', vtable => 'nkeys', value_magic => 1,

151 desc => 'scalar(keys()) lvalue' },

152 dbfile => { char => 'L',

153 desc => 'Debugger %_<filename' },

154 dbline => { char => 'l', vtable => 'dbline',

155 desc => 'Debugger %_<filename element' },

156 shared => { char => 'N', desc => 'Shared between threads',

157 unknown_to_sv_magic => 1 },

158 shared_scalar => { char => 'n', desc => 'Shared between threads',

159 unknown_to_sv_magic => 1 },

160 collxfrm => { char => 'o', vtable => 'collxfrm', value_magic => 1,

161 desc => 'Locale transformation' },

162 tied => { char => 'P', vtable => 'pack',

163 value_magic => 1, # treat as value, so 'local @tied' isn't tied

164 desc => 'Tied array or hash' },

165 tiedelem => { char => 'p', vtable => 'packelem',

166 desc => 'Tied array or hash element' },

167 tiedscalar => { char => 'q', vtable => 'packelem',

168 desc => 'Tied scalar or handle' },

169 qr => { char => 'r', vtable => 'regexp', value_magic => 1,

170 readonly_acceptable => 1, desc => 'Precompiled qr// regex' },

171

172 hook => { char => 'Z',

173 vtable => 'hook', desc => '%{^HOOK} hash' },

174 hookelem => { char => 'z',

175 vtable => 'hookelem', desc => '%{^HOOK} hash element' },

176

177 sig => { char => 'S', vtable => 'sig',

178 desc => '%SIG hash' },

179 sigelem => { char => 's', vtable => 'sigelem',

180 desc => '%SIG hash element' },

181

182 taint => { char => 't', vtable => 'taint', value_magic => 1,

183 desc => 'Taintedness' },

184 uvar => { char => 'U', vtable => 'uvar',

185 desc => 'Available for use by extensions' },

186 uvar_elem => { char => 'u', desc => 'Reserved for use by extensions',

187 unknown_to_sv_magic => 1 },

188 vec => { char => 'v', vtable => 'vec', value_magic => 1,

189 desc => 'vec() lvalue' },

190 vstring => { char => 'V', value_magic => 1,

191 desc => 'SV was vstring literal' },

192 utf8 => { char => 'w', vtable => 'utf8', value_magic => 1,

193 desc => 'Cached UTF-8 information' },

194 substr => { char => 'x', vtable => 'substr', value_magic => 1,

195 desc => 'substr() lvalue' },

196 defelem => { char => 'y', vtable => 'defelem', value_magic => 1,

197 desc => "Shadow \"foreach\" iterator variable /\nsmart parameter vivification" },

198 nonelem => { char => 'Y', vtable => 'nonelem', value_magic => 1,

199 desc => "Array element that does not exist" },

200 arylen => { char => '#', vtable => 'arylen', value_magic => 1,

201 desc => 'Array length ($#ary)' },

202 pos => { char => '.', vtable => 'pos', value_magic => 1,

203 desc => 'pos() lvalue' },

204 backref => { char => '<', vtable => 'backref', value_magic => 1,

205 readonly_acceptable => 1, desc => 'For weak ref data' },

206 symtab => { char => ':', value_magic => 1,

207 desc => 'Extra data for symbol tables' },

208 rhash => { char => '%', value_magic => 1,

209 desc => 'Extra data for restricted hashes' },

210 arylen_p => { char => '@', value_magic => 1,

211 desc => 'To move arylen out of XPVAV' },

212 ext => { char => '~', desc => 'Variable magic available for use by extensions',

213 readonly_acceptable => 1 },

214 extvalue => { char => '^', desc => 'Value magic available for use by extensions',

215 readonly_acceptable => 1, value_magic => 1 },

216 checkcall => { char => ']', value_magic => 1, vtable => 'checkcall',

217 desc => 'Inlining/mutation of call to this CV'},

218 debugvar => { char => '*', desc => '$DB::single, signal, trace vars',

219 vtable => 'debugvar' },

220 lvref => { char => '\\', vtable => 'lvref',

221 desc => "Lvalue reference constructor" },

222 destruct => {

223 char => "X",

224 vtable => 'destruct',

225 desc => "destruct callback",

226 value_magic => 1,

227 },

228 );

229

230

231 # %vtable_conf

232 #

233 # This hash is mainly concerned with populating the vtable.

234 #

235 # These have a subtly different "namespace" from the magic types.

236 #

237 # The key is the name, e.g. 'regdata' for PERL_MAGIC_regdata

238 # The keys of the value hash are:

239 #

240 # alias

241 # for each entry in the anon array, add

242 # add "#define want_vtbl_$_ want_vtbl_$name"

243 #

244 # cond

245 # prefix the vtable with the specified entry (e.g. '#ifdef FOO')

246 # and suffix it with '#else { 0, 0, 0, 0, 0, 0, 0, 0 } #endif'

247 #

248 # const

249 # special-case cast a 'get' function whose signature expects

250 # a pointer to constant magic, so that it can be added to a vtable

251 # which expects pointers to functions without the 'const'.

252 #

253 # get

254 # set

255 # len

256 # clear

257 # free

258 # copy

259 # dup

260 # local

261 # For each specified method, add a vtable function pointer

262 # of the form "Perl_magic_$vtable_conf{foo}{get}" etc

263

264 my %vtable_conf =

265 (

266 'sv' => {get => 'get', set => 'set'},

267 'env' => {set => 'set_all_env', clear => 'clear_all_env'},

268 'envelem' => {set => 'setenv', clear => 'clearenv'},

269 'sig' => { set => 'setsigall' },

270 'sigelem' => {get => 'getsig', set => 'setsig', clear => 'clearsig'},

271

272 'hook' => { set => 'sethookall', clear => 'clearhookall' },

273 'hookelem' => {set => 'sethook', clear => 'clearhook'},

274

275 'pack' => {len => 'sizepack', clear => 'wipepack'},

276 'packelem' => {get => 'getpack', set => 'setpack', clear => 'clearpack'},

277 'dbline' => {set => 'setdbline'},

278 'isa' => {set => 'setisa', clear => 'clearisa'},

279 'isaelem' => {set => 'setisa'},

280 'arylen' => {get => 'getarylen', set => 'setarylen', const => 1},

281 'arylen_p' => {clear => 'cleararylen_p', free => 'freearylen_p'},

282 'mglob' => {set => 'setmglob',

283 free => 'freemglob' },

284 'nkeys' => {get => 'getnkeys', set => 'setnkeys'},

285 'taint' => {get => 'gettaint', set => 'settaint'},

286 'substr' => {get => 'getsubstr', set => 'setsubstr'},

287 'vec' => {get => 'getvec', set => 'setvec'},

288 'pos' => {get => 'getpos', set => 'setpos'},

289 'uvar' => {get => 'getuvar', set => 'setuvar'},

290 'defelem' => {get => 'getdefelem', set => 'setdefelem'},

291 'nonelem' => {set => 'setnonelem'},

292 'regexp' => {set => 'setregexp', alias => [qw(bm fm)]},

293 'regdata' => {len => 'regdata_cnt'},

294 'regdatum' => {get => 'regdatum_get', set => 'regdatum_set'},

295 'backref' => {free => 'killbackrefs'},

296 'ovrld' => {free => 'freeovrld'},

297 'utf8' => {set => 'setutf8',

298 free => 'freeutf8' },

299 'collxfrm' => {set => 'setcollxfrm',

300 free => 'freecollxfrm',

301 cond => '#ifdef USE_LOCALE_COLLATE'},

302 'hintselem' => {set => 'sethint', clear => 'clearhint'},

303 'hints' => {clear => 'clearhints'},

304 'checkcall' => {copy => 'copycallchecker'},

305 'debugvar' => { set => 'setdebugvar', get => 'getdebugvar' },

306 'lvref' => {set => 'setlvref'},

307 'destruct' => {free => 'freedestruct'},

308 );

309

310

311 # END OF CONFIGURATION DATA

312 #

313 # =====================================================================

314

315

316

317 my ($vt, $raw, $names) = map {

318 open_new($_, '>',

319 { by => 'regen/mg_vtable.pl', file => $_, style => '*' });

320 } 'mg_vtable.h', 'mg_raw.h', 'mg_names.inc';

321 my $guts = open_new("pod/perlguts.pod", ">");

322

323 print $vt <<'EOH';

324 /* These constants should be used in preference to raw characters

325 * when using magic. Note that some perl guts still assume

326 * certain character properties of these constants, namely that

327 * isUPPER() and toLOWER() may do useful mappings.

328 */

329

330 EOH

331

332 # Of course, it would be *much* easier if we could output this table directly

333 # here and now. However, for our sins, we try to support EBCDIC, which wouldn't

334 # be *so* bad, except that there are (at least) 3 EBCDIC charset variants, and

335 # they don't agree on the code point for '~'. Which we use. Great.

336 # So we have to get the local build runtime to sort our table in character order

337 # (And of course, just to be helpful, in POSIX BC '~' is \xFF, so we can't even

338 # simplify the C code by assuming that the last element of the array is

339 # predictable)

340

341 # Process %mg

342

343 {

344 my $longest = 0;

345 foreach (keys %mg) {

346 $longest = length $_ if length $_ > $longest;

347 }

348

349 my $longest_p1 = $longest + 1;

350

351 my %mg_order;

352 while (my ($name, $data) = each %mg) {

353 my $byte = $data->{char};

354 if ($byte =~ /[[:print:]]/) {

355 $data->{r_char} = $byte; # readable char

356 ($data->{c_char} = $byte) =~ s/([\\"])/\\$1/g; # for C strings

357 }

358 else {

359 $data->{c_char} = $data->{r_char} = '\\'.ord $byte;

360 }

361 $mg_order{(uc $byte) . $byte} = $name;

362 }

363

364 my @rows;

365 my @names;

366 foreach (sort keys %mg_order) {

367 my $name = $mg_order{$_};

368 push @names, $name;

369 my $data = $mg{$name};

370 my $i = ord $data->{char};

371

372 # add entry to mg_raw.h

373

374 unless ($data->{unknown_to_sv_magic}) {

375 my $value = $data->{vtable}

376 ? "want_vtbl_$data->{vtable}" : 'magic_vtable_max';

377 $value .= ' | PERL_MAGIC_READONLY_ACCEPTABLE'

378 if $data->{readonly_acceptable};

379 $value .= ' | PERL_MAGIC_VALUE_MAGIC' if $data->{value_magic};

380 my $comment = "/* $name '$data->{r_char}' $data->{desc} */";

381 $comment =~ s/([\\"])/\\$1/g;

382 $comment =~ tr/\n/ /;

383 print $raw qq{ { '$data->{c_char}', "$value",\n "$comment" },\n};

384 }

385

386 # add #define PERL_MAGIC_foo entry to vt_table.h

387

388 my $comment = $data->{desc};

389 my $leader = ' ' x ($longest + 27);

390 $comment =~ s/\n/\n$leader/s;

391 printf $vt "#define PERL_MAGIC_%-${longest}s '%s' /* %s */\n",

392 $name, $data->{c_char}, $comment;

393

394 # add entry to mg_names.inc

395

396 my $char = $data->{r_char};

397 $char =~ s/([\\"])/\\$1/g;

398 printf $names qq[\t{ PERL_MAGIC_%-${longest_p1}s "%s(%s)" },\n],

399 "$name,", $name, $char;

400

401 # construct perlguts.pod entry

402

403 push @rows, [(sprintf "%-2s PERL_MAGIC_%s", $data->{r_char},$name),

404 $data->{vtable} ? "vtbl_$data->{vtable}" : '(none)',

405 $data->{desc}];

406 }

407

408 # output @rows to perlguts.pod

409

410 select +(select($guts), do {

411 my @header = ('(old-style char and macro)', 'MGVTBL', 'Type of magic');

412 my @widths = (0, 0);

413 foreach my $row (@rows) {

414 for (0, 1) {

415 $widths[$_] = length $row->[$_]

416 if length $row->[$_] > $widths[$_];

417 }

418 }

419 my $indent = ' ';

420 my $format

421 = sprintf "$indent%%-%ds%%-%ds%%s\n", $widths[0] + 1, $widths[1] + 1;

422 my $desc_wrap =

423 79 - 7 - (length $indent) - $widths[0] - $widths[1] - 2;

424

425 open my $oldguts, "<", "pod/perlguts.pod"

426 or die "$0 cannot open pod/perlguts.pod for reading: $!";

427 while (<$oldguts>) {

428 print;

429 last if /^=for mg_vtable.pl begin/

430 }

431

432 print "\n", $indent . "mg_type\n";

433 printf $format, @header;

434 printf $format, map {'-' x length $_} @header;

435 foreach (@rows) {

436 my ($type, $vtbl, $desc) = @$_;

437 $desc =~ tr/\n/ /;

438 my @cont;

439 if (length $desc > $desc_wrap) {

440 # If it's too long, first split on '(', if there.

441 # [Which, if there, is always short enough, currently.

442 # Make this more robust if that changes]

443 ($desc, @cont) = split /(?=\()/, $desc;

444 if (!@cont) {

445 ($desc, @cont) = $desc =~ /(.{1,$desc_wrap})(?: |\z)/g

446 }

447 }

448 s/\s+\z// for $desc, @cont;

449 printf $format, $type, $vtbl, $desc;

450 printf $format, '', '', $_ foreach @cont;

451 }

452 print "\n\n";

453

454 my $first = 1;

455 for my $magic (sort @names) {

456 if ($first) {

457 $first = 0;

458 print "=for apidoc_section \$magic\n";

459 print "=for apidoc AmnhU||PERL_MAGIC_$magic\n";

460 }

461 else {

462 print "=for apidoc_item ||PERL_MAGIC_$magic\n";

463 }

464 }

465 print "\n";

466

467 while (<$oldguts>) {

468 last if /^=for mg_vtable.pl end/;

469 }

470 do { print } while <$oldguts>;

471 })[0];

472 }

473

474

475 # Process %vtable_conf - everything goes to mg_vtable.h

476

477 my @names = sort keys %vtable_conf;

478 {

479 my $want = join ",\n ", (map {"want_vtbl_$_"} @names), 'magic_vtable_max';

480 my $names = join qq{",\n "}, @names;

481

482 print $vt <<"EOH";

483

484 enum { /* pass one of these to get_vtbl */

485 $want

486 };

487

488 #ifdef DOINIT

489 EXTCONST char * const PL_magic_vtable_names[magic_vtable_max] = {

490 "$names"

491 };

492 #else

493 EXTCONST char * const PL_magic_vtable_names[magic_vtable_max];

494 #endif

495

496 EOH

497 }

498

499 print $vt <<'EOH';

500 /* These all need to be 0, not NULL, as NULL can be (void*)0, which is a

501 * pointer to data, whereas we're assigning pointers to functions, which are

502 * not the same beast. ANSI doesn't allow the assignment from one to the other.

503 * (although most, but not all, compilers are prepared to do it)

504 */

505

506 /* order is:

507 get

508 set

509 len

510 clear

511 free

512 copy

513 dup

514 local

515 */

516

517 #ifdef DOINIT

518 EXT_MGVTBL PL_magic_vtables[magic_vtable_max] = {

519 EOH

520

521 my @vtable_names;

522 my @aliases;

523

524 while (my $name = shift @names) {

525 my $data = $vtable_conf{$name};

526 push @vtable_names, $name;

527 my @funcs = map {

528 $data->{$_} ? "Perl_magic_$data->{$_}" : 0;

529 } qw(get set len clear free copy dup local);

530

531 $funcs[0] = "(int (*)(pTHX_ SV *, MAGIC *))" . $funcs[0] if $data->{const};

532 my $funcs = join ", ", @funcs;

533

534 # Because we can't have a , after the last {...}

535 my $comma = @names ? ',' : '';

536

537 print $vt "$data->{cond}\n" if $data->{cond};

538 print $vt " { $funcs }$comma\n";

539 print $vt <<"EOH" if $data->{cond};

540 #else

541 { 0, 0, 0, 0, 0, 0, 0, 0 }$comma

542 #endif

543 EOH

544 foreach(@{$data->{alias}}) {

545 push @aliases, "#define want_vtbl_$_ want_vtbl_$name\n";

546 push @vtable_names, $_;

547 }

548 }

549

550 print $vt <<'EOH';

551 };

552 #else

553 EXT_MGVTBL PL_magic_vtables[magic_vtable_max];

554 #endif

555

556 EOH

557

558 print $vt (sort @aliases), "\n";

559

560 print $vt "#define PL_vtbl_$_ PL_magic_vtables[want_vtbl_$_]\n"

561 foreach sort @vtable_names;

562

563 # 63, not 64, As we rely on the last possible value to mean "NULL vtable"

564 die "Too many vtable names" if @vtable_names > 63;

565

566 read_only_bottom_close_and_rename($_) foreach $vt, $raw, $names;

567 close_and_rename($guts);