perly.y

   1 /*    perly.y
   2  *
   3  *    Copyright (c) 1991-2002, 2003, 2004, 2005, 2006 Larry Wall
   4  *    Copyright (c) 2007, 2008 by Larry Wall and others
   5  *
   6  *    You may distribute under the terms of either the GNU General Public
   7  *    License or the Artistic License, as specified in the README file.
   8  *
   9  */
  10
  11 /*
  12  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
  13  *  All that is gold does not glitter, not all those who wander are lost.'
  14  *
  15  *     [p.171 of _The Lord of the Rings_, I/x: "Strider"]
  16  */
  17
  18 /*
  19  * This file holds the grammar for the Perl language. If edited, you need
  20  * to run regen_perly.pl, which re-creates the files perly.h, perly.tab
  21  * and perly.act which are derived from this.
  22  *
  23  * Note that these derived files are included and compiled twice; once
  24  * from perly.c, and once from madly.c. The second time, a number of MAD
  25  * macros are defined, which compile in extra code that allows the parse
  26  * tree to be accurately dumped. In particular:
  27  *
  28  * MAD            defined if compiling madly.c
  29  * DO_MAD(A)      expands to A  under madly.c, to null otherwise
  30  * IF_MAD(a,b)    expands to A under madly.c, to B otherwise
  31  * TOKEN_GETMAD() expands to token_getmad() under madly.c, to null otherwise
  32  * TOKEN_FREE()   similarly
  33  * OP_GETMAD()    similarly
  34  * IVAL(i)        expands to (i)->tk_lval.ival or (i)
  35  * PVAL(p)        expands to (p)->tk_lval.pval or (p)
  36  *
  37  * The main job of of this grammar is to call the various newFOO()
  38  * functions in op.c to build a syntax tree of OP structs.
  39  * It relies on the lexer in toke.c to do the tokenizing.
  40  *
  41  * Note: due to the way that the cleanup code works WRT to freeing ops on
  42  * the parse stack, it is dangerous to assign to the $n variables within
  43  * an action.
  44  */
  45
  46 /*  Make the parser re-entrant. */
  47
  48 %pure_parser
  49
  50 /* FIXME for MAD - is the new mintro on while and until important?  */
  51
  52 %start grammar
  53
  54 %union {
  55     I32 ival; /* __DEFAULT__ (marker for regen_perly.pl;
  56                                 must always be 1st union member) */
  57     char *pval;
  58     OP *opval;
  59     GV *gvval;
  60 #ifdef PERL_IN_MADLY_C
  61     TOKEN* p_tkval;
  62     TOKEN* i_tkval;
  63 #else
  64     char *p_tkval;
  65     I32 i_tkval;
  66 #endif
  67 #ifdef PERL_MAD
  68     TOKEN* tkval;
  69 #endif
  70 }
  71
  72 %token <ival> GRAMPROG GRAMBLOCK GRAMFULLSTMT GRAMSTMTSEQ
  73
  74 %token <i_tkval> '{' '}' '[' ']' '-' '+' '$' '@' '%' '*' '&' ';'
  75
  76 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF QWLIST
  77 %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
  78 %token <opval> PLUGEXPR PLUGSTMT
  79 %token <p_tkval> LABEL
  80 %token <i_tkval> FORMAT SUB ANONSUB PACKAGE USE
  81 %token <i_tkval> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
  82 %token <i_tkval> GIVEN WHEN DEFAULT
  83 %token <i_tkval> LOOPEX DOTDOT YADAYADA
  84 %token <i_tkval> FUNC0 FUNC1 FUNC UNIOP LSTOP
  85 %token <i_tkval> RELOP EQOP MULOP ADDOP
  86 %token <i_tkval> DOLSHARP DO HASHBRACK NOAMP
  87 %token <i_tkval> LOCAL MY MYSUB REQUIRE
  88 %token <i_tkval> COLONATTR
  89
  90 %type <i_tkval> lpar_or_qw
  91
  92 %type <ival> grammar prog progstart remember mremember
  93 %type <ival>  startsub startanonsub startformsub
  94 /* FIXME for MAD - are these two ival? */
  95 %type <ival> mydefsv mintro
  96
  97 %type <opval> fullstmt decl format subrout mysubrout package use peg
  98 %type <opval> block package_block mblock stmtseq loop cond else
  99 %type <opval> expr term subscripted scalar ary hsh arylen star amper sideff
 100 %type <opval> argexpr nexpr texpr iexpr mexpr mnexpr miexpr
 101 %type <opval> listexpr listexprcom indirob listop method
 102 %type <opval> formname subname proto subbody cont my_scalar
 103 %type <opval> subattrlist myattrlist myattrterm myterm
 104 %type <opval> termbinop termunop anonymous termdo
 105 %type <opval> switch case
 106 %type <p_tkval> label
 107
 108 %nonassoc <i_tkval> PREC_LOW
 109 %nonassoc LOOPEX
 110
 111 %left <i_tkval> OROP DOROP
 112 %left <i_tkval> ANDOP
 113 %right <i_tkval> NOTOP
 114 %nonassoc LSTOP LSTOPSUB
 115 %left <i_tkval> ','
 116 %right <i_tkval> ASSIGNOP
 117 %right <i_tkval> '?' ':'
 118 %nonassoc DOTDOT YADAYADA
 119 %left <i_tkval> OROR DORDOR
 120 %left <i_tkval> ANDAND
 121 %left <i_tkval> BITOROP
 122 %left <i_tkval> BITANDOP
 123 %nonassoc EQOP
 124 %nonassoc RELOP
 125 %nonassoc UNIOP UNIOPSUB
 126 %nonassoc REQUIRE
 127 %left <i_tkval> SHIFTOP
 128 %left ADDOP
 129 %left MULOP
 130 %left <i_tkval> MATCHOP
 131 %right <i_tkval> '!' '~' UMINUS REFGEN
 132 %right <i_tkval> POWOP
 133 %nonassoc <i_tkval> PREINC PREDEC POSTINC POSTDEC
 134 %left <i_tkval> ARROW
 135 %nonassoc <i_tkval> ')'
 136 %left <i_tkval> '('
 137 %left '[' '{'
 138
 139 %token <i_tkval> PEG
 140
 141 %% /* RULES */
 142
 143 /* Top-level choice of what kind of thing yyparse was called to parse */
 144 grammar :       GRAMPROG prog
 145                         { $$ = $2; }
 146         |       GRAMBLOCK
 147                         {
 148                           parser->expect = XBLOCK;
 149                         }
 150                 block
 151                         {
 152                           PL_pad_reset_pending = TRUE;
 153                           PL_eval_root = $3;
 154                           $$ = 0;
 155                           yyunlex();
 156                           parser->yychar = YYEOF;
 157                         }
 158         |       GRAMFULLSTMT
 159                         {
 160                           parser->expect = XSTATE;
 161                         }
 162                 fullstmt
 163                         {
 164                           PL_pad_reset_pending = TRUE;
 165                           PL_eval_root = $3;
 166                           $$ = 0;
 167                           yyunlex();
 168                           parser->yychar = YYEOF;
 169                         }
 170         |       GRAMSTMTSEQ
 171                         {
 172                           parser->expect = XSTATE;
 173                         }
 174                 stmtseq
 175                         {
 176                           PL_eval_root = $3;
 177                           $$ = 0;
 178                         }
 179         ;
 180
 181 /* The whole program */
 182 prog    :       progstart
 183         /*CONTINUED*/   stmtseq
 184                         { $$ = $1; newPROG(block_end($1,$2)); }
 185         ;
 186
 187 /* An ordinary block */
 188 block   :       '{' remember stmtseq '}'
 189                         { if (PL_parser->copline > (line_t)IVAL($1))
 190                               PL_parser->copline = (line_t)IVAL($1);
 191                           $$ = block_end($2, $3);
 192                           TOKEN_GETMAD($1,$$,'{');
 193                           TOKEN_GETMAD($4,$$,'}');
 194                         }
 195         ;
 196
 197 remember:       /* NULL */      /* start a full lexical scope */
 198                         { $$ = block_start(TRUE); }
 199         ;
 200
 201 mydefsv:        /* NULL */      /* lexicalize $_ */
 202                         { $$ = (I32) Perl_allocmy(aTHX_ STR_WITH_LEN("$_"), 0); }
 203         ;
 204
 205 progstart:
 206                 {
 207                     PL_parser->expect = XSTATE; $$ = block_start(TRUE);
 208                 }
 209         ;
 210
 211
 212 mblock  :       '{' mremember stmtseq '}'
 213                         { if (PL_parser->copline > (line_t)IVAL($1))
 214                               PL_parser->copline = (line_t)IVAL($1);
 215                           $$ = block_end($2, $3);
 216                           TOKEN_GETMAD($1,$$,'{');
 217                           TOKEN_GETMAD($4,$$,'}');
 218                         }
 219         ;
 220
 221 mremember:      /* NULL */      /* start a partial lexical scope */
 222                         { $$ = block_start(FALSE); }
 223         ;
 224
 225 /* A collection of "lines" in the program */
 226 stmtseq :       /* NULL */
 227                         { $$ = (OP*)NULL; }
 228         |       stmtseq fullstmt
 229                         {   $$ = op_append_list(OP_LINESEQ, $1, $2);
 230                             PL_pad_reset_pending = TRUE;
 231                             if ($1 && $2)
 232                                 PL_hints |= HINT_BLOCK_SCOPE;
 233                         }
 234         ;
 235
 236 /* A statement in the program */
 237 fullstmt:       label cond
 238                         { $$ = newSTATEOP(0, PVAL($1), $2);
 239                           TOKEN_GETMAD($1,((LISTOP*)$$)->op_first,'L'); }
 240         |       loop    /* loops add their own labels */
 241         |       switch  /* ... and so do switches */
 242                         { $$ = $1; }
 243         |       label case
 244                         { $$ = newSTATEOP(0, PVAL($1), $2); }
 245         |       label ';'
 246                         {
 247                           if (PVAL($1)) {
 248                               $$ = newSTATEOP(0, PVAL($1), newOP(OP_NULL, 0));
 249                               TOKEN_GETMAD($1,$$,'L');
 250                               TOKEN_GETMAD($2,((LISTOP*)$$)->op_first,';');
 251                           }
 252                           else {
 253                               $$ = IF_MAD(
 254                                         newOP(OP_NULL, 0),
 255                                         (OP*)NULL);
 256                               PL_parser->copline = NOLINE;
 257                               TOKEN_FREE($1);
 258                               TOKEN_GETMAD($2,$$,';');
 259                           }
 260                           PL_parser->expect = XSTATE;
 261                         }
 262         |       label sideff ';'
 263                         {
 264                           $$ = newSTATEOP(0, PVAL($1), $2);
 265                           PL_parser->expect = XSTATE;
 266                           DO_MAD({
 267                               /* sideff might already have a nexstate */
 268                               OP* op = ((LISTOP*)$$)->op_first;
 269                               if (op) {
 270                                   while (op->op_sibling &&
 271                                      op->op_sibling->op_type == OP_NEXTSTATE)
 272                                         op = op->op_sibling;
 273                                   token_getmad($1,op,'L');
 274                                   token_getmad($3,op,';');
 275                               }
 276                           })
 277                         }
 278         |       label package_block
 279                         { $$ = newSTATEOP(0, PVAL($1),
 280                                  newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
 281                                             NOLINE, (OP*)NULL, $2,
 282                                             (OP*)NULL, 0)); }
 283         |       label PLUGSTMT
 284                         { $$ = newSTATEOP(0, PVAL($1), $2); }
 285         |       label decl
 286                         {
 287                           if (PVAL($1)) {
 288                               $$ = newSTATEOP(0, PVAL($1), $2);
 289                           } else {
 290                               $$ = IF_MAD($2 ? $2 : newOP(OP_NULL, 0), $2);
 291                           }
 292                         }
 293         ;
 294
 295 /* An expression which may have a side-effect */
 296 sideff  :       error
 297                         { $$ = (OP*)NULL; }
 298         |       expr
 299                         { $$ = $1; }
 300         |       expr IF expr
 301                         { $$ = newLOGOP(OP_AND, 0, $3, $1);
 302                           TOKEN_GETMAD($2,$$,'i');
 303                         }
 304         |       expr UNLESS expr
 305                         { $$ = newLOGOP(OP_OR, 0, $3, $1);
 306                           TOKEN_GETMAD($2,$$,'i');
 307                         }
 308         |       expr WHILE expr
 309                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1);
 310                           TOKEN_GETMAD($2,$$,'w');
 311                         }
 312         |       expr UNTIL iexpr
 313                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);
 314                           TOKEN_GETMAD($2,$$,'w');
 315                         }
 316         |       expr FOR expr
 317                         { $$ = newFOROP(0, NULL, (line_t)IVAL($2),
 318                                         (OP*)NULL, $3, $1, (OP*)NULL);
 319                           TOKEN_GETMAD($2,((LISTOP*)$$)->op_first->op_sibling,'w');
 320                         }
 321         |       expr WHEN expr
 322                         { $$ = newWHENOP($3, scope($1)); }
 323         ;
 324
 325 /* else and elsif blocks */
 326 else    :       /* NULL */
 327                         { $$ = (OP*)NULL; }
 328         |       ELSE mblock
 329                         { ($2)->op_flags |= OPf_PARENS; $$ = scope($2);
 330                           TOKEN_GETMAD($1,$$,'o');
 331                         }
 332         |       ELSIF lpar_or_qw mexpr ')' mblock else
 333                         { PL_parser->copline = (line_t)IVAL($1);
 334                             $$ = newCONDOP(0, newSTATEOP(OPf_SPECIAL,NULL,$3), scope($5), $6);
 335                             PL_hints |= HINT_BLOCK_SCOPE;
 336                           TOKEN_GETMAD($1,$$,'I');
 337                           TOKEN_GETMAD($2,$$,'(');
 338                           TOKEN_GETMAD($4,$$,')');
 339                         }
 340         ;
 341
 342 /* Real conditional expressions */
 343 cond    :       IF lpar_or_qw remember mexpr ')' mblock else
 344                         { PL_parser->copline = (line_t)IVAL($1);
 345                             $$ = block_end($3,
 346                                    newCONDOP(0, $4, scope($6), $7));
 347                           TOKEN_GETMAD($1,$$,'I');
 348                           TOKEN_GETMAD($2,$$,'(');
 349                           TOKEN_GETMAD($5,$$,')');
 350                         }
 351         |       UNLESS lpar_or_qw remember miexpr ')' mblock else
 352                         { PL_parser->copline = (line_t)IVAL($1);
 353                             $$ = block_end($3,
 354                                    newCONDOP(0, $4, scope($6), $7));
 355                           TOKEN_GETMAD($1,$$,'I');
 356                           TOKEN_GETMAD($2,$$,'(');
 357                           TOKEN_GETMAD($5,$$,')');
 358                         }
 359         ;
 360
 361 /* Cases for a switch statement */
 362 case    :       WHEN lpar_or_qw remember mexpr ')' mblock
 363         { $$ = block_end($3,
 364                 newWHENOP($4, scope($6))); }
 365         |       DEFAULT block
 366         { $$ = newWHENOP(0, scope($2)); }
 367         ;
 368
 369 /* Continue blocks */
 370 cont    :       /* NULL */
 371                         { $$ = (OP*)NULL; }
 372         |       CONTINUE block
 373                         { $$ = scope($2);
 374                           TOKEN_GETMAD($1,$$,'o');
 375                         }
 376         ;
 377
 378 /* Loops: while, until, for, and a bare block */
 379 loop    :       label WHILE lpar_or_qw remember texpr ')' mintro mblock cont
 380                         { OP *innerop;
 381                           PL_parser->copline = (line_t)IVAL($2);
 382                             $$ = block_end($4,
 383                                    newSTATEOP(0, PVAL($1),
 384                                      innerop = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
 385                                                 IVAL($2), $5, $8, $9, $7)));
 386                           TOKEN_GETMAD($1,innerop,'L');
 387                           TOKEN_GETMAD($2,innerop,'W');
 388                           TOKEN_GETMAD($3,innerop,'(');
 389                           TOKEN_GETMAD($6,innerop,')');
 390                         }
 391
 392         |       label UNTIL lpar_or_qw remember iexpr ')' mintro mblock cont
 393                         { OP *innerop;
 394                           PL_parser->copline = (line_t)IVAL($2);
 395                             $$ = block_end($4,
 396                                    newSTATEOP(0, PVAL($1),
 397                                      innerop = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
 398                                                 IVAL($2), $5, $8, $9, $7)));
 399                           TOKEN_GETMAD($1,innerop,'L');
 400                           TOKEN_GETMAD($2,innerop,'W');
 401                           TOKEN_GETMAD($3,innerop,'(');
 402                           TOKEN_GETMAD($6,innerop,')');
 403                         }
 404         |       label FOR MY remember my_scalar lpar_or_qw mexpr ')' mblock cont
 405                         { OP *innerop;
 406                           $$ = block_end($4,
 407                              innerop = newFOROP(0, PVAL($1), (line_t)IVAL($2),
 408                                             $5, $7, $9, $10));
 409                           TOKEN_GETMAD($1,((LISTOP*)innerop)->op_first,'L');
 410                           TOKEN_GETMAD($2,((LISTOP*)innerop)->op_first->op_sibling,'W');
 411                           TOKEN_GETMAD($3,((LISTOP*)innerop)->op_first->op_sibling,'d');
 412                           TOKEN_GETMAD($6,((LISTOP*)innerop)->op_first->op_sibling,'(');
 413                           TOKEN_GETMAD($8,((LISTOP*)innerop)->op_first->op_sibling,')');
 414                         }
 415         |       label FOR scalar lpar_or_qw remember mexpr ')' mblock cont
 416                         { OP *innerop;
 417                           $$ = block_end($5,
 418                              innerop = newFOROP(0, PVAL($1), (line_t)IVAL($2),
 419                                     mod($3, OP_ENTERLOOP), $6, $8, $9));
 420                           TOKEN_GETMAD($1,((LISTOP*)innerop)->op_first,'L');
 421                           TOKEN_GETMAD($2,((LISTOP*)innerop)->op_first->op_sibling,'W');
 422                           TOKEN_GETMAD($4,((LISTOP*)innerop)->op_first->op_sibling,'(');
 423                           TOKEN_GETMAD($7,((LISTOP*)innerop)->op_first->op_sibling,')');
 424                         }
 425         |       label FOR lpar_or_qw remember mexpr ')' mblock cont
 426                         { OP *innerop;
 427                           $$ = block_end($4,
 428                              innerop = newFOROP(0, PVAL($1), (line_t)IVAL($2),
 429                                                     (OP*)NULL, $5, $7, $8));
 430                           TOKEN_GETMAD($1,((LISTOP*)innerop)->op_first,'L');
 431                           TOKEN_GETMAD($2,((LISTOP*)innerop)->op_first->op_sibling,'W');
 432                           TOKEN_GETMAD($3,((LISTOP*)innerop)->op_first->op_sibling,'(');
 433                           TOKEN_GETMAD($6,((LISTOP*)innerop)->op_first->op_sibling,')');
 434                         }
 435         |       label FOR lpar_or_qw remember mnexpr ';' texpr ';' mintro mnexpr ')'
 436                     mblock
 437                         /* basically fake up an initialize-while stmtseq */
 438                         { OP *forop;
 439                           PL_parser->copline = (line_t)IVAL($2);
 440                           forop = newSTATEOP(0, PVAL($1),
 441                                             newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
 442                                                 IVAL($2), scalar($7),
 443                                                 $12, $10, $9));
 444 #ifdef MAD
 445                           forop = newUNOP(OP_NULL, 0, op_append_elem(OP_LINESEQ,
 446                                 newSTATEOP(0,
 447                                            CopLABEL_alloc(($1)->tk_lval.pval),
 448                                            ($5 ? $5 : newOP(OP_NULL, 0)) ),
 449                                 forop));
 450
 451                           token_getmad($2,forop,'3');
 452                           token_getmad($3,forop,'(');
 453                           token_getmad($6,forop,'1');
 454                           token_getmad($8,forop,'2');
 455                           token_getmad($11,forop,')');
 456                           token_getmad($1,forop,'L');
 457 #else
 458                           if ($5) {
 459                                 forop = op_append_elem(OP_LINESEQ,
 460                                         newSTATEOP(0, CopLABEL_alloc($1), $5),
 461                                         forop);
 462                           }
 463
 464
 465 #endif
 466                           $$ = block_end($4, forop); }
 467         |       label block cont  /* a block is a loop that happens once */
 468                         { $$ = newSTATEOP(0, PVAL($1),
 469                                  newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
 470                                             NOLINE, (OP*)NULL, $2, $3, 0));
 471                           TOKEN_GETMAD($1,((LISTOP*)$$)->op_first,'L'); }
 472         ;
 473
 474 /* Switch blocks */
 475 switch  :       label GIVEN lpar_or_qw remember mydefsv mexpr ')' mblock
 476                         { PL_parser->copline = (line_t) IVAL($2);
 477                             $$ = block_end($4,
 478                                 newSTATEOP(0, PVAL($1),
 479                                     newGIVENOP($6, scope($8),
 480                                         (PADOFFSET) $5) )); }
 481         ;
 482
 483 /* determine whether there are any new my declarations */
 484 mintro  :       /* NULL */
 485                         { $$ = (PL_min_intro_pending &&
 486                             PL_max_intro_pending >=  PL_min_intro_pending);
 487                           intro_my(); }
 488
 489 /* Normal expression */
 490 nexpr   :       /* NULL */
 491                         { $$ = (OP*)NULL; }
 492         |       sideff
 493         ;
 494
 495 /* Boolean expression */
 496 texpr   :       /* NULL means true */
 497                         { YYSTYPE tmplval;
 498                           (void)scan_num("1", &tmplval);
 499                           $$ = tmplval.opval; }
 500         |       expr
 501         ;
 502
 503 /* Inverted boolean expression */
 504 iexpr   :       expr
 505                         { $$ = invert(scalar($1)); }
 506         ;
 507
 508 /* Expression with its own lexical scope */
 509 mexpr   :       expr
 510                         { $$ = $1; intro_my(); }
 511         ;
 512
 513 mnexpr  :       nexpr
 514                         { $$ = $1; intro_my(); }
 515         ;
 516
 517 miexpr  :       iexpr
 518                         { $$ = $1; intro_my(); }
 519         ;
 520
 521 /* Optional "MAIN:"-style loop labels */
 522 label   :       /* empty */
 523                         {
 524 #ifdef MAD
 525                           YYSTYPE tmplval;
 526                           tmplval.pval = NULL;
 527                           $$ = newTOKEN(OP_NULL, tmplval, 0);
 528 #else
 529                           $$ = NULL;
 530 #endif
 531                         }
 532         |       LABEL
 533         ;
 534
 535 /* Some kind of declaration - just hang on peg in the parse tree */
 536 decl    :       format
 537                         { $$ = $1; }
 538         |       subrout
 539                         { $$ = $1; }
 540         |       mysubrout
 541                         { $$ = $1; }
 542         |       package
 543                         { $$ = $1; }
 544         |       use
 545                         { $$ = $1; }
 546
 547     /* these two are only used by MAD */
 548
 549         |       peg
 550                         { $$ = $1; }
 551         ;
 552
 553 peg     :       PEG
 554                         { $$ = newOP(OP_NULL,0);
 555                           TOKEN_GETMAD($1,$$,'p');
 556                         }
 557         ;
 558
 559 format  :       FORMAT startformsub formname block
 560                         {
 561                           CV *fmtcv = PL_compcv;
 562                           SvREFCNT_inc_simple_void(PL_compcv);
 563 #ifdef MAD
 564                           $$ = newFORM($2, $3, $4);
 565                           prepend_madprops($1->tk_mad, $$, 'F');
 566                           $1->tk_mad = 0;
 567                           token_free($1);
 568 #else
 569                           newFORM($2, $3, $4);
 570                           $$ = (OP*)NULL;
 571 #endif
 572                           if (CvOUTSIDE(fmtcv) && !CvUNIQUE(CvOUTSIDE(fmtcv))) {
 573                             SvREFCNT_inc_simple_void(fmtcv);
 574                             pad_add_anon((SV*)fmtcv, OP_NULL);
 575                           }
 576                         }
 577         ;
 578
 579 formname:       WORD            { $$ = $1; }
 580         |       /* NULL */      { $$ = (OP*)NULL; }
 581         ;
 582
 583 /* Unimplemented "my sub foo { }" */
 584 mysubrout:      MYSUB startsub subname proto subattrlist subbody
 585                         { SvREFCNT_inc_simple_void(PL_compcv);
 586 #ifdef MAD
 587                           $$ = newMYSUB($2, $3, $4, $5, $6);
 588                           token_getmad($1,$$,'d');
 589 #else
 590                           newMYSUB($2, $3, $4, $5, $6);
 591                           $$ = (OP*)NULL;
 592 #endif
 593                         }
 594         ;
 595
 596 /* Subroutine definition */
 597 subrout :       SUB startsub subname proto subattrlist subbody
 598                         { SvREFCNT_inc_simple_void(PL_compcv);
 599 #ifdef MAD
 600                           {
 601                               OP* o = newSVOP(OP_ANONCODE, 0,
 602                                 (SV*)newATTRSUB($2, $3, $4, $5, $6));
 603                               $$ = newOP(OP_NULL,0);
 604                               op_getmad(o,$$,'&');
 605                               op_getmad($3,$$,'n');
 606                               op_getmad($4,$$,'s');
 607                               op_getmad($5,$$,'a');
 608                               token_getmad($1,$$,'d');
 609                               append_madprops($6->op_madprop, $$, 0);
 610                               $6->op_madprop = 0;
 611                             }
 612 #else
 613                           newATTRSUB($2, $3, $4, $5, $6);
 614                           $$ = (OP*)NULL;
 615 #endif
 616                         }
 617         ;
 618
 619 startsub:       /* NULL */      /* start a regular subroutine scope */
 620                         { $$ = start_subparse(FALSE, 0);
 621                             SAVEFREESV(PL_compcv); }
 622
 623         ;
 624
 625 startanonsub:   /* NULL */      /* start an anonymous subroutine scope */
 626                         { $$ = start_subparse(FALSE, CVf_ANON);
 627                             SAVEFREESV(PL_compcv); }
 628         ;
 629
 630 startformsub:   /* NULL */      /* start a format subroutine scope */
 631                         { $$ = start_subparse(TRUE, 0);
 632                             SAVEFREESV(PL_compcv); }
 633         ;
 634
 635 /* Name of a subroutine - must be a bareword, could be special */
 636 subname :       WORD    { const char *const name = SvPV_nolen_const(((SVOP*)$1)->op_sv);
 637                           if (strEQ(name, "BEGIN") || strEQ(name, "END")
 638                               || strEQ(name, "INIT") || strEQ(name, "CHECK")
 639                               || strEQ(name, "UNITCHECK"))
 640                               CvSPECIAL_on(PL_compcv);
 641                           $$ = $1; }
 642         ;
 643
 644 /* Subroutine prototype */
 645 proto   :       /* NULL */
 646                         { $$ = (OP*)NULL; }
 647         |       THING
 648         ;
 649
 650 /* Optional list of subroutine attributes */
 651 subattrlist:    /* NULL */
 652                         { $$ = (OP*)NULL; }
 653         |       COLONATTR THING
 654                         { $$ = $2;
 655                           TOKEN_GETMAD($1,$$,':');
 656                         }
 657         |       COLONATTR
 658                         { $$ = IF_MAD(
 659                                     newOP(OP_NULL, 0),
 660                                     (OP*)NULL
 661                                 );
 662                           TOKEN_GETMAD($1,$$,':');
 663                         }
 664         ;
 665
 666 /* List of attributes for a "my" variable declaration */
 667 myattrlist:     COLONATTR THING
 668                         { $$ = $2;
 669                           TOKEN_GETMAD($1,$$,':');
 670                         }
 671         |       COLONATTR
 672                         { $$ = IF_MAD(
 673                                     newOP(OP_NULL, 0),
 674                                     (OP*)NULL
 675                                 );
 676                           TOKEN_GETMAD($1,$$,':');
 677                         }
 678         ;
 679
 680 /* Subroutine body - either null or a block */
 681 subbody :       block   { $$ = $1; }
 682         |       ';'     { $$ = IF_MAD(
 683                                     newOP(OP_NULL,0),
 684                                     (OP*)NULL
 685                                 );
 686                           PL_parser->expect = XSTATE;
 687                           TOKEN_GETMAD($1,$$,';');
 688                         }
 689         ;
 690
 691 package :       PACKAGE WORD WORD ';'
 692                         {
 693 #ifdef MAD
 694                           $$ = package($3);
 695                           token_getmad($1,$$,'o');
 696                           if ($2)
 697                               package_version($2);
 698                           token_getmad($4,$$,';');
 699 #else
 700                           package($3);
 701                           if ($2)
 702                               package_version($2);
 703                           $$ = (OP*)NULL;
 704 #endif
 705                         }
 706         ;
 707
 708 package_block:  PACKAGE WORD WORD '{' remember
 709                         {
 710                           int save_3_latefree = $3->op_latefree;
 711                           $3->op_latefree = 1;
 712                           package($3);
 713                           $3->op_latefree = save_3_latefree;
 714                           if ($2) {
 715                               int save_2_latefree = $2->op_latefree;
 716                               $2->op_latefree = 1;
 717                               package_version($2);
 718                               $2->op_latefree = save_2_latefree;
 719                           }
 720                         }
 721                     stmtseq '}'
 722                         { if (PL_parser->copline > (line_t)IVAL($4))
 723                               PL_parser->copline = (line_t)IVAL($4);
 724                           $$ = block_end($5, $7);
 725                           TOKEN_GETMAD($4,$$,'{');
 726                           TOKEN_GETMAD($8,$$,'}');
 727                           op_free($3);
 728                           if ($2)
 729                               op_free($2);
 730                         }
 731         ;
 732
 733 use     :       USE startsub
 734                         { CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
 735                     WORD WORD listexpr ';'
 736                         { SvREFCNT_inc_simple_void(PL_compcv);
 737 #ifdef MAD
 738                           $$ = utilize(IVAL($1), $2, $4, $5, $6);
 739                           token_getmad($1,$$,'o');
 740                           token_getmad($7,$$,';');
 741                           if (PL_parser->rsfp_filters &&
 742                                       AvFILLp(PL_parser->rsfp_filters) >= 0)
 743                               append_madprops(newMADPROP('!', MAD_NULL, NULL, 0), $$, 0);
 744 #else
 745                           utilize(IVAL($1), $2, $4, $5, $6);
 746                           $$ = (OP*)NULL;
 747 #endif
 748                         }
 749         ;
 750
 751 /* Ordinary expressions; logical combinations */
 752 expr    :       expr ANDOP expr
 753                         { $$ = newLOGOP(OP_AND, 0, $1, $3);
 754                           TOKEN_GETMAD($2,$$,'o');
 755                         }
 756         |       expr OROP expr
 757                         { $$ = newLOGOP(IVAL($2), 0, $1, $3);
 758                           TOKEN_GETMAD($2,$$,'o');
 759                         }
 760         |       expr DOROP expr
 761                         { $$ = newLOGOP(OP_DOR, 0, $1, $3);
 762                           TOKEN_GETMAD($2,$$,'o');
 763                         }
 764         |       argexpr %prec PREC_LOW
 765         ;
 766
 767 /* Expressions are a list of terms joined by commas */
 768 argexpr :       argexpr ','
 769                         {
 770 #ifdef MAD
 771                           OP* op = newNULLLIST();
 772                           token_getmad($2,op,',');
 773                           $$ = op_append_elem(OP_LIST, $1, op);
 774 #else
 775                           $$ = $1;
 776 #endif
 777                         }
 778         |       argexpr ',' term
 779                         {
 780                           OP* term = $3;
 781                           DO_MAD(
 782                               term = newUNOP(OP_NULL, 0, term);
 783                               token_getmad($2,term,',');
 784                           )
 785                           $$ = op_append_elem(OP_LIST, $1, term);
 786                         }
 787         |       term %prec PREC_LOW
 788         ;
 789
 790 /* List operators */
 791 listop  :       LSTOP indirob argexpr /* map {...} @args or print $fh @args */
 792                         { $$ = convert(IVAL($1), OPf_STACKED,
 793                                 op_prepend_elem(OP_LIST, newGVREF(IVAL($1),$2), $3) );
 794                           TOKEN_GETMAD($1,$$,'o');
 795                         }
 796         |       FUNC '(' indirob expr ')'      /* print ($fh @args */
 797                         { $$ = convert(IVAL($1), OPf_STACKED,
 798                                 op_prepend_elem(OP_LIST, newGVREF(IVAL($1),$3), $4) );
 799                           TOKEN_GETMAD($1,$$,'o');
 800                           TOKEN_GETMAD($2,$$,'(');
 801                           TOKEN_GETMAD($5,$$,')');
 802                         }
 803         |       term ARROW method lpar_or_qw listexprcom ')' /* $foo->bar(list) */
 804                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 805                                 op_append_elem(OP_LIST,
 806                                     op_prepend_elem(OP_LIST, scalar($1), $5),
 807                                     newUNOP(OP_METHOD, 0, $3)));
 808                           TOKEN_GETMAD($2,$$,'A');
 809                           TOKEN_GETMAD($4,$$,'(');
 810                           TOKEN_GETMAD($6,$$,')');
 811                         }
 812         |       term ARROW method                     /* $foo->bar */
 813                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 814                                 op_append_elem(OP_LIST, scalar($1),
 815                                     newUNOP(OP_METHOD, 0, $3)));
 816                           TOKEN_GETMAD($2,$$,'A');
 817                         }
 818         |       METHOD indirob listexpr              /* new Class @args */
 819                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 820                                 op_append_elem(OP_LIST,
 821                                     op_prepend_elem(OP_LIST, $2, $3),
 822                                     newUNOP(OP_METHOD, 0, $1)));
 823                         }
 824         |       FUNCMETH indirob '(' listexprcom ')' /* method $object (@args) */
 825                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 826                                 op_append_elem(OP_LIST,
 827                                     op_prepend_elem(OP_LIST, $2, $4),
 828                                     newUNOP(OP_METHOD, 0, $1)));
 829                           TOKEN_GETMAD($3,$$,'(');
 830                           TOKEN_GETMAD($5,$$,')');
 831                         }
 832         |       LSTOP listexpr                       /* print @args */
 833                         { $$ = convert(IVAL($1), 0, $2);
 834                           TOKEN_GETMAD($1,$$,'o');
 835                         }
 836         |       FUNC '(' listexprcom ')'             /* print (@args) */
 837                         { $$ = convert(IVAL($1), 0, $3);
 838                           TOKEN_GETMAD($1,$$,'o');
 839                           TOKEN_GETMAD($2,$$,'(');
 840                           TOKEN_GETMAD($4,$$,')');
 841                         }
 842         |       LSTOPSUB startanonsub block /* sub f(&@);   f { foo } ... */
 843                         { SvREFCNT_inc_simple_void(PL_compcv);
 844                           $<opval>$ = newANONATTRSUB($2, 0, (OP*)NULL, $3); }
 845                     listexpr            %prec LSTOP  /* ... @bar */
 846                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 847                                  op_append_elem(OP_LIST,
 848                                    op_prepend_elem(OP_LIST, $<opval>4, $5), $1));
 849                         }
 850         ;
 851
 852 /* Names of methods. May use $object->$methodname */
 853 method  :       METHOD
 854         |       scalar
 855         ;
 856
 857 /* Some kind of subscripted expression */
 858 subscripted:    star '{' expr ';' '}'        /* *main::{something} */
 859                         /* In this and all the hash accessors, ';' is
 860                          * provided by the tokeniser */
 861                         { $$ = newBINOP(OP_GELEM, 0, $1, scalar($3));
 862                             PL_parser->expect = XOPERATOR;
 863                           TOKEN_GETMAD($2,$$,'{');
 864                           TOKEN_GETMAD($4,$$,';');
 865                           TOKEN_GETMAD($5,$$,'}');
 866                         }
 867         |       scalar '[' expr ']'          /* $array[$element] */
 868                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3));
 869                           TOKEN_GETMAD($2,$$,'[');
 870                           TOKEN_GETMAD($4,$$,']');
 871                         }
 872         |       term ARROW '[' expr ']'      /* somearef->[$element] */
 873                         { $$ = newBINOP(OP_AELEM, 0,
 874                                         ref(newAVREF($1),OP_RV2AV),
 875                                         scalar($4));
 876                           TOKEN_GETMAD($2,$$,'a');
 877                           TOKEN_GETMAD($3,$$,'[');
 878                           TOKEN_GETMAD($5,$$,']');
 879                         }
 880         |       subscripted '[' expr ']'    /* $foo->[$bar]->[$baz] */
 881                         { $$ = newBINOP(OP_AELEM, 0,
 882                                         ref(newAVREF($1),OP_RV2AV),
 883                                         scalar($3));
 884                           TOKEN_GETMAD($2,$$,'[');
 885                           TOKEN_GETMAD($4,$$,']');
 886                         }
 887         |       scalar '{' expr ';' '}'    /* $foo->{bar();} */
 888                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
 889                             PL_parser->expect = XOPERATOR;
 890                           TOKEN_GETMAD($2,$$,'{');
 891                           TOKEN_GETMAD($4,$$,';');
 892                           TOKEN_GETMAD($5,$$,'}');
 893                         }
 894         |       term ARROW '{' expr ';' '}' /* somehref->{bar();} */
 895                         { $$ = newBINOP(OP_HELEM, 0,
 896                                         ref(newHVREF($1),OP_RV2HV),
 897                                         jmaybe($4));
 898                             PL_parser->expect = XOPERATOR;
 899                           TOKEN_GETMAD($2,$$,'a');
 900                           TOKEN_GETMAD($3,$$,'{');
 901                           TOKEN_GETMAD($5,$$,';');
 902                           TOKEN_GETMAD($6,$$,'}');
 903                         }
 904         |       subscripted '{' expr ';' '}' /* $foo->[bar]->{baz;} */
 905                         { $$ = newBINOP(OP_HELEM, 0,
 906                                         ref(newHVREF($1),OP_RV2HV),
 907                                         jmaybe($3));
 908                             PL_parser->expect = XOPERATOR;
 909                           TOKEN_GETMAD($2,$$,'{');
 910                           TOKEN_GETMAD($4,$$,';');
 911                           TOKEN_GETMAD($5,$$,'}');
 912                         }
 913         |       term ARROW '(' ')'          /* $subref->() */
 914                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 915                                    newCVREF(0, scalar($1)));
 916                           TOKEN_GETMAD($2,$$,'a');
 917                           TOKEN_GETMAD($3,$$,'(');
 918                           TOKEN_GETMAD($4,$$,')');
 919                         }
 920         |       term ARROW '(' expr ')'     /* $subref->(@args) */
 921                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 922                                    op_append_elem(OP_LIST, $4,
 923                                        newCVREF(0, scalar($1))));
 924                           TOKEN_GETMAD($2,$$,'a');
 925                           TOKEN_GETMAD($3,$$,'(');
 926                           TOKEN_GETMAD($5,$$,')');
 927                         }
 928
 929         |       subscripted lpar_or_qw expr ')'   /* $foo->{bar}->(@args) */
 930                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 931                                    op_append_elem(OP_LIST, $3,
 932                                                newCVREF(0, scalar($1))));
 933                           TOKEN_GETMAD($2,$$,'(');
 934                           TOKEN_GETMAD($4,$$,')');
 935                         }
 936         |       subscripted lpar_or_qw ')'        /* $foo->{bar}->() */
 937                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 938                                    newCVREF(0, scalar($1)));
 939                           TOKEN_GETMAD($2,$$,'(');
 940                           TOKEN_GETMAD($3,$$,')');
 941                         }
 942         |       '(' expr ')' '[' expr ']'            /* list slice */
 943                         { $$ = newSLICEOP(0, $5, $2);
 944                           TOKEN_GETMAD($1,$$,'(');
 945                           TOKEN_GETMAD($3,$$,')');
 946                           TOKEN_GETMAD($4,$$,'[');
 947                           TOKEN_GETMAD($6,$$,']');
 948                         }
 949         |       QWLIST '[' expr ']'            /* list literal slice */
 950                         { $$ = newSLICEOP(0, $3, $1);
 951                           TOKEN_GETMAD($2,$$,'[');
 952                           TOKEN_GETMAD($4,$$,']');
 953                         }
 954         |       '(' ')' '[' expr ']'                 /* empty list slice! */
 955                         { $$ = newSLICEOP(0, $4, (OP*)NULL);
 956                           TOKEN_GETMAD($1,$$,'(');
 957                           TOKEN_GETMAD($2,$$,')');
 958                           TOKEN_GETMAD($3,$$,'[');
 959                           TOKEN_GETMAD($5,$$,']');
 960                         }
 961     ;
 962
 963 /* Binary operators between terms */
 964 termbinop:      term ASSIGNOP term                     /* $x = $y */
 965                         { $$ = newASSIGNOP(OPf_STACKED, $1, IVAL($2), $3);
 966                           TOKEN_GETMAD($2,$$,'o');
 967                         }
 968         |       term POWOP term                        /* $x ** $y */
 969                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 970                           TOKEN_GETMAD($2,$$,'o');
 971                         }
 972         |       term MULOP term                        /* $x * $y, $x x $y */
 973                         {   if (IVAL($2) != OP_REPEAT)
 974                                 scalar($1);
 975                             $$ = newBINOP(IVAL($2), 0, $1, scalar($3));
 976                           TOKEN_GETMAD($2,$$,'o');
 977                         }
 978         |       term ADDOP term                        /* $x + $y */
 979                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 980                           TOKEN_GETMAD($2,$$,'o');
 981                         }
 982         |       term SHIFTOP term                      /* $x >> $y, $x << $y */
 983                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 984                           TOKEN_GETMAD($2,$$,'o');
 985                         }
 986         |       term RELOP term                        /* $x > $y, etc. */
 987                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 988                           TOKEN_GETMAD($2,$$,'o');
 989                         }
 990         |       term EQOP term                         /* $x == $y, $x eq $y */
 991                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 992                           TOKEN_GETMAD($2,$$,'o');
 993                         }
 994         |       term BITANDOP term                     /* $x & $y */
 995                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
 996                           TOKEN_GETMAD($2,$$,'o');
 997                         }
 998         |       term BITOROP term                      /* $x | $y */
 999                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
