This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Most magic.t tests can actually run on VMS.
[perl5.git] / t / op / magic.t
1 #!./perl
2
3 BEGIN {
4     $| = 1;
5     chdir 't' if -d 't';
6     @INC = '../lib';
7     require './test.pl';
8     plan (tests => 171);
9 }
10
11 # Test that defined() returns true for magic variables created on the fly,
12 # even before they have been created.
13 # This must come first, even before turning on warnings or setting up
14 # $SIG{__WARN__}, to avoid invalidating the tests.  warnings.pm currently
15 # does not mention any special variables, but that could easily change.
16 BEGIN {
17     # not available in miniperl
18     my %non_mini = map { $_ => 1 } qw(+ - [);
19     for (qw(
20         SIG ^OPEN ^TAINT ^UNICODE ^UTF8LOCALE ^WARNING_BITS 1 2 3 4 5 6 7 8
21         9 42 & ` ' : ? ! _ - [ ^ ~ = % . ( ) < > \ / $ | + ; ] ^A ^C ^D
22         ^E ^F ^H ^I ^L ^N ^O ^P ^S ^T ^V ^W ^UTF8CACHE ::12345 main::98732
23     )) {
24         my $v = $_;
25         # avoid using any global vars here:
26         if ($v =~ s/^\^(?=.)//) {
27             for(substr $v, 0, 1) {
28                 $_ = chr ord() - 64;
29             }
30         }
31         SKIP:
32         {
33             skip_if_miniperl("the module for *$_ may not be available in "
34                              . "miniperl", 1) if $non_mini{$_};
35             ok defined *$v, "*$_ appears to be defined at the outset";
36         }
37     }
38 }
39
40 # This must be in a separate BEGIN block, as the mere mention of ${^TAINT}
41 # will invalidate the test for it.
42 BEGIN {
43     $ENV{PATH} = '/bin' if ${^TAINT};
44     $SIG{__WARN__} = sub { die "Dying on warning: ", @_ };
45 }
46
47 use warnings;
48 use Config;
49
50
51 $Is_MSWin32  = $^O eq 'MSWin32';
52 $Is_NetWare  = $^O eq 'NetWare';
53 $Is_VMS      = $^O eq 'VMS';
54 $Is_Dos      = $^O eq 'dos';
55 $Is_os2      = $^O eq 'os2';
56 $Is_Cygwin   = $^O eq 'cygwin';
57 $Is_MPE      = $^O eq 'mpeix';          
58 $Is_BeOS     = $^O eq 'beos';
59
60 $PERL = $ENV{PERL}
61     || ($Is_NetWare           ? 'perl'   :
62        $Is_VMS                ? $^X      :
63        $Is_MSWin32            ? '.\perl' :
64        './perl');
65
66 sub env_is {
67     my ($key, $val, $desc) = @_;
68     if ($Is_MSWin32) {
69         # cmd.exe will echo 'variable=value' but 4nt will echo just the value
70         # -- Nikola Knezevic
71         like `set $key`, qr/^(?:\Q$key\E=)?\Q$val\E$/, $desc;
72     } elsif ($Is_VMS) {
73         is `write sys\$output f\$trnlnm("\Q$key\E")`, "$val\n", $desc;
74     } else {
75         is `echo \$\Q$key\E`, "$val\n", $desc;
76     }
77 }
78
79 END {
80     # On VMS, environment variable changes are peristent after perl exits
81     if ($Is_VMS) {
82         delete $ENV{'FOO'};
83         delete $ENV{'__NoNeSuCh'};
84     }
85 }
86
87 eval '$ENV{"FOO"} = "hi there";';       # check that ENV is inited inside eval
88 # cmd.exe will echo 'variable=value' but 4nt will echo just the value
89 # -- Nikola Knezevic
90 if ($Is_MSWin32)  { like `set FOO`, qr/^(?:FOO=)?hi there$/; }
91 elsif ($Is_VMS)   { is `write sys\$output f\$trnlnm("FOO")`, "hi there\n"; }
92 else              { is `echo \$FOO`, "hi there\n"; }
93
94 unlink_all 'ajslkdfpqjsjfk';
95 $! = 0;
96 open(FOO,'ajslkdfpqjsjfk');
97 isnt($!, 0);
98 close FOO; # just mention it, squelch used-only-once
99
100 SKIP: {
101     skip('SIGINT not safe on this platform', 5)
102         if $Is_MSWin32 || $Is_NetWare || $Is_Dos || $Is_MPE;
103   # the next tests are done in a subprocess because sh spits out a
104   # newline onto stderr when a child process kills itself with SIGINT.
105   # We use a pipe rather than system() because the VMS command buffer
106   # would overflow with a command that long.
107
108     # For easy interpolation of test numbers:
109     $next_test = curr_test() - 1;
110     sub TIEARRAY {bless[]}
111     sub FETCH { $next_test + pop }
112     tie my @tn, __PACKAGE__;
113
114     open( CMDPIPE, "| $PERL");
115
116     print CMDPIPE "\$t1 = $tn[1]; \$t2 = $tn[2];\n", <<'END';
117
118     $| = 1;             # command buffering
119
120     $SIG{"INT"} = "ok1";     kill "INT",$$; sleep 1;
121     $SIG{"INT"} = "IGNORE";  kill "INT",$$; sleep 1; print "ok $t2\n";
122     $SIG{"INT"} = "DEFAULT"; kill "INT",$$; sleep 1; print" not ok $t2\n";
123
124     sub ok1 {
125         if (($x = pop(@_)) eq "INT") {
126             print "ok $t1\n";
127         }
128         else {
129             print "not ok $t1 ($x @_)\n";
130         }
131     }
132
133 END
134
135     close CMDPIPE;
136
137     open( CMDPIPE, "| $PERL");
138     print CMDPIPE "\$t3 = $tn[3];\n", <<'END';
139
140     { package X;
141         sub DESTROY {
142             kill "INT",$$;
143         }
144     }
145     sub x {
146         my $x=bless [], 'X';
147         return sub { $x };
148     }
149     $| = 1;             # command buffering
150     $SIG{"INT"} = "ok3";
151     {
152         local $SIG{"INT"}=x();
153         print ""; # Needed to expose failure in 5.8.0 (why?)
154     }
155     sleep 1;
156     delete $SIG{"INT"};
157     kill "INT",$$; sleep 1;
158     sub ok3 {
159         print "ok $t3\n";
160     }
161 END
162     close CMDPIPE;
163     $? >>= 8 if $^O eq 'VMS'; # POSIX status hiding in 2nd byte
164     my $todo = ($^O eq 'os2' ? ' # TODO: EMX v0.9d_fix4 bug: wrong nibble? ' : '');
165     print $? & 0xFF ? "ok $tn[4]$todo\n" : "not ok $tn[4]$todo\n";
166
167     open(CMDPIPE, "| $PERL");
168     print CMDPIPE <<'END';
169
170     sub PVBM () { 'foo' }
171     index 'foo', PVBM;
172     my $pvbm = PVBM;
173
174     sub foo { exit 0 }
175
176     $SIG{"INT"} = $pvbm;
177     kill "INT", $$; sleep 1;
178 END
179     close CMDPIPE;
180     $? >>= 8 if $^O eq 'VMS';
181     print $? ? "not ok $tn[5]\n" : "ok $tn[5]\n";
182
183     curr_test(curr_test() + 5);
184 }
185
186 # can we slice ENV?
187 @val1 = @ENV{keys(%ENV)};
188 @val2 = values(%ENV);
189 is join(':',@val1), join(':',@val2);
190 cmp_ok @val1, '>', 1;
191
192 # regex vars
193 'foobarbaz' =~ /b(a)r/;
194 is $`, 'foo';
195 is $&, 'bar';
196 is $', 'baz';
197 is $+, 'a';
198
199 # [perl #24237]
200 for (qw < ` & ' >) {
201  fresh_perl_is
202   qq < \@$_; q "fff" =~ /(?!^)./; print "[\$$_]\\n" >,
203   "[f]\n", {},
204   "referencing \@$_ before \$$_ etc. still saws off ampersands";
205 }
206
207 # $"
208 @a = qw(foo bar baz);
209 is "@a", "foo bar baz";
210 {
211     local $" = ',';
212     is "@a", "foo,bar,baz";
213 }
214
215 # $;
216 %h = ();
217 $h{'foo', 'bar'} = 1;
218 is((keys %h)[0], "foo\034bar");
219 {
220     local $; = 'x';
221     %h = ();
222     $h{'foo', 'bar'} = 1;
223     is((keys %h)[0], 'fooxbar');
224 }
225
226 # $?, $@, $$
227 system qq[$PERL "-I../lib" -e "use vmsish qw(hushed); exit(0)"];
228 is $?, 0;
229 system qq[$PERL "-I../lib" -e "use vmsish qw(hushed); exit(1)"];
230 isnt $?, 0;
231
232 eval { die "foo\n" };
233 is $@, "foo\n";
234
235 cmp_ok($$, '>', 0);
236 my $pid = $$;
237 eval { $$ = 42 };
238 is $$, 42, '$$ can be modified';
239 SKIP: {
240     skip "no fork", 1 unless $Config{d_fork};
241     (my $kidpid = open my $fh, "-|") // skip "cannot fork: $!", 1;
242     if($kidpid) { # parent
243         my $kiddollars = <$fh>;
244         close $fh or die "cannot close pipe from kid proc: $!";
245         is $kiddollars, $kidpid, '$$ is reset on fork';
246     }
247     else { # child
248         print $$;
249         $::NO_ENDING = 1; # silence "Looks like you only ran..."
250         exit;
251     }
252 }
253 $$ = $pid; # Tests below use $$
254
255 # $^X and $0
256 {
257     my $is_abs = $Config{d_procselfexe} || $Config{usekernprocpathname}
258       || $Config{usensgetexecutablepath};
259     if ($^O eq 'qnx') {
260         chomp($wd = `/usr/bin/fullpath -t`);
261     }
262     elsif($Is_Cygwin || $is_abs) {
263        # Cygwin turns the symlink into the real file
264        chomp($wd = `pwd`);
265        $wd =~ s#/t$##;
266        $wd =~ /(.*)/; $wd = $1; # untaint
267        if ($Is_Cygwin) {
268            $wd = Cygwin::win_to_posix_path(Cygwin::posix_to_win_path($wd, 1));
269        }
270     }
271     elsif($Is_os2) {
272        $wd = Cwd::sys_cwd();
273     }
274     else {
275         $wd = '.';
276     }
277     my $perl = $Is_VMS || $is_abs ? $^X : "$wd/perl";
278     my $headmaybe = '';
279     my $middlemaybe = '';
280     my $tailmaybe = '';
281     $script = "$wd/show-shebang";
282     if ($Is_MSWin32) {
283         chomp($wd = `cd`);
284         $wd =~ s|\\|/|g;
285         $perl = "$wd/perl.exe";
286         $script = "$wd/show-shebang.bat";
287         $headmaybe = <<EOH ;
288 \@rem ='
289 \@echo off
290 $perl -x \%0
291 goto endofperl
292 \@rem ';
293 EOH
294         $tailmaybe = <<EOT ;
295
296 __END__
297 :endofperl
298 EOT
299     }
300     elsif ($Is_os2) {
301       $script = "./show-shebang";
302     }
303     elsif ($Is_VMS) {
304       $script = "[]show-shebang";
305     }
306     elsif ($Is_Cygwin) {
307       $middlemaybe = <<'EOX'
308 $^X = Cygwin::win_to_posix_path(Cygwin::posix_to_win_path($^X, 1));
309 $0 = Cygwin::win_to_posix_path(Cygwin::posix_to_win_path($0, 1));
310 EOX
311     }
312     if ($^O eq 'os390' or $^O eq 'posix-bc' or $^O eq 'vmesa') {  # no shebang
313         $headmaybe = <<EOH ;
314     eval 'exec ./perl -S \$0 \${1+"\$\@"}'
315         if 0;
316 EOH
317     }
318     $s1 = "\$^X is $perl, \$0 is $script\n";
319     ok open(SCRIPT, ">$script") or diag "Can't write to $script: $!";
320     ok print(SCRIPT $headmaybe . <<EOB . $middlemaybe . <<'EOF' . $tailmaybe) or diag $!;
321 #!$perl
322 EOB
323 print "\$^X is $^X, \$0 is $0\n";
324 EOF
325     ok close(SCRIPT) or diag $!;
326     ok chmod(0755, $script) or diag $!;
327     $_ = $Is_VMS ? `$perl $script` : `$script`;
328     s/\.exe//i if $Is_Dos or $Is_Cygwin or $Is_os2;
329     s{./$script}{$script} if $Is_BeOS; # revert BeOS execvp() side-effect
330     s{is perl}{is $perl}; # for systems where $^X is only a basename
331     s{\\}{/}g;
332     if ($Is_MSWin32 || $Is_os2) {
333         is uc $_, uc $s1;
334     } else {
335         is $_, $s1;
336     }
337     $_ = `$perl $script`;
338     s/\.exe//i if $Is_Dos or $Is_os2 or $Is_Cygwin;
339     s{./$perl}{$perl} if $Is_BeOS; # revert BeOS execvp() side-effect
340     s{\\}{/}g;
341     if ($Is_MSWin32 || $Is_os2) {
342         is uc $_, uc $s1;
343     } else {
344         is $_, $s1;
345     }
346     ok unlink($script) or diag $!;
347     # CHECK
348     # Could this be replaced with:
349     # unlink_all($script);
350 }
351
352 # $], $^O, $^T
353 cmp_ok $], '>=', 5.00319;
354 ok $^O;
355 cmp_ok $^T, '>', 850000000;
356
357 # Test change 25062 is working
358 my $orig_osname = $^O;
359 {
360 local $^I = '.bak';
361 is $^O, $orig_osname, 'Assigning $^I does not clobber $^O';
362 }
363 $^O = $orig_osname;
364
365 {
366     #RT #72422
367     foreach my $p (0, 1) {
368         fresh_perl_is(<<"EOP", '2 4 8', undef, "test \$^P = $p");
369 \$DB::single = 2;
370 \$DB::trace = 4;
371 \$DB::signal = 8;
372 \$^P = $p;
373 print "\$DB::single \$DB::trace \$DB::signal";
374 EOP
375     }
376 }
377
378 # Check that assigning to $0 on Linux sets the process name with both
379 # argv[0] assignment and by calling prctl()
380 {
381   SKIP: {
382     skip "We don't have prctl() here", 2 unless $Config{d_prctl_set_name};
383
384     # We don't really need these tests. prctl() is tested in the
385     # Kernel, but test it anyway for our sanity. If something doesn't
386     # work (like if the system doesn't have a ps(1) for whatever
387     # reason) just bail out gracefully.
388     my $maybe_ps = sub {
389         my ($cmd) = @_;
390         local ($?, $!);
391
392         no warnings;
393         my $res = `$cmd`;
394         skip "Couldn't shell out to '$cmd', returned code $?", 2 if $?;
395         return $res;
396     };
397
398     my $name = "Good Morning, Dave";
399     $0 = $name;
400
401     chomp(my $argv0 = $maybe_ps->("ps h $$"));
402     chomp(my $prctl = $maybe_ps->("ps hc $$"));
403
404     like($argv0, $name, "Set process name through argv[0] ($argv0)");
405     like($prctl, substr($name, 0, 15), "Set process name through prctl() ($prctl)");
406   }
407 }
408
409 {
410     my $ok = 1;
411     my $warn = '';
412     local $SIG{'__WARN__'} = sub { $ok = 0; $warn = join '', @_; $warn =~ s/\n$//; };
413     $! = undef;
414     local $TODO = $Is_VMS ? "'\$!=undef' does throw a warning" : '';
415     ok($ok, $warn);
416 }
417
418 SKIP: {
419     skip_if_miniperl("miniperl can't rely on loading %Errno", 2);
420    no warnings 'void';
421
422 # Make sure Errno hasn't been prematurely autoloaded
423
424    ok !keys %Errno::;
425
426 # Test auto-loading of Errno when %! is used
427
428    ok scalar eval q{
429       %!;
430       scalar %Errno::;
431    }, $@;
432 }
433
434 SKIP:  {
435     skip_if_miniperl("miniperl can't rely on loading %Errno", 2);
436     # Make sure that Errno loading doesn't clobber $!
437
438     undef %Errno::;
439     delete $INC{"Errno.pm"};
440
441     open(FOO, "nonesuch"); # Generate ENOENT
442     my %errs = %{"!"}; # Cause Errno.pm to be loaded at run-time
443     ok ${"!"}{ENOENT};
444
445     # Make sure defined(*{"!"}) before %! does not stop %! from working
446     is
447       runperl(
448         prog => 'BEGIN { defined *{q-!-} } print qq-ok\n- if tied %!',
449       ),
450      "ok\n",
451      'defined *{"!"} does not stop %! from working';
452 }
453
454 # Check that we don't auto-load packages
455 SKIP: {
456     skip "staticly linked; may be preloaded", 4 unless $Config{usedl};
457     foreach (['powie::!', 'Errno'],
458              ['powie::+', 'Tie::Hash::NamedCapture']) {
459         my ($symbol, $package) = @$_;
460         foreach my $scalar_first ('', '$$symbol;') {
461             my $desc = qq{Referencing %{"$symbol"}};
462             $desc .= qq{ after mentioning \${"$symbol"}} if $scalar_first;
463             $desc .= " doesn't load $package";
464
465             fresh_perl_is(<<"EOP", 0, {}, $desc);
466 use strict qw(vars subs);
467 my \$symbol = '$symbol';
468 $scalar_first;
469 1 if %{\$symbol};
470 print scalar %${package}::;
471 EOP
472         }
473     }
474 }
475
476 is $^S, 0;
477 eval { is $^S,1 };
478 eval " BEGIN { ok ! defined \$^S } ";
479 is $^S, 0;
480
481 my $taint = ${^TAINT};
482 is ${^TAINT}, $taint;
483 eval { ${^TAINT} = 1 };
484 is ${^TAINT}, $taint;
485
486 # 5.6.1 had a bug: @+ and @- were not properly interpolated
487 # into double-quoted strings
488 # 20020414 mjd-perl-patch+@plover.com
489 "I like pie" =~ /(I) (like) (pie)/;
490 is "@-",  "0 0 2 7";
491 is "@+", "10 1 6 10";
492
493 # Tests for the magic get of $\
494 {
495     my $ok = 0;
496     # [perl #19330]
497     {
498         local $\ = undef;
499         $\++; $\++;
500         $ok = $\ eq 2;
501     }
502     ok $ok;
503     $ok = 0;
504     {
505         local $\ = "a\0b";
506         $ok = "a$\b" eq "aa\0bb";
507     }
508     ok $ok;
509 }
510
511 # Test for bug [perl #36434]
512 # Can not do this test on VMS, EPOC, and SYMBIAN according to comments
513 # in mg.c/Perl_magic_clear_all_env()
514 SKIP: {
515     skip('Can\'t make assignment to \%ENV on this system', 3) if $Is_VMS;
516
517     local @ISA;
518     local %ENV;
519     # This used to be __PACKAGE__, but that causes recursive
520     #  inheritance, which is detected earlier now and broke
521     #  this test
522     eval { push @ISA, __FILE__ };
523     is $@, '', 'Push a constant on a magic array';
524     $@ and print "# $@";
525     eval { %ENV = (PATH => __PACKAGE__) };
526     is $@, '', 'Assign a constant to a magic hash';
527     $@ and print "# $@";
528     eval { my %h = qw(A B); %ENV = (PATH => (keys %h)[0]) };
529     is $@, '', 'Assign a shared key to a magic hash';
530     $@ and print "# $@";
531 }
532
533 # Tests for Perl_magic_clearsig
534 foreach my $sig (qw(__WARN__ INT)) {
535     $SIG{$sig} = lc $sig;
536     is $SIG{$sig}, 'main::' . lc $sig, "Can assign to $sig";
537     is delete $SIG{$sig}, 'main::' . lc $sig, "Can delete from $sig";
538     is $SIG{$sig}, undef, "$sig is now gone";
539     is delete $SIG{$sig}, undef, "$sig remains gone";
540 }
541
542 # And now one which doesn't exist;
543 {
544     no warnings 'signal';
545     $SIG{HUNGRY} = 'mmm, pie';
546 }
547 is $SIG{HUNGRY}, 'mmm, pie', 'Can assign to HUNGRY';
548 is delete $SIG{HUNGRY}, 'mmm, pie', 'Can delete from HUNGRY';
549 is $SIG{HUNGRY}, undef, "HUNGRY is now gone";
550 is delete $SIG{HUNGRY}, undef, "HUNGRY remains gone";
551
552 # Test deleting signals that we never set
553 foreach my $sig (qw(__DIE__ _BOGUS_HOOK KILL THIRSTY)) {
554     is $SIG{$sig}, undef, "$sig is not present";
555     is delete $SIG{$sig}, undef, "delete of $sig returns undef";
556 }
557
558 {
559     $! = 9999;
560     is int $!, 9999, q{[perl #72850] Core dump in bleadperl from perl -e '$! = 9999; $a = $!;'};
561
562 }
563
564 # %+ %-
565 SKIP: {
566     skip_if_miniperl("No XS in miniperl", 2);
567     # Make sure defined(*{"+"}) before %+ does not stop %+ from working
568     is
569       runperl(
570         prog => 'BEGIN { defined *{q-+-} } print qq-ok\n- if tied %+',
571       ),
572      "ok\n",
573      'defined *{"+"} does not stop %+ from working';
574     is
575       runperl(
576         prog => 'BEGIN { defined *{q=-=} } print qq-ok\n- if tied %-',
577       ),
578      "ok\n",
579      'defined *{"-"} does not stop %- from working';
580 }
581
582 SKIP: {
583     skip_if_miniperl("No XS in miniperl", 3);
584
585     for ( [qw( %- Tie::Hash::NamedCapture )], [qw( $[ arybase )],
586           [qw( %! Errno )] ) {
587         my ($var, $mod) = @$_;
588         my $modfile = $mod =~ s|::|/|gr . ".pm";
589         fresh_perl_is
590            qq 'sub UNIVERSAL::AUTOLOAD{}
591                $mod\::foo() if 0;
592                $var;
593                print "ok\\n" if \$INC{"$modfile"}',
594           "ok\n",
595            { switches => [ '-X' ] },
596           "$var still loads $mod when stash and UNIVERSAL::AUTOLOAD exist";
597     }
598 }
599
600 # ^^^^^^^^^ New tests go here ^^^^^^^^^
601
602 SKIP: {
603     skip("%ENV manipulations fail or aren't safe on $^O", 19)
604         if $Is_Dos;
605
606  SKIP: {
607         skip("clearing \%ENV is not safe when running under valgrind or on VMS")
608             if $ENV{PERL_VALGRIND} || $Is_VMS;
609
610             $PATH = $ENV{PATH};
611             $PDL = $ENV{PERL_DESTRUCT_LEVEL} || 0;
612             $ENV{foo} = "bar";
613             %ENV = ();
614             $ENV{PATH} = $PATH;
615             $ENV{PERL_DESTRUCT_LEVEL} = $PDL || 0;
616             if ($Is_MSWin32) {
617                 is `set foo 2>NUL`, "";
618             } else {
619                 is `echo \$foo`, "\n";
620             }
621         }
622
623         $ENV{__NoNeSuCh} = 'foo';
624         $0 = 'bar';
625         env_is(__NoNeSuCh => 'foo', 'setting $0 does not break %ENV');
626
627         # stringify a glob
628         $ENV{foo} = *TODO;
629         env_is(foo => '*main::TODO', 'ENV store of stringified glob');
630
631         # stringify a ref
632         my $ref = [];
633         $ENV{foo} = $ref;
634         env_is(foo => "$ref", 'ENV store of stringified ref');
635
636         # downgrade utf8 when possible
637         $bytes = "eh zero \x{A0}";
638         utf8::upgrade($chars = $bytes);
639         $forced = $ENV{foo} = $chars;
640         ok(!utf8::is_utf8($forced) && $forced eq $bytes, 'ENV store downgrades utf8 in SV');
641         env_is(foo => $bytes, 'ENV store downgrades utf8 in setenv');
642
643         # warn when downgrading utf8 is not possible
644         $chars = "X-Day \x{1998}";
645         utf8::encode($bytes = $chars);
646         {
647           my $warned = 0;
648           local $SIG{__WARN__} = sub { ++$warned if $_[0] =~ /^Wide character in setenv/; print "# @_" };
649           $forced = $ENV{foo} = $chars;
650           ok($warned == 1, 'ENV store warns about wide characters');
651         }
652         ok(!utf8::is_utf8($forced) && $forced eq $bytes, 'ENV store encodes high utf8 in SV');
653         env_is(foo => $bytes, 'ENV store encodes high utf8 in SV');
654
655         # test local $ENV{foo} on existing foo
656         {
657           local $ENV{__NoNeSuCh};
658           { local $TODO = 'exists on %ENV should reflect real env';
659             ok(!exists $ENV{__NoNeSuCh}, 'not exists $ENV{existing} during local $ENV{existing}'); }
660           env_is(__NoNeLoCaL => '');
661         }
662         ok(exists $ENV{__NoNeSuCh}, 'exists $ENV{existing} after local $ENV{existing}');
663         env_is(__NoNeSuCh => 'foo');
664
665         # test local $ENV{foo} on new foo
666         {
667           local $ENV{__NoNeLoCaL} = 'foo';
668           ok(exists $ENV{__NoNeLoCaL}, 'exists $ENV{new} during local $ENV{new}');
669           env_is(__NoNeLoCaL => 'foo');
670         }
671         ok(!exists $ENV{__NoNeLoCaL}, 'not exists $ENV{new} after local $ENV{new}');
672         env_is(__NoNeLoCaL => '');
673
674     SKIP: {
675             skip("\$0 check only on Linux and FreeBSD", 2)
676                 unless $^O =~ /^(linux|freebsd)$/
677                     && open CMDLINE, "/proc/$$/cmdline";
678
679             chomp(my $line = scalar <CMDLINE>);
680             my $me = (split /\0/, $line)[0];
681             is $me, $0, 'altering $0 is effective (testing with /proc/)';
682             close CMDLINE;
683             # perlbug #22811
684             my $mydollarzero = sub {
685               my($arg) = shift;
686               $0 = $arg if defined $arg;
687               # In FreeBSD the ps -o command= will cause
688               # an empty header line, grab only the last line.
689               my $ps = (`ps -o command= -p $$`)[-1];
690               return if $?;
691               chomp $ps;
692               printf "# 0[%s]ps[%s]\n", $0, $ps;
693               $ps;
694             };
695             my $ps = $mydollarzero->("x");
696             ok(!$ps  # we allow that something goes wrong with the ps command
697                # In Linux 2.4 we would get an exact match ($ps eq 'x') but
698                # in Linux 2.2 there seems to be something funny going on:
699                # it seems as if the original length of the argv[] would
700                # be stored in the proc struct and then used by ps(1),
701                # no matter what characters we use to pad the argv[].
702                # (And if we use \0:s, they are shown as spaces.)  Sigh.
703                || $ps =~ /^x\s*$/
704                # FreeBSD cannot get rid of both the leading "perl :"
705                # and the trailing " (perl)": some FreeBSD versions
706                # can get rid of the first one.
707                || ($^O eq 'freebsd' && $ps =~ m/^(?:perl: )?x(?: \(perl\))?$/),
708                        'altering $0 is effective (testing with `ps`)');
709         }
710 }
711
712 # test case-insignificance of %ENV (these tests must be enabled only
713 # when perl is compiled with -DENV_IS_CASELESS)
714 SKIP: {
715     skip('no caseless %ENV support', 4) unless $Is_MSWin32 || $Is_NetWare;
716
717     %ENV = ();
718     $ENV{'Foo'} = 'bar';
719     $ENV{'fOo'} = 'baz';
720     is scalar(keys(%ENV)), 1;
721     ok exists $ENV{'FOo'};
722     is delete $ENV{'foO'}, 'baz';
723     is scalar(keys(%ENV)), 0;
724 }
725
726 __END__
727
728 # Put new tests before the various ENV tests, as they blow %ENV away.