This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[perl5db-refactor] Refactoring.
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_04';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $evalarg
639     $filename
640     $frame
641     $hist
642     $histfile
643     $histsize
644     $ImmediateStop
645     $IN
646     $inhibit_exit
647     @ini_INC
648     $ini_warn
649     $line
650     $maxtrace
651     $od
652     $onetimeDump
653     $onetimedumpDepth
654     %option
655     @options
656     $osingle
657     $otrace
658     $OUT
659     $packname
660     $pager
661     $post
662     %postponed
663     $prc
664     $pre
665     $pretype
666     $psh
667     @RememberOnROptions
668     $remoteport
669     @res
670     $rl
671     @saved
672     $signal
673     $signalLevel
674     $single
675     $start
676     $sub
677     %sub
678     $subname
679     $term
680     $trace
681     $usercontext
682     $warnLevel
683     $window
684 );
685
686 # Used to save @ARGV and extract any debugger-related flags.
687 use vars qw(@ARGS);
688
689 # Used to prevent multiple entries to diesignal()
690 # (if for instance diesignal() itself dies)
691 use vars qw($panic);
692
693 # Used to prevent the debugger from running nonstop
694 # after a restart
695 use vars qw($second_time);
696
697 sub _calc_usercontext {
698     my ($package) = @_;
699
700     # Cancel strict completely for the evaluated code, so the code
701     # the user evaluates won't be affected by it. (Shlomi Fish)
702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
703     . "package $package;";    # this won't let them modify, alas
704 }
705
706 sub eval {
707
708     # 'my' would make it visible from user code
709     #    but so does local! --tchrist
710     # Remember: this localizes @DB::res, not @main::res.
711     local @res;
712     {
713
714         # Try to keep the user code from messing  with us. Save these so that
715         # even if the eval'ed code changes them, we can put them back again.
716         # Needed because the user could refer directly to the debugger's
717         # package globals (and any 'my' variables in this containing scope)
718         # inside the eval(), and we want to try to stay safe.
719         local $otrace  = $trace;
720         local $osingle = $single;
721         local $od      = $^D;
722
723         # Untaint the incoming eval() argument.
724         { ($evalarg) = $evalarg =~ /(.*)/s; }
725
726         # $usercontext built in DB::DB near the comment
727         # "set up the context for DB::eval ..."
728         # Evaluate and save any results.
729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
730
731         # Restore those old values.
732         $trace  = $otrace;
733         $single = $osingle;
734         $^D     = $od;
735     }
736
737     # Save the current value of $@, and preserve it in the debugger's copy
738     # of the saved precious globals.
739     my $at = $@;
740
741     # Since we're only saving $@, we only have to localize the array element
742     # that it will be stored in.
743     local $saved[0];    # Preserve the old value of $@
744     eval { &DB::save };
745
746     # Now see whether we need to report an error back to the user.
747     if ($at) {
748         local $\ = '';
749         print $OUT $at;
750     }
751
752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
753     # are package globals.
754     elsif ($onetimeDump) {
755         if ( $onetimeDump eq 'dump' ) {
756             local $option{dumpDepth} = $onetimedumpDepth
757               if defined $onetimedumpDepth;
758             dumpit( $OUT, \@res );
759         }
760         elsif ( $onetimeDump eq 'methods' ) {
761             methods( $res[0] );
762         }
763     } ## end elsif ($onetimeDump)
764     @res;
765 } ## end sub eval
766
767 ############################################## End lexical danger zone
768
769 # After this point it is safe to introduce lexicals.
770 # The code being debugged will be executing in its own context, and
771 # can't see the inside of the debugger.
772 #
773 # However, one should not overdo it: leave as much control from outside as
774 # possible. If you make something a lexical, it's not going to be addressable
775 # from outside the debugger even if you know its name.
776
777 # This file is automatically included if you do perl -d.
778 # It's probably not useful to include this yourself.
779 #
780 # Before venturing further into these twisty passages, it is
781 # wise to read the perldebguts man page or risk the ire of dragons.
782 #
783 # (It should be noted that perldebguts will tell you a lot about
784 # the underlying mechanics of how the debugger interfaces into the
785 # Perl interpreter, but not a lot about the debugger itself. The new
786 # comments in this code try to address this problem.)
787
788 # Note that no subroutine call is possible until &DB::sub is defined
789 # (for subroutines defined outside of the package DB). In fact the same is
790 # true if $deep is not defined.
791
792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
793
794 # modified Perl debugger, to be run from Emacs in perldb-mode
795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
796 # Johan Vromans -- upgrade to 4.0 pl 10
797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
798 ########################################################################
799
800 =head1 DEBUGGER INITIALIZATION
801
802 The debugger starts up in phases.
803
804 =head2 BASIC SETUP
805
806 First, it initializes the environment it wants to run in: turning off
807 warnings during its own compilation, defining variables which it will need
808 to avoid warnings later, setting itself up to not exit when the program
809 terminates, and defaulting to printing return values for the C<r> command.
810
811 =cut
812
813 # Needed for the statement after exec():
814 #
815 # This BEGIN block is simply used to switch off warnings during debugger
816 # compilation. Probably it would be better practice to fix the warnings,
817 # but this is how it's done at the moment.
818
819 BEGIN {
820     $ini_warn = $^W;
821     $^W       = 0;
822 }    # Switch compilation warnings off until another BEGIN.
823
824 local ($^W) = 0;    # Switch run-time warnings off during init.
825
826 =head2 THREADS SUPPORT
827
828 If we are running under a threaded Perl, we require threads and threads::shared
829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
830 threaded debugger control.  C<-dt> can also be used to set this.
831
832 Each new thread will be announced and the debugger prompt will always inform
833 you of each new thread created.  It will also indicate the thread id in which
834 we are currently running within the prompt like this:
835
836         [tid] DB<$i>
837
838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
839 command prompt.  The prompt will show: C<[0]> when running under threads, but
840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
841
842 While running under threads, when you set or delete a breakpoint (etc.), this
843 will apply to all threads, not just the currently running one.  When you are
844 in a currently executing thread, you will stay there until it completes.  With
845 the current implementation it is not currently possible to hop from one thread
846 to another.
847
848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
849
850 Note that threading support was built into the debugger as of Perl version
851 C<5.8.6> and debugger version C<1.2.8>.
852
853 =cut
854
855 BEGIN {
856   # ensure we can share our non-threaded variables or no-op
857   if ($ENV{PERL5DB_THREADED}) {
858         require threads;
859         require threads::shared;
860         import threads::shared qw(share);
861         $DBGR;
862         share(\$DBGR);
863         lock($DBGR);
864         print "Threads support enabled\n";
865   } else {
866         *lock  = sub(*) {};
867         *share = sub(*) {};
868   }
869 }
870
871 # These variables control the execution of 'dumpvar.pl'.
872 {
873     package dumpvar;
874     use vars qw(
875     $hashDepth
876     $arrayDepth
877     $dumpDBFiles
878     $dumpPackages
879     $quoteHighBit
880     $printUndef
881     $globPrint
882     $usageOnly
883     );
884 }
885
886 # used to control die() reporting in diesignal()
887 {
888     package Carp;
889     use vars qw($CarpLevel);
890 }
891
892 # without threads, $filename is not defined until DB::DB is called
893 foreach my $k (keys (%INC)) {
894         share(\$main::{'_<'.$filename}) if defined $filename;
895 };
896
897 # Command-line + PERLLIB:
898 # Save the contents of @INC before they are modified elsewhere.
899 @ini_INC = @INC;
900
901 # This was an attempt to clear out the previous values of various
902 # trapped errors. Apparently it didn't help. XXX More info needed!
903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
904
905 # We set these variables to safe values. We don't want to blindly turn
906 # off warnings, because other packages may still want them.
907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
908                                    # (local $^W cannot help - other packages!).
909
910 # Default to not exiting when program finishes; print the return
911 # value when the 'r' command is used to return from a subroutine.
912 $inhibit_exit = $option{PrintRet} = 1;
913
914 use vars qw($trace_to_depth);
915
916 # Default to 1E9 so it won't be limited to a certain recursion depth.
917 $trace_to_depth = 1E9;
918
919 =head1 OPTION PROCESSING
920
921 The debugger's options are actually spread out over the debugger itself and
922 C<dumpvar.pl>; some of these are variables to be set, while others are
923 subs to be called with a value. To try to make this a little easier to
924 manage, the debugger uses a few data structures to define what options
925 are legal and how they are to be processed.
926
927 First, the C<@options> array defines the I<names> of all the options that
928 are to be accepted.
929
930 =cut
931
932 @options = qw(
933   CommandSet   HistFile      HistSize
934   hashDepth    arrayDepth    dumpDepth
935   DumpDBFiles  DumpPackages  DumpReused
936   compactDump  veryCompact   quote
937   HighBit      undefPrint    globPrint
938   PrintRet     UsageOnly     frame
939   AutoTrace    TTY           noTTY
940   ReadLine     NonStop       LineInfo
941   maxTraceLen  recallCommand ShellBang
942   pager        tkRunning     ornaments
943   signalLevel  warnLevel     dieLevel
944   inhibit_exit ImmediateStop bareStringify
945   CreateTTY    RemotePort    windowSize
946   DollarCaretP
947 );
948
949 @RememberOnROptions = qw(DollarCaretP);
950
951 =pod
952
953 Second, C<optionVars> lists the variables that each option uses to save its
954 state.
955
956 =cut
957
958 use vars qw(%optionVars);
959
960 %optionVars = (
961     hashDepth     => \$dumpvar::hashDepth,
962     arrayDepth    => \$dumpvar::arrayDepth,
963     CommandSet    => \$CommandSet,
964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
965     DumpPackages  => \$dumpvar::dumpPackages,
966     DumpReused    => \$dumpvar::dumpReused,
967     HighBit       => \$dumpvar::quoteHighBit,
968     undefPrint    => \$dumpvar::printUndef,
969     globPrint     => \$dumpvar::globPrint,
970     UsageOnly     => \$dumpvar::usageOnly,
971     CreateTTY     => \$CreateTTY,
972     bareStringify => \$dumpvar::bareStringify,
973     frame         => \$frame,
974     AutoTrace     => \$trace,
975     inhibit_exit  => \$inhibit_exit,
976     maxTraceLen   => \$maxtrace,
977     ImmediateStop => \$ImmediateStop,
978     RemotePort    => \$remoteport,
979     windowSize    => \$window,
980     HistFile      => \$histfile,
981     HistSize      => \$histsize,
982 );
983
984 =pod
985
986 Third, C<%optionAction> defines the subroutine to be called to process each
987 option.
988
989 =cut
990
991 use vars qw(%optionAction);
992
993 %optionAction = (
994     compactDump   => \&dumpvar::compactDump,
995     veryCompact   => \&dumpvar::veryCompact,
996     quote         => \&dumpvar::quote,
997     TTY           => \&TTY,
998     noTTY         => \&noTTY,
999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 use vars qw($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(@hist @truehist %postponed_file @typeahead);
1381
1382 if ( exists $ENV{PERLDB_RESTART} ) {
1383
1384     # We're restarting, so we don't need the flag that says to restart anymore.
1385     delete $ENV{PERLDB_RESTART};
1386
1387     # $restart = 1;
1388     @hist          = get_list('PERLDB_HIST');
1389     %break_on_load = get_list("PERLDB_ON_LOAD");
1390     %postponed     = get_list("PERLDB_POSTPONE");
1391
1392         share(@hist);
1393         share(@truehist);
1394         share(%break_on_load);
1395         share(%postponed);
1396
1397     # restore breakpoints/actions
1398     my @had_breakpoints = get_list("PERLDB_VISITED");
1399     for my $file_idx ( 0 .. $#had_breakpoints ) {
1400         my $filename = $had_breakpoints[$file_idx];
1401         my %pf = get_list("PERLDB_FILE_$file_idx");
1402         $postponed_file{ $filename } = \%pf if %pf;
1403         my @lines = sort {$a <=> $b} keys(%pf);
1404         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1405         for my $line_idx (0 .. $#lines) {
1406             _set_breakpoint_enabled_status(
1407                 $filename,
1408                 $lines[$line_idx],
1409                 ($enabled_statuses[$line_idx] ? 1 : ''),
1410             );
1411         }
1412     }
1413
1414     # restore options
1415     my %opt = get_list("PERLDB_OPT");
1416     my ( $opt, $val );
1417     while ( ( $opt, $val ) = each %opt ) {
1418         $val =~ s/[\\\']/\\$1/g;
1419         parse_options("$opt'$val'");
1420     }
1421
1422     # restore original @INC
1423     @INC     = get_list("PERLDB_INC");
1424     @ini_INC = @INC;
1425
1426     # return pre/postprompt actions and typeahead buffer
1427     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1428     $pre       = [ get_list("PERLDB_PRE") ];
1429     $post      = [ get_list("PERLDB_POST") ];
1430     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1431 } ## end if (exists $ENV{PERLDB_RESTART...
1432
1433 =head2 SETTING UP THE TERMINAL
1434
1435 Now, we'll decide how the debugger is going to interact with the user.
1436 If there's no TTY, we set the debugger to run non-stop; there's not going
1437 to be anyone there to enter commands.
1438
1439 =cut
1440
1441 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1442 use vars qw($lineinfo $doccmd);
1443
1444 if ($notty) {
1445     $runnonstop = 1;
1446         share($runnonstop);
1447 }
1448
1449 =pod
1450
1451 If there is a TTY, we have to determine who it belongs to before we can
1452 proceed. If this is a slave editor or graphical debugger (denoted by
1453 the first command-line switch being '-emacs'), we shift this off and
1454 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1455
1456 =cut
1457
1458 else {
1459
1460     # Is Perl being run from a slave editor or graphical debugger?
1461     # If so, don't use readline, and set $slave_editor = 1.
1462     $slave_editor =
1463       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1464     $rl = 0, shift(@main::ARGV) if $slave_editor;
1465
1466     #require Term::ReadLine;
1467
1468 =pod
1469
1470 We then determine what the console should be on various systems:
1471
1472 =over 4
1473
1474 =item * Cygwin - We use C<stdin> instead of a separate device.
1475
1476 =cut
1477
1478     if ( $^O eq 'cygwin' ) {
1479
1480         # /dev/tty is binary. use stdin for textmode
1481         undef $console;
1482     }
1483
1484 =item * Unix - use C</dev/tty>.
1485
1486 =cut
1487
1488     elsif ( -e "/dev/tty" ) {
1489         $console = "/dev/tty";
1490     }
1491
1492 =item * Windows or MSDOS - use C<con>.
1493
1494 =cut
1495
1496     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1497         $console = "con";
1498     }
1499
1500 =item * VMS - use C<sys$command>.
1501
1502 =cut
1503
1504     else {
1505
1506         # everything else is ...
1507         $console = "sys\$command";
1508     }
1509
1510 =pod
1511
1512 =back
1513
1514 Several other systems don't use a specific console. We C<undef $console>
1515 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1516 with a slave editor, Epoc).
1517
1518 =cut
1519
1520     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1521
1522         # /dev/tty is binary. use stdin for textmode
1523         $console = undef;
1524     }
1525
1526     if ( $^O eq 'NetWare' ) {
1527
1528         # /dev/tty is binary. use stdin for textmode
1529         $console = undef;
1530     }
1531
1532     # In OS/2, we need to use STDIN to get textmode too, even though
1533     # it pretty much looks like Unix otherwise.
1534     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1535     {    # In OS/2
1536         $console = undef;
1537     }
1538
1539     # EPOC also falls into the 'got to use STDIN' camp.
1540     if ( $^O eq 'epoc' ) {
1541         $console = undef;
1542     }
1543
1544 =pod
1545
1546 If there is a TTY hanging around from a parent, we use that as the console.
1547
1548 =cut
1549
1550     $console = $tty if defined $tty;
1551
1552 =head2 SOCKET HANDLING
1553
1554 The debugger is capable of opening a socket and carrying out a debugging
1555 session over the socket.
1556
1557 If C<RemotePort> was defined in the options, the debugger assumes that it
1558 should try to start a debugging session on that port. It builds the socket
1559 and then tries to connect the input and output filehandles to it.
1560
1561 =cut
1562
1563     # Handle socket stuff.
1564
1565     if ( defined $remoteport ) {
1566
1567         # If RemotePort was defined in the options, connect input and output
1568         # to the socket.
1569         $IN = $OUT = connect_remoteport();
1570     } ## end if (defined $remoteport)
1571
1572 =pod
1573
1574 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1575 this is probably a situation where multiple debuggers are running (for example,
1576 a backticked command that starts up another debugger). We create a new IN and
1577 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1578 and if we can.
1579
1580 =cut
1581
1582     # Non-socket.
1583     else {
1584
1585         # Two debuggers running (probably a system or a backtick that invokes
1586         # the debugger itself under the running one). create a new IN and OUT
1587         # filehandle, and do the necessary mojo to create a new tty if we
1588         # know how, and we can.
1589         create_IN_OUT(4) if $CreateTTY & 4;
1590         if ($console) {
1591
1592             # If we have a console, check to see if there are separate ins and
1593             # outs to open. (They are assumed identical if not.)
1594
1595             my ( $i, $o ) = split /,/, $console;
1596             $o = $i unless defined $o;
1597
1598             # read/write on in, or just read, or read on STDIN.
1599             open( IN,      "+<$i" )
1600               || open( IN, "<$i" )
1601               || open( IN, "<&STDIN" );
1602
1603             # read/write/create/clobber out, or write/create/clobber out,
1604             # or merge with STDERR, or merge with STDOUT.
1605                  open( OUT, "+>$o" )
1606               || open( OUT, ">$o" )
1607               || open( OUT, ">&STDERR" )
1608               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1609
1610         } ## end if ($console)
1611         elsif ( not defined $console ) {
1612
1613             # No console. Open STDIN.
1614             open( IN, "<&STDIN" );
1615
1616             # merge with STDERR, or with STDOUT.
1617             open( OUT,      ">&STDERR" )
1618               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1619             $console = 'STDIN/OUT';
1620         } ## end elsif (not defined $console)
1621
1622         # Keep copies of the filehandles so that when the pager runs, it
1623         # can close standard input without clobbering ours.
1624         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1625     } ## end elsif (from if(defined $remoteport))
1626
1627     # Unbuffer DB::OUT. We need to see responses right away.
1628     $OUT->autoflush(1);
1629
1630     # Line info goes to debugger output unless pointed elsewhere.
1631     # Pointing elsewhere makes it possible for slave editors to
1632     # keep track of file and position. We have both a filehandle
1633     # and a I/O description to keep track of.
1634     $LINEINFO = $OUT     unless defined $LINEINFO;
1635     $lineinfo = $console unless defined $lineinfo;
1636         # share($LINEINFO); # <- unable to share globs
1637         share($lineinfo);   #
1638
1639 =pod
1640
1641 To finish initialization, we show the debugger greeting,
1642 and then call the C<afterinit()> subroutine if there is one.
1643
1644 =cut
1645
1646     # Show the debugger greeting.
1647     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1648     unless ($runnonstop) {
1649         local $\ = '';
1650         local $, = '';
1651         if ( $term_pid eq '-1' ) {
1652             print $OUT "\nDaughter DB session started...\n";
1653         }
1654         else {
1655             print $OUT "\nLoading DB routines from $header\n";
1656             print $OUT (
1657                 "Editor support ",
1658                 $slave_editor ? "enabled" : "available", ".\n"
1659             );
1660             print $OUT
1661 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1662         } ## end else [ if ($term_pid eq '-1')
1663     } ## end unless ($runnonstop)
1664 } ## end else [ if ($notty)
1665
1666 # XXX This looks like a bug to me.
1667 # Why copy to @ARGS and then futz with @args?
1668 @ARGS = @ARGV;
1669 # for (@args) {
1670     # Make sure backslashes before single quotes are stripped out, and
1671     # keep args unless they are numeric (XXX why?)
1672     # s/\'/\\\'/g;                      # removed while not justified understandably
1673     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1674 # }
1675
1676 # If there was an afterinit() sub defined, call it. It will get
1677 # executed in our scope, so it can fiddle with debugger globals.
1678 if ( defined &afterinit ) {    # May be defined in $rcfile
1679     &afterinit();
1680 }
1681
1682 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1683 use vars qw($I_m_init);
1684
1685 $I_m_init = 1;
1686
1687 ############################################################ Subroutines
1688
1689 =head1 SUBROUTINES
1690
1691 =head2 DB
1692
1693 This gigantic subroutine is the heart of the debugger. Called before every
1694 statement, its job is to determine if a breakpoint has been reached, and
1695 stop if so; read commands from the user, parse them, and execute
1696 them, and then send execution off to the next statement.
1697
1698 Note that the order in which the commands are processed is very important;
1699 some commands earlier in the loop will actually alter the C<$cmd> variable
1700 to create other commands to be executed later. This is all highly I<optimized>
1701 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1702 see what's happening in any given command.
1703
1704 =cut
1705
1706 use vars qw(
1707     $action
1708     %alias
1709     $cmd
1710     $doret
1711     $fall_off_end
1712     $file
1713     $filename_ini
1714     $finished
1715     %had_breakpoints
1716     $incr
1717     $laststep
1718     $level
1719     $max
1720     @old_watch
1721     $package
1722     $rc
1723     $sh
1724     @stack
1725     $stack_depth
1726     @to_watch
1727     $try
1728     $end
1729 );
1730
1731 sub DB {
1732
1733     # lock the debugger and get the thread id for the prompt
1734         lock($DBGR);
1735         my $tid;
1736         my $position;
1737         my ($prefix, $after, $infix);
1738         my $pat;
1739
1740         if ($ENV{PERL5DB_THREADED}) {
1741                 $tid = eval { "[".threads->tid."]" };
1742         }
1743
1744     # Check for whether we should be running continuously or not.
1745     # _After_ the perl program is compiled, $single is set to 1:
1746     if ( $single and not $second_time++ ) {
1747
1748         # Options say run non-stop. Run until we get an interrupt.
1749         if ($runnonstop) {    # Disable until signal
1750                 # If there's any call stack in place, turn off single
1751                 # stepping into subs throughout the stack.
1752             for my $i (0 .. $stack_depth) {
1753                 $stack[ $i ] &= ~1;
1754             }
1755
1756             # And we are now no longer in single-step mode.
1757             $single = 0;
1758
1759             # If we simply returned at this point, we wouldn't get
1760             # the trace info. Fall on through.
1761             # return;
1762         } ## end if ($runnonstop)
1763
1764         elsif ($ImmediateStop) {
1765
1766             # We are supposed to stop here; XXX probably a break.
1767             $ImmediateStop = 0;    # We've processed it; turn it off
1768             $signal        = 1;    # Simulate an interrupt to force
1769                                    # us into the command loop
1770         }
1771     } ## end if ($single and not $second_time...
1772
1773     # If we're in single-step mode, or an interrupt (real or fake)
1774     # has occurred, turn off non-stop mode.
1775     $runnonstop = 0 if $single or $signal;
1776
1777     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1778     # The code being debugged may have altered them.
1779     &save;
1780
1781     # Since DB::DB gets called after every line, we can use caller() to
1782     # figure out where we last were executing. Sneaky, eh? This works because
1783     # caller is returning all the extra information when called from the
1784     # debugger.
1785     local ( $package, $filename, $line ) = caller;
1786     $filename_ini = $filename;
1787
1788     # set up the context for DB::eval, so it can properly execute
1789     # code on behalf of the user. We add the package in so that the
1790     # code is eval'ed in the proper package (not in the debugger!).
1791     local $usercontext = _calc_usercontext($package);
1792
1793     # Create an alias to the active file magical array to simplify
1794     # the code here.
1795     local (*dbline) = $main::{ '_<' . $filename };
1796
1797     # Last line in the program.
1798     $max = $#dbline;
1799
1800     # if we have something here, see if we should break.
1801     {
1802         # $stop is lexical and local to this block - $action on the other hand
1803         # is global.
1804         my $stop;
1805
1806         if ( $dbline{$line}
1807             && _is_breakpoint_enabled($filename, $line)
1808             && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1809         {
1810
1811             # Stop if the stop criterion says to just stop.
1812             if ( $stop eq '1' ) {
1813                 $signal |= 1;
1814             }
1815
1816             # It's a conditional stop; eval it in the user's context and
1817             # see if we should stop. If so, remove the one-time sigil.
1818             elsif ($stop) {
1819                 $evalarg = "\$DB::signal |= 1 if do {$stop}";
1820                 &eval;
1821                 # If the breakpoint is temporary, then delete its enabled status.
1822                 if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1823                     _cancel_breakpoint_temp_enabled_status($filename, $line);
1824                 }
1825             }
1826         } ## end if ($dbline{$line} && ...
1827     }
1828
1829     # Preserve the current stop-or-not, and see if any of the W
1830     # (watch expressions) has changed.
1831     my $was_signal = $signal;
1832
1833     # If we have any watch expressions ...
1834     if ( $trace & 2 ) {
1835         for my $n (0 .. $#to_watch) {
1836             $evalarg = $to_watch[$n];
1837             local $onetimeDump;    # Tell DB::eval() to not output results
1838
1839             # Fix context DB::eval() wants to return an array, but
1840             # we need a scalar here.
1841             my ($val) = join( "', '", &eval );
1842             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1843
1844             # Did it change?
1845             if ( $val ne $old_watch[$n] ) {
1846
1847                 # Yep! Show the difference, and fake an interrupt.
1848                 $signal = 1;
1849                 print $OUT <<EOP;
1850 Watchpoint $n:\t$to_watch[$n] changed:
1851     old value:\t$old_watch[$n]
1852     new value:\t$val
1853 EOP
1854                 $old_watch[$n] = $val;
1855             } ## end if ($val ne $old_watch...
1856         } ## end for my $n (0 ..
1857     } ## end if ($trace & 2)
1858
1859 =head2 C<watchfunction()>
1860
1861 C<watchfunction()> is a function that can be defined by the user; it is a
1862 function which will be run on each entry to C<DB::DB>; it gets the
1863 current package, filename, and line as its parameters.
1864
1865 The watchfunction can do anything it likes; it is executing in the
1866 debugger's context, so it has access to all of the debugger's internal
1867 data structures and functions.
1868
1869 C<watchfunction()> can control the debugger's actions. Any of the following
1870 will cause the debugger to return control to the user's program after
1871 C<watchfunction()> executes:
1872
1873 =over 4
1874
1875 =item *
1876
1877 Returning a false value from the C<watchfunction()> itself.
1878
1879 =item *
1880
1881 Altering C<$single> to a false value.
1882
1883 =item *
1884
1885 Altering C<$signal> to a false value.
1886
1887 =item *
1888
1889 Turning off the C<4> bit in C<$trace> (this also disables the
1890 check for C<watchfunction()>. This can be done with
1891
1892     $trace &= ~4;
1893
1894 =back
1895
1896 =cut
1897
1898     # If there's a user-defined DB::watchfunction, call it with the
1899     # current package, filename, and line. The function executes in
1900     # the DB:: package.
1901     if ( $trace & 4 ) {    # User-installed watch
1902         return
1903           if watchfunction( $package, $filename, $line )
1904           and not $single
1905           and not $was_signal
1906           and not( $trace & ~4 );
1907     } ## end if ($trace & 4)
1908
1909     # Pick up any alteration to $signal in the watchfunction, and
1910     # turn off the signal now.
1911     $was_signal = $signal;
1912     $signal     = 0;
1913
1914 =head2 GETTING READY TO EXECUTE COMMANDS
1915
1916 The debugger decides to take control if single-step mode is on, the
1917 C<t> command was entered, or the user generated a signal. If the program
1918 has fallen off the end, we set things up so that entering further commands
1919 won't cause trouble, and we say that the program is over.
1920
1921 =cut
1922
1923     # Make sure that we always print if asked for explicitly regardless
1924     # of $trace_to_depth .
1925     my $explicit_stop = ($single || $was_signal);
1926
1927     # Check to see if we should grab control ($single true,
1928     # trace set appropriately, or we got a signal).
1929     if ( $explicit_stop || ( $trace & 1 ) ) {
1930
1931         # Yes, grab control.
1932         if ($slave_editor) {
1933
1934             # Tell the editor to update its position.
1935             $position = "\032\032$filename:$line:0\n";
1936             print_lineinfo($position);
1937         }
1938
1939 =pod
1940
1941 Special check: if we're in package C<DB::fake>, we've gone through the
1942 C<END> block at least once. We set up everything so that we can continue
1943 to enter commands and have a valid context to be in.
1944
1945 =cut
1946
1947         elsif ( $package eq 'DB::fake' ) {
1948
1949             # Fallen off the end already.
1950             $term || &setterm;
1951             print_help(<<EOP);
1952 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1953   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1954   B<h q>, B<h R> or B<h o> to get additional info.
1955 EOP
1956
1957             # Set the DB::eval context appropriately.
1958             $package     = 'main';
1959             $usercontext = _calc_usercontext($package);
1960         } ## end elsif ($package eq 'DB::fake')
1961
1962 =pod
1963
1964 If the program hasn't finished executing, we scan forward to the
1965 next executable line, print that out, build the prompt from the file and line
1966 number information, and print that.
1967
1968 =cut
1969
1970         else {
1971
1972
1973             # Still somewhere in the midst of execution. Set up the
1974             #  debugger prompt.
1975             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1976                                  # Perl 5 ones (sorry, we don't print Klingon
1977                                  #module names)
1978
1979             $prefix = $sub =~ /::/ ? "" : ($package . '::');
1980             $prefix .= "$sub($filename:";
1981             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1982
1983             # Break up the prompt if it's really long.
1984             if ( length($prefix) > 30 ) {
1985                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
1986                 $prefix   = "";
1987                 $infix    = ":\t";
1988             }
1989             else {
1990                 $infix    = "):\t";
1991                 $position = "$prefix$line$infix$dbline[$line]$after";
1992             }
1993
1994             # Print current line info, indenting if necessary.
1995             if ($frame) {
1996                 print_lineinfo( ' ' x $stack_depth,
1997                     "$line:\t$dbline[$line]$after" );
1998             }
1999             else {
2000                 depth_print_lineinfo($explicit_stop, $position);
2001             }
2002
2003             # Scan forward, stopping at either the end or the next
2004             # unbreakable line.
2005             for ( my $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2006             {    #{ vi
2007
2008                 # Drop out on null statements, block closers, and comments.
2009                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2010
2011                 # Drop out if the user interrupted us.
2012                 last if $signal;
2013
2014                 # Append a newline if the line doesn't have one. Can happen
2015                 # in eval'ed text, for instance.
2016                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2017
2018                 # Next executable line.
2019                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2020                 $position .= $incr_pos;
2021                 if ($frame) {
2022
2023                     # Print it indented if tracing is on.
2024                     print_lineinfo( ' ' x $stack_depth,
2025                         "$i:\t$dbline[$i]$after" );
2026                 }
2027                 else {
2028                     depth_print_lineinfo($explicit_stop, $incr_pos);
2029                 }
2030             } ## end for ($i = $line + 1 ; $i...
2031         } ## end else [ if ($slave_editor)
2032     } ## end if ($single || ($trace...
2033
2034 =pod
2035
2036 If there's an action to be executed for the line we stopped at, execute it.
2037 If there are any preprompt actions, execute those as well.
2038
2039 =cut
2040
2041     # If there's an action, do it now.
2042     $evalarg = $action, &eval if $action;
2043
2044     # Are we nested another level (e.g., did we evaluate a function
2045     # that had a breakpoint in it at the debugger prompt)?
2046     if ( $single || $was_signal ) {
2047
2048         # Yes, go down a level.
2049         local $level = $level + 1;
2050
2051         # Do any pre-prompt actions.
2052         foreach $evalarg (@$pre) {
2053             &eval;
2054         }
2055
2056         # Complain about too much recursion if we passed the limit.
2057         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2058           if $single & 4;
2059
2060         # The line we're currently on. Set $incr to -1 to stay here
2061         # until we get a command that tells us to advance.
2062         $start = $line;
2063         $incr  = -1;      # for backward motion.
2064
2065         # Tack preprompt debugger actions ahead of any actual input.
2066         @typeahead = ( @$pretype, @typeahead );
2067
2068 =head2 WHERE ARE WE?
2069
2070 XXX Relocate this section?
2071
2072 The debugger normally shows the line corresponding to the current line of
2073 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2074 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2075
2076 C<$incr> controls by how many lines the I<current> line should move forward
2077 after a command is executed. If set to -1, this indicates that the I<current>
2078 line shouldn't change.
2079
2080 C<$start> is the I<current> line. It is used for things like knowing where to
2081 move forwards or backwards from when doing an C<L> or C<-> command.
2082
2083 C<$max> tells the debugger where the last line of the current file is. It's
2084 used to terminate loops most often.
2085
2086 =head2 THE COMMAND LOOP
2087
2088 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2089 in two parts:
2090
2091 =over 4
2092
2093 =item *
2094
2095 The outer part of the loop, starting at the C<CMD> label. This loop
2096 reads a command and then executes it.
2097
2098 =item *
2099
2100 The inner part of the loop, starting at the C<PIPE> label. This part
2101 is wholly contained inside the C<CMD> block and only executes a command.
2102 Used to handle commands running inside a pager.
2103
2104 =back
2105
2106 So why have two labels to restart the loop? Because sometimes, it's easier to
2107 have a command I<generate> another command and then re-execute the loop to do
2108 the new command. This is faster, but perhaps a bit more convoluted.
2109
2110 =cut
2111
2112         # The big command dispatch loop. It keeps running until the
2113         # user yields up control again.
2114         #
2115         # If we have a terminal for input, and we get something back
2116         # from readline(), keep on processing.
2117         my $piped;
2118         my $selected;
2119
2120       CMD:
2121         while (
2122
2123             # We have a terminal, or can get one ...
2124             ( $term || &setterm ),
2125
2126             # ... and it belogs to this PID or we get one for this PID ...
2127             ( $term_pid == $$ or resetterm(1) ),
2128
2129             # ... and we got a line of command input ...
2130             defined(
2131                 $cmd = &readline(
2132                         "$pidprompt $tid DB"
2133                       . ( '<' x $level )
2134                       . ( $#hist + 1 )
2135                       . ( '>' x $level ) . " "
2136                 )
2137             )
2138           )
2139         {
2140
2141                         share($cmd);
2142             # ... try to execute the input as debugger commands.
2143
2144             # Don't stop running.
2145             $single = 0;
2146
2147             # No signal is active.
2148             $signal = 0;
2149
2150             # Handle continued commands (ending with \):
2151             if ($cmd =~ s/\\\z/\n/) {
2152                 $cmd .= &readline("  cont: ");
2153                 redo CMD;
2154             }
2155
2156 =head4 The null command
2157
2158 A newline entered by itself means I<re-execute the last command>. We grab the
2159 command out of C<$laststep> (where it was recorded previously), and copy it
2160 back into C<$cmd> to be executed below. If there wasn't any previous command,
2161 we'll do nothing below (no command will match). If there was, we also save it
2162 in the command history and fall through to allow the command parsing to pick
2163 it up.
2164
2165 =cut
2166
2167             # Empty input means repeat the last command.
2168             $cmd =~ /^$/ && ( $cmd = $laststep );
2169             chomp($cmd);    # get rid of the annoying extra newline
2170             push( @hist, $cmd ) if length($cmd) > 1;
2171             push( @truehist, $cmd );
2172                         share(@hist);
2173                         share(@truehist);
2174
2175             # This is a restart point for commands that didn't arrive
2176             # via direct user input. It allows us to 'redo PIPE' to
2177             # re-execute command processing without reading a new command.
2178           PIPE: {
2179                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2180                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2181                 my ($i) = split( /\s+/, $cmd );
2182
2183 =head3 COMMAND ALIASES
2184
2185 The debugger can create aliases for commands (these are stored in the
2186 C<%alias> hash). Before a command is executed, the command loop looks it up
2187 in the alias hash and substitutes the contents of the alias for the command,
2188 completely replacing it.
2189
2190 =cut
2191
2192                 # See if there's an alias for the command, and set it up if so.
2193                 if ( $alias{$i} ) {
2194
2195                     # Squelch signal handling; we want to keep control here
2196                     # if something goes loco during the alias eval.
2197                     local $SIG{__DIE__};
2198                     local $SIG{__WARN__};
2199
2200                     # This is a command, so we eval it in the DEBUGGER's
2201                     # scope! Otherwise, we can't see the special debugger
2202                     # variables, or get to the debugger's subs. (Well, we
2203                     # _could_, but why make it even more complicated?)
2204                     eval "\$cmd =~ $alias{$i}";
2205                     if ($@) {
2206                         local $\ = '';
2207                         print $OUT "Couldn't evaluate '$i' alias: $@";
2208                         next CMD;
2209                     }
2210                 } ## end if ($alias{$i})
2211
2212 =head3 MAIN-LINE COMMANDS
2213
2214 All of these commands work up to and after the program being debugged has
2215 terminated.
2216
2217 =head4 C<q> - quit
2218
2219 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2220 try to execute further, cleaning any restart-related stuff out of the
2221 environment, and executing with the last value of C<$?>.
2222
2223 =cut
2224
2225                 if ($cmd eq 'q') {
2226                     $fall_off_end = 1;
2227                     clean_ENV();
2228                     exit $?;
2229                 }
2230
2231 =head4 C<t> - trace [n]
2232
2233 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2234 If level is specified, set C<$trace_to_depth>.
2235
2236 =cut
2237
2238                 if (my ($levels) = $cmd =~ /\At(?:\s+(\d+))?\z/) {
2239                     $trace ^= 1;
2240                     local $\ = '';
2241                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2242                     print $OUT "Trace = "
2243                       . ( ( $trace & 1 )
2244                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2245                       : "off" ) . "\n";
2246                     next CMD;
2247                 }
2248
2249 =head4 C<S> - list subroutines matching/not matching a pattern
2250
2251 Walks through C<%sub>, checking to see whether or not to print the name.
2252
2253 =cut
2254
2255                 if (my ($print_all_subs, $should_reverse, $Spatt)
2256                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2257                     # $Spatt is the pattern (if any) to use.
2258                     # Reverse scan?
2259                     my $Srev     = defined $should_reverse;
2260                     # No args - print all subs.
2261                     my $Snocheck = !defined $print_all_subs;
2262
2263                     # Need to make these sane here.
2264                     local $\ = '';
2265                     local $, = '';
2266
2267                     # Search through the debugger's magical hash of subs.
2268                     # If $nocheck is true, just print the sub name.
2269                     # Otherwise, check it against the pattern. We then use
2270                     # the XOR trick to reverse the condition as required.
2271                     foreach $subname ( sort( keys %sub ) ) {
2272                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2273                             print $OUT $subname, "\n";
2274                         }
2275                     }
2276                     next CMD;
2277                 }
2278
2279 =head4 C<X> - list variables in current package
2280
2281 Since the C<V> command actually processes this, just change this to the
2282 appropriate C<V> command and fall through.
2283
2284 =cut
2285
2286                 $cmd =~ s/^X\b/V $package/;
2287
2288 =head4 C<V> - list variables
2289
2290 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2291
2292 =cut
2293
2294                 # Bare V commands get the currently-being-debugged package
2295                 # added.
2296                 if ($cmd eq "V") {
2297                     $cmd = "V $package";
2298                 }
2299
2300                 # V - show variables in package.
2301                 if (my ($new_packname, $new_vars_str) =
2302                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2303
2304                     # Save the currently selected filehandle and
2305                     # force output to debugger's filehandle (dumpvar
2306                     # just does "print" for output).
2307                     my $savout = select($OUT);
2308
2309                     # Grab package name and variables to dump.
2310                     $packname = $new_packname;
2311                     my @vars     = split( ' ', $new_vars_str );
2312
2313                     # If main::dumpvar isn't here, get it.
2314                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2315                     if ( defined &main::dumpvar ) {
2316
2317                         # We got it. Turn off subroutine entry/exit messages
2318                         # for the moment, along with return values.
2319                         local $frame = 0;
2320                         local $doret = -2;
2321
2322                         # must detect sigpipe failures  - not catching
2323                         # then will cause the debugger to die.
2324                         eval {
2325                             &main::dumpvar(
2326                                 $packname,
2327                                 defined $option{dumpDepth}
2328                                 ? $option{dumpDepth}
2329                                 : -1,    # assume -1 unless specified
2330                                 @vars
2331                             );
2332                         };
2333
2334                         # The die doesn't need to include the $@, because
2335                         # it will automatically get propagated for us.
2336                         if ($@) {
2337                             die unless $@ =~ /dumpvar print failed/;
2338                         }
2339                     } ## end if (defined &main::dumpvar)
2340                     else {
2341
2342                         # Couldn't load dumpvar.
2343                         print $OUT "dumpvar.pl not available.\n";
2344                     }
2345
2346                     # Restore the output filehandle, and go round again.
2347                     select($savout);
2348                     next CMD;
2349                 }
2350
2351 =head4 C<x> - evaluate and print an expression
2352
2353 Hands the expression off to C<DB::eval>, setting it up to print the value
2354 via C<dumpvar.pl> instead of just printing it directly.
2355
2356 =cut
2357
2358                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2359                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2360
2361                     # handle special  "x 3 blah" syntax XXX propagate
2362                     # doc back to special variables.
2363                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2364                         $onetimedumpDepth = $1;
2365                     }
2366                 }
2367
2368 =head4 C<m> - print methods
2369
2370 Just uses C<DB::methods> to determine what methods are available.
2371
2372 =cut
2373
2374                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2375                     methods($1);
2376                     next CMD;
2377                 }
2378
2379                 # m expr - set up DB::eval to do the work
2380                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2381                     $onetimeDump = 'methods';   #  method output gets used there
2382                 }
2383
2384 =head4 C<f> - switch files
2385
2386 =cut
2387
2388                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2389                     $file =~ s/\s+$//;
2390
2391                     # help for no arguments (old-style was return from sub).
2392                     if ( !$file ) {
2393                         print $OUT
2394                           "The old f command is now the r command.\n";    # hint
2395                         print $OUT "The new f command switches filenames.\n";
2396                         next CMD;
2397                     } ## end if (!$file)
2398
2399                     # if not in magic file list, try a close match.
2400                     if ( !defined $main::{ '_<' . $file } ) {
2401                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2402                             {
2403                                 $try = substr( $try, 2 );
2404                                 print $OUT "Choosing $try matching '$file':\n";
2405                                 $file = $try;
2406                             }
2407                         } ## end if (($try) = grep(m#^_<.*$file#...
2408                     } ## end if (!defined $main::{ ...
2409
2410                     # If not successfully switched now, we failed.
2411                     if ( !defined $main::{ '_<' . $file } ) {
2412                         print $OUT "No file matching '$file' is loaded.\n";
2413                         next CMD;
2414                     }
2415
2416                     # We switched, so switch the debugger internals around.
2417                     elsif ( $file ne $filename ) {
2418                         *dbline   = $main::{ '_<' . $file };
2419                         $max      = $#dbline;
2420                         $filename = $file;
2421                         $start    = 1;
2422                         $cmd      = "l";
2423                     } ## end elsif ($file ne $filename)
2424
2425                     # We didn't switch; say we didn't.
2426                     else {
2427                         print $OUT "Already in $file.\n";
2428                         next CMD;
2429                     }
2430                 }
2431
2432 =head4 C<.> - return to last-executed line.
2433
2434 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2435 and then we look up the line in the magical C<%dbline> hash.
2436
2437 =cut
2438
2439                 # . command.
2440                 if ($cmd eq '.') {
2441                     $incr = -1;    # stay at current line
2442
2443                     # Reset everything to the old location.
2444                     $start    = $line;
2445                     $filename = $filename_ini;
2446                     *dbline   = $main::{ '_<' . $filename };
2447                     $max      = $#dbline;
2448
2449                     # Now where are we?
2450                     print_lineinfo($position);
2451                     next CMD;
2452                 }
2453
2454 =head4 C<-> - back one window
2455
2456 We change C<$start> to be one window back; if we go back past the first line,
2457 we set it to be the first line. We ser C<$incr> to put us back at the
2458 currently-executing line, and then put a C<l $start +> (list one window from
2459 C<$start>) in C<$cmd> to be executed later.
2460
2461 =cut
2462
2463                 # - - back a window.
2464                 if ($cmd eq '-') {
2465
2466                     # back up by a window; go to 1 if back too far.
2467                     $start -= $incr + $window + 1;
2468                     $start = 1 if $start <= 0;
2469                     $incr  = $window - 1;
2470
2471                     # Generate and execute a "l +" command (handled below).
2472                     $cmd = 'l ' . ($start) . '+';
2473                 }
2474
2475 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2476
2477 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2478 problems, most notably that the default case of several commands destroying
2479 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2480 retain the old commands for those who were used to using them or who preferred
2481 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2482 deal with them instead of processing them in-line.
2483
2484 =cut
2485
2486                 # All of these commands were remapped in perl 5.8.0;
2487                 # we send them off to the secondary dispatcher (see below).
2488                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2489                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2490                     next CMD;
2491                 }
2492
2493 =head4 C<y> - List lexicals in higher scope
2494
2495 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2496 above the current one and then displays then using C<dumpvar.pl>.
2497
2498 =cut
2499
2500                 if (my ($match_level, $match_vars)
2501                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2502
2503                     # See if we've got the necessary support.
2504                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2505                       or &warn(
2506                         $@ =~ /locate/
2507                         ? "PadWalker module not found - please install\n"
2508                         : $@
2509                       )
2510                       and next CMD;
2511
2512                     # Load up dumpvar if we don't have it. If we can, that is.
2513                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2514                     defined &main::dumpvar
2515                       or print $OUT "dumpvar.pl not available.\n"
2516                       and next CMD;
2517
2518                     # Got all the modules we need. Find them and print them.
2519                     my @vars = split( ' ', $match_vars || '' );
2520
2521                     # Find the pad.
2522                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2523
2524                     # Oops. Can't find it.
2525                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2526
2527                     # Show the desired vars with dumplex().
2528                     my $savout = select($OUT);
2529
2530                     # Have dumplex dump the lexicals.
2531                     dumpvar::dumplex( $_, $h->{$_},
2532                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2533                         @vars )
2534                       for sort keys %$h;
2535                     select($savout);
2536                     next CMD;
2537                 }
2538
2539 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2540
2541 All of the commands below this point don't work after the program being
2542 debugged has ended. All of them check to see if the program has ended; this
2543 allows the commands to be relocated without worrying about a 'line of
2544 demarcation' above which commands can be entered anytime, and below which
2545 they can't.
2546
2547 =head4 C<n> - single step, but don't trace down into subs
2548
2549 Done by setting C<$single> to 2, which forces subs to execute straight through
2550 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2551 so a null command knows what to re-execute.
2552
2553 =cut
2554
2555                 # n - next
2556                 if ($cmd eq 'n') {
2557                     end_report(), next CMD if $finished and $level <= 1;
2558
2559                     # Single step, but don't enter subs.
2560                     $single = 2;
2561
2562                     # Save for empty command (repeat last).
2563                     $laststep = $cmd;
2564                     last CMD;
2565                 }
2566
2567 =head4 C<s> - single-step, entering subs
2568
2569 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2570 subs. Also saves C<s> as C<$lastcmd>.
2571
2572 =cut
2573
2574                 # s - single step.
2575                 if ($cmd eq 's') {
2576
2577                     # Get out and restart the command loop if program
2578                     # has finished.
2579                     end_report(), next CMD if $finished and $level <= 1;
2580
2581                     # Single step should enter subs.
2582                     $single = 1;
2583
2584                     # Save for empty command (repeat last).
2585                     $laststep = $cmd;
2586                     last CMD;
2587                 }
2588
2589 =head4 C<c> - run continuously, setting an optional breakpoint
2590
2591 Most of the code for this command is taken up with locating the optional
2592 breakpoint, which is either a subroutine name or a line number. We set
2593 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2594 in this and all call levels above this one.
2595
2596 =cut
2597
2598                 # c - start continuous execution.
2599                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2600
2601                     # Hey, show's over. The debugged program finished
2602                     # executing already.
2603                     end_report(), next CMD if $finished and $level <= 1;
2604
2605                     # Capture the place to put a one-time break.
2606                     $subname = $i;
2607
2608                     #  Probably not needed, since we finish an interactive
2609                     #  sub-session anyway...
2610                     # local $filename = $filename;
2611                     # local *dbline = *dbline; # XXX Would this work?!
2612                     #
2613                     # The above question wonders if localizing the alias
2614                     # to the magic array works or not. Since it's commented
2615                     # out, we'll just leave that to speculation for now.
2616
2617                     # If the "subname" isn't all digits, we'll assume it
2618                     # is a subroutine name, and try to find it.
2619                     if ( $subname =~ /\D/ ) {    # subroutine name
2620                             # Qualify it to the current package unless it's
2621                             # already qualified.
2622                         $subname = $package . "::" . $subname
2623                           unless $subname =~ /::/;
2624
2625                         # find_sub will return "file:line_number" corresponding
2626                         # to where the subroutine is defined; we call find_sub,
2627                         # break up the return value, and assign it in one
2628                         # operation.
2629                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2630
2631                         # Force the line number to be numeric.
2632                         $i += 0;
2633
2634                         # If we got a line number, we found the sub.
2635                         if ($i) {
2636
2637                             # Switch all the debugger's internals around so
2638                             # we're actually working with that file.
2639                             $filename = $file;
2640                             *dbline   = $main::{ '_<' . $filename };
2641
2642                             # Mark that there's a breakpoint in this file.
2643                             $had_breakpoints{$filename} |= 1;
2644
2645                             # Scan forward to the first executable line
2646                             # after the 'sub whatever' line.
2647                             $max = $#dbline;
2648                             ++$i while $dbline[$i] == 0 && $i < $max;
2649                         } ## end if ($i)
2650
2651                         # We didn't find a sub by that name.
2652                         else {
2653                             print $OUT "Subroutine $subname not found.\n";
2654                             next CMD;
2655                         }
2656                     } ## end if ($subname =~ /\D/)
2657
2658                     # At this point, either the subname was all digits (an
2659                     # absolute line-break request) or we've scanned through
2660                     # the code following the definition of the sub, looking
2661                     # for an executable, which we may or may not have found.
2662                     #
2663                     # If $i (which we set $subname from) is non-zero, we
2664                     # got a request to break at some line somewhere. On
2665                     # one hand, if there wasn't any real subroutine name
2666                     # involved, this will be a request to break in the current
2667                     # file at the specified line, so we have to check to make
2668                     # sure that the line specified really is breakable.
2669                     #
2670                     # On the other hand, if there was a subname supplied, the
2671                     # preceding block has moved us to the proper file and
2672                     # location within that file, and then scanned forward
2673                     # looking for the next executable line. We have to make
2674                     # sure that one was found.
2675                     #
2676                     # On the gripping hand, we can't do anything unless the
2677                     # current value of $i points to a valid breakable line.
2678                     # Check that.
2679                     if ($i) {
2680
2681                         # Breakable?
2682                         if ( $dbline[$i] == 0 ) {
2683                             print $OUT "Line $i not breakable.\n";
2684                             next CMD;
2685                         }
2686
2687                         # Yes. Set up the one-time-break sigil.
2688                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2689                         _enable_breakpoint_temp_enabled_status($filename, $i);
2690                     } ## end if ($i)
2691
2692                     # Turn off stack tracing from here up.
2693                     for my $i (0 .. $stack_depth) {
2694                         $stack[ $i ] &= ~1;
2695                     }
2696                     last CMD;
2697                 }
2698
2699 =head4 C<r> - return from a subroutine
2700
2701 For C<r> to work properly, the debugger has to stop execution again
2702 immediately after the return is executed. This is done by forcing
2703 single-stepping to be on in the call level above the current one. If
2704 we are printing return values when a C<r> is executed, set C<$doret>
2705 appropriately, and force us out of the command loop.
2706
2707 =cut
2708
2709                 # r - return from the current subroutine.
2710                 if ($cmd eq 'r') {
2711
2712                     # Can't do anything if the program's over.
2713                     end_report(), next CMD if $finished and $level <= 1;
2714
2715                     # Turn on stack trace.
2716                     $stack[$stack_depth] |= 1;
2717
2718                     # Print return value unless the stack is empty.
2719                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2720                     last CMD;
2721                 }
2722
2723 =head4 C<T> - stack trace
2724
2725 Just calls C<DB::print_trace>.
2726
2727 =cut
2728
2729                 if ($cmd eq 'T') {
2730                     print_trace( $OUT, 1 );    # skip DB
2731                     next CMD;
2732                 }
2733
2734 =head4 C<w> - List window around current line.
2735
2736 Just calls C<DB::cmd_w>.
2737
2738 =cut
2739
2740                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2741                     &cmd_w( 'w', $arg );
2742                     next CMD;
2743                 }
2744
2745 =head4 C<W> - watch-expression processing.
2746
2747 Just calls C<DB::cmd_W>.
2748
2749 =cut
2750
2751                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2752                     &cmd_W( 'W', $arg );
2753                     next CMD;
2754                 }
2755
2756 =head4 C</> - search forward for a string in the source
2757
2758 We take the argument and treat it as a pattern. If it turns out to be a
2759 bad one, we return the error we got from trying to C<eval> it and exit.
2760 If not, we create some code to do the search and C<eval> it so it can't
2761 mess us up.
2762
2763 =cut
2764
2765                 # The pattern as a string.
2766                 use vars qw($inpat);
2767
2768                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2769
2770                     # Remove the final slash.
2771                     $inpat =~ s:([^\\])/$:$1:;
2772
2773                     # If the pattern isn't null ...
2774                     if ( $inpat ne "" ) {
2775
2776                         # Turn of warn and die procesing for a bit.
2777                         local $SIG{__DIE__};
2778                         local $SIG{__WARN__};
2779
2780                         # Create the pattern.
2781                         eval '$inpat =~ m' . "\a$inpat\a";
2782                         if ( $@ ne "" ) {
2783
2784                             # Oops. Bad pattern. No biscuit.
2785                             # Print the eval error and go back for more
2786                             # commands.
2787                             print $OUT "$@";
2788                             next CMD;
2789                         }
2790                         $pat = $inpat;
2791                     } ## end if ($inpat ne "")
2792
2793                     # Set up to stop on wrap-around.
2794                     $end = $start;
2795
2796                     # Don't move off the current line.
2797                     $incr = -1;
2798
2799                     # Done in eval so nothing breaks if the pattern
2800                     # does something weird.
2801                     eval '
2802                         for (;;) {
2803                             # Move ahead one line.
2804                             ++$start;
2805
2806                             # Wrap if we pass the last line.
2807                             $start = 1 if ($start > $max);
2808
2809                             # Stop if we have gotten back to this line again,
2810                             last if ($start == $end);
2811
2812                             # A hit! (Note, though, that we are doing
2813                             # case-insensitive matching. Maybe a qr//
2814                             # expression would be better, so the user could
2815                             # do case-sensitive matching if desired.
2816                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2817                                 if ($slave_editor) {
2818                                     # Handle proper escaping in the slave.
2819                                     print $OUT "\032\032$filename:$start:0\n";
2820                                 }
2821                                 else {
2822                                     # Just print the line normally.
2823                                     print $OUT "$start:\t",$dbline[$start],"\n";
2824                                 }
2825                                 # And quit since we found something.
2826                                 last;
2827                             }
2828                          } ';
2829
2830                     # If we wrapped, there never was a match.
2831                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2832                     next CMD;
2833                 }
2834
2835 =head4 C<?> - search backward for a string in the source
2836
2837 Same as for C</>, except the loop runs backwards.
2838
2839 =cut
2840
2841                 # ? - backward pattern search.
2842                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2843
2844                     # Get the pattern, remove trailing question mark.
2845                     $inpat =~ s:([^\\])\?$:$1:;
2846
2847                     # If we've got one ...
2848                     if ( $inpat ne "" ) {
2849
2850                         # Turn off die & warn handlers.
2851                         local $SIG{__DIE__};
2852                         local $SIG{__WARN__};
2853                         eval '$inpat =~ m' . "\a$inpat\a";
2854
2855                         if ( $@ ne "" ) {
2856
2857                             # Ouch. Not good. Print the error.
2858                             print $OUT $@;
2859                             next CMD;
2860                         }
2861                         $pat = $inpat;
2862                     } ## end if ($inpat ne "")
2863
2864                     # Where we are now is where to stop after wraparound.
2865                     $end = $start;
2866
2867                     # Don't move away from this line.
2868                     $incr = -1;
2869
2870                     # Search inside the eval to prevent pattern badness
2871                     # from killing us.
2872                     eval '
2873                         for (;;) {
2874                             # Back up a line.
2875                             --$start;
2876
2877                             # Wrap if we pass the first line.
2878
2879                             $start = $max if ($start <= 0);
2880
2881                             # Quit if we get back where we started,
2882                             last if ($start == $end);
2883
2884                             # Match?
2885                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2886                                 if ($slave_editor) {
2887                                     # Yep, follow slave editor requirements.
2888                                     print $OUT "\032\032$filename:$start:0\n";
2889                                 }
2890                                 else {
2891                                     # Yep, just print normally.
2892                                     print $OUT "$start:\t",$dbline[$start],"\n";
2893                                 }
2894
2895                                 # Found, so done.
2896                                 last;
2897                             }
2898                         } ';
2899
2900                     # Say we failed if the loop never found anything,
2901                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2902                     next CMD;
2903                 }
2904
2905 =head4 C<$rc> - Recall command
2906
2907 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2908 that the terminal supports history). It find the the command required, puts it
2909 into C<$cmd>, and redoes the loop to execute it.
2910
2911 =cut
2912
2913                 # $rc - recall command.
2914                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2915
2916                     # No arguments, take one thing off history.
2917                     pop(@hist) if length($cmd) > 1;
2918
2919                     # Relative (- found)?
2920                     #  Y - index back from most recent (by 1 if bare minus)
2921                     #  N - go to that particular command slot or the last
2922                     #      thing if nothing following.
2923                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2924
2925                     # Pick out the command desired.
2926                     $cmd = $hist[$i];
2927
2928                     # Print the command to be executed and restart the loop
2929                     # with that command in the buffer.
2930                     print $OUT $cmd, "\n";
2931                     redo CMD;
2932                 }
2933
2934 =head4 C<$sh$sh> - C<system()> command
2935
2936 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2937 C<STDOUT> from getting messed up.
2938
2939 =cut
2940
2941                 # $sh$sh - run a shell command (if it's all ASCII).
2942                 # Can't run shell commands with Unicode in the debugger, hmm.
2943                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2944
2945                     # System it.
2946                     &system($arg);
2947                     next CMD;
2948                 }
2949
2950 =head4 C<$rc I<pattern> $rc> - Search command history
2951
2952 Another command to manipulate C<@hist>: this one searches it with a pattern.
2953 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2954
2955 =cut
2956
2957                 # $rc pattern $rc - find a command in the history.
2958                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2959
2960                     # Create the pattern to use.
2961                     $pat = "^$arg";
2962
2963                     # Toss off last entry if length is >1 (and it always is).
2964                     pop(@hist) if length($cmd) > 1;
2965
2966                     # Look backward through the history.
2967                     for ( $i = $#hist ; $i ; --$i ) {
2968                         # Stop if we find it.
2969                         last if $hist[$i] =~ /$pat/;
2970                     }
2971
2972                     if ( !$i ) {
2973
2974                         # Never found it.
2975                         print $OUT "No such command!\n\n";
2976                         next CMD;
2977                     }
2978
2979                     # Found it. Put it in the buffer, print it, and process it.
2980                     $cmd = $hist[$i];
2981                     print $OUT $cmd, "\n";
2982                     redo CMD;
2983                 }
2984
2985 =head4 C<$sh> - Invoke a shell
2986
2987 Uses C<DB::system> to invoke a shell.
2988
2989 =cut
2990
2991                 # $sh - start a shell.
2992                 if ($cmd =~ /\A$sh\z/) {
2993
2994                     # Run the user's shell. If none defined, run Bourne.
2995                     # We resume execution when the shell terminates.
2996                     &system( $ENV{SHELL} || "/bin/sh" );
2997                     next CMD;
2998                 }
2999
3000 =head4 C<$sh I<command>> - Force execution of a command in a shell
3001
3002 Like the above, but the command is passed to the shell. Again, we use
3003 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3004
3005 =cut
3006
3007                 # $sh command - start a shell and run a command in it.
3008                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
3009
3010                     # XXX: using csh or tcsh destroys sigint retvals!
3011                     #&system($1);  # use this instead
3012
3013                     # use the user's shell, or Bourne if none defined.
3014                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
3015                     next CMD;
3016                 }
3017
3018 =head4 C<H> - display commands in history
3019
3020 Prints the contents of C<@hist> (if any).
3021
3022 =cut
3023
3024                 if ($cmd =~ /\AH\b\s*\*/) {
3025                     @hist = @truehist = ();
3026                     print $OUT "History cleansed\n";
3027                     next CMD;
3028                 }
3029
3030                 if (my ($num)
3031                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
3032
3033                     # Anything other than negative numbers is ignored by
3034                     # the (incorrect) pattern, so this test does nothing.
3035                     $end = $num ? ( $#hist - $num ) : 0;
3036
3037                     # Set to the minimum if less than zero.
3038                     $hist = 0 if $hist < 0;
3039
3040                     # Start at the end of the array.
3041                     # Stay in while we're still above the ending value.
3042                     # Tick back by one each time around the loop.
3043                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3044
3045                         # Print the command  unless it has no arguments.
3046                         print $OUT "$i: ", $hist[$i], "\n"
3047                           unless $hist[$i] =~ /^.?$/;
3048                     }
3049                     next CMD;
3050                 }
3051
3052 =head4 C<man, doc, perldoc> - look up documentation
3053
3054 Just calls C<runman()> to print the appropriate document.
3055
3056 =cut
3057
3058                 # man, perldoc, doc - show manual pages.
3059                 if (my ($man_page)
3060                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3061                     runman($man_page);
3062                     next CMD;
3063                 }
3064
3065 =head4 C<p> - print
3066
3067 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3068 the bottom of the loop.
3069
3070 =cut
3071
3072                 my $print_cmd = 'print {$DB::OUT} ';
3073                 # p - print (no args): print $_.
3074                 if ($cmd eq 'p') {
3075                     $cmd = $print_cmd . '$_';
3076                 }
3077
3078                 # p - print the given expression.
3079                 $cmd =~ s/\Ap\b/$print_cmd /;
3080
3081 =head4 C<=> - define command alias
3082
3083 Manipulates C<%alias> to add or list command aliases.
3084
3085 =cut
3086
3087                 # = - set up a command alias.
3088                 if ($cmd =~ s/\A=\s*//) {
3089                     my @keys;
3090                     if ( length $cmd == 0 ) {
3091
3092                         # No args, get current aliases.
3093                         @keys = sort keys %alias;
3094                     }
3095                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3096
3097                         # Creating a new alias. $k is alias name, $v is
3098                         # alias value.
3099
3100                         # can't use $_ or kill //g state
3101                         for my $x ( $k, $v ) {
3102
3103                             # Escape "alarm" characters.
3104                             $x =~ s/\a/\\a/g;
3105                         }
3106
3107                         # Substitute key for value, using alarm chars
3108                         # as separators (which is why we escaped them in
3109                         # the command).
3110                         $alias{$k} = "s\a$k\a$v\a";
3111
3112                         # Turn off standard warn and die behavior.
3113                         local $SIG{__DIE__};
3114                         local $SIG{__WARN__};
3115
3116                         # Is it valid Perl?
3117                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3118
3119                             # Nope. Bad alias. Say so and get out.
3120                             print $OUT "Can't alias $k to $v: $@\n";
3121                             delete $alias{$k};
3122                             next CMD;
3123                         }
3124
3125                         # We'll only list the new one.
3126                         @keys = ($k);
3127                     } ## end elsif (my ($k, $v) = ($cmd...
3128
3129                     # The argument is the alias to list.
3130                     else {
3131                         @keys = ($cmd);
3132                     }
3133
3134                     # List aliases.
3135                     for my $k (@keys) {
3136
3137                         # Messy metaquoting: Trim the substitution code off.
3138                         # We use control-G as the delimiter because it's not
3139                         # likely to appear in the alias.
3140                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3141
3142                             # Print the alias.
3143                             print $OUT "$k\t= $1\n";
3144                         }
3145                         elsif ( defined $alias{$k} ) {
3146
3147                             # Couldn't trim it off; just print the alias code.
3148                             print $OUT "$k\t$alias{$k}\n";
3149                         }
3150                         else {
3151
3152                             # No such, dude.
3153                             print "No alias for $k\n";
3154                         }
3155                     } ## end for my $k (@keys)
3156                     next CMD;
3157                 }
3158
3159 =head4 C<source> - read commands from a file.
3160
3161 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3162 pick it up.
3163
3164 =cut
3165
3166                 # source - read commands from a file (or pipe!) and execute.
3167                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3168                     if ( open my $fh, $sourced_fn ) {
3169
3170                         # Opened OK; stick it in the list of file handles.
3171                         push @cmdfhs, $fh;
3172                     }
3173                     else {
3174
3175                         # Couldn't open it.
3176                         &warn("Can't execute '$sourced_fn': $!\n");
3177                     }
3178                     next CMD;
3179                 }
3180
3181                 if (my ($which_cmd, $position)
3182                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3183
3184                     my ($fn, $line_num);
3185                     if ($position =~ m{\A\d+\z})
3186                     {
3187                         $fn = $filename;
3188                         $line_num = $position;
3189                     }
3190                     elsif (my ($new_fn, $new_line_num)
3191                         = $position =~ m{\A(.*):(\d+)\z}) {
3192                         ($fn, $line_num) = ($new_fn, $new_line_num);
3193                     }
3194                     else
3195                     {
3196                         &warn("Wrong spec for enable/disable argument.\n");
3197                     }
3198
3199                     if (defined($fn)) {
3200                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3201                             _set_breakpoint_enabled_status($fn, $line_num,
3202                                 ($which_cmd eq 'enable' ? 1 : '')
3203                             );
3204                         }
3205                         else {
3206                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3207                         }
3208                     }
3209
3210                     next CMD;
3211                 }
3212
3213 =head4 C<save> - send current history to a file
3214
3215 Takes the complete history, (not the shrunken version you see with C<H>),
3216 and saves it to the given filename, so it can be replayed using C<source>.
3217
3218 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3219
3220 =cut
3221
3222                 # save source - write commands to a file for later use
3223                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3224                     my $filename = $new_fn || '.perl5dbrc';    # default?
3225                     if ( open my $fh, '>', $filename ) {
3226
3227                        # chomp to remove extraneous newlines from source'd files
3228                         chomp( my @truelist =
3229                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3230                               @truehist );
3231                         print $fh join( "\n", @truelist );
3232                         print "commands saved in $file\n";
3233                     }
3234                     else {
3235                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3236                     }
3237                     next CMD;
3238                 }
3239
3240 =head4 C<R> - restart
3241
3242 Restart the debugger session.
3243
3244 =head4 C<rerun> - rerun the current session
3245
3246 Return to any given position in the B<true>-history list
3247
3248 =cut
3249
3250                 # R - restart execution.
3251                 # rerun - controlled restart execution.
3252                 if (my ($cmd_cmd, $cmd_params) =
3253                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3254                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3255
3256                     # Close all non-system fds for a clean restart.  A more
3257                     # correct method would be to close all fds that were not
3258                     # open when the process started, but this seems to be
3259                     # hard.  See "debugger 'R'estart and open database
3260                     # connections" on p5p.
3261
3262                     my $max_fd = 1024; # default if POSIX can't be loaded
3263                     if (eval { require POSIX }) {
3264                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3265                     }
3266
3267                     if (defined $max_fd) {
3268                         foreach ($^F+1 .. $max_fd-1) {
3269                             next unless open FD_TO_CLOSE, "<&=$_";
3270                             close(FD_TO_CLOSE);
3271                         }
3272                     }
3273
3274                     # And run Perl again.  We use exec() to keep the
3275                     # PID stable (and that way $ini_pids is still valid).
3276                     exec(@args) || print $OUT "exec failed: $!\n";
3277
3278                     last CMD;
3279                 }
3280
3281 =head4 C<|, ||> - pipe output through the pager.
3282
3283 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3284 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3285 pipe to the pager (restoring the output filehandles if this fails). If this
3286 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3287 set C<$signal>, sending us back into the debugger.
3288
3289 We then trim off the pipe symbols and C<redo> the command loop at the
3290 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3291 reading another.
3292
3293 =cut
3294
3295                 # || - run command in the pager, with output to DB::OUT.
3296                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3297                     if ( $pager =~ /^\|/ ) {
3298
3299                         # Default pager is into a pipe. Redirect I/O.
3300                         open( SAVEOUT, ">&STDOUT" )
3301                           || &warn("Can't save STDOUT");
3302                         open( STDOUT, ">&OUT" )
3303                           || &warn("Can't redirect STDOUT");
3304                     } ## end if ($pager =~ /^\|/)
3305                     else {
3306
3307                         # Not into a pipe. STDOUT is safe.
3308                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3309                     }
3310
3311                     # Fix up environment to record we have less if so.
3312                     fix_less();
3313
3314                     unless ( $piped = open( OUT, $pager ) ) {
3315
3316                         # Couldn't open pipe to pager.
3317                         &warn("Can't pipe output to '$pager'");
3318                         if ( $pager =~ /^\|/ ) {
3319
3320                             # Redirect I/O back again.
3321                             open( OUT, ">&STDOUT" )    # XXX: lost message
3322                               || &warn("Can't restore DB::OUT");
3323                             open( STDOUT, ">&SAVEOUT" )
3324                               || &warn("Can't restore STDOUT");
3325                             close(SAVEOUT);
3326                         } ## end if ($pager =~ /^\|/)
3327                         else {
3328
3329                             # Redirect I/O. STDOUT already safe.
3330                             open( OUT, ">&STDOUT" )    # XXX: lost message
3331                               || &warn("Can't restore DB::OUT");
3332                         }
3333                         next CMD;
3334                     } ## end unless ($piped = open(OUT,...
3335
3336                     # Set up broken-pipe handler if necessary.
3337                     $SIG{PIPE} = \&DB::catch
3338                       if $pager =~ /^\|/
3339                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3340
3341                     OUT->autoflush(1);
3342                     # Save current filehandle, and put it back.
3343                     $selected = select(OUT);
3344                     # Don't put it back if pager was a pipe.
3345                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3346
3347                     # Trim off the pipe symbols and run the command now.
3348                     $cmd =~ s#\A\|+\s*##;
3349                     redo PIPE;
3350                 }
3351
3352 =head3 END OF COMMAND PARSING
3353
3354 Anything left in C<$cmd> at this point is a Perl expression that we want to
3355 evaluate. We'll always evaluate in the user's context, and fully qualify
3356 any variables we might want to address in the C<DB> package.
3357
3358 =cut
3359
3360                 # t - turn trace on.
3361                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3362                     my $trace_arg = $1;
3363                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3364                 }
3365
3366                 # s - single-step. Remember the last command was 's'.
3367                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3368                     $laststep = 's';
3369                 }
3370
3371                 # n - single-step, but not into subs. Remember last command
3372                 # was 'n'.
3373                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3374                     $laststep = 'n';
3375                 }
3376
3377             }    # PIPE:
3378
3379             # Make sure the flag that says "the debugger's running" is
3380             # still on, to make sure we get control again.
3381             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3382
3383             # Run *our* eval that executes in the caller's context.
3384             &eval;
3385
3386             # Turn off the one-time-dump stuff now.
3387             if ($onetimeDump) {
3388                 $onetimeDump      = undef;
3389                 $onetimedumpDepth = undef;
3390             }
3391             elsif ( $term_pid == $$ ) {
3392                 eval {          # May run under miniperl, when not available...
3393                     STDOUT->flush();
3394                     STDERR->flush();
3395                 };
3396
3397                 # XXX If this is the master pid, print a newline.
3398                 print $OUT "\n";
3399             }
3400         } ## end while (($term || &setterm...
3401
3402 =head3 POST-COMMAND PROCESSING
3403
3404 After each command, we check to see if the command output was piped anywhere.
3405 If so, we go through the necessary code to unhook the pipe and go back to
3406 our standard filehandles for input and output.
3407
3408 =cut
3409
3410         continue {    # CMD:
3411
3412             # At the end of every command:
3413             if ($piped) {
3414
3415                 # Unhook the pipe mechanism now.
3416                 if ( $pager =~ /^\|/ ) {
3417
3418                     # No error from the child.
3419                     $? = 0;
3420
3421                     # we cannot warn here: the handle is missing --tchrist
3422                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3423
3424                     # most of the $? crud was coping with broken cshisms
3425                     # $? is explicitly set to 0, so this never runs.
3426                     if ($?) {
3427                         print SAVEOUT "Pager '$pager' failed: ";
3428                         if ( $? == -1 ) {
3429                             print SAVEOUT "shell returned -1\n";
3430                         }
3431                         elsif ( $? >> 8 ) {
3432                             print SAVEOUT ( $? & 127 )
3433                               ? " (SIG#" . ( $? & 127 ) . ")"
3434                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3435                         }
3436                         else {
3437                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3438                         }
3439                     } ## end if ($?)
3440
3441                     # Reopen filehandle for our output (if we can) and
3442                     # restore STDOUT (if we can).
3443                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3444                     open( STDOUT, ">&SAVEOUT" )
3445                       || &warn("Can't restore STDOUT");
3446
3447                     # Turn off pipe exception handler if necessary.
3448                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3449
3450                     # Will stop ignoring SIGPIPE if done like nohup(1)
3451                     # does SIGINT but Perl doesn't give us a choice.
3452                 } ## end if ($pager =~ /^\|/)
3453                 else {
3454
3455                     # Non-piped "pager". Just restore STDOUT.
3456                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3457                 }
3458
3459                 # Close filehandle pager was using, restore the normal one
3460                 # if necessary,
3461                 close(SAVEOUT);
3462                 select($selected), $selected = "" unless $selected eq "";
3463
3464                 # No pipes now.
3465                 $piped = "";
3466             } ## end if ($piped)
3467         }    # CMD:
3468
3469 =head3 COMMAND LOOP TERMINATION
3470
3471 When commands have finished executing, we come here. If the user closed the
3472 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3473 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3474 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3475 The interpreter will then execute the next line and then return control to us
3476 again.
3477
3478 =cut
3479
3480         # No more commands? Quit.
3481         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3482
3483         # Evaluate post-prompt commands.
3484         foreach $evalarg (@$post) {
3485             &eval;
3486         }
3487     }    # if ($single || $signal)
3488
3489     # Put the user's globals back where you found them.
3490     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3491     ();
3492 } ## end sub DB
3493
3494 # The following code may be executed now:
3495 # BEGIN {warn 4}
3496
3497 =head2 sub
3498
3499 C<sub> is called whenever a subroutine call happens in the program being
3500 debugged. The variable C<$DB::sub> contains the name of the subroutine
3501 being called.
3502
3503 The core function of this subroutine is to actually call the sub in the proper
3504 context, capturing its output. This of course causes C<DB::DB> to get called
3505 again, repeating until the subroutine ends and returns control to C<DB::sub>
3506 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3507 return value, and returns its captured copy of the return value as its own
3508 return value. The value then feeds back into the program being debugged as if
3509 C<DB::sub> hadn't been there at all.
3510
3511 C<sub> does all the work of printing the subroutine entry and exit messages
3512 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3513 and also prints the return value if needed (for the C<r> command and if
3514 the 16 bit is set in C<$frame>).
3515
3516 It also tracks the subroutine call depth by saving the current setting of
3517 C<$single> in the C<@stack> package global; if this exceeds the value in
3518 C<$deep>, C<sub> automatically turns on printing of the current depth by
3519 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3520 of stop/don't stop on entry to subs set as it currently is set.
3521
3522 =head3 C<caller()> support
3523
3524 If C<caller()> is called from the package C<DB>, it provides some
3525 additional data, in the following order:
3526
3527 =over 4
3528
3529 =item * C<$package>
3530
3531 The package name the sub was in
3532
3533 =item * C<$filename>
3534
3535 The filename it was defined in
3536
3537 =item * C<$line>
3538
3539 The line number it was defined on
3540
3541 =item * C<$subroutine>
3542
3543 The subroutine name; C<(eval)> if an C<eval>().
3544
3545 =item * C<$hasargs>
3546
3547 1 if it has arguments, 0 if not
3548
3549 =item * C<$wantarray>
3550
3551 1 if array context, 0 if scalar context
3552
3553 =item * C<$evaltext>
3554
3555 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3556
3557 =item * C<$is_require>
3558
3559 frame was created by a C<use> or C<require> statement
3560
3561 =item * C<$hints>
3562
3563 pragma information; subject to change between versions
3564
3565 =item * C<$bitmask>
3566
3567 pragma information; subject to change between versions
3568
3569 =item * C<@DB::args>
3570
3571 arguments with which the subroutine was invoked
3572
3573 =back
3574
3575 =cut
3576
3577 use vars qw($deep);
3578
3579 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3580 # happy. -- Shlomi Fish
3581 sub DB::sub {
3582         # Do not use a regex in this subroutine -> results in corrupted memory
3583         # See: [perl #66110]
3584
3585         # lock ourselves under threads
3586         lock($DBGR);
3587
3588     # Whether or not the autoloader was running, a scalar to put the
3589     # sub's return value in (if needed), and an array to put the sub's
3590     # return value in (if needed).
3591     my ( $al, $ret, @ret ) = "";
3592         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3593                 print "creating new thread\n";
3594         }
3595
3596     # If the last ten characters are '::AUTOLOAD', note we've traced
3597     # into AUTOLOAD for $sub.
3598     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3599         no strict 'refs';
3600         $al = " for $$sub" if defined $$sub;
3601     }
3602
3603     # We stack the stack pointer and then increment it to protect us
3604     # from a situation that might unwind a whole bunch of call frames
3605     # at once. Localizing the stack pointer means that it will automatically
3606     # unwind the same amount when multiple stack frames are unwound.
3607     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3608
3609     # Expand @stack.
3610     $#stack = $stack_depth;
3611
3612     # Save current single-step setting.
3613     $stack[-1] = $single;
3614
3615     # Turn off all flags except single-stepping.
3616     $single &= 1;
3617
3618     # If we've gotten really deeply recursed, turn on the flag that will
3619     # make us stop with the 'deep recursion' message.
3620     $single |= 4 if $stack_depth == $deep;
3621
3622     # If frame messages are on ...
3623     (
3624         $frame & 4    # Extended frame entry message
3625         ? (
3626             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3627
3628             # Why -1? But it works! :-(
3629             # Because print_trace will call add 1 to it and then call
3630             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3631             # in dump_trace.
3632             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3633           )
3634         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3635
3636           # standard frame entry message
3637       )
3638       if $frame;
3639
3640     # Determine the sub's return type, and capture appropriately.
3641     if (wantarray) {
3642
3643         # Called in array context. call sub and capture output.
3644         # DB::DB will recursively get control again if appropriate; we'll come
3645         # back here when the sub is finished.
3646         {
3647             no strict 'refs';
3648             @ret = &$sub;
3649         }
3650
3651         # Pop the single-step value back off the stack.
3652         $single |= $stack[ $stack_depth-- ];
3653
3654         # Check for exit trace messages...
3655         (
3656             $frame & 4    # Extended exit message
3657             ? (
3658                 print_lineinfo( ' ' x $stack_depth, "out " ),
3659                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3660               )
3661             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3662
3663               # Standard exit message
3664           )
3665           if $frame & 2;
3666
3667         # Print the return info if we need to.
3668         if ( $doret eq $stack_depth or $frame & 16 ) {
3669
3670             # Turn off output record separator.
3671             local $\ = '';
3672             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3673
3674             # Indent if we're printing because of $frame tracing.
3675             print $fh ' ' x $stack_depth if $frame & 16;
3676
3677             # Print the return value.
3678             print $fh "list context return from $sub:\n";
3679             dumpit( $fh, \@ret );
3680
3681             # And don't print it again.
3682             $doret = -2;
3683         } ## end if ($doret eq $stack_depth...
3684             # And we have to return the return value now.
3685         @ret;
3686     } ## end if (wantarray)
3687
3688     # Scalar context.
3689     else {
3690         if ( defined wantarray ) {
3691         no strict 'refs';
3692             # Save the value if it's wanted at all.
3693             $ret = &$sub;
3694         }
3695         else {
3696         no strict 'refs';
3697             # Void return, explicitly.
3698             &$sub;
3699             undef $ret;
3700         }
3701
3702         # Pop the single-step value off the stack.
3703         $single |= $stack[ $stack_depth-- ];
3704
3705         # If we're doing exit messages...
3706         (
3707             $frame & 4    # Extended messages
3708             ? (
3709                 print_lineinfo( ' ' x $stack_depth, "out " ),
3710                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3711               )
3712             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3713
3714               # Standard messages
3715           )
3716           if $frame & 2;
3717
3718         # If we are supposed to show the return value... same as before.
3719         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3720             local $\ = '';
3721             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3722             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3723             print $fh (
3724                 defined wantarray
3725                 ? "scalar context return from $sub: "
3726                 : "void context return from $sub\n"
3727             );
3728             dumpit( $fh, $ret ) if defined wantarray;
3729             $doret = -2;
3730         } ## end if ($doret eq $stack_depth...
3731
3732         # Return the appropriate scalar value.
3733         $ret;
3734     } ## end else [ if (wantarray)
3735 } ## end sub _sub
3736
3737 sub lsub : lvalue {
3738
3739     no strict 'refs';
3740
3741         # lock ourselves under threads
3742         lock($DBGR);
3743
3744     # Whether or not the autoloader was running, a scalar to put the
3745     # sub's return value in (if needed), and an array to put the sub's
3746     # return value in (if needed).
3747     my ( $al, $ret, @ret ) = "";
3748         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3749                 print "creating new thread\n";
3750         }
3751
3752     # If the last ten characters are C'::AUTOLOAD', note we've traced
3753     # into AUTOLOAD for $sub.
3754     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3755         $al = " for $$sub";
3756     }
3757
3758     # We stack the stack pointer and then increment it to protect us
3759     # from a situation that might unwind a whole bunch of call frames
3760     # at once. Localizing the stack pointer means that it will automatically
3761     # unwind the same amount when multiple stack frames are unwound.
3762     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3763
3764     # Expand @stack.
3765     $#stack = $stack_depth;
3766
3767     # Save current single-step setting.
3768     $stack[-1] = $single;
3769
3770     # Turn off all flags except single-stepping.
3771     $single &= 1;
3772
3773     # If we've gotten really deeply recursed, turn on the flag that will
3774     # make us stop with the 'deep recursion' message.
3775     $single |= 4 if $stack_depth == $deep;
3776
3777     # If frame messages are on ...
3778     (
3779         $frame & 4    # Extended frame entry message
3780         ? (
3781             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3782
3783             # Why -1? But it works! :-(
3784             # Because print_trace will call add 1 to it and then call
3785             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3786             # in dump_trace.
3787             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3788           )
3789         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3790
3791           # standard frame entry message
3792       )
3793       if $frame;
3794
3795     # Pop the single-step value back off the stack.
3796     $single |= $stack[ $stack_depth-- ];
3797
3798     # call the original lvalue sub.
3799     &$sub;
3800 }
3801
3802 # Abstracting common code from multiple places elsewhere:
3803 sub depth_print_lineinfo {
3804     my $always_print = shift;
3805
3806     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3807 }
3808
3809 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3810
3811 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3812 Most of the changes were to systematize the command structure and to eliminate
3813 commands that threw away user input without checking.
3814
3815 The following sections describe the code added to make it easy to support
3816 multiple command sets with conflicting command names. This section is a start
3817 at unifying all command processing to make it simpler to develop commands.
3818
3819 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3820 number, and C<$dbline> (the current line) as arguments.
3821
3822 Support functions in this section which have multiple modes of failure C<die>
3823 on error; the rest simply return a false value.
3824
3825 The user-interface functions (all of the C<cmd_*> functions) just output
3826 error messages.
3827
3828 =head2 C<%set>
3829
3830 The C<%set> hash defines the mapping from command letter to subroutine
3831 name suffix.
3832
3833 C<%set> is a two-level hash, indexed by set name and then by command name.
3834 Note that trying to set the CommandSet to C<foobar> simply results in the
3835 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3836
3837 =cut
3838
3839 ### The API section
3840
3841 my %set = (    #
3842     'pre580' => {
3843         'a' => 'pre580_a',
3844         'A' => 'pre580_null',
3845         'b' => 'pre580_b',
3846         'B' => 'pre580_null',
3847         'd' => 'pre580_null',
3848         'D' => 'pre580_D',
3849         'h' => 'pre580_h',
3850         'M' => 'pre580_null',
3851         'O' => 'o',
3852         'o' => 'pre580_null',
3853         'v' => 'M',
3854         'w' => 'v',
3855         'W' => 'pre580_W',
3856     },
3857     'pre590' => {
3858         '<'  => 'pre590_prepost',
3859         '<<' => 'pre590_prepost',
3860         '>'  => 'pre590_prepost',
3861         '>>' => 'pre590_prepost',
3862         '{'  => 'pre590_prepost',
3863         '{{' => 'pre590_prepost',
3864     },
3865 );
3866
3867 my %breakpoints_data;
3868
3869 sub _has_breakpoint_data_ref {
3870     my ($filename, $line) = @_;
3871
3872     return (
3873         exists( $breakpoints_data{$filename} )
3874             and
3875         exists( $breakpoints_data{$filename}{$line} )
3876     );
3877 }
3878
3879 sub _get_breakpoint_data_ref {
3880     my ($filename, $line) = @_;
3881
3882     return ($breakpoints_data{$filename}{$line} ||= +{});
3883 }
3884
3885 sub _delete_breakpoint_data_ref {
3886     my ($filename, $line) = @_;
3887
3888     delete($breakpoints_data{$filename}{$line});
3889     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3890         delete($breakpoints_data{$filename});
3891     }
3892
3893     return;
3894 }
3895
3896 sub _set_breakpoint_enabled_status {
3897     my ($filename, $line, $status) = @_;
3898
3899     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3900         ($status ? 1 : '')
3901         ;
3902
3903     return;
3904 }
3905
3906 sub _enable_breakpoint_temp_enabled_status {
3907     my ($filename, $line) = @_;
3908
3909     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3910
3911     return;
3912 }
3913
3914 sub _cancel_breakpoint_temp_enabled_status {
3915     my ($filename, $line) = @_;
3916
3917     my $ref = _get_breakpoint_data_ref($filename, $line);
3918
3919     delete ($ref->{'temp_enabled'});
3920
3921     if (! %$ref) {
3922         _delete_breakpoint_data_ref($filename, $line);
3923     }
3924
3925     return;
3926 }
3927
3928 sub _is_breakpoint_enabled {
3929     my ($filename, $line) = @_;
3930
3931     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3932     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3933 }
3934
3935 =head2 C<cmd_wrapper()> (API)
3936
3937 C<cmd_wrapper()> allows the debugger to switch command sets
3938 depending on the value of the C<CommandSet> option.
3939
3940 It tries to look up the command in the C<%set> package-level I<lexical>
3941 (which means external entities can't fiddle with it) and create the name of
3942 the sub to call based on the value found in the hash (if it's there). I<All>
3943 of the commands to be handled in a set have to be added to C<%set>; if they
3944 aren't found, the 5.8.0 equivalent is called (if there is one).
3945
3946 This code uses symbolic references.
3947
3948 =cut
3949
3950 sub cmd_wrapper {
3951     my $cmd      = shift;
3952     my $line     = shift;
3953     my $dblineno = shift;
3954
3955     # Assemble the command subroutine's name by looking up the
3956     # command set and command name in %set. If we can't find it,
3957     # default to the older version of the command.
3958     my $call = 'cmd_'
3959       . ( $set{$CommandSet}{$cmd}
3960           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3961
3962     # Call the command subroutine, call it by name.
3963     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
3964 } ## end sub cmd_wrapper
3965
3966 =head3 C<cmd_a> (command)
3967
3968 The C<a> command handles pre-execution actions. These are associated with a
3969 particular line, so they're stored in C<%dbline>. We default to the current
3970 line if none is specified.
3971
3972 =cut
3973
3974 sub cmd_a {
3975     my $cmd    = shift;
3976     my $line   = shift || '';    # [.|line] expr
3977     my $dbline = shift;
3978
3979     # If it's dot (here), or not all digits,  use the current line.
3980     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3981
3982     # Should be a line number followed by an expression.
3983     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3984         my ( $lineno, $expr ) = ( $1, $2 );
3985
3986         # If we have an expression ...
3987         if ( length $expr ) {
3988
3989             # ... but the line isn't breakable, complain.
3990             if ( $dbline[$lineno] == 0 ) {
3991                 print $OUT
3992                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3993             }
3994             else {
3995
3996                 # It's executable. Record that the line has an action.
3997                 $had_breakpoints{$filename} |= 2;
3998
3999                 # Remove any action, temp breakpoint, etc.
4000                 $dbline{$lineno} =~ s/\0[^\0]*//;
4001
4002                 # Add the action to the line.
4003                 $dbline{$lineno} .= "\0" . action($expr);
4004
4005                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4006             }
4007         } ## end if (length $expr)
4008     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4009     else {
4010
4011         # Syntax wrong.
4012         print $OUT
4013           "Adding an action requires an optional lineno and an expression\n"
4014           ;    # hint
4015     }
4016 } ## end sub cmd_a
4017
4018 =head3 C<cmd_A> (command)
4019
4020 Delete actions. Similar to above, except the delete code is in a separate
4021 subroutine, C<delete_action>.
4022
4023 =cut
4024
4025 sub cmd_A {
4026     my $cmd    = shift;
4027     my $line   = shift || '';
4028     my $dbline = shift;
4029
4030     # Dot is this line.
4031     $line =~ s/^\./$dbline/;
4032
4033     # Call delete_action with a null param to delete them all.
4034     # The '1' forces the eval to be true. It'll be false only
4035     # if delete_action blows up for some reason, in which case
4036     # we print $@ and get out.
4037     if ( $line eq '*' ) {
4038         eval { &delete_action(); 1 } or print $OUT $@ and return;
4039     }
4040
4041     # There's a real line  number. Pass it to delete_action.
4042     # Error trapping is as above.
4043     elsif ( $line =~ /^(\S.*)/ ) {
4044         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4045     }
4046
4047     # Swing and a miss. Bad syntax.
4048     else {
4049         print $OUT
4050           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4051     }
4052 } ## end sub cmd_A
4053
4054 =head3 C<delete_action> (API)
4055
4056 C<delete_action> accepts either a line number or C<undef>. If a line number
4057 is specified, we check for the line being executable (if it's not, it
4058 couldn't have had an  action). If it is, we just take the action off (this
4059 will get any kind of an action, including breakpoints).
4060
4061 =cut
4062
4063 sub delete_action {
4064     my $i = shift;
4065     if ( defined($i) ) {
4066
4067         # Can there be one?
4068         die "Line $i has no action .\n" if $dbline[$i] == 0;
4069
4070         # Nuke whatever's there.
4071         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4072         delete $dbline{$i} if $dbline{$i} eq '';
4073     }
4074     else {
4075         print $OUT "Deleting all actions...\n";
4076         for my $file ( keys %had_breakpoints ) {
4077             local *dbline = $main::{ '_<' . $file };
4078             $max = $#dbline;
4079             my $was;
4080             for $i (1 .. $max) {
4081                 if ( defined $dbline{$i} ) {
4082                     $dbline{$i} =~ s/\0[^\0]*//;
4083                     delete $dbline{$i} if $dbline{$i} eq '';
4084                 }
4085                 unless ( $had_breakpoints{$file} &= ~2 ) {
4086                     delete $had_breakpoints{$file};
4087                 }
4088             } ## end for ($i = 1 .. $max)
4089         } ## end for my $file (keys %had_breakpoints)
4090     } ## end else [ if (defined($i))
4091 } ## end sub delete_action
4092
4093 =head3 C<cmd_b> (command)
4094
4095 Set breakpoints. Since breakpoints can be set in so many places, in so many
4096 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4097 we try to parse the command type, and then shuttle it off to an appropriate
4098 subroutine to actually do the work of setting the breakpoint in the right
4099 place.
4100
4101 =cut
4102
4103 sub cmd_b {
4104     my $cmd    = shift;
4105     my $line   = shift;    # [.|line] [cond]
4106     my $dbline = shift;
4107
4108     # Make . the current line number if it's there..
4109     $line =~ s/^\.(\s|\z)/$dbline$1/;
4110
4111     # No line number, no condition. Simple break on current line.
4112     if ( $line =~ /^\s*$/ ) {
4113         &cmd_b_line( $dbline, 1 );
4114     }
4115
4116     # Break on load for a file.
4117     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4118         my $file = $1;
4119         $file =~ s/\s+$//;
4120         &cmd_b_load($file);
4121     }
4122
4123     # b compile|postpone <some sub> [<condition>]
4124     # The interpreter actually traps this one for us; we just put the
4125     # necessary condition in the %postponed hash.
4126     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4127
4128         # Capture the condition if there is one. Make it true if none.
4129         my $cond = length $3 ? $3 : '1';
4130
4131         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4132         # if it was 'compile'.
4133         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4134
4135         # De-Perl4-ify the name - ' separators to ::.
4136         $subname =~ s/\'/::/g;
4137
4138         # Qualify it into the current package unless it's already qualified.
4139         $subname = "${package}::" . $subname unless $subname =~ /::/;
4140
4141         # Add main if it starts with ::.
4142         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4143
4144         # Save the break type for this sub.
4145         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4146     } ## end elsif ($line =~ ...
4147     # b <filename>:<line> [<condition>]
4148     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4149         my ($filename, $line_num, $cond) = ($1, $2, $3);
4150         cmd_b_filename_line(
4151             $filename,
4152             $line_num,
4153             (length($cond) ? $cond : '1'),
4154         );
4155     }
4156     # b <sub name> [<condition>]
4157     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4158
4159         #
4160         $subname = $1;
4161         my $cond = length $2 ? $2 : '1';
4162         &cmd_b_sub( $subname, $cond );
4163     }
4164
4165     # b <line> [<condition>].
4166     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4167
4168         # Capture the line. If none, it's the current line.
4169         $line = $1 || $dbline;
4170
4171         # If there's no condition, make it '1'.
4172         my $cond = length $2 ? $2 : '1';
4173
4174         # Break on line.
4175         &cmd_b_line( $line, $cond );
4176     }
4177
4178     # Line didn't make sense.
4179     else {
4180         print "confused by line($line)?\n";
4181     }
4182 } ## end sub cmd_b
4183
4184 =head3 C<break_on_load> (API)
4185
4186 We want to break when this file is loaded. Mark this file in the
4187 C<%break_on_load> hash, and note that it has a breakpoint in
4188 C<%had_breakpoints>.
4189
4190 =cut
4191
4192 sub break_on_load {
4193     my $file = shift;
4194     $break_on_load{$file} = 1;
4195     $had_breakpoints{$file} |= 1;
4196 }
4197
4198 =head3 C<report_break_on_load> (API)
4199
4200 Gives us an array of filenames that are set to break on load. Note that
4201 only files with break-on-load are in here, so simply showing the keys
4202 suffices.
4203
4204 =cut
4205
4206 sub report_break_on_load {
4207     sort keys %break_on_load;
4208 }
4209
4210 =head3 C<cmd_b_load> (command)
4211
4212 We take the file passed in and try to find it in C<%INC> (which maps modules
4213 to files they came from). We mark those files for break-on-load via
4214 C<break_on_load> and then report that it was done.
4215
4216 =cut
4217
4218 sub cmd_b_load {
4219     my $file = shift;
4220     my @files;
4221
4222     # This is a block because that way we can use a redo inside it
4223     # even without there being any looping structure at all outside it.
4224     {
4225
4226         # Save short name and full path if found.
4227         push @files, $file;
4228         push @files, $::INC{$file} if $::INC{$file};
4229
4230         # Tack on .pm and do it again unless there was a '.' in the name
4231         # already.
4232         $file .= '.pm', redo unless $file =~ /\./;
4233     }
4234
4235     # Do the real work here.
4236     break_on_load($_) for @files;
4237
4238     # All the files that have break-on-load breakpoints.
4239     @files = report_break_on_load;
4240
4241     # Normalize for the purposes of our printing this.
4242     local $\ = '';
4243     local $" = ' ';
4244     print $OUT "Will stop on load of '@files'.\n";
4245 } ## end sub cmd_b_load
4246
4247 =head3 C<$filename_error> (API package global)
4248
4249 Several of the functions we need to implement in the API need to work both
4250 on the current file and on other files. We don't want to duplicate code, so
4251 C<$filename_error> is used to contain the name of the file that's being
4252 worked on (if it's not the current one).
4253
4254 We can now build functions in pairs: the basic function works on the current
4255 file, and uses C<$filename_error> as part of its error message. Since this is
4256 initialized to C<"">, no filename will appear when we are working on the
4257 current file.
4258
4259 The second function is a wrapper which does the following:
4260
4261 =over 4
4262
4263 =item *
4264
4265 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4266
4267 =item *
4268
4269 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4270
4271 =item *
4272
4273 Calls the first function.
4274
4275 The first function works on the I<current> file (i.e., the one we changed to),
4276 and prints C<$filename_error> in the error message (the name of the other file)
4277 if it needs to. When the functions return, C<*dbline> is restored to point
4278 to the actual current file (the one we're executing in) and
4279 C<$filename_error> is restored to C<"">. This restores everything to
4280 the way it was before the second function was called at all.
4281
4282 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4283 details.
4284
4285 =back
4286
4287 =cut
4288
4289 use vars qw($filename_error);
4290 $filename_error = '';
4291
4292 =head3 breakable_line(from, to) (API)
4293
4294 The subroutine decides whether or not a line in the current file is breakable.
4295 It walks through C<@dbline> within the range of lines specified, looking for
4296 the first line that is breakable.
4297
4298 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4299 first line I<after> C<$to> that's breakable, if there is one.
4300
4301 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4302 first line I<before> C<$to> that's breakable, if there is one.
4303
4304 =cut
4305
4306 sub breakable_line {
4307
4308     my ( $from, $to ) = @_;
4309
4310     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4311     my $i = $from;
4312
4313     # If there are at least 2 arguments, we're trying to search a range.
4314     if ( @_ >= 2 ) {
4315
4316         # $delta is positive for a forward search, negative for a backward one.
4317         my $delta = $from < $to ? +1 : -1;
4318
4319         # Keep us from running off the ends of the file.
4320         my $limit = $delta > 0 ? $#dbline : 1;
4321
4322         # Clever test. If you're a mathematician, it's obvious why this
4323         # test works. If not:
4324         # If $delta is positive (going forward), $limit will be $#dbline.
4325         #    If $to is less than $limit, ($limit - $to) will be positive, times
4326         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4327         #    as the stopping point.
4328         #
4329         #    If $to is greater than $limit, ($limit - $to) is negative,
4330         #    times $delta of 1 (positive), so the result is < 0 and we should
4331         #    use $limit ($#dbline) as the stopping point.
4332         #
4333         # If $delta is negative (going backward), $limit will be 1.
4334         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4335         #    (negative) so the result is > 0, and we use $to as the stopping
4336         #    point.
4337         #
4338         #    If $to is less than zero, ($limit - $to) will be positive,
4339         #    times $delta of -1 (negative), so the result is not > 0, and
4340         #    we use $limit (1) as the stopping point.
4341         #
4342         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4343         #    (negative), still giving zero; the result is not > 0, and
4344         #    we use $limit (1) as the stopping point.
4345         #
4346         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4347         #    (negative), giving a positive (>0) value, so we'll set $limit to
4348         #    $to.
4349
4350         $limit = $to if ( $limit - $to ) * $delta > 0;
4351
4352         # The real search loop.
4353         # $i starts at $from (the point we want to start searching from).
4354         # We move through @dbline in the appropriate direction (determined
4355         # by $delta: either -1 (back) or +1 (ahead).
4356         # We stay in as long as we haven't hit an executable line
4357         # ($dbline[$i] == 0 means not executable) and we haven't reached
4358         # the limit yet (test similar to the above).
4359         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4360
4361     } ## end if (@_ >= 2)
4362
4363     # If $i points to a line that is executable, return that.
4364     return $i unless $dbline[$i] == 0;
4365
4366     # Format the message and print it: no breakable lines in range.
4367     my ( $pl, $upto ) = ( '', '' );
4368     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4369
4370     # If there's a filename in filename_error, we'll see it.
4371     # If not, not.
4372     die "Line$pl $from$upto$filename_error not breakable\n";
4373 } ## end sub breakable_line
4374
4375 =head3 breakable_line_in_filename(file, from, to) (API)
4376
4377 Like C<breakable_line>, but look in another file.
4378
4379 =cut
4380
4381 sub breakable_line_in_filename {
4382
4383     # Capture the file name.
4384     my ($f) = shift;
4385
4386     # Swap the magic line array over there temporarily.
4387     local *dbline = $main::{ '_<' . $f };
4388
4389     # If there's an error, it's in this other file.
4390     local $filename_error = " of '$f'";
4391
4392     # Find the breakable line.
4393     breakable_line(@_);
4394
4395     # *dbline and $filename_error get restored when this block ends.
4396
4397 } ## end sub breakable_line_in_filename
4398
4399 =head3 break_on_line(lineno, [condition]) (API)
4400
4401 Adds a breakpoint with the specified condition (or 1 if no condition was
4402 specified) to the specified line. Dies if it can't.
4403
4404 =cut
4405
4406 sub break_on_line {
4407     my ( $i, $cond ) = @_;
4408
4409     # Always true if no condition supplied.
4410     $cond = 1 unless @_ >= 2;
4411
4412     my $inii  = $i;
4413     my $after = '';
4414     my $pl    = '';
4415
4416     # Woops, not a breakable line. $filename_error allows us to say
4417     # if it was in a different file.
4418     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4419
4420     # Mark this file as having breakpoints in it.
4421     $had_breakpoints{$filename} |= 1;
4422
4423     # If there is an action or condition here already ...
4424     if ( $dbline{$i} ) {
4425
4426         # ... swap this condition for the existing one.
4427         $dbline{$i} =~ s/^[^\0]*/$cond/;
4428     }
4429     else {
4430
4431         # Nothing here - just add the condition.
4432         $dbline{$i} = $cond;
4433
4434         _set_breakpoint_enabled_status($filename, $i, 1);
4435     }
4436 } ## end sub break_on_line
4437
4438 =head3 cmd_b_line(line, [condition]) (command)
4439
4440 Wrapper for C<break_on_line>. Prints the failure message if it
4441 doesn't work.
4442
4443 =cut
4444
4445 sub cmd_b_line {
4446     if (not eval { break_on_line(@_); 1 }) {
4447         local $\ = '';
4448         print $OUT $@ and return;
4449     }
4450
4451     return;
4452 } ## end sub cmd_b_line
4453
4454 =head3 cmd_b_filename_line(line, [condition]) (command)
4455
4456 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4457 doesn't work.
4458
4459 =cut
4460
4461 sub cmd_b_filename_line {
4462     if (not eval { break_on_filename_line(@_); 1 }) {
4463         local $\ = '';
4464         print $OUT $@ and return;
4465     }
4466
4467     return;
4468 }
4469
4470 =head3 break_on_filename_line(file, line, [condition]) (API)
4471
4472 Switches to the file specified and then calls C<break_on_line> to set
4473 the breakpoint.
4474
4475 =cut
4476
4477 sub break_on_filename_line {
4478     my ( $f, $i, $cond ) = @_;
4479
4480     # Always true if condition left off.
4481     $cond = 1 unless @_ >= 3;
4482
4483     # Switch the magical hash temporarily.
4484     local *dbline = $main::{ '_<' . $f };
4485
4486     # Localize the variables that break_on_line uses to make its message.
4487     local $filename_error = " of '$f'";
4488     local $filename       = $f;
4489
4490     # Add the breakpoint.
4491     break_on_line( $i, $cond );
4492 } ## end sub break_on_filename_line
4493
4494 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4495
4496 Switch to another file, search the range of lines specified for an
4497 executable one, and put a breakpoint on the first one you find.
4498
4499 =cut
4500
4501 sub break_on_filename_line_range {
4502     my ( $f, $from, $to, $cond ) = @_;
4503
4504     # Find a breakable line if there is one.
4505     my $i = breakable_line_in_filename( $f, $from, $to );
4506
4507     # Always true if missing.
4508     $cond = 1 unless @_ >= 3;
4509
4510     # Add the breakpoint.
4511     break_on_filename_line( $f, $i, $cond );
4512 } ## end sub break_on_filename_line_range
4513
4514 =head3 subroutine_filename_lines(subname, [condition]) (API)
4515
4516 Search for a subroutine within a given file. The condition is ignored.
4517 Uses C<find_sub> to locate the desired subroutine.
4518
4519 =cut
4520
4521 sub subroutine_filename_lines {
4522     my ( $subname, $cond ) = @_;
4523
4524     # Returned value from find_sub() is fullpathname:startline-endline.
4525     # The match creates the list (fullpathname, start, end). Falling off
4526     # the end of the subroutine returns this implicitly.
4527     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4528 } ## end sub subroutine_filename_lines
4529
4530 =head3 break_subroutine(subname) (API)
4531
4532 Places a break on the first line possible in the specified subroutine. Uses
4533 C<subroutine_filename_lines> to find the subroutine, and
4534 C<break_on_filename_line_range> to place the break.
4535
4536 =cut