installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '../lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 BEGIN {
  11     use Config;
  12     if ($Config{userelocatableinc}) {
  13         # This might be a considered a hack. Need to get information about the
  14         # configuration from Config.pm *before* Config.pm expands any .../
  15         # prefixes.
  16         #
  17         # So we set $^X to pretend that we're the already installed perl, so
  18         # Config.pm doesits ... expansion off that location.
  19
  20         my $location = $Config{initialinstalllocation};
  21         die <<'OS' unless defined $location;
  22 $Config{initialinstalllocation} is not defined - can't install a relocatable
  23 perl without this.
  24 OS
  25         $^X = "$location/perl";
  26         # And then remove all trace of ever having loaded Config.pm, so that
  27         # it will reload with the revised $^X
  28         undef %Config::;
  29         delete $INC{"Config.pm"};
  30         delete $INC{"Config_heavy.pl"};
  31         # You never saw us. We weren't here.
  32     }
  33 }
  34
  35 use strict;
  36 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  37     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
  38     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
  39 use vars qw /$depth/;
  40
  41 BEGIN {
  42     $Is_VMS = $^O eq 'VMS';
  43     $Is_W32 = $^O eq 'MSWin32';
  44     $Is_OS2 = $^O eq 'os2';
  45     $Is_Cygwin = $^O eq 'cygwin';
  46     $Is_Darwin = $^O eq 'darwin';
  47     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  48 }
  49
  50 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  51
  52 use File::Find;
  53 use File::Compare;
  54 use File::Copy ();
  55 use File::Path ();
  56 use ExtUtils::Packlist;
  57 use Config;
  58 use subs qw(unlink link chmod);
  59
  60 if ($Config{d_umask}) {
  61     umask(022); # umasks like 077 aren't that useful for installations
  62 }
  63
  64 $Is_NetWare = $Config{osname} eq 'NetWare';
  65 if ($Is_NetWare) {
  66     $Is_W32 = 0;
  67     $scr_ext = '.pl';
  68 }
  69
  70 # override the ones in the rest of the script
  71 sub mkpath {
  72     File::Path::mkpath(@_) unless $nonono;
  73 }
  74
  75 my $mainperldir = "/usr/bin";
  76 my $exe_ext = $Config{exe_ext};
  77
  78 # Allow ``make install PERLNAME=something_besides_perl'':
  79 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  80
  81 # This is the base used for versioned names, like "perl5.6.0".
  82 # It's separate because a common use of $PERLNAME is to install
  83 # perl as "perl5", if that's used as base for versioned files you
  84 # get "perl55.6.0".
  85 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  86                     ? $ENV{PERLNAME_VERBASE}
  87                     : $perl;
  88 my $dbg = '';
  89 my $ndbg = '';
  90 if ( $Is_VMS ) {
  91     if ( defined $Config{usevmsdebug} ) {
  92         if ( $Config{usevmsdebug} eq 'define' ) {
  93             $dbg = 'dbg';
  94             $ndbg = 'ndbg';
  95         }
  96     }
  97 }
  98
  99 $otherperls = 1;
 100 my $destdir = '';
 101 while (@ARGV) {
 102     $nonono = 1 if $ARGV[0] eq '-n';
 103     $dostrip = 1 if $ARGV[0] eq '-s';
 104     $versiononly = 1 if $ARGV[0] eq '-v';
 105     $versiononly = 0 if $ARGV[0] eq '+v';
 106     $silent = 1 if $ARGV[0] eq '-S';
 107     $otherperls = 0 if $ARGV[0] eq '-o';
 108     $force = 1 if $ARGV[0] eq '-f';
 109     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
 110     $archname = 1 if $ARGV[0] eq '-A';
 111     $nwinstall = 1 if $ARGV[0] eq '-netware';
 112     $nopods = 1 if $ARGV[0] eq '-p';
 113     $destdir = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
 114     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
 115         print <<"EOT";
 116 Usage $0: [switches]
 117   -n        Don't actually run any commands; just print them.
 118   -s        Run strip on installed binaries.
 119   -v        Only install perl as a binary with the version number in the name.
 120             (Override whatever config.sh says)
 121   +v        Install perl as "perl" and as a binary with the version number in
 122             the name.  (Override whatever config.sh says)
 123   -S        Silent mode.
 124   -f        Force installation (don't check if same version is there)
 125   -o        Skip checking for other copies of perl in your PATH.
 126   -V        Verbose mode.
 127   -A        Also install perl with the architecture's name in the perl binary's
 128             name.
 129   -p        Don't install the pod files. [This will break use diagnostics;]
 130   -netware  Install correctly on a Netware server.
 131   -destdir  Prefix installation directories by this string.
 132 EOT
 133         exit;
 134     }
 135     shift;
 136 }
 137
 138 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 139 my (@scripts, @tolink);
 140 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 141 while (<SCRIPTS>) {
 142     next if /^#/;
 143     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 144     next if /a2p/; # a2p is binary, to be installed separately
 145     chomp;
 146     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 147         push @scripts, $1;
 148         push @tolink, [$1, $2];
 149     } else {
 150         push @scripts, $_;
 151     }
 152 }
 153 close SCRIPTS;
 154
 155 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 156
 157 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
 158
 159 # Specify here any .pm files that are actually architecture-dependent.
 160 # (Those included with XS extensions under ext/ are automatically
 161 # added later.)
 162 # Now that the default privlib has the full perl version number included,
 163 # we no longer have to play the trick of sticking version-specific .pm
 164 # files under the archlib directory.
 165 my %archpms = (
 166     Config => 1,
 167     lib => 1,
 168     Cwd => 1,
 169 );
 170
 171 if ($^O eq 'dos') {
 172     push(@scripts,'djgpp/fixpmain');
 173     $archpms{config} = $archpms{filehand} = 1;
 174 }
 175
 176 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 177     push(@scripts, map("$_.exe", @scripts));
 178 }
 179
 180 find(sub {
 181     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 182         my($path, $modname) = ($1,$2);
 183
 184         # strip trailing component first
 185         $path =~ s{/[^/]*$}{};
 186
 187         # strip optional "/lib";
 188         $path =~ s{/lib\b}{};
 189
 190         # strip any leading /
 191         $path =~ s{^/}{};
 192
 193         # reconstitute canonical module name
 194         $modname = "$path/$modname" if length $path;
 195
 196         # remember it
 197         $archpms{$modname} = 1;
 198     }
 199 }, 'ext');
 200
 201 # print "[$_]\n" for sort keys %archpms;
 202
 203 my $ver = $Config{version};
 204 my $release = substr($],0,3);   # Not used currently.
 205 my $patchlevel = substr($],3,2);
 206 die "Patchlevel of perl ($patchlevel)",
 207     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 208         if $patchlevel != $Config{'PERL_VERSION'};
 209
 210 # Fetch some frequently-used items from %Config
 211 my $installbin = "$destdir$Config{installbin}";
 212 my $installscript = "$destdir$Config{installscript}";
 213 my $installprivlib = "$destdir$Config{installprivlib}";
 214 my $installarchlib = "$destdir$Config{installarchlib}";
 215 my $installsitelib = "$destdir$Config{installsitelib}";
 216 my $installsitearch = "$destdir$Config{installsitearch}";
 217 my $installman1dir = "$destdir$Config{installman1dir}";
 218 my $man1ext = $Config{man1ext};
 219 my $libperl = $Config{libperl};
 220 # Shared library and dynamic loading suffixes.
 221 my $so = $Config{so};
 222 my $dlext = $Config{dlext};
 223 my $dlsrc = $Config{dlsrc};
 224 if ($^O eq 'os390') {
 225     my $pwd;
 226     chomp($pwd=`pwd`);
 227     my $archlibexp = $Config{archlibexp};
 228     my $usedl = $Config{usedl};
 229     if ($usedl eq 'define') {
 230         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 231     }
 232 }
 233
 234 if ($nwinstall) {
 235     # This is required only if we are installing on a NetWare server
 236     $installscript = $Config{installnwscripts};
 237     $installprivlib = $Config{installnwlib};
 238     $installarchlib = $Config{installnwlib};
 239     $installsitelib = $Config{installnwlib};
 240 }
 241
 242 my $d_dosuid = $Config{d_dosuid};
 243 my $binexp = $Config{binexp};
 244
 245 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 246     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 247               \$installarchlib, \$installsitelib, \$installsitearch,
 248               \$installman1dir ) {
 249         $$_ = unixify($$_);  $$_ =~ s:/$::;
 250     }
 251 }
 252
 253 # Do some quick sanity checks.
 254
 255 if (!$nonono && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 256
 257    $installbin          || die "No installbin directory in config.sh\n";
 258 -d $installbin          || mkpath($installbin, $verbose, 0777);
 259 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 260 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 261         unless $installbin =~ m#^/afs/# || $nonono;
 262
 263 if (!$Is_NetWare) {
 264 if (!$Is_VMS) {
 265 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 266 }
 267 else {
 268 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 269     if ($dbg) {
 270         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 271     }
 272 }
 273 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 274
 275 -f 't/rantests'         || $Is_W32
 276                         || warn "WARNING: You've never run 'make test' or",
 277                                 " some tests failed! (Installing anyway.)\n";
 278 } #if (!$Is_NetWare)
 279
 280 # This will be used to store the packlist
 281 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 282
 283 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 284     my $perldll;
 285
 286     if ($Is_Cygwin) {
 287         $perldll = $libperl;
 288         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 289         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 290         $perldll =~ s/^lib/cyg/;
 291         if ($Config{useshrplib} eq 'true') {
 292             # install ld2 and perlld as well
 293             foreach ('ld2', 'perlld') {
 294                 safe_unlink("$installbin/$_");
 295                 copy("$_", "$installbin/$_");
 296                 chmod(0755, "$installbin/$_");
 297                 $packlist->{"$installbin/$_"} = { type => 'file' };
 298             };
 299             open (LD2, ">$installbin/ld2");
 300             print LD2 <<SHELL;
 301 #!/bin/sh
 302 #
 303 # ld wrapper, passes all args to perlld;
 304 #
 305 for trythis in $installbin/perl
 306 do
 307   if [ -x \$trythis ]
 308   then
 309     \$trythis $installbin/perlld "\$\@"
 310     exit \$?
 311   fi
 312 done
 313 # hard luck!
 314 echo I see no perl executable around there
 315 echo perl is required to build dynamic libraries
 316 echo look if the path to perl in /bin/ld2 is correct
 317 exit 1
 318 SHELL
 319             close LD2;
 320             chmod(0755, "$installbin/ld2");
 321         };
 322     } else {
 323         $perldll = 'perl59.' . $dlext;
 324     }
 325
 326     if ($dlsrc ne "dl_none.xs") {
 327         -f $perldll || die "No perl DLL built\n";
 328     }
 329
 330     # Install the DLL
 331     safe_unlink("$installbin/$perldll");
 332     copy("$perldll", "$installbin/$perldll");
 333     chmod(0755, "$installbin/$perldll");
 334     $packlist->{"$installbin/$perldll"} = { type => 'file' };
 335 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 336
 337 # First we install the version-numbered executables.
 338
 339 if ($Is_VMS) {
 340     safe_unlink("$installbin/perl_setup.com");
 341     copy("perl_setup.com", "$installbin/perl_setup.com");
 342     chmod(0755, "$installbin/perl_setup.com");
 343     safe_unlink("$installbin/$dbg$perl$exe_ext");
 344     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 345     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 346     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 347     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 348     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 349     if ($ndbg) {
 350         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 351         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 352         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 353         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 354         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 355         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 356     }
 357 }
 358 elsif ($^O eq 'mpeix') {
 359     # MPE lacks hard links and requires that executables with special
 360     # capabilities reside in the MPE namespace.
 361     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 362     # Install the primary executable into the MPE namespace as perlpath.
 363     copy("perl$exe_ext", $Config{perlpath});
 364     chmod(0755, $Config{perlpath});
 365     # Create a backup copy with the version number.
 366     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 367 }
 368 elsif ($^O ne 'dos') {
 369     if (!$Is_NetWare) {
 370         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 371         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 372         strip("$installbin/$perl_verbase$ver$exe_ext");
 373         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 374     }
 375     else {
 376         # If installing onto a NetWare server
 377         if ($nwinstall) {
 378             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 379             mkpath($Config{installnwsystem}, 1, 0777);
 380             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 381             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 382             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 383             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 384             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 385             mkpath($Config{installnwlcgi}, 1, 0777);
 386             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 387         }
 388     } #if (!$Is_NetWare)
 389 }
 390 else {
 391     safe_unlink("$installbin/$perl.exe");
 392     copy("perl.exe", "$installbin/$perl.exe");
 393 }
 394
 395 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 396 if ($d_dosuid) {
 397     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 398     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 399 }
 400
 401 # Install library files.
 402
 403 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 404
 405 mkpath($installprivlib, $verbose, 0777);
 406 mkpath($installarchlib, $verbose, 0777);
 407 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 408 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 409
 410 if (chdir "lib") {
 411     $do_installarchlib = ! samepath($installarchlib, '.');
 412     $do_installprivlib = ! samepath($installprivlib, '.');
 413     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 414
 415     if ($do_installarchlib || $do_installprivlib) {
 416         find(\&installlib, '.');
 417     }
 418     chdir ".." || die "Can't cd back to source directory: $!\n";
 419 }
 420 else {
 421     warn "Can't cd to lib to install lib files: $!\n";
 422 }
 423
 424 # Install header files and libraries.
 425 mkpath("$installarchlib/CORE", $verbose, 0777);
 426 my @corefiles;
 427 if ($Is_VMS) {  # We did core file selection during build
 428     my $coredir = "lib/$Config{archname}/$ver/CORE";
 429     $coredir =~ tr/./_/;
 430     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 431 }
 432 else {
 433     # [als] hard-coded 'libperl' name... not good!
 434     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 435
 436     # AIX needs perl.exp installed as well.
 437     push(@corefiles,'perl.exp') if $^O eq 'aix';
 438     if ($^O eq 'mpeix') {
 439         # MPE needs mpeixish.h installed as well.
 440         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 441         push(@corefiles,'mpeix/mpeixish.h');
 442     }
 443     # If they have built sperl.o...
 444     push(@corefiles,'sperl.o') if -f 'sperl.o';
 445 }
 446 foreach my $file (@corefiles) {
 447     # HP-UX (at least) needs to maintain execute permissions
 448     # on dynamically-loadable libraries. So we do it for all.
 449     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 450         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 451             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 452             chmod(0555, "$installarchlib/CORE/$file");
 453         } else {
 454             chmod(0444, "$installarchlib/CORE/$file");
 455         }
 456     }
 457 }
 458
 459 # Install main perl executables
 460 # Make links to ordinary names if installbin directory isn't current directory.
 461
 462 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 463     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 464     if ($^O eq 'mpeix') {
 465         # MPE doesn't support hard links, so use a symlink.
 466         # We don't want another cloned copy.
 467         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 468     } elsif ($^O eq 'vos') {
 469         # VOS doesn't support hard links, so use a symlink.
 470         symlink("$installbin/$perl_verbase$ver$exe_ext",
 471                 "$installbin/$perl$exe_ext");
 472     } else {
 473         link("$installbin/$perl_verbase$ver$exe_ext",
 474                 "$installbin/$perl$exe_ext");
 475     }
 476     link("$installbin/$perl_verbase$ver$exe_ext",
 477             "$installbin/suid$perl$exe_ext")
 478       if $d_dosuid;
 479 }
 480
 481 # For development purposes it can be very useful to have multiple perls
 482 # build for different "architectures" (eg threading or not) simultaneously.
 483 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 484     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 485     safe_unlink("$installbin/$archperl");
 486     if ($^O eq 'mpeix') {
 487         # MPE doesn't support hard links, so use a symlink.
 488         # We don't want another cloned copy.
 489         symlink($Config{perlpath}, "$installbin/$archperl");
 490     } elsif ($^O eq 'vos') {
 491         # VOS doesn't support hard links, so use a symlink.
 492         symlink("$installbin/$perl_verbase$ver$exe_ext",
 493                 "$installbin/$archperl");
 494     } else {
 495         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 496     }
 497 }
 498
 499 # Offer to install perl in a "standard" location
 500
 501 my $mainperl_is_instperl = 0;
 502
 503 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 504     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 505         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 506     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 507     my($instperl)       = "$installbin/$perl$exe_ext";
 508     my($expinstperl)    = "$binexp/$perl$exe_ext";
 509
 510     # First make sure $usrbinperl is not already the same as the perl we
 511     # just installed.
 512     if (-x $usrbinperl) {
 513         # Try to be clever about mainperl being a symbolic link
 514         # to binexp/perl if binexp and installbin are different.
 515         $mainperl_is_instperl =
 516             samepath($usrbinperl, $instperl) ||
 517             samepath($usrbinperl, $expinstperl) ||
 518              (($binexp ne $installbin) &&
 519               (-l $usrbinperl) &&
 520               ((readlink $usrbinperl) eq $expinstperl));
 521     }
 522     if (! $mainperl_is_instperl) {
 523         unlink($usrbinperl);
 524         ( $Config{'d_link'} eq 'define' &&
 525           eval { CORE::link $instperl, $usrbinperl } )  ||
 526         eval { symlink $expinstperl, $usrbinperl }      ||
 527         copy($instperl, $usrbinperl);
 528
 529         $mainperl_is_instperl = 1;
 530     }
 531 }
 532
 533 # Make links to ordinary names if installbin directory isn't current directory.
 534 if (!$Is_NetWare && $dbg eq '') {
 535     if (! samepath($installbin, 'x2p')) {
 536         my $base = 'a2p';
 537         $base .= $ver if $versiononly;
 538         safe_unlink("$installbin/$base$exe_ext");
 539         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 540         strip("$installbin/$base$exe_ext");
 541         chmod(0755, "$installbin/$base$exe_ext");
 542     }
 543 }
 544
 545 # cppstdin is just a script, but it is architecture-dependent, so
 546 # it can't safely be shared.  Place it in $installbin.
 547 # Note that Configure doesn't build cppstin if it isn't needed, so
 548 # we skip this if cppstdin doesn't exist.
 549 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 550     safe_unlink("$installbin/cppstdin");
 551     copy("cppstdin", "$installbin/cppstdin");
 552     chmod(0755, "$installbin/cppstdin");
 553 }
 554
 555 sub script_alias {
 556     my ($installscript, $orig, $alias, $scr_ext) = @_;
 557
 558     safe_unlink("$installscript/$alias$scr_ext");
 559     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 560         copy("$installscript/$orig$scr_ext",
 561              "$installscript/$alias$scr_ext");
 562     } elsif ($^O eq 'vos') {
 563         symlink("$installscript/$orig$scr_ext",
 564                 "$installscript/$alias$scr_ext");
 565     } else {
 566         link("$installscript/$orig$scr_ext",
 567              "$installscript/$alias$scr_ext");
 568     }
 569 }
 570
 571 # Install scripts.
 572 mkpath($installscript, $verbose, 0777);
 573 if ($versiononly) {
 574     for (@scripts) {
 575         (my $base = $_) =~ s#.*/##;
 576         $base .= $ver;
 577         copy($_,    "$installscript/$base");
 578         chmod(0755, "$installscript/$base");
 579     }
 580
 581     for (@tolink) {
 582         my ($from, $to) = map { "$_$ver" } @$_;
 583         (my $frbase = $from) =~ s#.*/##;
 584         (my $tobase = $to) =~ s#.*/##;
 585         script_alias($installscript, $frbase, $tobase, $scr_ext);
 586     }
 587 } else {
 588     for (@scripts) {
 589         (my $base = $_) =~ s#.*/##;
 590         copy($_, "$installscript/$base");
 591         chmod(0755, "$installscript/$base");
 592     }
 593
 594     for (@tolink) {
 595         my ($from, $to) = @$_;
 596         (my $frbase = $from) =~ s#.*/##;
 597         (my $tobase = $to) =~ s#.*/##;
 598         script_alias($installscript, $frbase, $tobase, $scr_ext);
 599     }
 600 }
 601
 602 # Install pod pages.  Where? I guess in $installprivlib/pod
 603 # ($installprivlib/pods for cygwin).
 604
 605 my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
 606 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 607     mkpath("${installprivlib}/$pod", $verbose, 0777);
 608
 609     # If Perl 5.003's perldiag.pod is there, rename it.
 610     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 611         read POD, $_, 4000;
 612         close POD;
 613         # Some of Perl 5.003's diagnostic messages ended with periods.
 614         if (/^=.*\.$/m) {
 615             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 616                                "${installprivlib}/$pod/perldiag-5.003.pod");
 617             print "  rename $from $to";
 618             rename($from, $to)
 619                 or warn "Couldn't rename $from to $to: $!\n"
 620                 unless $nonono;
 621         }
 622     }
 623
 624     for (@pods) {
 625         # $_ is a name like  pod/perl.pod
 626         (my $base = $_) =~ s#.*/##;
 627         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 628     }
 629
 630 }
 631
 632 # Check to make sure there aren't other perls around in installer's
 633 # path.  This is probably UNIX-specific.  Check all absolute directories
 634 # in the path except for where public executables are supposed to live.
 635 # Also skip $mainperl if the user opted to have it be a link to the
 636 # installed perl.
 637
 638 if (!$versiononly && $otherperls) {
 639     my ($path, @path);
 640     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 641     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 642     @path = split(/$dirsep/, $path);
 643     if ($Is_VMS) {
 644         my $i = 0;
 645         while (exists $ENV{'DCL$PATH' . $i}) {
 646             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 647             push(@path,$dir);
 648         }
 649     }
 650     my @otherperls;
 651     my %otherperls;
 652     for (@path) {
 653         next unless m,^/,;
 654         # Use &samepath here because some systems have other dirs linked
 655         # to $mainperldir (like SunOS)
 656         next if samepath($_, $binexp);
 657         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 658         my $otherperl = "$_/$perl$exe_ext";
 659         next if $otherperls{$otherperl}++;
 660         push(@otherperls, $otherperl)
 661             if (-x $otherperl && ! -d $otherperl);
 662     }
 663     if (@otherperls) {
 664         warn "\nWarning: $perl appears in your path in the following " .
 665             "locations beyond where\nwe just installed it:\n";
 666         for (@otherperls) {
 667             warn "    ", $_, "\n";
 668         }
 669         warn "\n";
 670     }
 671
 672 }
 673
 674 $packlist->write() unless $nonono;
 675 print "  Installation complete\n" if $verbose;
 676
 677 exit 0;
 678
 679 ###############################################################################
 680
 681 sub yn {
 682     my($prompt) = @_;
 683     my($answer);
 684     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 685     print STDERR $prompt;
 686     chop($answer = <STDIN>);
 687     $answer = $default if $answer =~ m/^\s*$/;
 688     ($answer =~ m/^[yY]/);
 689 }
 690
 691 sub unlink {
 692     my(@names) = @_;
 693     my($cnt) = 0;
 694
 695     return scalar(@names) if $Is_VMS;
 696
 697     foreach my $name (@names) {
 698         next unless -e $name;
 699         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 700         print "  unlink $name\n" if $verbose;
 701         ( CORE::unlink($name) and ++$cnt
 702           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 703     }
 704     return $cnt;
 705 }
 706
 707 sub safe_unlink {
 708     return if $nonono or $Is_VMS;
 709     my @names = @_;
 710     foreach my $name (@names) {
 711         next unless -e $name;
 712         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 713         print "  unlink $name\n" if $verbose;
 714         next if CORE::unlink($name);
 715         warn "Couldn't unlink $name: $!\n";
 716         if ($! =~ /busy/i) {
 717             print "  mv $name $name.old\n" if $verbose;
 718             safe_rename($name, "$name.old")
 719                 or warn "Couldn't rename $name: $!\n";
 720         }
 721     }
 722 }
 723
 724 sub safe_rename {
 725     my($from,$to) = @_;
 726     if (-f $to and not unlink($to)) {
 727         my($i);
 728         for ($i = 1; $i < 50; $i++) {
 729             last if rename($to, "$to.$i");
 730         }
 731         warn("Cannot rename to `$to.$i': $!"), return 0
 732            if $i >= 50; # Give up!
 733     }
 734     link($from,$to) || return 0;
 735     unlink($from);
 736 }
 737
 738 sub link {
 739     my($from,$to) = @_;
 740     my($success) = 0;
 741
 742     my $xfrom = $from;
 743     $xfrom =~ s/^\Q$destdir\E// if $destdir;
 744     my $xto = $to;
 745     $xto =~ s/^\Q$destdir\E// if $destdir;
 746     print $verbose ? "  ln $xfrom $xto\n" : "  $xto\n" unless $silent;
 747     eval {
 748         CORE::link($from, $to)
 749             ? $success++
 750             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 751               ? die "AFS"  # okay inside eval {}
 752               : die "Couldn't link $from to $to: $!\n"
 753           unless $nonono;
 754         $packlist->{$xto} = { from => $xfrom, type => 'link' };
 755     };
 756     if ($@) {
 757         warn "Replacing link() with File::Copy::copy(): $@";
 758         print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 759         print "  creating new version of $xto\n"
 760                  if $Is_VMS and -e $to and !$silent;
 761         unless ($nonono or File::Copy::copy($from, $to) and ++$success) {
 762             # Might have been that F::C::c can't overwrite the target
 763             warn "Couldn't copy $from to $to: $!\n"
 764                 unless -f $to and (chmod(0666, $to), unlink $to)
 765                         and File::Copy::copy($from, $to) and ++$success;
 766         }
 767         $packlist->{$xto} = { type => 'file' };
 768     }
 769     $success;
 770 }
 771
 772 sub chmod {
 773     my($mode,$name) = @_;
 774
 775     return if ($^O eq 'dos');
 776     printf "  chmod %o %s\n", $mode, $name if $verbose;
 777     CORE::chmod($mode,$name)
 778         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 779       unless $nonono;
 780 }
 781
 782 sub copy {
 783     my($from,$to) = @_;
 784
 785     my $xto = $to;
 786     $xto =~ s/^\Q$destdir\E// if $destdir;
 787     print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 788     print "  creating new version of $xto\n" if $Is_VMS and -e $to and !$silent;
 789     unless ($nonono or File::Copy::copy($from, $to)) {
 790         # Might have been that F::C::c can't overwrite the target
 791         warn "Couldn't copy $from to $to: $!\n"
 792             unless -f $to and (chmod(0666, $to), unlink $to)
 793                    and File::Copy::copy($from, $to);
 794     }
 795     $packlist->{$xto} = { type => 'file' };
 796 }
 797
 798 sub samepath {
 799     my($p1, $p2) = @_;
 800
 801     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 802
 803     if ($p1 ne $p2) {
 804         my($dev1, $ino1, $dev2, $ino2);
 805         ($dev1, $ino1) = stat($p1);
 806         ($dev2, $ino2) = stat($p2);
 807         ($dev1 == $dev2 && $ino1 == $ino2);
 808     }
 809     else {
 810         1;
 811     }
 812 }
 813
 814 sub installlib {
 815     my $dir = $File::Find::dir;
 816     $dir =~ s#^\.(?![^/])/?##;
 817     local($depth) = $dir ? "lib/$dir" : "lib";
 818
 819     my $name = $_;
 820
 821     # Ignore version control directories.
 822     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
 823         $File::Find::prune = 1;
 824         return;
 825     }
 826
 827     # ignore patch backups, RCS files, emacs backup & temp files and the
 828     # .exists files, .PL files, and test files.
 829     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$} ||
 830               $dir  =~ m{/t(?:/|$)};
 831     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
 832     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
 833     # the corelist script from lib/Module/CoreList/bin and ptar* in
 834     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
 835     # (they're installed later with other utils)
 836     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|ptardiff|config_data)\z/;
 837     # ignore the Makefiles
 838     return if $name =~ /^makefile$/i;
 839     # ignore the test extensions
 840     return if $dir =~ m{ext/XS/(?:APItest|Typemap)/};
 841     # ignore the demo files
 842     return if $dir =~ /\bdemos?\b/;
 843
 844     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
 845     # Changes.e2x and README.e2x are needed by enc2xs.
 846     return if $name =~ m{^(?:README(?:\.\w+)?|MANIFEST|META\.yml|INSTALL)$} && $name ne 'README.e2x';
 847     return if $name =~ m{^(?:TODO|BUGS|CREDITS)$}i;
 848     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
 849
 850     $name = "$dir/$name" if $dir ne '';
 851
 852     my $installlib = $installprivlib;
 853     if ($dir =~ /^auto/ ||
 854           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 855           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
 856           $name eq 'Config_heavy.pl'
 857        ) {
 858         $installlib = $installarchlib;
 859         return unless $do_installarchlib;
 860     } else {
 861         return unless $do_installprivlib;
 862     }
 863
 864     if (-f $_) {
 865         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 866             $installlib = $installprivlib;
 867             #We're installing *.al and *.ix files into $installprivlib,
 868             #but we have to delete old *.al and *.ix files from the 5.000
 869             #distribution:
 870             #This might not work because $archname might have changed.
 871             unlink("$installarchlib/$name");
 872         }
 873         my $xname = "$installlib/$name";
 874         $xname =~ s/^\Q$destdir\E// if $destdir;
 875         $packlist->{$xname} = { type => 'file' };
 876         if ($force || compare($_, "$installlib/$name") || $nonono) {
 877             unlink("$installlib/$name");
 878             mkpath("$installlib/$dir", $verbose, 0777);
 879             # HP-UX (at least) needs to maintain execute permissions
 880             # on dynamically-loaded libraries.
 881             if ($Is_NetWare && !$nwinstall) {
 882                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 883                 # if copied will give problems when building new extensions.
 884                 # Has to be copied if we are installing on a NetWare server and hence
 885                 # the check !$nwinstall
 886                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 887                     copy_if_diff($_, "$installlib/$name")
 888                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 889                                   "$installlib/$name");
 890                 }
 891            } else {
 892                 if (copy_if_diff($_, "$installlib/$name")) {
 893                     if ($name =~ /\.(so|$dlext)$/o) {
 894                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 895                         chmod(0555, "$installlib/$name");
 896                     } else {
 897                         strip("-S", "$installlib/$name")
 898                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 899                         chmod(0444, "$installlib/$name");
 900                     }
 901                 }
 902             } #if ($Is_NetWare)
 903         }
 904     }
 905 }
 906
 907 # Copy $from to $to, only if $from is different than $to.
 908 # Also preserve modification times for .a libraries.
 909 # On some systems, if you do
 910 #   ranlib libperl.a
 911 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 912 # and then try to link against the installed libperl.a, you might
 913 # get an error message to the effect that the symbol table is older
 914 # than the library.
 915 # Return true if copying occurred.
 916
 917 sub copy_if_diff {
 918     my($from,$to)=@_;
 919     return 1 if (($^O eq 'VMS') && (-d $from));
 920     my $xto = $to;
 921     $xto =~ s/^\Q$destdir\E// if $destdir;
 922     my $perlpodbadsymlink;
 923     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 924         -l $from &&
 925         ! -e $from) {
 926         # Some Linux implementations have problems traversing over
 927         # multiple symlinks (when going over NFS?) and fail to read
 928         # the symlink target.  Combine this with the fact that some
 929         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 930         # and you end up with those pods not getting installed.
 931         $perlpodbadsymlink = 1;
 932     }
 933     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 934     $packlist->{$xto} = { type => 'file' };
 935     if ($force || compare($from, $to) || $nonono) {
 936         safe_unlink($to);   # In case we don't have write permissions.
 937         if ($nonono) {
 938             $from = $depth . "/" . $from if $depth;
 939         }
 940         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 941             $from = "README.$1";
 942         }
 943         copy($from, $to);
 944         # Restore timestamps if it's a .a library or for OS/2.
 945         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 946             my ($atime, $mtime) = (stat $from)[8,9];
 947             utime $atime, $mtime, $to;
 948         }
 949         1;
 950     }
 951 }
 952
 953 sub strip
 954 {
 955     my(@args) = @_;
 956
 957     return unless $dostrip;
 958
 959     my @opts;
 960     while (@args && $args[0] =~ /^(-\w+)$/) {
 961         push @opts, shift @args;
 962     }
 963
 964     foreach my $file (@args) {
 965         if (-f $file) {
 966             if ($verbose) {
 967                 print "  strip " . join(' ', @opts);
 968                 print " " if (@opts);
 969                 print "$file\n";
 970             }
 971             system("strip", @opts, $file);
 972         } else {
 973             print "# file '$file' skipped\n" if $verbose;
 974         }
 975     }
 976 }