installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $nonono $versiononly $depth);
  12
  13 BEGIN {
  14     $Is_VMS = $^O eq 'VMS';
  15     $Is_W32 = $^O eq 'MSWin32';
  16     $Is_OS2 = $^O eq 'os2';
  17     $Is_Cygwin = $^O eq 'cygwin';
  18     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  19 }
  20
  21 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  22
  23 use File::Find;
  24 use File::Compare;
  25 use File::Copy ();
  26 use File::Path ();
  27 use ExtUtils::Packlist;
  28 use Config;
  29 use subs qw(unlink link chmod);
  30 use vars qw($packlist);
  31
  32 # override the ones in the rest of the script
  33 sub mkpath {
  34     File::Path::mkpath(@_) unless $nonono;
  35 }
  36
  37 my $mainperldir = "/usr/bin";
  38 my $exe_ext = $Config{exe_ext};
  39
  40 # Allow ``make install PERLNAME=something_besides_perl'':
  41 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  42
  43 # This is the base used for versioned names, like "perl5.6.0".
  44 # It's separate because a common use of $PERLNAME is to install
  45 # perl as "perl5", if that's used as base for versioned files you
  46 # get "perl55.6.0".
  47 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  48                     ? $ENV{PERLNAME_VERBASE}
  49                     : $perl;
  50
  51 while (@ARGV) {
  52     $nonono = 1 if $ARGV[0] eq '-n';
  53     $versiononly = 1 if $ARGV[0] eq '-v';
  54     shift;
  55 }
  56
  57 my @scripts = qw(utils/c2ph utils/h2ph utils/h2xs utils/perlbug utils/perldoc
  58                 utils/pl2pm utils/splain utils/perlcc utils/dprofpp
  59                 x2p/s2p x2p/find2perl
  60                 pod/pod2man pod/pod2html pod/pod2latex pod/pod2text
  61                 pod/pod2usage pod/podchecker pod/podselect);
  62
  63 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
  64
  65 my @pods = (<pod/*.pod>);
  66
  67 # Specify here any .pm files that are actually architecture-dependent.
  68 # (Those included with XS extensions under ext/ are automatically
  69 # added later.)
  70 # Now that the default privlib has the full perl version number included,
  71 # we no longer have to play the trick of sticking version-specific .pm
  72 # files under the archlib directory.
  73 my %archpms = (
  74     Config => 1,
  75 );
  76
  77 if ($^O eq 'dos') {
  78     push(@scripts,'djgpp/fixpmain');
  79     $archpms{config} = $archpms{filehand} = 1;
  80 }
  81
  82 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
  83 {
  84         push(@scripts, map("$_.exe", @scripts));
  85 }
  86
  87 find(sub {
  88         if ("$File::Find::dir/$_" =~ m{^ext/[^/]+/(.*)\.pm$}) {
  89             (my $pm = $1) =~ s{^lib/}{};
  90             $archpms{$pm} = 1;
  91         }
  92     }, 'ext');
  93
  94 my $ver = $Config{version};
  95 my $release = substr($],0,3);   # Not used presently.
  96 my $patchlevel = substr($],3,2);
  97 die "Patchlevel of perl ($patchlevel)",
  98     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
  99         if $patchlevel != $Config{'PERL_VERSION'};
 100
 101 # Fetch some frequently-used items from %Config
 102 my $installbin = $Config{installbin};
 103 my $installscript = $Config{installscript};
 104 my $installprivlib = $Config{installprivlib};
 105 my $installarchlib = $Config{installarchlib};
 106 my $installsitelib = $Config{installsitelib};
 107 my $installsitearch = $Config{installsitearch};
 108 my $installman1dir = $Config{installman1dir};
 109 my $man1ext = $Config{man1ext};
 110 my $libperl = $Config{libperl};
 111 # Shared library and dynamic loading suffixes.
 112 my $so = $Config{so};
 113 my $dlext = $Config{dlext};
 114 my $dlsrc = $Config{dlsrc};
 115
 116 my $d_dosuid = $Config{d_dosuid};
 117 my $binexp = $Config{binexp};
 118
 119 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 120     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 121               \$installarchlib, \$installsitelib, \$installsitearch,
 122               \$installman1dir ) {
 123       $$_ = unixify($$_);  $$_ =~ s:/$::;
 124     }
 125 }
 126
 127 # Do some quick sanity checks.
 128
 129 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 130
 131    $installbin          || die "No installbin directory in config.sh\n";
 132 -d $installbin          || mkpath($installbin, 1, 0777);
 133 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 134 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 135         unless $installbin =~ m#^/afs/# || $nonono;
 136
 137 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 138 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 139
 140 -x 't/TEST'             || $Is_W32
 141                         || warn "WARNING: You've never run 'make test'!!!",
 142                                 "  (Installing anyway.)\n";
 143
 144 if ($Is_W32 or $Is_Cygwin) {
 145   my $perldll;
 146
 147 if ($Is_Cygwin) {
 148   $perldll = $libperl;
 149   $perldll =~ s/(\..*)?$/.$dlext/;
 150   if ($Config{useshrplib} eq 'true') {
 151     # install ld2 and perlld as well
 152     foreach ('ld2', 'perlld') {
 153       safe_unlink("$installbin/$_");
 154       copy("$_", "$installbin/$_");
 155       chmod(0755, "$installbin/$_");
 156     };
 157   };
 158 } else {
 159   $perldll = 'perl56.' . $dlext;
 160 }
 161
 162    if ($dlsrc ne "dl_none.xs") {
 163       -f $perldll || die "No perl DLL built\n";
 164    }
 165 # Install the DLL
 166
 167    safe_unlink("$installbin/$perldll");
 168    copy("$perldll", "$installbin/$perldll");
 169    chmod(0755, "$installbin/$perldll");
 170
 171 } # if ($Is_W32 or $Is_Cygwin)
 172
 173 # This will be used to store the packlist
 174 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 175
 176 # First we install the version-numbered executables.
 177
 178 if ($Is_VMS) {
 179     safe_unlink("$installbin/$perl$exe_ext");
 180     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 181     chmod(0755, "$installbin/$perl$exe_ext");
 182     safe_unlink("$installbin/${perl}shr$exe_ext");
 183     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 184     chmod(0755, "$installbin/${perl}shr$exe_ext");
 185 }
 186 elsif ($^O eq 'mpeix') {
 187     # MPE lacks hard links and requires that executables with special
 188     # capabilities reside in the MPE namespace.
 189     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 190     # Install the primary executable into the MPE namespace as perlpath.
 191     copy("perl$exe_ext", $Config{perlpath});
 192     chmod(0755, $Config{perlpath});
 193     # Create a backup copy with the version number.
 194     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 195 }
 196 elsif ($^O ne 'dos') {
 197     safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 198     copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 199     strip("$installbin/$perl_verbase$ver$exe_ext") if $^O =~ /^(rhapsody)$/;
 200     chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 201 }
 202 else {
 203     safe_unlink("$installbin/$perl.exe");
 204     copy("perl.exe", "$installbin/$perl.exe");
 205 }
 206
 207 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 208 if ($d_dosuid) {
 209     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 210     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 211 }
 212
 213 # Install library files.
 214
 215 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 216
 217 mkpath($installprivlib, 1, 0777);
 218 mkpath($installarchlib, 1, 0777);
 219 mkpath($installsitelib, 1, 0777) if ($installsitelib);
 220 mkpath($installsitearch, 1, 0777) if ($installsitearch);
 221
 222 if (chdir "lib") {
 223     $do_installarchlib = ! samepath($installarchlib, '.');
 224     $do_installprivlib = ! samepath($installprivlib, '.');
 225     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 226
 227     if ($do_installarchlib || $do_installprivlib) {
 228         find(\&installlib, '.');
 229     }
 230     chdir ".." || die "Can't cd back to source directory: $!\n";
 231 }
 232 else {
 233     warn "Can't cd to lib to install lib files: $!\n";
 234 }
 235
 236 # Install header files and libraries.
 237 mkpath("$installarchlib/CORE", 1, 0777);
 238 my @corefiles;
 239 if ($Is_VMS) {  # We did core file selection during build
 240     my $coredir = "lib/$Config{'arch'}/$ver";
 241     $coredir =~ tr/./_/;
 242     @corefiles = <$coredir/*.*>;
 243 }
 244 else {
 245     # [als] hard-coded 'libperl' name... not good!
 246     @corefiles = <*.h libperl*.*>;
 247
 248     # AIX needs perl.exp installed as well.
 249     push(@corefiles,'perl.exp') if $^O eq 'aix';
 250     if ($^O eq 'mpeix') {
 251         # MPE needs mpeixish.h installed as well.
 252         mkpath("$installarchlib/CORE/mpeix", 1, 0777);
 253         push(@corefiles,'mpeix/mpeixish.h');
 254     }
 255     # If they have built sperl.o...
 256     push(@corefiles,'sperl.o') if -f 'sperl.o';
 257 }
 258 foreach my $file (@corefiles) {
 259     # HP-UX (at least) needs to maintain execute permissions
 260     # on dynamically-loadable libraries. So we do it for all.
 261     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 262         if ($file =~ /\.(so|\Q$dlext\E)$/) {
 263             chmod(0555, "$installarchlib/CORE/$file");
 264             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody)$/;
 265         } else {
 266             chmod(0444, "$installarchlib/CORE/$file");
 267         }
 268     }
 269 }
 270
 271 # Install main perl executables
 272 # Make links to ordinary names if installbin directory isn't current directory.
 273
 274 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 275     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 276     if ($^O eq 'mpeix') {
 277         # MPE doesn't support hard links, so use a symlink.
 278         # We don't want another cloned copy.
 279         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 280     } else {
 281         link("$installbin/$perl_verbase$ver$exe_ext",
 282                 "$installbin/$perl$exe_ext");
 283     }
 284     link("$installbin/s$perl_verbase$ver$exe_ext",
 285             "$installbin/suid$perl$exe_ext")
 286       if $d_dosuid;
 287 }
 288
 289 # Offer to install perl in a "standard" location
 290
 291 my $mainperl_is_instperl = 0;
 292
 293 if ($Config{installusrbinperl} eq 'define' &&
 294     !$versiononly && !$nonono && !$Is_W32 && !$Is_VMS && -t STDIN && -t STDERR
 295         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 296     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 297     my($instperl)       = "$installbin/$perl$exe_ext";
 298     my($expinstperl)    = "$binexp/$perl$exe_ext";
 299
 300     # First make sure $usrbinperl is not already the same as the perl we
 301     # just installed.
 302     if (-x $usrbinperl) {
 303         # Try to be clever about mainperl being a symbolic link
 304         # to binexp/perl if binexp and installbin are different.
 305         $mainperl_is_instperl =
 306             samepath($usrbinperl, $instperl) ||
 307             samepath($usrbinperl, $expinstperl) ||
 308              (($binexp ne $installbin) &&
 309               (-l $usrbinperl) &&
 310               ((readlink $usrbinperl) eq $expinstperl));
 311     }
 312     if ((! $mainperl_is_instperl) &&
 313         (yn("Many scripts expect perl to be installed as $usrbinperl.\n" .
 314              "Do you wish to have $usrbinperl be the same as\n" .
 315              "$expinstperl? [y] ")))
 316     {
 317         unlink($usrbinperl);
 318         ( $Config{'d_link'} eq 'define' &&
 319           eval { CORE::link $instperl, $usrbinperl } )  ||
 320         eval { symlink $expinstperl, $usrbinperl }      ||
 321         copy($instperl, $usrbinperl);
 322
 323         $mainperl_is_instperl = 1;
 324     }
 325 }
 326
 327 # Make links to ordinary names if installbin directory isn't current directory.
 328
 329 if (!$versiononly && ! samepath($installbin, 'x2p')) {
 330     safe_unlink("$installbin/a2p$exe_ext");
 331     copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
 332     chmod(0755, "$installbin/a2p$exe_ext");
 333 }
 334
 335 # cppstdin is just a script, but it is architecture-dependent, so
 336 # it can't safely be shared.  Place it in $installbin.
 337 # Note that Configure doesn't build cppstin if it isn't needed, so
 338 # we skip this if cppstdin doesn't exist.
 339 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 340     safe_unlink("$installbin/cppstdin");
 341     copy("cppstdin", "$installbin/cppstdin");
 342     chmod(0755, "$installbin/cppstdin");
 343 }
 344
 345 # Install scripts.
 346
 347 mkpath($installscript, 1, 0777);
 348
 349 if (! $versiononly) {
 350     for (@scripts) {
 351         (my $base = $_) =~ s#.*/##;
 352         copy($_, "$installscript/$base");
 353         chmod(0755, "$installscript/$base");
 354     }
 355 }
 356
 357 # pstruct should be a link to c2ph
 358
 359 if (! $versiononly) {
 360     safe_unlink("$installscript/pstruct$scr_ext");
 361     if ($^O eq 'dos' or $Is_VMS) {
 362         copy("$installscript/c2ph$scr_ext", "$installscript/pstruct$scr_ext");
 363     } else {
 364         link("$installscript/c2ph$scr_ext", "$installscript/pstruct$scr_ext");
 365     }
 366 }
 367
 368 # Install pod pages.  Where? I guess in $installprivlib/pod
 369 # ($installprivlib/pods for cygwin).
 370
 371 my $pod = $Is_Cygwin ? 'pods' : 'pod';
 372 unless ( $versiononly && !($installprivlib =~ m/\Q$ver/)) {
 373     mkpath("${installprivlib}/$pod", 1, 0777);
 374
 375     # If Perl 5.003's perldiag.pod is there, rename it.
 376     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 377         read POD, $_, 4000;
 378         close POD;
 379         # Some of Perl 5.003's diagnostic messages ended with periods.
 380         if (/^=.*\.$/m) {
 381             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 382                                "${installprivlib}/$pod/perldiag-5.003.pod");
 383             print "  rename $from $to";
 384             rename($from, $to)
 385                 or warn "Couldn't rename $from to $to: $!\n"
 386                 unless $nonono;
 387         }
 388     }
 389
 390     for (@pods) {
 391         # $_ is a name like  pod/perl.pod
 392         (my $base = $_) =~ s#.*/##;
 393         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 394     }
 395
 396 }
 397
 398 # Check to make sure there aren't other perls around in installer's
 399 # path.  This is probably UNIX-specific.  Check all absolute directories
 400 # in the path except for where public executables are supposed to live.
 401 # Also skip $mainperl if the user opted to have it be a link to the
 402 # installed perl.
 403
 404 if (!$versiononly) {
 405     my ($path, @path);
 406     my $dirsep = ($Is_OS2 || $Is_W32) ? ';' : ':' ;
 407     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 408     @path = split(/$dirsep/, $path);
 409     if ($Is_VMS) {
 410         my $i = 0;
 411         while (exists $ENV{'DCL$PATH' . $i}) {
 412             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 413             push(@path,$dir);
 414         }
 415     }
 416     my @otherperls;
 417     my %otherperls;
 418     for (@path) {
 419         next unless m,^/,;
 420         # Use &samepath here because some systems have other dirs linked
 421         # to $mainperldir (like SunOS)
 422         next if samepath($_, $binexp);
 423         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 424         my $otherperl = "$_/$perl$exe_ext";
 425         next if $otherperls{$otherperl}++;
 426         push(@otherperls, $otherperl)
 427             if (-x $otherperl && ! -d $otherperl);
 428     }
 429     if (@otherperls) {
 430         print STDERR "\nWarning: $perl appears in your path in the following " .
 431             "locations beyond where\nwe just installed it:\n";
 432         for (@otherperls) {
 433             print STDERR "    ", $_, "\n";
 434         }
 435         print STDERR "\n";
 436     }
 437
 438 }
 439
 440 $packlist->write() unless $nonono;
 441 print "  Installation complete\n";
 442
 443 exit 0;
 444
 445 ###############################################################################
 446
 447 sub yn {
 448     my($prompt) = @_;
 449     my($answer);
 450     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 451     print $prompt;
 452     chop($answer = <STDIN>);
 453     $answer = $default if $answer =~ m/^\s*$/;
 454     ($answer =~ m/^[yY]/);
 455 }
 456
 457 sub unlink {
 458     my(@names) = @_;
 459     my($cnt) = 0;
 460
 461     return scalar(@names) if $Is_VMS;
 462
 463     foreach my $name (@names) {
 464         next unless -e $name;
 465         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin);
 466         print "  unlink $name\n";
 467         ( CORE::unlink($name) and ++$cnt
 468           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 469     }
 470     return $cnt;
 471 }
 472
 473 sub safe_unlink {
 474     return if $nonono or $Is_VMS;
 475     my @names = @_;
 476     foreach my $name (@names) {
 477         next unless -e $name;
 478         chmod 0777, $name if ($Is_OS2 || $Is_W32);
 479         print "  unlink $name\n";
 480         next if CORE::unlink($name);
 481         warn "Couldn't unlink $name: $!\n";
 482         if ($! =~ /busy/i) {
 483             print "  mv $name $name.old\n";
 484             safe_rename($name, "$name.old")
 485                 or warn "Couldn't rename $name: $!\n";
 486         }
 487     }
 488 }
 489
 490 sub safe_rename {
 491     my($from,$to) = @_;
 492     if (-f $to and not unlink($to)) {
 493         my($i);
 494         for ($i = 1; $i < 50; $i++) {
 495             last if rename($to, "$to.$i");
 496         }
 497         warn("Cannot rename to `$to.$i': $!"), return 0
 498            if $i >= 50; # Give up!
 499     }
 500     link($from,$to) || return 0;
 501     unlink($from);
 502 }
 503
 504 sub link {
 505     my($from,$to) = @_;
 506     my($success) = 0;
 507
 508     print "  ln $from $to\n";
 509     eval {
 510         CORE::link($from, $to)
 511             ? $success++
 512             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 513               ? die "AFS"  # okay inside eval {}
 514               : die "Couldn't link $from to $to: $!\n"
 515           unless $nonono;
 516         $packlist->{$to} = { from => $from, type => 'link' };
 517     };
 518     if ($@) {
 519         warn $@;
 520         print "  cp $from $to\n";
 521         print "  creating new version of $to\n" if $Is_VMS and -e $to;
 522         File::Copy::copy($from, $to)
 523             ? $success++
 524             : warn "Couldn't copy $from to $to: $!\n"
 525           unless $nonono;
 526         $packlist->{$to} = { type => 'file' };
 527     }
 528     $success;
 529 }
 530
 531 sub chmod {
 532     my($mode,$name) = @_;
 533
 534     return if ($^O eq 'dos');
 535     printf "  chmod %o %s\n", $mode, $name;
 536     CORE::chmod($mode,$name)
 537         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 538       unless $nonono;
 539 }
 540
 541 sub copy {
 542     my($from,$to) = @_;
 543
 544     print "  cp $from $to\n";
 545     print "  creating new version of $to\n" if $Is_VMS and -e $to;
 546     File::Copy::copy($from, $to)
 547         || warn "Couldn't copy $from to $to: $!\n"
 548       unless $nonono;
 549     $packlist->{$to} = { type => 'file' };
 550 }
 551
 552 sub samepath {
 553     my($p1, $p2) = @_;
 554
 555     return (lc($p1) eq lc($p2)) if $Is_W32;
 556
 557     if ($p1 ne $p2) {
 558         my($dev1, $ino1, $dev2, $ino2);
 559         ($dev1, $ino1) = stat($p1);
 560         ($dev2, $ino2) = stat($p2);
 561         ($dev1 == $dev2 && $ino1 == $ino2);
 562     }
 563     else {
 564         1;
 565     }
 566 }
 567
 568 sub installlib {
 569     my $dir = $File::Find::dir;
 570     $dir =~ s#^\.(?![^/])/?##;
 571     local($depth) = $dir ? "lib/$dir" : "lib";
 572
 573     my $name = $_;
 574
 575     # Ignore RCS and CVS directories.
 576     if (($name eq 'CVS' or $name eq 'RCS') and -d $name) {
 577         $File::Find::prune = 1;
 578         return;
 579     }
 580
 581     # ignore patch backups, RCS files, emacs backup & temp files and the
 582     # .exists files.
 583     return if $name =~ m{\.orig$|~$|^#.+#$|,v$|^\.exists};
 584
 585     $name = "$dir/$name" if $dir ne '';
 586
 587     my $installlib = $installprivlib;
 588     if ($dir =~ /^auto/ ||
 589           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 590           ($name =~ /^(.*)\.(?:h|lib)$/i && $Is_W32)
 591        ) {
 592         $installlib = $installarchlib;
 593         return unless $do_installarchlib;
 594     } else {
 595         return unless $do_installprivlib;
 596     }
 597
 598     if (-f $_) {
 599         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 600             $installlib = $installprivlib;
 601             #We're installing *.al and *.ix files into $installprivlib,
 602             #but we have to delete old *.al and *.ix files from the 5.000
 603             #distribution:
 604             #This might not work because $archname might have changed.
 605             unlink("$installarchlib/$name");
 606         }
 607         $packlist->{"$installlib/$name"} = { type => 'file' };
 608         if (compare($_, "$installlib/$name") || $nonono) {
 609             unlink("$installlib/$name");
 610             mkpath("$installlib/$dir", 1, 0777);
 611             # HP-UX (at least) needs to maintain execute permissions
 612             # on dynamically-loaded libraries.
 613             copy_if_diff($_, "$installlib/$name")
 614                 and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 615                            "$installlib/$name");
 616         }
 617     }
 618 }
 619
 620 # Copy $from to $to, only if $from is different than $to.
 621 # Also preserve modification times for .a libraries.
 622 # On some systems, if you do
 623 #   ranlib libperl.a
 624 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 625 # and then try to link against the installed libperl.a, you might
 626 # get an error message to the effect that the symbol table is older
 627 # than the library.
 628 # Return true if copying occurred.
 629
 630 sub copy_if_diff {
 631     my($from,$to)=@_;
 632     return 1 if (($^O eq 'VMS') && (-d $from));
 633     -f $from || die "$0: $from not found";
 634     $packlist->{$to} = { type => 'file' };
 635     if (compare($from, $to) || $nonono) {
 636         safe_unlink($to);   # In case we don't have write permissions.
 637         if ($nonono) {
 638             $from = $depth . "/" . $from if $depth;
 639         }
 640         copy($from, $to);
 641         # Restore timestamps if it's a .a library or for OS/2.
 642         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 643             my ($atime, $mtime) = (stat $from)[8,9];
 644             utime $atime, $mtime, $to;
 645         }
 646         1;
 647     }
 648 }
 649
 650 sub strip
 651 {
 652     my(@args) = @_;
 653
 654     my @opts;
 655     while (@args && $args[0] =~ /^(-\w+)$/) {
 656         push @opts, shift @args;
 657     }
 658
 659     foreach my $file (@args) {
 660         if (-f $file) {
 661             print "  strip $file\n";
 662             system("strip", @opts, $file);
 663         } else {
 664             print "# file '$file' skipped\n";
 665         }
 666     }
 667 }
 668