This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Rewrite $. entry and switch to -> syntax
[perl5.git] / installperl
1 #!./perl
2
3 BEGIN {
4     require 5.004;
5     chdir '..' if !-d 'lib' and -d '..\lib';
6     @INC = 'lib';
7     $ENV{PERL5LIB} = 'lib';
8 }
9
10 use strict;
11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
12     $nonono, $dostrip, $versiononly, $silent, $verbose,
13     $otherperls, $archname,$Is_NetWare, $nwinstall);
14 use vars qw /$depth/;
15
16 BEGIN {
17     $Is_VMS = $^O eq 'VMS';
18     $Is_W32 = $^O eq 'MSWin32';
19     $Is_OS2 = $^O eq 'os2';
20     $Is_Cygwin = $^O eq 'cygwin';
21     $Is_Darwin = $^O eq 'darwin';
22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
23 }
24
25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
26
27 use File::Find;
28 use File::Compare;
29 use File::Copy ();
30 use File::Path ();
31 use ExtUtils::Packlist;
32 use Config;
33 use subs qw(unlink link chmod);
34
35 if ($Config{d_umask}) {
36     umask(022); # umasks like 077 aren't that useful for installations
37 }
38
39 $Is_NetWare = $Config{osname} eq 'NetWare';
40 if ($Is_NetWare) {
41         $Is_W32 = 0;
42         $scr_ext = '.pl';
43 }
44
45 # override the ones in the rest of the script
46 sub mkpath {
47     File::Path::mkpath(@_) unless $nonono;
48 }
49
50 my $mainperldir = "/usr/bin";
51 my $exe_ext = $Config{exe_ext};
52
53 # Allow ``make install PERLNAME=something_besides_perl'':
54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
55
56 # This is the base used for versioned names, like "perl5.6.0".
57 # It's separate because a common use of $PERLNAME is to install
58 # perl as "perl5", if that's used as base for versioned files you
59 # get "perl55.6.0".
60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
61                     ? $ENV{PERLNAME_VERBASE}
62                     : $perl;
63
64 $otherperls = 1;
65 while (@ARGV) {
66     $nonono = 1 if $ARGV[0] eq '-n';
67     $dostrip = 1 if $ARGV[0] eq '-s';
68     $versiononly = 1 if $ARGV[0] eq '-v';
69     $versiononly = 0 if $ARGV[0] eq '+v';
70     $silent = 1 if $ARGV[0] eq '-S';
71     $otherperls = 0 if $ARGV[0] eq '-o';
72     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
73     $archname = 1 if $ARGV[0] eq '-A';
74         $nwinstall = 1 if $ARGV[0] eq '-netware';
75     shift;
76 }
77
78 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
79 my (@scripts, @tolink);
80 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
81 while (<SCRIPTS>) {
82     next if /^#/;
83     next if /#\s*pod\s*=/; # Binary programs need separate treatment
84     chomp;
85     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
86         push @scripts, $1;
87         push @tolink, [$1, $2];
88     } else {
89         push @scripts, $_;
90     }
91 }
92 close SCRIPTS;
93
94 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
95
96 my @pods = (<pod/*.pod>);
97
98 # Specify here any .pm files that are actually architecture-dependent.
99 # (Those included with XS extensions under ext/ are automatically
100 # added later.)
101 # Now that the default privlib has the full perl version number included,
102 # we no longer have to play the trick of sticking version-specific .pm 
103 # files under the archlib directory.
104 my %archpms = (
105     Config => 1, 
106     lib => 1, 
107 );
108
109 if ($^O eq 'dos') {
110     push(@scripts,'djgpp/fixpmain');
111     $archpms{config} = $archpms{filehand} = 1;
112 }
113
114 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
115 {
116         push(@scripts, map("$_.exe", @scripts));
117 }
118
119 find(sub {
120         if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
121             my($path, $modname) = ($1,$2);
122
123             # strip trailing component first
124             $path =~ s{/[^/]*$}{};
125
126             # strip optional "/lib";
127             $path =~ s{/lib\b}{};
128
129             # strip any leading /
130             $path =~ s{^/}{};
131
132             # reconstitute canonical module name
133             $modname = "$path/$modname" if length $path;
134
135             # remember it
136             $archpms{$modname} = 1;
137         }
138     }, 'ext');
139
140 # print "[$_]\n" for sort keys %archpms;
141
142 my $ver = $Config{version};
143 my $release = substr($],0,3);   # Not used currently.
144 my $patchlevel = substr($],3,2);
145 die "Patchlevel of perl ($patchlevel)",
146     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
147         if $patchlevel != $Config{'PERL_VERSION'};
148
149 # Fetch some frequently-used items from %Config
150 my $installbin = $Config{installbin};
151 my $installscript = $Config{installscript};
152 my $installprivlib = $Config{installprivlib};
153 my $installarchlib = $Config{installarchlib};
154 my $installsitelib = $Config{installsitelib};
155 my $installsitearch = $Config{installsitearch};
156 my $installman1dir = $Config{installman1dir};
157 my $man1ext = $Config{man1ext};
158 my $libperl = $Config{libperl};
159 # Shared library and dynamic loading suffixes.
160 my $so = $Config{so};
161 my $dlext = $Config{dlext};
162 my $dlsrc = $Config{dlsrc};
163 if ($^O eq 'os390') {
164     my $pwd;
165     chomp($pwd=`pwd`);
166     my $archlibexp = $Config{archlibexp};
167     my $usedl = $Config{usedl};
168     if ($usedl eq 'define') {
169         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
170     }
171 }
172
173 if ($nwinstall) {
174         # This is required only if we are installing on a NetWare server
175         $installscript = $Config{installnwscripts};
176         $installprivlib = $Config{installnwlib};
177         $installarchlib = $Config{installnwlib};
178         $installsitelib = $Config{installnwlib};
179 }
180
181 my $d_dosuid = $Config{d_dosuid};
182 my $binexp = $Config{binexp};
183
184 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
185     foreach ( \$installbin,     \$installscript,  \$installprivlib,
186               \$installarchlib, \$installsitelib, \$installsitearch,
187               \$installman1dir ) {
188       $$_ = unixify($$_);  $$_ =~ s:/$::;
189     }
190 }
191
192 # Do some quick sanity checks.
193
194 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
195
196    $installbin          || die "No installbin directory in config.sh\n";
197 -d $installbin          || mkpath($installbin, $verbose, 0777);
198 -d $installbin          || $nonono || die "$installbin is not a directory\n";
199 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
200         unless $installbin =~ m#^/afs/# || $nonono;
201
202 if (!$Is_NetWare) {
203 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
204 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
205
206 -f 't/rantests'         || $Is_W32
207                         || warn "WARNING: You've never run 'make test' or",
208                                 " some tests failed! (Installing anyway.)\n";
209 } #if (!$Is_NetWare)
210
211 if (($Is_W32 and ! $Is_NetWare)  or $Is_Cygwin) {
212   my $perldll;
213
214   if ($Is_Cygwin) {
215     $perldll = $libperl;
216     $perldll =~ s/(\..*)?$/.$dlext/;
217     if ($Config{useshrplib} eq 'true') {
218       # install ld2 and perlld as well
219       foreach ('ld2', 'perlld') {
220         safe_unlink("$installbin/$_");
221         copy("$_", "$installbin/$_");
222         chmod(0755, "$installbin/$_");
223       };
224     };
225   } else {
226     $perldll = 'perl57.' . $dlext;
227   }
228
229   if ($dlsrc ne "dl_none.xs") {
230     -f $perldll || die "No perl DLL built\n";
231   }
232   # Install the DLL
233
234   safe_unlink("$installbin/$perldll");
235   copy("$perldll", "$installbin/$perldll");
236   chmod(0755, "$installbin/$perldll");
237    
238 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
239
240 # This will be used to store the packlist
241 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
242
243 # First we install the version-numbered executables.
244
245 if ($Is_VMS) {
246     safe_unlink("$installbin/$perl$exe_ext");
247     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
248     chmod(0755, "$installbin/$perl$exe_ext");
249     safe_unlink("$installbin/${perl}shr$exe_ext");
250     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
251     chmod(0755, "$installbin/${perl}shr$exe_ext");
252 }
253 elsif ($^O eq 'mpeix') {
254     # MPE lacks hard links and requires that executables with special
255     # capabilities reside in the MPE namespace.
256     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
257     # Install the primary executable into the MPE namespace as perlpath.
258     copy("perl$exe_ext", $Config{perlpath});
259     chmod(0755, $Config{perlpath});
260     # Create a backup copy with the version number.
261     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
262 }
263 elsif ($^O ne 'dos') {
264         if (!$Is_NetWare) {
265                 safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
266                 copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
267                 strip("$installbin/$perl_verbase$ver$exe_ext");
268                 chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
269         }
270         else {
271                 # If installing onto a NetWare server
272                 if ($nwinstall) {
273                         # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
274                         mkpath($Config{installnwsystem}, 1, 0777);
275                         copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
276                         copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
277                         copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
278                         copy("x2p\\a2p.nlm", $Config{installnwsystem});
279                         chmod(0755, "$Config{installnwsystem}\\perl.nlm");
280                         mkpath($Config{installnwlcgi}, 1, 0777);
281                         copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
282                 }
283         } #if (!$Is_NetWare)
284 }
285 else {
286     safe_unlink("$installbin/$perl.exe");
287     copy("perl.exe", "$installbin/$perl.exe");
288 }
289
290 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
291 if ($d_dosuid) {
292     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
293     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
294 }
295
296 # Install library files.
297
298 my ($do_installarchlib, $do_installprivlib) = (0, 0);
299     
300 mkpath($installprivlib, $verbose, 0777);
301 mkpath($installarchlib, $verbose, 0777);
302 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
303 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
304
305 if (chdir "lib") {
306     $do_installarchlib = ! samepath($installarchlib, '.');
307     $do_installprivlib = ! samepath($installprivlib, '.');
308     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
309
310     if ($do_installarchlib || $do_installprivlib) {
311         find(\&installlib, '.');
312     }
313     chdir ".." || die "Can't cd back to source directory: $!\n";
314 }
315 else {
316     warn "Can't cd to lib to install lib files: $!\n";
317 }
318
319 # Install header files and libraries.
320 mkpath("$installarchlib/CORE", $verbose, 0777);
321 my @corefiles;
322 if ($Is_VMS) {  # We did core file selection during build
323     my $coredir = "lib/$Config{archname}/$ver/CORE";
324     $coredir =~ tr/./_/;
325     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
326 }
327 else {
328     # [als] hard-coded 'libperl' name... not good!
329     @corefiles = <*.h libperl*.*>;
330
331     # AIX needs perl.exp installed as well.
332     push(@corefiles,'perl.exp') if $^O eq 'aix';
333     if ($^O eq 'mpeix') {
334         # MPE needs mpeixish.h installed as well.
335         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
336         push(@corefiles,'mpeix/mpeixish.h');
337     }
338     # If they have built sperl.o...
339     push(@corefiles,'sperl.o') if -f 'sperl.o';
340 }
341 foreach my $file (@corefiles) {
342     # HP-UX (at least) needs to maintain execute permissions
343     # on dynamically-loadable libraries. So we do it for all.
344     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
345         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
346             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
347            chmod(0555, "$installarchlib/CORE/$file");
348         } else {
349             chmod(0444, "$installarchlib/CORE/$file");
350         }
351     }
352 }
353
354 # Install main perl executables
355 # Make links to ordinary names if installbin directory isn't current directory.
356
357 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
358     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
359     if ($^O eq 'mpeix') {
360         # MPE doesn't support hard links, so use a symlink.
361         # We don't want another cloned copy.
362         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
363     } else {
364         link("$installbin/$perl_verbase$ver$exe_ext",
365                 "$installbin/$perl$exe_ext");
366     }
367     link("$installbin/s$perl_verbase$ver$exe_ext",
368             "$installbin/suid$perl$exe_ext") 
369       if $d_dosuid;
370 }
371
372 # For development purposes it can be very useful to have multiple perls
373 # build for different "architectures" (eg threading or not) simultaneously.
374 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
375     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
376     safe_unlink("$installbin/$archperl");
377     if ($^O eq 'mpeix') {
378         # MPE doesn't support hard links, so use a symlink.
379         # We don't want another cloned copy.
380         symlink($Config{perlpath}, "$installbin/$archperl");
381     } else {
382         link("$installbin/$perl_verbase$ver$exe_ext",
383                 "$installbin/$archperl");
384     }
385 }
386
387 # Offer to install perl in a "standard" location
388
389 my $mainperl_is_instperl = 0;
390
391 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
392     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
393         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
394     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
395     my($instperl)       = "$installbin/$perl$exe_ext";
396     my($expinstperl)    = "$binexp/$perl$exe_ext";
397
398     # First make sure $usrbinperl is not already the same as the perl we
399     # just installed.
400     if (-x $usrbinperl) {
401         # Try to be clever about mainperl being a symbolic link
402         # to binexp/perl if binexp and installbin are different.
403         $mainperl_is_instperl =
404             samepath($usrbinperl, $instperl) ||
405             samepath($usrbinperl, $expinstperl) ||
406              (($binexp ne $installbin) &&
407               (-l $usrbinperl) &&
408               ((readlink $usrbinperl) eq $expinstperl));
409     }
410     if ((! $mainperl_is_instperl) &&
411         (yn("Many scripts expect perl to be installed as $usrbinperl.\n" . 
412              "Do you wish to have $usrbinperl be the same as\n" .
413              "$expinstperl? [y] ")))
414     {
415         unlink($usrbinperl);
416         ( $Config{'d_link'} eq 'define' &&
417           eval { CORE::link $instperl, $usrbinperl } )  ||
418         eval { symlink $expinstperl, $usrbinperl }      ||
419         copy($instperl, $usrbinperl);
420
421         $mainperl_is_instperl = 1;
422     }
423 }
424
425 # Make links to ordinary names if installbin directory isn't current directory.
426 if (!$Is_NetWare) {
427         if (!$versiononly && ! samepath($installbin, 'x2p')) {
428                 safe_unlink("$installbin/a2p$exe_ext");
429                 copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
430                strip("$installbin/a2p$exe_ext");
431                 chmod(0755, "$installbin/a2p$exe_ext");
432         }
433 }
434
435 # cppstdin is just a script, but it is architecture-dependent, so
436 # it can't safely be shared.  Place it in $installbin.
437 # Note that Configure doesn't build cppstin if it isn't needed, so
438 # we skip this if cppstdin doesn't exist.
439 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
440     safe_unlink("$installbin/cppstdin");
441     copy("cppstdin", "$installbin/cppstdin");
442     chmod(0755, "$installbin/cppstdin");
443 }
444
445 sub script_alias {
446     my ($installscript, $orig, $alias, $scr_ext) = @_;
447
448     safe_unlink("$installscript/$alias$scr_ext");
449     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
450         copy("$installscript/$orig$scr_ext",
451              "$installscript/$alias$scr_ext"); 
452     } else {
453         link("$installscript/$orig$scr_ext",
454              "$installscript/$alias$scr_ext");
455     }
456 }
457
458 # Install scripts.
459 mkpath($installscript, $verbose, 0777);
460 if ($versiononly) {
461     for (@scripts) {
462         (my $base = $_) =~ s#.*/##;
463         $base .= $ver;
464         copy($_,    "$installscript/$base");
465         chmod(0755, "$installscript/$base");
466     }
467
468     for (@tolink) { 
469         my ($from, $to) = map { "$_$ver" } @$_;
470         (my $frbase = $from) =~ s#.*/##;
471         (my $tobase = $to) =~ s#.*/##;
472         script_alias($installscript, $frbase, $tobase, $scr_ext);
473     }
474 } else {
475     for (@scripts) {
476         (my $base = $_) =~ s#.*/##;
477         copy($_, "$installscript/$base");
478         chmod(0755, "$installscript/$base");
479     }
480
481     for (@tolink) { 
482         my ($from, $to) = @$_;
483         (my $frbase = $from) =~ s#.*/##;
484         (my $tobase = $to) =~ s#.*/##;
485         script_alias($installscript, $frbase, $tobase, $scr_ext);
486     }
487 }
488
489 # Install pod pages.  Where? I guess in $installprivlib/pod
490 # ($installprivlib/pods for cygwin).
491
492 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
493 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
494     mkpath("${installprivlib}/$pod", $verbose, 0777);
495
496     # If Perl 5.003's perldiag.pod is there, rename it.
497     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
498         read POD, $_, 4000;
499         close POD;
500         # Some of Perl 5.003's diagnostic messages ended with periods.
501         if (/^=.*\.$/m) {
502             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
503                                "${installprivlib}/$pod/perldiag-5.003.pod");
504             print "  rename $from $to";
505             rename($from, $to)
506                 or warn "Couldn't rename $from to $to: $!\n"
507                 unless $nonono;
508         }
509     }
510
511     for (@pods) {
512         # $_ is a name like  pod/perl.pod
513         (my $base = $_) =~ s#.*/##;
514         copy_if_diff($_, "${installprivlib}/$pod/${base}");
515     }
516
517 }
518
519 # Check to make sure there aren't other perls around in installer's
520 # path.  This is probably UNIX-specific.  Check all absolute directories
521 # in the path except for where public executables are supposed to live.
522 # Also skip $mainperl if the user opted to have it be a link to the
523 # installed perl.
524
525 if (!$versiononly && $otherperls) {
526     my ($path, @path);
527     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
528     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
529     @path = split(/$dirsep/, $path);
530     if ($Is_VMS) {
531         my $i = 0;
532         while (exists $ENV{'DCL$PATH' . $i}) {
533             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
534             push(@path,$dir);
535         }
536     }
537     my @otherperls;
538     my %otherperls;
539     for (@path) {
540         next unless m,^/,;
541         # Use &samepath here because some systems have other dirs linked
542         # to $mainperldir (like SunOS)
543         next if samepath($_, $binexp);
544         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
545         my $otherperl = "$_/$perl$exe_ext";
546         next if $otherperls{$otherperl}++;
547         push(@otherperls, $otherperl)
548             if (-x $otherperl && ! -d $otherperl);
549     }
550     if (@otherperls) {
551         warn "\nWarning: $perl appears in your path in the following " .
552             "locations beyond where\nwe just installed it:\n";
553         for (@otherperls) {
554             warn "    ", $_, "\n";
555         }
556         warn "\n";
557     }
558
559 }
560
561 $packlist->write() unless $nonono;
562 print "  Installation complete\n" if $verbose;
563
564 exit 0;
565
566 ###############################################################################
567
568 sub yn {
569     my($prompt) = @_;
570     my($answer);
571     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
572     print STDERR $prompt;
573     chop($answer = <STDIN>);
574     $answer = $default if $answer =~ m/^\s*$/;
575     ($answer =~ m/^[yY]/);
576 }
577
578 sub unlink {
579     my(@names) = @_;
580     my($cnt) = 0;
581
582     return scalar(@names) if $Is_VMS;
583
584     foreach my $name (@names) {
585         next unless -e $name;
586         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
587         print "  unlink $name\n" if $verbose;
588         ( CORE::unlink($name) and ++$cnt 
589           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
590     }
591     return $cnt;
592 }
593
594 sub safe_unlink {
595     return if $nonono or $Is_VMS;
596     my @names = @_;
597     foreach my $name (@names) {
598         next unless -e $name;
599         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
600         print "  unlink $name\n" if $verbose;
601         next if CORE::unlink($name);
602         warn "Couldn't unlink $name: $!\n";
603         if ($! =~ /busy/i) {
604             print "  mv $name $name.old\n" if $verbose;
605             safe_rename($name, "$name.old")
606                 or warn "Couldn't rename $name: $!\n";
607         }
608     }
609 }
610
611 sub safe_rename {
612     my($from,$to) = @_;
613     if (-f $to and not unlink($to)) {
614         my($i);
615         for ($i = 1; $i < 50; $i++) {
616             last if rename($to, "$to.$i");
617         }
618         warn("Cannot rename to `$to.$i': $!"), return 0 
619            if $i >= 50; # Give up!
620     }
621     link($from,$to) || return 0;
622     unlink($from);
623 }
624
625 sub link {
626     my($from,$to) = @_;
627     my($success) = 0;
628
629     print $verbose ? "  ln $from $to\n" : "  $to\n" unless $silent;
630     eval {
631         CORE::link($from, $to)
632             ? $success++
633             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
634               ? die "AFS"  # okay inside eval {}
635               : die "Couldn't link $from to $to: $!\n"
636           unless $nonono;
637         $packlist->{$to} = { from => $from, type => 'link' };
638     };
639     if ($@) {
640         warn $@;
641         print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
642         print "  creating new version of $to\n"
643                  if $Is_VMS and -e $to and !$silent;
644         File::Copy::copy($from, $to)
645             ? $success++
646             : warn "Couldn't copy $from to $to: $!\n"
647           unless $nonono;
648         $packlist->{$to} = { type => 'file' };
649     }
650     $success;
651 }
652
653 sub chmod {
654     my($mode,$name) = @_;
655
656     return if ($^O eq 'dos');
657     printf "  chmod %o %s\n", $mode, $name if $verbose;
658     CORE::chmod($mode,$name)
659         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
660       unless $nonono;
661 }
662
663 sub copy {
664     my($from,$to) = @_;
665
666     print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
667     print "  creating new version of $to\n" if $Is_VMS and -e $to and !$silent;
668     File::Copy::copy($from, $to)
669         || warn "Couldn't copy $from to $to: $!\n"
670       unless $nonono;
671     $packlist->{$to} = { type => 'file' };
672 }
673
674 sub samepath {
675     my($p1, $p2) = @_;
676
677     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
678
679     if ($p1 ne $p2) {
680         my($dev1, $ino1, $dev2, $ino2);
681         ($dev1, $ino1) = stat($p1);
682         ($dev2, $ino2) = stat($p2);
683         ($dev1 == $dev2 && $ino1 == $ino2);
684     }
685     else {
686         1;
687     }
688 }
689
690 sub installlib {
691     my $dir = $File::Find::dir;
692     $dir =~ s#^\.(?![^/])/?##;
693     local($depth) = $dir ? "lib/$dir" : "lib";
694
695     my $name = $_;
696
697     # Ignore RCS and CVS directories.
698     if (($name eq 'CVS' or $name eq 'RCS') and -d $name) {
699         $File::Find::prune = 1;
700         return;
701     }
702     
703     # ignore patch backups, RCS files, emacs backup & temp files and the
704     # .exists files, .PL files, and .t files.
705     return if $name =~ m{\.orig$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.t$};
706
707     $name = "$dir/$name" if $dir ne '';
708
709     my $installlib = $installprivlib;
710     if ($dir =~ /^auto/ ||
711           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
712           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare))
713        ) {
714         $installlib = $installarchlib;
715         return unless $do_installarchlib;
716     } else {
717         return unless $do_installprivlib;
718     }
719
720     if (-f $_) {
721         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
722             $installlib = $installprivlib;
723             #We're installing *.al and *.ix files into $installprivlib,
724             #but we have to delete old *.al and *.ix files from the 5.000
725             #distribution:
726             #This might not work because $archname might have changed.
727             unlink("$installarchlib/$name");
728         }
729         $packlist->{"$installlib/$name"} = { type => 'file' };
730         if (compare($_, "$installlib/$name") || $nonono) {
731             unlink("$installlib/$name");
732             mkpath("$installlib/$dir", $verbose, 0777);
733             # HP-UX (at least) needs to maintain execute permissions
734             # on dynamically-loaded libraries.
735            if ($Is_NetWare && !$nwinstall) {
736                # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
737                # if copied will give problems when building new extensions.
738                # Has to be copied if we are installing on a NetWare server and hence
739                # the check !$nwinstall
740                if (!(/\.(?:nlp|nlm|bs)$/)) {
741                    copy_if_diff($_, "$installlib/$name")
742                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
743                                  "$installlib/$name");
744                }
745            } else {
746                if (copy_if_diff($_, "$installlib/$name")) {
747                    if ($name =~ /\.(so|$dlext)$/o) {
748                        strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
749                        chmod(0555, "$installlib/$name");
750                    } else {
751                        strip("-S", "$installlib/$name")
752                            if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
753                        chmod(0444, "$installlib/$name");
754                    }
755                }
756            } #if ($Is_NetWare)
757         }
758     }
759 }
760
761 # Copy $from to $to, only if $from is different than $to.
762 # Also preserve modification times for .a libraries.
763 # On some systems, if you do
764 #   ranlib libperl.a
765 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
766 # and then try to link against the installed libperl.a, you might
767 # get an error message to the effect that the symbol table is older
768 # than the library.
769 # Return true if copying occurred.
770
771 sub copy_if_diff {
772     my($from,$to)=@_;
773     return 1 if (($^O eq 'VMS') && (-d $from));
774     -f $from || warn "$0: $from not found";
775     $packlist->{$to} = { type => 'file' };
776     if (compare($from, $to) || $nonono) {
777         safe_unlink($to);   # In case we don't have write permissions.
778         if ($nonono) {
779             $from = $depth . "/" . $from if $depth;
780         }
781         copy($from, $to);
782         # Restore timestamps if it's a .a library or for OS/2.
783         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
784             my ($atime, $mtime) = (stat $from)[8,9];
785             utime $atime, $mtime, $to;
786         }
787         1;
788     }
789 }
790
791 sub strip
792 {
793     my(@args) = @_;
794
795     return unless $dostrip;
796
797     my @opts;
798     while (@args && $args[0] =~ /^(-\w+)$/) {
799         push @opts, shift @args;
800     }
801
802     foreach my $file (@args) {
803         if (-f $file) {
804            if ($verbose) {
805                print "  strip " . join(' ', @opts);
806                print " " if (@opts);
807                print "$file\n";
808            }
809             system("strip", @opts, $file);
810         } else {
811             print "# file '$file' skipped\n" if $verbose;
812         }
813     }
814 }