This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
fa9c1686ad91e330fe00e0e896a324398c557807
[perl5.git] / regen / embed.pl
1 #!/usr/bin/perl -w
2
3 # Regenerate (overwriting only if changed):
4 #
5 #    embed.h
6 #    embedvar.h
7 #    global.sym
8 #    perlapi.c
9 #    perlapi.h
10 #    proto.h
11 #
12 # from information stored in
13 #
14 #    embed.fnc
15 #    intrpvar.h
16 #    perlvars.h
17 #    regen/opcodes
18 #
19 # Accepts the standard regen_lib -q and -v args.
20 #
21 # This script is normally invoked from regen.pl.
22
23 require 5.004;  # keep this compatible, an old perl is all we may have before
24                 # we build the new one
25
26 use strict;
27
28 BEGIN {
29     # Get function prototypes
30     require 'regen/regen_lib.pl';
31 }
32
33 my $SPLINT = 0; # Turn true for experimental splint support http://www.splint.org
34 my $unflagged_pointers;
35
36 #
37 # See database of global and static function prototypes in embed.fnc
38 # This is used to generate prototype headers under various configurations,
39 # export symbols lists for different platforms, and macros to provide an
40 # implicit interpreter context argument.
41 #
42
43 sub open_print_header {
44     my ($file, $quote) = @_;
45
46     return open_new($file, '>',
47                     { file => $file, style => '*', by => 'regen/embed.pl',
48                       from => ['data in embed.fnc', 'regen/embed.pl',
49                                'regen/opcodes', 'intrpvar.h', 'perlvars.h'],
50                       final => "\nEdit those files and run 'make regen_headers' to effect changes.\n",
51                       copyright => [1993 .. 2009], quote => $quote });
52 }
53
54 open IN, "embed.fnc" or die $!;
55
56 my @embed;
57 my (%has_va, %has_nocontext);
58
59 while (<IN>) {
60     chomp;
61     next if /^:/;
62     next if /^$/;
63     while (s|\\$||) {
64         $_ .= <IN>;
65         chomp;
66     }
67     s/\s+$//;
68     my @args;
69     if (/^\s*(#|$)/) {
70         @args = $_;
71     }
72     else {
73         @args = split /\s*\|\s*/, $_;
74         my $func = $args[2];
75         if ($func) {
76             ++$has_va{$func} if $args[-1] =~ /\.\.\./;
77             ++$has_nocontext{$1} if $func =~ /(.*)_nocontext/;
78         }
79     }
80     if (@args == 1 && $args[0] !~ /^#\s*(?:if|ifdef|ifndef|else|endif)/) {
81         die "Illegal line $. '$args[0]' in embed.fnc";
82     }
83     push @embed, \@args;
84 }
85
86 open IN, 'regen/opcodes' or die $!;
87 {
88     my %syms;
89
90     while (<IN>) {
91         chop;
92         next unless $_;
93         next if /^#/;
94         my (undef, undef, $check) = split /\t+/, $_;
95         ++$syms{$check};
96     }
97
98     foreach (keys %syms) {
99         # These are all indirectly referenced by globals.c.
100         push @embed, ['pR', 'OP *', $_, 'NN OP *o'];
101     }
102 }
103 close IN;
104
105 my (@core, @ext, @api);
106 {
107     # Cluster entries in embed.fnc that have the same #ifdef guards.
108     # Also, split out at the top level the three classes of functions.
109     my @state;
110     my %groups;
111     my $current;
112     foreach (@embed) {
113         if (@$_ > 1) {
114             push @$current, $_;
115             next;
116         }
117         $_->[0] =~ s/^#\s+/#/;
118         $_->[0] =~ /^\S*/;
119         $_->[0] =~ s/^#ifdef\s+(\S+)/#if defined($1)/;
120         $_->[0] =~ s/^#ifndef\s+(\S+)/#if !defined($1)/;
121         if ($_->[0] =~ /^#if\s*(.*)/) {
122             push @state, $1;
123         } elsif ($_->[0] =~ /^#else\s*$/) {
124             die "Unmatched #else in embed.fnc" unless @state;
125             $state[-1] = "!($state[-1])";
126         } elsif ($_->[0] =~ m!^#endif\s*(?:/\*.*\*/)?$!) {
127             die "Unmatched #endif in embed.fnc" unless @state;
128             pop @state;
129         } else {
130             die "Unhandled pre-processor directive '$_->[0]' in embed.fnc";
131         }
132         $current = \%groups;
133         # Nested #if blocks are effectively &&ed together
134         # For embed.fnc, ordering withing the && isn't relevant, so we can
135         # sort them to try to group more functions together.
136         my @sorted = sort @state;
137         while (my $directive = shift @sorted) {
138             $current->{$directive} ||= {};
139             $current = $current->{$directive};
140         }
141         $current->{''} ||= [];
142         $current = $current->{''};
143     }
144
145     sub add_level {
146         my ($level, $indent, $wanted) = @_;
147         my $funcs = $level->{''};
148         my @entries;
149         if ($funcs) {
150             if (!defined $wanted) {
151                 @entries = @$funcs;
152             } else {
153                 foreach (@$funcs) {
154                     if ($_->[0] =~ /A/) {
155                         push @entries, $_ if $wanted eq 'A';
156                     } elsif ($_->[0] =~ /E/) {
157                         push @entries, $_ if $wanted eq 'E';
158                     } else {
159                         push @entries, $_ if $wanted eq '';
160                     }
161                 }
162             }
163             @entries = sort {$a->[2] cmp $b->[2]} @entries;
164         }
165         foreach (sort grep {length $_} keys %$level) {
166             my @conditional = add_level($level->{$_}, $indent . '  ', $wanted);
167             push @entries,
168                 ["#${indent}if $_"], @conditional, ["#${indent}endif"]
169                     if @conditional;
170         }
171         return @entries;
172     }
173     @core = add_level(\%groups, '', '');
174     @ext = add_level(\%groups, '', 'E');
175     @api = add_level(\%groups, '', 'A');
176
177     @embed = add_level(\%groups, '');
178 }
179
180 # walk table providing an array of components in each line to
181 # subroutine, printing the result
182 sub walk_table (&@) {
183     my ($function, $filename) = @_;
184     my $F;
185     if (ref $filename) {        # filehandle
186         $F = $filename;
187     }
188     else {
189         $F = open_print_header($filename);
190     }
191     foreach (@embed) {
192         my @outs = &{$function}(@$_);
193         # $function->(@args) is not 5.003
194         print $F @outs;
195     }
196     unless (ref $filename) {
197         read_only_bottom_close_and_rename($F);
198     }
199 }
200
201 # generate proto.h
202 {
203     my $pr = open_print_header("proto.h");
204     print $pr "START_EXTERN_C\n";
205     my $ret;
206
207     foreach (@embed) {
208         if (@$_ == 1) {
209             print $pr "$_->[0]\n";
210             next;
211         }
212
213         my ($flags,$retval,$plain_func,@args) = @$_;
214         my @nonnull;
215         my $has_context = ( $flags !~ /n/ );
216         my $never_returns = ( $flags =~ /r/ );
217         my $commented_out = ( $flags =~ /m/ );
218         my $binarycompat = ( $flags =~ /b/ );
219         my $is_malloc = ( $flags =~ /a/ );
220         my $can_ignore = ( $flags !~ /R/ ) && !$is_malloc;
221         my @names_of_nn;
222         my $func;
223
224         my $splint_flags = "";
225         if ( $SPLINT && !$commented_out ) {
226             $splint_flags .= '/*@noreturn@*/ ' if $never_returns;
227             if ($can_ignore && ($retval ne 'void') && ($retval !~ /\*/)) {
228                 $retval .= " /*\@alt void\@*/";
229             }
230         }
231
232         if ($flags =~ /([si])/) {
233             my $type = ($1 eq 's') ? "STATIC" : "PERL_STATIC_INLINE";
234             warn "$func: i and s flags are mutually exclusive"
235                                             if $flags =~ /s/ && $flags =~ /i/;
236             $retval = "$type $splint_flags$retval";
237             $func = "S_$plain_func";
238         }
239         else {
240             $retval = "PERL_CALLCONV $splint_flags$retval";
241             if ($flags =~ /[bp]/) {
242                 $func = "Perl_$plain_func";
243             } else {
244                 $func = $plain_func;
245             }
246         }
247         $ret = "$retval\t$func(";
248         if ( $has_context ) {
249             $ret .= @args ? "pTHX_ " : "pTHX";
250         }
251         if (@args) {
252             my $n;
253             for my $arg ( @args ) {
254                 ++$n;
255                 if ( $arg =~ /\*/ && $arg !~ /\b(NN|NULLOK)\b/ ) {
256                     warn "$func: $arg needs NN or NULLOK\n";
257                     ++$unflagged_pointers;
258                 }
259                 my $nn = ( $arg =~ s/\s*\bNN\b\s+// );
260                 push( @nonnull, $n ) if $nn;
261
262                 my $nullok = ( $arg =~ s/\s*\bNULLOK\b\s+// ); # strip NULLOK with no effect
263
264                 # Make sure each arg has at least a type and a var name.
265                 # An arg of "int" is valid C, but want it to be "int foo".
266                 my $temp_arg = $arg;
267                 $temp_arg =~ s/\*//g;
268                 $temp_arg =~ s/\s*\bstruct\b\s*/ /g;
269                 if ( ($temp_arg ne "...")
270                      && ($temp_arg !~ /\w+\s+(\w+)(?:\[\d+\])?\s*$/) ) {
271                     warn "$func: $arg ($n) doesn't have a name\n";
272                 }
273                 if ( $SPLINT && $nullok && !$commented_out ) {
274                     $arg = '/*@null@*/ ' . $arg;
275                 }
276                 if (defined $1 && $nn && !($commented_out && !$binarycompat)) {
277                     push @names_of_nn, $1;
278                 }
279             }
280             $ret .= join ", ", @args;
281         }
282         else {
283             $ret .= "void" if !$has_context;
284         }
285         $ret .= ")";
286         my @attrs;
287         if ( $flags =~ /r/ ) {
288             push @attrs, "__attribute__noreturn__";
289         }
290         if ( $flags =~ /D/ ) {
291             push @attrs, "__attribute__deprecated__";
292         }
293         if ( $is_malloc ) {
294             push @attrs, "__attribute__malloc__";
295         }
296         if ( !$can_ignore ) {
297             push @attrs, "__attribute__warn_unused_result__";
298         }
299         if ( $flags =~ /P/ ) {
300             push @attrs, "__attribute__pure__";
301         }
302         if( $flags =~ /f/ ) {
303             my $prefix  = $has_context ? 'pTHX_' : '';
304             my $args    = scalar @args;
305             my $pat     = $args - 1;
306             my $macro   = @nonnull && $nonnull[-1] == $pat  
307                                 ? '__attribute__format__'
308                                 : '__attribute__format__null_ok__';
309             push @attrs, sprintf "%s(__printf__,%s%d,%s%d)", $macro,
310                                 $prefix, $pat, $prefix, $args;
311         }
312         if ( @nonnull ) {
313             my @pos = map { $has_context ? "pTHX_$_" : $_ } @nonnull;
314             push @attrs, map { sprintf( "__attribute__nonnull__(%s)", $_ ) } @pos;
315         }
316         if ( @attrs ) {
317             $ret .= "\n";
318             $ret .= join( "\n", map { "\t\t\t$_" } @attrs );
319         }
320         $ret .= ";";
321         $ret = "/* $ret */" if $commented_out;
322         if (@names_of_nn) {
323             $ret .= "\n#define PERL_ARGS_ASSERT_\U$plain_func\E\t\\\n\t"
324                 . join '; ', map "assert($_)", @names_of_nn;
325         }
326         $ret .= @attrs ? "\n\n" : "\n";
327
328         print $pr $ret;
329     }
330
331     print $pr <<'EOF';
332 #ifdef PERL_CORE
333 #  include "pp_proto.h"
334 #endif
335 END_EXTERN_C
336 EOF
337
338     read_only_bottom_close_and_rename($pr);
339 }
340
341 # generates global.sym (API export list)
342 {
343   my %seen;
344   sub write_global_sym {
345       if (@_ > 1) {
346           my ($flags,$retval,$func,@args) = @_;
347           if ($flags =~ /[AX]/ && $flags !~ /[xm]/
348               || $flags =~ /b/) { # public API, so export
349               # If a function is defined twice, for example before and after
350               # an #else, only export its name once.
351               return '' if $seen{$func}++;
352               $func = "Perl_$func" if $flags =~ /[pbX]/;
353               return "$func\n";
354           }
355       }
356       return '';
357   }
358 }
359
360 warn "$unflagged_pointers pointer arguments to clean up\n" if $unflagged_pointers;
361 walk_table(\&write_global_sym, "global.sym");
362
363 sub readvars {
364     my ($file, $pre) = @_;
365     local (*FILE, $_);
366     my %seen;
367     open(FILE, "< $file")
368         or die "embed.pl: Can't open $file: $!\n";
369     while (<FILE>) {
370         s/[ \t]*#.*//;          # Delete comments.
371         if (/PERLVARA?I?C?\($pre(\w+)/) {
372             warn "duplicate symbol $1 while processing $file line $.\n"
373                 if $seen{$1}++;
374         }
375     }
376     close(FILE);
377     return sort keys %seen;
378 }
379
380 my @intrp = readvars 'intrpvar.h','I';
381 my @globvar = readvars 'perlvars.h','G';
382
383 sub undefine ($) {
384     my ($sym) = @_;
385     "#undef  $sym\n";
386 }
387
388 sub hide {
389     my ($from, $to, $indent) = @_;
390     $indent = '' unless defined $indent;
391     my $t = int(length("$indent$from") / 8);
392     "#${indent}define $from" . "\t" x ($t < 3 ? 3 - $t : 1) . "$to\n";
393 }
394
395 sub bincompat_var ($$) {
396     my ($pfx, $sym) = @_;
397     my $arg = ($pfx eq 'G' ? 'NULL' : 'aTHX');
398     undefine("PL_$sym") . hide("PL_$sym", "(*Perl_${pfx}${sym}_ptr($arg))");
399 }
400
401 sub multon ($$$) {
402     my ($sym,$pre,$ptr) = @_;
403     hide("PL_$sym", "($ptr$pre$sym)");
404 }
405
406 sub multoff ($$) {
407     my ($sym,$pre) = @_;
408     return hide("PL_$pre$sym", "PL_$sym");
409 }
410
411 my $em = open_print_header('embed.h');
412
413 print $em <<'END';
414 /* (Doing namespace management portably in C is really gross.) */
415
416 /* By defining PERL_NO_SHORT_NAMES (not done by default) the short forms
417  * (like warn instead of Perl_warn) for the API are not defined.
418  * Not defining the short forms is a good thing for cleaner embedding. */
419
420 #ifndef PERL_NO_SHORT_NAMES
421
422 /* Hide global symbols */
423
424 END
425
426 my @az = ('a'..'z');
427
428 sub embed_h {
429     my ($guard, $funcs) = @_;
430     print $em "$guard\n" if $guard;
431
432     my $lines;
433     foreach (@$funcs) {
434         if (@$_ == 1) {
435             my $cond = $_->[0];
436             # Indent the conditionals if we are wrapped in an #if/#endif pair.
437             $cond =~ s/#(.*)/#  $1/ if $guard;
438             $lines .= "$cond\n";
439             next;
440         }
441         my $ret = "";
442         my ($flags,$retval,$func,@args) = @$_;
443         unless ($flags =~ /[om]/) {
444             my $args = scalar @args;
445             if ($flags =~ /n/) {
446                 if ($flags =~ /s/) {
447                     $ret = hide($func,"S_$func");
448                 }
449                 elsif ($flags =~ /p/) {
450                     $ret = hide($func,"Perl_$func");
451                 }
452             }
453             elsif ($args and $args[$args-1] =~ /\.\.\./) {
454                 if ($flags =~ /p/) {
455                     # we're out of luck for varargs functions under CPP
456                     # So we can only do these macros for no implicit context:
457                     $ret = "#ifndef PERL_IMPLICIT_CONTEXT\n"
458                         . hide($func,"Perl_$func") . "#endif\n";
459                 }
460             }
461             else {
462                 my $alist = join(",", @az[0..$args-1]);
463                 $ret = "#define $func($alist)";
464                 my $t = int(length($ret) / 8);
465                 $ret .=  "\t" x ($t < 4 ? 4 - $t : 1);
466                 if ($flags =~ /[si]/) {
467                     $ret .= "S_$func(aTHX";
468                 }
469                 elsif ($flags =~ /p/) {
470                     $ret .= "Perl_$func(aTHX";
471                 }
472                 $ret .= "_ " if $alist;
473                 $ret .= $alist . ")\n";
474             }
475         }
476         $lines .= $ret;
477     }
478     # Prune empty #if/#endif pairs.
479     while ($lines =~ s/#\s*if[^\n]+\n#\s*endif\n//) {
480     }
481     # Merge adjacent blocks.
482     while ($lines =~ s/(#ifndef PERL_IMPLICIT_CONTEXT
483 [^\n]+
484 )#endif
485 #ifndef PERL_IMPLICIT_CONTEXT
486 /$1/) {
487     }
488
489     print $em $lines;
490     print $em "#endif\n" if $guard;
491 }
492
493 embed_h('', \@api);
494 embed_h('#if defined(PERL_CORE) || defined(PERL_EXT)', \@ext);
495 embed_h('#ifdef PERL_CORE', \@core);
496
497 print $em <<'END';
498
499 #endif  /* #ifndef PERL_NO_SHORT_NAMES */
500
501 /* Compatibility stubs.  Compile extensions with -DPERL_NOCOMPAT to
502    disable them.
503  */
504
505 #if !defined(PERL_CORE)
506 #  define sv_setptrobj(rv,ptr,name)     sv_setref_iv(rv,name,PTR2IV(ptr))
507 #  define sv_setptrref(rv,ptr)          sv_setref_iv(rv,NULL,PTR2IV(ptr))
508 #endif
509
510 #if !defined(PERL_CORE) && !defined(PERL_NOCOMPAT)
511
512 /* Compatibility for various misnamed functions.  All functions
513    in the API that begin with "perl_" (not "Perl_") take an explicit
514    interpreter context pointer.
515    The following are not like that, but since they had a "perl_"
516    prefix in previous versions, we provide compatibility macros.
517  */
518 #  define perl_atexit(a,b)              call_atexit(a,b)
519 END
520
521 walk_table {
522     my ($flags,$retval,$func,@args) = @_;
523     return unless $func;
524     return unless $flags =~ /O/;
525
526     my $alist = join ",", @az[0..$#args];
527     my $ret = "#  define perl_$func($alist)";
528     my $t = (length $ret) >> 3;
529     $ret .=  "\t" x ($t < 5 ? 5 - $t : 1);
530     "$ret$func($alist)\n";
531 } $em;
532
533 print $em <<'END';
534
535 /* varargs functions can't be handled with CPP macros. :-(
536    This provides a set of compatibility functions that don't take
537    an extra argument but grab the context pointer using the macro
538    dTHX.
539  */
540 #if defined(PERL_IMPLICIT_CONTEXT) && !defined(PERL_NO_SHORT_NAMES)
541 END
542
543 foreach (sort keys %has_va) {
544     next unless $has_nocontext{$_};
545     next if /printf/; # Not clear to me why these are skipped but they are.
546     print $em hide($_, "Perl_${_}_nocontext", "  ");
547 }
548
549 print $em <<'END';
550 #endif
551
552 #endif /* !defined(PERL_CORE) && !defined(PERL_NOCOMPAT) */
553
554 #if !defined(PERL_IMPLICIT_CONTEXT)
555 /* undefined symbols, point them back at the usual ones */
556 END
557
558 foreach (sort keys %has_va) {
559     next unless $has_nocontext{$_};
560     next if /printf/; # Not clear to me why these are skipped but they are.
561     print $em hide("Perl_${_}_nocontext", "Perl_$_", "  ");
562 }
563
564 print $em <<'END';
565 #endif
566 END
567
568 read_only_bottom_close_and_rename($em);
569
570 $em = open_print_header('embedvar.h');
571
572 print $em <<'END';
573 /* (Doing namespace management portably in C is really gross.) */
574
575 /*
576    The following combinations of MULTIPLICITY and PERL_IMPLICIT_CONTEXT
577    are supported:
578      1) none
579      2) MULTIPLICITY    # supported for compatibility
580      3) MULTIPLICITY && PERL_IMPLICIT_CONTEXT
581
582    All other combinations of these flags are errors.
583
584    only #3 is supported directly, while #2 is a special
585    case of #3 (supported by redefining vTHX appropriately).
586 */
587
588 #if defined(MULTIPLICITY)
589 /* cases 2 and 3 above */
590
591 #  if defined(PERL_IMPLICIT_CONTEXT)
592 #    define vTHX        aTHX
593 #  else
594 #    define vTHX        PERL_GET_INTERP
595 #  endif
596
597 END
598
599 my $sym;
600
601 for $sym (@intrp) {
602     print $em multon($sym,'I','vTHX->');
603 }
604
605 print $em <<'END';
606
607 #else   /* !MULTIPLICITY */
608
609 /* case 1 above */
610
611 END
612
613 for $sym (@intrp) {
614     print $em multoff($sym,'I');
615 }
616
617 print $em <<'END';
618
619 END
620
621 print $em <<'END';
622
623 #endif  /* MULTIPLICITY */
624
625 #if defined(PERL_GLOBAL_STRUCT)
626
627 END
628
629 for $sym (@globvar) {
630     print $em "#ifdef OS2\n" if $sym eq 'sh_path';
631     print $em multon($sym,   'G','my_vars->');
632     print $em multon("G$sym",'', 'my_vars->');
633     print $em "#endif\n" if $sym eq 'sh_path';
634 }
635
636 print $em <<'END';
637
638 #else /* !PERL_GLOBAL_STRUCT */
639
640 END
641
642 for $sym (@globvar) {
643     print $em "#ifdef OS2\n" if $sym eq 'sh_path';
644     print $em multoff($sym,'G');
645     print $em "#endif\n" if $sym eq 'sh_path';
646 }
647
648 print $em <<'END';
649
650 #endif /* PERL_GLOBAL_STRUCT */
651 END
652
653 read_only_bottom_close_and_rename($em);
654
655 my $capih = open_print_header('perlapi.h');
656
657 print $capih <<'EOT';
658 /* declare accessor functions for Perl variables */
659 #ifndef __perlapi_h__
660 #define __perlapi_h__
661
662 #if defined (MULTIPLICITY) && defined (PERL_GLOBAL_STRUCT)
663
664 START_EXTERN_C
665
666 #undef PERLVAR
667 #undef PERLVARA
668 #undef PERLVARI
669 #undef PERLVARIC
670 #define PERLVAR(v,t)    EXTERN_C t* Perl_##v##_ptr(pTHX);
671 #define PERLVARA(v,n,t) typedef t PL_##v##_t[n];                        \
672                         EXTERN_C PL_##v##_t* Perl_##v##_ptr(pTHX);
673 #define PERLVARI(v,t,i) PERLVAR(v,t)
674 #define PERLVARIC(v,t,i) PERLVAR(v, const t)
675
676 #include "perlvars.h"
677
678 #undef PERLVAR
679 #undef PERLVARA
680 #undef PERLVARI
681 #undef PERLVARIC
682
683 END_EXTERN_C
684
685 #if defined(PERL_CORE)
686
687 /* accessor functions for Perl "global" variables */
688
689 /* these need to be mentioned here, or most linkers won't put them in
690    the perl executable */
691
692 #ifndef PERL_NO_FORCE_LINK
693
694 START_EXTERN_C
695
696 #ifndef DOINIT
697 EXTCONST void * const PL_force_link_funcs[];
698 #else
699 EXTCONST void * const PL_force_link_funcs[] = {
700 #undef PERLVAR
701 #undef PERLVARA
702 #undef PERLVARI
703 #undef PERLVARIC
704 #define PERLVAR(v,t)    (void*)Perl_##v##_ptr,
705 #define PERLVARA(v,n,t) PERLVAR(v,t)
706 #define PERLVARI(v,t,i) PERLVAR(v,t)
707 #define PERLVARIC(v,t,i) PERLVAR(v,t)
708
709 /* In Tru64 (__DEC && __osf__) the cc option -std1 causes that one
710  * cannot cast between void pointers and function pointers without
711  * info level warnings.  The PL_force_link_funcs[] would cause a few
712  * hundred of those warnings.  In code one can circumnavigate this by using
713  * unions that overlay the different pointers, but in declarations one
714  * cannot use this trick.  Therefore we just disable the warning here
715  * for the duration of the PL_force_link_funcs[] declaration. */
716
717 #if defined(__DECC) && defined(__osf__)
718 #pragma message save
719 #pragma message disable (nonstandcast)
720 #endif
721
722 #include "perlvars.h"
723
724 #if defined(__DECC) && defined(__osf__)
725 #pragma message restore
726 #endif
727
728 #undef PERLVAR
729 #undef PERLVARA
730 #undef PERLVARI
731 #undef PERLVARIC
732 };
733 #endif  /* DOINIT */
734
735 END_EXTERN_C
736
737 #endif  /* PERL_NO_FORCE_LINK */
738
739 #else   /* !PERL_CORE */
740
741 EOT
742
743 foreach $sym (@globvar) {
744     print $capih bincompat_var('G',$sym);
745 }
746
747 print $capih <<'EOT';
748
749 #endif /* !PERL_CORE */
750 #endif /* MULTIPLICITY && PERL_GLOBAL_STRUCT */
751
752 #endif /* __perlapi_h__ */
753 EOT
754
755 read_only_bottom_close_and_rename($capih);
756
757 my $capi = open_print_header('perlapi.c', <<'EOQ');
758  *
759  *
760  * Up to the threshold of the door there mounted a flight of twenty-seven
761  * broad stairs, hewn by some unknown art of the same black stone.  This
762  * was the only entrance to the tower; ...
763  *
764  *     [p.577 of _The Lord of the Rings_, III/x: "The Voice of Saruman"]
765  *
766  */
767 EOQ
768
769 print $capi <<'EOT';
770 #include "EXTERN.h"
771 #include "perl.h"
772 #include "perlapi.h"
773
774 #if defined (MULTIPLICITY) && defined (PERL_GLOBAL_STRUCT)
775
776 /* accessor functions for Perl "global" variables */
777 START_EXTERN_C
778
779 #undef PERLVARI
780 #define PERLVARI(v,t,i) PERLVAR(v,t)
781
782 #undef PERLVAR
783 #undef PERLVARA
784 #define PERLVAR(v,t)    t* Perl_##v##_ptr(pTHX)                         \
785                         { dVAR; PERL_UNUSED_CONTEXT; return &(PL_##v); }
786 #define PERLVARA(v,n,t) PL_##v##_t* Perl_##v##_ptr(pTHX)                \
787                         { dVAR; PERL_UNUSED_CONTEXT; return &(PL_##v); }
788 #undef PERLVARIC
789 #define PERLVARIC(v,t,i)        \
790                         const t* Perl_##v##_ptr(pTHX)           \
791                         { PERL_UNUSED_CONTEXT; return (const t *)&(PL_##v); }
792 #include "perlvars.h"
793
794 #undef PERLVAR
795 #undef PERLVARA
796 #undef PERLVARI
797 #undef PERLVARIC
798
799 END_EXTERN_C
800
801 #endif /* MULTIPLICITY && PERL_GLOBAL_STRUCT */
802 EOT
803
804 read_only_bottom_close_and_rename($capi);
805
806 # ex: set ts=8 sts=4 sw=4 noet: