This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
point out another use for //o
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 =head2 Operator Precedence and Associativity
9 X<operator, precedence> X<precedence> X<associativity>
10
11 Operator precedence and associativity work in Perl more or less like
12 they do in mathematics.
13
14 I<Operator precedence> means some operators are evaluated before
15 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
16 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
17 22> and not C<6 * 5 == 30>.
18
19 I<Operator associativity> defines what happens if a sequence of the
20 same operators is used one after another: whether the evaluator will
21 evaluate the left operations first or the right.  For example, in C<8
22 - 4 - 2>, subtraction is left associative so Perl evaluates the
23 expression left to right.  C<8 - 4> is evaluated first making the
24 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
25
26 Perl operators have the following associativity and precedence,
27 listed from highest precedence to lowest.  Operators borrowed from
28 C keep the same precedence relationship with each other, even where
29 C's precedence is slightly screwy.  (This makes learning Perl easier
30 for C folks.)  With very few exceptions, these all operate on scalar
31 values only, not array values.
32
33     left        terms and list operators (leftward)
34     left        ->
35     nonassoc    ++ --
36     right       **
37     right       ! ~ \ and unary + and -
38     left        =~ !~
39     left        * / % x
40     left        + - .
41     left        << >>
42     nonassoc    named unary operators
43     nonassoc    < > <= >= lt gt le ge
44     nonassoc    == != <=> eq ne cmp ~~
45     left        &
46     left        | ^
47     left        &&
48     left        || //
49     nonassoc    ..  ...
50     right       ?:
51     right       = += -= *= etc.
52     left        , =>
53     nonassoc    list operators (rightward)
54     right       not
55     left        and
56     left        or xor
57
58 In the following sections, these operators are covered in precedence order.
59
60 Many operators can be overloaded for objects.  See L<overload>.
61
62 =head2 Terms and List Operators (Leftward)
63 X<list operator> X<operator, list> X<term>
64
65 A TERM has the highest precedence in Perl.  They include variables,
66 quote and quote-like operators, any expression in parentheses,
67 and any function whose arguments are parenthesized.  Actually, there
68 aren't really functions in this sense, just list operators and unary
69 operators behaving as functions because you put parentheses around
70 the arguments.  These are all documented in L<perlfunc>.
71
72 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
73 is followed by a left parenthesis as the next token, the operator and
74 arguments within parentheses are taken to be of highest precedence,
75 just like a normal function call.
76
77 In the absence of parentheses, the precedence of list operators such as
78 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
79 whether you are looking at the left side or the right side of the operator.
80 For example, in
81
82     @ary = (1, 3, sort 4, 2);
83     print @ary;         # prints 1324
84
85 the commas on the right of the sort are evaluated before the sort,
86 but the commas on the left are evaluated after.  In other words,
87 list operators tend to gobble up all arguments that follow, and
88 then act like a simple TERM with regard to the preceding expression.
89 Be careful with parentheses:
90
91     # These evaluate exit before doing the print:
92     print($foo, exit);  # Obviously not what you want.
93     print $foo, exit;   # Nor is this.
94
95     # These do the print before evaluating exit:
96     (print $foo), exit; # This is what you want.
97     print($foo), exit;  # Or this.
98     print ($foo), exit; # Or even this.
99
100 Also note that
101
102     print ($foo & 255) + 1, "\n";
103
104 probably doesn't do what you expect at first glance.  The parentheses
105 enclose the argument list for C<print> which is evaluated (printing
106 the result of C<$foo & 255>).  Then one is added to the return value
107 of C<print> (usually 1).  The result is something like this:
108
109     1 + 1, "\n";    # Obviously not what you meant.
110
111 To do what you meant properly, you must write:
112
113     print(($foo & 255) + 1, "\n");
114
115 See L<Named Unary Operators> for more discussion of this.
116
117 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
118 well as subroutine and method calls, and the anonymous
119 constructors C<[]> and C<{}>.
120
121 See also L<Quote and Quote-like Operators> toward the end of this section,
122 as well as L</"I/O Operators">.
123
124 =head2 The Arrow Operator
125 X<arrow> X<dereference> X<< -> >>
126
127 "C<< -> >>" is an infix dereference operator, just as it is in C
128 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
129 C<(...)> subscript, then the left side must be either a hard or
130 symbolic reference to an array, a hash, or a subroutine respectively.
131 (Or technically speaking, a location capable of holding a hard
132 reference, if it's an array or hash reference being used for
133 assignment.)  See L<perlreftut> and L<perlref>.
134
135 Otherwise, the right side is a method name or a simple scalar
136 variable containing either the method name or a subroutine reference,
137 and the left side must be either an object (a blessed reference)
138 or a class name (that is, a package name).  See L<perlobj>.
139
140 =head2 Auto-increment and Auto-decrement
141 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
142
143 "++" and "--" work as in C.  That is, if placed before a variable,
144 they increment or decrement the variable by one before returning the
145 value, and if placed after, increment or decrement after returning the
146 value.
147
148     $i = 0;  $j = 0;
149     print $i++;  # prints 0
150     print ++$j;  # prints 1
151
152 Note that just as in C, Perl doesn't define B<when> the variable is
153 incremented or decremented. You just know it will be done sometime
154 before or after the value is returned. This also means that modifying
155 a variable twice in the same statement will lead to undefined behavior.
156 Avoid statements like:
157
158     $i = $i ++;
159     print ++ $i + $i ++;
160
161 Perl will not guarantee what the result of the above statements is.
162
163 The auto-increment operator has a little extra builtin magic to it.  If
164 you increment a variable that is numeric, or that has ever been used in
165 a numeric context, you get a normal increment.  If, however, the
166 variable has been used in only string contexts since it was set, and
167 has a value that is not the empty string and matches the pattern
168 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
169 character within its range, with carry:
170
171     print ++($foo = "99");      # prints "100"
172     print ++($foo = "a0");      # prints "a1"
173     print ++($foo = "Az");      # prints "Ba"
174     print ++($foo = "zz");      # prints "aaa"
175
176 C<undef> is always treated as numeric, and in particular is changed
177 to C<0> before incrementing (so that a post-increment of an undef value
178 will return C<0> rather than C<undef>).
179
180 The auto-decrement operator is not magical.
181
182 =head2 Exponentiation
183 X<**> X<exponentiation> X<power>
184
185 Binary "**" is the exponentiation operator.  It binds even more
186 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
187 implemented using C's pow(3) function, which actually works on doubles
188 internally.)
189
190 =head2 Symbolic Unary Operators
191 X<unary operator> X<operator, unary>
192
193 Unary "!" performs logical negation, that is, "not".  See also C<not> for a lower
194 precedence version of this.
195 X<!>
196
197 Unary "-" performs arithmetic negation if the operand is numeric,
198 including any string that looks like a number.  If the operand is
199 an identifier, a string consisting of a minus sign concatenated
200 with the identifier is returned.  Otherwise, if the string starts
201 with a plus or minus, a string starting with the opposite sign is
202 returned.  One effect of these rules is that -bareword is equivalent
203 to the string "-bareword".  If, however, the string begins with a
204 non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert
205 the string to a numeric and the arithmetic negation is performed. If the
206 string cannot be cleanly converted to a numeric, Perl will give the warning
207 B<Argument "the string" isn't numeric in negation (-) at ...>.
208 X<-> X<negation, arithmetic>
209
210 Unary "~" performs bitwise negation, that is, 1's complement.  For
211 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
212 L<Bitwise String Operators>.)  Note that the width of the result is
213 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
214 bits wide on a 64-bit platform, so if you are expecting a certain bit
215 width, remember to use the "&" operator to mask off the excess bits.
216 X<~> X<negation, binary>
217
218 When complementing strings, if all characters have ordinal values under
219 256, then their complements will, also.  But if they do not, all
220 characters will be in either 32- or 64-bit complements, depending on your
221 architecture.  So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on
222 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines.
223
224 Unary "+" has no effect whatsoever, even on strings.  It is useful
225 syntactically for separating a function name from a parenthesized expression
226 that would otherwise be interpreted as the complete list of function
227 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
228 X<+>
229
230 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
231 and L<perlref>.  Do not confuse this behavior with the behavior of
232 backslash within a string, although both forms do convey the notion
233 of protecting the next thing from interpolation.
234 X<\> X<reference> X<backslash>
235
236 =head2 Binding Operators
237 X<binding> X<operator, binding> X<=~> X<!~>
238
239 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
240 search or modify the string $_ by default.  This operator makes that kind
241 of operation work on some other string.  The right argument is a search
242 pattern, substitution, or transliteration.  The left argument is what is
243 supposed to be searched, substituted, or transliterated instead of the default
244 $_.  When used in scalar context, the return value generally indicates the
245 success of the operation.  The exceptions are substitution (s///)
246 and transliteration (y///) with the C</r> (non-destructive) option,
247 which cause the B<r>eturn value to be the result of the substitution.
248 Behavior in list context depends on the particular operator.
249 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
250 examples using these operators.
251
252 If the right argument is an expression rather than a search pattern,
253 substitution, or transliteration, it is interpreted as a search pattern at run
254 time. Note that this means that its contents will be interpolated twice, so
255
256     '\\' =~ q'\\';
257
258 is not ok, as the regex engine will end up trying to compile the
259 pattern C<\>, which it will consider a syntax error.
260
261 Binary "!~" is just like "=~" except the return value is negated in
262 the logical sense.
263
264 Binary "!~" with a non-destructive substitution (s///r) or transliteration
265 (y///r) is a syntax error.
266
267 =head2 Multiplicative Operators
268 X<operator, multiplicative>
269
270 Binary "*" multiplies two numbers.
271 X<*>
272
273 Binary "/" divides two numbers.
274 X</> X<slash>
275
276 Binary "%" is the modulo operator, which computes the division
277 remainder of its first argument with respect to its second argument.
278 Given integer
279 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
280 C<$a> minus the largest multiple of C<$b> less than or equal to
281 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
282 smallest multiple of C<$b> that is not less than C<$a> (that is, the
283 result will be less than or equal to zero).  If the operands
284 C<$a> and C<$b> are floating point values and the absolute value of
285 C<$b> (that is C<abs($b)>) is less than C<(UV_MAX + 1)>, only
286 the integer portion of C<$a> and C<$b> will be used in the operation
287 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
288 If the absolute value of the right operand (C<abs($b)>) is greater than
289 or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder
290 C<$r> in the equation C<($r = $a - $i*$b)> where C<$i> is a certain
291 integer that makes C<$r> have the same sign as the right operand
292 C<$b> (B<not> as the left operand C<$a> like C function C<fmod()>)
293 and the absolute value less than that of C<$b>.
294 Note that when C<use integer> is in scope, "%" gives you direct access
295 to the modulo operator as implemented by your C compiler.  This
296 operator is not as well defined for negative operands, but it will
297 execute faster.
298 X<%> X<remainder> X<modulo> X<mod>
299
300 Binary "x" is the repetition operator.  In scalar context or if the left
301 operand is not enclosed in parentheses, it returns a string consisting
302 of the left operand repeated the number of times specified by the right
303 operand.  In list context, if the left operand is enclosed in
304 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
305 If the right operand is zero or negative, it returns an empty string
306 or an empty list, depending on the context.
307 X<x>
308
309     print '-' x 80;             # print row of dashes
310
311     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
312
313     @ones = (1) x 80;           # a list of 80 1's
314     @ones = (5) x @ones;        # set all elements to 5
315
316
317 =head2 Additive Operators
318 X<operator, additive>
319
320 Binary C<+> returns the sum of two numbers.
321 X<+>
322
323 Binary C<-> returns the difference of two numbers.
324 X<->
325
326 Binary C<.> concatenates two strings.
327 X<string, concatenation> X<concatenation>
328 X<cat> X<concat> X<concatenate> X<.>
329
330 =head2 Shift Operators
331 X<shift operator> X<operator, shift> X<<< << >>>
332 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
333 X<shl> X<shr> X<shift, right> X<shift, left>
334
335 Binary C<<< << >>> returns the value of its left argument shifted left by the
336 number of bits specified by the right argument.  Arguments should be
337 integers.  (See also L<Integer Arithmetic>.)
338
339 Binary C<<< >> >>> returns the value of its left argument shifted right by
340 the number of bits specified by the right argument.  Arguments should
341 be integers.  (See also L<Integer Arithmetic>.)
342
343 Note that both C<<< << >>> and C<<< >> >>> in Perl are implemented directly using
344 C<<< << >>> and C<<< >> >>>  in C.  If C<use integer> (see L<Integer Arithmetic>) is
345 in force then signed C integers are used, else unsigned C integers are
346 used.  Either way, the implementation isn't going to generate results
347 larger than the size of the integer type Perl was built with (32 bits
348 or 64 bits).
349
350 The result of overflowing the range of the integers is undefined
351 because it is undefined also in C.  In other words, using 32-bit
352 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
353 of bits is also undefined.
354
355 If you get tired of being subject to your platform's native integers,
356 the C<use bigint> pragma neatly sidesteps the issue altogether:
357
358     print 20 << 20;  # 20971520
359     print 20 << 40;  # 5120 on 32-bit machines, 
360                      # 21990232555520 on 64-bit machines
361     use bigint;
362     print 20 << 100; # 25353012004564588029934064107520
363
364 =head2 Named Unary Operators
365 X<operator, named unary>
366
367 The various named unary operators are treated as functions with one
368 argument, with optional parentheses.
369
370 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
371 is followed by a left parenthesis as the next token, the operator and
372 arguments within parentheses are taken to be of highest precedence,
373 just like a normal function call.  For example,
374 because named unary operators are higher precedence than C<||>:
375
376     chdir $foo    || die;       # (chdir $foo) || die
377     chdir($foo)   || die;       # (chdir $foo) || die
378     chdir ($foo)  || die;       # (chdir $foo) || die
379     chdir +($foo) || die;       # (chdir $foo) || die
380
381 but, because * is higher precedence than named operators:
382
383     chdir $foo * 20;    # chdir ($foo * 20)
384     chdir($foo) * 20;   # (chdir $foo) * 20
385     chdir ($foo) * 20;  # (chdir $foo) * 20
386     chdir +($foo) * 20; # chdir ($foo * 20)
387
388     rand 10 * 20;       # rand (10 * 20)
389     rand(10) * 20;      # (rand 10) * 20
390     rand (10) * 20;     # (rand 10) * 20
391     rand +(10) * 20;    # rand (10 * 20)
392
393 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
394 treated like named unary operators, but they don't follow this functional
395 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
396 equivalent to C<-f "$file.bak">.
397 X<-X> X<filetest> X<operator, filetest>
398
399 See also L<"Terms and List Operators (Leftward)">.
400
401 =head2 Relational Operators
402 X<relational operator> X<operator, relational>
403
404 Perl operators that return true or false generally return values 
405 that can be safely used as numbers.  For example, the relational
406 operators in this section and the equality operators in the next
407 one return C<1> for true and a special version of the defined empty
408 string, C<"">, which counts as a zero but is exempt from warnings
409 about improper numeric conversions, just as C<"0 but true"> is.
410
411 Binary "<" returns true if the left argument is numerically less than
412 the right argument.
413 X<< < >>
414
415 Binary ">" returns true if the left argument is numerically greater
416 than the right argument.
417 X<< > >>
418
419 Binary "<=" returns true if the left argument is numerically less than
420 or equal to the right argument.
421 X<< <= >>
422
423 Binary ">=" returns true if the left argument is numerically greater
424 than or equal to the right argument.
425 X<< >= >>
426
427 Binary "lt" returns true if the left argument is stringwise less than
428 the right argument.
429 X<< lt >>
430
431 Binary "gt" returns true if the left argument is stringwise greater
432 than the right argument.
433 X<< gt >>
434
435 Binary "le" returns true if the left argument is stringwise less than
436 or equal to the right argument.
437 X<< le >>
438
439 Binary "ge" returns true if the left argument is stringwise greater
440 than or equal to the right argument.
441 X<< ge >>
442
443 =head2 Equality Operators
444 X<equality> X<equal> X<equals> X<operator, equality>
445
446 Binary "==" returns true if the left argument is numerically equal to
447 the right argument.
448 X<==>
449
450 Binary "!=" returns true if the left argument is numerically not equal
451 to the right argument.
452 X<!=>
453
454 Binary "<=>" returns -1, 0, or 1 depending on whether the left
455 argument is numerically less than, equal to, or greater than the right
456 argument.  If your platform supports NaNs (not-a-numbers) as numeric
457 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
458 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
459 returns true, as does NaN != anything else. If your platform doesn't
460 support NaNs then NaN is just a string with numeric value 0.
461 X<< <=> >> X<spaceship>
462
463     $ perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
464     $ perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
465
466 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all 
467 support "NaN".)
468
469 Binary "eq" returns true if the left argument is stringwise equal to
470 the right argument.
471 X<eq>
472
473 Binary "ne" returns true if the left argument is stringwise not equal
474 to the right argument.
475 X<ne>
476
477 Binary "cmp" returns -1, 0, or 1 depending on whether the left
478 argument is stringwise less than, equal to, or greater than the right
479 argument.
480 X<cmp>
481
482 Binary "~~" does a smartmatch between its arguments.  Smart matching
483 is described in the next section.
484 X<~~>
485
486 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
487 by the current locale if a legacy C<use locale> (but not
488 C<use locale ':not_characters'>) is in effect.  See
489 L<perllocale>.  Do not mix these with Unicode, only with legacy binary
490 encodings.  The standard L<Unicode::Collate> and
491 L<Unicode::Collate::Locale> modules offer much more powerful solutions to
492 collation issues.
493
494 =head2 Smartmatch Operator
495
496 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
497 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
498 used implicitly in the C<when> construct described in L<perlsyn>, although
499 not all C<when> clauses call the smartmatch operator.  Unique among all of
500 Perl's operators, the smartmatch operator can recurse.
501
502 It is also unique in that all other Perl operators impose a context
503 (usually string or numeric context) on their operands, autoconverting
504 those operands to those imposed contexts.  In contrast, smartmatch
505 I<infers> contexts from the actual types of its operands and uses that
506 type information to select a suitable comparison mechanism.
507
508 The C<~~> operator compares its operands "polymorphically", determining how
509 to compare them according to their actual types (numeric, string, array,
510 hash, etc.)  Like the equality operators with which it shares the same
511 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
512 read aloud as "in", "inside of", or "is contained in", because the left
513 operand is often looked for I<inside> the right operand.  That makes the
514 order of the operands to the smartmatch operand often opposite that of
515 the regular match operator.  In other words, the "smaller" thing is usually
516 placed in the left operand and the larger one in the right.
517
518 The behavior of a smartmatch depends on what type of things its arguments
519 are, as determined by the following table.  The first row of the table
520 whose types apply determines the smartmatch behavior.  Because what
521 actually happens is mostly determined by the type of the second operand,
522 the table is sorted on the right operand instead of on the left.
523
524  Left      Right      Description and pseudocode                               
525  ===============================================================
526  Any       undef      check whether Any is undefined                    
527                 like: !defined Any
528
529  Any       Object     invoke ~~ overloading on Object, or die
530
531  Right operand is an ARRAY:
532
533  Left      Right      Description and pseudocode                               
534  ===============================================================
535  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
536                 like: (ARRAY1[0] ~~ ARRAY2[0])
537                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
538  HASH      ARRAY      any ARRAY elements exist as HASH keys             
539                 like: grep { exists HASH->{$_} } ARRAY
540  Regexp    ARRAY      any ARRAY elements pattern match Regexp
541                 like: grep { /Regexp/ } ARRAY
542  undef     ARRAY      undef in ARRAY                                    
543                 like: grep { !defined } ARRAY
544  Any       ARRAY      smartmatch each ARRAY element[3]                   
545                 like: grep { Any ~~ $_ } ARRAY
546
547  Right operand is a HASH:
548
549  Left      Right      Description and pseudocode                               
550  ===============================================================
551  HASH1     HASH2      all same keys in both HASHes                      
552                 like: keys HASH1 ==
553                          grep { exists HASH2->{$_} } keys HASH1
554  ARRAY     HASH       any ARRAY elements exist as HASH keys             
555                 like: grep { exists HASH->{$_} } ARRAY
556  Regexp    HASH       any HASH keys pattern match Regexp                
557                 like: grep { /Regexp/ } keys HASH
558  undef     HASH       always false (undef can't be a key)               
559                 like: 0 == 1
560  Any       HASH       HASH key existence                                
561                 like: exists HASH->{Any}
562
563  Right operand is CODE:
564    
565  Left      Right      Description and pseudocode                               
566  ===============================================================
567  ARRAY     CODE       sub returns true on all ARRAY elements[1]
568                 like: !grep { !CODE->($_) } ARRAY
569  HASH      CODE       sub returns true on all HASH keys[1]
570                 like: !grep { !CODE->($_) } keys HASH
571  Any       CODE       sub passed Any returns true              
572                 like: CODE->(Any)
573
574 Right operand is a Regexp:
575
576  Left      Right      Description and pseudocode                               
577  ===============================================================
578  ARRAY     Regexp     any ARRAY elements match Regexp                   
579                 like: grep { /Regexp/ } ARRAY
580  HASH      Regexp     any HASH keys match Regexp                        
581                 like: grep { /Regexp/ } keys HASH
582  Any       Regexp     pattern match                                     
583                 like: Any =~ /Regexp/
584
585  Other:
586
587  Left      Right      Description and pseudocode                               
588  ===============================================================
589  Object    Any        invoke ~~ overloading on Object,
590                       or fall back to...
591
592  Any       Num        numeric equality                                  
593                  like: Any == Num
594  Num       nummy[4]    numeric equality
595                  like: Num == nummy
596  undef     Any        check whether undefined
597                  like: !defined(Any)
598  Any       Any        string equality                                   
599                  like: Any eq Any
600
601
602 Notes:
603
604 =over
605
606 =item 1.
607 Empty hashes or arrays match. 
608
609 =item 2.
610 That is, each element smartmatches the element of the same index in the other array.[3]
611
612 =item 3.
613 If a circular reference is found, fall back to referential equality. 
614
615 =item 4.
616 Either an actual number, or a string that looks like one.
617
618 =back
619
620 The smartmatch implicitly dereferences any non-blessed hash or array
621 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
622 For blessed references, the C<I<Object>> entries apply.  Smartmatches
623 involving hashes only consider hash keys, never hash values.
624
625 The "like" code entry is not always an exact rendition.  For example, the
626 smartmatch operator short-circuits whenever possible, but C<grep> does
627 not.  Also, C<grep> in scalar context returns the number of matches, but
628 C<~~> returns only true or false.
629
630 Unlike most operators, the smartmatch operator knows to treat C<undef>
631 specially:
632
633     use v5.10.1;
634     @array = (1, 2, 3, undef, 4, 5);
635     say "some elements undefined" if undef ~~ @array;
636
637 Each operand is considered in a modified scalar context, the modification
638 being that array and hash variables are passed by reference to the
639 operator, which implicitly dereferences them.  Both elements
640 of each pair are the same:
641
642     use v5.10.1;
643
644     my %hash = (red    => 1, blue   => 2, green  => 3,
645                 orange => 4, yellow => 5, purple => 6,
646                 black  => 7, grey   => 8, white  => 9);
647
648     my @array = qw(red blue green);
649
650     say "some array elements in hash keys" if  @array ~~  %hash;
651     say "some array elements in hash keys" if \@array ~~ \%hash;
652
653     say "red in array" if "red" ~~  @array;
654     say "red in array" if "red" ~~ \@array;
655
656     say "some keys end in e" if /e$/ ~~  %hash;
657     say "some keys end in e" if /e$/ ~~ \%hash;
658
659 Two arrays smartmatch if each element in the first array smartmatches
660 (that is, is "in") the corresponding element in the second array,
661 recursively.
662
663     use v5.10.1;
664     my @little = qw(red blue green);
665     my @bigger = ("red", "blue", [ "orange", "green" ] );
666     if (@little ~~ @bigger) {  # true!
667         say "little is contained in bigger";
668     } 
669
670 Because the smartmatch operator recurses on nested arrays, this
671 will still report that "red" is in the array.
672
673     use v5.10.1;
674     my @array = qw(red blue green);
675     my $nested_array = [[[[[[[ @array ]]]]]]];
676     say "red in array" if "red" ~~ $nested_array;
677
678 If two arrays smartmatch each other, then they are deep
679 copies of each others' values, as this example reports:
680
681     use v5.12.0;
682     my @a = (0, 1, 2, [3, [4, 5], 6], 7); 
683     my @b = (0, 1, 2, [3, [4, 5], 6], 7); 
684
685     if (@a ~~ @b && @b ~~ @a) {
686         say "a and b are deep copies of each other";
687     } 
688     elsif (@a ~~ @b) {
689         say "a smartmatches in b";
690     } 
691     elsif (@b ~~ @a) {
692         say "b smartmatches in a";
693     } 
694     else {
695         say "a and b don't smartmatch each other at all";
696     } 
697
698
699 If you were to set C<$b[3] = 4>, then instead of reporting that "a and b
700 are deep copies of each other", it now reports that "b smartmatches in a".
701 That because the corresponding position in C<@a> contains an array that
702 (eventually) has a 4 in it.
703
704 Smartmatching one hash against another reports whether both contain the
705 same keys, no more and no less. This could be used to see whether two
706 records have the same field names, without caring what values those fields
707 might have.  For example:
708
709     use v5.10.1;
710     sub make_dogtag {
711         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
712
713         my ($class, $init_fields) = @_;
714
715         die "Must supply (only) name, rank, and serial number"
716             unless $init_fields ~~ $REQUIRED_FIELDS;
717
718         ...
719     }
720
721 or, if other non-required fields are allowed, use ARRAY ~~ HASH:
722
723     use v5.10.1;
724     sub make_dogtag {
725         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
726
727         my ($class, $init_fields) = @_;
728
729         die "Must supply (at least) name, rank, and serial number"
730             unless [keys %{$init_fields}] ~~ $REQUIRED_FIELDS;
731
732         ...
733     }
734
735 The smartmatch operator is most often used as the implicit operator of a
736 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
737
738 =head3 Smartmatching of Objects
739
740 To avoid relying on an object's underlying representation, if the
741 smartmatch's right operand is an object that doesn't overload C<~~>,
742 it raises the exception "C<Smartmatching a non-overloaded object
743 breaks encapsulation>". That's because one has no business digging
744 around to see whether something is "in" an object. These are all
745 illegal on objects without a C<~~> overload:
746
747     %hash ~~ $object
748        42 ~~ $object
749    "fred" ~~ $object
750
751 However, you can change the way an object is smartmatched by overloading
752 the C<~~> operator. This is allowed to extend the usual smartmatch semantics.
753 For objects that do have an C<~~> overload, see L<overload>.
754
755 Using an object as the left operand is allowed, although not very useful.
756 Smartmatching rules take precedence over overloading, so even if the
757 object in the left operand has smartmatch overloading, this will be
758 ignored.  A left operand that is a non-overloaded object falls back on a
759 string or numeric comparison of whatever the C<ref> operator returns.  That
760 means that
761
762     $object ~~ X
763
764 does I<not> invoke the overload method with C<I<X>> as an argument.
765 Instead the above table is consulted as normal, and based on the type of
766 C<I<X>>, overloading may or may not be invoked.  For simple strings or
767 numbers, in becomes equivalent to this:
768
769     $object ~~ $number          ref($object) == $number
770     $object ~~ $string          ref($object) eq $string 
771
772 For example, this reports that the handle smells IOish
773 (but please don't really do this!):
774
775     use IO::Handle;
776     my $fh = IO::Handle->new();
777     if ($fh ~~ /\bIO\b/) {
778         say "handle smells IOish";
779     } 
780
781 That's because it treats C<$fh> as a string like
782 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
783
784 =head2 Bitwise And
785 X<operator, bitwise, and> X<bitwise and> X<&>
786
787 Binary "&" returns its operands ANDed together bit by bit.
788 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
789
790 Note that "&" has lower priority than relational operators, so for example
791 the parentheses are essential in a test like
792
793     print "Even\n" if ($x & 1) == 0;
794
795 =head2 Bitwise Or and Exclusive Or
796 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
797 X<bitwise xor> X<^>
798
799 Binary "|" returns its operands ORed together bit by bit.
800 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
801
802 Binary "^" returns its operands XORed together bit by bit.
803 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
804
805 Note that "|" and "^" have lower priority than relational operators, so
806 for example the brackets are essential in a test like
807
808     print "false\n" if (8 | 2) != 10;
809
810 =head2 C-style Logical And
811 X<&&> X<logical and> X<operator, logical, and>
812
813 Binary "&&" performs a short-circuit logical AND operation.  That is,
814 if the left operand is false, the right operand is not even evaluated.
815 Scalar or list context propagates down to the right operand if it
816 is evaluated.
817
818 =head2 C-style Logical Or
819 X<||> X<operator, logical, or>
820
821 Binary "||" performs a short-circuit logical OR operation.  That is,
822 if the left operand is true, the right operand is not even evaluated.
823 Scalar or list context propagates down to the right operand if it
824 is evaluated.
825
826 =head2 Logical Defined-Or
827 X<//> X<operator, logical, defined-or>
828
829 Although it has no direct equivalent in C, Perl's C<//> operator is related
830 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
831 tests the left hand side's definedness instead of its truth.  Thus,
832 C<< EXPR1 // EXPR2 >> returns the value of C<< EXPR1 >> if it's defined,
833 otherwise, the value of C<< EXPR2 >> is returned. (C<< EXPR1 >> is evaluated
834 in scalar context, C<< EXPR2 >> in the context of C<< // >> itself). Usually,
835 this is the same result as C<< defined(EXPR1) ? EXPR1 : EXPR2 >> (except that
836 the ternary-operator form can be used as a lvalue, while C<< EXPR1 // EXPR2 >>
837 cannot). This is very useful for
838 providing default values for variables.  If you actually want to test if
839 at least one of C<$a> and C<$b> is defined, use C<defined($a // $b)>.
840
841 The C<||>, C<//> and C<&&> operators return the last value evaluated
842 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
843 portable way to find out the home directory might be:
844
845     $home =  $ENV{HOME}
846           // $ENV{LOGDIR}
847           // (getpwuid($<))[7]
848           // die "You're homeless!\n";
849
850 In particular, this means that you shouldn't use this
851 for selecting between two aggregates for assignment:
852
853     @a = @b || @c;              # this is wrong
854     @a = scalar(@b) || @c;      # really meant this
855     @a = @b ? @b : @c;          # this works fine, though
856
857 As alternatives to C<&&> and C<||> when used for
858 control flow, Perl provides the C<and> and C<or> operators (see below).
859 The short-circuit behavior is identical.  The precedence of "and"
860 and "or" is much lower, however, so that you can safely use them after a
861 list operator without the need for parentheses:
862
863     unlink "alpha", "beta", "gamma"
864             or gripe(), next LINE;
865
866 With the C-style operators that would have been written like this:
867
868     unlink("alpha", "beta", "gamma")
869             || (gripe(), next LINE);
870
871 It would be even more readable to write that this way:
872
873     unless(unlink("alpha", "beta", "gamma")) {
874         gripe();
875         next LINE;
876     } 
877
878 Using "or" for assignment is unlikely to do what you want; see below.
879
880 =head2 Range Operators
881 X<operator, range> X<range> X<..> X<...>
882
883 Binary ".." is the range operator, which is really two different
884 operators depending on the context.  In list context, it returns a
885 list of values counting (up by ones) from the left value to the right
886 value.  If the left value is greater than the right value then it
887 returns the empty list.  The range operator is useful for writing
888 C<foreach (1..10)> loops and for doing slice operations on arrays. In
889 the current implementation, no temporary array is created when the
890 range operator is used as the expression in C<foreach> loops, but older
891 versions of Perl might burn a lot of memory when you write something
892 like this:
893
894     for (1 .. 1_000_000) {
895         # code
896     }
897
898 The range operator also works on strings, using the magical
899 auto-increment, see below.
900
901 In scalar context, ".." returns a boolean value.  The operator is
902 bistable, like a flip-flop, and emulates the line-range (comma)
903 operator of B<sed>, B<awk>, and various editors. Each ".." operator
904 maintains its own boolean state, even across calls to a subroutine
905 that contains it. It is false as long as its left operand is false.
906 Once the left operand is true, the range operator stays true until the
907 right operand is true, I<AFTER> which the range operator becomes false
908 again.  It doesn't become false till the next time the range operator
909 is evaluated.  It can test the right operand and become false on the
910 same evaluation it became true (as in B<awk>), but it still returns
911 true once. If you don't want it to test the right operand until the
912 next evaluation, as in B<sed>, just use three dots ("...") instead of
913 two.  In all other regards, "..." behaves just like ".." does.
914
915 The right operand is not evaluated while the operator is in the
916 "false" state, and the left operand is not evaluated while the
917 operator is in the "true" state.  The precedence is a little lower
918 than || and &&.  The value returned is either the empty string for
919 false, or a sequence number (beginning with 1) for true.  The sequence
920 number is reset for each range encountered.  The final sequence number
921 in a range has the string "E0" appended to it, which doesn't affect
922 its numeric value, but gives you something to search for if you want
923 to exclude the endpoint.  You can exclude the beginning point by
924 waiting for the sequence number to be greater than 1.
925
926 If either operand of scalar ".." is a constant expression,
927 that operand is considered true if it is equal (C<==>) to the current
928 input line number (the C<$.> variable).
929
930 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
931 but that is only an issue if you use a floating point expression; when
932 implicitly using C<$.> as described in the previous paragraph, the
933 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
934 is set to a floating point value and you are not reading from a file.
935 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
936 you want in scalar context because each of the operands are evaluated
937 using their integer representation.
938
939 Examples:
940
941 As a scalar operator:
942
943     if (101 .. 200) { print; } # print 2nd hundred lines, short for
944                                #  if ($. == 101 .. $. == 200) { print; }
945
946     next LINE if (1 .. /^$/);  # skip header lines, short for
947                                #   next LINE if ($. == 1 .. /^$/);
948                                # (typically in a loop labeled LINE)
949
950     s/^/> / if (/^$/ .. eof());  # quote body
951
952     # parse mail messages
953     while (<>) {
954         $in_header =   1  .. /^$/;
955         $in_body   = /^$/ .. eof;
956         if ($in_header) {
957             # do something
958         } else { # in body
959             # do something else
960         }
961     } continue {
962         close ARGV if eof;             # reset $. each file
963     }
964
965 Here's a simple example to illustrate the difference between
966 the two range operators:
967
968     @lines = ("   - Foo",
969               "01 - Bar",
970               "1  - Baz",
971               "   - Quux");
972
973     foreach (@lines) {
974         if (/0/ .. /1/) {
975             print "$_\n";
976         }
977     }
978
979 This program will print only the line containing "Bar". If
980 the range operator is changed to C<...>, it will also print the
981 "Baz" line.
982
983 And now some examples as a list operator:
984
985     for (101 .. 200) { print }      # print $_ 100 times
986     @foo = @foo[0 .. $#foo];        # an expensive no-op
987     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
988
989 The range operator (in list context) makes use of the magical
990 auto-increment algorithm if the operands are strings.  You
991 can say
992
993     @alphabet = ("A" .. "Z");
994
995 to get all normal letters of the English alphabet, or
996
997     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
998
999 to get a hexadecimal digit, or
1000
1001     @z2 = ("01" .. "31");
1002     print $z2[$mday];
1003
1004 to get dates with leading zeros.
1005
1006 If the final value specified is not in the sequence that the magical
1007 increment would produce, the sequence goes until the next value would
1008 be longer than the final value specified.
1009
1010 If the initial value specified isn't part of a magical increment
1011 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1012 only the initial value will be returned.  So the following will only
1013 return an alpha:
1014
1015     use charnames "greek";
1016     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1017
1018 To get the 25 traditional lowercase Greek letters, including both sigmas,
1019 you could use this instead:
1020
1021     use charnames "greek";
1022     my @greek_small =  map { chr } ( ord("\N{alpha}") 
1023                                         ..
1024                                      ord("\N{omega}") 
1025                                    );
1026
1027 However, because there are I<many> other lowercase Greek characters than
1028 just those, to match lowercase Greek characters in a regular expression,
1029 you would use the pattern C</(?:(?=\p{Greek})\p{Lower})+/>.
1030
1031 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
1032 return two elements in list context.
1033
1034     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1035
1036 =head2 Conditional Operator
1037 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1038
1039 Ternary "?:" is the conditional operator, just as in C.  It works much
1040 like an if-then-else.  If the argument before the ? is true, the
1041 argument before the : is returned, otherwise the argument after the :
1042 is returned.  For example:
1043
1044     printf "I have %d dog%s.\n", $n,
1045             ($n == 1) ? "" : "s";
1046
1047 Scalar or list context propagates downward into the 2nd
1048 or 3rd argument, whichever is selected.
1049
1050     $a = $ok ? $b : $c;  # get a scalar
1051     @a = $ok ? @b : @c;  # get an array
1052     $a = $ok ? @b : @c;  # oops, that's just a count!
1053
1054 The operator may be assigned to if both the 2nd and 3rd arguments are
1055 legal lvalues (meaning that you can assign to them):
1056
1057     ($a_or_b ? $a : $b) = $c;
1058
1059 Because this operator produces an assignable result, using assignments
1060 without parentheses will get you in trouble.  For example, this:
1061
1062     $a % 2 ? $a += 10 : $a += 2
1063
1064 Really means this:
1065
1066     (($a % 2) ? ($a += 10) : $a) += 2
1067
1068 Rather than this:
1069
1070     ($a % 2) ? ($a += 10) : ($a += 2)
1071
1072 That should probably be written more simply as:
1073
1074     $a += ($a % 2) ? 10 : 2;
1075
1076 =head2 Assignment Operators
1077 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1078 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1079 X<%=> X<^=> X<x=>
1080
1081 "=" is the ordinary assignment operator.
1082
1083 Assignment operators work as in C.  That is,
1084
1085     $a += 2;
1086
1087 is equivalent to
1088
1089     $a = $a + 2;
1090
1091 although without duplicating any side effects that dereferencing the lvalue
1092 might trigger, such as from tie().  Other assignment operators work similarly.
1093 The following are recognized:
1094
1095     **=    +=    *=    &=    <<=    &&=
1096            -=    /=    |=    >>=    ||=
1097            .=    %=    ^=           //=
1098                  x=
1099
1100 Although these are grouped by family, they all have the precedence
1101 of assignment.
1102
1103 Unlike in C, the scalar assignment operator produces a valid lvalue.
1104 Modifying an assignment is equivalent to doing the assignment and
1105 then modifying the variable that was assigned to.  This is useful
1106 for modifying a copy of something, like this:
1107
1108     ($tmp = $global) =~ tr/13579/24680/;
1109
1110 Although as of 5.14, that can be also be accomplished this way:
1111
1112     use v5.14;
1113     $tmp = ($global =~  tr/13579/24680/r);
1114
1115 Likewise,
1116
1117     ($a += 2) *= 3;
1118
1119 is equivalent to
1120
1121     $a += 2;
1122     $a *= 3;
1123
1124 Similarly, a list assignment in list context produces the list of
1125 lvalues assigned to, and a list assignment in scalar context returns
1126 the number of elements produced by the expression on the right hand
1127 side of the assignment.
1128
1129 =head2 Comma Operator
1130 X<comma> X<operator, comma> X<,>
1131
1132 Binary "," is the comma operator.  In scalar context it evaluates
1133 its left argument, throws that value away, then evaluates its right
1134 argument and returns that value.  This is just like C's comma operator.
1135
1136 In list context, it's just the list argument separator, and inserts
1137 both its arguments into the list.  These arguments are also evaluated
1138 from left to right.
1139
1140 The C<< => >> operator is a synonym for the comma except that it causes a
1141 word on its left to be interpreted as a string if it begins with a letter
1142 or underscore and is composed only of letters, digits and underscores.
1143 This includes operands that might otherwise be interpreted as operators,
1144 constants, single number v-strings or function calls. If in doubt about
1145 this behavior, the left operand can be quoted explicitly.
1146
1147 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1148 or list argument separator, according to context.
1149
1150 For example:
1151
1152     use constant FOO => "something";
1153
1154     my %h = ( FOO => 23 );
1155
1156 is equivalent to:
1157
1158     my %h = ("FOO", 23);
1159
1160 It is I<NOT>:
1161
1162     my %h = ("something", 23);
1163
1164 The C<< => >> operator is helpful in documenting the correspondence
1165 between keys and values in hashes, and other paired elements in lists.
1166
1167     %hash = ( $key => $value );
1168     login( $username => $password );
1169
1170 The special quoting behavior ignores precedence, and hence may apply to
1171 I<part> of the left operand:
1172
1173     print time.shift => "bbb";
1174
1175 That example prints something like "1314363215shiftbbb", because the
1176 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1177 the fact that C<time.shift> is the entire left operand.
1178
1179 =head2 List Operators (Rightward)
1180 X<operator, list, rightward> X<list operator>
1181
1182 On the right side of a list operator, the comma has very low precedence,
1183 such that it controls all comma-separated expressions found there.
1184 The only operators with lower precedence are the logical operators
1185 "and", "or", and "not", which may be used to evaluate calls to list
1186 operators without the need for parentheses:
1187
1188     open HANDLE, "< :utf8", "filename" or die "Can't open: $!\n";
1189
1190 However, some people find that code harder to read than writing
1191 it with parentheses:
1192
1193     open(HANDLE, "< :utf8", "filename") or die "Can't open: $!\n";
1194
1195 in which case you might as well just use the more customary "||" operator:
1196
1197     open(HANDLE, "< :utf8", "filename") || die "Can't open: $!\n";
1198
1199 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
1200
1201 =head2 Logical Not
1202 X<operator, logical, not> X<not>
1203
1204 Unary "not" returns the logical negation of the expression to its right.
1205 It's the equivalent of "!" except for the very low precedence.
1206
1207 =head2 Logical And
1208 X<operator, logical, and> X<and>
1209
1210 Binary "and" returns the logical conjunction of the two surrounding
1211 expressions.  It's equivalent to C<&&> except for the very low
1212 precedence.  This means that it short-circuits: the right
1213 expression is evaluated only if the left expression is true.
1214
1215 =head2 Logical or and Exclusive Or
1216 X<operator, logical, or> X<operator, logical, xor>
1217 X<operator, logical, exclusive or>
1218 X<or> X<xor>
1219
1220 Binary "or" returns the logical disjunction of the two surrounding
1221 expressions.  It's equivalent to C<||> except for the very low precedence.
1222 This makes it useful for control flow:
1223
1224     print FH $data              or die "Can't write to FH: $!";
1225
1226 This means that it short-circuits: the right expression is evaluated
1227 only if the left expression is false.  Due to its precedence, you must
1228 be careful to avoid using it as replacement for the C<||> operator.
1229 It usually works out better for flow control than in assignments:
1230
1231     $a = $b or $c;              # bug: this is wrong
1232     ($a = $b) or $c;            # really means this
1233     $a = $b || $c;              # better written this way
1234
1235 However, when it's a list-context assignment and you're trying to use
1236 C<||> for control flow, you probably need "or" so that the assignment
1237 takes higher precedence.
1238
1239     @info = stat($file) || die;     # oops, scalar sense of stat!
1240     @info = stat($file) or die;     # better, now @info gets its due
1241
1242 Then again, you could always use parentheses.
1243
1244 Binary C<xor> returns the exclusive-OR of the two surrounding expressions.
1245 It cannot short-circuit (of course).
1246
1247 There is no low precedence operator for defined-OR.
1248
1249 =head2 C Operators Missing From Perl
1250 X<operator, missing from perl> X<&> X<*>
1251 X<typecasting> X<(TYPE)>
1252
1253 Here is what C has that Perl doesn't:
1254
1255 =over 8
1256
1257 =item unary &
1258
1259 Address-of operator.  (But see the "\" operator for taking a reference.)
1260
1261 =item unary *
1262
1263 Dereference-address operator. (Perl's prefix dereferencing
1264 operators are typed: $, @, %, and &.)
1265
1266 =item (TYPE)
1267
1268 Type-casting operator.
1269
1270 =back
1271
1272 =head2 Quote and Quote-like Operators
1273 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1274 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1275 X<escape sequence> X<escape>
1276
1277 While we usually think of quotes as literal values, in Perl they
1278 function as operators, providing various kinds of interpolating and
1279 pattern matching capabilities.  Perl provides customary quote characters
1280 for these behaviors, but also provides a way for you to choose your
1281 quote character for any of them.  In the following table, a C<{}> represents
1282 any pair of delimiters you choose.
1283
1284     Customary  Generic        Meaning        Interpolates
1285         ''       q{}          Literal             no
1286         ""      qq{}          Literal             yes
1287         ``      qx{}          Command             yes*
1288                 qw{}         Word list            no
1289         //       m{}       Pattern match          yes*
1290                 qr{}          Pattern             yes*
1291                  s{}{}      Substitution          yes*
1292                 tr{}{}    Transliteration         no (but see below)
1293                  y{}{}    Transliteration         no (but see below)
1294         <<EOF                 here-doc            yes*
1295
1296         * unless the delimiter is ''.
1297
1298 Non-bracketing delimiters use the same character fore and aft, but the four
1299 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1300 that
1301
1302     q{foo{bar}baz}
1303
1304 is the same as
1305
1306     'foo{bar}baz'
1307
1308 Note, however, that this does not always work for quoting Perl code:
1309
1310     $s = q{ if($a eq "}") ... }; # WRONG
1311
1312 is a syntax error. The C<Text::Balanced> module (standard as of v5.8,
1313 and from CPAN before then) is able to do this properly.
1314
1315 There can be whitespace between the operator and the quoting
1316 characters, except when C<#> is being used as the quoting character.
1317 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
1318 operator C<q> followed by a comment.  Its argument will be taken
1319 from the next line.  This allows you to write:
1320
1321     s {foo}  # Replace foo
1322       {bar}  # with bar.
1323
1324 The following escape sequences are available in constructs that interpolate,
1325 and in transliterations:
1326 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1327 X<\o{}>
1328
1329     Sequence     Note  Description
1330     \t                  tab               (HT, TAB)
1331     \n                  newline           (NL)
1332     \r                  return            (CR)
1333     \f                  form feed         (FF)
1334     \b                  backspace         (BS)
1335     \a                  alarm (bell)      (BEL)
1336     \e                  escape            (ESC)
1337     \x{263A}     [1,8]  hex char          (example: SMILEY)
1338     \x1b         [2,8]  restricted range hex char (example: ESC)
1339     \N{name}     [3]    named Unicode character or character sequence
1340     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1341     \c[          [5]    control char      (example: chr(27))
1342     \o{23072}    [6,8]  octal char        (example: SMILEY)
1343     \033         [7,8]  restricted range octal char  (example: ESC)
1344
1345 =over 4
1346
1347 =item [1]
1348
1349 The result is the character specified by the hexadecimal number between
1350 the braces.  See L</[8]> below for details on which character.
1351
1352 Only hexadecimal digits are valid between the braces. If an invalid
1353 character is encountered, a warning will be issued and the invalid
1354 character and all subsequent characters (valid or invalid) within the
1355 braces will be discarded.
1356
1357 If there are no valid digits between the braces, the generated character is
1358 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1359 will not cause a warning (currently).
1360
1361 =item [2]
1362
1363 The result is the character specified by the hexadecimal number in the range
1364 0x00 to 0xFF.  See L</[8]> below for details on which character.
1365
1366 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1367 by fewer than two valid digits, any valid digits will be zero-padded.  This
1368 means that C<\x7> will be interpreted as C<\x07>, and a lone <\x> will be
1369 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1370 two valid digits will result in a warning.  Note that although the warning
1371 says the illegal character is ignored, it is only ignored as part of the
1372 escape and will still be used as the subsequent character in the string.
1373 For example:
1374
1375   Original    Result    Warns?
1376   "\x7"       "\x07"    no
1377   "\x"        "\x00"    no
1378   "\x7q"      "\x07q"   yes
1379   "\xq"       "\x00q"   yes
1380
1381 =item [3]
1382
1383 The result is the Unicode character or character sequence given by I<name>.
1384 See L<charnames>.
1385
1386 =item [4]
1387
1388 C<\N{U+I<hexadecimal number>}> means the Unicode character whose Unicode code
1389 point is I<hexadecimal number>.
1390
1391 =item [5]
1392
1393 The character following C<\c> is mapped to some other character as shown in the
1394 table:
1395
1396  Sequence   Value
1397    \c@      chr(0)
1398    \cA      chr(1)
1399    \ca      chr(1)
1400    \cB      chr(2)
1401    \cb      chr(2)
1402    ...
1403    \cZ      chr(26)
1404    \cz      chr(26)
1405    \c[      chr(27)
1406    \c]      chr(29)
1407    \c^      chr(30)
1408    \c?      chr(127)
1409
1410 In other words, it's the character whose code point has had 64 xor'd with
1411 its uppercase.  C<\c?> is DELETE because C<ord("@") ^ 64> is 127, and
1412 C<\c@> is NULL because the ord of "@" is 64, so xor'ing 64 itself produces 0.
1413
1414 Also, C<\c\I<X>> yields C< chr(28) . "I<X>"> for any I<X>, but cannot come at the
1415 end of a string, because the backslash would be parsed as escaping the end
1416 quote.
1417
1418 On ASCII platforms, the resulting characters from the list above are the
1419 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1420 L<perlebcdic/OPERATOR DIFFERENCES> for the complete list of what these
1421 sequences mean on both ASCII and EBCDIC platforms.
1422
1423 Use of any other character following the "c" besides those listed above is
1424 discouraged, and some are deprecated with the intention of removing
1425 those in a later Perl version.  What happens for any of these
1426 other characters currently though, is that the value is derived by xor'ing
1427 with the seventh bit, which is 64.
1428
1429 To get platform independent controls, you can use C<\N{...}>.
1430
1431 =item [6]
1432
1433 The result is the character specified by the octal number between the braces.
1434 See L</[8]> below for details on which character.
1435
1436 If a character that isn't an octal digit is encountered, a warning is raised,
1437 and the value is based on the octal digits before it, discarding it and all
1438 following characters up to the closing brace.  It is a fatal error if there are
1439 no octal digits at all.
1440
1441 =item [7]
1442
1443 The result is the character specified by the three-digit octal number in the
1444 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1445 L</[8]> below for details on which character.
1446
1447 Some contexts allow 2 or even 1 digit, but any usage without exactly
1448 three digits, the first being a zero, may give unintended results.  (For
1449 example, in a regular expression it may be confused with a backreference;
1450 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1451 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1452 use this construct only for ordinals C<\077> and below, remembering to pad to
1453 the left with zeros to make three digits.  For larger ordinals, either use
1454 C<\o{}>, or convert to something else, such as to hex and use C<\x{}>
1455 instead.
1456
1457 Having fewer than 3 digits may lead to a misleading warning message that says
1458 that what follows is ignored.  For example, C<"\128"> in the ASCII character set
1459 is equivalent to the two characters C<"\n8">, but the warning C<Illegal octal
1460 digit '8' ignored> will be thrown.  If C<"\n8"> is what you want, you can
1461 avoid this warning by padding your octal number with C<0>'s: C<"\0128">.
1462
1463 =item [8]
1464
1465 Several constructs above specify a character by a number.  That number
1466 gives the character's position in the character set encoding (indexed from 0).
1467 This is called synonymously its ordinal, code position, or code point.  Perl
1468 works on platforms that have a native encoding currently of either ASCII/Latin1
1469 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1470 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1471 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1472 it as a Unicode code point and the result is the corresponding Unicode
1473 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1474 decimal, which is less than 256, so the number is interpreted in the native
1475 character set encoding.  In ASCII the character in the 80th position (indexed
1476 from 0) is the letter "P", and in EBCDIC it is the ampersand symbol "&".
1477 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1478 as a Unicode code point no matter what the native encoding is.  The name of the
1479 character in the 256th position (indexed by 0) in Unicode is
1480 C<LATIN CAPITAL LETTER A WITH MACRON>.
1481
1482 There are a couple of exceptions to the above rule.  S<C<\N{U+I<hex number>}>> is
1483 always interpreted as a Unicode code point, so that C<\N{U+0050}> is "P" even
1484 on EBCDIC platforms.  And if L<C<S<use encoding>>|encoding> is in effect, the
1485 number is considered to be in that encoding, and is translated from that into
1486 the platform's native encoding if there is a corresponding native character;
1487 otherwise to Unicode.
1488
1489 =back
1490
1491 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1492 the vertical tab (VT - ASCII 11), but you may use C<\ck> or C<\x0b>.  (C<\v>
1493 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1494
1495 The following escape sequences are available in constructs that interpolate,
1496 but not in transliterations.
1497 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1498
1499     \l          lowercase next character only
1500     \u          titlecase (not uppercase!) next character only
1501     \L          lowercase all characters till \E or end of string
1502     \U          uppercase all characters till \E or end of string
1503     \F          foldcase all characters till \E or end of string
1504     \Q          quote (disable) pattern metacharacters till \E or
1505                 end of string
1506     \E          end either case modification or quoted section
1507                 (whichever was last seen)
1508
1509 See L<perlfunc/quotemeta> for the exact definition of characters that
1510 are quoted by C<\Q>.
1511
1512 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1513 C<\E> for each.  For example:
1514
1515  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1516  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1517
1518 If C<use locale> is in effect (but not C<use locale ':not_characters'>),
1519 the case map used by C<\l>, C<\L>,
1520 C<\u>, and C<\U> is taken from the current locale.  See L<perllocale>.
1521 If Unicode (for example, C<\N{}> or code points of 0x100 or
1522 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u>, and
1523 C<\U> is as defined by Unicode.  That means that case-mapping
1524 a single character can sometimes produce several characters.
1525 Under C<use locale>, C<\F> produces the same results as C<\L>.
1526
1527 All systems use the virtual C<"\n"> to represent a line terminator,
1528 called a "newline".  There is no such thing as an unvarying, physical
1529 newline character.  It is only an illusion that the operating system,
1530 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1531 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1532 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1533 and on systems without line terminator,
1534 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1535 you mean a "newline" for your system, but use the literal ASCII when you
1536 need an exact character.  For example, most networking protocols expect
1537 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1538 and although they often accept just C<"\012">, they seldom tolerate just
1539 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1540 you may be burned some day.
1541 X<newline> X<line terminator> X<eol> X<end of line>
1542 X<\n> X<\r> X<\r\n>
1543
1544 For constructs that do interpolate, variables beginning with "C<$>"
1545 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1546 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1547 But method calls such as C<< $obj->meth >> are not.
1548
1549 Interpolating an array or slice interpolates the elements in order,
1550 separated by the value of C<$">, so is equivalent to interpolating
1551 C<join $", @array>.  "Punctuation" arrays such as C<@*> are usually
1552 interpolated only if the name is enclosed in braces C<@{*}>, but the
1553 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1554
1555 For double-quoted strings, the quoting from C<\Q> is applied after
1556 interpolation and escapes are processed.
1557
1558     "abc\Qfoo\tbar$s\Exyz"
1559
1560 is equivalent to
1561
1562     "abc" . quotemeta("foo\tbar$s") . "xyz"
1563
1564 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1565 the quoting from C<\Q> is applied after interpolation is processed,
1566 but before escapes are processed. This allows the pattern to match
1567 literally (except for C<$> and C<@>). For example, the following matches:
1568
1569     '\s\t' =~ /\Q\s\t/
1570
1571 Because C<$> or C<@> trigger interpolation, you'll need to use something
1572 like C</\Quser\E\@\Qhost/> to match them literally.
1573
1574 Patterns are subject to an additional level of interpretation as a
1575 regular expression.  This is done as a second pass, after variables are
1576 interpolated, so that regular expressions may be incorporated into the
1577 pattern from the variables.  If this is not what you want, use C<\Q> to
1578 interpolate a variable literally.
1579
1580 Apart from the behavior described above, Perl does not expand
1581 multiple levels of interpolation.  In particular, contrary to the
1582 expectations of shell programmers, back-quotes do I<NOT> interpolate
1583 within double quotes, nor do single quotes impede evaluation of
1584 variables when used within double quotes.
1585
1586 =head2 Regexp Quote-Like Operators
1587 X<operator, regexp>
1588
1589 Here are the quote-like operators that apply to pattern
1590 matching and related activities.
1591
1592 =over 8
1593
1594 =item qr/STRING/msixpodual
1595 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1596
1597 This operator quotes (and possibly compiles) its I<STRING> as a regular
1598 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1599 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1600 is done.  Returns a Perl value which may be used instead of the
1601 corresponding C</STRING/msixpodual> expression. The returned value is a
1602 normalized version of the original pattern. It magically differs from
1603 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1604 however, dereferencing it is not well defined (you currently get the 
1605 normalized version of the original pattern, but this may change).
1606
1607
1608 For example,
1609
1610     $rex = qr/my.STRING/is;
1611     print $rex;                 # prints (?si-xm:my.STRING)
1612     s/$rex/foo/;
1613
1614 is equivalent to
1615
1616     s/my.STRING/foo/is;
1617
1618 The result may be used as a subpattern in a match:
1619
1620     $re = qr/$pattern/;
1621     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1622     $string =~ $re;             # or used standalone
1623     $string =~ /$re/;           # or this way
1624
1625 Since Perl may compile the pattern at the moment of execution of the qr()
1626 operator, using qr() may have speed advantages in some situations,
1627 notably if the result of qr() is used standalone:
1628
1629     sub match {
1630         my $patterns = shift;
1631         my @compiled = map qr/$_/i, @$patterns;
1632         grep {
1633             my $success = 0;
1634             foreach my $pat (@compiled) {
1635                 $success = 1, last if /$pat/;
1636             }
1637             $success;
1638         } @_;
1639     }
1640
1641 Precompilation of the pattern into an internal representation at
1642 the moment of qr() avoids a need to recompile the pattern every
1643 time a match C</$pat/> is attempted.  (Perl has many other internal
1644 optimizations, but none would be triggered in the above example if
1645 we did not use qr() operator.)
1646
1647 Options (specified by the following modifiers) are:
1648
1649     m   Treat string as multiple lines.
1650     s   Treat string as single line. (Make . match a newline)
1651     i   Do case-insensitive pattern matching.
1652     x   Use extended regular expressions.
1653     p   When matching preserve a copy of the matched string so
1654         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be defined.
1655     o   Compile pattern only once.
1656     a   ASCII-restrict: Use ASCII for \d, \s, \w; specifying two a's
1657         further restricts /i matching so that no ASCII character will
1658         match a non-ASCII one
1659     l   Use the locale
1660     u   Use Unicode rules
1661     d   Use Unicode or native charset, as in 5.12 and earlier
1662
1663 If a precompiled pattern is embedded in a larger pattern then the effect
1664 of "msixpluad" will be propagated appropriately.  The effect the "o"
1665 modifier has is not propagated, being restricted to those patterns
1666 explicitly using it.
1667
1668 The last four modifiers listed above, added in Perl 5.14,
1669 control the character set semantics, but C</a> is the only one you are likely
1670 to want to specify explicitly; the other three are selected
1671 automatically by various pragmas.
1672
1673 See L<perlre> for additional information on valid syntax for STRING, and
1674 for a detailed look at the semantics of regular expressions.  In
1675 particular, all modifiers except the largely obsolete C</o> are further
1676 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1677
1678 =item m/PATTERN/msixpodualgc
1679 X<m> X<operator, match>
1680 X<regexp, options> X<regexp> X<regex, options> X<regex>
1681 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1682
1683 =item /PATTERN/msixpodualgc
1684
1685 Searches a string for a pattern match, and in scalar context returns
1686 true if it succeeds, false if it fails.  If no string is specified
1687 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1688 string specified with C<=~> need not be an lvalue--it may be the
1689 result of an expression evaluation, but remember the C<=~> binds
1690 rather tightly.)  See also L<perlre>.
1691
1692 Options are as described in C<qr//> above; in addition, the following match
1693 process modifiers are available:
1694
1695  g  Match globally, i.e., find all occurrences.
1696  c  Do not reset search position on a failed match when /g is in effect.
1697
1698 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1699 you can use any pair of non-whitespace (ASCII) characters
1700 as delimiters.  This is particularly useful for matching path names
1701 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1702 the delimiter, then a match-only-once rule applies,
1703 described in C<m?PATTERN?> below.
1704 If "'" is the delimiter, no interpolation is performed on the PATTERN.
1705 When using a character valid in an identifier, whitespace is required
1706 after the C<m>.
1707
1708 PATTERN may contain variables, which will be interpolated
1709 every time the pattern search is evaluated, except
1710 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1711 C<$|> are not interpolated because they look like end-of-string tests.)
1712 Perl will not recompile the pattern unless an interpolated
1713 variable that it contains changes.  You can force Perl to skip the
1714 test and never recompile by adding a C</o> (which stands for "once")
1715 after the trailing delimiter.
1716 Once upon a time, Perl would recompile regular expressions
1717 unnecessarily, and this modifier was useful to tell it not to do so, in the
1718 interests of speed.  But now, the only reasons to use C</o> are either:
1719
1720 =over
1721
1722 =item 1
1723
1724 The variables are thousands of characters long and you know that they
1725 don't change, and you need to wring out the last little bit of speed by
1726 having Perl skip testing for that.  (There is a maintenance penalty for
1727 doing this, as mentioning C</o> constitutes a promise that you won't
1728 change the variables in the pattern.  If you do change them, Perl won't
1729 even notice.)
1730
1731 =item 2
1732
1733 you want the pattern to use the initial values of the variables
1734 regardless of whether they change or not.  (But there are saner ways
1735 of accomplishing this than using C</o>.)
1736
1737 =item 3
1738
1739 If the pattern contains embedded code, such as
1740
1741     use re 'eval';
1742     $code = 'foo(?{ $x })';
1743     /$code/
1744
1745 then perl will recompile each time, even though the pattern string hasn't
1746 changed, to ensure that the current value of C<$x> is seen each time.
1747 Use C</o> if you want to avoid this.
1748
1749 =back
1750
1751 The bottom line is that using C</o> is almost never a good idea.
1752
1753 =item The empty pattern //
1754
1755 If the PATTERN evaluates to the empty string, the last
1756 I<successfully> matched regular expression is used instead. In this
1757 case, only the C<g> and C<c> flags on the empty pattern are honored;
1758 the other flags are taken from the original pattern. If no match has
1759 previously succeeded, this will (silently) act instead as a genuine
1760 empty pattern (which will always match).
1761
1762 Note that it's possible to confuse Perl into thinking C<//> (the empty
1763 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1764 good about this, but some pathological cases might trigger this, such as
1765 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1766 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1767 will assume you meant defined-or.  If you meant the empty regex, just
1768 use parentheses or spaces to disambiguate, or even prefix the empty
1769 regex with an C<m> (so C<//> becomes C<m//>).
1770
1771 =item Matching in list context
1772
1773 If the C</g> option is not used, C<m//> in list context returns a
1774 list consisting of the subexpressions matched by the parentheses in the
1775 pattern, that is, (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
1776 also set, and that this differs from Perl 4's behavior.)  When there are
1777 no parentheses in the pattern, the return value is the list C<(1)> for
1778 success.  With or without parentheses, an empty list is returned upon
1779 failure.
1780
1781 Examples:
1782
1783     open(TTY, "+</dev/tty")
1784         || die "can't access /dev/tty: $!";
1785
1786     <TTY> =~ /^y/i && foo();    # do foo if desired
1787
1788     if (/Version: *([0-9.]*)/) { $version = $1; }
1789
1790     next if m#^/usr/spool/uucp#;
1791
1792     # poor man's grep
1793     $arg = shift;
1794     while (<>) {
1795         print if /$arg/o;       # compile only once (no longer needed!)
1796     }
1797
1798     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1799
1800 This last example splits $foo into the first two words and the
1801 remainder of the line, and assigns those three fields to $F1, $F2, and
1802 $Etc.  The conditional is true if any variables were assigned; that is,
1803 if the pattern matched.
1804
1805 The C</g> modifier specifies global pattern matching--that is,
1806 matching as many times as possible within the string. How it behaves
1807 depends on the context. In list context, it returns a list of the
1808 substrings matched by any capturing parentheses in the regular
1809 expression. If there are no parentheses, it returns a list of all
1810 the matched strings, as if there were parentheses around the whole
1811 pattern.
1812
1813 In scalar context, each execution of C<m//g> finds the next match,
1814 returning true if it matches, and false if there is no further match.
1815 The position after the last match can be read or set using the C<pos()>
1816 function; see L<perlfunc/pos>. A failed match normally resets the
1817 search position to the beginning of the string, but you can avoid that
1818 by adding the C</c> modifier (for example, C<m//gc>). Modifying the target
1819 string also resets the search position.
1820
1821 =item \G assertion
1822
1823 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1824 zero-width assertion that matches the exact position where the
1825 previous C<m//g>, if any, left off. Without the C</g> modifier, the
1826 C<\G> assertion still anchors at C<pos()> as it was at the start of
1827 the operation (see L<perlfunc/pos>), but the match is of course only
1828 attempted once. Using C<\G> without C</g> on a target string that has
1829 not previously had a C</g> match applied to it is the same as using
1830 the C<\A> assertion to match the beginning of the string.  Note also
1831 that, currently, C<\G> is only properly supported when anchored at the
1832 very beginning of the pattern.
1833
1834 Examples:
1835
1836     # list context
1837     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1838
1839     # scalar context
1840     local $/ = "";
1841     while ($paragraph = <>) {
1842         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1843             $sentences++;
1844         }
1845     }
1846     say $sentences;
1847
1848 Here's another way to check for sentences in a paragraph:
1849
1850     my $sentence_rx = qr{
1851         (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or whitespace
1852         \p{Lu}                      # capital letter
1853         .*?                         # a bunch of anything
1854         (?<= \S )                   # that ends in non-whitespace
1855         (?<! \b [DMS]r  )           # but isn't a common abbreviation
1856         (?<! \b Mrs )
1857         (?<! \b Sra )
1858         (?<! \b St  )
1859         [.?!]                       # followed by a sentence ender
1860         (?= $ | \s )                # in front of end-of-string or whitespace
1861     }sx;
1862     local $/ = "";
1863     while (my $paragraph = <>) {
1864         say "NEW PARAGRAPH";
1865         my $count = 0;
1866         while ($paragraph =~ /($sentence_rx)/g) {
1867             printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1868         }
1869     }
1870
1871 Here's how to use C<m//gc> with C<\G>:
1872
1873     $_ = "ppooqppqq";
1874     while ($i++ < 2) {
1875         print "1: '";
1876         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1877         print "2: '";
1878         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1879         print "3: '";
1880         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1881     }
1882     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1883
1884 The last example should print:
1885
1886     1: 'oo', pos=4
1887     2: 'q', pos=5
1888     3: 'pp', pos=7
1889     1: '', pos=7
1890     2: 'q', pos=8
1891     3: '', pos=8
1892     Final: 'q', pos=8
1893
1894 Notice that the final match matched C<q> instead of C<p>, which a match
1895 without the C<\G> anchor would have done. Also note that the final match
1896 did not update C<pos>. C<pos> is only updated on a C</g> match. If the
1897 final match did indeed match C<p>, it's a good bet that you're running a
1898 very old (pre-5.6.0) version of Perl.
1899
1900 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1901 combine several regexps like this to process a string part-by-part,
1902 doing different actions depending on which regexp matched.  Each
1903 regexp tries to match where the previous one leaves off.
1904
1905  $_ = <<'EOL';
1906     $url = URI::URL->new( "http://example.com/" ); die if $url eq "xXx";
1907  EOL
1908
1909  LOOP: {
1910      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1911      print(" lowercase"),    redo LOOP if /\G\p{Ll}+\b[,.;]?\s*/gc;
1912      print(" UPPERCASE"),    redo LOOP if /\G\p{Lu}+\b[,.;]?\s*/gc;
1913      print(" Capitalized"),  redo LOOP if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
1914      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
1915      print(" alphanumeric"), redo LOOP if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
1916      print(" line-noise"),   redo LOOP if /\G\W+/gc;
1917      print ". That's all!\n";
1918  }
1919
1920 Here is the output (split into several lines):
1921
1922     line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
1923     line-noise lowercase line-noise lowercase line-noise lowercase
1924     lowercase line-noise lowercase lowercase line-noise lowercase
1925     lowercase line-noise MiXeD line-noise. That's all!
1926
1927 =item m?PATTERN?msixpodualgc
1928 X<?> X<operator, match-once>
1929
1930 =item ?PATTERN?msixpodualgc
1931
1932 This is just like the C<m/PATTERN/> search, except that it matches
1933 only once between calls to the reset() operator.  This is a useful
1934 optimization when you want to see only the first occurrence of
1935 something in each file of a set of files, for instance.  Only C<m??>
1936 patterns local to the current package are reset.
1937
1938     while (<>) {
1939         if (m?^$?) {
1940                             # blank line between header and body
1941         }
1942     } continue {
1943         reset if eof;       # clear m?? status for next file
1944     }
1945
1946 Another example switched the first "latin1" encoding it finds
1947 to "utf8" in a pod file:
1948
1949     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
1950
1951 The match-once behavior is controlled by the match delimiter being
1952 C<?>; with any other delimiter this is the normal C<m//> operator.  
1953
1954 For historical reasons, the leading C<m> in C<m?PATTERN?> is optional,
1955 but the resulting C<?PATTERN?> syntax is deprecated, will warn on
1956 usage and might be removed from a future stable release of Perl (without
1957 further notice!).
1958
1959 =item s/PATTERN/REPLACEMENT/msixpodualgcer
1960 X<substitute> X<substitution> X<replace> X<regexp, replace>
1961 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
1962
1963 Searches a string for a pattern, and if found, replaces that pattern
1964 with the replacement text and returns the number of substitutions
1965 made.  Otherwise it returns false (specifically, the empty string).
1966
1967 If the C</r> (non-destructive) option is used then it runs the
1968 substitution on a copy of the string and instead of returning the
1969 number of substitutions, it returns the copy whether or not a
1970 substitution occurred.  The original string is never changed when
1971 C</r> is used.  The copy will always be a plain string, even if the
1972 input is an object or a tied variable.
1973
1974 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1975 variable is searched and modified.  Unless the C</r> option is used,
1976 the string specified must be a scalar variable, an array element, a
1977 hash element, or an assignment to one of those; that is, some sort of
1978 scalar lvalue.
1979
1980 If the delimiter chosen is a single quote, no interpolation is
1981 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1982 PATTERN contains a $ that looks like a variable rather than an
1983 end-of-string test, the variable will be interpolated into the pattern
1984 at run-time.  If you want the pattern compiled only once the first time
1985 the variable is interpolated, use the C</o> option.  If the pattern
1986 evaluates to the empty string, the last successfully executed regular
1987 expression is used instead.  See L<perlre> for further explanation on these.
1988
1989 Options are as with m// with the addition of the following replacement
1990 specific options:
1991
1992     e   Evaluate the right side as an expression.
1993     ee  Evaluate the right side as a string then eval the result.
1994     r   Return substitution and leave the original string untouched.
1995
1996 Any non-whitespace delimiter may replace the slashes.  Add space after
1997 the C<s> when using a character allowed in identifiers.  If single quotes
1998 are used, no interpretation is done on the replacement string (the C</e>
1999 modifier overrides this, however).  Unlike Perl 4, Perl 5 treats backticks
2000 as normal delimiters; the replacement text is not evaluated as a command.
2001 If the PATTERN is delimited by bracketing quotes, the REPLACEMENT has
2002 its own pair of quotes, which may or may not be bracketing quotes, for example,
2003 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2004 replacement portion to be treated as a full-fledged Perl expression
2005 and evaluated right then and there.  It is, however, syntax checked at
2006 compile-time. A second C<e> modifier will cause the replacement portion
2007 to be C<eval>ed before being run as a Perl expression.
2008
2009 Examples:
2010
2011     s/\bgreen\b/mauve/g;                # don't change wintergreen
2012
2013     $path =~ s|/usr/bin|/usr/local/bin|;
2014
2015     s/Login: $foo/Login: $bar/; # run-time pattern
2016
2017     ($foo = $bar) =~ s/this/that/;      # copy first, then change
2018     ($foo = "$bar") =~ s/this/that/;    # convert to string, copy, then change
2019     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2020     $foo = $bar =~ s/this/that/r
2021                 =~ s/that/the other/r;  # Chained substitutes using /r
2022     @foo = map { s/this/that/r } @bar   # /r is very useful in maps
2023
2024     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
2025
2026     $_ = 'abc123xyz';
2027     s/\d+/$&*2/e;               # yields 'abc246xyz'
2028     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2029     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2030
2031     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2032     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2033     s/^=(\w+)/pod($1)/ge;       # use function call
2034
2035     $_ = 'abc123xyz';
2036     $a = s/abc/def/r;           # $a is 'def123xyz' and
2037                                 # $_ remains 'abc123xyz'.
2038
2039     # expand variables in $_, but dynamics only, using
2040     # symbolic dereferencing
2041     s/\$(\w+)/${$1}/g;
2042
2043     # Add one to the value of any numbers in the string
2044     s/(\d+)/1 + $1/eg;
2045
2046     # Titlecase words in the last 30 characters only
2047     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2048
2049     # This will expand any embedded scalar variable
2050     # (including lexicals) in $_ : First $1 is interpolated
2051     # to the variable name, and then evaluated
2052     s/(\$\w+)/$1/eeg;
2053
2054     # Delete (most) C comments.
2055     $program =~ s {
2056         /\*     # Match the opening delimiter.
2057         .*?     # Match a minimal number of characters.
2058         \*/     # Match the closing delimiter.
2059     } []gsx;
2060
2061     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_, expensively
2062
2063     for ($variable) {           # trim whitespace in $variable, cheap
2064         s/^\s+//;
2065         s/\s+$//;
2066     }
2067
2068     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2069
2070 Note the use of $ instead of \ in the last example.  Unlike
2071 B<sed>, we use the \<I<digit>> form in only the left hand side.
2072 Anywhere else it's $<I<digit>>.
2073
2074 Occasionally, you can't use just a C</g> to get all the changes
2075 to occur that you might want.  Here are two common cases:
2076
2077     # put commas in the right places in an integer
2078     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2079
2080     # expand tabs to 8-column spacing
2081     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2082
2083 =back
2084
2085 =head2 Quote-Like Operators
2086 X<operator, quote-like>
2087
2088 =over 4
2089
2090 =item q/STRING/
2091 X<q> X<quote, single> X<'> X<''>
2092
2093 =item 'STRING'
2094
2095 A single-quoted, literal string.  A backslash represents a backslash
2096 unless followed by the delimiter or another backslash, in which case
2097 the delimiter or backslash is interpolated.
2098
2099     $foo = q!I said, "You said, 'She said it.'"!;
2100     $bar = q('This is it.');
2101     $baz = '\n';                # a two-character string
2102
2103 =item qq/STRING/
2104 X<qq> X<quote, double> X<"> X<"">
2105
2106 =item "STRING"
2107
2108 A double-quoted, interpolated string.
2109
2110     $_ .= qq
2111      (*** The previous line contains the naughty word "$1".\n)
2112                 if /\b(tcl|java|python)\b/i;      # :-)
2113     $baz = "\n";                # a one-character string
2114
2115 =item qx/STRING/
2116 X<qx> X<`> X<``> X<backtick>
2117
2118 =item `STRING`
2119
2120 A string which is (possibly) interpolated and then executed as a
2121 system command with C</bin/sh> or its equivalent.  Shell wildcards,
2122 pipes, and redirections will be honored.  The collected standard
2123 output of the command is returned; standard error is unaffected.  In
2124 scalar context, it comes back as a single (potentially multi-line)
2125 string, or undef if the command failed.  In list context, returns a
2126 list of lines (however you've defined lines with $/ or
2127 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
2128
2129 Because backticks do not affect standard error, use shell file descriptor
2130 syntax (assuming the shell supports this) if you care to address this.
2131 To capture a command's STDERR and STDOUT together:
2132
2133     $output = `cmd 2>&1`;
2134
2135 To capture a command's STDOUT but discard its STDERR:
2136
2137     $output = `cmd 2>/dev/null`;
2138
2139 To capture a command's STDERR but discard its STDOUT (ordering is
2140 important here):
2141
2142     $output = `cmd 2>&1 1>/dev/null`;
2143
2144 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2145 but leave its STDOUT to come out the old STDERR:
2146
2147     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2148
2149 To read both a command's STDOUT and its STDERR separately, it's easiest
2150 to redirect them separately to files, and then read from those files
2151 when the program is done:
2152
2153     system("program args 1>program.stdout 2>program.stderr");
2154
2155 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2156 For example:
2157
2158     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2159     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2160     print STDOUT `sort`;
2161
2162 will print the sorted contents of the file named F<"stuff">.
2163
2164 Using single-quote as a delimiter protects the command from Perl's
2165 double-quote interpolation, passing it on to the shell instead:
2166
2167     $perl_info  = qx(ps $$);            # that's Perl's $$
2168     $shell_info = qx'ps $$';            # that's the new shell's $$
2169
2170 How that string gets evaluated is entirely subject to the command
2171 interpreter on your system.  On most platforms, you will have to protect
2172 shell metacharacters if you want them treated literally.  This is in
2173 practice difficult to do, as it's unclear how to escape which characters.
2174 See L<perlsec> for a clean and safe example of a manual fork() and exec()
2175 to emulate backticks safely.
2176
2177 On some platforms (notably DOS-like ones), the shell may not be
2178 capable of dealing with multiline commands, so putting newlines in
2179 the string may not get you what you want.  You may be able to evaluate
2180 multiple commands in a single line by separating them with the command
2181 separator character, if your shell supports that (for example, C<;> on 
2182 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2183
2184 Beginning with v5.6.0, Perl will attempt to flush all files opened for
2185 output before starting the child process, but this may not be supported
2186 on some platforms (see L<perlport>).  To be safe, you may need to set
2187 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2188 C<IO::Handle> on any open handles.
2189
2190 Beware that some command shells may place restrictions on the length
2191 of the command line.  You must ensure your strings don't exceed this
2192 limit after any necessary interpolations.  See the platform-specific
2193 release notes for more details about your particular environment.
2194
2195 Using this operator can lead to programs that are difficult to port,
2196 because the shell commands called vary between systems, and may in
2197 fact not be present at all.  As one example, the C<type> command under
2198 the POSIX shell is very different from the C<type> command under DOS.
2199 That doesn't mean you should go out of your way to avoid backticks
2200 when they're the right way to get something done.  Perl was made to be
2201 a glue language, and one of the things it glues together is commands.
2202 Just understand what you're getting yourself into.
2203
2204 See L</"I/O Operators"> for more discussion.
2205
2206 =item qw/STRING/
2207 X<qw> X<quote, list> X<quote, words>
2208
2209 Evaluates to a list of the words extracted out of STRING, using embedded
2210 whitespace as the word delimiters.  It can be understood as being roughly
2211 equivalent to:
2212
2213     split(" ", q/STRING/);
2214
2215 the differences being that it generates a real list at compile time, and
2216 in scalar context it returns the last element in the list.  So
2217 this expression:
2218
2219     qw(foo bar baz)
2220
2221 is semantically equivalent to the list:
2222
2223     "foo", "bar", "baz"
2224
2225 Some frequently seen examples:
2226
2227     use POSIX qw( setlocale localeconv )
2228     @EXPORT = qw( foo bar baz );
2229
2230 A common mistake is to try to separate the words with comma or to
2231 put comments into a multi-line C<qw>-string.  For this reason, the
2232 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
2233 produces warnings if the STRING contains the "," or the "#" character.
2234
2235 =item tr/SEARCHLIST/REPLACEMENTLIST/cdsr
2236 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2237
2238 =item y/SEARCHLIST/REPLACEMENTLIST/cdsr
2239
2240 Transliterates all occurrences of the characters found in the search list
2241 with the corresponding character in the replacement list.  It returns
2242 the number of characters replaced or deleted.  If no string is
2243 specified via the C<=~> or C<!~> operator, the $_ string is transliterated.
2244
2245 If the C</r> (non-destructive) option is present, a new copy of the string
2246 is made and its characters transliterated, and this copy is returned no
2247 matter whether it was modified or not: the original string is always
2248 left unchanged.  The new copy is always a plain string, even if the input
2249 string is an object or a tied variable.
2250
2251 Unless the C</r> option is used, the string specified with C<=~> must be a
2252 scalar variable, an array element, a hash element, or an assignment to one
2253 of those; in other words, an lvalue.
2254
2255 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2256 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2257 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2258 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
2259 its own pair of quotes, which may or may not be bracketing quotes;
2260 for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2261
2262 Note that C<tr> does B<not> do regular expression character classes such as
2263 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the tr(1)
2264 utility.  If you want to map strings between lower/upper cases, see
2265 L<perlfunc/lc> and L<perlfunc/uc>, and in general consider using the C<s>
2266 operator if you need regular expressions.  The C<\U>, C<\u>, C<\L>, and
2267 C<\l> string-interpolation escapes on the right side of a substitution
2268 operator will perform correct case-mappings, but C<tr[a-z][A-Z]> will not
2269 (except sometimes on legacy 7-bit data).
2270
2271 Note also that the whole range idea is rather unportable between
2272 character sets--and even within character sets they may cause results
2273 you probably didn't expect.  A sound principle is to use only ranges
2274 that begin from and end at either alphabets of equal case (a-e, A-E),
2275 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
2276 character sets in full.
2277
2278 Options:
2279
2280     c   Complement the SEARCHLIST.
2281     d   Delete found but unreplaced characters.
2282     s   Squash duplicate replaced characters.
2283     r   Return the modified string and leave the original string
2284         untouched.
2285
2286 If the C</c> modifier is specified, the SEARCHLIST character set
2287 is complemented.  If the C</d> modifier is specified, any characters
2288 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
2289 (Note that this is slightly more flexible than the behavior of some
2290 B<tr> programs, which delete anything they find in the SEARCHLIST,
2291 period.) If the C</s> modifier is specified, sequences of characters
2292 that were transliterated to the same character are squashed down
2293 to a single instance of the character.
2294
2295 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
2296 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
2297 than the SEARCHLIST, the final character is replicated till it is long
2298 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
2299 This latter is useful for counting characters in a class or for
2300 squashing character sequences in a class.
2301
2302 Examples:
2303
2304     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2305
2306     $cnt = tr/*/*/;             # count the stars in $_
2307
2308     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2309
2310     $cnt = tr/0-9//;            # count the digits in $_
2311
2312     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2313
2314     ($HOST = $host) =~ tr/a-z/A-Z/;
2315      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2316
2317     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2318                   =~ s/:/ -p/r;
2319
2320     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2321
2322     @stripped = map tr/a-zA-Z/ /csr, @original;
2323                                 # /r with map
2324
2325     tr [\200-\377]
2326        [\000-\177];             # wickedly delete 8th bit
2327
2328 If multiple transliterations are given for a character, only the
2329 first one is used:
2330
2331     tr/AAA/XYZ/
2332
2333 will transliterate any A to X.
2334
2335 Because the transliteration table is built at compile time, neither
2336 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
2337 interpolation.  That means that if you want to use variables, you
2338 must use an eval():
2339
2340     eval "tr/$oldlist/$newlist/";
2341     die $@ if $@;
2342
2343     eval "tr/$oldlist/$newlist/, 1" or die $@;
2344
2345 =item <<EOF
2346 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2347
2348 A line-oriented form of quoting is based on the shell "here-document"
2349 syntax.  Following a C<< << >> you specify a string to terminate
2350 the quoted material, and all lines following the current line down to
2351 the terminating string are the value of the item.
2352
2353 The terminating string may be either an identifier (a word), or some
2354 quoted text.  An unquoted identifier works like double quotes.
2355 There may not be a space between the C<< << >> and the identifier,
2356 unless the identifier is explicitly quoted.  (If you put a space it
2357 will be treated as a null identifier, which is valid, and matches the
2358 first empty line.)  The terminating string must appear by itself
2359 (unquoted and with no surrounding whitespace) on the terminating line.
2360
2361 If the terminating string is quoted, the type of quotes used determine
2362 the treatment of the text.
2363
2364 =over 4
2365
2366 =item Double Quotes
2367
2368 Double quotes indicate that the text will be interpolated using exactly
2369 the same rules as normal double quoted strings.
2370
2371        print <<EOF;
2372     The price is $Price.
2373     EOF
2374
2375        print << "EOF"; # same as above
2376     The price is $Price.
2377     EOF
2378
2379
2380 =item Single Quotes
2381
2382 Single quotes indicate the text is to be treated literally with no
2383 interpolation of its content. This is similar to single quoted
2384 strings except that backslashes have no special meaning, with C<\\>
2385 being treated as two backslashes and not one as they would in every
2386 other quoting construct.
2387
2388 Just as in the shell, a backslashed bareword following the C<<< << >>>
2389 means the same thing as a single-quoted string does:
2390
2391         $cost = <<'VISTA';  # hasta la ...
2392     That'll be $10 please, ma'am.
2393     VISTA
2394
2395         $cost = <<\VISTA;   # Same thing!
2396     That'll be $10 please, ma'am.
2397     VISTA
2398
2399 This is the only form of quoting in perl where there is no need
2400 to worry about escaping content, something that code generators
2401 can and do make good use of.
2402
2403 =item Backticks
2404
2405 The content of the here doc is treated just as it would be if the
2406 string were embedded in backticks. Thus the content is interpolated
2407 as though it were double quoted and then executed via the shell, with
2408 the results of the execution returned.
2409
2410        print << `EOC`; # execute command and get results
2411     echo hi there
2412     EOC
2413
2414 =back
2415
2416 It is possible to stack multiple here-docs in a row:
2417
2418        print <<"foo", <<"bar"; # you can stack them
2419     I said foo.
2420     foo
2421     I said bar.
2422     bar
2423
2424        myfunc(<< "THIS", 23, <<'THAT');
2425     Here's a line
2426     or two.
2427     THIS
2428     and here's another.
2429     THAT
2430
2431 Just don't forget that you have to put a semicolon on the end
2432 to finish the statement, as Perl doesn't know you're not going to
2433 try to do this:
2434
2435        print <<ABC
2436     179231
2437     ABC
2438        + 20;
2439
2440 If you want to remove the line terminator from your here-docs,
2441 use C<chomp()>.
2442
2443     chomp($string = <<'END');
2444     This is a string.
2445     END
2446
2447 If you want your here-docs to be indented with the rest of the code,
2448 you'll need to remove leading whitespace from each line manually:
2449
2450     ($quote = <<'FINIS') =~ s/^\s+//gm;
2451        The Road goes ever on and on,
2452        down from the door where it began.
2453     FINIS
2454
2455 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2456 the quoted material must come on the lines following the final delimiter.
2457 So instead of
2458
2459     s/this/<<E . 'that'
2460     the other
2461     E
2462      . 'more '/eg;
2463
2464 you have to write
2465
2466     s/this/<<E . 'that'
2467      . 'more '/eg;
2468     the other
2469     E
2470
2471 If the terminating identifier is on the last line of the program, you
2472 must be sure there is a newline after it; otherwise, Perl will give the
2473 warning B<Can't find string terminator "END" anywhere before EOF...>.
2474
2475 Additionally, quoting rules for the end-of-string identifier are
2476 unrelated to Perl's quoting rules. C<q()>, C<qq()>, and the like are not
2477 supported in place of C<''> and C<"">, and the only interpolation is for
2478 backslashing the quoting character:
2479
2480     print << "abc\"def";
2481     testing...
2482     abc"def
2483
2484 Finally, quoted strings cannot span multiple lines.  The general rule is
2485 that the identifier must be a string literal.  Stick with that, and you
2486 should be safe.
2487
2488 =back
2489
2490 =head2 Gory details of parsing quoted constructs
2491 X<quote, gory details>
2492
2493 When presented with something that might have several different
2494 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2495 principle to pick the most probable interpretation.  This strategy
2496 is so successful that Perl programmers often do not suspect the
2497 ambivalence of what they write.  But from time to time, Perl's
2498 notions differ substantially from what the author honestly meant.
2499
2500 This section hopes to clarify how Perl handles quoted constructs.
2501 Although the most common reason to learn this is to unravel labyrinthine
2502 regular expressions, because the initial steps of parsing are the
2503 same for all quoting operators, they are all discussed together.
2504
2505 The most important Perl parsing rule is the first one discussed
2506 below: when processing a quoted construct, Perl first finds the end
2507 of that construct, then interprets its contents.  If you understand
2508 this rule, you may skip the rest of this section on the first
2509 reading.  The other rules are likely to contradict the user's
2510 expectations much less frequently than this first one.
2511
2512 Some passes discussed below are performed concurrently, but because
2513 their results are the same, we consider them individually.  For different
2514 quoting constructs, Perl performs different numbers of passes, from
2515 one to four, but these passes are always performed in the same order.
2516
2517 =over 4
2518
2519 =item Finding the end
2520
2521 The first pass is finding the end of the quoted construct, where
2522 the information about the delimiters is used in parsing.
2523 During this search, text between the starting and ending delimiters
2524 is copied to a safe location. The text copied gets delimiter-independent.
2525
2526 If the construct is a here-doc, the ending delimiter is a line
2527 that has a terminating string as the content. Therefore C<<<EOF> is
2528 terminated by C<EOF> immediately followed by C<"\n"> and starting
2529 from the first column of the terminating line.
2530 When searching for the terminating line of a here-doc, nothing
2531 is skipped. In other words, lines after the here-doc syntax
2532 are compared with the terminating string line by line.
2533
2534 For the constructs except here-docs, single characters are used as starting
2535 and ending delimiters. If the starting delimiter is an opening punctuation
2536 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2537 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2538 If the starting delimiter is an unpaired character like C</> or a closing
2539 punctuation, the ending delimiter is same as the starting delimiter.
2540 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2541 C<qq[]> and C<qq]]> constructs.
2542
2543 When searching for single-character delimiters, escaped delimiters
2544 and C<\\> are skipped.  For example, while searching for terminating C</>,
2545 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2546 bracketing, nested pairs are also skipped.  For example, while searching
2547 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2548 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2549 However, when backslashes are used as the delimiters (like C<qq\\> and
2550 C<tr\\\>), nothing is skipped.
2551 During the search for the end, backslashes that escape delimiters or
2552 backslashes are removed (exactly speaking, they are not copied to the
2553 safe location).
2554
2555 For constructs with three-part delimiters (C<s///>, C<y///>, and
2556 C<tr///>), the search is repeated once more.
2557 If the first delimiter is not an opening punctuation, three delimiters must
2558 be same such as C<s!!!> and C<tr)))>, in which case the second delimiter
2559 terminates the left part and starts the right part at once.
2560 If the left part is delimited by bracketing punctuation (that is C<()>,
2561 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2562 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2563 and comments are allowed between both parts, though the comment must follow
2564 at least one whitespace character; otherwise a character expected as the 
2565 start of the comment may be regarded as the starting delimiter of the right part.
2566
2567 During this search no attention is paid to the semantics of the construct.
2568 Thus:
2569
2570     "$hash{"$foo/$bar"}"
2571
2572 or:
2573
2574     m/
2575       bar       # NOT a comment, this slash / terminated m//!
2576      /x
2577
2578 do not form legal quoted expressions.   The quoted part ends on the
2579 first C<"> and C</>, and the rest happens to be a syntax error.
2580 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2581 the example above is not C<m//x>, but rather C<m//> with no C</x>
2582 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2583
2584 Also no attention is paid to C<\c\> (multichar control char syntax) during
2585 this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2586 of C<\/>, and the following C</> is not recognized as a delimiter.
2587 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2588
2589 =item Interpolation
2590 X<interpolation>
2591
2592 The next step is interpolation in the text obtained, which is now
2593 delimiter-independent.  There are multiple cases.
2594
2595 =over 4
2596
2597 =item C<<<'EOF'>
2598
2599 No interpolation is performed.
2600 Note that the combination C<\\> is left intact, since escaped delimiters
2601 are not available for here-docs.
2602
2603 =item  C<m''>, the pattern of C<s'''>
2604
2605 No interpolation is performed at this stage.
2606 Any backslashed sequences including C<\\> are treated at the stage
2607 to L</"parsing regular expressions">.
2608
2609 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2610
2611 The only interpolation is removal of C<\> from pairs of C<\\>.
2612 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
2613 as a hyphen and no character range is available.
2614 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2615
2616 =item C<tr///>, C<y///>
2617
2618 No variable interpolation occurs.  String modifying combinations for
2619 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2620 The other escape sequences such as C<\200> and C<\t> and backslashed
2621 characters such as C<\\> and C<\-> are converted to appropriate literals.
2622 The character C<-> is treated specially and therefore C<\-> is treated
2623 as a literal C<->.
2624
2625 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2626
2627 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2628 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2629 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
2630 The other escape sequences such as C<\200> and C<\t> and backslashed
2631 characters such as C<\\> and C<\-> are replaced with appropriate
2632 expansions.
2633
2634 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2635 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2636 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
2637 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2638 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2639 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2640 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2641
2642   $str = '\t';
2643   return "\Q$str";
2644
2645 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2646
2647 Interpolated scalars and arrays are converted internally to the C<join> and
2648 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
2649
2650   $foo . " XXX '" . (join $", @arr) . "'";
2651
2652 All operations above are performed simultaneously, left to right.
2653
2654 Because the result of C<"\Q STRING \E"> has all metacharacters
2655 quoted, there is no way to insert a literal C<$> or C<@> inside a
2656 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
2657 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2658 scalar.
2659
2660 Note also that the interpolation code needs to make a decision on
2661 where the interpolated scalar ends.  For instance, whether
2662 C<< "a $b -> {c}" >> really means:
2663
2664   "a " . $b . " -> {c}";
2665
2666 or:
2667
2668   "a " . $b -> {c};
2669
2670 Most of the time, the longest possible text that does not include
2671 spaces between components and which contains matching braces or
2672 brackets.  because the outcome may be determined by voting based
2673 on heuristic estimators, the result is not strictly predictable.
2674 Fortunately, it's usually correct for ambiguous cases.
2675
2676 =item the replacement of C<s///>
2677
2678 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2679 happens as with C<qq//> constructs.
2680
2681 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2682 the replacement text of C<s///>, in order to correct the incorrigible
2683 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2684 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
2685 (that is, the C<$^W> variable) was set.
2686
2687 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2688
2689 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2690 and interpolation happens (almost) as with C<qq//> constructs.
2691
2692 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2693 form for the regex compiler.  (This is because, as mentioned below, the regex
2694 compilation may be done at execution time, and C<\N{...}> is a compile-time
2695 construct.)
2696
2697 However any other combinations of C<\> followed by a character
2698 are not substituted but only skipped, in order to parse them
2699 as regular expressions at the following step.
2700 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2701 treated as an array symbol (for example C<@foo>),
2702 even though the same text in C<qq//> gives interpolation of C<\c@>.
2703
2704 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2705 back to the perl parser, in a similar way that an interpolated array
2706 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2707
2708 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
2709 a C<#>-comment in a C<//x>-regular expression, no processing is
2710 performed whatsoever.  This is the first step at which the presence
2711 of the C<//x> modifier is relevant.
2712
2713 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2714 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2715 voted (by several different estimators) to be either an array element
2716 or C<$var> followed by an RE alternative.  This is where the notation
2717 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2718 array element C<-9>, not as a regular expression from the variable
2719 C<$arr> followed by a digit, which would be the interpretation of
2720 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2721 the result is not predictable.
2722
2723 The lack of processing of C<\\> creates specific restrictions on
2724 the post-processed text.  If the delimiter is C</>, one cannot get
2725 the combination C<\/> into the result of this step.  C</> will
2726 finish the regular expression, C<\/> will be stripped to C</> on
2727 the previous step, and C<\\/> will be left as is.  Because C</> is
2728 equivalent to C<\/> inside a regular expression, this does not
2729 matter unless the delimiter happens to be character special to the
2730 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2731 alphanumeric char, as in:
2732
2733   m m ^ a \s* b mmx;
2734
2735 In the RE above, which is intentionally obfuscated for illustration, the
2736 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2737 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2738 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2739 non-whitespace choices.
2740
2741 =back
2742
2743 This step is the last one for all constructs except regular expressions,
2744 which are processed further.
2745
2746 =item parsing regular expressions
2747 X<regexp, parse>
2748
2749 Previous steps were performed during the compilation of Perl code,
2750 but this one happens at run time, although it may be optimized to
2751 be calculated at compile time if appropriate.  After preprocessing
2752 described above, and possibly after evaluation if concatenation,
2753 joining, casing translation, or metaquoting are involved, the
2754 resulting I<string> is passed to the RE engine for compilation.
2755
2756 Whatever happens in the RE engine might be better discussed in L<perlre>,
2757 but for the sake of continuity, we shall do so here.
2758
2759 This is another step where the presence of the C<//x> modifier is
2760 relevant.  The RE engine scans the string from left to right and
2761 converts it to a finite automaton.
2762
2763 Backslashed characters are either replaced with corresponding
2764 literal strings (as with C<\{>), or else they generate special nodes
2765 in the finite automaton (as with C<\b>).  Characters special to the
2766 RE engine (such as C<|>) generate corresponding nodes or groups of
2767 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2768 converted to literal strings to match, or else is ignored (as is
2769 whitespace and C<#>-style comments if C<//x> is present).
2770
2771 Parsing of the bracketed character class construct, C<[...]>, is
2772 rather different than the rule used for the rest of the pattern.
2773 The terminator of this construct is found using the same rules as
2774 for finding the terminator of a C<{}>-delimited construct, the only
2775 exception being that C<]> immediately following C<[> is treated as
2776 though preceded by a backslash.
2777
2778 The terminator of runtime C<(?{...})> is found by temporarily switching
2779 control to the perl parser, which should stop at the point where the
2780 logically balancing terminating C<}> is found.
2781
2782 It is possible to inspect both the string given to RE engine and the
2783 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2784 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2785 switch documented in L<perlrun/"Command Switches">.
2786
2787 =item Optimization of regular expressions
2788 X<regexp, optimization>
2789
2790 This step is listed for completeness only.  Since it does not change
2791 semantics, details of this step are not documented and are subject
2792 to change without notice.  This step is performed over the finite
2793 automaton that was generated during the previous pass.
2794
2795 It is at this stage that C<split()> silently optimizes C</^/> to
2796 mean C</^/m>.
2797
2798 =back
2799
2800 =head2 I/O Operators
2801 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2802 X<< <> >> X<@ARGV>
2803
2804 There are several I/O operators you should know about.
2805
2806 A string enclosed by backticks (grave accents) first undergoes
2807 double-quote interpolation.  It is then interpreted as an external
2808 command, and the output of that command is the value of the
2809 backtick string, like in a shell.  In scalar context, a single string
2810 consisting of all output is returned.  In list context, a list of
2811 values is returned, one per line of output.  (You can set C<$/> to use
2812 a different line terminator.)  The command is executed each time the
2813 pseudo-literal is evaluated.  The status value of the command is
2814 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2815 Unlike in B<csh>, no translation is done on the return data--newlines
2816 remain newlines.  Unlike in any of the shells, single quotes do not
2817 hide variable names in the command from interpretation.  To pass a
2818 literal dollar-sign through to the shell you need to hide it with a
2819 backslash.  The generalized form of backticks is C<qx//>.  (Because
2820 backticks always undergo shell expansion as well, see L<perlsec> for
2821 security concerns.)
2822 X<qx> X<`> X<``> X<backtick> X<glob>
2823
2824 In scalar context, evaluating a filehandle in angle brackets yields
2825 the next line from that file (the newline, if any, included), or
2826 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2827 (sometimes known as file-slurp mode) and the file is empty, it
2828 returns C<''> the first time, followed by C<undef> subsequently.
2829
2830 Ordinarily you must assign the returned value to a variable, but
2831 there is one situation where an automatic assignment happens.  If
2832 and only if the input symbol is the only thing inside the conditional
2833 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2834 the value is automatically assigned to the global variable $_,
2835 destroying whatever was there previously.  (This may seem like an
2836 odd thing to you, but you'll use the construct in almost every Perl
2837 script you write.)  The $_ variable is not implicitly localized.
2838 You'll have to put a C<local $_;> before the loop if you want that
2839 to happen.
2840
2841 The following lines are equivalent:
2842
2843     while (defined($_ = <STDIN>)) { print; }
2844     while ($_ = <STDIN>) { print; }
2845     while (<STDIN>) { print; }
2846     for (;<STDIN>;) { print; }
2847     print while defined($_ = <STDIN>);
2848     print while ($_ = <STDIN>);
2849     print while <STDIN>;
2850
2851 This also behaves similarly, but assigns to a lexical variable 
2852 instead of to C<$_>:
2853
2854     while (my $line = <STDIN>) { print $line }
2855
2856 In these loop constructs, the assigned value (whether assignment
2857 is automatic or explicit) is then tested to see whether it is
2858 defined.  The defined test avoids problems where the line has a string
2859 value that would be treated as false by Perl; for example a "" or
2860 a "0" with no trailing newline.  If you really mean for such values
2861 to terminate the loop, they should be tested for explicitly:
2862
2863     while (($_ = <STDIN>) ne '0') { ... }
2864     while (<STDIN>) { last unless $_; ... }
2865
2866 In other boolean contexts, C<< <FILEHANDLE> >> without an
2867 explicit C<defined> test or comparison elicits a warning if the
2868 C<use warnings> pragma or the B<-w>
2869 command-line switch (the C<$^W> variable) is in effect.
2870
2871 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2872 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2873 in packages, where they would be interpreted as local identifiers
2874 rather than global.)  Additional filehandles may be created with
2875 the open() function, amongst others.  See L<perlopentut> and
2876 L<perlfunc/open> for details on this.
2877 X<stdin> X<stdout> X<sterr>
2878
2879 If a <FILEHANDLE> is used in a context that is looking for
2880 a list, a list comprising all input lines is returned, one line per
2881 list element.  It's easy to grow to a rather large data space this
2882 way, so use with care.
2883
2884 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2885 See L<perlfunc/readline>.
2886
2887 The null filehandle <> is special: it can be used to emulate the
2888 behavior of B<sed> and B<awk>, and any other Unix filter program
2889 that takes a list of filenames, doing the same to each line
2890 of input from all of them.  Input from <> comes either from
2891 standard input, or from each file listed on the command line.  Here's
2892 how it works: the first time <> is evaluated, the @ARGV array is
2893 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2894 gives you standard input.  The @ARGV array is then processed as a list
2895 of filenames.  The loop
2896
2897     while (<>) {
2898         ...                     # code for each line
2899     }
2900
2901 is equivalent to the following Perl-like pseudo code:
2902
2903     unshift(@ARGV, '-') unless @ARGV;
2904     while ($ARGV = shift) {
2905         open(ARGV, $ARGV);
2906         while (<ARGV>) {
2907             ...         # code for each line
2908         }
2909     }
2910
2911 except that it isn't so cumbersome to say, and will actually work.
2912 It really does shift the @ARGV array and put the current filename
2913 into the $ARGV variable.  It also uses filehandle I<ARGV>
2914 internally. <> is just a synonym for <ARGV>, which
2915 is magical.  (The pseudo code above doesn't work because it treats
2916 <ARGV> as non-magical.)
2917
2918 Since the null filehandle uses the two argument form of L<perlfunc/open>
2919 it interprets special characters, so if you have a script like this:
2920
2921     while (<>) {
2922         print;
2923     }
2924
2925 and call it with C<perl dangerous.pl 'rm -rfv *|'>, it actually opens a
2926 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
2927 If you want all items in C<@ARGV> to be interpreted as file names, you
2928 can use the module C<ARGV::readonly> from CPAN.
2929
2930 You can modify @ARGV before the first <> as long as the array ends up
2931 containing the list of filenames you really want.  Line numbers (C<$.>)
2932 continue as though the input were one big happy file.  See the example
2933 in L<perlfunc/eof> for how to reset line numbers on each file.
2934
2935 If you want to set @ARGV to your own list of files, go right ahead.
2936 This sets @ARGV to all plain text files if no @ARGV was given:
2937
2938     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2939
2940 You can even set them to pipe commands.  For example, this automatically
2941 filters compressed arguments through B<gzip>:
2942
2943     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2944
2945 If you want to pass switches into your script, you can use one of the
2946 Getopts modules or put a loop on the front like this:
2947
2948     while ($_ = $ARGV[0], /^-/) {
2949         shift;
2950         last if /^--$/;
2951         if (/^-D(.*)/) { $debug = $1 }
2952         if (/^-v/)     { $verbose++  }
2953         # ...           # other switches
2954     }
2955
2956     while (<>) {
2957         # ...           # code for each line
2958     }
2959
2960 The <> symbol will return C<undef> for end-of-file only once.
2961 If you call it again after this, it will assume you are processing another
2962 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
2963
2964 If what the angle brackets contain is a simple scalar variable (for example,
2965 <$foo>), then that variable contains the name of the
2966 filehandle to input from, or its typeglob, or a reference to the
2967 same.  For example:
2968
2969     $fh = \*STDIN;
2970     $line = <$fh>;
2971
2972 If what's within the angle brackets is neither a filehandle nor a simple
2973 scalar variable containing a filehandle name, typeglob, or typeglob
2974 reference, it is interpreted as a filename pattern to be globbed, and
2975 either a list of filenames or the next filename in the list is returned,
2976 depending on context.  This distinction is determined on syntactic
2977 grounds alone.  That means C<< <$x> >> is always a readline() from
2978 an indirect handle, but C<< <$hash{key}> >> is always a glob().
2979 That's because $x is a simple scalar variable, but C<$hash{key}> is
2980 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
2981 is treated as C<glob("$x ")>, not C<readline($x)>.
2982
2983 One level of double-quote interpretation is done first, but you can't
2984 say C<< <$foo> >> because that's an indirect filehandle as explained
2985 in the previous paragraph.  (In older versions of Perl, programmers
2986 would insert curly brackets to force interpretation as a filename glob:
2987 C<< <${foo}> >>.  These days, it's considered cleaner to call the
2988 internal function directly as C<glob($foo)>, which is probably the right
2989 way to have done it in the first place.)  For example:
2990
2991     while (<*.c>) {
2992         chmod 0644, $_;
2993     }
2994
2995 is roughly equivalent to:
2996
2997     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
2998     while (<FOO>) {
2999         chomp;
3000         chmod 0644, $_;
3001     }
3002
3003 except that the globbing is actually done internally using the standard
3004 C<File::Glob> extension.  Of course, the shortest way to do the above is:
3005
3006     chmod 0644, <*.c>;
3007
3008 A (file)glob evaluates its (embedded) argument only when it is
3009 starting a new list.  All values must be read before it will start
3010 over.  In list context, this isn't important because you automatically
3011 get them all anyway.  However, in scalar context the operator returns
3012 the next value each time it's called, or C<undef> when the list has
3013 run out.  As with filehandle reads, an automatic C<defined> is
3014 generated when the glob occurs in the test part of a C<while>,
3015 because legal glob returns (for example,
3016 a file called F<0>) would otherwise
3017 terminate the loop.  Again, C<undef> is returned only once.  So if
3018 you're expecting a single value from a glob, it is much better to
3019 say
3020
3021     ($file) = <blurch*>;
3022
3023 than
3024
3025     $file = <blurch*>;
3026
3027 because the latter will alternate between returning a filename and
3028 returning false.
3029
3030 If you're trying to do variable interpolation, it's definitely better
3031 to use the glob() function, because the older notation can cause people
3032 to become confused with the indirect filehandle notation.
3033
3034     @files = glob("$dir/*.[ch]");
3035     @files = glob($files[$i]);
3036
3037 =head2 Constant Folding
3038 X<constant folding> X<folding>
3039
3040 Like C, Perl does a certain amount of expression evaluation at
3041 compile time whenever it determines that all arguments to an
3042 operator are static and have no side effects.  In particular, string
3043 concatenation happens at compile time between literals that don't do
3044 variable substitution.  Backslash interpolation also happens at
3045 compile time.  You can say
3046
3047       'Now is the time for all'
3048     . "\n" 
3049     .  'good men to come to.'
3050
3051 and this all reduces to one string internally.  Likewise, if
3052 you say
3053
3054     foreach $file (@filenames) {
3055         if (-s $file > 5 + 100 * 2**16) {  }
3056     }
3057
3058 the compiler precomputes the number which that expression
3059 represents so that the interpreter won't have to.
3060
3061 =head2 No-ops
3062 X<no-op> X<nop>
3063
3064 Perl doesn't officially have a no-op operator, but the bare constants
3065 C<0> and C<1> are special-cased not to produce a warning in void
3066 context, so you can for example safely do
3067
3068     1 while foo();
3069
3070 =head2 Bitwise String Operators
3071 X<operator, bitwise, string>
3072
3073 Bitstrings of any size may be manipulated by the bitwise operators
3074 (C<~ | & ^>).
3075
3076 If the operands to a binary bitwise op are strings of different
3077 sizes, B<|> and B<^> ops act as though the shorter operand had
3078 additional zero bits on the right, while the B<&> op acts as though
3079 the longer operand were truncated to the length of the shorter.
3080 The granularity for such extension or truncation is one or more
3081 bytes.
3082
3083     # ASCII-based examples
3084     print "j p \n" ^ " a h";            # prints "JAPH\n"
3085     print "JA" | "  ph\n";              # prints "japh\n"
3086     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3087     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3088
3089 If you are intending to manipulate bitstrings, be certain that
3090 you're supplying bitstrings: If an operand is a number, that will imply
3091 a B<numeric> bitwise operation.  You may explicitly show which type of
3092 operation you intend by using C<""> or C<0+>, as in the examples below.
3093
3094     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3095     $foo = '150' |  105;        # yields 255
3096     $foo =  150  | '105';       # yields 255
3097     $foo = '150' | '105';       # yields string '155' (under ASCII)
3098
3099     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3100     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3101
3102 See L<perlfunc/vec> for information on how to manipulate individual bits
3103 in a bit vector.
3104
3105 =head2 Integer Arithmetic
3106 X<integer>
3107
3108 By default, Perl assumes that it must do most of its arithmetic in
3109 floating point.  But by saying
3110
3111     use integer;
3112
3113 you may tell the compiler to use integer operations
3114 (see L<integer> for a detailed explanation) from here to the end of
3115 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3116
3117     no integer;
3118
3119 which lasts until the end of that BLOCK.  Note that this doesn't
3120 mean everything is an integer, merely that Perl will use integer
3121 operations for arithmetic, comparison, and bitwise operators.  For
3122 example, even under C<use integer>, if you take the C<sqrt(2)>, you'll
3123 still get C<1.4142135623731> or so.
3124
3125 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
3126 and ">>") always produce integral results.  (But see also
3127 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
3128 them.  By default, their results are interpreted as unsigned integers, but
3129 if C<use integer> is in effect, their results are interpreted
3130 as signed integers.  For example, C<~0> usually evaluates to a large
3131 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
3132 machines.
3133
3134 =head2 Floating-point Arithmetic
3135
3136 X<floating-point> X<floating point> X<float> X<real>
3137
3138 While C<use integer> provides integer-only arithmetic, there is no
3139 analogous mechanism to provide automatic rounding or truncation to a
3140 certain number of decimal places.  For rounding to a certain number
3141 of digits, sprintf() or printf() is usually the easiest route.
3142 See L<perlfaq4>.
3143
3144 Floating-point numbers are only approximations to what a mathematician
3145 would call real numbers.  There are infinitely more reals than floats,
3146 so some corners must be cut.  For example:
3147
3148     printf "%.20g\n", 123456789123456789;
3149     #        produces 123456789123456784
3150
3151 Testing for exact floating-point equality or inequality is not a
3152 good idea.  Here's a (relatively expensive) work-around to compare
3153 whether two floating-point numbers are equal to a particular number of
3154 decimal places.  See Knuth, volume II, for a more robust treatment of
3155 this topic.
3156
3157     sub fp_equal {
3158         my ($X, $Y, $POINTS) = @_;
3159         my ($tX, $tY);
3160         $tX = sprintf("%.${POINTS}g", $X);
3161         $tY = sprintf("%.${POINTS}g", $Y);
3162         return $tX eq $tY;
3163     }
3164
3165 The POSIX module (part of the standard perl distribution) implements
3166 ceil(), floor(), and other mathematical and trigonometric functions.
3167 The Math::Complex module (part of the standard perl distribution)
3168 defines mathematical functions that work on both the reals and the
3169 imaginary numbers.  Math::Complex not as efficient as POSIX, but
3170 POSIX can't work with complex numbers.
3171
3172 Rounding in financial applications can have serious implications, and
3173 the rounding method used should be specified precisely.  In these
3174 cases, it probably pays not to trust whichever system rounding is
3175 being used by Perl, but to instead implement the rounding function you
3176 need yourself.
3177
3178 =head2 Bigger Numbers
3179 X<number, arbitrary precision>
3180
3181 The standard C<Math::BigInt>, C<Math::BigRat>, and C<Math::BigFloat> modules,
3182 along with the C<bigint>, C<bigrat>, and C<bitfloat> pragmas, provide
3183 variable-precision arithmetic and overloaded operators, although
3184 they're currently pretty slow. At the cost of some space and
3185 considerable speed, they avoid the normal pitfalls associated with
3186 limited-precision representations.
3187
3188         use 5.010;
3189         use bigint;  # easy interface to Math::BigInt
3190         $x = 123456789123456789;
3191         say $x * $x;
3192     +15241578780673678515622620750190521
3193
3194 Or with rationals:
3195
3196         use 5.010;
3197         use bigrat;
3198         $a = 3/22;
3199         $b = 4/6;
3200         say "a/b is ", $a/$b;
3201         say "a*b is ", $a*$b;
3202     a/b is 9/44
3203     a*b is 1/11
3204
3205 Several modules let you calculate with (bound only by memory and CPU time)
3206 unlimited or fixed precision. There are also some non-standard modules that
3207 provide faster implementations via external C libraries.
3208
3209 Here is a short, but incomplete summary:
3210
3211   Math::Fraction         big, unlimited fractions like 9973 / 12967
3212   Math::String           treat string sequences like numbers
3213   Math::FixedPrecision   calculate with a fixed precision
3214   Math::Currency         for currency calculations
3215   Bit::Vector            manipulate bit vectors fast (uses C)
3216   Math::BigIntFast       Bit::Vector wrapper for big numbers
3217   Math::Pari             provides access to the Pari C library
3218   Math::BigInteger       uses an external C library
3219   Math::Cephes           uses external Cephes C library (no big numbers)
3220   Math::Cephes::Fraction fractions via the Cephes library
3221   Math::GMP              another one using an external C library
3222
3223 Choose wisely.
3224
3225 =cut