cpan/CPAN/lib/CPAN/HandleConfig.pm

   1 package CPAN::HandleConfig;
   2 use strict;
   3 use vars qw(%can %keys $loading $VERSION);
   4 use File::Path ();
   5 use File::Spec ();
   6 use File::Basename ();
   7 use Carp ();
   8
   9 =head1 NAME
  10
  11 CPAN::HandleConfig - internal configuration handling for CPAN.pm
  12
  13 =cut
  14
  15 $VERSION = "5.5005"; # see also CPAN::Config::VERSION at end of file
  16
  17 %can = (
  18         commit   => "Commit changes to disk",
  19         defaults => "Reload defaults from disk",
  20         help     => "Short help about 'o conf' usage",
  21         init     => "Interactive setting of all options",
  22 );
  23
  24 # Q: where is the "How do I add a new config option" HOWTO?
  25 # A1: svn diff -r 757:758 # where dagolden added test_report [git e997b71de88f1019a1472fc13cb97b1b7f96610f]
  26 # A2: svn diff -r 985:986 # where andk added yaml_module [git 312b6d9b12b1bdec0b6e282d853482145475021f]
  27 # A3: 1. add new config option to %keys below
  28 #     2. add a Pod description in CPAN::FirstTime; it should include a
  29 #        prompt line; see others for examples
  30 #     3. add a "matcher" section in CPAN::FirstTime::init that includes
  31 #        a prompt function; see others for examples
  32 #     4. add config option to documentation section in CPAN.pm
  33
  34 %keys = map { $_ => undef }
  35     (
  36      "applypatch",
  37      "auto_commit",
  38      "build_cache",
  39      "build_dir",
  40      "build_dir_reuse",
  41      "build_requires_install_policy",
  42      "bzip2",
  43      "cache_metadata",
  44      "check_sigs",
  45      "colorize_debug",
  46      "colorize_output",
  47      "colorize_print",
  48      "colorize_warn",
  49      "commandnumber_in_prompt",
  50      "commands_quote",
  51      "connect_to_internet_ok",
  52      "cpan_home",
  53      "curl",
  54      "dontload_hash", # deprecated after 1.83_68 (rev. 581)
  55      "dontload_list",
  56      "ftp",
  57      "ftp_passive",
  58      "ftp_proxy",
  59      "ftpstats_size",
  60      "ftpstats_period",
  61      "getcwd",
  62      "gpg",
  63      "gzip",
  64      "halt_on_failure",
  65      "histfile",
  66      "histsize",
  67      "http_proxy",
  68      "inactivity_timeout",
  69      "index_expire",
  70      "inhibit_startup_message",
  71      "keep_source_where",
  72      "load_module_verbosity",
  73      "lynx",
  74      "make",
  75      "make_arg",
  76      "make_install_arg",
  77      "make_install_make_command",
  78      "makepl_arg",
  79      "mbuild_arg",
  80      "mbuild_install_arg",
  81      "mbuild_install_build_command",
  82      "mbuildpl_arg",
  83      "ncftp",
  84      "ncftpget",
  85      "no_proxy",
  86      "pager",
  87      "password",
  88      "patch",
  89      "patches_dir",
  90      "perl5lib_verbosity",
  91      "plugin_list",
  92      "prefer_external_tar",
  93      "prefer_installer",
  94      "prefs_dir",
  95      "prerequisites_policy",
  96      "proxy_pass",
  97      "proxy_user",
  98      "randomize_urllist",
  99      "recommends_policy",
 100      "scan_cache",
 101      "shell",
 102      "show_unparsable_versions",
 103      "show_upload_date",
 104      "show_zero_versions",
 105      "suggests_policy",
 106      "tar",
 107      "tar_verbosity",
 108      "term_is_latin",
 109      "term_ornaments",
 110      "test_report",
 111      "trust_test_report_history",
 112      "unzip",
 113      "urllist",
 114      "use_prompt_default",
 115      "use_sqlite",
 116      "username",
 117      "version_timeout",
 118      "wait_list",
 119      "wget",
 120      "yaml_load_code",
 121      "yaml_module",
 122     );
 123
 124 my %prefssupport = map { $_ => 1 }
 125     (
 126      "build_requires_install_policy",
 127      "check_sigs",
 128      "make",
 129      "make_install_make_command",
 130      "prefer_installer",
 131      "test_report",
 132     );
 133
 134 # returns true on successful action
 135 sub edit {
 136     my($self,@args) = @_;
 137     return unless @args;
 138     CPAN->debug("self[$self]args[".join(" | ",@args)."]");
 139     my($o,$str,$func,$args,$key_exists);
 140     $o = shift @args;
 141     if($can{$o}) {
 142         my $success = $self->$o(args => \@args); # o conf init => sub init => sub load
 143         unless ($success) {
 144             die "Panic: could not configure CPAN.pm for args [@args]. Giving up.";
 145         }
 146     } else {
 147         CPAN->debug("o[$o]") if $CPAN::DEBUG;
 148         unless (exists $keys{$o}) {
 149             $CPAN::Frontend->mywarn("Warning: unknown configuration variable '$o'\n");
 150         }
 151         my $changed;
 152
 153
 154         # one day I used randomize_urllist for a boolean, so we must
 155         # list them explicitly --ak
 156         if (0) {
 157         } elsif ($o =~ /^(wait_list|urllist|dontload_list|plugin_list)$/) {
 158
 159             #
 160             # ARRAYS
 161             #
 162
 163             $func = shift @args;
 164             $func ||= "";
 165             CPAN->debug("func[$func]args[@args]") if $CPAN::DEBUG;
 166             # Let's avoid eval, it's easier to comprehend without.
 167             if ($func eq "push") {
 168                 push @{$CPAN::Config->{$o}}, @args;
 169                 $changed = 1;
 170             } elsif ($func eq "pop") {
 171                 pop @{$CPAN::Config->{$o}};
 172                 $changed = 1;
 173             } elsif ($func eq "shift") {
 174                 shift @{$CPAN::Config->{$o}};
 175                 $changed = 1;
 176             } elsif ($func eq "unshift") {
 177                 unshift @{$CPAN::Config->{$o}}, @args;
 178                 $changed = 1;
 179             } elsif ($func eq "splice") {
 180                 my $offset = shift @args || 0;
 181                 my $length = shift @args || 0;
 182                 splice @{$CPAN::Config->{$o}}, $offset, $length, @args; # may warn
 183                 $changed = 1;
 184             } elsif ($func) {
 185                 $CPAN::Config->{$o} = [$func, @args];
 186                 $changed = 1;
 187             } else {
 188                 $self->prettyprint($o);
 189             }
 190             if ($changed) {
 191                 if ($o eq "urllist") {
 192                     # reset the cached values
 193                     undef $CPAN::FTP::Thesite;
 194                     undef $CPAN::FTP::Themethod;
 195                     $CPAN::Index::LAST_TIME = 0;
 196                 } elsif ($o eq "dontload_list") {
 197                     # empty it, it will be built up again
 198                     $CPAN::META->{dontload_hash} = {};
 199                 }
 200             }
 201         } elsif ($o =~ /_hash$/) {
 202
 203             #
 204             # HASHES
 205             #
 206
 207             if (@args==1 && $args[0] eq "") {
 208                 @args = ();
 209             } elsif (@args % 2) {
 210                 push @args, "";
 211             }
 212             $CPAN::Config->{$o} = { @args };
 213             $changed = 1;
 214         } else {
 215
 216             #
 217             # SCALARS
 218             #
 219
 220             if (defined $args[0]) {
 221                 $CPAN::CONFIG_DIRTY = 1;
 222                 $CPAN::Config->{$o} = $args[0];
 223                 $changed = 1;
 224             }
 225             $self->prettyprint($o)
 226                 if exists $keys{$o} or defined $CPAN::Config->{$o};
 227         }
 228         if ($changed) {
 229             if ($CPAN::Config->{auto_commit}) {
 230                 $self->commit;
 231             } else {
 232                 $CPAN::CONFIG_DIRTY = 1;
 233                 $CPAN::Frontend->myprint("Please use 'o conf commit' to ".
 234                                          "make the config permanent!\n\n");
 235             }
 236         }
 237     }
 238 }
 239
 240 sub prettyprint {
 241     my($self,$k) = @_;
 242     my $v = $CPAN::Config->{$k};
 243     if (ref $v) {
 244         my(@report);
 245         if (ref $v eq "ARRAY") {
 246             @report = map {"\t$_ \[$v->[$_]]\n"} 0..$#$v;
 247         } else {
 248             @report = map
 249                 {
 250                     sprintf "\t%-18s => %s\n",
 251                                "[$_]",
 252                                         defined $v->{$_} ? "[$v->{$_}]" : "undef"
 253                 } keys %$v;
 254         }
 255         $CPAN::Frontend->myprint(
 256                                  join(
 257                                       "",
 258                                       sprintf(
 259                                               "    %-18s\n",
 260                                               $k
 261                                              ),
 262                                       @report
 263                                      )
 264                                 );
 265     } elsif (defined $v) {
 266         $CPAN::Frontend->myprint(sprintf "    %-18s [%s]\n", $k, $v);
 267     } else {
 268         $CPAN::Frontend->myprint(sprintf "    %-18s undef\n", $k);
 269     }
 270 }
 271
 272 # generally, this should be called without arguments so that the currently
 273 # loaded config file is where changes are committed.
 274 sub commit {
 275     my($self,@args) = @_;
 276     CPAN->debug("args[@args]") if $CPAN::DEBUG;
 277     if ($CPAN::RUN_DEGRADED) {
 278         $CPAN::Frontend->mydie(
 279             "'o conf commit' disabled in ".
 280             "degraded mode. Maybe try\n".
 281             " !undef \$CPAN::RUN_DEGRADED\n"
 282         );
 283     }
 284     my ($configpm, $must_reload);
 285
 286     # XXX does anything do this? can it be simplified? -- dagolden, 2011-01-19
 287     if (@args) {
 288       if ($args[0] eq "args") {
 289         # we have not signed that contract
 290       } else {
 291         $configpm = $args[0];
 292       }
 293     }
 294
 295     # use provided name or the current config or create a new MyConfig
 296     $configpm ||= require_myconfig_or_config() || make_new_config();
 297
 298     # commit to MyConfig if we can't write to Config
 299     if ( ! -w $configpm && $configpm =~ m{CPAN/Config\.pm} ) {
 300         my $myconfig = _new_config_name();
 301         $CPAN::Frontend->mywarn(
 302             "Your $configpm file\n".
 303             "is not writable. I will attempt to write your configuration to\n" .
 304             "$myconfig instead.\n\n"
 305         );
 306         $configpm = make_new_config();
 307         $must_reload++; # so it gets loaded as $INC{'CPAN/MyConfig.pm'}
 308     }
 309
 310     # XXX why not just "-w $configpm"? -- dagolden, 2011-01-19
 311     my($mode);
 312     if (-f $configpm) {
 313         $mode = (stat $configpm)[2];
 314         if ($mode && ! -w _) {
 315             _die_cant_write_config($configpm);
 316         }
 317     }
 318
 319     $self->_write_config_file($configpm);
 320     require_myconfig_or_config() if $must_reload;
 321
 322     #$mode = 0444 | ( $mode & 0111 ? 0111 : 0 );
 323     #chmod $mode, $configpm;
 324 ###why was that so?    $self->defaults;
 325     $CPAN::Frontend->myprint("commit: wrote '$configpm'\n");
 326     $CPAN::CONFIG_DIRTY = 0;
 327     1;
 328 }
 329
 330 sub _write_config_file {
 331     my ($self, $configpm) = @_;
 332     my $msg;
 333     $msg = <<EOF if $configpm =~ m{CPAN/Config\.pm};
 334
 335 # This is CPAN.pm's systemwide configuration file. This file provides
 336 # defaults for users, and the values can be changed in a per-user
 337 # configuration file.
 338
 339 EOF
 340     $msg ||= "\n";
 341     my($fh) = FileHandle->new;
 342     rename $configpm, "$configpm~" if -f $configpm;
 343     open $fh, ">$configpm" or
 344         $CPAN::Frontend->mydie("Couldn't open >$configpm: $!");
 345     $fh->print(qq[$msg\$CPAN::Config = \{\n]);
 346     foreach (sort keys %$CPAN::Config) {
 347         unless (exists $keys{$_}) {
 348             # do not drop them: forward compatibility!
 349             $CPAN::Frontend->mywarn("Unknown config variable '$_'\n");
 350             next;
 351         }
 352         $fh->print(
 353             "  '$_' => ",
 354             $self->neatvalue($CPAN::Config->{$_}),
 355             ",\n"
 356         );
 357     }
 358     $fh->print("};\n1;\n__END__\n");
 359     close $fh;
 360
 361     return;
 362 }
 363
 364
 365 # stolen from MakeMaker; not taking the original because it is buggy;
 366 # bugreport will have to say: keys of hashes remain unquoted and can
 367 # produce syntax errors
 368 sub neatvalue {
 369     my($self, $v) = @_;
 370     return "undef" unless defined $v;
 371     my($t) = ref $v;
 372     unless ($t) {
 373         $v =~ s/\\/\\\\/g;
 374         return "q[$v]";
 375     }
 376     if ($t eq 'ARRAY') {
 377         my(@m, @neat);
 378         push @m, "[";
 379         foreach my $elem (@$v) {
 380             push @neat, "q[$elem]";
 381         }
 382         push @m, join ", ", @neat;
 383         push @m, "]";
 384         return join "", @m;
 385     }
 386     return "$v" unless $t eq 'HASH';
 387     my(@m, $key, $val);
 388     while (($key,$val) = each %$v) {
 389         last unless defined $key; # cautious programming in case (undef,undef) is true
 390         push(@m,"q[$key]=>".$self->neatvalue($val)) ;
 391     }
 392     return "{ ".join(', ',@m)." }";
 393 }
 394
 395 sub defaults {
 396     my($self) = @_;
 397     if ($CPAN::RUN_DEGRADED) {
 398                              $CPAN::Frontend->mydie(
 399                                                     "'o conf defaults' disabled in ".
 400                                                     "degraded mode. Maybe try\n".
 401                                                     " !undef \$CPAN::RUN_DEGRADED\n"
 402                                                    );
 403     }
 404     my $done;
 405     for my $config (qw(CPAN/MyConfig.pm CPAN/Config.pm)) {
 406         if ($INC{$config}) {
 407             CPAN->debug("INC{'$config'}[$INC{$config}]") if $CPAN::DEBUG;
 408             CPAN::Shell->_reload_this($config,{reloforce => 1});
 409             $CPAN::Frontend->myprint("'$INC{$config}' reread\n");
 410             last;
 411         }
 412     }
 413     $CPAN::CONFIG_DIRTY = 0;
 414     1;
 415 }
 416
 417 =head2 C<< CLASS->safe_quote ITEM >>
 418
 419 Quotes an item to become safe against spaces
 420 in shell interpolation. An item is enclosed
 421 in double quotes if:
 422
 423   - the item contains spaces in the middle
 424   - the item does not start with a quote
 425
 426 This happens to avoid shell interpolation
 427 problems when whitespace is present in
 428 directory names.
 429
 430 This method uses C<commands_quote> to determine
 431 the correct quote. If C<commands_quote> is
 432 a space, no quoting will take place.
 433
 434
 435 if it starts and ends with the same quote character: leave it as it is
 436
 437 if it contains no whitespace: leave it as it is
 438
 439 if it contains whitespace, then
 440
 441 if it contains quotes: better leave it as it is
 442
 443 else: quote it with the correct quote type for the box we're on
 444
 445 =cut
 446
 447 {
 448     # Instead of patching the guess, set commands_quote
 449     # to the right value
 450     my ($quotes,$use_quote)
 451         = $^O eq 'MSWin32'
 452             ? ('"', '"')
 453                 : (q{"'}, "'")
 454                     ;
 455
 456     sub safe_quote {
 457         my ($self, $command) = @_;
 458         # Set up quote/default quote
 459         my $quote = $CPAN::Config->{commands_quote} || $quotes;
 460
 461         if ($quote ne ' '
 462             and defined($command )
 463             and $command =~ /\s/
 464             and $command !~ /[$quote]/) {
 465             return qq<$use_quote$command$use_quote>
 466         }
 467         return $command;
 468     }
 469 }
 470
 471 sub init {
 472     my($self,@args) = @_;
 473     CPAN->debug("self[$self]args[".join(",",@args)."]");
 474     $self->load(do_init => 1, @args);
 475     1;
 476 }
 477
 478 # Loads CPAN::MyConfig or fall-back to CPAN::Config. Will not reload a file
 479 # if already loaded. Returns the path to the file %INC or else the empty string
 480 #
 481 # Note -- if CPAN::Config were loaded and CPAN::MyConfig subsequently
 482 # created, calling this again will leave *both* in %INC
 483
 484 sub require_myconfig_or_config () {
 485     if (   $INC{"CPAN/MyConfig.pm"} || _try_loading("CPAN::MyConfig", cpan_home())) {
 486         return $INC{"CPAN/MyConfig.pm"};
 487     }
 488     elsif ( $INC{"CPAN/Config.pm"} || _try_loading("CPAN::Config") ) {
 489         return $INC{"CPAN/Config.pm"};
 490     }
 491     else {
 492         return q{};
 493     }
 494 }
 495
 496 # Load a module, but ignore "can't locate..." errors
 497 # Optionally take a list of directories to add to @INC for the load
 498 sub _try_loading {
 499     my ($module, @dirs) = @_;
 500     (my $file = $module) =~ s{::}{/}g;
 501     $file .= ".pm";
 502
 503     local @INC = @INC;
 504     for my $dir ( @dirs ) {
 505         if ( -f File::Spec->catfile($dir, $file) ) {
 506             unshift @INC, $dir;
 507             last;
 508         }
 509     }
 510
 511     eval { require $file };
 512     my $err_myconfig = $@;
 513     if ($err_myconfig and $err_myconfig !~ m#locate \Q$file\E#) {
 514         die "Error while requiring ${module}:\n$err_myconfig";
 515     }
 516     return $INC{$file};
 517 }
 518
 519 # prioritized list of possible places for finding "CPAN/MyConfig.pm"
 520 sub cpan_home_dir_candidates {
 521     my @dirs;
 522     my $old_v = $CPAN::Config->{load_module_verbosity};
 523     $CPAN::Config->{load_module_verbosity} = q[none];
 524     if ($CPAN::META->has_usable('File::HomeDir')) {
 525         if ($^O ne 'darwin') {
 526             push @dirs, File::HomeDir->my_data;
 527             # my_data is ~/Library/Application Support on darwin,
 528             # which causes issues in the toolchain.
 529         }
 530         push @dirs, File::HomeDir->my_home;
 531     }
 532     # Windows might not have HOME, so check it first
 533     push @dirs, $ENV{HOME} if $ENV{HOME};
 534     # Windows might have these instead
 535     push( @dirs, File::Spec->catpath($ENV{HOMEDRIVE}, $ENV{HOMEPATH}, '') )
 536       if $ENV{HOMEDRIVE} && $ENV{HOMEPATH};
 537     push @dirs, $ENV{USERPROFILE} if $ENV{USERPROFILE};
 538
 539     $CPAN::Config->{load_module_verbosity} = $old_v;
 540     my $dotcpan = $^O eq 'VMS' ? '_cpan' : '.cpan';
 541     @dirs = map { File::Spec->catdir($_, $dotcpan) } grep { defined } @dirs;
 542     return wantarray ? @dirs : $dirs[0];
 543 }
 544
 545 sub load {
 546     my($self, %args) = @_;
 547     $CPAN::Be_Silent+=0; # protect against 'used only once'
 548     $CPAN::Be_Silent++ if $args{be_silent}; # do not use; planned to be removed in 2011
 549     my $do_init = delete $args{do_init} || 0;
 550     my $make_myconfig = delete $args{make_myconfig};
 551     $loading = 0 unless defined $loading;
 552
 553     my $configpm = require_myconfig_or_config;
 554     my @miss = $self->missing_config_data;
 555     CPAN->debug("do_init[$do_init]loading[$loading]miss[@miss]") if $CPAN::DEBUG;
 556     return unless $do_init || @miss;
 557
 558     # I'm not how we'd ever wind up in a recursive loop, but I'm leaving
 559     # this here for safety's sake -- dagolden, 2011-01-19
 560     return if $loading;
 561     local $loading = ($loading||0) + 1;
 562
 563     # Warn if we have a config file, but things were found missing
 564     if ($configpm && @miss && !$do_init) {
 565         if ($make_myconfig || ( ! -w $configpm && $configpm =~ m{CPAN/Config\.pm})) {
 566             $configpm = make_new_config();
 567             $CPAN::Frontend->myprint(<<END);
 568 The system CPAN configuration file has provided some default values,
 569 but you need to complete the configuration dialog for CPAN.pm.
 570 Configuration will be written to
 571  <<$configpm>>
 572 END
 573         }
 574         else {
 575             $CPAN::Frontend->myprint(<<END);
 576 Sorry, we have to rerun the configuration dialog for CPAN.pm due to
 577 some missing parameters. Configuration will be written to
 578  <<$configpm>>
 579
 580 END
 581         }
 582     }
 583
 584     require CPAN::FirstTime;
 585     return CPAN::FirstTime::init($configpm || make_new_config(), %args);
 586 }
 587
 588 # Creates a new, empty config file at the preferred location
 589 # Any existing will be renamed with a ".bak" suffix if possible
 590 # If the file cannot be created, an exception is thrown
 591 sub make_new_config {
 592     my $configpm = _new_config_name();
 593     my $configpmdir = File::Basename::dirname( $configpm );
 594     File::Path::mkpath($configpmdir) unless -d $configpmdir;
 595
 596     if ( -w $configpmdir ) {
 597         #_#_# following code dumped core on me with 5.003_11, a.k.
 598         if( -f $configpm ) {
 599             my $configpm_bak = "$configpm.bak";
 600             unlink $configpm_bak if -f $configpm_bak;
 601             if( rename $configpm, $configpm_bak ) {
 602                 $CPAN::Frontend->mywarn(<<END);
 603 Old configuration file $configpm
 604     moved to $configpm_bak
 605 END
 606             }
 607         }
 608         my $fh = FileHandle->new;
 609         if ($fh->open(">$configpm")) {
 610             $fh->print("1;\n");
 611             return $configpm;
 612         }
 613     }
 614     _die_cant_write_config($configpm);
 615 }
 616
 617 sub _die_cant_write_config {
 618     my ($configpm) = @_;
 619     $CPAN::Frontend->mydie(<<"END");
 620 WARNING: CPAN.pm is unable to write a configuration file.  You
 621 must be able to create and write to '$configpm'.
 622
 623 Aborting configuration.
 624 END
 625
 626 }
 627
 628 # From candidate directories, we would like (in descending preference order):
 629 #   * the one that contains a MyConfig file
 630 #   * one that exists (even without MyConfig)
 631 #   * the first one on the list
 632 sub cpan_home {
 633     my @dirs = cpan_home_dir_candidates();
 634     for my $d (@dirs) {
 635         return $d if -f "$d/CPAN/MyConfig.pm";
 636     }
 637     for my $d (@dirs) {
 638         return $d if -d $d;
 639     }
 640     return $dirs[0];
 641 }
 642
 643 sub _new_config_name {
 644     return File::Spec->catfile(cpan_home(), 'CPAN', 'MyConfig.pm');
 645 }
 646
 647 # returns mandatory but missing entries in the Config
 648 sub missing_config_data {
 649     my(@miss);
 650     for (
 651          "auto_commit",
 652          "build_cache",
 653          "build_dir",
 654          "cache_metadata",
 655          "cpan_home",
 656          "ftp_proxy",
 657          #"gzip",
 658          "http_proxy",
 659          "index_expire",
 660          #"inhibit_startup_message",
 661          "keep_source_where",
 662          #"make",
 663          "make_arg",
 664          "make_install_arg",
 665          "makepl_arg",
 666          "mbuild_arg",
 667          "mbuild_install_arg",
 668          ($^O eq "MSWin32" ? "" : "mbuild_install_build_command"),
 669          "mbuildpl_arg",
 670          "no_proxy",
 671          #"pager",
 672          "prerequisites_policy",
 673          "scan_cache",
 674          #"tar",
 675          #"unzip",
 676          "urllist",
 677         ) {
 678         next unless exists $keys{$_};
 679         push @miss, $_ unless defined $CPAN::Config->{$_};
 680     }
 681     return @miss;
 682 }
 683
 684 sub help {
 685     $CPAN::Frontend->myprint(q[
 686 Known options:
 687   commit    commit session changes to disk
 688   defaults  reload default config values from disk
 689   help      this help
 690   init      enter a dialog to set all or a set of parameters
 691
 692 Edit key values as in the following (the "o" is a literal letter o):
 693   o conf build_cache 15
 694   o conf build_dir "/foo/bar"
 695   o conf urllist shift
 696   o conf urllist unshift ftp://ftp.foo.bar/
 697   o conf inhibit_startup_message 1
 698
 699 ]);
 700     1; #don't reprint CPAN::Config
 701 }
 702
 703 sub cpl {
 704     my($word,$line,$pos) = @_;
 705     $word ||= "";
 706     CPAN->debug("word[$word] line[$line] pos[$pos]") if $CPAN::DEBUG;
 707     my(@words) = split " ", substr($line,0,$pos+1);
 708     if (
 709         defined($words[2])
 710         and
 711         $words[2] =~ /list$/
 712         and
 713         (
 714         @words == 3
 715         ||
 716         @words == 4 && length($word)
 717         )
 718        ) {
 719         return grep /^\Q$word\E/, qw(splice shift unshift pop push);
 720     } elsif (defined($words[2])
 721              and
 722              $words[2] eq "init"
 723              and
 724             (
 725              @words == 3
 726              ||
 727              @words >= 4 && length($word)
 728             )) {
 729         return sort grep /^\Q$word\E/, keys %keys;
 730     } elsif (@words >= 4) {
 731         return ();
 732     }
 733     my %seen;
 734     my(@o_conf) =  sort grep { !$seen{$_}++ }
 735         keys %can,
 736             keys %$CPAN::Config,
 737                 keys %keys;
 738     return grep /^\Q$word\E/, @o_conf;
 739 }
 740
 741 sub prefs_lookup {
 742     my($self,$distro,$what) = @_;
 743
 744     if ($prefssupport{$what}) {
 745         return $CPAN::Config->{$what} unless
 746             $distro
 747                 and $distro->prefs
 748                     and $distro->prefs->{cpanconfig}
 749                         and defined $distro->prefs->{cpanconfig}{$what};
 750         return $distro->prefs->{cpanconfig}{$what};
 751     } else {
 752         $CPAN::Frontend->mywarn("Warning: $what not yet officially ".
 753                                 "supported for distroprefs, doing a normal lookup");
 754         return $CPAN::Config->{$what};
 755     }
 756 }
 757
 758
 759 {
 760     package
 761         CPAN::Config; ####::###### #hide from indexer
 762     # note: J. Nick Koston wrote me that they are using
 763     # CPAN::Config->commit although undocumented. I suggested
 764     # CPAN::Shell->o("conf","commit") even when ugly it is at least
 765     # documented
 766
 767     # that's why I added the CPAN::Config class with autoload and
 768     # deprecated warning
 769
 770     use strict;
 771     use vars qw($AUTOLOAD $VERSION);
 772     $VERSION = "5.5005";
 773
 774     # formerly CPAN::HandleConfig was known as CPAN::Config
 775     sub AUTOLOAD { ## no critic
 776         my $class = shift; # e.g. in dh-make-perl: CPAN::Config
 777         my($l) = $AUTOLOAD;
 778         $CPAN::Frontend->mywarn("Dispatching deprecated method '$l' to CPAN::HandleConfig\n");
 779         $l =~ s/.*:://;
 780         CPAN::HandleConfig->$l(@_);
 781     }
 782 }
 783
 784 1;
 785
 786 __END__
 787
 788 =head1 LICENSE
 789
 790 This program is free software; you can redistribute it and/or
 791 modify it under the same terms as Perl itself.
 792
 793 =cut
 794
 795 # Local Variables:
 796 # mode: cperl
 797 # cperl-indent-level: 4
 798 # End:
 799 # vim: ts=4 sts=4 sw=4: