This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
fix perl #126186 make all verbs allow an optional arg
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19 New in v5.22, L<C<use re 'strict'>|re/'strict' mode> applies stricter
20 rules than otherwise when compiling regular expression patterns.  It can
21 find things that, while legal, may not be what you intended.
22
23 =head2 Modifiers
24
25 Matching operations can have various modifiers.  Modifiers
26 that relate to the interpretation of the regular expression inside
27 are listed below.  Modifiers that alter the way a regular expression
28 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
29 L<perlop/"Gory details of parsing quoted constructs">.
30
31 =over 4
32
33 =item m
34 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
35
36 Treat string as multiple lines.  That is, change "^" and "$" from matching
37 the start of the string's first line and the end of its last line to
38 matching the start and end of each line within the string.
39
40 =item s
41 X</s> X<regex, single-line> X<regexp, single-line>
42 X<regular expression, single-line>
43
44 Treat string as single line.  That is, change "." to match any character
45 whatsoever, even a newline, which normally it would not match.
46
47 Used together, as C</ms>, they let the "." match any character whatsoever,
48 while still allowing "^" and "$" to match, respectively, just after
49 and just before newlines within the string.
50
51 =item i
52 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
53 X<regular expression, case-insensitive>
54
55 Do case-insensitive pattern matching.
56
57 If locale matching rules are in effect, the case map is taken from the
58 current
59 locale for code points less than 255, and from Unicode rules for larger
60 code points.  However, matches that would cross the Unicode
61 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
62 L<perllocale>.
63
64 There are a number of Unicode characters that match multiple characters
65 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
66 should match the sequence C<fi>.  Perl is not
67 currently able to do this when the multiple characters are in the pattern and
68 are split between groupings, or when one or more are quantified.  Thus
69
70  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
71  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
72  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
73
74  # The below doesn't match, and it isn't clear what $1 and $2 would
75  # be even if it did!!
76  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
77
78 Perl doesn't match multiple characters in a bracketed
79 character class unless the character that maps to them is explicitly
80 mentioned, and it doesn't match them at all if the character class is
81 inverted, which otherwise could be highly confusing.  See
82 L<perlrecharclass/Bracketed Character Classes>, and
83 L<perlrecharclass/Negation>.
84
85 =item x
86 X</x>
87
88 Extend your pattern's legibility by permitting whitespace and comments.
89 Details in L</"/x">
90
91 =item p
92 X</p> X<regex, preserve> X<regexp, preserve>
93
94 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
95 ${^POSTMATCH} are available for use after matching.
96
97 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
98 mechanism, ${^PREMATCH}, ${^MATCH}, and ${^POSTMATCH} will be available
99 after the match regardless of the modifier.
100
101 =item a, d, l and u
102 X</a> X</d> X</l> X</u>
103
104 These modifiers, all new in 5.14, affect which character-set rules
105 (Unicode, etc.) are used, as described below in
106 L</Character set modifiers>.
107
108 =item n
109 X</n> X<regex, non-capture> X<regexp, non-capture>
110 X<regular expression, non-capture>
111
112 Prevent the grouping metacharacters C<()> from capturing. This modifier,
113 new in 5.22, will stop C<$1>, C<$2>, etc... from being filled in.
114
115   "hello" =~ /(hi|hello)/;   # $1 is "hello"
116   "hello" =~ /(hi|hello)/n;  # $1 is undef
117
118 This is equivalent to putting C<?:> at the beginning of every capturing group:
119
120   "hello" =~ /(?:hi|hello)/; # $1 is undef
121
122 C</n> can be negated on a per-group basis. Alternatively, named captures
123 may still be used.
124
125   "hello" =~ /(?-n:(hi|hello))/n;   # $1 is "hello"
126   "hello" =~ /(?<greet>hi|hello)/n; # $1 is "hello", $+{greet} is
127                                     # "hello"
128
129 =item Other Modifiers
130
131 There are a number of flags that can be found at the end of regular
132 expression constructs that are I<not> generic regular expression flags, but
133 apply to the operation being performed, like matching or substitution (C<m//>
134 or C<s///> respectively).
135
136 Flags described further in
137 L<perlretut/"Using regular expressions in Perl"> are:
138
139   c  - keep the current position during repeated matching
140   g  - globally match the pattern repeatedly in the string
141
142 Substitution-specific modifiers described in
143
144 L<perlop/"s/PATTERN/REPLACEMENT/msixpodualngcer"> are:
145
146   e  - evaluate the right-hand side as an expression
147   ee - evaluate the right side as a string then eval the result
148   o  - pretend to optimize your code, but actually introduce bugs
149   r  - perform non-destructive substitution and return the new value
150
151 =back
152
153 Regular expression modifiers are usually written in documentation
154 as e.g., "the C</x> modifier", even though the delimiter
155 in question might not really be a slash.  The modifiers C</imsxadlup>
156 may also be embedded within the regular expression itself using
157 the C<(?...)> construct, see L</Extended Patterns> below.
158
159 =head3 /x
160
161 C</x> tells
162 the regular expression parser to ignore most whitespace that is neither
163 backslashed nor within a bracketed character class.  You can use this to
164 break up your regular expression into (slightly) more readable parts.
165 Also, the C<#> character is treated as a metacharacter introducing a
166 comment that runs up to the pattern's closing delimiter, or to the end
167 of the current line if the pattern extends onto the next line.  Hence,
168 this is very much like an ordinary Perl code comment.  (You can include
169 the closing delimiter within the comment only if you precede it with a
170 backslash, so be careful!)
171
172 Use of C</x> means that if you want real
173 whitespace or C<#> characters in the pattern (outside a bracketed character
174 class, which is unaffected by C</x>), then you'll either have to
175 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
176 hex, or C<\N{}> escapes.
177 It is ineffective to try to continue a comment onto the next line by
178 escaping the C<\n> with a backslash or C<\Q>.
179
180 You can use L</(?#text)> to create a comment that ends earlier than the
181 end of the current line, but C<text> also can't contain the closing
182 delimiter unless escaped with a backslash.
183
184 Taken together, these features go a long way towards
185 making Perl's regular expressions more readable.  Here's an example:
186
187     # Delete (most) C comments.
188     $program =~ s {
189         /\*     # Match the opening delimiter.
190         .*?     # Match a minimal number of characters.
191         \*/     # Match the closing delimiter.
192     } []gsx;
193
194 Note that anything inside
195 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
196 space interpretation within a single multi-character construct.  For
197 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
198 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
199 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<(>,
200 C<?>, and C<:>.  Within any delimiters for such a
201 construct, allowed spaces are not affected by C</x>, and depend on the
202 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
203 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
204 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
205 L<perluniprops/Properties accessible through \p{} and \P{}>.
206 X</x>
207
208 The set of characters that are deemed whitespace are those that Unicode
209 calls "Pattern White Space", namely:
210
211  U+0009 CHARACTER TABULATION
212  U+000A LINE FEED
213  U+000B LINE TABULATION
214  U+000C FORM FEED
215  U+000D CARRIAGE RETURN
216  U+0020 SPACE
217  U+0085 NEXT LINE
218  U+200E LEFT-TO-RIGHT MARK
219  U+200F RIGHT-TO-LEFT MARK
220  U+2028 LINE SEPARATOR
221  U+2029 PARAGRAPH SEPARATOR
222
223 =head3 Character set modifiers
224
225 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
226 the character set modifiers; they affect the character set rules
227 used for the regular expression.
228
229 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
230 to you, and so you need not worry about them very much.  They exist for
231 Perl's internal use, so that complex regular expression data structures
232 can be automatically serialized and later exactly reconstituted,
233 including all their nuances.  But, since Perl can't keep a secret, and
234 there may be rare instances where they are useful, they are documented
235 here.
236
237 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
238 allow code that is to work mostly on ASCII data to not have to concern
239 itself with Unicode.
240
241 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
242 effect at the time of the execution of the pattern match.
243
244 C</u> sets the character set to B<U>nicode.
245
246 C</a> also sets the character set to Unicode, BUT adds several
247 restrictions for B<A>SCII-safe matching.
248
249 C</d> is the old, problematic, pre-5.14 B<D>efault character set
250 behavior.  Its only use is to force that old behavior.
251
252 At any given time, exactly one of these modifiers is in effect.  Their
253 existence allows Perl to keep the originally compiled behavior of a
254 regular expression, regardless of what rules are in effect when it is
255 actually executed.  And if it is interpolated into a larger regex, the
256 original's rules continue to apply to it, and only it.
257
258 The C</l> and C</u> modifiers are automatically selected for
259 regular expressions compiled within the scope of various pragmas,
260 and we recommend that in general, you use those pragmas instead of
261 specifying these modifiers explicitly.  For one thing, the modifiers
262 affect only pattern matching, and do not extend to even any replacement
263 done, whereas using the pragmas give consistent results for all
264 appropriate operations within their scopes.  For example,
265
266  s/foo/\Ubar/il
267
268 will match "foo" using the locale's rules for case-insensitive matching,
269 but the C</l> does not affect how the C<\U> operates.  Most likely you
270 want both of them to use locale rules.  To do this, instead compile the
271 regular expression within the scope of C<use locale>.  This both
272 implicitly adds the C</l>, and applies locale rules to the C<\U>.   The
273 lesson is to C<use locale>, and not C</l> explicitly.
274
275 Similarly, it would be better to use C<use feature 'unicode_strings'>
276 instead of,
277
278  s/foo/\Lbar/iu
279
280 to get Unicode rules, as the C<\L> in the former (but not necessarily
281 the latter) would also use Unicode rules.
282
283 More detail on each of the modifiers follows.  Most likely you don't
284 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
285 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
286
287 =head4 /l
288
289 means to use the current locale's rules (see L<perllocale>) when pattern
290 matching.  For example, C<\w> will match the "word" characters of that
291 locale, and C<"/i"> case-insensitive matching will match according to
292 the locale's case folding rules.  The locale used will be the one in
293 effect at the time of execution of the pattern match.  This may not be
294 the same as the compilation-time locale, and can differ from one match
295 to another if there is an intervening call of the
296 L<setlocale() function|perllocale/The setlocale function>.
297
298 The only non-single-byte locale Perl supports is (starting in v5.20)
299 UTF-8.  This means that code points above 255 are treated as Unicode no
300 matter what locale is in effect (since UTF-8 implies Unicode).
301
302 Under Unicode rules, there are a few case-insensitive matches that cross
303 the 255/256 boundary.  Except for UTF-8 locales in Perls v5.20 and
304 later, these are disallowed under C</l>.  For example, 0xFF (on ASCII
305 platforms) does not caselessly match the character at 0x178, C<LATIN
306 CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be C<LATIN SMALL
307 LETTER Y WITH DIAERESIS> in the current locale, and Perl has no way of
308 knowing if that character even exists in the locale, much less what code
309 point it is.
310
311 In a UTF-8 locale in v5.20 and later, the only visible difference
312 between locale and non-locale in regular expressions should be tainting
313 (see L<perlsec>).
314
315 This modifier may be specified to be the default by C<use locale>, but
316 see L</Which character set modifier is in effect?>.
317 X</l>
318
319 =head4 /u
320
321 means to use Unicode rules when pattern matching.  On ASCII platforms,
322 this means that the code points between 128 and 255 take on their
323 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
324 (Otherwise Perl considers their meanings to be undefined.)  Thus,
325 under this modifier, the ASCII platform effectively becomes a Unicode
326 platform; and hence, for example, C<\w> will match any of the more than
327 100_000 word characters in Unicode.
328
329 Unlike most locales, which are specific to a language and country pair,
330 Unicode classifies all the characters that are letters I<somewhere> in
331 the world as
332 C<\w>.  For example, your locale might not think that C<LATIN SMALL
333 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
334 Unicode does.  Similarly, all the characters that are decimal digits
335 somewhere in the world will match C<\d>; this is hundreds, not 10,
336 possible matches.  And some of those digits look like some of the 10
337 ASCII digits, but mean a different number, so a human could easily think
338 a number is a different quantity than it really is.  For example,
339 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
340 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
341 that are a mixture from different writing systems, creating a security
342 issue.  L<Unicode::UCD/num()> can be used to sort
343 this out.  Or the C</a> modifier can be used to force C<\d> to match
344 just the ASCII 0 through 9.
345
346 Also, under this modifier, case-insensitive matching works on the full
347 set of Unicode
348 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
349 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
350 if you're not prepared, might make it look like a hexadecimal constant,
351 presenting another potential security issue.  See
352 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
353 security issues.
354
355 This modifier may be specified to be the default by C<use feature
356 'unicode_strings>, C<use locale ':not_characters'>, or
357 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
358 but see L</Which character set modifier is in effect?>.
359 X</u>
360
361 =head4 /d
362
363 This modifier means to use the "Default" native rules of the platform
364 except when there is cause to use Unicode rules instead, as follows:
365
366 =over 4
367
368 =item 1
369
370 the target string is encoded in UTF-8; or
371
372 =item 2
373
374 the pattern is encoded in UTF-8; or
375
376 =item 3
377
378 the pattern explicitly mentions a code point that is above 255 (say by
379 C<\x{100}>); or
380
381 =item 4
382
383 the pattern uses a Unicode name (C<\N{...}>);  or
384
385 =item 5
386
387 the pattern uses a Unicode property (C<\p{...}> or C<\P{...}>); or
388
389 =item 6
390
391 the pattern uses a Unicode break (C<\b{...}> or C<\B{...}>); or
392
393 =item 7
394
395 the pattern uses L</C<(?[ ])>>
396
397 =back
398
399 Another mnemonic for this modifier is "Depends", as the rules actually
400 used depend on various things, and as a result you can get unexpected
401 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
402 become rather infamous, leading to yet another (printable) name for this
403 modifier, "Dodgy".
404
405 Unless the pattern or string are encoded in UTF-8, only ASCII characters
406 can match positively.
407
408 Here are some examples of how that works on an ASCII platform:
409
410  $str =  "\xDF";      # $str is not in UTF-8 format.
411  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
412  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
413  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
414  chop $str;
415  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
416
417 This modifier is automatically selected by default when none of the
418 others are, so yet another name for it is "Default".
419
420 Because of the unexpected behaviors associated with this modifier, you
421 probably should only use it to maintain weird backward compatibilities.
422
423 =head4 /a (and /aa)
424
425 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
426 unlike the others, may be doubled-up to increase its effect.
427
428 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
429 the Posix character classes to match only in the ASCII range.  They thus
430 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
431 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
432 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, the vertical tab;
433 C<\w> means the 63 characters
434 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
435 C<[[:print:]]> match only the appropriate ASCII-range characters.
436
437 This modifier is useful for people who only incidentally use Unicode,
438 and who do not wish to be burdened with its complexities and security
439 concerns.
440
441 With C</a>, one can write C<\d> with confidence that it will only match
442 ASCII characters, and should the need arise to match beyond ASCII, you
443 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
444 similar C<\p{...}> constructs that can match beyond ASCII both white
445 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
446 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
447 doesn't mean you can't use Unicode, it means that to get Unicode
448 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
449 signals Unicode.
450
451 As you would expect, this modifier causes, for example, C<\D> to mean
452 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
453 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
454 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
455 for C<\B>).
456
457 Otherwise, C</a> behaves like the C</u> modifier, in that
458 case-insensitive matching uses Unicode rules; for example, "k" will
459 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
460 points in the Latin1 range, above ASCII will have Unicode rules when it
461 comes to case-insensitive matching.
462
463 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
464 specify the "a" twice, for example C</aai> or C</aia>.  (The first
465 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
466 adds the C</i> restrictions.)  But, note that code points outside the
467 ASCII range will use Unicode rules for C</i> matching, so the modifier
468 doesn't really restrict things to just ASCII; it just forbids the
469 intermixing of ASCII and non-ASCII.
470
471 To summarize, this modifier provides protection for applications that
472 don't wish to be exposed to all of Unicode.  Specifying it twice
473 gives added protection.
474
475 This modifier may be specified to be the default by C<use re '/a'>
476 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
477 the C</u> modifier explicitly if there are a few regular expressions
478 where you do want full Unicode rules (but even here, it's best if
479 everything were under feature C<"unicode_strings">, along with the
480 C<use re '/aa'>).  Also see L</Which character set modifier is in
481 effect?>.
482 X</a>
483 X</aa>
484
485 =head4 Which character set modifier is in effect?
486
487 Which of these modifiers is in effect at any given point in a regular
488 expression depends on a fairly complex set of interactions.  These have
489 been designed so that in general you don't have to worry about it, but
490 this section gives the gory details.  As
491 explained below in L</Extended Patterns> it is possible to explicitly
492 specify modifiers that apply only to portions of a regular expression.
493 The innermost always has priority over any outer ones, and one applying
494 to the whole expression has priority over any of the default settings that are
495 described in the remainder of this section.
496
497 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
498 default modifiers (including these) for regular expressions compiled
499 within its scope.  This pragma has precedence over the other pragmas
500 listed below that also change the defaults.
501
502 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
503 and C<L<use feature 'unicode_strings|feature>>, or
504 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
505 C</u> when not in the same scope as either C<L<use locale|perllocale>>
506 or C<L<use bytes|bytes>>.
507 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
508 sets the default to C</u>, overriding any plain C<use locale>.)
509 Unlike the mechanisms mentioned above, these
510 affect operations besides regular expressions pattern matching, and so
511 give more consistent results with other operators, including using
512 C<\U>, C<\l>, etc. in substitution replacements.
513
514 If none of the above apply, for backwards compatibility reasons, the
515 C</d> modifier is the one in effect by default.  As this can lead to
516 unexpected results, it is best to specify which other rule set should be
517 used.
518
519 =head4 Character set modifier behavior prior to Perl 5.14
520
521 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
522 for regexes compiled within the scope of C<use locale>, and C</d> was
523 implied otherwise.  However, interpolating a regex into a larger regex
524 would ignore the original compilation in favor of whatever was in effect
525 at the time of the second compilation.  There were a number of
526 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
527 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
528 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
529
530 =head2 Regular Expressions
531
532 =head3 Metacharacters
533
534 The patterns used in Perl pattern matching evolved from those supplied in
535 the Version 8 regex routines.  (The routines are derived
536 (distantly) from Henry Spencer's freely redistributable reimplementation
537 of the V8 routines.)  See L<Version 8 Regular Expressions> for
538 details.
539
540 In particular the following metacharacters have their standard I<egrep>-ish
541 meanings:
542 X<metacharacter>
543 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
544
545
546     \        Quote the next metacharacter
547     ^        Match the beginning of the line
548     .        Match any character (except newline)
549     $        Match the end of the string (or before newline at the end
550              of the string)
551     |        Alternation
552     ()       Grouping
553     []       Bracketed Character class
554
555 By default, the "^" character is guaranteed to match only the
556 beginning of the string, the "$" character only the end (or before the
557 newline at the end), and Perl does certain optimizations with the
558 assumption that the string contains only one line.  Embedded newlines
559 will not be matched by "^" or "$".  You may, however, wish to treat a
560 string as a multi-line buffer, such that the "^" will match after any
561 newline within the string (except if the newline is the last character in
562 the string), and "$" will match before any newline.  At the
563 cost of a little more overhead, you can do this by using the /m modifier
564 on the pattern match operator.  (Older programs did this by setting C<$*>,
565 but this option was removed in perl 5.10.)
566 X<^> X<$> X</m>
567
568 To simplify multi-line substitutions, the "." character never matches a
569 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
570 the string is a single line--even if it isn't.
571 X<.> X</s>
572
573 =head3 Quantifiers
574
575 The following standard quantifiers are recognized:
576 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
577
578     *           Match 0 or more times
579     +           Match 1 or more times
580     ?           Match 1 or 0 times
581     {n}         Match exactly n times
582     {n,}        Match at least n times
583     {n,m}       Match at least n but not more than m times
584
585 (If a curly bracket occurs in any other context and does not form part of
586 a backslashed sequence like C<\x{...}>, it is treated as a regular
587 character.  However, a deprecation warning is raised for all such
588 occurrences, and in Perl v5.26, literal uses of a curly bracket will be
589 required to be escaped, say by preceding them with a backslash (C<"\{">)
590 or enclosing them within square brackets  (C<"[{]">).  This change will
591 allow for future syntax extensions (like making the lower bound of a
592 quantifier optional), and better error checking of quantifiers.)
593
594 The "*" quantifier is equivalent to C<{0,}>, the "+"
595 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
596 to non-negative integral values less than a preset limit defined when perl is built.
597 This is usually 32766 on the most common platforms.  The actual limit can
598 be seen in the error message generated by code such as this:
599
600     $_ **= $_ , / {$_} / for 2 .. 42;
601
602 By default, a quantified subpattern is "greedy", that is, it will match as
603 many times as possible (given a particular starting location) while still
604 allowing the rest of the pattern to match.  If you want it to match the
605 minimum number of times possible, follow the quantifier with a "?".  Note
606 that the meanings don't change, just the "greediness":
607 X<metacharacter> X<greedy> X<greediness>
608 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
609
610     *?        Match 0 or more times, not greedily
611     +?        Match 1 or more times, not greedily
612     ??        Match 0 or 1 time, not greedily
613     {n}?      Match exactly n times, not greedily (redundant)
614     {n,}?     Match at least n times, not greedily
615     {n,m}?    Match at least n but not more than m times, not greedily
616
617 Normally when a quantified subpattern does not allow the rest of the
618 overall pattern to match, Perl will backtrack. However, this behaviour is
619 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
620 as well.
621
622  *+     Match 0 or more times and give nothing back
623  ++     Match 1 or more times and give nothing back
624  ?+     Match 0 or 1 time and give nothing back
625  {n}+   Match exactly n times and give nothing back (redundant)
626  {n,}+  Match at least n times and give nothing back
627  {n,m}+ Match at least n but not more than m times and give nothing back
628
629 For instance,
630
631    'aaaa' =~ /a++a/
632
633 will never match, as the C<a++> will gobble up all the C<a>'s in the
634 string and won't leave any for the remaining part of the pattern. This
635 feature can be extremely useful to give perl hints about where it
636 shouldn't backtrack. For instance, the typical "match a double-quoted
637 string" problem can be most efficiently performed when written as:
638
639    /"(?:[^"\\]++|\\.)*+"/
640
641 as we know that if the final quote does not match, backtracking will not
642 help. See the independent subexpression
643 L</C<< (?>pattern) >>> for more details;
644 possessive quantifiers are just syntactic sugar for that construct. For
645 instance the above example could also be written as follows:
646
647    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
648
649 Note that the possessive quantifier modifier can not be be combined
650 with the non-greedy modifier. This is because it would make no sense.
651 Consider the follow equivalency table:
652
653     Illegal         Legal
654     ------------    ------
655     X??+            X{0}
656     X+?+            X{1}
657     X{min,max}?+    X{min}
658
659 =head3 Escape sequences
660
661 Because patterns are processed as double-quoted strings, the following
662 also work:
663
664  \t          tab                   (HT, TAB)
665  \n          newline               (LF, NL)
666  \r          return                (CR)
667  \f          form feed             (FF)
668  \a          alarm (bell)          (BEL)
669  \e          escape (think troff)  (ESC)
670  \cK         control char          (example: VT)
671  \x{}, \x00  character whose ordinal is the given hexadecimal number
672  \N{name}    named Unicode character or character sequence
673  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
674  \o{}, \000  character whose ordinal is the given octal number
675  \l          lowercase next char (think vi)
676  \u          uppercase next char (think vi)
677  \L          lowercase until \E (think vi)
678  \U          uppercase until \E (think vi)
679  \Q          quote (disable) pattern metacharacters until \E
680  \E          end either case modification or quoted section, think vi
681
682 Details are in L<perlop/Quote and Quote-like Operators>.
683
684 =head3 Character Classes and other Special Escapes
685
686 In addition, Perl defines the following:
687 X<\g> X<\k> X<\K> X<backreference>
688
689  Sequence   Note    Description
690   [...]     [1]  Match a character according to the rules of the
691                    bracketed character class defined by the "...".
692                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
693   [[:...:]] [2]  Match a character according to the rules of the POSIX
694                    character class "..." within the outer bracketed
695                    character class.  Example: [[:upper:]] matches any
696                    uppercase character.
697   (?[...])  [8]  Extended bracketed character class
698   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
699                    other connector punctuation chars plus Unicode
700                    marks)
701   \W        [3]  Match a non-"word" character
702   \s        [3]  Match a whitespace character
703   \S        [3]  Match a non-whitespace character
704   \d        [3]  Match a decimal digit character
705   \D        [3]  Match a non-digit character
706   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
707   \PP       [3]  Match non-P
708   \X        [4]  Match Unicode "eXtended grapheme cluster"
709   \1        [5]  Backreference to a specific capture group or buffer.
710                    '1' may actually be any positive integer.
711   \g1       [5]  Backreference to a specific or previous group,
712   \g{-1}    [5]  The number may be negative indicating a relative
713                    previous group and may optionally be wrapped in
714                    curly brackets for safer parsing.
715   \g{name}  [5]  Named backreference
716   \k<name>  [5]  Named backreference
717   \K        [6]  Keep the stuff left of the \K, don't include it in $&
718   \N        [7]  Any character but \n.  Not affected by /s modifier
719   \v        [3]  Vertical whitespace
720   \V        [3]  Not vertical whitespace
721   \h        [3]  Horizontal whitespace
722   \H        [3]  Not horizontal whitespace
723   \R        [4]  Linebreak
724
725 =over 4
726
727 =item [1]
728
729 See L<perlrecharclass/Bracketed Character Classes> for details.
730
731 =item [2]
732
733 See L<perlrecharclass/POSIX Character Classes> for details.
734
735 =item [3]
736
737 See L<perlrecharclass/Backslash sequences> for details.
738
739 =item [4]
740
741 See L<perlrebackslash/Misc> for details.
742
743 =item [5]
744
745 See L</Capture groups> below for details.
746
747 =item [6]
748
749 See L</Extended Patterns> below for details.
750
751 =item [7]
752
753 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
754 character or character sequence whose name is C<NAME>; and similarly
755 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
756 code point is I<hex>.  Otherwise it matches any character but C<\n>.
757
758 =item [8]
759
760 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
761
762 =back
763
764 =head3 Assertions
765
766 Perl defines the following zero-width assertions:
767 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
768 X<regexp, zero-width assertion>
769 X<regular expression, zero-width assertion>
770 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
771
772     \b{} Match at Unicode boundary of specified type
773     \B{} Match where corresponding \b{} doesn't match
774     \b  Match a word boundary
775     \B  Match except at a word boundary
776     \A  Match only at beginning of string
777     \Z  Match only at end of string, or before newline at the end
778     \z  Match only at end of string
779     \G  Match only at pos() (e.g. at the end-of-match position
780         of prior m//g)
781
782 A Unicode boundary (C<\b{}>), available starting in v5.22, is a spot
783 between two characters, or before the first character in the string, or
784 after the final character in the string where certain criteria defined
785 by Unicode are met.  See L<perlrebackslash/\b{}, \b, \B{}, \B> for
786 details.
787
788 A word boundary (C<\b>) is a spot between two characters
789 that has a C<\w> on one side of it and a C<\W> on the other side
790 of it (in either order), counting the imaginary characters off the
791 beginning and end of the string as matching a C<\W>.  (Within
792 character classes C<\b> represents backspace rather than a word
793 boundary, just as it normally does in any double-quoted string.)
794 The C<\A> and C<\Z> are just like "^" and "$", except that they
795 won't match multiple times when the C</m> modifier is used, while
796 "^" and "$" will match at every internal line boundary.  To match
797 the actual end of the string and not ignore an optional trailing
798 newline, use C<\z>.
799 X<\b> X<\A> X<\Z> X<\z> X</m>
800
801 The C<\G> assertion can be used to chain global matches (using
802 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
803 It is also useful when writing C<lex>-like scanners, when you have
804 several patterns that you want to match against consequent substrings
805 of your string; see the previous reference.  The actual location
806 where C<\G> will match can also be influenced by using C<pos()> as
807 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
808 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
809 is modified somewhat, in that contents to the left of C<\G> are
810 not counted when determining the length of the match. Thus the following
811 will not match forever:
812 X<\G>
813
814      my $string = 'ABC';
815      pos($string) = 1;
816      while ($string =~ /(.\G)/g) {
817          print $1;
818      }
819
820 It will print 'A' and then terminate, as it considers the match to
821 be zero-width, and thus will not match at the same position twice in a
822 row.
823
824 It is worth noting that C<\G> improperly used can result in an infinite
825 loop. Take care when using patterns that include C<\G> in an alternation.
826
827 Note also that C<s///> will refuse to overwrite part of a substitution
828 that has already been replaced; so for example this will stop after the
829 first iteration, rather than iterating its way backwards through the
830 string:
831
832     $_ = "123456789";
833     pos = 6;
834     s/.(?=.\G)/X/g;
835     print;      # prints 1234X6789, not XXXXX6789
836
837
838 =head3 Capture groups
839
840 The bracketing construct C<( ... )> creates capture groups (also referred to as
841 capture buffers). To refer to the current contents of a group later on, within
842 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
843 for the second, and so on.
844 This is called a I<backreference>.
845 X<regex, capture buffer> X<regexp, capture buffer>
846 X<regex, capture group> X<regexp, capture group>
847 X<regular expression, capture buffer> X<backreference>
848 X<regular expression, capture group> X<backreference>
849 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
850 X<named capture buffer> X<regular expression, named capture buffer>
851 X<named capture group> X<regular expression, named capture group>
852 X<%+> X<$+{name}> X<< \k<name> >>
853 There is no limit to the number of captured substrings that you may use.
854 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
855 a group did not match, the associated backreference won't match either. (This
856 can happen if the group is optional, or in a different branch of an
857 alternation.)
858 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
859 this form, described below.
860
861 You can also refer to capture groups relatively, by using a negative number, so
862 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
863 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
864 example:
865
866         /
867          (Y)            # group 1
868          (              # group 2
869             (X)         # group 3
870             \g{-1}      # backref to group 3
871             \g{-3}      # backref to group 1
872          )
873         /x
874
875 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
876 interpolate regexes into larger regexes and not have to worry about the
877 capture groups being renumbered.
878
879 You can dispense with numbers altogether and create named capture groups.
880 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
881 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
882 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
883 I<name> must not begin with a number, nor contain hyphens.
884 When different groups within the same pattern have the same name, any reference
885 to that name assumes the leftmost defined group.  Named groups count in
886 absolute and relative numbering, and so can also be referred to by those
887 numbers.
888 (It's possible to do things with named capture groups that would otherwise
889 require C<(??{})>.)
890
891 Capture group contents are dynamically scoped and available to you outside the
892 pattern until the end of the enclosing block or until the next successful
893 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
894 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
895 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
896
897 Braces are required in referring to named capture groups, but are optional for
898 absolute or relative numbered ones.  Braces are safer when creating a regex by
899 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
900 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
901 is probably not what you intended.
902
903 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
904 there were no named nor relative numbered capture groups.  Absolute numbered
905 groups were referred to using C<\1>,
906 C<\2>, etc., and this notation is still
907 accepted (and likely always will be).  But it leads to some ambiguities if
908 there are more than 9 capture groups, as C<\10> could mean either the tenth
909 capture group, or the character whose ordinal in octal is 010 (a backspace in
910 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
911 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
912 a backreference only if at least 11 left parentheses have opened before it.
913 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
914 There are several examples below that illustrate these perils.  You can avoid
915 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
916 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
917 digits padded with leading zeros, since a leading zero implies an octal
918 constant.
919
920 The C<\I<digit>> notation also works in certain circumstances outside
921 the pattern.  See L</Warning on \1 Instead of $1> below for details.
922
923 Examples:
924
925     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
926
927     /(.)\g1/                        # find first doubled char
928          and print "'$1' is the first doubled character\n";
929
930     /(?<char>.)\k<char>/            # ... a different way
931          and print "'$+{char}' is the first doubled character\n";
932
933     /(?'char'.)\g1/                 # ... mix and match
934          and print "'$1' is the first doubled character\n";
935
936     if (/Time: (..):(..):(..)/) {   # parse out values
937         $hours = $1;
938         $minutes = $2;
939         $seconds = $3;
940     }
941
942     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
943     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
944     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
945     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
946
947     $a = '(.)\1';        # Creates problems when concatenated.
948     $b = '(.)\g{1}';     # Avoids the problems.
949     "aa" =~ /${a}/;      # True
950     "aa" =~ /${b}/;      # True
951     "aa0" =~ /${a}0/;    # False!
952     "aa0" =~ /${b}0/;    # True
953     "aa\x08" =~ /${a}0/;  # True!
954     "aa\x08" =~ /${b}0/;  # False
955
956 Several special variables also refer back to portions of the previous
957 match.  C<$+> returns whatever the last bracket match matched.
958 C<$&> returns the entire matched string.  (At one point C<$0> did
959 also, but now it returns the name of the program.)  C<$`> returns
960 everything before the matched string.  C<$'> returns everything
961 after the matched string. And C<$^N> contains whatever was matched by
962 the most-recently closed group (submatch). C<$^N> can be used in
963 extended patterns (see below), for example to assign a submatch to a
964 variable.
965 X<$+> X<$^N> X<$&> X<$`> X<$'>
966
967 These special variables, like the C<%+> hash and the numbered match variables
968 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
969 until the end of the enclosing block or until the next successful
970 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
971 X<$+> X<$^N> X<$&> X<$`> X<$'>
972 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
973
974 B<NOTE>: Failed matches in Perl do not reset the match variables,
975 which makes it easier to write code that tests for a series of more
976 specific cases and remembers the best match.
977
978 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
979 beware that once Perl sees that you need one of C<$&>, C<$`>, or
980 C<$'> anywhere in the program, it has to provide them for every
981 pattern match.  This may substantially slow your program.
982
983 Perl uses the same mechanism to produce C<$1>, C<$2>, etc, so you also
984 pay a price for each pattern that contains capturing parentheses.
985 (To avoid this cost while retaining the grouping behaviour, use the
986 extended regular expression C<(?: ... )> instead.)  But if you never
987 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
988 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
989 if you can, but if you can't (and some algorithms really appreciate
990 them), once you've used them once, use them at will, because you've
991 already paid the price.
992 X<$&> X<$`> X<$'>
993
994 Perl 5.16 introduced a slightly more efficient mechanism that notes
995 separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and
996 thus may only need to copy part of the string.  Perl 5.20 introduced a
997 much more efficient copy-on-write mechanism which eliminates any slowdown.
998
999 As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
1000 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
1001 and C<$'>, B<except> that they are only guaranteed to be defined after a
1002 successful match that was executed with the C</p> (preserve) modifier.
1003 The use of these variables incurs no global performance penalty, unlike
1004 their punctuation char equivalents, however at the trade-off that you
1005 have to tell perl when you want to use them.  As of Perl 5.20, these three
1006 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
1007 X</p> X<p modifier>
1008
1009 =head2 Quoting metacharacters
1010
1011 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
1012 C<\w>, C<\n>.  Unlike some other regular expression languages, there
1013 are no backslashed symbols that aren't alphanumeric.  So anything
1014 that looks like \\, \(, \), \[, \], \{, or \} is always
1015 interpreted as a literal character, not a metacharacter.  This was
1016 once used in a common idiom to disable or quote the special meanings
1017 of regular expression metacharacters in a string that you want to
1018 use for a pattern. Simply quote all non-"word" characters:
1019
1020     $pattern =~ s/(\W)/\\$1/g;
1021
1022 (If C<use locale> is set, then this depends on the current locale.)
1023 Today it is more common to use the quotemeta() function or the C<\Q>
1024 metaquoting escape sequence to disable all metacharacters' special
1025 meanings like this:
1026
1027     /$unquoted\Q$quoted\E$unquoted/
1028
1029 Beware that if you put literal backslashes (those not inside
1030 interpolated variables) between C<\Q> and C<\E>, double-quotish
1031 backslash interpolation may lead to confusing results.  If you
1032 I<need> to use literal backslashes within C<\Q...\E>,
1033 consult L<perlop/"Gory details of parsing quoted constructs">.
1034
1035 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
1036
1037 =head2 Extended Patterns
1038
1039 Perl also defines a consistent extension syntax for features not
1040 found in standard tools like B<awk> and
1041 B<lex>.  The syntax for most of these is a
1042 pair of parentheses with a question mark as the first thing within
1043 the parentheses.  The character after the question mark indicates
1044 the extension.
1045
1046 The stability of these extensions varies widely.  Some have been
1047 part of the core language for many years.  Others are experimental
1048 and may change without warning or be completely removed.  Check
1049 the documentation on an individual feature to verify its current
1050 status.
1051
1052 A question mark was chosen for this and for the minimal-matching
1053 construct because 1) question marks are rare in older regular
1054 expressions, and 2) whenever you see one, you should stop and
1055 "question" exactly what is going on.  That's psychology....
1056
1057 =over 4
1058
1059 =item C<(?#text)>
1060 X<(?#)>
1061
1062 A comment.  The text is ignored.
1063 Note that Perl closes
1064 the comment as soon as it sees a C<)>, so there is no way to put a literal
1065 C<)> in the comment.  The pattern's closing delimiter must be escaped by
1066 a backslash if it appears in the comment.
1067
1068 See L</E<sol>x> for another way to have comments in patterns.
1069
1070 =item C<(?adlupimsx-imsx)>
1071
1072 =item C<(?^alupimsx)>
1073 X<(?)> X<(?^)>
1074
1075 One or more embedded pattern-match modifiers, to be turned on (or
1076 turned off, if preceded by C<->) for the remainder of the pattern or
1077 the remainder of the enclosing pattern group (if any).
1078
1079 This is particularly useful for dynamic patterns, such as those read in from a
1080 configuration file, taken from an argument, or specified in a table
1081 somewhere.  Consider the case where some patterns want to be
1082 case-sensitive and some do not:  The case-insensitive ones merely need to
1083 include C<(?i)> at the front of the pattern.  For example:
1084
1085     $pattern = "foobar";
1086     if ( /$pattern/i ) { }
1087
1088     # more flexible:
1089
1090     $pattern = "(?i)foobar";
1091     if ( /$pattern/ ) { }
1092
1093 These modifiers are restored at the end of the enclosing group. For example,
1094
1095     ( (?i) blah ) \s+ \g1
1096
1097 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1098 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1099 modifier outside this group.
1100
1101 These modifiers do not carry over into named subpatterns called in the
1102 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1103 change the case-sensitivity of the "NAME" pattern.
1104
1105 Any of these modifiers can be set to apply globally to all regular
1106 expressions compiled within the scope of a C<use re>.  See
1107 L<re/"'/flags' mode">.
1108
1109 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1110 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1111 C<"d">) may follow the caret to override it.
1112 But a minus sign is not legal with it.
1113
1114 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1115 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1116 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1117 others, and a maximum of one (or two C<a>'s) may appear in the
1118 construct.  Thus, for
1119 example, C<(?-p)> will warn when compiled under C<use warnings>;
1120 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1121
1122 Note also that the C<p> modifier is special in that its presence
1123 anywhere in a pattern has a global effect.
1124
1125 =item C<(?:pattern)>
1126 X<(?:)>
1127
1128 =item C<(?adluimsx-imsx:pattern)>
1129
1130 =item C<(?^aluimsx:pattern)>
1131 X<(?^:)>
1132
1133 This is for clustering, not capturing; it groups subexpressions like
1134 "()", but doesn't make backreferences as "()" does.  So
1135
1136     @fields = split(/\b(?:a|b|c)\b/)
1137
1138 is like
1139
1140     @fields = split(/\b(a|b|c)\b/)
1141
1142 but doesn't spit out extra fields.  It's also cheaper not to capture
1143 characters if you don't need to.
1144
1145 Any letters between C<?> and C<:> act as flags modifiers as with
1146 C<(?adluimsx-imsx)>.  For example,
1147
1148     /(?s-i:more.*than).*million/i
1149
1150 is equivalent to the more verbose
1151
1152     /(?:(?s-i)more.*than).*million/i
1153
1154 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1155 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1156 flags (except C<"d">) may follow the caret, so
1157
1158     (?^x:foo)
1159
1160 is equivalent to
1161
1162     (?x-ims:foo)
1163
1164 The caret tells Perl that this cluster doesn't inherit the flags of any
1165 surrounding pattern, but uses the system defaults (C<d-imsx>),
1166 modified by any flags specified.
1167
1168 The caret allows for simpler stringification of compiled regular
1169 expressions.  These look like
1170
1171     (?^:pattern)
1172
1173 with any non-default flags appearing between the caret and the colon.
1174 A test that looks at such stringification thus doesn't need to have the
1175 system default flags hard-coded in it, just the caret.  If new flags are
1176 added to Perl, the meaning of the caret's expansion will change to include
1177 the default for those flags, so the test will still work, unchanged.
1178
1179 Specifying a negative flag after the caret is an error, as the flag is
1180 redundant.
1181
1182 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1183 to match at the beginning.
1184
1185 =item C<(?|pattern)>
1186 X<(?|)> X<Branch reset>
1187
1188 This is the "branch reset" pattern, which has the special property
1189 that the capture groups are numbered from the same starting point
1190 in each alternation branch. It is available starting from perl 5.10.0.
1191
1192 Capture groups are numbered from left to right, but inside this
1193 construct the numbering is restarted for each branch.
1194
1195 The numbering within each branch will be as normal, and any groups
1196 following this construct will be numbered as though the construct
1197 contained only one branch, that being the one with the most capture
1198 groups in it.
1199
1200 This construct is useful when you want to capture one of a
1201 number of alternative matches.
1202
1203 Consider the following pattern.  The numbers underneath show in
1204 which group the captured content will be stored.
1205
1206
1207     # before  ---------------branch-reset----------- after        
1208     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1209     # 1            2         2  3        2     3     4  
1210
1211 Be careful when using the branch reset pattern in combination with 
1212 named captures. Named captures are implemented as being aliases to 
1213 numbered groups holding the captures, and that interferes with the
1214 implementation of the branch reset pattern. If you are using named
1215 captures in a branch reset pattern, it's best to use the same names,
1216 in the same order, in each of the alternations:
1217
1218    /(?|  (?<a> x ) (?<b> y )
1219       |  (?<a> z ) (?<b> w )) /x
1220
1221 Not doing so may lead to surprises:
1222
1223   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1224   say $+ {a};   # Prints '12'
1225   say $+ {b};   # *Also* prints '12'.
1226
1227 The problem here is that both the group named C<< a >> and the group
1228 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1229
1230 =item Look-Around Assertions
1231 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1232
1233 Look-around assertions are zero-width patterns which match a specific
1234 pattern without including it in C<$&>. Positive assertions match when
1235 their subpattern matches, negative assertions match when their subpattern
1236 fails. Look-behind matches text up to the current match position,
1237 look-ahead matches text following the current match position.
1238
1239 =over 4
1240
1241 =item C<(?=pattern)>
1242 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1243
1244 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1245 matches a word followed by a tab, without including the tab in C<$&>.
1246
1247 =item C<(?!pattern)>
1248 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1249
1250 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1251 matches any occurrence of "foo" that isn't followed by "bar".  Note
1252 however that look-ahead and look-behind are NOT the same thing.  You cannot
1253 use this for look-behind.
1254
1255 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1256 will not do what you want.  That's because the C<(?!foo)> is just saying that
1257 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1258 match.  Use look-behind instead (see below).
1259
1260 =item C<(?<=pattern)> C<\K>
1261 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1262
1263 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1264 matches a word that follows a tab, without including the tab in C<$&>.
1265 Works only for fixed-width look-behind.
1266
1267 There is a special form of this construct, called C<\K> (available since
1268 Perl 5.10.0), which causes the
1269 regex engine to "keep" everything it had matched prior to the C<\K> and
1270 not include it in C<$&>. This effectively provides variable-length
1271 look-behind. The use of C<\K> inside of another look-around assertion
1272 is allowed, but the behaviour is currently not well defined.
1273
1274 For various reasons C<\K> may be significantly more efficient than the
1275 equivalent C<< (?<=...) >> construct, and it is especially useful in
1276 situations where you want to efficiently remove something following
1277 something else in a string. For instance
1278
1279   s/(foo)bar/$1/g;
1280
1281 can be rewritten as the much more efficient
1282
1283   s/foo\Kbar//g;
1284
1285 =item C<(?<!pattern)>
1286 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1287
1288 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1289 matches any occurrence of "foo" that does not follow "bar".  Works
1290 only for fixed-width look-behind.
1291
1292 =back
1293
1294 =item C<(?'NAME'pattern)>
1295
1296 =item C<< (?<NAME>pattern) >>
1297 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1298
1299 A named capture group. Identical in every respect to normal capturing
1300 parentheses C<()> but for the additional fact that the group
1301 can be referred to by name in various regular expression
1302 constructs (like C<\g{NAME}>) and can be accessed by name
1303 after a successful match via C<%+> or C<%->. See L<perlvar>
1304 for more details on the C<%+> and C<%-> hashes.
1305
1306 If multiple distinct capture groups have the same name then the
1307 $+{NAME} will refer to the leftmost defined group in the match.
1308
1309 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1310
1311 B<NOTE:> While the notation of this construct is the same as the similar
1312 function in .NET regexes, the behavior is not. In Perl the groups are
1313 numbered sequentially regardless of being named or not. Thus in the
1314 pattern
1315
1316   /(x)(?<foo>y)(z)/
1317
1318 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1319 the opposite which is what a .NET regex hacker might expect.
1320
1321 Currently NAME is restricted to simple identifiers only.
1322 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1323 its Unicode extension (see L<utf8>),
1324 though it isn't extended by the locale (see L<perllocale>).
1325
1326 B<NOTE:> In order to make things easier for programmers with experience
1327 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1328 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1329 support the use of single quotes as a delimiter for the name.
1330
1331 =item C<< \k<NAME> >>
1332
1333 =item C<< \k'NAME' >>
1334
1335 Named backreference. Similar to numeric backreferences, except that
1336 the group is designated by name and not number. If multiple groups
1337 have the same name then it refers to the leftmost defined group in
1338 the current match.
1339
1340 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1341 earlier in the pattern.
1342
1343 Both forms are equivalent.
1344
1345 B<NOTE:> In order to make things easier for programmers with experience
1346 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1347 may be used instead of C<< \k<NAME> >>.
1348
1349 =item C<(?{ code })>
1350 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1351
1352 B<WARNING>: Using this feature safely requires that you understand its
1353 limitations.  Code executed that has side effects may not perform identically
1354 from version to version due to the effect of future optimisations in the regex
1355 engine.  For more information on this, see L</Embedded Code Execution
1356 Frequency>.
1357
1358 This zero-width assertion executes any embedded Perl code.  It always
1359 succeeds, and its return value is set as C<$^R>.
1360
1361 In literal patterns, the code is parsed at the same time as the
1362 surrounding code. While within the pattern, control is passed temporarily
1363 back to the perl parser, until the logically-balancing closing brace is
1364 encountered. This is similar to the way that an array index expression in
1365 a literal string is handled, for example
1366
1367     "abc$array[ 1 + f('[') + g()]def"
1368
1369 In particular, braces do not need to be balanced:
1370
1371     s/abc(?{ f('{'); })/def/
1372
1373 Even in a pattern that is interpolated and compiled at run-time, literal
1374 code blocks will be compiled once, at perl compile time; the following
1375 prints "ABCD":
1376
1377     print "D";
1378     my $qr = qr/(?{ BEGIN { print "A" } })/;
1379     my $foo = "foo";
1380     /$foo$qr(?{ BEGIN { print "B" } })/;
1381     BEGIN { print "C" }
1382
1383 In patterns where the text of the code is derived from run-time
1384 information rather than appearing literally in a source code /pattern/,
1385 the code is compiled at the same time that the pattern is compiled, and
1386 for reasons of security, C<use re 'eval'> must be in scope. This is to
1387 stop user-supplied patterns containing code snippets from being
1388 executable.
1389
1390 In situations where you need to enable this with C<use re 'eval'>, you should
1391 also have taint checking enabled.  Better yet, use the carefully
1392 constrained evaluation within a Safe compartment.  See L<perlsec> for
1393 details about both these mechanisms.
1394
1395 From the viewpoint of parsing, lexical variable scope and closures,
1396
1397     /AAA(?{ BBB })CCC/
1398
1399 behaves approximately like
1400
1401     /AAA/ && do { BBB } && /CCC/
1402
1403 Similarly,
1404
1405     qr/AAA(?{ BBB })CCC/
1406
1407 behaves approximately like
1408
1409     sub { /AAA/ && do { BBB } && /CCC/ }
1410
1411 In particular:
1412
1413     { my $i = 1; $r = qr/(?{ print $i })/ }
1414     my $i = 2;
1415     /$r/; # prints "1"
1416
1417 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1418 expression is matching against. You can also use C<pos()> to know what is
1419 the current position of matching within this string.
1420
1421 The code block introduces a new scope from the perspective of lexical
1422 variable declarations, but B<not> from the perspective of C<local> and
1423 similar localizing behaviours. So later code blocks within the same
1424 pattern will still see the values which were localized in earlier blocks.
1425 These accumulated localizations are undone either at the end of a
1426 successful match, or if the assertion is backtracked (compare
1427 L<"Backtracking">). For example,
1428
1429   $_ = 'a' x 8;
1430   m<
1431      (?{ $cnt = 0 })               # Initialize $cnt.
1432      (
1433        a
1434        (?{
1435            local $cnt = $cnt + 1;  # Update $cnt,
1436                                    # backtracking-safe.
1437        })
1438      )*
1439      aaaa
1440      (?{ $res = $cnt })            # On success copy to
1441                                    # non-localized location.
1442    >x;
1443
1444 will initially increment C<$cnt> up to 8; then during backtracking, its
1445 value will be unwound back to 4, which is the value assigned to C<$res>.
1446 At the end of the regex execution, $cnt will be wound back to its initial
1447 value of 0.
1448
1449 This assertion may be used as the condition in a
1450
1451     (?(condition)yes-pattern|no-pattern)
1452
1453 switch.  If I<not> used in this way, the result of evaluation of C<code>
1454 is put into the special variable C<$^R>.  This happens immediately, so
1455 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1456 regular expression.
1457
1458 The assignment to C<$^R> above is properly localized, so the old
1459 value of C<$^R> is restored if the assertion is backtracked; compare
1460 L<"Backtracking">.
1461
1462 Note that the special variable C<$^N>  is particularly useful with code
1463 blocks to capture the results of submatches in variables without having to
1464 keep track of the number of nested parentheses. For example:
1465
1466   $_ = "The brown fox jumps over the lazy dog";
1467   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1468   print "color = $color, animal = $animal\n";
1469
1470
1471 =item C<(??{ code })>
1472 X<(??{})>
1473 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1474
1475 B<WARNING>: Using this feature safely requires that you understand its
1476 limitations.  Code executed that has side effects may not perform
1477 identically from version to version due to the effect of future
1478 optimisations in the regex engine.  For more information on this, see
1479 L</Embedded Code Execution Frequency>.
1480
1481 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1482 same way as a C<(?{ code })> code block as described above, except that
1483 its return value, rather than being assigned to C<$^R>, is treated as a
1484 pattern, compiled if it's a string (or used as-is if its a qr// object),
1485 then matched as if it were inserted instead of this construct.
1486
1487 During the matching of this sub-pattern, it has its own set of
1488 captures which are valid during the sub-match, but are discarded once
1489 control returns to the main pattern. For example, the following matches,
1490 with the inner pattern capturing "B" and matching "BB", while the outer
1491 pattern captures "A";
1492
1493     my $inner = '(.)\1';
1494     "ABBA" =~ /^(.)(??{ $inner })\1/;
1495     print $1; # prints "A";
1496
1497 Note that this means that  there is no way for the inner pattern to refer
1498 to a capture group defined outside.  (The code block itself can use C<$1>,
1499 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1500
1501     ('a' x 100)=~/(??{'(.)' x 100})/
1502
1503 I<will> match, it will I<not> set $1 on exit.
1504
1505 The following pattern matches a parenthesized group:
1506
1507  $re = qr{
1508             \(
1509             (?:
1510                (?> [^()]+ )  # Non-parens without backtracking
1511              |
1512                (??{ $re })   # Group with matching parens
1513             )*
1514             \)
1515          }x;
1516
1517 See also
1518 L<C<(?I<PARNO>)>|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)>
1519 for a different, more efficient way to accomplish
1520 the same task.
1521
1522 Executing a postponed regular expression 50 times without consuming any
1523 input string will result in a fatal error.  The maximum depth is compiled
1524 into perl, so changing it requires a custom build.
1525
1526 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1527 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1528 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1529 X<regex, relative recursion> X<GOSUB> X<GOSTART>
1530
1531 Recursive subpattern. Treat the contents of a given capture buffer in the
1532 current pattern as an independent subpattern and attempt to match it at
1533 the current position in the string. Information about capture state from
1534 the caller for things like backreferences is available to the subpattern,
1535 but capture buffers set by the subpattern are not visible to the caller.
1536
1537 Similar to C<(??{ code })> except that it does not involve executing any
1538 code or potentially compiling a returned pattern string; instead it treats
1539 the part of the current pattern contained within a specified capture group
1540 as an independent pattern that must match at the current position. Also
1541 different is the treatment of capture buffers, unlike C<(??{ code })>
1542 recursive patterns have access to their callers match state, so one can
1543 use backreferences safely.
1544
1545 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1546 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1547 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1548 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1549 to be relative, with negative numbers indicating preceding capture groups
1550 and positive ones following. Thus C<(?-1)> refers to the most recently
1551 declared group, and C<(?+1)> indicates the next group to be declared.
1552 Note that the counting for relative recursion differs from that of
1553 relative backreferences, in that with recursion unclosed groups B<are>
1554 included.
1555
1556 The following pattern matches a function foo() which may contain
1557 balanced parentheses as the argument.
1558
1559   $re = qr{ (                   # paren group 1 (full function)
1560               foo
1561               (                 # paren group 2 (parens)
1562                 \(
1563                   (             # paren group 3 (contents of parens)
1564                   (?:
1565                    (?> [^()]+ ) # Non-parens without backtracking
1566                   |
1567                    (?2)         # Recurse to start of paren group 2
1568                   )*
1569                   )
1570                 \)
1571               )
1572             )
1573           }x;
1574
1575 If the pattern was used as follows
1576
1577     'foo(bar(baz)+baz(bop))'=~/$re/
1578         and print "\$1 = $1\n",
1579                   "\$2 = $2\n",
1580                   "\$3 = $3\n";
1581
1582 the output produced should be the following:
1583
1584     $1 = foo(bar(baz)+baz(bop))
1585     $2 = (bar(baz)+baz(bop))
1586     $3 = bar(baz)+baz(bop)
1587
1588 If there is no corresponding capture group defined, then it is a
1589 fatal error.  Recursing deeper than 50 times without consuming any input
1590 string will also result in a fatal error.  The maximum depth is compiled
1591 into perl, so changing it requires a custom build.
1592
1593 The following shows how using negative indexing can make it
1594 easier to embed recursive patterns inside of a C<qr//> construct
1595 for later use:
1596
1597     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1598     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1599        # do something here...
1600     }
1601
1602 B<Note> that this pattern does not behave the same way as the equivalent
1603 PCRE or Python construct of the same form. In Perl you can backtrack into
1604 a recursed group, in PCRE and Python the recursed into group is treated
1605 as atomic. Also, modifiers are resolved at compile time, so constructs
1606 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1607 be processed.
1608
1609 =item C<(?&NAME)>
1610 X<(?&NAME)>
1611
1612 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
1613 parenthesis to recurse to is determined by name. If multiple parentheses have
1614 the same name, then it recurses to the leftmost.
1615
1616 It is an error to refer to a name that is not declared somewhere in the
1617 pattern.
1618
1619 B<NOTE:> In order to make things easier for programmers with experience
1620 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1621 may be used instead of C<< (?&NAME) >>.
1622
1623 =item C<(?(condition)yes-pattern|no-pattern)>
1624 X<(?()>
1625
1626 =item C<(?(condition)yes-pattern)>
1627
1628 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1629 a true value, matches C<no-pattern> otherwise. A missing pattern always
1630 matches.
1631
1632 C<(condition)> should be one of: 1) an integer in
1633 parentheses (which is valid if the corresponding pair of parentheses
1634 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1635 name in angle brackets or single quotes (which is valid if a group
1636 with the given name matched); or 4) the special symbol (R) (true when
1637 evaluated inside of recursion or eval). Additionally the R may be
1638 followed by a number, (which will be true when evaluated when recursing
1639 inside of the appropriate group), or by C<&NAME>, in which case it will
1640 be true only when evaluated during recursion in the named group.
1641
1642 Here's a summary of the possible predicates:
1643
1644 =over 4
1645
1646 =item (1) (2) ...
1647
1648 Checks if the numbered capturing group has matched something.
1649
1650 =item (<NAME>) ('NAME')
1651
1652 Checks if a group with the given name has matched something.
1653
1654 =item (?=...) (?!...) (?<=...) (?<!...)
1655
1656 Checks whether the pattern matches (or does not match, for the '!'
1657 variants).
1658
1659 =item (?{ CODE })
1660
1661 Treats the return value of the code block as the condition.
1662
1663 =item (R)
1664
1665 Checks if the expression has been evaluated inside of recursion.
1666
1667 =item (R1) (R2) ...
1668
1669 Checks if the expression has been evaluated while executing directly
1670 inside of the n-th capture group. This check is the regex equivalent of
1671
1672   if ((caller(0))[3] eq 'subname') { ... }
1673
1674 In other words, it does not check the full recursion stack.
1675
1676 =item (R&NAME)
1677
1678 Similar to C<(R1)>, this predicate checks to see if we're executing
1679 directly inside of the leftmost group with a given name (this is the same
1680 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1681 stack, but only the name of the innermost active recursion.
1682
1683 =item (DEFINE)
1684
1685 In this case, the yes-pattern is never directly executed, and no
1686 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1687 See below for details.
1688
1689 =back
1690
1691 For example:
1692
1693     m{ ( \( )?
1694        [^()]+
1695        (?(1) \) )
1696      }x
1697
1698 matches a chunk of non-parentheses, possibly included in parentheses
1699 themselves.
1700
1701 A special form is the C<(DEFINE)> predicate, which never executes its
1702 yes-pattern directly, and does not allow a no-pattern. This allows one to
1703 define subpatterns which will be executed only by the recursion mechanism.
1704 This way, you can define a set of regular expression rules that can be
1705 bundled into any pattern you choose.
1706
1707 It is recommended that for this usage you put the DEFINE block at the
1708 end of the pattern, and that you name any subpatterns defined within it.
1709
1710 Also, it's worth noting that patterns defined this way probably will
1711 not be as efficient, as the optimizer is not very clever about
1712 handling them.
1713
1714 An example of how this might be used is as follows:
1715
1716   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1717    (?(DEFINE)
1718      (?<NAME_PAT>....)
1719      (?<ADDRESS_PAT>....)
1720    )/x
1721
1722 Note that capture groups matched inside of recursion are not accessible
1723 after the recursion returns, so the extra layer of capturing groups is
1724 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1725 C<$+{NAME}> would be.
1726
1727 Finally, keep in mind that subpatterns created inside a DEFINE block
1728 count towards the absolute and relative number of captures, so this:
1729
1730     my @captures = "a" =~ /(.)                  # First capture
1731                            (?(DEFINE)
1732                                (?<EXAMPLE> 1 )  # Second capture
1733                            )/x;
1734     say scalar @captures;
1735
1736 Will output 2, not 1. This is particularly important if you intend to
1737 compile the definitions with the C<qr//> operator, and later
1738 interpolate them in another pattern.
1739
1740 =item C<< (?>pattern) >>
1741 X<backtrack> X<backtracking> X<atomic> X<possessive>
1742
1743 An "independent" subexpression, one which matches the substring
1744 that a I<standalone> C<pattern> would match if anchored at the given
1745 position, and it matches I<nothing other than this substring>.  This
1746 construct is useful for optimizations of what would otherwise be
1747 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1748 It may also be useful in places where the "grab all you can, and do not
1749 give anything back" semantic is desirable.
1750
1751 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1752 (anchored at the beginning of string, as above) will match I<all>
1753 characters C<a> at the beginning of string, leaving no C<a> for
1754 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1755 since the match of the subgroup C<a*> is influenced by the following
1756 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1757 C<a*ab> will match fewer characters than a standalone C<a*>, since
1758 this makes the tail match.
1759
1760 C<< (?>pattern) >> does not disable backtracking altogether once it has
1761 matched. It is still possible to backtrack past the construct, but not
1762 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1763
1764 An effect similar to C<< (?>pattern) >> may be achieved by writing
1765 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1766 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1767 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1768 (The difference between these two constructs is that the second one
1769 uses a capturing group, thus shifting ordinals of backreferences
1770 in the rest of a regular expression.)
1771
1772 Consider this pattern:
1773
1774     m{ \(
1775           (
1776             [^()]+           # x+
1777           |
1778             \( [^()]* \)
1779           )+
1780        \)
1781      }x
1782
1783 That will efficiently match a nonempty group with matching parentheses
1784 two levels deep or less.  However, if there is no such group, it
1785 will take virtually forever on a long string.  That's because there
1786 are so many different ways to split a long string into several
1787 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1788 to a subpattern of the above pattern.  Consider how the pattern
1789 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1790 seconds, but that each extra letter doubles this time.  This
1791 exponential performance will make it appear that your program has
1792 hung.  However, a tiny change to this pattern
1793
1794     m{ \(
1795           (
1796             (?> [^()]+ )        # change x+ above to (?> x+ )
1797           |
1798             \( [^()]* \)
1799           )+
1800        \)
1801      }x
1802
1803 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1804 this yourself would be a productive exercise), but finishes in a fourth
1805 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1806 however, that, when this construct is followed by a
1807 quantifier, it currently triggers a warning message under
1808 the C<use warnings> pragma or B<-w> switch saying it
1809 C<"matches null string many times in regex">.
1810
1811 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1812 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1813 This was only 4 times slower on a string with 1000000 C<a>s.
1814
1815 The "grab all you can, and do not give anything back" semantic is desirable
1816 in many situations where on the first sight a simple C<()*> looks like
1817 the correct solution.  Suppose we parse text with comments being delimited
1818 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1819 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1820 the comment delimiter, because it may "give up" some whitespace if
1821 the remainder of the pattern can be made to match that way.  The correct
1822 answer is either one of these:
1823
1824     (?>#[ \t]*)
1825     #[ \t]*(?![ \t])
1826
1827 For example, to grab non-empty comments into $1, one should use either
1828 one of these:
1829
1830     / (?> \# [ \t]* ) (        .+ ) /x;
1831     /     \# [ \t]*   ( [^ \t] .* ) /x;
1832
1833 Which one you pick depends on which of these expressions better reflects
1834 the above specification of comments.
1835
1836 In some literature this construct is called "atomic matching" or
1837 "possessive matching".
1838
1839 Possessive quantifiers are equivalent to putting the item they are applied
1840 to inside of one of these constructs. The following equivalences apply:
1841
1842     Quantifier Form     Bracketing Form
1843     ---------------     ---------------
1844     PAT*+               (?>PAT*)
1845     PAT++               (?>PAT+)
1846     PAT?+               (?>PAT?)
1847     PAT{min,max}+       (?>PAT{min,max})
1848
1849 =item C<(?[ ])>
1850
1851 See L<perlrecharclass/Extended Bracketed Character Classes>.
1852
1853 =back
1854
1855 =head2 Special Backtracking Control Verbs
1856
1857 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1858 otherwise stated the ARG argument is optional; in some cases, it is
1859 mandatory.
1860
1861 Any pattern containing a special backtracking verb that allows an argument
1862 has the special behaviour that when executed it sets the current package's
1863 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1864 rules apply:
1865
1866 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1867 verb pattern, if the verb was involved in the failure of the match. If the
1868 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1869 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1870 none. Also, the C<$REGMARK> variable will be set to FALSE.
1871
1872 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1873 the C<$REGMARK> variable will be set to the name of the last
1874 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1875 C<(*MARK:NAME)> verb below for more details.
1876
1877 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1878 and most other regex-related variables. They are not local to a scope, nor
1879 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1880 Use C<local> to localize changes to them to a specific scope if necessary.
1881
1882 If a pattern does not contain a special backtracking verb that allows an
1883 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1884
1885 =over 3
1886
1887 =item Verbs
1888
1889 =over 4
1890
1891 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1892 X<(*PRUNE)> X<(*PRUNE:NAME)>
1893
1894 This zero-width pattern prunes the backtracking tree at the current point
1895 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1896 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1897 A may backtrack as necessary to match. Once it is reached, matching
1898 continues in B, which may also backtrack as necessary; however, should B
1899 not match, then no further backtracking will take place, and the pattern
1900 will fail outright at the current starting position.
1901
1902 The following example counts all the possible matching strings in a
1903 pattern (without actually matching any of them).
1904
1905     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1906     print "Count=$count\n";
1907
1908 which produces:
1909
1910     aaab
1911     aaa
1912     aa
1913     a
1914     aab
1915     aa
1916     a
1917     ab
1918     a
1919     Count=9
1920
1921 If we add a C<(*PRUNE)> before the count like the following
1922
1923     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1924     print "Count=$count\n";
1925
1926 we prevent backtracking and find the count of the longest matching string
1927 at each matching starting point like so:
1928
1929     aaab
1930     aab
1931     ab
1932     Count=3
1933
1934 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1935
1936 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1937 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1938 replaced with a C<< (?>pattern) >> with no functional difference; however,
1939 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1940 C<< (?>pattern) >> alone.
1941
1942 =item C<(*SKIP)> C<(*SKIP:NAME)>
1943 X<(*SKIP)>
1944
1945 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1946 failure it also signifies that whatever text that was matched leading up
1947 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1948 of this pattern. This effectively means that the regex engine "skips" forward
1949 to this position on failure and tries to match again, (assuming that
1950 there is sufficient room to match).
1951
1952 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1953 C<(*MARK:NAME)> was encountered while matching, then it is that position
1954 which is used as the "skip point". If no C<(*MARK)> of that name was
1955 encountered, then the C<(*SKIP)> operator has no effect. When used
1956 without a name the "skip point" is where the match point was when
1957 executing the (*SKIP) pattern.
1958
1959 Compare the following to the examples in C<(*PRUNE)>; note the string
1960 is twice as long:
1961
1962  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1963  print "Count=$count\n";
1964
1965 outputs
1966
1967     aaab
1968     aaab
1969     Count=2
1970
1971 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1972 executed, the next starting point will be where the cursor was when the
1973 C<(*SKIP)> was executed.
1974
1975 =item C<(*MARK:NAME)> C<(*:NAME)>
1976 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1977
1978 This zero-width pattern can be used to mark the point reached in a string
1979 when a certain part of the pattern has been successfully matched. This
1980 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1981 forward to that point if backtracked into on failure. Any number of
1982 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1983
1984 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1985 can be used to "label" a pattern branch, so that after matching, the
1986 program can determine which branches of the pattern were involved in the
1987 match.
1988
1989 When a match is successful, the C<$REGMARK> variable will be set to the
1990 name of the most recently executed C<(*MARK:NAME)> that was involved
1991 in the match.
1992
1993 This can be used to determine which branch of a pattern was matched
1994 without using a separate capture group for each branch, which in turn
1995 can result in a performance improvement, as perl cannot optimize
1996 C</(?:(x)|(y)|(z))/> as efficiently as something like
1997 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1998
1999 When a match has failed, and unless another verb has been involved in
2000 failing the match and has provided its own name to use, the C<$REGERROR>
2001 variable will be set to the name of the most recently executed
2002 C<(*MARK:NAME)>.
2003
2004 See L</(*SKIP)> for more details.
2005
2006 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
2007
2008 =item C<(*THEN)> C<(*THEN:NAME)>
2009
2010 This is similar to the "cut group" operator C<::> from Perl 6.  Like
2011 C<(*PRUNE)>, this verb always matches, and when backtracked into on
2012 failure, it causes the regex engine to try the next alternation in the
2013 innermost enclosing group (capturing or otherwise) that has alternations.
2014 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
2015 count as an alternation, as far as C<(*THEN)> is concerned.
2016
2017 Its name comes from the observation that this operation combined with the
2018 alternation operator (C<|>) can be used to create what is essentially a
2019 pattern-based if/then/else block:
2020
2021   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
2022
2023 Note that if this operator is used and NOT inside of an alternation then
2024 it acts exactly like the C<(*PRUNE)> operator.
2025
2026   / A (*PRUNE) B /
2027
2028 is the same as
2029
2030   / A (*THEN) B /
2031
2032 but
2033
2034   / ( A (*THEN) B | C ) /
2035
2036 is not the same as
2037
2038   / ( A (*PRUNE) B | C ) /
2039
2040 as after matching the A but failing on the B the C<(*THEN)> verb will
2041 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
2042
2043 =item C<(*COMMIT)> C<(*COMMIT:args)>
2044 X<(*COMMIT)>
2045
2046 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
2047 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
2048 into on failure it causes the match to fail outright. No further attempts
2049 to find a valid match by advancing the start pointer will occur again.
2050 For example,
2051
2052  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2053  print "Count=$count\n";
2054
2055 outputs
2056
2057     aaab
2058     Count=1
2059
2060 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
2061 does not match, the regex engine will not try any further matching on the
2062 rest of the string.
2063
2064 =item C<(*FAIL)> C<(*F)> C<(*FAIL:arg)>
2065 X<(*FAIL)> X<(*F)>
2066
2067 This pattern matches nothing and always fails. It can be used to force the
2068 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
2069 fact, C<(?!)> gets optimised into C<(*FAIL)> internally. You can provide
2070 an argument so that if the match fails because of this FAIL directive
2071 the argument can be obtained from $REGERROR.
2072
2073 It is probably useful only when combined with C<(?{})> or C<(??{})>.
2074
2075 =item C<(*ACCEPT)> C<(*ACCEPT:arg)>
2076 X<(*ACCEPT)>
2077
2078 This pattern matches nothing and causes the end of successful matching at
2079 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
2080 whether there is actually more to match in the string. When inside of a
2081 nested pattern, such as recursion, or in a subpattern dynamically generated
2082 via C<(??{})>, only the innermost pattern is ended immediately.
2083
2084 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
2085 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
2086 For instance:
2087
2088   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2089
2090 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
2091 be set. If another branch in the inner parentheses was matched, such as in the
2092 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
2093
2094 You can provide an argument, which will be available in the var $REGMARK
2095 after the match completes.
2096
2097 =back
2098
2099 =back
2100
2101 =head2 Backtracking
2102 X<backtrack> X<backtracking>
2103
2104 NOTE: This section presents an abstract approximation of regular
2105 expression behavior.  For a more rigorous (and complicated) view of
2106 the rules involved in selecting a match among possible alternatives,
2107 see L<Combining RE Pieces>.
2108
2109 A fundamental feature of regular expression matching involves the
2110 notion called I<backtracking>, which is currently used (when needed)
2111 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2112 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2113 internally, but the general principle outlined here is valid.
2114
2115 For a regular expression to match, the I<entire> regular expression must
2116 match, not just part of it.  So if the beginning of a pattern containing a
2117 quantifier succeeds in a way that causes later parts in the pattern to
2118 fail, the matching engine backs up and recalculates the beginning
2119 part--that's why it's called backtracking.
2120
2121 Here is an example of backtracking:  Let's say you want to find the
2122 word following "foo" in the string "Food is on the foo table.":
2123
2124     $_ = "Food is on the foo table.";
2125     if ( /\b(foo)\s+(\w+)/i ) {
2126         print "$2 follows $1.\n";
2127     }
2128
2129 When the match runs, the first part of the regular expression (C<\b(foo)>)
2130 finds a possible match right at the beginning of the string, and loads up
2131 $1 with "Foo".  However, as soon as the matching engine sees that there's
2132 no whitespace following the "Foo" that it had saved in $1, it realizes its
2133 mistake and starts over again one character after where it had the
2134 tentative match.  This time it goes all the way until the next occurrence
2135 of "foo". The complete regular expression matches this time, and you get
2136 the expected output of "table follows foo."
2137
2138 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2139 everything between "foo" and "bar".  Initially, you write something
2140 like this:
2141
2142     $_ =  "The food is under the bar in the barn.";
2143     if ( /foo(.*)bar/ ) {
2144         print "got <$1>\n";
2145     }
2146
2147 Which perhaps unexpectedly yields:
2148
2149   got <d is under the bar in the >
2150
2151 That's because C<.*> was greedy, so you get everything between the
2152 I<first> "foo" and the I<last> "bar".  Here it's more effective
2153 to use minimal matching to make sure you get the text between a "foo"
2154 and the first "bar" thereafter.
2155
2156     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2157   got <d is under the >
2158
2159 Here's another example. Let's say you'd like to match a number at the end
2160 of a string, and you also want to keep the preceding part of the match.
2161 So you write this:
2162
2163     $_ = "I have 2 numbers: 53147";
2164     if ( /(.*)(\d*)/ ) {                                # Wrong!
2165         print "Beginning is <$1>, number is <$2>.\n";
2166     }
2167
2168 That won't work at all, because C<.*> was greedy and gobbled up the
2169 whole string. As C<\d*> can match on an empty string the complete
2170 regular expression matched successfully.
2171
2172     Beginning is <I have 2 numbers: 53147>, number is <>.
2173
2174 Here are some variants, most of which don't work:
2175
2176     $_ = "I have 2 numbers: 53147";
2177     @pats = qw{
2178         (.*)(\d*)
2179         (.*)(\d+)
2180         (.*?)(\d*)
2181         (.*?)(\d+)
2182         (.*)(\d+)$
2183         (.*?)(\d+)$
2184         (.*)\b(\d+)$
2185         (.*\D)(\d+)$
2186     };
2187
2188     for $pat (@pats) {
2189         printf "%-12s ", $pat;
2190         if ( /$pat/ ) {
2191             print "<$1> <$2>\n";
2192         } else {
2193             print "FAIL\n";
2194         }
2195     }
2196
2197 That will print out:
2198
2199     (.*)(\d*)    <I have 2 numbers: 53147> <>
2200     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2201     (.*?)(\d*)   <> <>
2202     (.*?)(\d+)   <I have > <2>
2203     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2204     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2205     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2206     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2207
2208 As you see, this can be a bit tricky.  It's important to realize that a
2209 regular expression is merely a set of assertions that gives a definition
2210 of success.  There may be 0, 1, or several different ways that the
2211 definition might succeed against a particular string.  And if there are
2212 multiple ways it might succeed, you need to understand backtracking to
2213 know which variety of success you will achieve.
2214
2215 When using look-ahead assertions and negations, this can all get even
2216 trickier.  Imagine you'd like to find a sequence of non-digits not
2217 followed by "123".  You might try to write that as
2218
2219     $_ = "ABC123";
2220     if ( /^\D*(?!123)/ ) {                # Wrong!
2221         print "Yup, no 123 in $_\n";
2222     }
2223
2224 But that isn't going to match; at least, not the way you're hoping.  It
2225 claims that there is no 123 in the string.  Here's a clearer picture of
2226 why that pattern matches, contrary to popular expectations:
2227
2228     $x = 'ABC123';
2229     $y = 'ABC445';
2230
2231     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2232     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2233
2234     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2235     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2236
2237 This prints
2238
2239     2: got ABC
2240     3: got AB
2241     4: got ABC
2242
2243 You might have expected test 3 to fail because it seems to a more
2244 general purpose version of test 1.  The important difference between
2245 them is that test 3 contains a quantifier (C<\D*>) and so can use
2246 backtracking, whereas test 1 will not.  What's happening is
2247 that you've asked "Is it true that at the start of $x, following 0 or more
2248 non-digits, you have something that's not 123?"  If the pattern matcher had
2249 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2250 fail.
2251
2252 The search engine will initially match C<\D*> with "ABC".  Then it will
2253 try to match C<(?!123)> with "123", which fails.  But because
2254 a quantifier (C<\D*>) has been used in the regular expression, the
2255 search engine can backtrack and retry the match differently
2256 in the hope of matching the complete regular expression.
2257
2258 The pattern really, I<really> wants to succeed, so it uses the
2259 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2260 time.  Now there's indeed something following "AB" that is not
2261 "123".  It's "C123", which suffices.
2262
2263 We can deal with this by using both an assertion and a negation.
2264 We'll say that the first part in $1 must be followed both by a digit
2265 and by something that's not "123".  Remember that the look-aheads
2266 are zero-width expressions--they only look, but don't consume any
2267 of the string in their match.  So rewriting this way produces what
2268 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2269
2270     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2271     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2272
2273     6: got ABC
2274
2275 In other words, the two zero-width assertions next to each other work as though
2276 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2277 matches only if you're at the beginning of the line AND the end of the
2278 line simultaneously.  The deeper underlying truth is that juxtaposition in
2279 regular expressions always means AND, except when you write an explicit OR
2280 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2281 although the attempted matches are made at different positions because "a"
2282 is not a zero-width assertion, but a one-width assertion.
2283
2284 B<WARNING>: Particularly complicated regular expressions can take
2285 exponential time to solve because of the immense number of possible
2286 ways they can use backtracking to try for a match.  For example, without
2287 internal optimizations done by the regular expression engine, this will
2288 take a painfully long time to run:
2289
2290     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2291
2292 And if you used C<*>'s in the internal groups instead of limiting them
2293 to 0 through 5 matches, then it would take forever--or until you ran
2294 out of stack space.  Moreover, these internal optimizations are not
2295 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2296 on the external group, no current optimization is applicable, and the
2297 match takes a long time to finish.
2298
2299 A powerful tool for optimizing such beasts is what is known as an
2300 "independent group",
2301 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2302 zero-length look-ahead/look-behind assertions will not backtrack to make
2303 the tail match, since they are in "logical" context: only
2304 whether they match is considered relevant.  For an example
2305 where side-effects of look-ahead I<might> have influenced the
2306 following match, see L</C<< (?>pattern) >>>.
2307
2308 =head2 Version 8 Regular Expressions
2309 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2310
2311 In case you're not familiar with the "regular" Version 8 regex
2312 routines, here are the pattern-matching rules not described above.
2313
2314 Any single character matches itself, unless it is a I<metacharacter>
2315 with a special meaning described here or above.  You can cause
2316 characters that normally function as metacharacters to be interpreted
2317 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2318 character; "\\" matches a "\"). This escape mechanism is also required
2319 for the character used as the pattern delimiter.
2320
2321 A series of characters matches that series of characters in the target
2322 string, so the pattern C<blurfl> would match "blurfl" in the target
2323 string.
2324
2325 You can specify a character class, by enclosing a list of characters
2326 in C<[]>, which will match any character from the list.  If the
2327 first character after the "[" is "^", the class matches any character not
2328 in the list.  Within a list, the "-" character specifies a
2329 range, so that C<a-z> represents all characters between "a" and "z",
2330 inclusive.  If you want either "-" or "]" itself to be a member of a
2331 class, put it at the start of the list (possibly after a "^"), or
2332 escape it with a backslash.  "-" is also taken literally when it is
2333 at the end of the list, just before the closing "]".  (The
2334 following all specify the same class of three characters: C<[-az]>,
2335 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2336 specifies a class containing twenty-six characters, even on EBCDIC-based
2337 character sets.)  Also, if you try to use the character
2338 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2339 a range, the "-" is understood literally.
2340
2341 Note also that the whole range idea is rather unportable between
2342 character sets, except for four situations that Perl handles specially.
2343 Any subset of the ranges C<[A-Z]>, C<[a-z]>, and C<[0-9]> are guaranteed
2344 to match the expected subset of ASCII characters, no matter what
2345 character set the platform is running.  The fourth portable way to
2346 specify ranges is to use the C<\N{...}> syntax to specify either end
2347 point of the range.  For example, C<[\N{U+04}-\N{U+07}]> means to match
2348 the Unicode code points C<\N{U+04}>, C<\N{U+05}>, C<\N{U+06}>, and
2349 C<\N{U+07}>, whatever their native values may be on the platform.  Under
2350 L<use re 'strict'|re/'strict' mode> or within a L</C<(?[ ])>>, a warning
2351 is raised, if enabled, and the other end point of a range which has a
2352 C<\N{...}> endpoint is not portably specified.  For example,
2353
2354  [\N{U+00}-\x06]    # Warning under "use re 'strict'".
2355
2356 It is hard to understand without digging what exactly matches ranges
2357 other than subsets of C<[A-Z]>, C<[a-z]>, and C<[0-9]>.  A sound
2358 principle is to use only ranges that begin from and end at either
2359 alphabetics of equal case ([a-e], [A-E]), or digits ([0-9]).  Anything
2360 else is unsafe or unclear.  If in doubt, spell out the range in full.
2361
2362 Characters may be specified using a metacharacter syntax much like that
2363 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2364 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2365 of three octal digits, matches the character whose coded character set value
2366 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2367 matches the character whose ordinal is I<nn>. The expression \cI<x>
2368 matches the character control-I<x>.  Finally, the "." metacharacter
2369 matches any character except "\n" (unless you use C</s>).
2370
2371 You can specify a series of alternatives for a pattern using "|" to
2372 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2373 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2374 first alternative includes everything from the last pattern delimiter
2375 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2376 the last alternative contains everything from the last "|" to the next
2377 closing pattern delimiter.  That's why it's common practice to include
2378 alternatives in parentheses: to minimize confusion about where they
2379 start and end.
2380
2381 Alternatives are tried from left to right, so the first
2382 alternative found for which the entire expression matches, is the one that
2383 is chosen. This means that alternatives are not necessarily greedy. For
2384 example: when matching C<foo|foot> against "barefoot", only the "foo"
2385 part will match, as that is the first alternative tried, and it successfully
2386 matches the target string. (This might not seem important, but it is
2387 important when you are capturing matched text using parentheses.)
2388
2389 Also remember that "|" is interpreted as a literal within square brackets,
2390 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2391
2392 Within a pattern, you may designate subpatterns for later reference
2393 by enclosing them in parentheses, and you may refer back to the
2394 I<n>th subpattern later in the pattern using the metacharacter
2395 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2396 of their opening parenthesis.  A backreference matches whatever
2397 actually matched the subpattern in the string being examined, not
2398 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2399 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2400 1 matched "0x", even though the rule C<0|0x> could potentially match
2401 the leading 0 in the second number.
2402
2403 =head2 Warning on \1 Instead of $1
2404
2405 Some people get too used to writing things like:
2406
2407     $pattern =~ s/(\W)/\\\1/g;
2408
2409 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2410 shocking the
2411 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2412 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2413 the usual double-quoted string means a control-A.  The customary Unix
2414 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2415 of doing that, you get yourself into trouble if you then add an C</e>
2416 modifier.
2417
2418     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2419
2420 Or if you try to do
2421
2422     s/(\d+)/\1000/;
2423
2424 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2425 C<${1}000>.  The operation of interpolation should not be confused
2426 with the operation of matching a backreference.  Certainly they mean two
2427 different things on the I<left> side of the C<s///>.
2428
2429 =head2 Repeated Patterns Matching a Zero-length Substring
2430
2431 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2432
2433 Regular expressions provide a terse and powerful programming language.  As
2434 with most other power tools, power comes together with the ability
2435 to wreak havoc.
2436
2437 A common abuse of this power stems from the ability to make infinite
2438 loops using regular expressions, with something as innocuous as:
2439
2440     'foo' =~ m{ ( o? )* }x;
2441
2442 The C<o?> matches at the beginning of C<'foo'>, and since the position
2443 in the string is not moved by the match, C<o?> would match again and again
2444 because of the C<*> quantifier.  Another common way to create a similar cycle
2445 is with the looping modifier C<//g>:
2446
2447     @matches = ( 'foo' =~ m{ o? }xg );
2448
2449 or
2450
2451     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2452
2453 or the loop implied by split().
2454
2455 However, long experience has shown that many programming tasks may
2456 be significantly simplified by using repeated subexpressions that
2457 may match zero-length substrings.  Here's a simple example being:
2458
2459     @chars = split //, $string;           # // is not magic in split
2460     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2461
2462 Thus Perl allows such constructs, by I<forcefully breaking
2463 the infinite loop>.  The rules for this are different for lower-level
2464 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2465 ones like the C</g> modifier or split() operator.
2466
2467 The lower-level loops are I<interrupted> (that is, the loop is
2468 broken) when Perl detects that a repeated expression matched a
2469 zero-length substring.   Thus
2470
2471    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2472
2473 is made equivalent to
2474
2475    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2476
2477 For example, this program
2478
2479    #!perl -l
2480    "aaaaab" =~ /
2481      (?:
2482         a                 # non-zero
2483         |                 # or
2484        (?{print "hello"}) # print hello whenever this
2485                           #    branch is tried
2486        (?=(b))            # zero-width assertion
2487      )*  # any number of times
2488     /x;
2489    print $&;
2490    print $1;
2491
2492 prints
2493
2494    hello
2495    aaaaa
2496    b
2497
2498 Notice that "hello" is only printed once, as when Perl sees that the sixth
2499 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2500 the C<*>.
2501
2502 The higher-level loops preserve an additional state between iterations:
2503 whether the last match was zero-length.  To break the loop, the following
2504 match after a zero-length match is prohibited to have a length of zero.
2505 This prohibition interacts with backtracking (see L<"Backtracking">),
2506 and so the I<second best> match is chosen if the I<best> match is of
2507 zero length.
2508
2509 For example:
2510
2511     $_ = 'bar';
2512     s/\w??/<$&>/g;
2513
2514 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2515 match given by non-greedy C<??> is the zero-length match, and the I<second
2516 best> match is what is matched by C<\w>.  Thus zero-length matches
2517 alternate with one-character-long matches.
2518
2519 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2520 position one notch further in the string.
2521
2522 The additional state of being I<matched with zero-length> is associated with
2523 the matched string, and is reset by each assignment to pos().
2524 Zero-length matches at the end of the previous match are ignored
2525 during C<split>.
2526
2527 =head2 Combining RE Pieces
2528
2529 Each of the elementary pieces of regular expressions which were described
2530 before (such as C<ab> or C<\Z>) could match at most one substring
2531 at the given position of the input string.  However, in a typical regular
2532 expression these elementary pieces are combined into more complicated
2533 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2534 (in these examples C<S> and C<T> are regular subexpressions).
2535
2536 Such combinations can include alternatives, leading to a problem of choice:
2537 if we match a regular expression C<a|ab> against C<"abc">, will it match
2538 substring C<"a"> or C<"ab">?  One way to describe which substring is
2539 actually matched is the concept of backtracking (see L<"Backtracking">).
2540 However, this description is too low-level and makes you think
2541 in terms of a particular implementation.
2542
2543 Another description starts with notions of "better"/"worse".  All the
2544 substrings which may be matched by the given regular expression can be
2545 sorted from the "best" match to the "worst" match, and it is the "best"
2546 match which is chosen.  This substitutes the question of "what is chosen?"
2547 by the question of "which matches are better, and which are worse?".
2548
2549 Again, for elementary pieces there is no such question, since at most
2550 one match at a given position is possible.  This section describes the
2551 notion of better/worse for combining operators.  In the description
2552 below C<S> and C<T> are regular subexpressions.
2553
2554 =over 4
2555
2556 =item C<ST>
2557
2558 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2559 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2560 which can be matched by C<T>.
2561
2562 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2563 match than C<A'B'>.
2564
2565 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2566 C<B> is a better match for C<T> than C<B'>.
2567
2568 =item C<S|T>
2569
2570 When C<S> can match, it is a better match than when only C<T> can match.
2571
2572 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2573 two matches for C<T>.
2574
2575 =item C<S{REPEAT_COUNT}>
2576
2577 Matches as C<SSS...S> (repeated as many times as necessary).
2578
2579 =item C<S{min,max}>
2580
2581 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2582
2583 =item C<S{min,max}?>
2584
2585 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2586
2587 =item C<S?>, C<S*>, C<S+>
2588
2589 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2590
2591 =item C<S??>, C<S*?>, C<S+?>
2592
2593 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2594
2595 =item C<< (?>S) >>
2596
2597 Matches the best match for C<S> and only that.
2598
2599 =item C<(?=S)>, C<(?<=S)>
2600
2601 Only the best match for C<S> is considered.  (This is important only if
2602 C<S> has capturing parentheses, and backreferences are used somewhere
2603 else in the whole regular expression.)
2604
2605 =item C<(?!S)>, C<(?<!S)>
2606
2607 For this grouping operator there is no need to describe the ordering, since
2608 only whether or not C<S> can match is important.
2609
2610 =item C<(??{ EXPR })>, C<(?I<PARNO>)>
2611
2612 The ordering is the same as for the regular expression which is
2613 the result of EXPR, or the pattern contained by capture group I<PARNO>.
2614
2615 =item C<(?(condition)yes-pattern|no-pattern)>
2616
2617 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2618 already determined.  The ordering of the matches is the same as for the
2619 chosen subexpression.
2620
2621 =back
2622
2623 The above recipes describe the ordering of matches I<at a given position>.
2624 One more rule is needed to understand how a match is determined for the
2625 whole regular expression: a match at an earlier position is always better
2626 than a match at a later position.
2627
2628 =head2 Creating Custom RE Engines
2629
2630 As of Perl 5.10.0, one can create custom regular expression engines.  This
2631 is not for the faint of heart, as they have to plug in at the C level.  See
2632 L<perlreapi> for more details.
2633
2634 As an alternative, overloaded constants (see L<overload>) provide a simple
2635 way to extend the functionality of the RE engine, by substituting one
2636 pattern for another.
2637
2638 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2639 matches at a boundary between whitespace characters and non-whitespace
2640 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2641 at these positions, so we want to have each C<\Y|> in the place of the
2642 more complicated version.  We can create a module C<customre> to do
2643 this:
2644
2645     package customre;
2646     use overload;
2647
2648     sub import {
2649       shift;
2650       die "No argument to customre::import allowed" if @_;
2651       overload::constant 'qr' => \&convert;
2652     }
2653
2654     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2655
2656     # We must also take care of not escaping the legitimate \\Y|
2657     # sequence, hence the presence of '\\' in the conversion rules.
2658     my %rules = ( '\\' => '\\\\',
2659                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2660     sub convert {
2661       my $re = shift;
2662       $re =~ s{
2663                 \\ ( \\ | Y . )
2664               }
2665               { $rules{$1} or invalid($re,$1) }sgex;
2666       return $re;
2667     }
2668
2669 Now C<use customre> enables the new escape in constant regular
2670 expressions, i.e., those without any runtime variable interpolations.
2671 As documented in L<overload>, this conversion will work only over
2672 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2673 part of this regular expression needs to be converted explicitly
2674 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2675
2676     use customre;
2677     $re = <>;
2678     chomp $re;
2679     $re = customre::convert $re;
2680     /\Y|$re\Y|/;
2681
2682 =head2 Embedded Code Execution Frequency
2683
2684 The exact rules for how often (??{}) and (?{}) are executed in a pattern
2685 are unspecified.  In the case of a successful match you can assume that
2686 they DWIM and will be executed in left to right order the appropriate
2687 number of times in the accepting path of the pattern as would any other
2688 meta-pattern.  How non-accepting pathways and match failures affect the
2689 number of times a pattern is executed is specifically unspecified and
2690 may vary depending on what optimizations can be applied to the pattern
2691 and is likely to change from version to version.
2692
2693 For instance in
2694
2695   "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
2696
2697 the exact number of times "a" or "b" are printed out is unspecified for
2698 failure, but you may assume they will be printed at least once during
2699 a successful match, additionally you may assume that if "b" is printed,
2700 it will be preceded by at least one "a".
2701
2702 In the case of branching constructs like the following:
2703
2704   /a(b|(?{ print "a" }))c(?{ print "c" })/;
2705
2706 you can assume that the input "ac" will output "ac", and that "abc"
2707 will output only "c".
2708
2709 When embedded code is quantified, successful matches will call the
2710 code once for each matched iteration of the quantifier.  For
2711 example:
2712
2713   "good" =~ /g(?:o(?{print "o"}))*d/;
2714
2715 will output "o" twice.
2716
2717 =head2 PCRE/Python Support
2718
2719 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2720 to the regex syntax. While Perl programmers are encouraged to use the
2721 Perl-specific syntax, the following are also accepted:
2722
2723 =over 4
2724
2725 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2726
2727 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2728
2729 =item C<< (?P=NAME) >>
2730
2731 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2732
2733 =item C<< (?P>NAME) >>
2734
2735 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2736
2737 =back
2738
2739 =head1 BUGS
2740
2741 Many regular expression constructs don't work on EBCDIC platforms.
2742
2743 There are a number of issues with regard to case-insensitive matching
2744 in Unicode rules.  See C<i> under L</Modifiers> above.
2745
2746 This document varies from difficult to understand to completely
2747 and utterly opaque.  The wandering prose riddled with jargon is
2748 hard to fathom in several places.
2749
2750 This document needs a rewrite that separates the tutorial content
2751 from the reference content.
2752
2753 =head1 SEE ALSO
2754
2755 L<perlrequick>.
2756
2757 L<perlretut>.
2758
2759 L<perlop/"Regexp Quote-Like Operators">.
2760
2761 L<perlop/"Gory details of parsing quoted constructs">.
2762
2763 L<perlfaq6>.
2764
2765 L<perlfunc/pos>.
2766
2767 L<perllocale>.
2768
2769 L<perlebcdic>.
2770
2771 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2772 by O'Reilly and Associates.