This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Document string- and number-specific bitops in perlop
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands.  For example C<$x + $y>
10 is always a numeric addition, and if C<$x> or C<$y> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument.  It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison.  For example C<$x == $y> compares
17 two numbers for equality, and C<$x eq $y> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators are evaluated before
31 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
32 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
33 22> and not C<6 * 5 == 30>.
34
35 I<Operator associativity> defines what happens if a sequence of the
36 same operators is used one after another: whether the evaluator will
37 evaluate the left operations first or the right.  For example, in C<8
38 - 4 - 2>, subtraction is left associative so Perl evaluates the
39 expression left to right.  C<8 - 4> is evaluated first making the
40 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
41
42 Perl operators have the following associativity and precedence,
43 listed from highest precedence to lowest.  Operators borrowed from
44 C keep the same precedence relationship with each other, even where
45 C's precedence is slightly screwy.  (This makes learning Perl easier
46 for C folks.)  With very few exceptions, these all operate on scalar
47 values only, not array values.
48
49     left        terms and list operators (leftward)
50     left        ->
51     nonassoc    ++ --
52     right       **
53     right       ! ~ \ and unary + and -
54     left        =~ !~
55     left        * / % x
56     left        + - .
57     left        << >>
58     nonassoc    named unary operators
59     nonassoc    < > <= >= lt gt le ge
60     nonassoc    == != <=> eq ne cmp ~~
61     left        &
62     left        | ^
63     left        &&
64     left        || //
65     nonassoc    ..  ...
66     right       ?:
67     right       = += -= *= etc. goto last next redo dump
68     left        , =>
69     nonassoc    list operators (rightward)
70     right       not
71     left        and
72     left        or xor
73
74 In the following sections, these operators are covered in precedence order.
75
76 Many operators can be overloaded for objects.  See L<overload>.
77
78 =head2 Terms and List Operators (Leftward)
79 X<list operator> X<operator, list> X<term>
80
81 A TERM has the highest precedence in Perl.  They include variables,
82 quote and quote-like operators, any expression in parentheses,
83 and any function whose arguments are parenthesized.  Actually, there
84 aren't really functions in this sense, just list operators and unary
85 operators behaving as functions because you put parentheses around
86 the arguments.  These are all documented in L<perlfunc>.
87
88 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
89 is followed by a left parenthesis as the next token, the operator and
90 arguments within parentheses are taken to be of highest precedence,
91 just like a normal function call.
92
93 In the absence of parentheses, the precedence of list operators such as
94 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
95 whether you are looking at the left side or the right side of the operator.
96 For example, in
97
98     @ary = (1, 3, sort 4, 2);
99     print @ary;         # prints 1324
100
101 the commas on the right of the sort are evaluated before the sort,
102 but the commas on the left are evaluated after.  In other words,
103 list operators tend to gobble up all arguments that follow, and
104 then act like a simple TERM with regard to the preceding expression.
105 Be careful with parentheses:
106
107     # These evaluate exit before doing the print:
108     print($foo, exit);  # Obviously not what you want.
109     print $foo, exit;   # Nor is this.
110
111     # These do the print before evaluating exit:
112     (print $foo), exit; # This is what you want.
113     print($foo), exit;  # Or this.
114     print ($foo), exit; # Or even this.
115
116 Also note that
117
118     print ($foo & 255) + 1, "\n";
119
120 probably doesn't do what you expect at first glance.  The parentheses
121 enclose the argument list for C<print> which is evaluated (printing
122 the result of C<$foo & 255>).  Then one is added to the return value
123 of C<print> (usually 1).  The result is something like this:
124
125     1 + 1, "\n";    # Obviously not what you meant.
126
127 To do what you meant properly, you must write:
128
129     print(($foo & 255) + 1, "\n");
130
131 See L<Named Unary Operators> for more discussion of this.
132
133 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
134 well as subroutine and method calls, and the anonymous
135 constructors C<[]> and C<{}>.
136
137 See also L<Quote and Quote-like Operators> toward the end of this section,
138 as well as L</"I/O Operators">.
139
140 =head2 The Arrow Operator
141 X<arrow> X<dereference> X<< -> >>
142
143 "C<< -> >>" is an infix dereference operator, just as it is in C
144 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
145 C<(...)> subscript, then the left side must be either a hard or
146 symbolic reference to an array, a hash, or a subroutine respectively.
147 (Or technically speaking, a location capable of holding a hard
148 reference, if it's an array or hash reference being used for
149 assignment.)  See L<perlreftut> and L<perlref>.
150
151 Otherwise, the right side is a method name or a simple scalar
152 variable containing either the method name or a subroutine reference,
153 and the left side must be either an object (a blessed reference)
154 or a class name (that is, a package name).  See L<perlobj>.
155
156 The dereferencing cases (as opposed to method-calling cases) are
157 somewhat extended by the experimental C<postderef> feature.  For the
158 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
159
160 =head2 Auto-increment and Auto-decrement
161 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
162
163 "++" and "--" work as in C.  That is, if placed before a variable,
164 they increment or decrement the variable by one before returning the
165 value, and if placed after, increment or decrement after returning the
166 value.
167
168     $i = 0;  $j = 0;
169     print $i++;  # prints 0
170     print ++$j;  # prints 1
171
172 Note that just as in C, Perl doesn't define B<when> the variable is
173 incremented or decremented.  You just know it will be done sometime
174 before or after the value is returned.  This also means that modifying
175 a variable twice in the same statement will lead to undefined behavior.
176 Avoid statements like:
177
178     $i = $i ++;
179     print ++ $i + $i ++;
180
181 Perl will not guarantee what the result of the above statements is.
182
183 The auto-increment operator has a little extra builtin magic to it.  If
184 you increment a variable that is numeric, or that has ever been used in
185 a numeric context, you get a normal increment.  If, however, the
186 variable has been used in only string contexts since it was set, and
187 has a value that is not the empty string and matches the pattern
188 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
189 character within its range, with carry:
190
191     print ++($foo = "99");      # prints "100"
192     print ++($foo = "a0");      # prints "a1"
193     print ++($foo = "Az");      # prints "Ba"
194     print ++($foo = "zz");      # prints "aaa"
195
196 C<undef> is always treated as numeric, and in particular is changed
197 to C<0> before incrementing (so that a post-increment of an undef value
198 will return C<0> rather than C<undef>).
199
200 The auto-decrement operator is not magical.
201
202 =head2 Exponentiation
203 X<**> X<exponentiation> X<power>
204
205 Binary "**" is the exponentiation operator.  It binds even more
206 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4.  (This is
207 implemented using C's pow(3) function, which actually works on doubles
208 internally.)
209
210 Note that certain exponentiation expressions are ill-defined:
211 these include C<0**0>, C<1**Inf>, and C<Inf**0>.  Do not expect
212 any particular results from these special cases, the results
213 are platform-dependent.
214
215 =head2 Symbolic Unary Operators
216 X<unary operator> X<operator, unary>
217
218 Unary "!" performs logical negation, that is, "not".  See also C<not> for a lower
219 precedence version of this.
220 X<!>
221
222 Unary "-" performs arithmetic negation if the operand is numeric,
223 including any string that looks like a number.  If the operand is
224 an identifier, a string consisting of a minus sign concatenated
225 with the identifier is returned.  Otherwise, if the string starts
226 with a plus or minus, a string starting with the opposite sign is
227 returned.  One effect of these rules is that -bareword is equivalent
228 to the string "-bareword".  If, however, the string begins with a
229 non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert
230 the string to a numeric and the arithmetic negation is performed.  If the
231 string cannot be cleanly converted to a numeric, Perl will give the warning
232 B<Argument "the string" isn't numeric in negation (-) at ...>.
233 X<-> X<negation, arithmetic>
234
235 Unary "~" performs bitwise negation, that is, 1's complement.  For
236 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
237 L<Bitwise String Operators>.)  Note that the width of the result is
238 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
239 bits wide on a 64-bit platform, so if you are expecting a certain bit
240 width, remember to use the "&" operator to mask off the excess bits.
241 X<~> X<negation, binary>
242
243 When complementing strings, if all characters have ordinal values under
244 256, then their complements will, also.  But if they do not, all
245 characters will be in either 32- or 64-bit complements, depending on your
246 architecture.  So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on
247 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines.
248
249 If the experimental "bitwise" feature is enabled via C<use feature
250 'bitwise'>, then unary "~" always treats its argument as a number, and an
251 alternate form of the operator, "~.", always treats its argument as a
252 string.  So C<~0> and C<~"0"> will both give 2**32-1 on 32-bit platforms,
253 whereas C<~.0> and C<~."0"> will both yield C<"\xff">.  This feature
254 produces a warning unless you use C<no warnings 'experimental::bitwise'>.
255
256 Unary "+" has no effect whatsoever, even on strings.  It is useful
257 syntactically for separating a function name from a parenthesized expression
258 that would otherwise be interpreted as the complete list of function
259 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
260 X<+>
261
262 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
263 and L<perlref>.  Do not confuse this behavior with the behavior of
264 backslash within a string, although both forms do convey the notion
265 of protecting the next thing from interpolation.
266 X<\> X<reference> X<backslash>
267
268 =head2 Binding Operators
269 X<binding> X<operator, binding> X<=~> X<!~>
270
271 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
272 search or modify the string $_ by default.  This operator makes that kind
273 of operation work on some other string.  The right argument is a search
274 pattern, substitution, or transliteration.  The left argument is what is
275 supposed to be searched, substituted, or transliterated instead of the default
276 $_.  When used in scalar context, the return value generally indicates the
277 success of the operation.  The exceptions are substitution (s///)
278 and transliteration (y///) with the C</r> (non-destructive) option,
279 which cause the B<r>eturn value to be the result of the substitution.
280 Behavior in list context depends on the particular operator.
281 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
282 examples using these operators.
283
284 If the right argument is an expression rather than a search pattern,
285 substitution, or transliteration, it is interpreted as a search pattern at run
286 time.  Note that this means that its
287 contents will be interpolated twice, so
288
289     '\\' =~ q'\\';
290
291 is not ok, as the regex engine will end up trying to compile the
292 pattern C<\>, which it will consider a syntax error.
293
294 Binary "!~" is just like "=~" except the return value is negated in
295 the logical sense.
296
297 Binary "!~" with a non-destructive substitution (s///r) or transliteration
298 (y///r) is a syntax error.
299
300 =head2 Multiplicative Operators
301 X<operator, multiplicative>
302
303 Binary "*" multiplies two numbers.
304 X<*>
305
306 Binary "/" divides two numbers.
307 X</> X<slash>
308
309 Binary "%" is the modulo operator, which computes the division
310 remainder of its first argument with respect to its second argument.
311 Given integer
312 operands C<$m> and C<$n>: If C<$n> is positive, then C<$m % $n> is
313 C<$m> minus the largest multiple of C<$n> less than or equal to
314 C<$m>.  If C<$n> is negative, then C<$m % $n> is C<$m> minus the
315 smallest multiple of C<$n> that is not less than C<$m> (that is, the
316 result will be less than or equal to zero).  If the operands
317 C<$m> and C<$n> are floating point values and the absolute value of
318 C<$n> (that is C<abs($n)>) is less than C<(UV_MAX + 1)>, only
319 the integer portion of C<$m> and C<$n> will be used in the operation
320 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
321 If the absolute value of the right operand (C<abs($n)>) is greater than
322 or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder
323 C<$r> in the equation C<($r = $m - $i*$n)> where C<$i> is a certain
324 integer that makes C<$r> have the same sign as the right operand
325 C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>)
326 and the absolute value less than that of C<$n>.
327 Note that when C<use integer> is in scope, "%" gives you direct access
328 to the modulo operator as implemented by your C compiler.  This
329 operator is not as well defined for negative operands, but it will
330 execute faster.
331 X<%> X<remainder> X<modulo> X<mod>
332
333 Binary "x" is the repetition operator.  In scalar context or if the left
334 operand is not enclosed in parentheses, it returns a string consisting
335 of the left operand repeated the number of times specified by the right
336 operand.  In list context, if the left operand is enclosed in
337 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
338 If the right operand is zero or negative (raising a warning on
339 negative), it returns an empty string
340 or an empty list, depending on the context.
341 X<x>
342
343     print '-' x 80;             # print row of dashes
344
345     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
346
347     @ones = (1) x 80;           # a list of 80 1's
348     @ones = (5) x @ones;        # set all elements to 5
349
350
351 =head2 Additive Operators
352 X<operator, additive>
353
354 Binary C<+> returns the sum of two numbers.
355 X<+>
356
357 Binary C<-> returns the difference of two numbers.
358 X<->
359
360 Binary C<.> concatenates two strings.
361 X<string, concatenation> X<concatenation>
362 X<cat> X<concat> X<concatenate> X<.>
363
364 =head2 Shift Operators
365 X<shift operator> X<operator, shift> X<<< << >>>
366 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
367 X<shl> X<shr> X<shift, right> X<shift, left>
368
369 Binary C<<< << >>> returns the value of its left argument shifted left by the
370 number of bits specified by the right argument.  Arguments should be
371 integers.  (See also L<Integer Arithmetic>.)
372
373 Binary C<<< >> >>> returns the value of its left argument shifted right by
374 the number of bits specified by the right argument.  Arguments should
375 be integers.  (See also L<Integer Arithmetic>.)
376
377 Note that both C<<< << >>> and C<<< >> >>> in Perl are implemented directly using
378 C<<< << >>> and C<<< >> >>>  in C.  If C<use integer> (see L<Integer Arithmetic>) is
379 in force then signed C integers are used, else unsigned C integers are
380 used.  Either way, the implementation isn't going to generate results
381 larger than the size of the integer type Perl was built with (32 bits
382 or 64 bits).
383
384 The result of overflowing the range of the integers is undefined
385 because it is undefined also in C.  In other words, using 32-bit
386 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
387 of bits is also undefined.
388
389 If you get tired of being subject to your platform's native integers,
390 the C<use bigint> pragma neatly sidesteps the issue altogether:
391
392     print 20 << 20;  # 20971520
393     print 20 << 40;  # 5120 on 32-bit machines, 
394                      # 21990232555520 on 64-bit machines
395     use bigint;
396     print 20 << 100; # 25353012004564588029934064107520
397
398 =head2 Named Unary Operators
399 X<operator, named unary>
400
401 The various named unary operators are treated as functions with one
402 argument, with optional parentheses.
403
404 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
405 is followed by a left parenthesis as the next token, the operator and
406 arguments within parentheses are taken to be of highest precedence,
407 just like a normal function call.  For example,
408 because named unary operators are higher precedence than C<||>:
409
410     chdir $foo    || die;       # (chdir $foo) || die
411     chdir($foo)   || die;       # (chdir $foo) || die
412     chdir ($foo)  || die;       # (chdir $foo) || die
413     chdir +($foo) || die;       # (chdir $foo) || die
414
415 but, because * is higher precedence than named operators:
416
417     chdir $foo * 20;    # chdir ($foo * 20)
418     chdir($foo) * 20;   # (chdir $foo) * 20
419     chdir ($foo) * 20;  # (chdir $foo) * 20
420     chdir +($foo) * 20; # chdir ($foo * 20)
421
422     rand 10 * 20;       # rand (10 * 20)
423     rand(10) * 20;      # (rand 10) * 20
424     rand (10) * 20;     # (rand 10) * 20
425     rand +(10) * 20;    # rand (10 * 20)
426
427 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
428 treated like named unary operators, but they don't follow this functional
429 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
430 equivalent to C<-f "$file.bak">.
431 X<-X> X<filetest> X<operator, filetest>
432
433 See also L<"Terms and List Operators (Leftward)">.
434
435 =head2 Relational Operators
436 X<relational operator> X<operator, relational>
437
438 Perl operators that return true or false generally return values 
439 that can be safely used as numbers.  For example, the relational
440 operators in this section and the equality operators in the next
441 one return C<1> for true and a special version of the defined empty
442 string, C<"">, which counts as a zero but is exempt from warnings
443 about improper numeric conversions, just as C<"0 but true"> is.
444
445 Binary "<" returns true if the left argument is numerically less than
446 the right argument.
447 X<< < >>
448
449 Binary ">" returns true if the left argument is numerically greater
450 than the right argument.
451 X<< > >>
452
453 Binary "<=" returns true if the left argument is numerically less than
454 or equal to the right argument.
455 X<< <= >>
456
457 Binary ">=" returns true if the left argument is numerically greater
458 than or equal to the right argument.
459 X<< >= >>
460
461 Binary "lt" returns true if the left argument is stringwise less than
462 the right argument.
463 X<< lt >>
464
465 Binary "gt" returns true if the left argument is stringwise greater
466 than the right argument.
467 X<< gt >>
468
469 Binary "le" returns true if the left argument is stringwise less than
470 or equal to the right argument.
471 X<< le >>
472
473 Binary "ge" returns true if the left argument is stringwise greater
474 than or equal to the right argument.
475 X<< ge >>
476
477 =head2 Equality Operators
478 X<equality> X<equal> X<equals> X<operator, equality>
479
480 Binary "==" returns true if the left argument is numerically equal to
481 the right argument.
482 X<==>
483
484 Binary "!=" returns true if the left argument is numerically not equal
485 to the right argument.
486 X<!=>
487
488 Binary "<=>" returns -1, 0, or 1 depending on whether the left
489 argument is numerically less than, equal to, or greater than the right
490 argument.  If your platform supports NaNs (not-a-numbers) as numeric
491 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
492 "<=" or ">=" anything (even NaN), so those 5 return false.  NaN != NaN
493 returns true, as does NaN != anything else.  If your platform doesn't
494 support NaNs then NaN is just a string with numeric value 0.
495 X<< <=> >> X<spaceship>
496
497     $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x'
498     $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x'
499
500 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all
501 support "NaN".)
502
503 Binary "eq" returns true if the left argument is stringwise equal to
504 the right argument.
505 X<eq>
506
507 Binary "ne" returns true if the left argument is stringwise not equal
508 to the right argument.
509 X<ne>
510
511 Binary "cmp" returns -1, 0, or 1 depending on whether the left
512 argument is stringwise less than, equal to, or greater than the right
513 argument.
514 X<cmp>
515
516 Binary "~~" does a smartmatch between its arguments.  Smart matching
517 is described in the next section.
518 X<~~>
519
520 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
521 by the current locale if a legacy C<use locale> (but not
522 C<use locale ':not_characters'>) is in effect.  See
523 L<perllocale>.  Do not mix these with Unicode, only with legacy binary
524 encodings.  The standard L<Unicode::Collate> and
525 L<Unicode::Collate::Locale> modules offer much more powerful solutions to
526 collation issues.
527
528 =head2 Smartmatch Operator
529
530 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
531 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
532 used implicitly in the C<when> construct described in L<perlsyn>, although
533 not all C<when> clauses call the smartmatch operator.  Unique among all of
534 Perl's operators, the smartmatch operator can recurse.  The smartmatch
535 operator is L<experimental|perlpolicy/experimental> and its behavior is
536 subject to change.
537
538 It is also unique in that all other Perl operators impose a context
539 (usually string or numeric context) on their operands, autoconverting
540 those operands to those imposed contexts.  In contrast, smartmatch
541 I<infers> contexts from the actual types of its operands and uses that
542 type information to select a suitable comparison mechanism.
543
544 The C<~~> operator compares its operands "polymorphically", determining how
545 to compare them according to their actual types (numeric, string, array,
546 hash, etc.)  Like the equality operators with which it shares the same
547 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
548 read aloud as "in", "inside of", or "is contained in", because the left
549 operand is often looked for I<inside> the right operand.  That makes the
550 order of the operands to the smartmatch operand often opposite that of
551 the regular match operator.  In other words, the "smaller" thing is usually
552 placed in the left operand and the larger one in the right.
553
554 The behavior of a smartmatch depends on what type of things its arguments
555 are, as determined by the following table.  The first row of the table
556 whose types apply determines the smartmatch behavior.  Because what
557 actually happens is mostly determined by the type of the second operand,
558 the table is sorted on the right operand instead of on the left.
559
560  Left      Right      Description and pseudocode                               
561  ===============================================================
562  Any       undef      check whether Any is undefined                    
563                 like: !defined Any
564
565  Any       Object     invoke ~~ overloading on Object, or die
566
567  Right operand is an ARRAY:
568
569  Left      Right      Description and pseudocode                               
570  ===============================================================
571  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
572                 like: (ARRAY1[0] ~~ ARRAY2[0])
573                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
574  HASH      ARRAY      any ARRAY elements exist as HASH keys             
575                 like: grep { exists HASH->{$_} } ARRAY
576  Regexp    ARRAY      any ARRAY elements pattern match Regexp
577                 like: grep { /Regexp/ } ARRAY
578  undef     ARRAY      undef in ARRAY                                    
579                 like: grep { !defined } ARRAY
580  Any       ARRAY      smartmatch each ARRAY element[3]                   
581                 like: grep { Any ~~ $_ } ARRAY
582
583  Right operand is a HASH:
584
585  Left      Right      Description and pseudocode                               
586  ===============================================================
587  HASH1     HASH2      all same keys in both HASHes                      
588                 like: keys HASH1 ==
589                          grep { exists HASH2->{$_} } keys HASH1
590  ARRAY     HASH       any ARRAY elements exist as HASH keys             
591                 like: grep { exists HASH->{$_} } ARRAY
592  Regexp    HASH       any HASH keys pattern match Regexp                
593                 like: grep { /Regexp/ } keys HASH
594  undef     HASH       always false (undef can't be a key)               
595                 like: 0 == 1
596  Any       HASH       HASH key existence                                
597                 like: exists HASH->{Any}
598
599  Right operand is CODE:
600
601  Left      Right      Description and pseudocode                               
602  ===============================================================
603  ARRAY     CODE       sub returns true on all ARRAY elements[1]
604                 like: !grep { !CODE->($_) } ARRAY
605  HASH      CODE       sub returns true on all HASH keys[1]
606                 like: !grep { !CODE->($_) } keys HASH
607  Any       CODE       sub passed Any returns true              
608                 like: CODE->(Any)
609
610 Right operand is a Regexp:
611
612  Left      Right      Description and pseudocode                               
613  ===============================================================
614  ARRAY     Regexp     any ARRAY elements match Regexp                   
615                 like: grep { /Regexp/ } ARRAY
616  HASH      Regexp     any HASH keys match Regexp                        
617                 like: grep { /Regexp/ } keys HASH
618  Any       Regexp     pattern match                                     
619                 like: Any =~ /Regexp/
620
621  Other:
622
623  Left      Right      Description and pseudocode                               
624  ===============================================================
625  Object    Any        invoke ~~ overloading on Object,
626                       or fall back to...
627
628  Any       Num        numeric equality                                  
629                  like: Any == Num
630  Num       nummy[4]    numeric equality
631                  like: Num == nummy
632  undef     Any        check whether undefined
633                  like: !defined(Any)
634  Any       Any        string equality                                   
635                  like: Any eq Any
636
637
638 Notes:
639
640 =over
641
642 =item 1.
643 Empty hashes or arrays match. 
644
645 =item 2.
646 That is, each element smartmatches the element of the same index in the other array.[3]
647
648 =item 3.
649 If a circular reference is found, fall back to referential equality. 
650
651 =item 4.
652 Either an actual number, or a string that looks like one.
653
654 =back
655
656 The smartmatch implicitly dereferences any non-blessed hash or array
657 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
658 For blessed references, the C<I<Object>> entries apply.  Smartmatches
659 involving hashes only consider hash keys, never hash values.
660
661 The "like" code entry is not always an exact rendition.  For example, the
662 smartmatch operator short-circuits whenever possible, but C<grep> does
663 not.  Also, C<grep> in scalar context returns the number of matches, but
664 C<~~> returns only true or false.
665
666 Unlike most operators, the smartmatch operator knows to treat C<undef>
667 specially:
668
669     use v5.10.1;
670     @array = (1, 2, 3, undef, 4, 5);
671     say "some elements undefined" if undef ~~ @array;
672
673 Each operand is considered in a modified scalar context, the modification
674 being that array and hash variables are passed by reference to the
675 operator, which implicitly dereferences them.  Both elements
676 of each pair are the same:
677
678     use v5.10.1;
679
680     my %hash = (red    => 1, blue   => 2, green  => 3,
681                 orange => 4, yellow => 5, purple => 6,
682                 black  => 7, grey   => 8, white  => 9);
683
684     my @array = qw(red blue green);
685
686     say "some array elements in hash keys" if  @array ~~  %hash;
687     say "some array elements in hash keys" if \@array ~~ \%hash;
688
689     say "red in array" if "red" ~~  @array;
690     say "red in array" if "red" ~~ \@array;
691
692     say "some keys end in e" if /e$/ ~~  %hash;
693     say "some keys end in e" if /e$/ ~~ \%hash;
694
695 Two arrays smartmatch if each element in the first array smartmatches
696 (that is, is "in") the corresponding element in the second array,
697 recursively.
698
699     use v5.10.1;
700     my @little = qw(red blue green);
701     my @bigger = ("red", "blue", [ "orange", "green" ] );
702     if (@little ~~ @bigger) {  # true!
703         say "little is contained in bigger";
704     } 
705
706 Because the smartmatch operator recurses on nested arrays, this
707 will still report that "red" is in the array.
708
709     use v5.10.1;
710     my @array = qw(red blue green);
711     my $nested_array = [[[[[[[ @array ]]]]]]];
712     say "red in array" if "red" ~~ $nested_array;
713
714 If two arrays smartmatch each other, then they are deep
715 copies of each others' values, as this example reports:
716
717     use v5.12.0;
718     my @a = (0, 1, 2, [3, [4, 5], 6], 7); 
719     my @b = (0, 1, 2, [3, [4, 5], 6], 7); 
720
721     if (@a ~~ @b && @b ~~ @a) {
722         say "a and b are deep copies of each other";
723     } 
724     elsif (@a ~~ @b) {
725         say "a smartmatches in b";
726     } 
727     elsif (@b ~~ @a) {
728         say "b smartmatches in a";
729     } 
730     else {
731         say "a and b don't smartmatch each other at all";
732     } 
733
734
735 If you were to set C<$b[3] = 4>, then instead of reporting that "a and b
736 are deep copies of each other", it now reports that "b smartmatches in a".
737 That because the corresponding position in C<@a> contains an array that
738 (eventually) has a 4 in it.
739
740 Smartmatching one hash against another reports whether both contain the
741 same keys, no more and no less.  This could be used to see whether two
742 records have the same field names, without caring what values those fields
743 might have.  For example:
744
745     use v5.10.1;
746     sub make_dogtag {
747         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
748
749         my ($class, $init_fields) = @_;
750
751         die "Must supply (only) name, rank, and serial number"
752             unless $init_fields ~~ $REQUIRED_FIELDS;
753
754         ...
755     }
756
757 or, if other non-required fields are allowed, use ARRAY ~~ HASH:
758
759     use v5.10.1;
760     sub make_dogtag {
761         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
762
763         my ($class, $init_fields) = @_;
764
765         die "Must supply (at least) name, rank, and serial number"
766             unless [keys %{$init_fields}] ~~ $REQUIRED_FIELDS;
767
768         ...
769     }
770
771 The smartmatch operator is most often used as the implicit operator of a
772 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
773
774 =head3 Smartmatching of Objects
775
776 To avoid relying on an object's underlying representation, if the
777 smartmatch's right operand is an object that doesn't overload C<~~>,
778 it raises the exception "C<Smartmatching a non-overloaded object
779 breaks encapsulation>".  That's because one has no business digging
780 around to see whether something is "in" an object.  These are all
781 illegal on objects without a C<~~> overload:
782
783     %hash ~~ $object
784        42 ~~ $object
785    "fred" ~~ $object
786
787 However, you can change the way an object is smartmatched by overloading
788 the C<~~> operator.  This is allowed to
789 extend the usual smartmatch semantics.
790 For objects that do have an C<~~> overload, see L<overload>.
791
792 Using an object as the left operand is allowed, although not very useful.
793 Smartmatching rules take precedence over overloading, so even if the
794 object in the left operand has smartmatch overloading, this will be
795 ignored.  A left operand that is a non-overloaded object falls back on a
796 string or numeric comparison of whatever the C<ref> operator returns.  That
797 means that
798
799     $object ~~ X
800
801 does I<not> invoke the overload method with C<I<X>> as an argument.
802 Instead the above table is consulted as normal, and based on the type of
803 C<I<X>>, overloading may or may not be invoked.  For simple strings or
804 numbers, in becomes equivalent to this:
805
806     $object ~~ $number          ref($object) == $number
807     $object ~~ $string          ref($object) eq $string 
808
809 For example, this reports that the handle smells IOish
810 (but please don't really do this!):
811
812     use IO::Handle;
813     my $fh = IO::Handle->new();
814     if ($fh ~~ /\bIO\b/) {
815         say "handle smells IOish";
816     } 
817
818 That's because it treats C<$fh> as a string like
819 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
820
821 =head2 Bitwise And
822 X<operator, bitwise, and> X<bitwise and> X<&>
823
824 Binary "&" returns its operands ANDed together bit by bit.  Although no
825 warning is currently raised, the result is not well defined when this operation
826 is performed on operands that aren't either numbers (see
827 L<Integer Arithmetic>) or bitstrings (see L<Bitwise String Operators>).
828
829 Note that "&" has lower priority than relational operators, so for example
830 the parentheses are essential in a test like
831
832     print "Even\n" if ($x & 1) == 0;
833
834 If the experimental "bitwise" feature is enabled via C<use feature
835 'bitwise'>, then this operator always treats its operand as numbers.  This
836 feature produces a warning unless you use C<no warnings
837 'experimental::bitwise'>.
838
839 =head2 Bitwise Or and Exclusive Or
840 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
841 X<bitwise xor> X<^>
842
843 Binary "|" returns its operands ORed together bit by bit.
844
845 Binary "^" returns its operands XORed together bit by bit.
846
847 Although no warning is currently raised, the results are not well
848 defined when these operations are performed on operands that aren't either
849 numbers (see L<Integer Arithmetic>) or bitstrings (see L<Bitwise String
850 Operators>).
851
852 Note that "|" and "^" have lower priority than relational operators, so
853 for example the brackets are essential in a test like
854
855     print "false\n" if (8 | 2) != 10;
856
857 If the experimental "bitwise" feature is enabled via C<use feature
858 'bitwise'>, then this operator always treats its operand as numbers.  This
859 feature produces a warning unless you use C<no warnings
860 'experimental::bitwise'>.
861
862 =head2 C-style Logical And
863 X<&&> X<logical and> X<operator, logical, and>
864
865 Binary "&&" performs a short-circuit logical AND operation.  That is,
866 if the left operand is false, the right operand is not even evaluated.
867 Scalar or list context propagates down to the right operand if it
868 is evaluated.
869
870 =head2 C-style Logical Or
871 X<||> X<operator, logical, or>
872
873 Binary "||" performs a short-circuit logical OR operation.  That is,
874 if the left operand is true, the right operand is not even evaluated.
875 Scalar or list context propagates down to the right operand if it
876 is evaluated.
877
878 =head2 Logical Defined-Or
879 X<//> X<operator, logical, defined-or>
880
881 Although it has no direct equivalent in C, Perl's C<//> operator is related
882 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
883 tests the left hand side's definedness instead of its truth.  Thus,
884 C<< EXPR1 // EXPR2 >> returns the value of C<< EXPR1 >> if it's defined,
885 otherwise, the value of C<< EXPR2 >> is returned.
886 (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >>
887 in the context of C<< // >> itself).  Usually,
888 this is the same result as C<< defined(EXPR1) ? EXPR1 : EXPR2 >> (except that
889 the ternary-operator form can be used as a lvalue, while C<< EXPR1 // EXPR2 >>
890 cannot).  This is very useful for
891 providing default values for variables.  If you actually want to test if
892 at least one of C<$x> and C<$y> is defined, use C<defined($x // $y)>.
893
894 The C<||>, C<//> and C<&&> operators return the last value evaluated
895 (unlike C's C<||> and C<&&>, which return 0 or 1).  Thus, a reasonably
896 portable way to find out the home directory might be:
897
898     $home =  $ENV{HOME}
899           // $ENV{LOGDIR}
900           // (getpwuid($<))[7]
901           // die "You're homeless!\n";
902
903 In particular, this means that you shouldn't use this
904 for selecting between two aggregates for assignment:
905
906     @a = @b || @c;              # this is wrong
907     @a = scalar(@b) || @c;      # really meant this
908     @a = @b ? @b : @c;          # this works fine, though
909
910 As alternatives to C<&&> and C<||> when used for
911 control flow, Perl provides the C<and> and C<or> operators (see below).
912 The short-circuit behavior is identical.  The precedence of "and"
913 and "or" is much lower, however, so that you can safely use them after a
914 list operator without the need for parentheses:
915
916     unlink "alpha", "beta", "gamma"
917             or gripe(), next LINE;
918
919 With the C-style operators that would have been written like this:
920
921     unlink("alpha", "beta", "gamma")
922             || (gripe(), next LINE);
923
924 It would be even more readable to write that this way:
925
926     unless(unlink("alpha", "beta", "gamma")) {
927         gripe();
928         next LINE;
929     } 
930
931 Using "or" for assignment is unlikely to do what you want; see below.
932
933 =head2 Range Operators
934 X<operator, range> X<range> X<..> X<...>
935
936 Binary ".." is the range operator, which is really two different
937 operators depending on the context.  In list context, it returns a
938 list of values counting (up by ones) from the left value to the right
939 value.  If the left value is greater than the right value then it
940 returns the empty list.  The range operator is useful for writing
941 C<foreach (1..10)> loops and for doing slice operations on arrays.  In
942 the current implementation, no temporary array is created when the
943 range operator is used as the expression in C<foreach> loops, but older
944 versions of Perl might burn a lot of memory when you write something
945 like this:
946
947     for (1 .. 1_000_000) {
948         # code
949     }
950
951 The range operator also works on strings, using the magical
952 auto-increment, see below.
953
954 In scalar context, ".." returns a boolean value.  The operator is
955 bistable, like a flip-flop, and emulates the line-range (comma)
956 operator of B<sed>, B<awk>, and various editors.  Each ".." operator
957 maintains its own boolean state, even across calls to a subroutine
958 that contains it.  It is false as long as its left operand is false.
959 Once the left operand is true, the range operator stays true until the
960 right operand is true, I<AFTER> which the range operator becomes false
961 again.  It doesn't become false till the next time the range operator
962 is evaluated.  It can test the right operand and become false on the
963 same evaluation it became true (as in B<awk>), but it still returns
964 true once.  If you don't want it to test the right operand until the
965 next evaluation, as in B<sed>, just use three dots ("...") instead of
966 two.  In all other regards, "..." behaves just like ".." does.
967
968 The right operand is not evaluated while the operator is in the
969 "false" state, and the left operand is not evaluated while the
970 operator is in the "true" state.  The precedence is a little lower
971 than || and &&.  The value returned is either the empty string for
972 false, or a sequence number (beginning with 1) for true.  The sequence
973 number is reset for each range encountered.  The final sequence number
974 in a range has the string "E0" appended to it, which doesn't affect
975 its numeric value, but gives you something to search for if you want
976 to exclude the endpoint.  You can exclude the beginning point by
977 waiting for the sequence number to be greater than 1.
978
979 If either operand of scalar ".." is a constant expression,
980 that operand is considered true if it is equal (C<==>) to the current
981 input line number (the C<$.> variable).
982
983 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
984 but that is only an issue if you use a floating point expression; when
985 implicitly using C<$.> as described in the previous paragraph, the
986 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
987 is set to a floating point value and you are not reading from a file.
988 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
989 you want in scalar context because each of the operands are evaluated
990 using their integer representation.
991
992 Examples:
993
994 As a scalar operator:
995
996     if (101 .. 200) { print; } # print 2nd hundred lines, short for
997                                #  if ($. == 101 .. $. == 200) { print; }
998
999     next LINE if (1 .. /^$/);  # skip header lines, short for
1000                                #   next LINE if ($. == 1 .. /^$/);
1001                                # (typically in a loop labeled LINE)
1002
1003     s/^/> / if (/^$/ .. eof());  # quote body
1004
1005     # parse mail messages
1006     while (<>) {
1007         $in_header =   1  .. /^$/;
1008         $in_body   = /^$/ .. eof;
1009         if ($in_header) {
1010             # do something
1011         } else { # in body
1012             # do something else
1013         }
1014     } continue {
1015         close ARGV if eof;             # reset $. each file
1016     }
1017
1018 Here's a simple example to illustrate the difference between
1019 the two range operators:
1020
1021     @lines = ("   - Foo",
1022               "01 - Bar",
1023               "1  - Baz",
1024               "   - Quux");
1025
1026     foreach (@lines) {
1027         if (/0/ .. /1/) {
1028             print "$_\n";
1029         }
1030     }
1031
1032 This program will print only the line containing "Bar".  If
1033 the range operator is changed to C<...>, it will also print the
1034 "Baz" line.
1035
1036 And now some examples as a list operator:
1037
1038     for (101 .. 200) { print }      # print $_ 100 times
1039     @foo = @foo[0 .. $#foo];        # an expensive no-op
1040     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1041
1042 The range operator (in list context) makes use of the magical
1043 auto-increment algorithm if the operands are strings.  You
1044 can say
1045
1046     @alphabet = ("A" .. "Z");
1047
1048 to get all normal letters of the English alphabet, or
1049
1050     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1051
1052 to get a hexadecimal digit, or
1053
1054     @z2 = ("01" .. "31");
1055     print $z2[$mday];
1056
1057 to get dates with leading zeros.
1058
1059 If the final value specified is not in the sequence that the magical
1060 increment would produce, the sequence goes until the next value would
1061 be longer than the final value specified.
1062
1063 If the initial value specified isn't part of a magical increment
1064 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1065 only the initial value will be returned.  So the following will only
1066 return an alpha:
1067
1068     use charnames "greek";
1069     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1070
1071 To get the 25 traditional lowercase Greek letters, including both sigmas,
1072 you could use this instead:
1073
1074     use charnames "greek";
1075     my @greek_small =  map { chr } ( ord("\N{alpha}") 
1076                                         ..
1077                                      ord("\N{omega}") 
1078                                    );
1079
1080 However, because there are I<many> other lowercase Greek characters than
1081 just those, to match lowercase Greek characters in a regular expression,
1082 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1083 L<experimental feature|perlrecharclass/Extended Bracketed Character
1084 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1085
1086 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
1087 return two elements in list context.
1088
1089     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1090
1091 =head2 Conditional Operator
1092 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1093
1094 Ternary "?:" is the conditional operator, just as in C.  It works much
1095 like an if-then-else.  If the argument before the ? is true, the
1096 argument before the : is returned, otherwise the argument after the :
1097 is returned.  For example:
1098
1099     printf "I have %d dog%s.\n", $n,
1100             ($n == 1) ? "" : "s";
1101
1102 Scalar or list context propagates downward into the 2nd
1103 or 3rd argument, whichever is selected.
1104
1105     $x = $ok ? $y : $z;  # get a scalar
1106     @x = $ok ? @y : @z;  # get an array
1107     $x = $ok ? @y : @z;  # oops, that's just a count!
1108
1109 The operator may be assigned to if both the 2nd and 3rd arguments are
1110 legal lvalues (meaning that you can assign to them):
1111
1112     ($x_or_y ? $x : $y) = $z;
1113
1114 Because this operator produces an assignable result, using assignments
1115 without parentheses will get you in trouble.  For example, this:
1116
1117     $x % 2 ? $x += 10 : $x += 2
1118
1119 Really means this:
1120
1121     (($x % 2) ? ($x += 10) : $x) += 2
1122
1123 Rather than this:
1124
1125     ($x % 2) ? ($x += 10) : ($x += 2)
1126
1127 That should probably be written more simply as:
1128
1129     $x += ($x % 2) ? 10 : 2;
1130
1131 =head2 Assignment Operators
1132 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1133 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1134 X<%=> X<^=> X<x=> X<&.=> X<|.=> X<^.=>
1135
1136 "=" is the ordinary assignment operator.
1137
1138 Assignment operators work as in C.  That is,
1139
1140     $x += 2;
1141
1142 is equivalent to
1143
1144     $x = $x + 2;
1145
1146 although without duplicating any side effects that dereferencing the lvalue
1147 might trigger, such as from tie().  Other assignment operators work similarly.
1148 The following are recognized:
1149
1150     **=    +=    *=    &=    &.=    <<=    &&=
1151            -=    /=    |=    |.=    >>=    ||=
1152            .=    %=    ^=    ^.=           //=
1153                  x=
1154
1155 Although these are grouped by family, they all have the precedence
1156 of assignment.  These combined assignment operators can only operate on
1157 scalars, whereas the ordinary assignment operator can assign to arrays,
1158 hashes, lists and even references.  (See L<"Context"|perldata/Context>
1159 and L<perldata/List value constructors>, and L<perlref/Assigning to
1160 References>.)
1161
1162 Unlike in C, the scalar assignment operator produces a valid lvalue.
1163 Modifying an assignment is equivalent to doing the assignment and
1164 then modifying the variable that was assigned to.  This is useful
1165 for modifying a copy of something, like this:
1166
1167     ($tmp = $global) =~ tr/13579/24680/;
1168
1169 Although as of 5.14, that can be also be accomplished this way:
1170
1171     use v5.14;
1172     $tmp = ($global =~  tr/13579/24680/r);
1173
1174 Likewise,
1175
1176     ($x += 2) *= 3;
1177
1178 is equivalent to
1179
1180     $x += 2;
1181     $x *= 3;
1182
1183 Similarly, a list assignment in list context produces the list of
1184 lvalues assigned to, and a list assignment in scalar context returns
1185 the number of elements produced by the expression on the right hand
1186 side of the assignment.
1187
1188 The three dotted bitwise assignment operators (C<&.= |.= ^.=>) are new in
1189 Perl 5.22 and experimental.  See L</Bitwise String Operators>.
1190
1191 =head2 Comma Operator
1192 X<comma> X<operator, comma> X<,>
1193
1194 Binary "," is the comma operator.  In scalar context it evaluates
1195 its left argument, throws that value away, then evaluates its right
1196 argument and returns that value.  This is just like C's comma operator.
1197
1198 In list context, it's just the list argument separator, and inserts
1199 both its arguments into the list.  These arguments are also evaluated
1200 from left to right.
1201
1202 The C<< => >> operator is a synonym for the comma except that it causes a
1203 word on its left to be interpreted as a string if it begins with a letter
1204 or underscore and is composed only of letters, digits and underscores.
1205 This includes operands that might otherwise be interpreted as operators,
1206 constants, single number v-strings or function calls.  If in doubt about
1207 this behavior, the left operand can be quoted explicitly.
1208
1209 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1210 or list argument separator, according to context.
1211
1212 For example:
1213
1214     use constant FOO => "something";
1215
1216     my %h = ( FOO => 23 );
1217
1218 is equivalent to:
1219
1220     my %h = ("FOO", 23);
1221
1222 It is I<NOT>:
1223
1224     my %h = ("something", 23);
1225
1226 The C<< => >> operator is helpful in documenting the correspondence
1227 between keys and values in hashes, and other paired elements in lists.
1228
1229     %hash = ( $key => $value );
1230     login( $username => $password );
1231
1232 The special quoting behavior ignores precedence, and hence may apply to
1233 I<part> of the left operand:
1234
1235     print time.shift => "bbb";
1236
1237 That example prints something like "1314363215shiftbbb", because the
1238 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1239 the fact that C<time.shift> is the entire left operand.
1240
1241 =head2 List Operators (Rightward)
1242 X<operator, list, rightward> X<list operator>
1243
1244 On the right side of a list operator, the comma has very low precedence,
1245 such that it controls all comma-separated expressions found there.
1246 The only operators with lower precedence are the logical operators
1247 "and", "or", and "not", which may be used to evaluate calls to list
1248 operators without the need for parentheses:
1249
1250     open HANDLE, "< :utf8", "filename" or die "Can't open: $!\n";
1251
1252 However, some people find that code harder to read than writing
1253 it with parentheses:
1254
1255     open(HANDLE, "< :utf8", "filename") or die "Can't open: $!\n";
1256
1257 in which case you might as well just use the more customary "||" operator:
1258
1259     open(HANDLE, "< :utf8", "filename") || die "Can't open: $!\n";
1260
1261 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
1262
1263 =head2 Logical Not
1264 X<operator, logical, not> X<not>
1265
1266 Unary "not" returns the logical negation of the expression to its right.
1267 It's the equivalent of "!" except for the very low precedence.
1268
1269 =head2 Logical And
1270 X<operator, logical, and> X<and>
1271
1272 Binary "and" returns the logical conjunction of the two surrounding
1273 expressions.  It's equivalent to C<&&> except for the very low
1274 precedence.  This means that it short-circuits: the right
1275 expression is evaluated only if the left expression is true.
1276
1277 =head2 Logical or and Exclusive Or
1278 X<operator, logical, or> X<operator, logical, xor>
1279 X<operator, logical, exclusive or>
1280 X<or> X<xor>
1281
1282 Binary "or" returns the logical disjunction of the two surrounding
1283 expressions.  It's equivalent to C<||> except for the very low precedence.
1284 This makes it useful for control flow:
1285
1286     print FH $data              or die "Can't write to FH: $!";
1287
1288 This means that it short-circuits: the right expression is evaluated
1289 only if the left expression is false.  Due to its precedence, you must
1290 be careful to avoid using it as replacement for the C<||> operator.
1291 It usually works out better for flow control than in assignments:
1292
1293     $x = $y or $z;              # bug: this is wrong
1294     ($x = $y) or $z;            # really means this
1295     $x = $y || $z;              # better written this way
1296
1297 However, when it's a list-context assignment and you're trying to use
1298 C<||> for control flow, you probably need "or" so that the assignment
1299 takes higher precedence.
1300
1301     @info = stat($file) || die;     # oops, scalar sense of stat!
1302     @info = stat($file) or die;     # better, now @info gets its due
1303
1304 Then again, you could always use parentheses.
1305
1306 Binary C<xor> returns the exclusive-OR of the two surrounding expressions.
1307 It cannot short-circuit (of course).
1308
1309 There is no low precedence operator for defined-OR.
1310
1311 =head2 C Operators Missing From Perl
1312 X<operator, missing from perl> X<&> X<*>
1313 X<typecasting> X<(TYPE)>
1314
1315 Here is what C has that Perl doesn't:
1316
1317 =over 8
1318
1319 =item unary &
1320
1321 Address-of operator.  (But see the "\" operator for taking a reference.)
1322
1323 =item unary *
1324
1325 Dereference-address operator.  (Perl's prefix dereferencing
1326 operators are typed: $, @, %, and &.)
1327
1328 =item (TYPE)
1329
1330 Type-casting operator.
1331
1332 =back
1333
1334 =head2 Quote and Quote-like Operators
1335 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1336 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1337 X<escape sequence> X<escape>
1338
1339 While we usually think of quotes as literal values, in Perl they
1340 function as operators, providing various kinds of interpolating and
1341 pattern matching capabilities.  Perl provides customary quote characters
1342 for these behaviors, but also provides a way for you to choose your
1343 quote character for any of them.  In the following table, a C<{}> represents
1344 any pair of delimiters you choose.
1345
1346     Customary  Generic        Meaning        Interpolates
1347         ''       q{}          Literal             no
1348         ""      qq{}          Literal             yes
1349         ``      qx{}          Command             yes*
1350                 qw{}         Word list            no
1351         //       m{}       Pattern match          yes*
1352                 qr{}          Pattern             yes*
1353                  s{}{}      Substitution          yes*
1354                 tr{}{}    Transliteration         no (but see below)
1355                  y{}{}    Transliteration         no (but see below)
1356         <<EOF                 here-doc            yes*
1357
1358         * unless the delimiter is ''.
1359
1360 Non-bracketing delimiters use the same character fore and aft, but the four
1361 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1362 that
1363
1364     q{foo{bar}baz}
1365
1366 is the same as
1367
1368     'foo{bar}baz'
1369
1370 Note, however, that this does not always work for quoting Perl code:
1371
1372     $s = q{ if($x eq "}") ... }; # WRONG
1373
1374 is a syntax error.  The C<Text::Balanced> module (standard as of v5.8,
1375 and from CPAN before then) is able to do this properly.
1376
1377 There can be whitespace between the operator and the quoting
1378 characters, except when C<#> is being used as the quoting character.
1379 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
1380 operator C<q> followed by a comment.  Its argument will be taken
1381 from the next line.  This allows you to write:
1382
1383     s {foo}  # Replace foo
1384       {bar}  # with bar.
1385
1386 The following escape sequences are available in constructs that interpolate,
1387 and in transliterations:
1388 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1389 X<\o{}>
1390
1391     Sequence     Note  Description
1392     \t                  tab               (HT, TAB)
1393     \n                  newline           (NL)
1394     \r                  return            (CR)
1395     \f                  form feed         (FF)
1396     \b                  backspace         (BS)
1397     \a                  alarm (bell)      (BEL)
1398     \e                  escape            (ESC)
1399     \x{263A}     [1,8]  hex char          (example: SMILEY)
1400     \x1b         [2,8]  restricted range hex char (example: ESC)
1401     \N{name}     [3]    named Unicode character or character sequence
1402     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1403     \c[          [5]    control char      (example: chr(27))
1404     \o{23072}    [6,8]  octal char        (example: SMILEY)
1405     \033         [7,8]  restricted range octal char  (example: ESC)
1406
1407 =over 4
1408
1409 =item [1]
1410
1411 The result is the character specified by the hexadecimal number between
1412 the braces.  See L</[8]> below for details on which character.
1413
1414 Only hexadecimal digits are valid between the braces.  If an invalid
1415 character is encountered, a warning will be issued and the invalid
1416 character and all subsequent characters (valid or invalid) within the
1417 braces will be discarded.
1418
1419 If there are no valid digits between the braces, the generated character is
1420 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1421 will not cause a warning (currently).
1422
1423 =item [2]
1424
1425 The result is the character specified by the hexadecimal number in the range
1426 0x00 to 0xFF.  See L</[8]> below for details on which character.
1427
1428 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1429 by fewer than two valid digits, any valid digits will be zero-padded.  This
1430 means that C<\x7> will be interpreted as C<\x07>, and a lone <\x> will be
1431 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1432 two valid digits will result in a warning.  Note that although the warning
1433 says the illegal character is ignored, it is only ignored as part of the
1434 escape and will still be used as the subsequent character in the string.
1435 For example:
1436
1437   Original    Result    Warns?
1438   "\x7"       "\x07"    no
1439   "\x"        "\x00"    no
1440   "\x7q"      "\x07q"   yes
1441   "\xq"       "\x00q"   yes
1442
1443 =item [3]
1444
1445 The result is the Unicode character or character sequence given by I<name>.
1446 See L<charnames>.
1447
1448 =item [4]
1449
1450 C<\N{U+I<hexadecimal number>}> means the Unicode character whose Unicode code
1451 point is I<hexadecimal number>.
1452
1453 =item [5]
1454
1455 The character following C<\c> is mapped to some other character as shown in the
1456 table:
1457
1458  Sequence   Value
1459    \c@      chr(0)
1460    \cA      chr(1)
1461    \ca      chr(1)
1462    \cB      chr(2)
1463    \cb      chr(2)
1464    ...
1465    \cZ      chr(26)
1466    \cz      chr(26)
1467    \c[      chr(27)
1468    \c]      chr(29)
1469    \c^      chr(30)
1470    \c_      chr(31)
1471    \c?      chr(127) # (on ASCII platforms)
1472
1473 In other words, it's the character whose code point has had 64 xor'd with
1474 its uppercase.  C<\c?> is DELETE on ASCII platforms because
1475 S<C<ord("?") ^ 64>> is 127, and
1476 C<\c@> is NULL because the ord of "@" is 64, so xor'ing 64 itself produces 0.
1477
1478 Also, C<\c\I<X>> yields C< chr(28) . "I<X>"> for any I<X>, but cannot come at the
1479 end of a string, because the backslash would be parsed as escaping the end
1480 quote.
1481
1482 On ASCII platforms, the resulting characters from the list above are the
1483 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1484 L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the
1485 differences between these for ASCII versus EBCDIC platforms.
1486
1487 Use of any other character following the C<"c"> besides those listed above is
1488 discouraged, and as of Perl v5.20, the only characters actually allowed
1489 are the printable ASCII ones, minus the left brace C<"{">.  What happens
1490 for any of the allowed other characters is that the value is derived by
1491 xor'ing with the seventh bit, which is 64, and a warning raised if
1492 enabled.  Using the non-allowed characters generates a fatal error.
1493
1494 To get platform independent controls, you can use C<\N{...}>.
1495
1496 =item [6]
1497
1498 The result is the character specified by the octal number between the braces.
1499 See L</[8]> below for details on which character.
1500
1501 If a character that isn't an octal digit is encountered, a warning is raised,
1502 and the value is based on the octal digits before it, discarding it and all
1503 following characters up to the closing brace.  It is a fatal error if there are
1504 no octal digits at all.
1505
1506 =item [7]
1507
1508 The result is the character specified by the three-digit octal number in the
1509 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1510 L</[8]> below for details on which character.
1511
1512 Some contexts allow 2 or even 1 digit, but any usage without exactly
1513 three digits, the first being a zero, may give unintended results.  (For
1514 example, in a regular expression it may be confused with a backreference;
1515 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1516 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1517 use this construct only for ordinals C<\077> and below, remembering to pad to
1518 the left with zeros to make three digits.  For larger ordinals, either use
1519 C<\o{}>, or convert to something else, such as to hex and use C<\x{}>
1520 instead.
1521
1522 =item [8]
1523
1524 Several constructs above specify a character by a number.  That number
1525 gives the character's position in the character set encoding (indexed from 0).
1526 This is called synonymously its ordinal, code position, or code point.  Perl
1527 works on platforms that have a native encoding currently of either ASCII/Latin1
1528 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1529 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1530 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1531 it as a Unicode code point and the result is the corresponding Unicode
1532 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1533 decimal, which is less than 256, so the number is interpreted in the native
1534 character set encoding.  In ASCII the character in the 80th position (indexed
1535 from 0) is the letter "P", and in EBCDIC it is the ampersand symbol "&".
1536 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1537 as a Unicode code point no matter what the native encoding is.  The name of the
1538 character in the 256th position (indexed by 0) in Unicode is
1539 C<LATIN CAPITAL LETTER A WITH MACRON>.
1540
1541 There are a couple of exceptions to the above rule.  S<C<\N{U+I<hex number>}>> is
1542 always interpreted as a Unicode code point, so that C<\N{U+0050}> is "P" even
1543 on EBCDIC platforms.  And if L<C<S<use encoding>>|encoding> is in effect, the
1544 number is considered to be in that encoding, and is translated from that into
1545 the platform's native encoding if there is a corresponding native character;
1546 otherwise to Unicode.
1547
1548 =back
1549
1550 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1551 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1552 use C<\ck> or
1553 C<\x0b>.  (C<\v>
1554 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1555
1556 The following escape sequences are available in constructs that interpolate,
1557 but not in transliterations.
1558 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1559
1560     \l          lowercase next character only
1561     \u          titlecase (not uppercase!) next character only
1562     \L          lowercase all characters till \E or end of string
1563     \U          uppercase all characters till \E or end of string
1564     \F          foldcase all characters till \E or end of string
1565     \Q          quote (disable) pattern metacharacters till \E or
1566                 end of string
1567     \E          end either case modification or quoted section
1568                 (whichever was last seen)
1569
1570 See L<perlfunc/quotemeta> for the exact definition of characters that
1571 are quoted by C<\Q>.
1572
1573 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1574 C<\E> for each.  For example:
1575
1576  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1577  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1578
1579 If C<use locale> is in effect (but not C<use locale ':not_characters'>),
1580 the case map used by C<\l>, C<\L>,
1581 C<\u>, and C<\U> is taken from the current locale.  See L<perllocale>.
1582 If Unicode (for example, C<\N{}> or code points of 0x100 or
1583 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u>, and
1584 C<\U> is as defined by Unicode.  That means that case-mapping
1585 a single character can sometimes produce several characters.
1586 Under C<use locale>, C<\F> produces the same results as C<\L>
1587 for all locales but a UTF-8 one, where it instead uses the Unicode
1588 definition.
1589
1590 All systems use the virtual C<"\n"> to represent a line terminator,
1591 called a "newline".  There is no such thing as an unvarying, physical
1592 newline character.  It is only an illusion that the operating system,
1593 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1594 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1595 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1596 and on systems without line terminator,
1597 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1598 you mean a "newline" for your system, but use the literal ASCII when you
1599 need an exact character.  For example, most networking protocols expect
1600 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1601 and although they often accept just C<"\012">, they seldom tolerate just
1602 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1603 you may be burned some day.
1604 X<newline> X<line terminator> X<eol> X<end of line>
1605 X<\n> X<\r> X<\r\n>
1606
1607 For constructs that do interpolate, variables beginning with "C<$>"
1608 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1609 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1610 But method calls such as C<< $obj->meth >> are not.
1611
1612 Interpolating an array or slice interpolates the elements in order,
1613 separated by the value of C<$">, so is equivalent to interpolating
1614 C<join $", @array>.  "Punctuation" arrays such as C<@*> are usually
1615 interpolated only if the name is enclosed in braces C<@{*}>, but the
1616 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1617
1618 For double-quoted strings, the quoting from C<\Q> is applied after
1619 interpolation and escapes are processed.
1620
1621     "abc\Qfoo\tbar$s\Exyz"
1622
1623 is equivalent to
1624
1625     "abc" . quotemeta("foo\tbar$s") . "xyz"
1626
1627 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1628 the quoting from C<\Q> is applied after interpolation is processed,
1629 but before escapes are processed.  This allows the pattern to match
1630 literally (except for C<$> and C<@>).  For example, the following matches:
1631
1632     '\s\t' =~ /\Q\s\t/
1633
1634 Because C<$> or C<@> trigger interpolation, you'll need to use something
1635 like C</\Quser\E\@\Qhost/> to match them literally.
1636
1637 Patterns are subject to an additional level of interpretation as a
1638 regular expression.  This is done as a second pass, after variables are
1639 interpolated, so that regular expressions may be incorporated into the
1640 pattern from the variables.  If this is not what you want, use C<\Q> to
1641 interpolate a variable literally.
1642
1643 Apart from the behavior described above, Perl does not expand
1644 multiple levels of interpolation.  In particular, contrary to the
1645 expectations of shell programmers, back-quotes do I<NOT> interpolate
1646 within double quotes, nor do single quotes impede evaluation of
1647 variables when used within double quotes.
1648
1649 =head2 Regexp Quote-Like Operators
1650 X<operator, regexp>
1651
1652 Here are the quote-like operators that apply to pattern
1653 matching and related activities.
1654
1655 =over 8
1656
1657 =item qr/STRING/msixpodualn
1658 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1659
1660 This operator quotes (and possibly compiles) its I<STRING> as a regular
1661 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1662 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1663 is done.  Returns a Perl value which may be used instead of the
1664 corresponding C</STRING/msixpodualn> expression.  The returned value is a
1665 normalized version of the original pattern.  It magically differs from
1666 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1667 however, dereferencing it is not well defined (you currently get the 
1668 normalized version of the original pattern, but this may change).
1669
1670
1671 For example,
1672
1673     $rex = qr/my.STRING/is;
1674     print $rex;                 # prints (?si-xm:my.STRING)
1675     s/$rex/foo/;
1676
1677 is equivalent to
1678
1679     s/my.STRING/foo/is;
1680
1681 The result may be used as a subpattern in a match:
1682
1683     $re = qr/$pattern/;
1684     $string =~ /foo${re}bar/;   # can be interpolated in other
1685                                 # patterns
1686     $string =~ $re;             # or used standalone
1687     $string =~ /$re/;           # or this way
1688
1689 Since Perl may compile the pattern at the moment of execution of the qr()
1690 operator, using qr() may have speed advantages in some situations,
1691 notably if the result of qr() is used standalone:
1692
1693     sub match {
1694         my $patterns = shift;
1695         my @compiled = map qr/$_/i, @$patterns;
1696         grep {
1697             my $success = 0;
1698             foreach my $pat (@compiled) {
1699                 $success = 1, last if /$pat/;
1700             }
1701             $success;
1702         } @_;
1703     }
1704
1705 Precompilation of the pattern into an internal representation at
1706 the moment of qr() avoids a need to recompile the pattern every
1707 time a match C</$pat/> is attempted.  (Perl has many other internal
1708 optimizations, but none would be triggered in the above example if
1709 we did not use qr() operator.)
1710
1711 Options (specified by the following modifiers) are:
1712
1713     m   Treat string as multiple lines.
1714     s   Treat string as single line. (Make . match a newline)
1715     i   Do case-insensitive pattern matching.
1716     x   Use extended regular expressions.
1717     p   When matching preserve a copy of the matched string so
1718         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1719         defined.
1720     o   Compile pattern only once.
1721     a   ASCII-restrict: Use ASCII for \d, \s, \w; specifying two
1722         a's further restricts /i matching so that no ASCII
1723         character will match a non-ASCII one.
1724     l   Use the locale.
1725     u   Use Unicode rules.
1726     d   Use Unicode or native charset, as in 5.12 and earlier.
1727     n   Non-capture mode. Don't let () fill in $1, $2, etc...
1728
1729 If a precompiled pattern is embedded in a larger pattern then the effect
1730 of "msixpluadn" will be propagated appropriately.  The effect the "o"
1731 modifier has is not propagated, being restricted to those patterns
1732 explicitly using it.
1733
1734 The last four modifiers listed above, added in Perl 5.14,
1735 control the character set rules, but C</a> is the only one you are likely
1736 to want to specify explicitly; the other three are selected
1737 automatically by various pragmas.
1738
1739 See L<perlre> for additional information on valid syntax for STRING, and
1740 for a detailed look at the semantics of regular expressions.  In
1741 particular, all modifiers except the largely obsolete C</o> are further
1742 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1743
1744 =item m/PATTERN/msixpodualngc
1745 X<m> X<operator, match>
1746 X<regexp, options> X<regexp> X<regex, options> X<regex>
1747 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1748
1749 =item /PATTERN/msixpodualngc
1750
1751 Searches a string for a pattern match, and in scalar context returns
1752 true if it succeeds, false if it fails.  If no string is specified
1753 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1754 string specified with C<=~> need not be an lvalue--it may be the
1755 result of an expression evaluation, but remember the C<=~> binds
1756 rather tightly.)  See also L<perlre>.
1757
1758 Options are as described in C<qr//> above; in addition, the following match
1759 process modifiers are available:
1760
1761  g  Match globally, i.e., find all occurrences.
1762  c  Do not reset search position on a failed match when /g is
1763     in effect.
1764
1765 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1766 you can use any pair of non-whitespace (ASCII) characters
1767 as delimiters.  This is particularly useful for matching path names
1768 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1769 the delimiter, then a match-only-once rule applies,
1770 described in C<m?PATTERN?> below.  If "'" (single quote) is the delimiter,
1771 no interpolation is performed on the PATTERN.
1772 When using a character valid in an identifier, whitespace is required
1773 after the C<m>.
1774
1775 PATTERN may contain variables, which will be interpolated
1776 every time the pattern search is evaluated, except
1777 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1778 C<$|> are not interpolated because they look like end-of-string tests.)
1779 Perl will not recompile the pattern unless an interpolated
1780 variable that it contains changes.  You can force Perl to skip the
1781 test and never recompile by adding a C</o> (which stands for "once")
1782 after the trailing delimiter.
1783 Once upon a time, Perl would recompile regular expressions
1784 unnecessarily, and this modifier was useful to tell it not to do so, in the
1785 interests of speed.  But now, the only reasons to use C</o> are one of:
1786
1787 =over
1788
1789 =item 1
1790
1791 The variables are thousands of characters long and you know that they
1792 don't change, and you need to wring out the last little bit of speed by
1793 having Perl skip testing for that.  (There is a maintenance penalty for
1794 doing this, as mentioning C</o> constitutes a promise that you won't
1795 change the variables in the pattern.  If you do change them, Perl won't
1796 even notice.)
1797
1798 =item 2
1799
1800 you want the pattern to use the initial values of the variables
1801 regardless of whether they change or not.  (But there are saner ways
1802 of accomplishing this than using C</o>.)
1803
1804 =item 3
1805
1806 If the pattern contains embedded code, such as
1807
1808     use re 'eval';
1809     $code = 'foo(?{ $x })';
1810     /$code/
1811
1812 then perl will recompile each time, even though the pattern string hasn't
1813 changed, to ensure that the current value of C<$x> is seen each time.
1814 Use C</o> if you want to avoid this.
1815
1816 =back
1817
1818 The bottom line is that using C</o> is almost never a good idea.
1819
1820 =item The empty pattern //
1821
1822 If the PATTERN evaluates to the empty string, the last
1823 I<successfully> matched regular expression is used instead.  In this
1824 case, only the C<g> and C<c> flags on the empty pattern are honored;
1825 the other flags are taken from the original pattern.  If no match has
1826 previously succeeded, this will (silently) act instead as a genuine
1827 empty pattern (which will always match).
1828
1829 Note that it's possible to confuse Perl into thinking C<//> (the empty
1830 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1831 good about this, but some pathological cases might trigger this, such as
1832 C<$x///> (is that C<($x) / (//)> or C<$x // />?) and C<print $fh //>
1833 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1834 will assume you meant defined-or.  If you meant the empty regex, just
1835 use parentheses or spaces to disambiguate, or even prefix the empty
1836 regex with an C<m> (so C<//> becomes C<m//>).
1837
1838 =item Matching in list context
1839
1840 If the C</g> option is not used, C<m//> in list context returns a
1841 list consisting of the subexpressions matched by the parentheses in the
1842 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1843 also set).  When there are no parentheses in the pattern, the return
1844 value is the list C<(1)> for success.  
1845 With or without parentheses, an empty list is returned upon failure.
1846
1847 Examples:
1848
1849  open(TTY, "+</dev/tty")
1850     || die "can't access /dev/tty: $!";
1851
1852  <TTY> =~ /^y/i && foo();       # do foo if desired
1853
1854  if (/Version: *([0-9.]*)/) { $version = $1; }
1855
1856  next if m#^/usr/spool/uucp#;
1857
1858  # poor man's grep
1859  $arg = shift;
1860  while (<>) {
1861     print if /$arg/o; # compile only once (no longer needed!)
1862  }
1863
1864  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1865
1866 This last example splits $foo into the first two words and the
1867 remainder of the line, and assigns those three fields to $F1, $F2, and
1868 $Etc.  The conditional is true if any variables were assigned; that is,
1869 if the pattern matched.
1870
1871 The C</g> modifier specifies global pattern matching--that is,
1872 matching as many times as possible within the string.  How it behaves
1873 depends on the context.  In list context, it returns a list of the
1874 substrings matched by any capturing parentheses in the regular
1875 expression.  If there are no parentheses, it returns a list of all
1876 the matched strings, as if there were parentheses around the whole
1877 pattern.
1878
1879 In scalar context, each execution of C<m//g> finds the next match,
1880 returning true if it matches, and false if there is no further match.
1881 The position after the last match can be read or set using the C<pos()>
1882 function; see L<perlfunc/pos>.  A failed match normally resets the
1883 search position to the beginning of the string, but you can avoid that
1884 by adding the C</c> modifier (for example, C<m//gc>).  Modifying the target
1885 string also resets the search position.
1886
1887 =item \G assertion
1888
1889 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1890 zero-width assertion that matches the exact position where the
1891 previous C<m//g>, if any, left off.  Without the C</g> modifier, the
1892 C<\G> assertion still anchors at C<pos()> as it was at the start of
1893 the operation (see L<perlfunc/pos>), but the match is of course only
1894 attempted once.  Using C<\G> without C</g> on a target string that has
1895 not previously had a C</g> match applied to it is the same as using
1896 the C<\A> assertion to match the beginning of the string.  Note also
1897 that, currently, C<\G> is only properly supported when anchored at the
1898 very beginning of the pattern.
1899
1900 Examples:
1901
1902     # list context
1903     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1904
1905     # scalar context
1906     local $/ = "";
1907     while ($paragraph = <>) {
1908         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1909             $sentences++;
1910         }
1911     }
1912     say $sentences;
1913
1914 Here's another way to check for sentences in a paragraph:
1915
1916  my $sentence_rx = qr{
1917     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1918                                 # whitespace
1919     \p{Lu}                      # capital letter
1920     .*?                         # a bunch of anything
1921     (?<= \S )                   # that ends in non-
1922                                 # whitespace
1923     (?<! \b [DMS]r  )           # but isn't a common abbr.
1924     (?<! \b Mrs )
1925     (?<! \b Sra )
1926     (?<! \b St  )
1927     [.?!]                       # followed by a sentence
1928                                 # ender
1929     (?= $ | \s )                # in front of end-of-string
1930                                 # or whitespace
1931  }sx;
1932  local $/ = "";
1933  while (my $paragraph = <>) {
1934     say "NEW PARAGRAPH";
1935     my $count = 0;
1936     while ($paragraph =~ /($sentence_rx)/g) {
1937         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1938     }
1939  }
1940
1941 Here's how to use C<m//gc> with C<\G>:
1942
1943     $_ = "ppooqppqq";
1944     while ($i++ < 2) {
1945         print "1: '";
1946         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1947         print "2: '";
1948         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1949         print "3: '";
1950         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1951     }
1952     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1953
1954 The last example should print:
1955
1956     1: 'oo', pos=4
1957     2: 'q', pos=5
1958     3: 'pp', pos=7
1959     1: '', pos=7
1960     2: 'q', pos=8
1961     3: '', pos=8
1962     Final: 'q', pos=8
1963
1964 Notice that the final match matched C<q> instead of C<p>, which a match
1965 without the C<\G> anchor would have done.  Also note that the final match
1966 did not update C<pos>.  C<pos> is only updated on a C</g> match.  If the
1967 final match did indeed match C<p>, it's a good bet that you're running a
1968 very old (pre-5.6.0) version of Perl.
1969
1970 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1971 combine several regexps like this to process a string part-by-part,
1972 doing different actions depending on which regexp matched.  Each
1973 regexp tries to match where the previous one leaves off.
1974
1975  $_ = <<'EOL';
1976     $url = URI::URL->new( "http://example.com/" );
1977     die if $url eq "xXx";
1978  EOL
1979
1980  LOOP: {
1981      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1982      print(" lowercase"),    redo LOOP
1983                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
1984      print(" UPPERCASE"),    redo LOOP
1985                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
1986      print(" Capitalized"),  redo LOOP
1987                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
1988      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
1989      print(" alphanumeric"), redo LOOP
1990                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
1991      print(" line-noise"),   redo LOOP if /\G\W+/gc;
1992      print ". That's all!\n";
1993  }
1994
1995 Here is the output (split into several lines):
1996
1997  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
1998  line-noise lowercase line-noise lowercase line-noise lowercase
1999  lowercase line-noise lowercase lowercase line-noise lowercase
2000  lowercase line-noise MiXeD line-noise. That's all!
2001
2002 =item m?PATTERN?msixpodualngc
2003 X<?> X<operator, match-once>
2004
2005 =item ?PATTERN?msixpodualngc
2006
2007 This is just like the C<m/PATTERN/> search, except that it matches
2008 only once between calls to the reset() operator.  This is a useful
2009 optimization when you want to see only the first occurrence of
2010 something in each file of a set of files, for instance.  Only C<m??>
2011 patterns local to the current package are reset.
2012
2013     while (<>) {
2014         if (m?^$?) {
2015                             # blank line between header and body
2016         }
2017     } continue {
2018         reset if eof;       # clear m?? status for next file
2019     }
2020
2021 Another example switched the first "latin1" encoding it finds
2022 to "utf8" in a pod file:
2023
2024     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
2025
2026 The match-once behavior is controlled by the match delimiter being
2027 C<?>; with any other delimiter this is the normal C<m//> operator.
2028
2029 In the past, the leading C<m> in C<m?PATTERN?> was optional, but omitting it
2030 would produce a deprecation warning.  As of v5.22.0, omitting it produces a
2031 syntax error.  If you encounter this construct in older code, you can just add
2032 C<m>.
2033
2034 =item s/PATTERN/REPLACEMENT/msixpodualngcer
2035 X<substitute> X<substitution> X<replace> X<regexp, replace>
2036 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2037
2038 Searches a string for a pattern, and if found, replaces that pattern
2039 with the replacement text and returns the number of substitutions
2040 made.  Otherwise it returns false (specifically, the empty string).
2041
2042 If the C</r> (non-destructive) option is used then it runs the
2043 substitution on a copy of the string and instead of returning the
2044 number of substitutions, it returns the copy whether or not a
2045 substitution occurred.  The original string is never changed when
2046 C</r> is used.  The copy will always be a plain string, even if the
2047 input is an object or a tied variable.
2048
2049 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2050 variable is searched and modified.  Unless the C</r> option is used,
2051 the string specified must be a scalar variable, an array element, a
2052 hash element, or an assignment to one of those; that is, some sort of
2053 scalar lvalue.
2054
2055 If the delimiter chosen is a single quote, no interpolation is
2056 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
2057 PATTERN contains a $ that looks like a variable rather than an
2058 end-of-string test, the variable will be interpolated into the pattern
2059 at run-time.  If you want the pattern compiled only once the first time
2060 the variable is interpolated, use the C</o> option.  If the pattern
2061 evaluates to the empty string, the last successfully executed regular
2062 expression is used instead.  See L<perlre> for further explanation on these.
2063
2064 Options are as with m// with the addition of the following replacement
2065 specific options:
2066
2067     e   Evaluate the right side as an expression.
2068     ee  Evaluate the right side as a string then eval the
2069         result.
2070     r   Return substitution and leave the original string
2071         untouched.
2072
2073 Any non-whitespace delimiter may replace the slashes.  Add space after
2074 the C<s> when using a character allowed in identifiers.  If single quotes
2075 are used, no interpretation is done on the replacement string (the C</e>
2076 modifier overrides this, however).  Note that Perl treats backticks
2077 as normal delimiters; the replacement text is not evaluated as a command.
2078 If the PATTERN is delimited by bracketing quotes, the REPLACEMENT has
2079 its own pair of quotes, which may or may not be bracketing quotes, for example,
2080 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2081 replacement portion to be treated as a full-fledged Perl expression
2082 and evaluated right then and there.  It is, however, syntax checked at
2083 compile-time.  A second C<e> modifier will cause the replacement portion
2084 to be C<eval>ed before being run as a Perl expression.
2085
2086 Examples:
2087
2088     s/\bgreen\b/mauve/g;              # don't change wintergreen
2089
2090     $path =~ s|/usr/bin|/usr/local/bin|;
2091
2092     s/Login: $foo/Login: $bar/; # run-time pattern
2093
2094     ($foo = $bar) =~ s/this/that/;      # copy first, then
2095                                         # change
2096     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2097                                         # copy, then change
2098     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2099     $foo = $bar =~ s/this/that/r
2100                 =~ s/that/the other/r;  # Chained substitutes
2101                                         # using /r
2102     @foo = map { s/this/that/r } @bar   # /r is very useful in
2103                                         # maps
2104
2105     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2106
2107     $_ = 'abc123xyz';
2108     s/\d+/$&*2/e;               # yields 'abc246xyz'
2109     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2110     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2111
2112     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2113     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2114     s/^=(\w+)/pod($1)/ge;       # use function call
2115
2116     $_ = 'abc123xyz';
2117     $x = s/abc/def/r;           # $x is 'def123xyz' and
2118                                 # $_ remains 'abc123xyz'.
2119
2120     # expand variables in $_, but dynamics only, using
2121     # symbolic dereferencing
2122     s/\$(\w+)/${$1}/g;
2123
2124     # Add one to the value of any numbers in the string
2125     s/(\d+)/1 + $1/eg;
2126
2127     # Titlecase words in the last 30 characters only
2128     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2129
2130     # This will expand any embedded scalar variable
2131     # (including lexicals) in $_ : First $1 is interpolated
2132     # to the variable name, and then evaluated
2133     s/(\$\w+)/$1/eeg;
2134
2135     # Delete (most) C comments.
2136     $program =~ s {
2137         /\*     # Match the opening delimiter.
2138         .*?     # Match a minimal number of characters.
2139         \*/     # Match the closing delimiter.
2140     } []gsx;
2141
2142     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2143                                 # expensively
2144
2145     for ($variable) {           # trim whitespace in $variable,
2146                                 # cheap
2147         s/^\s+//;
2148         s/\s+$//;
2149     }
2150
2151     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2152
2153 Note the use of $ instead of \ in the last example.  Unlike
2154 B<sed>, we use the \<I<digit>> form in only the left hand side.
2155 Anywhere else it's $<I<digit>>.
2156
2157 Occasionally, you can't use just a C</g> to get all the changes
2158 to occur that you might want.  Here are two common cases:
2159
2160     # put commas in the right places in an integer
2161     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2162
2163     # expand tabs to 8-column spacing
2164     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2165
2166 =back
2167
2168 =head2 Quote-Like Operators
2169 X<operator, quote-like>
2170
2171 =over 4
2172
2173 =item q/STRING/
2174 X<q> X<quote, single> X<'> X<''>
2175
2176 =item 'STRING'
2177
2178 A single-quoted, literal string.  A backslash represents a backslash
2179 unless followed by the delimiter or another backslash, in which case
2180 the delimiter or backslash is interpolated.
2181
2182     $foo = q!I said, "You said, 'She said it.'"!;
2183     $bar = q('This is it.');
2184     $baz = '\n';                # a two-character string
2185
2186 =item qq/STRING/
2187 X<qq> X<quote, double> X<"> X<"">
2188
2189 =item "STRING"
2190
2191 A double-quoted, interpolated string.
2192
2193     $_ .= qq
2194      (*** The previous line contains the naughty word "$1".\n)
2195                 if /\b(tcl|java|python)\b/i;      # :-)
2196     $baz = "\n";                # a one-character string
2197
2198 =item qx/STRING/
2199 X<qx> X<`> X<``> X<backtick>
2200
2201 =item `STRING`
2202
2203 A string which is (possibly) interpolated and then executed as a
2204 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2205 pipes, and redirections will be honored.  The collected standard
2206 output of the command is returned; standard error is unaffected.  In
2207 scalar context, it comes back as a single (potentially multi-line)
2208 string, or undef if the command failed.  In list context, returns a
2209 list of lines (however you've defined lines with $/ or
2210 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
2211
2212 Because backticks do not affect standard error, use shell file descriptor
2213 syntax (assuming the shell supports this) if you care to address this.
2214 To capture a command's STDERR and STDOUT together:
2215
2216     $output = `cmd 2>&1`;
2217
2218 To capture a command's STDOUT but discard its STDERR:
2219
2220     $output = `cmd 2>/dev/null`;
2221
2222 To capture a command's STDERR but discard its STDOUT (ordering is
2223 important here):
2224
2225     $output = `cmd 2>&1 1>/dev/null`;
2226
2227 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2228 but leave its STDOUT to come out the old STDERR:
2229
2230     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2231
2232 To read both a command's STDOUT and its STDERR separately, it's easiest
2233 to redirect them separately to files, and then read from those files
2234 when the program is done:
2235
2236     system("program args 1>program.stdout 2>program.stderr");
2237
2238 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2239 For example:
2240
2241     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2242     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2243     print STDOUT `sort`;
2244
2245 will print the sorted contents of the file named F<"stuff">.
2246
2247 Using single-quote as a delimiter protects the command from Perl's
2248 double-quote interpolation, passing it on to the shell instead:
2249
2250     $perl_info  = qx(ps $$);            # that's Perl's $$
2251     $shell_info = qx'ps $$';            # that's the new shell's $$
2252
2253 How that string gets evaluated is entirely subject to the command
2254 interpreter on your system.  On most platforms, you will have to protect
2255 shell metacharacters if you want them treated literally.  This is in
2256 practice difficult to do, as it's unclear how to escape which characters.
2257 See L<perlsec> for a clean and safe example of a manual fork() and exec()
2258 to emulate backticks safely.
2259
2260 On some platforms (notably DOS-like ones), the shell may not be
2261 capable of dealing with multiline commands, so putting newlines in
2262 the string may not get you what you want.  You may be able to evaluate
2263 multiple commands in a single line by separating them with the command
2264 separator character, if your shell supports that (for example, C<;> on 
2265 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2266
2267 Perl will attempt to flush all files opened for
2268 output before starting the child process, but this may not be supported
2269 on some platforms (see L<perlport>).  To be safe, you may need to set
2270 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2271 C<IO::Handle> on any open handles.
2272
2273 Beware that some command shells may place restrictions on the length
2274 of the command line.  You must ensure your strings don't exceed this
2275 limit after any necessary interpolations.  See the platform-specific
2276 release notes for more details about your particular environment.
2277
2278 Using this operator can lead to programs that are difficult to port,
2279 because the shell commands called vary between systems, and may in
2280 fact not be present at all.  As one example, the C<type> command under
2281 the POSIX shell is very different from the C<type> command under DOS.
2282 That doesn't mean you should go out of your way to avoid backticks
2283 when they're the right way to get something done.  Perl was made to be
2284 a glue language, and one of the things it glues together is commands.
2285 Just understand what you're getting yourself into.
2286
2287 See L</"I/O Operators"> for more discussion.
2288
2289 =item qw/STRING/
2290 X<qw> X<quote, list> X<quote, words>
2291
2292 Evaluates to a list of the words extracted out of STRING, using embedded
2293 whitespace as the word delimiters.  It can be understood as being roughly
2294 equivalent to:
2295
2296     split(" ", q/STRING/);
2297
2298 the differences being that it generates a real list at compile time, and
2299 in scalar context it returns the last element in the list.  So
2300 this expression:
2301
2302     qw(foo bar baz)
2303
2304 is semantically equivalent to the list:
2305
2306     "foo", "bar", "baz"
2307
2308 Some frequently seen examples:
2309
2310     use POSIX qw( setlocale localeconv )
2311     @EXPORT = qw( foo bar baz );
2312
2313 A common mistake is to try to separate the words with comma or to
2314 put comments into a multi-line C<qw>-string.  For this reason, the
2315 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
2316 produces warnings if the STRING contains the "," or the "#" character.
2317
2318 =item tr/SEARCHLIST/REPLACEMENTLIST/cdsr
2319 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2320
2321 =item y/SEARCHLIST/REPLACEMENTLIST/cdsr
2322
2323 Transliterates all occurrences of the characters found in the search list
2324 with the corresponding character in the replacement list.  It returns
2325 the number of characters replaced or deleted.  If no string is
2326 specified via the C<=~> or C<!~> operator, the $_ string is transliterated.
2327
2328 If the C</r> (non-destructive) option is present, a new copy of the string
2329 is made and its characters transliterated, and this copy is returned no
2330 matter whether it was modified or not: the original string is always
2331 left unchanged.  The new copy is always a plain string, even if the input
2332 string is an object or a tied variable.
2333
2334 Unless the C</r> option is used, the string specified with C<=~> must be a
2335 scalar variable, an array element, a hash element, or an assignment to one
2336 of those; in other words, an lvalue.
2337
2338 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2339 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2340 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2341 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
2342 its own pair of quotes, which may or may not be bracketing quotes;
2343 for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2344
2345 Note that C<tr> does B<not> do regular expression character classes such as
2346 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the tr(1)
2347 utility.  If you want to map strings between lower/upper cases, see
2348 L<perlfunc/lc> and L<perlfunc/uc>, and in general consider using the C<s>
2349 operator if you need regular expressions.  The C<\U>, C<\u>, C<\L>, and
2350 C<\l> string-interpolation escapes on the right side of a substitution
2351 operator will perform correct case-mappings, but C<tr[a-z][A-Z]> will not
2352 (except sometimes on legacy 7-bit data).
2353
2354 Note also that the whole range idea is rather unportable between
2355 character sets--and even within character sets they may cause results
2356 you probably didn't expect.  A sound principle is to use only ranges
2357 that begin from and end at either alphabets of equal case (a-e, A-E),
2358 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
2359 character sets in full.
2360
2361 Options:
2362
2363     c   Complement the SEARCHLIST.
2364     d   Delete found but unreplaced characters.
2365     s   Squash duplicate replaced characters.
2366     r   Return the modified string and leave the original string
2367         untouched.
2368
2369 If the C</c> modifier is specified, the SEARCHLIST character set
2370 is complemented.  If the C</d> modifier is specified, any characters
2371 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
2372 (Note that this is slightly more flexible than the behavior of some
2373 B<tr> programs, which delete anything they find in the SEARCHLIST,
2374 period.)  If the C</s> modifier is specified, sequences of characters
2375 that were transliterated to the same character are squashed down
2376 to a single instance of the character.
2377
2378 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
2379 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
2380 than the SEARCHLIST, the final character is replicated till it is long
2381 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
2382 This latter is useful for counting characters in a class or for
2383 squashing character sequences in a class.
2384
2385 Examples:
2386
2387     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2388
2389     $cnt = tr/*/*/;             # count the stars in $_
2390
2391     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2392
2393     $cnt = tr/0-9//;            # count the digits in $_
2394
2395     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2396
2397     ($HOST = $host) =~ tr/a-z/A-Z/;
2398      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2399
2400     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2401                   =~ s/:/ -p/r;
2402
2403     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2404
2405     @stripped = map tr/a-zA-Z/ /csr, @original;
2406                                 # /r with map
2407
2408     tr [\200-\377]
2409        [\000-\177];             # wickedly delete 8th bit
2410
2411 If multiple transliterations are given for a character, only the
2412 first one is used:
2413
2414     tr/AAA/XYZ/
2415
2416 will transliterate any A to X.
2417
2418 Because the transliteration table is built at compile time, neither
2419 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
2420 interpolation.  That means that if you want to use variables, you
2421 must use an eval():
2422
2423     eval "tr/$oldlist/$newlist/";
2424     die $@ if $@;
2425
2426     eval "tr/$oldlist/$newlist/, 1" or die $@;
2427
2428 =item <<EOF
2429 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2430
2431 A line-oriented form of quoting is based on the shell "here-document"
2432 syntax.  Following a C<< << >> you specify a string to terminate
2433 the quoted material, and all lines following the current line down to
2434 the terminating string are the value of the item.
2435
2436 The terminating string may be either an identifier (a word), or some
2437 quoted text.  An unquoted identifier works like double quotes.
2438 There may not be a space between the C<< << >> and the identifier,
2439 unless the identifier is explicitly quoted.  (If you put a space it
2440 will be treated as a null identifier, which is valid, and matches the
2441 first empty line.)  The terminating string must appear by itself
2442 (unquoted and with no surrounding whitespace) on the terminating line.
2443
2444 If the terminating string is quoted, the type of quotes used determine
2445 the treatment of the text.
2446
2447 =over 4
2448
2449 =item Double Quotes
2450
2451 Double quotes indicate that the text will be interpolated using exactly
2452 the same rules as normal double quoted strings.
2453
2454        print <<EOF;
2455     The price is $Price.
2456     EOF
2457
2458        print << "EOF"; # same as above
2459     The price is $Price.
2460     EOF
2461
2462
2463 =item Single Quotes
2464
2465 Single quotes indicate the text is to be treated literally with no
2466 interpolation of its content.  This is similar to single quoted
2467 strings except that backslashes have no special meaning, with C<\\>
2468 being treated as two backslashes and not one as they would in every
2469 other quoting construct.
2470
2471 Just as in the shell, a backslashed bareword following the C<<< << >>>
2472 means the same thing as a single-quoted string does:
2473
2474         $cost = <<'VISTA';  # hasta la ...
2475     That'll be $10 please, ma'am.
2476     VISTA
2477
2478         $cost = <<\VISTA;   # Same thing!
2479     That'll be $10 please, ma'am.
2480     VISTA
2481
2482 This is the only form of quoting in perl where there is no need
2483 to worry about escaping content, something that code generators
2484 can and do make good use of.
2485
2486 =item Backticks
2487
2488 The content of the here doc is treated just as it would be if the
2489 string were embedded in backticks.  Thus the content is interpolated
2490 as though it were double quoted and then executed via the shell, with
2491 the results of the execution returned.
2492
2493        print << `EOC`; # execute command and get results
2494     echo hi there
2495     EOC
2496
2497 =back
2498
2499 It is possible to stack multiple here-docs in a row:
2500
2501        print <<"foo", <<"bar"; # you can stack them
2502     I said foo.
2503     foo
2504     I said bar.
2505     bar
2506
2507        myfunc(<< "THIS", 23, <<'THAT');
2508     Here's a line
2509     or two.
2510     THIS
2511     and here's another.
2512     THAT
2513
2514 Just don't forget that you have to put a semicolon on the end
2515 to finish the statement, as Perl doesn't know you're not going to
2516 try to do this:
2517
2518        print <<ABC
2519     179231
2520     ABC
2521        + 20;
2522
2523 If you want to remove the line terminator from your here-docs,
2524 use C<chomp()>.
2525
2526     chomp($string = <<'END');
2527     This is a string.
2528     END
2529
2530 If you want your here-docs to be indented with the rest of the code,
2531 you'll need to remove leading whitespace from each line manually:
2532
2533     ($quote = <<'FINIS') =~ s/^\s+//gm;
2534        The Road goes ever on and on,
2535        down from the door where it began.
2536     FINIS
2537
2538 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2539 the quoted material must still come on the line following the
2540 C<<< <<FOO >>> marker, which means it may be inside the delimited
2541 construct:
2542
2543     s/this/<<E . 'that'
2544     the other
2545     E
2546      . 'more '/eg;
2547
2548 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2549 you would have to write
2550
2551     s/this/<<E . 'that'
2552      . 'more '/eg;
2553     the other
2554     E
2555
2556 outside of string evals.
2557
2558 Additionally, quoting rules for the end-of-string identifier are
2559 unrelated to Perl's quoting rules.  C<q()>, C<qq()>, and the like are not
2560 supported in place of C<''> and C<"">, and the only interpolation is for
2561 backslashing the quoting character:
2562
2563     print << "abc\"def";
2564     testing...
2565     abc"def
2566
2567 Finally, quoted strings cannot span multiple lines.  The general rule is
2568 that the identifier must be a string literal.  Stick with that, and you
2569 should be safe.
2570
2571 =back
2572
2573 =head2 Gory details of parsing quoted constructs
2574 X<quote, gory details>
2575
2576 When presented with something that might have several different
2577 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2578 principle to pick the most probable interpretation.  This strategy
2579 is so successful that Perl programmers often do not suspect the
2580 ambivalence of what they write.  But from time to time, Perl's
2581 notions differ substantially from what the author honestly meant.
2582
2583 This section hopes to clarify how Perl handles quoted constructs.
2584 Although the most common reason to learn this is to unravel labyrinthine
2585 regular expressions, because the initial steps of parsing are the
2586 same for all quoting operators, they are all discussed together.
2587
2588 The most important Perl parsing rule is the first one discussed
2589 below: when processing a quoted construct, Perl first finds the end
2590 of that construct, then interprets its contents.  If you understand
2591 this rule, you may skip the rest of this section on the first
2592 reading.  The other rules are likely to contradict the user's
2593 expectations much less frequently than this first one.
2594
2595 Some passes discussed below are performed concurrently, but because
2596 their results are the same, we consider them individually.  For different
2597 quoting constructs, Perl performs different numbers of passes, from
2598 one to four, but these passes are always performed in the same order.
2599
2600 =over 4
2601
2602 =item Finding the end
2603
2604 The first pass is finding the end of the quoted construct, where
2605 the information about the delimiters is used in parsing.
2606 During this search, text between the starting and ending delimiters
2607 is copied to a safe location.  The text copied gets delimiter-independent.
2608
2609 If the construct is a here-doc, the ending delimiter is a line
2610 that has a terminating string as the content.  Therefore C<<<EOF> is
2611 terminated by C<EOF> immediately followed by C<"\n"> and starting
2612 from the first column of the terminating line.
2613 When searching for the terminating line of a here-doc, nothing
2614 is skipped.  In other words, lines after the here-doc syntax
2615 are compared with the terminating string line by line.
2616
2617 For the constructs except here-docs, single characters are used as starting
2618 and ending delimiters.  If the starting delimiter is an opening punctuation
2619 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2620 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2621 If the starting delimiter is an unpaired character like C</> or a closing
2622 punctuation, the ending delimiter is same as the starting delimiter.
2623 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2624 both C<qq[]> and C<qq]]> constructs.
2625
2626 When searching for single-character delimiters, escaped delimiters
2627 and C<\\> are skipped.  For example, while searching for terminating C</>,
2628 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2629 bracketing, nested pairs are also skipped.  For example, while searching
2630 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2631 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2632 However, when backslashes are used as the delimiters (like C<qq\\> and
2633 C<tr\\\>), nothing is skipped.
2634 During the search for the end, backslashes that escape delimiters or
2635 other backslashes are removed (exactly speaking, they are not copied to the
2636 safe location).
2637
2638 For constructs with three-part delimiters (C<s///>, C<y///>, and
2639 C<tr///>), the search is repeated once more.
2640 If the first delimiter is not an opening punctuation, the three delimiters must
2641 be the same, such as C<s!!!> and C<tr)))>,
2642 in which case the second delimiter
2643 terminates the left part and starts the right part at once.
2644 If the left part is delimited by bracketing punctuation (that is C<()>,
2645 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2646 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2647 and comments are allowed between the two parts, though the comment must follow
2648 at least one whitespace character; otherwise a character expected as the 
2649 start of the comment may be regarded as the starting delimiter of the right part.
2650
2651 During this search no attention is paid to the semantics of the construct.
2652 Thus:
2653
2654     "$hash{"$foo/$bar"}"
2655
2656 or:
2657
2658     m/
2659       bar       # NOT a comment, this slash / terminated m//!
2660      /x
2661
2662 do not form legal quoted expressions.   The quoted part ends on the
2663 first C<"> and C</>, and the rest happens to be a syntax error.
2664 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2665 the example above is not C<m//x>, but rather C<m//> with no C</x>
2666 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2667
2668 Also no attention is paid to C<\c\> (multichar control char syntax) during
2669 this search.  Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2670 of C<\/>, and the following C</> is not recognized as a delimiter.
2671 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2672
2673 =item Interpolation
2674 X<interpolation>
2675
2676 The next step is interpolation in the text obtained, which is now
2677 delimiter-independent.  There are multiple cases.
2678
2679 =over 4
2680
2681 =item C<<<'EOF'>
2682
2683 No interpolation is performed.
2684 Note that the combination C<\\> is left intact, since escaped delimiters
2685 are not available for here-docs.
2686
2687 =item  C<m''>, the pattern of C<s'''>
2688
2689 No interpolation is performed at this stage.
2690 Any backslashed sequences including C<\\> are treated at the stage
2691 to L</"parsing regular expressions">.
2692
2693 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2694
2695 The only interpolation is removal of C<\> from pairs of C<\\>.
2696 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
2697 as a hyphen and no character range is available.
2698 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2699
2700 =item C<tr///>, C<y///>
2701
2702 No variable interpolation occurs.  String modifying combinations for
2703 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2704 The other escape sequences such as C<\200> and C<\t> and backslashed
2705 characters such as C<\\> and C<\-> are converted to appropriate literals.
2706 The character C<-> is treated specially and therefore C<\-> is treated
2707 as a literal C<->.
2708
2709 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2710
2711 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2712 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2713 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
2714 The other escape sequences such as C<\200> and C<\t> and backslashed
2715 characters such as C<\\> and C<\-> are replaced with appropriate
2716 expansions.
2717
2718 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2719 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2720 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2721 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2722 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2723 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2724 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2725
2726   $str = '\t';
2727   return "\Q$str";
2728
2729 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2730
2731 Interpolated scalars and arrays are converted internally to the C<join> and
2732 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
2733
2734   $foo . " XXX '" . (join $", @arr) . "'";
2735
2736 All operations above are performed simultaneously, left to right.
2737
2738 Because the result of C<"\Q STRING \E"> has all metacharacters
2739 quoted, there is no way to insert a literal C<$> or C<@> inside a
2740 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
2741 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2742 scalar.
2743
2744 Note also that the interpolation code needs to make a decision on
2745 where the interpolated scalar ends.  For instance, whether
2746 C<< "a $x -> {c}" >> really means:
2747
2748   "a " . $x . " -> {c}";
2749
2750 or:
2751
2752   "a " . $x -> {c};
2753
2754 Most of the time, the longest possible text that does not include
2755 spaces between components and which contains matching braces or
2756 brackets.  because the outcome may be determined by voting based
2757 on heuristic estimators, the result is not strictly predictable.
2758 Fortunately, it's usually correct for ambiguous cases.
2759
2760 =item the replacement of C<s///>
2761
2762 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2763 happens as with C<qq//> constructs.
2764
2765 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2766 the replacement text of C<s///>, in order to correct the incorrigible
2767 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2768 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
2769 (that is, the C<$^W> variable) was set.
2770
2771 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2772
2773 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2774 and interpolation happens (almost) as with C<qq//> constructs.
2775
2776 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2777 form for the regex compiler.  (This is because, as mentioned below, the regex
2778 compilation may be done at execution time, and C<\N{...}> is a compile-time
2779 construct.)
2780
2781 However any other combinations of C<\> followed by a character
2782 are not substituted but only skipped, in order to parse them
2783 as regular expressions at the following step.
2784 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2785 treated as an array symbol (for example C<@foo>),
2786 even though the same text in C<qq//> gives interpolation of C<\c@>.
2787
2788 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2789 back to the perl parser, in a similar way that an interpolated array
2790 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2791
2792 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
2793 a C<#>-comment in a C<//x>-regular expression, no processing is
2794 performed whatsoever.  This is the first step at which the presence
2795 of the C<//x> modifier is relevant.
2796
2797 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2798 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2799 voted (by several different estimators) to be either an array element
2800 or C<$var> followed by an RE alternative.  This is where the notation
2801 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2802 array element C<-9>, not as a regular expression from the variable
2803 C<$arr> followed by a digit, which would be the interpretation of
2804 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2805 the result is not predictable.
2806
2807 The lack of processing of C<\\> creates specific restrictions on
2808 the post-processed text.  If the delimiter is C</>, one cannot get
2809 the combination C<\/> into the result of this step.  C</> will
2810 finish the regular expression, C<\/> will be stripped to C</> on
2811 the previous step, and C<\\/> will be left as is.  Because C</> is
2812 equivalent to C<\/> inside a regular expression, this does not
2813 matter unless the delimiter happens to be character special to the
2814 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2815 alphanumeric char, as in:
2816
2817   m m ^ a \s* b mmx;
2818
2819 In the RE above, which is intentionally obfuscated for illustration, the
2820 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2821 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2822 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2823 non-whitespace choices.
2824
2825 =back
2826
2827 This step is the last one for all constructs except regular expressions,
2828 which are processed further.
2829
2830 =item parsing regular expressions
2831 X<regexp, parse>
2832
2833 Previous steps were performed during the compilation of Perl code,
2834 but this one happens at run time, although it may be optimized to
2835 be calculated at compile time if appropriate.  After preprocessing
2836 described above, and possibly after evaluation if concatenation,
2837 joining, casing translation, or metaquoting are involved, the
2838 resulting I<string> is passed to the RE engine for compilation.
2839
2840 Whatever happens in the RE engine might be better discussed in L<perlre>,
2841 but for the sake of continuity, we shall do so here.
2842
2843 This is another step where the presence of the C<//x> modifier is
2844 relevant.  The RE engine scans the string from left to right and
2845 converts it to a finite automaton.
2846
2847 Backslashed characters are either replaced with corresponding
2848 literal strings (as with C<\{>), or else they generate special nodes
2849 in the finite automaton (as with C<\b>).  Characters special to the
2850 RE engine (such as C<|>) generate corresponding nodes or groups of
2851 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2852 converted to literal strings to match, or else is ignored (as is
2853 whitespace and C<#>-style comments if C<//x> is present).
2854
2855 Parsing of the bracketed character class construct, C<[...]>, is
2856 rather different than the rule used for the rest of the pattern.
2857 The terminator of this construct is found using the same rules as
2858 for finding the terminator of a C<{}>-delimited construct, the only
2859 exception being that C<]> immediately following C<[> is treated as
2860 though preceded by a backslash.
2861
2862 The terminator of runtime C<(?{...})> is found by temporarily switching
2863 control to the perl parser, which should stop at the point where the
2864 logically balancing terminating C<}> is found.
2865
2866 It is possible to inspect both the string given to RE engine and the
2867 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2868 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2869 switch documented in L<perlrun/"Command Switches">.
2870
2871 =item Optimization of regular expressions
2872 X<regexp, optimization>
2873
2874 This step is listed for completeness only.  Since it does not change
2875 semantics, details of this step are not documented and are subject
2876 to change without notice.  This step is performed over the finite
2877 automaton that was generated during the previous pass.
2878
2879 It is at this stage that C<split()> silently optimizes C</^/> to
2880 mean C</^/m>.
2881
2882 =back
2883
2884 =head2 I/O Operators
2885 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2886 X<< <> >> X<< <<>> >> X<@ARGV>
2887
2888 There are several I/O operators you should know about.
2889
2890 A string enclosed by backticks (grave accents) first undergoes
2891 double-quote interpolation.  It is then interpreted as an external
2892 command, and the output of that command is the value of the
2893 backtick string, like in a shell.  In scalar context, a single string
2894 consisting of all output is returned.  In list context, a list of
2895 values is returned, one per line of output.  (You can set C<$/> to use
2896 a different line terminator.)  The command is executed each time the
2897 pseudo-literal is evaluated.  The status value of the command is
2898 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2899 Unlike in B<csh>, no translation is done on the return data--newlines
2900 remain newlines.  Unlike in any of the shells, single quotes do not
2901 hide variable names in the command from interpretation.  To pass a
2902 literal dollar-sign through to the shell you need to hide it with a
2903 backslash.  The generalized form of backticks is C<qx//>.  (Because
2904 backticks always undergo shell expansion as well, see L<perlsec> for
2905 security concerns.)
2906 X<qx> X<`> X<``> X<backtick> X<glob>
2907
2908 In scalar context, evaluating a filehandle in angle brackets yields
2909 the next line from that file (the newline, if any, included), or
2910 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2911 (sometimes known as file-slurp mode) and the file is empty, it
2912 returns C<''> the first time, followed by C<undef> subsequently.
2913
2914 Ordinarily you must assign the returned value to a variable, but
2915 there is one situation where an automatic assignment happens.  If
2916 and only if the input symbol is the only thing inside the conditional
2917 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2918 the value is automatically assigned to the global variable $_,
2919 destroying whatever was there previously.  (This may seem like an
2920 odd thing to you, but you'll use the construct in almost every Perl
2921 script you write.)  The $_ variable is not implicitly localized.
2922 You'll have to put a C<local $_;> before the loop if you want that
2923 to happen.
2924
2925 The following lines are equivalent:
2926
2927     while (defined($_ = <STDIN>)) { print; }
2928     while ($_ = <STDIN>) { print; }
2929     while (<STDIN>) { print; }
2930     for (;<STDIN>;) { print; }
2931     print while defined($_ = <STDIN>);
2932     print while ($_ = <STDIN>);
2933     print while <STDIN>;
2934
2935 This also behaves similarly, but assigns to a lexical variable 
2936 instead of to C<$_>:
2937
2938     while (my $line = <STDIN>) { print $line }
2939
2940 In these loop constructs, the assigned value (whether assignment
2941 is automatic or explicit) is then tested to see whether it is
2942 defined.  The defined test avoids problems where the line has a string
2943 value that would be treated as false by Perl; for example a "" or
2944 a "0" with no trailing newline.  If you really mean for such values
2945 to terminate the loop, they should be tested for explicitly:
2946
2947     while (($_ = <STDIN>) ne '0') { ... }
2948     while (<STDIN>) { last unless $_; ... }
2949
2950 In other boolean contexts, C<< <FILEHANDLE> >> without an
2951 explicit C<defined> test or comparison elicits a warning if the
2952 C<use warnings> pragma or the B<-w>
2953 command-line switch (the C<$^W> variable) is in effect.
2954
2955 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2956 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2957 in packages, where they would be interpreted as local identifiers
2958 rather than global.)  Additional filehandles may be created with
2959 the open() function, amongst others.  See L<perlopentut> and
2960 L<perlfunc/open> for details on this.
2961 X<stdin> X<stdout> X<sterr>
2962
2963 If a <FILEHANDLE> is used in a context that is looking for
2964 a list, a list comprising all input lines is returned, one line per
2965 list element.  It's easy to grow to a rather large data space this
2966 way, so use with care.
2967
2968 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2969 See L<perlfunc/readline>.
2970
2971 The null filehandle <> is special: it can be used to emulate the
2972 behavior of B<sed> and B<awk>, and any other Unix filter program
2973 that takes a list of filenames, doing the same to each line
2974 of input from all of them.  Input from <> comes either from
2975 standard input, or from each file listed on the command line.  Here's
2976 how it works: the first time <> is evaluated, the @ARGV array is
2977 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2978 gives you standard input.  The @ARGV array is then processed as a list
2979 of filenames.  The loop
2980
2981     while (<>) {
2982         ...                     # code for each line
2983     }
2984
2985 is equivalent to the following Perl-like pseudo code:
2986
2987     unshift(@ARGV, '-') unless @ARGV;
2988     while ($ARGV = shift) {
2989         open(ARGV, $ARGV);
2990         while (<ARGV>) {
2991             ...         # code for each line
2992         }
2993     }
2994
2995 except that it isn't so cumbersome to say, and will actually work.
2996 It really does shift the @ARGV array and put the current filename
2997 into the $ARGV variable.  It also uses filehandle I<ARGV>
2998 internally.  <> is just a synonym for <ARGV>, which
2999 is magical.  (The pseudo code above doesn't work because it treats
3000 <ARGV> as non-magical.)
3001
3002 Since the null filehandle uses the two argument form of L<perlfunc/open>
3003 it interprets special characters, so if you have a script like this:
3004
3005     while (<>) {
3006         print;
3007     }
3008
3009 and call it with C<perl dangerous.pl 'rm -rfv *|'>, it actually opens a
3010 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
3011 If you want all items in C<@ARGV> to be interpreted as file names, you
3012 can use the module C<ARGV::readonly> from CPAN, or use the double bracket:
3013
3014     while (<<>>) {
3015         print;
3016     }
3017
3018 Using double angle brackets inside of a while causes the open to use the
3019 three argument form (with the second argument being C<< < >>), so all
3020 arguments in ARGV are treated as literal filenames (including "-").
3021 (Note that for convenience, if you use C<< <<>> >> and if @ARGV is
3022 empty, it will still read from the standard input.)
3023
3024 You can modify @ARGV before the first <> as long as the array ends up
3025 containing the list of filenames you really want.  Line numbers (C<$.>)
3026 continue as though the input were one big happy file.  See the example
3027 in L<perlfunc/eof> for how to reset line numbers on each file.
3028
3029 If you want to set @ARGV to your own list of files, go right ahead.
3030 This sets @ARGV to all plain text files if no @ARGV was given:
3031
3032     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
3033
3034 You can even set them to pipe commands.  For example, this automatically
3035 filters compressed arguments through B<gzip>:
3036
3037     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
3038
3039 If you want to pass switches into your script, you can use one of the
3040 Getopts modules or put a loop on the front like this:
3041
3042     while ($_ = $ARGV[0], /^-/) {
3043         shift;
3044         last if /^--$/;
3045         if (/^-D(.*)/) { $debug = $1 }
3046         if (/^-v/)     { $verbose++  }
3047         # ...           # other switches
3048     }
3049
3050     while (<>) {
3051         # ...           # code for each line
3052     }
3053
3054 The <> symbol will return C<undef> for end-of-file only once.
3055 If you call it again after this, it will assume you are processing another
3056 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
3057
3058 If what the angle brackets contain is a simple scalar variable (for example,
3059 <$foo>), then that variable contains the name of the
3060 filehandle to input from, or its typeglob, or a reference to the
3061 same.  For example:
3062
3063     $fh = \*STDIN;
3064     $line = <$fh>;
3065
3066 If what's within the angle brackets is neither a filehandle nor a simple
3067 scalar variable containing a filehandle name, typeglob, or typeglob
3068 reference, it is interpreted as a filename pattern to be globbed, and
3069 either a list of filenames or the next filename in the list is returned,
3070 depending on context.  This distinction is determined on syntactic
3071 grounds alone.  That means C<< <$x> >> is always a readline() from
3072 an indirect handle, but C<< <$hash{key}> >> is always a glob().
3073 That's because $x is a simple scalar variable, but C<$hash{key}> is
3074 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3075 is treated as C<glob("$x ")>, not C<readline($x)>.
3076
3077 One level of double-quote interpretation is done first, but you can't
3078 say C<< <$foo> >> because that's an indirect filehandle as explained
3079 in the previous paragraph.  (In older versions of Perl, programmers
3080 would insert curly brackets to force interpretation as a filename glob:
3081 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3082 internal function directly as C<glob($foo)>, which is probably the right
3083 way to have done it in the first place.)  For example:
3084
3085     while (<*.c>) {
3086         chmod 0644, $_;
3087     }
3088
3089 is roughly equivalent to:
3090
3091     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3092     while (<FOO>) {
3093         chomp;
3094         chmod 0644, $_;
3095     }
3096
3097 except that the globbing is actually done internally using the standard
3098 C<File::Glob> extension.  Of course, the shortest way to do the above is:
3099
3100     chmod 0644, <*.c>;
3101
3102 A (file)glob evaluates its (embedded) argument only when it is
3103 starting a new list.  All values must be read before it will start
3104 over.  In list context, this isn't important because you automatically
3105 get them all anyway.  However, in scalar context the operator returns
3106 the next value each time it's called, or C<undef> when the list has
3107 run out.  As with filehandle reads, an automatic C<defined> is
3108 generated when the glob occurs in the test part of a C<while>,
3109 because legal glob returns (for example,
3110 a file called F<0>) would otherwise
3111 terminate the loop.  Again, C<undef> is returned only once.  So if
3112 you're expecting a single value from a glob, it is much better to
3113 say
3114
3115     ($file) = <blurch*>;
3116
3117 than
3118
3119     $file = <blurch*>;
3120
3121 because the latter will alternate between returning a filename and
3122 returning false.
3123
3124 If you're trying to do variable interpolation, it's definitely better
3125 to use the glob() function, because the older notation can cause people
3126 to become confused with the indirect filehandle notation.
3127
3128     @files = glob("$dir/*.[ch]");
3129     @files = glob($files[$i]);
3130
3131 =head2 Constant Folding
3132 X<constant folding> X<folding>
3133
3134 Like C, Perl does a certain amount of expression evaluation at
3135 compile time whenever it determines that all arguments to an
3136 operator are static and have no side effects.  In particular, string
3137 concatenation happens at compile time between literals that don't do
3138 variable substitution.  Backslash interpolation also happens at
3139 compile time.  You can say
3140
3141       'Now is the time for all'
3142     . "\n" 
3143     .  'good men to come to.'
3144
3145 and this all reduces to one string internally.  Likewise, if
3146 you say
3147
3148     foreach $file (@filenames) {
3149         if (-s $file > 5 + 100 * 2**16) {  }
3150     }
3151
3152 the compiler precomputes the number which that expression
3153 represents so that the interpreter won't have to.
3154
3155 =head2 No-ops
3156 X<no-op> X<nop>
3157
3158 Perl doesn't officially have a no-op operator, but the bare constants
3159 C<0> and C<1> are special-cased not to produce a warning in void
3160 context, so you can for example safely do
3161
3162     1 while foo();
3163
3164 =head2 Bitwise String Operators
3165 X<operator, bitwise, string> X<&.> X<|.> X<^.> X<~.>
3166
3167 Bitstrings of any size may be manipulated by the bitwise operators
3168 (C<~ | & ^>).
3169
3170 If the operands to a binary bitwise op are strings of different
3171 sizes, B<|> and B<^> ops act as though the shorter operand had
3172 additional zero bits on the right, while the B<&> op acts as though
3173 the longer operand were truncated to the length of the shorter.
3174 The granularity for such extension or truncation is one or more
3175 bytes.
3176
3177     # ASCII-based examples
3178     print "j p \n" ^ " a h";            # prints "JAPH\n"
3179     print "JA" | "  ph\n";              # prints "japh\n"
3180     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3181     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3182
3183 If you are intending to manipulate bitstrings, be certain that
3184 you're supplying bitstrings: If an operand is a number, that will imply
3185 a B<numeric> bitwise operation.  You may explicitly show which type of
3186 operation you intend by using C<""> or C<0+>, as in the examples below.
3187
3188     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3189     $foo = '150' |  105;        # yields 255
3190     $foo =  150  | '105';       # yields 255
3191     $foo = '150' | '105';       # yields string '155' (under ASCII)
3192
3193     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3194     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3195
3196 This somewhat unpredictable behavior can be avoided with the experimental
3197 "bitwise" feature, new in Perl 5.22.  You can enable it via C<use feature
3198 'bitwise'>.  By default, it will warn unless the "experimental::bitwise"
3199 warnings category has been disabled.  (C<use experimental 'bitwise'> will
3200 enable the feature and disable the warning.)  Under this feature, the four
3201 standard bitwise operators (C<~ | & ^>) are always numeric.  Adding a dot
3202 after each operator (C<~. |. &. ^.>) forces it to treat its operands as
3203 strings:
3204
3205     use experimental "bitwise";
3206     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3207     $foo = '150' |  105;        # yields 255
3208     $foo =  150  | '105';       # yields 255
3209     $foo = '150' | '105';       # yields 255
3210     $foo =  150  |. 105;        # yields string '155' (under ASCII)
3211     $foo = '150' |. 105;        # yields string '155'
3212     $foo =  150  |.'105';       # yields string '155'
3213     $foo = '150' |.'105';       # yields string '155'
3214
3215     $baz = $foo &  $bar;        # both operands numeric
3216     $biz = $foo ^. $bar;        # both operands stringy
3217
3218 The assignment variants of these operators (C<&= |= ^= &.= |.= ^.=>)
3219 behave likewise under the feature.
3220
3221 See L<perlfunc/vec> for information on how to manipulate individual bits
3222 in a bit vector.
3223
3224 =head2 Integer Arithmetic
3225 X<integer>
3226
3227 By default, Perl assumes that it must do most of its arithmetic in
3228 floating point.  But by saying
3229
3230     use integer;
3231
3232 you may tell the compiler to use integer operations
3233 (see L<integer> for a detailed explanation) from here to the end of
3234 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3235
3236     no integer;
3237
3238 which lasts until the end of that BLOCK.  Note that this doesn't
3239 mean everything is an integer, merely that Perl will use integer
3240 operations for arithmetic, comparison, and bitwise operators.  For
3241 example, even under C<use integer>, if you take the C<sqrt(2)>, you'll
3242 still get C<1.4142135623731> or so.
3243
3244 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
3245 and ">>") always produce integral results.  (But see also
3246 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
3247 them.  By default, their results are interpreted as unsigned integers, but
3248 if C<use integer> is in effect, their results are interpreted
3249 as signed integers.  For example, C<~0> usually evaluates to a large
3250 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
3251 machines.
3252
3253 =head2 Floating-point Arithmetic
3254
3255 X<floating-point> X<floating point> X<float> X<real>
3256
3257 While C<use integer> provides integer-only arithmetic, there is no
3258 analogous mechanism to provide automatic rounding or truncation to a
3259 certain number of decimal places.  For rounding to a certain number
3260 of digits, sprintf() or printf() is usually the easiest route.
3261 See L<perlfaq4>.
3262
3263 Floating-point numbers are only approximations to what a mathematician
3264 would call real numbers.  There are infinitely more reals than floats,
3265 so some corners must be cut.  For example:
3266
3267     printf "%.20g\n", 123456789123456789;
3268     #        produces 123456789123456784
3269
3270 Testing for exact floating-point equality or inequality is not a
3271 good idea.  Here's a (relatively expensive) work-around to compare
3272 whether two floating-point numbers are equal to a particular number of
3273 decimal places.  See Knuth, volume II, for a more robust treatment of
3274 this topic.
3275
3276     sub fp_equal {
3277         my ($X, $Y, $POINTS) = @_;
3278         my ($tX, $tY);
3279         $tX = sprintf("%.${POINTS}g", $X);
3280         $tY = sprintf("%.${POINTS}g", $Y);
3281         return $tX eq $tY;
3282     }
3283
3284 The POSIX module (part of the standard perl distribution) implements
3285 ceil(), floor(), and other mathematical and trigonometric functions.
3286 The Math::Complex module (part of the standard perl distribution)
3287 defines mathematical functions that work on both the reals and the
3288 imaginary numbers.  Math::Complex not as efficient as POSIX, but
3289 POSIX can't work with complex numbers.
3290
3291 Rounding in financial applications can have serious implications, and
3292 the rounding method used should be specified precisely.  In these
3293 cases, it probably pays not to trust whichever system rounding is
3294 being used by Perl, but to instead implement the rounding function you
3295 need yourself.
3296
3297 =head2 Bigger Numbers
3298 X<number, arbitrary precision>
3299
3300 The standard C<Math::BigInt>, C<Math::BigRat>, and C<Math::BigFloat> modules,
3301 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3302 variable-precision arithmetic and overloaded operators, although
3303 they're currently pretty slow.  At the cost of some space and
3304 considerable speed, they avoid the normal pitfalls associated with
3305 limited-precision representations.
3306
3307         use 5.010;
3308         use bigint;  # easy interface to Math::BigInt
3309         $x = 123456789123456789;
3310         say $x * $x;
3311     +15241578780673678515622620750190521
3312
3313 Or with rationals:
3314
3315         use 5.010;
3316         use bigrat;
3317         $x = 3/22;
3318         $y = 4/6;
3319         say "x/y is ", $x/$y;
3320         say "x*y is ", $x*$y;
3321         x/y is 9/44
3322         x*y is 1/11
3323
3324 Several modules let you calculate with (bound only by memory and CPU time)
3325 unlimited or fixed precision.  There
3326 are also some non-standard modules that
3327 provide faster implementations via external C libraries.
3328
3329 Here is a short, but incomplete summary:
3330
3331   Math::String           treat string sequences like numbers
3332   Math::FixedPrecision   calculate with a fixed precision
3333   Math::Currency         for currency calculations
3334   Bit::Vector            manipulate bit vectors fast (uses C)
3335   Math::BigIntFast       Bit::Vector wrapper for big numbers
3336   Math::Pari             provides access to the Pari C library
3337   Math::Cephes           uses the external Cephes C library (no
3338                          big numbers)
3339   Math::Cephes::Fraction fractions via the Cephes library
3340   Math::GMP              another one using an external C library
3341   Math::GMPz             an alternative interface to libgmp's big ints
3342   Math::GMPq             an interface to libgmp's fraction numbers
3343   Math::GMPf             an interface to libgmp's floating point numbers
3344
3345 Choose wisely.
3346
3347 =cut