This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[perl #114020] perlvar: warn against my $_
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 The Syntax of Variable Names
8
9 Variable names in Perl can have several formats.  Usually, they
10 must begin with a letter or underscore, in which case they can be
11 arbitrarily long (up to an internal limit of 251 characters) and
12 may contain letters, digits, underscores, or the special sequence
13 C<::> or C<'>.  In this case, the part before the last C<::> or
14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
15
16 Perl variable names may also be a sequence of digits or a single
17 punctuation or control character.  These names are all reserved for
18 special uses by Perl; for example, the all-digits names are used
19 to hold data captured by backreferences after a regular expression
20 match.  Perl has a special syntax for the single-control-character
21 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
22 character.  For example, the notation C<$^W> (dollar-sign caret
23 C<W>) is the scalar variable whose name is the single character
24 control-C<W>.  This is better than typing a literal control-C<W>
25 into your program.
26
27 Since Perl v5.6.0, Perl variable names may be alphanumeric
28 strings that begin with control characters (or better yet, a caret).
29 These variables must be written in the form C<${^Foo}>; the braces
30 are not optional.  C<${^Foo}> denotes the scalar variable whose
31 name is a control-C<F> followed by two C<o>'s.  These variables are
32 reserved for future special uses by Perl, except for the ones that
33 begin with C<^_> (control-underscore or caret-underscore).  No
34 control-character name that begins with C<^_> will acquire a special
35 meaning in any future version of Perl; such names may therefore be
36 used safely in programs.  C<$^_> itself, however, I<is> reserved.
37
38 Perl identifiers that begin with digits, control characters, or
39 punctuation characters are exempt from the effects of the C<package>
40 declaration and are always forced to be in package C<main>; they are
41 also exempt from C<strict 'vars'> errors.  A few other names are also
42 exempt in these ways:
43
44     ENV      STDIN
45     INC      STDOUT
46     ARGV     STDERR
47     ARGVOUT
48     SIG
49
50 In particular, the special C<${^_XYZ}> variables are always taken
51 to be in package C<main>, regardless of any C<package> declarations
52 presently in scope.
53
54 =head1 SPECIAL VARIABLES
55
56 The following names have special meaning to Perl.  Most punctuation
57 names have reasonable mnemonics, or analogs in the shells.
58 Nevertheless, if you wish to use long variable names, you need only say:
59
60     use English;
61
62 at the top of your program.  This aliases all the short names to the long
63 names in the current package.  Some even have medium names, generally
64 borrowed from B<awk>.  To avoid a performance hit, if you don't need the
65 C<$PREMATCH>, C<$MATCH>, or C<$POSTMATCH> it's best to use the C<English>
66 module without them:
67
68     use English '-no_match_vars';
69
70 Before you continue, note the sort order for variables.  In general, we
71 first list the variables in case-insensitive, almost-lexigraphical
72 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
73 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
74 For variables with the same identifier, we list it in order of scalar,
75 array, hash, and bareword.
76
77 =head2 General Variables
78
79 =over 8
80
81 =item $ARG
82
83 =item $_
84 X<$_> X<$ARG>
85
86 The default input and pattern-searching space.  The following pairs are
87 equivalent:
88
89     while (<>) {...}    # equivalent only in while!
90     while (defined($_ = <>)) {...}
91
92     /^Subject:/
93     $_ =~ /^Subject:/
94
95     tr/a-z/A-Z/
96     $_ =~ tr/a-z/A-Z/
97
98     chomp
99     chomp($_)
100
101 Here are the places where Perl will assume C<$_> even if you don't use it:
102
103 =over 3
104
105 =item *
106
107 The following functions use C<$_> as a default argument:
108
109 abs, alarm, chomp, chop, chr, chroot,
110 cos, defined, eval, evalbytes, exp, fc, glob, hex, int, lc,
111 lcfirst, length, log, lstat, mkdir, oct, ord, pos, print, printf,
112 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
113 rmdir, say, sin, split (for its second
114 argument), sqrt, stat, study, uc, ucfirst,
115 unlink, unpack.
116
117 =item *
118
119 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
120 See L<perlfunc/-X>
121
122 =item *
123
124 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
125 when used without an C<=~> operator.
126
127 =item *
128
129 The default iterator variable in a C<foreach> loop if no other
130 variable is supplied.
131
132 =item *
133
134 The implicit iterator variable in the C<grep()> and C<map()> functions.
135
136 =item *
137
138 The implicit variable of C<given()>.
139
140 =item *
141
142 The default place to put the next value or input record
143 when a C<< <FH> >>, C<readline>, C<readdir> or C<each>
144 operation's result is tested by itself as the sole criterion of a C<while>
145 test.  Outside a C<while> test, this will not happen.
146
147 =back
148
149 C<$_> is by default a global variable.  However, as
150 of perl v5.10.0, you can use a lexical version of
151 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
152 declaring C<our $_> restores the global C<$_> in the current scope.  Though
153 this seemed like a good idea at the time it was introduced, lexical C<$_>
154 actually causes more problems than it solves.  If you call a function that
155 expects to be passed information via C<$_>, it may or may not work,
156 depending on how the function is written, there not being any easy way to
157 solve this.  Just avoid lexical C<$_>, unless you are feeling particularly
158 masochistic.
159
160 Mnemonic: underline is understood in certain operations.
161
162 =item @ARG
163
164 =item @_
165 X<@_> X<@ARG>
166
167 Within a subroutine the array C<@_> contains the parameters passed to
168 that subroutine.  Inside a subroutine, C<@_> is the default array for
169 the array operators C<push>, C<pop>, C<shift>, and C<unshift>.
170
171 See L<perlsub>.
172
173 =item $LIST_SEPARATOR
174
175 =item $"
176 X<$"> X<$LIST_SEPARATOR>
177
178 When an array or an array slice is interpolated into a double-quoted
179 string or a similar context such as C</.../>, its elements are
180 separated by this value.  Default is a space.  For example, this:
181
182     print "The array is: @array\n";
183
184 is equivalent to this:
185
186     print "The array is: " . join($", @array) . "\n";
187
188 Mnemonic: works in double-quoted context.
189
190 =item $PROCESS_ID
191
192 =item $PID
193
194 =item $$
195 X<$$> X<$PID> X<$PROCESS_ID>
196
197 The process number of the Perl running this script.  Though you I<can> set
198 this variable, doing so is generally discouraged, although it can be
199 invaluable for some testing purposes.  It will be reset automatically
200 across C<fork()> calls.
201
202 Note for Linux and Debian GNU/kFreeBSD users: Before Perl v5.16.0 perl
203 would emulate POSIX semantics on Linux systems using LinuxThreads, a
204 partial implementation of POSIX Threads that has since been superseded
205 by the Native POSIX Thread Library (NPTL).
206
207 LinuxThreads is now obsolete on Linux, and caching C<getpid()>
208 like this made embedding perl unnecessarily complex (since you'd have
209 to manually update the value of $$), so now C<$$> and C<getppid()>
210 will always return the same values as the underlying C library.
211
212 Debian GNU/kFreeBSD systems also used LinuxThreads up until and
213 including the 6.0 release, but after that moved to FreeBSD thread
214 semantics, which are POSIX-like.
215
216 To see if your system is affected by this discrepancy check if
217 C<getconf GNU_LIBPTHREAD_VERSION | grep -q NPTL> returns a false
218 value. NTPL threads preserve the POSIX semantics.
219
220 Mnemonic: same as shells.
221
222 =item $PROGRAM_NAME
223
224 =item $0
225 X<$0> X<$PROGRAM_NAME>
226
227 Contains the name of the program being executed.
228
229 On some (but not all) operating systems assigning to C<$0> modifies
230 the argument area that the C<ps> program sees.  On some platforms you
231 may have to use special C<ps> options or a different C<ps> to see the
232 changes.  Modifying the C<$0> is more useful as a way of indicating the
233 current program state than it is for hiding the program you're
234 running.
235
236 Note that there are platform-specific limitations on the maximum
237 length of C<$0>.  In the most extreme case it may be limited to the
238 space occupied by the original C<$0>.
239
240 In some platforms there may be arbitrary amount of padding, for
241 example space characters, after the modified name as shown by C<ps>.
242 In some platforms this padding may extend all the way to the original
243 length of the argument area, no matter what you do (this is the case
244 for example with Linux 2.2).
245
246 Note for BSD users: setting C<$0> does not completely remove "perl"
247 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
248 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
249 and the " (perl)" suffix are shown depends on your exact BSD variant
250 and version).  This is an operating system feature, Perl cannot help it.
251
252 In multithreaded scripts Perl coordinates the threads so that any
253 thread may modify its copy of the C<$0> and the change becomes visible
254 to ps(1) (assuming the operating system plays along).  Note that
255 the view of C<$0> the other threads have will not change since they
256 have their own copies of it.
257
258 If the program has been given to perl via the switches C<-e> or C<-E>,
259 C<$0> will contain the string C<"-e">.
260
261 On Linux as of perl v5.14.0 the legacy process name will be set with
262 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
263 perl has done since version 4.000.  Now system utilities that read the
264 legacy process name such as ps, top and killall will recognize the
265 name you set when assigning to C<$0>.  The string you supply will be
266 cut off at 16 bytes, this is a limitation imposed by Linux.
267
268 Mnemonic: same as B<sh> and B<ksh>.
269
270 =item $REAL_GROUP_ID
271
272 =item $GID
273
274 =item $(
275 X<$(> X<$GID> X<$REAL_GROUP_ID>
276
277 The real gid of this process.  If you are on a machine that supports
278 membership in multiple groups simultaneously, gives a space separated
279 list of groups you are in.  The first number is the one returned by
280 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
281 the same as the first number.
282
283 However, a value assigned to C<$(> must be a single number used to
284 set the real gid.  So the value given by C<$(> should I<not> be assigned
285 back to C<$(> without being forced numeric, such as by adding zero.  Note
286 that this is different to the effective gid (C<$)>) which does take a
287 list.
288
289 You can change both the real gid and the effective gid at the same
290 time by using C<POSIX::setgid()>.  Changes
291 to C<$(> require a check to C<$!>
292 to detect any possible errors after an attempted change.
293
294 Mnemonic: parentheses are used to I<group> things.  The real gid is the
295 group you I<left>, if you're running setgid.
296
297 =item $EFFECTIVE_GROUP_ID
298
299 =item $EGID
300
301 =item $)
302 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
303
304 The effective gid of this process.  If you are on a machine that
305 supports membership in multiple groups simultaneously, gives a space
306 separated list of groups you are in.  The first number is the one
307 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
308 one of which may be the same as the first number.
309
310 Similarly, a value assigned to C<$)> must also be a space-separated
311 list of numbers.  The first number sets the effective gid, and
312 the rest (if any) are passed to C<setgroups()>.  To get the effect of an
313 empty list for C<setgroups()>, just repeat the new effective gid; that is,
314 to force an effective gid of 5 and an effectively empty C<setgroups()>
315 list, say C< $) = "5 5" >.
316
317 You can change both the effective gid and the real gid at the same
318 time by using C<POSIX::setgid()> (use only a single numeric argument).
319 Changes to C<$)> require a check to C<$!> to detect any possible errors
320 after an attempted change.
321
322 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
323 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
324 and C<$)> can be swapped only on machines supporting C<setregid()>.
325
326 Mnemonic: parentheses are used to I<group> things.  The effective gid
327 is the group that's I<right> for you, if you're running setgid.
328
329 =item $REAL_USER_ID
330
331 =item $UID
332
333 =item $<
334 X<< $< >> X<$UID> X<$REAL_USER_ID>
335
336 The real uid of this process.  You can change both the real uid and the
337 effective uid at the same time by using C<POSIX::setuid()>.  Since
338 changes to C<< $< >> require a system call, check C<$!> after a change
339 attempt to detect any possible errors.
340
341 Mnemonic: it's the uid you came I<from>, if you're running setuid.
342
343 =item $EFFECTIVE_USER_ID
344
345 =item $EUID
346
347 =item $>
348 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
349
350 The effective uid of this process.  For example:
351
352     $< = $>;            # set real to effective uid
353     ($<,$>) = ($>,$<);  # swap real and effective uids
354
355 You can change both the effective uid and the real uid at the same
356 time by using C<POSIX::setuid()>.  Changes to C<< $> >> require a check
357 to C<$!> to detect any possible errors after an attempted change.
358
359 C<< $< >> and C<< $> >> can be swapped only on machines
360 supporting C<setreuid()>.
361
362 Mnemonic: it's the uid you went I<to>, if you're running setuid.
363
364 =item $SUBSCRIPT_SEPARATOR
365
366 =item $SUBSEP
367
368 =item $;
369 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
370
371 The subscript separator for multidimensional array emulation.  If you
372 refer to a hash element as
373
374     $foo{$a,$b,$c}
375
376 it really means
377
378     $foo{join($;, $a, $b, $c)}
379
380 But don't put
381
382     @foo{$a,$b,$c}      # a slice--note the @
383
384 which means
385
386     ($foo{$a},$foo{$b},$foo{$c})
387
388 Default is "\034", the same as SUBSEP in B<awk>.  If your keys contain
389 binary data there might not be any safe value for C<$;>.
390
391 Consider using "real" multidimensional arrays as described
392 in L<perllol>.
393
394 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
395
396 =item $a
397
398 =item $b
399 X<$a> X<$b>
400
401 Special package variables when using C<sort()>, see L<perlfunc/sort>.
402 Because of this specialness C<$a> and C<$b> don't need to be declared
403 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
404 pragma.  Don't lexicalize them with C<my $a> or C<my $b> if you want to
405 be able to use them in the C<sort()> comparison block or function.
406
407 =item %ENV
408 X<%ENV>
409
410 The hash C<%ENV> contains your current environment.  Setting a
411 value in C<ENV> changes the environment for any child processes
412 you subsequently C<fork()> off.
413
414 =item $SYSTEM_FD_MAX
415
416 =item $^F
417 X<$^F> X<$SYSTEM_FD_MAX>
418
419 The maximum system file descriptor, ordinarily 2.  System file
420 descriptors are passed to C<exec()>ed processes, while higher file
421 descriptors are not.  Also, during an
422 C<open()>, system file descriptors are
423 preserved even if the C<open()> fails (ordinary file descriptors are
424 closed before the C<open()> is attempted).  The close-on-exec
425 status of a file descriptor will be decided according to the value of
426 C<$^F> when the corresponding file, pipe, or socket was opened, not the
427 time of the C<exec()>.
428
429 =item @F
430 X<@F>
431
432 The array C<@F> contains the fields of each line read in when autosplit
433 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
434 is package-specific, and must be declared or given a full package name
435 if not in package main when running under C<strict 'vars'>.
436
437 =item @INC
438 X<@INC>
439
440 The array C<@INC> contains the list of places that the C<do EXPR>,
441 C<require>, or C<use> constructs look for their library files.  It
442 initially consists of the arguments to any B<-I> command-line
443 switches, followed by the default Perl library, probably
444 F</usr/local/lib/perl>, followed by ".", to represent the current
445 directory.  ("." will not be appended if taint checks are enabled,
446 either by C<-T> or by C<-t>.)  If you need to modify this at runtime,
447 you should use the C<use lib> pragma to get the machine-dependent
448 library properly loaded also:
449
450     use lib '/mypath/libdir/';
451     use SomeMod;
452
453 You can also insert hooks into the file inclusion system by putting Perl
454 code directly into C<@INC>.  Those hooks may be subroutine references,
455 array references or blessed objects.  See L<perlfunc/require> for details.
456
457 =item %INC
458 X<%INC>
459
460 The hash C<%INC> contains entries for each filename included via the
461 C<do>, C<require>, or C<use> operators.  The key is the filename
462 you specified (with module names converted to pathnames), and the
463 value is the location of the file found.  The C<require>
464 operator uses this hash to determine whether a particular file has
465 already been included.
466
467 If the file was loaded via a hook (e.g. a subroutine reference, see
468 L<perlfunc/require> for a description of these hooks), this hook is
469 by default inserted into C<%INC> in place of a filename.  Note, however,
470 that the hook may have set the C<%INC> entry by itself to provide some more
471 specific info.
472
473 =item $INPLACE_EDIT
474
475 =item $^I
476 X<$^I> X<$INPLACE_EDIT>
477
478 The current value of the inplace-edit extension.  Use C<undef> to disable
479 inplace editing.
480
481 Mnemonic: value of B<-i> switch.
482
483 =item $^M
484 X<$^M>
485
486 By default, running out of memory is an untrappable, fatal error.
487 However, if suitably built, Perl can use the contents of C<$^M>
488 as an emergency memory pool after C<die()>ing.  Suppose that your Perl
489 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
490 Then
491
492     $^M = 'a' x (1 << 16);
493
494 would allocate a 64K buffer for use in an emergency.  See the
495 F<INSTALL> file in the Perl distribution for information on how to
496 add custom C compilation flags when compiling perl.  To discourage casual
497 use of this advanced feature, there is no L<English|English> long name for
498 this variable.
499
500 This variable was added in Perl 5.004.
501
502 =item $OSNAME
503
504 =item $^O
505 X<$^O> X<$OSNAME>
506
507 The name of the operating system under which this copy of Perl was
508 built, as determined during the configuration process.  For examples
509 see L<perlport/PLATFORMS>.
510
511 The value is identical to C<$Config{'osname'}>.  See also L<Config>
512 and the B<-V> command-line switch documented in L<perlrun>.
513
514 In Windows platforms, C<$^O> is not very helpful: since it is always
515 C<MSWin32>, it doesn't tell the difference between
516 95/98/ME/NT/2000/XP/CE/.NET.  Use C<Win32::GetOSName()> or
517 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
518 between the variants.
519
520 This variable was added in Perl 5.003.
521
522 =item %SIG
523 X<%SIG>
524
525 The hash C<%SIG> contains signal handlers for signals.  For example:
526
527     sub handler {   # 1st argument is signal name
528         my($sig) = @_;
529         print "Caught a SIG$sig--shutting down\n";
530         close(LOG);
531         exit(0);
532         }
533
534     $SIG{'INT'}  = \&handler;
535     $SIG{'QUIT'} = \&handler;
536     ...
537     $SIG{'INT'}  = 'DEFAULT';   # restore default action
538     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
539
540 Using a value of C<'IGNORE'> usually has the effect of ignoring the
541 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
542 this special case.
543
544 Here are some other examples:
545
546     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not
547                                 # recommended)
548     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current
549                                 # Plumber
550     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
551     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber()
552                                 # return??
553
554 Be sure not to use a bareword as the name of a signal handler,
555 lest you inadvertently call it.
556
557 If your system has the C<sigaction()> function then signal handlers
558 are installed using it.  This means you get reliable signal handling.
559
560 The default delivery policy of signals changed in Perl v5.8.0 from
561 immediate (also known as "unsafe") to deferred, also known as "safe
562 signals".  See L<perlipc> for more information.
563
564 Certain internal hooks can be also set using the C<%SIG> hash.  The
565 routine indicated by C<$SIG{__WARN__}> is called when a warning
566 message is about to be printed.  The warning message is passed as the
567 first argument.  The presence of a C<__WARN__> hook causes the
568 ordinary printing of warnings to C<STDERR> to be suppressed.  You can
569 use this to save warnings in a variable, or turn warnings into fatal
570 errors, like this:
571
572     local $SIG{__WARN__} = sub { die $_[0] };
573     eval $proggie;
574
575 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
576 disable warnings using the empty subroutine:
577
578     local $SIG{__WARN__} = sub {};
579
580 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
581 exception is about to be thrown.  The error message is passed as the
582 first argument.  When a C<__DIE__> hook routine returns, the exception
583 processing continues as it would have in the absence of the hook,
584 unless the hook routine itself exits via a C<goto &sub>, a loop exit,
585 or a C<die()>.  The C<__DIE__> handler is explicitly disabled during
586 the call, so that you can die from a C<__DIE__> handler.  Similarly
587 for C<__WARN__>.
588
589 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
590 even inside an C<eval()>.  Do not use this to rewrite a pending
591 exception in C<$@>, or as a bizarre substitute for overriding
592 C<CORE::GLOBAL::die()>.  This strange action at a distance may be fixed
593 in a future release so that C<$SIG{__DIE__}> is only called if your
594 program is about to exit, as was the original intent.  Any other use is
595 deprecated.
596
597 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
598 may be called to report (probable) errors found by the parser.  In such
599 a case the parser may be in inconsistent state, so any attempt to
600 evaluate Perl code from such a handler will probably result in a
601 segfault.  This means that warnings or errors that result from parsing
602 Perl should be used with extreme caution, like this:
603
604     require Carp if defined $^S;
605     Carp::confess("Something wrong") if defined &Carp::confess;
606     die "Something wrong, but could not load Carp to give "
607       . "backtrace...\n\t"
608       . "To see backtrace try starting Perl with -MCarp switch";
609
610 Here the first line will load C<Carp> I<unless> it is the parser who
611 called the handler.  The second line will print backtrace and die if
612 C<Carp> was available.  The third line will be executed only if C<Carp> was
613 not available.
614
615 Having to even think about the C<$^S> variable in your exception
616 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
617 invites grievous and difficult to track down errors.  Avoid it
618 and use an C<END{}> or CORE::GLOBAL::die override instead.
619
620 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
621 L<warnings> for additional information.
622
623 =item $BASETIME
624
625 =item $^T
626 X<$^T> X<$BASETIME>
627
628 The time at which the program began running, in seconds since the
629 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
630 and B<-C> filetests are based on this value.
631
632 =item $PERL_VERSION
633
634 =item $^V
635 X<$^V> X<$PERL_VERSION>
636
637 The revision, version, and subversion of the Perl interpreter,
638 represented as a C<version> object.
639
640 This variable first appeared in perl v5.6.0; earlier versions of perl
641 will see an undefined value.  Before perl v5.10.0 C<$^V> was represented
642 as a v-string.
643
644 C<$^V> can be used to determine whether the Perl interpreter executing
645 a script is in the right range of versions.  For example:
646
647     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
648
649 To convert C<$^V> into its string representation use C<sprintf()>'s
650 C<"%vd"> conversion:
651
652     printf "version is v%vd\n", $^V;  # Perl's version
653
654 See the documentation of C<use VERSION> and C<require VERSION>
655 for a convenient way to fail if the running Perl interpreter is too old.
656
657 See also C<$]> for an older representation of the Perl version.
658
659 This variable was added in Perl v5.6.0.
660
661 Mnemonic: use ^V for Version Control.
662
663 =item ${^WIN32_SLOPPY_STAT}
664 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
665
666 If this variable is set to a true value, then C<stat()> on Windows will
667 not try to open the file.  This means that the link count cannot be
668 determined and file attributes may be out of date if additional
669 hardlinks to the file exist.  On the other hand, not opening the file
670 is considerably faster, especially for files on network drives.
671
672 This variable could be set in the F<sitecustomize.pl> file to
673 configure the local Perl installation to use "sloppy" C<stat()> by
674 default.  See the documentation for B<-f> in
675 L<perlrun|perlrun/"Command Switches"> for more information about site
676 customization.
677
678 This variable was added in Perl v5.10.0.
679
680 =item $EXECUTABLE_NAME
681
682 =item $^X
683 X<$^X> X<$EXECUTABLE_NAME>
684
685 The name used to execute the current copy of Perl, from C's
686 C<argv[0]> or (where supported) F</proc/self/exe>.
687
688 Depending on the host operating system, the value of C<$^X> may be
689 a relative or absolute pathname of the perl program file, or may
690 be the string used to invoke perl but not the pathname of the
691 perl program file.  Also, most operating systems permit invoking
692 programs that are not in the PATH environment variable, so there
693 is no guarantee that the value of C<$^X> is in PATH.  For VMS, the
694 value may or may not include a version number.
695
696 You usually can use the value of C<$^X> to re-invoke an independent
697 copy of the same perl that is currently running, e.g.,
698
699     @first_run = `$^X -le "print int rand 100 for 1..100"`;
700
701 But recall that not all operating systems support forking or
702 capturing of the output of commands, so this complex statement
703 may not be portable.
704
705 It is not safe to use the value of C<$^X> as a path name of a file,
706 as some operating systems that have a mandatory suffix on
707 executable files do not require use of the suffix when invoking
708 a command.  To convert the value of C<$^X> to a path name, use the
709 following statements:
710
711     # Build up a set of file names (not command names).
712     use Config;
713     my $this_perl = $^X;
714     if ($^O ne 'VMS') {
715         $this_perl .= $Config{_exe}
716           unless $this_perl =~ m/$Config{_exe}$/i;
717         }
718
719 Because many operating systems permit anyone with read access to
720 the Perl program file to make a copy of it, patch the copy, and
721 then execute the copy, the security-conscious Perl programmer
722 should take care to invoke the installed copy of perl, not the
723 copy referenced by C<$^X>.  The following statements accomplish
724 this goal, and produce a pathname that can be invoked as a
725 command or referenced as a file.
726
727     use Config;
728     my $secure_perl_path = $Config{perlpath};
729     if ($^O ne 'VMS') {
730         $secure_perl_path .= $Config{_exe}
731             unless $secure_perl_path =~ m/$Config{_exe}$/i;
732         }
733
734 =back
735
736 =head2 Variables related to regular expressions
737
738 Most of the special variables related to regular expressions are side
739 effects.  Perl sets these variables when it has a successful match, so
740 you should check the match result before using them.  For instance:
741
742     if( /P(A)TT(ER)N/ ) {
743         print "I found $1 and $2\n";
744         }
745
746 These variables are read-only and dynamically-scoped, unless we note
747 otherwise.
748
749 The dynamic nature of the regular expression variables means that
750 their value is limited to the block that they are in, as demonstrated
751 by this bit of code:
752
753     my $outer = 'Wallace and Grommit';
754     my $inner = 'Mutt and Jeff';
755
756     my $pattern = qr/(\S+) and (\S+)/;
757
758     sub show_n { print "\$1 is $1; \$2 is $2\n" }
759
760     {
761     OUTER:
762         show_n() if $outer =~ m/$pattern/;
763
764         INNER: {
765             show_n() if $inner =~ m/$pattern/;
766             }
767
768         show_n();
769     }
770
771 The output shows that while in the C<OUTER> block, the values of C<$1>
772 and C<$2> are from the match against C<$outer>.  Inside the C<INNER>
773 block, the values of C<$1> and C<$2> are from the match against
774 C<$inner>, but only until the end of the block (i.e. the dynamic
775 scope).  After the C<INNER> block completes, the values of C<$1> and
776 C<$2> return to the values for the match against C<$outer> even though
777 we have not made another match:
778
779     $1 is Wallace; $2 is Grommit
780     $1 is Mutt; $2 is Jeff
781     $1 is Wallace; $2 is Grommit
782
783 Due to an unfortunate accident of Perl's implementation, C<use
784 English> imposes a considerable performance penalty on all regular
785 expression matches in a program because it uses the C<$`>, C<$&>, and
786 C<$'>, regardless of whether they occur in the scope of C<use
787 English>.  For that reason, saying C<use English> in libraries is
788 strongly discouraged unless you import it without the match variables:
789
790     use English '-no_match_vars'
791
792 The C<Devel::NYTProf> and C<Devel::FindAmpersand>
793 modules can help you find uses of these
794 problematic match variables in your code.
795
796 Since Perl v5.10.0, you can use the C</p> match operator flag and the
797 C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> variables instead
798 so you only suffer the performance penalties.
799
800 =over 8
801
802 =item $<I<digits>> ($1, $2, ...)
803 X<$1> X<$2> X<$3>
804
805 Contains the subpattern from the corresponding set of capturing
806 parentheses from the last successful pattern match, not counting patterns
807 matched in nested blocks that have been exited already.
808
809 These variables are read-only and dynamically-scoped.
810
811 Mnemonic: like \digits.
812
813 =item $MATCH
814
815 =item $&
816 X<$&> X<$MATCH>
817
818 The string matched by the last successful pattern match (not counting
819 any matches hidden within a BLOCK or C<eval()> enclosed by the current
820 BLOCK).
821
822 The use of this variable anywhere in a program imposes a considerable
823 performance penalty on all regular expression matches.  To avoid this
824 penalty, you can extract the same substring by using L</@->.  Starting
825 with Perl v5.10.0, you can use the C</p> match flag and the C<${^MATCH}>
826 variable to do the same thing for particular match operations.
827
828 This variable is read-only and dynamically-scoped.
829
830 Mnemonic: like C<&> in some editors.
831
832 =item ${^MATCH}
833 X<${^MATCH}>
834
835 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
836 performance penalty associated with that variable, and is only guaranteed
837 to return a defined value when the pattern was compiled or executed with
838 the C</p> modifier.
839
840 This variable was added in Perl v5.10.0.
841
842 This variable is read-only and dynamically-scoped.
843
844 =item $PREMATCH
845
846 =item $`
847 X<$`> X<$PREMATCH> X<${^PREMATCH}>
848
849 The string preceding whatever was matched by the last successful
850 pattern match, not counting any matches hidden within a BLOCK or C<eval>
851 enclosed by the current BLOCK.
852
853 The use of this variable anywhere in a program imposes a considerable
854 performance penalty on all regular expression matches.  To avoid this
855 penalty, you can extract the same substring by using L</@->.  Starting
856 with Perl v5.10.0, you can use the C</p> match flag and the
857 C<${^PREMATCH}> variable to do the same thing for particular match
858 operations.
859
860 This variable is read-only and dynamically-scoped.
861
862 Mnemonic: C<`> often precedes a quoted string.
863
864 =item ${^PREMATCH}
865 X<$`> X<${^PREMATCH}>
866
867 This is similar to C<$`> ($PREMATCH) except that it does not incur the
868 performance penalty associated with that variable, and is only guaranteed
869 to return a defined value when the pattern was compiled or executed with
870 the C</p> modifier.
871
872 This variable was added in Perl v5.10.0
873
874 This variable is read-only and dynamically-scoped.
875
876 =item $POSTMATCH
877
878 =item $'
879 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
880
881 The string following whatever was matched by the last successful
882 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
883 enclosed by the current BLOCK).  Example:
884
885     local $_ = 'abcdefghi';
886     /def/;
887     print "$`:$&:$'\n";         # prints abc:def:ghi
888
889 The use of this variable anywhere in a program imposes a considerable
890 performance penalty on all regular expression matches.
891 To avoid this penalty, you can extract the same substring by
892 using L</@->.  Starting with Perl v5.10.0, you can use the C</p> match flag
893 and the C<${^POSTMATCH}> variable to do the same thing for particular
894 match operations.
895
896 This variable is read-only and dynamically-scoped.
897
898 Mnemonic: C<'> often follows a quoted string.
899
900 =item ${^POSTMATCH}
901 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
902
903 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
904 performance penalty associated with that variable, and is only guaranteed
905 to return a defined value when the pattern was compiled or executed with
906 the C</p> modifier.
907
908 This variable was added in Perl v5.10.0.
909
910 This variable is read-only and dynamically-scoped.
911
912 =item $LAST_PAREN_MATCH
913
914 =item $+
915 X<$+> X<$LAST_PAREN_MATCH>
916
917 The text matched by the last bracket of the last successful search pattern.
918 This is useful if you don't know which one of a set of alternative patterns
919 matched.  For example:
920
921     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
922
923 This variable is read-only and dynamically-scoped.
924
925 Mnemonic: be positive and forward looking.
926
927 =item $LAST_SUBMATCH_RESULT
928
929 =item $^N
930 X<$^N> X<$LAST_SUBMATCH_RESULT>
931
932 The text matched by the used group most-recently closed (i.e. the group
933 with the rightmost closing parenthesis) of the last successful search
934 pattern.
935
936 This is primarily used inside C<(?{...})> blocks for examining text
937 recently matched.  For example, to effectively capture text to a variable
938 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
939
940     (?:(...)(?{ $var = $^N }))
941
942 By setting and then using C<$var> in this way relieves you from having to
943 worry about exactly which numbered set of parentheses they are.
944
945 This variable was added in Perl v5.8.0.
946
947 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
948
949 =item @LAST_MATCH_END
950
951 =item @+
952 X<@+> X<@LAST_MATCH_END>
953
954 This array holds the offsets of the ends of the last successful
955 submatches in the currently active dynamic scope.  C<$+[0]> is
956 the offset into the string of the end of the entire match.  This
957 is the same value as what the C<pos> function returns when called
958 on the variable that was matched against.  The I<n>th element
959 of this array holds the offset of the I<n>th submatch, so
960 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
961 past where C<$2> ends, and so on.  You can use C<$#+> to determine
962 how many subgroups were in the last successful match.  See the
963 examples given for the C<@-> variable.
964
965 This variable was added in Perl v5.6.0.
966
967 =item %LAST_PAREN_MATCH
968
969 =item %+
970 X<%+> X<%LAST_PAREN_MATCH>
971
972 Similar to C<@+>, the C<%+> hash allows access to the named capture
973 buffers, should they exist, in the last successful match in the
974 currently active dynamic scope.
975
976 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
977
978     'foo' =~ /(?<foo>foo)/;
979
980 The keys of the C<%+> hash list only the names of buffers that have
981 captured (and that are thus associated to defined values).
982
983 The underlying behaviour of C<%+> is provided by the
984 L<Tie::Hash::NamedCapture> module.
985
986 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
987 associated with the last successful regular expression.  Therefore mixing
988 iterative access to them via C<each> may have unpredictable results.
989 Likewise, if the last successful match changes, then the results may be
990 surprising.
991
992 This variable was added in Perl v5.10.0.
993
994 This variable is read-only and dynamically-scoped.
995
996 =item @LAST_MATCH_START
997
998 =item @-
999 X<@-> X<@LAST_MATCH_START>
1000
1001 C<$-[0]> is the offset of the start of the last successful match.
1002 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
1003 I<n>-th subpattern, or undef if the subpattern did not match.
1004
1005 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
1006 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
1007 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
1008 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the
1009 last matched subgroup in the last successful match.  Contrast with
1010 C<$#+>, the number of subgroups in the regular expression.  Compare
1011 with C<@+>.
1012
1013 This array holds the offsets of the beginnings of the last
1014 successful submatches in the currently active dynamic scope.
1015 C<$-[0]> is the offset into the string of the beginning of the
1016 entire match.  The I<n>th element of this array holds the offset
1017 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1018 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1019
1020 After a match against some variable C<$var>:
1021
1022 =over 5
1023
1024 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1025
1026 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1027
1028 =item C<$'> is the same as C<substr($var, $+[0])>
1029
1030 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1031
1032 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1033
1034 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1035
1036 =back
1037
1038 This variable was added in Perl v5.6.0.
1039
1040 =item %LAST_MATCH_START
1041
1042 =item %-
1043 X<%-> X<%LAST_MATCH_START>
1044
1045 Similar to C<%+>, this variable allows access to the named capture groups
1046 in the last successful match in the currently active dynamic scope.  To
1047 each capture group name found in the regular expression, it associates a
1048 reference to an array containing the list of values captured by all
1049 buffers with that name (should there be several of them), in the order
1050 where they appear.
1051
1052 Here's an example:
1053
1054     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1055         foreach my $bufname (sort keys %-) {
1056             my $ary = $-{$bufname};
1057             foreach my $idx (0..$#$ary) {
1058                 print "\$-{$bufname}[$idx] : ",
1059                       (defined($ary->[$idx])
1060                           ? "'$ary->[$idx]'"
1061                           : "undef"),
1062                       "\n";
1063             }
1064         }
1065     }
1066
1067 would print out:
1068
1069     $-{A}[0] : '1'
1070     $-{A}[1] : '3'
1071     $-{B}[0] : '2'
1072     $-{B}[1] : '4'
1073
1074 The keys of the C<%-> hash correspond to all buffer names found in
1075 the regular expression.
1076
1077 The behaviour of C<%-> is implemented via the
1078 L<Tie::Hash::NamedCapture> module.
1079
1080 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1081 associated with the last successful regular expression.  Therefore mixing
1082 iterative access to them via C<each> may have unpredictable results.
1083 Likewise, if the last successful match changes, then the results may be
1084 surprising.
1085
1086 This variable was added in Perl v5.10.0.
1087
1088 This variable is read-only and dynamically-scoped.
1089
1090 =item $LAST_REGEXP_CODE_RESULT
1091
1092 =item $^R
1093 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1094
1095 The result of evaluation of the last successful C<(?{ code })>
1096 regular expression assertion (see L<perlre>).  May be written to.
1097
1098 This variable was added in Perl 5.005.
1099
1100 =item ${^RE_DEBUG_FLAGS}
1101 X<${^RE_DEBUG_FLAGS}>
1102
1103 The current value of the regex debugging flags.  Set to 0 for no debug output
1104 even when the C<re 'debug'> module is loaded.  See L<re> for details.
1105
1106 This variable was added in Perl v5.10.0.
1107
1108 =item ${^RE_TRIE_MAXBUF}
1109 X<${^RE_TRIE_MAXBUF}>
1110
1111 Controls how certain regex optimisations are applied and how much memory they
1112 utilize.  This value by default is 65536 which corresponds to a 512kB
1113 temporary cache.  Set this to a higher value to trade
1114 memory for speed when matching large alternations.  Set
1115 it to a lower value if you want the optimisations to
1116 be as conservative of memory as possible but still occur, and set it to a
1117 negative value to prevent the optimisation and conserve the most memory.
1118 Under normal situations this variable should be of no interest to you.
1119
1120 This variable was added in Perl v5.10.0.
1121
1122 =back
1123
1124 =head2 Variables related to filehandles
1125
1126 Variables that depend on the currently selected filehandle may be set
1127 by calling an appropriate object method on the C<IO::Handle> object,
1128 although this is less efficient than using the regular built-in
1129 variables.  (Summary lines below for this contain the word HANDLE.)
1130 First you must say
1131
1132     use IO::Handle;
1133
1134 after which you may use either
1135
1136     method HANDLE EXPR
1137
1138 or more safely,
1139
1140     HANDLE->method(EXPR)
1141
1142 Each method returns the old value of the C<IO::Handle> attribute.  The
1143 methods each take an optional EXPR, which, if supplied, specifies the
1144 new value for the C<IO::Handle> attribute in question.  If not
1145 supplied, most methods do nothing to the current value--except for
1146 C<autoflush()>, which will assume a 1 for you, just to be different.
1147
1148 Because loading in the C<IO::Handle> class is an expensive operation,
1149 you should learn how to use the regular built-in variables.
1150
1151 A few of these variables are considered "read-only".  This means that
1152 if you try to assign to this variable, either directly or indirectly
1153 through a reference, you'll raise a run-time exception.
1154
1155 You should be very careful when modifying the default values of most
1156 special variables described in this document.  In most cases you want
1157 to localize these variables before changing them, since if you don't,
1158 the change may affect other modules which rely on the default values
1159 of the special variables that you have changed.  This is one of the
1160 correct ways to read the whole file at once:
1161
1162     open my $fh, "<", "foo" or die $!;
1163     local $/; # enable localized slurp mode
1164     my $content = <$fh>;
1165     close $fh;
1166
1167 But the following code is quite bad:
1168
1169     open my $fh, "<", "foo" or die $!;
1170     undef $/; # enable slurp mode
1171     my $content = <$fh>;
1172     close $fh;
1173
1174 since some other module, may want to read data from some file in the
1175 default "line mode", so if the code we have just presented has been
1176 executed, the global value of C<$/> is now changed for any other code
1177 running inside the same Perl interpreter.
1178
1179 Usually when a variable is localized you want to make sure that this
1180 change affects the shortest scope possible.  So unless you are already
1181 inside some short C<{}> block, you should create one yourself.  For
1182 example:
1183
1184     my $content = '';
1185     open my $fh, "<", "foo" or die $!;
1186     {
1187         local $/;
1188         $content = <$fh>;
1189     }
1190     close $fh;
1191
1192 Here is an example of how your own code can go broken:
1193
1194     for ( 1..3 ){
1195         $\ = "\r\n";
1196         nasty_break();
1197         print "$_";
1198     }
1199
1200     sub nasty_break {
1201         $\ = "\f";
1202         # do something with $_
1203     }
1204
1205 You probably expect this code to print the equivalent of
1206
1207     "1\r\n2\r\n3\r\n"
1208
1209 but instead you get:
1210
1211     "1\f2\f3\f"
1212
1213 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1214 first.  The value you set in  C<nasty_break()> is still there when you
1215 return.  The fix is to add C<local()> so the value doesn't leak out of
1216 C<nasty_break()>:
1217
1218     local $\ = "\f";
1219
1220 It's easy to notice the problem in such a short example, but in more
1221 complicated code you are looking for trouble if you don't localize
1222 changes to the special variables.
1223
1224 =over 8
1225
1226 =item $ARGV
1227 X<$ARGV>
1228
1229 Contains the name of the current file when reading from C<< <> >>.
1230
1231 =item @ARGV
1232 X<@ARGV>
1233
1234 The array C<@ARGV> contains the command-line arguments intended for
1235 the script.  C<$#ARGV> is generally the number of arguments minus
1236 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1237 command name itself.  See L</$0> for the command name.
1238
1239 =item ARGV
1240 X<ARGV>
1241
1242 The special filehandle that iterates over command-line filenames in
1243 C<@ARGV>.  Usually written as the null filehandle in the angle operator
1244 C<< <> >>.  Note that currently C<ARGV> only has its magical effect
1245 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1246 corresponding to the last file opened by C<< <> >>.  In particular,
1247 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1248 may not cause your function to automatically read the contents of all the
1249 files in C<@ARGV>.
1250
1251 =item ARGVOUT
1252 X<ARGVOUT>
1253
1254 The special filehandle that points to the currently open output file
1255 when doing edit-in-place processing with B<-i>.  Useful when you have
1256 to do a lot of inserting and don't want to keep modifying C<$_>.  See
1257 L<perlrun> for the B<-i> switch.
1258
1259 =item Handle->output_field_separator( EXPR )
1260
1261 =item $OUTPUT_FIELD_SEPARATOR
1262
1263 =item $OFS
1264
1265 =item $,
1266 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1267
1268 The output field separator for the print operator.  If defined, this
1269 value is printed between each of print's arguments.  Default is C<undef>.
1270
1271 Mnemonic: what is printed when there is a "," in your print statement.
1272
1273 =item HANDLE->input_line_number( EXPR )
1274
1275 =item $INPUT_LINE_NUMBER
1276
1277 =item $NR
1278
1279 =item $.
1280 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1281
1282 Current line number for the last filehandle accessed.
1283
1284 Each filehandle in Perl counts the number of lines that have been read
1285 from it.  (Depending on the value of C<$/>, Perl's idea of what
1286 constitutes a line may not match yours.)  When a line is read from a
1287 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1288 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1289 for that filehandle.
1290
1291 You can adjust the counter by assigning to C<$.>, but this will not
1292 actually move the seek pointer.  I<Localizing C<$.> will not localize
1293 the filehandle's line count>.  Instead, it will localize perl's notion
1294 of which filehandle C<$.> is currently aliased to.
1295
1296 C<$.> is reset when the filehandle is closed, but B<not> when an open
1297 filehandle is reopened without an intervening C<close()>.  For more
1298 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
1299 an explicit close, line numbers increase across C<ARGV> files (but see
1300 examples in L<perlfunc/eof>).
1301
1302 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1303 line counter for a given filehandle without having to worry about
1304 which handle you last accessed.
1305
1306 Mnemonic: many programs use "." to mean the current line number.
1307
1308 =item HANDLE->input_record_separator( EXPR )
1309
1310 =item $INPUT_RECORD_SEPARATOR
1311
1312 =item $RS
1313
1314 =item $/
1315 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1316
1317 The input record separator, newline by default.  This influences Perl's
1318 idea of what a "line" is.  Works like B<awk>'s RS variable, including
1319 treating empty lines as a terminator if set to the null string (an
1320 empty line cannot contain any spaces or tabs).  You may set it to a
1321 multi-character string to match a multi-character terminator, or to
1322 C<undef> to read through the end of file.  Setting it to C<"\n\n">
1323 means something slightly different than setting to C<"">, if the file
1324 contains consecutive empty lines.  Setting to C<""> will treat two or
1325 more consecutive empty lines as a single empty line.  Setting to
1326 C<"\n\n"> will blindly assume that the next input character belongs to
1327 the next paragraph, even if it's a newline.
1328
1329     local $/;           # enable "slurp" mode
1330     local $_ = <FH>;    # whole file now here
1331     s/\n[ \t]+/ /g;
1332
1333 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to
1334 be better for something. :-)
1335
1336 Setting C<$/> to a reference to an integer, scalar containing an
1337 integer, or scalar that's convertible to an integer will attempt to
1338 read records instead of lines, with the maximum record size being the
1339 referenced integer.  So this:
1340
1341     local $/ = \32768; # or \"32768", or \$var_containing_32768
1342     open my $fh, "<", $myfile or die $!;
1343     local $_ = <$fh>;
1344
1345 will read a record of no more than 32768 bytes from FILE.  If you're
1346 not reading from a record-oriented file (or your OS doesn't have
1347 record-oriented files), then you'll likely get a full chunk of data
1348 with every read.  If a record is larger than the record size you've
1349 set, you'll get the record back in pieces.  Trying to set the record
1350 size to zero or less will cause reading in the (rest of the) whole file.
1351
1352 On VMS only, record reads bypass PerlIO layers and any associated
1353 buffering,so you must not mix record and non-record reads on the
1354 same filehandle.  Record mode mixes with line mode only when the
1355 same buffering layer is in use for both modes.
1356
1357 If you perform a record read on a FILE with an encoding layer such as
1358 C<:encoding(latin1)> or C<:utf8>, you may get an invalid string as a
1359 result, may leave the FILE positioned between characters in the stream
1360 and may not be reading the number of bytes from the underlying file
1361 that you specified.  This behaviour may change without warning in a
1362 future version of perl.
1363
1364 See also L<perlport/"Newlines">. Also see L</$.>.
1365
1366 Mnemonic: / delimits line boundaries when quoting poetry.
1367
1368 =item Handle->output_record_separator( EXPR )
1369
1370 =item $OUTPUT_RECORD_SEPARATOR
1371
1372 =item $ORS
1373
1374 =item $\
1375 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1376
1377 The output record separator for the print operator.  If defined, this
1378 value is printed after the last of print's arguments.  Default is C<undef>.
1379
1380 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1381 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1382
1383 =item HANDLE->autoflush( EXPR )
1384
1385 =item $OUTPUT_AUTOFLUSH
1386
1387 =item $|
1388 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1389
1390 If set to nonzero, forces a flush right away and after every write or
1391 print on the currently selected output channel.  Default is 0
1392 (regardless of whether the channel is really buffered by the system or
1393 not; C<$|> tells you only whether you've asked Perl explicitly to
1394 flush after each write).  STDOUT will typically be line buffered if
1395 output is to the terminal and block buffered otherwise.  Setting this
1396 variable is useful primarily when you are outputting to a pipe or
1397 socket, such as when you are running a Perl program under B<rsh> and
1398 want to see the output as it's happening.  This has no effect on input
1399 buffering.  See L<perlfunc/getc> for that.  See L<perlfunc/select> on
1400 how to select the output channel.  See also L<IO::Handle>.
1401
1402 Mnemonic: when you want your pipes to be piping hot.
1403
1404 =back
1405
1406 =head3 Variables related to formats
1407
1408 The special variables for formats are a subset of those for
1409 filehandles.  See L<perlform> for more information about Perl's
1410 formats.
1411
1412 =over 8
1413
1414 =item $ACCUMULATOR
1415
1416 =item $^A
1417 X<$^A> X<$ACCUMULATOR>
1418
1419 The current value of the C<write()> accumulator for C<format()> lines.
1420 A format contains C<formline()> calls that put their result into
1421 C<$^A>.  After calling its format, C<write()> prints out the contents
1422 of C<$^A> and empties.  So you never really see the contents of C<$^A>
1423 unless you call C<formline()> yourself and then look at it.  See
1424 L<perlform> and L<perlfunc/"formline PICTURE,LIST">.
1425
1426 =item HANDLE->format_formfeed(EXPR)
1427
1428 =item $FORMAT_FORMFEED
1429
1430 =item $^L
1431 X<$^L> X<$FORMAT_FORMFEED>
1432
1433 What formats output as a form feed.  The default is C<\f>.
1434
1435 =item HANDLE->format_page_number(EXPR)
1436
1437 =item $FORMAT_PAGE_NUMBER
1438
1439 =item $%
1440 X<$%> X<$FORMAT_PAGE_NUMBER>
1441
1442 The current page number of the currently selected output channel.
1443
1444 Mnemonic: C<%> is page number in B<nroff>.
1445
1446 =item HANDLE->format_lines_left(EXPR)
1447
1448 =item $FORMAT_LINES_LEFT
1449
1450 =item $-
1451 X<$-> X<$FORMAT_LINES_LEFT>
1452
1453 The number of lines left on the page of the currently selected output
1454 channel.
1455
1456 Mnemonic: lines_on_page - lines_printed.
1457
1458 =item Handle->format_line_break_characters EXPR
1459
1460 =item $FORMAT_LINE_BREAK_CHARACTERS
1461
1462 =item $:
1463 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1464
1465 The current set of characters after which a string may be broken to
1466 fill continuation fields (starting with C<^>) in a format.  The default is
1467 S<" \n-">, to break on a space, newline, or a hyphen.
1468
1469 Mnemonic: a "colon" in poetry is a part of a line.
1470
1471 =item HANDLE->format_lines_per_page(EXPR)
1472
1473 =item $FORMAT_LINES_PER_PAGE
1474
1475 =item $=
1476 X<$=> X<$FORMAT_LINES_PER_PAGE>
1477
1478 The current page length (printable lines) of the currently selected
1479 output channel.  The default is 60.
1480
1481 Mnemonic: = has horizontal lines.
1482
1483 =item HANDLE->format_top_name(EXPR)
1484
1485 =item $FORMAT_TOP_NAME
1486
1487 =item $^
1488 X<$^> X<$FORMAT_TOP_NAME>
1489
1490 The name of the current top-of-page format for the currently selected
1491 output channel.  The default is the name of the filehandle with C<_TOP>
1492 appended.  For example, the default format top name for the C<STDOUT>
1493 filehandle is C<STDOUT_TOP>.
1494
1495 Mnemonic: points to top of page.
1496
1497 =item HANDLE->format_name(EXPR)
1498
1499 =item $FORMAT_NAME
1500
1501 =item $~
1502 X<$~> X<$FORMAT_NAME>
1503
1504 The name of the current report format for the currently selected
1505 output channel.  The default format name is the same as the filehandle
1506 name.  For example, the default format name for the C<STDOUT>
1507 filehandle is just C<STDOUT>.
1508
1509 Mnemonic: brother to C<$^>.
1510
1511 =back
1512
1513 =head2 Error Variables
1514 X<error> X<exception>
1515
1516 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1517 about different types of error conditions that may appear during
1518 execution of a Perl program.  The variables are shown ordered by
1519 the "distance" between the subsystem which reported the error and
1520 the Perl process.  They correspond to errors detected by the Perl
1521 interpreter, C library, operating system, or an external program,
1522 respectively.
1523
1524 To illustrate the differences between these variables, consider the
1525 following Perl expression, which uses a single-quoted string.  After
1526 execution of this statement, perl may have set all four special error
1527 variables:
1528
1529     eval q{
1530         open my $pipe, "/cdrom/install |" or die $!;
1531         my @res = <$pipe>;
1532         close $pipe or die "bad pipe: $?, $!";
1533     };
1534
1535 When perl executes the C<eval()> expression, it translates the
1536 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1537 and thence to the operating system kernel.  perl sets C<$!> to
1538 the C library's C<errno> if one of these calls fails.
1539
1540 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1541 happen if C<open> or C<close> were imported with bad prototypes), or
1542 if Perl code executed during evaluation C<die()>d.  In these cases the
1543 value of C<$@> is the compile error, or the argument to C<die> (which
1544 will interpolate C<$!> and C<$?>).  (See also L<Fatal>, though.)
1545
1546 Under a few operating systems, C<$^E> may contain a more verbose error
1547 indicator, such as in this case, "CDROM tray not closed."  Systems that
1548 do not support extended error messages leave C<$^E> the same as C<$!>.
1549
1550 Finally, C<$?> may be set to non-0 value if the external program
1551 F</cdrom/install> fails.  The upper eight bits reflect specific error
1552 conditions encountered by the program (the program's C<exit()> value).
1553 The lower eight bits reflect mode of failure, like signal death and
1554 core dump information.  See L<wait(2)> for details.  In contrast to
1555 C<$!> and C<$^E>, which are set only if error condition is detected,
1556 the variable C<$?> is set on each C<wait> or pipe C<close>,
1557 overwriting the old value.  This is more like C<$@>, which on every
1558 C<eval()> is always set on failure and cleared on success.
1559
1560 For more details, see the individual descriptions at C<$@>, C<$!>,
1561 C<$^E>, and C<$?>.
1562
1563 =over 8
1564
1565 =item ${^CHILD_ERROR_NATIVE}
1566 X<$^CHILD_ERROR_NATIVE>
1567
1568 The native status returned by the last pipe close, backtick (C<``>)
1569 command, successful call to C<wait()> or C<waitpid()>, or from the
1570 C<system()> operator.  On POSIX-like systems this value can be decoded
1571 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1572 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1573
1574 Under VMS this reflects the actual VMS exit status; i.e. it is the
1575 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1576
1577 This variable was added in Perl v5.10.0.
1578
1579 =item $EXTENDED_OS_ERROR
1580
1581 =item $^E
1582 X<$^E> X<$EXTENDED_OS_ERROR>
1583
1584 Error information specific to the current operating system.  At the
1585 moment, this differs from C<$!> under only VMS, OS/2, and Win32 (and
1586 for MacPerl).  On all other platforms, C<$^E> is always just the same
1587 as C<$!>.
1588
1589 Under VMS, C<$^E> provides the VMS status value from the last system
1590 error.  This is more specific information about the last system error
1591 than that provided by C<$!>.  This is particularly important when C<$!>
1592 is set to B<EVMSERR>.
1593
1594 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1595 API either via CRT, or directly from perl.
1596
1597 Under Win32, C<$^E> always returns the last error information reported
1598 by the Win32 call C<GetLastError()> which describes the last error
1599 from within the Win32 API.  Most Win32-specific code will report errors
1600 via C<$^E>.  ANSI C and Unix-like calls set C<errno> and so most
1601 portable Perl code will report errors via C<$!>.
1602
1603 Caveats mentioned in the description of C<$!> generally apply to
1604 C<$^E>, also.
1605
1606 This variable was added in Perl 5.003.
1607
1608 Mnemonic: Extra error explanation.
1609
1610 =item $EXCEPTIONS_BEING_CAUGHT
1611
1612 =item $^S
1613 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1614
1615 Current state of the interpreter.
1616
1617         $^S         State
1618         ---------   -------------------------------------
1619         undef       Parsing module, eval, or main program
1620         true (1)    Executing an eval
1621         false (0)   Otherwise
1622
1623 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1624 handlers.
1625
1626 The English name $EXCEPTIONS_BEING_CAUGHT is slightly misleading, because
1627 the C<undef> value does not indicate whether exceptions are being caught,
1628 since compilation of the main program does not catch exceptions.
1629
1630 This variable was added in Perl 5.004.
1631
1632 =item $WARNING
1633
1634 =item $^W
1635 X<$^W> X<$WARNING>
1636
1637 The current value of the warning switch, initially true if B<-w> was
1638 used, false otherwise, but directly modifiable.
1639
1640 See also L<warnings>.
1641
1642 Mnemonic: related to the B<-w> switch.
1643
1644 =item ${^WARNING_BITS}
1645 X<${^WARNING_BITS}>
1646
1647 The current set of warning checks enabled by the C<use warnings> pragma.
1648 It has the same scoping as the C<$^H> and C<%^H> variables.  The exact
1649 values are considered internal to the L<warnings> pragma and may change
1650 between versions of Perl.
1651
1652 This variable was added in Perl v5.6.0.
1653
1654 =item $OS_ERROR
1655
1656 =item $ERRNO
1657
1658 =item $!
1659 X<$!> X<$ERRNO> X<$OS_ERROR>
1660
1661 When referenced, C<$!> retrieves the current value
1662 of the C C<errno> integer variable.
1663 If C<$!> is assigned a numerical value, that value is stored in C<errno>.
1664 When referenced as a string, C<$!> yields the system error string
1665 corresponding to C<errno>.
1666
1667 Many system or library calls set C<errno> if they fail,
1668 to indicate the cause of failure.  They usually do B<not>
1669 set C<errno> to zero if they succeed.  This means C<errno>,
1670 hence C<$!>, is meaningful only I<immediately> after a B<failure>:
1671
1672     if (open my $fh, "<", $filename) {
1673                 # Here $! is meaningless.
1674                 ...
1675     }
1676     else {
1677                 # ONLY here is $! meaningful.
1678                 ...
1679                 # Already here $! might be meaningless.
1680     }
1681     # Since here we might have either success or failure,
1682     # $! is meaningless.
1683
1684 Here, I<meaningless> means that C<$!> may be unrelated to the outcome
1685 of the C<open()> operator.  Assignment to C<$!> is similarly ephemeral.
1686 It can be used immediately before invoking the C<die()> operator,
1687 to set the exit value, or to inspect the system error string
1688 corresponding to error I<n>, or to restore C<$!> to a meaningful state.
1689
1690 Mnemonic: What just went bang?
1691
1692 =item %OS_ERROR
1693
1694 =item %ERRNO
1695
1696 =item %!
1697 X<%!> X<%OS_ERROR> X<%ERRNO>
1698
1699 Each element of C<%!> has a true value only if C<$!> is set to that
1700 value.  For example, C<$!{ENOENT}> is true if and only if the current
1701 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1702 such file or directory" (or its moral equivalent: not all operating
1703 systems give that exact error, and certainly not all languages).  To
1704 check if a particular key is meaningful on your system, use C<exists
1705 $!{the_key}>; for a list of legal keys, use C<keys %!>.  See L<Errno>
1706 for more information, and also see L</$!>.
1707
1708 This variable was added in Perl 5.005.
1709
1710 =item $CHILD_ERROR
1711
1712 =item $?
1713 X<$?> X<$CHILD_ERROR>
1714
1715 The status returned by the last pipe close, backtick (C<``>) command,
1716 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1717 operator.  This is just the 16-bit status word returned by the
1718 traditional Unix C<wait()> system call (or else is made up to look
1719 like it).  Thus, the exit value of the subprocess is really (C<<< $? >>
1720 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1721 from, and C<$? & 128> reports whether there was a core dump.
1722
1723 Additionally, if the C<h_errno> variable is supported in C, its value
1724 is returned via C<$?> if any C<gethost*()> function fails.
1725
1726 If you have installed a signal handler for C<SIGCHLD>, the
1727 value of C<$?> will usually be wrong outside that handler.
1728
1729 Inside an C<END> subroutine C<$?> contains the value that is going to be
1730 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
1731 change the exit status of your program.  For example:
1732
1733     END {
1734         $? = 1 if $? == 255;  # die would make it 255
1735     }
1736
1737 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1738 actual VMS exit status, instead of the default emulation of POSIX
1739 status; see L<perlvms/$?> for details.
1740
1741 Mnemonic: similar to B<sh> and B<ksh>.
1742
1743 =item $EVAL_ERROR
1744
1745 =item $@
1746 X<$@> X<$EVAL_ERROR>
1747
1748 The Perl syntax error message from the
1749 last C<eval()> operator.  If C<$@> is
1750 the null string, the last C<eval()> parsed and executed correctly
1751 (although the operations you invoked may have failed in the normal
1752 fashion).
1753
1754 Warning messages are not collected in this variable.  You can, however,
1755 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
1756 described in L</%SIG>.
1757
1758 Mnemonic: Where was the syntax error "at"?
1759
1760 =back
1761
1762 =head2 Variables related to the interpreter state
1763
1764 These variables provide information about the current interpreter state.
1765
1766 =over 8
1767
1768 =item $COMPILING
1769
1770 =item $^C
1771 X<$^C> X<$COMPILING>
1772
1773 The current value of the flag associated with the B<-c> switch.
1774 Mainly of use with B<-MO=...> to allow code to alter its behavior
1775 when being compiled, such as for example to C<AUTOLOAD> at compile
1776 time rather than normal, deferred loading.  Setting
1777 C<$^C = 1> is similar to calling C<B::minus_c>.
1778
1779 This variable was added in Perl v5.6.0.
1780
1781 =item $DEBUGGING
1782
1783 =item $^D
1784 X<$^D> X<$DEBUGGING>
1785
1786 The current value of the debugging flags.  May be read or set.  Like its
1787 command-line equivalent, you can use numeric or symbolic values, eg
1788 C<$^D = 10> or C<$^D = "st">.
1789
1790 Mnemonic: value of B<-D> switch.
1791
1792 =item ${^ENCODING}
1793 X<${^ENCODING}>
1794
1795 The I<object reference> to the C<Encode> object that is used to convert
1796 the source code to Unicode.  Thanks to this variable your Perl script
1797 does not have to be written in UTF-8.  Default is I<undef>.  The direct
1798 manipulation of this variable is highly discouraged.
1799
1800 This variable was added in Perl 5.8.2.
1801
1802 =item ${^GLOBAL_PHASE}
1803 X<${^GLOBAL_PHASE}>
1804
1805 The current phase of the perl interpreter.
1806
1807 Possible values are:
1808
1809 =over 8
1810
1811 =item CONSTRUCT
1812
1813 The C<PerlInterpreter*> is being constructed via C<perl_construct>.  This
1814 value is mostly there for completeness and for use via the
1815 underlying C variable C<PL_phase>.  It's not really possible for Perl
1816 code to be executed unless construction of the interpreter is
1817 finished.
1818
1819 =item START
1820
1821 This is the global compile-time.  That includes, basically, every
1822 C<BEGIN> block executed directly or indirectly from during the
1823 compile-time of the top-level program.
1824
1825 This phase is not called "BEGIN" to avoid confusion with
1826 C<BEGIN>-blocks, as those are executed during compile-time of any
1827 compilation unit, not just the top-level program.  A new, localised
1828 compile-time entered at run-time, for example by constructs as
1829 C<eval "use SomeModule"> are not global interpreter phases, and
1830 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
1831
1832 =item CHECK
1833
1834 Execution of any C<CHECK> blocks.
1835
1836 =item INIT
1837
1838 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
1839
1840 =item RUN
1841
1842 The main run-time, i.e. the execution of C<PL_main_root>.
1843
1844 =item END
1845
1846 Execution of any C<END> blocks.
1847
1848 =item DESTRUCT
1849
1850 Global destruction.
1851
1852 =back
1853
1854 Also note that there's no value for UNITCHECK-blocks.  That's because
1855 those are run for each compilation unit individually, and therefore is
1856 not a global interpreter phase.
1857
1858 Not every program has to go through each of the possible phases, but
1859 transition from one phase to another can only happen in the order
1860 described in the above list.
1861
1862 An example of all of the phases Perl code can see:
1863
1864     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
1865
1866     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
1867
1868     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
1869
1870     {
1871         package Print::Phase;
1872
1873         sub new {
1874             my ($class, $time) = @_;
1875             return bless \$time, $class;
1876         }
1877
1878         sub DESTROY {
1879             my $self = shift;
1880             print "$$self: ${^GLOBAL_PHASE}\n";
1881         }
1882     }
1883
1884     print "run-time: ${^GLOBAL_PHASE}\n";
1885
1886     my $runtime = Print::Phase->new(
1887         "lexical variables are garbage collected before END"
1888     );
1889
1890     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
1891
1892     our $destruct = Print::Phase->new(
1893         "package variables are garbage collected after END"
1894     );
1895
1896 This will print out
1897
1898     compile-time: START
1899     check-time: CHECK
1900     init-time: INIT
1901     run-time: RUN
1902     lexical variables are garbage collected before END: RUN
1903     end-time: END
1904     package variables are garbage collected after END: DESTRUCT
1905
1906 This variable was added in Perl 5.14.0.
1907
1908 =item $^H
1909 X<$^H>
1910
1911 WARNING: This variable is strictly for
1912 internal use only.  Its availability,
1913 behavior, and contents are subject to change without notice.
1914
1915 This variable contains compile-time hints for the Perl interpreter.  At the
1916 end of compilation of a BLOCK the value of this variable is restored to the
1917 value when the interpreter started to compile the BLOCK.
1918
1919 When perl begins to parse any block construct that provides a lexical scope
1920 (e.g., eval body, required file, subroutine body, loop body, or conditional
1921 block), the existing value of C<$^H> is saved, but its value is left unchanged.
1922 When the compilation of the block is completed, it regains the saved value.
1923 Between the points where its value is saved and restored, code that
1924 executes within BEGIN blocks is free to change the value of C<$^H>.
1925
1926 This behavior provides the semantic of lexical scoping, and is used in,
1927 for instance, the C<use strict> pragma.
1928
1929 The contents should be an integer; different bits of it are used for
1930 different pragmatic flags.  Here's an example:
1931
1932     sub add_100 { $^H |= 0x100 }
1933
1934     sub foo {
1935         BEGIN { add_100() }
1936         bar->baz($boon);
1937     }
1938
1939 Consider what happens during execution of the BEGIN block.  At this point
1940 the BEGIN block has already been compiled, but the body of C<foo()> is still
1941 being compiled.  The new value of C<$^H>
1942 will therefore be visible only while
1943 the body of C<foo()> is being compiled.
1944
1945 Substitution of C<BEGIN { add_100() }> block with:
1946
1947     BEGIN { require strict; strict->import('vars') }
1948
1949 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
1950 version of the same lexical pragma:
1951
1952     BEGIN {
1953         require strict; strict->import('vars') if $condition
1954     }
1955
1956 This variable was added in Perl 5.003.
1957
1958 =item %^H
1959 X<%^H>
1960
1961 The C<%^H> hash provides the same scoping semantic as C<$^H>.  This makes
1962 it useful for implementation of lexically scoped pragmas.  See
1963 L<perlpragma>.
1964
1965 When putting items into C<%^H>, in order to avoid conflicting with other
1966 users of the hash there is a convention regarding which keys to use.
1967 A module should use only keys that begin with the module's name (the
1968 name of its main package) and a "/" character.  For example, a module
1969 C<Foo::Bar> should use keys such as C<Foo::Bar/baz>.
1970
1971 This variable was added in Perl v5.6.0.
1972
1973 =item ${^OPEN}
1974 X<${^OPEN}>
1975
1976 An internal variable used by PerlIO.  A string in two parts, separated
1977 by a C<\0> byte, the first part describes the input layers, the second
1978 part describes the output layers.
1979
1980 This variable was added in Perl v5.8.0.
1981
1982 =item $PERLDB
1983
1984 =item $^P
1985 X<$^P> X<$PERLDB>
1986
1987 The internal variable for debugging support.  The meanings of the
1988 various bits are subject to change, but currently indicate:
1989
1990 =over 6
1991
1992 =item 0x01
1993
1994 Debug subroutine enter/exit.
1995
1996 =item 0x02
1997
1998 Line-by-line debugging.  Causes C<DB::DB()> subroutine to be called for
1999 each statement executed.  Also causes saving source code lines (like
2000 0x400).
2001
2002 =item 0x04
2003
2004 Switch off optimizations.
2005
2006 =item 0x08
2007
2008 Preserve more data for future interactive inspections.
2009
2010 =item 0x10
2011
2012 Keep info about source lines on which a subroutine is defined.
2013
2014 =item 0x20
2015
2016 Start with single-step on.
2017
2018 =item 0x40
2019
2020 Use subroutine address instead of name when reporting.
2021
2022 =item 0x80
2023
2024 Report C<goto &subroutine> as well.
2025
2026 =item 0x100
2027
2028 Provide informative "file" names for evals based on the place they were compiled.
2029
2030 =item 0x200
2031
2032 Provide informative names to anonymous subroutines based on the place they
2033 were compiled.
2034
2035 =item 0x400
2036
2037 Save source code lines into C<@{"_<$filename"}>.
2038
2039 =back
2040
2041 Some bits may be relevant at compile-time only, some at
2042 run-time only.  This is a new mechanism and the details may change.
2043 See also L<perldebguts>.
2044
2045 =item ${^TAINT}
2046 X<${^TAINT}>
2047
2048 Reflects if taint mode is on or off.  1 for on (the program was run with
2049 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
2050 B<-t> or B<-TU>).
2051
2052 This variable is read-only.
2053
2054 This variable was added in Perl v5.8.0.
2055
2056 =item ${^UNICODE}
2057 X<${^UNICODE}>
2058
2059 Reflects certain Unicode settings of Perl.  See L<perlrun>
2060 documentation for the C<-C> switch for more information about
2061 the possible values.
2062
2063 This variable is set during Perl startup and is thereafter read-only.
2064
2065 This variable was added in Perl v5.8.2.
2066
2067 =item ${^UTF8CACHE}
2068 X<${^UTF8CACHE}>
2069
2070 This variable controls the state of the internal UTF-8 offset caching code.
2071 1 for on (the default), 0 for off, -1 to debug the caching code by checking
2072 all its results against linear scans, and panicking on any discrepancy.
2073
2074 This variable was added in Perl v5.8.9.
2075
2076 =item ${^UTF8LOCALE}
2077 X<${^UTF8LOCALE}>
2078
2079 This variable indicates whether a UTF-8 locale was detected by perl at
2080 startup.  This information is used by perl when it's in
2081 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
2082 switch); see L<perlrun> for more info on this.
2083
2084 This variable was added in Perl v5.8.8.
2085
2086 =back
2087
2088 =head2 Deprecated and removed variables
2089
2090 Deprecating a variable announces the intent of the perl maintainers to
2091 eventually remove the variable from the language.  It may still be
2092 available despite its status.  Using a deprecated variable triggers
2093 a warning.
2094
2095 Once a variable is removed, its use triggers an error telling you
2096 the variable is unsupported.
2097
2098 See L<perldiag> for details about error messages.
2099
2100 =over 8
2101
2102 =item $OFMT
2103
2104 =item $#
2105 X<$#> X<$OFMT>
2106
2107 C<$#> was a variable that could be used to format printed numbers.
2108 After a deprecation cycle, its magic was removed in Perl v5.10.0 and
2109 using it now triggers a warning: C<$# is no longer supported>.
2110
2111 This is not the sigil you use in front of an array name to get the
2112 last index, like C<$#array>.  That's still how you get the last index
2113 of an array in Perl.  The two have nothing to do with each other.
2114
2115 Deprecated in Perl 5.
2116
2117 Removed in Perl v5.10.0.
2118
2119 =item $*
2120 X<$*>
2121
2122 C<$*> was a variable that you could use to enable multiline matching.
2123 After a deprecation cycle, its magic was removed in Perl v5.10.0.
2124 Using it now triggers a warning: C<$* is no longer supported>.
2125 You should use the C</s> and C</m> regexp modifiers instead.
2126
2127 Deprecated in Perl 5.
2128
2129 Removed in Perl v5.10.0.
2130
2131 =item $ARRAY_BASE
2132
2133 =item $[
2134 X<$[> X<$ARRAY_BASE>
2135
2136 This variable stores the index of the first element in an array, and
2137 of the first character in a substring.  The default is 0, but you could
2138 theoretically set it to 1 to make Perl behave more like B<awk> (or Fortran)
2139 when subscripting and when evaluating the index() and substr() functions.
2140
2141 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
2142 directive, and cannot influence the behavior of any other file.
2143 (That's why you can only assign compile-time constants to it.)
2144 Its use is highly discouraged.
2145
2146 Prior to Perl v5.10.0, assignment to C<$[> could be seen from outer lexical
2147 scopes in the same file, unlike other compile-time directives (such as
2148 L<strict>).  Using local() on it would bind its value strictly to a lexical
2149 block.  Now it is always lexically scoped.
2150
2151 As of Perl v5.16.0, it is implemented by the L<arybase> module.  See
2152 L<arybase> for more details on its behaviour.
2153
2154 Under C<use v5.16>, or C<no feature "array_base">, C<$[> no longer has any
2155 effect, and always contains 0.  Assigning 0 to it is permitted, but any
2156 other value will produce an error.
2157
2158 Mnemonic: [ begins subscripts.
2159
2160 Deprecated in Perl v5.12.0.
2161
2162 =item $OLD_PERL_VERSION
2163
2164 =item $]
2165 X<$]> X<$OLD_PERL_VERSION>
2166
2167 See L</$^V> for a more modern representation of the Perl version that allows
2168 accurate string comparisons.
2169
2170 The version + patchlevel / 1000 of the Perl interpreter.  This variable
2171 can be used to determine whether the Perl interpreter executing a
2172 script is in the right range of versions:
2173
2174     warn "No checksumming!\n" if $] < 3.019;
2175
2176 The floating point representation can sometimes lead to inaccurate
2177 numeric comparisons.
2178
2179 See also the documentation of C<use VERSION> and C<require VERSION>
2180 for a convenient way to fail if the running Perl interpreter is too old.
2181
2182 Mnemonic: Is this version of perl in the right bracket?
2183
2184 =back
2185
2186 =cut