This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Extract _restore_shared_globals_after_restart.
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_04';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $evalarg
639     $filename
640     $frame
641     $hist
642     $histfile
643     $histsize
644     $ImmediateStop
645     $IN
646     $inhibit_exit
647     @ini_INC
648     $ini_warn
649     $line
650     $maxtrace
651     $od
652     $onetimeDump
653     $onetimedumpDepth
654     %option
655     @options
656     $osingle
657     $otrace
658     $OUT
659     $packname
660     $pager
661     $post
662     %postponed
663     $prc
664     $pre
665     $pretype
666     $psh
667     @RememberOnROptions
668     $remoteport
669     @res
670     $rl
671     @saved
672     $signal
673     $signalLevel
674     $single
675     $start
676     $sub
677     %sub
678     $subname
679     $term
680     $trace
681     $usercontext
682     $warnLevel
683     $window
684 );
685
686 # Used to save @ARGV and extract any debugger-related flags.
687 use vars qw(@ARGS);
688
689 # Used to prevent multiple entries to diesignal()
690 # (if for instance diesignal() itself dies)
691 use vars qw($panic);
692
693 # Used to prevent the debugger from running nonstop
694 # after a restart
695 use vars qw($second_time);
696
697 sub _calc_usercontext {
698     my ($package) = @_;
699
700     # Cancel strict completely for the evaluated code, so the code
701     # the user evaluates won't be affected by it. (Shlomi Fish)
702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
703     . "package $package;";    # this won't let them modify, alas
704 }
705
706 sub eval {
707
708     # 'my' would make it visible from user code
709     #    but so does local! --tchrist
710     # Remember: this localizes @DB::res, not @main::res.
711     local @res;
712     {
713
714         # Try to keep the user code from messing  with us. Save these so that
715         # even if the eval'ed code changes them, we can put them back again.
716         # Needed because the user could refer directly to the debugger's
717         # package globals (and any 'my' variables in this containing scope)
718         # inside the eval(), and we want to try to stay safe.
719         local $otrace  = $trace;
720         local $osingle = $single;
721         local $od      = $^D;
722
723         # Untaint the incoming eval() argument.
724         { ($evalarg) = $evalarg =~ /(.*)/s; }
725
726         # $usercontext built in DB::DB near the comment
727         # "set up the context for DB::eval ..."
728         # Evaluate and save any results.
729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
730
731         # Restore those old values.
732         $trace  = $otrace;
733         $single = $osingle;
734         $^D     = $od;
735     }
736
737     # Save the current value of $@, and preserve it in the debugger's copy
738     # of the saved precious globals.
739     my $at = $@;
740
741     # Since we're only saving $@, we only have to localize the array element
742     # that it will be stored in.
743     local $saved[0];    # Preserve the old value of $@
744     eval { &DB::save };
745
746     # Now see whether we need to report an error back to the user.
747     if ($at) {
748         local $\ = '';
749         print $OUT $at;
750     }
751
752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
753     # are package globals.
754     elsif ($onetimeDump) {
755         if ( $onetimeDump eq 'dump' ) {
756             local $option{dumpDepth} = $onetimedumpDepth
757               if defined $onetimedumpDepth;
758             dumpit( $OUT, \@res );
759         }
760         elsif ( $onetimeDump eq 'methods' ) {
761             methods( $res[0] );
762         }
763     } ## end elsif ($onetimeDump)
764     @res;
765 } ## end sub eval
766
767 ############################################## End lexical danger zone
768
769 # After this point it is safe to introduce lexicals.
770 # The code being debugged will be executing in its own context, and
771 # can't see the inside of the debugger.
772 #
773 # However, one should not overdo it: leave as much control from outside as
774 # possible. If you make something a lexical, it's not going to be addressable
775 # from outside the debugger even if you know its name.
776
777 # This file is automatically included if you do perl -d.
778 # It's probably not useful to include this yourself.
779 #
780 # Before venturing further into these twisty passages, it is
781 # wise to read the perldebguts man page or risk the ire of dragons.
782 #
783 # (It should be noted that perldebguts will tell you a lot about
784 # the underlying mechanics of how the debugger interfaces into the
785 # Perl interpreter, but not a lot about the debugger itself. The new
786 # comments in this code try to address this problem.)
787
788 # Note that no subroutine call is possible until &DB::sub is defined
789 # (for subroutines defined outside of the package DB). In fact the same is
790 # true if $deep is not defined.
791
792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
793
794 # modified Perl debugger, to be run from Emacs in perldb-mode
795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
796 # Johan Vromans -- upgrade to 4.0 pl 10
797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
798 ########################################################################
799
800 =head1 DEBUGGER INITIALIZATION
801
802 The debugger starts up in phases.
803
804 =head2 BASIC SETUP
805
806 First, it initializes the environment it wants to run in: turning off
807 warnings during its own compilation, defining variables which it will need
808 to avoid warnings later, setting itself up to not exit when the program
809 terminates, and defaulting to printing return values for the C<r> command.
810
811 =cut
812
813 # Needed for the statement after exec():
814 #
815 # This BEGIN block is simply used to switch off warnings during debugger
816 # compilation. Probably it would be better practice to fix the warnings,
817 # but this is how it's done at the moment.
818
819 BEGIN {
820     $ini_warn = $^W;
821     $^W       = 0;
822 }    # Switch compilation warnings off until another BEGIN.
823
824 local ($^W) = 0;    # Switch run-time warnings off during init.
825
826 =head2 THREADS SUPPORT
827
828 If we are running under a threaded Perl, we require threads and threads::shared
829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
830 threaded debugger control.  C<-dt> can also be used to set this.
831
832 Each new thread will be announced and the debugger prompt will always inform
833 you of each new thread created.  It will also indicate the thread id in which
834 we are currently running within the prompt like this:
835
836         [tid] DB<$i>
837
838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
839 command prompt.  The prompt will show: C<[0]> when running under threads, but
840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
841
842 While running under threads, when you set or delete a breakpoint (etc.), this
843 will apply to all threads, not just the currently running one.  When you are
844 in a currently executing thread, you will stay there until it completes.  With
845 the current implementation it is not currently possible to hop from one thread
846 to another.
847
848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
849
850 Note that threading support was built into the debugger as of Perl version
851 C<5.8.6> and debugger version C<1.2.8>.
852
853 =cut
854
855 BEGIN {
856   # ensure we can share our non-threaded variables or no-op
857   if ($ENV{PERL5DB_THREADED}) {
858         require threads;
859         require threads::shared;
860         import threads::shared qw(share);
861         $DBGR;
862         share(\$DBGR);
863         lock($DBGR);
864         print "Threads support enabled\n";
865   } else {
866         *lock  = sub(*) {};
867         *share = sub(*) {};
868   }
869 }
870
871 # These variables control the execution of 'dumpvar.pl'.
872 {
873     package dumpvar;
874     use vars qw(
875     $hashDepth
876     $arrayDepth
877     $dumpDBFiles
878     $dumpPackages
879     $quoteHighBit
880     $printUndef
881     $globPrint
882     $usageOnly
883     );
884 }
885
886 # used to control die() reporting in diesignal()
887 {
888     package Carp;
889     use vars qw($CarpLevel);
890 }
891
892 # without threads, $filename is not defined until DB::DB is called
893 foreach my $k (keys (%INC)) {
894         share(\$main::{'_<'.$filename}) if defined $filename;
895 };
896
897 # Command-line + PERLLIB:
898 # Save the contents of @INC before they are modified elsewhere.
899 @ini_INC = @INC;
900
901 # This was an attempt to clear out the previous values of various
902 # trapped errors. Apparently it didn't help. XXX More info needed!
903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
904
905 # We set these variables to safe values. We don't want to blindly turn
906 # off warnings, because other packages may still want them.
907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
908                                    # (local $^W cannot help - other packages!).
909
910 # Default to not exiting when program finishes; print the return
911 # value when the 'r' command is used to return from a subroutine.
912 $inhibit_exit = $option{PrintRet} = 1;
913
914 use vars qw($trace_to_depth);
915
916 # Default to 1E9 so it won't be limited to a certain recursion depth.
917 $trace_to_depth = 1E9;
918
919 =head1 OPTION PROCESSING
920
921 The debugger's options are actually spread out over the debugger itself and
922 C<dumpvar.pl>; some of these are variables to be set, while others are
923 subs to be called with a value. To try to make this a little easier to
924 manage, the debugger uses a few data structures to define what options
925 are legal and how they are to be processed.
926
927 First, the C<@options> array defines the I<names> of all the options that
928 are to be accepted.
929
930 =cut
931
932 @options = qw(
933   CommandSet   HistFile      HistSize
934   hashDepth    arrayDepth    dumpDepth
935   DumpDBFiles  DumpPackages  DumpReused
936   compactDump  veryCompact   quote
937   HighBit      undefPrint    globPrint
938   PrintRet     UsageOnly     frame
939   AutoTrace    TTY           noTTY
940   ReadLine     NonStop       LineInfo
941   maxTraceLen  recallCommand ShellBang
942   pager        tkRunning     ornaments
943   signalLevel  warnLevel     dieLevel
944   inhibit_exit ImmediateStop bareStringify
945   CreateTTY    RemotePort    windowSize
946   DollarCaretP
947 );
948
949 @RememberOnROptions = qw(DollarCaretP);
950
951 =pod
952
953 Second, C<optionVars> lists the variables that each option uses to save its
954 state.
955
956 =cut
957
958 use vars qw(%optionVars);
959
960 %optionVars = (
961     hashDepth     => \$dumpvar::hashDepth,
962     arrayDepth    => \$dumpvar::arrayDepth,
963     CommandSet    => \$CommandSet,
964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
965     DumpPackages  => \$dumpvar::dumpPackages,
966     DumpReused    => \$dumpvar::dumpReused,
967     HighBit       => \$dumpvar::quoteHighBit,
968     undefPrint    => \$dumpvar::printUndef,
969     globPrint     => \$dumpvar::globPrint,
970     UsageOnly     => \$dumpvar::usageOnly,
971     CreateTTY     => \$CreateTTY,
972     bareStringify => \$dumpvar::bareStringify,
973     frame         => \$frame,
974     AutoTrace     => \$trace,
975     inhibit_exit  => \$inhibit_exit,
976     maxTraceLen   => \$maxtrace,
977     ImmediateStop => \$ImmediateStop,
978     RemotePort    => \$remoteport,
979     windowSize    => \$window,
980     HistFile      => \$histfile,
981     HistSize      => \$histsize,
982 );
983
984 =pod
985
986 Third, C<%optionAction> defines the subroutine to be called to process each
987 option.
988
989 =cut
990
991 use vars qw(%optionAction);
992
993 %optionAction = (
994     compactDump   => \&dumpvar::compactDump,
995     veryCompact   => \&dumpvar::veryCompact,
996     quote         => \&dumpvar::quote,
997     TTY           => \&TTY,
998     noTTY         => \&noTTY,
999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 use vars qw($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(@hist @truehist %postponed_file @typeahead);
1381
1382 sub _restore_shared_globals_after_restart
1383 {
1384     @hist          = get_list('PERLDB_HIST');
1385     %break_on_load = get_list("PERLDB_ON_LOAD");
1386     %postponed     = get_list("PERLDB_POSTPONE");
1387
1388     share(@hist);
1389     share(@truehist);
1390     share(%break_on_load);
1391     share(%postponed);
1392 }
1393
1394 sub _restore_breakpoints_and_actions {
1395
1396     my @had_breakpoints = get_list("PERLDB_VISITED");
1397
1398     for my $file_idx ( 0 .. $#had_breakpoints ) {
1399         my $filename = $had_breakpoints[$file_idx];
1400         my %pf = get_list("PERLDB_FILE_$file_idx");
1401         $postponed_file{ $filename } = \%pf if %pf;
1402         my @lines = sort {$a <=> $b} keys(%pf);
1403         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1404         for my $line_idx (0 .. $#lines) {
1405             _set_breakpoint_enabled_status(
1406                 $filename,
1407                 $lines[$line_idx],
1408                 ($enabled_statuses[$line_idx] ? 1 : ''),
1409             );
1410         }
1411     }
1412
1413     return;
1414 }
1415
1416 sub _restore_options_after_restart
1417 {
1418     my %options_map = get_list("PERLDB_OPT");
1419
1420     while ( my ( $opt, $val ) = each %options_map ) {
1421         $val =~ s/[\\\']/\\$1/g;
1422         parse_options("$opt'$val'");
1423     }
1424
1425     return;
1426 }
1427
1428 sub _restore_globals_after_restart
1429 {
1430     # restore original @INC
1431     @INC     = get_list("PERLDB_INC");
1432     @ini_INC = @INC;
1433
1434     # return pre/postprompt actions and typeahead buffer
1435     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1436     $pre       = [ get_list("PERLDB_PRE") ];
1437     $post      = [ get_list("PERLDB_POST") ];
1438     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1439
1440     return;
1441 }
1442
1443
1444 if ( exists $ENV{PERLDB_RESTART} ) {
1445
1446     # We're restarting, so we don't need the flag that says to restart anymore.
1447     delete $ENV{PERLDB_RESTART};
1448
1449     # $restart = 1;
1450     _restore_shared_globals_after_restart();
1451
1452     _restore_breakpoints_and_actions();
1453
1454     # restore options
1455     _restore_options_after_restart();
1456
1457     _restore_globals_after_restart();
1458 } ## end if (exists $ENV{PERLDB_RESTART...
1459
1460 =head2 SETTING UP THE TERMINAL
1461
1462 Now, we'll decide how the debugger is going to interact with the user.
1463 If there's no TTY, we set the debugger to run non-stop; there's not going
1464 to be anyone there to enter commands.
1465
1466 =cut
1467
1468 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1469 use vars qw($lineinfo $doccmd);
1470
1471 if ($notty) {
1472     $runnonstop = 1;
1473         share($runnonstop);
1474 }
1475
1476 =pod
1477
1478 If there is a TTY, we have to determine who it belongs to before we can
1479 proceed. If this is a slave editor or graphical debugger (denoted by
1480 the first command-line switch being '-emacs'), we shift this off and
1481 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1482
1483 =cut
1484
1485 else {
1486
1487     # Is Perl being run from a slave editor or graphical debugger?
1488     # If so, don't use readline, and set $slave_editor = 1.
1489     $slave_editor =
1490       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1491     $rl = 0, shift(@main::ARGV) if $slave_editor;
1492
1493     #require Term::ReadLine;
1494
1495 =pod
1496
1497 We then determine what the console should be on various systems:
1498
1499 =over 4
1500
1501 =item * Cygwin - We use C<stdin> instead of a separate device.
1502
1503 =cut
1504
1505     if ( $^O eq 'cygwin' ) {
1506
1507         # /dev/tty is binary. use stdin for textmode
1508         undef $console;
1509     }
1510
1511 =item * Unix - use C</dev/tty>.
1512
1513 =cut
1514
1515     elsif ( -e "/dev/tty" ) {
1516         $console = "/dev/tty";
1517     }
1518
1519 =item * Windows or MSDOS - use C<con>.
1520
1521 =cut
1522
1523     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1524         $console = "con";
1525     }
1526
1527 =item * VMS - use C<sys$command>.
1528
1529 =cut
1530
1531     else {
1532
1533         # everything else is ...
1534         $console = "sys\$command";
1535     }
1536
1537 =pod
1538
1539 =back
1540
1541 Several other systems don't use a specific console. We C<undef $console>
1542 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1543 with a slave editor, Epoc).
1544
1545 =cut
1546
1547     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1548
1549         # /dev/tty is binary. use stdin for textmode
1550         $console = undef;
1551     }
1552
1553     if ( $^O eq 'NetWare' ) {
1554
1555         # /dev/tty is binary. use stdin for textmode
1556         $console = undef;
1557     }
1558
1559     # In OS/2, we need to use STDIN to get textmode too, even though
1560     # it pretty much looks like Unix otherwise.
1561     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1562     {    # In OS/2
1563         $console = undef;
1564     }
1565
1566     # EPOC also falls into the 'got to use STDIN' camp.
1567     if ( $^O eq 'epoc' ) {
1568         $console = undef;
1569     }
1570
1571 =pod
1572
1573 If there is a TTY hanging around from a parent, we use that as the console.
1574
1575 =cut
1576
1577     $console = $tty if defined $tty;
1578
1579 =head2 SOCKET HANDLING
1580
1581 The debugger is capable of opening a socket and carrying out a debugging
1582 session over the socket.
1583
1584 If C<RemotePort> was defined in the options, the debugger assumes that it
1585 should try to start a debugging session on that port. It builds the socket
1586 and then tries to connect the input and output filehandles to it.
1587
1588 =cut
1589
1590     # Handle socket stuff.
1591
1592     if ( defined $remoteport ) {
1593
1594         # If RemotePort was defined in the options, connect input and output
1595         # to the socket.
1596         $IN = $OUT = connect_remoteport();
1597     } ## end if (defined $remoteport)
1598
1599 =pod
1600
1601 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1602 this is probably a situation where multiple debuggers are running (for example,
1603 a backticked command that starts up another debugger). We create a new IN and
1604 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1605 and if we can.
1606
1607 =cut
1608
1609     # Non-socket.
1610     else {
1611
1612         # Two debuggers running (probably a system or a backtick that invokes
1613         # the debugger itself under the running one). create a new IN and OUT
1614         # filehandle, and do the necessary mojo to create a new tty if we
1615         # know how, and we can.
1616         create_IN_OUT(4) if $CreateTTY & 4;
1617         if ($console) {
1618
1619             # If we have a console, check to see if there are separate ins and
1620             # outs to open. (They are assumed identical if not.)
1621
1622             my ( $i, $o ) = split /,/, $console;
1623             $o = $i unless defined $o;
1624
1625             # read/write on in, or just read, or read on STDIN.
1626             open( IN,      "+<$i" )
1627               || open( IN, "<$i" )
1628               || open( IN, "<&STDIN" );
1629
1630             # read/write/create/clobber out, or write/create/clobber out,
1631             # or merge with STDERR, or merge with STDOUT.
1632                  open( OUT, "+>$o" )
1633               || open( OUT, ">$o" )
1634               || open( OUT, ">&STDERR" )
1635               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1636
1637         } ## end if ($console)
1638         elsif ( not defined $console ) {
1639
1640             # No console. Open STDIN.
1641             open( IN, "<&STDIN" );
1642
1643             # merge with STDERR, or with STDOUT.
1644             open( OUT,      ">&STDERR" )
1645               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1646             $console = 'STDIN/OUT';
1647         } ## end elsif (not defined $console)
1648
1649         # Keep copies of the filehandles so that when the pager runs, it
1650         # can close standard input without clobbering ours.
1651         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1652     } ## end elsif (from if(defined $remoteport))
1653
1654     # Unbuffer DB::OUT. We need to see responses right away.
1655     $OUT->autoflush(1);
1656
1657     # Line info goes to debugger output unless pointed elsewhere.
1658     # Pointing elsewhere makes it possible for slave editors to
1659     # keep track of file and position. We have both a filehandle
1660     # and a I/O description to keep track of.
1661     $LINEINFO = $OUT     unless defined $LINEINFO;
1662     $lineinfo = $console unless defined $lineinfo;
1663         # share($LINEINFO); # <- unable to share globs
1664         share($lineinfo);   #
1665
1666 =pod
1667
1668 To finish initialization, we show the debugger greeting,
1669 and then call the C<afterinit()> subroutine if there is one.
1670
1671 =cut
1672
1673     # Show the debugger greeting.
1674     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1675     unless ($runnonstop) {
1676         local $\ = '';
1677         local $, = '';
1678         if ( $term_pid eq '-1' ) {
1679             print $OUT "\nDaughter DB session started...\n";
1680         }
1681         else {
1682             print $OUT "\nLoading DB routines from $header\n";
1683             print $OUT (
1684                 "Editor support ",
1685                 $slave_editor ? "enabled" : "available", ".\n"
1686             );
1687             print $OUT
1688 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1689         } ## end else [ if ($term_pid eq '-1')
1690     } ## end unless ($runnonstop)
1691 } ## end else [ if ($notty)
1692
1693 # XXX This looks like a bug to me.
1694 # Why copy to @ARGS and then futz with @args?
1695 @ARGS = @ARGV;
1696 # for (@args) {
1697     # Make sure backslashes before single quotes are stripped out, and
1698     # keep args unless they are numeric (XXX why?)
1699     # s/\'/\\\'/g;                      # removed while not justified understandably
1700     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1701 # }
1702
1703 # If there was an afterinit() sub defined, call it. It will get
1704 # executed in our scope, so it can fiddle with debugger globals.
1705 if ( defined &afterinit ) {    # May be defined in $rcfile
1706     &afterinit();
1707 }
1708
1709 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1710 use vars qw($I_m_init);
1711
1712 $I_m_init = 1;
1713
1714 ############################################################ Subroutines
1715
1716 =head1 SUBROUTINES
1717
1718 =head2 DB
1719
1720 This gigantic subroutine is the heart of the debugger. Called before every
1721 statement, its job is to determine if a breakpoint has been reached, and
1722 stop if so; read commands from the user, parse them, and execute
1723 them, and then send execution off to the next statement.
1724
1725 Note that the order in which the commands are processed is very important;
1726 some commands earlier in the loop will actually alter the C<$cmd> variable
1727 to create other commands to be executed later. This is all highly I<optimized>
1728 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1729 see what's happening in any given command.
1730
1731 =cut
1732
1733 use vars qw(
1734     $action
1735     %alias
1736     $cmd
1737     $doret
1738     $fall_off_end
1739     $file
1740     $filename_ini
1741     $finished
1742     %had_breakpoints
1743     $incr
1744     $laststep
1745     $level
1746     $max
1747     @old_watch
1748     $package
1749     $rc
1750     $sh
1751     @stack
1752     $stack_depth
1753     @to_watch
1754     $try
1755     $end
1756 );
1757
1758 sub DB {
1759
1760     # lock the debugger and get the thread id for the prompt
1761         lock($DBGR);
1762         my $tid;
1763         my $position;
1764         my ($prefix, $after, $infix);
1765         my $pat;
1766
1767         if ($ENV{PERL5DB_THREADED}) {
1768                 $tid = eval { "[".threads->tid."]" };
1769         }
1770
1771     # Check for whether we should be running continuously or not.
1772     # _After_ the perl program is compiled, $single is set to 1:
1773     if ( $single and not $second_time++ ) {
1774
1775         # Options say run non-stop. Run until we get an interrupt.
1776         if ($runnonstop) {    # Disable until signal
1777                 # If there's any call stack in place, turn off single
1778                 # stepping into subs throughout the stack.
1779             for my $i (0 .. $stack_depth) {
1780                 $stack[ $i ] &= ~1;
1781             }
1782
1783             # And we are now no longer in single-step mode.
1784             $single = 0;
1785
1786             # If we simply returned at this point, we wouldn't get
1787             # the trace info. Fall on through.
1788             # return;
1789         } ## end if ($runnonstop)
1790
1791         elsif ($ImmediateStop) {
1792
1793             # We are supposed to stop here; XXX probably a break.
1794             $ImmediateStop = 0;    # We've processed it; turn it off
1795             $signal        = 1;    # Simulate an interrupt to force
1796                                    # us into the command loop
1797         }
1798     } ## end if ($single and not $second_time...
1799
1800     # If we're in single-step mode, or an interrupt (real or fake)
1801     # has occurred, turn off non-stop mode.
1802     $runnonstop = 0 if $single or $signal;
1803
1804     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1805     # The code being debugged may have altered them.
1806     &save;
1807
1808     # Since DB::DB gets called after every line, we can use caller() to
1809     # figure out where we last were executing. Sneaky, eh? This works because
1810     # caller is returning all the extra information when called from the
1811     # debugger.
1812     local ( $package, $filename, $line ) = caller;
1813     $filename_ini = $filename;
1814
1815     # set up the context for DB::eval, so it can properly execute
1816     # code on behalf of the user. We add the package in so that the
1817     # code is eval'ed in the proper package (not in the debugger!).
1818     local $usercontext = _calc_usercontext($package);
1819
1820     # Create an alias to the active file magical array to simplify
1821     # the code here.
1822     local (*dbline) = $main::{ '_<' . $filename };
1823
1824     # Last line in the program.
1825     $max = $#dbline;
1826
1827     # if we have something here, see if we should break.
1828     {
1829         # $stop is lexical and local to this block - $action on the other hand
1830         # is global.
1831         my $stop;
1832
1833         if ( $dbline{$line}
1834             && _is_breakpoint_enabled($filename, $line)
1835             && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1836         {
1837
1838             # Stop if the stop criterion says to just stop.
1839             if ( $stop eq '1' ) {
1840                 $signal |= 1;
1841             }
1842
1843             # It's a conditional stop; eval it in the user's context and
1844             # see if we should stop. If so, remove the one-time sigil.
1845             elsif ($stop) {
1846                 $evalarg = "\$DB::signal |= 1 if do {$stop}";
1847                 &eval;
1848                 # If the breakpoint is temporary, then delete its enabled status.
1849                 if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1850                     _cancel_breakpoint_temp_enabled_status($filename, $line);
1851                 }
1852             }
1853         } ## end if ($dbline{$line} && ...
1854     }
1855
1856     # Preserve the current stop-or-not, and see if any of the W
1857     # (watch expressions) has changed.
1858     my $was_signal = $signal;
1859
1860     # If we have any watch expressions ...
1861     if ( $trace & 2 ) {
1862         for my $n (0 .. $#to_watch) {
1863             $evalarg = $to_watch[$n];
1864             local $onetimeDump;    # Tell DB::eval() to not output results
1865
1866             # Fix context DB::eval() wants to return an array, but
1867             # we need a scalar here.
1868             my ($val) = join( "', '", &eval );
1869             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1870
1871             # Did it change?
1872             if ( $val ne $old_watch[$n] ) {
1873
1874                 # Yep! Show the difference, and fake an interrupt.
1875                 $signal = 1;
1876                 print $OUT <<EOP;
1877 Watchpoint $n:\t$to_watch[$n] changed:
1878     old value:\t$old_watch[$n]
1879     new value:\t$val
1880 EOP
1881                 $old_watch[$n] = $val;
1882             } ## end if ($val ne $old_watch...
1883         } ## end for my $n (0 ..
1884     } ## end if ($trace & 2)
1885
1886 =head2 C<watchfunction()>
1887
1888 C<watchfunction()> is a function that can be defined by the user; it is a
1889 function which will be run on each entry to C<DB::DB>; it gets the
1890 current package, filename, and line as its parameters.
1891
1892 The watchfunction can do anything it likes; it is executing in the
1893 debugger's context, so it has access to all of the debugger's internal
1894 data structures and functions.
1895
1896 C<watchfunction()> can control the debugger's actions. Any of the following
1897 will cause the debugger to return control to the user's program after
1898 C<watchfunction()> executes:
1899
1900 =over 4
1901
1902 =item *
1903
1904 Returning a false value from the C<watchfunction()> itself.
1905
1906 =item *
1907
1908 Altering C<$single> to a false value.
1909
1910 =item *
1911
1912 Altering C<$signal> to a false value.
1913
1914 =item *
1915
1916 Turning off the C<4> bit in C<$trace> (this also disables the
1917 check for C<watchfunction()>. This can be done with
1918
1919     $trace &= ~4;
1920
1921 =back
1922
1923 =cut
1924
1925     # If there's a user-defined DB::watchfunction, call it with the
1926     # current package, filename, and line. The function executes in
1927     # the DB:: package.
1928     if ( $trace & 4 ) {    # User-installed watch
1929         return
1930           if watchfunction( $package, $filename, $line )
1931           and not $single
1932           and not $was_signal
1933           and not( $trace & ~4 );
1934     } ## end if ($trace & 4)
1935
1936     # Pick up any alteration to $signal in the watchfunction, and
1937     # turn off the signal now.
1938     $was_signal = $signal;
1939     $signal     = 0;
1940
1941 =head2 GETTING READY TO EXECUTE COMMANDS
1942
1943 The debugger decides to take control if single-step mode is on, the
1944 C<t> command was entered, or the user generated a signal. If the program
1945 has fallen off the end, we set things up so that entering further commands
1946 won't cause trouble, and we say that the program is over.
1947
1948 =cut
1949
1950     # Make sure that we always print if asked for explicitly regardless
1951     # of $trace_to_depth .
1952     my $explicit_stop = ($single || $was_signal);
1953
1954     # Check to see if we should grab control ($single true,
1955     # trace set appropriately, or we got a signal).
1956     if ( $explicit_stop || ( $trace & 1 ) ) {
1957
1958         # Yes, grab control.
1959         if ($slave_editor) {
1960
1961             # Tell the editor to update its position.
1962             $position = "\032\032$filename:$line:0\n";
1963             print_lineinfo($position);
1964         }
1965
1966 =pod
1967
1968 Special check: if we're in package C<DB::fake>, we've gone through the
1969 C<END> block at least once. We set up everything so that we can continue
1970 to enter commands and have a valid context to be in.
1971
1972 =cut
1973
1974         elsif ( $package eq 'DB::fake' ) {
1975
1976             # Fallen off the end already.
1977             $term || &setterm;
1978             print_help(<<EOP);
1979 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1980   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1981   B<h q>, B<h R> or B<h o> to get additional info.
1982 EOP
1983
1984             # Set the DB::eval context appropriately.
1985             $package     = 'main';
1986             $usercontext = _calc_usercontext($package);
1987         } ## end elsif ($package eq 'DB::fake')
1988
1989 =pod
1990
1991 If the program hasn't finished executing, we scan forward to the
1992 next executable line, print that out, build the prompt from the file and line
1993 number information, and print that.
1994
1995 =cut
1996
1997         else {
1998
1999
2000             # Still somewhere in the midst of execution. Set up the
2001             #  debugger prompt.
2002             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2003                                  # Perl 5 ones (sorry, we don't print Klingon
2004                                  #module names)
2005
2006             $prefix = $sub =~ /::/ ? "" : ($package . '::');
2007             $prefix .= "$sub($filename:";
2008             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2009
2010             # Break up the prompt if it's really long.
2011             if ( length($prefix) > 30 ) {
2012                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2013                 $prefix   = "";
2014                 $infix    = ":\t";
2015             }
2016             else {
2017                 $infix    = "):\t";
2018                 $position = "$prefix$line$infix$dbline[$line]$after";
2019             }
2020
2021             # Print current line info, indenting if necessary.
2022             if ($frame) {
2023                 print_lineinfo( ' ' x $stack_depth,
2024                     "$line:\t$dbline[$line]$after" );
2025             }
2026             else {
2027                 depth_print_lineinfo($explicit_stop, $position);
2028             }
2029
2030             # Scan forward, stopping at either the end or the next
2031             # unbreakable line.
2032             for ( my $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2033             {    #{ vi
2034
2035                 # Drop out on null statements, block closers, and comments.
2036                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2037
2038                 # Drop out if the user interrupted us.
2039                 last if $signal;
2040
2041                 # Append a newline if the line doesn't have one. Can happen
2042                 # in eval'ed text, for instance.
2043                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2044
2045                 # Next executable line.
2046                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2047                 $position .= $incr_pos;
2048                 if ($frame) {
2049
2050                     # Print it indented if tracing is on.
2051                     print_lineinfo( ' ' x $stack_depth,
2052                         "$i:\t$dbline[$i]$after" );
2053                 }
2054                 else {
2055                     depth_print_lineinfo($explicit_stop, $incr_pos);
2056                 }
2057             } ## end for ($i = $line + 1 ; $i...
2058         } ## end else [ if ($slave_editor)
2059     } ## end if ($single || ($trace...
2060
2061 =pod
2062
2063 If there's an action to be executed for the line we stopped at, execute it.
2064 If there are any preprompt actions, execute those as well.
2065
2066 =cut
2067
2068     # If there's an action, do it now.
2069     $evalarg = $action, &eval if $action;
2070
2071     # Are we nested another level (e.g., did we evaluate a function
2072     # that had a breakpoint in it at the debugger prompt)?
2073     if ( $single || $was_signal ) {
2074
2075         # Yes, go down a level.
2076         local $level = $level + 1;
2077
2078         # Do any pre-prompt actions.
2079         foreach $evalarg (@$pre) {
2080             &eval;
2081         }
2082
2083         # Complain about too much recursion if we passed the limit.
2084         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2085           if $single & 4;
2086
2087         # The line we're currently on. Set $incr to -1 to stay here
2088         # until we get a command that tells us to advance.
2089         $start = $line;
2090         $incr  = -1;      # for backward motion.
2091
2092         # Tack preprompt debugger actions ahead of any actual input.
2093         @typeahead = ( @$pretype, @typeahead );
2094
2095 =head2 WHERE ARE WE?
2096
2097 XXX Relocate this section?
2098
2099 The debugger normally shows the line corresponding to the current line of
2100 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2101 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2102
2103 C<$incr> controls by how many lines the I<current> line should move forward
2104 after a command is executed. If set to -1, this indicates that the I<current>
2105 line shouldn't change.
2106
2107 C<$start> is the I<current> line. It is used for things like knowing where to
2108 move forwards or backwards from when doing an C<L> or C<-> command.
2109
2110 C<$max> tells the debugger where the last line of the current file is. It's
2111 used to terminate loops most often.
2112
2113 =head2 THE COMMAND LOOP
2114
2115 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2116 in two parts:
2117
2118 =over 4
2119
2120 =item *
2121
2122 The outer part of the loop, starting at the C<CMD> label. This loop
2123 reads a command and then executes it.
2124
2125 =item *
2126
2127 The inner part of the loop, starting at the C<PIPE> label. This part
2128 is wholly contained inside the C<CMD> block and only executes a command.
2129 Used to handle commands running inside a pager.
2130
2131 =back
2132
2133 So why have two labels to restart the loop? Because sometimes, it's easier to
2134 have a command I<generate> another command and then re-execute the loop to do
2135 the new command. This is faster, but perhaps a bit more convoluted.
2136
2137 =cut
2138
2139         # The big command dispatch loop. It keeps running until the
2140         # user yields up control again.
2141         #
2142         # If we have a terminal for input, and we get something back
2143         # from readline(), keep on processing.
2144         my $piped;
2145         my $selected;
2146
2147       CMD:
2148         while (
2149
2150             # We have a terminal, or can get one ...
2151             ( $term || &setterm ),
2152
2153             # ... and it belogs to this PID or we get one for this PID ...
2154             ( $term_pid == $$ or resetterm(1) ),
2155
2156             # ... and we got a line of command input ...
2157             defined(
2158                 $cmd = &readline(
2159                         "$pidprompt $tid DB"
2160                       . ( '<' x $level )
2161                       . ( $#hist + 1 )
2162                       . ( '>' x $level ) . " "
2163                 )
2164             )
2165           )
2166         {
2167
2168                         share($cmd);
2169             # ... try to execute the input as debugger commands.
2170
2171             # Don't stop running.
2172             $single = 0;
2173
2174             # No signal is active.
2175             $signal = 0;
2176
2177             # Handle continued commands (ending with \):
2178             if ($cmd =~ s/\\\z/\n/) {
2179                 $cmd .= &readline("  cont: ");
2180                 redo CMD;
2181             }
2182
2183 =head4 The null command
2184
2185 A newline entered by itself means I<re-execute the last command>. We grab the
2186 command out of C<$laststep> (where it was recorded previously), and copy it
2187 back into C<$cmd> to be executed below. If there wasn't any previous command,
2188 we'll do nothing below (no command will match). If there was, we also save it
2189 in the command history and fall through to allow the command parsing to pick
2190 it up.
2191
2192 =cut
2193
2194             # Empty input means repeat the last command.
2195             $cmd =~ /^$/ && ( $cmd = $laststep );
2196             chomp($cmd);    # get rid of the annoying extra newline
2197             push( @hist, $cmd ) if length($cmd) > 1;
2198             push( @truehist, $cmd );
2199                         share(@hist);
2200                         share(@truehist);
2201
2202             # This is a restart point for commands that didn't arrive
2203             # via direct user input. It allows us to 'redo PIPE' to
2204             # re-execute command processing without reading a new command.
2205           PIPE: {
2206                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2207                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2208                 my ($i) = split( /\s+/, $cmd );
2209
2210 =head3 COMMAND ALIASES
2211
2212 The debugger can create aliases for commands (these are stored in the
2213 C<%alias> hash). Before a command is executed, the command loop looks it up
2214 in the alias hash and substitutes the contents of the alias for the command,
2215 completely replacing it.
2216
2217 =cut
2218
2219                 # See if there's an alias for the command, and set it up if so.
2220                 if ( $alias{$i} ) {
2221
2222                     # Squelch signal handling; we want to keep control here
2223                     # if something goes loco during the alias eval.
2224                     local $SIG{__DIE__};
2225                     local $SIG{__WARN__};
2226
2227                     # This is a command, so we eval it in the DEBUGGER's
2228                     # scope! Otherwise, we can't see the special debugger
2229                     # variables, or get to the debugger's subs. (Well, we
2230                     # _could_, but why make it even more complicated?)
2231                     eval "\$cmd =~ $alias{$i}";
2232                     if ($@) {
2233                         local $\ = '';
2234                         print $OUT "Couldn't evaluate '$i' alias: $@";
2235                         next CMD;
2236                     }
2237                 } ## end if ($alias{$i})
2238
2239 =head3 MAIN-LINE COMMANDS
2240
2241 All of these commands work up to and after the program being debugged has
2242 terminated.
2243
2244 =head4 C<q> - quit
2245
2246 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2247 try to execute further, cleaning any restart-related stuff out of the
2248 environment, and executing with the last value of C<$?>.
2249
2250 =cut
2251
2252                 if ($cmd eq 'q') {
2253                     $fall_off_end = 1;
2254                     clean_ENV();
2255                     exit $?;
2256                 }
2257
2258 =head4 C<t> - trace [n]
2259
2260 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2261 If level is specified, set C<$trace_to_depth>.
2262
2263 =cut
2264
2265                 if (my ($levels) = $cmd =~ /\At(?:\s+(\d+))?\z/) {
2266                     $trace ^= 1;
2267                     local $\ = '';
2268                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2269                     print $OUT "Trace = "
2270                       . ( ( $trace & 1 )
2271                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2272                       : "off" ) . "\n";
2273                     next CMD;
2274                 }
2275
2276 =head4 C<S> - list subroutines matching/not matching a pattern
2277
2278 Walks through C<%sub>, checking to see whether or not to print the name.
2279
2280 =cut
2281
2282                 if (my ($print_all_subs, $should_reverse, $Spatt)
2283                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2284                     # $Spatt is the pattern (if any) to use.
2285                     # Reverse scan?
2286                     my $Srev     = defined $should_reverse;
2287                     # No args - print all subs.
2288                     my $Snocheck = !defined $print_all_subs;
2289
2290                     # Need to make these sane here.
2291                     local $\ = '';
2292                     local $, = '';
2293
2294                     # Search through the debugger's magical hash of subs.
2295                     # If $nocheck is true, just print the sub name.
2296                     # Otherwise, check it against the pattern. We then use
2297                     # the XOR trick to reverse the condition as required.
2298                     foreach $subname ( sort( keys %sub ) ) {
2299                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2300                             print $OUT $subname, "\n";
2301                         }
2302                     }
2303                     next CMD;
2304                 }
2305
2306 =head4 C<X> - list variables in current package
2307
2308 Since the C<V> command actually processes this, just change this to the
2309 appropriate C<V> command and fall through.
2310
2311 =cut
2312
2313                 $cmd =~ s/^X\b/V $package/;
2314
2315 =head4 C<V> - list variables
2316
2317 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2318
2319 =cut
2320
2321                 # Bare V commands get the currently-being-debugged package
2322                 # added.
2323                 if ($cmd eq "V") {
2324                     $cmd = "V $package";
2325                 }
2326
2327                 # V - show variables in package.
2328                 if (my ($new_packname, $new_vars_str) =
2329                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2330
2331                     # Save the currently selected filehandle and
2332                     # force output to debugger's filehandle (dumpvar
2333                     # just does "print" for output).
2334                     my $savout = select($OUT);
2335
2336                     # Grab package name and variables to dump.
2337                     $packname = $new_packname;
2338                     my @vars     = split( ' ', $new_vars_str );
2339
2340                     # If main::dumpvar isn't here, get it.
2341                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2342                     if ( defined &main::dumpvar ) {
2343
2344                         # We got it. Turn off subroutine entry/exit messages
2345                         # for the moment, along with return values.
2346                         local $frame = 0;
2347                         local $doret = -2;
2348
2349                         # must detect sigpipe failures  - not catching
2350                         # then will cause the debugger to die.
2351                         eval {
2352                             &main::dumpvar(
2353                                 $packname,
2354                                 defined $option{dumpDepth}
2355                                 ? $option{dumpDepth}
2356                                 : -1,    # assume -1 unless specified
2357                                 @vars
2358                             );
2359                         };
2360
2361                         # The die doesn't need to include the $@, because
2362                         # it will automatically get propagated for us.
2363                         if ($@) {
2364                             die unless $@ =~ /dumpvar print failed/;
2365                         }
2366                     } ## end if (defined &main::dumpvar)
2367                     else {
2368
2369                         # Couldn't load dumpvar.
2370                         print $OUT "dumpvar.pl not available.\n";
2371                     }
2372
2373                     # Restore the output filehandle, and go round again.
2374                     select($savout);
2375                     next CMD;
2376                 }
2377
2378 =head4 C<x> - evaluate and print an expression
2379
2380 Hands the expression off to C<DB::eval>, setting it up to print the value
2381 via C<dumpvar.pl> instead of just printing it directly.
2382
2383 =cut
2384
2385                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2386                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2387
2388                     # handle special  "x 3 blah" syntax XXX propagate
2389                     # doc back to special variables.
2390                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2391                         $onetimedumpDepth = $1;
2392                     }
2393                 }
2394
2395 =head4 C<m> - print methods
2396
2397 Just uses C<DB::methods> to determine what methods are available.
2398
2399 =cut
2400
2401                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2402                     methods($1);
2403                     next CMD;
2404                 }
2405
2406                 # m expr - set up DB::eval to do the work
2407                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2408                     $onetimeDump = 'methods';   #  method output gets used there
2409                 }
2410
2411 =head4 C<f> - switch files
2412
2413 =cut
2414
2415                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2416                     $file =~ s/\s+$//;
2417
2418                     # help for no arguments (old-style was return from sub).
2419                     if ( !$file ) {
2420                         print $OUT
2421                           "The old f command is now the r command.\n";    # hint
2422                         print $OUT "The new f command switches filenames.\n";
2423                         next CMD;
2424                     } ## end if (!$file)
2425
2426                     # if not in magic file list, try a close match.
2427                     if ( !defined $main::{ '_<' . $file } ) {
2428                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2429                             {
2430                                 $try = substr( $try, 2 );
2431                                 print $OUT "Choosing $try matching '$file':\n";
2432                                 $file = $try;
2433                             }
2434                         } ## end if (($try) = grep(m#^_<.*$file#...
2435                     } ## end if (!defined $main::{ ...
2436
2437                     # If not successfully switched now, we failed.
2438                     if ( !defined $main::{ '_<' . $file } ) {
2439                         print $OUT "No file matching '$file' is loaded.\n";
2440                         next CMD;
2441                     }
2442
2443                     # We switched, so switch the debugger internals around.
2444                     elsif ( $file ne $filename ) {
2445                         *dbline   = $main::{ '_<' . $file };
2446                         $max      = $#dbline;
2447                         $filename = $file;
2448                         $start    = 1;
2449                         $cmd      = "l";
2450                     } ## end elsif ($file ne $filename)
2451
2452                     # We didn't switch; say we didn't.
2453                     else {
2454                         print $OUT "Already in $file.\n";
2455                         next CMD;
2456                     }
2457                 }
2458
2459 =head4 C<.> - return to last-executed line.
2460
2461 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2462 and then we look up the line in the magical C<%dbline> hash.
2463
2464 =cut
2465
2466                 # . command.
2467                 if ($cmd eq '.') {
2468                     $incr = -1;    # stay at current line
2469
2470                     # Reset everything to the old location.
2471                     $start    = $line;
2472                     $filename = $filename_ini;
2473                     *dbline   = $main::{ '_<' . $filename };
2474                     $max      = $#dbline;
2475
2476                     # Now where are we?
2477                     print_lineinfo($position);
2478                     next CMD;
2479                 }
2480
2481 =head4 C<-> - back one window
2482
2483 We change C<$start> to be one window back; if we go back past the first line,
2484 we set it to be the first line. We ser C<$incr> to put us back at the
2485 currently-executing line, and then put a C<l $start +> (list one window from
2486 C<$start>) in C<$cmd> to be executed later.
2487
2488 =cut
2489
2490                 # - - back a window.
2491                 if ($cmd eq '-') {
2492
2493                     # back up by a window; go to 1 if back too far.
2494                     $start -= $incr + $window + 1;
2495                     $start = 1 if $start <= 0;
2496                     $incr  = $window - 1;
2497
2498                     # Generate and execute a "l +" command (handled below).
2499                     $cmd = 'l ' . ($start) . '+';
2500                 }
2501
2502 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2503
2504 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2505 problems, most notably that the default case of several commands destroying
2506 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2507 retain the old commands for those who were used to using them or who preferred
2508 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2509 deal with them instead of processing them in-line.
2510
2511 =cut
2512
2513                 # All of these commands were remapped in perl 5.8.0;
2514                 # we send them off to the secondary dispatcher (see below).
2515                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2516                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2517                     next CMD;
2518                 }
2519
2520 =head4 C<y> - List lexicals in higher scope
2521
2522 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2523 above the current one and then displays then using C<dumpvar.pl>.
2524
2525 =cut
2526
2527                 if (my ($match_level, $match_vars)
2528                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2529
2530                     # See if we've got the necessary support.
2531                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2532                       or &warn(
2533                         $@ =~ /locate/
2534                         ? "PadWalker module not found - please install\n"
2535                         : $@
2536                       )
2537                       and next CMD;
2538
2539                     # Load up dumpvar if we don't have it. If we can, that is.
2540                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2541                     defined &main::dumpvar
2542                       or print $OUT "dumpvar.pl not available.\n"
2543                       and next CMD;
2544
2545                     # Got all the modules we need. Find them and print them.
2546                     my @vars = split( ' ', $match_vars || '' );
2547
2548                     # Find the pad.
2549                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2550
2551                     # Oops. Can't find it.
2552                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2553
2554                     # Show the desired vars with dumplex().
2555                     my $savout = select($OUT);
2556
2557                     # Have dumplex dump the lexicals.
2558                     dumpvar::dumplex( $_, $h->{$_},
2559                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2560                         @vars )
2561                       for sort keys %$h;
2562                     select($savout);
2563                     next CMD;
2564                 }
2565
2566 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2567
2568 All of the commands below this point don't work after the program being
2569 debugged has ended. All of them check to see if the program has ended; this
2570 allows the commands to be relocated without worrying about a 'line of
2571 demarcation' above which commands can be entered anytime, and below which
2572 they can't.
2573
2574 =head4 C<n> - single step, but don't trace down into subs
2575
2576 Done by setting C<$single> to 2, which forces subs to execute straight through
2577 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2578 so a null command knows what to re-execute.
2579
2580 =cut
2581
2582                 # n - next
2583                 if ($cmd eq 'n') {
2584                     end_report(), next CMD if $finished and $level <= 1;
2585
2586                     # Single step, but don't enter subs.
2587                     $single = 2;
2588
2589                     # Save for empty command (repeat last).
2590                     $laststep = $cmd;
2591                     last CMD;
2592                 }
2593
2594 =head4 C<s> - single-step, entering subs
2595
2596 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2597 subs. Also saves C<s> as C<$lastcmd>.
2598
2599 =cut
2600
2601                 # s - single step.
2602                 if ($cmd eq 's') {
2603
2604                     # Get out and restart the command loop if program
2605                     # has finished.
2606                     end_report(), next CMD if $finished and $level <= 1;
2607
2608                     # Single step should enter subs.
2609                     $single = 1;
2610
2611                     # Save for empty command (repeat last).
2612                     $laststep = $cmd;
2613                     last CMD;
2614                 }
2615
2616 =head4 C<c> - run continuously, setting an optional breakpoint
2617
2618 Most of the code for this command is taken up with locating the optional
2619 breakpoint, which is either a subroutine name or a line number. We set
2620 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2621 in this and all call levels above this one.
2622
2623 =cut
2624
2625                 # c - start continuous execution.
2626                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2627
2628                     # Hey, show's over. The debugged program finished
2629                     # executing already.
2630                     end_report(), next CMD if $finished and $level <= 1;
2631
2632                     # Capture the place to put a one-time break.
2633                     $subname = $i;
2634
2635                     #  Probably not needed, since we finish an interactive
2636                     #  sub-session anyway...
2637                     # local $filename = $filename;
2638                     # local *dbline = *dbline; # XXX Would this work?!
2639                     #
2640                     # The above question wonders if localizing the alias
2641                     # to the magic array works or not. Since it's commented
2642                     # out, we'll just leave that to speculation for now.
2643
2644                     # If the "subname" isn't all digits, we'll assume it
2645                     # is a subroutine name, and try to find it.
2646                     if ( $subname =~ /\D/ ) {    # subroutine name
2647                             # Qualify it to the current package unless it's
2648                             # already qualified.
2649                         $subname = $package . "::" . $subname
2650                           unless $subname =~ /::/;
2651
2652                         # find_sub will return "file:line_number" corresponding
2653                         # to where the subroutine is defined; we call find_sub,
2654                         # break up the return value, and assign it in one
2655                         # operation.
2656                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2657
2658                         # Force the line number to be numeric.
2659                         $i += 0;
2660
2661                         # If we got a line number, we found the sub.
2662                         if ($i) {
2663
2664                             # Switch all the debugger's internals around so
2665                             # we're actually working with that file.
2666                             $filename = $file;
2667                             *dbline   = $main::{ '_<' . $filename };
2668
2669                             # Mark that there's a breakpoint in this file.
2670                             $had_breakpoints{$filename} |= 1;
2671
2672                             # Scan forward to the first executable line
2673                             # after the 'sub whatever' line.
2674                             $max = $#dbline;
2675                             ++$i while $dbline[$i] == 0 && $i < $max;
2676                         } ## end if ($i)
2677
2678                         # We didn't find a sub by that name.
2679                         else {
2680                             print $OUT "Subroutine $subname not found.\n";
2681                             next CMD;
2682                         }
2683                     } ## end if ($subname =~ /\D/)
2684
2685                     # At this point, either the subname was all digits (an
2686                     # absolute line-break request) or we've scanned through
2687                     # the code following the definition of the sub, looking
2688                     # for an executable, which we may or may not have found.
2689                     #
2690                     # If $i (which we set $subname from) is non-zero, we
2691                     # got a request to break at some line somewhere. On
2692                     # one hand, if there wasn't any real subroutine name
2693                     # involved, this will be a request to break in the current
2694                     # file at the specified line, so we have to check to make
2695                     # sure that the line specified really is breakable.
2696                     #
2697                     # On the other hand, if there was a subname supplied, the
2698                     # preceding block has moved us to the proper file and
2699                     # location within that file, and then scanned forward
2700                     # looking for the next executable line. We have to make
2701                     # sure that one was found.
2702                     #
2703                     # On the gripping hand, we can't do anything unless the
2704                     # current value of $i points to a valid breakable line.
2705                     # Check that.
2706                     if ($i) {
2707
2708                         # Breakable?
2709                         if ( $dbline[$i] == 0 ) {
2710                             print $OUT "Line $i not breakable.\n";
2711                             next CMD;
2712                         }
2713
2714                         # Yes. Set up the one-time-break sigil.
2715                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2716                         _enable_breakpoint_temp_enabled_status($filename, $i);
2717                     } ## end if ($i)
2718
2719                     # Turn off stack tracing from here up.
2720                     for my $i (0 .. $stack_depth) {
2721                         $stack[ $i ] &= ~1;
2722                     }
2723                     last CMD;
2724                 }
2725
2726 =head4 C<r> - return from a subroutine
2727
2728 For C<r> to work properly, the debugger has to stop execution again
2729 immediately after the return is executed. This is done by forcing
2730 single-stepping to be on in the call level above the current one. If
2731 we are printing return values when a C<r> is executed, set C<$doret>
2732 appropriately, and force us out of the command loop.
2733
2734 =cut
2735
2736                 # r - return from the current subroutine.
2737                 if ($cmd eq 'r') {
2738
2739                     # Can't do anything if the program's over.
2740                     end_report(), next CMD if $finished and $level <= 1;
2741
2742                     # Turn on stack trace.
2743                     $stack[$stack_depth] |= 1;
2744
2745                     # Print return value unless the stack is empty.
2746                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2747                     last CMD;
2748                 }
2749
2750 =head4 C<T> - stack trace
2751
2752 Just calls C<DB::print_trace>.
2753
2754 =cut
2755
2756                 if ($cmd eq 'T') {
2757                     print_trace( $OUT, 1 );    # skip DB
2758                     next CMD;
2759                 }
2760
2761 =head4 C<w> - List window around current line.
2762
2763 Just calls C<DB::cmd_w>.
2764
2765 =cut
2766
2767                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2768                     &cmd_w( 'w', $arg );
2769                     next CMD;
2770                 }
2771
2772 =head4 C<W> - watch-expression processing.
2773
2774 Just calls C<DB::cmd_W>.
2775
2776 =cut
2777
2778                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2779                     &cmd_W( 'W', $arg );
2780                     next CMD;
2781                 }
2782
2783 =head4 C</> - search forward for a string in the source
2784
2785 We take the argument and treat it as a pattern. If it turns out to be a
2786 bad one, we return the error we got from trying to C<eval> it and exit.
2787 If not, we create some code to do the search and C<eval> it so it can't
2788 mess us up.
2789
2790 =cut
2791
2792                 # The pattern as a string.
2793                 use vars qw($inpat);
2794
2795                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2796
2797                     # Remove the final slash.
2798                     $inpat =~ s:([^\\])/$:$1:;
2799
2800                     # If the pattern isn't null ...
2801                     if ( $inpat ne "" ) {
2802
2803                         # Turn of warn and die procesing for a bit.
2804                         local $SIG{__DIE__};
2805                         local $SIG{__WARN__};
2806
2807                         # Create the pattern.
2808                         eval '$inpat =~ m' . "\a$inpat\a";
2809                         if ( $@ ne "" ) {
2810
2811                             # Oops. Bad pattern. No biscuit.
2812                             # Print the eval error and go back for more
2813                             # commands.
2814                             print $OUT "$@";
2815                             next CMD;
2816                         }
2817                         $pat = $inpat;
2818                     } ## end if ($inpat ne "")
2819
2820                     # Set up to stop on wrap-around.
2821                     $end = $start;
2822
2823                     # Don't move off the current line.
2824                     $incr = -1;
2825
2826                     # Done in eval so nothing breaks if the pattern
2827                     # does something weird.
2828                     eval '
2829                         for (;;) {
2830                             # Move ahead one line.
2831                             ++$start;
2832
2833                             # Wrap if we pass the last line.
2834                             $start = 1 if ($start > $max);
2835
2836                             # Stop if we have gotten back to this line again,
2837                             last if ($start == $end);
2838
2839                             # A hit! (Note, though, that we are doing
2840                             # case-insensitive matching. Maybe a qr//
2841                             # expression would be better, so the user could
2842                             # do case-sensitive matching if desired.
2843                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2844                                 if ($slave_editor) {
2845                                     # Handle proper escaping in the slave.
2846                                     print $OUT "\032\032$filename:$start:0\n";
2847                                 }
2848                                 else {
2849                                     # Just print the line normally.
2850                                     print $OUT "$start:\t",$dbline[$start],"\n";
2851                                 }
2852                                 # And quit since we found something.
2853                                 last;
2854                             }
2855                          } ';
2856
2857                     # If we wrapped, there never was a match.
2858                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2859                     next CMD;
2860                 }
2861
2862 =head4 C<?> - search backward for a string in the source
2863
2864 Same as for C</>, except the loop runs backwards.
2865
2866 =cut
2867
2868                 # ? - backward pattern search.
2869                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2870
2871                     # Get the pattern, remove trailing question mark.
2872                     $inpat =~ s:([^\\])\?$:$1:;
2873
2874                     # If we've got one ...
2875                     if ( $inpat ne "" ) {
2876
2877                         # Turn off die & warn handlers.
2878                         local $SIG{__DIE__};
2879                         local $SIG{__WARN__};
2880                         eval '$inpat =~ m' . "\a$inpat\a";
2881
2882                         if ( $@ ne "" ) {
2883
2884                             # Ouch. Not good. Print the error.
2885                             print $OUT $@;
2886                             next CMD;
2887                         }
2888                         $pat = $inpat;
2889                     } ## end if ($inpat ne "")
2890
2891                     # Where we are now is where to stop after wraparound.
2892                     $end = $start;
2893
2894                     # Don't move away from this line.
2895                     $incr = -1;
2896
2897                     # Search inside the eval to prevent pattern badness
2898                     # from killing us.
2899                     eval '
2900                         for (;;) {
2901                             # Back up a line.
2902                             --$start;
2903
2904                             # Wrap if we pass the first line.
2905
2906                             $start = $max if ($start <= 0);
2907
2908                             # Quit if we get back where we started,
2909                             last if ($start == $end);
2910
2911                             # Match?
2912                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2913                                 if ($slave_editor) {
2914                                     # Yep, follow slave editor requirements.
2915                                     print $OUT "\032\032$filename:$start:0\n";
2916                                 }
2917                                 else {
2918                                     # Yep, just print normally.
2919                                     print $OUT "$start:\t",$dbline[$start],"\n";
2920                                 }
2921
2922                                 # Found, so done.
2923                                 last;
2924                             }
2925                         } ';
2926
2927                     # Say we failed if the loop never found anything,
2928                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2929                     next CMD;
2930                 }
2931
2932 =head4 C<$rc> - Recall command
2933
2934 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2935 that the terminal supports history). It find the the command required, puts it
2936 into C<$cmd>, and redoes the loop to execute it.
2937
2938 =cut
2939
2940                 # $rc - recall command.
2941                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2942
2943                     # No arguments, take one thing off history.
2944                     pop(@hist) if length($cmd) > 1;
2945
2946                     # Relative (- found)?
2947                     #  Y - index back from most recent (by 1 if bare minus)
2948                     #  N - go to that particular command slot or the last
2949                     #      thing if nothing following.
2950                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2951
2952                     # Pick out the command desired.
2953                     $cmd = $hist[$i];
2954
2955                     # Print the command to be executed and restart the loop
2956                     # with that command in the buffer.
2957                     print $OUT $cmd, "\n";
2958                     redo CMD;
2959                 }
2960
2961 =head4 C<$sh$sh> - C<system()> command
2962
2963 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2964 C<STDOUT> from getting messed up.
2965
2966 =cut
2967
2968                 # $sh$sh - run a shell command (if it's all ASCII).
2969                 # Can't run shell commands with Unicode in the debugger, hmm.
2970                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2971
2972                     # System it.
2973                     &system($arg);
2974                     next CMD;
2975                 }
2976
2977 =head4 C<$rc I<pattern> $rc> - Search command history
2978
2979 Another command to manipulate C<@hist>: this one searches it with a pattern.
2980 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2981
2982 =cut
2983
2984                 # $rc pattern $rc - find a command in the history.
2985                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2986
2987                     # Create the pattern to use.
2988                     $pat = "^$arg";
2989
2990                     # Toss off last entry if length is >1 (and it always is).
2991                     pop(@hist) if length($cmd) > 1;
2992
2993                     # Look backward through the history.
2994                     for ( $i = $#hist ; $i ; --$i ) {
2995                         # Stop if we find it.
2996                         last if $hist[$i] =~ /$pat/;
2997                     }
2998
2999                     if ( !$i ) {
3000
3001                         # Never found it.
3002                         print $OUT "No such command!\n\n";
3003                         next CMD;
3004                     }
3005
3006                     # Found it. Put it in the buffer, print it, and process it.
3007                     $cmd = $hist[$i];
3008                     print $OUT $cmd, "\n";
3009                     redo CMD;
3010                 }
3011
3012 =head4 C<$sh> - Invoke a shell
3013
3014 Uses C<DB::system> to invoke a shell.
3015
3016 =cut
3017
3018                 # $sh - start a shell.
3019                 if ($cmd =~ /\A$sh\z/) {
3020
3021                     # Run the user's shell. If none defined, run Bourne.
3022                     # We resume execution when the shell terminates.
3023                     &system( $ENV{SHELL} || "/bin/sh" );
3024                     next CMD;
3025                 }
3026
3027 =head4 C<$sh I<command>> - Force execution of a command in a shell
3028
3029 Like the above, but the command is passed to the shell. Again, we use
3030 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3031
3032 =cut
3033
3034                 # $sh command - start a shell and run a command in it.
3035                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
3036
3037                     # XXX: using csh or tcsh destroys sigint retvals!
3038                     #&system($1);  # use this instead
3039
3040                     # use the user's shell, or Bourne if none defined.
3041                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
3042                     next CMD;
3043                 }
3044
3045 =head4 C<H> - display commands in history
3046
3047 Prints the contents of C<@hist> (if any).
3048
3049 =cut
3050
3051                 if ($cmd =~ /\AH\b\s*\*/) {
3052                     @hist = @truehist = ();
3053                     print $OUT "History cleansed\n";
3054                     next CMD;
3055                 }
3056
3057                 if (my ($num)
3058                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
3059
3060                     # Anything other than negative numbers is ignored by
3061                     # the (incorrect) pattern, so this test does nothing.
3062                     $end = $num ? ( $#hist - $num ) : 0;
3063
3064                     # Set to the minimum if less than zero.
3065                     $hist = 0 if $hist < 0;
3066
3067                     # Start at the end of the array.
3068                     # Stay in while we're still above the ending value.
3069                     # Tick back by one each time around the loop.
3070                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3071
3072                         # Print the command  unless it has no arguments.
3073                         print $OUT "$i: ", $hist[$i], "\n"
3074                           unless $hist[$i] =~ /^.?$/;
3075                     }
3076                     next CMD;
3077                 }
3078
3079 =head4 C<man, doc, perldoc> - look up documentation
3080
3081 Just calls C<runman()> to print the appropriate document.
3082
3083 =cut
3084
3085                 # man, perldoc, doc - show manual pages.
3086                 if (my ($man_page)
3087                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3088                     runman($man_page);
3089                     next CMD;
3090                 }
3091
3092 =head4 C<p> - print
3093
3094 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3095 the bottom of the loop.
3096
3097 =cut
3098
3099                 my $print_cmd = 'print {$DB::OUT} ';
3100                 # p - print (no args): print $_.
3101                 if ($cmd eq 'p') {
3102                     $cmd = $print_cmd . '$_';
3103                 }
3104
3105                 # p - print the given expression.
3106                 $cmd =~ s/\Ap\b/$print_cmd /;
3107
3108 =head4 C<=> - define command alias
3109
3110 Manipulates C<%alias> to add or list command aliases.
3111
3112 =cut
3113
3114                 # = - set up a command alias.
3115                 if ($cmd =~ s/\A=\s*//) {
3116                     my @keys;
3117                     if ( length $cmd == 0 ) {
3118
3119                         # No args, get current aliases.
3120                         @keys = sort keys %alias;
3121                     }
3122                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3123
3124                         # Creating a new alias. $k is alias name, $v is
3125                         # alias value.
3126
3127                         # can't use $_ or kill //g state
3128                         for my $x ( $k, $v ) {
3129
3130                             # Escape "alarm" characters.
3131                             $x =~ s/\a/\\a/g;
3132                         }
3133
3134                         # Substitute key for value, using alarm chars
3135                         # as separators (which is why we escaped them in
3136                         # the command).
3137                         $alias{$k} = "s\a$k\a$v\a";
3138
3139                         # Turn off standard warn and die behavior.
3140                         local $SIG{__DIE__};
3141                         local $SIG{__WARN__};
3142
3143                         # Is it valid Perl?
3144                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3145
3146                             # Nope. Bad alias. Say so and get out.
3147                             print $OUT "Can't alias $k to $v: $@\n";
3148                             delete $alias{$k};
3149                             next CMD;
3150                         }
3151
3152                         # We'll only list the new one.
3153                         @keys = ($k);
3154                     } ## end elsif (my ($k, $v) = ($cmd...
3155
3156                     # The argument is the alias to list.
3157                     else {
3158                         @keys = ($cmd);
3159                     }
3160
3161                     # List aliases.
3162                     for my $k (@keys) {
3163
3164                         # Messy metaquoting: Trim the substitution code off.
3165                         # We use control-G as the delimiter because it's not
3166                         # likely to appear in the alias.
3167                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3168
3169                             # Print the alias.
3170                             print $OUT "$k\t= $1\n";
3171                         }
3172                         elsif ( defined $alias{$k} ) {
3173
3174                             # Couldn't trim it off; just print the alias code.
3175                             print $OUT "$k\t$alias{$k}\n";
3176                         }
3177                         else {
3178
3179                             # No such, dude.
3180                             print "No alias for $k\n";
3181                         }
3182                     } ## end for my $k (@keys)
3183                     next CMD;
3184                 }
3185
3186 =head4 C<source> - read commands from a file.
3187
3188 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3189 pick it up.
3190
3191 =cut
3192
3193                 # source - read commands from a file (or pipe!) and execute.
3194                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3195                     if ( open my $fh, $sourced_fn ) {
3196
3197                         # Opened OK; stick it in the list of file handles.
3198                         push @cmdfhs, $fh;
3199                     }
3200                     else {
3201
3202                         # Couldn't open it.
3203                         &warn("Can't execute '$sourced_fn': $!\n");
3204                     }
3205                     next CMD;
3206                 }
3207
3208                 if (my ($which_cmd, $position)
3209                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3210
3211                     my ($fn, $line_num);
3212                     if ($position =~ m{\A\d+\z})
3213                     {
3214                         $fn = $filename;
3215                         $line_num = $position;
3216                     }
3217                     elsif (my ($new_fn, $new_line_num)
3218                         = $position =~ m{\A(.*):(\d+)\z}) {
3219                         ($fn, $line_num) = ($new_fn, $new_line_num);
3220                     }
3221                     else
3222                     {
3223                         &warn("Wrong spec for enable/disable argument.\n");
3224                     }
3225
3226                     if (defined($fn)) {
3227                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3228                             _set_breakpoint_enabled_status($fn, $line_num,
3229                                 ($which_cmd eq 'enable' ? 1 : '')
3230                             );
3231                         }
3232                         else {
3233                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3234                         }
3235                     }
3236
3237                     next CMD;
3238                 }
3239
3240 =head4 C<save> - send current history to a file
3241
3242 Takes the complete history, (not the shrunken version you see with C<H>),
3243 and saves it to the given filename, so it can be replayed using C<source>.
3244
3245 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3246
3247 =cut
3248
3249                 # save source - write commands to a file for later use
3250                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3251                     my $filename = $new_fn || '.perl5dbrc';    # default?
3252                     if ( open my $fh, '>', $filename ) {
3253
3254                        # chomp to remove extraneous newlines from source'd files
3255                         chomp( my @truelist =
3256                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3257                               @truehist );
3258                         print $fh join( "\n", @truelist );
3259                         print "commands saved in $file\n";
3260                     }
3261                     else {
3262                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3263                     }
3264                     next CMD;
3265                 }
3266
3267 =head4 C<R> - restart
3268
3269 Restart the debugger session.
3270
3271 =head4 C<rerun> - rerun the current session
3272
3273 Return to any given position in the B<true>-history list
3274
3275 =cut
3276
3277                 # R - restart execution.
3278                 # rerun - controlled restart execution.
3279                 if (my ($cmd_cmd, $cmd_params) =
3280                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3281                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3282
3283                     # Close all non-system fds for a clean restart.  A more
3284                     # correct method would be to close all fds that were not
3285                     # open when the process started, but this seems to be
3286                     # hard.  See "debugger 'R'estart and open database
3287                     # connections" on p5p.
3288
3289                     my $max_fd = 1024; # default if POSIX can't be loaded
3290                     if (eval { require POSIX }) {
3291                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3292                     }
3293
3294                     if (defined $max_fd) {
3295                         foreach ($^F+1 .. $max_fd-1) {
3296                             next unless open FD_TO_CLOSE, "<&=$_";
3297                             close(FD_TO_CLOSE);
3298                         }
3299                     }
3300
3301                     # And run Perl again.  We use exec() to keep the
3302                     # PID stable (and that way $ini_pids is still valid).
3303                     exec(@args) || print $OUT "exec failed: $!\n";
3304
3305                     last CMD;
3306                 }
3307
3308 =head4 C<|, ||> - pipe output through the pager.
3309
3310 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3311 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3312 pipe to the pager (restoring the output filehandles if this fails). If this
3313 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3314 set C<$signal>, sending us back into the debugger.
3315
3316 We then trim off the pipe symbols and C<redo> the command loop at the
3317 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3318 reading another.
3319
3320 =cut
3321
3322                 # || - run command in the pager, with output to DB::OUT.
3323                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3324                     if ( $pager =~ /^\|/ ) {
3325
3326                         # Default pager is into a pipe. Redirect I/O.
3327                         open( SAVEOUT, ">&STDOUT" )
3328                           || &warn("Can't save STDOUT");
3329                         open( STDOUT, ">&OUT" )
3330                           || &warn("Can't redirect STDOUT");
3331                     } ## end if ($pager =~ /^\|/)
3332                     else {
3333
3334                         # Not into a pipe. STDOUT is safe.
3335                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3336                     }
3337
3338                     # Fix up environment to record we have less if so.
3339                     fix_less();
3340
3341                     unless ( $piped = open( OUT, $pager ) ) {
3342
3343                         # Couldn't open pipe to pager.
3344                         &warn("Can't pipe output to '$pager'");
3345                         if ( $pager =~ /^\|/ ) {
3346
3347                             # Redirect I/O back again.
3348                             open( OUT, ">&STDOUT" )    # XXX: lost message
3349                               || &warn("Can't restore DB::OUT");
3350                             open( STDOUT, ">&SAVEOUT" )
3351                               || &warn("Can't restore STDOUT");
3352                             close(SAVEOUT);
3353                         } ## end if ($pager =~ /^\|/)
3354                         else {
3355
3356                             # Redirect I/O. STDOUT already safe.
3357                             open( OUT, ">&STDOUT" )    # XXX: lost message
3358                               || &warn("Can't restore DB::OUT");
3359                         }
3360                         next CMD;
3361                     } ## end unless ($piped = open(OUT,...
3362
3363                     # Set up broken-pipe handler if necessary.
3364                     $SIG{PIPE} = \&DB::catch
3365                       if $pager =~ /^\|/
3366                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3367
3368                     OUT->autoflush(1);
3369                     # Save current filehandle, and put it back.
3370                     $selected = select(OUT);
3371                     # Don't put it back if pager was a pipe.
3372                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3373
3374                     # Trim off the pipe symbols and run the command now.
3375                     $cmd =~ s#\A\|+\s*##;
3376                     redo PIPE;
3377                 }
3378
3379 =head3 END OF COMMAND PARSING
3380
3381 Anything left in C<$cmd> at this point is a Perl expression that we want to
3382 evaluate. We'll always evaluate in the user's context, and fully qualify
3383 any variables we might want to address in the C<DB> package.
3384
3385 =cut
3386
3387                 # t - turn trace on.
3388                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3389                     my $trace_arg = $1;
3390                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3391                 }
3392
3393                 # s - single-step. Remember the last command was 's'.
3394                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3395                     $laststep = 's';
3396                 }
3397
3398                 # n - single-step, but not into subs. Remember last command
3399                 # was 'n'.
3400                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3401                     $laststep = 'n';
3402                 }
3403
3404             }    # PIPE:
3405
3406             # Make sure the flag that says "the debugger's running" is
3407             # still on, to make sure we get control again.
3408             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3409
3410             # Run *our* eval that executes in the caller's context.
3411             &eval;
3412
3413             # Turn off the one-time-dump stuff now.
3414             if ($onetimeDump) {
3415                 $onetimeDump      = undef;
3416                 $onetimedumpDepth = undef;
3417             }
3418             elsif ( $term_pid == $$ ) {
3419                 eval {          # May run under miniperl, when not available...
3420                     STDOUT->flush();
3421                     STDERR->flush();
3422                 };
3423
3424                 # XXX If this is the master pid, print a newline.
3425                 print $OUT "\n";
3426             }
3427         } ## end while (($term || &setterm...
3428
3429 =head3 POST-COMMAND PROCESSING
3430
3431 After each command, we check to see if the command output was piped anywhere.
3432 If so, we go through the necessary code to unhook the pipe and go back to
3433 our standard filehandles for input and output.
3434
3435 =cut
3436
3437         continue {    # CMD:
3438
3439             # At the end of every command:
3440             if ($piped) {
3441
3442                 # Unhook the pipe mechanism now.
3443                 if ( $pager =~ /^\|/ ) {
3444
3445                     # No error from the child.
3446                     $? = 0;
3447
3448                     # we cannot warn here: the handle is missing --tchrist
3449                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3450
3451                     # most of the $? crud was coping with broken cshisms
3452                     # $? is explicitly set to 0, so this never runs.
3453                     if ($?) {
3454                         print SAVEOUT "Pager '$pager' failed: ";
3455                         if ( $? == -1 ) {
3456                             print SAVEOUT "shell returned -1\n";
3457                         }
3458                         elsif ( $? >> 8 ) {
3459                             print SAVEOUT ( $? & 127 )
3460                               ? " (SIG#" . ( $? & 127 ) . ")"
3461                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3462                         }
3463                         else {
3464                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3465                         }
3466                     } ## end if ($?)
3467
3468                     # Reopen filehandle for our output (if we can) and
3469                     # restore STDOUT (if we can).
3470                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3471                     open( STDOUT, ">&SAVEOUT" )
3472                       || &warn("Can't restore STDOUT");
3473
3474                     # Turn off pipe exception handler if necessary.
3475                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3476
3477                     # Will stop ignoring SIGPIPE if done like nohup(1)
3478                     # does SIGINT but Perl doesn't give us a choice.
3479                 } ## end if ($pager =~ /^\|/)
3480                 else {
3481
3482                     # Non-piped "pager". Just restore STDOUT.
3483                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3484                 }
3485
3486                 # Close filehandle pager was using, restore the normal one
3487                 # if necessary,
3488                 close(SAVEOUT);
3489                 select($selected), $selected = "" unless $selected eq "";
3490
3491                 # No pipes now.
3492                 $piped = "";
3493             } ## end if ($piped)
3494         }    # CMD:
3495
3496 =head3 COMMAND LOOP TERMINATION
3497
3498 When commands have finished executing, we come here. If the user closed the
3499 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3500 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3501 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3502 The interpreter will then execute the next line and then return control to us
3503 again.
3504
3505 =cut
3506
3507         # No more commands? Quit.
3508         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3509
3510         # Evaluate post-prompt commands.
3511         foreach $evalarg (@$post) {
3512             &eval;
3513         }
3514     }    # if ($single || $signal)
3515
3516     # Put the user's globals back where you found them.
3517     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3518     ();
3519 } ## end sub DB
3520
3521 # The following code may be executed now:
3522 # BEGIN {warn 4}
3523
3524 =head2 sub
3525
3526 C<sub> is called whenever a subroutine call happens in the program being
3527 debugged. The variable C<$DB::sub> contains the name of the subroutine
3528 being called.
3529
3530 The core function of this subroutine is to actually call the sub in the proper
3531 context, capturing its output. This of course causes C<DB::DB> to get called
3532 again, repeating until the subroutine ends and returns control to C<DB::sub>
3533 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3534 return value, and returns its captured copy of the return value as its own
3535 return value. The value then feeds back into the program being debugged as if
3536 C<DB::sub> hadn't been there at all.
3537
3538 C<sub> does all the work of printing the subroutine entry and exit messages
3539 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3540 and also prints the return value if needed (for the C<r> command and if
3541 the 16 bit is set in C<$frame>).
3542
3543 It also tracks the subroutine call depth by saving the current setting of
3544 C<$single> in the C<@stack> package global; if this exceeds the value in
3545 C<$deep>, C<sub> automatically turns on printing of the current depth by
3546 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3547 of stop/don't stop on entry to subs set as it currently is set.
3548
3549 =head3 C<caller()> support
3550
3551 If C<caller()> is called from the package C<DB>, it provides some
3552 additional data, in the following order:
3553
3554 =over 4
3555
3556 =item * C<$package>
3557
3558 The package name the sub was in
3559
3560 =item * C<$filename>
3561
3562 The filename it was defined in
3563
3564 =item * C<$line>
3565
3566 The line number it was defined on
3567
3568 =item * C<$subroutine>
3569
3570 The subroutine name; C<(eval)> if an C<eval>().
3571
3572 =item * C<$hasargs>
3573
3574 1 if it has arguments, 0 if not
3575
3576 =item * C<$wantarray>
3577
3578 1 if array context, 0 if scalar context
3579
3580 =item * C<$evaltext>
3581
3582 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3583
3584 =item * C<$is_require>
3585
3586 frame was created by a C<use> or C<require> statement
3587
3588 =item * C<$hints>
3589
3590 pragma information; subject to change between versions
3591
3592 =item * C<$bitmask>
3593
3594 pragma information; subject to change between versions
3595
3596 =item * C<@DB::args>
3597
3598 arguments with which the subroutine was invoked
3599
3600 =back
3601
3602 =cut
3603
3604 use vars qw($deep);
3605
3606 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3607 # happy. -- Shlomi Fish
3608 sub DB::sub {
3609         # Do not use a regex in this subroutine -> results in corrupted memory
3610         # See: [perl #66110]
3611
3612         # lock ourselves under threads
3613         lock($DBGR);
3614
3615     # Whether or not the autoloader was running, a scalar to put the
3616     # sub's return value in (if needed), and an array to put the sub's
3617     # return value in (if needed).
3618     my ( $al, $ret, @ret ) = "";
3619         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3620                 print "creating new thread\n";
3621         }
3622
3623     # If the last ten characters are '::AUTOLOAD', note we've traced
3624     # into AUTOLOAD for $sub.
3625     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3626         no strict 'refs';
3627         $al = " for $$sub" if defined $$sub;
3628     }
3629
3630     # We stack the stack pointer and then increment it to protect us
3631     # from a situation that might unwind a whole bunch of call frames
3632     # at once. Localizing the stack pointer means that it will automatically
3633     # unwind the same amount when multiple stack frames are unwound.
3634     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3635
3636     # Expand @stack.
3637     $#stack = $stack_depth;
3638
3639     # Save current single-step setting.
3640     $stack[-1] = $single;
3641
3642     # Turn off all flags except single-stepping.
3643     $single &= 1;
3644
3645     # If we've gotten really deeply recursed, turn on the flag that will
3646     # make us stop with the 'deep recursion' message.
3647     $single |= 4 if $stack_depth == $deep;
3648
3649     # If frame messages are on ...
3650     (
3651         $frame & 4    # Extended frame entry message
3652         ? (
3653             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3654
3655             # Why -1? But it works! :-(
3656             # Because print_trace will call add 1 to it and then call
3657             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3658             # in dump_trace.
3659             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3660           )
3661         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3662
3663           # standard frame entry message
3664       )
3665       if $frame;
3666
3667     # Determine the sub's return type, and capture appropriately.
3668     if (wantarray) {
3669
3670         # Called in array context. call sub and capture output.
3671         # DB::DB will recursively get control again if appropriate; we'll come
3672         # back here when the sub is finished.
3673         {
3674             no strict 'refs';
3675             @ret = &$sub;
3676         }
3677
3678         # Pop the single-step value back off the stack.
3679         $single |= $stack[ $stack_depth-- ];
3680
3681         # Check for exit trace messages...
3682         (
3683             $frame & 4    # Extended exit message
3684             ? (
3685                 print_lineinfo( ' ' x $stack_depth, "out " ),
3686                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3687               )
3688             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3689
3690               # Standard exit message
3691           )
3692           if $frame & 2;
3693
3694         # Print the return info if we need to.
3695         if ( $doret eq $stack_depth or $frame & 16 ) {
3696
3697             # Turn off output record separator.
3698             local $\ = '';
3699             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3700
3701             # Indent if we're printing because of $frame tracing.
3702             print $fh ' ' x $stack_depth if $frame & 16;
3703
3704             # Print the return value.
3705             print $fh "list context return from $sub:\n";
3706             dumpit( $fh, \@ret );
3707
3708             # And don't print it again.
3709             $doret = -2;
3710         } ## end if ($doret eq $stack_depth...
3711             # And we have to return the return value now.
3712         @ret;
3713     } ## end if (wantarray)
3714
3715     # Scalar context.
3716     else {
3717         if ( defined wantarray ) {
3718         no strict 'refs';
3719             # Save the value if it's wanted at all.
3720             $ret = &$sub;
3721         }
3722         else {
3723         no strict 'refs';
3724             # Void return, explicitly.
3725             &$sub;
3726             undef $ret;
3727         }
3728
3729         # Pop the single-step value off the stack.
3730         $single |= $stack[ $stack_depth-- ];
3731
3732         # If we're doing exit messages...
3733         (
3734             $frame & 4    # Extended messages
3735             ? (
3736                 print_lineinfo( ' ' x $stack_depth, "out " ),
3737                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3738               )
3739             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3740
3741               # Standard messages
3742           )
3743           if $frame & 2;
3744
3745         # If we are supposed to show the return value... same as before.
3746         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3747             local $\ = '';
3748             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3749             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3750             print $fh (
3751                 defined wantarray
3752                 ? "scalar context return from $sub: "
3753                 : "void context return from $sub\n"
3754             );
3755             dumpit( $fh, $ret ) if defined wantarray;
3756             $doret = -2;
3757         } ## end if ($doret eq $stack_depth...
3758
3759         # Return the appropriate scalar value.
3760         $ret;
3761     } ## end else [ if (wantarray)
3762 } ## end sub _sub
3763
3764 sub lsub : lvalue {
3765
3766     no strict 'refs';
3767
3768         # lock ourselves under threads
3769         lock($DBGR);
3770
3771     # Whether or not the autoloader was running, a scalar to put the
3772     # sub's return value in (if needed), and an array to put the sub's
3773     # return value in (if needed).
3774     my ( $al, $ret, @ret ) = "";
3775         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3776                 print "creating new thread\n";
3777         }
3778
3779     # If the last ten characters are C'::AUTOLOAD', note we've traced
3780     # into AUTOLOAD for $sub.
3781     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3782         $al = " for $$sub";
3783     }
3784
3785     # We stack the stack pointer and then increment it to protect us
3786     # from a situation that might unwind a whole bunch of call frames
3787     # at once. Localizing the stack pointer means that it will automatically
3788     # unwind the same amount when multiple stack frames are unwound.
3789     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3790
3791     # Expand @stack.
3792     $#stack = $stack_depth;
3793
3794     # Save current single-step setting.
3795     $stack[-1] = $single;
3796
3797     # Turn off all flags except single-stepping.
3798     $single &= 1;
3799
3800     # If we've gotten really deeply recursed, turn on the flag that will
3801     # make us stop with the 'deep recursion' message.
3802     $single |= 4 if $stack_depth == $deep;
3803
3804     # If frame messages are on ...
3805     (
3806         $frame & 4    # Extended frame entry message
3807         ? (
3808             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3809
3810             # Why -1? But it works! :-(
3811             # Because print_trace will call add 1 to it and then call
3812             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3813             # in dump_trace.
3814             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3815           )
3816         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3817
3818           # standard frame entry message
3819       )
3820       if $frame;
3821
3822     # Pop the single-step value back off the stack.
3823     $single |= $stack[ $stack_depth-- ];
3824
3825     # call the original lvalue sub.
3826     &$sub;
3827 }
3828
3829 # Abstracting common code from multiple places elsewhere:
3830 sub depth_print_lineinfo {
3831     my $always_print = shift;
3832
3833     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3834 }
3835
3836 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3837
3838 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3839 Most of the changes were to systematize the command structure and to eliminate
3840 commands that threw away user input without checking.
3841
3842 The following sections describe the code added to make it easy to support
3843 multiple command sets with conflicting command names. This section is a start
3844 at unifying all command processing to make it simpler to develop commands.
3845
3846 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3847 number, and C<$dbline> (the current line) as arguments.
3848
3849 Support functions in this section which have multiple modes of failure C<die>
3850 on error; the rest simply return a false value.
3851
3852 The user-interface functions (all of the C<cmd_*> functions) just output
3853 error messages.
3854
3855 =head2 C<%set>
3856
3857 The C<%set> hash defines the mapping from command letter to subroutine
3858 name suffix.
3859
3860 C<%set> is a two-level hash, indexed by set name and then by command name.
3861 Note that trying to set the CommandSet to C<foobar> simply results in the
3862 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3863
3864 =cut
3865
3866 ### The API section
3867
3868 my %set = (    #
3869     'pre580' => {
3870         'a' => 'pre580_a',
3871         'A' => 'pre580_null',
3872         'b' => 'pre580_b',
3873         'B' => 'pre580_null',
3874         'd' => 'pre580_null',
3875         'D' => 'pre580_D',
3876         'h' => 'pre580_h',
3877         'M' => 'pre580_null',
3878         'O' => 'o',
3879         'o' => 'pre580_null',
3880         'v' => 'M',
3881         'w' => 'v',
3882         'W' => 'pre580_W',
3883     },
3884     'pre590' => {
3885         '<'  => 'pre590_prepost',
3886         '<<' => 'pre590_prepost',
3887         '>'  => 'pre590_prepost',
3888         '>>' => 'pre590_prepost',
3889         '{'  => 'pre590_prepost',
3890         '{{' => 'pre590_prepost',
3891     },
3892 );
3893
3894 my %breakpoints_data;
3895
3896 sub _has_breakpoint_data_ref {
3897     my ($filename, $line) = @_;
3898
3899     return (
3900         exists( $breakpoints_data{$filename} )
3901             and
3902         exists( $breakpoints_data{$filename}{$line} )
3903     );
3904 }
3905
3906 sub _get_breakpoint_data_ref {
3907     my ($filename, $line) = @_;
3908
3909     return ($breakpoints_data{$filename}{$line} ||= +{});
3910 }
3911
3912 sub _delete_breakpoint_data_ref {
3913     my ($filename, $line) = @_;
3914
3915     delete($breakpoints_data{$filename}{$line});
3916     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3917         delete($breakpoints_data{$filename});
3918     }
3919
3920     return;
3921 }
3922
3923 sub _set_breakpoint_enabled_status {
3924     my ($filename, $line, $status) = @_;
3925
3926     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3927         ($status ? 1 : '')
3928         ;
3929
3930     return;
3931 }
3932
3933 sub _enable_breakpoint_temp_enabled_status {
3934     my ($filename, $line) = @_;
3935
3936     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3937
3938     return;
3939 }
3940
3941 sub _cancel_breakpoint_temp_enabled_status {
3942     my ($filename, $line) = @_;
3943
3944     my $ref = _get_breakpoint_data_ref($filename, $line);
3945
3946     delete ($ref->{'temp_enabled'});
3947
3948     if (! %$ref) {
3949         _delete_breakpoint_data_ref($filename, $line);
3950     }
3951
3952     return;
3953 }
3954
3955 sub _is_breakpoint_enabled {
3956     my ($filename, $line) = @_;
3957
3958     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3959     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3960 }
3961
3962 =head2 C<cmd_wrapper()> (API)
3963
3964 C<cmd_wrapper()> allows the debugger to switch command sets
3965 depending on the value of the C<CommandSet> option.
3966
3967 It tries to look up the command in the C<%set> package-level I<lexical>
3968 (which means external entities can't fiddle with it) and create the name of
3969 the sub to call based on the value found in the hash (if it's there). I<All>
3970 of the commands to be handled in a set have to be added to C<%set>; if they
3971 aren't found, the 5.8.0 equivalent is called (if there is one).
3972
3973 This code uses symbolic references.
3974
3975 =cut
3976
3977 sub cmd_wrapper {
3978     my $cmd      = shift;
3979     my $line     = shift;
3980     my $dblineno = shift;
3981
3982     # Assemble the command subroutine's name by looking up the
3983     # command set and command name in %set. If we can't find it,
3984     # default to the older version of the command.
3985     my $call = 'cmd_'
3986       . ( $set{$CommandSet}{$cmd}
3987           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3988
3989     # Call the command subroutine, call it by name.
3990     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
3991 } ## end sub cmd_wrapper
3992
3993 =head3 C<cmd_a> (command)
3994
3995 The C<a> command handles pre-execution actions. These are associated with a
3996 particular line, so they're stored in C<%dbline>. We default to the current
3997 line if none is specified.
3998
3999 =cut
4000
4001 sub cmd_a {
4002     my $cmd    = shift;
4003     my $line   = shift || '';    # [.|line] expr
4004     my $dbline = shift;
4005
4006     # If it's dot (here), or not all digits,  use the current line.
4007     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
4008
4009     # Should be a line number followed by an expression.
4010     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4011         my ( $lineno, $expr ) = ( $1, $2 );
4012
4013         # If we have an expression ...
4014         if ( length $expr ) {
4015
4016             # ... but the line isn't breakable, complain.
4017             if ( $dbline[$lineno] == 0 ) {
4018                 print $OUT
4019                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4020             }
4021             else {
4022
4023                 # It's executable. Record that the line has an action.
4024                 $had_breakpoints{$filename} |= 2;
4025
4026                 # Remove any action, temp breakpoint, etc.
4027                 $dbline{$lineno} =~ s/\0[^\0]*//;
4028
4029                 # Add the action to the line.
4030                 $dbline{$lineno} .= "\0" . action($expr);
4031
4032                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4033             }
4034         } ## end if (length $expr)
4035     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4036     else {
4037
4038         # Syntax wrong.
4039         print $OUT
4040           "Adding an action requires an optional lineno and an expression\n"
4041           ;    # hint
4042     }
4043 } ## end sub cmd_a
4044
4045 =head3 C<cmd_A> (command)
4046
4047 Delete actions. Similar to above, except the delete code is in a separate
4048 subroutine, C<delete_action>.
4049
4050 =cut
4051
4052 sub cmd_A {
4053     my $cmd    = shift;
4054     my $line   = shift || '';
4055     my $dbline = shift;
4056
4057     # Dot is this line.
4058     $line =~ s/^\./$dbline/;
4059
4060     # Call delete_action with a null param to delete them all.
4061     # The '1' forces the eval to be true. It'll be false only
4062     # if delete_action blows up for some reason, in which case
4063     # we print $@ and get out.
4064     if ( $line eq '*' ) {
4065         eval { &delete_action(); 1 } or print $OUT $@ and return;
4066     }
4067
4068     # There's a real line  number. Pass it to delete_action.
4069     # Error trapping is as above.
4070     elsif ( $line =~ /^(\S.*)/ ) {
4071         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4072     }
4073
4074     # Swing and a miss. Bad syntax.
4075     else {
4076         print $OUT
4077           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4078     }
4079 } ## end sub cmd_A
4080
4081 =head3 C<delete_action> (API)
4082
4083 C<delete_action> accepts either a line number or C<undef>. If a line number
4084 is specified, we check for the line being executable (if it's not, it
4085 couldn't have had an  action). If it is, we just take the action off (this
4086 will get any kind of an action, including breakpoints).
4087
4088 =cut
4089
4090 sub delete_action {
4091     my $i = shift;
4092     if ( defined($i) ) {
4093
4094         # Can there be one?
4095         die "Line $i has no action .\n" if $dbline[$i] == 0;
4096
4097         # Nuke whatever's there.
4098         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4099         delete $dbline{$i} if $dbline{$i} eq '';
4100     }
4101     else {
4102         print $OUT "Deleting all actions...\n";
4103         for my $file ( keys %had_breakpoints ) {
4104             local *dbline = $main::{ '_<' . $file };
4105             $max = $#dbline;
4106             my $was;
4107             for $i (1 .. $max) {
4108                 if ( defined $dbline{$i} ) {
4109                     $dbline{$i} =~ s/\0[^\0]*//;
4110                     delete $dbline{$i} if $dbline{$i} eq '';
4111                 }
4112                 unless ( $had_breakpoints{$file} &= ~2 ) {
4113                     delete $had_breakpoints{$file};
4114                 }
4115             } ## end for ($i = 1 .. $max)
4116         } ## end for my $file (keys %had_breakpoints)
4117     } ## end else [ if (defined($i))
4118 } ## end sub delete_action
4119
4120 =head3 C<cmd_b> (command)
4121
4122 Set breakpoints. Since breakpoints can be set in so many places, in so many
4123 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4124 we try to parse the command type, and then shuttle it off to an appropriate
4125 subroutine to actually do the work of setting the breakpoint in the right
4126 place.
4127
4128 =cut
4129
4130 sub cmd_b {
4131     my $cmd    = shift;
4132     my $line   = shift;    # [.|line] [cond]
4133     my $dbline = shift;
4134
4135     # Make . the current line number if it's there..
4136     $line =~ s/^\.(\s|\z)/$dbline$1/;
4137
4138     # No line number, no condition. Simple break on current line.
4139     if ( $line =~ /^\s*$/ ) {
4140         &cmd_b_line( $dbline, 1 );
4141     }
4142
4143     # Break on load for a file.
4144     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4145         my $file = $1;
4146         $file =~ s/\s+$//;
4147         &cmd_b_load($file);
4148     }
4149
4150     # b compile|postpone <some sub> [<condition>]
4151     # The interpreter actually traps this one for us; we just put the
4152     # necessary condition in the %postponed hash.
4153     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4154
4155         # Capture the condition if there is one. Make it true if none.
4156         my $cond = length $3 ? $3 : '1';
4157
4158         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4159         # if it was 'compile'.
4160         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4161
4162         # De-Perl4-ify the name - ' separators to ::.
4163         $subname =~ s/\'/::/g;
4164
4165         # Qualify it into the current package unless it's already qualified.
4166         $subname = "${package}::" . $subname unless $subname =~ /::/;
4167
4168         # Add main if it starts with ::.
4169         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4170
4171         # Save the break type for this sub.
4172         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4173     } ## end elsif ($line =~ ...
4174     # b <filename>:<line> [<condition>]
4175     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4176         my ($filename, $line_num, $cond) = ($1, $2, $3);
4177         cmd_b_filename_line(
4178             $filename,
4179             $line_num,
4180             (length($cond) ? $cond : '1'),
4181         );
4182     }
4183     # b <sub name> [<condition>]
4184     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4185
4186         #
4187         $subname = $1;
4188         my $cond = length $2 ? $2 : '1';
4189         &cmd_b_sub( $subname, $cond );
4190     }
4191
4192     # b <line> [<condition>].
4193     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4194
4195         # Capture the line. If none, it's the current line.
4196         $line = $1 || $dbline;
4197
4198         # If there's no condition, make it '1'.
4199         my $cond = length $2 ? $2 : '1';
4200
4201         # Break on line.
4202         &cmd_b_line( $line, $cond );
4203     }
4204
4205     # Line didn't make sense.
4206     else {
4207         print "confused by line($line)?\n";
4208     }
4209 } ## end sub cmd_b
4210
4211 =head3 C<break_on_load> (API)
4212
4213 We want to break when this file is loaded. Mark this file in the
4214 C<%break_on_load> hash, and note that it has a breakpoint in
4215 C<%had_breakpoints>.
4216
4217 =cut
4218
4219 sub break_on_load {
4220     my $file = shift;
4221     $break_on_load{$file} = 1;
4222     $had_breakpoints{$file} |= 1;
4223 }
4224
4225 =head3 C<report_break_on_load> (API)
4226
4227 Gives us an array of filenames that are set to break on load. Note that
4228 only files with break-on-load are in here, so simply showing the keys
4229 suffices.
4230
4231 =cut
4232
4233 sub report_break_on_load {
4234     sort keys %break_on_load;
4235 }
4236
4237 =head3 C<cmd_b_load> (command)
4238
4239 We take the file passed in and try to find it in C<%INC> (which maps modules
4240 to files they came from). We mark those files for break-on-load via
4241 C<break_on_load> and then report that it was done.
4242
4243 =cut
4244
4245 sub cmd_b_load {
4246     my $file = shift;
4247     my @files;
4248
4249     # This is a block because that way we can use a redo inside it
4250     # even without there being any looping structure at all outside it.
4251     {
4252
4253         # Save short name and full path if found.
4254         push @files, $file;
4255         push @files, $::INC{$file} if $::INC{$file};
4256
4257         # Tack on .pm and do it again unless there was a '.' in the name
4258         # already.
4259         $file .= '.pm', redo unless $file =~ /\./;
4260     }
4261
4262     # Do the real work here.
4263     break_on_load($_) for @files;
4264
4265     # All the files that have break-on-load breakpoints.
4266     @files = report_break_on_load;
4267
4268     # Normalize for the purposes of our printing this.
4269     local $\ = '';
4270     local $" = ' ';
4271     print $OUT "Will stop on load of '@files'.\n";
4272 } ## end sub cmd_b_load
4273
4274 =head3 C<$filename_error> (API package global)
4275
4276 Several of the functions we need to implement in the API need to work both
4277 on the current file and on other files. We don't want to duplicate code, so
4278 C<$filename_error> is used to contain the name of the file that's being
4279 worked on (if it's not the current one).
4280
4281 We can now build functions in pairs: the basic function works on the current
4282 file, and uses C<$filename_error> as part of its error message. Since this is
4283 initialized to C<"">, no filename will appear when we are working on the
4284 current file.
4285
4286 The second function is a wrapper which does the following:
4287
4288 =over 4
4289
4290 =item *
4291
4292 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4293
4294 =item *
4295
4296 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4297
4298 =item *
4299
4300 Calls the first function.
4301
4302 The first function works on the I<current> file (i.e., the one we changed to),
4303 and prints C<$filename_error> in the error message (the name of the other file)
4304 if it needs to. When the functions return, C<*dbline> is restored to point
4305 to the actual current file (the one we're executing in) and
4306 C<$filename_error> is restored to C<"">. This restores everything to
4307 the way it was before the second function was called at all.
4308
4309 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4310 details.
4311
4312 =back
4313
4314 =cut
4315
4316 use vars qw($filename_error);
4317 $filename_error = '';
4318
4319 =head3 breakable_line(from, to) (API)
4320
4321 The subroutine decides whether or not a line in the current file is breakable.
4322 It walks through C<@dbline> within the range of lines specified, looking for
4323 the first line that is breakable.
4324
4325 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4326 first line I<after> C<$to> that's breakable, if there is one.
4327
4328 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4329 first line I<before> C<$to> that's breakable, if there is one.
4330
4331 =cut
4332
4333 sub breakable_line {
4334
4335     my ( $from, $to ) = @_;
4336
4337     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4338     my $i = $from;
4339
4340     # If there are at least 2 arguments, we're trying to search a range.
4341     if ( @_ >= 2 ) {
4342
4343         # $delta is positive for a forward search, negative for a backward one.
4344         my $delta = $from < $to ? +1 : -1;
4345
4346         # Keep us from running off the ends of the file.
4347         my $limit = $delta > 0 ? $#dbline : 1;
4348
4349         # Clever test. If you're a mathematician, it's obvious why this
4350         # test works. If not:
4351         # If $delta is positive (going forward), $limit will be $#dbline.
4352         #    If $to is less than $limit, ($limit - $to) will be positive, times
4353         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4354         #    as the stopping point.
4355         #
4356         #    If $to is greater than $limit, ($limit - $to) is negative,
4357         #    times $delta of 1 (positive), so the result is < 0 and we should
4358         #    use $limit ($#dbline) as the stopping point.
4359         #
4360         # If $delta is negative (going backward), $limit will be 1.
4361         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4362         #    (negative) so the result is > 0, and we use $to as the stopping
4363         #    point.
4364         #
4365         #    If $to is less than zero, ($limit - $to) will be positive,
4366         #    times $delta of -1 (negative), so the result is not > 0, and
4367         #    we use $limit (1) as the stopping point.
4368         #
4369         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4370         #    (negative), still giving zero; the result is not > 0, and
4371         #    we use $limit (1) as the stopping point.
4372         #
4373         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4374         #    (negative), giving a positive (>0) value, so we'll set $limit to
4375         #    $to.
4376
4377         $limit = $to if ( $limit - $to ) * $delta > 0;
4378
4379         # The real search loop.
4380         # $i starts at $from (the point we want to start searching from).
4381         # We move through @dbline in the appropriate direction (determined
4382         # by $delta: either -1 (back) or +1 (ahead).
4383         # We stay in as long as we haven't hit an executable line
4384         # ($dbline[$i] == 0 means not executable) and we haven't reached
4385         # the limit yet (test similar to the above).
4386         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4387
4388     } ## end if (@_ >= 2)
4389
4390     # If $i points to a line that is executable, return that.
4391     return $i unless $dbline[$i] == 0;
4392
4393     # Format the message and print it: no breakable lines in range.
4394     my ( $pl, $upto ) = ( '', '' );
4395     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4396
4397     # If there's a filename in filename_error, we'll see it.
4398     # If not, not.
4399     die "Line$pl $from$upto$filename_error not breakable\n";
4400 } ## end sub breakable_line
4401
4402 =head3 breakable_line_in_filename(file, from, to) (API)
4403
4404 Like C<breakable_line>, but look in another file.
4405
4406 =cut
4407
4408 sub breakable_line_in_filename {
4409
4410     # Capture the file name.
4411     my ($f) = shift;
4412
4413     # Swap the magic line array over there temporarily.
4414     local *dbline = $main::{ '_<' . $f };
4415
4416     # If there's an error, it's in this other file.
4417     local $filename_error = " of '$f'";
4418
4419     # Find the breakable line.
4420     breakable_line(@_);
4421
4422     # *dbline and $filename_error get restored when this block ends.
4423
4424 } ## end sub breakable_line_in_filename
4425
4426 =head3 break_on_line(lineno, [condition]) (API)
4427
4428 Adds a breakpoint with the specified condition (or 1 if no condition was
4429 specified) to the specified line. Dies if it can't.
4430
4431 =cut
4432
4433 sub break_on_line {
4434     my ( $i, $cond ) = @_;
4435
4436     # Always true if no condition supplied.
4437     $cond = 1 unless @_ >= 2;
4438
4439     my $inii  = $i;
4440     my $after = '';
4441     my $pl    = '';
4442
4443     # Woops, not a breakable line. $filename_error allows us to say
4444     # if it was in a different file.
4445     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4446
4447     # Mark this file as having breakpoints in it.
4448     $had_breakpoints{$filename} |= 1;
4449
4450     # If there is an action or condition here already ...
4451     if ( $dbline{$i} ) {
4452
4453         # ... swap this condition for the existing one.
4454         $dbline{$i} =~ s/^[^\0]*/$cond/;
4455     }
4456     else {
4457
4458         # Nothing here - just add the condition.
4459         $dbline{$i} = $cond;
4460
4461         _set_breakpoint_enabled_status($filename, $i, 1);
4462     }
4463 } ## end sub break_on_line
4464
4465 =head3 cmd_b_line(line, [condition]) (command)
4466
4467 Wrapper for C<break_on_line>. Prints the failure message if it
4468 doesn't work.
4469
4470 =cut
4471
4472 sub cmd_b_line {
4473     if (not eval { break_on_line(@_); 1 }) {
4474         local $\ = '';
4475         print $OUT $@ and return;
4476     }
4477
4478     return;
4479 } ## end sub cmd_b_line
4480
4481 =head3 cmd_b_filename_line(line, [condition]) (command)
4482
4483 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4484 doesn't work.
4485
4486 =cut
4487
4488 sub cmd_b_filename_line {
4489     if (not eval { break_on_filename_line(@_); 1 }) {
4490         local $\ = '';
4491         print $OUT $@ and return;
4492     }
4493
4494     return;
4495 }
4496
4497 =head3 break_on_filename_line(file, line, [condition]) (API)
4498
4499 Switches to the file specified and then calls C<break_on_line> to set
4500 the breakpoint.
4501
4502 =cut
4503
4504 sub break_on_filename_line {
4505     my ( $f, $i, $cond ) = @_;
4506
4507     # Always true if condition left off.
4508     $cond = 1 unless @_ >= 3;
4509
4510     # Switch the magical hash temporarily.
4511     local *dbline = $main::{ '_<' . $f };
4512
4513     # Localize the variables that break_on_line uses to make its message.
4514     local $filename_error = " of '$f'";
4515     local $filename       = $f;
4516
4517     # Add the breakpoint.
4518     break_on_line( $i, $cond );
4519 } ## end sub break_on_filename_line
4520
4521 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4522
4523 Switch to another file, search the range of lines specified for an
4524 executable one, and put a breakpoint on the first one you find.
4525
4526 =cut
4527
4528 sub break_on_filename_line_range {
4529     my ( $f, $from, $to, $cond ) = @_;
4530
4531     # Find a breakable line if there is one.
4532     my $i = breakable_line_in_filename( $f, $from, $to );
4533
4534     # Always true if missing.
4535     $cond = 1 unless @_ >= 3;
4536
4537     # Add the breakpoint.
4538     break_on_filename_line( $f, $i, $cond );
4539 } ## end sub break_on_filename_line_range
4540
4541 =head3 subroutine_filename_lines(subname, [condition]) (API)
4542