This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Remove version checks from B::Deparse’s imports
[perl5.git] / dist / B-Deparse / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
18          OPpSORT_REVERSE
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          CVf_METHOD CVf_LVALUE
21          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
22          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
23 $VERSION = "1.10";
24 use strict;
25 use vars qw/$AUTOLOAD/;
26 use warnings ();
27
28 BEGIN {
29     # List version-specific constants here.
30     # Easiest way to keep this code portable between version looks to
31     # be to fake up a dummy constant that will never actually be true.
32     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
33                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
34                 CVf_LOCKED OPpREVERSE_INPLACE
35                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES)) {
36         eval { import B $_ };
37         no strict 'refs';
38         *{$_} = sub () {0} unless *{$_}{CODE};
39     }
40 }
41
42 # Changes between 0.50 and 0.51:
43 # - fixed nulled leave with live enter in sort { }
44 # - fixed reference constants (\"str")
45 # - handle empty programs gracefully
46 # - handle infinite loops (for (;;) {}, while (1) {})
47 # - differentiate between `for my $x ...' and `my $x; for $x ...'
48 # - various minor cleanups
49 # - moved globals into an object
50 # - added `-u', like B::C
51 # - package declarations using cop_stash
52 # - subs, formats and code sorted by cop_seq
53 # Changes between 0.51 and 0.52:
54 # - added pp_threadsv (special variables under USE_5005THREADS)
55 # - added documentation
56 # Changes between 0.52 and 0.53:
57 # - many changes adding precedence contexts and associativity
58 # - added `-p' and `-s' output style options
59 # - various other minor fixes
60 # Changes between 0.53 and 0.54:
61 # - added support for new `for (1..100)' optimization,
62 #   thanks to Gisle Aas
63 # Changes between 0.54 and 0.55:
64 # - added support for new qr// construct
65 # - added support for new pp_regcreset OP
66 # Changes between 0.55 and 0.56:
67 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
68 # - fixed $# on non-lexicals broken in last big rewrite
69 # - added temporary fix for change in opcode of OP_STRINGIFY
70 # - fixed problem in 0.54's for() patch in `for (@ary)'
71 # - fixed precedence in conditional of ?:
72 # - tweaked list paren elimination in `my($x) = @_'
73 # - made continue-block detection trickier wrt. null ops
74 # - fixed various prototype problems in pp_entersub
75 # - added support for sub prototypes that never get GVs
76 # - added unquoting for special filehandle first arg in truncate
77 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
78 # - added semicolons at the ends of blocks
79 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
80 # Changes between 0.56 and 0.561:
81 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
82 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
83 # Changes between 0.561 and 0.57:
84 # - stylistic changes to symbolic constant stuff
85 # - handled scope in s///e replacement code
86 # - added unquote option for expanding "" into concats, etc.
87 # - split method and proto parts of pp_entersub into separate functions
88 # - various minor cleanups
89 # Changes after 0.57:
90 # - added parens in \&foo (patch by Albert Dvornik)
91 # Changes between 0.57 and 0.58:
92 # - fixed `0' statements that weren't being printed
93 # - added methods for use from other programs
94 #   (based on patches from James Duncan and Hugo van der Sanden)
95 # - added -si and -sT to control indenting (also based on a patch from Hugo)
96 # - added -sv to print something else instead of '???'
97 # - preliminary version of utf8 tr/// handling
98 # Changes after 0.58:
99 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
100 # - added support for Hugo's new OP_SETSTATE (like nextstate)
101 # Changes between 0.58 and 0.59
102 # - added support for Chip's OP_METHOD_NAMED
103 # - added support for Ilya's OPpTARGET_MY optimization
104 # - elided arrows before `()' subscripts when possible
105 # Changes between 0.59 and 0.60
106 # - support for method attributes was added
107 # - some warnings fixed
108 # - separate recognition of constant subs
109 # - rewrote continue block handling, now recognizing for loops
110 # - added more control of expanding control structures
111 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
112 # - many bug-fixes
113 # - support for pragmas and 'use'
114 # - support for the little-used $[ variable
115 # - support for __DATA__ sections
116 # - UTF8 support
117 # - BEGIN, CHECK, INIT and END blocks
118 # - scoping of subroutine declarations fixed
119 # - compile-time output from the input program can be suppressed, so that the
120 #   output is just the deparsed code. (a change to O.pm in fact)
121 # - our() declarations
122 # - *all* the known bugs are now listed in the BUGS section
123 # - comprehensive test mechanism (TEST -deparse)
124 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
125 # - bug-fixes
126 # - new switch -P
127 # - support for command-line switches (-l, -0, etc.)
128 # Changes between 0.63 and 0.64
129 # - support for //, CHECK blocks, and assertions
130 # - improved handling of foreach loops and lexicals
131 # - option to use Data::Dumper for constants
132 # - more bug fixes
133 # - discovered lots more bugs not yet fixed
134 #
135 # ...
136 #
137 # Changes between 0.72 and 0.73
138 # - support new switch constructs
139
140 # Todo:
141 #  (See also BUGS section at the end of this file)
142 #
143 # - finish tr/// changes
144 # - add option for even more parens (generalize \&foo change)
145 # - left/right context
146 # - copy comments (look at real text with $^P?)
147 # - avoid semis in one-statement blocks
148 # - associativity of &&=, ||=, ?:
149 # - ',' => '=>' (auto-unquote?)
150 # - break long lines ("\r" as discretionary break?)
151 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
152 # - more style options: brace style, hex vs. octal, quotes, ...
153 # - print big ints as hex/octal instead of decimal (heuristic?)
154 # - handle `my $x if 0'?
155 # - version using op_next instead of op_first/sibling?
156 # - avoid string copies (pass arrays, one big join?)
157 # - here-docs?
158
159 # Current test.deparse failures
160 # comp/hints 6 - location of BEGIN blocks wrt. block openings
161 # run/switchI 1 - missing -I switches entirely
162 #    perl -Ifoo -e 'print @INC'
163 # op/caller 2 - warning mask propagates backwards before warnings::register
164 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
165 # op/getpid 2 - can't assign to shared my() declaration (threads only)
166 #    'my $x : shared = 5'
167 # op/override 7 - parens on overridden require change v-string interpretation
168 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
169 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
170 # op/pat 774 - losing Unicode-ness of Latin1-only strings
171 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
172 # op/recurse 12 - missing parens on recursive call makes it look like method
173 #    'sub f { f($x) }'
174 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
175 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
176 # op/tiehandle compile - "use strict" deparsed in the wrong place
177 # uni/tr_ several
178 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
179 # ext/Data/Dumper/t/dumper compile
180 # ext/DB_file/several
181 # ext/Encode/several
182 # ext/Ernno/Errno warnings
183 # ext/IO/lib/IO/t/io_sel 23
184 # ext/PerlIO/t/encoding compile
185 # ext/POSIX/t/posix 6
186 # ext/Socket/Socket 8
187 # ext/Storable/t/croak compile
188 # lib/Attribute/Handlers/t/multi compile
189 # lib/bignum/ several
190 # lib/charnames 35
191 # lib/constant 32
192 # lib/English 40
193 # lib/ExtUtils/t/bytes 4
194 # lib/File/DosGlob compile
195 # lib/Filter/Simple/t/data 1
196 # lib/Math/BigInt/t/constant 1
197 # lib/Net/t/config Deparse-warning
198 # lib/overload compile
199 # lib/Switch/ several
200 # lib/Symbol 4
201 # lib/Test/Simple several
202 # lib/Term/Complete
203 # lib/Tie/File/t/29_downcopy 5
204 # lib/vars 22
205
206 # Object fields (were globals):
207 #
208 # avoid_local:
209 # (local($a), local($b)) and local($a, $b) have the same internal
210 # representation but the short form looks better. We notice we can
211 # use a large-scale local when checking the list, but need to prevent
212 # individual locals too. This hash holds the addresses of OPs that
213 # have already had their local-ness accounted for. The same thing
214 # is done with my().
215 #
216 # curcv:
217 # CV for current sub (or main program) being deparsed
218 #
219 # curcvlex:
220 # Cached hash of lexical variables for curcv: keys are names,
221 # each value is an array of pairs, indicating the cop_seq of scopes
222 # in which a var of that name is valid.
223 #
224 # curcop:
225 # COP for statement being deparsed
226 #
227 # curstash:
228 # name of the current package for deparsed code
229 #
230 # subs_todo:
231 # array of [cop_seq, CV, is_format?] for subs and formats we still
232 # want to deparse
233 #
234 # protos_todo:
235 # as above, but [name, prototype] for subs that never got a GV
236 #
237 # subs_done, forms_done:
238 # keys are addresses of GVs for subs and formats we've already
239 # deparsed (or at least put into subs_todo)
240 #
241 # subs_declared
242 # keys are names of subs for which we've printed declarations.
243 # That means we can omit parentheses from the arguments. It also means we
244 # need to put CORE:: on core functions of the same name.
245 #
246 # subs_deparsed
247 # Keeps track of fully qualified names of all deparsed subs.
248 #
249 # parens: -p
250 # linenums: -l
251 # unquote: -q
252 # cuddle: ` ' or `\n', depending on -sC
253 # indent_size: -si
254 # use_tabs: -sT
255 # ex_const: -sv
256
257 # A little explanation of how precedence contexts and associativity
258 # work:
259 #
260 # deparse() calls each per-op subroutine with an argument $cx (short
261 # for context, but not the same as the cx* in the perl core), which is
262 # a number describing the op's parents in terms of precedence, whether
263 # they're inside an expression or at statement level, etc.  (see
264 # chart below). When ops with children call deparse on them, they pass
265 # along their precedence. Fractional values are used to implement
266 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
267 # parentheses hacks. The major disadvantage of this scheme is that
268 # it doesn't know about right sides and left sides, so say if you
269 # assign a listop to a variable, it can't tell it's allowed to leave
270 # the parens off the listop.
271
272 # Precedences:
273 # 26             [TODO] inside interpolation context ("")
274 # 25 left        terms and list operators (leftward)
275 # 24 left        ->
276 # 23 nonassoc    ++ --
277 # 22 right       **
278 # 21 right       ! ~ \ and unary + and -
279 # 20 left        =~ !~
280 # 19 left        * / % x
281 # 18 left        + - .
282 # 17 left        << >>
283 # 16 nonassoc    named unary operators
284 # 15 nonassoc    < > <= >= lt gt le ge
285 # 14 nonassoc    == != <=> eq ne cmp
286 # 13 left        &
287 # 12 left        | ^
288 # 11 left        &&
289 # 10 left        ||
290 #  9 nonassoc    ..  ...
291 #  8 right       ?:
292 #  7 right       = += -= *= etc.
293 #  6 left        , =>
294 #  5 nonassoc    list operators (rightward)
295 #  4 right       not
296 #  3 left        and
297 #  2 left        or xor
298 #  1             statement modifiers
299 #  0.5           statements, but still print scopes as do { ... }
300 #  0             statement level
301
302 # Nonprinting characters with special meaning:
303 # \cS - steal parens (see maybe_parens_unop)
304 # \n - newline and indent
305 # \t - increase indent
306 # \b - decrease indent (`outdent')
307 # \f - flush left (no indent)
308 # \cK - kill following semicolon, if any
309
310 sub null {
311     my $op = shift;
312     return class($op) eq "NULL";
313 }
314
315 sub todo {
316     my $self = shift;
317     my($cv, $is_form) = @_;
318     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
319     my $seq;
320     if ($cv->OUTSIDE_SEQ) {
321         $seq = $cv->OUTSIDE_SEQ;
322     } elsif (!null($cv->START) and is_state($cv->START)) {
323         $seq = $cv->START->cop_seq;
324     } else {
325         $seq = 0;
326     }
327     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
328     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
329         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
330     }
331 }
332
333 sub next_todo {
334     my $self = shift;
335     my $ent = shift @{$self->{'subs_todo'}};
336     my $cv = $ent->[1];
337     my $gv = $cv->GV;
338     my $name = $self->gv_name($gv);
339     if ($ent->[2]) {
340         return "format $name =\n"
341             . $self->deparse_format($ent->[1]). "\n";
342     } else {
343         $self->{'subs_declared'}{$name} = 1;
344         if ($name eq "BEGIN") {
345             my $use_dec = $self->begin_is_use($cv);
346             if (defined ($use_dec) and $self->{'expand'} < 5) {
347                 return () if 0 == length($use_dec);
348                 return $use_dec;
349             }
350         }
351         my $l = '';
352         if ($self->{'linenums'}) {
353             my $line = $gv->LINE;
354             my $file = $gv->FILE;
355             $l = "\n\f#line $line \"$file\"\n";
356         }
357         my $p = '';
358         if (class($cv->STASH) ne "SPECIAL") {
359             my $stash = $cv->STASH->NAME;
360             if ($stash ne $self->{'curstash'}) {
361                 $p = "package $stash;\n";
362                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
363                 $self->{'curstash'} = $stash;
364             }
365             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
366         }
367         return "${p}${l}sub $name " . $self->deparse_sub($cv);
368     }
369 }
370
371 # Return a "use" declaration for this BEGIN block, if appropriate
372 sub begin_is_use {
373     my ($self, $cv) = @_;
374     my $root = $cv->ROOT;
375     local @$self{qw'curcv curcvlex'} = ($cv);
376 #require B::Debug;
377 #B::walkoptree($cv->ROOT, "debug");
378     my $lineseq = $root->first;
379     return if $lineseq->name ne "lineseq";
380
381     my $req_op = $lineseq->first->sibling;
382     return if $req_op->name ne "require";
383
384     my $module;
385     if ($req_op->first->private & OPpCONST_BARE) {
386         # Actually it should always be a bareword
387         $module = $self->const_sv($req_op->first)->PV;
388         $module =~ s[/][::]g;
389         $module =~ s/.pm$//;
390     }
391     else {
392         $module = $self->const($self->const_sv($req_op->first), 6);
393     }
394
395     my $version;
396     my $version_op = $req_op->sibling;
397     return if class($version_op) eq "NULL";
398     if ($version_op->name eq "lineseq") {
399         # We have a version parameter; skip nextstate & pushmark
400         my $constop = $version_op->first->next->next;
401
402         return unless $self->const_sv($constop)->PV eq $module;
403         $constop = $constop->sibling;
404         $version = $self->const_sv($constop);
405         if (class($version) eq "IV") {
406             $version = $version->int_value;
407         } elsif (class($version) eq "NV") {
408             $version = $version->NV;
409         } elsif (class($version) ne "PVMG") {
410             # Includes PVIV and PVNV
411             $version = $version->PV;
412         } else {
413             # version specified as a v-string
414             $version = 'v'.join '.', map ord, split //, $version->PV;
415         }
416         $constop = $constop->sibling;
417         return if $constop->name ne "method_named";
418         return if $self->const_sv($constop)->PV ne "VERSION";
419     }
420
421     $lineseq = $version_op->sibling;
422     return if $lineseq->name ne "lineseq";
423     my $entersub = $lineseq->first->sibling;
424     if ($entersub->name eq "stub") {
425         return "use $module $version ();\n" if defined $version;
426         return "use $module ();\n";
427     }
428     return if $entersub->name ne "entersub";
429
430     # See if there are import arguments
431     my $args = '';
432
433     my $svop = $entersub->first->sibling; # Skip over pushmark
434     return unless $self->const_sv($svop)->PV eq $module;
435
436     # Pull out the arguments
437     for ($svop=$svop->sibling; $svop->name ne "method_named";
438                 $svop = $svop->sibling) {
439         $args .= ", " if length($args);
440         $args .= $self->deparse($svop, 6);
441     }
442
443     my $use = 'use';
444     my $method_named = $svop;
445     return if $method_named->name ne "method_named";
446     my $method_name = $self->const_sv($method_named)->PV;
447
448     if ($method_name eq "unimport") {
449         $use = 'no';
450     }
451
452     # Certain pragmas are dealt with using hint bits,
453     # so we ignore them here
454     if ($module eq 'strict' || $module eq 'integer'
455         || $module eq 'bytes' || $module eq 'warnings'
456         || $module eq 'feature') {
457         return "";
458     }
459
460     if (defined $version && length $args) {
461         return "$use $module $version ($args);\n";
462     } elsif (defined $version) {
463         return "$use $module $version;\n";
464     } elsif (length $args) {
465         return "$use $module ($args);\n";
466     } else {
467         return "$use $module;\n";
468     }
469 }
470
471 sub stash_subs {
472     my ($self, $pack) = @_;
473     my (@ret, $stash);
474     if (!defined $pack) {
475         $pack = '';
476         $stash = \%::;
477     }
478     else {
479         $pack =~ s/(::)?$/::/;
480         no strict 'refs';
481         $stash = \%{"main::$pack"};
482     }
483     my %stash = svref_2object($stash)->ARRAY;
484     while (my ($key, $val) = each %stash) {
485         my $class = class($val);
486         if ($class eq "PV") {
487             # Just a prototype. As an ugly but fairly effective way
488             # to find out if it belongs here is to see if the AUTOLOAD
489             # (if any) for the stash was defined in one of our files.
490             my $A = $stash{"AUTOLOAD"};
491             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
492                 && class($A->CV) eq "CV") {
493                 my $AF = $A->FILE;
494                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
495             }
496             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
497         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
498             # Just a name. As above.
499             # But skip proxy constant subroutines, as some form of perl-space
500             # visible code must have created them, be it a use statement, or
501             # some direct symbol-table manipulation code that we will Deparse
502             my $A = $stash{"AUTOLOAD"};
503             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
504                 && class($A->CV) eq "CV") {
505                 my $AF = $A->FILE;
506                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
507             }
508             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
509         } elsif ($class eq "GV") {
510             if (class(my $cv = $val->CV) ne "SPECIAL") {
511                 next if $self->{'subs_done'}{$$val}++;
512                 next if $$val != ${$cv->GV};   # Ignore imposters
513                 $self->todo($cv, 0);
514             }
515             if (class(my $cv = $val->FORM) ne "SPECIAL") {
516                 next if $self->{'forms_done'}{$$val}++;
517                 next if $$val != ${$cv->GV};   # Ignore imposters
518                 $self->todo($cv, 1);
519             }
520             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
521                 $self->stash_subs($pack . $key)
522                     unless $pack eq '' && $key eq 'main::';
523                     # avoid infinite recursion
524             }
525         }
526     }
527 }
528
529 sub print_protos {
530     my $self = shift;
531     my $ar;
532     my @ret;
533     foreach $ar (@{$self->{'protos_todo'}}) {
534         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
535         push @ret, "sub " . $ar->[0] .  "$proto;\n";
536     }
537     delete $self->{'protos_todo'};
538     return @ret;
539 }
540
541 sub style_opts {
542     my $self = shift;
543     my $opts = shift;
544     my $opt;
545     while (length($opt = substr($opts, 0, 1))) {
546         if ($opt eq "C") {
547             $self->{'cuddle'} = " ";
548             $opts = substr($opts, 1);
549         } elsif ($opt eq "i") {
550             $opts =~ s/^i(\d+)//;
551             $self->{'indent_size'} = $1;
552         } elsif ($opt eq "T") {
553             $self->{'use_tabs'} = 1;
554             $opts = substr($opts, 1);
555         } elsif ($opt eq "v") {
556             $opts =~ s/^v([^.]*)(.|$)//;
557             $self->{'ex_const'} = $1;
558         }
559     }
560 }
561
562 sub new {
563     my $class = shift;
564     my $self = bless {}, $class;
565     $self->{'cuddle'} = "\n";
566     $self->{'curcop'} = undef;
567     $self->{'curstash'} = "main";
568     $self->{'ex_const'} = "'???'";
569     $self->{'expand'} = 0;
570     $self->{'files'} = {};
571     $self->{'indent_size'} = 4;
572     $self->{'linenums'} = 0;
573     $self->{'parens'} = 0;
574     $self->{'subs_todo'} = [];
575     $self->{'unquote'} = 0;
576     $self->{'use_dumper'} = 0;
577     $self->{'use_tabs'} = 0;
578
579     $self->{'ambient_arybase'} = 0;
580     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
581     $self->{'ambient_hints'} = 0;
582     $self->{'ambient_hinthash'} = undef;
583     $self->init();
584
585     while (my $arg = shift @_) {
586         if ($arg eq "-d") {
587             $self->{'use_dumper'} = 1;
588             require Data::Dumper;
589         } elsif ($arg =~ /^-f(.*)/) {
590             $self->{'files'}{$1} = 1;
591         } elsif ($arg eq "-l") {
592             $self->{'linenums'} = 1;
593         } elsif ($arg eq "-p") {
594             $self->{'parens'} = 1;
595         } elsif ($arg eq "-P") {
596             $self->{'noproto'} = 1;
597         } elsif ($arg eq "-q") {
598             $self->{'unquote'} = 1;
599         } elsif (substr($arg, 0, 2) eq "-s") {
600             $self->style_opts(substr $arg, 2);
601         } elsif ($arg =~ /^-x(\d)$/) {
602             $self->{'expand'} = $1;
603         }
604     }
605     return $self;
606 }
607
608 {
609     # Mask out the bits that L<warnings::register> uses
610     my $WARN_MASK;
611     BEGIN {
612         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
613     }
614     sub WARN_MASK () {
615         return $WARN_MASK;
616     }
617 }
618
619 # Initialise the contextual information, either from
620 # defaults provided with the ambient_pragmas method,
621 # or from perl's own defaults otherwise.
622 sub init {
623     my $self = shift;
624
625     $self->{'arybase'}  = $self->{'ambient_arybase'};
626     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
627                                 ? $self->{'ambient_warnings'} & WARN_MASK
628                                 : undef;
629     $self->{'hints'}    = $self->{'ambient_hints'};
630     $self->{'hints'} &= 0xFF if $] < 5.009;
631     $self->{'hinthash'} = $self->{'ambient_hinthash'};
632
633     # also a convenient place to clear out subs_declared
634     delete $self->{'subs_declared'};
635 }
636
637 sub compile {
638     my(@args) = @_;
639     return sub {
640         my $self = B::Deparse->new(@args);
641         # First deparse command-line args
642         if (defined $^I) { # deparse -i
643             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
644         }
645         if ($^W) { # deparse -w
646             print qq(BEGIN { \$^W = $^W; }\n);
647         }
648         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
649             my $fs = perlstring($/) || 'undef';
650             my $bs = perlstring($O::savebackslash) || 'undef';
651             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
652         }
653         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
654         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
655             ? B::unitcheck_av->ARRAY
656             : ();
657         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
658         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
659         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
660         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
661             $self->todo($block, 0);
662         }
663         $self->stash_subs();
664         local($SIG{"__DIE__"}) =
665           sub {
666               if ($self->{'curcop'}) {
667                   my $cop = $self->{'curcop'};
668                   my($line, $file) = ($cop->line, $cop->file);
669                   print STDERR "While deparsing $file near line $line,\n";
670               }
671             };
672         $self->{'curcv'} = main_cv;
673         $self->{'curcvlex'} = undef;
674         print $self->print_protos;
675         @{$self->{'subs_todo'}} =
676           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
677         print $self->indent($self->deparse_root(main_root)), "\n"
678           unless null main_root;
679         my @text;
680         while (scalar(@{$self->{'subs_todo'}})) {
681             push @text, $self->next_todo;
682         }
683         print $self->indent(join("", @text)), "\n" if @text;
684
685         # Print __DATA__ section, if necessary
686         no strict 'refs';
687         my $laststash = defined $self->{'curcop'}
688             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
689         if (defined *{$laststash."::DATA"}{IO}) {
690             print "package $laststash;\n"
691                 unless $laststash eq $self->{'curstash'};
692             print "__DATA__\n";
693             print readline(*{$laststash."::DATA"});
694         }
695     }
696 }
697
698 sub coderef2text {
699     my $self = shift;
700     my $sub = shift;
701     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
702
703     $self->init();
704     return $self->indent($self->deparse_sub(svref_2object($sub)));
705 }
706
707 sub ambient_pragmas {
708     my $self = shift;
709     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
710
711     while (@_ > 1) {
712         my $name = shift();
713         my $val  = shift();
714
715         if ($name eq 'strict') {
716             require strict;
717
718             if ($val eq 'none') {
719                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
720                 next();
721             }
722
723             my @names;
724             if ($val eq "all") {
725                 @names = qw/refs subs vars/;
726             }
727             elsif (ref $val) {
728                 @names = @$val;
729             }
730             else {
731                 @names = split' ', $val;
732             }
733             $hint_bits |= strict::bits(@names);
734         }
735
736         elsif ($name eq '$[') {
737             if (OPpCONST_ARYBASE) {
738                 $arybase = $val;
739             } else {
740                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
741             }
742         }
743
744         elsif ($name eq 'integer'
745             || $name eq 'bytes'
746             || $name eq 'utf8') {
747             require "$name.pm";
748             if ($val) {
749                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
750             }
751             else {
752                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
753             }
754         }
755
756         elsif ($name eq 're') {
757             require re;
758             if ($val eq 'none') {
759                 $hint_bits &= ~re::bits(qw/taint eval/);
760                 next();
761             }
762
763             my @names;
764             if ($val eq 'all') {
765                 @names = qw/taint eval/;
766             }
767             elsif (ref $val) {
768                 @names = @$val;
769             }
770             else {
771                 @names = split' ',$val;
772             }
773             $hint_bits |= re::bits(@names);
774         }
775
776         elsif ($name eq 'warnings') {
777             if ($val eq 'none') {
778                 $warning_bits = $warnings::NONE;
779                 next();
780             }
781
782             my @names;
783             if (ref $val) {
784                 @names = @$val;
785             }
786             else {
787                 @names = split/\s+/, $val;
788             }
789
790             $warning_bits = $warnings::NONE if !defined ($warning_bits);
791             $warning_bits |= warnings::bits(@names);
792         }
793
794         elsif ($name eq 'warning_bits') {
795             $warning_bits = $val;
796         }
797
798         elsif ($name eq 'hint_bits') {
799             $hint_bits = $val;
800         }
801
802         elsif ($name eq '%^H') {
803             $hinthash = $val;
804         }
805
806         else {
807             croak "Unknown pragma type: $name";
808         }
809     }
810     if (@_) {
811         croak "The ambient_pragmas method expects an even number of args";
812     }
813
814     $self->{'ambient_arybase'} = $arybase;
815     $self->{'ambient_warnings'} = $warning_bits;
816     $self->{'ambient_hints'} = $hint_bits;
817     $self->{'ambient_hinthash'} = $hinthash;
818 }
819
820 # This method is the inner loop, so try to keep it simple
821 sub deparse {
822     my $self = shift;
823     my($op, $cx) = @_;
824
825     Carp::confess("Null op in deparse") if !defined($op)
826                                         || class($op) eq "NULL";
827     my $meth = "pp_" . $op->name;
828     return $self->$meth($op, $cx);
829 }
830
831 sub indent {
832     my $self = shift;
833     my $txt = shift;
834     my @lines = split(/\n/, $txt);
835     my $leader = "";
836     my $level = 0;
837     my $line;
838     for $line (@lines) {
839         my $cmd = substr($line, 0, 1);
840         if ($cmd eq "\t" or $cmd eq "\b") {
841             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
842             if ($self->{'use_tabs'}) {
843                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
844             } else {
845                 $leader = " " x $level;
846             }
847             $line = substr($line, 1);
848         }
849         if (substr($line, 0, 1) eq "\f") {
850             $line = substr($line, 1); # no indent
851         } else {
852             $line = $leader . $line;
853         }
854         $line =~ s/\cK;?//g;
855     }
856     return join("\n", @lines);
857 }
858
859 sub deparse_sub {
860     my $self = shift;
861     my $cv = shift;
862     my $proto = "";
863 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
864 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
865     local $self->{'curcop'} = $self->{'curcop'};
866     if ($cv->FLAGS & SVf_POK) {
867         $proto = "(". $cv->PV . ") ";
868     }
869     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
870         $proto .= ": ";
871         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
872         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
873         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
874     }
875
876     local($self->{'curcv'}) = $cv;
877     local($self->{'curcvlex'});
878     local(@$self{qw'curstash warnings hints hinthash'})
879                 = @$self{qw'curstash warnings hints hinthash'};
880     my $body;
881     if (not null $cv->ROOT) {
882         my $lineseq = $cv->ROOT->first;
883         if ($lineseq->name eq "lineseq") {
884             my @ops;
885             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
886                 push @ops, $o;
887             }
888             $body = $self->lineseq(undef, @ops).";";
889             my $scope_en = $self->find_scope_en($lineseq);
890             if (defined $scope_en) {
891                 my $subs = join"", $self->seq_subs($scope_en);
892                 $body .= ";\n$subs" if length($subs);
893             }
894         }
895         else {
896             $body = $self->deparse($cv->ROOT->first, 0);
897         }
898     }
899     else {
900         my $sv = $cv->const_sv;
901         if ($$sv) {
902             # uh-oh. inlinable sub... format it differently
903             return $proto . "{ " . $self->const($sv, 0) . " }\n";
904         } else { # XSUB? (or just a declaration)
905             return "$proto;\n";
906         }
907     }
908     return $proto ."{\n\t$body\n\b}" ."\n";
909 }
910
911 sub deparse_format {
912     my $self = shift;
913     my $form = shift;
914     my @text;
915     local($self->{'curcv'}) = $form;
916     local($self->{'curcvlex'});
917     local($self->{'in_format'}) = 1;
918     local(@$self{qw'curstash warnings hints hinthash'})
919                 = @$self{qw'curstash warnings hints hinthash'};
920     my $op = $form->ROOT;
921     my $kid;
922     return "\f." if $op->first->name eq 'stub'
923                 || $op->first->name eq 'nextstate';
924     $op = $op->first->first; # skip leavewrite, lineseq
925     while (not null $op) {
926         $op = $op->sibling; # skip nextstate
927         my @exprs;
928         $kid = $op->first->sibling; # skip pushmark
929         push @text, "\f".$self->const_sv($kid)->PV;
930         $kid = $kid->sibling;
931         for (; not null $kid; $kid = $kid->sibling) {
932             push @exprs, $self->deparse($kid, 0);
933         }
934         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
935         $op = $op->sibling;
936     }
937     return join("", @text) . "\f.";
938 }
939
940 sub is_scope {
941     my $op = shift;
942     return $op->name eq "leave" || $op->name eq "scope"
943       || $op->name eq "lineseq"
944         || ($op->name eq "null" && class($op) eq "UNOP"
945             && (is_scope($op->first) || $op->first->name eq "enter"));
946 }
947
948 sub is_state {
949     my $name = $_[0]->name;
950     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
951 }
952
953 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
954     my $op = shift;
955     return (!null($op) and null($op->sibling)
956             and $op->name eq "null" and class($op) eq "UNOP"
957             and (($op->first->name =~ /^(and|or)$/
958                   and $op->first->first->sibling->name eq "lineseq")
959                  or ($op->first->name eq "lineseq"
960                      and not null $op->first->first->sibling
961                      and $op->first->first->sibling->name eq "unstack")
962                  ));
963 }
964
965 # Check if the op and its sibling are the initialization and the rest of a
966 # for (..;..;..) { ... } loop
967 sub is_for_loop {
968     my $op = shift;
969     # This OP might be almost anything, though it won't be a
970     # nextstate. (It's the initialization, so in the canonical case it
971     # will be an sassign.) The sibling is (old style) a lineseq whose
972     # first child is a nextstate and whose second is a leaveloop, or
973     # (new style) an unstack whose sibling is a leaveloop.
974     my $lseq = $op->sibling;
975     return 0 unless !is_state($op) and !null($lseq);
976     if ($lseq->name eq "lineseq") {
977         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
978             && (my $sib = $lseq->first->sibling)) {
979             return (!null($sib) && $sib->name eq "leaveloop");
980         }
981     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
982         my $sib = $lseq->sibling;
983         return $sib && !null($sib) && $sib->name eq "leaveloop";
984     }
985     return 0;
986 }
987
988 sub is_scalar {
989     my $op = shift;
990     return ($op->name eq "rv2sv" or
991             $op->name eq "padsv" or
992             $op->name eq "gv" or # only in array/hash constructs
993             $op->flags & OPf_KIDS && !null($op->first)
994               && $op->first->name eq "gvsv");
995 }
996
997 sub maybe_parens {
998     my $self = shift;
999     my($text, $cx, $prec) = @_;
1000     if ($prec < $cx              # unary ops nest just fine
1001         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1002         or $self->{'parens'})
1003     {
1004         $text = "($text)";
1005         # In a unop, let parent reuse our parens; see maybe_parens_unop
1006         $text = "\cS" . $text if $cx == 16;
1007         return $text;
1008     } else {
1009         return $text;
1010     }
1011 }
1012
1013 # same as above, but get around the `if it looks like a function' rule
1014 sub maybe_parens_unop {
1015     my $self = shift;
1016     my($name, $kid, $cx) = @_;
1017     if ($cx > 16 or $self->{'parens'}) {
1018         $kid =  $self->deparse($kid, 1);
1019         if ($name eq "umask" && $kid =~ /^\d+$/) {
1020             $kid = sprintf("%#o", $kid);
1021         }
1022         return $self->keyword($name) . "($kid)";
1023     } else {
1024         $kid = $self->deparse($kid, 16);
1025         if ($name eq "umask" && $kid =~ /^\d+$/) {
1026             $kid = sprintf("%#o", $kid);
1027         }
1028         $name = $self->keyword($name);
1029         if (substr($kid, 0, 1) eq "\cS") {
1030             # use kid's parens
1031             return $name . substr($kid, 1);
1032         } elsif (substr($kid, 0, 1) eq "(") {
1033             # avoid looks-like-a-function trap with extra parens
1034             # (`+' can lead to ambiguities)
1035             return "$name(" . $kid  . ")";
1036         } else {
1037             return "$name $kid";
1038         }
1039     }
1040 }
1041
1042 sub maybe_parens_func {
1043     my $self = shift;
1044     my($func, $text, $cx, $prec) = @_;
1045     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1046         return "$func($text)";
1047     } else {
1048         return "$func $text";
1049     }
1050 }
1051
1052 sub maybe_local {
1053     my $self = shift;
1054     my($op, $cx, $text) = @_;
1055     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1056     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1057         and not $self->{'avoid_local'}{$$op}) {
1058         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1059         if( $our_local eq 'our' ) {
1060             if ( $text !~ /^\W(\w+::)*\w+\z/
1061              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1062             ) {
1063                 die "Unexpected our($text)\n";
1064             }
1065             $text =~ s/(\w+::)+//;
1066         }
1067         if (want_scalar($op)) {
1068             return "$our_local $text";
1069         } else {
1070             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1071         }
1072     } else {
1073         return $text;
1074     }
1075 }
1076
1077 sub maybe_targmy {
1078     my $self = shift;
1079     my($op, $cx, $func, @args) = @_;
1080     if ($op->private & OPpTARGET_MY) {
1081         my $var = $self->padname($op->targ);
1082         my $val = $func->($self, $op, 7, @args);
1083         return $self->maybe_parens("$var = $val", $cx, 7);
1084     } else {
1085         return $func->($self, $op, $cx, @args);
1086     }
1087 }
1088
1089 sub padname_sv {
1090     my $self = shift;
1091     my $targ = shift;
1092     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1093 }
1094
1095 sub maybe_my {
1096     my $self = shift;
1097     my($op, $cx, $text) = @_;
1098     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1099         my $my = $op->private & OPpPAD_STATE
1100             ? $self->keyword("state")
1101             : "my";
1102         if (want_scalar($op)) {
1103             return "$my $text";
1104         } else {
1105             return $self->maybe_parens_func($my, $text, $cx, 16);
1106         }
1107     } else {
1108         return $text;
1109     }
1110 }
1111
1112 # The following OPs don't have functions:
1113
1114 # pp_padany -- does not exist after parsing
1115
1116 sub AUTOLOAD {
1117     if ($AUTOLOAD =~ s/^.*::pp_//) {
1118         warn "unexpected OP_".uc $AUTOLOAD;
1119         return "XXX";
1120     } else {
1121         die "Undefined subroutine $AUTOLOAD called";
1122     }
1123 }
1124
1125 sub DESTROY {}  #       Do not AUTOLOAD
1126
1127 # $root should be the op which represents the root of whatever
1128 # we're sequencing here. If it's undefined, then we don't append
1129 # any subroutine declarations to the deparsed ops, otherwise we
1130 # append appropriate declarations.
1131 sub lineseq {
1132     my($self, $root, @ops) = @_;
1133     my($expr, @exprs);
1134
1135     my $out_cop = $self->{'curcop'};
1136     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1137     my $limit_seq;
1138     if (defined $root) {
1139         $limit_seq = $out_seq;
1140         my $nseq;
1141         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1142         $limit_seq = $nseq if !defined($limit_seq)
1143                            or defined($nseq) && $nseq < $limit_seq;
1144     }
1145     $limit_seq = $self->{'limit_seq'}
1146         if defined($self->{'limit_seq'})
1147         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1148     local $self->{'limit_seq'} = $limit_seq;
1149
1150     $self->walk_lineseq($root, \@ops,
1151                        sub { push @exprs, $_[0]} );
1152
1153     my $body = join(";\n", grep {length} @exprs);
1154     my $subs = "";
1155     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1156         $subs = join "\n", $self->seq_subs($limit_seq);
1157     }
1158     return join(";\n", grep {length} $body, $subs);
1159 }
1160
1161 sub scopeop {
1162     my($real_block, $self, $op, $cx) = @_;
1163     my $kid;
1164     my @kids;
1165
1166     local(@$self{qw'curstash warnings hints hinthash'})
1167                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1168     if ($real_block) {
1169         $kid = $op->first->sibling; # skip enter
1170         if (is_miniwhile($kid)) {
1171             my $top = $kid->first;
1172             my $name = $top->name;
1173             if ($name eq "and") {
1174                 $name = "while";
1175             } elsif ($name eq "or") {
1176                 $name = "until";
1177             } else { # no conditional -> while 1 or until 0
1178                 return $self->deparse($top->first, 1) . " while 1";
1179             }
1180             my $cond = $top->first;
1181             my $body = $cond->sibling->first; # skip lineseq
1182             $cond = $self->deparse($cond, 1);
1183             $body = $self->deparse($body, 1);
1184             return "$body $name $cond";
1185         }
1186     } else {
1187         $kid = $op->first;
1188     }
1189     for (; !null($kid); $kid = $kid->sibling) {
1190         push @kids, $kid;
1191     }
1192     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1193         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1194     } else {
1195         my $lineseq = $self->lineseq($op, @kids);
1196         return (length ($lineseq) ? "$lineseq;" : "");
1197     }
1198 }
1199
1200 sub pp_scope { scopeop(0, @_); }
1201 sub pp_lineseq { scopeop(0, @_); }
1202 sub pp_leave { scopeop(1, @_); }
1203
1204 # This is a special case of scopeop and lineseq, for the case of the
1205 # main_root. The difference is that we print the output statements as
1206 # soon as we get them, for the sake of impatient users.
1207 sub deparse_root {
1208     my $self = shift;
1209     my($op) = @_;
1210     local(@$self{qw'curstash warnings hints hinthash'})
1211       = @$self{qw'curstash warnings hints hinthash'};
1212     my @kids;
1213     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1214     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1215         push @kids, $kid;
1216     }
1217     $self->walk_lineseq($op, \@kids,
1218                         sub { print $self->indent($_[0].';');
1219                               print "\n" unless $_[1] == $#kids;
1220                           });
1221 }
1222
1223 sub walk_lineseq {
1224     my ($self, $op, $kids, $callback) = @_;
1225     my @kids = @$kids;
1226     for (my $i = 0; $i < @kids; $i++) {
1227         my $expr = "";
1228         if (is_state $kids[$i]) {
1229             $expr = $self->deparse($kids[$i++], 0);
1230             if ($i > $#kids) {
1231                 $callback->($expr, $i);
1232                 last;
1233             }
1234         }
1235         if (is_for_loop($kids[$i])) {
1236             $callback->($expr . $self->for_loop($kids[$i], 0),
1237                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1238             next;
1239         }
1240         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1241         $expr =~ s/;\n?\z//;
1242         $callback->($expr, $i);
1243     }
1244 }
1245
1246 # The BEGIN {} is used here because otherwise this code isn't executed
1247 # when you run B::Deparse on itself.
1248 my %globalnames;
1249 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1250             "ENV", "ARGV", "ARGVOUT", "_"); }
1251
1252 sub gv_name {
1253     my $self = shift;
1254     my $gv = shift;
1255 Carp::confess() unless ref($gv) eq "B::GV";
1256     my $stash = $gv->STASH->NAME;
1257     my $name = $gv->SAFENAME;
1258     if ($stash eq 'main' && $name =~ /^::/) {
1259         $stash = '::';
1260     }
1261     elsif (($stash eq 'main' && $globalnames{$name})
1262         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1263             && ($stash eq 'main' || $name !~ /::/))
1264         or $name =~ /^[^A-Za-z_:]/)
1265     {
1266         $stash = "";
1267     } else {
1268         $stash = $stash . "::";
1269     }
1270     if ($name =~ /^(\^..|{)/) {
1271         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1272     }
1273     return $stash . $name;
1274 }
1275
1276 # Return the name to use for a stash variable.
1277 # If a lexical with the same name is in scope, it may need to be
1278 # fully-qualified.
1279 sub stash_variable {
1280     my ($self, $prefix, $name, $cx) = @_;
1281
1282     return "$prefix$name" if $name =~ /::/;
1283
1284     unless ($prefix eq '$' || $prefix eq '@' || #'
1285             $prefix eq '%' || $prefix eq '$#') {
1286         return "$prefix$name";
1287     }
1288
1289     if ($name =~ /^[^\w+-]$/) {
1290       if (defined $cx && $cx == 26) {
1291         if ($prefix eq '@') {
1292             return "$prefix\{$name}";
1293         }
1294         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1295       }
1296       if ($prefix eq '$#') {
1297         return "\$#{$name}";
1298       }
1299     }
1300
1301     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1302     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1303     return "$prefix$name";
1304 }
1305
1306 sub lex_in_scope {
1307     my ($self, $name) = @_;
1308     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1309
1310     return 0 if !defined($self->{'curcop'});
1311     my $seq = $self->{'curcop'}->cop_seq;
1312     return 0 if !exists $self->{'curcvlex'}{$name};
1313     for my $a (@{$self->{'curcvlex'}{$name}}) {
1314         my ($st, $en) = @$a;
1315         return 1 if $seq > $st && $seq <= $en;
1316     }
1317     return 0;
1318 }
1319
1320 sub populate_curcvlex {
1321     my $self = shift;
1322     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1323         my $padlist = $cv->PADLIST;
1324         # an undef CV still in lexical chain
1325         next if class($padlist) eq "SPECIAL";
1326         my @padlist = $padlist->ARRAY;
1327         my @ns = $padlist[0]->ARRAY;
1328
1329         for (my $i=0; $i<@ns; ++$i) {
1330             next if class($ns[$i]) eq "SPECIAL";
1331             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1332             if (class($ns[$i]) eq "PV") {
1333                 # Probably that pesky lexical @_
1334                 next;
1335             }
1336             my $name = $ns[$i]->PVX;
1337             my ($seq_st, $seq_en) =
1338                 ($ns[$i]->FLAGS & SVf_FAKE)
1339                     ? (0, 999999)
1340                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1341
1342             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1343         }
1344     }
1345 }
1346
1347 sub find_scope_st { ((find_scope(@_))[0]); }
1348 sub find_scope_en { ((find_scope(@_))[1]); }
1349
1350 # Recurses down the tree, looking for pad variable introductions and COPs
1351 sub find_scope {
1352     my ($self, $op, $scope_st, $scope_en) = @_;
1353     carp("Undefined op in find_scope") if !defined $op;
1354     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1355
1356     my @queue = ($op);
1357     while(my $op = shift @queue ) {
1358         for (my $o=$op->first; $$o; $o=$o->sibling) {
1359             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1360                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1361                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1362                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1363                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1364                 return ($scope_st, $scope_en);
1365             }
1366             elsif (is_state($o)) {
1367                 my $c = $o->cop_seq;
1368                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1369                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1370                 return ($scope_st, $scope_en);
1371             }
1372             elsif ($o->flags & OPf_KIDS) {
1373                 unshift (@queue, $o);
1374             }
1375         }
1376     }
1377
1378     return ($scope_st, $scope_en);
1379 }
1380
1381 # Returns a list of subs which should be inserted before the COP
1382 sub cop_subs {
1383     my ($self, $op, $out_seq) = @_;
1384     my $seq = $op->cop_seq;
1385     # If we have nephews, then our sequence number indicates
1386     # the cop_seq of the end of some sort of scope.
1387     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1388         and my $nseq = $self->find_scope_st($op->sibling) ) {
1389         $seq = $nseq;
1390     }
1391     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1392     return $self->seq_subs($seq);
1393 }
1394
1395 sub seq_subs {
1396     my ($self, $seq) = @_;
1397     my @text;
1398 #push @text, "# ($seq)\n";
1399
1400     return "" if !defined $seq;
1401     while (scalar(@{$self->{'subs_todo'}})
1402            and $seq > $self->{'subs_todo'}[0][0]) {
1403         push @text, $self->next_todo;
1404     }
1405     return @text;
1406 }
1407
1408 # Notice how subs and formats are inserted between statements here;
1409 # also $[ assignments and pragmas.
1410 sub pp_nextstate {
1411     my $self = shift;
1412     my($op, $cx) = @_;
1413     $self->{'curcop'} = $op;
1414     my @text;
1415     push @text, $self->cop_subs($op);
1416     my $stash = $op->stashpv;
1417     if ($stash ne $self->{'curstash'}) {
1418         push @text, "package $stash;\n";
1419         $self->{'curstash'} = $stash;
1420     }
1421
1422     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
1423         push @text, '$[ = '. $op->arybase .";\n";
1424         $self->{'arybase'} = $op->arybase;
1425     }
1426
1427     my $warnings = $op->warnings;
1428     my $warning_bits;
1429     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1430         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1431     }
1432     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1433         $warning_bits = $warnings::NONE;
1434     }
1435     elsif ($warnings->isa("B::SPECIAL")) {
1436         $warning_bits = undef;
1437     }
1438     else {
1439         $warning_bits = $warnings->PV & WARN_MASK;
1440     }
1441
1442     if (defined ($warning_bits) and
1443        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1444         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1445         $self->{'warnings'} = $warning_bits;
1446     }
1447
1448     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1449     if ($self->{'hints'} != $hints) {
1450         push @text, declare_hints($self->{'hints'}, $hints);
1451         $self->{'hints'} = $hints;
1452     }
1453
1454     # hack to check that the hint hash hasn't changed
1455     if ($] > 5.009 &&
1456         "@{[sort %{$self->{'hinthash'} || {}}]}"
1457         ne "@{[sort %{$op->hints_hash->HASH || {}}]}") {
1458         push @text, declare_hinthash($self->{'hinthash'}, $op->hints_hash->HASH, $self->{indent_size});
1459         $self->{'hinthash'} = $op->hints_hash->HASH;
1460     }
1461
1462     # This should go after of any branches that add statements, to
1463     # increase the chances that it refers to the same line it did in
1464     # the original program.
1465     if ($self->{'linenums'}) {
1466         push @text, "\f#line " . $op->line .
1467           ' "' . $op->file, qq'"\n';
1468     }
1469
1470     push @text, $op->label . ": " if $op->label;
1471
1472     return join("", @text);
1473 }
1474
1475 sub declare_warnings {
1476     my ($from, $to) = @_;
1477     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1478         return "use warnings;\n";
1479     }
1480     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1481         return "no warnings;\n";
1482     }
1483     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1484 }
1485
1486 sub declare_hints {
1487     my ($from, $to) = @_;
1488     my $use = $to   & ~$from;
1489     my $no  = $from & ~$to;
1490     my $decls = "";
1491     for my $pragma (hint_pragmas($use)) {
1492         $decls .= "use $pragma;\n";
1493     }
1494     for my $pragma (hint_pragmas($no)) {
1495         $decls .= "no $pragma;\n";
1496     }
1497     return $decls;
1498 }
1499
1500 # Internal implementation hints that the core sets automatically, so don't need
1501 # (or want) to be passed back to the user
1502 my %ignored_hints = (
1503     'open<' => 1,
1504     'open>' => 1,
1505     ':'     => 1,
1506 );
1507
1508 sub declare_hinthash {
1509     my ($from, $to, $indent) = @_;
1510     my @decls;
1511     for my $key (keys %$to) {
1512         next if $ignored_hints{$key};
1513         if (!defined $from->{$key} or $from->{$key} ne $to->{$key}) {
1514             push @decls, qq(\$^H{'$key'} = q($to->{$key}););
1515         }
1516     }
1517     for my $key (keys %$from) {
1518         next if $ignored_hints{$key};
1519         if (!exists $to->{$key}) {
1520             push @decls, qq(delete \$^H{'$key'};);
1521         }
1522     }
1523     @decls or return '';
1524     return join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1525 }
1526
1527 sub hint_pragmas {
1528     my ($bits) = @_;
1529     my @pragmas;
1530     push @pragmas, "integer" if $bits & 0x1;
1531     push @pragmas, "strict 'refs'" if $bits & 0x2;
1532     push @pragmas, "bytes" if $bits & 0x8;
1533     return @pragmas;
1534 }
1535
1536 sub pp_dbstate { pp_nextstate(@_) }
1537 sub pp_setstate { pp_nextstate(@_) }
1538
1539 sub pp_unstack { return "" } # see also leaveloop
1540
1541 my %feature_keywords = (
1542   # keyword => 'feature',
1543     state   => 'state',
1544     say     => 'say',
1545     given   => 'switch',
1546     when    => 'switch',
1547     default => 'switch',
1548     break   => 'switch',
1549     evalbytes=>'evalbytes',
1550 );
1551
1552 sub keyword {
1553     my $self = shift;
1554     my $name = shift;
1555     return $name if $name =~ /^CORE::/; # just in case
1556     if (exists $feature_keywords{$name}) {
1557         return "CORE::$name"
1558          if !$self->{'hinthash'}
1559          || !$self->{'hinthash'}{"feature_$feature_keywords{$name}"}
1560     }
1561     if (
1562       $name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
1563        && !defined eval{prototype "CORE::$name"}
1564     ) { return $name }
1565     if (
1566         exists $self->{subs_declared}{$name}
1567          or
1568         exists &{"$self->{curstash}::$name"}
1569     ) {
1570         return "CORE::$name"
1571     }
1572     return $name;
1573 }
1574
1575 sub baseop {
1576     my $self = shift;
1577     my($op, $cx, $name) = @_;
1578     return $self->keyword($name);
1579 }
1580
1581 sub pp_stub {
1582     my $self = shift;
1583     my($op, $cx, $name) = @_;
1584     if ($cx >= 1) {
1585         return "()";
1586     }
1587     else {
1588         return "();";
1589     }
1590 }
1591 sub pp_wantarray { baseop(@_, "wantarray") }
1592 sub pp_fork { baseop(@_, "fork") }
1593 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1594 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1595 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1596 sub pp_tms { baseop(@_, "times") }
1597 sub pp_ghostent { baseop(@_, "gethostent") }
1598 sub pp_gnetent { baseop(@_, "getnetent") }
1599 sub pp_gprotoent { baseop(@_, "getprotoent") }
1600 sub pp_gservent { baseop(@_, "getservent") }
1601 sub pp_ehostent { baseop(@_, "endhostent") }
1602 sub pp_enetent { baseop(@_, "endnetent") }
1603 sub pp_eprotoent { baseop(@_, "endprotoent") }
1604 sub pp_eservent { baseop(@_, "endservent") }
1605 sub pp_gpwent { baseop(@_, "getpwent") }
1606 sub pp_spwent { baseop(@_, "setpwent") }
1607 sub pp_epwent { baseop(@_, "endpwent") }
1608 sub pp_ggrent { baseop(@_, "getgrent") }
1609 sub pp_sgrent { baseop(@_, "setgrent") }
1610 sub pp_egrent { baseop(@_, "endgrent") }
1611 sub pp_getlogin { baseop(@_, "getlogin") }
1612
1613 sub POSTFIX () { 1 }
1614
1615 # I couldn't think of a good short name, but this is the category of
1616 # symbolic unary operators with interesting precedence
1617
1618 sub pfixop {
1619     my $self = shift;
1620     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1621     my $kid = $op->first;
1622     $kid = $self->deparse($kid, $prec);
1623     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1624                                $cx, $prec);
1625 }
1626
1627 sub pp_preinc { pfixop(@_, "++", 23) }
1628 sub pp_predec { pfixop(@_, "--", 23) }
1629 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1630 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1631 sub pp_i_preinc { pfixop(@_, "++", 23) }
1632 sub pp_i_predec { pfixop(@_, "--", 23) }
1633 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1634 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1635 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1636
1637 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1638 sub real_negate {
1639     my $self = shift;
1640     my($op, $cx) = @_;
1641     if ($op->first->name =~ /^(i_)?negate$/) {
1642         # avoid --$x
1643         $self->pfixop($op, $cx, "-", 21.5);
1644     } else {
1645         $self->pfixop($op, $cx, "-", 21);       
1646     }
1647 }
1648 sub pp_i_negate { pp_negate(@_) }
1649
1650 sub pp_not {
1651     my $self = shift;
1652     my($op, $cx) = @_;
1653     if ($cx <= 4) {
1654         $self->pfixop($op, $cx, $self->keyword("not")." ", 4);
1655     } else {
1656         $self->pfixop($op, $cx, "!", 21);       
1657     }
1658 }
1659
1660 sub unop {
1661     my $self = shift;
1662     my($op, $cx, $name) = @_;
1663     my $kid;
1664     if ($op->flags & OPf_KIDS) {
1665         $kid = $op->first;
1666         if (not $name) {
1667             # this deals with 'boolkeys' right now
1668             return $self->deparse($kid,$cx);
1669         }
1670         my $builtinname = $name;
1671         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
1672         if (defined prototype($builtinname)
1673            && prototype($builtinname) =~ /^;?\*/
1674            && $kid->name eq "rv2gv") {
1675             $kid = $kid->first;
1676         }
1677
1678         return $self->maybe_parens_unop($name, $kid, $cx);
1679     } else {
1680         return $self->keyword($name)
1681           . ($op->flags & OPf_SPECIAL ? "()" : "");
1682     }
1683 }
1684
1685 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1686 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1687 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1688 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1689 sub pp_defined { unop(@_, "defined") }
1690 sub pp_undef { unop(@_, "undef") }
1691 sub pp_study { unop(@_, "study") }
1692 sub pp_ref { unop(@_, "ref") }
1693 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1694
1695 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1696 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1697 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1698 sub pp_srand { unop(@_, "srand") }
1699 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1700 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1701 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1702 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1703 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1704 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1705 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1706
1707 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1708 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1709 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1710
1711 sub pp_each { unop(@_, "each") }
1712 sub pp_values { unop(@_, "values") }
1713 sub pp_keys { unop(@_, "keys") }
1714 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
1715 sub pp_boolkeys { 
1716     # no name because its an optimisation op that has no keyword
1717     unop(@_,"");
1718 }
1719 sub pp_aeach { unop(@_, "each") }
1720 sub pp_avalues { unop(@_, "values") }
1721 sub pp_akeys { unop(@_, "keys") }
1722 sub pp_pop { unop(@_, "pop") }
1723 sub pp_shift { unop(@_, "shift") }
1724
1725 sub pp_caller { unop(@_, "caller") }
1726 sub pp_reset { unop(@_, "reset") }
1727 sub pp_exit { unop(@_, "exit") }
1728 sub pp_prototype { unop(@_, "prototype") }
1729
1730 sub pp_close { unop(@_, "close") }
1731 sub pp_fileno { unop(@_, "fileno") }
1732 sub pp_umask { unop(@_, "umask") }
1733 sub pp_untie { unop(@_, "untie") }
1734 sub pp_tied { unop(@_, "tied") }
1735 sub pp_dbmclose { unop(@_, "dbmclose") }
1736 sub pp_getc { unop(@_, "getc") }
1737 sub pp_eof { unop(@_, "eof") }
1738 sub pp_tell { unop(@_, "tell") }
1739 sub pp_getsockname { unop(@_, "getsockname") }
1740 sub pp_getpeername { unop(@_, "getpeername") }
1741
1742 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1743 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1744 sub pp_readlink { unop(@_, "readlink") }
1745 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1746 sub pp_readdir { unop(@_, "readdir") }
1747 sub pp_telldir { unop(@_, "telldir") }
1748 sub pp_rewinddir { unop(@_, "rewinddir") }
1749 sub pp_closedir { unop(@_, "closedir") }
1750 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1751 sub pp_localtime { unop(@_, "localtime") }
1752 sub pp_gmtime { unop(@_, "gmtime") }
1753 sub pp_alarm { unop(@_, "alarm") }
1754 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1755
1756 sub pp_dofile { unop(@_, "do") }
1757 sub pp_entereval {
1758     unop(
1759       @_,
1760       $_[1]->private & OPpEVAL_BYTES ? $_[0]->keyword('evalbytes') : "eval"
1761     )
1762 }
1763
1764 sub pp_ghbyname { unop(@_, "gethostbyname") }
1765 sub pp_gnbyname { unop(@_, "getnetbyname") }
1766 sub pp_gpbyname { unop(@_, "getprotobyname") }
1767 sub pp_shostent { unop(@_, "sethostent") }
1768 sub pp_snetent { unop(@_, "setnetent") }
1769 sub pp_sprotoent { unop(@_, "setprotoent") }
1770 sub pp_sservent { unop(@_, "setservent") }
1771 sub pp_gpwnam { unop(@_, "getpwnam") }
1772 sub pp_gpwuid { unop(@_, "getpwuid") }
1773 sub pp_ggrnam { unop(@_, "getgrnam") }
1774 sub pp_ggrgid { unop(@_, "getgrgid") }
1775
1776 sub pp_lock { unop(@_, "lock") }
1777
1778 sub pp_continue { unop(@_, "continue"); }
1779 sub pp_break { unop(@_, "break"); }
1780
1781 sub givwhen {
1782     my $self = shift;
1783     my($op, $cx, $givwhen) = @_;
1784
1785     my $enterop = $op->first;
1786     my ($head, $block);
1787     if ($enterop->flags & OPf_SPECIAL) {
1788         $head = $self->keyword("default");
1789         $block = $self->deparse($enterop->first, 0);
1790     }
1791     else {
1792         my $cond = $enterop->first;
1793         my $cond_str = $self->deparse($cond, 1);
1794         $head = "$givwhen ($cond_str)";
1795         $block = $self->deparse($cond->sibling, 0);
1796     }
1797
1798     return "$head {\n".
1799         "\t$block\n".
1800         "\b}\cK";
1801 }
1802
1803 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
1804 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
1805
1806 sub pp_exists {
1807     my $self = shift;
1808     my($op, $cx) = @_;
1809     my $arg;
1810     if ($op->private & OPpEXISTS_SUB) {
1811         # Checking for the existence of a subroutine
1812         return $self->maybe_parens_func("exists",
1813                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1814     }
1815     if ($op->flags & OPf_SPECIAL) {
1816         # Array element, not hash element
1817         return $self->maybe_parens_func("exists",
1818                                 $self->pp_aelem($op->first, 16), $cx, 16);
1819     }
1820     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1821                                     $cx, 16);
1822 }
1823
1824 sub pp_delete {
1825     my $self = shift;
1826     my($op, $cx) = @_;
1827     my $arg;
1828     if ($op->private & OPpSLICE) {
1829         if ($op->flags & OPf_SPECIAL) {
1830             # Deleting from an array, not a hash
1831             return $self->maybe_parens_func("delete",
1832                                         $self->pp_aslice($op->first, 16),
1833                                         $cx, 16);
1834         }
1835         return $self->maybe_parens_func("delete",
1836                                         $self->pp_hslice($op->first, 16),
1837                                         $cx, 16);
1838     } else {
1839         if ($op->flags & OPf_SPECIAL) {
1840             # Deleting from an array, not a hash
1841             return $self->maybe_parens_func("delete",
1842                                         $self->pp_aelem($op->first, 16),
1843                                         $cx, 16);
1844         }
1845         return $self->maybe_parens_func("delete",
1846                                         $self->pp_helem($op->first, 16),
1847                                         $cx, 16);
1848     }
1849 }
1850
1851 sub pp_require {
1852     my $self = shift;
1853     my($op, $cx) = @_;
1854     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
1855     if (class($op) eq "UNOP" and $op->first->name eq "const"
1856         and $op->first->private & OPpCONST_BARE)
1857     {
1858         my $name = $self->const_sv($op->first)->PV;
1859         $name =~ s[/][::]g;
1860         $name =~ s/\.pm//g;
1861         return "$opname $name";
1862     } else {    
1863         $self->unop($op, $cx, $op->first->private & OPpCONST_NOVER ? "no" : $opname);
1864     }
1865 }
1866
1867 sub pp_scalar {
1868     my $self = shift;
1869     my($op, $cx) = @_;
1870     my $kid = $op->first;
1871     if (not null $kid->sibling) {
1872         # XXX Was a here-doc
1873         return $self->dquote($op);
1874     }
1875     $self->unop(@_, "scalar");
1876 }
1877
1878
1879 sub padval {
1880     my $self = shift;
1881     my $targ = shift;
1882     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1883 }
1884
1885 sub anon_hash_or_list {
1886     my $self = shift;
1887     my($op, $cx) = @_;
1888
1889     my($pre, $post) = @{{"anonlist" => ["[","]"],
1890                          "anonhash" => ["{","}"]}->{$op->name}};
1891     my($expr, @exprs);
1892     $op = $op->first->sibling; # skip pushmark
1893     for (; !null($op); $op = $op->sibling) {
1894         $expr = $self->deparse($op, 6);
1895         push @exprs, $expr;
1896     }
1897     if ($pre eq "{" and $cx < 1) {
1898         # Disambiguate that it's not a block
1899         $pre = "+{";
1900     }
1901     return $pre . join(", ", @exprs) . $post;
1902 }
1903
1904 sub pp_anonlist {
1905     my $self = shift;
1906     my ($op, $cx) = @_;
1907     if ($op->flags & OPf_SPECIAL) {
1908         return $self->anon_hash_or_list($op, $cx);
1909     }
1910     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
1911     return 'XXX';
1912 }
1913
1914 *pp_anonhash = \&pp_anonlist;
1915
1916 sub pp_refgen {
1917     my $self = shift;   
1918     my($op, $cx) = @_;
1919     my $kid = $op->first;
1920     if ($kid->name eq "null") {
1921         $kid = $kid->first;
1922         if (!null($kid->sibling) and
1923                  $kid->sibling->name eq "anoncode") {
1924             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
1925         } elsif ($kid->name eq "pushmark") {
1926             my $sib_name = $kid->sibling->name;
1927             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1928                 and not $kid->sibling->flags & OPf_REF)
1929             {
1930                 # The @a in \(@a) isn't in ref context, but only when the
1931                 # parens are there.
1932                 return "\\(" . $self->pp_list($op->first) . ")";
1933             } elsif ($sib_name eq 'entersub') {
1934                 my $text = $self->deparse($kid->sibling, 1);
1935                 # Always show parens for \(&func()), but only with -p otherwise
1936                 $text = "($text)" if $self->{'parens'}
1937                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1938                 return "\\$text";
1939             }
1940         }
1941     }
1942     $self->pfixop($op, $cx, "\\", 20);
1943 }
1944
1945 sub e_anoncode {
1946     my ($self, $info) = @_;
1947     my $text = $self->deparse_sub($info->{code});
1948     return "sub " . $text;
1949 }
1950
1951 sub pp_srefgen { pp_refgen(@_) }
1952
1953 sub pp_readline {
1954     my $self = shift;
1955     my($op, $cx) = @_;
1956     my $kid = $op->first;
1957     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1958     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1959     return $self->unop($op, $cx, "readline");
1960 }
1961
1962 sub pp_rcatline {
1963     my $self = shift;
1964     my($op) = @_;
1965     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1966 }
1967
1968 # Unary operators that can occur as pseudo-listops inside double quotes
1969 sub dq_unop {
1970     my $self = shift;
1971     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1972     my $kid;
1973     if ($op->flags & OPf_KIDS) {
1974        $kid = $op->first;
1975        # If there's more than one kid, the first is an ex-pushmark.
1976        $kid = $kid->sibling if not null $kid->sibling;
1977        return $self->maybe_parens_unop($name, $kid, $cx);
1978     } else {
1979        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1980     }
1981 }
1982
1983 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1984 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1985 sub pp_uc { dq_unop(@_, "uc") }
1986 sub pp_lc { dq_unop(@_, "lc") }
1987 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1988
1989 sub loopex {
1990     my $self = shift;
1991     my ($op, $cx, $name) = @_;
1992     if (class($op) eq "PVOP") {
1993         return "$name " . $op->pv;
1994     } elsif (class($op) eq "OP") {
1995         return $name;
1996     } elsif (class($op) eq "UNOP") {
1997         # Note -- loop exits are actually exempt from the
1998         # looks-like-a-func rule, but a few extra parens won't hurt
1999         return $self->maybe_parens_unop($name, $op->first, $cx);
2000     }
2001 }
2002
2003 sub pp_last { loopex(@_, "last") }
2004 sub pp_next { loopex(@_, "next") }
2005 sub pp_redo { loopex(@_, "redo") }
2006 sub pp_goto { loopex(@_, "goto") }
2007 sub pp_dump { loopex(@_, $_[0]->keyword("dump")) }
2008
2009 sub ftst {
2010     my $self = shift;
2011     my($op, $cx, $name) = @_;
2012     if (class($op) eq "UNOP") {
2013         # Genuine `-X' filetests are exempt from the LLAFR, but not
2014         # l?stat(); for the sake of clarity, give'em all parens
2015         return $self->maybe_parens_unop($name, $op->first, $cx);
2016     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2017         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2018     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2019         return $name;
2020     }
2021 }
2022
2023 sub pp_lstat    { ftst(@_, "lstat") }
2024 sub pp_stat     { ftst(@_, "stat") }
2025 sub pp_ftrread  { ftst(@_, "-R") }
2026 sub pp_ftrwrite { ftst(@_, "-W") }
2027 sub pp_ftrexec  { ftst(@_, "-X") }
2028 sub pp_fteread  { ftst(@_, "-r") }
2029 sub pp_ftewrite { ftst(@_, "-w") }
2030 sub pp_fteexec  { ftst(@_, "-x") }
2031 sub pp_ftis     { ftst(@_, "-e") }
2032 sub pp_fteowned { ftst(@_, "-O") }
2033 sub pp_ftrowned { ftst(@_, "-o") }
2034 sub pp_ftzero   { ftst(@_, "-z") }
2035 sub pp_ftsize   { ftst(@_, "-s") }
2036 sub pp_ftmtime  { ftst(@_, "-M") }
2037 sub pp_ftatime  { ftst(@_, "-A") }
2038 sub pp_ftctime  { ftst(@_, "-C") }
2039 sub pp_ftsock   { ftst(@_, "-S") }
2040 sub pp_ftchr    { ftst(@_, "-c") }
2041 sub pp_ftblk    { ftst(@_, "-b") }
2042 sub pp_ftfile   { ftst(@_, "-f") }
2043 sub pp_ftdir    { ftst(@_, "-d") }
2044 sub pp_ftpipe   { ftst(@_, "-p") }
2045 sub pp_ftlink   { ftst(@_, "-l") }
2046 sub pp_ftsuid   { ftst(@_, "-u") }
2047 sub pp_ftsgid   { ftst(@_, "-g") }
2048 sub pp_ftsvtx   { ftst(@_, "-k") }
2049 sub pp_fttty    { ftst(@_, "-t") }
2050 sub pp_fttext   { ftst(@_, "-T") }
2051 sub pp_ftbinary { ftst(@_, "-B") }
2052
2053 sub SWAP_CHILDREN () { 1 }
2054 sub ASSIGN () { 2 } # has OP= variant
2055 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2056
2057 my(%left, %right);
2058
2059 sub assoc_class {
2060     my $op = shift;
2061     my $name = $op->name;
2062     if ($name eq "concat" and $op->first->name eq "concat") {
2063         # avoid spurious `=' -- see comment in pp_concat
2064         return "concat";
2065     }
2066     if ($name eq "null" and class($op) eq "UNOP"
2067         and $op->first->name =~ /^(and|x?or)$/
2068         and null $op->first->sibling)
2069     {
2070         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2071         # with a null that's used as the common end point of the two
2072         # flows of control. For precedence purposes, ignore it.
2073         # (COND_EXPRs have these too, but we don't bother with
2074         # their associativity).
2075         return assoc_class($op->first);
2076     }
2077     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2078 }
2079
2080 # Left associative operators, like `+', for which
2081 # $a + $b + $c is equivalent to ($a + $b) + $c
2082
2083 BEGIN {
2084     %left = ('multiply' => 19, 'i_multiply' => 19,
2085              'divide' => 19, 'i_divide' => 19,
2086              'modulo' => 19, 'i_modulo' => 19,
2087              'repeat' => 19,
2088              'add' => 18, 'i_add' => 18,
2089              'subtract' => 18, 'i_subtract' => 18,
2090              'concat' => 18,
2091              'left_shift' => 17, 'right_shift' => 17,
2092              'bit_and' => 13,
2093              'bit_or' => 12, 'bit_xor' => 12,
2094              'and' => 3,
2095              'or' => 2, 'xor' => 2,
2096             );
2097 }
2098
2099 sub deparse_binop_left {
2100     my $self = shift;
2101     my($op, $left, $prec) = @_;
2102     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2103         and $left{assoc_class($op)} == $left{assoc_class($left)})
2104     {
2105         return $self->deparse($left, $prec - .00001);
2106     } else {
2107         return $self->deparse($left, $prec);    
2108     }
2109 }
2110
2111 # Right associative operators, like `=', for which
2112 # $a = $b = $c is equivalent to $a = ($b = $c)
2113
2114 BEGIN {
2115     %right = ('pow' => 22,
2116               'sassign=' => 7, 'aassign=' => 7,
2117               'multiply=' => 7, 'i_multiply=' => 7,
2118               'divide=' => 7, 'i_divide=' => 7,
2119               'modulo=' => 7, 'i_modulo=' => 7,
2120               'repeat=' => 7,
2121               'add=' => 7, 'i_add=' => 7,
2122               'subtract=' => 7, 'i_subtract=' => 7,
2123               'concat=' => 7,
2124               'left_shift=' => 7, 'right_shift=' => 7,
2125               'bit_and=' => 7,
2126               'bit_or=' => 7, 'bit_xor=' => 7,
2127               'andassign' => 7,
2128               'orassign' => 7,
2129              );
2130 }
2131
2132 sub deparse_binop_right {
2133     my $self = shift;
2134     my($op, $right, $prec) = @_;
2135     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2136         and $right{assoc_class($op)} == $right{assoc_class($right)})
2137     {
2138         return $self->deparse($right, $prec - .00001);
2139     } else {
2140         return $self->deparse($right, $prec);   
2141     }
2142 }
2143
2144 sub binop {
2145     my $self = shift;
2146     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2147     my $left = $op->first;
2148     my $right = $op->last;
2149     my $eq = "";
2150     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2151         $eq = "=";
2152         $prec = 7;
2153     }
2154     if ($flags & SWAP_CHILDREN) {
2155         ($left, $right) = ($right, $left);
2156     }
2157     $left = $self->deparse_binop_left($op, $left, $prec);
2158     $left = "($left)" if $flags & LIST_CONTEXT
2159                 && $left !~ /^(my|our|local|)[\@\(]/;
2160     $right = $self->deparse_binop_right($op, $right, $prec);
2161     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2162 }
2163
2164 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2165 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2166 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2167 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2168 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2169 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2170 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2171 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2172 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2173 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2174 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2175
2176 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2177 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2178 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2179 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2180 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2181
2182 sub pp_eq { binop(@_, "==", 14) }
2183 sub pp_ne { binop(@_, "!=", 14) }
2184 sub pp_lt { binop(@_, "<", 15) }
2185 sub pp_gt { binop(@_, ">", 15) }
2186 sub pp_ge { binop(@_, ">=", 15) }
2187 sub pp_le { binop(@_, "<=", 15) }
2188 sub pp_ncmp { binop(@_, "<=>", 14) }
2189 sub pp_i_eq { binop(@_, "==", 14) }
2190 sub pp_i_ne { binop(@_, "!=", 14) }
2191 sub pp_i_lt { binop(@_, "<", 15) }
2192 sub pp_i_gt { binop(@_, ">", 15) }
2193 sub pp_i_ge { binop(@_, ">=", 15) }
2194 sub pp_i_le { binop(@_, "<=", 15) }
2195 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2196
2197 sub pp_seq { binop(@_, "eq", 14) }
2198 sub pp_sne { binop(@_, "ne", 14) }
2199 sub pp_slt { binop(@_, "lt", 15) }
2200 sub pp_sgt { binop(@_, "gt", 15) }
2201 sub pp_sge { binop(@_, "ge", 15) }
2202 sub pp_sle { binop(@_, "le", 15) }
2203 sub pp_scmp { binop(@_, "cmp", 14) }
2204
2205 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2206 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2207
2208 sub pp_smartmatch {
2209     my ($self, $op, $cx) = @_;
2210     if ($op->flags & OPf_SPECIAL) {
2211         return $self->deparse($op->last, $cx);
2212     }
2213     else {
2214         binop(@_, "~~", 14);
2215     }
2216 }
2217
2218 # `.' is special because concats-of-concats are optimized to save copying
2219 # by making all but the first concat stacked. The effect is as if the
2220 # programmer had written `($a . $b) .= $c', except legal.
2221 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2222 sub real_concat {
2223     my $self = shift;
2224     my($op, $cx) = @_;
2225     my $left = $op->first;
2226     my $right = $op->last;
2227     my $eq = "";
2228     my $prec = 18;
2229     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2230         $eq = "=";
2231         $prec = 7;
2232     }
2233     $left = $self->deparse_binop_left($op, $left, $prec);
2234     $right = $self->deparse_binop_right($op, $right, $prec);
2235     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2236 }
2237
2238 # `x' is weird when the left arg is a list
2239 sub pp_repeat {
2240     my $self = shift;
2241     my($op, $cx) = @_;
2242     my $left = $op->first;
2243     my $right = $op->last;
2244     my $eq = "";
2245     my $prec = 19;
2246     if ($op->flags & OPf_STACKED) {
2247         $eq = "=";
2248         $prec = 7;
2249     }
2250     if (null($right)) { # list repeat; count is inside left-side ex-list
2251         my $kid = $left->first->sibling; # skip pushmark
2252         my @exprs;
2253         for (; !null($kid->sibling); $kid = $kid->sibling) {
2254             push @exprs, $self->deparse($kid, 6);
2255         }
2256         $right = $kid;
2257         $left = "(" . join(", ", @exprs). ")";
2258     } else {
2259         $left = $self->deparse_binop_left($op, $left, $prec);
2260     }
2261     $right = $self->deparse_binop_right($op, $right, $prec);
2262     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2263 }
2264
2265 sub range {
2266     my $self = shift;
2267     my ($op, $cx, $type) = @_;
2268     my $left = $op->first;
2269     my $right = $left->sibling;
2270     $left = $self->deparse($left, 9);
2271     $right = $self->deparse($right, 9);
2272     return $self->maybe_parens("$left $type $right", $cx, 9);
2273 }
2274
2275 sub pp_flop {
2276     my $self = shift;
2277     my($op, $cx) = @_;
2278     my $flip = $op->first;
2279     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2280     return $self->range($flip->first, $cx, $type);
2281 }
2282
2283 # one-line while/until is handled in pp_leave
2284
2285 sub logop {
2286     my $self = shift;
2287     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2288     my $left = $op->first;
2289     my $right = $op->first->sibling;
2290     if ($cx < 1 and is_scope($right) and $blockname
2291         and $self->{'expand'} < 7)
2292     { # if ($a) {$b}
2293         $left = $self->deparse($left, 1);
2294         $right = $self->deparse($right, 0);
2295         return "$blockname ($left) {\n\t$right\n\b}\cK";
2296     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2297              and $self->{'expand'} < 7) { # $b if $a
2298         $right = $self->deparse($right, 1);
2299         $left = $self->deparse($left, 1);
2300         return "$right $blockname $left";
2301     } elsif ($cx > $lowprec and $highop) { # $a && $b
2302         $left = $self->deparse_binop_left($op, $left, $highprec);
2303         $right = $self->deparse_binop_right($op, $right, $highprec);
2304         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2305     } else { # $a and $b
2306         $left = $self->deparse_binop_left($op, $left, $lowprec);
2307         $right = $self->deparse_binop_right($op, $right, $lowprec);
2308         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2309     }
2310 }
2311
2312 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2313 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2314 sub pp_dor { logop(@_, "//", 10) }
2315
2316 # xor is syntactically a logop, but it's really a binop (contrary to
2317 # old versions of opcode.pl). Syntax is what matters here.
2318 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2319
2320 sub logassignop {
2321     my $self = shift;
2322     my ($op, $cx, $opname) = @_;
2323     my $left = $op->first;
2324     my $right = $op->first->sibling->first; # skip sassign
2325     $left = $self->deparse($left, 7);
2326     $right = $self->deparse($right, 7);
2327     return $self->maybe_parens("$left $opname $right", $cx, 7);
2328 }
2329
2330 sub pp_andassign { logassignop(@_, "&&=") }
2331 sub pp_orassign  { logassignop(@_, "||=") }
2332 sub pp_dorassign { logassignop(@_, "//=") }
2333
2334 sub listop {
2335     my $self = shift;
2336     my($op, $cx, $name) = @_;
2337     my(@exprs);
2338     my $parens = ($cx >= 5) || $self->{'parens'};
2339     my $kid = $op->first->sibling;
2340     return $self->keyword($name) if null $kid;
2341     my $first;
2342     $name = "socketpair" if $name eq "sockpair";
2343     my $fullname = $self->keyword($name);
2344     my $proto = prototype("CORE::$name");
2345     if (defined $proto
2346         && $proto =~ /^;?\*/
2347         && $kid->name eq "rv2gv") {
2348         $first = $self->deparse($kid->first, 6);
2349     }
2350     else {
2351         $first = $self->deparse($kid, 6);
2352     }
2353     if ($name eq "chmod" && $first =~ /^\d+$/) {
2354         $first = sprintf("%#o", $first);
2355     }
2356     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
2357     push @exprs, $first;
2358     $kid = $kid->sibling;
2359     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv") {
2360         push @exprs, $self->deparse($kid->first, 6);
2361         $kid = $kid->sibling;
2362     }
2363     for (; !null($kid); $kid = $kid->sibling) {
2364         push @exprs, $self->deparse($kid, 6);
2365     }
2366     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2367         return "$exprs[0] = $fullname"
2368                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2369     }
2370     if ($parens) {
2371         return "$fullname(" . join(", ", @exprs) . ")";
2372     } else {
2373         return "$fullname " . join(", ", @exprs);
2374     }
2375 }
2376
2377 sub pp_bless { listop(@_, "bless") }
2378 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2379 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2380 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2381 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2382 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2383 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2384 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2385 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2386 sub pp_unpack { listop(@_, "unpack") }
2387 sub pp_pack { listop(@_, "pack") }
2388 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2389 sub pp_splice { listop(@_, "splice") }
2390 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2391 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2392 sub pp_reverse { listop(@_, "reverse") }
2393 sub pp_warn { listop(@_, "warn") }
2394 sub pp_die { listop(@_, "die") }
2395 # Actually, return is exempt from the LLAFR (see examples in this very
2396 # module!), but for consistency's sake, ignore that fact
2397 sub pp_return { listop(@_, "return") }
2398 sub pp_open { listop(@_, "open") }
2399 sub pp_pipe_op { listop(@_, "pipe") }
2400 sub pp_tie { listop(@_, "tie") }
2401 sub pp_binmode { listop(@_, "binmode") }
2402 sub pp_dbmopen { listop(@_, "dbmopen") }
2403 sub pp_sselect { listop(@_, "select") }
2404 sub pp_select { listop(@_, "select") }
2405 sub pp_read { listop(@_, "read") }
2406 sub pp_sysopen { listop(@_, "sysopen") }
2407 sub pp_sysseek { listop(@_, "sysseek") }
2408 sub pp_sysread { listop(@_, "sysread") }
2409 sub pp_syswrite { listop(@_, "syswrite") }
2410 sub pp_send { listop(@_, "send") }
2411 sub pp_recv { listop(@_, "recv") }
2412 sub pp_seek { listop(@_, "seek") }
2413 sub pp_fcntl { listop(@_, "fcntl") }
2414 sub pp_ioctl { listop(@_, "ioctl") }
2415 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2416 sub pp_socket { listop(@_, "socket") }
2417 sub pp_sockpair { listop(@_, "sockpair") }
2418 sub pp_bind { listop(@_, "bind") }
2419 sub pp_connect { listop(@_, "connect") }
2420 sub pp_listen { listop(@_, "listen") }
2421 sub pp_accept { listop(@_, "accept") }
2422 sub pp_shutdown { listop(@_, "shutdown") }
2423 sub pp_gsockopt { listop(@_, "getsockopt") }
2424 sub pp_ssockopt { listop(@_, "setsockopt") }
2425 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2426 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2427 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2428 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2429 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2430 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2431 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2432 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2433 sub pp_open_dir { listop(@_, "opendir") }
2434 sub pp_seekdir { listop(@_, "seekdir") }
2435 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2436 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2437 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2438 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2439 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2440 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2441 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2442 sub pp_shmget { listop(@_, "shmget") }
2443 sub pp_shmctl { listop(@_, "shmctl") }
2444 sub pp_shmread { listop(@_, "shmread") }
2445 sub pp_shmwrite { listop(@_, "shmwrite") }
2446 sub pp_msgget { listop(@_, "msgget") }
2447 sub pp_msgctl { listop(@_, "msgctl") }
2448 sub pp_msgsnd { listop(@_, "msgsnd") }
2449 sub pp_msgrcv { listop(@_, "msgrcv") }
2450 sub pp_semget { listop(@_, "semget") }
2451 sub pp_semctl { listop(@_, "semctl") }
2452 sub pp_semop { listop(@_, "semop") }
2453 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2454 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2455 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2456 sub pp_gsbyname { listop(@_, "getservbyname") }
2457 sub pp_gsbyport { listop(@_, "getservbyport") }
2458 sub pp_syscall { listop(@_, "syscall") }
2459
2460 sub pp_glob {
2461     my $self = shift;
2462     my($op, $cx) = @_;
2463     my $text = $self->dq($op->first->sibling);  # skip pushmark
2464     my $keyword =
2465         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
2466     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2467         or $keyword =~ /^CORE::/
2468         or $text =~ /[<>]/) {
2469         return "$keyword(" . single_delim('qq', '"', $text) . ')';
2470     } else {
2471         return '<' . $text . '>';
2472     }
2473 }
2474
2475 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2476 # be a filehandle. This could probably be better fixed in the core
2477 # by moving the GV lookup into ck_truc.
2478
2479 sub pp_truncate {
2480     my $self = shift;
2481     my($op, $cx) = @_;
2482     my(@exprs);
2483     my $parens = ($cx >= 5) || $self->{'parens'};
2484     my $kid = $op->first->sibling;
2485     my $fh;
2486     if ($op->flags & OPf_SPECIAL) {
2487         # $kid is an OP_CONST
2488         $fh = $self->const_sv($kid)->PV;
2489     } else {
2490         $fh = $self->deparse($kid, 6);
2491         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2492     }
2493     my $len = $self->deparse($kid->sibling, 6);
2494     my $name = $self->keyword('truncate');
2495     if ($parens) {
2496         return "$name($fh, $len)";
2497     } else {
2498         return "$name $fh, $len";
2499     }
2500 }
2501
2502 sub indirop {
2503     my $self = shift;
2504     my($op, $cx, $name) = @_;
2505     my($expr, @exprs);
2506     my $firstkid = my $kid = $op->first->sibling;
2507     my $indir = "";
2508     if ($op->flags & OPf_STACKED) {
2509         $indir = $kid;
2510         $indir = $indir->first; # skip rv2gv
2511         if (is_scope($indir)) {
2512             $indir = "{" . $self->deparse($indir, 0) . "}";
2513             $indir = "{;}" if $indir eq "{}";
2514         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2515             $indir = $self->const_sv($indir)->PV;
2516         } else {
2517             $indir = $self->deparse($indir, 24);
2518         }
2519         $indir = $indir . " ";
2520         $kid = $kid->sibling;
2521     }
2522     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2523         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2524                                                   : '{$a <=> $b} ';
2525     }
2526     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2527         $indir = '{$b cmp $a} ';
2528     }
2529     for (; !null($kid); $kid = $kid->sibling) {
2530         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
2531         push @exprs, $expr;
2532     }
2533     my $name2;
2534     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2535         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
2536     }
2537     else { $name2 = $self->keyword($name) }
2538     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2539         return "$exprs[0] = $name2 $indir $exprs[0]";
2540     }
2541
2542     my $args = $indir . join(", ", @exprs);
2543     if ($indir ne "" && $name eq "sort") {
2544         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2545         # give bareword warnings in that case. Therefore if context
2546         # requires, we'll put parens around the outside "(sort f 1, 2,
2547         # 3)". Unfortunately, we'll currently think the parens are
2548         # necessary more often that they really are, because we don't
2549         # distinguish which side of an assignment we're on.
2550         if ($cx >= 5) {
2551             return "($name2 $args)";
2552         } else {
2553             return "$name2 $args";
2554         }
2555     } elsif (
2556         !$indir && $name eq "sort"
2557       && $op->first->sibling->name eq 'entersub'
2558     ) {
2559         # We cannot say sort foo(bar), as foo will be interpreted as a
2560         # comparison routine.  We have to say sort(...) in that case.
2561         return "$name2($args)";
2562     } else {
2563         return $self->maybe_parens_func($name2, $args, $cx, 5);
2564     }
2565
2566 }
2567
2568 sub pp_prtf { indirop(@_, "printf") }
2569 sub pp_print { indirop(@_, "print") }
2570 sub pp_say  { indirop(@_, "say") }
2571 sub pp_sort { indirop(@_, "sort") }
2572
2573 sub mapop {
2574     my $self = shift;
2575     my($op, $cx, $name) = @_;
2576     my($expr, @exprs);
2577     my $kid = $op->first; # this is the (map|grep)start
2578     $kid = $kid->first->sibling; # skip a pushmark
2579     my $code = $kid->first; # skip a null
2580     if (is_scope $code) {
2581         $code = "{" . $self->deparse($code, 0) . "} ";
2582     } else {
2583         $code = $self->deparse($code, 24) . ", ";
2584     }
2585     $kid = $kid->sibling;
2586     for (; !null($kid); $kid = $kid->sibling) {
2587         $expr = $self->deparse($kid, 6);
2588         push @exprs, $expr if defined $expr;
2589     }
2590     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2591 }
2592
2593 sub pp_mapwhile { mapop(@_, "map") }
2594 sub pp_grepwhile { mapop(@_, "grep") }
2595 sub pp_mapstart { baseop(@_, "map") }
2596 sub pp_grepstart { baseop(@_, "grep") }
2597
2598 sub pp_list {
2599     my $self = shift;
2600     my($op, $cx) = @_;
2601     my($expr, @exprs);
2602     my $kid = $op->first->sibling; # skip pushmark
2603     return '' if class($kid) eq 'NULL';
2604     my $lop;
2605     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2606     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2607         # This assumes that no other private flags equal 128, and that
2608         # OPs that store things other than flags in their op_private,
2609         # like OP_AELEMFAST, won't be immediate children of a list.
2610         #
2611         # OP_ENTERSUB can break this logic, so check for it.
2612         # I suspect that open and exit can too.
2613
2614         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2615                 or $lop->name eq "undef")
2616             or $lop->name eq "entersub"
2617             or $lop->name eq "exit"
2618             or $lop->name eq "open")
2619         {
2620             $local = ""; # or not
2621             last;
2622         }
2623         if ($lop->name =~ /^pad[ash]v$/) {
2624             if ($lop->private & OPpPAD_STATE) { # state()
2625                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
2626                 $local = "state";
2627             } else { # my()
2628                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
2629                 $local = "my";
2630             }
2631         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2632                         && $lop->private & OPpOUR_INTRO
2633                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2634                         && $lop->first->private & OPpOUR_INTRO) { # our()
2635             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
2636             $local = "our";
2637         } elsif ($lop->name ne "undef"
2638                 # specifically avoid the "reverse sort" optimisation,
2639                 # where "reverse" is nullified
2640                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2641         {
2642             # local()
2643             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
2644             $local = "local";
2645         }
2646     }
2647     $local = "" if $local eq "either"; # no point if it's all undefs
2648     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2649     for (; !null($kid); $kid = $kid->sibling) {
2650         if ($local) {
2651             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2652                 $lop = $kid->first;
2653             } else {
2654                 $lop = $kid;
2655             }
2656             $self->{'avoid_local'}{$$lop}++;
2657             $expr = $self->deparse($kid, 6);
2658             delete $self->{'avoid_local'}{$$lop};
2659         } else {
2660             $expr = $self->deparse($kid, 6);
2661         }
2662         push @exprs, $expr;
2663     }
2664     if ($local) {
2665         return "$local(" . join(", ", @exprs) . ")";
2666     } else {
2667         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
2668     }
2669 }
2670
2671 sub is_ifelse_cont {
2672     my $op = shift;
2673     return ($op->name eq "null" and class($op) eq "UNOP"
2674             and $op->first->name =~ /^(and|cond_expr)$/
2675             and is_scope($op->first->first->sibling));
2676 }
2677
2678 sub pp_cond_expr {
2679     my $self = shift;
2680     my($op, $cx) = @_;
2681     my $cond = $op->first;
2682     my $true = $cond->sibling;
2683     my $false = $true->sibling;
2684     my $cuddle = $self->{'cuddle'};
2685     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2686             (is_scope($false) || is_ifelse_cont($false))
2687             and $self->{'expand'} < 7) {
2688         $cond = $self->deparse($cond, 8);
2689         $true = $self->deparse($true, 6);
2690         $false = $self->deparse($false, 8);
2691         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2692     }
2693
2694     $cond = $self->deparse($cond, 1);
2695     $true = $self->deparse($true, 0);
2696     my $head = "if ($cond) {\n\t$true\n\b}";
2697     my @elsifs;
2698     while (!null($false) and is_ifelse_cont($false)) {
2699         my $newop = $false->first;
2700         my $newcond = $newop->first;
2701         my $newtrue = $newcond->sibling;
2702         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2703         if ($newcond->name eq "lineseq")
2704         {
2705             # lineseq to ensure correct line numbers in elsif()
2706             # Bug #37302 fixed by change #33710.
2707             $newcond = $newcond->first->sibling;
2708         }
2709         $newcond = $self->deparse($newcond, 1);
2710         $newtrue = $self->deparse($newtrue, 0);
2711         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2712     }
2713     if (!null($false)) {
2714         $false = $cuddle . "else {\n\t" .
2715           $self->deparse($false, 0) . "\n\b}\cK";
2716     } else {
2717         $false = "\cK";
2718     }
2719     return $head . join($cuddle, "", @elsifs) . $false;
2720 }
2721
2722 sub pp_once {
2723     my ($self, $op, $cx) = @_;
2724     my $cond = $op->first;
2725     my $true = $cond->sibling;
2726
2727     return $self->deparse($true, $cx);
2728 }
2729
2730 sub loop_common {
2731     my $self = shift;
2732     my($op, $cx, $init) = @_;
2733     my $enter = $op->first;
2734     my $kid = $enter->sibling;
2735     local(@$self{qw'curstash warnings hints hinthash'})
2736                 = @$self{qw'curstash warnings hints hinthash'};
2737     my $head = "";
2738     my $bare = 0;
2739     my $body;
2740     my $cond = undef;
2741     if ($kid->name eq "lineseq") { # bare or infinite loop
2742         if ($kid->last->name eq "unstack") { # infinite
2743             $head = "while (1) "; # Can't use for(;;) if there's a continue
2744             $cond = "";
2745         } else {
2746             $bare = 1;
2747         }
2748         $body = $kid;
2749     } elsif ($enter->name eq "enteriter") { # foreach
2750         my $ary = $enter->first->sibling; # first was pushmark
2751         my $var = $ary->sibling;
2752         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
2753             # "reverse" was optimised away
2754             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
2755         } elsif ($enter->flags & OPf_STACKED
2756             and not null $ary->first->sibling->sibling)
2757         {
2758             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2759               $self->deparse($ary->first->sibling->sibling, 9);
2760         } else {
2761             $ary = $self->deparse($ary, 1);
2762         }
2763         if (null $var) {
2764             if (($enter->flags & OPf_SPECIAL) && ($] < 5.009)) {
2765                 # thread special var, under 5005threads
2766                 $var = $self->pp_threadsv($enter, 1);
2767             } else { # regular my() variable
2768                 $var = $self->pp_padsv($enter, 1);
2769             }
2770         } elsif ($var->name eq "rv2gv") {
2771             $var = $self->pp_rv2sv($var, 1);
2772             if ($enter->private & OPpOUR_INTRO) {
2773                 # our declarations don't have package names
2774                 $var =~ s/^(.).*::/$1/;
2775                 $var = "our $var";
2776             }
2777         } elsif ($var->name eq "gv") {
2778             $var = "\$" . $self->deparse($var, 1);
2779         }
2780         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2781         if (!is_state $body->first and $body->first->name ne "stub") {
2782             confess unless $var eq '$_';
2783             $body = $body->first;
2784             return $self->deparse($body, 2) . " foreach ($ary)";
2785         }
2786         $head = "foreach $var ($ary) ";
2787     } elsif ($kid->name eq "null") { # while/until
2788         $kid = $kid->first;
2789         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2790         $cond = $self->deparse($kid->first, 1);
2791         $head = "$name ($cond) ";
2792         $body = $kid->first->sibling;
2793     } elsif ($kid->name eq "stub") { # bare and empty
2794         return "{;}"; # {} could be a hashref
2795     }
2796     # If there isn't a continue block, then the next pointer for the loop
2797     # will point to the unstack, which is kid's last child, except
2798     # in a bare loop, when it will point to the leaveloop. When neither of
2799     # these conditions hold, then the second-to-last child is the continue
2800     # block (or the last in a bare loop).
2801     my $cont_start = $enter->nextop;
2802     my $cont;
2803     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2804         if ($bare) {
2805             $cont = $body->last;
2806         } else {
2807             $cont = $body->first;
2808             while (!null($cont->sibling->sibling)) {
2809                 $cont = $cont->sibling;
2810             }
2811         }
2812         my $state = $body->first;
2813         my $cuddle = $self->{'cuddle'};
2814         my @states;
2815         for (; $$state != $$cont; $state = $state->sibling) {
2816             push @states, $state;
2817         }
2818         $body = $self->lineseq(undef, @states);
2819         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2820             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2821             $cont = "\cK";
2822         } else {
2823             $cont = $cuddle . "continue {\n\t" .
2824               $self->deparse($cont, 0) . "\n\b}\cK";
2825         }
2826     } else {
2827         return "" if !defined $body;
2828         if (length $init) {
2829             $head = "for ($init; $cond;) ";
2830         }
2831         $cont = "\cK";
2832         $body = $self->deparse($body, 0);
2833     }
2834     $body =~ s/;?$/;\n/;
2835
2836     return $head . "{\n\t" . $body . "\b}" . $cont;
2837 }
2838
2839 sub pp_leaveloop { shift->loop_common(@_, "") }
2840
2841 sub for_loop {
2842     my $self = shift;
2843     my($op, $cx) = @_;
2844     my $init = $self->deparse($op, 1);
2845     my $s = $op->sibling;
2846     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
2847     return $self->loop_common($ll, $cx, $init);
2848 }
2849
2850 sub pp_leavetry {
2851     my $self = shift;
2852     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2853 }
2854
2855 BEGIN { for (qw[ const stringify rv2sv list glob ]) {
2856     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
2857 }}
2858
2859 sub pp_null {
2860     my $self = shift;
2861     my($op, $cx) = @_;
2862     if (class($op) eq "OP") {
2863         # old value is lost
2864         return $self->{'ex_const'} if $op->targ == OP_CONST;
2865     } elsif ($op->first->name eq "pushmark") {
2866         return $self->pp_list($op, $cx);
2867     } elsif ($op->first->name eq "enter") {
2868         return $self->pp_leave($op, $cx);
2869     } elsif ($op->first->name eq "leave") {
2870         return $self->pp_leave($op->first, $cx);
2871     } elsif ($op->first->name eq "scope") {
2872         return $self->pp_scope($op->first, $cx);
2873     } elsif ($op->targ == OP_STRINGIFY) {
2874         return $self->dquote($op, $cx);
2875     } elsif ($op->targ == OP_GLOB) {
2876         return $self->pp_glob(
2877                  $op->first    # entersub
2878                     ->first    # ex-list
2879                     ->first    # pushmark
2880                     ->sibling, # glob
2881                  $cx
2882                );
2883     } elsif (!null($op->first->sibling) and
2884              $op->first->sibling->name eq "readline" and
2885              $op->first->sibling->flags & OPf_STACKED) {
2886         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2887                                    . $self->deparse($op->first->sibling, 7),
2888                                    $cx, 7);
2889     } elsif (!null($op->first->sibling) and
2890              $op->first->sibling->name eq "trans" and
2891              $op->first->sibling->flags & OPf_STACKED) {
2892         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2893                                    . $self->deparse($op->first->sibling, 20),
2894                                    $cx, 20);
2895     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2896         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2897     } elsif (!null($op->first->sibling) and
2898              $op->first->sibling->name eq "null" and
2899              class($op->first->sibling) eq "UNOP" and
2900              $op->first->sibling->first->flags & OPf_STACKED and
2901              $op->first->sibling->first->name eq "rcatline") {
2902         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2903                                    . $self->deparse($op->first->sibling, 18),
2904                                    $cx, 18);
2905     } else {
2906         return $self->deparse($op->first, $cx);
2907     }
2908 }
2909
2910 sub padname {
2911     my $self = shift;
2912     my $targ = shift;
2913     return $self->padname_sv($targ)->PVX;
2914 }
2915
2916 sub padany {
2917     my $self = shift;
2918     my $op = shift;
2919     return substr($self->padname($op->targ), 1); # skip $/@/%
2920 }
2921
2922 sub pp_padsv {
2923     my $self = shift;
2924     my($op, $cx) = @_;
2925     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2926 }
2927
2928 sub pp_padav { pp_padsv(@_) }
2929 sub pp_padhv { pp_padsv(@_) }
2930
2931 my @threadsv_names = B::threadsv_names;
2932 sub pp_threadsv {
2933     my $self = shift;
2934     my($op, $cx) = @_;
2935     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2936 }
2937
2938 sub gv_or_padgv {
2939     my $self = shift;
2940     my $op = shift;
2941     if (class($op) eq "PADOP") {
2942         return $self->padval($op->padix);
2943     } else { # class($op) eq "SVOP"
2944         return $op->gv;
2945     }
2946 }
2947
2948 sub pp_gvsv {
2949     my $self = shift;
2950     my($op, $cx) = @_;
2951     my $gv = $self->gv_or_padgv($op);
2952     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2953                                  $self->gv_name($gv), $cx));
2954 }
2955
2956 sub pp_gv {
2957     my $self = shift;
2958     my($op, $cx) = @_;
2959     my $gv = $self->gv_or_padgv($op);
2960     return $self->gv_name($gv);
2961 }
2962
2963 sub pp_aelemfast_lex {
2964     my $self = shift;
2965     my($op, $cx) = @_;
2966     my $name = $self->padname($op->targ);
2967     $name =~ s/^@/\$/;
2968     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2969 }
2970
2971 sub pp_aelemfast {
2972     my $self = shift;
2973     my($op, $cx) = @_;
2974     # optimised PADAV, pre 5.15
2975     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
2976
2977     my $gv = $self->gv_or_padgv($op);
2978     my $name = $self->gv_name($gv);
2979     $name = $self->{'curstash'}."::$name"
2980         if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2981     $name = '$' . $name;
2982     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2983 }
2984
2985 sub rv2x {
2986     my $self = shift;
2987     my($op, $cx, $type) = @_;
2988
2989     if (class($op) eq 'NULL' || !$op->can("first")) {
2990         carp("Unexpected op in pp_rv2x");
2991         return 'XXX';
2992     }
2993     my $kid = $op->first;
2994     if ($kid->name eq "gv") {
2995         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
2996     } elsif (is_scalar $kid) {
2997         my $str = $self->deparse($kid, 0);
2998         if ($str =~ /^\$([^\w\d])\z/) {
2999             # "$$+" isn't a legal way to write the scalar dereference
3000             # of $+, since the lexer can't tell you aren't trying to
3001             # do something like "$$ + 1" to get one more than your
3002             # PID. Either "${$+}" or "$${+}" are workable
3003             # disambiguations, but if the programmer did the former,
3004             # they'd be in the "else" clause below rather than here.
3005             # It's not clear if this should somehow be unified with
3006             # the code in dq and re_dq that also adds lexer
3007             # disambiguation braces.
3008             $str = '$' . "{$1}"; #'
3009         }
3010         return $type . $str;
3011     } else {
3012         return $type . "{" . $self->deparse($kid, 0) . "}";
3013     }
3014 }
3015
3016 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
3017 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
3018 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
3019
3020 # skip rv2av
3021 sub pp_av2arylen {
3022     my $self = shift;
3023     my($op, $cx) = @_;
3024     if ($op->first->name eq "padav") {
3025         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3026     } else {
3027         return $self->maybe_local($op, $cx,
3028                                   $self->rv2x($op->first, $cx, '$#'));
3029     }
3030 }
3031
3032 # skip down to the old, ex-rv2cv
3033 sub pp_rv2cv {
3034     my ($self, $op, $cx) = @_;
3035     if (!null($op->first) && $op->first->name eq 'null' &&
3036         $op->first->targ eq OP_LIST)
3037     {
3038         return $self->rv2x($op->first->first->sibling, $cx, "&")
3039     }
3040     else {
3041         return $self->rv2x($op, $cx, "")
3042     }
3043 }
3044
3045 sub list_const {
3046     my $self = shift;
3047     my($cx, @list) = @_;
3048     my @a = map $self->const($_, 6), @list;
3049     if (@a == 0) {
3050         return "()";
3051     } elsif (@a == 1) {
3052         return $a[0];
3053     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3054         # collapse (-1,0,1,2) into (-1..2)
3055         my ($s, $e) = @a[0,-1];
3056         my $i = $s;
3057         return $self->maybe_parens("$s..$e", $cx, 9)
3058           unless grep $i++ != $_, @a;
3059     }
3060     return $self->maybe_parens(join(", ", @a), $cx, 6);
3061 }
3062
3063 sub pp_rv2av {
3064     my $self = shift;
3065     my($op, $cx) = @_;
3066     my $kid = $op->first;
3067     if ($kid->name eq "const") { # constant list
3068         my $av = $self->const_sv($kid);
3069         return $self->list_const($cx, $av->ARRAY);
3070     } else {
3071         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3072     }
3073  }
3074
3075 sub is_subscriptable {
3076     my $op = shift;
3077     if ($op->name =~ /^[ahg]elem/) {
3078         return 1;
3079     } elsif ($op->name eq "entersub") {
3080         my $kid = $op->first;
3081         return 0 unless null $kid->sibling;
3082         $kid = $kid->first;
3083         $kid = $kid->sibling until null $kid->sibling;
3084         return 0 if is_scope($kid);
3085         $kid = $kid->first;
3086         return 0 if $kid->name eq "gv";
3087         return 0 if is_scalar($kid);
3088         return is_subscriptable($kid);  
3089     } else {
3090         return 0;
3091     }
3092 }
3093
3094 sub elem_or_slice_array_name
3095 {
3096     my $self = shift;
3097     my ($array, $left, $padname, $allow_arrow) = @_;
3098
3099     if ($array->name eq $padname) {
3100         return $self->padany($array);
3101     } elsif (is_scope($array)) { # ${expr}[0]
3102         return "{" . $self->deparse($array, 0) . "}";
3103     } elsif ($array->name eq "gv") {
3104         $array = $self->gv_name($self->gv_or_padgv($array));
3105         if ($array !~ /::/) {
3106             my $prefix = ($left eq '[' ? '@' : '%');
3107             $array = $self->{curstash}.'::'.$array
3108                 if $self->lex_in_scope($prefix . $array);
3109         }
3110         return $array;
3111     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3112         return $self->deparse($array, 24);
3113     } else {
3114         return undef;
3115     }
3116 }
3117
3118 sub elem_or_slice_single_index
3119 {
3120     my $self = shift;
3121     my ($idx) = @_;
3122
3123     $idx = $self->deparse($idx, 1);
3124
3125     # Outer parens in an array index will confuse perl
3126     # if we're interpolating in a regular expression, i.e.
3127     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3128     #
3129     # If $self->{parens}, then an initial '(' will
3130     # definitely be paired with a final ')'. If
3131     # !$self->{parens}, the misleading parens won't
3132     # have been added in the first place.
3133     #
3134     # [You might think that we could get "(...)...(...)"
3135     # where the initial and final parens do not match
3136     # each other. But we can't, because the above would
3137     # only happen if there's an infix binop between the
3138     # two pairs of parens, and *that* means that the whole
3139     # expression would be parenthesized as well.]
3140     #
3141     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3142
3143     # Hash-element braces will autoquote a bareword inside themselves.
3144     # We need to make sure that C<$hash{warn()}> doesn't come out as
3145     # C<$hash{warn}>, which has a quite different meaning. Currently
3146     # B::Deparse will always quote strings, even if the string was a
3147     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3148     # for constant strings.) So we can cheat slightly here - if we see
3149     # a bareword, we know that it is supposed to be a function call.
3150     #
3151     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3152
3153     return $idx;
3154 }
3155
3156 sub elem {
3157     my $self = shift;
3158     my ($op, $cx, $left, $right, $padname) = @_;
3159     my($array, $idx) = ($op->first, $op->first->sibling);
3160
3161     $idx = $self->elem_or_slice_single_index($idx);
3162
3163     unless ($array->name eq $padname) { # Maybe this has been fixed     
3164         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3165     }
3166     if (my $array_name=$self->elem_or_slice_array_name
3167             ($array, $left, $padname, 1)) {
3168         return "\$" . $array_name . $left . $idx . $right;
3169     } else {
3170         # $x[20][3]{hi} or expr->[20]
3171         my $arrow = is_subscriptable($array) ? "" : "->";
3172         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3173     }
3174
3175 }
3176
3177 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3178 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3179
3180 sub pp_gelem {
3181     my $self = shift;
3182     my($op, $cx) = @_;
3183     my($glob, $part) = ($op->first, $op->last);
3184     $glob = $glob->first; # skip rv2gv
3185     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3186     my $scope = is_scope($glob);
3187     $glob = $self->deparse($glob, 0);
3188     $part = $self->deparse($part, 1);
3189     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3190 }
3191
3192 sub slice {
3193     my $self = shift;
3194     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3195     my $last;
3196     my(@elems, $kid, $array, $list);
3197     if (class($op) eq "LISTOP") {
3198         $last = $op->last;
3199     } else { # ex-hslice inside delete()
3200         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3201         $last = $kid;
3202     }
3203     $array = $last;
3204     $array = $array->first
3205         if $array->name eq $regname or $array->name eq "null";
3206     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3207     $kid = $op->first->sibling; # skip pushmark
3208     if ($kid->name eq "list") {
3209         $kid = $kid->first->sibling; # skip list, pushmark
3210         for (; !null $kid; $kid = $kid->sibling) {
3211             push @elems, $self->deparse($kid, 6);
3212         }
3213         $list = join(", ", @elems);
3214     } else {
3215         $list = $self->elem_or_slice_single_index($kid);
3216     }
3217     return "\@" . $array . $left . $list . $right;
3218 }
3219
3220 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3221 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3222
3223 sub pp_lslice {
3224     my $self = shift;
3225     my($op, $cx) = @_;
3226     my $idx = $op->first;
3227     my $list = $op->last;
3228     my(@elems, $kid);
3229     $list = $self->deparse($list, 1);
3230     $idx = $self->deparse($idx, 1);
3231     return "($list)" . "[$idx]";
3232 }
3233
3234 sub want_scalar {
3235     my $op = shift;
3236     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3237 }
3238
3239 sub want_list {
3240     my $op = shift;
3241     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3242 }
3243
3244 sub _method {
3245     my $self = shift;
3246     my($op, $cx) = @_;
3247     my $kid = $op->first->sibling; # skip pushmark
3248     my($meth, $obj, @exprs);
3249     if ($kid->name eq "list" and want_list $kid) {
3250         # When an indirect object isn't a bareword but the args are in
3251         # parens, the parens aren't part of the method syntax (the LLAFR
3252         # doesn't apply), but they make a list with OPf_PARENS set that
3253         # doesn't get flattened by the append_elem that adds the method,
3254         # making a (object, arg1, arg2, ...) list where the object
3255         # usually is. This can be distinguished from
3256         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3257         # object) because in the later the list is in scalar context
3258         # as the left side of -> always is, while in the former
3259         # the list is in list context as method arguments always are.
3260         # (Good thing there aren't method prototypes!)
3261         $meth = $kid->sibling;
3262         $kid = $kid->first->sibling; # skip pushmark
3263         $obj = $kid;
3264         $kid = $kid->sibling;
3265         for (; not null $kid; $kid = $kid->sibling) {
3266             push @exprs, $kid;
3267         }
3268     } else {
3269         $obj = $kid;
3270         $kid = $kid->sibling;
3271         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3272               $kid = $kid->sibling) {
3273             push @exprs, $kid
3274         }
3275         $meth = $kid;
3276     }
3277
3278     if ($meth->name eq "method_named") {
3279         $meth = $self->const_sv($meth)->PV;
3280     } else {
3281         $meth = $meth->first;
3282         if ($meth->name eq "const") {
3283             # As of 5.005_58, this case is probably obsoleted by the
3284             # method_named case above
3285             $meth = $self->const_sv($meth)->PV; # needs to be bare
3286         }
3287     }
3288
3289     return { method => $meth, variable_method => ref($meth),
3290              object => $obj, args => \@exprs  };
3291 }
3292
3293 # compat function only
3294 sub method {
3295     my $self = shift;
3296     my $info = $self->_method(@_);
3297     return $self->e_method( $self->_method(@_) );
3298 }
3299
3300 sub e_method {
3301     my ($self, $info) = @_;
3302     my $obj = $self->deparse($info->{object}, 24);
3303
3304     my $meth = $info->{method};
3305     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3306     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3307     my $kid = $obj . "->" . $meth;
3308     if (length $args) {
3309         return $kid . "(" . $args . ")"; # parens mandatory
3310     } else {
3311         return $kid;
3312     }
3313 }
3314
3315 # returns "&" if the prototype doesn't match the args,
3316 # or ("", $args_after_prototype_demunging) if it does.
3317 sub check_proto {
3318     my $self = shift;
3319     return "&" if $self->{'noproto'};
3320     my($proto, @args) = @_;
3321     my($arg, $real);
3322     my $doneok = 0;
3323     my @reals;
3324     # An unbackslashed @ or % gobbles up the rest of the args
3325     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3326     while ($proto) {
3327         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)//;
3328         my $chr = $1;
3329         if ($chr eq "") {
3330             return "&" if @args;
3331         } elsif ($chr eq ";") {
3332             $doneok = 1;
3333         } elsif ($chr eq "@" or $chr eq "%") {
3334             push @reals, map($self->deparse($_, 6), @args);
3335             @args = ();
3336         } else {
3337             $arg = shift @args;
3338             last unless $arg;
3339             if ($chr eq "\$" || $chr eq "_") {
3340                 if (want_scalar $arg) {
3341                     push @reals, $self->deparse($arg, 6);
3342                 } else {
3343                     return "&";
3344                 }
3345             } elsif ($chr eq "&") {
3346                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3347                     push @reals, $self->deparse($arg, 6);
3348                 } else {
3349                     return "&";
3350                 }
3351             } elsif ($chr eq "*") {
3352                 if ($arg->name =~ /^s?refgen$/
3353                     and $arg->first->first->name eq "rv2gv")
3354                   {
3355                       $real = $arg->first->first; # skip refgen, null
3356                       if ($real->first->name eq "gv") {
3357                           push @reals, $self->deparse($real, 6);
3358                       } else {
3359                           push @reals, $self->deparse($real->first, 6);
3360                       }
3361                   } else {
3362                       return "&";
3363                   }
3364             } elsif (substr($chr, 0, 1) eq "\\") {
3365                 $chr =~ tr/\\[]//d;
3366                 if ($arg->name =~ /^s?refgen$/ and
3367                     !null($real = $arg->first) and
3368                     ($chr =~ /\$/ && is_scalar($real->first)
3369                      or ($chr =~ /@/
3370                          && class($real->first->sibling) ne 'NULL'
3371                          && $real->first->sibling->name
3372                          =~ /^(rv2|pad)av$/)
3373                      or ($chr =~ /%/
3374                          && class($real->first->sibling) ne 'NULL'
3375                          && $real->first->sibling->name
3376                          =~ /^(rv2|pad)hv$/)
3377                      #or ($chr =~ /&/ # This doesn't work
3378                      #   && $real->first->name eq "rv2cv")
3379                      or ($chr =~ /\*/
3380                          && $real->first->name eq "rv2gv")))
3381                   {
3382                       push @reals, $self->deparse($real, 6);
3383                   } else {
3384                       return "&";
3385                   }
3386             }
3387        }
3388     }
3389     return "&" if $proto and !$doneok; # too few args and no `;'
3390     return "&" if @args;               # too many args
3391     return ("", join ", ", @reals);
3392 }
3393
3394 sub pp_entersub {
3395     my $self = shift;
3396     my($op, $cx) = @_;
3397     return $self->e_method($self->_method($op, $cx))
3398         unless null $op->first->sibling;
3399     my $prefix = "";
3400     my $amper = "";
3401     my($kid, @exprs);
3402     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3403         $prefix = "do ";
3404     } elsif ($op->private & OPpENTERSUB_AMPER) {
3405         $amper = "&";
3406     }
3407     $kid = $op->first;
3408     $kid = $kid->first->sibling; # skip ex-list, pushmark
3409     for (; not null $kid->sibling; $kid = $kid->sibling) {
3410         push @exprs, $kid;
3411     }
3412     my $simple = 0;
3413     my $proto = undef;
3414     if (is_scope($kid)) {
3415         $amper = "&";
3416         $kid = "{" . $self->deparse($kid, 0) . "}";
3417     } elsif ($kid->first->name eq "gv") {
3418         my $gv = $self->gv_or_padgv($kid->first);
3419         if (class($gv->CV) ne "SPECIAL") {
3420             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3421         }
3422         $simple = 1; # only calls of named functions can be prototyped
3423         $kid = $self->deparse($kid, 24);
3424         if (!$amper) {
3425             if ($kid eq 'main::') {
3426                 $kid = '::';
3427             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3428                 $kid = single_delim("q", "'", $kid) . '->';
3429             }
3430         }
3431     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3432         $amper = "&";
3433         $kid = $self->deparse($kid, 24);
3434     } else {
3435         $prefix = "";
3436         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3437         $kid = $self->deparse($kid, 24) . $arrow;
3438     }
3439
3440     # Doesn't matter how many prototypes there are, if
3441     # they haven't happened yet!
3442     my $declared;
3443     {
3444         no strict 'refs';
3445         no warnings 'uninitialized';
3446         $declared = exists $self->{'subs_declared'}{$kid}
3447             || (
3448                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3449                  && !exists
3450                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3451                  && defined prototype $self->{'curstash'}."::".$kid
3452                );
3453         if (!$declared && defined($proto)) {
3454             # Avoid "too early to check prototype" warning
3455             ($amper, $proto) = ('&');
3456         }
3457     }
3458
3459     my $args;
3460     if ($declared and defined $proto and not $amper) {
3461         ($amper, $args) = $self->check_proto($proto, @exprs);
3462         if ($amper eq "&") {
3463             $args = join(", ", map($self->deparse($_, 6), @exprs));
3464         }
3465     } else {
3466         $args = join(", ", map($self->deparse($_, 6), @exprs));
3467     }
3468     if ($prefix or $amper) {
3469         if ($op->flags & OPf_STACKED) {
3470             return $prefix . $amper . $kid . "(" . $args . ")";
3471         } else {
3472             return $prefix . $amper. $kid;
3473         }
3474     } else {
3475         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
3476         # so it must have been translated from a keyword call. Translate
3477         # it back.
3478         $kid =~ s/^CORE::GLOBAL:://;
3479
3480         my $dproto = defined($proto) ? $proto : "undefined";
3481         if (!$declared) {
3482             return "$kid(" . $args . ")";
3483         } elsif ($dproto eq "") {
3484             return $kid;
3485         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3486             # is_scalar is an excessively conservative test here:
3487             # really, we should be comparing to the precedence of the
3488             # top operator of $exprs[0] (ala unop()), but that would
3489             # take some major code restructuring to do right.
3490             return $self->maybe_parens_func($kid, $args, $cx, 16);
3491         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3492             return $self->maybe_parens_func($kid, $args, $cx, 5);
3493         } else {
3494             return "$kid(" . $args . ")";
3495         }
3496     }
3497 }
3498
3499 sub pp_enterwrite { unop(@_, "write") }
3500
3501 # escape things that cause interpolation in double quotes,
3502 # but not character escapes
3503 sub uninterp {
3504     my($str) = @_;
3505     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3506     return $str;
3507 }
3508
3509 {
3510 my $bal;
3511 BEGIN {
3512     use re "eval";
3513     # Matches any string which is balanced with respect to {braces}
3514     $bal = qr(
3515       (?:
3516         [^\\{}]
3517       | \\\\
3518       | \\[{}]
3519       | \{(??{$bal})\}
3520       )*
3521     )x;
3522 }
3523
3524 # the same, but treat $|, $), $( and $ at the end of the string differently
3525 sub re_uninterp {
3526     my($str) = @_;
3527
3528     $str =~ s/
3529           ( ^|\G                  # $1
3530           | [^\\]
3531           )
3532
3533           (                       # $2
3534             (?:\\\\)*
3535           )
3536
3537           (                       # $3
3538             (\(\?\??\{$bal\}\))   # $4
3539           | [\$\@]
3540             (?!\||\)|\(|$)
3541           | \\[uUlLQE]
3542           )
3543
3544         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3545
3546     return $str;
3547 }
3548
3549 # This is for regular expressions with the /x modifier
3550 # We have to leave comments unmangled.
3551 sub re_uninterp_extended {
3552     my($str) = @_;
3553
3554     $str =~ s/
3555           ( ^|\G                  # $1
3556           | [^\\]
3557           )
3558
3559           (                       # $2
3560             (?:\\\\)*
3561           )
3562
3563           (                       # $3
3564             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3565             | \#[^\n]*            #     (skip over comments)
3566             )
3567           | [\$\@]
3568             (?!\||\)|\(|$|\s)
3569           | \\[uUlLQE]
3570           )
3571
3572         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3573
3574     return $str;
3575 }
3576 }
3577
3578 my %unctrl = # portable to to EBCDIC
3579     (
3580      "\c@" => '\c@',    # unused
3581      "\cA" => '\cA',
3582      "\cB" => '\cB',
3583      "\cC" => '\cC',
3584      "\cD" => '\cD',
3585      "\cE" => '\cE',
3586      "\cF" => '\cF',
3587      "\cG" => '\cG',
3588      "\cH" => '\cH',
3589      "\cI" => '\cI',
3590      "\cJ" => '\cJ',
3591      "\cK" => '\cK',
3592      "\cL" => '\cL',
3593      "\cM" => '\cM',
3594      "\cN" => '\cN',
3595      "\cO" => '\cO',
3596      "\cP" => '\cP',
3597      "\cQ" => '\cQ',
3598      "\cR" => '\cR',
3599      "\cS" => '\cS',
3600      "\cT" => '\cT',
3601      "\cU" => '\cU',
3602      "\cV" => '\cV',
3603      "\cW" => '\cW',
3604      "\cX" => '\cX',
3605      "\cY" => '\cY',
3606      "\cZ" => '\cZ',
3607      "\c[" => '\c[',    # unused
3608      "\c\\" => '\c\\',  # unused
3609      "\c]" => '\c]',    # unused
3610      "\c_" => '\c_',    # unused
3611     );
3612
3613 # character escapes, but not delimiters that might need to be escaped
3614 sub escape_str { # ASCII, UTF8
3615     my($str) = @_;
3616     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3617     $str =~ s/\a/\\a/g;
3618 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3619     $str =~ s/\t/\\t/g;
3620     $str =~ s/\n/\\n/g;
3621     $str =~ s/\e/\\e/g;
3622     $str =~ s/\f/\\f/g;
3623     $str =~ s/\r/\\r/g;
3624     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3625     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3626     return $str;
3627 }
3628
3629 # For regexes with the /x modifier.
3630 # Leave whitespace unmangled.
3631 sub escape_extended_re {
3632     my($str) = @_;
3633     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3634     $str =~ s/([[:^print:]])/
3635         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3636     $str =~ s/\n/\n\f/g;
3637     return $str;
3638 }
3639
3640 # Don't do this for regexen
3641 sub unback {
3642     my($str) = @_;
3643     $str =~ s/\\/\\\\/g;
3644     return $str;
3645 }
3646
3647 # Remove backslashes which precede literal control characters,
3648 # to avoid creating ambiguity when we escape the latter.
3649 sub re_unback {
3650     my($str) = @_;
3651
3652     # the insane complexity here is due to the behaviour of "\c\"
3653     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3654     return $str;
3655 }
3656
3657 sub balanced_delim {
3658     my($str) = @_;
3659     my @str = split //, $str;
3660     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
3661     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3662         ($open, $close) = @$ar;
3663         $fail = 0; $cnt = 0; $last_bs = 0;
3664         for $c (@str) {
3665             if ($c eq $open) {
3666                 $fail = 1 if $last_bs;
3667                 $cnt++;
3668             } elsif ($c eq $close) {
3669                 $fail = 1 if $last_bs;
3670                 $cnt--;
3671                 if ($cnt < 0) {
3672                     # qq()() isn't ")("
3673                     $fail = 1;
3674                     last;
3675                 }
3676             }
3677             $last_bs = $c eq '\\';
3678         }
3679         $fail = 1 if $cnt != 0;
3680         return ($open, "$open$str$close") if not $fail;
3681     }
3682     return ("", $str);
3683 }
3684
3685 sub single_delim {
3686     my($q, $default, $str) = @_;
3687     return "$default$str$default" if $default and index($str, $default) == -1;
3688     if ($q ne 'qr') {
3689         (my $succeed, $str) = balanced_delim($str);
3690         return "$q$str" if $succeed;
3691     }
3692     for my $delim ('/', '"', '#') {
3693         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3694     }
3695     if ($default) {
3696         $str =~ s/$default/\\$default/g;
3697         return "$default$str$default";
3698     } else {
3699         $str =~ s[/][\\/]g;
3700         return "$q/$str/";
3701     }
3702 }
3703
3704 my $max_prec;
3705 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3706
3707 # Split a floating point number into an integer mantissa and a binary
3708 # exponent. Assumes you've already made sure the number isn't zero or
3709 # some weird infinity or NaN.
3710 sub split_float {
3711     my($f) = @_;
3712     my $exponent = 0;
3713     if ($f == int($f)) {
3714         while ($f % 2 == 0) {
3715             $f /= 2;
3716             $exponent++;
3717         }
3718     } else {
3719         while ($f != int($f)) {
3720             $f *= 2;
3721             $exponent--;
3722         }
3723     }
3724     my $mantissa = sprintf("%.0f", $f);
3725     return ($mantissa, $exponent);
3726 }
3727
3728 sub const {
3729     my $self = shift;
3730     my($sv, $cx) = @_;
3731     if ($self->{'use_dumper'}) {
3732         return $self->const_dumper($sv, $cx);
3733     }
3734     if (class($sv) eq "SPECIAL") {
3735         # sv_undef, sv_yes, sv_no
3736         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3737     }
3738     if (class($sv) eq "NULL") {
3739        return 'undef';
3740     }
3741     # convert a version object into the "v1.2.3" string in its V magic
3742     if ($sv->FLAGS & SVs_RMG) {
3743         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3744             return $mg->PTR if $mg->TYPE eq 'V';
3745         }
3746     }
3747
3748     if ($sv->FLAGS & SVf_IOK) {
3749         my $str = $sv->int_value;
3750         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3751         return $str;
3752     } elsif ($sv->FLAGS & SVf_NOK) {
3753         my $nv = $sv->NV;
3754         if ($nv == 0) {
3755             if (pack("F", $nv) eq pack("F", 0)) {
3756                 # positive zero
3757                 return "0";
3758             } else {
3759                 # negative zero
3760                 return $self->maybe_parens("-.0", $cx, 21);
3761             }
3762         } elsif (1/$nv == 0) {
3763             if ($nv > 0) {
3764                 # positive infinity
3765                 return $self->maybe_parens("9**9**9", $cx, 22);
3766             } else {
3767                 # negative infinity
3768                 return $self->maybe_parens("-9**9**9", $cx, 21);
3769             }
3770         } elsif ($nv != $nv) {
3771             # NaN
3772             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3773                 # the normal kind
3774                 return "sin(9**9**9)";
3775             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3776                 # the inverted kind
3777                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3778             } else {
3779                 # some other kind
3780                 my $hex = unpack("h*", pack("F", $nv));
3781                 return qq'unpack("F", pack("h*", "$hex"))';
3782             }
3783         }
3784         # first, try the default stringification
3785         my $str = "$nv";
3786         if ($str != $nv) {
3787             # failing that, try using more precision
3788             $str = sprintf("%.${max_prec}g", $nv);
3789 #           if (pack("F", $str) ne pack("F", $nv)) {
3790             if ($str != $nv) {
3791                 # not representable in decimal with whatever sprintf()
3792                 # and atof() Perl is using here.
3793                 my($mant, $exp) = split_float($nv);
3794                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3795             }
3796         }
3797         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3798         return $str;
3799     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3800         my $ref = $sv->RV;
3801         if (class($ref) eq "AV") {
3802             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3803         } elsif (class($ref) eq "HV") {
3804             my %hash = $ref->ARRAY;
3805             my @elts;
3806             for my $k (sort keys %hash) {
3807                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3808             }
3809             return "{" . join(", ", @elts) . "}";
3810         } elsif (class($ref) eq "CV") {
3811             return "sub " . $self->deparse_sub($ref);
3812         }
3813         if ($ref->FLAGS & SVs_SMG) {
3814             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3815                 if ($mg->TYPE eq 'r') {
3816                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3817                     return single_delim("qr", "", $re);
3818                 }
3819             }
3820         }
3821         
3822         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3823     } elsif ($sv->FLAGS & SVf_POK) {
3824         my $str = $sv->PV;
3825         if ($str =~ /[[:^print:]]/) {
3826             return single_delim("qq", '"', uninterp escape_str unback $str);
3827         } else {
3828             return single_delim("q", "'", unback $str);
3829         }
3830     } else {
3831         return "undef";
3832     }
3833 }
3834
3835 sub const_dumper {
3836     my $self = shift;
3837     my($sv, $cx) = @_;
3838     my $ref = $sv->object_2svref();
3839     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3840     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3841     my $str = $dumper->Dump();
3842     if ($str =~ /^\$v/) {
3843         return '${my ' . $str . ' \$v}';
3844     } else {
3845         return $str;
3846     }
3847 }
3848
3849 sub const_sv {
3850     my $self = shift;
3851     my $op = shift;
3852     my $sv = $op->sv;
3853     # the constant could be in the pad (under useithreads)
3854     $sv = $self->padval($op->targ) unless $$sv;
3855     return $sv;
3856 }
3857
3858 sub pp_const {
3859     my $self = shift;
3860     my($op, $cx) = @_;
3861     if ($op->private & OPpCONST_ARYBASE) {
3862         return '$[';
3863     }
3864 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3865 #       return $self->const_sv($op)->PV;
3866 #    }
3867     my $sv = $self->const_sv($op);
3868     return $self->const($sv, $cx);
3869 }
3870
3871 sub dq {
3872     my $self = shift;
3873     my $op = shift;
3874     my $type = $op->name;
3875     if ($type eq "const") {
3876         return '$[' if $op->private & OPpCONST_ARYBASE;
3877         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3878     } elsif ($type eq "concat") {
3879         my $first = $self->dq($op->first);
3880         my $last  = $self->dq($op->last);
3881
3882         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3883         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3884             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3885             || ($last =~ /^[:'{\[\w_]/ && #'
3886                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3887
3888         return $first . $last;
3889     } elsif ($type eq "uc") {
3890         return '\U' . $self->dq($op->first->sibling) . '\E';
3891     } elsif ($type eq "lc") {
3892         return '\L' . $self->dq($op->first->sibling) . '\E';
3893     } elsif ($type eq "ucfirst") {
3894         return '\u' . $self->dq($op->first->sibling);
3895     } elsif ($type eq "lcfirst") {
3896         return '\l' . $self->dq($op->first->sibling);
3897     } elsif ($type eq "quotemeta") {
3898         return '\Q' . $self->dq($op->first->sibling) . '\E';
3899     } elsif ($type eq "join") {
3900         return $self->deparse($op->last, 26); # was join($", @ary)
3901     } else {
3902         return $self->deparse($op, 26);
3903     }
3904 }
3905
3906 sub pp_backtick {
3907     my $self = shift;
3908     my($op, $cx) = @_;
3909     # skip pushmark if it exists (readpipe() vs ``)
3910     my $child = $op->first->sibling->isa('B::NULL')
3911         ? $op->first : $op->first->sibling;
3912     if ($self->pure_string($child)) {
3913         return single_delim("qx", '`', $self->dq($child, 1));
3914     }
3915     unop($self, @_, "readpipe");
3916 }
3917
3918 sub dquote {
3919     my $self = shift;
3920     my($op, $cx) = @_;
3921     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3922     return $self->deparse($kid, $cx) if $self->{'unquote'};
3923     $self->maybe_targmy($kid, $cx,
3924                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3925 }
3926
3927 # OP_STRINGIFY is a listop, but it only ever has one arg
3928 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3929
3930 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3931 # note that tr(from)/to/ is OK, but not tr/from/(to)
3932 sub double_delim {
3933     my($from, $to) = @_;
3934     my($succeed, $delim);
3935     if ($from !~ m[/] and $to !~ m[/]) {
3936         return "/$from/$to/";
3937     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3938         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3939             return "$from$to";
3940         } else {
3941             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3942                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3943             }
3944             $to =~ s[/][\\/]g;
3945             return "$from/$to/";
3946         }
3947     } else {
3948         for $delim ('/', '"', '#') { # note no '
3949             return "$delim$from$delim$to$delim"
3950                 if index($to . $from, $delim) == -1;
3951         }
3952         $from =~ s[/][\\/]g;
3953         $to =~ s[/][\\/]g;
3954         return "/$from/$to/";   
3955     }
3956 }
3957
3958 # Only used by tr///, so backslashes hyphens
3959 sub pchr { # ASCII
3960     my($n) = @_;
3961     if ($n == ord '\\') {
3962         return '\\\\';
3963     } elsif ($n == ord "-") {
3964         return "\\-";
3965     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3966         return chr($n);
3967     } elsif ($n == ord "\a") {
3968         return '\\a';
3969     } elsif ($n == ord "\b") {
3970         return '\\b';
3971     } elsif ($n == ord "\t") {
3972         return '\\t';
3973     } elsif ($n == ord "\n") {
3974         return '\\n';
3975     } elsif ($n == ord "\e") {
3976         return '\\e';
3977     } elsif ($n == ord "\f") {
3978         return '\\f';
3979     } elsif ($n == ord "\r") {
3980         return '\\r';
3981     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3982         return '\\c' . chr(ord("@") + $n);
3983     } else {
3984 #       return '\x' . sprintf("%02x", $n);
3985         return '\\' . sprintf("%03o", $n);
3986     }
3987 }
3988
3989 sub collapse {
3990     my(@chars) = @_;
3991     my($str, $c, $tr) = ("");
3992     for ($c = 0; $c < @chars; $c++) {
3993         $tr = $chars[$c];
3994         $str .= pchr($tr);
3995         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3996             $chars[$c + 2] == $tr + 2)
3997         {
3998             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3999               {}
4000             $str .= "-";
4001             $str .= pchr($chars[$c]);
4002         }
4003     }
4004     return $str;
4005 }
4006
4007 sub tr_decode_byte {
4008     my($table, $flags) = @_;
4009     my(@table) = unpack("s*", $table);
4010     splice @table, 0x100, 1;   # Number of subsequent elements
4011     my($c, $tr, @from, @to, @delfrom, $delhyphen);
4012     if ($table[ord "-"] != -1 and
4013         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
4014     {
4015         $tr = $table[ord "-"];
4016         $table[ord "-"] = -1;
4017         if ($tr >= 0) {
4018             @from = ord("-");
4019             @to = $tr;
4020         } else { # -2 ==> delete
4021             $delhyphen = 1;
4022         }
4023     }
4024     for ($c = 0; $c < @table; $c++) {
4025         $tr = $table[$c];
4026         if ($tr >= 0) {
4027             push @from, $c; push @to, $tr;
4028         } elsif ($tr == -2) {
4029             push @delfrom, $c;
4030         }
4031     }
4032     @from = (@from, @delfrom);
4033     if ($flags & OPpTRANS_COMPLEMENT) {
4034         my @newfrom = ();
4035         my %from;
4036         @from{@from} = (1) x @from;
4037         for ($c = 0; $c < 256; $c++) {
4038             push @newfrom, $c unless $from{$c};
4039         }
4040         @from = @newfrom;
4041     }
4042     unless ($flags & OPpTRANS_DELETE || !@to) {
4043         pop @to while $#to and $to[$#to] == $to[$#to -1];
4044     }
4045     my($from, $to);
4046     $from = collapse(@from);
4047     $to = collapse(@to);
4048     $from .= "-" if $delhyphen;
4049     return ($from, $to);
4050 }
4051
4052 sub tr_chr {
4053     my $x = shift;
4054     if ($x == ord "-") {
4055         return "\\-";
4056     } elsif ($x == ord "\\") {
4057         return "\\\\";
4058     } else {
4059         return chr $x;
4060     }
4061 }
4062
4063 # XXX This doesn't yet handle all cases correctly either
4064
4065 sub tr_decode_utf8 {
4066     my($swash_hv, $flags) = @_;
4067     my %swash = $swash_hv->ARRAY;
4068     my $final = undef;
4069     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
4070     my $none = $swash{"NONE"}->IV;
4071     my $extra = $none + 1;
4072     my(@from, @delfrom, @to);
4073     my $line;
4074     foreach $line (split /\n/, $swash{'LIST'}->PV) {
4075         my($min, $max, $result) = split(/\t/, $line);
4076         $min = hex $min;
4077         if (length $max) {
4078             $max = hex $max;
4079         } else {
4080             $max = $min;
4081         }
4082         $result = hex $result;
4083         if ($result == $extra) {
4084             push @delfrom, [$min, $max];
4085         } else {
4086             push @from, [$min, $max];
4087             push @to, [$result, $result + $max - $min];
4088         }
4089     }
4090     for my $i (0 .. $#from) {
4091         if ($from[$i][0] == ord '-') {
4092             unshift @from, splice(@from, $i, 1);
4093             unshift @to, splice(@to, $i, 1);
4094             last;
4095         } elsif ($from[$i][1] == ord '-') {
4096             $from[$i][1]--;
4097             $to[$i][1]--;
4098             unshift @from, ord '-';
4099             unshift @to, ord '-';
4100             last;
4101         }
4102     }
4103     for my $i (0 .. $#delfrom) {
4104         if ($delfrom[$i][0] == ord '-') {
4105             push @delfrom, splice(@delfrom, $i, 1);
4106             last;
4107         } elsif ($delfrom[$i][1] == ord '-') {
4108             $delfrom[$i][1]--;
4109             push @delfrom, ord '-';
4110             last;
4111         }
4112     }
4113     if (defined $final and $to[$#to][1] != $final) {
4114         push @to, [$final, $final];
4115     }
4116     push @from, @delfrom;
4117     if ($flags & OPpTRANS_COMPLEMENT) {
4118         my @newfrom;
4119         my $next = 0;
4120         for my $i (0 .. $#from) {
4121             push @newfrom, [$next, $from[$i][0] - 1];
4122             $next = $from[$i][1] + 1;
4123         }
4124         @from = ();
4125         for my $range (@newfrom) {
4126             if ($range->[0] <= $range->[1]) {
4127                 push @from, $range;
4128             }
4129         }
4130     }
4131     my($from, $to, $diff);
4132     for my $chunk (@from) {
4133         $diff = $chunk->[1] - $chunk->[0];
4134         if ($diff > 1) {
4135             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4136         } elsif ($diff == 1) {
4137             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4138         } else {
4139             $from .= tr_chr($chunk->[0]);
4140         }
4141     }
4142     for my $chunk (@to) {
4143         $diff = $chunk->[1] - $chunk->[0];
4144         if ($diff > 1) {
4145             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4146         } elsif ($diff == 1) {
4147             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4148         } else {
4149             $to .= tr_chr($chunk->[0]);
4150         }
4151     }
4152     #$final = sprintf("%04x", $final) if defined $final;
4153     #$none = sprintf("%04x", $none) if defined $none;
4154     #$extra = sprintf("%04x", $extra) if defined $extra;
4155     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
4156     #print STDERR $swash{'LIST'}->PV;
4157     return (escape_str($from), escape_str($to));
4158 }
4159
4160 sub pp_trans {
4161     my $self = shift;
4162     my($op, $cx) = @_;
4163     my($from, $to);
4164     my $class = class($op);
4165     my $priv_flags = $op->private;
4166     if ($class eq "PVOP") {
4167         ($from, $to) = tr_decode_byte($op->pv, $priv_flags);
4168     } elsif ($class eq "PADOP") {
4169         ($from, $to)
4170           = tr_decode_utf8($self->padval($op->padix)->RV, $priv_flags);
4171     } else { # class($op) eq "SVOP"
4172         ($from, $to) = tr_decode_utf8($op->sv->RV, $priv_flags);
4173     }
4174     my $flags = "";
4175     $flags .= "c" if $priv_flags & OPpTRANS_COMPLEMENT;
4176     $flags .= "d" if $priv_flags & OPpTRANS_DELETE;
4177     $to = "" if $from eq $to and $flags eq "";
4178     $flags .= "s" if $priv_flags & OPpTRANS_SQUASH;
4179     return "tr" . double_delim($from, $to) . $flags;
4180 }
4181
4182 sub pp_transr { &pp_trans . 'r' }
4183
4184 sub re_dq_disambiguate {
4185     my ($first, $last) = @_;
4186     # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
4187     ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4188         $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4189         || ($last =~ /^[{\[\w_]/ &&
4190             $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4191     return $first . $last;
4192 }
4193
4194 # Like dq(), but different
4195 sub re_dq {
4196     my $self = shift;
4197     my ($op, $extended) = @_;
4198
4199     my $type = $op->name;
4200     if ($type eq "const") {
4201         return '$[' if $op->private & OPpCONST_ARYBASE;
4202         my $unbacked = re_unback($self->const_sv($op)->as_string);
4203         return re_uninterp_extended(escape_extended_re($unbacked))
4204             if $extended;
4205         return re_uninterp(escape_str($unbacked));
4206     } elsif ($type eq "concat") {
4207         my $first = $self->re_dq($op->first, $extended);
4208         my $last  = $self->re_dq($op->last,  $extended);
4209         return re_dq_disambiguate($first, $last);
4210     } elsif ($type eq "uc") {
4211         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
4212     } elsif ($type eq "lc") {
4213         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
4214     } elsif ($type eq "ucfirst") {
4215         return '\u' . $self->re_dq($op->first->sibling, $extended);
4216     } elsif ($type eq "lcfirst") {
4217         return '\l' . $self->re_dq($op->first->sibling, $extended);
4218     } elsif ($type eq "quotemeta") {
4219         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
4220     } elsif ($type eq "join") {
4221         return $self->deparse($op->last, 26); # was join($", @ary)
4222     } else {
4223         return $self->deparse($op, 26);
4224     }
4225 }
4226
4227 sub pure_string {
4228     my ($self, $op) = @_;
4229     return 0 if null $op;
4230     my $type = $op->name;
4231
4232     if ($type eq 'const') {
4233         return 1;
4234     }
4235     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
4236         return $self->pure_string($op->first->sibling);
4237     }
4238     elsif ($type eq 'join') {
4239         my $join_op = $op->first->sibling;  # Skip pushmark
4240         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
4241
4242         my $gvop = $join_op->first;
4243         return 0 unless $gvop->name eq 'gvsv';
4244         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
4245
4246         return 0 unless ${$join_op->sibling} eq ${$op->last};
4247         return 0 unless $op->last->name =~ /^(?:[ah]slice|(?:rv2|pad)av)$/;
4248     }
4249     elsif ($type eq 'concat') {
4250         return $self->pure_string($op->first)
4251             && $self->pure_string($op->last);
4252     }
4253     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
4254         return 1;
4255     }
4256     elsif ($type eq "null" and $op->can('first') and not null $op->first and
4257            $op->first->name eq "null" and $op->first->can('first')
4258            and not null $op->first->first and
4259            $op->first->first->name eq "aelemfast") {
4260         return 1;
4261     }
4262     else {
4263         return 0;
4264     }
4265
4266     return 1;
4267 }
4268
4269 sub regcomp {
4270     my $self = shift;
4271     my($op, $cx, $extended) = @_;
4272     my $kid = $op->first;
4273     $kid = $kid->first if $kid->name eq "regcmaybe";
4274     $kid = $kid->first if $kid->name eq "regcreset";
4275     if ($kid->name eq "null" and !null($kid->first)
4276         and $kid->first->name eq 'pushmark')
4277     {
4278         my $str = '';
4279         $kid = $kid->first->sibling;
4280         while (!null($kid)) {
4281             my $first = $str;
4282             my $last = $self->re_dq($kid, $extended);
4283             $str = re_dq_disambiguate($first, $last);
4284             $kid = $kid->sibling;
4285         }
4286         return $str, 1;
4287     }
4288
4289     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
4290     return ($self->deparse($kid, $cx), 0);
4291 }
4292
4293 sub pp_regcomp {
4294     my ($self, $op, $cx) = @_;
4295     return (($self->regcomp($op, $cx, 0))[0]);
4296 }
4297
4298 # osmic acid -- see osmium tetroxide
4299
4300 my %matchwords;
4301 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
4302     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
4303     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
4304
4305 sub matchop {
4306     my $self = shift;
4307     my($op, $cx, $name, $delim) = @_;
4308     my $kid = $op->first;
4309     my ($binop, $var, $re) = ("", "", "");
4310     if ($op->flags & OPf_STACKED) {
4311         $binop = 1;
4312         $var = $self->deparse($kid, 20);
4313         $kid = $kid->sibling;
4314     }
4315     my $quote = 1;
4316     my $extended = ($op->pmflags & PMf_EXTENDED);
4317     my $rhs_bound_to_defsv;
4318     if (null $kid) {
4319         my $unbacked = re_unback($op->precomp);
4320         if ($extended) {
4321             $re = re_uninterp_extended(escape_extended_re($unbacked));
4322         } else {
4323             $re = re_uninterp(escape_str(re_unback($op->precomp)));
4324         }
4325     } elsif ($kid->name ne 'regcomp') {
4326         carp("found ".$kid->name." where regcomp expected");
4327     } else {
4328         ($re, $quote) = $self->regcomp($kid, 21, $extended);
4329         $rhs_bound_to_defsv = 1 if $kid->first->first->flags & OPf_SPECIAL;
4330     }
4331     my $flags = "";
4332     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
4333     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4334     $flags .= "i" if $op->pmflags & PMf_FOLD;
4335     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4336     $flags .= "o" if $op->pmflags & PMf_KEEP;
4337     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4338     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
4339     $flags = $matchwords{$flags} if $matchwords{$flags};
4340     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
4341         $re =~ s/\?/\\?/g;
4342         $re = "?$re?";
4343     } elsif ($quote) {
4344         $re = single_delim($name, $delim, $re);
4345     }
4346     $re = $re . $flags if $quote;
4347     if ($binop) {
4348         return
4349          $self->maybe_parens(
4350           $rhs_bound_to_defsv
4351            ? "$var =~ (\$_ =~ $re)"
4352            : "$var =~ $re",
4353           $cx, 20
4354          );
4355     } else {
4356         return $re;
4357     }
4358 }
4359
4360 sub pp_match { matchop(@_, "m", "/") }
4361 sub pp_pushre { matchop(@_, "m", "/") }
4362 sub pp_qr { matchop(@_, "qr", "") }
4363
4364 sub pp_split {
4365     my $self = shift;
4366     my($op, $cx) = @_;
4367     my($kid, @exprs, $ary, $expr);
4368     $kid = $op->first;
4369
4370     # For our kid (an OP_PUSHRE), pmreplroot is never actually the
4371     # root of a replacement; it's either empty, or abused to point to
4372     # the GV for an array we split into (an optimization to save
4373     # assignment overhead). Depending on whether we're using ithreads,
4374     # this OP* holds either a GV* or a PADOFFSET. Luckily, B.xs