1000                           TOKEN_GETMAD($2,$$,'o');
1001                         }
1002         |       term DOTDOT term                       /* $x..$y, $x...$y */
1003                         {
1004                           $$ = newRANGE(IVAL($2), scalar($1), scalar($3));
1005                           DO_MAD({
1006                               UNOP *op;
1007                               op = (UNOP*)$$;
1008                               op = (UNOP*)op->op_first; /* get to flop */
1009                               op = (UNOP*)op->op_first; /* get to flip */
1010                               op = (UNOP*)op->op_first; /* get to range */
1011                               token_getmad($2,(OP*)op,'o');
1012                             })
1013                         }
1014         |       term ANDAND term                       /* $x && $y */
1015                         { $$ = newLOGOP(OP_AND, 0, $1, $3);
1016                           TOKEN_GETMAD($2,$$,'o');
1017                         }
1018         |       term OROR term                         /* $x || $y */
1019                         { $$ = newLOGOP(OP_OR, 0, $1, $3);
1020                           TOKEN_GETMAD($2,$$,'o');
1021                         }
1022         |       term DORDOR term                       /* $x // $y */
1023                         { $$ = newLOGOP(OP_DOR, 0, $1, $3);
1024                           TOKEN_GETMAD($2,$$,'o');
1025                         }
1026         |       term MATCHOP term                      /* $x =~ /$y/ */
1027                         { $$ = bind_match(IVAL($2), $1, $3);
1028                           TOKEN_GETMAD($2,
1029                                 ($$->op_type == OP_NOT
1030                                     ? ((UNOP*)$$)->op_first : $$),
1031                                 '~');
1032                         }
1033     ;
1034
1035 /* Unary operators and terms */
1036 termunop : '-' term %prec UMINUS                       /* -$x */
1037                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2));
1038                           TOKEN_GETMAD($1,$$,'o');
1039                         }
1040         |       '+' term %prec UMINUS                  /* +$x */
1041                         { $$ = IF_MAD(
1042                                     newUNOP(OP_NULL, 0, $2),
1043                                     $2
1044                                 );
1045                           TOKEN_GETMAD($1,$$,'+');
1046                         }
1047         |       '!' term                               /* !$x */
1048                         { $$ = newUNOP(OP_NOT, 0, scalar($2));
1049                           TOKEN_GETMAD($1,$$,'o');
1050                         }
1051         |       '~' term                               /* ~$x */
1052                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));
1053                           TOKEN_GETMAD($1,$$,'o');
1054                         }
1055         |       term POSTINC                           /* $x++ */
1056                         { $$ = newUNOP(OP_POSTINC, 0,
1057                                         mod(scalar($1), OP_POSTINC));
1058                           TOKEN_GETMAD($2,$$,'o');
1059                         }
1060         |       term POSTDEC                           /* $x-- */
1061                         { $$ = newUNOP(OP_POSTDEC, 0,
1062                                         mod(scalar($1), OP_POSTDEC));
1063                           TOKEN_GETMAD($2,$$,'o');
1064                         }
1065         |       PREINC term                            /* ++$x */
1066                         { $$ = newUNOP(OP_PREINC, 0,
1067                                         mod(scalar($2), OP_PREINC));
1068                           TOKEN_GETMAD($1,$$,'o');
1069                         }
1070         |       PREDEC term                            /* --$x */
1071                         { $$ = newUNOP(OP_PREDEC, 0,
1072                                         mod(scalar($2), OP_PREDEC));
1073                           TOKEN_GETMAD($1,$$,'o');
1074                         }
1075
1076     ;
1077
1078 /* Constructors for anonymous data */
1079 anonymous:      '[' expr ']'
1080                         { $$ = newANONLIST($2);
1081                           TOKEN_GETMAD($1,$$,'[');
1082                           TOKEN_GETMAD($3,$$,']');
1083                         }
1084         |       '[' ']'
1085                         { $$ = newANONLIST((OP*)NULL);
1086                           TOKEN_GETMAD($1,$$,'[');
1087                           TOKEN_GETMAD($2,$$,']');
1088                         }
1089         |       HASHBRACK expr ';' '}'  %prec '(' /* { foo => "Bar" } */
1090                         { $$ = newANONHASH($2);
1091                           TOKEN_GETMAD($1,$$,'{');
1092                           TOKEN_GETMAD($3,$$,';');
1093                           TOKEN_GETMAD($4,$$,'}');
1094                         }
1095         |       HASHBRACK ';' '}'       %prec '(' /* { } (';' by tokener) */
1096                         { $$ = newANONHASH((OP*)NULL);
1097                           TOKEN_GETMAD($1,$$,'{');
1098                           TOKEN_GETMAD($2,$$,';');
1099                           TOKEN_GETMAD($3,$$,'}');
1100                         }
1101         |       ANONSUB startanonsub proto subattrlist block    %prec '('
1102                         { SvREFCNT_inc_simple_void(PL_compcv);
1103                           $$ = newANONATTRSUB($2, $3, $4, $5);
1104                           TOKEN_GETMAD($1,$$,'o');
1105                           OP_GETMAD($3,$$,'s');
1106                           OP_GETMAD($4,$$,'a');
1107                         }
1108
1109     ;
1110
1111 /* Things called with "do" */
1112 termdo  :       DO term %prec UNIOP                     /* do $filename */
1113                         { $$ = dofile($2, IVAL($1));
1114                           TOKEN_GETMAD($1,$$,'o');
1115                         }
1116         |       DO block        %prec '('               /* do { code */
1117                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2));
1118                           TOKEN_GETMAD($1,$$,'D');
1119                         }
1120         |       DO WORD lpar_or_qw ')'                  /* do somesub() */
1121                         { $$ = newUNOP(OP_ENTERSUB,
1122                             OPf_SPECIAL|OPf_STACKED,
1123                             op_prepend_elem(OP_LIST,
1124                                 scalar(newCVREF(
1125                                     (OPpENTERSUB_AMPER<<8),
1126                                     scalar($2)
1127                                 )),(OP*)NULL)); dep();
1128                           TOKEN_GETMAD($1,$$,'o');
1129                           TOKEN_GETMAD($3,$$,'(');
1130                           TOKEN_GETMAD($4,$$,')');
1131                         }
1132         |       DO WORD lpar_or_qw expr ')'             /* do somesub(@args) */
1133                         { $$ = newUNOP(OP_ENTERSUB,
1134                             OPf_SPECIAL|OPf_STACKED,
1135                             op_append_elem(OP_LIST,
1136                                 $4,
1137                                 scalar(newCVREF(
1138                                     (OPpENTERSUB_AMPER<<8),
1139                                     scalar($2)
1140                                 )))); dep();
1141                           TOKEN_GETMAD($1,$$,'o');
1142                           TOKEN_GETMAD($3,$$,'(');
1143                           TOKEN_GETMAD($5,$$,')');
1144                         }
1145         |       DO scalar lpar_or_qw ')'                /* do $subref () */
1146                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
1147                             op_prepend_elem(OP_LIST,
1148                                 scalar(newCVREF(0,scalar($2))), (OP*)NULL)); dep();
1149                           TOKEN_GETMAD($1,$$,'o');
1150                           TOKEN_GETMAD($3,$$,'(');
1151                           TOKEN_GETMAD($4,$$,')');
1152                         }
1153         |       DO scalar lpar_or_qw expr ')'           /* do $subref (@args) */
1154                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
1155                             op_prepend_elem(OP_LIST,
1156                                 $4,
1157                                 scalar(newCVREF(0,scalar($2))))); dep();
1158                           TOKEN_GETMAD($1,$$,'o');
1159                           TOKEN_GETMAD($3,$$,'(');
1160                           TOKEN_GETMAD($5,$$,')');
1161                         }
1162
1163         ;
1164
1165 term    :       termbinop
1166         |       termunop
1167         |       anonymous
1168         |       termdo
1169         |       term '?' term ':' term
1170                         { $$ = newCONDOP(0, $1, $3, $5);
1171                           TOKEN_GETMAD($2,$$,'?');
1172                           TOKEN_GETMAD($4,$$,':');
1173                         }
1174         |       REFGEN term                          /* \$x, \@y, \%z */
1175                         { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN));
1176                           TOKEN_GETMAD($1,$$,'o');
1177                         }
1178         |       myattrterm      %prec UNIOP
1179                         { $$ = $1; }
1180         |       LOCAL term      %prec UNIOP
1181                         { $$ = localize($2,IVAL($1));
1182                           TOKEN_GETMAD($1,$$,'k');
1183                         }
1184         |       '(' expr ')'
1185                         { $$ = sawparens(IF_MAD(newUNOP(OP_NULL,0,$2), $2));
1186                           TOKEN_GETMAD($1,$$,'(');
1187                           TOKEN_GETMAD($3,$$,')');
1188                         }
1189         |       QWLIST
1190                         { $$ = IF_MAD(newUNOP(OP_NULL,0,$1), $1); }
1191         |       '(' ')'
1192                         { $$ = sawparens(newNULLLIST());
1193                           TOKEN_GETMAD($1,$$,'(');
1194                           TOKEN_GETMAD($2,$$,')');
1195                         }
1196         |       scalar  %prec '('
1197                         { $$ = $1; }
1198         |       star    %prec '('
1199                         { $$ = $1; }
1200         |       hsh     %prec '('
1201                         { $$ = $1; }
1202         |       ary     %prec '('
1203                         { $$ = $1; }
1204         |       arylen  %prec '('                    /* $#x, $#{ something } */
1205                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
1206         |       subscripted
1207                         { $$ = $1; }
1208         |       ary '[' expr ']'                     /* array slice */
1209                         { $$ = op_prepend_elem(OP_ASLICE,
1210                                 newOP(OP_PUSHMARK, 0),
1211                                     newLISTOP(OP_ASLICE, 0,
1212                                         list($3),
1213                                         ref($1, OP_ASLICE)));
1214                           TOKEN_GETMAD($2,$$,'[');
1215                           TOKEN_GETMAD($4,$$,']');
1216                         }
1217         |       ary '{' expr ';' '}'                 /* @hash{@keys} */
1218                         { $$ = op_prepend_elem(OP_HSLICE,
1219                                 newOP(OP_PUSHMARK, 0),
1220                                     newLISTOP(OP_HSLICE, 0,
1221                                         list($3),
1222                                         ref(oopsHV($1), OP_HSLICE)));
1223                             PL_parser->expect = XOPERATOR;
1224                           TOKEN_GETMAD($2,$$,'{');
1225                           TOKEN_GETMAD($4,$$,';');
1226                           TOKEN_GETMAD($5,$$,'}');
1227                         }
1228         |       THING   %prec '('
1229                         { $$ = $1; }
1230         |       amper                                /* &foo; */
1231                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
1232         |       amper lpar_or_qw ')'                 /* &foo() */
1233                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1));
1234                           TOKEN_GETMAD($2,$$,'(');
1235                           TOKEN_GETMAD($3,$$,')');
1236                         }
1237         |       amper lpar_or_qw expr ')'            /* &foo(@args) */
1238                         {
1239                           $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1240                                 op_append_elem(OP_LIST, $3, scalar($1)));
1241                           DO_MAD({
1242                               OP* op = $$;
1243                               if (op->op_type == OP_CONST) { /* defeat const fold */
1244                                 op = (OP*)op->op_madprop->mad_val;
1245                               }
1246                               token_getmad($2,op,'(');
1247                               token_getmad($4,op,')');
1248                           })
1249                         }
1250         |       NOAMP WORD listexpr                  /* foo(@args) */
1251                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1252                             op_append_elem(OP_LIST, $3, scalar($2)));
1253                           TOKEN_GETMAD($1,$$,'o');
1254                         }
1255         |       LOOPEX  /* loop exiting command (goto, last, dump, etc) */
1256                         { $$ = newOP(IVAL($1), OPf_SPECIAL);
1257                             PL_hints |= HINT_BLOCK_SCOPE;
1258                           TOKEN_GETMAD($1,$$,'o');
1259                         }
1260         |       LOOPEX term
1261                         { $$ = newLOOPEX(IVAL($1),$2);
1262                           TOKEN_GETMAD($1,$$,'o');
1263                         }
1264         |       NOTOP argexpr                        /* not $foo */
1265                         { $$ = newUNOP(OP_NOT, 0, scalar($2));
1266                           TOKEN_GETMAD($1,$$,'o');
1267                         }
1268         |       UNIOP                                /* Unary op, $_ implied */
1269                         { $$ = newOP(IVAL($1), 0);
1270                           TOKEN_GETMAD($1,$$,'o');
1271                         }
1272         |       UNIOP block                          /* eval { foo }* */
1273                         { $$ = newUNOP(IVAL($1), 0, $2);
1274                           TOKEN_GETMAD($1,$$,'o');
1275                         }
1276         |       UNIOP term                           /* Unary op */
1277                         { $$ = newUNOP(IVAL($1), 0, $2);
1278                           TOKEN_GETMAD($1,$$,'o');
1279                         }
1280         |       REQUIRE                              /* require, $_ implied */
1281                         { $$ = newOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0);
1282                           TOKEN_GETMAD($1,$$,'o');
1283                         }
1284         |       REQUIRE term                         /* require Foo */
1285                         { $$ = newUNOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0, $2);
1286                           TOKEN_GETMAD($1,$$,'o');
1287                         }
1288         |       UNIOPSUB
1289                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
1290         |       UNIOPSUB term                        /* Sub treated as unop */
1291                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1292                             op_append_elem(OP_LIST, $2, scalar($1))); }
1293         |       FUNC0                                /* Nullary operator */
1294                         { $$ = newOP(IVAL($1), 0);
1295                           TOKEN_GETMAD($1,$$,'o');
1296                         }
1297         |       FUNC0 '(' ')'
1298                         { $$ = newOP(IVAL($1), 0);
1299                           TOKEN_GETMAD($1,$$,'o');
1300                           TOKEN_GETMAD($2,$$,'(');
1301                           TOKEN_GETMAD($3,$$,')');
1302                         }
1303         |       FUNC0SUB                             /* Sub treated as nullop */
1304                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1305                                 scalar($1)); }
1306         |       FUNC1 '(' ')'                        /* not () */
1307                         { $$ = (IVAL($1) == OP_NOT)
1308                             ? newUNOP(IVAL($1), 0, newSVOP(OP_CONST, 0, newSViv(0)))
1309                             : newOP(IVAL($1), OPf_SPECIAL);
1310
1311                           TOKEN_GETMAD($1,$$,'o');
1312                           TOKEN_GETMAD($2,$$,'(');
1313                           TOKEN_GETMAD($3,$$,')');
1314                         }
1315         |       FUNC1 '(' expr ')'                   /* not($foo) */
1316                         { $$ = newUNOP(IVAL($1), 0, $3);
1317                           TOKEN_GETMAD($1,$$,'o');
1318                           TOKEN_GETMAD($2,$$,'(');
1319                           TOKEN_GETMAD($4,$$,')');
1320                         }
1321         |       PMFUNC '(' argexpr ')'          /* m//, s///, tr/// */
1322                         { $$ = pmruntime($1, $3, 1);
1323                           TOKEN_GETMAD($2,$$,'(');
1324                           TOKEN_GETMAD($4,$$,')');
1325                         }
1326         |       WORD
1327         |       listop
1328         |       YADAYADA
1329                         {
1330                           $$ = newLISTOP(OP_DIE, 0, newOP(OP_PUSHMARK, 0),
1331                                 newSVOP(OP_CONST, 0, newSVpvs("Unimplemented")));
1332                           TOKEN_GETMAD($1,$$,'X');
1333                         }
1334         |       PLUGEXPR
1335         ;
1336
1337 /* "my" declarations, with optional attributes */
1338 myattrterm:     MY myterm myattrlist
1339                         { $$ = my_attrs($2,$3);
1340                           DO_MAD(
1341                               token_getmad($1,$$,'d');
1342                               append_madprops($3->op_madprop, $$, 'a');
1343                               $3->op_madprop = 0;
1344                           )
1345                         }
1346         |       MY myterm
1347                         { $$ = localize($2,IVAL($1));
1348                           TOKEN_GETMAD($1,$$,'d');
1349                         }
1350         ;
1351
1352 /* Things that can be "my"'d */
1353 myterm  :       '(' expr ')'
1354                         { $$ = sawparens($2);
1355                           TOKEN_GETMAD($1,$$,'(');
1356                           TOKEN_GETMAD($3,$$,')');
1357                         }
1358         |       '(' ')'
1359                         { $$ = sawparens(newNULLLIST());
1360                           TOKEN_GETMAD($1,$$,'(');
1361                           TOKEN_GETMAD($2,$$,')');
1362                         }
1363         |       scalar  %prec '('
1364                         { $$ = $1; }
1365         |       hsh     %prec '('
1366                         { $$ = $1; }
1367         |       ary     %prec '('
1368                         { $$ = $1; }
1369         ;
1370
1371 /* Basic list expressions */
1372 listexpr:       /* NULL */ %prec PREC_LOW
1373                         { $$ = (OP*)NULL; }
1374         |       argexpr    %prec PREC_LOW
1375                         { $$ = $1; }
1376         ;
1377
1378 listexprcom:    /* NULL */
1379                         { $$ = (OP*)NULL; }
1380         |       expr
1381                         { $$ = $1; }
1382         ;
1383
1384 lpar_or_qw:     '('
1385                         { $$ = $1; }
1386         |       QWLIST
1387                         { munge_qwlist_to_paren_list($1); }
1388                 '('
1389                         { $$ = $3; }
1390         ;
1391
1392 /* A little bit of trickery to make "for my $foo (@bar)" actually be
1393    lexical */
1394 my_scalar:      scalar
1395                         { PL_parser->in_my = 0; $$ = my($1); }
1396         ;
1397
1398 amper   :       '&' indirob
1399                         { $$ = newCVREF(IVAL($1),$2);
1400                           TOKEN_GETMAD($1,$$,'&');
1401                         }
1402         ;
1403
1404 scalar  :       '$' indirob
1405                         { $$ = newSVREF($2);
1406                           TOKEN_GETMAD($1,$$,'$');
1407                         }
1408         ;
1409
1410 ary     :       '@' indirob
1411                         { $$ = newAVREF($2);
1412                           TOKEN_GETMAD($1,$$,'@');
1413                         }
1414         ;
1415
1416 hsh     :       '%' indirob
1417                         { $$ = newHVREF($2);
1418                           TOKEN_GETMAD($1,$$,'%');
1419                         }
1420         ;
1421
1422 arylen  :       DOLSHARP indirob
1423                         { $$ = newAVREF($2);
1424                           TOKEN_GETMAD($1,$$,'l');
1425                         }
1426         ;
1427
1428 star    :       '*' indirob
1429                         { $$ = newGVREF(0,$2);
1430                           TOKEN_GETMAD($1,$$,'*');
1431                         }
1432         ;
1433
1434 /* Indirect objects */
1435 indirob :       WORD
1436                         { $$ = scalar($1); }
1437         |       scalar %prec PREC_LOW
1438                         { $$ = scalar($1); }
1439         |       block
1440                         { $$ = scope($1); }
1441
1442         |       PRIVATEREF
1443                         { $$ = $1; }
1444         ;