pod/perlsyn.pod

   1 =head1 NAME
   2
   3 perlsyn - Perl syntax
   4
   5 =head1 DESCRIPTION
   6
   7 A Perl script consists of a sequence of declarations and statements.
   8 The sequence of statements is executed just once, unlike in B<sed>
   9 and B<awk> scripts, where the sequence of statements is executed
  10 for each input line.  While this means that you must explicitly
  11 loop over the lines of your input file (or files), it also means
  12 you have much more control over which files and which lines you look at.
  13 (Actually, I'm lying--it is possible to do an implicit loop with
  14 either the B<-n> or B<-p> switch.  It's just not the mandatory
  15 default like it is in B<sed> and B<awk>.)
  16
  17 Perl is, for the most part, a free-form language.  (The only exception
  18 to this is format declarations, for obvious reasons.)  Text from a
  19 C<"#"> character until the end of the line is a comment, and is
  20 ignored.  If you attempt to use C</* */> C-style comments, it will be
  21 interpreted either as division or pattern matching, depending on the
  22 context, and C++ C<//> comments just look like a null regular
  23 expression or defined-or operator, so don't do that.
  24
  25 =head2 Declarations
  26
  27 The only things you need to declare in Perl are report formats
  28 and subroutines--and even undefined subroutines can be handled
  29 through AUTOLOAD.  A variable holds the undefined value (C<undef>)
  30 until it has been assigned a defined value, which is anything
  31 other than C<undef>.  When used as a number, C<undef> is treated
  32 as C<0>; when used as a string, it is treated the empty string,
  33 C<"">; and when used as a reference that isn't being assigned
  34 to, it is treated as an error.  If you enable warnings, you'll
  35 be notified of an uninitialized value whenever you treat C<undef>
  36 as a string or a number.  Well, usually.  Boolean contexts, such as:
  37
  38     my $a;
  39     if ($a) {}
  40
  41 are exempt from warnings (because they care about truth rather than
  42 definedness).  Operators such as C<++>, C<-->, C<+=>,
  43 C<-=>, and C<.=>, that operate on undefined left values such as:
  44
  45     my $a;
  46     $a++;
  47
  48 are also always exempt from such warnings.
  49
  50 A declaration can be put anywhere a statement can, but has no effect on
  51 the execution of the primary sequence of statements--declarations all
  52 take effect at compile time.  Typically all the declarations are put at
  53 the beginning or the end of the script.  However, if you're using
  54 lexically-scoped private variables created with C<my()>, you'll
  55 have to make sure
  56 your format or subroutine definition is within the same block scope
  57 as the my if you expect to be able to access those private variables.
  58
  59 Declaring a subroutine allows a subroutine name to be used as if it were a
  60 list operator from that point forward in the program.  You can declare a
  61 subroutine without defining it by saying C<sub name>, thus:
  62
  63     sub myname;
  64     $me = myname $0             or die "can't get myname";
  65
  66 Note that myname() functions as a list operator, not as a unary operator;
  67 so be careful to use C<or> instead of C<||> in this case.  However, if
  68 you were to declare the subroutine as C<sub myname ($)>, then
  69 C<myname> would function as a unary operator, so either C<or> or
  70 C<||> would work.
  71
  72 Subroutines declarations can also be loaded up with the C<require> statement
  73 or both loaded and imported into your namespace with a C<use> statement.
  74 See L<perlmod> for details on this.
  75
  76 A statement sequence may contain declarations of lexically-scoped
  77 variables, but apart from declaring a variable name, the declaration acts
  78 like an ordinary statement, and is elaborated within the sequence of
  79 statements as if it were an ordinary statement.  That means it actually
  80 has both compile-time and run-time effects.
  81
  82 =head2 Simple statements
  83
  84 The only kind of simple statement is an expression evaluated for its
  85 side effects.  Every simple statement must be terminated with a
  86 semicolon, unless it is the final statement in a block, in which case
  87 the semicolon is optional.  (A semicolon is still encouraged there if the
  88 block takes up more than one line, because you may eventually add another line.)
  89 Note that there are some operators like C<eval {}> and C<do {}> that look
  90 like compound statements, but aren't (they're just TERMs in an expression),
  91 and thus need an explicit termination if used as the last item in a statement.
  92
  93 Any simple statement may optionally be followed by a I<SINGLE> modifier,
  94 just before the terminating semicolon (or block ending).  The possible
  95 modifiers are:
  96
  97     if EXPR
  98     unless EXPR
  99     while EXPR
 100     until EXPR
 101     foreach EXPR
 102
 103 The C<if> and C<unless> modifiers have the expected semantics,
 104 presuming you're a speaker of English.  The C<foreach> modifier is an
 105 iterator:  For each value in EXPR, it aliases C<$_> to the value and
 106 executes the statement.  The C<while> and C<until> modifiers have the
 107 usual "C<while> loop" semantics (conditional evaluated first), except
 108 when applied to a C<do>-BLOCK (or to the deprecated C<do>-SUBROUTINE
 109 statement), in which case the block executes once before the
 110 conditional is evaluated.  This is so that you can write loops like:
 111
 112     do {
 113         $line = <STDIN>;
 114         ...
 115     } until $line  eq ".\n";
 116
 117 See L<perlfunc/do>.  Note also that the loop control statements described
 118 later will I<NOT> work in this construct, because modifiers don't take
 119 loop labels.  Sorry.  You can always put another block inside of it
 120 (for C<next>) or around it (for C<last>) to do that sort of thing.
 121 For C<next>, just double the braces:
 122
 123     do {{
 124         next if $x == $y;
 125         # do something here
 126     }} until $x++ > $z;
 127
 128 For C<last>, you have to be more elaborate:
 129
 130     LOOP: {
 131             do {
 132                 last if $x = $y**2;
 133                 # do something here
 134             } while $x++ <= $z;
 135     }
 136
 137 B<NOTE:> The behaviour of a C<my> statement modified with a statement
 138 modifier conditional or loop construct (e.g. C<my $x if ...>) is
 139 B<undefined>.  The value of the C<my> variable may be C<undef>, any
 140 previously assigned value, or possibly anything else.  Don't rely on
 141 it.  Future versions of perl might do something different from the
 142 version of perl you try it out on.  Here be dragons.
 143
 144 =head2 Compound statements
 145
 146 In Perl, a sequence of statements that defines a scope is called a block.
 147 Sometimes a block is delimited by the file containing it (in the case
 148 of a required file, or the program as a whole), and sometimes a block
 149 is delimited by the extent of a string (in the case of an eval).
 150
 151 But generally, a block is delimited by curly brackets, also known as braces.
 152 We will call this syntactic construct a BLOCK.
 153
 154 The following compound statements may be used to control flow:
 155
 156     if (EXPR) BLOCK
 157     if (EXPR) BLOCK else BLOCK
 158     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
 159     LABEL while (EXPR) BLOCK
 160     LABEL while (EXPR) BLOCK continue BLOCK
 161     LABEL for (EXPR; EXPR; EXPR) BLOCK
 162     LABEL foreach VAR (LIST) BLOCK
 163     LABEL foreach VAR (LIST) BLOCK continue BLOCK
 164     LABEL BLOCK continue BLOCK
 165
 166 Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
 167 not statements.  This means that the curly brackets are I<required>--no
 168 dangling statements allowed.  If you want to write conditionals without
 169 curly brackets there are several other ways to do it.  The following
 170 all do the same thing:
 171
 172     if (!open(FOO)) { die "Can't open $FOO: $!"; }
 173     die "Can't open $FOO: $!" unless open(FOO);
 174     open(FOO) or die "Can't open $FOO: $!";     # FOO or bust!
 175     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
 176                         # a bit exotic, that last one
 177
 178 The C<if> statement is straightforward.  Because BLOCKs are always
 179 bounded by curly brackets, there is never any ambiguity about which
 180 C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
 181 the sense of the test is reversed.
 182
 183 The C<while> statement executes the block as long as the expression is
 184 true (does not evaluate to the null string C<""> or C<0> or C<"0">).
 185 The LABEL is optional, and if present, consists of an identifier followed
 186 by a colon.  The LABEL identifies the loop for the loop control
 187 statements C<next>, C<last>, and C<redo>.
 188 If the LABEL is omitted, the loop control statement
 189 refers to the innermost enclosing loop.  This may include dynamically
 190 looking back your call-stack at run time to find the LABEL.  Such
 191 desperate behavior triggers a warning if you use the C<use warnings>
 192 pragma or the B<-w> flag.
 193
 194 If there is a C<continue> BLOCK, it is always executed just before the
 195 conditional is about to be evaluated again, just like the third part of a
 196 C<for> loop in C.  Thus it can be used to increment a loop variable, even
 197 when the loop has been continued via the C<next> statement (which is
 198 similar to the C C<continue> statement).
 199
 200 =head2 Loop Control
 201
 202 The C<next> command is like the C<continue> statement in C; it starts
 203 the next iteration of the loop:
 204
 205     LINE: while (<STDIN>) {
 206         next LINE if /^#/;      # discard comments
 207         ...
 208     }
 209
 210 The C<last> command is like the C<break> statement in C (as used in
 211 loops); it immediately exits the loop in question.  The
 212 C<continue> block, if any, is not executed:
 213
 214     LINE: while (<STDIN>) {
 215         last LINE if /^$/;      # exit when done with header
 216         ...
 217     }
 218
 219 The C<redo> command restarts the loop block without evaluating the
 220 conditional again.  The C<continue> block, if any, is I<not> executed.
 221 This command is normally used by programs that want to lie to themselves
 222 about what was just input.
 223
 224 For example, when processing a file like F</etc/termcap>.
 225 If your input lines might end in backslashes to indicate continuation, you
 226 want to skip ahead and get the next record.
 227
 228     while (<>) {
 229         chomp;
 230         if (s/\\$//) {
 231             $_ .= <>;
 232             redo unless eof();
 233         }
 234         # now process $_
 235     }
 236
 237 which is Perl short-hand for the more explicitly written version:
 238
 239     LINE: while (defined($line = <ARGV>)) {
 240         chomp($line);
 241         if ($line =~ s/\\$//) {
 242             $line .= <ARGV>;
 243             redo LINE unless eof(); # not eof(ARGV)!
 244         }
 245         # now process $line
 246     }
 247
 248 Note that if there were a C<continue> block on the above code, it would
 249 get executed only on lines discarded by the regex (since redo skips the
 250 continue block). A continue block is often used to reset line counters
 251 or C<?pat?> one-time matches:
 252
 253     # inspired by :1,$g/fred/s//WILMA/
 254     while (<>) {
 255         ?(fred)?    && s//WILMA $1 WILMA/;
 256         ?(barney)?  && s//BETTY $1 BETTY/;
 257         ?(homer)?   && s//MARGE $1 MARGE/;
 258     } continue {
 259         print "$ARGV $.: $_";
 260         close ARGV  if eof();           # reset $.
 261         reset       if eof();           # reset ?pat?
 262     }
 263
 264 If the word C<while> is replaced by the word C<until>, the sense of the
 265 test is reversed, but the conditional is still tested before the first
 266 iteration.
 267
 268 The loop control statements don't work in an C<if> or C<unless>, since
 269 they aren't loops.  You can double the braces to make them such, though.
 270
 271     if (/pattern/) {{
 272         last if /fred/;
 273         next if /barney/; # same effect as "last", but doesn't document as well
 274         # do something here
 275     }}
 276
 277 This is caused by the fact that a block by itself acts as a loop that
 278 executes once, see L<"Basic BLOCKs and Switch Statements">.
 279
 280 The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
 281 available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
 282
 283 =head2 For Loops
 284
 285 Perl's C-style C<for> loop works like the corresponding C<while> loop;
 286 that means that this:
 287
 288     for ($i = 1; $i < 10; $i++) {
 289         ...
 290     }
 291
 292 is the same as this:
 293
 294     $i = 1;
 295     while ($i < 10) {
 296         ...
 297     } continue {
 298         $i++;
 299     }
 300
 301 There is one minor difference: if variables are declared with C<my>
 302 in the initialization section of the C<for>, the lexical scope of
 303 those variables is exactly the C<for> loop (the body of the loop
 304 and the control sections).
 305
 306 Besides the normal array index looping, C<for> can lend itself
 307 to many other interesting applications.  Here's one that avoids the
 308 problem you get into if you explicitly test for end-of-file on
 309 an interactive file descriptor causing your program to appear to
 310 hang.
 311
 312     $on_a_tty = -t STDIN && -t STDOUT;
 313     sub prompt { print "yes? " if $on_a_tty }
 314     for ( prompt(); <STDIN>; prompt() ) {
 315         # do something
 316     }
 317
 318 Using C<readline> (or the operator form, C<< <EXPR> >>) as the
 319 conditional of a C<for> loop is shorthand for the following.  This
 320 behaviour is the same as a C<while> loop conditional.
 321
 322     for ( prompt(); defined( $_ = <STDIN> ); prompt() ) {
 323         # do something
 324     }
 325
 326 =head2 Foreach Loops
 327
 328 The C<foreach> loop iterates over a normal list value and sets the
 329 variable VAR to be each element of the list in turn.  If the variable
 330 is preceded with the keyword C<my>, then it is lexically scoped, and
 331 is therefore visible only within the loop.  Otherwise, the variable is
 332 implicitly local to the loop and regains its former value upon exiting
 333 the loop.  If the variable was previously declared with C<my>, it uses
 334 that variable instead of the global one, but it's still localized to
 335 the loop.  This implicit localisation occurs I<only> in a C<foreach>
 336 loop.
 337
 338 The C<foreach> keyword is actually a synonym for the C<for> keyword, so
 339 you can use C<foreach> for readability or C<for> for brevity.  (Or because
 340 the Bourne shell is more familiar to you than I<csh>, so writing C<for>
 341 comes more naturally.)  If VAR is omitted, C<$_> is set to each value.
 342
 343 If any element of LIST is an lvalue, you can modify it by modifying
 344 VAR inside the loop.  Conversely, if any element of LIST is NOT an
 345 lvalue, any attempt to modify that element will fail.  In other words,
 346 the C<foreach> loop index variable is an implicit alias for each item
 347 in the list that you're looping over.
 348
 349 If any part of LIST is an array, C<foreach> will get very confused if
 350 you add or remove elements within the loop body, for example with
 351 C<splice>.   So don't do that.
 352
 353 C<foreach> probably won't do what you expect if VAR is a tied or other
 354 special variable.   Don't do that either.
 355
 356 Examples:
 357
 358     for (@ary) { s/foo/bar/ }
 359
 360     for my $elem (@elements) {
 361         $elem *= 2;
 362     }
 363
 364     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
 365         print $count, "\n"; sleep(1);
 366     }
 367
 368     for (1..15) { print "Merry Christmas\n"; }
 369
 370     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
 371         print "Item: $item\n";
 372     }
 373
 374 Here's how a C programmer might code up a particular algorithm in Perl:
 375
 376     for (my $i = 0; $i < @ary1; $i++) {
 377         for (my $j = 0; $j < @ary2; $j++) {
 378             if ($ary1[$i] > $ary2[$j]) {
 379                 last; # can't go to outer :-(
 380             }
 381             $ary1[$i] += $ary2[$j];
 382         }
 383         # this is where that last takes me
 384     }
 385
 386 Whereas here's how a Perl programmer more comfortable with the idiom might
 387 do it:
 388
 389     OUTER: for my $wid (@ary1) {
 390     INNER:   for my $jet (@ary2) {
 391                 next OUTER if $wid > $jet;
 392                 $wid += $jet;
 393              }
 394           }
 395
 396 See how much easier this is?  It's cleaner, safer, and faster.  It's
 397 cleaner because it's less noisy.  It's safer because if code gets added
 398 between the inner and outer loops later on, the new code won't be
 399 accidentally executed.  The C<next> explicitly iterates the other loop
 400 rather than merely terminating the inner one.  And it's faster because
 401 Perl executes a C<foreach> statement more rapidly than it would the
 402 equivalent C<for> loop.
 403
 404 =head2 Basic BLOCKs and Switch Statements
 405
 406 A BLOCK by itself (labeled or not) is semantically equivalent to a
 407 loop that executes once.  Thus you can use any of the loop control
 408 statements in it to leave or restart the block.  (Note that this is
 409 I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
 410 C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
 411 block is optional.
 412
 413 The BLOCK construct is particularly nice for doing case
 414 structures.
 415
 416     SWITCH: {
 417         if (/^abc/) { $abc = 1; last SWITCH; }
 418         if (/^def/) { $def = 1; last SWITCH; }
 419         if (/^xyz/) { $xyz = 1; last SWITCH; }
 420         $nothing = 1;
 421     }
 422
 423 There is no official C<switch> statement in Perl, because there are
 424 already several ways to write the equivalent.
 425
 426 However, starting from Perl 5.8 to get switch and case one can use
 427 the Switch extension and say:
 428
 429         use Switch;
 430
 431 after which one has switch and case.  It is not as fast as it could be
 432 because it's not really part of the language (it's done using source
 433 filters) but it is available, and it's very flexible.
 434
 435 In addition to the above BLOCK construct, you could write
 436
 437     SWITCH: {
 438         $abc = 1, last SWITCH  if /^abc/;
 439         $def = 1, last SWITCH  if /^def/;
 440         $xyz = 1, last SWITCH  if /^xyz/;
 441         $nothing = 1;
 442     }
 443
 444 (That's actually not as strange as it looks once you realize that you can
 445 use loop control "operators" within an expression,  That's just the normal
 446 C comma operator.)
 447
 448 or
 449
 450     SWITCH: {
 451         /^abc/ && do { $abc = 1; last SWITCH; };
 452         /^def/ && do { $def = 1; last SWITCH; };
 453         /^xyz/ && do { $xyz = 1; last SWITCH; };
 454         $nothing = 1;
 455     }
 456
 457 or formatted so it stands out more as a "proper" C<switch> statement:
 458
 459     SWITCH: {
 460         /^abc/      && do {
 461                             $abc = 1;
 462                             last SWITCH;
 463                        };
 464
 465         /^def/      && do {
 466                             $def = 1;
 467                             last SWITCH;
 468                        };
 469
 470         /^xyz/      && do {
 471                             $xyz = 1;
 472                             last SWITCH;
 473                         };
 474         $nothing = 1;
 475     }
 476
 477 or
 478
 479     SWITCH: {
 480         /^abc/ and $abc = 1, last SWITCH;
 481         /^def/ and $def = 1, last SWITCH;
 482         /^xyz/ and $xyz = 1, last SWITCH;
 483         $nothing = 1;
 484     }
 485
 486 or even, horrors,
 487
 488     if (/^abc/)
 489         { $abc = 1 }
 490     elsif (/^def/)
 491         { $def = 1 }
 492     elsif (/^xyz/)
 493         { $xyz = 1 }
 494     else
 495         { $nothing = 1 }
 496
 497 A common idiom for a C<switch> statement is to use C<foreach>'s aliasing to make
 498 a temporary assignment to C<$_> for convenient matching:
 499
 500     SWITCH: for ($where) {
 501                 /In Card Names/     && do { push @flags, '-e'; last; };
 502                 /Anywhere/          && do { push @flags, '-h'; last; };
 503                 /In Rulings/        && do {                    last; };
 504                 die "unknown value for form variable where: `$where'";
 505             }
 506
 507 Another interesting approach to a switch statement is arrange
 508 for a C<do> block to return the proper value:
 509
 510     $amode = do {
 511         if     ($flag & O_RDONLY) { "r" }       # XXX: isn't this 0?
 512         elsif  ($flag & O_WRONLY) { ($flag & O_APPEND) ? "a" : "w" }
 513         elsif  ($flag & O_RDWR)   {
 514             if ($flag & O_CREAT)  { "w+" }
 515             else                  { ($flag & O_APPEND) ? "a+" : "r+" }
 516         }
 517     };
 518
 519 Or
 520
 521         print do {
 522             ($flags & O_WRONLY) ? "write-only"          :
 523             ($flags & O_RDWR)   ? "read-write"          :
 524                                   "read-only";
 525         };
 526
 527 Or if you are certain that all the C<&&> clauses are true, you can use
 528 something like this, which "switches" on the value of the
 529 C<HTTP_USER_AGENT> environment variable.
 530
 531     #!/usr/bin/perl
 532     # pick out jargon file page based on browser
 533     $dir = 'http://www.wins.uva.nl/~mes/jargon';
 534     for ($ENV{HTTP_USER_AGENT}) {
 535         $page  =    /Mac/            && 'm/Macintrash.html'
 536                  || /Win(dows )?NT/  && 'e/evilandrude.html'
 537                  || /Win|MSIE|WebTV/ && 'm/MicroslothWindows.html'
 538                  || /Linux/          && 'l/Linux.html'
 539                  || /HP-UX/          && 'h/HP-SUX.html'
 540                  || /SunOS/          && 's/ScumOS.html'
 541                  ||                     'a/AppendixB.html';
 542     }
 543     print "Location: $dir/$page\015\012\015\012";
 544
 545 That kind of switch statement only works when you know the C<&&> clauses
 546 will be true.  If you don't, the previous C<?:> example should be used.
 547
 548 You might also consider writing a hash of subroutine references
 549 instead of synthesizing a C<switch> statement.
 550
 551 =head2 Goto
 552
 553 Although not for the faint of heart, Perl does support a C<goto>
 554 statement.  There are three forms: C<goto>-LABEL, C<goto>-EXPR, and
 555 C<goto>-&NAME.  A loop's LABEL is not actually a valid target for
 556 a C<goto>; it's just the name of the loop.
 557
 558 The C<goto>-LABEL form finds the statement labeled with LABEL and resumes
 559 execution there.  It may not be used to go into any construct that
 560 requires initialization, such as a subroutine or a C<foreach> loop.  It
 561 also can't be used to go into a construct that is optimized away.  It
 562 can be used to go almost anywhere else within the dynamic scope,
 563 including out of subroutines, but it's usually better to use some other
 564 construct such as C<last> or C<die>.  The author of Perl has never felt the
 565 need to use this form of C<goto> (in Perl, that is--C is another matter).
 566
 567 The C<goto>-EXPR form expects a label name, whose scope will be resolved
 568 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
 569 necessarily recommended if you're optimizing for maintainability:
 570
 571     goto(("FOO", "BAR", "GLARCH")[$i]);
 572
 573 The C<goto>-&NAME form is highly magical, and substitutes a call to the
 574 named subroutine for the currently running subroutine.  This is used by
 575 C<AUTOLOAD()> subroutines that wish to load another subroutine and then
 576 pretend that the other subroutine had been called in the first place
 577 (except that any modifications to C<@_> in the current subroutine are
 578 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
 579 will be able to tell that this routine was called first.
 580
 581 In almost all cases like this, it's usually a far, far better idea to use the
 582 structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
 583 resorting to a C<goto>.  For certain applications, the catch and throw pair of
 584 C<eval{}> and die() for exception processing can also be a prudent approach.
 585
 586 =head2 PODs: Embedded Documentation
 587
 588 Perl has a mechanism for intermixing documentation with source code.
 589 While it's expecting the beginning of a new statement, if the compiler
 590 encounters a line that begins with an equal sign and a word, like this
 591
 592     =head1 Here There Be Pods!
 593
 594 Then that text and all remaining text up through and including a line
 595 beginning with C<=cut> will be ignored.  The format of the intervening
 596 text is described in L<perlpod>.
 597
 598 This allows you to intermix your source code
 599 and your documentation text freely, as in
 600
 601     =item snazzle($)
 602
 603     The snazzle() function will behave in the most spectacular
 604     form that you can possibly imagine, not even excepting
 605     cybernetic pyrotechnics.
 606
 607     =cut back to the compiler, nuff of this pod stuff!
 608
 609     sub snazzle($) {
 610         my $thingie = shift;
 611         .........
 612     }
 613
 614 Note that pod translators should look at only paragraphs beginning
 615 with a pod directive (it makes parsing easier), whereas the compiler
 616 actually knows to look for pod escapes even in the middle of a
 617 paragraph.  This means that the following secret stuff will be
 618 ignored by both the compiler and the translators.
 619
 620     $a=3;
 621     =secret stuff
 622      warn "Neither POD nor CODE!?"
 623     =cut back
 624     print "got $a\n";
 625
 626 You probably shouldn't rely upon the C<warn()> being podded out forever.
 627 Not all pod translators are well-behaved in this regard, and perhaps
 628 the compiler will become pickier.
 629
 630 One may also use pod directives to quickly comment out a section
 631 of code.
 632
 633 =head2 Plain Old Comments (Not!)
 634
 635 Much like the C preprocessor, Perl can process line directives.  Using
 636 this, one can control Perl's idea of filenames and line numbers in
 637 error or warning messages (especially for strings that are processed
 638 with C<eval()>).  The syntax for this mechanism is the same as for most
 639 C preprocessors: it matches the regular expression
 640 C</^#\s*line\s+(\d+)\s*(?:\s"([^"]+)")?\s*$/> with C<$1> being the line
 641 number for the next line, and C<$2> being the optional filename
 642 (specified within quotes).
 643
 644 There is a fairly obvious gotcha included with the line directive:
 645 Debuggers and profilers will only show the last source line to appear
 646 at a particular line number in a given file.  Care should be taken not
 647 to cause line number collisions in code you'd like to debug later.
 648
 649 Here are some examples that you should be able to type into your command
 650 shell:
 651
 652     % perl
 653     # line 200 "bzzzt"
 654     # the `#' on the previous line must be the first char on line
 655     die 'foo';
 656     __END__
 657     foo at bzzzt line 201.
 658
 659     % perl
 660     # line 200 "bzzzt"
 661     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
 662     __END__
 663     foo at - line 2001.
 664
 665     % perl
 666     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
 667     __END__
 668     foo at foo bar line 200.
 669
 670     % perl
 671     # line 345 "goop"
 672     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
 673     print $@;
 674     __END__
 675     foo at goop line 345.
 676
 677 =cut